lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10 );
  11
  12 sub new {
  13   bless({ %{$_[1]||{}} }, (ref($_[0])||$_[0]))->BUILDALL;
  14 }
  15
  16 sub BUILDALL {
  17   my $self = shift;
  18   $self->{reserved_ident_parts}
  19     ||= (
  20       our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  21     );
  22   $self->{quote_chars}||=[''];
  23   $self->{simple_ops}||=$self->_default_simple_ops;
  24   return $self;
  25 }
  26
  27 sub _default_simple_ops {
  28   +{
  29     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  30     (map +($_ => 'unop'), qw(NOT) ),
  31     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  32     (map +($_ => 'flatten'), qw(AND OR) ),
  33     (map +($_ => 'in'), ('IN', 'NOT IN')),
  34     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  35     (apply => 'apply'),
  36   }
  37 }
  38
  39 sub render {
  40   my $self = shift;
  41   $self->_flatten_structure($self->_render(@_))
  42 }
  43
  44 sub _flatten_structure {
  45   my ($self, $struct) = @_;
  46   my @bind;
  47   [ do {
  48       my @p = map {
  49         my $r = ref;
  50         if (!$r) { $_ }
  51         elsif ($r eq 'ARRAY') {
  52           my ($sql, @b) = @{$self->_flatten_structure($_)};
  53           push @bind, @b;
  54           $sql;
  55         }
  56         elsif ($r eq 'HASH') { push @bind, $_; () }
  57         else { die "_flatten_structure can't handle ref type $r for $_" }
  58       } @$struct;
  59       join '', map {
  60         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  61       } 0 .. $#p;
  62     },
  63     @bind
  64   ];
  65 }
  66
  67 # I presented this to permit strange people to easily supply a patch to lc()
  68 # their keywords, as I have heard many desire to do, lest they infect me
  69 # with whatever malady caused this desire by their continued proximity for
  70 # want of such a feature.
  71 #
  72 # Then I realised that SQL::Abstract compatibility work required it.
  73 #
  74 # FEH.
  75
  76 sub _format_keyword { $_[0]->{lc_keywords} ? lc($_[1]) : $_[1] }
  77
  78 sub _render {
  79   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  80 }
  81
  82 sub _render_broken {
  83   my ($self, $dq) = @_;
  84   require Data::Dumper::Concise;
  85   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  86 }
  87
  88 sub _render_identifier {
  89   die "Unidentified identifier (SQL can no has \$_)"
  90     unless my @i = @{$_[1]->{elements}};
  91   # handle single or paired quote chars
  92   my ($q1, $q2) = @{$_[0]->{quote_chars}}[0,-1];
  93   my $always_quote = $_[0]->{always_quote};
  94   my $res_check = $_[0]->{reserved_ident_parts};
  95   return [
  96     join
  97       $_[0]->{identifier_sep}||'.',
  98       map +(
  99         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 100           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 101           : ( # reserved are stored uc, quote if non-word
 102               $always_quote || $res_check->{+uc} || /\W/
 103                 ? $q1.$_.$q2
 104                 : $_
 105             )
 106       ), @i
 107   ];
 108 }
 109
 110 sub _render_value {
 111   defined($_[1]->{value})
 112     ? [ '?', $_[1] ]
 113     : [ 'NULL' ];
 114 }
 115
 116 sub _operator_type { 'SQL.Naive' }
 117
 118 sub _render_operator {
 119   my ($self, $dq) = @_;
 120   my $op = $dq->{operator};
 121   unless (exists $op->{$self->_operator_type}) {
 122     $op->{$self->_operator_type} = $self->_convert_op($dq);
 123   }
 124   my $op_name = $op->{$self->_operator_type};
 125   if (my $op_type = $self->{simple_ops}{$op_name}) {
 126     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 127   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 128     return $self->$meth($dq);
 129   }
 130   if (my $argc = @{$dq->{args}}) {
 131     if ($argc == 1) {
 132       return $self->_handle_op_type_unop($op_name, $dq);
 133     } elsif ($argc == 2) {
 134       return $self->_handle_op_type_binop($op_name, $dq);
 135     }
 136   }
 137   die "Unsure how to handle ${op_name}";
 138 }
 139
 140 sub _handle_op_type_binop {
 141   my ($self, $op_name, $dq) = @_;
 142   die "${op_name} registered as binary op but args contain "
 143       .scalar(@{$dq->{args}})." entries"
 144     unless @{$dq->{args}} == 2;
 145   [
 146     $self->_render($dq->{args}[0]),
 147     $op_name,
 148     $self->_render($dq->{args}[1]),
 149   ]
 150 }
 151
 152 sub _handle_op_type_unop {
 153   my ($self, $op_name, $dq) = @_;
 154   die "${op_name} registered as unary op but args contain "
 155       .scalar(@{$dq->{args}})." entries"
 156     unless @{$dq->{args}} == 1;
 157   [
 158     '(',
 159     $op_name,
 160     $self->_render($dq->{args}[0]),
 161     ')',
 162   ]
 163 }
 164
 165 sub _handle_op_type_unop_reverse {
 166   my ($self, $op_name, $dq) = @_;
 167   die "${op_name} registered as unary op but args contain "
 168       .scalar(@{$dq->{args}})." entries"
 169     unless @{$dq->{args}} == 1;
 170   [
 171     $self->_render($dq->{args}[0]),
 172     $op_name,
 173   ]
 174 }
 175
 176 sub _handle_op_type_flatten {
 177   my ($self, $op_name, $dq) = @_;
 178   my @argq = @{$dq->{args}};
 179   my @arg_final;
 180   while (my $arg = shift @argq) {
 181
 182     unless ($arg->{type} eq DQ_OPERATOR) {
 183       push @arg_final, $arg;
 184       next;
 185     }
 186
 187     my $op = $arg->{operator};
 188     unless (exists $op->{$self->_operator_type}) {
 189       $op->{$self->_operator_type} = $self->_convert_op($arg);
 190     }
 191
 192     if ($op->{$self->_operator_type} eq $op_name) {
 193       unshift @argq, @{$arg->{args}};
 194     } else {
 195       push @arg_final, $arg;
 196     }
 197   }
 198   my @sql = ('(', map +($self->_render($_), $op_name), @arg_final);
 199   $sql[-1] = ')'; # replace final AND or whatever with )
 200   \@sql;
 201 }
 202
 203 sub _handle_op_type_in {
 204   my ($self, $op, $dq) = @_;
 205   my ($lhs, @in) = @{$dq->{args}};
 206   my @rhs = ('(', map +($self->_render($_), ','), @in);
 207   $rhs[-1] = ')';
 208   [ $self->_render($lhs), $op, @rhs ];
 209 }
 210
 211 sub _handle_op_type_between {
 212   my ($self, $op_name, $dq) = @_;
 213   my @args = @{$dq->{args}};
 214   if (@args == 3) {
 215     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 216     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 217   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 218     my ($lhs, $rhs) = (map $self->_render($_), @args);
 219     [ '(', $lhs, $op_name, $rhs, ')' ];
 220   } else {
 221     die "Invalid args for between: ${\scalar @args} given";
 222   }
 223 }
 224
 225 sub _handle_op_type_apply {
 226   my ($self, $op_name, $dq) = @_;
 227   my ($func, @args) = @{$dq->{args}};
 228   die "Function name must be identifier"
 229     unless $func->{type} eq DQ_IDENTIFIER;
 230   my $ident = do {
 231     # The problem we have here is that built-ins can't be quoted, generally.
 232     # I rather wonder if things like MAX(...) need to -not- be handled as
 233     # an apply and instead of something else, maybe a parenop type - but
 234     # as an explicitly Naive renderer this seems like a reasonable answer.
 235     local @{$self}{qw(reserved_ident_parts always_quote)};
 236     $self->_render_identifier($func)->[0];
 237   };
 238   [
 239     "$ident(",
 240     (map $self->_render($_), @args),
 241     ')'
 242   ]
 243 }
 244
 245 sub _convert_op {
 246   my ($self, $dq) = @_;
 247   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 248     for ($perl_op) {
 249       $_ eq '==' and return '=';
 250       $_ eq 'eq' and return '=';
 251       $_ eq '!' and return 'NOT';
 252     }
 253     return uc $perl_op; # hope!
 254   }
 255   die "Can't convert non-perl op yet";
 256 }
 257
 258 sub _render_select {
 259   my ($self, $dq) = @_;
 260   die "Empty select list" unless @{$dq->{select}};
 261
 262   # it is, in fact, completely valid for there to be nothing for us
 263   # to project from since many databases handle 'SELECT 1;' fine
 264
 265   my @select = map [
 266     ($_->{type} eq DQ_ALIAS
 267       ? $self->_render_alias($_, $self->_format_keyword('AS'))
 268       : $self->_render($_)
 269     ),
 270    ','
 271   ], @{$dq->{select}};
 272
 273   # we put the commas inside the [] for each entry as a hint to the pretty
 274   # printer downstream so now we need to eliminate the comma from the last
 275   # entry - we know there always is one due to the die guard at the top
 276
 277   pop @{$select[-1]};
 278
 279   return [
 280     $self->_format_keyword('SELECT'),
 281     \@select,
 282     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 283     # since we're the SELECT and therefore always come first, we don't care.
 284     ($dq->{from}
 285        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 286        : ()
 287     )
 288   ];
 289 }
 290
 291 sub _render_alias {
 292   my ($self, $dq, $as) = @_;
 293   # FROM foo foo -> FROM foo
 294   # FROM foo.bar bar -> FROM foo.bar
 295   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 296     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 297       return $self->_render($dq->{alias});
 298     }
 299   }
 300   return [
 301     $self->_render($dq->{alias}),
 302     $as || ' ',
 303     $self->_render_identifier({ elements => [ $dq->{as} ] })
 304   ];
 305 }
 306
 307 sub _render_literal {
 308   my ($self, $dq) = @_;
 309   unless ($dq->{subtype} eq 'SQL') {
 310     die "Can't render non-SQL literal";
 311   }
 312   if ($dq->{literal}) {
 313     return [
 314       $dq->{literal}, @{$dq->{values}||[]}
 315     ];
 316   } elsif ($dq->{parts}) {
 317     return [ map $self->_render($_), @{$dq->{parts}} ];
 318   } else {
 319     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 320   }
 321 }
 322
 323 sub _render_join {
 324   my ($self, $dq) = @_;
 325   my ($left, $right) = @{$dq->{join}};
 326   die "No support for ON yet" if $dq->{on};
 327   die "No support for LEFT/RIGHT yet" if $dq->{outer};
 328   [ $self->_render($left), ',', $self->_render($right) ];
 329 }
 330
 331 sub _render_where {
 332   my ($self, $dq) = @_;
 333   my ($from, $where) = @{$dq}{qw(from where)};
 334   [
 335     ($from ? $self->_render($from) : ()),
 336     $self->_format_keyword('WHERE'),
 337     $self->_render($where)
 338   ]
 339 }
 340
 341 sub _render_order {
 342   my ($self, $dq) = @_;
 343   my @ret = (
 344     $self->_format_keyword('ORDER BY'),
 345     $self->_render($dq->{by}),
 346     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 347   );
 348   my $from;
 349   while ($from = $dq->{from}) {
 350     last unless $from->{type} eq DQ_ORDER;
 351     $dq = $from;
 352     push @ret, (
 353       ',',
 354       $self->_render($dq->{by}),
 355       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 356     );
 357   }
 358   unshift @ret, $self->_render($from) if $from;
 359   \@ret;
 360 }
 361
 362 sub _render_delete {
 363   my ($self, $dq) = @_;
 364   my ($target, $where) = @{$dq}{qw(target where)};
 365   [ $self->_format_keyword('DELETE FROM'),
 366     $self->_render($target),
 367     ($where
 368       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 369       : ())
 370   ];
 371 }
 372
 373 sub _render_update {
 374   my ($self, $dq) = @_;
 375   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 376   my @rendered_set = intersperse(
 377     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 378   );
 379   [ $self->_format_keyword('UPDATE'),
 380     $self->_render($target),
 381     $self->_format_keyword('SET'),
 382     @rendered_set,
 383     ($where
 384       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 385       : ())
 386   ];
 387 }
 388
 389 1;