lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use FileHandle;
  35 use Fcntl qw/:flock/;
  36 use Digest::MD5 ();
  37 use Scalar::Util ();
  38 use vars qw/$VERSION/;
  39
  40 $VERSION = "0.96";
  41
  42 ##
  43 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  44 #       (Perl must be compiled with largefile support for files > 2 GB)
  45 #
  46 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47 #       (Perl must be compiled with largefile and 64-bit long support)
  48 ##
  49 #my $LONG_SIZE = 4;
  50 #my $LONG_PACK = 'N';
  51
  52 ##
  53 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  54 # Upgrading this is possible (see above) but probably not necessary.  If you need
  55 # more than 4 GB for a single key or value, this module is really not for you :-)
  56 ##
  57 #my $DATA_LENGTH_SIZE = 4;
  58 #my $DATA_LENGTH_PACK = 'N';
  59 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  60
  61 ##
  62 # Maximum number of buckets per list before another level of indexing is done.
  63 # Increase this value for slightly greater speed, but larger database files.
  64 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  65 ##
  66 my $MAX_BUCKETS = 16;
  67
  68 ##
  69 # Better not adjust anything below here, unless you're me :-)
  70 ##
  71
  72 ##
  73 # Setup digest function for keys
  74 ##
  75 my ($DIGEST_FUNC, $HASH_SIZE);
  76 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  77
  78 ##
  79 # Precalculate index and bucket sizes based on values above.
  80 ##
  81 #my $HASH_SIZE = 16;
  82 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  83
  84 set_digest();
  85 #set_pack();
  86 #precalc_sizes();
  87
  88 ##
  89 # Setup file and tag signatures.  These should never change.
  90 ##
  91 sub SIG_FILE  () { 'DPDB' }
  92 sub SIG_HASH  () { 'H' }
  93 sub SIG_ARRAY () { 'A' }
  94 sub SIG_NULL  () { 'N' }
  95 sub SIG_DATA  () { 'D' }
  96 sub SIG_INDEX () { 'I' }
  97 sub SIG_BLIST () { 'B' }
  98 sub SIG_SIZE  () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH  () { return SIG_HASH; }
 104 sub TYPE_ARRAY () { return SIG_ARRAY; }
 105
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116     #print "Calling new()\n";
 117
 118         ##
 119         # Check if we want a tied hash or array.
 120         ##
 121         my $self;
 122         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 123                 my $foo = tie @$self, $class, %$args;
 124         #print "Tied '$foo' to array\n";
 125 #        return $foo;
 126         }
 127         else {
 128                 my $foo = tie %$self, $class, %$args;
 129         #print "Tied '$foo' to hash\n";
 130 #        return $foo;
 131         }
 132
 133         bless $self, $class;
 134     #print "Created '$self'\n";
 135     return $self;
 136 }
 137
 138 {
 139     my @outer_params = qw( type base_offset );
 140     sub _init {
 141         ##
 142         # Setup $self and bless into this class.
 143         ##
 144         my $class = shift;
 145         my $args = shift;
 146
 147         my $self = {
 148             type => TYPE_HASH,
 149             base_offset => length(SIG_FILE),
 150             root => {
 151                 file => undef,
 152                 fh => undef,
 153                 end => 0,
 154                 links => 0,
 155                 autoflush => undef,
 156                 locking => undef,
 157                 volatile => undef,
 158                 debug => undef,
 159                 mode => 'r+',
 160                 filter_store_key => undef,
 161                 filter_store_value => undef,
 162                 filter_fetch_key => undef,
 163                 filter_fetch_value => undef,
 164                 autobless => undef,
 165                 locked => 0,
 166                 %$args,
 167             },
 168         };
 169
 170         bless $self, $class;
 171
 172         foreach my $outer_parm ( @outer_params ) {
 173             next unless exists $args->{$outer_parm};
 174             $self->{$outer_parm} = $args->{$outer_parm}
 175         }
 176
 177         if ( exists $args->{root} ) {
 178             $self->{root} = $args->{root};
 179         }
 180         else {
 181             # This is cleanup based on the fact that the $args
 182             # coming in is for both the root and non-root items
 183             delete $self->root->{$_} for @outer_params;
 184         }
 185         $self->root->{links}++;
 186
 187         if (!defined($self->fh)) { $self->_open(); }
 188
 189         return $self;
 190     }
 191 }
 192
 193 sub _get_self {
 194     tied( %{$_[0]} ) || $_[0]
 195 }
 196
 197 sub TIEHASH {
 198     ##
 199     # Tied hash constructor method, called by Perl's tie() function.
 200     ##
 201     my $class = shift;
 202     my $args;
 203     if (scalar(@_) > 1) { $args = {@_}; }
 204     #XXX This use of ref() is bad and is a bug
 205     elsif (ref($_[0])) { $args = $_[0]; }
 206     else { $args = { file => shift }; }
 207
 208     $args->{type} = TYPE_HASH;
 209
 210     return $class->_init($args);
 211 }
 212
 213 sub TIEARRAY {
 214 ##
 215 # Tied array constructor method, called by Perl's tie() function.
 216 ##
 217     my $class = shift;
 218     my $args;
 219     if (scalar(@_) > 1) { $args = {@_}; }
 220     #XXX This use of ref() is bad and is a bug
 221         elsif (ref($_[0])) { $args = $_[0]; }
 222         else { $args = { file => shift }; }
 223
 224         $args->{type} = TYPE_ARRAY;
 225
 226         return $class->_init($args);
 227 }
 228
 229 sub DESTROY {
 230         ##
 231         # Class deconstructor.  Close file handle if there are no more refs.
 232         ##
 233     my $self = _get_self($_[0]);
 234     return unless $self;
 235
 236         $self->root->{links}--;
 237     #print "DESTROY( $self ): ", $self->root, ':', $self->root->{links}, "\n";
 238
 239         if (!$self->root->{links}) {
 240                 $self->_close();
 241         }
 242 }
 243
 244 my %translate_mode = (
 245     'r' => '<',
 246     'r+' => '+<',
 247     'w' => '>',
 248     'w+' => '+>',
 249     'a' => '>>',
 250     'a+' => '+>>',
 251 );
 252 sub _open {
 253         ##
 254         # Open a FileHandle to the database, create if nonexistent.
 255         # Make sure file signature matches DeepDB spec.
 256         ##
 257     my $self = _get_self($_[0]);
 258
 259         if (defined($self->fh)) { $self->_close(); }
 260
 261     eval {
 262         my $filename = $self->root->{file};
 263         my $mode = $translate_mode{ $self->root->{mode} };
 264         #print "Opening '$filename' as '$mode'\n";
 265
 266         #if (!(-e $filename) && $self->root->{mode} eq 'r+') {
 267         if (!(-e $filename) && $mode eq '+<') {
 268             #FileHandle->new( $filename, 'w' );
 269             open( FH, '>', $filename );
 270             close FH;
 271         }
 272
 273         #XXX Convert to set_fh()
 274         $self->root->{fh} = FileHandle->new( $self->root->{file}, $self->root->{mode} );
 275 #        my $fh;
 276 #        open( $fh, $mode, $filename )
 277 #            or $fh = undef;
 278 #        $self->root->{fh} = $fh;
 279     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 280         if (! defined($self->fh)) {
 281                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 282         }
 283
 284     my $fh = $self->fh;
 285
 286     #XXX Can we remove this by using the right sysopen() flags?
 287     binmode $fh; # for win32
 288
 289     if ($self->root->{autoflush}) {
 290 #        $self->fh->autoflush();
 291         my $old = select $fh;
 292         $|=1;
 293         select $old;
 294     }
 295
 296     my $signature;
 297     seek($fh, 0, 0);
 298     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 299
 300     ##
 301     # File is empty -- write signature and master index
 302     ##
 303     if (!$bytes_read) {
 304         seek($fh, 0, 0);
 305         print($fh SIG_FILE);
 306         $self->root->{end} = length(SIG_FILE);
 307         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 308
 309         my $plain_key = "[base]";
 310         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 311         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 312
 313 #        $fh->flush();
 314         my $old_fh = select $fh;
 315         my $old_af = $|;
 316         $| = 1;
 317         $| = $old_af;
 318         select $old_fh;
 319
 320         return 1;
 321     }
 322
 323     ##
 324     # Check signature was valid
 325     ##
 326     unless ($signature eq SIG_FILE) {
 327         $self->_close();
 328         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 329     }
 330
 331     $self->root->{end} = (stat($fh))[7];
 332
 333     ##
 334     # Get our type from master index signature
 335     ##
 336     my $tag = $self->_load_tag($self->base_offset);
 337 #XXX We probably also want to store the hash algorithm name and not assume anything
 338     if (!$tag) {
 339         return $self->_throw_error("Corrupted file, no master index record");
 340     }
 341     if ($self->{type} ne $tag->{signature}) {
 342         return $self->_throw_error("File type mismatch");
 343     }
 344
 345     return 1;
 346 }
 347
 348 sub _close {
 349         ##
 350         # Close database FileHandle
 351         ##
 352     #print "_close()\n";
 353     my $self = _get_self($_[0]);
 354         undef $self->root->{fh};
 355 }
 356
 357 sub _create_tag {
 358         ##
 359         # Given offset, signature and content, create tag and write to disk
 360         ##
 361         my ($self, $offset, $sig, $content) = @_;
 362         my $size = length($content);
 363
 364     my $fh = $self->fh;
 365
 366         seek($fh, $offset, 0);
 367         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 368
 369         if ($offset == $self->root->{end}) {
 370                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 371         }
 372
 373         return {
 374                 signature => $sig,
 375                 size => $size,
 376                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 377                 content => $content
 378         };
 379 }
 380
 381 sub _load_tag {
 382         ##
 383         # Given offset, load single tag and return signature, size and data
 384         ##
 385         my $self = shift;
 386         my $offset = shift;
 387
 388     my $fh = $self->fh;
 389
 390         seek($fh, $offset, 0);
 391         if (eof $fh) { return undef; }
 392
 393         my $sig;
 394         read( $fh, $sig, SIG_SIZE);
 395
 396         my $size;
 397         read( $fh, $size, $DATA_LENGTH_SIZE);
 398         $size = unpack($DATA_LENGTH_PACK, $size);
 399
 400         my $buffer;
 401         read( $fh, $buffer, $size);
 402
 403         return {
 404                 signature => $sig,
 405                 size => $size,
 406                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 407                 content => $buffer
 408         };
 409 }
 410
 411 sub _index_lookup {
 412         ##
 413         # Given index tag, lookup single entry in index and return .
 414         ##
 415         my $self = shift;
 416         my ($tag, $index) = @_;
 417
 418         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 419         if (!$location) { return; }
 420
 421         return $self->_load_tag( $location );
 422 }
 423
 424 sub _add_bucket {
 425         ##
 426         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 427         # plain (undigested) key and value.
 428         ##
 429         my $self = shift;
 430         my ($tag, $md5, $plain_key, $value) = @_;
 431         my $keys = $tag->{content};
 432         my $location = 0;
 433         my $result = 2;
 434
 435     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 436         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 437
 438     #print "_add: 1\n";
 439     my $fh = $self->fh;
 440
 441         ##
 442         # Iterate through buckets, seeing if this is a new entry or a replace.
 443         ##
 444         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 445                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 446                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 447                 if (!$subloc) {
 448                         ##
 449                         # Found empty bucket (end of list).  Populate and exit loop.
 450                         ##
 451                         $result = 2;
 452
 453             $location = $internal_ref
 454                 ? $value->base_offset
 455                 : $self->root->{end};
 456
 457                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 458                         print($fh $md5 . pack($LONG_PACK, $location) );
 459                         last;
 460                 }
 461                 elsif ($md5 eq $key) {
 462                         ##
 463                         # Found existing bucket with same key.  Replace with new value.
 464                         ##
 465                         $result = 1;
 466
 467                         if ($internal_ref) {
 468                                 $location = $value->base_offset;
 469                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 470                                 print($fh $md5 . pack($LONG_PACK, $location) );
 471                         }
 472                         else {
 473                                 seek($fh, $subloc + SIG_SIZE, 0);
 474                                 my $size;
 475                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 476
 477                                 ##
 478                                 # If value is a hash, array, or raw value with equal or less size, we can
 479                                 # reuse the same content area of the database.  Otherwise, we have to create
 480                                 # a new content area at the EOF.
 481                                 ##
 482                                 my $actual_length;
 483                 my $r = Scalar::Util::reftype( $value ) || '';
 484                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 485                                 else { $actual_length = length($value); }
 486
 487                                 if ($actual_length <= $size) {
 488                                         $location = $subloc;
 489                                 }
 490                                 else {
 491                                         $location = $self->root->{end};
 492                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 493                                         print($fh pack($LONG_PACK, $location) );
 494                                 }
 495                         }
 496                         last;
 497                 }
 498         } # i loop
 499
 500         ##
 501         # If this is an internal reference, return now.
 502         # No need to write value or plain key
 503         ##
 504         if ($internal_ref) {
 505         return $result;
 506     }
 507
 508         ##
 509         # If bucket didn't fit into list, split into a new index level
 510         ##
 511         if (!$location) {
 512                 seek($fh, $tag->{ref_loc}, 0);
 513                 print($fh pack($LONG_PACK, $self->root->{end}) );
 514
 515                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 516                 my @offsets = ();
 517
 518                 $keys .= $md5 . pack($LONG_PACK, 0);
 519
 520                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 521                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 522                         if ($key) {
 523                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 524                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 525
 526                                 if ($offsets[$num]) {
 527                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 528                                         seek($fh, $offset, 0);
 529                                         my $subkeys;
 530                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 531
 532                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 533                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 534                                                 if (!$subloc) {
 535                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), 0);
 536                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 537                                                         last;
 538                                                 }
 539                                         } # k loop
 540                                 }
 541                                 else {
 542                                         $offsets[$num] = $self->root->{end};
 543                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 544                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 545
 546                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 547
 548                                         seek($fh, $blist_tag->{offset}, 0);
 549                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 550                                 }
 551                         } # key is real
 552                 } # i loop
 553
 554                 $location ||= $self->root->{end};
 555         } # re-index bucket list
 556
 557         ##
 558         # Seek to content area and store signature, value and plaintext key
 559         ##
 560         if ($location) {
 561                 my $content_length;
 562                 seek($fh, $location, 0);
 563
 564                 ##
 565                 # Write signature based on content type, set content length and write actual value.
 566                 ##
 567         my $r = Scalar::Util::reftype($value) || '';
 568                 if ($r eq 'HASH') {
 569                         print($fh TYPE_HASH );
 570                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 571                         $content_length = $INDEX_SIZE;
 572                 }
 573                 elsif ($r eq 'ARRAY') {
 574                         print($fh TYPE_ARRAY );
 575                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 576                         $content_length = $INDEX_SIZE;
 577                 }
 578                 elsif (!defined($value)) {
 579                         print($fh SIG_NULL );
 580                         print($fh pack($DATA_LENGTH_PACK, 0) );
 581                         $content_length = 0;
 582                 }
 583                 else {
 584                         print($fh SIG_DATA );
 585                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 586                         $content_length = length($value);
 587                 }
 588
 589                 ##
 590                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 591                 ##
 592                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 593
 594                 ##
 595                 # If value is blessed, preserve class name
 596                 ##
 597                 if ( $self->root->{autobless} ) {
 598             my $value_class = Scalar::Util::blessed($value);
 599             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 600                 ##
 601                 # Blessed ref -- will restore later
 602                 ##
 603                 print($fh chr(1) );
 604                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 605                 $content_length += 1;
 606                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 607             }
 608             else {
 609                 print($fh chr(0) );
 610                 $content_length += 1;
 611             }
 612         }
 613
 614                 ##
 615                 # If this is a new content area, advance EOF counter
 616                 ##
 617                 if ($location == $self->root->{end}) {
 618                         $self->root->{end} += SIG_SIZE;
 619                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 620                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 621                 }
 622
 623                 ##
 624                 # If content is a hash or array, create new child DeepDB object and
 625                 # pass each key or element to it.
 626                 ##
 627         #print "_add: 2\n";
 628                 if ($r eq 'HASH') {
 629                         my $branch = DBM::Deep->new(
 630                                 type => TYPE_HASH,
 631                                 base_offset => $location,
 632                                 root => $self->root,
 633                         );
 634                         foreach my $key (keys %{$value}) {
 635                 #$branch->{$key} = $value->{$key};
 636                 $branch->STORE( $key, $value->{$key} );
 637                         }
 638                 }
 639                 elsif ($r eq 'ARRAY') {
 640             #print "$self -> ", $self->root, $/;
 641                         my $branch = DBM::Deep->new(
 642                                 type => TYPE_ARRAY,
 643                                 base_offset => $location,
 644                                 root => $self->root,
 645                         );
 646             #print "After new - $branch -> ", $branch->root, "\n";
 647                         my $index = 0;
 648                         foreach my $element (@{$value}) {
 649                 #$branch->[$index] = $element;
 650                 $branch->STORE( $index, $element );
 651                                 $index++;
 652                         }
 653             #print "After elements\n";
 654                 }
 655         #print "_add: 3\n";
 656
 657                 return $result;
 658         }
 659
 660         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 661 }
 662
 663 sub _get_bucket_value {
 664         ##
 665         # Fetch single value given tag and MD5 digested key.
 666         ##
 667         my $self = shift;
 668         my ($tag, $md5) = @_;
 669         my $keys = $tag->{content};
 670
 671     my $fh = $self->fh;
 672
 673         ##
 674         # Iterate through buckets, looking for a key match
 675         ##
 676     BUCKET:
 677         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 678                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 679                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 680
 681                 if (!$subloc) {
 682                         ##
 683                         # Hit end of list, no match
 684                         ##
 685                         return;
 686                 }
 687
 688         if ( $md5 ne $key ) {
 689             next BUCKET;
 690         }
 691
 692         ##
 693         # Found match -- seek to offset and read signature
 694         ##
 695         my $signature;
 696         seek($fh, $subloc, 0);
 697         read( $fh, $signature, SIG_SIZE);
 698
 699         ##
 700         # If value is a hash or array, return new DeepDB object with correct offset
 701         ##
 702         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 703             my $obj = DBM::Deep->new(
 704                 type => $signature,
 705                 base_offset => $subloc,
 706                 root => $self->root
 707             );
 708
 709             if ($self->root->{autobless}) {
 710                 ##
 711                 # Skip over value and plain key to see if object needs
 712                 # to be re-blessed
 713                 ##
 714                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 715
 716                 my $size;
 717                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 718                 if ($size) { seek($fh, $size, 1); }
 719
 720                 my $bless_bit;
 721                 read( $fh, $bless_bit, 1);
 722                 if (ord($bless_bit)) {
 723                     ##
 724                     # Yes, object needs to be re-blessed
 725                     ##
 726                     my $class_name;
 727                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 728                     if ($size) { read( $fh, $class_name, $size); }
 729                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 730                 }
 731             }
 732
 733             return $obj;
 734         }
 735
 736         ##
 737         # Otherwise return actual value
 738         ##
 739         elsif ($signature eq SIG_DATA) {
 740             my $size;
 741             my $value = '';
 742             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 743             if ($size) { read( $fh, $value, $size); }
 744             return $value;
 745         }
 746
 747         ##
 748         # Key exists, but content is null
 749         ##
 750         else { return; }
 751         } # i loop
 752
 753         return;
 754 }
 755
 756 sub _delete_bucket {
 757         ##
 758         # Delete single key/value pair given tag and MD5 digested key.
 759         ##
 760         my $self = shift;
 761         my ($tag, $md5) = @_;
 762         my $keys = $tag->{content};
 763
 764     my $fh = $self->fh;
 765
 766         ##
 767         # Iterate through buckets, looking for a key match
 768         ##
 769     BUCKET:
 770         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 771                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 772                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 773
 774                 if (!$subloc) {
 775                         ##
 776                         # Hit end of list, no match
 777                         ##
 778                         return;
 779                 }
 780
 781         if ( $md5 ne $key ) {
 782             next BUCKET;
 783         }
 784
 785         ##
 786         # Matched key -- delete bucket and return
 787         ##
 788         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 789         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 790         print($fh chr(0) x $BUCKET_SIZE );
 791
 792         return 1;
 793         } # i loop
 794
 795         return;
 796 }
 797
 798 sub _bucket_exists {
 799         ##
 800         # Check existence of single key given tag and MD5 digested key.
 801         ##
 802         my $self = shift;
 803         my ($tag, $md5) = @_;
 804         my $keys = $tag->{content};
 805
 806         ##
 807         # Iterate through buckets, looking for a key match
 808         ##
 809     BUCKET:
 810         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 811                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 812                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 813
 814                 if (!$subloc) {
 815                         ##
 816                         # Hit end of list, no match
 817                         ##
 818                         return;
 819                 }
 820
 821         if ( $md5 ne $key ) {
 822             next BUCKET;
 823         }
 824
 825         ##
 826         # Matched key -- return true
 827         ##
 828         return 1;
 829         } # i loop
 830
 831         return;
 832 }
 833
 834 sub _find_bucket_list {
 835         ##
 836         # Locate offset for bucket list, given digested key
 837         ##
 838         my $self = shift;
 839         my $md5 = shift;
 840
 841         ##
 842         # Locate offset for bucket list using digest index system
 843         ##
 844         my $ch = 0;
 845         my $tag = $self->_load_tag($self->base_offset);
 846         if (!$tag) { return; }
 847
 848         while ($tag->{signature} ne SIG_BLIST) {
 849                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 850                 if (!$tag) { return; }
 851                 $ch++;
 852         }
 853
 854         return $tag;
 855 }
 856
 857 sub _traverse_index {
 858         ##
 859         # Scan index and recursively step into deeper levels, looking for next key.
 860         ##
 861     my ($self, $offset, $ch, $force_return_next) = @_;
 862     $force_return_next = undef unless $force_return_next;
 863
 864         my $tag = $self->_load_tag( $offset );
 865
 866     my $fh = $self->fh;
 867
 868         if ($tag->{signature} ne SIG_BLIST) {
 869                 my $content = $tag->{content};
 870                 my $start;
 871                 if ($self->{return_next}) { $start = 0; }
 872                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 873
 874                 for (my $index = $start; $index < 256; $index++) {
 875                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 876                         if ($subloc) {
 877                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 878                                 if (defined($result)) { return $result; }
 879                         }
 880                 } # index loop
 881
 882                 $self->{return_next} = 1;
 883         } # tag is an index
 884
 885         elsif ($tag->{signature} eq SIG_BLIST) {
 886                 my $keys = $tag->{content};
 887                 if ($force_return_next) { $self->{return_next} = 1; }
 888
 889                 ##
 890                 # Iterate through buckets, looking for a key match
 891                 ##
 892                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 893                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 894                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 895
 896                         if (!$subloc) {
 897                                 ##
 898                                 # End of bucket list -- return to outer loop
 899                                 ##
 900                                 $self->{return_next} = 1;
 901                                 last;
 902                         }
 903                         elsif ($key eq $self->{prev_md5}) {
 904                                 ##
 905                                 # Located previous key -- return next one found
 906                                 ##
 907                                 $self->{return_next} = 1;
 908                                 next;
 909                         }
 910                         elsif ($self->{return_next}) {
 911                                 ##
 912                                 # Seek to bucket location and skip over signature
 913                                 ##
 914                                 seek($fh, $subloc + SIG_SIZE, 0);
 915
 916                                 ##
 917                                 # Skip over value to get to plain key
 918                                 ##
 919                                 my $size;
 920                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 921                                 if ($size) { seek($fh, $size, 1); }
 922
 923                                 ##
 924                                 # Read in plain key and return as scalar
 925                                 ##
 926                                 my $plain_key;
 927                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 928                                 if ($size) { read( $fh, $plain_key, $size); }
 929
 930                                 return $plain_key;
 931                         }
 932                 } # bucket loop
 933
 934                 $self->{return_next} = 1;
 935         } # tag is a bucket list
 936
 937         return;
 938 }
 939
 940 sub _get_next_key {
 941         ##
 942         # Locate next key, given digested previous one
 943         ##
 944     my $self = _get_self($_[0]);
 945
 946         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 947         $self->{return_next} = 0;
 948
 949         ##
 950         # If the previous key was not specifed, start at the top and
 951         # return the first one found.
 952         ##
 953         if (!$self->{prev_md5}) {
 954                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 955                 $self->{return_next} = 1;
 956         }
 957
 958         return $self->_traverse_index( $self->base_offset, 0 );
 959 }
 960
 961 sub lock {
 962         ##
 963         # If db locking is set, flock() the db file.  If called multiple
 964         # times before unlock(), then the same number of unlocks() must
 965         # be called before the lock is released.
 966         ##
 967     my $self = _get_self($_[0]);
 968         my $type = $_[1];
 969     $type = LOCK_EX unless defined $type;
 970
 971         if ($self->root->{locking}) {
 972                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 973                 $self->root->{locked}++;
 974         }
 975 }
 976
 977 sub unlock {
 978         ##
 979         # If db locking is set, unlock the db file.  See note in lock()
 980         # regarding calling lock() multiple times.
 981         ##
 982     my $self = _get_self($_[0]);
 983
 984         if ($self->root->{locking} && $self->root->{locked} > 0) {
 985                 $self->root->{locked}--;
 986                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 987         }
 988 }
 989
 990 #XXX These uses of ref() need verified
 991 sub _copy_node {
 992         ##
 993         # Copy single level of keys or elements to new DB handle.
 994         # Recurse for nested structures
 995         ##
 996     my $self = _get_self($_[0]);
 997         my $db_temp = $_[1];
 998
 999         if ($self->type eq TYPE_HASH) {
1000                 my $key = $self->first_key();
1001                 while ($key) {
1002                         my $value = $self->get($key);
1003 #XXX This doesn't work with autobless
1004                         if (!ref($value)) { $db_temp->{$key} = $value; }
1005                         else {
1006                                 my $type = $value->type;
1007                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
1008                                 else { $db_temp->{$key} = []; }
1009                                 $value->_copy_node( $db_temp->{$key} );
1010                         }
1011                         $key = $self->next_key($key);
1012                 }
1013         }
1014         else {
1015                 my $length = $self->length();
1016                 for (my $index = 0; $index < $length; $index++) {
1017                         my $value = $self->get($index);
1018                         if (!ref($value)) { $db_temp->[$index] = $value; }
1019             #XXX NO tests for this code
1020                         else {
1021                                 my $type = $value->type;
1022                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
1023                                 else { $db_temp->[$index] = []; }
1024                                 $value->_copy_node( $db_temp->[$index] );
1025                         }
1026                 }
1027         }
1028 }
1029
1030 sub export {
1031         ##
1032         # Recursively export into standard Perl hashes and arrays.
1033         ##
1034     my $self = _get_self($_[0]);
1035
1036         my $temp;
1037         if ($self->type eq TYPE_HASH) { $temp = {}; }
1038         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1039
1040         $self->lock();
1041         $self->_copy_node( $temp );
1042         $self->unlock();
1043
1044         return $temp;
1045 }
1046
1047 sub import {
1048         ##
1049         # Recursively import Perl hash/array structure
1050         ##
1051     #XXX This use of ref() seems to be ok
1052         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1053
1054     my $self = _get_self($_[0]);
1055         my $struct = $_[1];
1056
1057     #XXX This use of ref() seems to be ok
1058         if (!ref($struct)) {
1059                 ##
1060                 # struct is not a reference, so just import based on our type
1061                 ##
1062                 shift @_;
1063
1064                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1065                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1066         }
1067
1068     my $r = Scalar::Util::reftype($struct) || '';
1069         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1070                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1071         }
1072         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1073                 $self->push( @$struct );
1074         }
1075         else {
1076                 return $self->_throw_error("Cannot import: type mismatch");
1077         }
1078
1079         return 1;
1080 }
1081
1082 sub optimize {
1083         ##
1084         # Rebuild entire database into new file, then move
1085         # it back on top of original.
1086         ##
1087     my $self = _get_self($_[0]);
1088         if ($self->root->{links} > 1) {
1089                 return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1090         }
1091
1092         my $db_temp = DBM::Deep->new(
1093                 file => $self->root->{file} . '.tmp',
1094                 type => $self->type
1095         );
1096         if (!$db_temp) {
1097                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1098         }
1099
1100         $self->lock();
1101         $self->_copy_node( $db_temp );
1102         undef $db_temp;
1103
1104         ##
1105         # Attempt to copy user, group and permissions over to new file
1106         ##
1107         my @stats = stat($self->fh);
1108         my $perms = $stats[2] & 07777;
1109         my $uid = $stats[4];
1110         my $gid = $stats[5];
1111         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1112         chmod( $perms, $self->root->{file} . '.tmp' );
1113
1114     # q.v. perlport for more information on this variable
1115     if ( $^O eq 'MSWin32' ) {
1116                 ##
1117                 # Potential race condition when optmizing on Win32 with locking.
1118                 # The Windows filesystem requires that the filehandle be closed
1119                 # before it is overwritten with rename().  This could be redone
1120                 # with a soft copy.
1121                 ##
1122                 $self->unlock();
1123                 $self->_close();
1124         }
1125
1126         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1127                 unlink $self->root->{file} . '.tmp';
1128                 $self->unlock();
1129                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1130         }
1131
1132         $self->unlock();
1133         $self->_close();
1134         $self->_open();
1135
1136         return 1;
1137 }
1138
1139 sub clone {
1140         ##
1141         # Make copy of object and return
1142         ##
1143     my $self = _get_self($_[0]);
1144
1145         return DBM::Deep->new(
1146                 type => $self->type,
1147                 base_offset => $self->base_offset,
1148                 root => $self->root
1149         );
1150 }
1151
1152 {
1153     my %is_legal_filter = map {
1154         $_ => ~~1,
1155     } qw(
1156         store_key store_value
1157         fetch_key fetch_value
1158     );
1159
1160     sub set_filter {
1161         ##
1162         # Setup filter function for storing or fetching the key or value
1163         ##
1164         my $self = _get_self($_[0]);
1165         my $type = lc $_[1];
1166         my $func = $_[2] ? $_[2] : undef;
1167
1168         if ( $is_legal_filter{$type} ) {
1169             $self->root->{"filter_$type"} = $func;
1170             return 1;
1171         }
1172
1173         return;
1174     }
1175 }
1176
1177 ##
1178 # Accessor methods
1179 ##
1180
1181 sub root {
1182         ##
1183         # Get access to the root structure
1184         ##
1185     my $self = _get_self($_[0]);
1186         return $self->{root};
1187 }
1188
1189 sub fh {
1190         ##
1191         # Get access to the raw FileHandle
1192         ##
1193     #XXX It will be useful, though, when we split out HASH and ARRAY
1194     my $self = _get_self($_[0]);
1195         return $self->root->{fh};
1196 }
1197
1198 sub type {
1199         ##
1200         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1201         ##
1202     my $self = _get_self($_[0]);
1203         return $self->{type};
1204 }
1205
1206 sub base_offset {
1207         ##
1208         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1209         ##
1210     my $self = _get_self($_[0]);
1211         return $self->{base_offset};
1212 }
1213
1214 sub error {
1215         ##
1216         # Get last error string, or undef if no error
1217         ##
1218         return $_[0]
1219         ? ( _get_self($_[0])->{root}->{error} or undef )
1220         : $@;
1221 }
1222
1223 ##
1224 # Utility methods
1225 ##
1226
1227 sub _throw_error {
1228         ##
1229         # Store error string in self
1230         ##
1231     my $self = _get_self($_[0]);
1232         my $error_text = $_[1];
1233
1234         $self->root->{error} = $error_text;
1235
1236         unless ($self->root->{debug}) {
1237         die "DBM::Deep: $error_text\n";
1238     }
1239
1240     warn "DBM::Deep: $error_text\n";
1241         return;
1242 }
1243
1244 sub clear_error {
1245         ##
1246         # Clear error state
1247         ##
1248     my $self = _get_self($_[0]);
1249
1250         undef $self->root->{error};
1251 }
1252
1253 sub precalc_sizes {
1254         ##
1255         # Precalculate index, bucket and bucket list sizes
1256         ##
1257
1258     #XXX I don't like this ...
1259     set_pack() unless defined $LONG_SIZE;
1260
1261         $INDEX_SIZE = 256 * $LONG_SIZE;
1262         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1263         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1264 }
1265
1266 sub set_pack {
1267         ##
1268         # Set pack/unpack modes (see file header for more)
1269         ##
1270     my ($long_s, $long_p, $data_s, $data_p) = @_;
1271
1272     $LONG_SIZE = $long_s ? $long_s : 4;
1273     $LONG_PACK = $long_p ? $long_p : 'N';
1274
1275     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1276     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1277
1278         precalc_sizes();
1279 }
1280
1281 sub set_digest {
1282         ##
1283         # Set key digest function (default is MD5)
1284         ##
1285     my ($digest_func, $hash_size) = @_;
1286
1287     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1288     $HASH_SIZE = $hash_size ? $hash_size : 16;
1289
1290         precalc_sizes();
1291 }
1292
1293 ##
1294 # tie() methods (hashes and arrays)
1295 ##
1296
1297 sub STORE {
1298         ##
1299         # Store single hash key/value or array element in database.
1300         ##
1301     my $self = _get_self($_[0]);
1302     #print "STORE: $self ... $_[0]\n";
1303         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1304     #XXX What is ref() checking here?
1305     #YYY User may be storing a hash, in which case we do not want it run
1306     #YYY through the filtering system
1307         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1308
1309         my $unpacked_key = $key;
1310         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1311         my $md5 = $DIGEST_FUNC->($key);
1312
1313     #print "1\n";
1314         ##
1315         # Make sure file is open
1316         ##
1317         if (!defined($self->fh) && !$self->_open()) {
1318                 return;
1319         }
1320         ##
1321
1322     my $fh = $self->fh;
1323
1324         ##
1325         # Request exclusive lock for writing
1326         ##
1327         $self->lock( LOCK_EX );
1328
1329         ##
1330         # If locking is enabled, set 'end' parameter again, in case another
1331         # DB instance appended to our file while we were unlocked.
1332         ##
1333         if ($self->root->{locking} || $self->root->{volatile}) {
1334                 $self->root->{end} = (stat($fh))[7];
1335         }
1336
1337         ##
1338         # Locate offset for bucket list using digest index system
1339         ##
1340         my $tag = $self->_load_tag($self->base_offset);
1341         if (!$tag) {
1342                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1343         }
1344
1345         my $ch = 0;
1346         while ($tag->{signature} ne SIG_BLIST) {
1347                 my $num = ord(substr($md5, $ch, 1));
1348                 my $new_tag = $self->_index_lookup($tag, $num);
1349                 if (!$new_tag) {
1350                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1351                         seek($fh, $ref_loc, 0);
1352                         print($fh pack($LONG_PACK, $self->root->{end}) );
1353
1354                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1355                         $tag->{ref_loc} = $ref_loc;
1356                         $tag->{ch} = $ch;
1357                         last;
1358                 }
1359                 else {
1360                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1361                         $tag = $new_tag;
1362                         $tag->{ref_loc} = $ref_loc;
1363                         $tag->{ch} = $ch;
1364                 }
1365                 $ch++;
1366         }
1367
1368         ##
1369         # Add key/value to bucket list
1370         ##
1371         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1372     #print "2\n";
1373
1374         ##
1375         # If this object is an array, and bucket was not a replace, and key is numerical,
1376         # and index is equal or greater than current length, advance length variable.
1377         ##
1378         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1379                 $self->STORESIZE( $unpacked_key + 1 );
1380         }
1381
1382         $self->unlock();
1383
1384         return $result;
1385 }
1386
1387 sub FETCH {
1388         ##
1389         # Fetch single value or element given plain key or array index
1390         ##
1391     my $self = _get_self($_[0]);
1392     #print "FETCH: $self ... $_[0]\n";
1393
1394     my $key = $_[1];
1395     if ( $self->type eq TYPE_HASH ) {
1396         if ( my $filter = $self->root->{filter_store_key} ) {
1397             $key = $filter->( $key );
1398         }
1399     }
1400     elsif ( $self->type eq TYPE_ARRAY ) {
1401         if ( $key =~ /^\d+$/ ) {
1402             $key = pack($LONG_PACK, $key);
1403         }
1404     }
1405
1406         my $md5 = $DIGEST_FUNC->($key);
1407
1408         ##
1409         # Make sure file is open
1410         ##
1411         if (!defined($self->fh)) {
1412         #print "Calling _open from FETCH for '$key'\n";
1413         $self->_open(); }
1414
1415         ##
1416         # Request shared lock for reading
1417         ##
1418         $self->lock( LOCK_SH );
1419
1420         my $tag = $self->_find_bucket_list( $md5 );
1421         if (!$tag) {
1422                 $self->unlock();
1423                 return;
1424         }
1425
1426         ##
1427         # Get value from bucket list
1428         ##
1429         my $result = $self->_get_bucket_value( $tag, $md5 );
1430
1431         $self->unlock();
1432
1433     #XXX What is ref() checking here?
1434         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1435 }
1436
1437 sub DELETE {
1438         ##
1439         # Delete single key/value pair or element given plain key or array index
1440         ##
1441     my $self = _get_self($_[0]);
1442         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1443
1444         my $unpacked_key = $key;
1445         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1446         my $md5 = $DIGEST_FUNC->($key);
1447
1448         ##
1449         # Make sure file is open
1450         ##
1451         if (!defined($self->fh)) { $self->_open(); }
1452
1453         ##
1454         # Request exclusive lock for writing
1455         ##
1456         $self->lock( LOCK_EX );
1457
1458         my $tag = $self->_find_bucket_list( $md5 );
1459         if (!$tag) {
1460                 $self->unlock();
1461                 return;
1462         }
1463
1464         ##
1465         # Delete bucket
1466         ##
1467         my $result = $self->_delete_bucket( $tag, $md5 );
1468
1469         ##
1470         # If this object is an array and the key deleted was on the end of the stack,
1471         # decrement the length variable.
1472         ##
1473         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1474                 $self->STORESIZE( $unpacked_key );
1475         }
1476
1477         $self->unlock();
1478
1479         return $result;
1480 }
1481
1482 sub EXISTS {
1483         ##
1484         # Check if a single key or element exists given plain key or array index
1485         ##
1486     my $self = _get_self($_[0]);
1487         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1488
1489         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1490         my $md5 = $DIGEST_FUNC->($key);
1491
1492         ##
1493         # Make sure file is open
1494         ##
1495         if (!defined($self->fh)) { $self->_open(); }
1496
1497         ##
1498         # Request shared lock for reading
1499         ##
1500         $self->lock( LOCK_SH );
1501
1502         my $tag = $self->_find_bucket_list( $md5 );
1503
1504         ##
1505         # For some reason, the built-in exists() function returns '' for false
1506         ##
1507         if (!$tag) {
1508                 $self->unlock();
1509                 return '';
1510         }
1511
1512         ##
1513         # Check if bucket exists and return 1 or ''
1514         ##
1515         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1516
1517         $self->unlock();
1518
1519         return $result;
1520 }
1521
1522 sub CLEAR {
1523         ##
1524         # Clear all keys from hash, or all elements from array.
1525         ##
1526     my $self = _get_self($_[0]);
1527
1528         ##
1529         # Make sure file is open
1530         ##
1531         if (!defined($self->fh)) { $self->_open(); }
1532
1533         ##
1534         # Request exclusive lock for writing
1535         ##
1536         $self->lock( LOCK_EX );
1537
1538     my $fh = $self->fh;
1539
1540         seek($fh, $self->base_offset, 0);
1541         if (eof $fh) {
1542                 $self->unlock();
1543                 return;
1544         }
1545
1546         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1547
1548         $self->unlock();
1549
1550         return 1;
1551 }
1552
1553 sub FIRSTKEY {
1554         ##
1555         # Locate and return first key (in no particular order)
1556         ##
1557     my $self = _get_self($_[0]);
1558         if ($self->type ne TYPE_HASH) {
1559                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1560         }
1561
1562         ##
1563         # Make sure file is open
1564         ##
1565         if (!defined($self->fh)) { $self->_open(); }
1566
1567         ##
1568         # Request shared lock for reading
1569         ##
1570         $self->lock( LOCK_SH );
1571
1572         my $result = $self->_get_next_key();
1573
1574         $self->unlock();
1575
1576         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1577 }
1578
1579 sub NEXTKEY {
1580         ##
1581         # Return next key (in no particular order), given previous one
1582         ##
1583     my $self = _get_self($_[0]);
1584         if ($self->type ne TYPE_HASH) {
1585                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1586         }
1587         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1588         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1589
1590         ##
1591         # Make sure file is open
1592         ##
1593         if (!defined($self->fh)) { $self->_open(); }
1594
1595         ##
1596         # Request shared lock for reading
1597         ##
1598         $self->lock( LOCK_SH );
1599
1600         my $result = $self->_get_next_key( $prev_md5 );
1601
1602         $self->unlock();
1603
1604         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1605 }
1606
1607 ##
1608 # The following methods are for arrays only
1609 ##
1610
1611 sub FETCHSIZE {
1612         ##
1613         # Return the length of the array
1614         ##
1615     my $self = _get_self($_[0]);
1616         if ($self->type ne TYPE_ARRAY) {
1617                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1618         }
1619
1620         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1621         $self->root->{filter_fetch_value} = undef;
1622
1623     #print "Fetching size ...\n";
1624         my $packed_size = $self->FETCH('length');
1625     #print "size is '$packed_size'\n";
1626
1627         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1628
1629         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1630         else { return 0; }
1631 }
1632
1633 sub STORESIZE {
1634         ##
1635         # Set the length of the array
1636         ##
1637     my $self = _get_self($_[0]);
1638         if ($self->type ne TYPE_ARRAY) {
1639                 return $self->_throw_error("STORESIZE method only supported for arrays");
1640         }
1641         my $new_length = $_[1];
1642
1643         my $SAVE_FILTER = $self->root->{filter_store_value};
1644         $self->root->{filter_store_value} = undef;
1645
1646         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1647
1648         $self->root->{filter_store_value} = $SAVE_FILTER;
1649
1650         return $result;
1651 }
1652
1653 sub POP {
1654         ##
1655         # Remove and return the last element on the array
1656         ##
1657     my $self = _get_self($_[0]);
1658         if ($self->type ne TYPE_ARRAY) {
1659                 return $self->_throw_error("POP method only supported for arrays");
1660         }
1661         my $length = $self->FETCHSIZE();
1662
1663         if ($length) {
1664                 my $content = $self->FETCH( $length - 1 );
1665                 $self->DELETE( $length - 1 );
1666                 return $content;
1667         }
1668         else {
1669                 return;
1670         }
1671 }
1672
1673 sub PUSH {
1674         ##
1675         # Add new element(s) to the end of the array
1676         ##
1677     my $self = _get_self(shift);
1678         if ($self->type ne TYPE_ARRAY) {
1679                 return $self->_throw_error("PUSH method only supported for arrays");
1680         }
1681         my $length = $self->FETCHSIZE();
1682
1683         while (my $content = shift @_) {
1684                 $self->STORE( $length, $content );
1685                 $length++;
1686         }
1687 }
1688
1689 sub SHIFT {
1690         ##
1691         # Remove and return first element on the array.
1692         # Shift over remaining elements to take up space.
1693         ##
1694     my $self = _get_self($_[0]);
1695         if ($self->type ne TYPE_ARRAY) {
1696                 return $self->_throw_error("SHIFT method only supported for arrays");
1697         }
1698         my $length = $self->FETCHSIZE();
1699
1700         if ($length) {
1701                 my $content = $self->FETCH( 0 );
1702
1703                 ##
1704                 # Shift elements over and remove last one.
1705                 ##
1706                 for (my $i = 0; $i < $length - 1; $i++) {
1707                         $self->STORE( $i, $self->FETCH($i + 1) );
1708                 }
1709                 $self->DELETE( $length - 1 );
1710
1711                 return $content;
1712         }
1713         else {
1714                 return;
1715         }
1716 }
1717
1718 sub UNSHIFT {
1719         ##
1720         # Insert new element(s) at beginning of array.
1721         # Shift over other elements to make space.
1722         ##
1723     my $self = _get_self($_[0]);shift @_;
1724         if ($self->type ne TYPE_ARRAY) {
1725                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1726         }
1727         my @new_elements = @_;
1728         my $length = $self->FETCHSIZE();
1729         my $new_size = scalar @new_elements;
1730
1731         if ($length) {
1732                 for (my $i = $length - 1; $i >= 0; $i--) {
1733                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1734                 }
1735         }
1736
1737         for (my $i = 0; $i < $new_size; $i++) {
1738                 $self->STORE( $i, $new_elements[$i] );
1739         }
1740 }
1741
1742 sub SPLICE {
1743         ##
1744         # Splices section of array with optional new section.
1745         # Returns deleted section, or last element deleted in scalar context.
1746         ##
1747     my $self = _get_self($_[0]);shift @_;
1748         if ($self->type ne TYPE_ARRAY) {
1749                 return $self->_throw_error("SPLICE method only supported for arrays");
1750         }
1751         my $length = $self->FETCHSIZE();
1752
1753         ##
1754         # Calculate offset and length of splice
1755         ##
1756         my $offset = shift || 0;
1757         if ($offset < 0) { $offset += $length; }
1758
1759         my $splice_length;
1760         if (scalar @_) { $splice_length = shift; }
1761         else { $splice_length = $length - $offset; }
1762         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1763
1764         ##
1765         # Setup array with new elements, and copy out old elements for return
1766         ##
1767         my @new_elements = @_;
1768         my $new_size = scalar @new_elements;
1769
1770         my @old_elements = ();
1771         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1772                 push @old_elements, $self->FETCH( $i );
1773         }
1774
1775         ##
1776         # Adjust array length, and shift elements to accomodate new section.
1777         ##
1778     if ( $new_size != $splice_length ) {
1779         if ($new_size > $splice_length) {
1780             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1781                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1782             }
1783         }
1784         else {
1785             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1786                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1787             }
1788             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1789                 $self->DELETE( $length - 1 );
1790                 $length--;
1791             }
1792         }
1793         }
1794
1795         ##
1796         # Insert new elements into array
1797         ##
1798         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1799                 $self->STORE( $i, shift @new_elements );
1800         }
1801
1802         ##
1803         # Return deleted section, or last element in scalar context.
1804         ##
1805         return wantarray ? @old_elements : $old_elements[-1];
1806 }
1807
1808 #XXX We don't need to define it.
1809 #XXX It will be useful, though, when we split out HASH and ARRAY
1810 #sub EXTEND {
1811         ##
1812         # Perl will call EXTEND() when the array is likely to grow.
1813         # We don't care, but include it for compatibility.
1814         ##
1815 #}
1816
1817 ##
1818 # Public method aliases
1819 ##
1820 *put = *store = *STORE;
1821 *get = *fetch = *FETCH;
1822 *delete = *DELETE;
1823 *exists = *EXISTS;
1824 *clear = *CLEAR;
1825 *first_key = *FIRSTKEY;
1826 *next_key = *NEXTKEY;
1827 *length = *FETCHSIZE;
1828 *pop = *POP;
1829 *push = *PUSH;
1830 *shift = *SHIFT;
1831 *unshift = *UNSHIFT;
1832 *splice = *SPLICE;
1833
1834 1;
1835
1836 __END__
1837
1838 =head1 NAME
1839
1840 DBM::Deep - A pure perl multi-level hash/array DBM
1841
1842 =head1 SYNOPSIS
1843
1844   use DBM::Deep;
1845   my $db = DBM::Deep->new( "foo.db" );
1846
1847   $db->{key} = 'value'; # tie() style
1848   print $db->{key};
1849
1850   $db->put('key', 'value'); # OO style
1851   print $db->get('key');
1852
1853   # true multi-level support
1854   $db->{my_complex} = [
1855         'hello', { perl => 'rules' },
1856         42, 99 ];
1857
1858 =head1 DESCRIPTION
1859
1860 A unique flat-file database module, written in pure perl.  True
1861 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1862 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1863 handle millions of keys and unlimited hash levels without significant
1864 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1865 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1866 Mac OS X and Windows.
1867
1868 =head1 INSTALLATION
1869
1870 Hopefully you are using CPAN's excellent Perl module, which will download
1871 and install the module for you.  If not, get the tarball, and run these
1872 commands:
1873
1874         tar zxf DBM-Deep-*
1875         cd DBM-Deep-*
1876         perl Makefile.PL
1877         make
1878         make test
1879         make install
1880
1881 =head1 SETUP
1882
1883 Construction can be done OO-style (which is the recommended way), or using
1884 Perl's tie() function.  Both are examined here.
1885
1886 =head2 OO CONSTRUCTION
1887
1888 The recommended way to construct a DBM::Deep object is to use the new()
1889 method, which gets you a blessed, tied hash or array reference.
1890
1891         my $db = DBM::Deep->new( "foo.db" );
1892
1893 This opens a new database handle, mapped to the file "foo.db".  If this
1894 file does not exist, it will automatically be created.  DB files are
1895 opened in "r+" (read/write) mode, and the type of object returned is a
1896 hash, unless otherwise specified (see L<OPTIONS> below).
1897
1898
1899
1900 You can pass a number of options to the constructor to specify things like
1901 locking, autoflush, etc.  This is done by passing an inline hash:
1902
1903         my $db = DBM::Deep->new(
1904                 file => "foo.db",
1905                 locking => 1,
1906                 autoflush => 1
1907         );
1908
1909 Notice that the filename is now specified I<inside> the hash with
1910 the "file" parameter, as opposed to being the sole argument to the
1911 constructor.  This is required if any options are specified.
1912 See L<OPTIONS> below for the complete list.
1913
1914
1915
1916 You can also start with an array instead of a hash.  For this, you must
1917 specify the C<type> parameter:
1918
1919         my $db = DBM::Deep->new(
1920                 file => "foo.db",
1921                 type => DBM::Deep->TYPE_ARRAY
1922         );
1923
1924 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1925 a new DB file.  If you create a DBM::Deep object with an existing file, the
1926 C<type> will be loaded from the file header, and ignored if it is passed
1927 to the constructor.
1928
1929 =head2 TIE CONSTRUCTION
1930
1931 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1932 tie() function.  This is not ideal, because you get only a basic, tied hash
1933 (or array) which is not blessed, so you can't call any functions on it.
1934
1935         my %hash;
1936         tie %hash, "DBM::Deep", "foo.db";
1937
1938         my @array;
1939         tie @array, "DBM::Deep", "bar.db";
1940
1941 As with the OO constructor, you can replace the DB filename parameter with
1942 a hash containing one or more options (see L<OPTIONS> just below for the
1943 complete list).
1944
1945         tie %hash, "DBM::Deep", {
1946                 file => "foo.db",
1947                 locking => 1,
1948                 autoflush => 1
1949         };
1950
1951 =head2 OPTIONS
1952
1953 There are a number of options that can be passed in when constructing your
1954 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1955
1956 =over
1957
1958 =item * file
1959
1960 Filename of the DB file to link the handle to.  You can pass a full absolute
1961 filesystem path, partial path, or a plain filename if the file is in the
1962 current working directory.  This is a required parameter.
1963
1964 =item * mode
1965
1966 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1967 module.  This is an optional parameter, and defaults to "r+" (read/write).
1968 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1969 created if it doesn't exist.
1970
1971 =item * type
1972
1973 This parameter specifies what type of object to create, a hash or array.  Use
1974 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1975 This only takes effect when beginning a new file.  This is an optional
1976 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1977
1978 =item * locking
1979
1980 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1981 function to lock the database in exclusive mode for writes, and shared mode for
1982 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1983 any child hashes or arrays> that use the same DB file.  This is an optional
1984 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1985
1986 =item * autoflush
1987
1988 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1989 This obviously slows down write operations, but is required if you may have
1990 multiple processes accessing the same DB file (also consider enable I<locking>
1991 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1992 parameter, and defaults to 0 (disabled).
1993
1994 =item * volatile
1995
1996 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1997 STORE() operation.  This is required if an outside force may change the size of
1998 the file between transactions.  Locking also implicitly enables volatile.  This
1999 is useful if you want to use a different locking system or write your own.  Pass
2000 any true value to enable.  This is an optional parameter, and defaults to 0
2001 (disabled).
2002
2003 =item * autobless
2004
2005 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
2006 restore them when fetched.  This is an B<experimental> feature, and does have
2007 side-effects.  Basically, when hashes are re-blessed into their original
2008 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
2009 able to call any DBM::Deep methods on them.  You have been warned.
2010 This is an optional parameter, and defaults to 0 (disabled).
2011
2012 =item * filter_*
2013
2014 See L<FILTERS> below.
2015
2016 =item * debug
2017
2018 Setting I<debug> mode will make all errors non-fatal, dump them out to
2019 STDERR, and continue on.  This is for debugging purposes only, and probably
2020 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
2021
2022 =item * fh
2023
2024 Instead of passing a file path, you can instead pass a handle to an pre-opened
2025 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
2026 contains your entire Perl script, as well as the data following the __DATA__
2027 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
2028 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
2029 in that.
2030
2031 =back
2032
2033 =head1 TIE INTERFACE
2034
2035 With DBM::Deep you can access your databases using Perl's standard hash/array
2036 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
2037 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
2038 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
2039 section above.  This simply tells you how to use DBM::Deep using regular hashes
2040 and arrays, rather than calling functions like C<get()> and C<put()> (although those
2041 work too).  It is entirely up to you how to want to access your databases.
2042
2043 =head2 HASHES
2044
2045 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
2046 or even nested hashes (or arrays) using standard Perl syntax:
2047
2048         my $db = DBM::Deep->new( "foo.db" );
2049
2050         $db->{mykey} = "myvalue";
2051         $db->{myhash} = {};
2052         $db->{myhash}->{subkey} = "subvalue";
2053
2054         print $db->{myhash}->{subkey} . "\n";
2055
2056 You can even step through hash keys using the normal Perl C<keys()> function:
2057
2058         foreach my $key (keys %$db) {
2059                 print "$key: " . $db->{$key} . "\n";
2060         }
2061
2062 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
2063 pushes them onto an array, all before the loop even begins.  If you have an
2064 extra large hash, this may exhaust Perl's memory.  Instead, consider using
2065 Perl's C<each()> function, which pulls keys/values one at a time, using very
2066 little memory:
2067
2068         while (my ($key, $value) = each %$db) {
2069                 print "$key: $value\n";
2070         }
2071
2072 Please note that when using C<each()>, you should always pass a direct
2073 hash reference, not a lookup.  Meaning, you should B<never> do this:
2074
2075         # NEVER DO THIS
2076         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
2077
2078 This causes an infinite loop, because for each iteration, Perl is calling
2079 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
2080 it effectively keeps returning the first key over and over again. Instead,
2081 assign a temporary variable to C<$db->{foo}>, then pass that to each().
2082
2083 =head2 ARRAYS
2084
2085 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2086 reference.  This includes inserting, removing and manipulating elements,
2087 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2088 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2089 or simply be a nested array reference inside a hash.  Example:
2090
2091         my $db = DBM::Deep->new(
2092                 file => "foo-array.db",
2093                 type => DBM::Deep->TYPE_ARRAY
2094         );
2095
2096         $db->[0] = "foo";
2097         push @$db, "bar", "baz";
2098         unshift @$db, "bah";
2099
2100         my $last_elem = pop @$db; # baz
2101         my $first_elem = shift @$db; # bah
2102         my $second_elem = $db->[1]; # bar
2103
2104         my $num_elements = scalar @$db;
2105
2106 =head1 OO INTERFACE
2107
2108 In addition to the I<tie()> interface, you can also use a standard OO interface
2109 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2110 array) has its own methods, but both types share the following common methods:
2111 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2112
2113 =over
2114
2115 =item * put()
2116
2117 Stores a new hash key/value pair, or sets an array element value.  Takes two
2118 arguments, the hash key or array index, and the new value.  The value can be
2119 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2120
2121         $db->put("foo", "bar"); # for hashes
2122         $db->put(1, "bar"); # for arrays
2123
2124 =item * get()
2125
2126 Fetches the value of a hash key or array element.  Takes one argument: the hash
2127 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2128 data type stored.
2129
2130         my $value = $db->get("foo"); # for hashes
2131         my $value = $db->get(1); # for arrays
2132
2133 =item * exists()
2134
2135 Checks if a hash key or array index exists.  Takes one argument: the hash key
2136 or array index.  Returns true if it exists, false if not.
2137
2138         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2139         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2140
2141 =item * delete()
2142
2143 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2144 key or array index.  Returns true on success, false if not found.  For arrays,
2145 the remaining elements located after the deleted element are NOT moved over.
2146 The deleted element is essentially just undefined, which is exactly how Perl's
2147 internal arrays work.  Please note that the space occupied by the deleted
2148 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2149 below for details and workarounds.
2150
2151         $db->delete("foo"); # for hashes
2152         $db->delete(1); # for arrays
2153
2154 =item * clear()
2155
2156 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2157 value.  Please note that the space occupied by the deleted keys/values or
2158 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2159 details and workarounds.
2160
2161         $db->clear(); # hashes or arrays
2162
2163 =back
2164
2165 =head2 HASHES
2166
2167 For hashes, DBM::Deep supports all the common methods described above, and the
2168 following additional methods: C<first_key()> and C<next_key()>.
2169
2170 =over
2171
2172 =item * first_key()
2173
2174 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2175 fetched in an undefined order (which appears random).  Takes no arguments,
2176 returns the key as a scalar value.
2177
2178         my $key = $db->first_key();
2179
2180 =item * next_key()
2181
2182 Returns the "next" key in the hash, given the previous one as the sole argument.
2183 Returns undef if there are no more keys to be fetched.
2184
2185         $key = $db->next_key($key);
2186
2187 =back
2188
2189 Here are some examples of using hashes:
2190
2191         my $db = DBM::Deep->new( "foo.db" );
2192
2193         $db->put("foo", "bar");
2194         print "foo: " . $db->get("foo") . "\n";
2195
2196         $db->put("baz", {}); # new child hash ref
2197         $db->get("baz")->put("buz", "biz");
2198         print "buz: " . $db->get("baz")->get("buz") . "\n";
2199
2200         my $key = $db->first_key();
2201         while ($key) {
2202                 print "$key: " . $db->get($key) . "\n";
2203                 $key = $db->next_key($key);
2204         }
2205
2206         if ($db->exists("foo")) { $db->delete("foo"); }
2207
2208 =head2 ARRAYS
2209
2210 For arrays, DBM::Deep supports all the common methods described above, and the
2211 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2212 C<unshift()> and C<splice()>.
2213
2214 =over
2215
2216 =item * length()
2217
2218 Returns the number of elements in the array.  Takes no arguments.
2219
2220         my $len = $db->length();
2221
2222 =item * push()
2223
2224 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2225 refs or array refs.  No return value.
2226
2227         $db->push("foo", "bar", {});
2228
2229 =item * pop()
2230
2231 Fetches the last element in the array, and deletes it.  Takes no arguments.
2232 Returns undef if array is empty.  Returns the element value.
2233
2234         my $elem = $db->pop();
2235
2236 =item * shift()
2237
2238 Fetches the first element in the array, deletes it, then shifts all the
2239 remaining elements over to take up the space.  Returns the element value.  This
2240 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2241 details.
2242
2243         my $elem = $db->shift();
2244
2245 =item * unshift()
2246
2247 Inserts one or more elements onto the beginning of the array, shifting all
2248 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2249 No return value.  This method is not recommended with large arrays -- see
2250 <LARGE ARRAYS> below for details.
2251
2252         $db->unshift("foo", "bar", {});
2253
2254 =item * splice()
2255
2256 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2257 -f splice> for usage -- it is too complicated to document here.  This method is
2258 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2259
2260 =back
2261
2262 Here are some examples of using arrays:
2263
2264         my $db = DBM::Deep->new(
2265                 file => "foo.db",
2266                 type => DBM::Deep->TYPE_ARRAY
2267         );
2268
2269         $db->push("bar", "baz");
2270         $db->unshift("foo");
2271         $db->put(3, "buz");
2272
2273         my $len = $db->length();
2274         print "length: $len\n"; # 4
2275
2276         for (my $k=0; $k<$len; $k++) {
2277                 print "$k: " . $db->get($k) . "\n";
2278         }
2279
2280         $db->splice(1, 2, "biz", "baf");
2281
2282         while (my $elem = shift @$db) {
2283                 print "shifted: $elem\n";
2284         }
2285
2286 =head1 LOCKING
2287
2288 Enable automatic file locking by passing a true value to the C<locking>
2289 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2290
2291         my $db = DBM::Deep->new(
2292                 file => "foo.db",
2293                 locking => 1
2294         );
2295
2296 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2297 mode for writes, and shared mode for reads.  This is required if you have
2298 multiple processes accessing the same database file, to avoid file corruption.
2299 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2300 NFS> below for more.
2301
2302 =head2 EXPLICIT LOCKING
2303
2304 You can explicitly lock a database, so it remains locked for multiple
2305 transactions.  This is done by calling the C<lock()> method, and passing an
2306 optional lock mode argument (defaults to exclusive mode).  This is particularly
2307 useful for things like counters, where the current value needs to be fetched,
2308 then incremented, then stored again.
2309
2310         $db->lock();
2311         my $counter = $db->get("counter");
2312         $counter++;
2313         $db->put("counter", $counter);
2314         $db->unlock();
2315
2316         # or...
2317
2318         $db->lock();
2319         $db->{counter}++;
2320         $db->unlock();
2321
2322 You can pass C<lock()> an optional argument, which specifies which mode to use
2323 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2324 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2325 same as the constants defined in Perl's C<Fcntl> module.
2326
2327         $db->lock( DBM::Deep->LOCK_SH );
2328         # something here
2329         $db->unlock();
2330
2331 If you want to implement your own file locking scheme, be sure to create your
2332 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2333 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2334 below for more.
2335
2336 =head1 IMPORTING/EXPORTING
2337
2338 You can import existing complex structures by calling the C<import()> method,
2339 and export an entire database into an in-memory structure using the C<export()>
2340 method.  Both are examined here.
2341
2342 =head2 IMPORTING
2343
2344 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2345 walking the structure and adding keys/elements to the database as you go,
2346 simply pass a reference to the C<import()> method.  This recursively adds
2347 everything to an existing DBM::Deep object for you.  Here is an example:
2348
2349         my $struct = {
2350                 key1 => "value1",
2351                 key2 => "value2",
2352                 array1 => [ "elem0", "elem1", "elem2" ],
2353                 hash1 => {
2354                         subkey1 => "subvalue1",
2355                         subkey2 => "subvalue2"
2356                 }
2357         };
2358
2359         my $db = DBM::Deep->new( "foo.db" );
2360         $db->import( $struct );
2361
2362         print $db->{key1} . "\n"; # prints "value1"
2363
2364 This recursively imports the entire C<$struct> object into C<$db>, including
2365 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2366 keys are merged with the existing ones, replacing if they already exist.
2367 The C<import()> method can be called on any database level (not just the base
2368 level), and works with both hash and array DB types.
2369
2370
2371
2372 B<Note:> Make sure your existing structure has no circular references in it.
2373 These will cause an infinite loop when importing.
2374
2375 =head2 EXPORTING
2376
2377 Calling the C<export()> method on an existing DBM::Deep object will return
2378 a reference to a new in-memory copy of the database.  The export is done
2379 recursively, so all nested hashes/arrays are all exported to standard Perl
2380 objects.  Here is an example:
2381
2382         my $db = DBM::Deep->new( "foo.db" );
2383
2384         $db->{key1} = "value1";
2385         $db->{key2} = "value2";
2386         $db->{hash1} = {};
2387         $db->{hash1}->{subkey1} = "subvalue1";
2388         $db->{hash1}->{subkey2} = "subvalue2";
2389
2390         my $struct = $db->export();
2391
2392         print $struct->{key1} . "\n"; # prints "value1"
2393
2394 This makes a complete copy of the database in memory, and returns a reference
2395 to it.  The C<export()> method can be called on any database level (not just
2396 the base level), and works with both hash and array DB types.  Be careful of
2397 large databases -- you can store a lot more data in a DBM::Deep object than an
2398 in-memory Perl structure.
2399
2400
2401
2402 B<Note:> Make sure your database has no circular references in it.
2403 These will cause an infinite loop when exporting.
2404
2405 =head1 FILTERS
2406
2407 DBM::Deep has a number of hooks where you can specify your own Perl function
2408 to perform filtering on incoming or outgoing data.  This is a perfect
2409 way to extend the engine, and implement things like real-time compression or
2410 encryption.  Filtering applies to the base DB level, and all child hashes /
2411 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2412 constructed, or by calling the C<set_filter()> method at any time.  There are
2413 four available filter hooks, described below:
2414
2415 =over
2416
2417 =item * filter_store_key
2418
2419 This filter is called whenever a hash key is stored.  It
2420 is passed the incoming key, and expected to return a transformed key.
2421
2422 =item * filter_store_value
2423
2424 This filter is called whenever a hash key or array element is stored.  It
2425 is passed the incoming value, and expected to return a transformed value.
2426
2427 =item * filter_fetch_key
2428
2429 This filter is called whenever a hash key is fetched (i.e. via
2430 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2431 and expected to return the plain key.
2432
2433 =item * filter_fetch_value
2434
2435 This filter is called whenever a hash key or array element is fetched.
2436 It is passed the transformed value, and expected to return the plain value.
2437
2438 =back
2439
2440 Here are the two ways to setup a filter hook:
2441
2442         my $db = DBM::Deep->new(
2443                 file => "foo.db",
2444                 filter_store_value => \&my_filter_store,
2445                 filter_fetch_value => \&my_filter_fetch
2446         );
2447
2448         # or...
2449
2450         $db->set_filter( "filter_store_value", \&my_filter_store );
2451         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2452
2453 Your filter function will be called only when dealing with SCALAR keys or
2454 values.  When nested hashes and arrays are being stored/fetched, filtering
2455 is bypassed.  Filters are called as static functions, passed a single SCALAR
2456 argument, and expected to return a single SCALAR value.  If you want to
2457 remove a filter, set the function reference to C<undef>:
2458
2459         $db->set_filter( "filter_store_value", undef );
2460
2461 =head2 REAL-TIME ENCRYPTION EXAMPLE
2462
2463 Here is a working example that uses the I<Crypt::Blowfish> module to
2464 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2465 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2466 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2467
2468         use DBM::Deep;
2469         use Crypt::Blowfish;
2470         use Crypt::CBC;
2471
2472         my $cipher = Crypt::CBC->new({
2473                 'key'             => 'my secret key',
2474                 'cipher'          => 'Blowfish',
2475                 'iv'              => '$KJh#(}q',
2476                 'regenerate_key'  => 0,
2477                 'padding'         => 'space',
2478                 'prepend_iv'      => 0
2479         });
2480
2481         my $db = DBM::Deep->new(
2482                 file => "foo-encrypt.db",
2483                 filter_store_key => \&my_encrypt,
2484                 filter_store_value => \&my_encrypt,
2485                 filter_fetch_key => \&my_decrypt,
2486                 filter_fetch_value => \&my_decrypt,
2487         );
2488
2489         $db->{key1} = "value1";
2490         $db->{key2} = "value2";
2491         print "key1: " . $db->{key1} . "\n";
2492         print "key2: " . $db->{key2} . "\n";
2493
2494         undef $db;
2495         exit;
2496
2497         sub my_encrypt {
2498                 return $cipher->encrypt( $_[0] );
2499         }
2500         sub my_decrypt {
2501                 return $cipher->decrypt( $_[0] );
2502         }
2503
2504 =head2 REAL-TIME COMPRESSION EXAMPLE
2505
2506 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2507 compression / decompression of keys & values with DBM::Deep Filters.
2508 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2509 more on I<Compress::Zlib>.
2510
2511         use DBM::Deep;
2512         use Compress::Zlib;
2513
2514         my $db = DBM::Deep->new(
2515                 file => "foo-compress.db",
2516                 filter_store_key => \&my_compress,
2517                 filter_store_value => \&my_compress,
2518                 filter_fetch_key => \&my_decompress,
2519                 filter_fetch_value => \&my_decompress,
2520         );
2521
2522         $db->{key1} = "value1";
2523         $db->{key2} = "value2";
2524         print "key1: " . $db->{key1} . "\n";
2525         print "key2: " . $db->{key2} . "\n";
2526
2527         undef $db;
2528         exit;
2529
2530         sub my_compress {
2531                 return Compress::Zlib::memGzip( $_[0] ) ;
2532         }
2533         sub my_decompress {
2534                 return Compress::Zlib::memGunzip( $_[0] ) ;
2535         }
2536
2537 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2538 actually numerical index numbers, and are not filtered.
2539
2540 =head1 ERROR HANDLING
2541
2542 Most DBM::Deep methods return a true value for success, and call die() on
2543 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2544 actual error message is stored in an internal scalar, which can be fetched by
2545 calling the C<error()> method.
2546
2547         my $db = DBM::Deep->new( "foo.db" ); # create hash
2548         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2549
2550         print $db->error(); # prints error message
2551
2552 You can then call C<clear_error()> to clear the current error state.
2553
2554         $db->clear_error();
2555
2556 If you set the C<debug> option to true when creating your DBM::Deep object,
2557 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2558 for debugging purposes.
2559
2560 =head1 LARGEFILE SUPPORT
2561
2562 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2563 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2564 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2565 by calling the static C<set_pack()> method before you do anything else.
2566
2567         DBM::Deep::set_pack(8, 'Q');
2568
2569 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2570 instead of 32-bit longs.  After setting these values your DB files have a
2571 theoretical maximum size of 16 XB (exabytes).
2572
2573
2574
2575 B<Note:> Changing these values will B<NOT> work for existing database files.
2576 Only change this for new files, and make sure it stays set consistently
2577 throughout the file's life.  If you do set these values, you can no longer
2578 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2579 back to 32-bit mode.
2580
2581
2582
2583 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2584 only a 32-bit Perl.  However, I have received user reports that this does
2585 indeed work!
2586
2587 =head1 LOW-LEVEL ACCESS
2588
2589 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2590 you can call the C<fh()> method, which returns the handle:
2591
2592         my $fh = $db->fh();
2593
2594 This method can be called on the root level of the datbase, or any child
2595 hashes or arrays.  All levels share a I<root> structure, which contains things
2596 like the FileHandle, a reference counter, and all your options you specified
2597 when you created the object.  You can get access to this root structure by
2598 calling the C<root()> method.
2599
2600         my $root = $db->root();
2601
2602 This is useful for changing options after the object has already been created,
2603 such as enabling/disabling locking, volatile or debug modes.  You can also
2604 store your own temporary user data in this structure (be wary of name
2605 collision), which is then accessible from any child hash or array.
2606
2607 =head1 CUSTOM DIGEST ALGORITHM
2608
2609 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2610 keys.  However you can override this, and use another algorithm (such as SHA-256)
2611 or even write your own.  But please note that DBM::Deep currently expects zero
2612 collisions, so your algorithm has to be I<perfect>, so to speak.
2613 Collision detection may be introduced in a later version.
2614
2615
2616
2617 You can specify a custom digest algorithm by calling the static C<set_digest()>
2618 function, passing a reference to a subroutine, and the length of the algorithm's
2619 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2620 objects.  Here is a working example that uses a 256-bit hash from the
2621 I<Digest::SHA256> module.  Please see
2622 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2623
2624         use DBM::Deep;
2625         use Digest::SHA256;
2626
2627         my $context = Digest::SHA256::new(256);
2628
2629         DBM::Deep::set_digest( \&my_digest, 32 );
2630
2631         my $db = DBM::Deep->new( "foo-sha.db" );
2632
2633         $db->{key1} = "value1";
2634         $db->{key2} = "value2";
2635         print "key1: " . $db->{key1} . "\n";
2636         print "key2: " . $db->{key2} . "\n";
2637
2638         undef $db;
2639         exit;
2640
2641         sub my_digest {
2642                 return substr( $context->hash($_[0]), 0, 32 );
2643         }
2644
2645 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2646 of bytes you specify in the C<set_digest()> function (in this case 32).
2647
2648 =head1 CIRCULAR REFERENCES
2649
2650 DBM::Deep has B<experimental> support for circular references.  Meaning you
2651 can have a nested hash key or array element that points to a parent object.
2652 This relationship is stored in the DB file, and is preserved between sessions.
2653 Here is an example:
2654
2655         my $db = DBM::Deep->new( "foo.db" );
2656
2657         $db->{foo} = "bar";
2658         $db->{circle} = $db; # ref to self
2659
2660         print $db->{foo} . "\n"; # prints "foo"
2661         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2662
2663 One catch is, passing the object to a function that recursively walks the
2664 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2665 C<export()> methods) will result in an infinite loop.  The other catch is,
2666 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2667 or C<next_key()> methods), you will get the I<target object's key>, not the
2668 ref's key.  This gets even more interesting with the above example, where
2669 the I<circle> key points to the base DB object, which technically doesn't
2670 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2671 special case.
2672
2673 =head1 CAVEATS / ISSUES / BUGS
2674
2675 This section describes all the known issues with DBM::Deep.  It you have found
2676 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2677
2678 =head2 UNUSED SPACE RECOVERY
2679
2680 One major caveat with DBM::Deep is that space occupied by existing keys and
2681 values is not recovered when they are deleted.  Meaning if you keep deleting
2682 and adding new keys, your file will continuously grow.  I am working on this,
2683 but in the meantime you can call the built-in C<optimize()> method from time to
2684 time (perhaps in a crontab or something) to recover all your unused space.
2685
2686         $db->optimize(); # returns true on success
2687
2688 This rebuilds the ENTIRE database into a new file, then moves it on top of
2689 the original.  The new file will have no unused space, thus it will take up as
2690 little disk space as possible.  Please note that this operation can take
2691 a long time for large files, and you need enough disk space to temporarily hold
2692 2 copies of your DB file.  The temporary file is created in the same directory
2693 as the original, named with a ".tmp" extension, and is deleted when the
2694 operation completes.  Oh, and if locking is enabled, the DB is automatically
2695 locked for the entire duration of the copy.
2696
2697
2698
2699 B<WARNING:> Only call optimize() on the top-level node of the database, and
2700 make sure there are no child references lying around.  DBM::Deep keeps a reference
2701 counter, and if it is greater than 1, optimize() will abort and return undef.
2702
2703 =head2 AUTOVIVIFICATION
2704
2705 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2706 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2707 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2708 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2709 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2710 this does not work:
2711
2712         $db->{foo}->{bar} = "hello";
2713
2714 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2715 being an empty hash.  Try this instead, which works fine:
2716
2717         $db->{foo} = { bar => "hello" };
2718
2719 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2720 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2721 Probably a bug in Perl.
2722
2723 =head2 FILE CORRUPTION
2724
2725 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2726 for a 32-bit signature when opened, but other corruption in files can cause
2727 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2728 stuck in an infinite loop depending on the level of corruption.  File write
2729 operations are not checked for failure (for speed), so if you happen to run
2730 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2731 be addressed in a later version of DBM::Deep.
2732
2733 =head2 DB OVER NFS
2734
2735 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2736 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2737 about setting up your NFS server with a locking daemon, then using lockf() to
2738 lock your files, but your milage may vary there as well.  From what I
2739 understand, there is no real way to do it.  However, if you need access to the
2740 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2741 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2742
2743 =head2 COPYING OBJECTS
2744
2745 Beware of copying tied objects in Perl.  Very strange things can happen.
2746 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2747 returns a new, blessed, tied hash or array to the same level in the DB.
2748
2749         my $copy = $db->clone();
2750
2751 =head2 LARGE ARRAYS
2752
2753 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2754 These functions cause every element in the array to move, which can be murder
2755 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2756 a different location.  This may be addressed in a later version.
2757
2758 =head1 PERFORMANCE
2759
2760 This section discusses DBM::Deep's speed and memory usage.
2761
2762 =head2 SPEED
2763
2764 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2765 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2766 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2767 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2768 with huge databases.  Here is some test data:
2769
2770         Adding 1,000,000 keys to new DB file...
2771
2772         At 100 keys, avg. speed is 2,703 keys/sec
2773         At 200 keys, avg. speed is 2,642 keys/sec
2774         At 300 keys, avg. speed is 2,598 keys/sec
2775         At 400 keys, avg. speed is 2,578 keys/sec
2776         At 500 keys, avg. speed is 2,722 keys/sec
2777         At 600 keys, avg. speed is 2,628 keys/sec
2778         At 700 keys, avg. speed is 2,700 keys/sec
2779         At 800 keys, avg. speed is 2,607 keys/sec
2780         At 900 keys, avg. speed is 2,190 keys/sec
2781         At 1,000 keys, avg. speed is 2,570 keys/sec
2782         At 2,000 keys, avg. speed is 2,417 keys/sec
2783         At 3,000 keys, avg. speed is 1,982 keys/sec
2784         At 4,000 keys, avg. speed is 1,568 keys/sec
2785         At 5,000 keys, avg. speed is 1,533 keys/sec
2786         At 6,000 keys, avg. speed is 1,787 keys/sec
2787         At 7,000 keys, avg. speed is 1,977 keys/sec
2788         At 8,000 keys, avg. speed is 2,028 keys/sec
2789         At 9,000 keys, avg. speed is 2,077 keys/sec
2790         At 10,000 keys, avg. speed is 2,031 keys/sec
2791         At 20,000 keys, avg. speed is 1,970 keys/sec
2792         At 30,000 keys, avg. speed is 2,050 keys/sec
2793         At 40,000 keys, avg. speed is 2,073 keys/sec
2794         At 50,000 keys, avg. speed is 1,973 keys/sec
2795         At 60,000 keys, avg. speed is 1,914 keys/sec
2796         At 70,000 keys, avg. speed is 2,091 keys/sec
2797         At 80,000 keys, avg. speed is 2,103 keys/sec
2798         At 90,000 keys, avg. speed is 1,886 keys/sec
2799         At 100,000 keys, avg. speed is 1,970 keys/sec
2800         At 200,000 keys, avg. speed is 2,053 keys/sec
2801         At 300,000 keys, avg. speed is 1,697 keys/sec
2802         At 400,000 keys, avg. speed is 1,838 keys/sec
2803         At 500,000 keys, avg. speed is 1,941 keys/sec
2804         At 600,000 keys, avg. speed is 1,930 keys/sec
2805         At 700,000 keys, avg. speed is 1,735 keys/sec
2806         At 800,000 keys, avg. speed is 1,795 keys/sec
2807         At 900,000 keys, avg. speed is 1,221 keys/sec
2808         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2809
2810 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2811 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2812 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2813 Run time was 12 min 3 sec.
2814
2815 =head2 MEMORY USAGE
2816
2817 One of the great things about DBM::Deep is that it uses very little memory.
2818 Even with huge databases (1,000,000+ keys) you will not see much increased
2819 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2820 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2821 database handle:
2822
2823           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2824         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2825
2826 Basically the process is taking 2,716K of memory.  And here is the same
2827 process after storing and fetching 1,000,000 keys:
2828
2829           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2830         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2831
2832 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2833 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2834
2835 =head1 DB FILE FORMAT
2836
2837 In case you were interested in the underlying DB file format, it is documented
2838 here in this section.  You don't need to know this to use the module, it's just
2839 included for reference.
2840
2841 =head2 SIGNATURE
2842
2843 DBM::Deep files always start with a 32-bit signature to identify the file type.
2844 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2845 checked when the file is opened.
2846
2847 =head2 TAG
2848
2849 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2850 has a standard header containing the type of data, the length of data, and then
2851 the data itself.  The type is a single character (1 byte), the length is a
2852 32-bit unsigned long in network byte order, and the data is, well, the data.
2853 Here is how it unfolds:
2854
2855 =head2 MASTER INDEX
2856
2857 Immediately after the 32-bit file signature is the I<Master Index> record.
2858 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2859 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2860 depending on how the DBM::Deep object was constructed.
2861
2862
2863
2864 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2865 number).  The first 8-bit char of the MD5 signature is the offset into the
2866 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2867 index element is a file offset of the next tag for the key/element in question,
2868 which is usually a I<Bucket List> tag (see below).
2869
2870
2871
2872 The next tag I<could> be another index, depending on how many keys/elements
2873 exist.  See L<RE-INDEXING> below for details.
2874
2875 =head2 BUCKET LIST
2876
2877 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2878 file offsets to where the actual data is stored.  It starts with a standard
2879 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2880 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2881 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2882 When the list fills up, a I<Re-Index> operation is performed (See
2883 L<RE-INDEXING> below).
2884
2885 =head2 BUCKET
2886
2887 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2888 index/value pair (in array mode).  It starts with a standard tag header with
2889 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2890 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2891 header.  The size reported in the tag header is only for the value, but then,
2892 just after the value is another size (32-bit unsigned long) and then the plain
2893 key itself.  Since the value is likely to be fetched more often than the plain
2894 key, I figured it would be I<slightly> faster to store the value first.
2895
2896
2897
2898 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2899 record for the nested structure, where the process begins all over again.
2900
2901 =head2 RE-INDEXING
2902
2903 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2904 exhausted.  Then, when another key/element comes in, the list is converted to a
2905 new index record.  However, this index will look at the next char in the MD5
2906 hash, and arrange new Bucket List pointers accordingly.  This process is called
2907 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2908 17 (16 + new one) keys/elements are removed from the old Bucket List and
2909 inserted into the new index.  Several new Bucket Lists are created in the
2910 process, as a new MD5 char from the key is being examined (it is unlikely that
2911 the keys will all share the same next char of their MD5s).
2912
2913
2914
2915 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2916 when the Bucket Lists will turn into indexes, but the first round tends to
2917 happen right around 4,000 keys.  You will see a I<slight> decrease in
2918 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2919 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2920 right around 900,000 keys.  This process can continue nearly indefinitely --
2921 right up until the point the I<MD5> signatures start colliding with each other,
2922 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2923 getting struck by lightning while you are walking to cash in your tickets.
2924 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2925 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2926 this is 340 unodecillion, but don't quote me).
2927
2928 =head2 STORING
2929
2930 When a new key/element is stored, the key (or index number) is first ran through
2931 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2932 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2933 for the first char of the signature (in this case I<b>).  If it does not exist,
2934 a new I<Bucket List> is created for our key (and the next 15 future keys that
2935 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2936 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2937 this point, unless we are replacing an existing I<Bucket>), where the actual
2938 data will be stored.
2939
2940 =head2 FETCHING
2941
2942 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2943 (or index number), then walking along the indexes.  If there are enough
2944 keys/elements in this DB level, there might be nested indexes, each linked to
2945 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2946 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2947 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2948 plain key are stored.
2949
2950
2951
2952 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2953 methods.  In this process the indexes are walked systematically, and each key
2954 fetched in increasing MD5 order (which is why it appears random).   Once the
2955 I<Bucket> is found, the value is skipped the plain key returned instead.
2956 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2957 alphabetically sorted.  This only happens on an index-level -- as soon as the
2958 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2959 so it's pretty much undefined how the keys will come out -- just like Perl's
2960 built-in hashes.
2961
2962 =head1 CODE COVERAGE
2963
2964 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2965 module's test suite.
2966
2967   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2968   File                           stmt   bran   cond    sub    pod   time  total
2969   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2970   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2971   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2972   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2973
2974 =head1 AUTHOR
2975
2976 Joseph Huckaby, L<jhuckaby@cpan.org>
2977
2978 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2979
2980 =head1 SEE ALSO
2981
2982 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2983 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2984
2985 =head1 LICENSE
2986
2987 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2988 This is free software, you may use it and distribute it under the
2989 same terms as Perl itself.
2990
2991 =cut