lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.97);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a FileHandle to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         #XXX Can the mode be anything but r+, w+, or a+??
 215         #XXX ie, it has to be in read-write mode
 216         #XXX So, should we verify that the mode is legitimate?
 217
 218         #XXX Maybe the mode thingy should just go away. There's no good
 219         #XXX reason for it ...
 220         if ( $self->root->{mode} eq 'w+' ) {
 221             $flags |= O_TRUNC;
 222         }
 223
 224         my $fh;
 225         sysopen( $fh, $self->root->{file}, $flags )
 226             or $fh = undef;
 227         $self->root->{fh} = $fh;
 228     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 229         if (! defined($self->fh)) {
 230                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 231         }
 232
 233     my $fh = $self->fh;
 234
 235     #XXX Can we remove this by using the right sysopen() flags?
 236     # Maybe ... q.v. above
 237     binmode $fh; # for win32
 238
 239     if ($self->root->{autoflush}) {
 240         my $old = select $fh;
 241         $|=1;
 242         select $old;
 243     }
 244
 245     # Set the
 246     seek($fh, 0, SEEK_SET);
 247
 248     my $signature;
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, SEEK_SET);
 256         print($fh SIG_FILE);
 257         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 258
 259         my $plain_key = "[base]";
 260         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 261
 262         # Flush the filehandle
 263         my $old_fh = select $fh;
 264         my $old_af = $|;
 265         $| = 1;
 266         $| = $old_af;
 267         select $old_fh;
 268
 269         my @stats = stat($fh);
 270         $self->root->{inode} = $stats[1];
 271         $self->root->{end} = $stats[7];
 272
 273         return 1;
 274     }
 275
 276     ##
 277     # Check signature was valid
 278     ##
 279     unless ($signature eq SIG_FILE) {
 280         $self->_close();
 281         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 282     }
 283
 284         my @stats = stat($fh);
 285         $self->root->{inode} = $stats[1];
 286     $self->root->{end} = $stats[7];
 287
 288     ##
 289     # Get our type from master index signature
 290     ##
 291     my $tag = $self->_load_tag($self->base_offset);
 292
 293 #XXX We probably also want to store the hash algorithm name and not assume anything
 294 #XXX The cool thing would be to allow a different hashing algorithm at every level
 295
 296     if (!$tag) {
 297         return $self->_throw_error("Corrupted file, no master index record");
 298     }
 299     if ($self->{type} ne $tag->{signature}) {
 300         return $self->_throw_error("File type mismatch");
 301     }
 302
 303     return 1;
 304 }
 305
 306 sub _close {
 307         ##
 308         # Close database FileHandle
 309         ##
 310     my $self = $_[0]->_get_self;
 311     close $self->root->{fh};
 312     $self->root->{fh} = undef;
 313 }
 314
 315 sub _create_tag {
 316         ##
 317         # Given offset, signature and content, create tag and write to disk
 318         ##
 319         my ($self, $offset, $sig, $content) = @_;
 320         my $size = length($content);
 321
 322     my $fh = $self->fh;
 323
 324         seek($fh, $offset, SEEK_SET);
 325         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 326
 327         if ($offset == $self->root->{end}) {
 328                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 329         }
 330
 331         return {
 332                 signature => $sig,
 333                 size => $size,
 334                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 335                 content => $content
 336         };
 337 }
 338
 339 sub _load_tag {
 340         ##
 341         # Given offset, load single tag and return signature, size and data
 342         ##
 343         my $self = shift;
 344         my $offset = shift;
 345
 346     my $fh = $self->fh;
 347
 348         seek($fh, $offset, SEEK_SET);
 349         if (eof $fh) { return undef; }
 350
 351         my $sig;
 352         read( $fh, $sig, SIG_SIZE);
 353
 354         my $size;
 355         read( $fh, $size, $DATA_LENGTH_SIZE);
 356         $size = unpack($DATA_LENGTH_PACK, $size);
 357
 358         my $buffer;
 359         read( $fh, $buffer, $size);
 360
 361         return {
 362                 signature => $sig,
 363                 size => $size,
 364                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 365                 content => $buffer
 366         };
 367 }
 368
 369 sub _index_lookup {
 370         ##
 371         # Given index tag, lookup single entry in index and return .
 372         ##
 373         my $self = shift;
 374         my ($tag, $index) = @_;
 375
 376         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 377         if (!$location) { return; }
 378
 379         return $self->_load_tag( $location );
 380 }
 381
 382 sub _add_bucket {
 383         ##
 384         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 385         # plain (undigested) key and value.
 386         ##
 387         my $self = shift;
 388         my ($tag, $md5, $plain_key, $value) = @_;
 389         my $keys = $tag->{content};
 390         my $location = 0;
 391         my $result = 2;
 392
 393         # added ref() check first to avoid eval and runtime exception for every
 394         # scalar value being stored.  performance tweak.
 395     my $is_dbm_deep = ref($value) && eval { $value->isa( 'DBM::Deep' ) };
 396
 397         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 398
 399     my $fh = $self->fh;
 400
 401         ##
 402         # Iterate through buckets, seeing if this is a new entry or a replace.
 403         ##
 404         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 405                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 406                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 407                 if (!$subloc) {
 408                         ##
 409                         # Found empty bucket (end of list).  Populate and exit loop.
 410                         ##
 411                         $result = 2;
 412
 413             $location = $internal_ref
 414                 ? $value->base_offset
 415                 : $self->root->{end};
 416
 417                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 418                         print($fh $md5 . pack($LONG_PACK, $location) );
 419                         last;
 420                 }
 421                 elsif ($md5 eq $key) {
 422                         ##
 423                         # Found existing bucket with same key.  Replace with new value.
 424                         ##
 425                         $result = 1;
 426
 427                         if ($internal_ref) {
 428                                 $location = $value->base_offset;
 429                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 430                                 print($fh $md5 . pack($LONG_PACK, $location) );
 431                         }
 432                         else {
 433                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 434                                 my $size;
 435                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 436
 437                                 ##
 438                                 # If value is a hash, array, or raw value with equal or less size, we can
 439                                 # reuse the same content area of the database.  Otherwise, we have to create
 440                                 # a new content area at the EOF.
 441                                 ##
 442                                 my $actual_length;
 443                 my $r = Scalar::Util::reftype( $value ) || '';
 444                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 445                         $actual_length = $INDEX_SIZE;
 446
 447                         # if autobless is enabled, must also take into consideration
 448                         # the class name, as it is stored along with key/value.
 449                         if ( $self->root->{autobless} ) {
 450                                                 my $value_class = Scalar::Util::blessed($value);
 451                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 452                                                         $actual_length += length($value_class);
 453                                                 }
 454                                         } # autobless
 455                 }
 456                                 else { $actual_length = length($value); }
 457
 458                                 if ($actual_length <= $size) {
 459                                         $location = $subloc;
 460                                 }
 461                                 else {
 462                                         $location = $self->root->{end};
 463                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 464                                         print($fh pack($LONG_PACK, $location) );
 465                                 }
 466                         }
 467                         last;
 468                 }
 469         } # i loop
 470
 471         ##
 472         # If this is an internal reference, return now.
 473         # No need to write value or plain key
 474         ##
 475         if ($internal_ref) {
 476         return $result;
 477     }
 478
 479         ##
 480         # If bucket didn't fit into list, split into a new index level
 481         ##
 482         if (!$location) {
 483                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 484                 print($fh pack($LONG_PACK, $self->root->{end}) );
 485
 486                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 487                 my @offsets = ();
 488
 489                 $keys .= $md5 . pack($LONG_PACK, 0);
 490
 491                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 492                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 493                         if ($key) {
 494                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 495                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 496
 497                                 if ($offsets[$num]) {
 498                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 499                                         seek($fh, $offset, SEEK_SET);
 500                                         my $subkeys;
 501                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 502
 503                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 504                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 505                                                 if (!$subloc) {
 506                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 507                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 508                                                         last;
 509                                                 }
 510                                         } # k loop
 511                                 }
 512                                 else {
 513                                         $offsets[$num] = $self->root->{end};
 514                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 515                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 516
 517                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 518
 519                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 520                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 521                                 }
 522                         } # key is real
 523                 } # i loop
 524
 525                 $location ||= $self->root->{end};
 526         } # re-index bucket list
 527
 528         ##
 529         # Seek to content area and store signature, value and plaintext key
 530         ##
 531         if ($location) {
 532                 my $content_length;
 533                 seek($fh, $location, SEEK_SET);
 534
 535                 ##
 536                 # Write signature based on content type, set content length and write actual value.
 537                 ##
 538         my $r = Scalar::Util::reftype($value) || '';
 539                 if ($r eq 'HASH') {
 540                         print($fh TYPE_HASH );
 541                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 542                         $content_length = $INDEX_SIZE;
 543                 }
 544                 elsif ($r eq 'ARRAY') {
 545                         print($fh TYPE_ARRAY );
 546                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 547                         $content_length = $INDEX_SIZE;
 548                 }
 549                 elsif (!defined($value)) {
 550                         print($fh SIG_NULL );
 551                         print($fh pack($DATA_LENGTH_PACK, 0) );
 552                         $content_length = 0;
 553                 }
 554                 else {
 555                         print($fh SIG_DATA );
 556                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 557                         $content_length = length($value);
 558                 }
 559
 560                 ##
 561                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 562                 ##
 563                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 564
 565                 ##
 566                 # If value is blessed, preserve class name
 567                 ##
 568                 if ( $self->root->{autobless} ) {
 569             my $value_class = Scalar::Util::blessed($value);
 570             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 571                 ##
 572                 # Blessed ref -- will restore later
 573                 ##
 574                 print($fh chr(1) );
 575                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 576                 $content_length += 1;
 577                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 578             }
 579             else {
 580                 print($fh chr(0) );
 581                 $content_length += 1;
 582             }
 583         }
 584
 585                 ##
 586                 # If this is a new content area, advance EOF counter
 587                 ##
 588                 if ($location == $self->root->{end}) {
 589                         $self->root->{end} += SIG_SIZE;
 590                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 591                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 592                 }
 593
 594                 ##
 595                 # If content is a hash or array, create new child DeepDB object and
 596                 # pass each key or element to it.
 597                 ##
 598                 if ($r eq 'HASH') {
 599                         my $branch = DBM::Deep->new(
 600                                 type => TYPE_HASH,
 601                                 base_offset => $location,
 602                                 root => $self->root,
 603                         );
 604                         foreach my $key (keys %{$value}) {
 605                 #$branch->{$key} = $value->{$key};
 606                 $branch->STORE( $key, $value->{$key} );
 607                         }
 608                 }
 609                 elsif ($r eq 'ARRAY') {
 610                         my $branch = DBM::Deep->new(
 611                                 type => TYPE_ARRAY,
 612                                 base_offset => $location,
 613                                 root => $self->root,
 614                         );
 615                         my $index = 0;
 616                         foreach my $element (@{$value}) {
 617                 #$branch->[$index] = $element;
 618                 $branch->STORE( $index, $element );
 619                                 $index++;
 620                         }
 621                 }
 622
 623                 return $result;
 624         }
 625
 626         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 627 }
 628
 629 sub _get_bucket_value {
 630         ##
 631         # Fetch single value given tag and MD5 digested key.
 632         ##
 633         my $self = shift;
 634         my ($tag, $md5) = @_;
 635         my $keys = $tag->{content};
 636
 637     my $fh = $self->fh;
 638
 639         ##
 640         # Iterate through buckets, looking for a key match
 641         ##
 642     BUCKET:
 643         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 644                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 645                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 646
 647                 if (!$subloc) {
 648                         ##
 649                         # Hit end of list, no match
 650                         ##
 651                         return;
 652                 }
 653
 654         if ( $md5 ne $key ) {
 655             next BUCKET;
 656         }
 657
 658         ##
 659         # Found match -- seek to offset and read signature
 660         ##
 661         my $signature;
 662         seek($fh, $subloc, SEEK_SET);
 663         read( $fh, $signature, SIG_SIZE);
 664
 665         ##
 666         # If value is a hash or array, return new DeepDB object with correct offset
 667         ##
 668         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 669             my $obj = DBM::Deep->new(
 670                 type => $signature,
 671                 base_offset => $subloc,
 672                 root => $self->root
 673             );
 674
 675             if ($self->root->{autobless}) {
 676                 ##
 677                 # Skip over value and plain key to see if object needs
 678                 # to be re-blessed
 679                 ##
 680                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 681
 682                 my $size;
 683                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 684                 if ($size) { seek($fh, $size, SEEK_CUR); }
 685
 686                 my $bless_bit;
 687                 read( $fh, $bless_bit, 1);
 688                 if (ord($bless_bit)) {
 689                     ##
 690                     # Yes, object needs to be re-blessed
 691                     ##
 692                     my $class_name;
 693                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 694                     if ($size) { read( $fh, $class_name, $size); }
 695                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 696                 }
 697             }
 698
 699             return $obj;
 700         }
 701
 702         ##
 703         # Otherwise return actual value
 704         ##
 705         elsif ($signature eq SIG_DATA) {
 706             my $size;
 707             my $value = '';
 708             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 709             if ($size) { read( $fh, $value, $size); }
 710             return $value;
 711         }
 712
 713         ##
 714         # Key exists, but content is null
 715         ##
 716         else { return; }
 717         } # i loop
 718
 719         return;
 720 }
 721
 722 sub _delete_bucket {
 723         ##
 724         # Delete single key/value pair given tag and MD5 digested key.
 725         ##
 726         my $self = shift;
 727         my ($tag, $md5) = @_;
 728         my $keys = $tag->{content};
 729
 730     my $fh = $self->fh;
 731
 732         ##
 733         # Iterate through buckets, looking for a key match
 734         ##
 735     BUCKET:
 736         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 737                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 738                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 739
 740                 if (!$subloc) {
 741                         ##
 742                         # Hit end of list, no match
 743                         ##
 744                         return;
 745                 }
 746
 747         if ( $md5 ne $key ) {
 748             next BUCKET;
 749         }
 750
 751         ##
 752         # Matched key -- delete bucket and return
 753         ##
 754         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 755         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 756         print($fh chr(0) x $BUCKET_SIZE );
 757
 758         return 1;
 759         } # i loop
 760
 761         return;
 762 }
 763
 764 sub _bucket_exists {
 765         ##
 766         # Check existence of single key given tag and MD5 digested key.
 767         ##
 768         my $self = shift;
 769         my ($tag, $md5) = @_;
 770         my $keys = $tag->{content};
 771
 772         ##
 773         # Iterate through buckets, looking for a key match
 774         ##
 775     BUCKET:
 776         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 777                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 778                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 779
 780                 if (!$subloc) {
 781                         ##
 782                         # Hit end of list, no match
 783                         ##
 784                         return;
 785                 }
 786
 787         if ( $md5 ne $key ) {
 788             next BUCKET;
 789         }
 790
 791         ##
 792         # Matched key -- return true
 793         ##
 794         return 1;
 795         } # i loop
 796
 797         return;
 798 }
 799
 800 sub _find_bucket_list {
 801         ##
 802         # Locate offset for bucket list, given digested key
 803         ##
 804         my $self = shift;
 805         my $md5 = shift;
 806
 807         ##
 808         # Locate offset for bucket list using digest index system
 809         ##
 810         my $ch = 0;
 811         my $tag = $self->_load_tag($self->base_offset);
 812         if (!$tag) { return; }
 813
 814         while ($tag->{signature} ne SIG_BLIST) {
 815                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 816                 if (!$tag) { return; }
 817                 $ch++;
 818         }
 819
 820         return $tag;
 821 }
 822
 823 sub _traverse_index {
 824         ##
 825         # Scan index and recursively step into deeper levels, looking for next key.
 826         ##
 827     my ($self, $offset, $ch, $force_return_next) = @_;
 828     $force_return_next = undef unless $force_return_next;
 829
 830         my $tag = $self->_load_tag( $offset );
 831
 832     my $fh = $self->fh;
 833
 834         if ($tag->{signature} ne SIG_BLIST) {
 835                 my $content = $tag->{content};
 836                 my $start;
 837                 if ($self->{return_next}) { $start = 0; }
 838                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 839
 840                 for (my $index = $start; $index < 256; $index++) {
 841                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 842                         if ($subloc) {
 843                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 844                                 if (defined($result)) { return $result; }
 845                         }
 846                 } # index loop
 847
 848                 $self->{return_next} = 1;
 849         } # tag is an index
 850
 851         elsif ($tag->{signature} eq SIG_BLIST) {
 852                 my $keys = $tag->{content};
 853                 if ($force_return_next) { $self->{return_next} = 1; }
 854
 855                 ##
 856                 # Iterate through buckets, looking for a key match
 857                 ##
 858                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 859                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 860                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 861
 862                         if (!$subloc) {
 863                                 ##
 864                                 # End of bucket list -- return to outer loop
 865                                 ##
 866                                 $self->{return_next} = 1;
 867                                 last;
 868                         }
 869                         elsif ($key eq $self->{prev_md5}) {
 870                                 ##
 871                                 # Located previous key -- return next one found
 872                                 ##
 873                                 $self->{return_next} = 1;
 874                                 next;
 875                         }
 876                         elsif ($self->{return_next}) {
 877                                 ##
 878                                 # Seek to bucket location and skip over signature
 879                                 ##
 880                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 881
 882                                 ##
 883                                 # Skip over value to get to plain key
 884                                 ##
 885                                 my $size;
 886                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 887                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 888
 889                                 ##
 890                                 # Read in plain key and return as scalar
 891                                 ##
 892                                 my $plain_key;
 893                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 894                                 if ($size) { read( $fh, $plain_key, $size); }
 895
 896                                 return $plain_key;
 897                         }
 898                 } # bucket loop
 899
 900                 $self->{return_next} = 1;
 901         } # tag is a bucket list
 902
 903         return;
 904 }
 905
 906 sub _get_next_key {
 907         ##
 908         # Locate next key, given digested previous one
 909         ##
 910     my $self = $_[0]->_get_self;
 911
 912         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 913         $self->{return_next} = 0;
 914
 915         ##
 916         # If the previous key was not specifed, start at the top and
 917         # return the first one found.
 918         ##
 919         if (!$self->{prev_md5}) {
 920                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 921                 $self->{return_next} = 1;
 922         }
 923
 924         return $self->_traverse_index( $self->base_offset, 0 );
 925 }
 926
 927 sub lock {
 928         ##
 929         # If db locking is set, flock() the db file.  If called multiple
 930         # times before unlock(), then the same number of unlocks() must
 931         # be called before the lock is released.
 932         ##
 933     my $self = $_[0]->_get_self;
 934         my $type = $_[1];
 935     $type = LOCK_EX unless defined $type;
 936
 937         if (!defined($self->fh)) { return; }
 938
 939         if ($self->root->{locking}) {
 940                 if (!$self->root->{locked}) {
 941                         flock($self->fh, $type);
 942
 943                         # double-check file inode, in case another process
 944                         # has optimize()d our file while we were waiting.
 945                         if ((stat($self->root->{file}))[1] != $self->root->{inode}) {
 946                                 $self->_open(); # re-open
 947                                 flock($self->fh, $type); # re-lock
 948                         }
 949                 }
 950                 $self->root->{locked}++;
 951
 952         return 1;
 953         }
 954
 955     return;
 956 }
 957
 958 sub unlock {
 959         ##
 960         # If db locking is set, unlock the db file.  See note in lock()
 961         # regarding calling lock() multiple times.
 962         ##
 963     my $self = $_[0]->_get_self;
 964
 965         if (!defined($self->fh)) { return; }
 966
 967         if ($self->root->{locking} && $self->root->{locked} > 0) {
 968                 $self->root->{locked}--;
 969                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 970
 971         return 1;
 972         }
 973
 974     return;
 975 }
 976
 977 #XXX These uses of ref() need verified
 978 sub _copy_node {
 979         ##
 980         # Copy single level of keys or elements to new DB handle.
 981         # Recurse for nested structures
 982         ##
 983     my $self = $_[0]->_get_self;
 984         my $db_temp = $_[1];
 985
 986         if ($self->type eq TYPE_HASH) {
 987                 my $key = $self->first_key();
 988                 while ($key) {
 989                         my $value = $self->get($key);
 990 #XXX This doesn't work with autobless
 991                         if (!ref($value)) { $db_temp->{$key} = $value; }
 992                         else {
 993                                 my $type = $value->type;
 994                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 995                                 else { $db_temp->{$key} = []; }
 996                                 $value->_copy_node( $db_temp->{$key} );
 997                         }
 998                         $key = $self->next_key($key);
 999                 }
1000         }
1001         else {
1002                 my $length = $self->length();
1003                 for (my $index = 0; $index < $length; $index++) {
1004                         my $value = $self->get($index);
1005                         if (!ref($value)) { $db_temp->[$index] = $value; }
1006             #XXX NO tests for this code
1007                         else {
1008                                 my $type = $value->type;
1009                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
1010                                 else { $db_temp->[$index] = []; }
1011                                 $value->_copy_node( $db_temp->[$index] );
1012                         }
1013                 }
1014         }
1015 }
1016
1017 sub export {
1018         ##
1019         # Recursively export into standard Perl hashes and arrays.
1020         ##
1021     my $self = $_[0]->_get_self;
1022
1023         my $temp;
1024         if ($self->type eq TYPE_HASH) { $temp = {}; }
1025         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1026
1027         $self->lock();
1028         $self->_copy_node( $temp );
1029         $self->unlock();
1030
1031         return $temp;
1032 }
1033
1034 sub import {
1035         ##
1036         # Recursively import Perl hash/array structure
1037         ##
1038     #XXX This use of ref() seems to be ok
1039         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1040
1041     my $self = $_[0]->_get_self;
1042         my $struct = $_[1];
1043
1044     #XXX This use of ref() seems to be ok
1045         if (!ref($struct)) {
1046                 ##
1047                 # struct is not a reference, so just import based on our type
1048                 ##
1049                 shift @_;
1050
1051                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1052                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1053         }
1054
1055     my $r = Scalar::Util::reftype($struct) || '';
1056         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1057                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1058         }
1059         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1060                 $self->push( @$struct );
1061         }
1062         else {
1063                 return $self->_throw_error("Cannot import: type mismatch");
1064         }
1065
1066         return 1;
1067 }
1068
1069 sub optimize {
1070         ##
1071         # Rebuild entire database into new file, then move
1072         # it back on top of original.
1073         ##
1074     my $self = $_[0]->_get_self;
1075
1076 #XXX Need to create a new test for this
1077 #       if ($self->root->{links} > 1) {
1078 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1079 #       }
1080
1081         my $db_temp = DBM::Deep->new(
1082                 file => $self->root->{file} . '.tmp',
1083                 type => $self->type
1084         );
1085         if (!$db_temp) {
1086                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1087         }
1088
1089         $self->lock();
1090         $self->_copy_node( $db_temp );
1091         undef $db_temp;
1092
1093         ##
1094         # Attempt to copy user, group and permissions over to new file
1095         ##
1096         my @stats = stat($self->fh);
1097         my $perms = $stats[2] & 07777;
1098         my $uid = $stats[4];
1099         my $gid = $stats[5];
1100         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1101         chmod( $perms, $self->root->{file} . '.tmp' );
1102
1103     # q.v. perlport for more information on this variable
1104     if ( $^O eq 'MSWin32' ) {
1105                 ##
1106                 # Potential race condition when optmizing on Win32 with locking.
1107                 # The Windows filesystem requires that the filehandle be closed
1108                 # before it is overwritten with rename().  This could be redone
1109                 # with a soft copy.
1110                 ##
1111                 $self->unlock();
1112                 $self->_close();
1113         }
1114
1115         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1116                 unlink $self->root->{file} . '.tmp';
1117                 $self->unlock();
1118                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1119         }
1120
1121         $self->unlock();
1122         $self->_close();
1123         $self->_open();
1124
1125         return 1;
1126 }
1127
1128 sub clone {
1129         ##
1130         # Make copy of object and return
1131         ##
1132     my $self = $_[0]->_get_self;
1133
1134         return DBM::Deep->new(
1135                 type => $self->type,
1136                 base_offset => $self->base_offset,
1137                 root => $self->root
1138         );
1139 }
1140
1141 {
1142     my %is_legal_filter = map {
1143         $_ => ~~1,
1144     } qw(
1145         store_key store_value
1146         fetch_key fetch_value
1147     );
1148
1149     sub set_filter {
1150         ##
1151         # Setup filter function for storing or fetching the key or value
1152         ##
1153         my $self = $_[0]->_get_self;
1154         my $type = lc $_[1];
1155         my $func = $_[2] ? $_[2] : undef;
1156
1157         if ( $is_legal_filter{$type} ) {
1158             $self->root->{"filter_$type"} = $func;
1159             return 1;
1160         }
1161
1162         return;
1163     }
1164 }
1165
1166 ##
1167 # Accessor methods
1168 ##
1169
1170 sub root {
1171         ##
1172         # Get access to the root structure
1173         ##
1174     my $self = $_[0]->_get_self;
1175         return $self->{root};
1176 }
1177
1178 sub fh {
1179         ##
1180         # Get access to the raw FileHandle
1181         ##
1182     #XXX It will be useful, though, when we split out HASH and ARRAY
1183     my $self = $_[0]->_get_self;
1184         return $self->root->{fh};
1185 }
1186
1187 sub type {
1188         ##
1189         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1190         ##
1191     my $self = $_[0]->_get_self;
1192         return $self->{type};
1193 }
1194
1195 sub base_offset {
1196         ##
1197         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1198         ##
1199     my $self = $_[0]->_get_self;
1200         return $self->{base_offset};
1201 }
1202
1203 sub error {
1204         ##
1205         # Get last error string, or undef if no error
1206         ##
1207         return $_[0]
1208         #? ( _get_self($_[0])->{root}->{error} or undef )
1209         ? ( $_[0]->_get_self->{root}->{error} or undef )
1210         : $@;
1211 }
1212
1213 ##
1214 # Utility methods
1215 ##
1216
1217 sub _throw_error {
1218         ##
1219         # Store error string in self
1220         ##
1221     my $self = $_[0]->_get_self;
1222         my $error_text = $_[1];
1223
1224     if ( Scalar::Util::blessed $self ) {
1225         $self->root->{error} = $error_text;
1226
1227         unless ($self->root->{debug}) {
1228             die "DBM::Deep: $error_text\n";
1229         }
1230
1231         warn "DBM::Deep: $error_text\n";
1232         return;
1233     }
1234     else {
1235         die "DBM::Deep: $error_text\n";
1236     }
1237 }
1238
1239 sub clear_error {
1240         ##
1241         # Clear error state
1242         ##
1243     my $self = $_[0]->_get_self;
1244
1245         undef $self->root->{error};
1246 }
1247
1248 sub precalc_sizes {
1249         ##
1250         # Precalculate index, bucket and bucket list sizes
1251         ##
1252
1253     #XXX I don't like this ...
1254     set_pack() unless defined $LONG_SIZE;
1255
1256         $INDEX_SIZE = 256 * $LONG_SIZE;
1257         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1258         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1259 }
1260
1261 sub set_pack {
1262         ##
1263         # Set pack/unpack modes (see file header for more)
1264         ##
1265     my ($long_s, $long_p, $data_s, $data_p) = @_;
1266
1267     $LONG_SIZE = $long_s ? $long_s : 4;
1268     $LONG_PACK = $long_p ? $long_p : 'N';
1269
1270     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1271     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1272
1273         precalc_sizes();
1274 }
1275
1276 sub set_digest {
1277         ##
1278         # Set key digest function (default is MD5)
1279         ##
1280     my ($digest_func, $hash_size) = @_;
1281
1282     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1283     $HASH_SIZE = $hash_size ? $hash_size : 16;
1284
1285         precalc_sizes();
1286 }
1287
1288 ##
1289 # tie() methods (hashes and arrays)
1290 ##
1291
1292 sub STORE {
1293         ##
1294         # Store single hash key/value or array element in database.
1295         ##
1296     my $self = $_[0]->_get_self;
1297         my $key = $_[1];
1298
1299     # User may be storing a hash, in which case we do not want it run
1300     # through the filtering system
1301         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1302         ? $self->root->{filter_store_value}->($_[2])
1303         : $_[2];
1304
1305         my $md5 = $DIGEST_FUNC->($key);
1306
1307         ##
1308         # Make sure file is open
1309         ##
1310         if (!defined($self->fh) && !$self->_open()) {
1311                 return;
1312         }
1313         ##
1314
1315         ##
1316         # Request exclusive lock for writing
1317         ##
1318         $self->lock( LOCK_EX );
1319
1320         my $fh = $self->fh;
1321
1322         ##
1323         # If locking is enabled, set 'end' parameter again, in case another
1324         # DB instance appended to our file while we were unlocked.
1325         ##
1326         if ($self->root->{locking} || $self->root->{volatile}) {
1327                 $self->root->{end} = (stat($fh))[7];
1328         }
1329
1330         ##
1331         # Locate offset for bucket list using digest index system
1332         ##
1333         my $tag = $self->_load_tag($self->base_offset);
1334         if (!$tag) {
1335                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1336         }
1337
1338         my $ch = 0;
1339         while ($tag->{signature} ne SIG_BLIST) {
1340                 my $num = ord(substr($md5, $ch, 1));
1341                 my $new_tag = $self->_index_lookup($tag, $num);
1342                 if (!$new_tag) {
1343                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1344                         seek($fh, $ref_loc, SEEK_SET);
1345                         print($fh pack($LONG_PACK, $self->root->{end}) );
1346
1347                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1348                         $tag->{ref_loc} = $ref_loc;
1349                         $tag->{ch} = $ch;
1350                         last;
1351                 }
1352                 else {
1353                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1354                         $tag = $new_tag;
1355                         $tag->{ref_loc} = $ref_loc;
1356                         $tag->{ch} = $ch;
1357                 }
1358                 $ch++;
1359         }
1360
1361         ##
1362         # Add key/value to bucket list
1363         ##
1364         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1365
1366         $self->unlock();
1367
1368         return $result;
1369 }
1370
1371 sub FETCH {
1372         ##
1373         # Fetch single value or element given plain key or array index
1374         ##
1375     my $self = shift->_get_self;
1376     my $key = shift;
1377
1378         ##
1379         # Make sure file is open
1380         ##
1381         if (!defined($self->fh)) { $self->_open(); }
1382
1383         my $md5 = $DIGEST_FUNC->($key);
1384
1385         ##
1386         # Request shared lock for reading
1387         ##
1388         $self->lock( LOCK_SH );
1389
1390         my $tag = $self->_find_bucket_list( $md5 );
1391         if (!$tag) {
1392                 $self->unlock();
1393                 return;
1394         }
1395
1396         ##
1397         # Get value from bucket list
1398         ##
1399         my $result = $self->_get_bucket_value( $tag, $md5 );
1400
1401         $self->unlock();
1402
1403     #XXX What is ref() checking here?
1404     #YYY Filters only apply on scalar values, so the ref check is making
1405     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1406         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1407         ? $self->root->{filter_fetch_value}->($result)
1408         : $result;
1409 }
1410
1411 sub DELETE {
1412         ##
1413         # Delete single key/value pair or element given plain key or array index
1414         ##
1415     my $self = $_[0]->_get_self;
1416         my $key = $_[1];
1417
1418         my $md5 = $DIGEST_FUNC->($key);
1419
1420         ##
1421         # Make sure file is open
1422         ##
1423         if (!defined($self->fh)) { $self->_open(); }
1424
1425         ##
1426         # Request exclusive lock for writing
1427         ##
1428         $self->lock( LOCK_EX );
1429
1430         my $tag = $self->_find_bucket_list( $md5 );
1431         if (!$tag) {
1432                 $self->unlock();
1433                 return;
1434         }
1435
1436         ##
1437         # Delete bucket
1438         ##
1439     my $value = $self->_get_bucket_value( $tag, $md5 );
1440         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1441         $value = $self->root->{filter_fetch_value}->($value);
1442     }
1443
1444         my $result = $self->_delete_bucket( $tag, $md5 );
1445
1446         ##
1447         # If this object is an array and the key deleted was on the end of the stack,
1448         # decrement the length variable.
1449         ##
1450
1451         $self->unlock();
1452
1453         return $value;
1454 }
1455
1456 sub EXISTS {
1457         ##
1458         # Check if a single key or element exists given plain key or array index
1459         ##
1460     my $self = $_[0]->_get_self;
1461         my $key = $_[1];
1462
1463         my $md5 = $DIGEST_FUNC->($key);
1464
1465         ##
1466         # Make sure file is open
1467         ##
1468         if (!defined($self->fh)) { $self->_open(); }
1469
1470         ##
1471         # Request shared lock for reading
1472         ##
1473         $self->lock( LOCK_SH );
1474
1475         my $tag = $self->_find_bucket_list( $md5 );
1476
1477         ##
1478         # For some reason, the built-in exists() function returns '' for false
1479         ##
1480         if (!$tag) {
1481                 $self->unlock();
1482                 return '';
1483         }
1484
1485         ##
1486         # Check if bucket exists and return 1 or ''
1487         ##
1488         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1489
1490         $self->unlock();
1491
1492         return $result;
1493 }
1494
1495 sub CLEAR {
1496         ##
1497         # Clear all keys from hash, or all elements from array.
1498         ##
1499     my $self = $_[0]->_get_self;
1500
1501         ##
1502         # Make sure file is open
1503         ##
1504         if (!defined($self->fh)) { $self->_open(); }
1505
1506         ##
1507         # Request exclusive lock for writing
1508         ##
1509         $self->lock( LOCK_EX );
1510
1511     my $fh = $self->fh;
1512
1513         seek($fh, $self->base_offset, SEEK_SET);
1514         if (eof $fh) {
1515                 $self->unlock();
1516                 return;
1517         }
1518
1519         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1520
1521         $self->unlock();
1522
1523         return 1;
1524 }
1525
1526 ##
1527 # Public method aliases
1528 ##
1529 sub put { (shift)->STORE( @_ ) }
1530 sub store { (shift)->STORE( @_ ) }
1531 sub get { (shift)->FETCH( @_ ) }
1532 sub fetch { (shift)->FETCH( @_ ) }
1533 sub delete { (shift)->DELETE( @_ ) }
1534 sub exists { (shift)->EXISTS( @_ ) }
1535 sub clear { (shift)->CLEAR( @_ ) }
1536
1537 package DBM::Deep::_::Root;
1538
1539 sub new {
1540     my $class = shift;
1541     my ($args) = @_;
1542
1543     my $self = bless {
1544         file => undef,
1545         fh => undef,
1546         end => 0,
1547         autoflush => undef,
1548         locking => undef,
1549         volatile => undef,
1550         debug => undef,
1551         mode => 'r+',
1552         filter_store_key => undef,
1553         filter_store_value => undef,
1554         filter_fetch_key => undef,
1555         filter_fetch_value => undef,
1556         autobless => undef,
1557         locked => 0,
1558         %$args,
1559     }, $class;
1560
1561     return $self;
1562 }
1563
1564 sub DESTROY {
1565     my $self = shift;
1566     return unless $self;
1567
1568     close $self->{fh} if $self->{fh};
1569
1570     return;
1571 }
1572
1573 1;
1574
1575 __END__
1576
1577 =head1 NAME
1578
1579 DBM::Deep - A pure perl multi-level hash/array DBM
1580
1581 =head1 SYNOPSIS
1582
1583   use DBM::Deep;
1584   my $db = DBM::Deep->new( "foo.db" );
1585
1586   $db->{key} = 'value'; # tie() style
1587   print $db->{key};
1588
1589   $db->put('key', 'value'); # OO style
1590   print $db->get('key');
1591
1592   # true multi-level support
1593   $db->{my_complex} = [
1594         'hello', { perl => 'rules' },
1595         42, 99 ];
1596
1597 =head1 DESCRIPTION
1598
1599 A unique flat-file database module, written in pure perl.  True
1600 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1601 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1602 handle millions of keys and unlimited hash levels without significant
1603 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1604 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1605 Mac OS X and Windows.
1606
1607 =head1 INSTALLATION
1608
1609 Hopefully you are using CPAN's excellent Perl module, which will download
1610 and install the module for you.  If not, get the tarball, and run these
1611 commands:
1612
1613         tar zxf DBM-Deep-*
1614         cd DBM-Deep-*
1615         perl Makefile.PL
1616         make
1617         make test
1618         make install
1619
1620 =head1 SETUP
1621
1622 Construction can be done OO-style (which is the recommended way), or using
1623 Perl's tie() function.  Both are examined here.
1624
1625 =head2 OO CONSTRUCTION
1626
1627 The recommended way to construct a DBM::Deep object is to use the new()
1628 method, which gets you a blessed, tied hash or array reference.
1629
1630         my $db = DBM::Deep->new( "foo.db" );
1631
1632 This opens a new database handle, mapped to the file "foo.db".  If this
1633 file does not exist, it will automatically be created.  DB files are
1634 opened in "r+" (read/write) mode, and the type of object returned is a
1635 hash, unless otherwise specified (see L<OPTIONS> below).
1636
1637
1638
1639 You can pass a number of options to the constructor to specify things like
1640 locking, autoflush, etc.  This is done by passing an inline hash:
1641
1642         my $db = DBM::Deep->new(
1643                 file => "foo.db",
1644                 locking => 1,
1645                 autoflush => 1
1646         );
1647
1648 Notice that the filename is now specified I<inside> the hash with
1649 the "file" parameter, as opposed to being the sole argument to the
1650 constructor.  This is required if any options are specified.
1651 See L<OPTIONS> below for the complete list.
1652
1653
1654
1655 You can also start with an array instead of a hash.  For this, you must
1656 specify the C<type> parameter:
1657
1658         my $db = DBM::Deep->new(
1659                 file => "foo.db",
1660                 type => DBM::Deep->TYPE_ARRAY
1661         );
1662
1663 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1664 a new DB file.  If you create a DBM::Deep object with an existing file, the
1665 C<type> will be loaded from the file header, and ignored if it is passed
1666 to the constructor.
1667
1668 =head2 TIE CONSTRUCTION
1669
1670 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1671 tie() function.  This is not ideal, because you get only a basic, tied hash
1672 (or array) which is not blessed, so you can't call any functions on it.
1673
1674         my %hash;
1675         tie %hash, "DBM::Deep", "foo.db";
1676
1677         my @array;
1678         tie @array, "DBM::Deep", "bar.db";
1679
1680 As with the OO constructor, you can replace the DB filename parameter with
1681 a hash containing one or more options (see L<OPTIONS> just below for the
1682 complete list).
1683
1684         tie %hash, "DBM::Deep", {
1685                 file => "foo.db",
1686                 locking => 1,
1687                 autoflush => 1
1688         };
1689
1690 =head2 OPTIONS
1691
1692 There are a number of options that can be passed in when constructing your
1693 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1694
1695 =over
1696
1697 =item * file
1698
1699 Filename of the DB file to link the handle to.  You can pass a full absolute
1700 filesystem path, partial path, or a plain filename if the file is in the
1701 current working directory.  This is a required parameter.
1702
1703 =item * mode
1704
1705 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1706 module.  This is an optional parameter, and defaults to "r+" (read/write).
1707 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1708 created if it doesn't exist.
1709
1710 =item * type
1711
1712 This parameter specifies what type of object to create, a hash or array.  Use
1713 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1714 This only takes effect when beginning a new file.  This is an optional
1715 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1716
1717 =item * locking
1718
1719 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1720 function to lock the database in exclusive mode for writes, and shared mode for
1721 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1722 any child hashes or arrays> that use the same DB file.  This is an optional
1723 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1724
1725 =item * autoflush
1726
1727 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1728 This obviously slows down write operations, but is required if you may have
1729 multiple processes accessing the same DB file (also consider enable I<locking>
1730 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1731 parameter, and defaults to 0 (disabled).
1732
1733 =item * volatile
1734
1735 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1736 STORE() operation.  This is required if an outside force may change the size of
1737 the file between transactions.  Locking also implicitly enables volatile.  This
1738 is useful if you want to use a different locking system or write your own.  Pass
1739 any true value to enable.  This is an optional parameter, and defaults to 0
1740 (disabled).
1741
1742 =item * autobless
1743
1744 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1745 restore them when fetched.  This is an B<experimental> feature, and does have
1746 side-effects.  Basically, when hashes are re-blessed into their original
1747 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1748 able to call any DBM::Deep methods on them.  You have been warned.
1749 This is an optional parameter, and defaults to 0 (disabled).
1750
1751 =item * filter_*
1752
1753 See L<FILTERS> below.
1754
1755 =item * debug
1756
1757 Setting I<debug> mode will make all errors non-fatal, dump them out to
1758 STDERR, and continue on.  This is for debugging purposes only, and probably
1759 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1760
1761 =item * fh
1762
1763 Instead of passing a file path, you can instead pass a handle to an pre-opened
1764 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1765 contains your entire Perl script, as well as the data following the __DATA__
1766 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1767 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1768 in that.  Also please note optimize() will NOT work when passing in only a
1769 handle.  Pass in a real filename in order to use optimize().
1770
1771 =back
1772
1773 =head1 TIE INTERFACE
1774
1775 With DBM::Deep you can access your databases using Perl's standard hash/array
1776 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1777 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1778 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1779 section above.  This simply tells you how to use DBM::Deep using regular hashes
1780 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1781 work too).  It is entirely up to you how to want to access your databases.
1782
1783 =head2 HASHES
1784
1785 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1786 or even nested hashes (or arrays) using standard Perl syntax:
1787
1788         my $db = DBM::Deep->new( "foo.db" );
1789
1790         $db->{mykey} = "myvalue";
1791         $db->{myhash} = {};
1792         $db->{myhash}->{subkey} = "subvalue";
1793
1794         print $db->{myhash}->{subkey} . "\n";
1795
1796 You can even step through hash keys using the normal Perl C<keys()> function:
1797
1798         foreach my $key (keys %$db) {
1799                 print "$key: " . $db->{$key} . "\n";
1800         }
1801
1802 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1803 pushes them onto an array, all before the loop even begins.  If you have an
1804 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1805 Perl's C<each()> function, which pulls keys/values one at a time, using very
1806 little memory:
1807
1808         while (my ($key, $value) = each %$db) {
1809                 print "$key: $value\n";
1810         }
1811
1812 Please note that when using C<each()>, you should always pass a direct
1813 hash reference, not a lookup.  Meaning, you should B<never> do this:
1814
1815         # NEVER DO THIS
1816         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1817
1818 This causes an infinite loop, because for each iteration, Perl is calling
1819 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1820 it effectively keeps returning the first key over and over again. Instead,
1821 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1822
1823 =head2 ARRAYS
1824
1825 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1826 reference.  This includes inserting, removing and manipulating elements,
1827 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1828 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1829 or simply be a nested array reference inside a hash.  Example:
1830
1831         my $db = DBM::Deep->new(
1832                 file => "foo-array.db",
1833                 type => DBM::Deep->TYPE_ARRAY
1834         );
1835
1836         $db->[0] = "foo";
1837         push @$db, "bar", "baz";
1838         unshift @$db, "bah";
1839
1840         my $last_elem = pop @$db; # baz
1841         my $first_elem = shift @$db; # bah
1842         my $second_elem = $db->[1]; # bar
1843
1844         my $num_elements = scalar @$db;
1845
1846 =head1 OO INTERFACE
1847
1848 In addition to the I<tie()> interface, you can also use a standard OO interface
1849 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1850 array) has its own methods, but both types share the following common methods:
1851 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1852
1853 =over
1854
1855 =item * put()
1856
1857 Stores a new hash key/value pair, or sets an array element value.  Takes two
1858 arguments, the hash key or array index, and the new value.  The value can be
1859 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1860
1861         $db->put("foo", "bar"); # for hashes
1862         $db->put(1, "bar"); # for arrays
1863
1864 =item * get()
1865
1866 Fetches the value of a hash key or array element.  Takes one argument: the hash
1867 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1868 data type stored.
1869
1870         my $value = $db->get("foo"); # for hashes
1871         my $value = $db->get(1); # for arrays
1872
1873 =item * exists()
1874
1875 Checks if a hash key or array index exists.  Takes one argument: the hash key
1876 or array index.  Returns true if it exists, false if not.
1877
1878         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1879         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1880
1881 =item * delete()
1882
1883 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1884 key or array index.  Returns true on success, false if not found.  For arrays,
1885 the remaining elements located after the deleted element are NOT moved over.
1886 The deleted element is essentially just undefined, which is exactly how Perl's
1887 internal arrays work.  Please note that the space occupied by the deleted
1888 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1889 below for details and workarounds.
1890
1891         $db->delete("foo"); # for hashes
1892         $db->delete(1); # for arrays
1893
1894 =item * clear()
1895
1896 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1897 value.  Please note that the space occupied by the deleted keys/values or
1898 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1899 details and workarounds.
1900
1901         $db->clear(); # hashes or arrays
1902
1903 =back
1904
1905 =head2 HASHES
1906
1907 For hashes, DBM::Deep supports all the common methods described above, and the
1908 following additional methods: C<first_key()> and C<next_key()>.
1909
1910 =over
1911
1912 =item * first_key()
1913
1914 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1915 fetched in an undefined order (which appears random).  Takes no arguments,
1916 returns the key as a scalar value.
1917
1918         my $key = $db->first_key();
1919
1920 =item * next_key()
1921
1922 Returns the "next" key in the hash, given the previous one as the sole argument.
1923 Returns undef if there are no more keys to be fetched.
1924
1925         $key = $db->next_key($key);
1926
1927 =back
1928
1929 Here are some examples of using hashes:
1930
1931         my $db = DBM::Deep->new( "foo.db" );
1932
1933         $db->put("foo", "bar");
1934         print "foo: " . $db->get("foo") . "\n";
1935
1936         $db->put("baz", {}); # new child hash ref
1937         $db->get("baz")->put("buz", "biz");
1938         print "buz: " . $db->get("baz")->get("buz") . "\n";
1939
1940         my $key = $db->first_key();
1941         while ($key) {
1942                 print "$key: " . $db->get($key) . "\n";
1943                 $key = $db->next_key($key);
1944         }
1945
1946         if ($db->exists("foo")) { $db->delete("foo"); }
1947
1948 =head2 ARRAYS
1949
1950 For arrays, DBM::Deep supports all the common methods described above, and the
1951 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1952 C<unshift()> and C<splice()>.
1953
1954 =over
1955
1956 =item * length()
1957
1958 Returns the number of elements in the array.  Takes no arguments.
1959
1960         my $len = $db->length();
1961
1962 =item * push()
1963
1964 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1965 refs or array refs.  No return value.
1966
1967         $db->push("foo", "bar", {});
1968
1969 =item * pop()
1970
1971 Fetches the last element in the array, and deletes it.  Takes no arguments.
1972 Returns undef if array is empty.  Returns the element value.
1973
1974         my $elem = $db->pop();
1975
1976 =item * shift()
1977
1978 Fetches the first element in the array, deletes it, then shifts all the
1979 remaining elements over to take up the space.  Returns the element value.  This
1980 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1981 details.
1982
1983         my $elem = $db->shift();
1984
1985 =item * unshift()
1986
1987 Inserts one or more elements onto the beginning of the array, shifting all
1988 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1989 No return value.  This method is not recommended with large arrays -- see
1990 <LARGE ARRAYS> below for details.
1991
1992         $db->unshift("foo", "bar", {});
1993
1994 =item * splice()
1995
1996 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1997 -f splice> for usage -- it is too complicated to document here.  This method is
1998 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1999
2000 =back
2001
2002 Here are some examples of using arrays:
2003
2004         my $db = DBM::Deep->new(
2005                 file => "foo.db",
2006                 type => DBM::Deep->TYPE_ARRAY
2007         );
2008
2009         $db->push("bar", "baz");
2010         $db->unshift("foo");
2011         $db->put(3, "buz");
2012
2013         my $len = $db->length();
2014         print "length: $len\n"; # 4
2015
2016         for (my $k=0; $k<$len; $k++) {
2017                 print "$k: " . $db->get($k) . "\n";
2018         }
2019
2020         $db->splice(1, 2, "biz", "baf");
2021
2022         while (my $elem = shift @$db) {
2023                 print "shifted: $elem\n";
2024         }
2025
2026 =head1 LOCKING
2027
2028 Enable automatic file locking by passing a true value to the C<locking>
2029 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2030
2031         my $db = DBM::Deep->new(
2032                 file => "foo.db",
2033                 locking => 1
2034         );
2035
2036 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2037 mode for writes, and shared mode for reads.  This is required if you have
2038 multiple processes accessing the same database file, to avoid file corruption.
2039 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2040 NFS> below for more.
2041
2042 =head2 EXPLICIT LOCKING
2043
2044 You can explicitly lock a database, so it remains locked for multiple
2045 transactions.  This is done by calling the C<lock()> method, and passing an
2046 optional lock mode argument (defaults to exclusive mode).  This is particularly
2047 useful for things like counters, where the current value needs to be fetched,
2048 then incremented, then stored again.
2049
2050         $db->lock();
2051         my $counter = $db->get("counter");
2052         $counter++;
2053         $db->put("counter", $counter);
2054         $db->unlock();
2055
2056         # or...
2057
2058         $db->lock();
2059         $db->{counter}++;
2060         $db->unlock();
2061
2062 You can pass C<lock()> an optional argument, which specifies which mode to use
2063 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2064 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2065 same as the constants defined in Perl's C<Fcntl> module.
2066
2067         $db->lock( DBM::Deep->LOCK_SH );
2068         # something here
2069         $db->unlock();
2070
2071 If you want to implement your own file locking scheme, be sure to create your
2072 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2073 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2074 below for more.
2075
2076 =head1 IMPORTING/EXPORTING
2077
2078 You can import existing complex structures by calling the C<import()> method,
2079 and export an entire database into an in-memory structure using the C<export()>
2080 method.  Both are examined here.
2081
2082 =head2 IMPORTING
2083
2084 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2085 walking the structure and adding keys/elements to the database as you go,
2086 simply pass a reference to the C<import()> method.  This recursively adds
2087 everything to an existing DBM::Deep object for you.  Here is an example:
2088
2089         my $struct = {
2090                 key1 => "value1",
2091                 key2 => "value2",
2092                 array1 => [ "elem0", "elem1", "elem2" ],
2093                 hash1 => {
2094                         subkey1 => "subvalue1",
2095                         subkey2 => "subvalue2"
2096                 }
2097         };
2098
2099         my $db = DBM::Deep->new( "foo.db" );
2100         $db->import( $struct );
2101
2102         print $db->{key1} . "\n"; # prints "value1"
2103
2104 This recursively imports the entire C<$struct> object into C<$db>, including
2105 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2106 keys are merged with the existing ones, replacing if they already exist.
2107 The C<import()> method can be called on any database level (not just the base
2108 level), and works with both hash and array DB types.
2109
2110
2111
2112 B<Note:> Make sure your existing structure has no circular references in it.
2113 These will cause an infinite loop when importing.
2114
2115 =head2 EXPORTING
2116
2117 Calling the C<export()> method on an existing DBM::Deep object will return
2118 a reference to a new in-memory copy of the database.  The export is done
2119 recursively, so all nested hashes/arrays are all exported to standard Perl
2120 objects.  Here is an example:
2121
2122         my $db = DBM::Deep->new( "foo.db" );
2123
2124         $db->{key1} = "value1";
2125         $db->{key2} = "value2";
2126         $db->{hash1} = {};
2127         $db->{hash1}->{subkey1} = "subvalue1";
2128         $db->{hash1}->{subkey2} = "subvalue2";
2129
2130         my $struct = $db->export();
2131
2132         print $struct->{key1} . "\n"; # prints "value1"
2133
2134 This makes a complete copy of the database in memory, and returns a reference
2135 to it.  The C<export()> method can be called on any database level (not just
2136 the base level), and works with both hash and array DB types.  Be careful of
2137 large databases -- you can store a lot more data in a DBM::Deep object than an
2138 in-memory Perl structure.
2139
2140
2141
2142 B<Note:> Make sure your database has no circular references in it.
2143 These will cause an infinite loop when exporting.
2144
2145 =head1 FILTERS
2146
2147 DBM::Deep has a number of hooks where you can specify your own Perl function
2148 to perform filtering on incoming or outgoing data.  This is a perfect
2149 way to extend the engine, and implement things like real-time compression or
2150 encryption.  Filtering applies to the base DB level, and all child hashes /
2151 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2152 constructed, or by calling the C<set_filter()> method at any time.  There are
2153 four available filter hooks, described below:
2154
2155 =over
2156
2157 =item * filter_store_key
2158
2159 This filter is called whenever a hash key is stored.  It
2160 is passed the incoming key, and expected to return a transformed key.
2161
2162 =item * filter_store_value
2163
2164 This filter is called whenever a hash key or array element is stored.  It
2165 is passed the incoming value, and expected to return a transformed value.
2166
2167 =item * filter_fetch_key
2168
2169 This filter is called whenever a hash key is fetched (i.e. via
2170 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2171 and expected to return the plain key.
2172
2173 =item * filter_fetch_value
2174
2175 This filter is called whenever a hash key or array element is fetched.
2176 It is passed the transformed value, and expected to return the plain value.
2177
2178 =back
2179
2180 Here are the two ways to setup a filter hook:
2181
2182         my $db = DBM::Deep->new(
2183                 file => "foo.db",
2184                 filter_store_value => \&my_filter_store,
2185                 filter_fetch_value => \&my_filter_fetch
2186         );
2187
2188         # or...
2189
2190         $db->set_filter( "filter_store_value", \&my_filter_store );
2191         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2192
2193 Your filter function will be called only when dealing with SCALAR keys or
2194 values.  When nested hashes and arrays are being stored/fetched, filtering
2195 is bypassed.  Filters are called as static functions, passed a single SCALAR
2196 argument, and expected to return a single SCALAR value.  If you want to
2197 remove a filter, set the function reference to C<undef>:
2198
2199         $db->set_filter( "filter_store_value", undef );
2200
2201 =head2 REAL-TIME ENCRYPTION EXAMPLE
2202
2203 Here is a working example that uses the I<Crypt::Blowfish> module to
2204 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2205 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2206 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2207
2208         use DBM::Deep;
2209         use Crypt::Blowfish;
2210         use Crypt::CBC;
2211
2212         my $cipher = Crypt::CBC->new({
2213                 'key'             => 'my secret key',
2214                 'cipher'          => 'Blowfish',
2215                 'iv'              => '$KJh#(}q',
2216                 'regenerate_key'  => 0,
2217                 'padding'         => 'space',
2218                 'prepend_iv'      => 0
2219         });
2220
2221         my $db = DBM::Deep->new(
2222                 file => "foo-encrypt.db",
2223                 filter_store_key => \&my_encrypt,
2224                 filter_store_value => \&my_encrypt,
2225                 filter_fetch_key => \&my_decrypt,
2226                 filter_fetch_value => \&my_decrypt,
2227         );
2228
2229         $db->{key1} = "value1";
2230         $db->{key2} = "value2";
2231         print "key1: " . $db->{key1} . "\n";
2232         print "key2: " . $db->{key2} . "\n";
2233
2234         undef $db;
2235         exit;
2236
2237         sub my_encrypt {
2238                 return $cipher->encrypt( $_[0] );
2239         }
2240         sub my_decrypt {
2241                 return $cipher->decrypt( $_[0] );
2242         }
2243
2244 =head2 REAL-TIME COMPRESSION EXAMPLE
2245
2246 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2247 compression / decompression of keys & values with DBM::Deep Filters.
2248 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2249 more on I<Compress::Zlib>.
2250
2251         use DBM::Deep;
2252         use Compress::Zlib;
2253
2254         my $db = DBM::Deep->new(
2255                 file => "foo-compress.db",
2256                 filter_store_key => \&my_compress,
2257                 filter_store_value => \&my_compress,
2258                 filter_fetch_key => \&my_decompress,
2259                 filter_fetch_value => \&my_decompress,
2260         );
2261
2262         $db->{key1} = "value1";
2263         $db->{key2} = "value2";
2264         print "key1: " . $db->{key1} . "\n";
2265         print "key2: " . $db->{key2} . "\n";
2266
2267         undef $db;
2268         exit;
2269
2270         sub my_compress {
2271                 return Compress::Zlib::memGzip( $_[0] ) ;
2272         }
2273         sub my_decompress {
2274                 return Compress::Zlib::memGunzip( $_[0] ) ;
2275         }
2276
2277 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2278 actually numerical index numbers, and are not filtered.
2279
2280 =head1 ERROR HANDLING
2281
2282 Most DBM::Deep methods return a true value for success, and call die() on
2283 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2284 actual error message is stored in an internal scalar, which can be fetched by
2285 calling the C<error()> method.
2286
2287         my $db = DBM::Deep->new( "foo.db" ); # create hash
2288         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2289
2290         print $db->error(); # prints error message
2291
2292 You can then call C<clear_error()> to clear the current error state.
2293
2294         $db->clear_error();
2295
2296 If you set the C<debug> option to true when creating your DBM::Deep object,
2297 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2298 for debugging purposes.
2299
2300 =head1 LARGEFILE SUPPORT
2301
2302 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2303 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2304 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2305 by calling the static C<set_pack()> method before you do anything else.
2306
2307         DBM::Deep::set_pack(8, 'Q');
2308
2309 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2310 instead of 32-bit longs.  After setting these values your DB files have a
2311 theoretical maximum size of 16 XB (exabytes).
2312
2313
2314
2315 B<Note:> Changing these values will B<NOT> work for existing database files.
2316 Only change this for new files, and make sure it stays set consistently
2317 throughout the file's life.  If you do set these values, you can no longer
2318 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2319 back to 32-bit mode.
2320
2321
2322
2323 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2324 only a 32-bit Perl.  However, I have received user reports that this does
2325 indeed work!
2326
2327 =head1 LOW-LEVEL ACCESS
2328
2329 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2330 you can call the C<fh()> method, which returns the handle:
2331
2332         my $fh = $db->fh();
2333
2334 This method can be called on the root level of the datbase, or any child
2335 hashes or arrays.  All levels share a I<root> structure, which contains things
2336 like the FileHandle, a reference counter, and all your options you specified
2337 when you created the object.  You can get access to this root structure by
2338 calling the C<root()> method.
2339
2340         my $root = $db->root();
2341
2342 This is useful for changing options after the object has already been created,
2343 such as enabling/disabling locking, volatile or debug modes.  You can also
2344 store your own temporary user data in this structure (be wary of name
2345 collision), which is then accessible from any child hash or array.
2346
2347 =head1 CUSTOM DIGEST ALGORITHM
2348
2349 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2350 keys.  However you can override this, and use another algorithm (such as SHA-256)
2351 or even write your own.  But please note that DBM::Deep currently expects zero
2352 collisions, so your algorithm has to be I<perfect>, so to speak.
2353 Collision detection may be introduced in a later version.
2354
2355
2356
2357 You can specify a custom digest algorithm by calling the static C<set_digest()>
2358 function, passing a reference to a subroutine, and the length of the algorithm's
2359 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2360 objects.  Here is a working example that uses a 256-bit hash from the
2361 I<Digest::SHA256> module.  Please see
2362 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2363
2364         use DBM::Deep;
2365         use Digest::SHA256;
2366
2367         my $context = Digest::SHA256::new(256);
2368
2369         DBM::Deep::set_digest( \&my_digest, 32 );
2370
2371         my $db = DBM::Deep->new( "foo-sha.db" );
2372
2373         $db->{key1} = "value1";
2374         $db->{key2} = "value2";
2375         print "key1: " . $db->{key1} . "\n";
2376         print "key2: " . $db->{key2} . "\n";
2377
2378         undef $db;
2379         exit;
2380
2381         sub my_digest {
2382                 return substr( $context->hash($_[0]), 0, 32 );
2383         }
2384
2385 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2386 of bytes you specify in the C<set_digest()> function (in this case 32).
2387
2388 =head1 CIRCULAR REFERENCES
2389
2390 DBM::Deep has B<experimental> support for circular references.  Meaning you
2391 can have a nested hash key or array element that points to a parent object.
2392 This relationship is stored in the DB file, and is preserved between sessions.
2393 Here is an example:
2394
2395         my $db = DBM::Deep->new( "foo.db" );
2396
2397         $db->{foo} = "bar";
2398         $db->{circle} = $db; # ref to self
2399
2400         print $db->{foo} . "\n"; # prints "foo"
2401         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2402
2403 One catch is, passing the object to a function that recursively walks the
2404 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2405 C<export()> methods) will result in an infinite loop.  The other catch is,
2406 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2407 or C<next_key()> methods), you will get the I<target object's key>, not the
2408 ref's key.  This gets even more interesting with the above example, where
2409 the I<circle> key points to the base DB object, which technically doesn't
2410 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2411 special case.
2412
2413 =head1 CAVEATS / ISSUES / BUGS
2414
2415 This section describes all the known issues with DBM::Deep.  It you have found
2416 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2417
2418 =head2 UNUSED SPACE RECOVERY
2419
2420 One major caveat with DBM::Deep is that space occupied by existing keys and
2421 values is not recovered when they are deleted.  Meaning if you keep deleting
2422 and adding new keys, your file will continuously grow.  I am working on this,
2423 but in the meantime you can call the built-in C<optimize()> method from time to
2424 time (perhaps in a crontab or something) to recover all your unused space.
2425
2426         $db->optimize(); # returns true on success
2427
2428 This rebuilds the ENTIRE database into a new file, then moves it on top of
2429 the original.  The new file will have no unused space, thus it will take up as
2430 little disk space as possible.  Please note that this operation can take
2431 a long time for large files, and you need enough disk space to temporarily hold
2432 2 copies of your DB file.  The temporary file is created in the same directory
2433 as the original, named with a ".tmp" extension, and is deleted when the
2434 operation completes.  Oh, and if locking is enabled, the DB is automatically
2435 locked for the entire duration of the copy.
2436
2437
2438
2439 B<WARNING:> Only call optimize() on the top-level node of the database, and
2440 make sure there are no child references lying around.  DBM::Deep keeps a reference
2441 counter, and if it is greater than 1, optimize() will abort and return undef.
2442
2443 =head2 AUTOVIVIFICATION
2444
2445 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2446 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2447 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2448 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2449 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2450 this does not work:
2451
2452         $db->{foo}->{bar} = "hello";
2453
2454 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2455 being an empty hash.  Try this instead, which works fine:
2456
2457         $db->{foo} = { bar => "hello" };
2458
2459 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2460 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2461 Probably a bug in Perl.
2462
2463 =head2 FILE CORRUPTION
2464
2465 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2466 for a 32-bit signature when opened, but other corruption in files can cause
2467 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2468 stuck in an infinite loop depending on the level of corruption.  File write
2469 operations are not checked for failure (for speed), so if you happen to run
2470 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2471 be addressed in a later version of DBM::Deep.
2472
2473 =head2 DB OVER NFS
2474
2475 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2476 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2477 about setting up your NFS server with a locking daemon, then using lockf() to
2478 lock your files, but your milage may vary there as well.  From what I
2479 understand, there is no real way to do it.  However, if you need access to the
2480 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2481 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2482
2483 =head2 COPYING OBJECTS
2484
2485 Beware of copying tied objects in Perl.  Very strange things can happen.
2486 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2487 returns a new, blessed, tied hash or array to the same level in the DB.
2488
2489         my $copy = $db->clone();
2490
2491 =head2 LARGE ARRAYS
2492
2493 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2494 These functions cause every element in the array to move, which can be murder
2495 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2496 a different location.  This may be addressed in a later version.
2497
2498 =head1 PERFORMANCE
2499
2500 This section discusses DBM::Deep's speed and memory usage.
2501
2502 =head2 SPEED
2503
2504 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2505 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2506 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2507 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2508 with huge databases.  Here is some test data:
2509
2510         Adding 1,000,000 keys to new DB file...
2511
2512         At 100 keys, avg. speed is 2,703 keys/sec
2513         At 200 keys, avg. speed is 2,642 keys/sec
2514         At 300 keys, avg. speed is 2,598 keys/sec
2515         At 400 keys, avg. speed is 2,578 keys/sec
2516         At 500 keys, avg. speed is 2,722 keys/sec
2517         At 600 keys, avg. speed is 2,628 keys/sec
2518         At 700 keys, avg. speed is 2,700 keys/sec
2519         At 800 keys, avg. speed is 2,607 keys/sec
2520         At 900 keys, avg. speed is 2,190 keys/sec
2521         At 1,000 keys, avg. speed is 2,570 keys/sec
2522         At 2,000 keys, avg. speed is 2,417 keys/sec
2523         At 3,000 keys, avg. speed is 1,982 keys/sec
2524         At 4,000 keys, avg. speed is 1,568 keys/sec
2525         At 5,000 keys, avg. speed is 1,533 keys/sec
2526         At 6,000 keys, avg. speed is 1,787 keys/sec
2527         At 7,000 keys, avg. speed is 1,977 keys/sec
2528         At 8,000 keys, avg. speed is 2,028 keys/sec
2529         At 9,000 keys, avg. speed is 2,077 keys/sec
2530         At 10,000 keys, avg. speed is 2,031 keys/sec
2531         At 20,000 keys, avg. speed is 1,970 keys/sec
2532         At 30,000 keys, avg. speed is 2,050 keys/sec
2533         At 40,000 keys, avg. speed is 2,073 keys/sec
2534         At 50,000 keys, avg. speed is 1,973 keys/sec
2535         At 60,000 keys, avg. speed is 1,914 keys/sec
2536         At 70,000 keys, avg. speed is 2,091 keys/sec
2537         At 80,000 keys, avg. speed is 2,103 keys/sec
2538         At 90,000 keys, avg. speed is 1,886 keys/sec
2539         At 100,000 keys, avg. speed is 1,970 keys/sec
2540         At 200,000 keys, avg. speed is 2,053 keys/sec
2541         At 300,000 keys, avg. speed is 1,697 keys/sec
2542         At 400,000 keys, avg. speed is 1,838 keys/sec
2543         At 500,000 keys, avg. speed is 1,941 keys/sec
2544         At 600,000 keys, avg. speed is 1,930 keys/sec
2545         At 700,000 keys, avg. speed is 1,735 keys/sec
2546         At 800,000 keys, avg. speed is 1,795 keys/sec
2547         At 900,000 keys, avg. speed is 1,221 keys/sec
2548         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2549
2550 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2551 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2552 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2553 Run time was 12 min 3 sec.
2554
2555 =head2 MEMORY USAGE
2556
2557 One of the great things about DBM::Deep is that it uses very little memory.
2558 Even with huge databases (1,000,000+ keys) you will not see much increased
2559 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2560 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2561 database handle:
2562
2563           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2564         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2565
2566 Basically the process is taking 2,716K of memory.  And here is the same
2567 process after storing and fetching 1,000,000 keys:
2568
2569           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2570         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2571
2572 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2573 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2574
2575 =head1 DB FILE FORMAT
2576
2577 In case you were interested in the underlying DB file format, it is documented
2578 here in this section.  You don't need to know this to use the module, it's just
2579 included for reference.
2580
2581 =head2 SIGNATURE
2582
2583 DBM::Deep files always start with a 32-bit signature to identify the file type.
2584 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2585 checked when the file is opened.
2586
2587 =head2 TAG
2588
2589 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2590 has a standard header containing the type of data, the length of data, and then
2591 the data itself.  The type is a single character (1 byte), the length is a
2592 32-bit unsigned long in network byte order, and the data is, well, the data.
2593 Here is how it unfolds:
2594
2595 =head2 MASTER INDEX
2596
2597 Immediately after the 32-bit file signature is the I<Master Index> record.
2598 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2599 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2600 depending on how the DBM::Deep object was constructed.
2601
2602
2603
2604 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2605 number).  The first 8-bit char of the MD5 signature is the offset into the
2606 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2607 index element is a file offset of the next tag for the key/element in question,
2608 which is usually a I<Bucket List> tag (see below).
2609
2610
2611
2612 The next tag I<could> be another index, depending on how many keys/elements
2613 exist.  See L<RE-INDEXING> below for details.
2614
2615 =head2 BUCKET LIST
2616
2617 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2618 file offsets to where the actual data is stored.  It starts with a standard
2619 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2620 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2621 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2622 When the list fills up, a I<Re-Index> operation is performed (See
2623 L<RE-INDEXING> below).
2624
2625 =head2 BUCKET
2626
2627 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2628 index/value pair (in array mode).  It starts with a standard tag header with
2629 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2630 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2631 header.  The size reported in the tag header is only for the value, but then,
2632 just after the value is another size (32-bit unsigned long) and then the plain
2633 key itself.  Since the value is likely to be fetched more often than the plain
2634 key, I figured it would be I<slightly> faster to store the value first.
2635
2636
2637
2638 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2639 record for the nested structure, where the process begins all over again.
2640
2641 =head2 RE-INDEXING
2642
2643 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2644 exhausted.  Then, when another key/element comes in, the list is converted to a
2645 new index record.  However, this index will look at the next char in the MD5
2646 hash, and arrange new Bucket List pointers accordingly.  This process is called
2647 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2648 17 (16 + new one) keys/elements are removed from the old Bucket List and
2649 inserted into the new index.  Several new Bucket Lists are created in the
2650 process, as a new MD5 char from the key is being examined (it is unlikely that
2651 the keys will all share the same next char of their MD5s).
2652
2653
2654
2655 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2656 when the Bucket Lists will turn into indexes, but the first round tends to
2657 happen right around 4,000 keys.  You will see a I<slight> decrease in
2658 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2659 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2660 right around 900,000 keys.  This process can continue nearly indefinitely --
2661 right up until the point the I<MD5> signatures start colliding with each other,
2662 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2663 getting struck by lightning while you are walking to cash in your tickets.
2664 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2665 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2666 this is 340 unodecillion, but don't quote me).
2667
2668 =head2 STORING
2669
2670 When a new key/element is stored, the key (or index number) is first ran through
2671 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2672 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2673 for the first char of the signature (in this case I<b>).  If it does not exist,
2674 a new I<Bucket List> is created for our key (and the next 15 future keys that
2675 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2676 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2677 this point, unless we are replacing an existing I<Bucket>), where the actual
2678 data will be stored.
2679
2680 =head2 FETCHING
2681
2682 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2683 (or index number), then walking along the indexes.  If there are enough
2684 keys/elements in this DB level, there might be nested indexes, each linked to
2685 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2686 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2687 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2688 plain key are stored.
2689
2690
2691
2692 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2693 methods.  In this process the indexes are walked systematically, and each key
2694 fetched in increasing MD5 order (which is why it appears random).   Once the
2695 I<Bucket> is found, the value is skipped the plain key returned instead.
2696 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2697 alphabetically sorted.  This only happens on an index-level -- as soon as the
2698 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2699 so it's pretty much undefined how the keys will come out -- just like Perl's
2700 built-in hashes.
2701
2702 =head1 CODE COVERAGE
2703
2704 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover>
2705 report on this module's test suite.
2706
2707 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2708 File                           stmt   bran   cond    sub    pod   time  total
2709 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2710 blib/lib/DBM/Deep.pm           93.7   82.5   71.9   96.5   25.9   82.8   87.9
2711 blib/lib/DBM/Deep/Array.pm     98.8   88.0   90.9  100.0    n/a   12.8   96.3
2712 blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    4.4   92.3
2713 Total                          94.8   83.2   76.5   97.6   25.9  100.0   89.7
2714 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2715
2716 =head1 AUTHORS
2717
2718 Joseph Huckaby, L<jhuckaby@cpan.org>
2719 Rob Kinyon, L<rkinyon@cpan.org>
2720
2721 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2722
2723 =head1 SEE ALSO
2724
2725 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2726 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2727
2728 =head1 LICENSE
2729
2730 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2731 This is free software, you may use it and distribute it under the
2732 same terms as Perl itself.
2733
2734 =cut