lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10 );
  11
  12 sub new {
  13   bless({ %{$_[1]||{}} }, (ref($_[0])||$_[0]))->BUILDALL;
  14 }
  15
  16 sub BUILDALL {
  17   my $self = shift;
  18   $self->{reserved_ident_parts}
  19     ||= (
  20       our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  21     );
  22   $self->{quote_chars}||=[''];
  23   $self->{simple_ops}||=$self->_default_simple_ops;
  24   return $self;
  25 }
  26
  27 sub _default_simple_ops {
  28   +{
  29     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  30     (map +($_ => 'unop'), qw(NOT) ),
  31     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  32     (map +($_ => 'flatten'), qw(AND OR) ),
  33     (map +($_ => 'in'), ('IN', 'NOT IN')),
  34     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  35     (apply => 'apply'),
  36   }
  37 }
  38
  39 sub render {
  40   my $self = shift;
  41   $self->_flatten_structure($self->_render(@_))
  42 }
  43
  44 sub _flatten_structure {
  45   my ($self, $struct) = @_;
  46   my @bind;
  47   [ do {
  48       my @p = map {
  49         my $r = ref;
  50         if (!$r) { $_ }
  51         elsif ($r eq 'ARRAY') {
  52           my ($sql, @b) = @{$self->_flatten_structure($_)};
  53           push @bind, @b;
  54           $sql;
  55         }
  56         elsif ($r eq 'HASH') { push @bind, $_; () }
  57         else { die "_flatten_structure can't handle ref type $r for $_" }
  58       } @$struct;
  59       join '', map {
  60         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  61       } 0 .. $#p;
  62     },
  63     @bind
  64   ];
  65 }
  66
  67 # I presented this to permit strange people to easily supply a patch to lc()
  68 # their keywords, as I have heard many desire to do, lest they infect me
  69 # with whatever malady caused this desire by their continued proximity for
  70 # want of such a feature.
  71 #
  72 # Then I realised that SQL::Abstract compatibility work required it.
  73 #
  74 # FEH.
  75
  76 sub _format_keyword { $_[0]->{lc_keywords} ? lc($_[1]) : $_[1] }
  77
  78 sub _render {
  79   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  80 }
  81
  82 sub _render_broken {
  83   my ($self, $dq) = @_;
  84   require Data::Dumper::Concise;
  85   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  86 }
  87
  88 sub _render_identifier {
  89   die "Unidentified identifier (SQL can no has \$_)"
  90     unless my @i = @{$_[1]->{elements}};
  91   # handle single or paired quote chars
  92   my ($q1, $q2) = @{$_[0]->{quote_chars}}[0,-1];
  93   my $always_quote = $_[0]->{always_quote};
  94   my $res_check = $_[0]->{reserved_ident_parts};
  95   return [
  96     join
  97       $_[0]->{identifier_sep}||'.',
  98       map +(
  99         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 100           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 101           : ( # reserved are stored uc, quote if non-word
 102               $always_quote || $res_check->{+uc} || /\W/
 103                 ? $q1.$_.$q2
 104                 : $_
 105             )
 106       ), @i
 107   ];
 108 }
 109
 110 sub _render_value {
 111   [ '?', $_[1] ]
 112 }
 113
 114 sub _operator_type { 'SQL.Naive' }
 115
 116 sub _render_operator {
 117   my ($self, $dq) = @_;
 118   my $op = $dq->{operator};
 119   unless (exists $op->{$self->_operator_type}) {
 120     $op->{$self->_operator_type} = $self->_convert_op($dq);
 121   }
 122   my $op_name = $op->{$self->_operator_type};
 123   if (my $op_type = $self->{simple_ops}{$op_name}) {
 124     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 125   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 126     return $self->$meth($dq);
 127   }
 128   if (my $argc = @{$dq->{args}}) {
 129     if ($argc == 1) {
 130       return $self->_handle_op_type_unop($op_name, $dq);
 131     } elsif ($argc == 2) {
 132       return $self->_handle_op_type_binop($op_name, $dq);
 133     }
 134   }
 135   die "Unsure how to handle ${op_name}";
 136 }
 137
 138 sub _handle_op_type_binop {
 139   my ($self, $op_name, $dq) = @_;
 140   die "${op_name} registered as binary op but args contain "
 141       .scalar(@{$dq->{args}})." entries"
 142     unless @{$dq->{args}} == 2;
 143   [
 144     $self->_render($dq->{args}[0]),
 145     $op_name,
 146     $self->_render($dq->{args}[1]),
 147   ]
 148 }
 149
 150 sub _handle_op_type_unop {
 151   my ($self, $op_name, $dq) = @_;
 152   die "${op_name} registered as unary op but args contain "
 153       .scalar(@{$dq->{args}})." entries"
 154     unless @{$dq->{args}} == 1;
 155   [
 156     '(',
 157     $op_name,
 158     $self->_render($dq->{args}[0]),
 159     ')',
 160   ]
 161 }
 162
 163 sub _handle_op_type_unop_reverse {
 164   my ($self, $op_name, $dq) = @_;
 165   die "${op_name} registered as unary op but args contain "
 166       .scalar(@{$dq->{args}})." entries"
 167     unless @{$dq->{args}} == 1;
 168   [
 169     $self->_render($dq->{args}[0]),
 170     $op_name,
 171   ]
 172 }
 173
 174 sub _handle_op_type_flatten {
 175   my ($self, $op_name, $dq) = @_;
 176   my @argq = @{$dq->{args}};
 177   my @arg_final;
 178   while (my $arg = shift @argq) {
 179
 180     unless ($arg->{type} eq DQ_OPERATOR) {
 181       push @arg_final, $arg;
 182       next;
 183     }
 184
 185     my $op = $arg->{operator};
 186     unless (exists $op->{$self->_operator_type}) {
 187       $op->{$self->_operator_type} = $self->_convert_op($arg);
 188     }
 189
 190     if ($op->{$self->_operator_type} eq $op_name) {
 191       unshift @argq, @{$arg->{args}};
 192     } else {
 193       push @arg_final, $arg;
 194     }
 195   }
 196   my @sql = ('(', map +($self->_render($_), $op_name), @arg_final);
 197   $sql[-1] = ')'; # replace final AND or whatever with )
 198   \@sql;
 199 }
 200
 201 sub _handle_op_type_in {
 202   my ($self, $op, $dq) = @_;
 203   my ($lhs, @in) = @{$dq->{args}};
 204   my @rhs = ('(', map +($self->_render($_), ','), @in);
 205   $rhs[-1] = ')';
 206   [ $self->_render($lhs), $op, @rhs ];
 207 }
 208
 209 sub _handle_op_type_between {
 210   my ($self, $op_name, $dq) = @_;
 211   my @args = @{$dq->{args}};
 212   if (@args == 3) {
 213     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 214     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 215   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 216     my ($lhs, $rhs) = (map $self->_render($_), @args);
 217     [ '(', $lhs, $op_name, $rhs, ')' ];
 218   } else {
 219     die "Invalid args for between: ${\scalar @args} given";
 220   }
 221 }
 222
 223 sub _handle_op_type_apply {
 224   my ($self, $op_name, $dq) = @_;
 225   my ($func, @args) = @{$dq->{args}};
 226   die "Function name must be identifier"
 227     unless $func->{type} eq DQ_IDENTIFIER;
 228   my $ident = do {
 229     # The problem we have here is that built-ins can't be quoted, generally.
 230     # I rather wonder if things like MAX(...) need to -not- be handled as
 231     # an apply and instead of something else, maybe a parenop type - but
 232     # as an explicitly Naive renderer this seems like a reasonable answer.
 233     local @{$self}{qw(reserved_ident_parts always_quote)};
 234     $self->_render_identifier($func)->[0];
 235   };
 236   [
 237     "$ident(",
 238     (map $self->_render($_), @args),
 239     ')'
 240   ]
 241 }
 242
 243 sub _convert_op {
 244   my ($self, $dq) = @_;
 245   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 246     for ($perl_op) {
 247       $_ eq '==' and return '=';
 248       $_ eq 'eq' and return '=';
 249       $_ eq '!' and return 'NOT';
 250     }
 251     return uc $perl_op; # hope!
 252   }
 253   die "Can't convert non-perl op yet";
 254 }
 255
 256 sub _render_select {
 257   my ($self, $dq) = @_;
 258   die "Empty select list" unless @{$dq->{select}};
 259
 260   # it is, in fact, completely valid for there to be nothing for us
 261   # to project from since many databases handle 'SELECT 1;' fine
 262
 263   my @select = map [
 264     ($_->{type} eq DQ_ALIAS
 265       ? $self->_render_alias($_, $self->_format_keyword('AS'))
 266       : $self->_render($_)
 267     ),
 268    ','
 269   ], @{$dq->{select}};
 270
 271   # we put the commas inside the [] for each entry as a hint to the pretty
 272   # printer downstream so now we need to eliminate the comma from the last
 273   # entry - we know there always is one due to the die guard at the top
 274
 275   pop @{$select[-1]};
 276
 277   return [
 278     $self->_format_keyword('SELECT'),
 279     \@select,
 280     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 281     # since we're the SELECT and therefore always come first, we don't care.
 282     ($dq->{from}
 283        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 284        : ()
 285     )
 286   ];
 287 }
 288
 289 sub _render_alias {
 290   my ($self, $dq, $as) = @_;
 291   # FROM foo foo -> FROM foo
 292   # FROM foo.bar bar -> FROM foo.bar
 293   if ($dq->{alias}{type} eq DQ_IDENTIFIER) {
 294     if ($dq->{alias}{elements}[-1] eq $dq->{as}) {
 295       return $self->_render($dq->{alias});
 296     }
 297   }
 298   return [
 299     $self->_render($dq->{alias}),
 300     $as || ' ',
 301     $self->_render_identifier({ elements => [ $dq->{as} ] })
 302   ];
 303 }
 304
 305 sub _render_literal {
 306   my ($self, $dq) = @_;
 307   unless ($dq->{subtype} eq 'SQL') {
 308     die "Can't render non-SQL literal";
 309   }
 310   if ($dq->{literal}) {
 311     return [
 312       $dq->{literal}, @{$dq->{values}||[]}
 313     ];
 314   } elsif ($dq->{parts}) {
 315     return [ map $self->_render($_), @{$dq->{parts}} ];
 316   } else {
 317     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 318   }
 319 }
 320
 321 sub _render_join {
 322   my ($self, $dq) = @_;
 323   my ($left, $right) = @{$dq->{join}};
 324   die "No support for ON yet" if $dq->{on};
 325   die "No support for LEFT/RIGHT yet" if $dq->{outer};
 326   [ $self->_render($left), ',', $self->_render($right) ];
 327 }
 328
 329 sub _render_where {
 330   my ($self, $dq) = @_;
 331   my ($from, $where) = @{$dq}{qw(from where)};
 332   [
 333     ($from ? $self->_render($from) : ()),
 334     $self->_format_keyword('WHERE'),
 335     $self->_render($where)
 336   ]
 337 }
 338
 339 sub _render_order {
 340   my ($self, $dq) = @_;
 341   my @ret = (
 342     $self->_format_keyword('ORDER BY'),
 343     $self->_render($dq->{by}),
 344     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 345   );
 346   my $from;
 347   while ($from = $dq->{from}) {
 348     last unless $from->{type} eq DQ_ORDER;
 349     $dq = $from;
 350     push @ret, (
 351       ',',
 352       $self->_render($dq->{by}),
 353       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 354     );
 355   }
 356   unshift @ret, $self->_render($from) if $from;
 357   \@ret;
 358 }
 359
 360 sub _render_delete {
 361   my ($self, $dq) = @_;
 362   my ($target, $where) = @{$dq}{qw(target where)};
 363   [ $self->_format_keyword('DELETE FROM'),
 364     $self->_render($target),
 365     ($where
 366       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 367       : ())
 368   ];
 369 }
 370
 371 sub _render_update {
 372   my ($self, $dq) = @_;
 373   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 374   unless ($set) {
 375     die "Must have set key - names+value keys not yet tested";
 376     my ($names, $value) = @{$dq}{qw(names value)};
 377     die "Must have names and value or set" unless $names and $value;
 378     die "names and value must be same size" unless @$names == @$value;
 379     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 380   }
 381   my @rendered_set = intersperse(
 382     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 383   );
 384   [ $self->_format_keyword('UPDATE'),
 385     $self->_render($target),
 386     $self->_format_keyword('SET'),
 387     @rendered_set,
 388     ($where
 389       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 390       : ())
 391   ];
 392 }
 393
 394 sub _render_insert {
 395   my ($self, $dq) = @_;
 396   my ($target, $names, $values, $returning)
 397     = @{$dq}{qw(target names values returning)};
 398   unless ($values) {
 399     die "Must have values key - sets key not yet implemented";
 400   }
 401   [ $self->_format_keyword('INSERT INTO'),
 402     $self->_render($target),
 403     ($names
 404       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 405       : ()),
 406     $self->_format_keyword('VALUES'),
 407     intersperse(',',
 408       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 409         @$values
 410     ),
 411     ($returning
 412       ? ($self->_format_keyword('RETURNING'),
 413          intersperse(',', map $self->_render($_), @$returning))
 414       : ()),
 415   ];
 416 }
 417
 418 1;