lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4 use SQL::ReservedWords;
   5 use Data::Query::Constants qw(
   6   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
   7 );
   8
   9 sub new {
  10   bless({ %{$_[1]||{}} }, (ref($_[0])||$_[0]))->BUILDALL;
  11 }
  12
  13 sub BUILDALL {
  14   my $self = shift;
  15   $self->{reserved_ident_parts}
  16     ||= (
  17       our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  18     );
  19   $self->{quote_chars}||=[''];
  20   $self->{simple_ops}||=$self->_default_simple_ops;
  21   return $self;
  22 }
  23
  24 sub _default_simple_ops {
  25   +{
  26     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  27     (map +($_ => 'unop'), qw(NOT) ),
  28     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  29     (map +($_ => 'flatten'), qw(AND OR) ),
  30     (map +($_ => 'in'), ('IN', 'NOT IN')),
  31     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  32     (apply => 'apply'),
  33   }
  34 }
  35
  36 sub render {
  37   my $self = shift;
  38   $self->_flatten_structure($self->_render(@_))
  39 }
  40
  41 sub _flatten_structure {
  42   my ($self, $struct) = @_;
  43   my @bind;
  44   [ do {
  45       my @p = map {
  46         my $r = ref;
  47         if (!$r) { $_ }
  48         elsif ($r eq 'ARRAY') {
  49           my ($sql, @b) = @{$self->_flatten_structure($_)};
  50           push @bind, @b;
  51           $sql;
  52         }
  53         elsif ($r eq 'HASH') { push @bind, $_; () }
  54         else { die "_flatten_structure can't handle ref type $r for $_" }
  55       } @$struct;
  56       join '', map {
  57         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  58       } 0 .. $#p;
  59     },
  60     @bind
  61   ];
  62 }
  63
  64 # I present this to permit strange people to easily supply a patch to lc()
  65 # their keywords, as I have heard many desire to do, lest they infect me
  66 # with whatever malady caused this desire by their continued proximity for
  67 # want of such a feature.
  68
  69 sub _format_keyword { $_[1] }
  70
  71 sub _render {
  72   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  73 }
  74
  75 sub _render_broken {
  76   my ($self, $dq) = @_;
  77   require Data::Dumper::Concise;
  78   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  79 }
  80
  81 sub _render_identifier {
  82   die "Unidentified identifier (SQL can no has \$_)"
  83     unless my @i = @{$_[1]->{elements}};
  84   # handle single or paired quote chars
  85   my ($q1, $q2) = @{$_[0]->{quote_chars}}[0,-1];
  86   my $always_quote = $_[0]->{always_quote};
  87   my $res_check = $_[0]->{reserved_ident_parts};
  88   return [
  89     join
  90       $_[0]->{identifier_sep}||'.',
  91       map +(
  92         $_ eq '*' # Yes, this means you can't have a column just called '*'.
  93           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
  94           : ( # reserved are stored uc, quote if non-word
  95               $always_quote || $res_check->{+uc} || /\W/
  96                 ? $q1.$_.$q2
  97                 : $_
  98             )
  99       ), @i
 100   ];
 101 }
 102
 103 sub _render_value {
 104   defined($_[1]->{value})
 105     ? [ '?', $_[1] ]
 106     : [ 'NULL' ];
 107 }
 108
 109 sub _operator_type { 'SQL.Naive' }
 110
 111 sub _render_operator {
 112   my ($self, $dq) = @_;
 113   my $op = $dq->{operator};
 114   unless (exists $op->{$self->_operator_type}) {
 115     $op->{$self->_operator_type} = $self->_convert_op($dq);
 116   }
 117   my $op_name = $op->{$self->_operator_type};
 118   if (my $op_type = $self->{simple_ops}{$op_name}) {
 119     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 120   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 121     return $self->$meth($dq);
 122   }
 123   if (my $argc = @{$dq->{args}}) {
 124     if ($argc == 1) {
 125       return $self->_handle_op_type_unop($op_name, $dq);
 126     } elsif ($argc == 2) {
 127       return $self->_handle_op_type_binop($op_name, $dq);
 128     }
 129   }
 130   die "Unsure how to handle ${op_name}";
 131 }
 132
 133 sub _handle_op_type_binop {
 134   my ($self, $op_name, $dq) = @_;
 135   die "${op_name} registered as binary op but args contain "
 136       .scalar(@{$dq->{args}})." entries"
 137     unless @{$dq->{args}} == 2;
 138   [
 139     $self->_render($dq->{args}[0]),
 140     $op_name,
 141     $self->_render($dq->{args}[1]),
 142   ]
 143 }
 144
 145 sub _handle_op_type_unop {
 146   my ($self, $op_name, $dq) = @_;
 147   die "${op_name} registered as unary op but args contain "
 148       .scalar(@{$dq->{args}})." entries"
 149     unless @{$dq->{args}} == 1;
 150   [
 151     '(',
 152     $op_name,
 153     $self->_render($dq->{args}[0]),
 154     ')',
 155   ]
 156 }
 157
 158 sub _handle_op_type_unop_reverse {
 159   my ($self, $op_name, $dq) = @_;
 160   die "${op_name} registered as unary op but args contain "
 161       .scalar(@{$dq->{args}})." entries"
 162     unless @{$dq->{args}} == 1;
 163   [
 164     $self->_render($dq->{args}[0]),
 165     $op_name,
 166   ]
 167 }
 168
 169 sub _handle_op_type_flatten {
 170   my ($self, $op_name, $dq) = @_;
 171   my @argq = @{$dq->{args}};
 172   my @arg_final;
 173   while (my $arg = shift @argq) {
 174
 175     unless ($arg->{type} eq DQ_OPERATOR) {
 176       push @arg_final, $arg;
 177       next;
 178     }
 179
 180     my $op = $arg->{operator};
 181     unless (exists $op->{$self->_operator_type}) {
 182       $op->{$self->_operator_type} = $self->_convert_op($arg);
 183     }
 184
 185     if ($op->{$self->_operator_type} eq $op_name) {
 186       unshift @argq, @{$arg->{args}};
 187     } else {
 188       push @arg_final, $arg;
 189     }
 190   }
 191   my @sql = ('(', map +($self->_render($_), $op_name), @arg_final);
 192   $sql[-1] = ')'; # replace final AND or whatever with )
 193   \@sql;
 194 }
 195
 196 sub _handle_op_type_in {
 197   my ($self, $op, $dq) = @_;
 198   my ($lhs, @in) = @{$dq->{args}};
 199   my @rhs = ('(', map +($self->_render($_), ','), @in);
 200   $rhs[-1] = ')';
 201   [ $self->_render($lhs), $op, @rhs ];
 202 }
 203
 204 sub _handle_op_type_between {
 205   my ($self, $op_name, $dq) = @_;
 206   my @args = @{$dq->{args}};
 207   if (@args == 3) {
 208     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 209     [ $lhs, $op_name, $rhs1, 'AND', $rhs2 ];
 210   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 211     my ($lhs, $rhs) = (map $self->_render($_), @args);
 212     [ $lhs, $op_name, $rhs ];
 213   } else {
 214     die "Invalid args for between: ${\scalar @args} given";
 215   }
 216 }
 217
 218 sub _handle_op_type_apply {
 219   my ($self, $op_name, $dq) = @_;
 220   my ($func, @args) = @{$dq->{args}};
 221   die "Function name must be identifier"
 222     unless $func->{type} eq DQ_IDENTIFIER;
 223   my $ident = do {
 224     # The problem we have here is that built-ins can't be quoted, generally.
 225     # I rather wonder if things like MAX(...) need to -not- be handled as
 226     # an apply and instead of something else, maybe a parenop type - but
 227     # as an explicitly Naive renderer this seems like a reasonable answer.
 228     local @{$self}{qw(reserved_ident_parts always_quote)};
 229     $self->_render_identifier($func)->[0];
 230   };
 231   [
 232     "$ident(",
 233     (map $self->_render($_), @args),
 234     ')'
 235   ]
 236 }
 237
 238 sub _convert_op {
 239   my ($self, $dq) = @_;
 240   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 241     for ($perl_op) {
 242       $_ eq '==' and return '=';
 243       $_ eq 'eq' and return '=';
 244       $_ eq '!' and return 'NOT';
 245     }
 246     return uc $perl_op; # hope!
 247   }
 248   die "Can't convert non-perl op yet";
 249 }
 250
 251 sub _render_select {
 252   my ($self, $dq) = @_;
 253   die "Empty select list" unless @{$dq->{select}};
 254
 255   # it is, in fact, completely valid for there to be nothing for us
 256   # to project from since many databases handle 'SELECT 1;' fine
 257
 258   my @select = map [
 259     ($_->{type} eq DQ_ALIAS
 260       ? $self->_render_alias($_, $self->_format_keyword('AS'))
 261       : $self->_render($_)
 262     ),
 263    ','
 264   ], @{$dq->{select}};
 265
 266   # we put the commas inside the [] for each entry as a hint to the pretty
 267   # printer downstream so now we need to eliminate the comma from the last
 268   # entry - we know there always is one due to the die guard at the top
 269
 270   pop @{$select[-1]};
 271
 272   return [
 273     $self->_format_keyword('SELECT'),
 274     \@select,
 275     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 276     # since we're the SELECT and therefore always come first, we don't care.
 277     ($dq->{from}
 278        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 279        : ()
 280     )
 281   ];
 282 }
 283
 284 sub _render_alias {
 285   my ($self, $dq, $as) = @_;
 286   # FROM foo foo -> FROM foo
 287   # FROM foo.bar bar -> FROM foo.bar
 288   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 289     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 290       return $self->_render($dq->{alias});
 291     }
 292   }
 293   return [
 294     $self->_render($dq->{alias}),
 295     $as || ' ',
 296     $self->_render_identifier({ elements => [ $dq->{as} ] })
 297   ];
 298 }
 299
 300 sub _render_literal {
 301   my ($self, $dq) = @_;
 302   unless ($dq->{subtype} eq 'SQL') {
 303     die "Can't render non-SQL literal";
 304   }
 305   return [
 306     $dq->{literal}, @{$dq->{values}||[]}
 307   ];
 308 }
 309
 310 sub _render_join {
 311   my ($self, $dq) = @_;
 312   my ($left, $right) = @{$dq->{join}};
 313   die "No support for ON yet" if $dq->{on};
 314   die "No support for LEFT/RIGHT yet" if $dq->{outer};
 315   [ $self->_render($left), ',', $self->_render($right) ];
 316 }
 317
 318 sub _render_where {
 319   my ($self, $dq) = @_;
 320   my ($from, $where) = @{$dq}{qw(from where)};
 321   [
 322     ($from ? $self->_render($from) : ()),
 323     $self->_format_keyword('WHERE'),
 324     $self->_render($where)
 325   ]
 326 }
 327
 328 sub _render_order {
 329   my ($self, $dq) = @_;
 330   my @ret = (
 331     $self->_format_keyword('ORDER BY'),
 332     $self->_render($dq->{by}),
 333     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 334   );
 335   my $from;
 336   while ($from = $dq->{from}) {
 337     last unless $from->{type} eq DQ_ORDER;
 338     $dq = $from;
 339     push @ret, (
 340       ',',
 341       $self->_render($dq->{by}),
 342       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 343     );
 344   }
 345   unshift @ret, $self->_render($from) if $from;
 346   \@ret;
 347 }
 348
 349 1;