lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10   DQ_GROUP DQ_SELECT DQ_SLICE
  11 );
  12
  13 use Moo;
  14
  15 has reserved_ident_parts => (
  16   is => 'ro', default => sub {
  17     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  18   }
  19 );
  20
  21 has quote_chars => (is => 'ro', default => sub { [''] });
  22
  23 has identifier_sep => (is => 'ro', default => sub { '.' });
  24
  25 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  26
  27 has lc_keywords => (is => 'ro', default => sub { 0 });
  28
  29 has always_quote => (is => 'ro', default => sub { 0 });
  30
  31 has collapse_aliases => (is => 'ro', default => sub { 1 });
  32
  33 sub _default_simple_ops {
  34   +{
  35     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  36     (map +($_ => 'unop'), qw(NOT) ),
  37     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  38     (map +($_ => 'flatten'), qw(AND OR) ),
  39     (map +($_ => 'in'), ('IN', 'NOT IN')),
  40     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  41     (apply => 'apply'),
  42   }
  43 }
  44
  45 sub render {
  46   my $self = shift;
  47   $self->_flatten_structure($self->_render(@_))
  48 }
  49
  50 sub _flatten_structure {
  51   my ($self, $struct) = @_;
  52   my @bind;
  53   [ do {
  54       my @p = map {
  55         my $r = ref;
  56         if (!$r) { $_ }
  57         elsif ($r eq 'ARRAY') {
  58           my ($sql, @b) = @{$self->_flatten_structure($_)};
  59           push @bind, @b;
  60           $sql;
  61         }
  62         elsif ($r eq 'HASH') { push @bind, $_; () }
  63         else { die "_flatten_structure can't handle ref type $r for $_" }
  64       } @$struct;
  65       join '', map {
  66         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  67       } 0 .. $#p;
  68     },
  69     @bind
  70   ];
  71 }
  72
  73 # I presented this to permit strange people to easily supply a patch to lc()
  74 # their keywords, as I have heard many desire to do, lest they infect me
  75 # with whatever malady caused this desire by their continued proximity for
  76 # want of such a feature.
  77 #
  78 # Then I realised that SQL::Abstract compatibility work required it.
  79 #
  80 # FEH.
  81
  82 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  83
  84 sub _render {
  85   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  86 }
  87
  88 sub _render_broken {
  89   my ($self, $dq) = @_;
  90   require Data::Dumper::Concise;
  91   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  92 }
  93
  94 sub _render_identifier {
  95   die "Unidentified identifier (SQL can no has \$_)"
  96     unless my @i = @{$_[1]->{elements}};
  97   # handle single or paired quote chars
  98   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  99   my $always_quote = $_[0]->always_quote;
 100   my $res_check = $_[0]->reserved_ident_parts;
 101   return [
 102     join
 103       $_[0]->identifier_sep,
 104       map +(
 105         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 106           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 107           : ( # reserved are stored uc, quote if non-word
 108               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 109                 ? $q1.$_.$q2
 110                 : $_
 111             )
 112       ), @i
 113   ];
 114 }
 115
 116 sub _render_value {
 117   [ '?', $_[1] ]
 118 }
 119
 120 sub _operator_type { 'SQL.Naive' }
 121
 122 sub _render_operator {
 123   my ($self, $dq) = @_;
 124   my $op = $dq->{operator};
 125   unless (exists $op->{$self->_operator_type}) {
 126     $op->{$self->_operator_type} = $self->_convert_op($dq);
 127   }
 128   my $op_name = $op->{$self->_operator_type};
 129   if (my $op_type = $self->simple_ops->{$op_name}) {
 130     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 131   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 132     return $self->$meth($dq);
 133   }
 134   if (my $argc = @{$dq->{args}}) {
 135     if ($argc == 1) {
 136       return $self->_handle_op_type_unop($op_name, $dq);
 137     } elsif ($argc == 2) {
 138       return $self->_handle_op_type_binop($op_name, $dq);
 139     }
 140   }
 141   die "Unsure how to handle ${op_name}";
 142 }
 143
 144 sub _maybe_parenthesise {
 145   my ($self, $dq) = @_;
 146   my %parenthesise = map +($_ => 1), DQ_SELECT, DQ_SLICE;
 147   return
 148     ($parenthesise{$dq->{type}}
 149       ? [ '(', $self->_render($dq), ')' ]
 150       : $self->_render($dq));
 151 }
 152
 153 sub _handle_op_type_binop {
 154   my ($self, $op_name, $dq) = @_;
 155   die "${op_name} registered as binary op but args contain "
 156       .scalar(@{$dq->{args}})." entries"
 157     unless @{$dq->{args}} == 2;
 158   [
 159     $self->_maybe_parenthesise($dq->{args}[0]),
 160     $op_name,
 161     $self->_maybe_parenthesise($dq->{args}[1]),
 162   ]
 163 }
 164
 165 sub _handle_op_type_unop {
 166   my ($self, $op_name, $dq) = @_;
 167   die "${op_name} registered as unary op but args contain "
 168       .scalar(@{$dq->{args}})." entries"
 169     unless @{$dq->{args}} == 1;
 170   [
 171     '(',
 172     $op_name,
 173     $self->_render($dq->{args}[0]),
 174     ')',
 175   ]
 176 }
 177
 178 sub _handle_op_type_unop_reverse {
 179   my ($self, $op_name, $dq) = @_;
 180   die "${op_name} registered as unary op but args contain "
 181       .scalar(@{$dq->{args}})." entries"
 182     unless @{$dq->{args}} == 1;
 183   [
 184     $self->_render($dq->{args}[0]),
 185     $op_name,
 186   ]
 187 }
 188
 189 sub _handle_op_type_flatten {
 190   my ($self, $op_name, $dq) = @_;
 191   my @argq = @{$dq->{args}};
 192   my @arg_final;
 193   while (my $arg = shift @argq) {
 194
 195     unless ($arg->{type} eq DQ_OPERATOR) {
 196       push @arg_final, $arg;
 197       next;
 198     }
 199
 200     my $op = $arg->{operator};
 201     unless (exists $op->{$self->_operator_type}) {
 202       $op->{$self->_operator_type} = $self->_convert_op($arg);
 203     }
 204
 205     if ($op->{$self->_operator_type} eq $op_name) {
 206       unshift @argq, @{$arg->{args}};
 207     } else {
 208       push @arg_final, $arg;
 209     }
 210   }
 211   [ '(',
 212       intersperse(
 213         $self->_format_keyword($op_name),
 214         map $self->_maybe_parenthesise($_), @arg_final
 215       ),
 216     ')'
 217   ];
 218 }
 219
 220 sub _handle_op_type_in {
 221   my ($self, $op, $dq) = @_;
 222   my ($lhs, @in) = @{$dq->{args}};
 223   [ $self->_render($lhs),
 224     $op,
 225     '(',
 226       intersperse(',', map $self->_render($_), @in),
 227     ')'
 228   ];
 229 }
 230
 231 sub _handle_op_type_between {
 232   my ($self, $op_name, $dq) = @_;
 233   my @args = @{$dq->{args}};
 234   if (@args == 3) {
 235     my ($lhs, $rhs1, $rhs2) = (map $self->_maybe_parenthesise($_), @args);
 236     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 237   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 238     my ($lhs, $rhs) = (map $self->_render($_), @args);
 239     [ '(', $lhs, $op_name, $rhs, ')' ];
 240   } else {
 241     die "Invalid args for between: ${\scalar @args} given";
 242   }
 243 }
 244
 245 sub _handle_op_type_apply {
 246   my ($self, $op_name, $dq) = @_;
 247   my ($func, @args) = @{$dq->{args}};
 248   die "Function name must be identifier"
 249     unless $func->{type} eq DQ_IDENTIFIER;
 250   my $ident = do {
 251     # The problem we have here is that built-ins can't be quoted, generally.
 252     # I rather wonder if things like MAX(...) need to -not- be handled as
 253     # an apply and instead of something else, maybe a parenop type - but
 254     # as an explicitly Naive renderer this seems like a reasonable answer.
 255     local @{$self}{qw(reserved_ident_parts always_quote)};
 256     $self->_render_identifier($func)->[0];
 257   };
 258   [
 259     "$ident(",
 260       intersperse(',', map $self->_maybe_parenthesise($_), @args),
 261     ')'
 262   ]
 263 }
 264
 265 sub _convert_op {
 266   my ($self, $dq) = @_;
 267   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 268     for ($perl_op) {
 269       $_ eq '==' and return '=';
 270       $_ eq 'eq' and return '=';
 271       $_ eq '!' and return 'NOT';
 272     }
 273     return uc $perl_op; # hope!
 274   }
 275   die "Can't convert non-perl op yet";
 276 }
 277
 278 sub _render_select {
 279   my ($self, $dq) = @_;
 280   die "Empty select list" unless @{$dq->{select}};
 281
 282   # it is, in fact, completely valid for there to be nothing for us
 283   # to project from since many databases handle 'SELECT 1;' fine
 284
 285   my @select = intersperse(',',
 286     map +($_->{type} eq DQ_ALIAS
 287            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 288            : $self->_render($_)), @{$dq->{select}}
 289   );
 290
 291   return [
 292     $self->_format_keyword('SELECT'),
 293     \@select,
 294     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 295     # since we're the SELECT and therefore always come first, we don't care.
 296     ($dq->{from}
 297        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 298        : ()
 299     ),
 300   ];
 301 }
 302
 303 sub _render_alias {
 304   my ($self, $dq, $as) = @_;
 305   # FROM foo foo -> FROM foo
 306   # FROM foo.bar bar -> FROM foo.bar
 307   if ($self->collapse_aliases) {
 308     if ($dq->{from}{type} eq DQ_IDENTIFIER) {
 309       if ($dq->{from}{elements}[-1] eq $dq->{to}) {
 310         return $self->_render($dq->{from});
 311       }
 312     }
 313   }
 314   my %parenthesise = map +($_ => 1), DQ_SELECT, DQ_SLICE;
 315   return [ # XXX not sure this is the right place to detect this
 316     $self->_maybe_parenthesise($dq->{from}),
 317     $as || ' ',
 318     $self->_render_identifier({ elements => [ $dq->{to} ] })
 319   ];
 320 }
 321
 322 sub _render_literal {
 323   my ($self, $dq) = @_;
 324   unless ($dq->{subtype} eq 'SQL') {
 325     die "Can't render non-SQL literal";
 326   }
 327   if (defined($dq->{literal})) {
 328     return [
 329       $dq->{literal}, @{$dq->{values}||[]}
 330     ];
 331   } elsif ($dq->{parts}) {
 332     return [ map $self->_render($_), @{$dq->{parts}} ];
 333   } else {
 334     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 335   }
 336 }
 337
 338 sub _render_join {
 339   my ($self, $dq) = @_;
 340   my ($left, $right) = @{$dq}{qw(left right)};
 341   my $join = do {
 342     if ($dq->{outer}) {
 343       $self->_format_keyword(uc($dq->{outer}).' JOIN');
 344     } elsif ($dq->{on}) {
 345       $self->_format_keyword('JOIN');
 346     } else {
 347       ','
 348     }
 349   };
 350   my $rhs = $self->_render($right);
 351   [
 352     $self->_render($left), $join,
 353     ($right->{type} eq DQ_JOIN ? ('(', $rhs, ')') : $rhs),
 354     ($dq->{on}
 355       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 356       : ())
 357   ];
 358 }
 359
 360 sub _render_where {
 361   my ($self, $dq) = @_;
 362   my ($from, $where) = @{$dq}{qw(from where)};
 363   my $keyword = ($from && $from->{type} eq DQ_GROUP) ? 'HAVING' : 'WHERE';
 364   [
 365     ($from ? $self->_render($from) : ()),
 366     $self->_format_keyword($keyword),
 367     $self->_render($where)
 368   ]
 369 }
 370
 371 sub _render_order {
 372   my ($self, $dq) = @_;
 373   my @ret = (
 374     $self->_format_keyword('ORDER BY'),
 375     $self->_render($dq->{by}),
 376     ($dq->{reverse}
 377       ? $self->_format_keyword('DESC')
 378       : ())
 379   );
 380   my $from;
 381   while ($from = $dq->{from}) {
 382     last unless $from->{type} eq DQ_ORDER;
 383     $dq = $from;
 384     push @ret, (
 385       ',',
 386       $self->_render($dq->{by}),
 387       ($dq->{reverse}
 388         ? $self->_format_keyword('DESC')
 389         : ())
 390     );
 391   }
 392   unshift @ret, $self->_render($from) if $from;
 393   \@ret;
 394 }
 395
 396 sub _render_group {
 397   my ($self, $dq) = @_;
 398   # this could also squash like order does. but I dunno whether that should
 399   # move somewhere else just yet.
 400   my @ret = (
 401     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 402     (@{$dq->{by}}
 403       ? (
 404           $self->_format_keyword('GROUP BY'),
 405           intersperse(',', map $self->_render($_), @{$dq->{by}})
 406          )
 407       : ())
 408   );
 409   \@ret;
 410 }
 411
 412 sub _render_delete {
 413   my ($self, $dq) = @_;
 414   my ($target, $where) = @{$dq}{qw(target where)};
 415   [ $self->_format_keyword('DELETE FROM'),
 416     $self->_render($target),
 417     ($where
 418       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 419       : ())
 420   ];
 421 }
 422
 423 sub _render_update {
 424   my ($self, $dq) = @_;
 425   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 426   unless ($set) {
 427     die "Must have set key - names+value keys not yet tested";
 428     my ($names, $value) = @{$dq}{qw(names value)};
 429     die "Must have names and value or set" unless $names and $value;
 430     die "names and value must be same size" unless @$names == @$value;
 431     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 432   }
 433   my @rendered_set = intersperse(
 434     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 435   );
 436   [ $self->_format_keyword('UPDATE'),
 437     $self->_render($target),
 438     $self->_format_keyword('SET'),
 439     @rendered_set,
 440     ($where
 441       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 442       : ())
 443   ];
 444 }
 445
 446 sub _render_insert {
 447   my ($self, $dq) = @_;
 448   my ($target, $names, $values, $returning)
 449     = @{$dq}{qw(target names values returning)};
 450   unless ($values) {
 451     die "Must have values key - sets key not yet implemented";
 452   }
 453   [ $self->_format_keyword('INSERT INTO'),
 454     $self->_render($target),
 455     ($names
 456       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 457       : ()),
 458     $self->_format_keyword('VALUES'),
 459     intersperse(',',
 460       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 461         @$values
 462     ),
 463     ($returning
 464       ? ($self->_format_keyword('RETURNING'),
 465          intersperse(',', map $self->_render($_), @$returning))
 466       : ()),
 467   ];
 468 }
 469
 470 1;