lib/Data/Query/Renderer/SQL/Naive.pm

   1 package Data::Query::Renderer::SQL::Naive;
   2
   3 use strictures 1;
   4
   5 sub intersperse { my $i = shift; my @i = map +($_, $i), @_; pop @i; @i }
   6
   7 use SQL::ReservedWords;
   8 use Data::Query::Constants qw(
   9   DQ_IDENTIFIER DQ_OPERATOR DQ_VALUE DQ_JOIN DQ_ALIAS DQ_ORDER DQ_LITERAL
  10   DQ_GROUP
  11 );
  12
  13 use Moo;
  14
  15 has reserved_ident_parts => (
  16   is => 'ro', default => sub {
  17     our $_DEFAULT_RESERVED ||= { map +($_ => 1), SQL::ReservedWords->words }
  18   }
  19 );
  20
  21 has quote_chars => (is => 'ro', default => sub { [''] });
  22
  23 has identifier_sep => (is => 'ro', default => sub { '.' });
  24
  25 has simple_ops => (is => 'ro', builder => '_default_simple_ops');
  26
  27 has lc_keywords => (is => 'ro', default => sub { 0 });
  28
  29 has always_quote => (is => 'ro', default => sub { 0 });
  30
  31 has collapse_aliases => (is => 'ro', default => sub { 1 });
  32
  33 sub _default_simple_ops {
  34   +{
  35     (map +($_ => 'binop'), qw(= > < >= <= != LIKE), 'NOT LIKE' ),
  36     (map +($_ => 'unop'), qw(NOT) ),
  37     (map +($_ => 'unop_reverse'), ('IS NULL', 'IS NOT NULL')),
  38     (map +($_ => 'flatten'), qw(AND OR) ),
  39     (map +($_ => 'in'), ('IN', 'NOT IN')),
  40     (map +($_ => 'between'), ('BETWEEN', 'NOT BETWEEN')),
  41     (apply => 'apply'),
  42   }
  43 }
  44
  45 sub render {
  46   my $self = shift;
  47   $self->_flatten_structure($self->_render(@_))
  48 }
  49
  50 sub _flatten_structure {
  51   my ($self, $struct) = @_;
  52   my @bind;
  53   [ do {
  54       my @p = map {
  55         my $r = ref;
  56         if (!$r) { $_ }
  57         elsif ($r eq 'ARRAY') {
  58           my ($sql, @b) = @{$self->_flatten_structure($_)};
  59           push @bind, @b;
  60           $sql;
  61         }
  62         elsif ($r eq 'HASH') { push @bind, $_; () }
  63         else { die "_flatten_structure can't handle ref type $r for $_" }
  64       } @$struct;
  65       join '', map {
  66         ($p[$_], (($p[$_+1]||',') eq ',') ? () : (' '))
  67       } 0 .. $#p;
  68     },
  69     @bind
  70   ];
  71 }
  72
  73 # I presented this to permit strange people to easily supply a patch to lc()
  74 # their keywords, as I have heard many desire to do, lest they infect me
  75 # with whatever malady caused this desire by their continued proximity for
  76 # want of such a feature.
  77 #
  78 # Then I realised that SQL::Abstract compatibility work required it.
  79 #
  80 # FEH.
  81
  82 sub _format_keyword { $_[0]->lc_keywords ? lc($_[1]) : $_[1] }
  83
  84 sub _render {
  85   $_[0]->${\"_render_${\(lc($_[1]->{type})||'broken')}"}($_[1]);
  86 }
  87
  88 sub _render_broken {
  89   my ($self, $dq) = @_;
  90   require Data::Dumper::Concise;
  91   die "Broken DQ entry: ".Data::Dumper::Concise::Dumper($dq);
  92 }
  93
  94 sub _render_identifier {
  95   die "Unidentified identifier (SQL can no has \$_)"
  96     unless my @i = @{$_[1]->{elements}};
  97   # handle single or paired quote chars
  98   my ($q1, $q2) = @{$_[0]->quote_chars}[0,-1];
  99   my $always_quote = $_[0]->always_quote;
 100   my $res_check = $_[0]->reserved_ident_parts;
 101   return [
 102     join
 103       $_[0]->identifier_sep,
 104       map +(
 105         $_ eq '*' # Yes, this means you can't have a column just called '*'.
 106           ? $_    # Yes, this is a feature. Go shoot the DBA if he disagrees.
 107           : ( # reserved are stored uc, quote if non-word
 108               ($always_quote and $q1) || $res_check->{+uc} || /\W/
 109                 ? $q1.$_.$q2
 110                 : $_
 111             )
 112       ), @i
 113   ];
 114 }
 115
 116 sub _render_value {
 117   [ '?', $_[1] ]
 118 }
 119
 120 sub _operator_type { 'SQL.Naive' }
 121
 122 sub _render_operator {
 123   my ($self, $dq) = @_;
 124   my $op = $dq->{operator};
 125   unless (exists $op->{$self->_operator_type}) {
 126     $op->{$self->_operator_type} = $self->_convert_op($dq);
 127   }
 128   my $op_name = $op->{$self->_operator_type};
 129   if (my $op_type = $self->simple_ops->{$op_name}) {
 130     return $self->${\"_handle_op_type_${op_type}"}($op_name, $dq);
 131   } elsif (my $meth = $self->can("_handle_op_special_${op_name}")) {
 132     return $self->$meth($dq);
 133   }
 134   if (my $argc = @{$dq->{args}}) {
 135     if ($argc == 1) {
 136       return $self->_handle_op_type_unop($op_name, $dq);
 137     } elsif ($argc == 2) {
 138       return $self->_handle_op_type_binop($op_name, $dq);
 139     }
 140   }
 141   die "Unsure how to handle ${op_name}";
 142 }
 143
 144 sub _handle_op_type_binop {
 145   my ($self, $op_name, $dq) = @_;
 146   die "${op_name} registered as binary op but args contain "
 147       .scalar(@{$dq->{args}})." entries"
 148     unless @{$dq->{args}} == 2;
 149   [
 150     $self->_render($dq->{args}[0]),
 151     $op_name,
 152     $self->_render($dq->{args}[1]),
 153   ]
 154 }
 155
 156 sub _handle_op_type_unop {
 157   my ($self, $op_name, $dq) = @_;
 158   die "${op_name} registered as unary op but args contain "
 159       .scalar(@{$dq->{args}})." entries"
 160     unless @{$dq->{args}} == 1;
 161   [
 162     '(',
 163     $op_name,
 164     $self->_render($dq->{args}[0]),
 165     ')',
 166   ]
 167 }
 168
 169 sub _handle_op_type_unop_reverse {
 170   my ($self, $op_name, $dq) = @_;
 171   die "${op_name} registered as unary op but args contain "
 172       .scalar(@{$dq->{args}})." entries"
 173     unless @{$dq->{args}} == 1;
 174   [
 175     $self->_render($dq->{args}[0]),
 176     $op_name,
 177   ]
 178 }
 179
 180 sub _handle_op_type_flatten {
 181   my ($self, $op_name, $dq) = @_;
 182   my @argq = @{$dq->{args}};
 183   my @arg_final;
 184   while (my $arg = shift @argq) {
 185
 186     unless ($arg->{type} eq DQ_OPERATOR) {
 187       push @arg_final, $arg;
 188       next;
 189     }
 190
 191     my $op = $arg->{operator};
 192     unless (exists $op->{$self->_operator_type}) {
 193       $op->{$self->_operator_type} = $self->_convert_op($arg);
 194     }
 195
 196     if ($op->{$self->_operator_type} eq $op_name) {
 197       unshift @argq, @{$arg->{args}};
 198     } else {
 199       push @arg_final, $arg;
 200     }
 201   }
 202   [ '(',
 203       intersperse(
 204         $self->_format_keyword($op_name),
 205         map $self->_render($_), @arg_final
 206       ),
 207     ')'
 208   ];
 209 }
 210
 211 sub _handle_op_type_in {
 212   my ($self, $op, $dq) = @_;
 213   my ($lhs, @in) = @{$dq->{args}};
 214   [ $self->_render($lhs),
 215     $op,
 216     '(',
 217       intersperse(',', map $self->_render($_), @in),
 218     ')'
 219   ];
 220 }
 221
 222 sub _handle_op_type_between {
 223   my ($self, $op_name, $dq) = @_;
 224   my @args = @{$dq->{args}};
 225   if (@args == 3) {
 226     my ($lhs, $rhs1, $rhs2) = (map $self->_render($_), @args);
 227     [ '(', $lhs, $op_name, $rhs1, 'AND', $rhs2, ')' ];
 228   } elsif (@args == 2 and $args[1]->{type} eq DQ_LITERAL) {
 229     my ($lhs, $rhs) = (map $self->_render($_), @args);
 230     [ '(', $lhs, $op_name, $rhs, ')' ];
 231   } else {
 232     die "Invalid args for between: ${\scalar @args} given";
 233   }
 234 }
 235
 236 sub _handle_op_type_apply {
 237   my ($self, $op_name, $dq) = @_;
 238   my ($func, @args) = @{$dq->{args}};
 239   die "Function name must be identifier"
 240     unless $func->{type} eq DQ_IDENTIFIER;
 241   my $ident = do {
 242     # The problem we have here is that built-ins can't be quoted, generally.
 243     # I rather wonder if things like MAX(...) need to -not- be handled as
 244     # an apply and instead of something else, maybe a parenop type - but
 245     # as an explicitly Naive renderer this seems like a reasonable answer.
 246     local @{$self}{qw(reserved_ident_parts always_quote)};
 247     $self->_render_identifier($func)->[0];
 248   };
 249   [
 250     "$ident(",
 251       intersperse(',', map $self->_render($_), @args),
 252     ')'
 253   ]
 254 }
 255
 256 sub _convert_op {
 257   my ($self, $dq) = @_;
 258   if (my $perl_op = $dq->{'operator'}->{'Perl'}) {
 259     for ($perl_op) {
 260       $_ eq '==' and return '=';
 261       $_ eq 'eq' and return '=';
 262       $_ eq '!' and return 'NOT';
 263     }
 264     return uc $perl_op; # hope!
 265   }
 266   die "Can't convert non-perl op yet";
 267 }
 268
 269 sub _render_select {
 270   my ($self, $dq) = @_;
 271   die "Empty select list" unless @{$dq->{select}};
 272
 273   # it is, in fact, completely valid for there to be nothing for us
 274   # to project from since many databases handle 'SELECT 1;' fine
 275
 276   my @select = intersperse(',',
 277     map +($_->{type} eq DQ_ALIAS
 278            ? $self->_render_alias($_, $self->_format_keyword('AS'))
 279            : $self->_render($_)), @{$dq->{select}}
 280   );
 281
 282   return [
 283     $self->_format_keyword('SELECT'),
 284     \@select,
 285     # if present this may be a bare FROM, a FROM+WHERE, or a FROM+WHERE+GROUP
 286     # since we're the SELECT and therefore always come first, we don't care.
 287     ($dq->{from}
 288        ? ($self->_format_keyword('FROM'), @{$self->_render($dq->{from})})
 289        : ()
 290     )
 291   ];
 292 }
 293
 294 sub _render_alias {
 295   my ($self, $dq, $as) = @_;
 296   # FROM foo foo -> FROM foo
 297   # FROM foo.bar bar -> FROM foo.bar
 298   if ($self->collapse_aliases) {
 299     if ($dq->{from}{type} eq DQ_IDENTIFIER) {
 300       if ($dq->{from}{elements}[-1] eq $dq->{to}) {
 301         return $self->_render($dq->{from});
 302       }
 303     }
 304   }
 305   return [
 306     $self->_render($dq->{from}),
 307     $as || ' ',
 308     $self->_render_identifier({ elements => [ $dq->{to} ] })
 309   ];
 310 }
 311
 312 sub _render_literal {
 313   my ($self, $dq) = @_;
 314   unless ($dq->{subtype} eq 'SQL') {
 315     die "Can't render non-SQL literal";
 316   }
 317   if ($dq->{literal}) {
 318     return [
 319       $dq->{literal}, @{$dq->{values}||[]}
 320     ];
 321   } elsif ($dq->{parts}) {
 322     return [ map $self->_render($_), @{$dq->{parts}} ];
 323   } else {
 324     die "Invalid SQL literal - neither 'literal' nor 'parts' found";
 325   }
 326 }
 327
 328 sub _render_join {
 329   my ($self, $dq) = @_;
 330   my ($left, $right) = @{$dq}{qw(left right)};
 331   my $join = do {
 332     if ($dq->{outer}) {
 333       $self->_format_keyword(uc($dq->{outer}).' JOIN');
 334     } elsif ($dq->{on}) {
 335       $self->_format_keyword('JOIN');
 336     } else {
 337       ','
 338     }
 339   };
 340   [
 341     $self->_render($left), $join, $self->_render($right),
 342     ($dq->{on}
 343       ? ($self->_format_keyword('ON'), $self->_render($dq->{on}))
 344       : ())
 345   ];
 346 }
 347
 348 sub _render_where {
 349   my ($self, $dq) = @_;
 350   my ($from, $where) = @{$dq}{qw(from where)};
 351   my $keyword = ($from && $from->{type} eq DQ_GROUP) ? 'HAVING' : 'WHERE';
 352   [
 353     ($from ? $self->_render($from) : ()),
 354     $self->_format_keyword($keyword),
 355     $self->_render($where)
 356   ]
 357 }
 358
 359 sub _render_order {
 360   my ($self, $dq) = @_;
 361   my @ret = (
 362     $self->_format_keyword('ORDER BY'),
 363     $self->_render($dq->{by}),
 364     ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 365   );
 366   my $from;
 367   while ($from = $dq->{from}) {
 368     last unless $from->{type} eq DQ_ORDER;
 369     $dq = $from;
 370     push @ret, (
 371       ',',
 372       $self->_render($dq->{by}),
 373       ($dq->{direction} ? $self->_format_keyword($dq->{direction}) : ())
 374     );
 375   }
 376   unshift @ret, $self->_render($from) if $from;
 377   \@ret;
 378 }
 379
 380 sub _render_group {
 381   my ($self, $dq) = @_;
 382   # this could also squash like order does. but I dunno whether that should
 383   # move somewhere else just yet.
 384   my @ret = (
 385     ($dq->{from} ? $self->_render($dq->{from}) : ()),
 386     $self->_format_keyword('GROUP BY'),
 387     intersperse(',', map $self->_render($_), @{$dq->{by}})
 388   );
 389   \@ret;
 390 }
 391
 392 sub _render_delete {
 393   my ($self, $dq) = @_;
 394   my ($target, $where) = @{$dq}{qw(target where)};
 395   [ $self->_format_keyword('DELETE FROM'),
 396     $self->_render($target),
 397     ($where
 398       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 399       : ())
 400   ];
 401 }
 402
 403 sub _render_update {
 404   my ($self, $dq) = @_;
 405   my ($target, $set, $where) = @{$dq}{qw(target set where)};
 406   unless ($set) {
 407     die "Must have set key - names+value keys not yet tested";
 408     my ($names, $value) = @{$dq}{qw(names value)};
 409     die "Must have names and value or set" unless $names and $value;
 410     die "names and value must be same size" unless @$names == @$value;
 411     $set = [ map [ $names->[$_], $value->[$_] ], 0..$#$names ];
 412   }
 413   my @rendered_set = intersperse(
 414     ',', map [ intersperse('=', map $self->_render($_), @$_) ], @{$set}
 415   );
 416   [ $self->_format_keyword('UPDATE'),
 417     $self->_render($target),
 418     $self->_format_keyword('SET'),
 419     @rendered_set,
 420     ($where
 421       ? ($self->_format_keyword('WHERE'), $self->_render($where))
 422       : ())
 423   ];
 424 }
 425
 426 sub _render_insert {
 427   my ($self, $dq) = @_;
 428   my ($target, $names, $values, $returning)
 429     = @{$dq}{qw(target names values returning)};
 430   unless ($values) {
 431     die "Must have values key - sets key not yet implemented";
 432   }
 433   [ $self->_format_keyword('INSERT INTO'),
 434     $self->_render($target),
 435     ($names
 436       ? ('(', intersperse(',', map $self->_render($_), @$names), ')')
 437       : ()),
 438     $self->_format_keyword('VALUES'),
 439     intersperse(',',
 440       map [ '(', intersperse(',', map $self->_render($_), @$_), ')' ],
 441         @$values
 442     ),
 443     ($returning
 444       ? ($self->_format_keyword('RETURNING'),
 445          intersperse(',', map $self->_render($_), @$returning))
 446       : ()),
 447   ];
 448 }
 449
 450 1;