lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use DBM::Deep::Engine;
  39
  40 use vars qw( $VERSION );
  41 $VERSION = q(0.99_01);
  42
  43 ##
  44 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  45 #       (Perl must be compiled with largefile support for files > 2 GB)
  46 #
  47 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  48 #       (Perl must be compiled with largefile and 64-bit long support)
  49 ##
  50 #my $LONG_SIZE = 4;
  51 #my $LONG_PACK = 'N';
  52
  53 ##
  54 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  55 # Upgrading this is possible (see above) but probably not necessary.  If you need
  56 # more than 4 GB for a single key or value, this module is really not for you :-)
  57 ##
  58 #my $DATA_LENGTH_SIZE = 4;
  59 #my $DATA_LENGTH_PACK = 'N';
  60 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  61
  62 ##
  63 # Maximum number of buckets per list before another level of indexing is done.
  64 # Increase this value for slightly greater speed, but larger database files.
  65 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  66 ##
  67 my $MAX_BUCKETS = 16;
  68
  69 ##
  70 # Better not adjust anything below here, unless you're me :-)
  71 ##
  72
  73 ##
  74 # Setup digest function for keys
  75 ##
  76 our ($DIGEST_FUNC, $HASH_SIZE);
  77 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  78
  79 ##
  80 # Precalculate index and bucket sizes based on values above.
  81 ##
  82 #my $HASH_SIZE = 16;
  83 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  84
  85 set_digest();
  86 #set_pack();
  87 #_precalc_sizes();
  88
  89 ##
  90 # Setup file and tag signatures.  These should never change.
  91 ##
  92 sub SIG_FILE   () { 'DPDB' }
  93 sub SIG_HASH   () { 'H' }
  94 sub SIG_ARRAY  () { 'A' }
  95 sub SIG_SCALAR () { 'S' }
  96 sub SIG_NULL   () { 'N' }
  97 sub SIG_DATA   () { 'D' }
  98 sub SIG_INDEX  () { 'I' }
  99 sub SIG_BLIST  () { 'B' }
 100 sub SIG_SIZE   () {  1  }
 101
 102 ##
 103 # Setup constants for users to pass to new()
 104 ##
 105 sub TYPE_HASH   () { SIG_HASH   }
 106 sub TYPE_ARRAY  () { SIG_ARRAY  }
 107 sub TYPE_SCALAR () { SIG_SCALAR }
 108
 109 sub _get_args {
 110     my $proto = shift;
 111
 112     my $args;
 113     if (scalar(@_) > 1) {
 114         if ( @_ % 2 ) {
 115             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 116         }
 117         $args = {@_};
 118     }
 119         elsif ( ref $_[0] ) {
 120         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 121             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 122         }
 123         $args = $_[0];
 124     }
 125         else {
 126         $args = { file => shift };
 127     }
 128
 129     return $args;
 130 }
 131
 132 sub new {
 133         ##
 134         # Class constructor method for Perl OO interface.
 135         # Calls tie() and returns blessed reference to tied hash or array,
 136         # providing a hybrid OO/tie interface.
 137         ##
 138         my $class = shift;
 139         my $args = $class->_get_args( @_ );
 140
 141         ##
 142         # Check if we want a tied hash or array.
 143         ##
 144         my $self;
 145         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 146         $class = 'DBM::Deep::Array';
 147         require DBM::Deep::Array;
 148                 tie @$self, $class, %$args;
 149         }
 150         else {
 151         $class = 'DBM::Deep::Hash';
 152         require DBM::Deep::Hash;
 153                 tie %$self, $class, %$args;
 154         }
 155
 156         return bless $self, $class;
 157 }
 158
 159 sub _init {
 160     ##
 161     # Setup $self and bless into this class.
 162     ##
 163     my $class = shift;
 164     my $args = shift;
 165
 166     # These are the defaults to be optionally overridden below
 167     my $self = bless {
 168         type        => TYPE_HASH,
 169         base_offset => length(SIG_FILE),
 170         engine      => 'DBM::Deep::Engine',
 171     }, $class;
 172
 173     foreach my $param ( keys %$self ) {
 174         next unless exists $args->{$param};
 175         $self->{$param} = delete $args->{$param}
 176     }
 177
 178     # locking implicitly enables autoflush
 179     if ($args->{locking}) { $args->{autoflush} = 1; }
 180
 181     $self->{root} = exists $args->{root}
 182         ? $args->{root}
 183         : DBM::Deep::_::Root->new( $args );
 184
 185     if (!defined($self->_fh)) { $self->_open(); }
 186
 187     return $self;
 188 }
 189
 190 sub TIEHASH {
 191     shift;
 192     require DBM::Deep::Hash;
 193     return DBM::Deep::Hash->TIEHASH( @_ );
 194 }
 195
 196 sub TIEARRAY {
 197     shift;
 198     require DBM::Deep::Array;
 199     return DBM::Deep::Array->TIEARRAY( @_ );
 200 }
 201
 202 #XXX Unneeded now ...
 203 #sub DESTROY {
 204 #}
 205
 206 sub _open {
 207         ##
 208         # Open a fh to the database, create if nonexistent.
 209         # Make sure file signature matches DBM::Deep spec.
 210         ##
 211     my $self = $_[0]->_get_self;
 212
 213         if (defined($self->_fh)) { $self->_close(); }
 214
 215     eval {
 216         local $SIG{'__DIE__'};
 217         # Theoretically, adding O_BINARY should remove the need for the binmode
 218         # Of course, testing it is going to be ... interesting.
 219         my $flags = O_RDWR | O_CREAT | O_BINARY;
 220
 221         my $fh;
 222         sysopen( $fh, $self->_root->{file}, $flags )
 223             or $fh = undef;
 224         $self->_root->{fh} = $fh;
 225     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 226         if (! defined($self->_fh)) {
 227                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 228         }
 229
 230     my $fh = $self->_fh;
 231
 232     #XXX Can we remove this by using the right sysopen() flags?
 233     # Maybe ... q.v. above
 234     binmode $fh; # for win32
 235
 236     if ($self->_root->{autoflush}) {
 237         my $old = select $fh;
 238         $|=1;
 239         select $old;
 240     }
 241
 242     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 243
 244     my $signature;
 245     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 246
 247     ##
 248     # File is empty -- write signature and master index
 249     ##
 250     if (!$bytes_read) {
 251         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 252         print( $fh SIG_FILE);
 253         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 254
 255         my $plain_key = "[base]";
 256         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 257
 258         # Flush the filehandle
 259         my $old_fh = select $fh;
 260         my $old_af = $|; $| = 1; $| = $old_af;
 261         select $old_fh;
 262
 263         my @stats = stat($fh);
 264         $self->_root->{inode} = $stats[1];
 265         $self->_root->{end} = $stats[7];
 266
 267         return 1;
 268     }
 269
 270     ##
 271     # Check signature was valid
 272     ##
 273     unless ($signature eq SIG_FILE) {
 274         $self->_close();
 275         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 276     }
 277
 278         my @stats = stat($fh);
 279         $self->_root->{inode} = $stats[1];
 280     $self->_root->{end} = $stats[7];
 281
 282     ##
 283     # Get our type from master index signature
 284     ##
 285     my $tag = $self->_load_tag($self->_base_offset);
 286
 287 #XXX We probably also want to store the hash algorithm name and not assume anything
 288 #XXX The cool thing would be to allow a different hashing algorithm at every level
 289
 290     if (!$tag) {
 291         return $self->_throw_error("Corrupted file, no master index record");
 292     }
 293     if ($self->{type} ne $tag->{signature}) {
 294         return $self->_throw_error("File type mismatch");
 295     }
 296
 297     return 1;
 298 }
 299
 300 sub _close {
 301         ##
 302         # Close database fh
 303         ##
 304     my $self = $_[0]->_get_self;
 305     close $self->_root->{fh} if $self->_root->{fh};
 306     $self->_root->{fh} = undef;
 307 }
 308
 309 sub _create_tag {
 310         ##
 311         # Given offset, signature and content, create tag and write to disk
 312         ##
 313         my ($self, $offset, $sig, $content) = @_;
 314         my $size = length($content);
 315
 316     my $fh = $self->_fh;
 317
 318         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 319         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 320
 321         if ($offset == $self->_root->{end}) {
 322                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 323         }
 324
 325         return {
 326                 signature => $sig,
 327                 size => $size,
 328                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 329                 content => $content
 330         };
 331 }
 332
 333 sub _load_tag {
 334         ##
 335         # Given offset, load single tag and return signature, size and data
 336         ##
 337         my $self = shift;
 338         my $offset = shift;
 339
 340     my $fh = $self->_fh;
 341
 342         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 343         if (eof $fh) { return undef; }
 344
 345     my $b;
 346     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 347     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 348
 349         my $buffer;
 350         read( $fh, $buffer, $size);
 351
 352         return {
 353                 signature => $sig,
 354                 size => $size,
 355                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 356                 content => $buffer
 357         };
 358 }
 359
 360 sub _index_lookup {
 361         ##
 362         # Given index tag, lookup single entry in index and return .
 363         ##
 364         my $self = shift;
 365         my ($tag, $index) = @_;
 366
 367         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 368         if (!$location) { return; }
 369
 370         return $self->_load_tag( $location );
 371 }
 372
 373 sub _add_bucket {
 374         ##
 375         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 376         # plain (undigested) key and value.
 377         ##
 378         my $self = shift;
 379         my ($tag, $md5, $plain_key, $value) = @_;
 380         my $keys = $tag->{content};
 381         my $location = 0;
 382         my $result = 2;
 383
 384     my $root = $self->_root;
 385
 386     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 387         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 388
 389     my $fh = $self->_fh;
 390
 391         ##
 392         # Iterate through buckets, seeing if this is a new entry or a replace.
 393         ##
 394         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 395                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 396                 if (!$subloc) {
 397                         ##
 398                         # Found empty bucket (end of list).  Populate and exit loop.
 399                         ##
 400                         $result = 2;
 401
 402             $location = $internal_ref
 403                 ? $value->_base_offset
 404                 : $root->{end};
 405
 406                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 407                         print( $fh $md5 . pack($LONG_PACK, $location) );
 408                         last;
 409                 }
 410
 411                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 412                 if ($md5 eq $key) {
 413                         ##
 414                         # Found existing bucket with same key.  Replace with new value.
 415                         ##
 416                         $result = 1;
 417
 418                         if ($internal_ref) {
 419                                 $location = $value->_base_offset;
 420                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 421                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 422                 return $result;
 423                         }
 424
 425             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 426             my $size;
 427             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 428
 429             ##
 430             # If value is a hash, array, or raw value with equal or less size, we can
 431             # reuse the same content area of the database.  Otherwise, we have to create
 432             # a new content area at the EOF.
 433             ##
 434             my $actual_length;
 435             my $r = Scalar::Util::reftype( $value ) || '';
 436             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 437                 $actual_length = $INDEX_SIZE;
 438
 439                 # if autobless is enabled, must also take into consideration
 440                 # the class name, as it is stored along with key/value.
 441                 if ( $root->{autobless} ) {
 442                     my $value_class = Scalar::Util::blessed($value);
 443                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 444                         $actual_length += length($value_class);
 445                     }
 446                 }
 447             }
 448             else { $actual_length = length($value); }
 449
 450             if ($actual_length <= $size) {
 451                 $location = $subloc;
 452             }
 453             else {
 454                 $location = $root->{end};
 455                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 456                 print( $fh pack($LONG_PACK, $location) );
 457             }
 458
 459                         last;
 460                 }
 461         }
 462
 463         ##
 464         # If this is an internal reference, return now.
 465         # No need to write value or plain key
 466         ##
 467         if ($internal_ref) {
 468         return $result;
 469     }
 470
 471         ##
 472         # If bucket didn't fit into list, split into a new index level
 473         ##
 474         if (!$location) {
 475                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 476                 print( $fh pack($LONG_PACK, $root->{end}) );
 477
 478                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 479                 my @offsets = ();
 480
 481                 $keys .= $md5 . pack($LONG_PACK, 0);
 482
 483                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 484                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 485                         if ($key) {
 486                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 487                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 488
 489                                 if ($offsets[$num]) {
 490                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 491                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 492                                         my $subkeys;
 493                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 494
 495                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 496                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 497                                                 if (!$subloc) {
 498                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 499                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 500                                                         last;
 501                                                 }
 502                                         } # k loop
 503                                 }
 504                                 else {
 505                                         $offsets[$num] = $root->{end};
 506                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 507                                         print( $fh pack($LONG_PACK, $root->{end}) );
 508
 509                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 510
 511                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 512                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 513                                 }
 514                         } # key is real
 515                 } # i loop
 516
 517                 $location ||= $root->{end};
 518         } # re-index bucket list
 519
 520         ##
 521         # Seek to content area and store signature, value and plaintext key
 522         ##
 523         if ($location) {
 524                 my $content_length;
 525                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 526
 527                 ##
 528                 # Write signature based on content type, set content length and write actual value.
 529                 ##
 530         my $r = Scalar::Util::reftype($value) || '';
 531                 if ($r eq 'HASH') {
 532                         print( $fh TYPE_HASH );
 533                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 534                         $content_length = $INDEX_SIZE;
 535                 }
 536                 elsif ($r eq 'ARRAY') {
 537                         print( $fh TYPE_ARRAY );
 538                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 539                         $content_length = $INDEX_SIZE;
 540                 }
 541                 elsif (!defined($value)) {
 542                         print( $fh SIG_NULL );
 543                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 544                         $content_length = 0;
 545                 }
 546                 else {
 547                         print( $fh SIG_DATA );
 548                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 549                         $content_length = length($value);
 550                 }
 551
 552                 ##
 553                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 554                 ##
 555                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 556
 557                 ##
 558                 # If value is blessed, preserve class name
 559                 ##
 560                 if ( $root->{autobless} ) {
 561             my $value_class = Scalar::Util::blessed($value);
 562             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 563                 ##
 564                 # Blessed ref -- will restore later
 565                 ##
 566                 print( $fh chr(1) );
 567                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 568                 $content_length += 1;
 569                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 570             }
 571             else {
 572                 print( $fh chr(0) );
 573                 $content_length += 1;
 574             }
 575         }
 576
 577                 ##
 578                 # If this is a new content area, advance EOF counter
 579                 ##
 580                 if ($location == $root->{end}) {
 581                         $root->{end} += SIG_SIZE;
 582                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 583                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 584                 }
 585
 586                 ##
 587                 # If content is a hash or array, create new child DBM::Deep object and
 588                 # pass each key or element to it.
 589                 ##
 590                 if ($r eq 'HASH') {
 591                         my $branch = DBM::Deep->new(
 592                                 type => TYPE_HASH,
 593                                 base_offset => $location,
 594                                 root => $root,
 595                         );
 596                         foreach my $key (keys %{$value}) {
 597                 $branch->STORE( $key, $value->{$key} );
 598                         }
 599                 }
 600                 elsif ($r eq 'ARRAY') {
 601                         my $branch = DBM::Deep->new(
 602                                 type => TYPE_ARRAY,
 603                                 base_offset => $location,
 604                                 root => $root,
 605                         );
 606                         my $index = 0;
 607                         foreach my $element (@{$value}) {
 608                 $branch->STORE( $index, $element );
 609                                 $index++;
 610                         }
 611                 }
 612
 613                 return $result;
 614         }
 615
 616         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 617 }
 618
 619 sub _get_bucket_value {
 620         ##
 621         # Fetch single value given tag and MD5 digested key.
 622         ##
 623         my $self = shift;
 624         my ($tag, $md5) = @_;
 625         my $keys = $tag->{content};
 626
 627     my $fh = $self->_fh;
 628
 629         ##
 630         # Iterate through buckets, looking for a key match
 631         ##
 632     BUCKET:
 633         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 634                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 635                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 636
 637                 if (!$subloc) {
 638                         ##
 639                         # Hit end of list, no match
 640                         ##
 641                         return;
 642                 }
 643
 644         if ( $md5 ne $key ) {
 645             next BUCKET;
 646         }
 647
 648         ##
 649         # Found match -- seek to offset and read signature
 650         ##
 651         my $signature;
 652         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 653         read( $fh, $signature, SIG_SIZE);
 654
 655         ##
 656         # If value is a hash or array, return new DBM::Deep object with correct offset
 657         ##
 658         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 659             my $obj = DBM::Deep->new(
 660                 type => $signature,
 661                 base_offset => $subloc,
 662                 root => $self->_root
 663             );
 664
 665             if ($self->_root->{autobless}) {
 666                 ##
 667                 # Skip over value and plain key to see if object needs
 668                 # to be re-blessed
 669                 ##
 670                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 671
 672                 my $size;
 673                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 674                 if ($size) { seek($fh, $size, SEEK_CUR); }
 675
 676                 my $bless_bit;
 677                 read( $fh, $bless_bit, 1);
 678                 if (ord($bless_bit)) {
 679                     ##
 680                     # Yes, object needs to be re-blessed
 681                     ##
 682                     my $class_name;
 683                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 684                     if ($size) { read( $fh, $class_name, $size); }
 685                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 686                 }
 687             }
 688
 689             return $obj;
 690         }
 691
 692         ##
 693         # Otherwise return actual value
 694         ##
 695         elsif ($signature eq SIG_DATA) {
 696             my $size;
 697             my $value = '';
 698             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 699             if ($size) { read( $fh, $value, $size); }
 700             return $value;
 701         }
 702
 703         ##
 704         # Key exists, but content is null
 705         ##
 706         else { return; }
 707         } # i loop
 708
 709         return;
 710 }
 711
 712 sub _delete_bucket {
 713         ##
 714         # Delete single key/value pair given tag and MD5 digested key.
 715         ##
 716         my $self = shift;
 717         my ($tag, $md5) = @_;
 718         my $keys = $tag->{content};
 719
 720     my $fh = $self->_fh;
 721
 722         ##
 723         # Iterate through buckets, looking for a key match
 724         ##
 725     BUCKET:
 726         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 727                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 728                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 729
 730                 if (!$subloc) {
 731                         ##
 732                         # Hit end of list, no match
 733                         ##
 734                         return;
 735                 }
 736
 737         if ( $md5 ne $key ) {
 738             next BUCKET;
 739         }
 740
 741         ##
 742         # Matched key -- delete bucket and return
 743         ##
 744         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 745         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 746         print( $fh chr(0) x $BUCKET_SIZE );
 747
 748         return 1;
 749         } # i loop
 750
 751         return;
 752 }
 753
 754 sub _bucket_exists {
 755         ##
 756         # Check existence of single key given tag and MD5 digested key.
 757         ##
 758         my $self = shift;
 759         my ($tag, $md5) = @_;
 760         my $keys = $tag->{content};
 761
 762         ##
 763         # Iterate through buckets, looking for a key match
 764         ##
 765     BUCKET:
 766         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 767                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 768                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 769
 770                 if (!$subloc) {
 771                         ##
 772                         # Hit end of list, no match
 773                         ##
 774                         return;
 775                 }
 776
 777         if ( $md5 ne $key ) {
 778             next BUCKET;
 779         }
 780
 781         ##
 782         # Matched key -- return true
 783         ##
 784         return 1;
 785         } # i loop
 786
 787         return;
 788 }
 789
 790 sub _find_bucket_list {
 791         ##
 792         # Locate offset for bucket list, given digested key
 793         ##
 794         my $self = shift;
 795         my $md5 = shift;
 796
 797         ##
 798         # Locate offset for bucket list using digest index system
 799         ##
 800         my $ch = 0;
 801         my $tag = $self->_load_tag($self->_base_offset);
 802         if (!$tag) { return; }
 803
 804         while ($tag->{signature} ne SIG_BLIST) {
 805                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 806                 if (!$tag) { return; }
 807                 $ch++;
 808         }
 809
 810         return $tag;
 811 }
 812
 813 sub _traverse_index {
 814         ##
 815         # Scan index and recursively step into deeper levels, looking for next key.
 816         ##
 817     my ($self, $offset, $ch, $force_return_next) = @_;
 818     $force_return_next = undef unless $force_return_next;
 819
 820         my $tag = $self->_load_tag( $offset );
 821
 822     my $fh = $self->_fh;
 823
 824         if ($tag->{signature} ne SIG_BLIST) {
 825                 my $content = $tag->{content};
 826                 my $start;
 827                 if ($self->{return_next}) { $start = 0; }
 828                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 829
 830                 for (my $index = $start; $index < 256; $index++) {
 831                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 832                         if ($subloc) {
 833                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 834                                 if (defined($result)) { return $result; }
 835                         }
 836                 } # index loop
 837
 838                 $self->{return_next} = 1;
 839         } # tag is an index
 840
 841         elsif ($tag->{signature} eq SIG_BLIST) {
 842                 my $keys = $tag->{content};
 843                 if ($force_return_next) { $self->{return_next} = 1; }
 844
 845                 ##
 846                 # Iterate through buckets, looking for a key match
 847                 ##
 848                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 849                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 850                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 851
 852                         if (!$subloc) {
 853                                 ##
 854                                 # End of bucket list -- return to outer loop
 855                                 ##
 856                                 $self->{return_next} = 1;
 857                                 last;
 858                         }
 859                         elsif ($key eq $self->{prev_md5}) {
 860                                 ##
 861                                 # Located previous key -- return next one found
 862                                 ##
 863                                 $self->{return_next} = 1;
 864                                 next;
 865                         }
 866                         elsif ($self->{return_next}) {
 867                                 ##
 868                                 # Seek to bucket location and skip over signature
 869                                 ##
 870                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 871
 872                                 ##
 873                                 # Skip over value to get to plain key
 874                                 ##
 875                                 my $size;
 876                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 877                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 878
 879                                 ##
 880                                 # Read in plain key and return as scalar
 881                                 ##
 882                                 my $plain_key;
 883                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 884                                 if ($size) { read( $fh, $plain_key, $size); }
 885
 886                                 return $plain_key;
 887                         }
 888                 } # bucket loop
 889
 890                 $self->{return_next} = 1;
 891         } # tag is a bucket list
 892
 893         return;
 894 }
 895
 896 sub _get_next_key {
 897         ##
 898         # Locate next key, given digested previous one
 899         ##
 900     my $self = $_[0]->_get_self;
 901
 902         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 903         $self->{return_next} = 0;
 904
 905         ##
 906         # If the previous key was not specifed, start at the top and
 907         # return the first one found.
 908         ##
 909         if (!$self->{prev_md5}) {
 910                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 911                 $self->{return_next} = 1;
 912         }
 913
 914         return $self->_traverse_index( $self->_base_offset, 0 );
 915 }
 916
 917 sub lock {
 918         ##
 919         # If db locking is set, flock() the db file.  If called multiple
 920         # times before unlock(), then the same number of unlocks() must
 921         # be called before the lock is released.
 922         ##
 923     my $self = $_[0]->_get_self;
 924         my $type = $_[1];
 925     $type = LOCK_EX unless defined $type;
 926
 927         if (!defined($self->_fh)) { return; }
 928
 929         if ($self->_root->{locking}) {
 930                 if (!$self->_root->{locked}) {
 931                         flock($self->_fh, $type);
 932
 933                         # refresh end counter in case file has changed size
 934                         my @stats = stat($self->_root->{file});
 935                         $self->_root->{end} = $stats[7];
 936
 937                         # double-check file inode, in case another process
 938                         # has optimize()d our file while we were waiting.
 939                         if ($stats[1] != $self->_root->{inode}) {
 940                                 $self->_open(); # re-open
 941                                 flock($self->_fh, $type); # re-lock
 942                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 943                         }
 944                 }
 945                 $self->_root->{locked}++;
 946
 947         return 1;
 948         }
 949
 950     return;
 951 }
 952
 953 sub unlock {
 954         ##
 955         # If db locking is set, unlock the db file.  See note in lock()
 956         # regarding calling lock() multiple times.
 957         ##
 958     my $self = $_[0]->_get_self;
 959
 960         if (!defined($self->_fh)) { return; }
 961
 962         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 963                 $self->_root->{locked}--;
 964                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 965
 966         return 1;
 967         }
 968
 969     return;
 970 }
 971
 972 sub _copy_value {
 973     my $self = shift->_get_self;
 974     my ($spot, $value) = @_;
 975
 976     if ( !ref $value ) {
 977         ${$spot} = $value;
 978     }
 979     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 980         my $type = $value->_type;
 981         ${$spot} = $type eq TYPE_HASH ? {} : [];
 982         $value->_copy_node( ${$spot} );
 983     }
 984     else {
 985         my $r = Scalar::Util::reftype( $value );
 986         my $c = Scalar::Util::blessed( $value );
 987         if ( $r eq 'ARRAY' ) {
 988             ${$spot} = [ @{$value} ];
 989         }
 990         else {
 991             ${$spot} = { %{$value} };
 992         }
 993         ${$spot} = bless ${$spot}, $c
 994             if defined $c;
 995     }
 996
 997     return 1;
 998 }
 999
1000 sub _copy_node {
1001         ##
1002         # Copy single level of keys or elements to new DB handle.
1003         # Recurse for nested structures
1004         ##
1005     my $self = shift->_get_self;
1006         my ($db_temp) = @_;
1007
1008         if ($self->_type eq TYPE_HASH) {
1009                 my $key = $self->first_key();
1010                 while ($key) {
1011                         my $value = $self->get($key);
1012             $self->_copy_value( \$db_temp->{$key}, $value );
1013                         $key = $self->next_key($key);
1014                 }
1015         }
1016         else {
1017                 my $length = $self->length();
1018                 for (my $index = 0; $index < $length; $index++) {
1019                         my $value = $self->get($index);
1020             $self->_copy_value( \$db_temp->[$index], $value );
1021                 }
1022         }
1023
1024     return 1;
1025 }
1026
1027 sub export {
1028         ##
1029         # Recursively export into standard Perl hashes and arrays.
1030         ##
1031     my $self = $_[0]->_get_self;
1032
1033         my $temp;
1034         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1035         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1036
1037         $self->lock();
1038         $self->_copy_node( $temp );
1039         $self->unlock();
1040
1041         return $temp;
1042 }
1043
1044 sub import {
1045         ##
1046         # Recursively import Perl hash/array structure
1047         ##
1048     #XXX This use of ref() seems to be ok
1049         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1050
1051     my $self = $_[0]->_get_self;
1052         my $struct = $_[1];
1053
1054     #XXX This use of ref() seems to be ok
1055         if (!ref($struct)) {
1056                 ##
1057                 # struct is not a reference, so just import based on our type
1058                 ##
1059                 shift @_;
1060
1061                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1062                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1063         }
1064
1065     my $r = Scalar::Util::reftype($struct) || '';
1066         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1067                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1068         }
1069         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1070                 $self->push( @$struct );
1071         }
1072         else {
1073                 return $self->_throw_error("Cannot import: type mismatch");
1074         }
1075
1076         return 1;
1077 }
1078
1079 sub optimize {
1080         ##
1081         # Rebuild entire database into new file, then move
1082         # it back on top of original.
1083         ##
1084     my $self = $_[0]->_get_self;
1085
1086 #XXX Need to create a new test for this
1087 #       if ($self->_root->{links} > 1) {
1088 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1089 #       }
1090
1091         my $db_temp = DBM::Deep->new(
1092                 file => $self->_root->{file} . '.tmp',
1093                 type => $self->_type
1094         );
1095         if (!$db_temp) {
1096                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1097         }
1098
1099         $self->lock();
1100         $self->_copy_node( $db_temp );
1101         undef $db_temp;
1102
1103         ##
1104         # Attempt to copy user, group and permissions over to new file
1105         ##
1106         my @stats = stat($self->_fh);
1107         my $perms = $stats[2] & 07777;
1108         my $uid = $stats[4];
1109         my $gid = $stats[5];
1110         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1111         chmod( $perms, $self->_root->{file} . '.tmp' );
1112
1113     # q.v. perlport for more information on this variable
1114     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1115                 ##
1116                 # Potential race condition when optmizing on Win32 with locking.
1117                 # The Windows filesystem requires that the filehandle be closed
1118                 # before it is overwritten with rename().  This could be redone
1119                 # with a soft copy.
1120                 ##
1121                 $self->unlock();
1122                 $self->_close();
1123         }
1124
1125         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1126                 unlink $self->_root->{file} . '.tmp';
1127                 $self->unlock();
1128                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1129         }
1130
1131         $self->unlock();
1132         $self->_close();
1133         $self->_open();
1134
1135         return 1;
1136 }
1137
1138 sub clone {
1139         ##
1140         # Make copy of object and return
1141         ##
1142     my $self = $_[0]->_get_self;
1143
1144         return DBM::Deep->new(
1145                 type => $self->_type,
1146                 base_offset => $self->_base_offset,
1147                 root => $self->_root
1148         );
1149 }
1150
1151 {
1152     my %is_legal_filter = map {
1153         $_ => ~~1,
1154     } qw(
1155         store_key store_value
1156         fetch_key fetch_value
1157     );
1158
1159     sub set_filter {
1160         ##
1161         # Setup filter function for storing or fetching the key or value
1162         ##
1163         my $self = $_[0]->_get_self;
1164         my $type = lc $_[1];
1165         my $func = $_[2] ? $_[2] : undef;
1166
1167         if ( $is_legal_filter{$type} ) {
1168             $self->_root->{"filter_$type"} = $func;
1169             return 1;
1170         }
1171
1172         return;
1173     }
1174 }
1175
1176 ##
1177 # Accessor methods
1178 ##
1179
1180 sub _root {
1181         ##
1182         # Get access to the root structure
1183         ##
1184     my $self = $_[0]->_get_self;
1185         return $self->{root};
1186 }
1187
1188 sub _fh {
1189         ##
1190         # Get access to the raw fh
1191         ##
1192     #XXX It will be useful, though, when we split out HASH and ARRAY
1193     my $self = $_[0]->_get_self;
1194         return $self->_root->{fh};
1195 }
1196
1197 sub _type {
1198         ##
1199         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1200         ##
1201     my $self = $_[0]->_get_self;
1202         return $self->{type};
1203 }
1204
1205 sub _base_offset {
1206         ##
1207         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1208         ##
1209     my $self = $_[0]->_get_self;
1210         return $self->{base_offset};
1211 }
1212
1213 ##
1214 # Utility methods
1215 ##
1216
1217 sub _throw_error {
1218     die "DBM::Deep: $_[1]\n";
1219 }
1220
1221 sub _precalc_sizes {
1222         ##
1223         # Precalculate index, bucket and bucket list sizes
1224         ##
1225
1226     #XXX I don't like this ...
1227     set_pack() unless defined $LONG_SIZE;
1228
1229         $INDEX_SIZE = 256 * $LONG_SIZE;
1230         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1231         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1232 }
1233
1234 sub set_pack {
1235         ##
1236         # Set pack/unpack modes (see file header for more)
1237         ##
1238     my ($long_s, $long_p, $data_s, $data_p) = @_;
1239
1240     $LONG_SIZE = $long_s ? $long_s : 4;
1241     $LONG_PACK = $long_p ? $long_p : 'N';
1242
1243     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1244     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1245
1246         _precalc_sizes();
1247 }
1248
1249 sub set_digest {
1250         ##
1251         # Set key digest function (default is MD5)
1252         ##
1253     my ($digest_func, $hash_size) = @_;
1254
1255     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1256     $HASH_SIZE = $hash_size ? $hash_size : 16;
1257
1258         _precalc_sizes();
1259 }
1260
1261 sub _is_writable {
1262     my $fh = shift;
1263     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1264 }
1265
1266 #sub _is_readable {
1267 #    my $fh = shift;
1268 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1269 #}
1270
1271 ##
1272 # tie() methods (hashes and arrays)
1273 ##
1274
1275 sub STORE {
1276         ##
1277         # Store single hash key/value or array element in database.
1278         ##
1279     my $self = $_[0]->_get_self;
1280         my $key = $_[1];
1281
1282     # User may be storing a hash, in which case we do not want it run
1283     # through the filtering system
1284         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1285         ? $self->_root->{filter_store_value}->($_[2])
1286         : $_[2];
1287
1288         my $md5 = $DIGEST_FUNC->($key);
1289
1290     unless ( _is_writable( $self->_fh ) ) {
1291         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1292     }
1293
1294         ##
1295         # Request exclusive lock for writing
1296         ##
1297         $self->lock( LOCK_EX );
1298
1299         my $fh = $self->_fh;
1300
1301         ##
1302         # Locate offset for bucket list using digest index system
1303         ##
1304         my $tag = $self->_load_tag($self->_base_offset);
1305         if (!$tag) {
1306                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1307         }
1308
1309         my $ch = 0;
1310         while ($tag->{signature} ne SIG_BLIST) {
1311                 my $num = ord(substr($md5, $ch, 1));
1312
1313         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1314                 my $new_tag = $self->_index_lookup($tag, $num);
1315
1316                 if (!$new_tag) {
1317                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1318                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1319
1320                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1321
1322                         $tag->{ref_loc} = $ref_loc;
1323                         $tag->{ch} = $ch;
1324
1325                         last;
1326                 }
1327                 else {
1328                         $tag = $new_tag;
1329
1330                         $tag->{ref_loc} = $ref_loc;
1331                         $tag->{ch} = $ch;
1332                 }
1333                 $ch++;
1334         }
1335
1336         ##
1337         # Add key/value to bucket list
1338         ##
1339         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1340
1341         $self->unlock();
1342
1343         return $result;
1344 }
1345
1346 sub FETCH {
1347         ##
1348         # Fetch single value or element given plain key or array index
1349         ##
1350     my $self = shift->_get_self;
1351     my $key = shift;
1352
1353         my $md5 = $DIGEST_FUNC->($key);
1354
1355         ##
1356         # Request shared lock for reading
1357         ##
1358         $self->lock( LOCK_SH );
1359
1360         my $tag = $self->_find_bucket_list( $md5 );
1361         if (!$tag) {
1362                 $self->unlock();
1363                 return;
1364         }
1365
1366         ##
1367         # Get value from bucket list
1368         ##
1369         my $result = $self->_get_bucket_value( $tag, $md5 );
1370
1371         $self->unlock();
1372
1373     #XXX What is ref() checking here?
1374     #YYY Filters only apply on scalar values, so the ref check is making
1375     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1376         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1377         ? $self->_root->{filter_fetch_value}->($result)
1378         : $result;
1379 }
1380
1381 sub DELETE {
1382         ##
1383         # Delete single key/value pair or element given plain key or array index
1384         ##
1385     my $self = $_[0]->_get_self;
1386         my $key = $_[1];
1387
1388         my $md5 = $DIGEST_FUNC->($key);
1389
1390         ##
1391         # Request exclusive lock for writing
1392         ##
1393         $self->lock( LOCK_EX );
1394
1395         my $tag = $self->_find_bucket_list( $md5 );
1396         if (!$tag) {
1397                 $self->unlock();
1398                 return;
1399         }
1400
1401         ##
1402         # Delete bucket
1403         ##
1404     my $value = $self->_get_bucket_value( $tag, $md5 );
1405         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1406         $value = $self->_root->{filter_fetch_value}->($value);
1407     }
1408
1409         my $result = $self->_delete_bucket( $tag, $md5 );
1410
1411         ##
1412         # If this object is an array and the key deleted was on the end of the stack,
1413         # decrement the length variable.
1414         ##
1415
1416         $self->unlock();
1417
1418         return $value;
1419 }
1420
1421 sub EXISTS {
1422         ##
1423         # Check if a single key or element exists given plain key or array index
1424         ##
1425     my $self = $_[0]->_get_self;
1426         my $key = $_[1];
1427
1428         my $md5 = $DIGEST_FUNC->($key);
1429
1430         ##
1431         # Request shared lock for reading
1432         ##
1433         $self->lock( LOCK_SH );
1434
1435         my $tag = $self->_find_bucket_list( $md5 );
1436
1437         ##
1438         # For some reason, the built-in exists() function returns '' for false
1439         ##
1440         if (!$tag) {
1441                 $self->unlock();
1442                 return '';
1443         }
1444
1445         ##
1446         # Check if bucket exists and return 1 or ''
1447         ##
1448         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1449
1450         $self->unlock();
1451
1452         return $result;
1453 }
1454
1455 sub CLEAR {
1456         ##
1457         # Clear all keys from hash, or all elements from array.
1458         ##
1459     my $self = $_[0]->_get_self;
1460
1461         ##
1462         # Request exclusive lock for writing
1463         ##
1464         $self->lock( LOCK_EX );
1465
1466     my $fh = $self->_fh;
1467
1468         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1469         if (eof $fh) {
1470                 $self->unlock();
1471                 return;
1472         }
1473
1474         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1475
1476         $self->unlock();
1477
1478         return 1;
1479 }
1480
1481 ##
1482 # Public method aliases
1483 ##
1484 sub put { (shift)->STORE( @_ ) }
1485 sub store { (shift)->STORE( @_ ) }
1486 sub get { (shift)->FETCH( @_ ) }
1487 sub fetch { (shift)->FETCH( @_ ) }
1488 sub delete { (shift)->DELETE( @_ ) }
1489 sub exists { (shift)->EXISTS( @_ ) }
1490 sub clear { (shift)->CLEAR( @_ ) }
1491
1492 package DBM::Deep::_::Root;
1493
1494 sub new {
1495     my $class = shift;
1496     my ($args) = @_;
1497
1498     my $self = bless {
1499         file => undef,
1500         fh => undef,
1501         file_offset => 0,
1502         end => 0,
1503         autoflush => undef,
1504         locking => undef,
1505         debug => undef,
1506         filter_store_key => undef,
1507         filter_store_value => undef,
1508         filter_fetch_key => undef,
1509         filter_fetch_value => undef,
1510         autobless => undef,
1511         locked => 0,
1512         %$args,
1513     }, $class;
1514
1515     if ( $self->{fh} && !$self->{file_offset} ) {
1516         $self->{file_offset} = tell( $self->{fh} );
1517     }
1518
1519     return $self;
1520 }
1521
1522 sub DESTROY {
1523     my $self = shift;
1524     return unless $self;
1525
1526     close $self->{fh} if $self->{fh};
1527
1528     return;
1529 }
1530
1531 1;
1532
1533 __END__
1534
1535 =head1 NAME
1536
1537 DBM::Deep - A pure perl multi-level hash/array DBM
1538
1539 =head1 SYNOPSIS
1540
1541   use DBM::Deep;
1542   my $db = DBM::Deep->new( "foo.db" );
1543
1544   $db->{key} = 'value'; # tie() style
1545   print $db->{key};
1546
1547   $db->put('key' => 'value'); # OO style
1548   print $db->get('key');
1549
1550   # true multi-level support
1551   $db->{my_complex} = [
1552         'hello', { perl => 'rules' },
1553         42, 99,
1554   ];
1555
1556 =head1 DESCRIPTION
1557
1558 A unique flat-file database module, written in pure perl.  True
1559 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1560 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1561 handle millions of keys and unlimited hash levels without significant
1562 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1563 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1564 Mac OS X and Windows.
1565
1566 =head1 INSTALLATION
1567
1568 Hopefully you are using Perl's excellent CPAN module, which will download
1569 and install the module for you.  If not, get the tarball, and run these
1570 commands:
1571
1572         tar zxf DBM-Deep-*
1573         cd DBM-Deep-*
1574         perl Makefile.PL
1575         make
1576         make test
1577         make install
1578
1579 =head1 SETUP
1580
1581 Construction can be done OO-style (which is the recommended way), or using
1582 Perl's tie() function.  Both are examined here.
1583
1584 =head2 OO CONSTRUCTION
1585
1586 The recommended way to construct a DBM::Deep object is to use the new()
1587 method, which gets you a blessed, tied hash or array reference.
1588
1589         my $db = DBM::Deep->new( "foo.db" );
1590
1591 This opens a new database handle, mapped to the file "foo.db".  If this
1592 file does not exist, it will automatically be created.  DB files are
1593 opened in "r+" (read/write) mode, and the type of object returned is a
1594 hash, unless otherwise specified (see L<OPTIONS> below).
1595
1596 You can pass a number of options to the constructor to specify things like
1597 locking, autoflush, etc.  This is done by passing an inline hash:
1598
1599         my $db = DBM::Deep->new(
1600                 file => "foo.db",
1601                 locking => 1,
1602                 autoflush => 1
1603         );
1604
1605 Notice that the filename is now specified I<inside> the hash with
1606 the "file" parameter, as opposed to being the sole argument to the
1607 constructor.  This is required if any options are specified.
1608 See L<OPTIONS> below for the complete list.
1609
1610
1611
1612 You can also start with an array instead of a hash.  For this, you must
1613 specify the C<type> parameter:
1614
1615         my $db = DBM::Deep->new(
1616                 file => "foo.db",
1617                 type => DBM::Deep->TYPE_ARRAY
1618         );
1619
1620 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1621 a new DB file.  If you create a DBM::Deep object with an existing file, the
1622 C<type> will be loaded from the file header, and an error will be thrown if
1623 the wrong type is passed in.
1624
1625 =head2 TIE CONSTRUCTION
1626
1627 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1628 tie() function.  The object returned from tie() can be used to call methods,
1629 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1630 file (as expected with most tie'd objects).
1631
1632         my %hash;
1633         my $db = tie %hash, "DBM::Deep", "foo.db";
1634
1635         my @array;
1636         my $db = tie @array, "DBM::Deep", "bar.db";
1637
1638 As with the OO constructor, you can replace the DB filename parameter with
1639 a hash containing one or more options (see L<OPTIONS> just below for the
1640 complete list).
1641
1642         tie %hash, "DBM::Deep", {
1643                 file => "foo.db",
1644                 locking => 1,
1645                 autoflush => 1
1646         };
1647
1648 =head2 OPTIONS
1649
1650 There are a number of options that can be passed in when constructing your
1651 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1652
1653 =over
1654
1655 =item * file
1656
1657 Filename of the DB file to link the handle to.  You can pass a full absolute
1658 filesystem path, partial path, or a plain filename if the file is in the
1659 current working directory.  This is a required parameter (though q.v. fh).
1660
1661 =item * fh
1662
1663 If you want, you can pass in the fh instead of the file. This is most useful for doing
1664 something like:
1665
1666   my $db = DBM::Deep->new( { fh => \*DATA } );
1667
1668 You are responsible for making sure that the fh has been opened appropriately for your
1669 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1670 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1671 needs to read from the fh.
1672
1673 =item * file_offset
1674
1675 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1676 not need to set this. However, it's there if you want it.
1677
1678 If you pass in fh and do not set this, it will be set appropriately.
1679
1680 =item * type
1681
1682 This parameter specifies what type of object to create, a hash or array.  Use
1683 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1684 This only takes effect when beginning a new file.  This is an optional
1685 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1686
1687 =item * locking
1688
1689 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1690 function to lock the database in exclusive mode for writes, and shared mode for
1691 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1692 any child hashes or arrays> that use the same DB file.  This is an optional
1693 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1694
1695 =item * autoflush
1696
1697 Specifies whether autoflush is to be enabled on the underlying filehandle.
1698 This obviously slows down write operations, but is required if you may have
1699 multiple processes accessing the same DB file (also consider enable I<locking>).
1700 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1701 (disabled).
1702
1703 =item * autobless
1704
1705 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1706 restore them when fetched.  This is an B<experimental> feature, and does have
1707 side-effects.  Basically, when hashes are re-blessed into their original
1708 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1709 able to call any DBM::Deep methods on them.  You have been warned.
1710 This is an optional parameter, and defaults to 0 (disabled).
1711
1712 =item * filter_*
1713
1714 See L<FILTERS> below.
1715
1716 =item * debug
1717
1718 Setting I<debug> mode will make all errors non-fatal, dump them out to
1719 STDERR, and continue on.  This is for debugging purposes only, and probably
1720 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1721
1722 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1723
1724 =back
1725
1726 =head1 TIE INTERFACE
1727
1728 With DBM::Deep you can access your databases using Perl's standard hash/array
1729 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1730 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1731 to the right place -- the DB file.  This has nothing to do with the
1732 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1733 using regular hashes and arrays, rather than calling functions like C<get()>
1734 and C<put()> (although those work too).  It is entirely up to you how to want
1735 to access your databases.
1736
1737 =head2 HASHES
1738
1739 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1740 or even nested hashes (or arrays) using standard Perl syntax:
1741
1742         my $db = DBM::Deep->new( "foo.db" );
1743
1744         $db->{mykey} = "myvalue";
1745         $db->{myhash} = {};
1746         $db->{myhash}->{subkey} = "subvalue";
1747
1748         print $db->{myhash}->{subkey} . "\n";
1749
1750 You can even step through hash keys using the normal Perl C<keys()> function:
1751
1752         foreach my $key (keys %$db) {
1753                 print "$key: " . $db->{$key} . "\n";
1754         }
1755
1756 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1757 pushes them onto an array, all before the loop even begins.  If you have an
1758 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1759 Perl's C<each()> function, which pulls keys/values one at a time, using very
1760 little memory:
1761
1762         while (my ($key, $value) = each %$db) {
1763                 print "$key: $value\n";
1764         }
1765
1766 Please note that when using C<each()>, you should always pass a direct
1767 hash reference, not a lookup.  Meaning, you should B<never> do this:
1768
1769         # NEVER DO THIS
1770         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1771
1772 This causes an infinite loop, because for each iteration, Perl is calling
1773 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1774 it effectively keeps returning the first key over and over again. Instead,
1775 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1776
1777 =head2 ARRAYS
1778
1779 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1780 reference.  This includes inserting, removing and manipulating elements,
1781 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1782 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1783 or simply be a nested array reference inside a hash.  Example:
1784
1785         my $db = DBM::Deep->new(
1786                 file => "foo-array.db",
1787                 type => DBM::Deep->TYPE_ARRAY
1788         );
1789
1790         $db->[0] = "foo";
1791         push @$db, "bar", "baz";
1792         unshift @$db, "bah";
1793
1794         my $last_elem = pop @$db; # baz
1795         my $first_elem = shift @$db; # bah
1796         my $second_elem = $db->[1]; # bar
1797
1798         my $num_elements = scalar @$db;
1799
1800 =head1 OO INTERFACE
1801
1802 In addition to the I<tie()> interface, you can also use a standard OO interface
1803 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1804 array) has its own methods, but both types share the following common methods:
1805 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1806
1807 =over
1808
1809 =item * new() / clone()
1810
1811 These are the constructor and copy-functions.
1812
1813 =item * put() / store()
1814
1815 Stores a new hash key/value pair, or sets an array element value.  Takes two
1816 arguments, the hash key or array index, and the new value.  The value can be
1817 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1818
1819         $db->put("foo", "bar"); # for hashes
1820         $db->put(1, "bar"); # for arrays
1821
1822 =item * get() / fetch()
1823
1824 Fetches the value of a hash key or array element.  Takes one argument: the hash
1825 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1826 data type stored.
1827
1828         my $value = $db->get("foo"); # for hashes
1829         my $value = $db->get(1); # for arrays
1830
1831 =item * exists()
1832
1833 Checks if a hash key or array index exists.  Takes one argument: the hash key
1834 or array index.  Returns true if it exists, false if not.
1835
1836         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1837         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1838
1839 =item * delete()
1840
1841 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1842 key or array index.  Returns true on success, false if not found.  For arrays,
1843 the remaining elements located after the deleted element are NOT moved over.
1844 The deleted element is essentially just undefined, which is exactly how Perl's
1845 internal arrays work.  Please note that the space occupied by the deleted
1846 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1847 below for details and workarounds.
1848
1849         $db->delete("foo"); # for hashes
1850         $db->delete(1); # for arrays
1851
1852 =item * clear()
1853
1854 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1855 value.  Please note that the space occupied by the deleted keys/values or
1856 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1857 details and workarounds.
1858
1859         $db->clear(); # hashes or arrays
1860
1861 =item * lock() / unlock()
1862
1863 q.v. Locking.
1864
1865 =item * optimize()
1866
1867 Recover lost disk space.
1868
1869 =item * import() / export()
1870
1871 Data going in and out.
1872
1873 =item * set_digest() / set_pack() / set_filter()
1874
1875 q.v. adjusting the interal parameters.
1876
1877 =back
1878
1879 =head2 HASHES
1880
1881 For hashes, DBM::Deep supports all the common methods described above, and the
1882 following additional methods: C<first_key()> and C<next_key()>.
1883
1884 =over
1885
1886 =item * first_key()
1887
1888 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1889 fetched in an undefined order (which appears random).  Takes no arguments,
1890 returns the key as a scalar value.
1891
1892         my $key = $db->first_key();
1893
1894 =item * next_key()
1895
1896 Returns the "next" key in the hash, given the previous one as the sole argument.
1897 Returns undef if there are no more keys to be fetched.
1898
1899         $key = $db->next_key($key);
1900
1901 =back
1902
1903 Here are some examples of using hashes:
1904
1905         my $db = DBM::Deep->new( "foo.db" );
1906
1907         $db->put("foo", "bar");
1908         print "foo: " . $db->get("foo") . "\n";
1909
1910         $db->put("baz", {}); # new child hash ref
1911         $db->get("baz")->put("buz", "biz");
1912         print "buz: " . $db->get("baz")->get("buz") . "\n";
1913
1914         my $key = $db->first_key();
1915         while ($key) {
1916                 print "$key: " . $db->get($key) . "\n";
1917                 $key = $db->next_key($key);
1918         }
1919
1920         if ($db->exists("foo")) { $db->delete("foo"); }
1921
1922 =head2 ARRAYS
1923
1924 For arrays, DBM::Deep supports all the common methods described above, and the
1925 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1926 C<unshift()> and C<splice()>.
1927
1928 =over
1929
1930 =item * length()
1931
1932 Returns the number of elements in the array.  Takes no arguments.
1933
1934         my $len = $db->length();
1935
1936 =item * push()
1937
1938 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1939 refs or array refs.  No return value.
1940
1941         $db->push("foo", "bar", {});
1942
1943 =item * pop()
1944
1945 Fetches the last element in the array, and deletes it.  Takes no arguments.
1946 Returns undef if array is empty.  Returns the element value.
1947
1948         my $elem = $db->pop();
1949
1950 =item * shift()
1951
1952 Fetches the first element in the array, deletes it, then shifts all the
1953 remaining elements over to take up the space.  Returns the element value.  This
1954 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1955 details.
1956
1957         my $elem = $db->shift();
1958
1959 =item * unshift()
1960
1961 Inserts one or more elements onto the beginning of the array, shifting all
1962 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1963 No return value.  This method is not recommended with large arrays -- see
1964 <LARGE ARRAYS> below for details.
1965
1966         $db->unshift("foo", "bar", {});
1967
1968 =item * splice()
1969
1970 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1971 -f splice> for usage -- it is too complicated to document here.  This method is
1972 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1973
1974 =back
1975
1976 Here are some examples of using arrays:
1977
1978         my $db = DBM::Deep->new(
1979                 file => "foo.db",
1980                 type => DBM::Deep->TYPE_ARRAY
1981         );
1982
1983         $db->push("bar", "baz");
1984         $db->unshift("foo");
1985         $db->put(3, "buz");
1986
1987         my $len = $db->length();
1988         print "length: $len\n"; # 4
1989
1990         for (my $k=0; $k<$len; $k++) {
1991                 print "$k: " . $db->get($k) . "\n";
1992         }
1993
1994         $db->splice(1, 2, "biz", "baf");
1995
1996         while (my $elem = shift @$db) {
1997                 print "shifted: $elem\n";
1998         }
1999
2000 =head1 LOCKING
2001
2002 Enable automatic file locking by passing a true value to the C<locking>
2003 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2004
2005         my $db = DBM::Deep->new(
2006                 file => "foo.db",
2007                 locking => 1
2008         );
2009
2010 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2011 mode for writes, and shared mode for reads.  This is required if you have
2012 multiple processes accessing the same database file, to avoid file corruption.
2013 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2014 NFS> below for more.
2015
2016 =head2 EXPLICIT LOCKING
2017
2018 You can explicitly lock a database, so it remains locked for multiple
2019 transactions.  This is done by calling the C<lock()> method, and passing an
2020 optional lock mode argument (defaults to exclusive mode).  This is particularly
2021 useful for things like counters, where the current value needs to be fetched,
2022 then incremented, then stored again.
2023
2024         $db->lock();
2025         my $counter = $db->get("counter");
2026         $counter++;
2027         $db->put("counter", $counter);
2028         $db->unlock();
2029
2030         # or...
2031
2032         $db->lock();
2033         $db->{counter}++;
2034         $db->unlock();
2035
2036 You can pass C<lock()> an optional argument, which specifies which mode to use
2037 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2038 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2039 same as the constants defined in Perl's C<Fcntl> module.
2040
2041         $db->lock( DBM::Deep->LOCK_SH );
2042         # something here
2043         $db->unlock();
2044
2045 =head1 IMPORTING/EXPORTING
2046
2047 You can import existing complex structures by calling the C<import()> method,
2048 and export an entire database into an in-memory structure using the C<export()>
2049 method.  Both are examined here.
2050
2051 =head2 IMPORTING
2052
2053 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2054 walking the structure and adding keys/elements to the database as you go,
2055 simply pass a reference to the C<import()> method.  This recursively adds
2056 everything to an existing DBM::Deep object for you.  Here is an example:
2057
2058         my $struct = {
2059                 key1 => "value1",
2060                 key2 => "value2",
2061                 array1 => [ "elem0", "elem1", "elem2" ],
2062                 hash1 => {
2063                         subkey1 => "subvalue1",
2064                         subkey2 => "subvalue2"
2065                 }
2066         };
2067
2068         my $db = DBM::Deep->new( "foo.db" );
2069         $db->import( $struct );
2070
2071         print $db->{key1} . "\n"; # prints "value1"
2072
2073 This recursively imports the entire C<$struct> object into C<$db>, including
2074 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2075 keys are merged with the existing ones, replacing if they already exist.
2076 The C<import()> method can be called on any database level (not just the base
2077 level), and works with both hash and array DB types.
2078
2079 B<Note:> Make sure your existing structure has no circular references in it.
2080 These will cause an infinite loop when importing.
2081
2082 =head2 EXPORTING
2083
2084 Calling the C<export()> method on an existing DBM::Deep object will return
2085 a reference to a new in-memory copy of the database.  The export is done
2086 recursively, so all nested hashes/arrays are all exported to standard Perl
2087 objects.  Here is an example:
2088
2089         my $db = DBM::Deep->new( "foo.db" );
2090
2091         $db->{key1} = "value1";
2092         $db->{key2} = "value2";
2093         $db->{hash1} = {};
2094         $db->{hash1}->{subkey1} = "subvalue1";
2095         $db->{hash1}->{subkey2} = "subvalue2";
2096
2097         my $struct = $db->export();
2098
2099         print $struct->{key1} . "\n"; # prints "value1"
2100
2101 This makes a complete copy of the database in memory, and returns a reference
2102 to it.  The C<export()> method can be called on any database level (not just
2103 the base level), and works with both hash and array DB types.  Be careful of
2104 large databases -- you can store a lot more data in a DBM::Deep object than an
2105 in-memory Perl structure.
2106
2107 B<Note:> Make sure your database has no circular references in it.
2108 These will cause an infinite loop when exporting.
2109
2110 =head1 FILTERS
2111
2112 DBM::Deep has a number of hooks where you can specify your own Perl function
2113 to perform filtering on incoming or outgoing data.  This is a perfect
2114 way to extend the engine, and implement things like real-time compression or
2115 encryption.  Filtering applies to the base DB level, and all child hashes /
2116 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2117 constructed, or by calling the C<set_filter()> method at any time.  There are
2118 four available filter hooks, described below:
2119
2120 =over
2121
2122 =item * filter_store_key
2123
2124 This filter is called whenever a hash key is stored.  It
2125 is passed the incoming key, and expected to return a transformed key.
2126
2127 =item * filter_store_value
2128
2129 This filter is called whenever a hash key or array element is stored.  It
2130 is passed the incoming value, and expected to return a transformed value.
2131
2132 =item * filter_fetch_key
2133
2134 This filter is called whenever a hash key is fetched (i.e. via
2135 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2136 and expected to return the plain key.
2137
2138 =item * filter_fetch_value
2139
2140 This filter is called whenever a hash key or array element is fetched.
2141 It is passed the transformed value, and expected to return the plain value.
2142
2143 =back
2144
2145 Here are the two ways to setup a filter hook:
2146
2147         my $db = DBM::Deep->new(
2148                 file => "foo.db",
2149                 filter_store_value => \&my_filter_store,
2150                 filter_fetch_value => \&my_filter_fetch
2151         );
2152
2153         # or...
2154
2155         $db->set_filter( "filter_store_value", \&my_filter_store );
2156         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2157
2158 Your filter function will be called only when dealing with SCALAR keys or
2159 values.  When nested hashes and arrays are being stored/fetched, filtering
2160 is bypassed.  Filters are called as static functions, passed a single SCALAR
2161 argument, and expected to return a single SCALAR value.  If you want to
2162 remove a filter, set the function reference to C<undef>:
2163
2164         $db->set_filter( "filter_store_value", undef );
2165
2166 =head2 REAL-TIME ENCRYPTION EXAMPLE
2167
2168 Here is a working example that uses the I<Crypt::Blowfish> module to
2169 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2170 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2171 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2172
2173         use DBM::Deep;
2174         use Crypt::Blowfish;
2175         use Crypt::CBC;
2176
2177         my $cipher = Crypt::CBC->new({
2178                 'key'             => 'my secret key',
2179                 'cipher'          => 'Blowfish',
2180                 'iv'              => '$KJh#(}q',
2181                 'regenerate_key'  => 0,
2182                 'padding'         => 'space',
2183                 'prepend_iv'      => 0
2184         });
2185
2186         my $db = DBM::Deep->new(
2187                 file => "foo-encrypt.db",
2188                 filter_store_key => \&my_encrypt,
2189                 filter_store_value => \&my_encrypt,
2190                 filter_fetch_key => \&my_decrypt,
2191                 filter_fetch_value => \&my_decrypt,
2192         );
2193
2194         $db->{key1} = "value1";
2195         $db->{key2} = "value2";
2196         print "key1: " . $db->{key1} . "\n";
2197         print "key2: " . $db->{key2} . "\n";
2198
2199         undef $db;
2200         exit;
2201
2202         sub my_encrypt {
2203                 return $cipher->encrypt( $_[0] );
2204         }
2205         sub my_decrypt {
2206                 return $cipher->decrypt( $_[0] );
2207         }
2208
2209 =head2 REAL-TIME COMPRESSION EXAMPLE
2210
2211 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2212 compression / decompression of keys & values with DBM::Deep Filters.
2213 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2214 more on I<Compress::Zlib>.
2215
2216         use DBM::Deep;
2217         use Compress::Zlib;
2218
2219         my $db = DBM::Deep->new(
2220                 file => "foo-compress.db",
2221                 filter_store_key => \&my_compress,
2222                 filter_store_value => \&my_compress,
2223                 filter_fetch_key => \&my_decompress,
2224                 filter_fetch_value => \&my_decompress,
2225         );
2226
2227         $db->{key1} = "value1";
2228         $db->{key2} = "value2";
2229         print "key1: " . $db->{key1} . "\n";
2230         print "key2: " . $db->{key2} . "\n";
2231
2232         undef $db;
2233         exit;
2234
2235         sub my_compress {
2236                 return Compress::Zlib::memGzip( $_[0] ) ;
2237         }
2238         sub my_decompress {
2239                 return Compress::Zlib::memGunzip( $_[0] ) ;
2240         }
2241
2242 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2243 actually numerical index numbers, and are not filtered.
2244
2245 =head1 ERROR HANDLING
2246
2247 Most DBM::Deep methods return a true value for success, and call die() on
2248 failure.  You can wrap calls in an eval block to catch the die.
2249
2250         my $db = DBM::Deep->new( "foo.db" ); # create hash
2251         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2252
2253     print $@;           # prints error message
2254
2255 =head1 LARGEFILE SUPPORT
2256
2257 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2258 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2259 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2260 by calling the static C<set_pack()> method before you do anything else.
2261
2262         DBM::Deep::set_pack(8, 'Q');
2263
2264 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2265 instead of 32-bit longs.  After setting these values your DB files have a
2266 theoretical maximum size of 16 XB (exabytes).
2267
2268 B<Note:> Changing these values will B<NOT> work for existing database files.
2269 Only change this for new files, and make sure it stays set consistently
2270 throughout the file's life.  If you do set these values, you can no longer
2271 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2272 back to 32-bit mode.
2273
2274 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2275 only a 32-bit Perl.  However, I have received user reports that this does
2276 indeed work!
2277
2278 =head1 LOW-LEVEL ACCESS
2279
2280 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2281 you can call the C<_fh()> method, which returns the handle:
2282
2283         my $fh = $db->_fh();
2284
2285 This method can be called on the root level of the datbase, or any child
2286 hashes or arrays.  All levels share a I<root> structure, which contains things
2287 like the filehandle, a reference counter, and all the options specified
2288 when you created the object.  You can get access to this root structure by
2289 calling the C<root()> method.
2290
2291         my $root = $db->_root();
2292
2293 This is useful for changing options after the object has already been created,
2294 such as enabling/disabling locking, or debug modes.  You can also
2295 store your own temporary user data in this structure (be wary of name
2296 collision), which is then accessible from any child hash or array.
2297
2298 =head1 CUSTOM DIGEST ALGORITHM
2299
2300 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2301 keys.  However you can override this, and use another algorithm (such as SHA-256)
2302 or even write your own.  But please note that DBM::Deep currently expects zero
2303 collisions, so your algorithm has to be I<perfect>, so to speak.
2304 Collision detection may be introduced in a later version.
2305
2306
2307
2308 You can specify a custom digest algorithm by calling the static C<set_digest()>
2309 function, passing a reference to a subroutine, and the length of the algorithm's
2310 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2311 objects.  Here is a working example that uses a 256-bit hash from the
2312 I<Digest::SHA256> module.  Please see
2313 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2314
2315         use DBM::Deep;
2316         use Digest::SHA256;
2317
2318         my $context = Digest::SHA256::new(256);
2319
2320         DBM::Deep::set_digest( \&my_digest, 32 );
2321
2322         my $db = DBM::Deep->new( "foo-sha.db" );
2323
2324         $db->{key1} = "value1";
2325         $db->{key2} = "value2";
2326         print "key1: " . $db->{key1} . "\n";
2327         print "key2: " . $db->{key2} . "\n";
2328
2329         undef $db;
2330         exit;
2331
2332         sub my_digest {
2333                 return substr( $context->hash($_[0]), 0, 32 );
2334         }
2335
2336 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2337 of bytes you specify in the C<set_digest()> function (in this case 32).
2338
2339 =head1 CIRCULAR REFERENCES
2340
2341 DBM::Deep has B<experimental> support for circular references.  Meaning you
2342 can have a nested hash key or array element that points to a parent object.
2343 This relationship is stored in the DB file, and is preserved between sessions.
2344 Here is an example:
2345
2346         my $db = DBM::Deep->new( "foo.db" );
2347
2348         $db->{foo} = "bar";
2349         $db->{circle} = $db; # ref to self
2350
2351         print $db->{foo} . "\n"; # prints "foo"
2352         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2353
2354 One catch is, passing the object to a function that recursively walks the
2355 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2356 C<export()> methods) will result in an infinite loop.  The other catch is,
2357 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2358 or C<next_key()> methods), you will get the I<target object's key>, not the
2359 ref's key.  This gets even more interesting with the above example, where
2360 the I<circle> key points to the base DB object, which technically doesn't
2361 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2362 special case.
2363
2364 =head1 CAVEATS / ISSUES / BUGS
2365
2366 This section describes all the known issues with DBM::Deep.  It you have found
2367 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2368
2369 =head2 UNUSED SPACE RECOVERY
2370
2371 One major caveat with DBM::Deep is that space occupied by existing keys and
2372 values is not recovered when they are deleted.  Meaning if you keep deleting
2373 and adding new keys, your file will continuously grow.  I am working on this,
2374 but in the meantime you can call the built-in C<optimize()> method from time to
2375 time (perhaps in a crontab or something) to recover all your unused space.
2376
2377         $db->optimize(); # returns true on success
2378
2379 This rebuilds the ENTIRE database into a new file, then moves it on top of
2380 the original.  The new file will have no unused space, thus it will take up as
2381 little disk space as possible.  Please note that this operation can take
2382 a long time for large files, and you need enough disk space to temporarily hold
2383 2 copies of your DB file.  The temporary file is created in the same directory
2384 as the original, named with a ".tmp" extension, and is deleted when the
2385 operation completes.  Oh, and if locking is enabled, the DB is automatically
2386 locked for the entire duration of the copy.
2387
2388 B<WARNING:> Only call optimize() on the top-level node of the database, and
2389 make sure there are no child references lying around.  DBM::Deep keeps a reference
2390 counter, and if it is greater than 1, optimize() will abort and return undef.
2391
2392 =head2 AUTOVIVIFICATION
2393
2394 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2395 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2396 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2397 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2398 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2399 this does not work:
2400
2401         $db->{foo}->{bar} = "hello";
2402
2403 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2404 being an empty hash.  Try this instead, which works fine:
2405
2406         $db->{foo} = { bar => "hello" };
2407
2408 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2409 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2410 Probably a bug in Perl.
2411
2412 =head2 FILE CORRUPTION
2413
2414 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2415 for a 32-bit signature when opened, but other corruption in files can cause
2416 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2417 stuck in an infinite loop depending on the level of corruption.  File write
2418 operations are not checked for failure (for speed), so if you happen to run
2419 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2420 be addressed in a later version of DBM::Deep.
2421
2422 =head2 DB OVER NFS
2423
2424 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2425 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2426 about setting up your NFS server with a locking daemon, then using lockf() to
2427 lock your files, but your mileage may vary there as well.  From what I
2428 understand, there is no real way to do it.  However, if you need access to the
2429 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2430 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2431
2432 =head2 COPYING OBJECTS
2433
2434 Beware of copying tied objects in Perl.  Very strange things can happen.
2435 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2436 returns a new, blessed, tied hash or array to the same level in the DB.
2437
2438         my $copy = $db->clone();
2439
2440 B<Note>: Since clone() here is cloning the object, not the database location, any
2441 modifications to either $db or $copy will be visible in both.
2442
2443 =head2 LARGE ARRAYS
2444
2445 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2446 These functions cause every element in the array to move, which can be murder
2447 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2448 a different location.  This will be addressed in the forthcoming version 1.00.
2449
2450 =head2 WRITEONLY FILES
2451
2452 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2453 writeonly mode. STORE will verify that the filehandle is writable. However, there
2454 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2455 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2456
2457 =head1 PERFORMANCE
2458
2459 This section discusses DBM::Deep's speed and memory usage.
2460
2461 =head2 SPEED
2462
2463 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2464 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2465 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2466 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2467 with huge databases.  Here is some test data:
2468
2469         Adding 1,000,000 keys to new DB file...
2470
2471         At 100 keys, avg. speed is 2,703 keys/sec
2472         At 200 keys, avg. speed is 2,642 keys/sec
2473         At 300 keys, avg. speed is 2,598 keys/sec
2474         At 400 keys, avg. speed is 2,578 keys/sec
2475         At 500 keys, avg. speed is 2,722 keys/sec
2476         At 600 keys, avg. speed is 2,628 keys/sec
2477         At 700 keys, avg. speed is 2,700 keys/sec
2478         At 800 keys, avg. speed is 2,607 keys/sec
2479         At 900 keys, avg. speed is 2,190 keys/sec
2480         At 1,000 keys, avg. speed is 2,570 keys/sec
2481         At 2,000 keys, avg. speed is 2,417 keys/sec
2482         At 3,000 keys, avg. speed is 1,982 keys/sec
2483         At 4,000 keys, avg. speed is 1,568 keys/sec
2484         At 5,000 keys, avg. speed is 1,533 keys/sec
2485         At 6,000 keys, avg. speed is 1,787 keys/sec
2486         At 7,000 keys, avg. speed is 1,977 keys/sec
2487         At 8,000 keys, avg. speed is 2,028 keys/sec
2488         At 9,000 keys, avg. speed is 2,077 keys/sec
2489         At 10,000 keys, avg. speed is 2,031 keys/sec
2490         At 20,000 keys, avg. speed is 1,970 keys/sec
2491         At 30,000 keys, avg. speed is 2,050 keys/sec
2492         At 40,000 keys, avg. speed is 2,073 keys/sec
2493         At 50,000 keys, avg. speed is 1,973 keys/sec
2494         At 60,000 keys, avg. speed is 1,914 keys/sec
2495         At 70,000 keys, avg. speed is 2,091 keys/sec
2496         At 80,000 keys, avg. speed is 2,103 keys/sec
2497         At 90,000 keys, avg. speed is 1,886 keys/sec
2498         At 100,000 keys, avg. speed is 1,970 keys/sec
2499         At 200,000 keys, avg. speed is 2,053 keys/sec
2500         At 300,000 keys, avg. speed is 1,697 keys/sec
2501         At 400,000 keys, avg. speed is 1,838 keys/sec
2502         At 500,000 keys, avg. speed is 1,941 keys/sec
2503         At 600,000 keys, avg. speed is 1,930 keys/sec
2504         At 700,000 keys, avg. speed is 1,735 keys/sec
2505         At 800,000 keys, avg. speed is 1,795 keys/sec
2506         At 900,000 keys, avg. speed is 1,221 keys/sec
2507         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2508
2509 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2510 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2511 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2512 Run time was 12 min 3 sec.
2513
2514 =head2 MEMORY USAGE
2515
2516 One of the great things about DBM::Deep is that it uses very little memory.
2517 Even with huge databases (1,000,000+ keys) you will not see much increased
2518 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2519 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2520 database handle:
2521
2522           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2523         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2524
2525 Basically the process is taking 2,716K of memory.  And here is the same
2526 process after storing and fetching 1,000,000 keys:
2527
2528           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2529         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2530
2531 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2532 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2533
2534 =head1 DB FILE FORMAT
2535
2536 In case you were interested in the underlying DB file format, it is documented
2537 here in this section.  You don't need to know this to use the module, it's just
2538 included for reference.
2539
2540 =head2 SIGNATURE
2541
2542 DBM::Deep files always start with a 32-bit signature to identify the file type.
2543 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2544 checked for when the file is opened and an error will be thrown if it's not found.
2545
2546 =head2 TAG
2547
2548 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2549 has a standard header containing the type of data, the length of data, and then
2550 the data itself.  The type is a single character (1 byte), the length is a
2551 32-bit unsigned long in network byte order, and the data is, well, the data.
2552 Here is how it unfolds:
2553
2554 =head2 MASTER INDEX
2555
2556 Immediately after the 32-bit file signature is the I<Master Index> record.
2557 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2558 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2559 depending on how the DBM::Deep object was constructed.
2560
2561 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2562 number).  The first 8-bit char of the MD5 signature is the offset into the
2563 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2564 index element is a file offset of the next tag for the key/element in question,
2565 which is usually a I<Bucket List> tag (see below).
2566
2567 The next tag I<could> be another index, depending on how many keys/elements
2568 exist.  See L<RE-INDEXING> below for details.
2569
2570 =head2 BUCKET LIST
2571
2572 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2573 file offsets to where the actual data is stored.  It starts with a standard
2574 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2575 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2576 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2577 When the list fills up, a I<Re-Index> operation is performed (See
2578 L<RE-INDEXING> below).
2579
2580 =head2 BUCKET
2581
2582 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2583 index/value pair (in array mode).  It starts with a standard tag header with
2584 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2585 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2586 header.  The size reported in the tag header is only for the value, but then,
2587 just after the value is another size (32-bit unsigned long) and then the plain
2588 key itself.  Since the value is likely to be fetched more often than the plain
2589 key, I figured it would be I<slightly> faster to store the value first.
2590
2591 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2592 record for the nested structure, where the process begins all over again.
2593
2594 =head2 RE-INDEXING
2595
2596 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2597 exhausted.  Then, when another key/element comes in, the list is converted to a
2598 new index record.  However, this index will look at the next char in the MD5
2599 hash, and arrange new Bucket List pointers accordingly.  This process is called
2600 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2601 17 (16 + new one) keys/elements are removed from the old Bucket List and
2602 inserted into the new index.  Several new Bucket Lists are created in the
2603 process, as a new MD5 char from the key is being examined (it is unlikely that
2604 the keys will all share the same next char of their MD5s).
2605
2606 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2607 when the Bucket Lists will turn into indexes, but the first round tends to
2608 happen right around 4,000 keys.  You will see a I<slight> decrease in
2609 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2610 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2611 right around 900,000 keys.  This process can continue nearly indefinitely --
2612 right up until the point the I<MD5> signatures start colliding with each other,
2613 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2614 getting struck by lightning while you are walking to cash in your tickets.
2615 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2616 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2617 this is 340 unodecillion, but don't quote me).
2618
2619 =head2 STORING
2620
2621 When a new key/element is stored, the key (or index number) is first run through
2622 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2623 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2624 for the first char of the signature (in this case I<b0>).  If it does not exist,
2625 a new I<Bucket List> is created for our key (and the next 15 future keys that
2626 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2627 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2628 this point, unless we are replacing an existing I<Bucket>), where the actual
2629 data will be stored.
2630
2631 =head2 FETCHING
2632
2633 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2634 (or index number), then walking along the indexes.  If there are enough
2635 keys/elements in this DB level, there might be nested indexes, each linked to
2636 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2637 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2638 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2639 plain key are stored.
2640
2641 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2642 methods.  In this process the indexes are walked systematically, and each key
2643 fetched in increasing MD5 order (which is why it appears random).   Once the
2644 I<Bucket> is found, the value is skipped and the plain key returned instead.
2645 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2646 alphabetically sorted.  This only happens on an index-level -- as soon as the
2647 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2648 so it's pretty much undefined how the keys will come out -- just like Perl's
2649 built-in hashes.
2650
2651 =head1 CODE COVERAGE
2652
2653 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2654 B<Devel::Cover> report on this module's test suite.
2655
2656   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2657   File                           stmt   bran   cond    sub    pod   time  total
2658   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2659   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2660   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2661   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2662   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2663   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2664
2665 =head1 MORE INFORMATION
2666
2667 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2668 or send email to L<DBM-Deep@googlegroups.com>.
2669
2670 =head1 AUTHORS
2671
2672 Joseph Huckaby, L<jhuckaby@cpan.org>
2673
2674 Rob Kinyon, L<rkinyon@cpan.org>
2675
2676 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2677
2678 =head1 SEE ALSO
2679
2680 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2681 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2682
2683 =head1 LICENSE
2684
2685 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2686 This is free software, you may use it and distribute it under the
2687 same terms as Perl itself.
2688
2689 =cut