lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub new {
 106         ##
 107         # Class constructor method for Perl OO interface.
 108         # Calls tie() and returns blessed reference to tied hash or array,
 109         # providing a hybrid OO/tie interface.
 110         ##
 111         my $class = shift;
 112         my $args;
 113         if (scalar(@_) > 1) { $args = {@_}; }
 114         else { $args = { file => shift }; }
 115
 116         ##
 117         # Check if we want a tied hash or array.
 118         ##
 119         my $self;
 120         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 121         $class = 'DBM::Deep::Array';
 122         require DBM::Deep::Array;
 123                 tie @$self, $class, %$args;
 124         }
 125         else {
 126         $class = 'DBM::Deep::Hash';
 127         require DBM::Deep::Hash;
 128                 tie %$self, $class, %$args;
 129         }
 130
 131         return bless $self, $class;
 132 }
 133
 134 sub _init {
 135     ##
 136     # Setup $self and bless into this class.
 137     ##
 138     my $class = shift;
 139     my $args = shift;
 140
 141     # These are the defaults to be optionally overridden below
 142     my $self = bless {
 143         type => TYPE_HASH,
 144         base_offset => length(SIG_FILE),
 145     }, $class;
 146
 147     foreach my $param ( keys %$self ) {
 148         next unless exists $args->{$param};
 149         $self->{$param} = delete $args->{$param}
 150     }
 151
 152     $self->{root} = exists $args->{root}
 153         ? $args->{root}
 154         : DBM::Deep::_::Root->new( $args );
 155
 156     if (!defined($self->fh)) { $self->_open(); }
 157
 158     return $self;
 159 }
 160
 161 sub TIEHASH {
 162     shift;
 163     require DBM::Deep::Hash;
 164     return DBM::Deep::Hash->TIEHASH( @_ );
 165 }
 166
 167 sub TIEARRAY {
 168     shift;
 169     require DBM::Deep::Array;
 170     return DBM::Deep::Array->TIEARRAY( @_ );
 171 }
 172
 173 #XXX Unneeded now ...
 174 #sub DESTROY {
 175 #}
 176
 177 sub _open {
 178         ##
 179         # Open a FileHandle to the database, create if nonexistent.
 180         # Make sure file signature matches DeepDB spec.
 181         ##
 182     my $self = $_[0]->_get_self;
 183
 184         if (defined($self->fh)) { $self->_close(); }
 185
 186     eval {
 187         # Theoretically, adding O_BINARY should remove the need for the binmode
 188         # Of course, testing it is going to be ... interesting.
 189         my $flags = O_RDWR | O_CREAT | O_BINARY;
 190
 191         #XXX Can the mode be anything but r+, w+, or a+??
 192         #XXX ie, it has to be in read-write mode
 193         #XXX So, should we verify that the mode is legitimate?
 194
 195         #XXX Maybe the mode thingy should just go away. There's no good
 196         #XXX reason for it ...
 197         if ( $self->root->{mode} eq 'w+' ) {
 198             $flags |= O_TRUNC;
 199         }
 200
 201         my $fh;
 202         sysopen( $fh, $self->root->{file}, $flags )
 203             or $fh = undef;
 204         $self->root->{fh} = $fh;
 205     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 206         if (! defined($self->fh)) {
 207                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 208         }
 209
 210     my $fh = $self->fh;
 211
 212     #XXX Can we remove this by using the right sysopen() flags?
 213     # Maybe ... q.v. above
 214     binmode $fh; # for win32
 215
 216     if ($self->root->{autoflush}) {
 217         my $old = select $fh;
 218         $|=1;
 219         select $old;
 220     }
 221
 222     # Set the
 223     seek($fh, 0, SEEK_SET);
 224
 225     my $signature;
 226     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 227
 228     ##
 229     # File is empty -- write signature and master index
 230     ##
 231     if (!$bytes_read) {
 232         seek($fh, 0, SEEK_SET);
 233         print($fh SIG_FILE);
 234         $self->root->{end} = length(SIG_FILE);
 235         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 236
 237         my $plain_key = "[base]";
 238         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 239         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 240
 241         # Flush the filehandle
 242         my $old_fh = select $fh;
 243         my $old_af = $|;
 244         $| = 1;
 245         $| = $old_af;
 246         select $old_fh;
 247
 248         return 1;
 249     }
 250
 251     ##
 252     # Check signature was valid
 253     ##
 254     unless ($signature eq SIG_FILE) {
 255         $self->_close();
 256         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 257     }
 258
 259     $self->root->{end} = (stat($fh))[7];
 260
 261     ##
 262     # Get our type from master index signature
 263     ##
 264     my $tag = $self->_load_tag($self->base_offset);
 265
 266 #XXX We probably also want to store the hash algorithm name and not assume anything
 267 #XXX The cool thing would be to allow a different hashing algorithm at every level
 268
 269     if (!$tag) {
 270         return $self->_throw_error("Corrupted file, no master index record");
 271     }
 272     if ($self->{type} ne $tag->{signature}) {
 273         return $self->_throw_error("File type mismatch");
 274     }
 275
 276     return 1;
 277 }
 278
 279 sub _close {
 280         ##
 281         # Close database FileHandle
 282         ##
 283     my $self = $_[0]->_get_self;
 284     close $self->root->{fh};
 285 }
 286
 287 sub _create_tag {
 288         ##
 289         # Given offset, signature and content, create tag and write to disk
 290         ##
 291         my ($self, $offset, $sig, $content) = @_;
 292         my $size = length($content);
 293
 294     my $fh = $self->fh;
 295
 296         seek($fh, $offset, SEEK_SET);
 297         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 298
 299         if ($offset == $self->root->{end}) {
 300                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 301         }
 302
 303         return {
 304                 signature => $sig,
 305                 size => $size,
 306                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 307                 content => $content
 308         };
 309 }
 310
 311 sub _load_tag {
 312         ##
 313         # Given offset, load single tag and return signature, size and data
 314         ##
 315         my $self = shift;
 316         my $offset = shift;
 317
 318     my $fh = $self->fh;
 319
 320         seek($fh, $offset, SEEK_SET);
 321         if (eof $fh) { return undef; }
 322
 323         my $sig;
 324         read( $fh, $sig, SIG_SIZE);
 325
 326         my $size;
 327         read( $fh, $size, $DATA_LENGTH_SIZE);
 328         $size = unpack($DATA_LENGTH_PACK, $size);
 329
 330         my $buffer;
 331         read( $fh, $buffer, $size);
 332
 333         return {
 334                 signature => $sig,
 335                 size => $size,
 336                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 337                 content => $buffer
 338         };
 339 }
 340
 341 sub _index_lookup {
 342         ##
 343         # Given index tag, lookup single entry in index and return .
 344         ##
 345         my $self = shift;
 346         my ($tag, $index) = @_;
 347
 348         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 349         if (!$location) { return; }
 350
 351         return $self->_load_tag( $location );
 352 }
 353
 354 sub _add_bucket {
 355         ##
 356         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 357         # plain (undigested) key and value.
 358         ##
 359         my $self = shift;
 360         my ($tag, $md5, $plain_key, $value) = @_;
 361         my $keys = $tag->{content};
 362         my $location = 0;
 363         my $result = 2;
 364
 365     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 366         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 367
 368     my $fh = $self->fh;
 369
 370         ##
 371         # Iterate through buckets, seeing if this is a new entry or a replace.
 372         ##
 373         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 374                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 375                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 376                 if (!$subloc) {
 377                         ##
 378                         # Found empty bucket (end of list).  Populate and exit loop.
 379                         ##
 380                         $result = 2;
 381
 382             $location = $internal_ref
 383                 ? $value->base_offset
 384                 : $self->root->{end};
 385
 386                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 387                         print($fh $md5 . pack($LONG_PACK, $location) );
 388                         last;
 389                 }
 390                 elsif ($md5 eq $key) {
 391                         ##
 392                         # Found existing bucket with same key.  Replace with new value.
 393                         ##
 394                         $result = 1;
 395
 396                         if ($internal_ref) {
 397                                 $location = $value->base_offset;
 398                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 399                                 print($fh $md5 . pack($LONG_PACK, $location) );
 400                         }
 401                         else {
 402                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 403                                 my $size;
 404                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 405
 406                                 ##
 407                                 # If value is a hash, array, or raw value with equal or less size, we can
 408                                 # reuse the same content area of the database.  Otherwise, we have to create
 409                                 # a new content area at the EOF.
 410                                 ##
 411                                 my $actual_length;
 412                 my $r = Scalar::Util::reftype( $value ) || '';
 413                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 414                                 else { $actual_length = length($value); }
 415
 416                                 if ($actual_length <= $size) {
 417                                         $location = $subloc;
 418                                 }
 419                                 else {
 420                                         $location = $self->root->{end};
 421                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 422                                         print($fh pack($LONG_PACK, $location) );
 423                                 }
 424                         }
 425                         last;
 426                 }
 427         } # i loop
 428
 429         ##
 430         # If this is an internal reference, return now.
 431         # No need to write value or plain key
 432         ##
 433         if ($internal_ref) {
 434         return $result;
 435     }
 436
 437         ##
 438         # If bucket didn't fit into list, split into a new index level
 439         ##
 440         if (!$location) {
 441                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 442                 print($fh pack($LONG_PACK, $self->root->{end}) );
 443
 444                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 445                 my @offsets = ();
 446
 447                 $keys .= $md5 . pack($LONG_PACK, 0);
 448
 449                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 450                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 451                         if ($key) {
 452                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 453                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 454
 455                                 if ($offsets[$num]) {
 456                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 457                                         seek($fh, $offset, SEEK_SET);
 458                                         my $subkeys;
 459                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 460
 461                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 462                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 463                                                 if (!$subloc) {
 464                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 465                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 466                                                         last;
 467                                                 }
 468                                         } # k loop
 469                                 }
 470                                 else {
 471                                         $offsets[$num] = $self->root->{end};
 472                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 473                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 474
 475                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 476
 477                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 478                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 479                                 }
 480                         } # key is real
 481                 } # i loop
 482
 483                 $location ||= $self->root->{end};
 484         } # re-index bucket list
 485
 486         ##
 487         # Seek to content area and store signature, value and plaintext key
 488         ##
 489         if ($location) {
 490                 my $content_length;
 491                 seek($fh, $location, SEEK_SET);
 492
 493                 ##
 494                 # Write signature based on content type, set content length and write actual value.
 495                 ##
 496         my $r = Scalar::Util::reftype($value) || '';
 497                 if ($r eq 'HASH') {
 498                         print($fh TYPE_HASH );
 499                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 500                         $content_length = $INDEX_SIZE;
 501                 }
 502                 elsif ($r eq 'ARRAY') {
 503                         print($fh TYPE_ARRAY );
 504                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 505                         $content_length = $INDEX_SIZE;
 506                 }
 507                 elsif (!defined($value)) {
 508                         print($fh SIG_NULL );
 509                         print($fh pack($DATA_LENGTH_PACK, 0) );
 510                         $content_length = 0;
 511                 }
 512                 else {
 513                         print($fh SIG_DATA );
 514                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 515                         $content_length = length($value);
 516                 }
 517
 518                 ##
 519                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 520                 ##
 521                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 522
 523                 ##
 524                 # If value is blessed, preserve class name
 525                 ##
 526                 if ( $self->root->{autobless} ) {
 527             my $value_class = Scalar::Util::blessed($value);
 528             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 529                 ##
 530                 # Blessed ref -- will restore later
 531                 ##
 532                 print($fh chr(1) );
 533                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 534                 $content_length += 1;
 535                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 536             }
 537             else {
 538                 print($fh chr(0) );
 539                 $content_length += 1;
 540             }
 541         }
 542
 543                 ##
 544                 # If this is a new content area, advance EOF counter
 545                 ##
 546                 if ($location == $self->root->{end}) {
 547                         $self->root->{end} += SIG_SIZE;
 548                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 549                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 550                 }
 551
 552                 ##
 553                 # If content is a hash or array, create new child DeepDB object and
 554                 # pass each key or element to it.
 555                 ##
 556                 if ($r eq 'HASH') {
 557                         my $branch = DBM::Deep->new(
 558                                 type => TYPE_HASH,
 559                                 base_offset => $location,
 560                                 root => $self->root,
 561                         );
 562                         foreach my $key (keys %{$value}) {
 563                 #$branch->{$key} = $value->{$key};
 564                 $branch->STORE( $key, $value->{$key} );
 565                         }
 566                 }
 567                 elsif ($r eq 'ARRAY') {
 568                         my $branch = DBM::Deep->new(
 569                                 type => TYPE_ARRAY,
 570                                 base_offset => $location,
 571                                 root => $self->root,
 572                         );
 573                         my $index = 0;
 574                         foreach my $element (@{$value}) {
 575                 #$branch->[$index] = $element;
 576                 $branch->STORE( $index, $element );
 577                                 $index++;
 578                         }
 579                 }
 580
 581                 return $result;
 582         }
 583
 584         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 585 }
 586
 587 sub _get_bucket_value {
 588         ##
 589         # Fetch single value given tag and MD5 digested key.
 590         ##
 591         my $self = shift;
 592         my ($tag, $md5) = @_;
 593         my $keys = $tag->{content};
 594
 595     my $fh = $self->fh;
 596
 597         ##
 598         # Iterate through buckets, looking for a key match
 599         ##
 600     BUCKET:
 601         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 602                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 603                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 604
 605                 if (!$subloc) {
 606                         ##
 607                         # Hit end of list, no match
 608                         ##
 609                         return;
 610                 }
 611
 612         if ( $md5 ne $key ) {
 613             next BUCKET;
 614         }
 615
 616         ##
 617         # Found match -- seek to offset and read signature
 618         ##
 619         my $signature;
 620         seek($fh, $subloc, SEEK_SET);
 621         read( $fh, $signature, SIG_SIZE);
 622
 623         ##
 624         # If value is a hash or array, return new DeepDB object with correct offset
 625         ##
 626         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 627             my $obj = DBM::Deep->new(
 628                 type => $signature,
 629                 base_offset => $subloc,
 630                 root => $self->root
 631             );
 632
 633             if ($self->root->{autobless}) {
 634                 ##
 635                 # Skip over value and plain key to see if object needs
 636                 # to be re-blessed
 637                 ##
 638                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 639
 640                 my $size;
 641                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 642                 if ($size) { seek($fh, $size, SEEK_CUR); }
 643
 644                 my $bless_bit;
 645                 read( $fh, $bless_bit, 1);
 646                 if (ord($bless_bit)) {
 647                     ##
 648                     # Yes, object needs to be re-blessed
 649                     ##
 650                     my $class_name;
 651                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 652                     if ($size) { read( $fh, $class_name, $size); }
 653                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 654                 }
 655             }
 656
 657             return $obj;
 658         }
 659
 660         ##
 661         # Otherwise return actual value
 662         ##
 663         elsif ($signature eq SIG_DATA) {
 664             my $size;
 665             my $value = '';
 666             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 667             if ($size) { read( $fh, $value, $size); }
 668             return $value;
 669         }
 670
 671         ##
 672         # Key exists, but content is null
 673         ##
 674         else { return; }
 675         } # i loop
 676
 677         return;
 678 }
 679
 680 sub _delete_bucket {
 681         ##
 682         # Delete single key/value pair given tag and MD5 digested key.
 683         ##
 684         my $self = shift;
 685         my ($tag, $md5) = @_;
 686         my $keys = $tag->{content};
 687
 688     my $fh = $self->fh;
 689
 690         ##
 691         # Iterate through buckets, looking for a key match
 692         ##
 693     BUCKET:
 694         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 695                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 696                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 697
 698                 if (!$subloc) {
 699                         ##
 700                         # Hit end of list, no match
 701                         ##
 702                         return;
 703                 }
 704
 705         if ( $md5 ne $key ) {
 706             next BUCKET;
 707         }
 708
 709         ##
 710         # Matched key -- delete bucket and return
 711         ##
 712         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 713         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 714         print($fh chr(0) x $BUCKET_SIZE );
 715
 716         return 1;
 717         } # i loop
 718
 719         return;
 720 }
 721
 722 sub _bucket_exists {
 723         ##
 724         # Check existence of single key given tag and MD5 digested key.
 725         ##
 726         my $self = shift;
 727         my ($tag, $md5) = @_;
 728         my $keys = $tag->{content};
 729
 730         ##
 731         # Iterate through buckets, looking for a key match
 732         ##
 733     BUCKET:
 734         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 735                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 736                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 737
 738                 if (!$subloc) {
 739                         ##
 740                         # Hit end of list, no match
 741                         ##
 742                         return;
 743                 }
 744
 745         if ( $md5 ne $key ) {
 746             next BUCKET;
 747         }
 748
 749         ##
 750         # Matched key -- return true
 751         ##
 752         return 1;
 753         } # i loop
 754
 755         return;
 756 }
 757
 758 sub _find_bucket_list {
 759         ##
 760         # Locate offset for bucket list, given digested key
 761         ##
 762         my $self = shift;
 763         my $md5 = shift;
 764
 765         ##
 766         # Locate offset for bucket list using digest index system
 767         ##
 768         my $ch = 0;
 769         my $tag = $self->_load_tag($self->base_offset);
 770         if (!$tag) { return; }
 771
 772         while ($tag->{signature} ne SIG_BLIST) {
 773                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 774                 if (!$tag) { return; }
 775                 $ch++;
 776         }
 777
 778         return $tag;
 779 }
 780
 781 sub _traverse_index {
 782         ##
 783         # Scan index and recursively step into deeper levels, looking for next key.
 784         ##
 785     my ($self, $offset, $ch, $force_return_next) = @_;
 786     $force_return_next = undef unless $force_return_next;
 787
 788         my $tag = $self->_load_tag( $offset );
 789
 790     my $fh = $self->fh;
 791
 792         if ($tag->{signature} ne SIG_BLIST) {
 793                 my $content = $tag->{content};
 794                 my $start;
 795                 if ($self->{return_next}) { $start = 0; }
 796                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 797
 798                 for (my $index = $start; $index < 256; $index++) {
 799                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 800                         if ($subloc) {
 801                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 802                                 if (defined($result)) { return $result; }
 803                         }
 804                 } # index loop
 805
 806                 $self->{return_next} = 1;
 807         } # tag is an index
 808
 809         elsif ($tag->{signature} eq SIG_BLIST) {
 810                 my $keys = $tag->{content};
 811                 if ($force_return_next) { $self->{return_next} = 1; }
 812
 813                 ##
 814                 # Iterate through buckets, looking for a key match
 815                 ##
 816                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 817                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 818                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 819
 820                         if (!$subloc) {
 821                                 ##
 822                                 # End of bucket list -- return to outer loop
 823                                 ##
 824                                 $self->{return_next} = 1;
 825                                 last;
 826                         }
 827                         elsif ($key eq $self->{prev_md5}) {
 828                                 ##
 829                                 # Located previous key -- return next one found
 830                                 ##
 831                                 $self->{return_next} = 1;
 832                                 next;
 833                         }
 834                         elsif ($self->{return_next}) {
 835                                 ##
 836                                 # Seek to bucket location and skip over signature
 837                                 ##
 838                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 839
 840                                 ##
 841                                 # Skip over value to get to plain key
 842                                 ##
 843                                 my $size;
 844                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 845                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 846
 847                                 ##
 848                                 # Read in plain key and return as scalar
 849                                 ##
 850                                 my $plain_key;
 851                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 852                                 if ($size) { read( $fh, $plain_key, $size); }
 853
 854                                 return $plain_key;
 855                         }
 856                 } # bucket loop
 857
 858                 $self->{return_next} = 1;
 859         } # tag is a bucket list
 860
 861         return;
 862 }
 863
 864 sub _get_next_key {
 865         ##
 866         # Locate next key, given digested previous one
 867         ##
 868     my $self = $_[0]->_get_self;
 869
 870         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 871         $self->{return_next} = 0;
 872
 873         ##
 874         # If the previous key was not specifed, start at the top and
 875         # return the first one found.
 876         ##
 877         if (!$self->{prev_md5}) {
 878                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 879                 $self->{return_next} = 1;
 880         }
 881
 882         return $self->_traverse_index( $self->base_offset, 0 );
 883 }
 884
 885 sub lock {
 886         ##
 887         # If db locking is set, flock() the db file.  If called multiple
 888         # times before unlock(), then the same number of unlocks() must
 889         # be called before the lock is released.
 890         ##
 891     my $self = $_[0]->_get_self;
 892         my $type = $_[1];
 893     $type = LOCK_EX unless defined $type;
 894
 895         if ($self->root->{locking}) {
 896                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 897                 $self->root->{locked}++;
 898
 899         return 1;
 900         }
 901
 902     return;
 903 }
 904
 905 sub unlock {
 906         ##
 907         # If db locking is set, unlock the db file.  See note in lock()
 908         # regarding calling lock() multiple times.
 909         ##
 910     my $self = $_[0]->_get_self;
 911
 912         if ($self->root->{locking} && $self->root->{locked} > 0) {
 913                 $self->root->{locked}--;
 914                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 915
 916         return 1;
 917         }
 918
 919     return;
 920 }
 921
 922 #XXX These uses of ref() need verified
 923 sub _copy_node {
 924         ##
 925         # Copy single level of keys or elements to new DB handle.
 926         # Recurse for nested structures
 927         ##
 928     my $self = $_[0]->_get_self;
 929         my $db_temp = $_[1];
 930
 931         if ($self->type eq TYPE_HASH) {
 932                 my $key = $self->first_key();
 933                 while ($key) {
 934                         my $value = $self->get($key);
 935 #XXX This doesn't work with autobless
 936                         if (!ref($value)) { $db_temp->{$key} = $value; }
 937                         else {
 938                                 my $type = $value->type;
 939                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 940                                 else { $db_temp->{$key} = []; }
 941                                 $value->_copy_node( $db_temp->{$key} );
 942                         }
 943                         $key = $self->next_key($key);
 944                 }
 945         }
 946         else {
 947                 my $length = $self->length();
 948                 for (my $index = 0; $index < $length; $index++) {
 949                         my $value = $self->get($index);
 950                         if (!ref($value)) { $db_temp->[$index] = $value; }
 951             #XXX NO tests for this code
 952                         else {
 953                                 my $type = $value->type;
 954                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 955                                 else { $db_temp->[$index] = []; }
 956                                 $value->_copy_node( $db_temp->[$index] );
 957                         }
 958                 }
 959         }
 960 }
 961
 962 sub export {
 963         ##
 964         # Recursively export into standard Perl hashes and arrays.
 965         ##
 966     my $self = $_[0]->_get_self;
 967
 968         my $temp;
 969         if ($self->type eq TYPE_HASH) { $temp = {}; }
 970         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 971
 972         $self->lock();
 973         $self->_copy_node( $temp );
 974         $self->unlock();
 975
 976         return $temp;
 977 }
 978
 979 sub import {
 980         ##
 981         # Recursively import Perl hash/array structure
 982         ##
 983     #XXX This use of ref() seems to be ok
 984         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 985
 986     my $self = $_[0]->_get_self;
 987         my $struct = $_[1];
 988
 989     #XXX This use of ref() seems to be ok
 990         if (!ref($struct)) {
 991                 ##
 992                 # struct is not a reference, so just import based on our type
 993                 ##
 994                 shift @_;
 995
 996                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
 997                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
 998         }
 999
1000     my $r = Scalar::Util::reftype($struct) || '';
1001         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1002                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1003         }
1004         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1005                 $self->push( @$struct );
1006         }
1007         else {
1008                 return $self->_throw_error("Cannot import: type mismatch");
1009         }
1010
1011         return 1;
1012 }
1013
1014 sub optimize {
1015         ##
1016         # Rebuild entire database into new file, then move
1017         # it back on top of original.
1018         ##
1019     my $self = $_[0]->_get_self;
1020
1021 #XXX Need to create a new test for this
1022 #       if ($self->root->{links} > 1) {
1023 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1024 #       }
1025
1026         my $db_temp = DBM::Deep->new(
1027                 file => $self->root->{file} . '.tmp',
1028                 type => $self->type
1029         );
1030         if (!$db_temp) {
1031                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1032         }
1033
1034         $self->lock();
1035         $self->_copy_node( $db_temp );
1036         undef $db_temp;
1037
1038         ##
1039         # Attempt to copy user, group and permissions over to new file
1040         ##
1041         my @stats = stat($self->fh);
1042         my $perms = $stats[2] & 07777;
1043         my $uid = $stats[4];
1044         my $gid = $stats[5];
1045         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1046         chmod( $perms, $self->root->{file} . '.tmp' );
1047
1048     # q.v. perlport for more information on this variable
1049     if ( $^O eq 'MSWin32' ) {
1050                 ##
1051                 # Potential race condition when optmizing on Win32 with locking.
1052                 # The Windows filesystem requires that the filehandle be closed
1053                 # before it is overwritten with rename().  This could be redone
1054                 # with a soft copy.
1055                 ##
1056                 $self->unlock();
1057                 $self->_close();
1058         }
1059
1060         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1061                 unlink $self->root->{file} . '.tmp';
1062                 $self->unlock();
1063                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1064         }
1065
1066         $self->unlock();
1067         $self->_close();
1068         $self->_open();
1069
1070         return 1;
1071 }
1072
1073 sub clone {
1074         ##
1075         # Make copy of object and return
1076         ##
1077     my $self = $_[0]->_get_self;
1078
1079         return DBM::Deep->new(
1080                 type => $self->type,
1081                 base_offset => $self->base_offset,
1082                 root => $self->root
1083         );
1084 }
1085
1086 {
1087     my %is_legal_filter = map {
1088         $_ => ~~1,
1089     } qw(
1090         store_key store_value
1091         fetch_key fetch_value
1092     );
1093
1094     sub set_filter {
1095         ##
1096         # Setup filter function for storing or fetching the key or value
1097         ##
1098         my $self = $_[0]->_get_self;
1099         my $type = lc $_[1];
1100         my $func = $_[2] ? $_[2] : undef;
1101
1102         if ( $is_legal_filter{$type} ) {
1103             $self->root->{"filter_$type"} = $func;
1104             return 1;
1105         }
1106
1107         return;
1108     }
1109 }
1110
1111 ##
1112 # Accessor methods
1113 ##
1114
1115 sub root {
1116         ##
1117         # Get access to the root structure
1118         ##
1119     my $self = $_[0]->_get_self;
1120         return $self->{root};
1121 }
1122
1123 sub fh {
1124         ##
1125         # Get access to the raw FileHandle
1126         ##
1127     #XXX It will be useful, though, when we split out HASH and ARRAY
1128     my $self = $_[0]->_get_self;
1129         return $self->root->{fh};
1130 }
1131
1132 sub type {
1133         ##
1134         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1135         ##
1136     my $self = $_[0]->_get_self;
1137         return $self->{type};
1138 }
1139
1140 sub base_offset {
1141         ##
1142         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1143         ##
1144     my $self = $_[0]->_get_self;
1145         return $self->{base_offset};
1146 }
1147
1148 sub error {
1149         ##
1150         # Get last error string, or undef if no error
1151         ##
1152         return $_[0]
1153         #? ( _get_self($_[0])->{root}->{error} or undef )
1154         ? ( $_[0]->_get_self->{root}->{error} or undef )
1155         : $@;
1156 }
1157
1158 ##
1159 # Utility methods
1160 ##
1161
1162 sub _throw_error {
1163         ##
1164         # Store error string in self
1165         ##
1166     my $self = $_[0]->_get_self;
1167         my $error_text = $_[1];
1168
1169         $self->root->{error} = $error_text;
1170
1171         unless ($self->root->{debug}) {
1172         die "DBM::Deep: $error_text\n";
1173     }
1174
1175     warn "DBM::Deep: $error_text\n";
1176         return;
1177 }
1178
1179 sub clear_error {
1180         ##
1181         # Clear error state
1182         ##
1183     my $self = $_[0]->_get_self;
1184
1185         undef $self->root->{error};
1186 }
1187
1188 sub precalc_sizes {
1189         ##
1190         # Precalculate index, bucket and bucket list sizes
1191         ##
1192
1193     #XXX I don't like this ...
1194     set_pack() unless defined $LONG_SIZE;
1195
1196         $INDEX_SIZE = 256 * $LONG_SIZE;
1197         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1198         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1199 }
1200
1201 sub set_pack {
1202         ##
1203         # Set pack/unpack modes (see file header for more)
1204         ##
1205     my ($long_s, $long_p, $data_s, $data_p) = @_;
1206
1207     $LONG_SIZE = $long_s ? $long_s : 4;
1208     $LONG_PACK = $long_p ? $long_p : 'N';
1209
1210     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1211     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1212
1213         precalc_sizes();
1214 }
1215
1216 sub set_digest {
1217         ##
1218         # Set key digest function (default is MD5)
1219         ##
1220     my ($digest_func, $hash_size) = @_;
1221
1222     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1223     $HASH_SIZE = $hash_size ? $hash_size : 16;
1224
1225         precalc_sizes();
1226 }
1227
1228 ##
1229 # tie() methods (hashes and arrays)
1230 ##
1231
1232 sub STORE {
1233         ##
1234         # Store single hash key/value or array element in database.
1235         ##
1236     my $self = $_[0]->_get_self;
1237         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1238     #XXX What is ref() checking here?
1239     #YYY User may be storing a hash, in which case we do not want it run
1240     #YYY through the filtering system
1241         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1242
1243         my $unpacked_key = $key;
1244         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1245         my $md5 = $DIGEST_FUNC->($key);
1246
1247         ##
1248         # Make sure file is open
1249         ##
1250         if (!defined($self->fh) && !$self->_open()) {
1251                 return;
1252         }
1253         ##
1254
1255     my $fh = $self->fh;
1256
1257         ##
1258         # Request exclusive lock for writing
1259         ##
1260         $self->lock( LOCK_EX );
1261
1262         ##
1263         # If locking is enabled, set 'end' parameter again, in case another
1264         # DB instance appended to our file while we were unlocked.
1265         ##
1266         if ($self->root->{locking} || $self->root->{volatile}) {
1267                 $self->root->{end} = (stat($fh))[7];
1268         }
1269
1270         ##
1271         # Locate offset for bucket list using digest index system
1272         ##
1273         my $tag = $self->_load_tag($self->base_offset);
1274         if (!$tag) {
1275                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1276         }
1277
1278         my $ch = 0;
1279         while ($tag->{signature} ne SIG_BLIST) {
1280                 my $num = ord(substr($md5, $ch, 1));
1281                 my $new_tag = $self->_index_lookup($tag, $num);
1282                 if (!$new_tag) {
1283                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1284                         seek($fh, $ref_loc, SEEK_SET);
1285                         print($fh pack($LONG_PACK, $self->root->{end}) );
1286
1287                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1288                         $tag->{ref_loc} = $ref_loc;
1289                         $tag->{ch} = $ch;
1290                         last;
1291                 }
1292                 else {
1293                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1294                         $tag = $new_tag;
1295                         $tag->{ref_loc} = $ref_loc;
1296                         $tag->{ch} = $ch;
1297                 }
1298                 $ch++;
1299         }
1300
1301         ##
1302         # Add key/value to bucket list
1303         ##
1304         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1305
1306         ##
1307         # If this object is an array, and bucket was not a replace, and key is numerical,
1308         # and index is equal or greater than current length, advance length variable.
1309         ##
1310         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1311                 $self->STORESIZE( $unpacked_key + 1 );
1312         }
1313
1314         $self->unlock();
1315
1316         return $result;
1317 }
1318
1319 sub FETCH {
1320         ##
1321         # Fetch single value or element given plain key or array index
1322         ##
1323     my $self = $_[0]->_get_self;
1324
1325     my $key = $_[1];
1326     if ( $self->type eq TYPE_HASH ) {
1327         if ( my $filter = $self->root->{filter_store_key} ) {
1328             $key = $filter->( $key );
1329         }
1330     }
1331     elsif ( $self->type eq TYPE_ARRAY ) {
1332         if ( $key =~ /^\d+$/ ) {
1333             $key = pack($LONG_PACK, $key);
1334         }
1335     }
1336
1337         my $md5 = $DIGEST_FUNC->($key);
1338
1339         ##
1340         # Make sure file is open
1341         ##
1342         if (!defined($self->fh)) { $self->_open(); }
1343
1344         ##
1345         # Request shared lock for reading
1346         ##
1347         $self->lock( LOCK_SH );
1348
1349         my $tag = $self->_find_bucket_list( $md5 );
1350         if (!$tag) {
1351                 $self->unlock();
1352                 return;
1353         }
1354
1355         ##
1356         # Get value from bucket list
1357         ##
1358         my $result = $self->_get_bucket_value( $tag, $md5 );
1359
1360         $self->unlock();
1361
1362     #XXX What is ref() checking here?
1363         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1364 }
1365
1366 sub DELETE {
1367         ##
1368         # Delete single key/value pair or element given plain key or array index
1369         ##
1370     my $self = $_[0]->_get_self;
1371         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1372
1373         my $unpacked_key = $key;
1374         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1375         my $md5 = $DIGEST_FUNC->($key);
1376
1377         ##
1378         # Make sure file is open
1379         ##
1380         if (!defined($self->fh)) { $self->_open(); }
1381
1382         ##
1383         # Request exclusive lock for writing
1384         ##
1385         $self->lock( LOCK_EX );
1386
1387         my $tag = $self->_find_bucket_list( $md5 );
1388         if (!$tag) {
1389                 $self->unlock();
1390                 return;
1391         }
1392
1393         ##
1394         # Delete bucket
1395         ##
1396         my $result = $self->_delete_bucket( $tag, $md5 );
1397
1398         ##
1399         # If this object is an array and the key deleted was on the end of the stack,
1400         # decrement the length variable.
1401         ##
1402         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1403                 $self->STORESIZE( $unpacked_key );
1404         }
1405
1406         $self->unlock();
1407
1408         return $result;
1409 }
1410
1411 sub EXISTS {
1412         ##
1413         # Check if a single key or element exists given plain key or array index
1414         ##
1415     my $self = $_[0]->_get_self;
1416         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1417
1418         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1419         my $md5 = $DIGEST_FUNC->($key);
1420
1421         ##
1422         # Make sure file is open
1423         ##
1424         if (!defined($self->fh)) { $self->_open(); }
1425
1426         ##
1427         # Request shared lock for reading
1428         ##
1429         $self->lock( LOCK_SH );
1430
1431         my $tag = $self->_find_bucket_list( $md5 );
1432
1433         ##
1434         # For some reason, the built-in exists() function returns '' for false
1435         ##
1436         if (!$tag) {
1437                 $self->unlock();
1438                 return '';
1439         }
1440
1441         ##
1442         # Check if bucket exists and return 1 or ''
1443         ##
1444         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1445
1446         $self->unlock();
1447
1448         return $result;
1449 }
1450
1451 sub CLEAR {
1452         ##
1453         # Clear all keys from hash, or all elements from array.
1454         ##
1455     my $self = $_[0]->_get_self;
1456
1457         ##
1458         # Make sure file is open
1459         ##
1460         if (!defined($self->fh)) { $self->_open(); }
1461
1462         ##
1463         # Request exclusive lock for writing
1464         ##
1465         $self->lock( LOCK_EX );
1466
1467     my $fh = $self->fh;
1468
1469         seek($fh, $self->base_offset, SEEK_SET);
1470         if (eof $fh) {
1471                 $self->unlock();
1472                 return;
1473         }
1474
1475         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1476
1477         $self->unlock();
1478
1479         return 1;
1480 }
1481
1482 ##
1483 # Public method aliases
1484 ##
1485 *put = *store = *STORE;
1486 *get = *fetch = *FETCH;
1487 *delete = *DELETE;
1488 *exists = *EXISTS;
1489 *clear = *CLEAR;
1490
1491 package DBM::Deep::_::Root;
1492
1493 sub new {
1494     my $class = shift;
1495     my ($args) = @_;
1496
1497     my $self = bless {
1498         file => undef,
1499         fh => undef,
1500         end => 0,
1501         autoflush => undef,
1502         locking => undef,
1503         volatile => undef,
1504         debug => undef,
1505         mode => 'r+',
1506         filter_store_key => undef,
1507         filter_store_value => undef,
1508         filter_fetch_key => undef,
1509         filter_fetch_value => undef,
1510         autobless => undef,
1511         locked => 0,
1512         %$args,
1513     }, $class;
1514
1515     return $self;
1516 }
1517
1518 sub DESTROY {
1519     my $self = shift;
1520     return unless $self;
1521
1522     close $self->{fh} if $self->{fh};
1523
1524     return;
1525 }
1526
1527 1;
1528
1529 __END__
1530
1531 =head1 NAME
1532
1533 DBM::Deep - A pure perl multi-level hash/array DBM
1534
1535 =head1 SYNOPSIS
1536
1537   use DBM::Deep;
1538   my $db = DBM::Deep->new( "foo.db" );
1539
1540   $db->{key} = 'value'; # tie() style
1541   print $db->{key};
1542
1543   $db->put('key', 'value'); # OO style
1544   print $db->get('key');
1545
1546   # true multi-level support
1547   $db->{my_complex} = [
1548         'hello', { perl => 'rules' },
1549         42, 99 ];
1550
1551 =head1 DESCRIPTION
1552
1553 A unique flat-file database module, written in pure perl.  True
1554 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1555 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1556 handle millions of keys and unlimited hash levels without significant
1557 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1558 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1559 Mac OS X and Windows.
1560
1561 =head1 INSTALLATION
1562
1563 Hopefully you are using CPAN's excellent Perl module, which will download
1564 and install the module for you.  If not, get the tarball, and run these
1565 commands:
1566
1567         tar zxf DBM-Deep-*
1568         cd DBM-Deep-*
1569         perl Makefile.PL
1570         make
1571         make test
1572         make install
1573
1574 =head1 SETUP
1575
1576 Construction can be done OO-style (which is the recommended way), or using
1577 Perl's tie() function.  Both are examined here.
1578
1579 =head2 OO CONSTRUCTION
1580
1581 The recommended way to construct a DBM::Deep object is to use the new()
1582 method, which gets you a blessed, tied hash or array reference.
1583
1584         my $db = DBM::Deep->new( "foo.db" );
1585
1586 This opens a new database handle, mapped to the file "foo.db".  If this
1587 file does not exist, it will automatically be created.  DB files are
1588 opened in "r+" (read/write) mode, and the type of object returned is a
1589 hash, unless otherwise specified (see L<OPTIONS> below).
1590
1591
1592
1593 You can pass a number of options to the constructor to specify things like
1594 locking, autoflush, etc.  This is done by passing an inline hash:
1595
1596         my $db = DBM::Deep->new(
1597                 file => "foo.db",
1598                 locking => 1,
1599                 autoflush => 1
1600         );
1601
1602 Notice that the filename is now specified I<inside> the hash with
1603 the "file" parameter, as opposed to being the sole argument to the
1604 constructor.  This is required if any options are specified.
1605 See L<OPTIONS> below for the complete list.
1606
1607
1608
1609 You can also start with an array instead of a hash.  For this, you must
1610 specify the C<type> parameter:
1611
1612         my $db = DBM::Deep->new(
1613                 file => "foo.db",
1614                 type => DBM::Deep->TYPE_ARRAY
1615         );
1616
1617 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1618 a new DB file.  If you create a DBM::Deep object with an existing file, the
1619 C<type> will be loaded from the file header, and ignored if it is passed
1620 to the constructor.
1621
1622 =head2 TIE CONSTRUCTION
1623
1624 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1625 tie() function.  This is not ideal, because you get only a basic, tied hash
1626 (or array) which is not blessed, so you can't call any functions on it.
1627
1628         my %hash;
1629         tie %hash, "DBM::Deep", "foo.db";
1630
1631         my @array;
1632         tie @array, "DBM::Deep", "bar.db";
1633
1634 As with the OO constructor, you can replace the DB filename parameter with
1635 a hash containing one or more options (see L<OPTIONS> just below for the
1636 complete list).
1637
1638         tie %hash, "DBM::Deep", {
1639                 file => "foo.db",
1640                 locking => 1,
1641                 autoflush => 1
1642         };
1643
1644 =head2 OPTIONS
1645
1646 There are a number of options that can be passed in when constructing your
1647 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1648
1649 =over
1650
1651 =item * file
1652
1653 Filename of the DB file to link the handle to.  You can pass a full absolute
1654 filesystem path, partial path, or a plain filename if the file is in the
1655 current working directory.  This is a required parameter.
1656
1657 =item * mode
1658
1659 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1660 module.  This is an optional parameter, and defaults to "r+" (read/write).
1661 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1662 created if it doesn't exist.
1663
1664 =item * type
1665
1666 This parameter specifies what type of object to create, a hash or array.  Use
1667 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1668 This only takes effect when beginning a new file.  This is an optional
1669 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1670
1671 =item * locking
1672
1673 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1674 function to lock the database in exclusive mode for writes, and shared mode for
1675 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1676 any child hashes or arrays> that use the same DB file.  This is an optional
1677 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1678
1679 =item * autoflush
1680
1681 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1682 This obviously slows down write operations, but is required if you may have
1683 multiple processes accessing the same DB file (also consider enable I<locking>
1684 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1685 parameter, and defaults to 0 (disabled).
1686
1687 =item * volatile
1688
1689 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1690 STORE() operation.  This is required if an outside force may change the size of
1691 the file between transactions.  Locking also implicitly enables volatile.  This
1692 is useful if you want to use a different locking system or write your own.  Pass
1693 any true value to enable.  This is an optional parameter, and defaults to 0
1694 (disabled).
1695
1696 =item * autobless
1697
1698 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1699 restore them when fetched.  This is an B<experimental> feature, and does have
1700 side-effects.  Basically, when hashes are re-blessed into their original
1701 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1702 able to call any DBM::Deep methods on them.  You have been warned.
1703 This is an optional parameter, and defaults to 0 (disabled).
1704
1705 =item * filter_*
1706
1707 See L<FILTERS> below.
1708
1709 =item * debug
1710
1711 Setting I<debug> mode will make all errors non-fatal, dump them out to
1712 STDERR, and continue on.  This is for debugging purposes only, and probably
1713 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1714
1715 =item * fh
1716
1717 Instead of passing a file path, you can instead pass a handle to an pre-opened
1718 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1719 contains your entire Perl script, as well as the data following the __DATA__
1720 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1721 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1722 in that.
1723
1724 =back
1725
1726 =head1 TIE INTERFACE
1727
1728 With DBM::Deep you can access your databases using Perl's standard hash/array
1729 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1730 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1731 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1732 section above.  This simply tells you how to use DBM::Deep using regular hashes
1733 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1734 work too).  It is entirely up to you how to want to access your databases.
1735
1736 =head2 HASHES
1737
1738 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1739 or even nested hashes (or arrays) using standard Perl syntax:
1740
1741         my $db = DBM::Deep->new( "foo.db" );
1742
1743         $db->{mykey} = "myvalue";
1744         $db->{myhash} = {};
1745         $db->{myhash}->{subkey} = "subvalue";
1746
1747         print $db->{myhash}->{subkey} . "\n";
1748
1749 You can even step through hash keys using the normal Perl C<keys()> function:
1750
1751         foreach my $key (keys %$db) {
1752                 print "$key: " . $db->{$key} . "\n";
1753         }
1754
1755 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1756 pushes them onto an array, all before the loop even begins.  If you have an
1757 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1758 Perl's C<each()> function, which pulls keys/values one at a time, using very
1759 little memory:
1760
1761         while (my ($key, $value) = each %$db) {
1762                 print "$key: $value\n";
1763         }
1764
1765 Please note that when using C<each()>, you should always pass a direct
1766 hash reference, not a lookup.  Meaning, you should B<never> do this:
1767
1768         # NEVER DO THIS
1769         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1770
1771 This causes an infinite loop, because for each iteration, Perl is calling
1772 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1773 it effectively keeps returning the first key over and over again. Instead,
1774 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1775
1776 =head2 ARRAYS
1777
1778 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1779 reference.  This includes inserting, removing and manipulating elements,
1780 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1781 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1782 or simply be a nested array reference inside a hash.  Example:
1783
1784         my $db = DBM::Deep->new(
1785                 file => "foo-array.db",
1786                 type => DBM::Deep->TYPE_ARRAY
1787         );
1788
1789         $db->[0] = "foo";
1790         push @$db, "bar", "baz";
1791         unshift @$db, "bah";
1792
1793         my $last_elem = pop @$db; # baz
1794         my $first_elem = shift @$db; # bah
1795         my $second_elem = $db->[1]; # bar
1796
1797         my $num_elements = scalar @$db;
1798
1799 =head1 OO INTERFACE
1800
1801 In addition to the I<tie()> interface, you can also use a standard OO interface
1802 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1803 array) has its own methods, but both types share the following common methods:
1804 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1805
1806 =over
1807
1808 =item * put()
1809
1810 Stores a new hash key/value pair, or sets an array element value.  Takes two
1811 arguments, the hash key or array index, and the new value.  The value can be
1812 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1813
1814         $db->put("foo", "bar"); # for hashes
1815         $db->put(1, "bar"); # for arrays
1816
1817 =item * get()
1818
1819 Fetches the value of a hash key or array element.  Takes one argument: the hash
1820 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1821 data type stored.
1822
1823         my $value = $db->get("foo"); # for hashes
1824         my $value = $db->get(1); # for arrays
1825
1826 =item * exists()
1827
1828 Checks if a hash key or array index exists.  Takes one argument: the hash key
1829 or array index.  Returns true if it exists, false if not.
1830
1831         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1832         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1833
1834 =item * delete()
1835
1836 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1837 key or array index.  Returns true on success, false if not found.  For arrays,
1838 the remaining elements located after the deleted element are NOT moved over.
1839 The deleted element is essentially just undefined, which is exactly how Perl's
1840 internal arrays work.  Please note that the space occupied by the deleted
1841 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1842 below for details and workarounds.
1843
1844         $db->delete("foo"); # for hashes
1845         $db->delete(1); # for arrays
1846
1847 =item * clear()
1848
1849 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1850 value.  Please note that the space occupied by the deleted keys/values or
1851 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1852 details and workarounds.
1853
1854         $db->clear(); # hashes or arrays
1855
1856 =back
1857
1858 =head2 HASHES
1859
1860 For hashes, DBM::Deep supports all the common methods described above, and the
1861 following additional methods: C<first_key()> and C<next_key()>.
1862
1863 =over
1864
1865 =item * first_key()
1866
1867 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1868 fetched in an undefined order (which appears random).  Takes no arguments,
1869 returns the key as a scalar value.
1870
1871         my $key = $db->first_key();
1872
1873 =item * next_key()
1874
1875 Returns the "next" key in the hash, given the previous one as the sole argument.
1876 Returns undef if there are no more keys to be fetched.
1877
1878         $key = $db->next_key($key);
1879
1880 =back
1881
1882 Here are some examples of using hashes:
1883
1884         my $db = DBM::Deep->new( "foo.db" );
1885
1886         $db->put("foo", "bar");
1887         print "foo: " . $db->get("foo") . "\n";
1888
1889         $db->put("baz", {}); # new child hash ref
1890         $db->get("baz")->put("buz", "biz");
1891         print "buz: " . $db->get("baz")->get("buz") . "\n";
1892
1893         my $key = $db->first_key();
1894         while ($key) {
1895                 print "$key: " . $db->get($key) . "\n";
1896                 $key = $db->next_key($key);
1897         }
1898
1899         if ($db->exists("foo")) { $db->delete("foo"); }
1900
1901 =head2 ARRAYS
1902
1903 For arrays, DBM::Deep supports all the common methods described above, and the
1904 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1905 C<unshift()> and C<splice()>.
1906
1907 =over
1908
1909 =item * length()
1910
1911 Returns the number of elements in the array.  Takes no arguments.
1912
1913         my $len = $db->length();
1914
1915 =item * push()
1916
1917 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1918 refs or array refs.  No return value.
1919
1920         $db->push("foo", "bar", {});
1921
1922 =item * pop()
1923
1924 Fetches the last element in the array, and deletes it.  Takes no arguments.
1925 Returns undef if array is empty.  Returns the element value.
1926
1927         my $elem = $db->pop();
1928
1929 =item * shift()
1930
1931 Fetches the first element in the array, deletes it, then shifts all the
1932 remaining elements over to take up the space.  Returns the element value.  This
1933 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1934 details.
1935
1936         my $elem = $db->shift();
1937
1938 =item * unshift()
1939
1940 Inserts one or more elements onto the beginning of the array, shifting all
1941 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1942 No return value.  This method is not recommended with large arrays -- see
1943 <LARGE ARRAYS> below for details.
1944
1945         $db->unshift("foo", "bar", {});
1946
1947 =item * splice()
1948
1949 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1950 -f splice> for usage -- it is too complicated to document here.  This method is
1951 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1952
1953 =back
1954
1955 Here are some examples of using arrays:
1956
1957         my $db = DBM::Deep->new(
1958                 file => "foo.db",
1959                 type => DBM::Deep->TYPE_ARRAY
1960         );
1961
1962         $db->push("bar", "baz");
1963         $db->unshift("foo");
1964         $db->put(3, "buz");
1965
1966         my $len = $db->length();
1967         print "length: $len\n"; # 4
1968
1969         for (my $k=0; $k<$len; $k++) {
1970                 print "$k: " . $db->get($k) . "\n";
1971         }
1972
1973         $db->splice(1, 2, "biz", "baf");
1974
1975         while (my $elem = shift @$db) {
1976                 print "shifted: $elem\n";
1977         }
1978
1979 =head1 LOCKING
1980
1981 Enable automatic file locking by passing a true value to the C<locking>
1982 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1983
1984         my $db = DBM::Deep->new(
1985                 file => "foo.db",
1986                 locking => 1
1987         );
1988
1989 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1990 mode for writes, and shared mode for reads.  This is required if you have
1991 multiple processes accessing the same database file, to avoid file corruption.
1992 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1993 NFS> below for more.
1994
1995 =head2 EXPLICIT LOCKING
1996
1997 You can explicitly lock a database, so it remains locked for multiple
1998 transactions.  This is done by calling the C<lock()> method, and passing an
1999 optional lock mode argument (defaults to exclusive mode).  This is particularly
2000 useful for things like counters, where the current value needs to be fetched,
2001 then incremented, then stored again.
2002
2003         $db->lock();
2004         my $counter = $db->get("counter");
2005         $counter++;
2006         $db->put("counter", $counter);
2007         $db->unlock();
2008
2009         # or...
2010
2011         $db->lock();
2012         $db->{counter}++;
2013         $db->unlock();
2014
2015 You can pass C<lock()> an optional argument, which specifies which mode to use
2016 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2017 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2018 same as the constants defined in Perl's C<Fcntl> module.
2019
2020         $db->lock( DBM::Deep->LOCK_SH );
2021         # something here
2022         $db->unlock();
2023
2024 If you want to implement your own file locking scheme, be sure to create your
2025 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2026 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2027 below for more.
2028
2029 =head1 IMPORTING/EXPORTING
2030
2031 You can import existing complex structures by calling the C<import()> method,
2032 and export an entire database into an in-memory structure using the C<export()>
2033 method.  Both are examined here.
2034
2035 =head2 IMPORTING
2036
2037 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2038 walking the structure and adding keys/elements to the database as you go,
2039 simply pass a reference to the C<import()> method.  This recursively adds
2040 everything to an existing DBM::Deep object for you.  Here is an example:
2041
2042         my $struct = {
2043                 key1 => "value1",
2044                 key2 => "value2",
2045                 array1 => [ "elem0", "elem1", "elem2" ],
2046                 hash1 => {
2047                         subkey1 => "subvalue1",
2048                         subkey2 => "subvalue2"
2049                 }
2050         };
2051
2052         my $db = DBM::Deep->new( "foo.db" );
2053         $db->import( $struct );
2054
2055         print $db->{key1} . "\n"; # prints "value1"
2056
2057 This recursively imports the entire C<$struct> object into C<$db>, including
2058 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2059 keys are merged with the existing ones, replacing if they already exist.
2060 The C<import()> method can be called on any database level (not just the base
2061 level), and works with both hash and array DB types.
2062
2063
2064
2065 B<Note:> Make sure your existing structure has no circular references in it.
2066 These will cause an infinite loop when importing.
2067
2068 =head2 EXPORTING
2069
2070 Calling the C<export()> method on an existing DBM::Deep object will return
2071 a reference to a new in-memory copy of the database.  The export is done
2072 recursively, so all nested hashes/arrays are all exported to standard Perl
2073 objects.  Here is an example:
2074
2075         my $db = DBM::Deep->new( "foo.db" );
2076
2077         $db->{key1} = "value1";
2078         $db->{key2} = "value2";
2079         $db->{hash1} = {};
2080         $db->{hash1}->{subkey1} = "subvalue1";
2081         $db->{hash1}->{subkey2} = "subvalue2";
2082
2083         my $struct = $db->export();
2084
2085         print $struct->{key1} . "\n"; # prints "value1"
2086
2087 This makes a complete copy of the database in memory, and returns a reference
2088 to it.  The C<export()> method can be called on any database level (not just
2089 the base level), and works with both hash and array DB types.  Be careful of
2090 large databases -- you can store a lot more data in a DBM::Deep object than an
2091 in-memory Perl structure.
2092
2093
2094
2095 B<Note:> Make sure your database has no circular references in it.
2096 These will cause an infinite loop when exporting.
2097
2098 =head1 FILTERS
2099
2100 DBM::Deep has a number of hooks where you can specify your own Perl function
2101 to perform filtering on incoming or outgoing data.  This is a perfect
2102 way to extend the engine, and implement things like real-time compression or
2103 encryption.  Filtering applies to the base DB level, and all child hashes /
2104 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2105 constructed, or by calling the C<set_filter()> method at any time.  There are
2106 four available filter hooks, described below:
2107
2108 =over
2109
2110 =item * filter_store_key
2111
2112 This filter is called whenever a hash key is stored.  It
2113 is passed the incoming key, and expected to return a transformed key.
2114
2115 =item * filter_store_value
2116
2117 This filter is called whenever a hash key or array element is stored.  It
2118 is passed the incoming value, and expected to return a transformed value.
2119
2120 =item * filter_fetch_key
2121
2122 This filter is called whenever a hash key is fetched (i.e. via
2123 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2124 and expected to return the plain key.
2125
2126 =item * filter_fetch_value
2127
2128 This filter is called whenever a hash key or array element is fetched.
2129 It is passed the transformed value, and expected to return the plain value.
2130
2131 =back
2132
2133 Here are the two ways to setup a filter hook:
2134
2135         my $db = DBM::Deep->new(
2136                 file => "foo.db",
2137                 filter_store_value => \&my_filter_store,
2138                 filter_fetch_value => \&my_filter_fetch
2139         );
2140
2141         # or...
2142
2143         $db->set_filter( "filter_store_value", \&my_filter_store );
2144         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2145
2146 Your filter function will be called only when dealing with SCALAR keys or
2147 values.  When nested hashes and arrays are being stored/fetched, filtering
2148 is bypassed.  Filters are called as static functions, passed a single SCALAR
2149 argument, and expected to return a single SCALAR value.  If you want to
2150 remove a filter, set the function reference to C<undef>:
2151
2152         $db->set_filter( "filter_store_value", undef );
2153
2154 =head2 REAL-TIME ENCRYPTION EXAMPLE
2155
2156 Here is a working example that uses the I<Crypt::Blowfish> module to
2157 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2158 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2159 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2160
2161         use DBM::Deep;
2162         use Crypt::Blowfish;
2163         use Crypt::CBC;
2164
2165         my $cipher = Crypt::CBC->new({
2166                 'key'             => 'my secret key',
2167                 'cipher'          => 'Blowfish',
2168                 'iv'              => '$KJh#(}q',
2169                 'regenerate_key'  => 0,
2170                 'padding'         => 'space',
2171                 'prepend_iv'      => 0
2172         });
2173
2174         my $db = DBM::Deep->new(
2175                 file => "foo-encrypt.db",
2176                 filter_store_key => \&my_encrypt,
2177                 filter_store_value => \&my_encrypt,
2178                 filter_fetch_key => \&my_decrypt,
2179                 filter_fetch_value => \&my_decrypt,
2180         );
2181
2182         $db->{key1} = "value1";
2183         $db->{key2} = "value2";
2184         print "key1: " . $db->{key1} . "\n";
2185         print "key2: " . $db->{key2} . "\n";
2186
2187         undef $db;
2188         exit;
2189
2190         sub my_encrypt {
2191                 return $cipher->encrypt( $_[0] );
2192         }
2193         sub my_decrypt {
2194                 return $cipher->decrypt( $_[0] );
2195         }
2196
2197 =head2 REAL-TIME COMPRESSION EXAMPLE
2198
2199 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2200 compression / decompression of keys & values with DBM::Deep Filters.
2201 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2202 more on I<Compress::Zlib>.
2203
2204         use DBM::Deep;
2205         use Compress::Zlib;
2206
2207         my $db = DBM::Deep->new(
2208                 file => "foo-compress.db",
2209                 filter_store_key => \&my_compress,
2210                 filter_store_value => \&my_compress,
2211                 filter_fetch_key => \&my_decompress,
2212                 filter_fetch_value => \&my_decompress,
2213         );
2214
2215         $db->{key1} = "value1";
2216         $db->{key2} = "value2";
2217         print "key1: " . $db->{key1} . "\n";
2218         print "key2: " . $db->{key2} . "\n";
2219
2220         undef $db;
2221         exit;
2222
2223         sub my_compress {
2224                 return Compress::Zlib::memGzip( $_[0] ) ;
2225         }
2226         sub my_decompress {
2227                 return Compress::Zlib::memGunzip( $_[0] ) ;
2228         }
2229
2230 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2231 actually numerical index numbers, and are not filtered.
2232
2233 =head1 ERROR HANDLING
2234
2235 Most DBM::Deep methods return a true value for success, and call die() on
2236 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2237 actual error message is stored in an internal scalar, which can be fetched by
2238 calling the C<error()> method.
2239
2240         my $db = DBM::Deep->new( "foo.db" ); # create hash
2241         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2242
2243         print $db->error(); # prints error message
2244
2245 You can then call C<clear_error()> to clear the current error state.
2246
2247         $db->clear_error();
2248
2249 If you set the C<debug> option to true when creating your DBM::Deep object,
2250 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2251 for debugging purposes.
2252
2253 =head1 LARGEFILE SUPPORT
2254
2255 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2256 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2257 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2258 by calling the static C<set_pack()> method before you do anything else.
2259
2260         DBM::Deep::set_pack(8, 'Q');
2261
2262 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2263 instead of 32-bit longs.  After setting these values your DB files have a
2264 theoretical maximum size of 16 XB (exabytes).
2265
2266
2267
2268 B<Note:> Changing these values will B<NOT> work for existing database files.
2269 Only change this for new files, and make sure it stays set consistently
2270 throughout the file's life.  If you do set these values, you can no longer
2271 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2272 back to 32-bit mode.
2273
2274
2275
2276 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2277 only a 32-bit Perl.  However, I have received user reports that this does
2278 indeed work!
2279
2280 =head1 LOW-LEVEL ACCESS
2281
2282 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2283 you can call the C<fh()> method, which returns the handle:
2284
2285         my $fh = $db->fh();
2286
2287 This method can be called on the root level of the datbase, or any child
2288 hashes or arrays.  All levels share a I<root> structure, which contains things
2289 like the FileHandle, a reference counter, and all your options you specified
2290 when you created the object.  You can get access to this root structure by
2291 calling the C<root()> method.
2292
2293         my $root = $db->root();
2294
2295 This is useful for changing options after the object has already been created,
2296 such as enabling/disabling locking, volatile or debug modes.  You can also
2297 store your own temporary user data in this structure (be wary of name
2298 collision), which is then accessible from any child hash or array.
2299
2300 =head1 CUSTOM DIGEST ALGORITHM
2301
2302 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2303 keys.  However you can override this, and use another algorithm (such as SHA-256)
2304 or even write your own.  But please note that DBM::Deep currently expects zero
2305 collisions, so your algorithm has to be I<perfect>, so to speak.
2306 Collision detection may be introduced in a later version.
2307
2308
2309
2310 You can specify a custom digest algorithm by calling the static C<set_digest()>
2311 function, passing a reference to a subroutine, and the length of the algorithm's
2312 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2313 objects.  Here is a working example that uses a 256-bit hash from the
2314 I<Digest::SHA256> module.  Please see
2315 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2316
2317         use DBM::Deep;
2318         use Digest::SHA256;
2319
2320         my $context = Digest::SHA256::new(256);
2321
2322         DBM::Deep::set_digest( \&my_digest, 32 );
2323
2324         my $db = DBM::Deep->new( "foo-sha.db" );
2325
2326         $db->{key1} = "value1";
2327         $db->{key2} = "value2";
2328         print "key1: " . $db->{key1} . "\n";
2329         print "key2: " . $db->{key2} . "\n";
2330
2331         undef $db;
2332         exit;
2333
2334         sub my_digest {
2335                 return substr( $context->hash($_[0]), 0, 32 );
2336         }
2337
2338 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2339 of bytes you specify in the C<set_digest()> function (in this case 32).
2340
2341 =head1 CIRCULAR REFERENCES
2342
2343 DBM::Deep has B<experimental> support for circular references.  Meaning you
2344 can have a nested hash key or array element that points to a parent object.
2345 This relationship is stored in the DB file, and is preserved between sessions.
2346 Here is an example:
2347
2348         my $db = DBM::Deep->new( "foo.db" );
2349
2350         $db->{foo} = "bar";
2351         $db->{circle} = $db; # ref to self
2352
2353         print $db->{foo} . "\n"; # prints "foo"
2354         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2355
2356 One catch is, passing the object to a function that recursively walks the
2357 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2358 C<export()> methods) will result in an infinite loop.  The other catch is,
2359 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2360 or C<next_key()> methods), you will get the I<target object's key>, not the
2361 ref's key.  This gets even more interesting with the above example, where
2362 the I<circle> key points to the base DB object, which technically doesn't
2363 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2364 special case.
2365
2366 =head1 CAVEATS / ISSUES / BUGS
2367
2368 This section describes all the known issues with DBM::Deep.  It you have found
2369 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2370
2371 =head2 UNUSED SPACE RECOVERY
2372
2373 One major caveat with DBM::Deep is that space occupied by existing keys and
2374 values is not recovered when they are deleted.  Meaning if you keep deleting
2375 and adding new keys, your file will continuously grow.  I am working on this,
2376 but in the meantime you can call the built-in C<optimize()> method from time to
2377 time (perhaps in a crontab or something) to recover all your unused space.
2378
2379         $db->optimize(); # returns true on success
2380
2381 This rebuilds the ENTIRE database into a new file, then moves it on top of
2382 the original.  The new file will have no unused space, thus it will take up as
2383 little disk space as possible.  Please note that this operation can take
2384 a long time for large files, and you need enough disk space to temporarily hold
2385 2 copies of your DB file.  The temporary file is created in the same directory
2386 as the original, named with a ".tmp" extension, and is deleted when the
2387 operation completes.  Oh, and if locking is enabled, the DB is automatically
2388 locked for the entire duration of the copy.
2389
2390
2391
2392 B<WARNING:> Only call optimize() on the top-level node of the database, and
2393 make sure there are no child references lying around.  DBM::Deep keeps a reference
2394 counter, and if it is greater than 1, optimize() will abort and return undef.
2395
2396 =head2 AUTOVIVIFICATION
2397
2398 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2399 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2400 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2401 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2402 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2403 this does not work:
2404
2405         $db->{foo}->{bar} = "hello";
2406
2407 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2408 being an empty hash.  Try this instead, which works fine:
2409
2410         $db->{foo} = { bar => "hello" };
2411
2412 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2413 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2414 Probably a bug in Perl.
2415
2416 =head2 FILE CORRUPTION
2417
2418 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2419 for a 32-bit signature when opened, but other corruption in files can cause
2420 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2421 stuck in an infinite loop depending on the level of corruption.  File write
2422 operations are not checked for failure (for speed), so if you happen to run
2423 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2424 be addressed in a later version of DBM::Deep.
2425
2426 =head2 DB OVER NFS
2427
2428 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2429 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2430 about setting up your NFS server with a locking daemon, then using lockf() to
2431 lock your files, but your milage may vary there as well.  From what I
2432 understand, there is no real way to do it.  However, if you need access to the
2433 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2434 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2435
2436 =head2 COPYING OBJECTS
2437
2438 Beware of copying tied objects in Perl.  Very strange things can happen.
2439 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2440 returns a new, blessed, tied hash or array to the same level in the DB.
2441
2442         my $copy = $db->clone();
2443
2444 =head2 LARGE ARRAYS
2445
2446 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2447 These functions cause every element in the array to move, which can be murder
2448 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2449 a different location.  This may be addressed in a later version.
2450
2451 =head1 PERFORMANCE
2452
2453 This section discusses DBM::Deep's speed and memory usage.
2454
2455 =head2 SPEED
2456
2457 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2458 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2459 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2460 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2461 with huge databases.  Here is some test data:
2462
2463         Adding 1,000,000 keys to new DB file...
2464
2465         At 100 keys, avg. speed is 2,703 keys/sec
2466         At 200 keys, avg. speed is 2,642 keys/sec
2467         At 300 keys, avg. speed is 2,598 keys/sec
2468         At 400 keys, avg. speed is 2,578 keys/sec
2469         At 500 keys, avg. speed is 2,722 keys/sec
2470         At 600 keys, avg. speed is 2,628 keys/sec
2471         At 700 keys, avg. speed is 2,700 keys/sec
2472         At 800 keys, avg. speed is 2,607 keys/sec
2473         At 900 keys, avg. speed is 2,190 keys/sec
2474         At 1,000 keys, avg. speed is 2,570 keys/sec
2475         At 2,000 keys, avg. speed is 2,417 keys/sec
2476         At 3,000 keys, avg. speed is 1,982 keys/sec
2477         At 4,000 keys, avg. speed is 1,568 keys/sec
2478         At 5,000 keys, avg. speed is 1,533 keys/sec
2479         At 6,000 keys, avg. speed is 1,787 keys/sec
2480         At 7,000 keys, avg. speed is 1,977 keys/sec
2481         At 8,000 keys, avg. speed is 2,028 keys/sec
2482         At 9,000 keys, avg. speed is 2,077 keys/sec
2483         At 10,000 keys, avg. speed is 2,031 keys/sec
2484         At 20,000 keys, avg. speed is 1,970 keys/sec
2485         At 30,000 keys, avg. speed is 2,050 keys/sec
2486         At 40,000 keys, avg. speed is 2,073 keys/sec
2487         At 50,000 keys, avg. speed is 1,973 keys/sec
2488         At 60,000 keys, avg. speed is 1,914 keys/sec
2489         At 70,000 keys, avg. speed is 2,091 keys/sec
2490         At 80,000 keys, avg. speed is 2,103 keys/sec
2491         At 90,000 keys, avg. speed is 1,886 keys/sec
2492         At 100,000 keys, avg. speed is 1,970 keys/sec
2493         At 200,000 keys, avg. speed is 2,053 keys/sec
2494         At 300,000 keys, avg. speed is 1,697 keys/sec
2495         At 400,000 keys, avg. speed is 1,838 keys/sec
2496         At 500,000 keys, avg. speed is 1,941 keys/sec
2497         At 600,000 keys, avg. speed is 1,930 keys/sec
2498         At 700,000 keys, avg. speed is 1,735 keys/sec
2499         At 800,000 keys, avg. speed is 1,795 keys/sec
2500         At 900,000 keys, avg. speed is 1,221 keys/sec
2501         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2502
2503 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2504 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2505 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2506 Run time was 12 min 3 sec.
2507
2508 =head2 MEMORY USAGE
2509
2510 One of the great things about DBM::Deep is that it uses very little memory.
2511 Even with huge databases (1,000,000+ keys) you will not see much increased
2512 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2513 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2514 database handle:
2515
2516           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2517         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2518
2519 Basically the process is taking 2,716K of memory.  And here is the same
2520 process after storing and fetching 1,000,000 keys:
2521
2522           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2523         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2524
2525 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2526 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2527
2528 =head1 DB FILE FORMAT
2529
2530 In case you were interested in the underlying DB file format, it is documented
2531 here in this section.  You don't need to know this to use the module, it's just
2532 included for reference.
2533
2534 =head2 SIGNATURE
2535
2536 DBM::Deep files always start with a 32-bit signature to identify the file type.
2537 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2538 checked when the file is opened.
2539
2540 =head2 TAG
2541
2542 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2543 has a standard header containing the type of data, the length of data, and then
2544 the data itself.  The type is a single character (1 byte), the length is a
2545 32-bit unsigned long in network byte order, and the data is, well, the data.
2546 Here is how it unfolds:
2547
2548 =head2 MASTER INDEX
2549
2550 Immediately after the 32-bit file signature is the I<Master Index> record.
2551 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2552 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2553 depending on how the DBM::Deep object was constructed.
2554
2555
2556
2557 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2558 number).  The first 8-bit char of the MD5 signature is the offset into the
2559 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2560 index element is a file offset of the next tag for the key/element in question,
2561 which is usually a I<Bucket List> tag (see below).
2562
2563
2564
2565 The next tag I<could> be another index, depending on how many keys/elements
2566 exist.  See L<RE-INDEXING> below for details.
2567
2568 =head2 BUCKET LIST
2569
2570 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2571 file offsets to where the actual data is stored.  It starts with a standard
2572 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2573 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2574 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2575 When the list fills up, a I<Re-Index> operation is performed (See
2576 L<RE-INDEXING> below).
2577
2578 =head2 BUCKET
2579
2580 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2581 index/value pair (in array mode).  It starts with a standard tag header with
2582 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2583 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2584 header.  The size reported in the tag header is only for the value, but then,
2585 just after the value is another size (32-bit unsigned long) and then the plain
2586 key itself.  Since the value is likely to be fetched more often than the plain
2587 key, I figured it would be I<slightly> faster to store the value first.
2588
2589
2590
2591 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2592 record for the nested structure, where the process begins all over again.
2593
2594 =head2 RE-INDEXING
2595
2596 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2597 exhausted.  Then, when another key/element comes in, the list is converted to a
2598 new index record.  However, this index will look at the next char in the MD5
2599 hash, and arrange new Bucket List pointers accordingly.  This process is called
2600 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2601 17 (16 + new one) keys/elements are removed from the old Bucket List and
2602 inserted into the new index.  Several new Bucket Lists are created in the
2603 process, as a new MD5 char from the key is being examined (it is unlikely that
2604 the keys will all share the same next char of their MD5s).
2605
2606
2607
2608 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2609 when the Bucket Lists will turn into indexes, but the first round tends to
2610 happen right around 4,000 keys.  You will see a I<slight> decrease in
2611 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2612 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2613 right around 900,000 keys.  This process can continue nearly indefinitely --
2614 right up until the point the I<MD5> signatures start colliding with each other,
2615 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2616 getting struck by lightning while you are walking to cash in your tickets.
2617 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2618 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2619 this is 340 unodecillion, but don't quote me).
2620
2621 =head2 STORING
2622
2623 When a new key/element is stored, the key (or index number) is first ran through
2624 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2625 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2626 for the first char of the signature (in this case I<b>).  If it does not exist,
2627 a new I<Bucket List> is created for our key (and the next 15 future keys that
2628 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2629 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2630 this point, unless we are replacing an existing I<Bucket>), where the actual
2631 data will be stored.
2632
2633 =head2 FETCHING
2634
2635 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2636 (or index number), then walking along the indexes.  If there are enough
2637 keys/elements in this DB level, there might be nested indexes, each linked to
2638 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2639 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2640 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2641 plain key are stored.
2642
2643
2644
2645 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2646 methods.  In this process the indexes are walked systematically, and each key
2647 fetched in increasing MD5 order (which is why it appears random).   Once the
2648 I<Bucket> is found, the value is skipped the plain key returned instead.
2649 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2650 alphabetically sorted.  This only happens on an index-level -- as soon as the
2651 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2652 so it's pretty much undefined how the keys will come out -- just like Perl's
2653 built-in hashes.
2654
2655 =head1 CODE COVERAGE
2656
2657 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2658 module's test suite.
2659
2660   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2661   File                           stmt   bran   cond    sub    pod   time  total
2662   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2663   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2664   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2665   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2666   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2667   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2668
2669 =head1 AUTHOR
2670
2671 Joseph Huckaby, L<jhuckaby@cpan.org>
2672
2673 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2674
2675 =head1 SEE ALSO
2676
2677 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2678 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2679
2680 =head1 LICENSE
2681
2682 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2683 This is free software, you may use it and distribute it under the
2684 same terms as Perl itself.
2685
2686 =cut