lib/DX/Op/CallRule.pm

   1 package DX::Op::CallRule;
   2
   3 use DX::Op::SetScope;
   4 use DX::Op::FromCode;
   5 use DX::Var;
   6 use DX::ArrayStream;
   7 use Moo;
   8
   9 with 'DX::Role::Op';
  10
  11 has rule_name => (is => 'ro', required => 1);
  12 has rule_args => (is => 'ro', required => 1);
  13 has full_name => (is => 'lazy', builder => sub {
  14   my ($self) = @_;
  15   join('/', $self->rule_name, scalar @{$self->rule_args});
  16 });
  17
  18 sub run {
  19   my ($self, $state) = @_;
  20   my @args = map $self->_expand_argspec($state, $_), @{$self->rule_args};
  21   my @rules = @{$state->rule_set->rules->{$self->full_name}||[]};
  22   die "No rules for ${\$self->full_name}" unless @rules;
  23   my $var = DX::Var->new(id => "rule:".$self->full_name)
  24                    ->with_stream(DX::ArrayStream->from_array(@rules));
  25   my $invoke = DX::Op::FromCode->new(
  26     code => sub {
  27       my ($self, $state) = @_;
  28       my ($names, $body) = @{$var->bound_value};
  29       my %new; @new{@$names} = @args;
  30       $state->but(scope => {})->assign_vars(%new)->then($body);
  31     }
  32   );
  33   my $ret_op = DX::Op::SetScope->new(
  34     scope => $state->scope, next => $self->next
  35   );
  36   $state->push_return_then($ret_op, $invoke)->mark_choice($var);
  37 }
  38
  39 1;