lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10   DQ_GROUP
  11 );
  12
  13 use Moo;
  14
  15 has reserved_ident_parts => (
  16   is => 'ro', default => sub {
  17     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  18   }
  19 );
  20
  21 has quote_chars => (is => 'ro', default => sub { [''] });
  22
  23 has identifier_sep => (is => 'ro', default => sub { '.' });
  24
  25 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  26
  27 has lc_keywords => (is => 'ro', default => sub { 0 });
  28
  29 has always_quote => (is => 'ro', default => sub { 0 });
  30
  31 sub _default_simple_ops {
  32   +{
  33     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  34     (map +($_ => 'unop'), qw(NOT) ),
  35     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  36     (map +($_ => 'flatten'), qw(AND OR) ),
  37     (map +($_ => 'in'), ('IN', 'NOT IN')),
  38     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  39     (apply => 'apply'),
  40   }
  41 }
  42
  43 sub render {
  44   my $self = shift;
  45   $self->_flatten_structure($self->_render(@_))
  46 }
  47
  48 sub _flatten_structure {
  49   my ($self, $struct) = @_;
  50   my @bind;
  51   [ do {
  52       my @p = map {
  53         my $r = ref;
  54         if (!$r) { $_ }
  55         elsif ($r eq 'ARRAY') {
  56           my ($sql, @b) = @{$self->_flatten_structure($_)};
  57           push @bind, @b;
  58           $sql;
  59         }
  60         elsif ($r eq 'HASH') { push @bind, $_; () }
  61         else { die "_flatten_structure can't handle ref type $r for $_" }
  62       } @$struct;
  63       join '', map {
  64         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  65       } 0 .. $#p;
  66     },
  67     @bind
  68   ];
  69 }
  70
  71 # I presented this to permit strange people to easily supply a patch to lc()
  72 # their keywords, as I have heard many desire to do, lest they infect me
  73 # with whatever malady caused this desire by their continued proximity for
  74 # want of such a feature.
  75 #
  76 # Then I realised that SQL::Abstract compatibility work required it.
  77 #
  78 # FEH.
  79
  80 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  81
  82 sub _render {
  83   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  84 }
  85
  86 sub _render_broken {
  87   my ($self, $dq) = @_;
  88   require Data::Dumper::Concise;
  89   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  90 }
  91
  92 sub _render_identifier {
  93   die "Unidentified identifier (SQL can no has \$_)"
  94     unless my @i = @{$_[1]->{elements}};
  95   # handle single or paired quote chars
  96   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  97   my $always_quote = $_[0]->always_quote;
  98   my $res_check = $_[0]->reserved_ident_parts;
  99   return [
 100     join
 101       $_[0]->identifier_sep,
 102       map +(
 103         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 104           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 105           : ( # reserved are stored uc, quote if non-word
 106               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 107                 ? $q1.$_.$q2
 108                 : $_
 109             )
 110       ), @i
 111   ];
 112 }
 113
 114 sub _render_value {
 115   [ '?', $_[1] ]
 116 }
 117
 118 sub _operator_type { 'SQL.Naive' }
 119
 120 sub _render_operator {
 121   my ($self, $dq) = @_;
 122   my $op = $dq->{operator};
 123   unless (exists $op->{$self->_operator_type}) {
 124     $op->{$self->_operator_type} = $self->_convert_op($dq);
 125   }
 126   my $op_name = $op->{$self->_operator_type};
 127   if (my $op_type = $self->simple_ops->{$op_name}) {
 128     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 129   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 130     return $self->$meth($dq);
 131   }
 132   if (my $argc = @{$dq->{args}}) {
 133     if ($argc == 1) {
 134       return $self->_handle_op_type_unop($op_name, $dq);
 135     } elsif ($argc == 2) {
 136       return $self->_handle_op_type_binop($op_name, $dq);
 137     }
 138   }
 139   die "Unsure how to handle ${op_name}";
 140 }
 141
 142 sub _handle_op_type_binop {
 143   my ($self, $op_name, $dq) = @_;
 144   die "${op_name} registered as binary op but args contain "
 145       .scalar(@{$dq->{args}})." entries"
 146     unless @{$dq->{args}} == 2;
 147   [
 148     $self->_render($dq->{args}[0]),
 149     $op_name,
 150     $self->_render($dq->{args}[1]),
 151   ]
 152 }
 153
 154 sub _handle_op_type_unop {
 155   my ($self, $op_name, $dq) = @_;
 156   die "${op_name} registered as unary op but args contain "
 157       .scalar(@{$dq->{args}})." entries"
 158     unless @{$dq->{args}} == 1;
 159   [
 160     '(',
 161     $op_name,
 162     $self->_render($dq->{args}[0]),
 163     ')',
 164   ]
 165 }
 166
 167 sub _handle_op_type_unop_reverse {
 168   my ($self, $op_name, $dq) = @_;
 169   die "${op_name} registered as unary op but args contain "
 170       .scalar(@{$dq->{args}})." entries"
 171     unless @{$dq->{args}} == 1;
 172   [
 173     $self->_render($dq->{args}[0]),
 174     $op_name,
 175   ]
 176 }
 177
 178 sub _handle_op_type_flatten {
 179   my ($self, $op_name, $dq) = @_;
 180   my @argq = @{$dq->{args}};
 181   my @arg_final;
 182   while (my $arg = shift @argq) {
 183
 184     unless ($arg->{type} eq DQ_OPERATOR) {
 185       push @arg_final, $arg;
 186       next;
 187     }
 188
 189     my $op = $arg->{operator};
 190     unless (exists $op->{$self->_operator_type}) {
 191       $op->{$self->_operator_type} = $self->_convert_op($arg);
 192     }
 193
 194     if ($op->{$self->_operator_type} eq $op_name) {
 195       unshift @argq, @{$arg->{args}};
 196     } else {
 197       push @arg_final, $arg;
 198     }
 199   }
 200   [ '(',
 201       intersperse(
 202         $self->_format_keyword($op_name),
 203         map $self->_render($_), @arg_final
 204       ),
 205     ')'
 206   ];
 207 }
 208
 209 sub _handle_op_type_in {
 210   my ($self, $op, $dq) = @_;
 211   my ($lhs, @in) = @{$dq->{args}};
 212   [ $self->_render($lhs),
 213     $op,
 214     '(',
 215       intersperse(',', map $self->_render($_), @in),
 216     ')'
 217   ];
 218 }
 219
 220 sub _handle_op_type_between {
 221   my ($self, $op_name, $dq) = @_;
 222   my @args = @{$dq->{args}};
 223   if (@args == 3) {
 224     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 225     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 226   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 227     my ($lhs, $rhs) = (map $self->_render($_), @args);
 228     [ '(', $lhs, $op_name, $rhs, ')' ];
 229   } else {
 230     die "Invalid args for between: ${\scalar @args} given";
 231   }
 232 }
 233
 234 sub _handle_op_type_apply {
 235   my ($self, $op_name, $dq) = @_;
 236   my ($func, @args) = @{$dq->{args}};
 237   die "Function name must be identifier"
 238     unless $func->{type} eq DQ_IDENTIFIER;
 239   my $ident = do {
 240     # The problem we have here is that built-ins can't be quoted, generally.
 241     # I rather wonder if things like MAX(...) need to -not- be handled as
 242     # an apply and instead of something else, maybe a parenop type - but
 243     # as an explicitly Naive renderer this seems like a reasonable answer.
 244     local @{$self}{qw(reserved_ident_parts always_quote)};
 245     $self->_render_identifier($func)->[0];
 246   };
 247   [
 248     "$ident(",
 249       intersperse(',', map $self->_render($_), @args),
 250     ')'
 251   ]
 252 }
 253
 254 sub _convert_op {
 255   my ($self, $dq) = @_;
 256   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 257     for ($perl_op) {
 258       $_ eq '==' and return '=';
 259       $_ eq 'eq' and return '=';
 260       $_ eq '!' and return 'NOT';
 261     }
 262     return uc $perl_op; # hope!
 263   }
 264   die "Can't convert non-perl op yet";
 265 }
 266
 267 sub _render_select {
 268   my ($self, $dq) = @_;
 269   die "Empty select list" unless @{$dq->{select}};
 270
 271   # it is, in fact, completely valid for there to be nothing for us
 272   # to project from since many databases handle 'SELECT 1;' fine
 273
 274   my @select = intersperse(',',
 275     map +($_->{type} eq DQ_ALIAS
 276            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 277            : $self->_render($_)), @{$dq->{select}}
 278   );
 279
 280   return [
 281     $self->_format_keyword('SELECT'),
 282     \@select,
 283     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 284     # since we're the SELECT and therefore always come first, we don't care.
 285     ($dq->{from}
 286        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 287        : ()
 288     )
 289   ];
 290 }
 291
 292 sub _render_alias {
 293   my ($self, $dq, $as) = @_;
 294   # FROM foo foo -> FROM foo
 295   # FROM foo.bar bar -> FROM foo.bar
 296   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 297     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 298       return $self->_render($dq->{alias});
 299     }
 300   }
 301   return [
 302     $self->_render($dq->{alias}),
 303     $as || ' ',
 304     $self->_render_identifier({ elements => [ $dq->{as} ] })
 305   ];
 306 }
 307
 308 sub _render_literal {
 309   my ($self, $dq) = @_;
 310   unless ($dq->{subtype} eq 'SQL') {
 311     die "Can't render non-SQL literal";
 312   }
 313   if ($dq->{literal}) {
 314     return [
 315       $dq->{literal}, @{$dq->{values}||[]}
 316     ];
 317   } elsif ($dq->{parts}) {
 318     return [ map $self->_render($_), @{$dq->{parts}} ];
 319   } else {
 320     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 321   }
 322 }
 323
 324 sub _render_join {
 325   my ($self, $dq) = @_;
 326   my ($left, $right) = @{$dq->{join}};
 327   my $join = do {
 328     if ($dq->{outer}) {
 329       $self->_format_keyword(uc($dq->{outer}).' JOIN');
 330     } elsif ($dq->{on}) {
 331       $self->_format_keyword('JOIN');
 332     } else {
 333       ','
 334     }
 335   };
 336   [
 337     $self->_render($left), $join, $self->_render($right),
 338     ($dq->{on}
 339       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 340       : ())
 341   ];
 342 }
 343
 344 sub _render_where {
 345   my ($self, $dq) = @_;
 346   my ($from, $where) = @{$dq}{qw(from where)};
 347   my $keyword = ($from && $from->{type} eq DQ_GROUP) ? 'HAVING' : 'WHERE';
 348   [
 349     ($from ? $self->_render($from) : ()),
 350     $self->_format_keyword($keyword),
 351     $self->_render($where)
 352   ]
 353 }
 354
 355 sub _render_order {
 356   my ($self, $dq) = @_;
 357   my @ret = (
 358     $self->_format_keyword('ORDER BY'),
 359     $self->_render($dq->{by}),
 360     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 361   );
 362   my $from;
 363   while ($from = $dq->{from}) {
 364     last unless $from->{type} eq DQ_ORDER;
 365     $dq = $from;
 366     push @ret, (
 367       ',',
 368       $self->_render($dq->{by}),
 369       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 370     );
 371   }
 372   unshift @ret, $self->_render($from) if $from;
 373   \@ret;
 374 }
 375
 376 sub _render_group {
 377   my ($self, $dq) = @_;
 378   # this could also squash like order does. but I dunno whether that should
 379   # move somewhere else just yet.
 380   my @ret = (
 381     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 382     $self->_format_keyword('GROUP BY'),
 383     intersperse(',', map $self->_render($_), @{$dq->{by}})
 384   );
 385   \@ret;
 386 }
 387
 388 sub _render_delete {
 389   my ($self, $dq) = @_;
 390   my ($target, $where) = @{$dq}{qw(target where)};
 391   [ $self->_format_keyword('DELETE FROM'),
 392     $self->_render($target),
 393     ($where
 394       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 395       : ())
 396   ];
 397 }
 398
 399 sub _render_update {
 400   my ($self, $dq) = @_;
 401   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 402   unless ($set) {
 403     die "Must have set key - names+value keys not yet tested";
 404     my ($names, $value) = @{$dq}{qw(names value)};
 405     die "Must have names and value or set" unless $names and $value;
 406     die "names and value must be same size" unless @$names == @$value;
 407     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 408   }
 409   my @rendered_set = intersperse(
 410     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 411   );
 412   [ $self->_format_keyword('UPDATE'),
 413     $self->_render($target),
 414     $self->_format_keyword('SET'),
 415     @rendered_set,
 416     ($where
 417       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 418       : ())
 419   ];
 420 }
 421
 422 sub _render_insert {
 423   my ($self, $dq) = @_;
 424   my ($target, $names, $values, $returning)
 425     = @{$dq}{qw(target names values returning)};
 426   unless ($values) {
 427     die "Must have values key - sets key not yet implemented";
 428   }
 429   [ $self->_format_keyword('INSERT INTO'),
 430     $self->_render($target),
 431     ($names
 432       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 433       : ()),
 434     $self->_format_keyword('VALUES'),
 435     intersperse(',',
 436       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 437         @$values
 438     ),
 439     ($returning
 440       ? ($self->_format_keyword('RETURNING'),
 441          intersperse(',', map $self->_render($_), @$returning))
 442       : ()),
 443   ];
 444 }
 445
 446 1;