lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 use SQL::ReservedWords;
   6 use Data::Query::ExprHelpers;
   7
   8 use Moo;
   9 use namespace::clean;
  10
  11 has reserved_ident_parts => (
  12   is => 'ro', default => sub {
  13     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  14   }
  15 );
  16
  17 has quote_chars => (is => 'ro', default => sub { [''] });
  18
  19 has identifier_sep => (is => 'ro', default => sub { '.' });
  20
  21 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  22
  23 has lc_keywords => (is => 'ro', default => sub { 0 });
  24
  25 has always_quote => (is => 'ro', default => sub { 0 });
  26
  27 has collapse_aliases => (is => 'ro', default => sub { 1 });
  28
  29 sub _default_simple_ops {
  30   +{
  31     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  32     (map +($_ => 'unop'), qw(NOT) ),
  33     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  34     (map +($_ => 'flatten'), qw(AND OR) ),
  35     (map +($_ => 'in'), ('IN', 'NOT IN')),
  36     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  37     (apply => 'apply'),
  38   }
  39 }
  40
  41 sub render {
  42   my $self = shift;
  43   $self->_flatten_structure($self->_render(@_))
  44 }
  45
  46 sub _flatten_structure {
  47   my ($self, $struct) = @_;
  48   my @bind;
  49   [ do {
  50       my @p = map {
  51         my $r = ref;
  52         if (!$r) { $_ }
  53         elsif ($r eq 'ARRAY') {
  54           my ($sql, @b) = @{$self->_flatten_structure($_)};
  55           push @bind, @b;
  56           $sql;
  57         }
  58         elsif ($r eq 'HASH') { push @bind, $_; () }
  59         else { die "_flatten_structure can't handle ref type $r for $_" }
  60       } @$struct;
  61       join '', map {
  62         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  63       } 0 .. $#p;
  64     },
  65     @bind
  66   ];
  67 }
  68
  69 # I presented this to permit strange people to easily supply a patch to lc()
  70 # their keywords, as I have heard many desire to do, lest they infect me
  71 # with whatever malady caused this desire by their continued proximity for
  72 # want of such a feature.
  73 #
  74 # Then I realised that SQL::Abstract compatibility work required it.
  75 #
  76 # FEH.
  77
  78 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  79
  80 sub _render {
  81   unless (ref($_[1]) eq 'HASH') {
  82     die "Expected hashref, got ".(defined($_[1])?$_[1]:'undef');
  83   }
  84   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  85 }
  86
  87 sub _render_broken {
  88   my ($self, $dq) = @_;
  89   require Data::Dumper::Concise;
  90   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  91 }
  92
  93 sub _render_identifier {
  94   die "Unidentified identifier (SQL can no has \$_)"
  95     unless my @i = @{$_[1]->{elements}};
  96   # handle single or paired quote chars
  97   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  98   my $always_quote = $_[0]->always_quote;
  99   my $res_check = $_[0]->reserved_ident_parts;
 100   return [
 101     join
 102       $_[0]->identifier_sep,
 103       map +(
 104         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 105           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 106           : ( # reserved are stored uc, quote if non-word
 107               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 108                 ? $q1.$_.$q2
 109                 : $_
 110             )
 111       ), @i
 112   ];
 113 }
 114
 115 sub _render_value {
 116   [ '?', $_[1] ]
 117 }
 118
 119 sub _operator_type { 'SQL.Naive' }
 120
 121 sub _render_operator {
 122   my ($self, $dq) = @_;
 123   my $op = $dq->{operator};
 124   unless (exists $op->{$self->_operator_type}) {
 125     $op->{$self->_operator_type} = $self->_convert_op($dq);
 126   }
 127   my $op_name = $op->{$self->_operator_type};
 128   if (my $op_type = $self->simple_ops->{$op_name}) {
 129     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 130   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 131     return $self->$meth($dq);
 132   }
 133   if (my $argc = @{$dq->{args}}) {
 134     if ($argc == 1) {
 135       return $self->_handle_op_type_unop($op_name, $dq);
 136     } elsif ($argc == 2) {
 137       return $self->_handle_op_type_binop($op_name, $dq);
 138     }
 139   }
 140   die "Unsure how to handle ${op_name}";
 141 }
 142
 143 sub _maybe_parenthesise {
 144   my ($self, $dq) = @_;
 145   for ($dq) {
 146     return is_Select() || is_Group() || is_Slice() || is_Having()
 147       ? [ '(', $self->_render($dq), ')' ]
 148       : $self->_render($dq);
 149   }
 150 }
 151
 152 sub _handle_op_type_binop {
 153   my ($self, $op_name, $dq) = @_;
 154   die "${op_name} registered as binary op but args contain "
 155       .scalar(@{$dq->{args}})." entries"
 156     unless @{$dq->{args}} == 2;
 157   [
 158     $self->_maybe_parenthesise($dq->{args}[0]),
 159     $op_name,
 160     $self->_maybe_parenthesise($dq->{args}[1]),
 161   ]
 162 }
 163
 164 sub _handle_op_type_unop {
 165   my ($self, $op_name, $dq) = @_;
 166   die "${op_name} registered as unary op but args contain "
 167       .scalar(@{$dq->{args}})." entries"
 168     unless @{$dq->{args}} == 1;
 169   [
 170     '(',
 171     $op_name,
 172     $self->_render($dq->{args}[0]),
 173     ')',
 174   ]
 175 }
 176
 177 sub _handle_op_type_unop_reverse {
 178   my ($self, $op_name, $dq) = @_;
 179   die "${op_name} registered as unary op but args contain "
 180       .scalar(@{$dq->{args}})." entries"
 181     unless @{$dq->{args}} == 1;
 182   [
 183     $self->_render($dq->{args}[0]),
 184     $op_name,
 185   ]
 186 }
 187
 188 sub _handle_op_type_flatten {
 189   my ($self, $op_name, $dq) = @_;
 190   my @argq = @{$dq->{args}};
 191   my @arg_final;
 192   while (my $arg = shift @argq) {
 193
 194     unless (is_Operator($arg)) {
 195       push @arg_final, $arg;
 196       next;
 197     }
 198
 199     my $op = $arg->{operator};
 200     unless (exists $op->{$self->_operator_type}) {
 201       $op->{$self->_operator_type} = $self->_convert_op($arg);
 202     }
 203
 204     if ($op->{$self->_operator_type} eq $op_name) {
 205       unshift @argq, @{$arg->{args}};
 206     } else {
 207       push @arg_final, $arg;
 208     }
 209   }
 210   [ '(',
 211       intersperse(
 212         $self->_format_keyword($op_name),
 213         map $self->_maybe_parenthesise($_), @arg_final
 214       ),
 215     ')'
 216   ];
 217 }
 218
 219 sub _handle_op_type_in {
 220   my ($self, $op, $dq) = @_;
 221   my ($lhs, @in) = @{$dq->{args}};
 222   [ $self->_render($lhs),
 223     $op,
 224     '(',
 225       intersperse(',', map $self->_render($_), @in),
 226     ')'
 227   ];
 228 }
 229
 230 sub _handle_op_type_between {
 231   my ($self, $op_name, $dq) = @_;
 232   my @args = @{$dq->{args}};
 233   if (@args == 3) {
 234     my ($lhs, $rhs1, $rhs2) = (map $self->_maybe_parenthesise($_), @args);
 235     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 236   } elsif (@args == 2 and is_Literal $args[1]) {
 237     my ($lhs, $rhs) = (map $self->_render($_), @args);
 238     [ '(', $lhs, $op_name, $rhs, ')' ];
 239   } else {
 240     die "Invalid args for between: ${\scalar @args} given";
 241   }
 242 }
 243
 244 sub _handle_op_type_apply {
 245   my ($self, $op_name, $dq) = @_;
 246   my ($func, @args) = @{$dq->{args}};
 247   die "Function name must be identifier"
 248     unless is_Identifier $func;
 249   my $ident = do {
 250     # The problem we have here is that built-ins can't be quoted, generally.
 251     # I rather wonder if things like MAX(...) need to -not- be handled as
 252     # an apply and instead of something else, maybe a parenop type - but
 253     # as an explicitly Naive renderer this seems like a reasonable answer.
 254     local @{$self}{qw(reserved_ident_parts always_quote)};
 255     $self->_render_identifier($func)->[0];
 256   };
 257   [
 258     "$ident(",
 259       intersperse(',', map $self->_maybe_parenthesise($_), @args),
 260     ')'
 261   ]
 262 }
 263
 264 sub _convert_op {
 265   my ($self, $dq) = @_;
 266   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 267     for ($perl_op) {
 268       $_ eq '==' and return '=';
 269       $_ eq 'eq' and return '=';
 270       $_ eq '!' and return 'NOT';
 271       $_ eq 'defined' and return 'IS NOT NULL';
 272     }
 273     return uc $perl_op; # hope!
 274   }
 275   die "Can't convert non-perl op yet";
 276 }
 277
 278 sub _render_select {
 279   my ($self, $dq) = @_;
 280   die "Empty select list" unless @{$dq->{select}};
 281
 282   # it is, in fact, completely valid for there to be nothing for us
 283   # to project from since many databases handle 'SELECT 1;' fine
 284
 285   my @select = intersperse(',',
 286     map +(is_Alias()
 287            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 288            : $self->_render($_)), @{$dq->{select}}
 289   );
 290
 291   return [
 292     $self->_format_keyword('SELECT'),
 293     \@select,
 294     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 295     # since we're the SELECT and therefore always come first, we don't care.
 296     ($dq->{from}
 297        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 298        : ()
 299     ),
 300   ];
 301 }
 302
 303 sub _render_alias {
 304   my ($self, $dq, $as) = @_;
 305   # FROM foo foo -> FROM foo
 306   # FROM foo.bar bar -> FROM foo.bar
 307   if ($self->collapse_aliases) {
 308     if (is_Identifier(my $from = $dq->{from})) {
 309       if ($from->{elements}[-1] eq $dq->{to}) {
 310         return $self->_render($from);
 311       }
 312     }
 313   }
 314   return [
 315     $self->_maybe_parenthesise($dq->{from}),
 316     $as || '',
 317     $self->_render_identifier({ elements => [ $dq->{to} ] })
 318   ];
 319 }
 320
 321 sub _render_literal {
 322   my ($self, $dq) = @_;
 323   unless ($dq->{subtype} eq 'SQL') {
 324     die "Can't render non-SQL literal";
 325   }
 326   if (defined($dq->{literal})) {
 327     return [
 328       $dq->{literal}, @{$dq->{values}||[]}
 329     ];
 330   } elsif ($dq->{parts}) {
 331     return [ map $self->_render($_), @{$dq->{parts}} ];
 332   } else {
 333     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 334   }
 335 }
 336
 337 sub _render_join {
 338   my ($self, $dq) = @_;
 339   my ($left, $right) = @{$dq}{qw(left right)};
 340   my $rhs = $self->_render($right);
 341   [
 342     $self->_render($left), $self->_format_join_keyword($dq),
 343     (is_Join($right) ? ('(', $rhs, ')') : $rhs),
 344     ($dq->{on}
 345       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 346       : ())
 347   ];
 348 }
 349
 350 sub _format_join_keyword {
 351   my ($self, $dq) = @_;
 352   if ($dq->{outer}) {
 353     $self->_format_keyword(uc($dq->{outer}).' JOIN');
 354   } elsif ($dq->{on}) {
 355     $self->_format_keyword('JOIN');
 356   } else {
 357     ','
 358   }
 359 }
 360
 361 sub _render_where {
 362   my ($self, $dq) = @_;
 363   my ($from, $where) = @{$dq}{qw(from where)};
 364   while (is_Where $from) {
 365     $where = Operator({ 'SQL.Naive' => 'AND' }, [ $from->{where}, $where ]);
 366     $from = $from->{from};
 367   }
 368   my $keyword = (is_Group($from) ? 'HAVING' : 'WHERE');
 369   [
 370     ($from ? $self->_render($from) : ()),
 371     $self->_format_keyword($keyword),
 372     $self->_render($where)
 373   ]
 374 }
 375
 376 sub _order_chunk {
 377   my ($self, $dq) = @_;
 378   return +(
 379     $self->_render($dq->{by}),
 380     ($dq->{reverse}
 381       ? $self->_format_keyword('DESC')
 382       : ()),
 383     ($dq->{nulls} && $dq->{nulls} =~ /^(first|last)$/i
 384       ? $self->_format_keyword('NULLS '.$dq->{nulls})
 385       : ()),
 386   );
 387 }
 388
 389 sub _render_order {
 390   my ($self, $dq) = @_;
 391   my @ret = (
 392     $self->_format_keyword('ORDER BY'),
 393     $self->_order_chunk($dq),
 394   );
 395   my $from;
 396   while ($from = $dq->{from}) {
 397     last unless is_Order $from;
 398     $dq = $from;
 399     push @ret, (
 400       ',',
 401       $self->_order_chunk($dq),
 402     );
 403   }
 404   unshift @ret, $self->_render($from) if $from;
 405   \@ret;
 406 }
 407
 408 sub _render_group {
 409   my ($self, $dq) = @_;
 410   # this could also squash like order does. but I dunno whether that should
 411   # move somewhere else just yet.
 412   my @ret = (
 413     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 414     (@{$dq->{by}}
 415       ? (
 416           $self->_format_keyword('GROUP BY'),
 417           intersperse(',', map $self->_render($_), @{$dq->{by}})
 418          )
 419       : ())
 420   );
 421   \@ret;
 422 }
 423
 424 sub _render_delete {
 425   my ($self, $dq) = @_;
 426   my ($target, $where) = @{$dq}{qw(target where)};
 427   [ $self->_format_keyword('DELETE FROM'),
 428     $self->_render($target),
 429     ($where
 430       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 431       : ())
 432   ];
 433 }
 434
 435 sub _render_update {
 436   my ($self, $dq) = @_;
 437   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 438   unless ($set) {
 439     die "Must have set key - names+value keys not yet tested";
 440     my ($names, $value) = @{$dq}{qw(names value)};
 441     die "Must have names and value or set" unless $names and $value;
 442     die "names and value must be same size" unless @$names == @$value;
 443     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 444   }
 445   my @rendered_set = intersperse(
 446     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 447   );
 448   [ $self->_format_keyword('UPDATE'),
 449     $self->_render($target),
 450     $self->_format_keyword('SET'),
 451     @rendered_set,
 452     ($where
 453       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 454       : ())
 455   ];
 456 }
 457
 458 sub _render_insert {
 459   my ($self, $dq) = @_;
 460   my ($target, $names, $values, $returning)
 461     = @{$dq}{qw(target names values returning)};
 462   unless ($values) {
 463     die "Must have values key - sets key not yet implemented";
 464   }
 465   [ $self->_format_keyword('INSERT INTO'),
 466     $self->_render($target),
 467     ($names
 468       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 469       : ()),
 470     (@$values && @{$values->[0]}
 471       ? ($self->_format_keyword('VALUES'),
 472          intersperse(',',
 473            map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 474              @$values
 475          ))
 476       : ($self->_insert_default_values)),
 477     ($returning
 478       ? ($self->_format_keyword('RETURNING'),
 479          intersperse(',', map $self->_render($_), @$returning))
 480       : ()),
 481   ];
 482 }
 483
 484 sub _insert_default_values {
 485   my ($self) = @_;
 486   $self->_format_keyword('DEFAULT VALUES'),
 487 }
 488
 489 1;