lib/DX/SearchState.pm

   1 package DX::SearchState;
   2
   3 use Types::Standard qw(Maybe);
   4 use DX::Step::InvokeNextPredicate;
   5 use DX::Class;
   6
   7 has current_hypothesis => (is => 'ro', isa => Hypothesis, required => 1);
   8
   9 has next_step => (is => 'ro', isa => Maybe[Step]);
  10
  11 has propositions => (is => 'ro', isa => PropositionSequence, required => 1);
  12
  13 has alternatives => (is => 'ro', isa => AlternativeList, required => 1);
  14
  15 sub next_proposition {
  16   my ($self, $hyp) = @_;
  17   $hyp ||= $self->current_hypothesis;
  18   $self->propositions->members->[
  19     $hyp->resolved_propositions->resolved_count
  20   ];
  21 }
  22
  23 sub new_for {
  24   my ($class, $hyp, $props) = @_;
  25   $class->new(
  26     current_hypothesis => $hyp,
  27     alternatives => [],
  28     next_step => DX::Step::InvokeNextPredicate->new(
  29       proposition => $props->members->[0],
  30     ),
  31     propositions => $props,
  32   );
  33 }
  34
  35 sub with_one_step {
  36   my ($self) = @_;
  37   my $hyp = $self->current_hypothesis;
  38   return undef unless my $step = $self->next_step;
  39   my ($new_ss, $alt_step) = $step->apply_to($self);
  40   if ($new_ss) {
  41     return $new_ss->but(
  42       alternatives => [
  43         ($alt_step
  44           ? [ $hyp, $alt_step ]
  45           : ()),
  46         @{$new_ss->alternatives}
  47       ],
  48       next_step => DX::Step::InvokeNextPredicate->new(
  49         proposition => $new_ss->next_proposition,
  50       ),
  51     );
  52   }
  53   if ($alt_step) {
  54     return $self->but(next_step => $alt_step);
  55   }
  56   my ($first_alt, @rest_alt) = @{$self->alternatives};
  57   return undef unless $first_alt;
  58   trace 'search.backtrack.rewind_to' => $first_alt->[1];
  59   return $self->but(
  60     current_hypothesis => $first_alt->[0],
  61     alternatives => \@rest_alt,
  62     next_step => $first_alt->[1],
  63   );
  64 }
  65
  66 sub force_backtrack {
  67   my ($self) = @_;
  68   my ($first_alt, @rest_alt) = @{$self->alternatives};
  69   return undef unless $first_alt;
  70   trace 'search.backtrack.forced' => $first_alt->[0];
  71   return ref($self)->new(
  72     current_hypothesis => $first_alt->[0],
  73     next_step => $first_alt->[1],
  74     alternatives => \@rest_alt,
  75     propositions => $self->propositions,
  76   );
  77 }
  78
  79 1;