lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use DBM::Deep::Engine;
  39
  40 use vars qw( $VERSION );
  41 $VERSION = q(0.99_01);
  42
  43 ##
  44 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  45 #       (Perl must be compiled with largefile support for files > 2 GB)
  46 #
  47 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  48 #       (Perl must be compiled with largefile and 64-bit long support)
  49 ##
  50 #my $LONG_SIZE = 4;
  51 #my $LONG_PACK = 'N';
  52
  53 ##
  54 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  55 # Upgrading this is possible (see above) but probably not necessary.  If you need
  56 # more than 4 GB for a single key or value, this module is really not for you :-)
  57 ##
  58 #my $DATA_LENGTH_SIZE = 4;
  59 #my $DATA_LENGTH_PACK = 'N';
  60 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  61
  62 ##
  63 # Maximum number of buckets per list before another level of indexing is done.
  64 # Increase this value for slightly greater speed, but larger database files.
  65 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  66 ##
  67 my $MAX_BUCKETS = 16;
  68
  69 ##
  70 # Better not adjust anything below here, unless you're me :-)
  71 ##
  72
  73 ##
  74 # Setup digest function for keys
  75 ##
  76 our ($DIGEST_FUNC, $HASH_SIZE);
  77 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  78
  79 ##
  80 # Precalculate index and bucket sizes based on values above.
  81 ##
  82 #my $HASH_SIZE = 16;
  83 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  84
  85 set_digest();
  86 #set_pack();
  87 #_precalc_sizes();
  88
  89 ##
  90 # Setup file and tag signatures.  These should never change.
  91 ##
  92 sub SIG_FILE   () { 'DPDB' }
  93 sub SIG_HASH   () { 'H' }
  94 sub SIG_ARRAY  () { 'A' }
  95 sub SIG_SCALAR () { 'S' }
  96 sub SIG_NULL   () { 'N' }
  97 sub SIG_DATA   () { 'D' }
  98 sub SIG_INDEX  () { 'I' }
  99 sub SIG_BLIST  () { 'B' }
 100 sub SIG_SIZE   () {  1  }
 101
 102 ##
 103 # Setup constants for users to pass to new()
 104 ##
 105 sub TYPE_HASH   () { SIG_HASH   }
 106 sub TYPE_ARRAY  () { SIG_ARRAY  }
 107 sub TYPE_SCALAR () { SIG_SCALAR }
 108
 109 sub _get_args {
 110     my $proto = shift;
 111
 112     my $args;
 113     if (scalar(@_) > 1) {
 114         if ( @_ % 2 ) {
 115             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 116         }
 117         $args = {@_};
 118     }
 119         elsif ( ref $_[0] ) {
 120         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 121             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 122         }
 123         $args = $_[0];
 124     }
 125         else {
 126         $args = { file => shift };
 127     }
 128
 129     return $args;
 130 }
 131
 132 sub new {
 133         ##
 134         # Class constructor method for Perl OO interface.
 135         # Calls tie() and returns blessed reference to tied hash or array,
 136         # providing a hybrid OO/tie interface.
 137         ##
 138         my $class = shift;
 139         my $args = $class->_get_args( @_ );
 140
 141         ##
 142         # Check if we want a tied hash or array.
 143         ##
 144         my $self;
 145         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 146         $class = 'DBM::Deep::Array';
 147         require DBM::Deep::Array;
 148                 tie @$self, $class, %$args;
 149         }
 150         else {
 151         $class = 'DBM::Deep::Hash';
 152         require DBM::Deep::Hash;
 153                 tie %$self, $class, %$args;
 154         }
 155
 156         return bless $self, $class;
 157 }
 158
 159 sub _init {
 160     ##
 161     # Setup $self and bless into this class.
 162     ##
 163     my $class = shift;
 164     my $args = shift;
 165
 166     # These are the defaults to be optionally overridden below
 167     my $self = bless {
 168         type        => TYPE_HASH,
 169         base_offset => length(SIG_FILE),
 170         engine      => 'DBM::Deep::Engine',
 171     }, $class;
 172
 173     foreach my $param ( keys %$self ) {
 174         next unless exists $args->{$param};
 175         $self->{$param} = delete $args->{$param}
 176     }
 177
 178     # locking implicitly enables autoflush
 179     if ($args->{locking}) { $args->{autoflush} = 1; }
 180
 181     $self->{root} = exists $args->{root}
 182         ? $args->{root}
 183         : DBM::Deep::_::Root->new( $args );
 184
 185     if (!defined($self->_fh)) { $self->_open(); }
 186
 187     return $self;
 188 }
 189
 190 sub TIEHASH {
 191     shift;
 192     require DBM::Deep::Hash;
 193     return DBM::Deep::Hash->TIEHASH( @_ );
 194 }
 195
 196 sub TIEARRAY {
 197     shift;
 198     require DBM::Deep::Array;
 199     return DBM::Deep::Array->TIEARRAY( @_ );
 200 }
 201
 202 #XXX Unneeded now ...
 203 #sub DESTROY {
 204 #}
 205
 206 sub _open {
 207         ##
 208         # Open a fh to the database, create if nonexistent.
 209         # Make sure file signature matches DBM::Deep spec.
 210         ##
 211     my $self = $_[0]->_get_self;
 212
 213         if (defined($self->_fh)) { $self->_close(); }
 214
 215     eval {
 216         local $SIG{'__DIE__'};
 217         # Theoretically, adding O_BINARY should remove the need for the binmode
 218         # Of course, testing it is going to be ... interesting.
 219         my $flags = O_RDWR | O_CREAT | O_BINARY;
 220
 221         my $fh;
 222         sysopen( $fh, $self->_root->{file}, $flags )
 223             or $fh = undef;
 224         $self->_root->{fh} = $fh;
 225     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 226         if (! defined($self->_fh)) {
 227                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 228         }
 229
 230     my $fh = $self->_fh;
 231
 232     #XXX Can we remove this by using the right sysopen() flags?
 233     # Maybe ... q.v. above
 234     binmode $fh; # for win32
 235
 236     if ($self->_root->{autoflush}) {
 237         my $old = select $fh;
 238         $|=1;
 239         select $old;
 240     }
 241
 242     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 243
 244     my $signature;
 245     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 246
 247     ##
 248     # File is empty -- write signature and master index
 249     ##
 250     if (!$bytes_read) {
 251         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 252         print( $fh SIG_FILE);
 253         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 254
 255         my $plain_key = "[base]";
 256         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 257
 258         # Flush the filehandle
 259         my $old_fh = select $fh;
 260         my $old_af = $|; $| = 1; $| = $old_af;
 261         select $old_fh;
 262
 263         my @stats = stat($fh);
 264         $self->_root->{inode} = $stats[1];
 265         $self->_root->{end} = $stats[7];
 266
 267         return 1;
 268     }
 269
 270     ##
 271     # Check signature was valid
 272     ##
 273     unless ($signature eq SIG_FILE) {
 274         $self->_close();
 275         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 276     }
 277
 278         my @stats = stat($fh);
 279         $self->_root->{inode} = $stats[1];
 280     $self->_root->{end} = $stats[7];
 281
 282     ##
 283     # Get our type from master index signature
 284     ##
 285     my $tag = $self->_load_tag($self->_base_offset);
 286
 287 #XXX We probably also want to store the hash algorithm name and not assume anything
 288 #XXX The cool thing would be to allow a different hashing algorithm at every level
 289
 290     if (!$tag) {
 291         return $self->_throw_error("Corrupted file, no master index record");
 292     }
 293     if ($self->{type} ne $tag->{signature}) {
 294         return $self->_throw_error("File type mismatch");
 295     }
 296
 297     return 1;
 298 }
 299
 300 sub _close {
 301         ##
 302         # Close database fh
 303         ##
 304     my $self = $_[0]->_get_self;
 305     close $self->_root->{fh} if $self->_root->{fh};
 306     $self->_root->{fh} = undef;
 307 }
 308
 309 sub _create_tag {
 310         ##
 311         # Given offset, signature and content, create tag and write to disk
 312         ##
 313         my ($self, $offset, $sig, $content) = @_;
 314         my $size = length($content);
 315
 316     my $fh = $self->_fh;
 317
 318         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 319         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 320
 321         if ($offset == $self->_root->{end}) {
 322                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 323         }
 324
 325         return {
 326                 signature => $sig,
 327                 size => $size,
 328                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 329                 content => $content
 330         };
 331 }
 332
 333 sub _load_tag {
 334         ##
 335         # Given offset, load single tag and return signature, size and data
 336         ##
 337         my $self = shift;
 338         my $offset = shift;
 339
 340     my $fh = $self->_fh;
 341
 342         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 343         if (eof $fh) { return undef; }
 344
 345     my $b;
 346     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 347     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 348
 349         my $buffer;
 350         read( $fh, $buffer, $size);
 351
 352         return {
 353                 signature => $sig,
 354                 size => $size,
 355                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 356                 content => $buffer
 357         };
 358 }
 359
 360 sub _index_lookup {
 361         ##
 362         # Given index tag, lookup single entry in index and return .
 363         ##
 364         my $self = shift;
 365         my ($tag, $index) = @_;
 366
 367         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 368         if (!$location) { return; }
 369
 370         return $self->_load_tag( $location );
 371 }
 372
 373 sub _add_bucket {
 374         ##
 375         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 376         # plain (undigested) key and value.
 377         ##
 378         my $self = shift;
 379         my ($tag, $md5, $plain_key, $value) = @_;
 380         my $keys = $tag->{content};
 381         my $location = 0;
 382         my $result = 2;
 383
 384     my $root = $self->_root;
 385
 386     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 387         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 388
 389     my $fh = $self->_fh;
 390
 391         ##
 392         # Iterate through buckets, seeing if this is a new entry or a replace.
 393         ##
 394         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 395                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 396                 if (!$subloc) {
 397                         ##
 398                         # Found empty bucket (end of list).  Populate and exit loop.
 399                         ##
 400                         $result = 2;
 401
 402             $location = $internal_ref
 403                 ? $value->_base_offset
 404                 : $root->{end};
 405
 406                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 407                         print( $fh $md5 . pack($LONG_PACK, $location) );
 408                         last;
 409                 }
 410
 411                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 412                 if ($md5 eq $key) {
 413                         ##
 414                         # Found existing bucket with same key.  Replace with new value.
 415                         ##
 416                         $result = 1;
 417
 418                         if ($internal_ref) {
 419                                 $location = $value->_base_offset;
 420                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 421                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 422                 return $result;
 423                         }
 424
 425             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 426             my $size;
 427             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 428
 429             ##
 430             # If value is a hash, array, or raw value with equal or less size, we can
 431             # reuse the same content area of the database.  Otherwise, we have to create
 432             # a new content area at the EOF.
 433             ##
 434             my $actual_length;
 435             my $r = Scalar::Util::reftype( $value ) || '';
 436             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 437                 $actual_length = $INDEX_SIZE;
 438
 439                 # if autobless is enabled, must also take into consideration
 440                 # the class name, as it is stored along with key/value.
 441                 if ( $root->{autobless} ) {
 442                     my $value_class = Scalar::Util::blessed($value);
 443                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 444                         $actual_length += length($value_class);
 445                     }
 446                 }
 447             }
 448             else { $actual_length = length($value); }
 449
 450             if ($actual_length <= $size) {
 451                 $location = $subloc;
 452             }
 453             else {
 454                 $location = $root->{end};
 455                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 456                 print( $fh pack($LONG_PACK, $location) );
 457             }
 458
 459                         last;
 460                 }
 461         }
 462
 463         ##
 464         # If this is an internal reference, return now.
 465         # No need to write value or plain key
 466         ##
 467         if ($internal_ref) {
 468         return $result;
 469     }
 470
 471         ##
 472         # If bucket didn't fit into list, split into a new index level
 473         ##
 474         if (!$location) {
 475                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 476                 print( $fh pack($LONG_PACK, $root->{end}) );
 477
 478                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 479                 my @offsets = ();
 480
 481                 $keys .= $md5 . pack($LONG_PACK, 0);
 482
 483                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 484                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 485                         if ($key) {
 486                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 487                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 488
 489                                 if ($offsets[$num]) {
 490                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 491                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 492                                         my $subkeys;
 493                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 494
 495                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 496                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 497                                                 if (!$subloc) {
 498                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 499                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 500                                                         last;
 501                                                 }
 502                                         } # k loop
 503                                 }
 504                                 else {
 505                                         $offsets[$num] = $root->{end};
 506                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 507                                         print( $fh pack($LONG_PACK, $root->{end}) );
 508
 509                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 510
 511                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 512                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 513                                 }
 514                         } # key is real
 515                 } # i loop
 516
 517                 $location ||= $root->{end};
 518         } # re-index bucket list
 519
 520         ##
 521         # Seek to content area and store signature, value and plaintext key
 522         ##
 523         if ($location) {
 524                 my $content_length;
 525                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 526
 527                 ##
 528                 # Write signature based on content type, set content length and write actual value.
 529                 ##
 530         my $r = Scalar::Util::reftype($value) || '';
 531                 if ($r eq 'HASH') {
 532                         print( $fh TYPE_HASH );
 533                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 534                         $content_length = $INDEX_SIZE;
 535                 }
 536                 elsif ($r eq 'ARRAY') {
 537                         print( $fh TYPE_ARRAY );
 538                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 539                         $content_length = $INDEX_SIZE;
 540                 }
 541                 elsif (!defined($value)) {
 542                         print( $fh SIG_NULL );
 543                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 544                         $content_length = 0;
 545                 }
 546                 else {
 547                         print( $fh SIG_DATA );
 548                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 549                         $content_length = length($value);
 550                 }
 551
 552                 ##
 553                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 554                 ##
 555                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 556
 557                 ##
 558                 # If value is blessed, preserve class name
 559                 ##
 560                 if ( $root->{autobless} ) {
 561             my $value_class = Scalar::Util::blessed($value);
 562             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 563                 ##
 564                 # Blessed ref -- will restore later
 565                 ##
 566                 print( $fh chr(1) );
 567                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 568                 $content_length += 1;
 569                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 570             }
 571             else {
 572                 print( $fh chr(0) );
 573                 $content_length += 1;
 574             }
 575         }
 576
 577                 ##
 578                 # If this is a new content area, advance EOF counter
 579                 ##
 580                 if ($location == $root->{end}) {
 581                         $root->{end} += SIG_SIZE;
 582                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 583                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 584                 }
 585
 586                 ##
 587                 # If content is a hash or array, create new child DBM::Deep object and
 588                 # pass each key or element to it.
 589                 ##
 590                 if ($r eq 'HASH') {
 591                         my $branch = DBM::Deep->new(
 592                                 type => TYPE_HASH,
 593                                 base_offset => $location,
 594                                 root => $root,
 595                         );
 596                         foreach my $key (keys %{$value}) {
 597                 $branch->STORE( $key, $value->{$key} );
 598                         }
 599                 }
 600                 elsif ($r eq 'ARRAY') {
 601                         my $branch = DBM::Deep->new(
 602                                 type => TYPE_ARRAY,
 603                                 base_offset => $location,
 604                                 root => $root,
 605                         );
 606                         my $index = 0;
 607                         foreach my $element (@{$value}) {
 608                 $branch->STORE( $index, $element );
 609                                 $index++;
 610                         }
 611                 }
 612
 613                 return $result;
 614         }
 615
 616         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 617 }
 618
 619 sub _get_bucket_value {
 620         ##
 621         # Fetch single value given tag and MD5 digested key.
 622         ##
 623         my $self = shift;
 624         my ($tag, $md5) = @_;
 625         my $keys = $tag->{content};
 626
 627     my $fh = $self->_fh;
 628
 629         ##
 630         # Iterate through buckets, looking for a key match
 631         ##
 632     BUCKET:
 633         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 634                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 635                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 636
 637                 if (!$subloc) {
 638                         ##
 639                         # Hit end of list, no match
 640                         ##
 641                         return;
 642                 }
 643
 644         if ( $md5 ne $key ) {
 645             next BUCKET;
 646         }
 647
 648         ##
 649         # Found match -- seek to offset and read signature
 650         ##
 651         my $signature;
 652         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 653         read( $fh, $signature, SIG_SIZE);
 654
 655         ##
 656         # If value is a hash or array, return new DBM::Deep object with correct offset
 657         ##
 658         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 659             my $obj = DBM::Deep->new(
 660                 type => $signature,
 661                 base_offset => $subloc,
 662                 root => $self->_root
 663             );
 664
 665             if ($self->_root->{autobless}) {
 666                 ##
 667                 # Skip over value and plain key to see if object needs
 668                 # to be re-blessed
 669                 ##
 670                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 671
 672                 my $size;
 673                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 674                 if ($size) { seek($fh, $size, SEEK_CUR); }
 675
 676                 my $bless_bit;
 677                 read( $fh, $bless_bit, 1);
 678                 if (ord($bless_bit)) {
 679                     ##
 680                     # Yes, object needs to be re-blessed
 681                     ##
 682                     my $class_name;
 683                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 684                     if ($size) { read( $fh, $class_name, $size); }
 685                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 686                 }
 687             }
 688
 689             return $obj;
 690         }
 691
 692         ##
 693         # Otherwise return actual value
 694         ##
 695         elsif ($signature eq SIG_DATA) {
 696             my $size;
 697             my $value = '';
 698             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 699             if ($size) { read( $fh, $value, $size); }
 700             return $value;
 701         }
 702
 703         ##
 704         # Key exists, but content is null
 705         ##
 706         else { return; }
 707         } # i loop
 708
 709         return;
 710 }
 711
 712 sub _delete_bucket {
 713         ##
 714         # Delete single key/value pair given tag and MD5 digested key.
 715         ##
 716         my $self = shift;
 717         my ($tag, $md5) = @_;
 718         my $keys = $tag->{content};
 719
 720     my $fh = $self->_fh;
 721
 722         ##
 723         # Iterate through buckets, looking for a key match
 724         ##
 725     BUCKET:
 726         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 727                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 728                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 729
 730                 if (!$subloc) {
 731                         ##
 732                         # Hit end of list, no match
 733                         ##
 734                         return;
 735                 }
 736
 737         if ( $md5 ne $key ) {
 738             next BUCKET;
 739         }
 740
 741         ##
 742         # Matched key -- delete bucket and return
 743         ##
 744         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 745         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 746         print( $fh chr(0) x $BUCKET_SIZE );
 747
 748         return 1;
 749         } # i loop
 750
 751         return;
 752 }
 753
 754 sub _bucket_exists {
 755         ##
 756         # Check existence of single key given tag and MD5 digested key.
 757         ##
 758         my $self = shift;
 759         my ($tag, $md5) = @_;
 760         my $keys = $tag->{content};
 761
 762         ##
 763         # Iterate through buckets, looking for a key match
 764         ##
 765     BUCKET:
 766         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 767                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 768                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 769
 770                 if (!$subloc) {
 771                         ##
 772                         # Hit end of list, no match
 773                         ##
 774                         return;
 775                 }
 776
 777         if ( $md5 ne $key ) {
 778             next BUCKET;
 779         }
 780
 781         ##
 782         # Matched key -- return true
 783         ##
 784         return 1;
 785         } # i loop
 786
 787         return;
 788 }
 789
 790 sub _find_bucket_list {
 791         ##
 792         # Locate offset for bucket list, given digested key
 793         ##
 794         my $self = shift;
 795         my $md5 = shift;
 796
 797         ##
 798         # Locate offset for bucket list using digest index system
 799         ##
 800         my $ch = 0;
 801         my $tag = $self->_load_tag($self->_base_offset);
 802         if (!$tag) { return; }
 803
 804         while ($tag->{signature} ne SIG_BLIST) {
 805                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 806                 if (!$tag) { return; }
 807                 $ch++;
 808         }
 809
 810         return $tag;
 811 }
 812
 813 sub _traverse_index {
 814         ##
 815         # Scan index and recursively step into deeper levels, looking for next key.
 816         ##
 817     my ($self, $offset, $ch, $force_return_next) = @_;
 818     $force_return_next = undef unless $force_return_next;
 819
 820         my $tag = $self->_load_tag( $offset );
 821
 822     my $fh = $self->_fh;
 823
 824         if ($tag->{signature} ne SIG_BLIST) {
 825                 my $content = $tag->{content};
 826                 my $start;
 827                 if ($self->{return_next}) { $start = 0; }
 828                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 829
 830                 for (my $index = $start; $index < 256; $index++) {
 831                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 832                         if ($subloc) {
 833                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 834                                 if (defined($result)) { return $result; }
 835                         }
 836                 } # index loop
 837
 838                 $self->{return_next} = 1;
 839         } # tag is an index
 840
 841         elsif ($tag->{signature} eq SIG_BLIST) {
 842                 my $keys = $tag->{content};
 843                 if ($force_return_next) { $self->{return_next} = 1; }
 844
 845                 ##
 846                 # Iterate through buckets, looking for a key match
 847                 ##
 848                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 849                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 850                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 851
 852                         if (!$subloc) {
 853                                 ##
 854                                 # End of bucket list -- return to outer loop
 855                                 ##
 856                                 $self->{return_next} = 1;
 857                                 last;
 858                         }
 859                         elsif ($key eq $self->{prev_md5}) {
 860                                 ##
 861                                 # Located previous key -- return next one found
 862                                 ##
 863                                 $self->{return_next} = 1;
 864                                 next;
 865                         }
 866                         elsif ($self->{return_next}) {
 867                                 ##
 868                                 # Seek to bucket location and skip over signature
 869                                 ##
 870                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 871
 872                                 ##
 873                                 # Skip over value to get to plain key
 874                                 ##
 875                                 my $size;
 876                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 877                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 878
 879                                 ##
 880                                 # Read in plain key and return as scalar
 881                                 ##
 882                                 my $plain_key;
 883                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 884                                 if ($size) { read( $fh, $plain_key, $size); }
 885
 886                                 return $plain_key;
 887                         }
 888                 } # bucket loop
 889
 890                 $self->{return_next} = 1;
 891         } # tag is a bucket list
 892
 893         return;
 894 }
 895
 896 sub _get_next_key {
 897         ##
 898         # Locate next key, given digested previous one
 899         ##
 900     my $self = $_[0]->_get_self;
 901
 902         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 903         $self->{return_next} = 0;
 904
 905         ##
 906         # If the previous key was not specifed, start at the top and
 907         # return the first one found.
 908         ##
 909         if (!$self->{prev_md5}) {
 910                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 911                 $self->{return_next} = 1;
 912         }
 913
 914         return $self->_traverse_index( $self->_base_offset, 0 );
 915 }
 916
 917 sub lock {
 918         ##
 919         # If db locking is set, flock() the db file.  If called multiple
 920         # times before unlock(), then the same number of unlocks() must
 921         # be called before the lock is released.
 922         ##
 923     my $self = $_[0]->_get_self;
 924         my $type = $_[1];
 925     $type = LOCK_EX unless defined $type;
 926
 927         if (!defined($self->_fh)) { return; }
 928
 929         if ($self->_root->{locking}) {
 930                 if (!$self->_root->{locked}) {
 931                         flock($self->_fh, $type);
 932
 933                         # refresh end counter in case file has changed size
 934                         my @stats = stat($self->_root->{file});
 935                         $self->_root->{end} = $stats[7];
 936
 937                         # double-check file inode, in case another process
 938                         # has optimize()d our file while we were waiting.
 939                         if ($stats[1] != $self->_root->{inode}) {
 940                                 $self->_open(); # re-open
 941                                 flock($self->_fh, $type); # re-lock
 942                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 943                         }
 944                 }
 945                 $self->_root->{locked}++;
 946
 947         return 1;
 948         }
 949
 950     return;
 951 }
 952
 953 sub unlock {
 954         ##
 955         # If db locking is set, unlock the db file.  See note in lock()
 956         # regarding calling lock() multiple times.
 957         ##
 958     my $self = $_[0]->_get_self;
 959
 960         if (!defined($self->_fh)) { return; }
 961
 962         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 963                 $self->_root->{locked}--;
 964                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 965
 966         return 1;
 967         }
 968
 969     return;
 970 }
 971
 972 sub _copy_value {
 973     my $self = shift->_get_self;
 974     my ($spot, $value) = @_;
 975
 976     if ( !ref $value ) {
 977         ${$spot} = $value;
 978     }
 979     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 980         my $type = $value->_type;
 981         ${$spot} = $type eq TYPE_HASH ? {} : [];
 982         $value->_copy_node( ${$spot} );
 983     }
 984     else {
 985         my $r = Scalar::Util::reftype( $value );
 986         my $c = Scalar::Util::blessed( $value );
 987         if ( $r eq 'ARRAY' ) {
 988             ${$spot} = [ @{$value} ];
 989         }
 990         else {
 991             ${$spot} = { %{$value} };
 992         }
 993         ${$spot} = bless ${$spot}, $c
 994             if defined $c;
 995     }
 996
 997     return 1;
 998 }
 999
1000 sub _copy_node {
1001         ##
1002         # Copy single level of keys or elements to new DB handle.
1003         # Recurse for nested structures
1004         ##
1005     my $self = shift->_get_self;
1006         my ($db_temp) = @_;
1007
1008         if ($self->_type eq TYPE_HASH) {
1009                 my $key = $self->first_key();
1010                 while ($key) {
1011                         my $value = $self->get($key);
1012             $self->_copy_value( \$db_temp->{$key}, $value );
1013                         $key = $self->next_key($key);
1014                 }
1015         }
1016         else {
1017                 my $length = $self->length();
1018                 for (my $index = 0; $index < $length; $index++) {
1019                         my $value = $self->get($index);
1020             $self->_copy_value( \$db_temp->[$index], $value );
1021                 }
1022         }
1023
1024     return 1;
1025 }
1026
1027 sub export {
1028         ##
1029         # Recursively export into standard Perl hashes and arrays.
1030         ##
1031     my $self = $_[0]->_get_self;
1032
1033         my $temp;
1034         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1035         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1036
1037         $self->lock();
1038         $self->_copy_node( $temp );
1039         $self->unlock();
1040
1041         return $temp;
1042 }
1043
1044 sub import {
1045         ##
1046         # Recursively import Perl hash/array structure
1047         ##
1048     #XXX This use of ref() seems to be ok
1049         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1050
1051     my $self = $_[0]->_get_self;
1052         my $struct = $_[1];
1053
1054     #XXX This use of ref() seems to be ok
1055         if (!ref($struct)) {
1056                 ##
1057                 # struct is not a reference, so just import based on our type
1058                 ##
1059                 shift @_;
1060
1061                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1062                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1063         }
1064
1065     my $r = Scalar::Util::reftype($struct) || '';
1066         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1067                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1068         }
1069         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1070                 $self->push( @$struct );
1071         }
1072         else {
1073                 return $self->_throw_error("Cannot import: type mismatch");
1074         }
1075
1076         return 1;
1077 }
1078
1079 sub optimize {
1080         ##
1081         # Rebuild entire database into new file, then move
1082         # it back on top of original.
1083         ##
1084     my $self = $_[0]->_get_self;
1085
1086 #XXX Need to create a new test for this
1087 #       if ($self->_root->{links} > 1) {
1088 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1089 #       }
1090
1091         my $db_temp = DBM::Deep->new(
1092                 file => $self->_root->{file} . '.tmp',
1093                 type => $self->_type
1094         );
1095         if (!$db_temp) {
1096                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1097         }
1098
1099         $self->lock();
1100         $self->_copy_node( $db_temp );
1101         undef $db_temp;
1102
1103         ##
1104         # Attempt to copy user, group and permissions over to new file
1105         ##
1106         my @stats = stat($self->_fh);
1107         my $perms = $stats[2] & 07777;
1108         my $uid = $stats[4];
1109         my $gid = $stats[5];
1110         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1111         chmod( $perms, $self->_root->{file} . '.tmp' );
1112
1113     # q.v. perlport for more information on this variable
1114     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1115                 ##
1116                 # Potential race condition when optmizing on Win32 with locking.
1117                 # The Windows filesystem requires that the filehandle be closed
1118                 # before it is overwritten with rename().  This could be redone
1119                 # with a soft copy.
1120                 ##
1121                 $self->unlock();
1122                 $self->_close();
1123         }
1124
1125         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1126                 unlink $self->_root->{file} . '.tmp';
1127                 $self->unlock();
1128                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1129         }
1130
1131         $self->unlock();
1132         $self->_close();
1133         $self->_open();
1134
1135         return 1;
1136 }
1137
1138 sub clone {
1139         ##
1140         # Make copy of object and return
1141         ##
1142     my $self = $_[0]->_get_self;
1143
1144         return DBM::Deep->new(
1145                 type => $self->_type,
1146                 base_offset => $self->_base_offset,
1147                 root => $self->_root
1148         );
1149 }
1150
1151 {
1152     my %is_legal_filter = map {
1153         $_ => ~~1,
1154     } qw(
1155         store_key store_value
1156         fetch_key fetch_value
1157     );
1158
1159     sub set_filter {
1160         ##
1161         # Setup filter function for storing or fetching the key or value
1162         ##
1163         my $self = $_[0]->_get_self;
1164         my $type = lc $_[1];
1165         my $func = $_[2] ? $_[2] : undef;
1166
1167         if ( $is_legal_filter{$type} ) {
1168             $self->_root->{"filter_$type"} = $func;
1169             return 1;
1170         }
1171
1172         return;
1173     }
1174 }
1175
1176 ##
1177 # Accessor methods
1178 ##
1179
1180 sub _root {
1181         ##
1182         # Get access to the root structure
1183         ##
1184     my $self = $_[0]->_get_self;
1185         return $self->{root};
1186 }
1187
1188 sub _fh {
1189         ##
1190         # Get access to the raw fh
1191         ##
1192     #XXX It will be useful, though, when we split out HASH and ARRAY
1193     my $self = $_[0]->_get_self;
1194         return $self->_root->{fh};
1195 }
1196
1197 sub _type {
1198         ##
1199         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1200         ##
1201     my $self = $_[0]->_get_self;
1202         return $self->{type};
1203 }
1204
1205 sub _base_offset {
1206         ##
1207         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1208         ##
1209     my $self = $_[0]->_get_self;
1210         return $self->{base_offset};
1211 }
1212
1213 ##
1214 # Utility methods
1215 ##
1216
1217 sub _throw_error {
1218     die "DBM::Deep: $_[1]\n";
1219 }
1220
1221 sub _precalc_sizes {
1222         ##
1223         # Precalculate index, bucket and bucket list sizes
1224         ##
1225
1226     #XXX I don't like this ...
1227     set_pack() unless defined $LONG_SIZE;
1228
1229         $INDEX_SIZE = 256 * $LONG_SIZE;
1230         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1231         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1232 }
1233
1234 sub set_pack {
1235         ##
1236         # Set pack/unpack modes (see file header for more)
1237         ##
1238     my ($long_s, $long_p, $data_s, $data_p) = @_;
1239
1240     $LONG_SIZE = $long_s ? $long_s : 4;
1241     $LONG_PACK = $long_p ? $long_p : 'N';
1242
1243     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1244     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1245
1246         _precalc_sizes();
1247 }
1248
1249 sub set_digest {
1250         ##
1251         # Set key digest function (default is MD5)
1252         ##
1253     my ($digest_func, $hash_size) = @_;
1254
1255     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1256     $HASH_SIZE = $hash_size ? $hash_size : 16;
1257
1258         _precalc_sizes();
1259 }
1260
1261 sub _is_writable {
1262     my $fh = shift;
1263     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1264 }
1265
1266 #sub _is_readable {
1267 #    my $fh = shift;
1268 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1269 #}
1270
1271 ##
1272 # tie() methods (hashes and arrays)
1273 ##
1274
1275 sub STORE {
1276         ##
1277         # Store single hash key/value or array element in database.
1278         ##
1279     my $self = $_[0]->_get_self;
1280         my $key = $_[1];
1281
1282     # User may be storing a hash, in which case we do not want it run
1283     # through the filtering system
1284         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1285         ? $self->_root->{filter_store_value}->($_[2])
1286         : $_[2];
1287
1288         my $md5 = $DIGEST_FUNC->($key);
1289
1290         ##
1291         # Make sure file is open
1292         ##
1293 #       if (!defined($self->_fh) && !$self->_open()) {
1294 #               return;
1295 #       }
1296
1297     unless ( _is_writable( $self->_fh ) ) {
1298         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1299     }
1300
1301         ##
1302         # Request exclusive lock for writing
1303         ##
1304         $self->lock( LOCK_EX );
1305
1306         my $fh = $self->_fh;
1307
1308         ##
1309         # Locate offset for bucket list using digest index system
1310         ##
1311         my $tag = $self->_load_tag($self->_base_offset);
1312         if (!$tag) {
1313                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1314         }
1315
1316         my $ch = 0;
1317         while ($tag->{signature} ne SIG_BLIST) {
1318                 my $num = ord(substr($md5, $ch, 1));
1319
1320         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1321                 my $new_tag = $self->_index_lookup($tag, $num);
1322
1323                 if (!$new_tag) {
1324                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1325                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1326
1327                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1328
1329                         $tag->{ref_loc} = $ref_loc;
1330                         $tag->{ch} = $ch;
1331
1332                         last;
1333                 }
1334                 else {
1335                         $tag = $new_tag;
1336
1337                         $tag->{ref_loc} = $ref_loc;
1338                         $tag->{ch} = $ch;
1339                 }
1340                 $ch++;
1341         }
1342
1343         ##
1344         # Add key/value to bucket list
1345         ##
1346         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1347
1348         $self->unlock();
1349
1350         return $result;
1351 }
1352
1353 sub FETCH {
1354         ##
1355         # Fetch single value or element given plain key or array index
1356         ##
1357     my $self = shift->_get_self;
1358     my $key = shift;
1359
1360         ##
1361         # Make sure file is open
1362         ##
1363 #       if (!defined($self->_fh)) { $self->_open(); }
1364
1365         my $md5 = $DIGEST_FUNC->($key);
1366
1367         ##
1368         # Request shared lock for reading
1369         ##
1370         $self->lock( LOCK_SH );
1371
1372         my $tag = $self->_find_bucket_list( $md5 );
1373         if (!$tag) {
1374                 $self->unlock();
1375                 return;
1376         }
1377
1378         ##
1379         # Get value from bucket list
1380         ##
1381         my $result = $self->_get_bucket_value( $tag, $md5 );
1382
1383         $self->unlock();
1384
1385     #XXX What is ref() checking here?
1386     #YYY Filters only apply on scalar values, so the ref check is making
1387     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1388         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1389         ? $self->_root->{filter_fetch_value}->($result)
1390         : $result;
1391 }
1392
1393 sub DELETE {
1394         ##
1395         # Delete single key/value pair or element given plain key or array index
1396         ##
1397     my $self = $_[0]->_get_self;
1398         my $key = $_[1];
1399
1400         my $md5 = $DIGEST_FUNC->($key);
1401
1402         ##
1403         # Make sure file is open
1404         ##
1405 #       if (!defined($self->_fh)) { $self->_open(); }
1406
1407         ##
1408         # Request exclusive lock for writing
1409         ##
1410         $self->lock( LOCK_EX );
1411
1412         my $tag = $self->_find_bucket_list( $md5 );
1413         if (!$tag) {
1414                 $self->unlock();
1415                 return;
1416         }
1417
1418         ##
1419         # Delete bucket
1420         ##
1421     my $value = $self->_get_bucket_value( $tag, $md5 );
1422         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1423         $value = $self->_root->{filter_fetch_value}->($value);
1424     }
1425
1426         my $result = $self->_delete_bucket( $tag, $md5 );
1427
1428         ##
1429         # If this object is an array and the key deleted was on the end of the stack,
1430         # decrement the length variable.
1431         ##
1432
1433         $self->unlock();
1434
1435         return $value;
1436 }
1437
1438 sub EXISTS {
1439         ##
1440         # Check if a single key or element exists given plain key or array index
1441         ##
1442     my $self = $_[0]->_get_self;
1443         my $key = $_[1];
1444
1445         my $md5 = $DIGEST_FUNC->($key);
1446
1447         ##
1448         # Make sure file is open
1449         ##
1450 #       if (!defined($self->_fh)) { $self->_open(); }
1451
1452         ##
1453         # Request shared lock for reading
1454         ##
1455         $self->lock( LOCK_SH );
1456
1457         my $tag = $self->_find_bucket_list( $md5 );
1458
1459         ##
1460         # For some reason, the built-in exists() function returns '' for false
1461         ##
1462         if (!$tag) {
1463                 $self->unlock();
1464                 return '';
1465         }
1466
1467         ##
1468         # Check if bucket exists and return 1 or ''
1469         ##
1470         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1471
1472         $self->unlock();
1473
1474         return $result;
1475 }
1476
1477 sub CLEAR {
1478         ##
1479         # Clear all keys from hash, or all elements from array.
1480         ##
1481     my $self = $_[0]->_get_self;
1482
1483         ##
1484         # Make sure file is open
1485         ##
1486 #       if (!defined($self->_fh)) { $self->_open(); }
1487
1488         ##
1489         # Request exclusive lock for writing
1490         ##
1491         $self->lock( LOCK_EX );
1492
1493     my $fh = $self->_fh;
1494
1495         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1496         if (eof $fh) {
1497                 $self->unlock();
1498                 return;
1499         }
1500
1501         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1502
1503         $self->unlock();
1504
1505         return 1;
1506 }
1507
1508 ##
1509 # Public method aliases
1510 ##
1511 sub put { (shift)->STORE( @_ ) }
1512 sub store { (shift)->STORE( @_ ) }
1513 sub get { (shift)->FETCH( @_ ) }
1514 sub fetch { (shift)->FETCH( @_ ) }
1515 sub delete { (shift)->DELETE( @_ ) }
1516 sub exists { (shift)->EXISTS( @_ ) }
1517 sub clear { (shift)->CLEAR( @_ ) }
1518
1519 package DBM::Deep::_::Root;
1520
1521 sub new {
1522     my $class = shift;
1523     my ($args) = @_;
1524
1525     my $self = bless {
1526         file => undef,
1527         fh => undef,
1528         file_offset => 0,
1529         end => 0,
1530         autoflush => undef,
1531         locking => undef,
1532         debug => undef,
1533         filter_store_key => undef,
1534         filter_store_value => undef,
1535         filter_fetch_key => undef,
1536         filter_fetch_value => undef,
1537         autobless => undef,
1538         locked => 0,
1539         %$args,
1540     }, $class;
1541
1542     if ( $self->{fh} && !$self->{file_offset} ) {
1543         $self->{file_offset} = tell( $self->{fh} );
1544     }
1545
1546     return $self;
1547 }
1548
1549 sub DESTROY {
1550     my $self = shift;
1551     return unless $self;
1552
1553     close $self->{fh} if $self->{fh};
1554
1555     return;
1556 }
1557
1558 1;
1559
1560 __END__
1561
1562 =head1 NAME
1563
1564 DBM::Deep - A pure perl multi-level hash/array DBM
1565
1566 =head1 SYNOPSIS
1567
1568   use DBM::Deep;
1569   my $db = DBM::Deep->new( "foo.db" );
1570
1571   $db->{key} = 'value'; # tie() style
1572   print $db->{key};
1573
1574   $db->put('key' => 'value'); # OO style
1575   print $db->get('key');
1576
1577   # true multi-level support
1578   $db->{my_complex} = [
1579         'hello', { perl => 'rules' },
1580         42, 99,
1581   ];
1582
1583 =head1 DESCRIPTION
1584
1585 A unique flat-file database module, written in pure perl.  True
1586 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1587 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1588 handle millions of keys and unlimited hash levels without significant
1589 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1590 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1591 Mac OS X and Windows.
1592
1593 =head1 INSTALLATION
1594
1595 Hopefully you are using Perl's excellent CPAN module, which will download
1596 and install the module for you.  If not, get the tarball, and run these
1597 commands:
1598
1599         tar zxf DBM-Deep-*
1600         cd DBM-Deep-*
1601         perl Makefile.PL
1602         make
1603         make test
1604         make install
1605
1606 =head1 SETUP
1607
1608 Construction can be done OO-style (which is the recommended way), or using
1609 Perl's tie() function.  Both are examined here.
1610
1611 =head2 OO CONSTRUCTION
1612
1613 The recommended way to construct a DBM::Deep object is to use the new()
1614 method, which gets you a blessed, tied hash or array reference.
1615
1616         my $db = DBM::Deep->new( "foo.db" );
1617
1618 This opens a new database handle, mapped to the file "foo.db".  If this
1619 file does not exist, it will automatically be created.  DB files are
1620 opened in "r+" (read/write) mode, and the type of object returned is a
1621 hash, unless otherwise specified (see L<OPTIONS> below).
1622
1623 You can pass a number of options to the constructor to specify things like
1624 locking, autoflush, etc.  This is done by passing an inline hash:
1625
1626         my $db = DBM::Deep->new(
1627                 file => "foo.db",
1628                 locking => 1,
1629                 autoflush => 1
1630         );
1631
1632 Notice that the filename is now specified I<inside> the hash with
1633 the "file" parameter, as opposed to being the sole argument to the
1634 constructor.  This is required if any options are specified.
1635 See L<OPTIONS> below for the complete list.
1636
1637
1638
1639 You can also start with an array instead of a hash.  For this, you must
1640 specify the C<type> parameter:
1641
1642         my $db = DBM::Deep->new(
1643                 file => "foo.db",
1644                 type => DBM::Deep->TYPE_ARRAY
1645         );
1646
1647 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1648 a new DB file.  If you create a DBM::Deep object with an existing file, the
1649 C<type> will be loaded from the file header, and an error will be thrown if
1650 the wrong type is passed in.
1651
1652 =head2 TIE CONSTRUCTION
1653
1654 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1655 tie() function.  The object returned from tie() can be used to call methods,
1656 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1657 file (as expected with most tie'd objects).
1658
1659         my %hash;
1660         my $db = tie %hash, "DBM::Deep", "foo.db";
1661
1662         my @array;
1663         my $db = tie @array, "DBM::Deep", "bar.db";
1664
1665 As with the OO constructor, you can replace the DB filename parameter with
1666 a hash containing one or more options (see L<OPTIONS> just below for the
1667 complete list).
1668
1669         tie %hash, "DBM::Deep", {
1670                 file => "foo.db",
1671                 locking => 1,
1672                 autoflush => 1
1673         };
1674
1675 =head2 OPTIONS
1676
1677 There are a number of options that can be passed in when constructing your
1678 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1679
1680 =over
1681
1682 =item * file
1683
1684 Filename of the DB file to link the handle to.  You can pass a full absolute
1685 filesystem path, partial path, or a plain filename if the file is in the
1686 current working directory.  This is a required parameter (though q.v. fh).
1687
1688 =item * fh
1689
1690 If you want, you can pass in the fh instead of the file. This is most useful for doing
1691 something like:
1692
1693   my $db = DBM::Deep->new( { fh => \*DATA } );
1694
1695 You are responsible for making sure that the fh has been opened appropriately for your
1696 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1697 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1698 needs to read from the fh.
1699
1700 =item * file_offset
1701
1702 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1703 not need to set this. However, it's there if you want it.
1704
1705 If you pass in fh and do not set this, it will be set appropriately.
1706
1707 =item * type
1708
1709 This parameter specifies what type of object to create, a hash or array.  Use
1710 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1711 This only takes effect when beginning a new file.  This is an optional
1712 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1713
1714 =item * locking
1715
1716 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1717 function to lock the database in exclusive mode for writes, and shared mode for
1718 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1719 any child hashes or arrays> that use the same DB file.  This is an optional
1720 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1721
1722 =item * autoflush
1723
1724 Specifies whether autoflush is to be enabled on the underlying filehandle.
1725 This obviously slows down write operations, but is required if you may have
1726 multiple processes accessing the same DB file (also consider enable I<locking>).
1727 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1728 (disabled).
1729
1730 =item * autobless
1731
1732 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1733 restore them when fetched.  This is an B<experimental> feature, and does have
1734 side-effects.  Basically, when hashes are re-blessed into their original
1735 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1736 able to call any DBM::Deep methods on them.  You have been warned.
1737 This is an optional parameter, and defaults to 0 (disabled).
1738
1739 =item * filter_*
1740
1741 See L<FILTERS> below.
1742
1743 =item * debug
1744
1745 Setting I<debug> mode will make all errors non-fatal, dump them out to
1746 STDERR, and continue on.  This is for debugging purposes only, and probably
1747 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1748
1749 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1750
1751 =back
1752
1753 =head1 TIE INTERFACE
1754
1755 With DBM::Deep you can access your databases using Perl's standard hash/array
1756 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1757 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1758 to the right place -- the DB file.  This has nothing to do with the
1759 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1760 using regular hashes and arrays, rather than calling functions like C<get()>
1761 and C<put()> (although those work too).  It is entirely up to you how to want
1762 to access your databases.
1763
1764 =head2 HASHES
1765
1766 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1767 or even nested hashes (or arrays) using standard Perl syntax:
1768
1769         my $db = DBM::Deep->new( "foo.db" );
1770
1771         $db->{mykey} = "myvalue";
1772         $db->{myhash} = {};
1773         $db->{myhash}->{subkey} = "subvalue";
1774
1775         print $db->{myhash}->{subkey} . "\n";
1776
1777 You can even step through hash keys using the normal Perl C<keys()> function:
1778
1779         foreach my $key (keys %$db) {
1780                 print "$key: " . $db->{$key} . "\n";
1781         }
1782
1783 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1784 pushes them onto an array, all before the loop even begins.  If you have an
1785 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1786 Perl's C<each()> function, which pulls keys/values one at a time, using very
1787 little memory:
1788
1789         while (my ($key, $value) = each %$db) {
1790                 print "$key: $value\n";
1791         }
1792
1793 Please note that when using C<each()>, you should always pass a direct
1794 hash reference, not a lookup.  Meaning, you should B<never> do this:
1795
1796         # NEVER DO THIS
1797         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1798
1799 This causes an infinite loop, because for each iteration, Perl is calling
1800 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1801 it effectively keeps returning the first key over and over again. Instead,
1802 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1803
1804 =head2 ARRAYS
1805
1806 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1807 reference.  This includes inserting, removing and manipulating elements,
1808 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1809 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1810 or simply be a nested array reference inside a hash.  Example:
1811
1812         my $db = DBM::Deep->new(
1813                 file => "foo-array.db",
1814                 type => DBM::Deep->TYPE_ARRAY
1815         );
1816
1817         $db->[0] = "foo";
1818         push @$db, "bar", "baz";
1819         unshift @$db, "bah";
1820
1821         my $last_elem = pop @$db; # baz
1822         my $first_elem = shift @$db; # bah
1823         my $second_elem = $db->[1]; # bar
1824
1825         my $num_elements = scalar @$db;
1826
1827 =head1 OO INTERFACE
1828
1829 In addition to the I<tie()> interface, you can also use a standard OO interface
1830 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1831 array) has its own methods, but both types share the following common methods:
1832 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1833
1834 =over
1835
1836 =item * new() / clone()
1837
1838 These are the constructor and copy-functions.
1839
1840 =item * put() / store()
1841
1842 Stores a new hash key/value pair, or sets an array element value.  Takes two
1843 arguments, the hash key or array index, and the new value.  The value can be
1844 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1845
1846         $db->put("foo", "bar"); # for hashes
1847         $db->put(1, "bar"); # for arrays
1848
1849 =item * get() / fetch()
1850
1851 Fetches the value of a hash key or array element.  Takes one argument: the hash
1852 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1853 data type stored.
1854
1855         my $value = $db->get("foo"); # for hashes
1856         my $value = $db->get(1); # for arrays
1857
1858 =item * exists()
1859
1860 Checks if a hash key or array index exists.  Takes one argument: the hash key
1861 or array index.  Returns true if it exists, false if not.
1862
1863         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1864         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1865
1866 =item * delete()
1867
1868 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1869 key or array index.  Returns true on success, false if not found.  For arrays,
1870 the remaining elements located after the deleted element are NOT moved over.
1871 The deleted element is essentially just undefined, which is exactly how Perl's
1872 internal arrays work.  Please note that the space occupied by the deleted
1873 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1874 below for details and workarounds.
1875
1876         $db->delete("foo"); # for hashes
1877         $db->delete(1); # for arrays
1878
1879 =item * clear()
1880
1881 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1882 value.  Please note that the space occupied by the deleted keys/values or
1883 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1884 details and workarounds.
1885
1886         $db->clear(); # hashes or arrays
1887
1888 =item * lock() / unlock()
1889
1890 q.v. Locking.
1891
1892 =item * optimize()
1893
1894 Recover lost disk space.
1895
1896 =item * import() / export()
1897
1898 Data going in and out.
1899
1900 =item * set_digest() / set_pack() / set_filter()
1901
1902 q.v. adjusting the interal parameters.
1903
1904 =back
1905
1906 =head2 HASHES
1907
1908 For hashes, DBM::Deep supports all the common methods described above, and the
1909 following additional methods: C<first_key()> and C<next_key()>.
1910
1911 =over
1912
1913 =item * first_key()
1914
1915 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1916 fetched in an undefined order (which appears random).  Takes no arguments,
1917 returns the key as a scalar value.
1918
1919         my $key = $db->first_key();
1920
1921 =item * next_key()
1922
1923 Returns the "next" key in the hash, given the previous one as the sole argument.
1924 Returns undef if there are no more keys to be fetched.
1925
1926         $key = $db->next_key($key);
1927
1928 =back
1929
1930 Here are some examples of using hashes:
1931
1932         my $db = DBM::Deep->new( "foo.db" );
1933
1934         $db->put("foo", "bar");
1935         print "foo: " . $db->get("foo") . "\n";
1936
1937         $db->put("baz", {}); # new child hash ref
1938         $db->get("baz")->put("buz", "biz");
1939         print "buz: " . $db->get("baz")->get("buz") . "\n";
1940
1941         my $key = $db->first_key();
1942         while ($key) {
1943                 print "$key: " . $db->get($key) . "\n";
1944                 $key = $db->next_key($key);
1945         }
1946
1947         if ($db->exists("foo")) { $db->delete("foo"); }
1948
1949 =head2 ARRAYS
1950
1951 For arrays, DBM::Deep supports all the common methods described above, and the
1952 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1953 C<unshift()> and C<splice()>.
1954
1955 =over
1956
1957 =item * length()
1958
1959 Returns the number of elements in the array.  Takes no arguments.
1960
1961         my $len = $db->length();
1962
1963 =item * push()
1964
1965 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1966 refs or array refs.  No return value.
1967
1968         $db->push("foo", "bar", {});
1969
1970 =item * pop()
1971
1972 Fetches the last element in the array, and deletes it.  Takes no arguments.
1973 Returns undef if array is empty.  Returns the element value.
1974
1975         my $elem = $db->pop();
1976
1977 =item * shift()
1978
1979 Fetches the first element in the array, deletes it, then shifts all the
1980 remaining elements over to take up the space.  Returns the element value.  This
1981 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1982 details.
1983
1984         my $elem = $db->shift();
1985
1986 =item * unshift()
1987
1988 Inserts one or more elements onto the beginning of the array, shifting all
1989 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1990 No return value.  This method is not recommended with large arrays -- see
1991 <LARGE ARRAYS> below for details.
1992
1993         $db->unshift("foo", "bar", {});
1994
1995 =item * splice()
1996
1997 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1998 -f splice> for usage -- it is too complicated to document here.  This method is
1999 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2000
2001 =back
2002
2003 Here are some examples of using arrays:
2004
2005         my $db = DBM::Deep->new(
2006                 file => "foo.db",
2007                 type => DBM::Deep->TYPE_ARRAY
2008         );
2009
2010         $db->push("bar", "baz");
2011         $db->unshift("foo");
2012         $db->put(3, "buz");
2013
2014         my $len = $db->length();
2015         print "length: $len\n"; # 4
2016
2017         for (my $k=0; $k<$len; $k++) {
2018                 print "$k: " . $db->get($k) . "\n";
2019         }
2020
2021         $db->splice(1, 2, "biz", "baf");
2022
2023         while (my $elem = shift @$db) {
2024                 print "shifted: $elem\n";
2025         }
2026
2027 =head1 LOCKING
2028
2029 Enable automatic file locking by passing a true value to the C<locking>
2030 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2031
2032         my $db = DBM::Deep->new(
2033                 file => "foo.db",
2034                 locking => 1
2035         );
2036
2037 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2038 mode for writes, and shared mode for reads.  This is required if you have
2039 multiple processes accessing the same database file, to avoid file corruption.
2040 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2041 NFS> below for more.
2042
2043 =head2 EXPLICIT LOCKING
2044
2045 You can explicitly lock a database, so it remains locked for multiple
2046 transactions.  This is done by calling the C<lock()> method, and passing an
2047 optional lock mode argument (defaults to exclusive mode).  This is particularly
2048 useful for things like counters, where the current value needs to be fetched,
2049 then incremented, then stored again.
2050
2051         $db->lock();
2052         my $counter = $db->get("counter");
2053         $counter++;
2054         $db->put("counter", $counter);
2055         $db->unlock();
2056
2057         # or...
2058
2059         $db->lock();
2060         $db->{counter}++;
2061         $db->unlock();
2062
2063 You can pass C<lock()> an optional argument, which specifies which mode to use
2064 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2065 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2066 same as the constants defined in Perl's C<Fcntl> module.
2067
2068         $db->lock( DBM::Deep->LOCK_SH );
2069         # something here
2070         $db->unlock();
2071
2072 =head1 IMPORTING/EXPORTING
2073
2074 You can import existing complex structures by calling the C<import()> method,
2075 and export an entire database into an in-memory structure using the C<export()>
2076 method.  Both are examined here.
2077
2078 =head2 IMPORTING
2079
2080 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2081 walking the structure and adding keys/elements to the database as you go,
2082 simply pass a reference to the C<import()> method.  This recursively adds
2083 everything to an existing DBM::Deep object for you.  Here is an example:
2084
2085         my $struct = {
2086                 key1 => "value1",
2087                 key2 => "value2",
2088                 array1 => [ "elem0", "elem1", "elem2" ],
2089                 hash1 => {
2090                         subkey1 => "subvalue1",
2091                         subkey2 => "subvalue2"
2092                 }
2093         };
2094
2095         my $db = DBM::Deep->new( "foo.db" );
2096         $db->import( $struct );
2097
2098         print $db->{key1} . "\n"; # prints "value1"
2099
2100 This recursively imports the entire C<$struct> object into C<$db>, including
2101 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2102 keys are merged with the existing ones, replacing if they already exist.
2103 The C<import()> method can be called on any database level (not just the base
2104 level), and works with both hash and array DB types.
2105
2106 B<Note:> Make sure your existing structure has no circular references in it.
2107 These will cause an infinite loop when importing.
2108
2109 =head2 EXPORTING
2110
2111 Calling the C<export()> method on an existing DBM::Deep object will return
2112 a reference to a new in-memory copy of the database.  The export is done
2113 recursively, so all nested hashes/arrays are all exported to standard Perl
2114 objects.  Here is an example:
2115
2116         my $db = DBM::Deep->new( "foo.db" );
2117
2118         $db->{key1} = "value1";
2119         $db->{key2} = "value2";
2120         $db->{hash1} = {};
2121         $db->{hash1}->{subkey1} = "subvalue1";
2122         $db->{hash1}->{subkey2} = "subvalue2";
2123
2124         my $struct = $db->export();
2125
2126         print $struct->{key1} . "\n"; # prints "value1"
2127
2128 This makes a complete copy of the database in memory, and returns a reference
2129 to it.  The C<export()> method can be called on any database level (not just
2130 the base level), and works with both hash and array DB types.  Be careful of
2131 large databases -- you can store a lot more data in a DBM::Deep object than an
2132 in-memory Perl structure.
2133
2134 B<Note:> Make sure your database has no circular references in it.
2135 These will cause an infinite loop when exporting.
2136
2137 =head1 FILTERS
2138
2139 DBM::Deep has a number of hooks where you can specify your own Perl function
2140 to perform filtering on incoming or outgoing data.  This is a perfect
2141 way to extend the engine, and implement things like real-time compression or
2142 encryption.  Filtering applies to the base DB level, and all child hashes /
2143 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2144 constructed, or by calling the C<set_filter()> method at any time.  There are
2145 four available filter hooks, described below:
2146
2147 =over
2148
2149 =item * filter_store_key
2150
2151 This filter is called whenever a hash key is stored.  It
2152 is passed the incoming key, and expected to return a transformed key.
2153
2154 =item * filter_store_value
2155
2156 This filter is called whenever a hash key or array element is stored.  It
2157 is passed the incoming value, and expected to return a transformed value.
2158
2159 =item * filter_fetch_key
2160
2161 This filter is called whenever a hash key is fetched (i.e. via
2162 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2163 and expected to return the plain key.
2164
2165 =item * filter_fetch_value
2166
2167 This filter is called whenever a hash key or array element is fetched.
2168 It is passed the transformed value, and expected to return the plain value.
2169
2170 =back
2171
2172 Here are the two ways to setup a filter hook:
2173
2174         my $db = DBM::Deep->new(
2175                 file => "foo.db",
2176                 filter_store_value => \&my_filter_store,
2177                 filter_fetch_value => \&my_filter_fetch
2178         );
2179
2180         # or...
2181
2182         $db->set_filter( "filter_store_value", \&my_filter_store );
2183         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2184
2185 Your filter function will be called only when dealing with SCALAR keys or
2186 values.  When nested hashes and arrays are being stored/fetched, filtering
2187 is bypassed.  Filters are called as static functions, passed a single SCALAR
2188 argument, and expected to return a single SCALAR value.  If you want to
2189 remove a filter, set the function reference to C<undef>:
2190
2191         $db->set_filter( "filter_store_value", undef );
2192
2193 =head2 REAL-TIME ENCRYPTION EXAMPLE
2194
2195 Here is a working example that uses the I<Crypt::Blowfish> module to
2196 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2197 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2198 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2199
2200         use DBM::Deep;
2201         use Crypt::Blowfish;
2202         use Crypt::CBC;
2203
2204         my $cipher = Crypt::CBC->new({
2205                 'key'             => 'my secret key',
2206                 'cipher'          => 'Blowfish',
2207                 'iv'              => '$KJh#(}q',
2208                 'regenerate_key'  => 0,
2209                 'padding'         => 'space',
2210                 'prepend_iv'      => 0
2211         });
2212
2213         my $db = DBM::Deep->new(
2214                 file => "foo-encrypt.db",
2215                 filter_store_key => \&my_encrypt,
2216                 filter_store_value => \&my_encrypt,
2217                 filter_fetch_key => \&my_decrypt,
2218                 filter_fetch_value => \&my_decrypt,
2219         );
2220
2221         $db->{key1} = "value1";
2222         $db->{key2} = "value2";
2223         print "key1: " . $db->{key1} . "\n";
2224         print "key2: " . $db->{key2} . "\n";
2225
2226         undef $db;
2227         exit;
2228
2229         sub my_encrypt {
2230                 return $cipher->encrypt( $_[0] );
2231         }
2232         sub my_decrypt {
2233                 return $cipher->decrypt( $_[0] );
2234         }
2235
2236 =head2 REAL-TIME COMPRESSION EXAMPLE
2237
2238 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2239 compression / decompression of keys & values with DBM::Deep Filters.
2240 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2241 more on I<Compress::Zlib>.
2242
2243         use DBM::Deep;
2244         use Compress::Zlib;
2245
2246         my $db = DBM::Deep->new(
2247                 file => "foo-compress.db",
2248                 filter_store_key => \&my_compress,
2249                 filter_store_value => \&my_compress,
2250                 filter_fetch_key => \&my_decompress,
2251                 filter_fetch_value => \&my_decompress,
2252         );
2253
2254         $db->{key1} = "value1";
2255         $db->{key2} = "value2";
2256         print "key1: " . $db->{key1} . "\n";
2257         print "key2: " . $db->{key2} . "\n";
2258
2259         undef $db;
2260         exit;
2261
2262         sub my_compress {
2263                 return Compress::Zlib::memGzip( $_[0] ) ;
2264         }
2265         sub my_decompress {
2266                 return Compress::Zlib::memGunzip( $_[0] ) ;
2267         }
2268
2269 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2270 actually numerical index numbers, and are not filtered.
2271
2272 =head1 ERROR HANDLING
2273
2274 Most DBM::Deep methods return a true value for success, and call die() on
2275 failure.  You can wrap calls in an eval block to catch the die.
2276
2277         my $db = DBM::Deep->new( "foo.db" ); # create hash
2278         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2279
2280     print $@;           # prints error message
2281
2282 =head1 LARGEFILE SUPPORT
2283
2284 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2285 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2286 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2287 by calling the static C<set_pack()> method before you do anything else.
2288
2289         DBM::Deep::set_pack(8, 'Q');
2290
2291 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2292 instead of 32-bit longs.  After setting these values your DB files have a
2293 theoretical maximum size of 16 XB (exabytes).
2294
2295 B<Note:> Changing these values will B<NOT> work for existing database files.
2296 Only change this for new files, and make sure it stays set consistently
2297 throughout the file's life.  If you do set these values, you can no longer
2298 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2299 back to 32-bit mode.
2300
2301 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2302 only a 32-bit Perl.  However, I have received user reports that this does
2303 indeed work!
2304
2305 =head1 LOW-LEVEL ACCESS
2306
2307 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2308 you can call the C<_fh()> method, which returns the handle:
2309
2310         my $fh = $db->_fh();
2311
2312 This method can be called on the root level of the datbase, or any child
2313 hashes or arrays.  All levels share a I<root> structure, which contains things
2314 like the filehandle, a reference counter, and all the options specified
2315 when you created the object.  You can get access to this root structure by
2316 calling the C<root()> method.
2317
2318         my $root = $db->_root();
2319
2320 This is useful for changing options after the object has already been created,
2321 such as enabling/disabling locking, or debug modes.  You can also
2322 store your own temporary user data in this structure (be wary of name
2323 collision), which is then accessible from any child hash or array.
2324
2325 =head1 CUSTOM DIGEST ALGORITHM
2326
2327 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2328 keys.  However you can override this, and use another algorithm (such as SHA-256)
2329 or even write your own.  But please note that DBM::Deep currently expects zero
2330 collisions, so your algorithm has to be I<perfect>, so to speak.
2331 Collision detection may be introduced in a later version.
2332
2333
2334
2335 You can specify a custom digest algorithm by calling the static C<set_digest()>
2336 function, passing a reference to a subroutine, and the length of the algorithm's
2337 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2338 objects.  Here is a working example that uses a 256-bit hash from the
2339 I<Digest::SHA256> module.  Please see
2340 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2341
2342         use DBM::Deep;
2343         use Digest::SHA256;
2344
2345         my $context = Digest::SHA256::new(256);
2346
2347         DBM::Deep::set_digest( \&my_digest, 32 );
2348
2349         my $db = DBM::Deep->new( "foo-sha.db" );
2350
2351         $db->{key1} = "value1";
2352         $db->{key2} = "value2";
2353         print "key1: " . $db->{key1} . "\n";
2354         print "key2: " . $db->{key2} . "\n";
2355
2356         undef $db;
2357         exit;
2358
2359         sub my_digest {
2360                 return substr( $context->hash($_[0]), 0, 32 );
2361         }
2362
2363 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2364 of bytes you specify in the C<set_digest()> function (in this case 32).
2365
2366 =head1 CIRCULAR REFERENCES
2367
2368 DBM::Deep has B<experimental> support for circular references.  Meaning you
2369 can have a nested hash key or array element that points to a parent object.
2370 This relationship is stored in the DB file, and is preserved between sessions.
2371 Here is an example:
2372
2373         my $db = DBM::Deep->new( "foo.db" );
2374
2375         $db->{foo} = "bar";
2376         $db->{circle} = $db; # ref to self
2377
2378         print $db->{foo} . "\n"; # prints "foo"
2379         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2380
2381 One catch is, passing the object to a function that recursively walks the
2382 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2383 C<export()> methods) will result in an infinite loop.  The other catch is,
2384 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2385 or C<next_key()> methods), you will get the I<target object's key>, not the
2386 ref's key.  This gets even more interesting with the above example, where
2387 the I<circle> key points to the base DB object, which technically doesn't
2388 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2389 special case.
2390
2391 =head1 CAVEATS / ISSUES / BUGS
2392
2393 This section describes all the known issues with DBM::Deep.  It you have found
2394 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2395
2396 =head2 UNUSED SPACE RECOVERY
2397
2398 One major caveat with DBM::Deep is that space occupied by existing keys and
2399 values is not recovered when they are deleted.  Meaning if you keep deleting
2400 and adding new keys, your file will continuously grow.  I am working on this,
2401 but in the meantime you can call the built-in C<optimize()> method from time to
2402 time (perhaps in a crontab or something) to recover all your unused space.
2403
2404         $db->optimize(); # returns true on success
2405
2406 This rebuilds the ENTIRE database into a new file, then moves it on top of
2407 the original.  The new file will have no unused space, thus it will take up as
2408 little disk space as possible.  Please note that this operation can take
2409 a long time for large files, and you need enough disk space to temporarily hold
2410 2 copies of your DB file.  The temporary file is created in the same directory
2411 as the original, named with a ".tmp" extension, and is deleted when the
2412 operation completes.  Oh, and if locking is enabled, the DB is automatically
2413 locked for the entire duration of the copy.
2414
2415 B<WARNING:> Only call optimize() on the top-level node of the database, and
2416 make sure there are no child references lying around.  DBM::Deep keeps a reference
2417 counter, and if it is greater than 1, optimize() will abort and return undef.
2418
2419 =head2 AUTOVIVIFICATION
2420
2421 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2422 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2423 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2424 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2425 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2426 this does not work:
2427
2428         $db->{foo}->{bar} = "hello";
2429
2430 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2431 being an empty hash.  Try this instead, which works fine:
2432
2433         $db->{foo} = { bar => "hello" };
2434
2435 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2436 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2437 Probably a bug in Perl.
2438
2439 =head2 FILE CORRUPTION
2440
2441 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2442 for a 32-bit signature when opened, but other corruption in files can cause
2443 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2444 stuck in an infinite loop depending on the level of corruption.  File write
2445 operations are not checked for failure (for speed), so if you happen to run
2446 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2447 be addressed in a later version of DBM::Deep.
2448
2449 =head2 DB OVER NFS
2450
2451 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2452 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2453 about setting up your NFS server with a locking daemon, then using lockf() to
2454 lock your files, but your mileage may vary there as well.  From what I
2455 understand, there is no real way to do it.  However, if you need access to the
2456 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2457 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2458
2459 =head2 COPYING OBJECTS
2460
2461 Beware of copying tied objects in Perl.  Very strange things can happen.
2462 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2463 returns a new, blessed, tied hash or array to the same level in the DB.
2464
2465         my $copy = $db->clone();
2466
2467 B<Note>: Since clone() here is cloning the object, not the database location, any
2468 modifications to either $db or $copy will be visible in both.
2469
2470 =head2 LARGE ARRAYS
2471
2472 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2473 These functions cause every element in the array to move, which can be murder
2474 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2475 a different location.  This will be addressed in the forthcoming version 1.00.
2476
2477 =head2 WRITEONLY FILES
2478
2479 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2480 writeonly mode. STORE will verify that the filehandle is writable. However, there
2481 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2482 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2483
2484 =head1 PERFORMANCE
2485
2486 This section discusses DBM::Deep's speed and memory usage.
2487
2488 =head2 SPEED
2489
2490 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2491 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2492 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2493 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2494 with huge databases.  Here is some test data:
2495
2496         Adding 1,000,000 keys to new DB file...
2497
2498         At 100 keys, avg. speed is 2,703 keys/sec
2499         At 200 keys, avg. speed is 2,642 keys/sec
2500         At 300 keys, avg. speed is 2,598 keys/sec
2501         At 400 keys, avg. speed is 2,578 keys/sec
2502         At 500 keys, avg. speed is 2,722 keys/sec
2503         At 600 keys, avg. speed is 2,628 keys/sec
2504         At 700 keys, avg. speed is 2,700 keys/sec
2505         At 800 keys, avg. speed is 2,607 keys/sec
2506         At 900 keys, avg. speed is 2,190 keys/sec
2507         At 1,000 keys, avg. speed is 2,570 keys/sec
2508         At 2,000 keys, avg. speed is 2,417 keys/sec
2509         At 3,000 keys, avg. speed is 1,982 keys/sec
2510         At 4,000 keys, avg. speed is 1,568 keys/sec
2511         At 5,000 keys, avg. speed is 1,533 keys/sec
2512         At 6,000 keys, avg. speed is 1,787 keys/sec
2513         At 7,000 keys, avg. speed is 1,977 keys/sec
2514         At 8,000 keys, avg. speed is 2,028 keys/sec
2515         At 9,000 keys, avg. speed is 2,077 keys/sec
2516         At 10,000 keys, avg. speed is 2,031 keys/sec
2517         At 20,000 keys, avg. speed is 1,970 keys/sec
2518         At 30,000 keys, avg. speed is 2,050 keys/sec
2519         At 40,000 keys, avg. speed is 2,073 keys/sec
2520         At 50,000 keys, avg. speed is 1,973 keys/sec
2521         At 60,000 keys, avg. speed is 1,914 keys/sec
2522         At 70,000 keys, avg. speed is 2,091 keys/sec
2523         At 80,000 keys, avg. speed is 2,103 keys/sec
2524         At 90,000 keys, avg. speed is 1,886 keys/sec
2525         At 100,000 keys, avg. speed is 1,970 keys/sec
2526         At 200,000 keys, avg. speed is 2,053 keys/sec
2527         At 300,000 keys, avg. speed is 1,697 keys/sec
2528         At 400,000 keys, avg. speed is 1,838 keys/sec
2529         At 500,000 keys, avg. speed is 1,941 keys/sec
2530         At 600,000 keys, avg. speed is 1,930 keys/sec
2531         At 700,000 keys, avg. speed is 1,735 keys/sec
2532         At 800,000 keys, avg. speed is 1,795 keys/sec
2533         At 900,000 keys, avg. speed is 1,221 keys/sec
2534         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2535
2536 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2537 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2538 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2539 Run time was 12 min 3 sec.
2540
2541 =head2 MEMORY USAGE
2542
2543 One of the great things about DBM::Deep is that it uses very little memory.
2544 Even with huge databases (1,000,000+ keys) you will not see much increased
2545 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2546 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2547 database handle:
2548
2549           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2550         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2551
2552 Basically the process is taking 2,716K of memory.  And here is the same
2553 process after storing and fetching 1,000,000 keys:
2554
2555           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2556         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2557
2558 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2559 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2560
2561 =head1 DB FILE FORMAT
2562
2563 In case you were interested in the underlying DB file format, it is documented
2564 here in this section.  You don't need to know this to use the module, it's just
2565 included for reference.
2566
2567 =head2 SIGNATURE
2568
2569 DBM::Deep files always start with a 32-bit signature to identify the file type.
2570 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2571 checked for when the file is opened and an error will be thrown if it's not found.
2572
2573 =head2 TAG
2574
2575 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2576 has a standard header containing the type of data, the length of data, and then
2577 the data itself.  The type is a single character (1 byte), the length is a
2578 32-bit unsigned long in network byte order, and the data is, well, the data.
2579 Here is how it unfolds:
2580
2581 =head2 MASTER INDEX
2582
2583 Immediately after the 32-bit file signature is the I<Master Index> record.
2584 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2585 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2586 depending on how the DBM::Deep object was constructed.
2587
2588 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2589 number).  The first 8-bit char of the MD5 signature is the offset into the
2590 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2591 index element is a file offset of the next tag for the key/element in question,
2592 which is usually a I<Bucket List> tag (see below).
2593
2594 The next tag I<could> be another index, depending on how many keys/elements
2595 exist.  See L<RE-INDEXING> below for details.
2596
2597 =head2 BUCKET LIST
2598
2599 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2600 file offsets to where the actual data is stored.  It starts with a standard
2601 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2602 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2603 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2604 When the list fills up, a I<Re-Index> operation is performed (See
2605 L<RE-INDEXING> below).
2606
2607 =head2 BUCKET
2608
2609 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2610 index/value pair (in array mode).  It starts with a standard tag header with
2611 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2612 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2613 header.  The size reported in the tag header is only for the value, but then,
2614 just after the value is another size (32-bit unsigned long) and then the plain
2615 key itself.  Since the value is likely to be fetched more often than the plain
2616 key, I figured it would be I<slightly> faster to store the value first.
2617
2618 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2619 record for the nested structure, where the process begins all over again.
2620
2621 =head2 RE-INDEXING
2622
2623 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2624 exhausted.  Then, when another key/element comes in, the list is converted to a
2625 new index record.  However, this index will look at the next char in the MD5
2626 hash, and arrange new Bucket List pointers accordingly.  This process is called
2627 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2628 17 (16 + new one) keys/elements are removed from the old Bucket List and
2629 inserted into the new index.  Several new Bucket Lists are created in the
2630 process, as a new MD5 char from the key is being examined (it is unlikely that
2631 the keys will all share the same next char of their MD5s).
2632
2633 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2634 when the Bucket Lists will turn into indexes, but the first round tends to
2635 happen right around 4,000 keys.  You will see a I<slight> decrease in
2636 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2637 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2638 right around 900,000 keys.  This process can continue nearly indefinitely --
2639 right up until the point the I<MD5> signatures start colliding with each other,
2640 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2641 getting struck by lightning while you are walking to cash in your tickets.
2642 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2643 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2644 this is 340 unodecillion, but don't quote me).
2645
2646 =head2 STORING
2647
2648 When a new key/element is stored, the key (or index number) is first run through
2649 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2650 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2651 for the first char of the signature (in this case I<b0>).  If it does not exist,
2652 a new I<Bucket List> is created for our key (and the next 15 future keys that
2653 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2654 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2655 this point, unless we are replacing an existing I<Bucket>), where the actual
2656 data will be stored.
2657
2658 =head2 FETCHING
2659
2660 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2661 (or index number), then walking along the indexes.  If there are enough
2662 keys/elements in this DB level, there might be nested indexes, each linked to
2663 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2664 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2665 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2666 plain key are stored.
2667
2668 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2669 methods.  In this process the indexes are walked systematically, and each key
2670 fetched in increasing MD5 order (which is why it appears random).   Once the
2671 I<Bucket> is found, the value is skipped and the plain key returned instead.
2672 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2673 alphabetically sorted.  This only happens on an index-level -- as soon as the
2674 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2675 so it's pretty much undefined how the keys will come out -- just like Perl's
2676 built-in hashes.
2677
2678 =head1 CODE COVERAGE
2679
2680 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2681 B<Devel::Cover> report on this module's test suite.
2682
2683   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2684   File                           stmt   bran   cond    sub    pod   time  total
2685   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2686   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2687   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2688   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2689   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2690   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2691
2692 =head1 MORE INFORMATION
2693
2694 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2695 or send email to L<DBM-Deep@googlegroups.com>.
2696
2697 =head1 AUTHORS
2698
2699 Joseph Huckaby, L<jhuckaby@cpan.org>
2700
2701 Rob Kinyon, L<rkinyon@cpan.org>
2702
2703 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2704
2705 =head1 SEE ALSO
2706
2707 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2708 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2709
2710 =head1 LICENSE
2711
2712 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2713 This is free software, you may use it and distribute it under the
2714 same terms as Perl itself.
2715
2716 =cut