lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub new {
 108         ##
 109         # Class constructor method for Perl OO interface.
 110         # Calls tie() and returns blessed reference to tied hash or array,
 111         # providing a hybrid OO/tie interface.
 112         ##
 113         my $class = shift;
 114         my $args;
 115         if (scalar(@_) > 1) { $args = {@_}; }
 116         else { $args = { file => shift }; }
 117
 118         ##
 119         # Check if we want a tied hash or array.
 120         ##
 121         my $self;
 122         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 123         $class = 'DBM::Deep::Array';
 124         require DBM::Deep::Array;
 125                 tie @$self, $class, %$args;
 126         }
 127         else {
 128         $class = 'DBM::Deep::Hash';
 129         require DBM::Deep::Hash;
 130                 tie %$self, $class, %$args;
 131         }
 132
 133         return bless $self, $class;
 134 }
 135
 136 sub _init {
 137     ##
 138     # Setup $self and bless into this class.
 139     ##
 140     my $class = shift;
 141     my $args = shift;
 142
 143     # These are the defaults to be optionally overridden below
 144     my $self = bless {
 145         type => TYPE_HASH,
 146         base_offset => length(SIG_FILE),
 147     }, $class;
 148
 149     foreach my $param ( keys %$self ) {
 150         next unless exists $args->{$param};
 151         $self->{$param} = delete $args->{$param}
 152     }
 153
 154     $self->{root} = exists $args->{root}
 155         ? $args->{root}
 156         : DBM::Deep::_::Root->new( $args );
 157
 158     if (!defined($self->fh)) { $self->_open(); }
 159
 160     return $self;
 161 }
 162
 163 sub TIEHASH {
 164     shift;
 165     require DBM::Deep::Hash;
 166     return DBM::Deep::Hash->TIEHASH( @_ );
 167 }
 168
 169 sub TIEARRAY {
 170     shift;
 171     require DBM::Deep::Array;
 172     return DBM::Deep::Array->TIEARRAY( @_ );
 173 }
 174
 175 #XXX Unneeded now ...
 176 #sub DESTROY {
 177 #}
 178
 179 sub _open {
 180         ##
 181         # Open a FileHandle to the database, create if nonexistent.
 182         # Make sure file signature matches DeepDB spec.
 183         ##
 184     my $self = $_[0]->_get_self;
 185
 186         if (defined($self->fh)) { $self->_close(); }
 187
 188     eval {
 189         # Theoretically, adding O_BINARY should remove the need for the binmode
 190         # Of course, testing it is going to be ... interesting.
 191         my $flags = O_RDWR | O_CREAT | O_BINARY;
 192
 193         #XXX Can the mode be anything but r+, w+, or a+??
 194         #XXX ie, it has to be in read-write mode
 195         #XXX So, should we verify that the mode is legitimate?
 196
 197         #XXX Maybe the mode thingy should just go away. There's no good
 198         #XXX reason for it ...
 199         if ( $self->root->{mode} eq 'w+' ) {
 200             $flags |= O_TRUNC;
 201         }
 202
 203         my $fh;
 204         sysopen( $fh, $self->root->{file}, $flags )
 205             or $fh = undef;
 206         $self->root->{fh} = $fh;
 207     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 208         if (! defined($self->fh)) {
 209                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 210         }
 211
 212     my $fh = $self->fh;
 213
 214     #XXX Can we remove this by using the right sysopen() flags?
 215     # Maybe ... q.v. above
 216     binmode $fh; # for win32
 217
 218     if ($self->root->{autoflush}) {
 219         my $old = select $fh;
 220         $|=1;
 221         select $old;
 222     }
 223
 224     # Set the
 225     seek($fh, 0, SEEK_SET);
 226
 227     my $signature;
 228     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 229
 230     ##
 231     # File is empty -- write signature and master index
 232     ##
 233     if (!$bytes_read) {
 234         seek($fh, 0, SEEK_SET);
 235         print($fh SIG_FILE);
 236         $self->root->{end} = length(SIG_FILE);
 237         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 238
 239         my $plain_key = "[base]";
 240         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 241         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 242
 243         # Flush the filehandle
 244         my $old_fh = select $fh;
 245         my $old_af = $|;
 246         $| = 1;
 247         $| = $old_af;
 248         select $old_fh;
 249
 250         return 1;
 251     }
 252
 253     ##
 254     # Check signature was valid
 255     ##
 256     unless ($signature eq SIG_FILE) {
 257         $self->_close();
 258         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 259     }
 260
 261     $self->root->{end} = (stat($fh))[7];
 262
 263     ##
 264     # Get our type from master index signature
 265     ##
 266     my $tag = $self->_load_tag($self->base_offset);
 267
 268 #XXX We probably also want to store the hash algorithm name and not assume anything
 269 #XXX The cool thing would be to allow a different hashing algorithm at every level
 270
 271     if (!$tag) {
 272         return $self->_throw_error("Corrupted file, no master index record");
 273     }
 274     if ($self->{type} ne $tag->{signature}) {
 275         return $self->_throw_error("File type mismatch");
 276     }
 277
 278     return 1;
 279 }
 280
 281 sub _close {
 282         ##
 283         # Close database FileHandle
 284         ##
 285     my $self = $_[0]->_get_self;
 286     close $self->root->{fh};
 287     $self->root->{fh} = undef;
 288 }
 289
 290 sub _create_tag {
 291         ##
 292         # Given offset, signature and content, create tag and write to disk
 293         ##
 294         my ($self, $offset, $sig, $content) = @_;
 295         my $size = length($content);
 296
 297     my $fh = $self->fh;
 298
 299         seek($fh, $offset, SEEK_SET);
 300         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 301
 302         if ($offset == $self->root->{end}) {
 303                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 304         }
 305
 306         return {
 307                 signature => $sig,
 308                 size => $size,
 309                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 310                 content => $content
 311         };
 312 }
 313
 314 sub _load_tag {
 315         ##
 316         # Given offset, load single tag and return signature, size and data
 317         ##
 318         my $self = shift;
 319         my $offset = shift;
 320
 321     my $fh = $self->fh;
 322
 323         seek($fh, $offset, SEEK_SET);
 324         if (eof $fh) { return undef; }
 325
 326         my $sig;
 327         read( $fh, $sig, SIG_SIZE);
 328
 329         my $size;
 330         read( $fh, $size, $DATA_LENGTH_SIZE);
 331         $size = unpack($DATA_LENGTH_PACK, $size);
 332
 333         my $buffer;
 334         read( $fh, $buffer, $size);
 335
 336         return {
 337                 signature => $sig,
 338                 size => $size,
 339                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 340                 content => $buffer
 341         };
 342 }
 343
 344 sub _index_lookup {
 345         ##
 346         # Given index tag, lookup single entry in index and return .
 347         ##
 348         my $self = shift;
 349         my ($tag, $index) = @_;
 350
 351         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 352         if (!$location) { return; }
 353
 354         return $self->_load_tag( $location );
 355 }
 356
 357 sub _add_bucket {
 358         ##
 359         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 360         # plain (undigested) key and value.
 361         ##
 362         my $self = shift;
 363         my ($tag, $md5, $plain_key, $value) = @_;
 364         my $keys = $tag->{content};
 365         my $location = 0;
 366         my $result = 2;
 367
 368     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 369         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 370
 371     my $fh = $self->fh;
 372
 373         ##
 374         # Iterate through buckets, seeing if this is a new entry or a replace.
 375         ##
 376         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 377                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 378                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 379                 if (!$subloc) {
 380                         ##
 381                         # Found empty bucket (end of list).  Populate and exit loop.
 382                         ##
 383                         $result = 2;
 384
 385             $location = $internal_ref
 386                 ? $value->base_offset
 387                 : $self->root->{end};
 388
 389                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 390                         print($fh $md5 . pack($LONG_PACK, $location) );
 391                         last;
 392                 }
 393                 elsif ($md5 eq $key) {
 394                         ##
 395                         # Found existing bucket with same key.  Replace with new value.
 396                         ##
 397                         $result = 1;
 398
 399                         if ($internal_ref) {
 400                                 $location = $value->base_offset;
 401                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 402                                 print($fh $md5 . pack($LONG_PACK, $location) );
 403                         }
 404                         else {
 405                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 406                                 my $size;
 407                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 408
 409                                 ##
 410                                 # If value is a hash, array, or raw value with equal or less size, we can
 411                                 # reuse the same content area of the database.  Otherwise, we have to create
 412                                 # a new content area at the EOF.
 413                                 ##
 414                                 my $actual_length;
 415                 my $r = Scalar::Util::reftype( $value ) || '';
 416                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 417                                 else { $actual_length = length($value); }
 418
 419                                 if ($actual_length <= $size) {
 420                                         $location = $subloc;
 421                                 }
 422                                 else {
 423                                         $location = $self->root->{end};
 424                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 425                                         print($fh pack($LONG_PACK, $location) );
 426                                 }
 427                         }
 428                         last;
 429                 }
 430         } # i loop
 431
 432         ##
 433         # If this is an internal reference, return now.
 434         # No need to write value or plain key
 435         ##
 436         if ($internal_ref) {
 437         return $result;
 438     }
 439
 440         ##
 441         # If bucket didn't fit into list, split into a new index level
 442         ##
 443         if (!$location) {
 444                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 445                 print($fh pack($LONG_PACK, $self->root->{end}) );
 446
 447                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 448                 my @offsets = ();
 449
 450                 $keys .= $md5 . pack($LONG_PACK, 0);
 451
 452                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 453                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 454                         if ($key) {
 455                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 456                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 457
 458                                 if ($offsets[$num]) {
 459                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 460                                         seek($fh, $offset, SEEK_SET);
 461                                         my $subkeys;
 462                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 463
 464                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 465                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 466                                                 if (!$subloc) {
 467                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 468                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 469                                                         last;
 470                                                 }
 471                                         } # k loop
 472                                 }
 473                                 else {
 474                                         $offsets[$num] = $self->root->{end};
 475                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 476                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 477
 478                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 479
 480                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 481                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 482                                 }
 483                         } # key is real
 484                 } # i loop
 485
 486                 $location ||= $self->root->{end};
 487         } # re-index bucket list
 488
 489         ##
 490         # Seek to content area and store signature, value and plaintext key
 491         ##
 492         if ($location) {
 493                 my $content_length;
 494                 seek($fh, $location, SEEK_SET);
 495
 496                 ##
 497                 # Write signature based on content type, set content length and write actual value.
 498                 ##
 499         my $r = Scalar::Util::reftype($value) || '';
 500                 if ($r eq 'HASH') {
 501                         print($fh TYPE_HASH );
 502                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 503                         $content_length = $INDEX_SIZE;
 504                 }
 505                 elsif ($r eq 'ARRAY') {
 506                         print($fh TYPE_ARRAY );
 507                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 508                         $content_length = $INDEX_SIZE;
 509                 }
 510                 elsif (!defined($value)) {
 511                         print($fh SIG_NULL );
 512                         print($fh pack($DATA_LENGTH_PACK, 0) );
 513                         $content_length = 0;
 514                 }
 515                 else {
 516                         print($fh SIG_DATA );
 517                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 518                         $content_length = length($value);
 519                 }
 520
 521                 ##
 522                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 523                 ##
 524                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 525
 526                 ##
 527                 # If value is blessed, preserve class name
 528                 ##
 529                 if ( $self->root->{autobless} ) {
 530             my $value_class = Scalar::Util::blessed($value);
 531             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 532                 ##
 533                 # Blessed ref -- will restore later
 534                 ##
 535                 print($fh chr(1) );
 536                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 537                 $content_length += 1;
 538                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 539             }
 540             else {
 541                 print($fh chr(0) );
 542                 $content_length += 1;
 543             }
 544         }
 545
 546                 ##
 547                 # If this is a new content area, advance EOF counter
 548                 ##
 549                 if ($location == $self->root->{end}) {
 550                         $self->root->{end} += SIG_SIZE;
 551                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 552                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 553                 }
 554
 555                 ##
 556                 # If content is a hash or array, create new child DeepDB object and
 557                 # pass each key or element to it.
 558                 ##
 559                 if ($r eq 'HASH') {
 560                         my $branch = DBM::Deep->new(
 561                                 type => TYPE_HASH,
 562                                 base_offset => $location,
 563                                 root => $self->root,
 564                         );
 565                         foreach my $key (keys %{$value}) {
 566                 #$branch->{$key} = $value->{$key};
 567                 $branch->STORE( $key, $value->{$key} );
 568                         }
 569                 }
 570                 elsif ($r eq 'ARRAY') {
 571                         my $branch = DBM::Deep->new(
 572                                 type => TYPE_ARRAY,
 573                                 base_offset => $location,
 574                                 root => $self->root,
 575                         );
 576                         my $index = 0;
 577                         foreach my $element (@{$value}) {
 578                 #$branch->[$index] = $element;
 579                 $branch->STORE( $index, $element );
 580                                 $index++;
 581                         }
 582                 }
 583
 584                 return $result;
 585         }
 586
 587         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 588 }
 589
 590 sub _get_bucket_value {
 591         ##
 592         # Fetch single value given tag and MD5 digested key.
 593         ##
 594         my $self = shift;
 595         my ($tag, $md5) = @_;
 596         my $keys = $tag->{content};
 597
 598     my $fh = $self->fh;
 599
 600         ##
 601         # Iterate through buckets, looking for a key match
 602         ##
 603     BUCKET:
 604         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 605                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 606                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 607
 608                 if (!$subloc) {
 609                         ##
 610                         # Hit end of list, no match
 611                         ##
 612                         return;
 613                 }
 614
 615         if ( $md5 ne $key ) {
 616             next BUCKET;
 617         }
 618
 619         ##
 620         # Found match -- seek to offset and read signature
 621         ##
 622         my $signature;
 623         seek($fh, $subloc, SEEK_SET);
 624         read( $fh, $signature, SIG_SIZE);
 625
 626         ##
 627         # If value is a hash or array, return new DeepDB object with correct offset
 628         ##
 629         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 630             my $obj = DBM::Deep->new(
 631                 type => $signature,
 632                 base_offset => $subloc,
 633                 root => $self->root
 634             );
 635
 636             if ($self->root->{autobless}) {
 637                 ##
 638                 # Skip over value and plain key to see if object needs
 639                 # to be re-blessed
 640                 ##
 641                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 642
 643                 my $size;
 644                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 645                 if ($size) { seek($fh, $size, SEEK_CUR); }
 646
 647                 my $bless_bit;
 648                 read( $fh, $bless_bit, 1);
 649                 if (ord($bless_bit)) {
 650                     ##
 651                     # Yes, object needs to be re-blessed
 652                     ##
 653                     my $class_name;
 654                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 655                     if ($size) { read( $fh, $class_name, $size); }
 656                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 657                 }
 658             }
 659
 660             return $obj;
 661         }
 662
 663         ##
 664         # Otherwise return actual value
 665         ##
 666         elsif ($signature eq SIG_DATA) {
 667             my $size;
 668             my $value = '';
 669             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 670             if ($size) { read( $fh, $value, $size); }
 671             return $value;
 672         }
 673
 674         ##
 675         # Key exists, but content is null
 676         ##
 677         else { return; }
 678         } # i loop
 679
 680         return;
 681 }
 682
 683 sub _delete_bucket {
 684         ##
 685         # Delete single key/value pair given tag and MD5 digested key.
 686         ##
 687         my $self = shift;
 688         my ($tag, $md5) = @_;
 689         my $keys = $tag->{content};
 690
 691     my $fh = $self->fh;
 692
 693         ##
 694         # Iterate through buckets, looking for a key match
 695         ##
 696     BUCKET:
 697         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 698                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 699                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 700
 701                 if (!$subloc) {
 702                         ##
 703                         # Hit end of list, no match
 704                         ##
 705                         return;
 706                 }
 707
 708         if ( $md5 ne $key ) {
 709             next BUCKET;
 710         }
 711
 712         ##
 713         # Matched key -- delete bucket and return
 714         ##
 715         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 716         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 717         print($fh chr(0) x $BUCKET_SIZE );
 718
 719         return 1;
 720         } # i loop
 721
 722         return;
 723 }
 724
 725 sub _bucket_exists {
 726         ##
 727         # Check existence of single key given tag and MD5 digested key.
 728         ##
 729         my $self = shift;
 730         my ($tag, $md5) = @_;
 731         my $keys = $tag->{content};
 732
 733         ##
 734         # Iterate through buckets, looking for a key match
 735         ##
 736     BUCKET:
 737         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 738                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 739                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 740
 741                 if (!$subloc) {
 742                         ##
 743                         # Hit end of list, no match
 744                         ##
 745                         return;
 746                 }
 747
 748         if ( $md5 ne $key ) {
 749             next BUCKET;
 750         }
 751
 752         ##
 753         # Matched key -- return true
 754         ##
 755         return 1;
 756         } # i loop
 757
 758         return;
 759 }
 760
 761 sub _find_bucket_list {
 762         ##
 763         # Locate offset for bucket list, given digested key
 764         ##
 765         my $self = shift;
 766         my $md5 = shift;
 767
 768         ##
 769         # Locate offset for bucket list using digest index system
 770         ##
 771         my $ch = 0;
 772         my $tag = $self->_load_tag($self->base_offset);
 773         if (!$tag) { return; }
 774
 775         while ($tag->{signature} ne SIG_BLIST) {
 776                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 777                 if (!$tag) { return; }
 778                 $ch++;
 779         }
 780
 781         return $tag;
 782 }
 783
 784 sub _traverse_index {
 785         ##
 786         # Scan index and recursively step into deeper levels, looking for next key.
 787         ##
 788     my ($self, $offset, $ch, $force_return_next) = @_;
 789     $force_return_next = undef unless $force_return_next;
 790
 791         my $tag = $self->_load_tag( $offset );
 792
 793     my $fh = $self->fh;
 794
 795         if ($tag->{signature} ne SIG_BLIST) {
 796                 my $content = $tag->{content};
 797                 my $start;
 798                 if ($self->{return_next}) { $start = 0; }
 799                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 800
 801                 for (my $index = $start; $index < 256; $index++) {
 802                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 803                         if ($subloc) {
 804                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 805                                 if (defined($result)) { return $result; }
 806                         }
 807                 } # index loop
 808
 809                 $self->{return_next} = 1;
 810         } # tag is an index
 811
 812         elsif ($tag->{signature} eq SIG_BLIST) {
 813                 my $keys = $tag->{content};
 814                 if ($force_return_next) { $self->{return_next} = 1; }
 815
 816                 ##
 817                 # Iterate through buckets, looking for a key match
 818                 ##
 819                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 820                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 821                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 822
 823                         if (!$subloc) {
 824                                 ##
 825                                 # End of bucket list -- return to outer loop
 826                                 ##
 827                                 $self->{return_next} = 1;
 828                                 last;
 829                         }
 830                         elsif ($key eq $self->{prev_md5}) {
 831                                 ##
 832                                 # Located previous key -- return next one found
 833                                 ##
 834                                 $self->{return_next} = 1;
 835                                 next;
 836                         }
 837                         elsif ($self->{return_next}) {
 838                                 ##
 839                                 # Seek to bucket location and skip over signature
 840                                 ##
 841                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 842
 843                                 ##
 844                                 # Skip over value to get to plain key
 845                                 ##
 846                                 my $size;
 847                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 848                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 849
 850                                 ##
 851                                 # Read in plain key and return as scalar
 852                                 ##
 853                                 my $plain_key;
 854                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 855                                 if ($size) { read( $fh, $plain_key, $size); }
 856
 857                                 return $plain_key;
 858                         }
 859                 } # bucket loop
 860
 861                 $self->{return_next} = 1;
 862         } # tag is a bucket list
 863
 864         return;
 865 }
 866
 867 sub _get_next_key {
 868         ##
 869         # Locate next key, given digested previous one
 870         ##
 871     my $self = $_[0]->_get_self;
 872
 873         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 874         $self->{return_next} = 0;
 875
 876         ##
 877         # If the previous key was not specifed, start at the top and
 878         # return the first one found.
 879         ##
 880         if (!$self->{prev_md5}) {
 881                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 882                 $self->{return_next} = 1;
 883         }
 884
 885         return $self->_traverse_index( $self->base_offset, 0 );
 886 }
 887
 888 sub lock {
 889         ##
 890         # If db locking is set, flock() the db file.  If called multiple
 891         # times before unlock(), then the same number of unlocks() must
 892         # be called before the lock is released.
 893         ##
 894     my $self = $_[0]->_get_self;
 895         my $type = $_[1];
 896     $type = LOCK_EX unless defined $type;
 897
 898         if (!defined($self->fh)) { return; }
 899
 900         if ($self->root->{locking}) {
 901                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 902                 $self->root->{locked}++;
 903
 904         return 1;
 905         }
 906
 907     return;
 908 }
 909
 910 sub unlock {
 911         ##
 912         # If db locking is set, unlock the db file.  See note in lock()
 913         # regarding calling lock() multiple times.
 914         ##
 915     my $self = $_[0]->_get_self;
 916
 917         if (!defined($self->fh)) { return; }
 918
 919         if ($self->root->{locking} && $self->root->{locked} > 0) {
 920                 $self->root->{locked}--;
 921                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 922
 923         return 1;
 924         }
 925
 926     return;
 927 }
 928
 929 #XXX These uses of ref() need verified
 930 sub _copy_node {
 931         ##
 932         # Copy single level of keys or elements to new DB handle.
 933         # Recurse for nested structures
 934         ##
 935     my $self = $_[0]->_get_self;
 936         my $db_temp = $_[1];
 937
 938         if ($self->type eq TYPE_HASH) {
 939                 my $key = $self->first_key();
 940                 while ($key) {
 941                         my $value = $self->get($key);
 942 #XXX This doesn't work with autobless
 943                         if (!ref($value)) { $db_temp->{$key} = $value; }
 944                         else {
 945                                 my $type = $value->type;
 946                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 947                                 else { $db_temp->{$key} = []; }
 948                                 $value->_copy_node( $db_temp->{$key} );
 949                         }
 950                         $key = $self->next_key($key);
 951                 }
 952         }
 953         else {
 954                 my $length = $self->length();
 955                 for (my $index = 0; $index < $length; $index++) {
 956                         my $value = $self->get($index);
 957                         if (!ref($value)) { $db_temp->[$index] = $value; }
 958             #XXX NO tests for this code
 959                         else {
 960                                 my $type = $value->type;
 961                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 962                                 else { $db_temp->[$index] = []; }
 963                                 $value->_copy_node( $db_temp->[$index] );
 964                         }
 965                 }
 966         }
 967 }
 968
 969 sub export {
 970         ##
 971         # Recursively export into standard Perl hashes and arrays.
 972         ##
 973     my $self = $_[0]->_get_self;
 974
 975         my $temp;
 976         if ($self->type eq TYPE_HASH) { $temp = {}; }
 977         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 978
 979         $self->lock();
 980         $self->_copy_node( $temp );
 981         $self->unlock();
 982
 983         return $temp;
 984 }
 985
 986 sub import {
 987         ##
 988         # Recursively import Perl hash/array structure
 989         ##
 990     #XXX This use of ref() seems to be ok
 991         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 992
 993     my $self = $_[0]->_get_self;
 994         my $struct = $_[1];
 995
 996     #XXX This use of ref() seems to be ok
 997         if (!ref($struct)) {
 998                 ##
 999                 # struct is not a reference, so just import based on our type
1000                 ##
1001                 shift @_;
1002
1003                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1004                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1005         }
1006
1007     my $r = Scalar::Util::reftype($struct) || '';
1008         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1009                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1010         }
1011         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1012                 $self->push( @$struct );
1013         }
1014         else {
1015                 return $self->_throw_error("Cannot import: type mismatch");
1016         }
1017
1018         return 1;
1019 }
1020
1021 sub optimize {
1022         ##
1023         # Rebuild entire database into new file, then move
1024         # it back on top of original.
1025         ##
1026     my $self = $_[0]->_get_self;
1027
1028 #XXX Need to create a new test for this
1029 #       if ($self->root->{links} > 1) {
1030 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1031 #       }
1032
1033         my $db_temp = DBM::Deep->new(
1034                 file => $self->root->{file} . '.tmp',
1035                 type => $self->type
1036         );
1037         if (!$db_temp) {
1038                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1039         }
1040
1041         $self->lock();
1042         $self->_copy_node( $db_temp );
1043         undef $db_temp;
1044
1045         ##
1046         # Attempt to copy user, group and permissions over to new file
1047         ##
1048         my @stats = stat($self->fh);
1049         my $perms = $stats[2] & 07777;
1050         my $uid = $stats[4];
1051         my $gid = $stats[5];
1052         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1053         chmod( $perms, $self->root->{file} . '.tmp' );
1054
1055     # q.v. perlport for more information on this variable
1056     if ( $^O eq 'MSWin32' ) {
1057                 ##
1058                 # Potential race condition when optmizing on Win32 with locking.
1059                 # The Windows filesystem requires that the filehandle be closed
1060                 # before it is overwritten with rename().  This could be redone
1061                 # with a soft copy.
1062                 ##
1063                 $self->unlock();
1064                 $self->_close();
1065         }
1066
1067         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1068                 unlink $self->root->{file} . '.tmp';
1069                 $self->unlock();
1070                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1071         }
1072
1073         $self->unlock();
1074         $self->_close();
1075         $self->_open();
1076
1077         return 1;
1078 }
1079
1080 sub clone {
1081         ##
1082         # Make copy of object and return
1083         ##
1084     my $self = $_[0]->_get_self;
1085
1086         return DBM::Deep->new(
1087                 type => $self->type,
1088                 base_offset => $self->base_offset,
1089                 root => $self->root
1090         );
1091 }
1092
1093 {
1094     my %is_legal_filter = map {
1095         $_ => ~~1,
1096     } qw(
1097         store_key store_value
1098         fetch_key fetch_value
1099     );
1100
1101     sub set_filter {
1102         ##
1103         # Setup filter function for storing or fetching the key or value
1104         ##
1105         my $self = $_[0]->_get_self;
1106         my $type = lc $_[1];
1107         my $func = $_[2] ? $_[2] : undef;
1108
1109         if ( $is_legal_filter{$type} ) {
1110             $self->root->{"filter_$type"} = $func;
1111             return 1;
1112         }
1113
1114         return;
1115     }
1116 }
1117
1118 ##
1119 # Accessor methods
1120 ##
1121
1122 sub root {
1123         ##
1124         # Get access to the root structure
1125         ##
1126     my $self = $_[0]->_get_self;
1127         return $self->{root};
1128 }
1129
1130 sub fh {
1131         ##
1132         # Get access to the raw FileHandle
1133         ##
1134     #XXX It will be useful, though, when we split out HASH and ARRAY
1135     my $self = $_[0]->_get_self;
1136         return $self->root->{fh};
1137 }
1138
1139 sub type {
1140         ##
1141         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1142         ##
1143     my $self = $_[0]->_get_self;
1144         return $self->{type};
1145 }
1146
1147 sub base_offset {
1148         ##
1149         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1150         ##
1151     my $self = $_[0]->_get_self;
1152         return $self->{base_offset};
1153 }
1154
1155 sub error {
1156         ##
1157         # Get last error string, or undef if no error
1158         ##
1159         return $_[0]
1160         #? ( _get_self($_[0])->{root}->{error} or undef )
1161         ? ( $_[0]->_get_self->{root}->{error} or undef )
1162         : $@;
1163 }
1164
1165 ##
1166 # Utility methods
1167 ##
1168
1169 sub _throw_error {
1170         ##
1171         # Store error string in self
1172         ##
1173     my $self = $_[0]->_get_self;
1174         my $error_text = $_[1];
1175
1176     if ( Scalar::Util::blessed $self ) {
1177         $self->root->{error} = $error_text;
1178
1179         unless ($self->root->{debug}) {
1180             die "DBM::Deep: $error_text\n";
1181         }
1182
1183         warn "DBM::Deep: $error_text\n";
1184         return;
1185     }
1186     else {
1187         die "DBM::Deep: $error_text\n";
1188     }
1189 }
1190
1191 sub clear_error {
1192         ##
1193         # Clear error state
1194         ##
1195     my $self = $_[0]->_get_self;
1196
1197         undef $self->root->{error};
1198 }
1199
1200 sub precalc_sizes {
1201         ##
1202         # Precalculate index, bucket and bucket list sizes
1203         ##
1204
1205     #XXX I don't like this ...
1206     set_pack() unless defined $LONG_SIZE;
1207
1208         $INDEX_SIZE = 256 * $LONG_SIZE;
1209         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1210         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1211 }
1212
1213 sub set_pack {
1214         ##
1215         # Set pack/unpack modes (see file header for more)
1216         ##
1217     my ($long_s, $long_p, $data_s, $data_p) = @_;
1218
1219     $LONG_SIZE = $long_s ? $long_s : 4;
1220     $LONG_PACK = $long_p ? $long_p : 'N';
1221
1222     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1223     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1224
1225         precalc_sizes();
1226 }
1227
1228 sub set_digest {
1229         ##
1230         # Set key digest function (default is MD5)
1231         ##
1232     my ($digest_func, $hash_size) = @_;
1233
1234     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1235     $HASH_SIZE = $hash_size ? $hash_size : 16;
1236
1237         precalc_sizes();
1238 }
1239
1240 ##
1241 # tie() methods (hashes and arrays)
1242 ##
1243
1244 sub STORE {
1245         ##
1246         # Store single hash key/value or array element in database.
1247         ##
1248     my $self = $_[0]->_get_self;
1249         my $key = $_[1];
1250
1251     #XXX What is ref() checking here?
1252     #YYY User may be storing a hash, in which case we do not want it run
1253     #YYY through the filtering system
1254         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1255         ? $self->root->{filter_store_value}->($_[2])
1256         : $_[2];
1257
1258         my $unpacked_key = $key;
1259         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1260
1261         my $md5 = $DIGEST_FUNC->($key);
1262
1263         ##
1264         # Make sure file is open
1265         ##
1266         if (!defined($self->fh) && !$self->_open()) {
1267                 return;
1268         }
1269         ##
1270
1271     my $fh = $self->fh;
1272
1273         ##
1274         # Request exclusive lock for writing
1275         ##
1276         $self->lock( LOCK_EX );
1277
1278         ##
1279         # If locking is enabled, set 'end' parameter again, in case another
1280         # DB instance appended to our file while we were unlocked.
1281         ##
1282         if ($self->root->{locking} || $self->root->{volatile}) {
1283                 $self->root->{end} = (stat($fh))[7];
1284         }
1285
1286         ##
1287         # Locate offset for bucket list using digest index system
1288         ##
1289         my $tag = $self->_load_tag($self->base_offset);
1290         if (!$tag) {
1291                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1292         }
1293
1294         my $ch = 0;
1295         while ($tag->{signature} ne SIG_BLIST) {
1296                 my $num = ord(substr($md5, $ch, 1));
1297                 my $new_tag = $self->_index_lookup($tag, $num);
1298                 if (!$new_tag) {
1299                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1300                         seek($fh, $ref_loc, SEEK_SET);
1301                         print($fh pack($LONG_PACK, $self->root->{end}) );
1302
1303                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1304                         $tag->{ref_loc} = $ref_loc;
1305                         $tag->{ch} = $ch;
1306                         last;
1307                 }
1308                 else {
1309                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1310                         $tag = $new_tag;
1311                         $tag->{ref_loc} = $ref_loc;
1312                         $tag->{ch} = $ch;
1313                 }
1314                 $ch++;
1315         }
1316
1317         ##
1318         # Add key/value to bucket list
1319         ##
1320         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1321
1322         ##
1323         # If this object is an array, and bucket was not a replace, and key is numerical,
1324         # and index is equal or greater than current length, advance length variable.
1325         ##
1326         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1327                 $self->STORESIZE( $unpacked_key + 1 );
1328         }
1329
1330         $self->unlock();
1331
1332         return $result;
1333 }
1334
1335 sub FETCH {
1336         ##
1337         # Fetch single value or element given plain key or array index
1338         ##
1339     my $self = $_[0]->_get_self;
1340
1341     my $key = $_[1];
1342     if ( $self->type eq TYPE_HASH ) {
1343         if ( my $filter = $self->root->{filter_store_key} ) {
1344             $key = $filter->( $key );
1345         }
1346     }
1347
1348         my $md5 = $DIGEST_FUNC->($key);
1349
1350         ##
1351         # Make sure file is open
1352         ##
1353         if (!defined($self->fh)) { $self->_open(); }
1354
1355         ##
1356         # Request shared lock for reading
1357         ##
1358         $self->lock( LOCK_SH );
1359
1360         my $tag = $self->_find_bucket_list( $md5 );
1361         if (!$tag) {
1362                 $self->unlock();
1363                 return;
1364         }
1365
1366         ##
1367         # Get value from bucket list
1368         ##
1369         my $result = $self->_get_bucket_value( $tag, $md5 );
1370
1371         $self->unlock();
1372
1373     #XXX What is ref() checking here?
1374         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1375 }
1376
1377 sub DELETE {
1378         ##
1379         # Delete single key/value pair or element given plain key or array index
1380         ##
1381     my $self = $_[0]->_get_self;
1382         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1383
1384         my $unpacked_key = $key;
1385         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1386         my $md5 = $DIGEST_FUNC->($key);
1387
1388         ##
1389         # Make sure file is open
1390         ##
1391         if (!defined($self->fh)) { $self->_open(); }
1392
1393         ##
1394         # Request exclusive lock for writing
1395         ##
1396         $self->lock( LOCK_EX );
1397
1398         my $tag = $self->_find_bucket_list( $md5 );
1399         if (!$tag) {
1400                 $self->unlock();
1401                 return;
1402         }
1403
1404         ##
1405         # Delete bucket
1406         ##
1407     my $value = $self->FETCH( $unpacked_key );
1408         my $result = $self->_delete_bucket( $tag, $md5 );
1409
1410         ##
1411         # If this object is an array and the key deleted was on the end of the stack,
1412         # decrement the length variable.
1413         ##
1414         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1415                 $self->STORESIZE( $unpacked_key );
1416         }
1417
1418         $self->unlock();
1419
1420         return $value;
1421 }
1422
1423 sub EXISTS {
1424         ##
1425         # Check if a single key or element exists given plain key or array index
1426         ##
1427     my $self = $_[0]->_get_self;
1428         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1429
1430         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1431         my $md5 = $DIGEST_FUNC->($key);
1432
1433         ##
1434         # Make sure file is open
1435         ##
1436         if (!defined($self->fh)) { $self->_open(); }
1437
1438         ##
1439         # Request shared lock for reading
1440         ##
1441         $self->lock( LOCK_SH );
1442
1443         my $tag = $self->_find_bucket_list( $md5 );
1444
1445         ##
1446         # For some reason, the built-in exists() function returns '' for false
1447         ##
1448         if (!$tag) {
1449                 $self->unlock();
1450                 return '';
1451         }
1452
1453         ##
1454         # Check if bucket exists and return 1 or ''
1455         ##
1456         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1457
1458         $self->unlock();
1459
1460         return $result;
1461 }
1462
1463 sub CLEAR {
1464         ##
1465         # Clear all keys from hash, or all elements from array.
1466         ##
1467     my $self = $_[0]->_get_self;
1468
1469         ##
1470         # Make sure file is open
1471         ##
1472         if (!defined($self->fh)) { $self->_open(); }
1473
1474         ##
1475         # Request exclusive lock for writing
1476         ##
1477         $self->lock( LOCK_EX );
1478
1479     my $fh = $self->fh;
1480
1481         seek($fh, $self->base_offset, SEEK_SET);
1482         if (eof $fh) {
1483                 $self->unlock();
1484                 return;
1485         }
1486
1487         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1488
1489         $self->unlock();
1490
1491         return 1;
1492 }
1493
1494 ##
1495 # Public method aliases
1496 ##
1497 sub put { (shift)->STORE( @_ ) }
1498 sub store { (shift)->STORE( @_ ) }
1499 sub get { (shift)->FETCH( @_ ) }
1500 sub fetch { (shift)->FETCH( @_ ) }
1501 *delete = *DELETE;
1502 *exists = *EXISTS;
1503 *clear = *CLEAR;
1504
1505 package DBM::Deep::_::Root;
1506
1507 sub new {
1508     my $class = shift;
1509     my ($args) = @_;
1510
1511     my $self = bless {
1512         file => undef,
1513         fh => undef,
1514         end => 0,
1515         autoflush => undef,
1516         locking => undef,
1517         volatile => undef,
1518         debug => undef,
1519         mode => 'r+',
1520         filter_store_key => undef,
1521         filter_store_value => undef,
1522         filter_fetch_key => undef,
1523         filter_fetch_value => undef,
1524         autobless => undef,
1525         locked => 0,
1526         %$args,
1527     }, $class;
1528
1529     return $self;
1530 }
1531
1532 sub DESTROY {
1533     my $self = shift;
1534     return unless $self;
1535
1536     close $self->{fh} if $self->{fh};
1537
1538     return;
1539 }
1540
1541 1;
1542
1543 __END__
1544
1545 =head1 NAME
1546
1547 DBM::Deep - A pure perl multi-level hash/array DBM
1548
1549 =head1 SYNOPSIS
1550
1551   use DBM::Deep;
1552   my $db = DBM::Deep->new( "foo.db" );
1553
1554   $db->{key} = 'value'; # tie() style
1555   print $db->{key};
1556
1557   $db->put('key', 'value'); # OO style
1558   print $db->get('key');
1559
1560   # true multi-level support
1561   $db->{my_complex} = [
1562         'hello', { perl => 'rules' },
1563         42, 99 ];
1564
1565 =head1 DESCRIPTION
1566
1567 A unique flat-file database module, written in pure perl.  True
1568 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1569 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1570 handle millions of keys and unlimited hash levels without significant
1571 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1572 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1573 Mac OS X and Windows.
1574
1575 =head1 INSTALLATION
1576
1577 Hopefully you are using CPAN's excellent Perl module, which will download
1578 and install the module for you.  If not, get the tarball, and run these
1579 commands:
1580
1581         tar zxf DBM-Deep-*
1582         cd DBM-Deep-*
1583         perl Makefile.PL
1584         make
1585         make test
1586         make install
1587
1588 =head1 SETUP
1589
1590 Construction can be done OO-style (which is the recommended way), or using
1591 Perl's tie() function.  Both are examined here.
1592
1593 =head2 OO CONSTRUCTION
1594
1595 The recommended way to construct a DBM::Deep object is to use the new()
1596 method, which gets you a blessed, tied hash or array reference.
1597
1598         my $db = DBM::Deep->new( "foo.db" );
1599
1600 This opens a new database handle, mapped to the file "foo.db".  If this
1601 file does not exist, it will automatically be created.  DB files are
1602 opened in "r+" (read/write) mode, and the type of object returned is a
1603 hash, unless otherwise specified (see L<OPTIONS> below).
1604
1605
1606
1607 You can pass a number of options to the constructor to specify things like
1608 locking, autoflush, etc.  This is done by passing an inline hash:
1609
1610         my $db = DBM::Deep->new(
1611                 file => "foo.db",
1612                 locking => 1,
1613                 autoflush => 1
1614         );
1615
1616 Notice that the filename is now specified I<inside> the hash with
1617 the "file" parameter, as opposed to being the sole argument to the
1618 constructor.  This is required if any options are specified.
1619 See L<OPTIONS> below for the complete list.
1620
1621
1622
1623 You can also start with an array instead of a hash.  For this, you must
1624 specify the C<type> parameter:
1625
1626         my $db = DBM::Deep->new(
1627                 file => "foo.db",
1628                 type => DBM::Deep->TYPE_ARRAY
1629         );
1630
1631 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1632 a new DB file.  If you create a DBM::Deep object with an existing file, the
1633 C<type> will be loaded from the file header, and ignored if it is passed
1634 to the constructor.
1635
1636 =head2 TIE CONSTRUCTION
1637
1638 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1639 tie() function.  This is not ideal, because you get only a basic, tied hash
1640 (or array) which is not blessed, so you can't call any functions on it.
1641
1642         my %hash;
1643         tie %hash, "DBM::Deep", "foo.db";
1644
1645         my @array;
1646         tie @array, "DBM::Deep", "bar.db";
1647
1648 As with the OO constructor, you can replace the DB filename parameter with
1649 a hash containing one or more options (see L<OPTIONS> just below for the
1650 complete list).
1651
1652         tie %hash, "DBM::Deep", {
1653                 file => "foo.db",
1654                 locking => 1,
1655                 autoflush => 1
1656         };
1657
1658 =head2 OPTIONS
1659
1660 There are a number of options that can be passed in when constructing your
1661 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1662
1663 =over
1664
1665 =item * file
1666
1667 Filename of the DB file to link the handle to.  You can pass a full absolute
1668 filesystem path, partial path, or a plain filename if the file is in the
1669 current working directory.  This is a required parameter.
1670
1671 =item * mode
1672
1673 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1674 module.  This is an optional parameter, and defaults to "r+" (read/write).
1675 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1676 created if it doesn't exist.
1677
1678 =item * type
1679
1680 This parameter specifies what type of object to create, a hash or array.  Use
1681 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1682 This only takes effect when beginning a new file.  This is an optional
1683 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1684
1685 =item * locking
1686
1687 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1688 function to lock the database in exclusive mode for writes, and shared mode for
1689 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1690 any child hashes or arrays> that use the same DB file.  This is an optional
1691 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1692
1693 =item * autoflush
1694
1695 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1696 This obviously slows down write operations, but is required if you may have
1697 multiple processes accessing the same DB file (also consider enable I<locking>
1698 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1699 parameter, and defaults to 0 (disabled).
1700
1701 =item * volatile
1702
1703 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1704 STORE() operation.  This is required if an outside force may change the size of
1705 the file between transactions.  Locking also implicitly enables volatile.  This
1706 is useful if you want to use a different locking system or write your own.  Pass
1707 any true value to enable.  This is an optional parameter, and defaults to 0
1708 (disabled).
1709
1710 =item * autobless
1711
1712 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1713 restore them when fetched.  This is an B<experimental> feature, and does have
1714 side-effects.  Basically, when hashes are re-blessed into their original
1715 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1716 able to call any DBM::Deep methods on them.  You have been warned.
1717 This is an optional parameter, and defaults to 0 (disabled).
1718
1719 =item * filter_*
1720
1721 See L<FILTERS> below.
1722
1723 =item * debug
1724
1725 Setting I<debug> mode will make all errors non-fatal, dump them out to
1726 STDERR, and continue on.  This is for debugging purposes only, and probably
1727 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1728
1729 =item * fh
1730
1731 Instead of passing a file path, you can instead pass a handle to an pre-opened
1732 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1733 contains your entire Perl script, as well as the data following the __DATA__
1734 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1735 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1736 in that.
1737
1738 =back
1739
1740 =head1 TIE INTERFACE
1741
1742 With DBM::Deep you can access your databases using Perl's standard hash/array
1743 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1744 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1745 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1746 section above.  This simply tells you how to use DBM::Deep using regular hashes
1747 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1748 work too).  It is entirely up to you how to want to access your databases.
1749
1750 =head2 HASHES
1751
1752 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1753 or even nested hashes (or arrays) using standard Perl syntax:
1754
1755         my $db = DBM::Deep->new( "foo.db" );
1756
1757         $db->{mykey} = "myvalue";
1758         $db->{myhash} = {};
1759         $db->{myhash}->{subkey} = "subvalue";
1760
1761         print $db->{myhash}->{subkey} . "\n";
1762
1763 You can even step through hash keys using the normal Perl C<keys()> function:
1764
1765         foreach my $key (keys %$db) {
1766                 print "$key: " . $db->{$key} . "\n";
1767         }
1768
1769 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1770 pushes them onto an array, all before the loop even begins.  If you have an
1771 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1772 Perl's C<each()> function, which pulls keys/values one at a time, using very
1773 little memory:
1774
1775         while (my ($key, $value) = each %$db) {
1776                 print "$key: $value\n";
1777         }
1778
1779 Please note that when using C<each()>, you should always pass a direct
1780 hash reference, not a lookup.  Meaning, you should B<never> do this:
1781
1782         # NEVER DO THIS
1783         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1784
1785 This causes an infinite loop, because for each iteration, Perl is calling
1786 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1787 it effectively keeps returning the first key over and over again. Instead,
1788 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1789
1790 =head2 ARRAYS
1791
1792 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1793 reference.  This includes inserting, removing and manipulating elements,
1794 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1795 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1796 or simply be a nested array reference inside a hash.  Example:
1797
1798         my $db = DBM::Deep->new(
1799                 file => "foo-array.db",
1800                 type => DBM::Deep->TYPE_ARRAY
1801         );
1802
1803         $db->[0] = "foo";
1804         push @$db, "bar", "baz";
1805         unshift @$db, "bah";
1806
1807         my $last_elem = pop @$db; # baz
1808         my $first_elem = shift @$db; # bah
1809         my $second_elem = $db->[1]; # bar
1810
1811         my $num_elements = scalar @$db;
1812
1813 =head1 OO INTERFACE
1814
1815 In addition to the I<tie()> interface, you can also use a standard OO interface
1816 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1817 array) has its own methods, but both types share the following common methods:
1818 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1819
1820 =over
1821
1822 =item * put()
1823
1824 Stores a new hash key/value pair, or sets an array element value.  Takes two
1825 arguments, the hash key or array index, and the new value.  The value can be
1826 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1827
1828         $db->put("foo", "bar"); # for hashes
1829         $db->put(1, "bar"); # for arrays
1830
1831 =item * get()
1832
1833 Fetches the value of a hash key or array element.  Takes one argument: the hash
1834 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1835 data type stored.
1836
1837         my $value = $db->get("foo"); # for hashes
1838         my $value = $db->get(1); # for arrays
1839
1840 =item * exists()
1841
1842 Checks if a hash key or array index exists.  Takes one argument: the hash key
1843 or array index.  Returns true if it exists, false if not.
1844
1845         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1846         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1847
1848 =item * delete()
1849
1850 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1851 key or array index.  Returns true on success, false if not found.  For arrays,
1852 the remaining elements located after the deleted element are NOT moved over.
1853 The deleted element is essentially just undefined, which is exactly how Perl's
1854 internal arrays work.  Please note that the space occupied by the deleted
1855 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1856 below for details and workarounds.
1857
1858         $db->delete("foo"); # for hashes
1859         $db->delete(1); # for arrays
1860
1861 =item * clear()
1862
1863 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1864 value.  Please note that the space occupied by the deleted keys/values or
1865 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1866 details and workarounds.
1867
1868         $db->clear(); # hashes or arrays
1869
1870 =back
1871
1872 =head2 HASHES
1873
1874 For hashes, DBM::Deep supports all the common methods described above, and the
1875 following additional methods: C<first_key()> and C<next_key()>.
1876
1877 =over
1878
1879 =item * first_key()
1880
1881 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1882 fetched in an undefined order (which appears random).  Takes no arguments,
1883 returns the key as a scalar value.
1884
1885         my $key = $db->first_key();
1886
1887 =item * next_key()
1888
1889 Returns the "next" key in the hash, given the previous one as the sole argument.
1890 Returns undef if there are no more keys to be fetched.
1891
1892         $key = $db->next_key($key);
1893
1894 =back
1895
1896 Here are some examples of using hashes:
1897
1898         my $db = DBM::Deep->new( "foo.db" );
1899
1900         $db->put("foo", "bar");
1901         print "foo: " . $db->get("foo") . "\n";
1902
1903         $db->put("baz", {}); # new child hash ref
1904         $db->get("baz")->put("buz", "biz");
1905         print "buz: " . $db->get("baz")->get("buz") . "\n";
1906
1907         my $key = $db->first_key();
1908         while ($key) {
1909                 print "$key: " . $db->get($key) . "\n";
1910                 $key = $db->next_key($key);
1911         }
1912
1913         if ($db->exists("foo")) { $db->delete("foo"); }
1914
1915 =head2 ARRAYS
1916
1917 For arrays, DBM::Deep supports all the common methods described above, and the
1918 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1919 C<unshift()> and C<splice()>.
1920
1921 =over
1922
1923 =item * length()
1924
1925 Returns the number of elements in the array.  Takes no arguments.
1926
1927         my $len = $db->length();
1928
1929 =item * push()
1930
1931 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1932 refs or array refs.  No return value.
1933
1934         $db->push("foo", "bar", {});
1935
1936 =item * pop()
1937
1938 Fetches the last element in the array, and deletes it.  Takes no arguments.
1939 Returns undef if array is empty.  Returns the element value.
1940
1941         my $elem = $db->pop();
1942
1943 =item * shift()
1944
1945 Fetches the first element in the array, deletes it, then shifts all the
1946 remaining elements over to take up the space.  Returns the element value.  This
1947 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1948 details.
1949
1950         my $elem = $db->shift();
1951
1952 =item * unshift()
1953
1954 Inserts one or more elements onto the beginning of the array, shifting all
1955 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1956 No return value.  This method is not recommended with large arrays -- see
1957 <LARGE ARRAYS> below for details.
1958
1959         $db->unshift("foo", "bar", {});
1960
1961 =item * splice()
1962
1963 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1964 -f splice> for usage -- it is too complicated to document here.  This method is
1965 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1966
1967 =back
1968
1969 Here are some examples of using arrays:
1970
1971         my $db = DBM::Deep->new(
1972                 file => "foo.db",
1973                 type => DBM::Deep->TYPE_ARRAY
1974         );
1975
1976         $db->push("bar", "baz");
1977         $db->unshift("foo");
1978         $db->put(3, "buz");
1979
1980         my $len = $db->length();
1981         print "length: $len\n"; # 4
1982
1983         for (my $k=0; $k<$len; $k++) {
1984                 print "$k: " . $db->get($k) . "\n";
1985         }
1986
1987         $db->splice(1, 2, "biz", "baf");
1988
1989         while (my $elem = shift @$db) {
1990                 print "shifted: $elem\n";
1991         }
1992
1993 =head1 LOCKING
1994
1995 Enable automatic file locking by passing a true value to the C<locking>
1996 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1997
1998         my $db = DBM::Deep->new(
1999                 file => "foo.db",
2000                 locking => 1
2001         );
2002
2003 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2004 mode for writes, and shared mode for reads.  This is required if you have
2005 multiple processes accessing the same database file, to avoid file corruption.
2006 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2007 NFS> below for more.
2008
2009 =head2 EXPLICIT LOCKING
2010
2011 You can explicitly lock a database, so it remains locked for multiple
2012 transactions.  This is done by calling the C<lock()> method, and passing an
2013 optional lock mode argument (defaults to exclusive mode).  This is particularly
2014 useful for things like counters, where the current value needs to be fetched,
2015 then incremented, then stored again.
2016
2017         $db->lock();
2018         my $counter = $db->get("counter");
2019         $counter++;
2020         $db->put("counter", $counter);
2021         $db->unlock();
2022
2023         # or...
2024
2025         $db->lock();
2026         $db->{counter}++;
2027         $db->unlock();
2028
2029 You can pass C<lock()> an optional argument, which specifies which mode to use
2030 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2031 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2032 same as the constants defined in Perl's C<Fcntl> module.
2033
2034         $db->lock( DBM::Deep->LOCK_SH );
2035         # something here
2036         $db->unlock();
2037
2038 If you want to implement your own file locking scheme, be sure to create your
2039 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2040 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2041 below for more.
2042
2043 =head1 IMPORTING/EXPORTING
2044
2045 You can import existing complex structures by calling the C<import()> method,
2046 and export an entire database into an in-memory structure using the C<export()>
2047 method.  Both are examined here.
2048
2049 =head2 IMPORTING
2050
2051 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2052 walking the structure and adding keys/elements to the database as you go,
2053 simply pass a reference to the C<import()> method.  This recursively adds
2054 everything to an existing DBM::Deep object for you.  Here is an example:
2055
2056         my $struct = {
2057                 key1 => "value1",
2058                 key2 => "value2",
2059                 array1 => [ "elem0", "elem1", "elem2" ],
2060                 hash1 => {
2061                         subkey1 => "subvalue1",
2062                         subkey2 => "subvalue2"
2063                 }
2064         };
2065
2066         my $db = DBM::Deep->new( "foo.db" );
2067         $db->import( $struct );
2068
2069         print $db->{key1} . "\n"; # prints "value1"
2070
2071 This recursively imports the entire C<$struct> object into C<$db>, including
2072 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2073 keys are merged with the existing ones, replacing if they already exist.
2074 The C<import()> method can be called on any database level (not just the base
2075 level), and works with both hash and array DB types.
2076
2077
2078
2079 B<Note:> Make sure your existing structure has no circular references in it.
2080 These will cause an infinite loop when importing.
2081
2082 =head2 EXPORTING
2083
2084 Calling the C<export()> method on an existing DBM::Deep object will return
2085 a reference to a new in-memory copy of the database.  The export is done
2086 recursively, so all nested hashes/arrays are all exported to standard Perl
2087 objects.  Here is an example:
2088
2089         my $db = DBM::Deep->new( "foo.db" );
2090
2091         $db->{key1} = "value1";
2092         $db->{key2} = "value2";
2093         $db->{hash1} = {};
2094         $db->{hash1}->{subkey1} = "subvalue1";
2095         $db->{hash1}->{subkey2} = "subvalue2";
2096
2097         my $struct = $db->export();
2098
2099         print $struct->{key1} . "\n"; # prints "value1"
2100
2101 This makes a complete copy of the database in memory, and returns a reference
2102 to it.  The C<export()> method can be called on any database level (not just
2103 the base level), and works with both hash and array DB types.  Be careful of
2104 large databases -- you can store a lot more data in a DBM::Deep object than an
2105 in-memory Perl structure.
2106
2107
2108
2109 B<Note:> Make sure your database has no circular references in it.
2110 These will cause an infinite loop when exporting.
2111
2112 =head1 FILTERS
2113
2114 DBM::Deep has a number of hooks where you can specify your own Perl function
2115 to perform filtering on incoming or outgoing data.  This is a perfect
2116 way to extend the engine, and implement things like real-time compression or
2117 encryption.  Filtering applies to the base DB level, and all child hashes /
2118 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2119 constructed, or by calling the C<set_filter()> method at any time.  There are
2120 four available filter hooks, described below:
2121
2122 =over
2123
2124 =item * filter_store_key
2125
2126 This filter is called whenever a hash key is stored.  It
2127 is passed the incoming key, and expected to return a transformed key.
2128
2129 =item * filter_store_value
2130
2131 This filter is called whenever a hash key or array element is stored.  It
2132 is passed the incoming value, and expected to return a transformed value.
2133
2134 =item * filter_fetch_key
2135
2136 This filter is called whenever a hash key is fetched (i.e. via
2137 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2138 and expected to return the plain key.
2139
2140 =item * filter_fetch_value
2141
2142 This filter is called whenever a hash key or array element is fetched.
2143 It is passed the transformed value, and expected to return the plain value.
2144
2145 =back
2146
2147 Here are the two ways to setup a filter hook:
2148
2149         my $db = DBM::Deep->new(
2150                 file => "foo.db",
2151                 filter_store_value => \&my_filter_store,
2152                 filter_fetch_value => \&my_filter_fetch
2153         );
2154
2155         # or...
2156
2157         $db->set_filter( "filter_store_value", \&my_filter_store );
2158         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2159
2160 Your filter function will be called only when dealing with SCALAR keys or
2161 values.  When nested hashes and arrays are being stored/fetched, filtering
2162 is bypassed.  Filters are called as static functions, passed a single SCALAR
2163 argument, and expected to return a single SCALAR value.  If you want to
2164 remove a filter, set the function reference to C<undef>:
2165
2166         $db->set_filter( "filter_store_value", undef );
2167
2168 =head2 REAL-TIME ENCRYPTION EXAMPLE
2169
2170 Here is a working example that uses the I<Crypt::Blowfish> module to
2171 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2172 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2173 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2174
2175         use DBM::Deep;
2176         use Crypt::Blowfish;
2177         use Crypt::CBC;
2178
2179         my $cipher = Crypt::CBC->new({
2180                 'key'             => 'my secret key',
2181                 'cipher'          => 'Blowfish',
2182                 'iv'              => '$KJh#(}q',
2183                 'regenerate_key'  => 0,
2184                 'padding'         => 'space',
2185                 'prepend_iv'      => 0
2186         });
2187
2188         my $db = DBM::Deep->new(
2189                 file => "foo-encrypt.db",
2190                 filter_store_key => \&my_encrypt,
2191                 filter_store_value => \&my_encrypt,
2192                 filter_fetch_key => \&my_decrypt,
2193                 filter_fetch_value => \&my_decrypt,
2194         );
2195
2196         $db->{key1} = "value1";
2197         $db->{key2} = "value2";
2198         print "key1: " . $db->{key1} . "\n";
2199         print "key2: " . $db->{key2} . "\n";
2200
2201         undef $db;
2202         exit;
2203
2204         sub my_encrypt {
2205                 return $cipher->encrypt( $_[0] );
2206         }
2207         sub my_decrypt {
2208                 return $cipher->decrypt( $_[0] );
2209         }
2210
2211 =head2 REAL-TIME COMPRESSION EXAMPLE
2212
2213 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2214 compression / decompression of keys & values with DBM::Deep Filters.
2215 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2216 more on I<Compress::Zlib>.
2217
2218         use DBM::Deep;
2219         use Compress::Zlib;
2220
2221         my $db = DBM::Deep->new(
2222                 file => "foo-compress.db",
2223                 filter_store_key => \&my_compress,
2224                 filter_store_value => \&my_compress,
2225                 filter_fetch_key => \&my_decompress,
2226                 filter_fetch_value => \&my_decompress,
2227         );
2228
2229         $db->{key1} = "value1";
2230         $db->{key2} = "value2";
2231         print "key1: " . $db->{key1} . "\n";
2232         print "key2: " . $db->{key2} . "\n";
2233
2234         undef $db;
2235         exit;
2236
2237         sub my_compress {
2238                 return Compress::Zlib::memGzip( $_[0] ) ;
2239         }
2240         sub my_decompress {
2241                 return Compress::Zlib::memGunzip( $_[0] ) ;
2242         }
2243
2244 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2245 actually numerical index numbers, and are not filtered.
2246
2247 =head1 ERROR HANDLING
2248
2249 Most DBM::Deep methods return a true value for success, and call die() on
2250 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2251 actual error message is stored in an internal scalar, which can be fetched by
2252 calling the C<error()> method.
2253
2254         my $db = DBM::Deep->new( "foo.db" ); # create hash
2255         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2256
2257         print $db->error(); # prints error message
2258
2259 You can then call C<clear_error()> to clear the current error state.
2260
2261         $db->clear_error();
2262
2263 If you set the C<debug> option to true when creating your DBM::Deep object,
2264 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2265 for debugging purposes.
2266
2267 =head1 LARGEFILE SUPPORT
2268
2269 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2270 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2271 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2272 by calling the static C<set_pack()> method before you do anything else.
2273
2274         DBM::Deep::set_pack(8, 'Q');
2275
2276 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2277 instead of 32-bit longs.  After setting these values your DB files have a
2278 theoretical maximum size of 16 XB (exabytes).
2279
2280
2281
2282 B<Note:> Changing these values will B<NOT> work for existing database files.
2283 Only change this for new files, and make sure it stays set consistently
2284 throughout the file's life.  If you do set these values, you can no longer
2285 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2286 back to 32-bit mode.
2287
2288
2289
2290 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2291 only a 32-bit Perl.  However, I have received user reports that this does
2292 indeed work!
2293
2294 =head1 LOW-LEVEL ACCESS
2295
2296 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2297 you can call the C<fh()> method, which returns the handle:
2298
2299         my $fh = $db->fh();
2300
2301 This method can be called on the root level of the datbase, or any child
2302 hashes or arrays.  All levels share a I<root> structure, which contains things
2303 like the FileHandle, a reference counter, and all your options you specified
2304 when you created the object.  You can get access to this root structure by
2305 calling the C<root()> method.
2306
2307         my $root = $db->root();
2308
2309 This is useful for changing options after the object has already been created,
2310 such as enabling/disabling locking, volatile or debug modes.  You can also
2311 store your own temporary user data in this structure (be wary of name
2312 collision), which is then accessible from any child hash or array.
2313
2314 =head1 CUSTOM DIGEST ALGORITHM
2315
2316 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2317 keys.  However you can override this, and use another algorithm (such as SHA-256)
2318 or even write your own.  But please note that DBM::Deep currently expects zero
2319 collisions, so your algorithm has to be I<perfect>, so to speak.
2320 Collision detection may be introduced in a later version.
2321
2322
2323
2324 You can specify a custom digest algorithm by calling the static C<set_digest()>
2325 function, passing a reference to a subroutine, and the length of the algorithm's
2326 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2327 objects.  Here is a working example that uses a 256-bit hash from the
2328 I<Digest::SHA256> module.  Please see
2329 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2330
2331         use DBM::Deep;
2332         use Digest::SHA256;
2333
2334         my $context = Digest::SHA256::new(256);
2335
2336         DBM::Deep::set_digest( \&my_digest, 32 );
2337
2338         my $db = DBM::Deep->new( "foo-sha.db" );
2339
2340         $db->{key1} = "value1";
2341         $db->{key2} = "value2";
2342         print "key1: " . $db->{key1} . "\n";
2343         print "key2: " . $db->{key2} . "\n";
2344
2345         undef $db;
2346         exit;
2347
2348         sub my_digest {
2349                 return substr( $context->hash($_[0]), 0, 32 );
2350         }
2351
2352 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2353 of bytes you specify in the C<set_digest()> function (in this case 32).
2354
2355 =head1 CIRCULAR REFERENCES
2356
2357 DBM::Deep has B<experimental> support for circular references.  Meaning you
2358 can have a nested hash key or array element that points to a parent object.
2359 This relationship is stored in the DB file, and is preserved between sessions.
2360 Here is an example:
2361
2362         my $db = DBM::Deep->new( "foo.db" );
2363
2364         $db->{foo} = "bar";
2365         $db->{circle} = $db; # ref to self
2366
2367         print $db->{foo} . "\n"; # prints "foo"
2368         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2369
2370 One catch is, passing the object to a function that recursively walks the
2371 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2372 C<export()> methods) will result in an infinite loop.  The other catch is,
2373 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2374 or C<next_key()> methods), you will get the I<target object's key>, not the
2375 ref's key.  This gets even more interesting with the above example, where
2376 the I<circle> key points to the base DB object, which technically doesn't
2377 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2378 special case.
2379
2380 =head1 CAVEATS / ISSUES / BUGS
2381
2382 This section describes all the known issues with DBM::Deep.  It you have found
2383 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2384
2385 =head2 UNUSED SPACE RECOVERY
2386
2387 One major caveat with DBM::Deep is that space occupied by existing keys and
2388 values is not recovered when they are deleted.  Meaning if you keep deleting
2389 and adding new keys, your file will continuously grow.  I am working on this,
2390 but in the meantime you can call the built-in C<optimize()> method from time to
2391 time (perhaps in a crontab or something) to recover all your unused space.
2392
2393         $db->optimize(); # returns true on success
2394
2395 This rebuilds the ENTIRE database into a new file, then moves it on top of
2396 the original.  The new file will have no unused space, thus it will take up as
2397 little disk space as possible.  Please note that this operation can take
2398 a long time for large files, and you need enough disk space to temporarily hold
2399 2 copies of your DB file.  The temporary file is created in the same directory
2400 as the original, named with a ".tmp" extension, and is deleted when the
2401 operation completes.  Oh, and if locking is enabled, the DB is automatically
2402 locked for the entire duration of the copy.
2403
2404
2405
2406 B<WARNING:> Only call optimize() on the top-level node of the database, and
2407 make sure there are no child references lying around.  DBM::Deep keeps a reference
2408 counter, and if it is greater than 1, optimize() will abort and return undef.
2409
2410 =head2 AUTOVIVIFICATION
2411
2412 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2413 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2414 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2415 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2416 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2417 this does not work:
2418
2419         $db->{foo}->{bar} = "hello";
2420
2421 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2422 being an empty hash.  Try this instead, which works fine:
2423
2424         $db->{foo} = { bar => "hello" };
2425
2426 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2427 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2428 Probably a bug in Perl.
2429
2430 =head2 FILE CORRUPTION
2431
2432 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2433 for a 32-bit signature when opened, but other corruption in files can cause
2434 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2435 stuck in an infinite loop depending on the level of corruption.  File write
2436 operations are not checked for failure (for speed), so if you happen to run
2437 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2438 be addressed in a later version of DBM::Deep.
2439
2440 =head2 DB OVER NFS
2441
2442 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2443 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2444 about setting up your NFS server with a locking daemon, then using lockf() to
2445 lock your files, but your milage may vary there as well.  From what I
2446 understand, there is no real way to do it.  However, if you need access to the
2447 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2448 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2449
2450 =head2 COPYING OBJECTS
2451
2452 Beware of copying tied objects in Perl.  Very strange things can happen.
2453 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2454 returns a new, blessed, tied hash or array to the same level in the DB.
2455
2456         my $copy = $db->clone();
2457
2458 =head2 LARGE ARRAYS
2459
2460 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2461 These functions cause every element in the array to move, which can be murder
2462 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2463 a different location.  This may be addressed in a later version.
2464
2465 =head1 PERFORMANCE
2466
2467 This section discusses DBM::Deep's speed and memory usage.
2468
2469 =head2 SPEED
2470
2471 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2472 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2473 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2474 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2475 with huge databases.  Here is some test data:
2476
2477         Adding 1,000,000 keys to new DB file...
2478
2479         At 100 keys, avg. speed is 2,703 keys/sec
2480         At 200 keys, avg. speed is 2,642 keys/sec
2481         At 300 keys, avg. speed is 2,598 keys/sec
2482         At 400 keys, avg. speed is 2,578 keys/sec
2483         At 500 keys, avg. speed is 2,722 keys/sec
2484         At 600 keys, avg. speed is 2,628 keys/sec
2485         At 700 keys, avg. speed is 2,700 keys/sec
2486         At 800 keys, avg. speed is 2,607 keys/sec
2487         At 900 keys, avg. speed is 2,190 keys/sec
2488         At 1,000 keys, avg. speed is 2,570 keys/sec
2489         At 2,000 keys, avg. speed is 2,417 keys/sec
2490         At 3,000 keys, avg. speed is 1,982 keys/sec
2491         At 4,000 keys, avg. speed is 1,568 keys/sec
2492         At 5,000 keys, avg. speed is 1,533 keys/sec
2493         At 6,000 keys, avg. speed is 1,787 keys/sec
2494         At 7,000 keys, avg. speed is 1,977 keys/sec
2495         At 8,000 keys, avg. speed is 2,028 keys/sec
2496         At 9,000 keys, avg. speed is 2,077 keys/sec
2497         At 10,000 keys, avg. speed is 2,031 keys/sec
2498         At 20,000 keys, avg. speed is 1,970 keys/sec
2499         At 30,000 keys, avg. speed is 2,050 keys/sec
2500         At 40,000 keys, avg. speed is 2,073 keys/sec
2501         At 50,000 keys, avg. speed is 1,973 keys/sec
2502         At 60,000 keys, avg. speed is 1,914 keys/sec
2503         At 70,000 keys, avg. speed is 2,091 keys/sec
2504         At 80,000 keys, avg. speed is 2,103 keys/sec
2505         At 90,000 keys, avg. speed is 1,886 keys/sec
2506         At 100,000 keys, avg. speed is 1,970 keys/sec
2507         At 200,000 keys, avg. speed is 2,053 keys/sec
2508         At 300,000 keys, avg. speed is 1,697 keys/sec
2509         At 400,000 keys, avg. speed is 1,838 keys/sec
2510         At 500,000 keys, avg. speed is 1,941 keys/sec
2511         At 600,000 keys, avg. speed is 1,930 keys/sec
2512         At 700,000 keys, avg. speed is 1,735 keys/sec
2513         At 800,000 keys, avg. speed is 1,795 keys/sec
2514         At 900,000 keys, avg. speed is 1,221 keys/sec
2515         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2516
2517 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2518 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2519 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2520 Run time was 12 min 3 sec.
2521
2522 =head2 MEMORY USAGE
2523
2524 One of the great things about DBM::Deep is that it uses very little memory.
2525 Even with huge databases (1,000,000+ keys) you will not see much increased
2526 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2527 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2528 database handle:
2529
2530           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2531         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2532
2533 Basically the process is taking 2,716K of memory.  And here is the same
2534 process after storing and fetching 1,000,000 keys:
2535
2536           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2537         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2538
2539 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2540 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2541
2542 =head1 DB FILE FORMAT
2543
2544 In case you were interested in the underlying DB file format, it is documented
2545 here in this section.  You don't need to know this to use the module, it's just
2546 included for reference.
2547
2548 =head2 SIGNATURE
2549
2550 DBM::Deep files always start with a 32-bit signature to identify the file type.
2551 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2552 checked when the file is opened.
2553
2554 =head2 TAG
2555
2556 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2557 has a standard header containing the type of data, the length of data, and then
2558 the data itself.  The type is a single character (1 byte), the length is a
2559 32-bit unsigned long in network byte order, and the data is, well, the data.
2560 Here is how it unfolds:
2561
2562 =head2 MASTER INDEX
2563
2564 Immediately after the 32-bit file signature is the I<Master Index> record.
2565 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2566 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2567 depending on how the DBM::Deep object was constructed.
2568
2569
2570
2571 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2572 number).  The first 8-bit char of the MD5 signature is the offset into the
2573 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2574 index element is a file offset of the next tag for the key/element in question,
2575 which is usually a I<Bucket List> tag (see below).
2576
2577
2578
2579 The next tag I<could> be another index, depending on how many keys/elements
2580 exist.  See L<RE-INDEXING> below for details.
2581
2582 =head2 BUCKET LIST
2583
2584 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2585 file offsets to where the actual data is stored.  It starts with a standard
2586 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2587 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2588 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2589 When the list fills up, a I<Re-Index> operation is performed (See
2590 L<RE-INDEXING> below).
2591
2592 =head2 BUCKET
2593
2594 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2595 index/value pair (in array mode).  It starts with a standard tag header with
2596 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2597 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2598 header.  The size reported in the tag header is only for the value, but then,
2599 just after the value is another size (32-bit unsigned long) and then the plain
2600 key itself.  Since the value is likely to be fetched more often than the plain
2601 key, I figured it would be I<slightly> faster to store the value first.
2602
2603
2604
2605 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2606 record for the nested structure, where the process begins all over again.
2607
2608 =head2 RE-INDEXING
2609
2610 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2611 exhausted.  Then, when another key/element comes in, the list is converted to a
2612 new index record.  However, this index will look at the next char in the MD5
2613 hash, and arrange new Bucket List pointers accordingly.  This process is called
2614 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2615 17 (16 + new one) keys/elements are removed from the old Bucket List and
2616 inserted into the new index.  Several new Bucket Lists are created in the
2617 process, as a new MD5 char from the key is being examined (it is unlikely that
2618 the keys will all share the same next char of their MD5s).
2619
2620
2621
2622 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2623 when the Bucket Lists will turn into indexes, but the first round tends to
2624 happen right around 4,000 keys.  You will see a I<slight> decrease in
2625 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2626 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2627 right around 900,000 keys.  This process can continue nearly indefinitely --
2628 right up until the point the I<MD5> signatures start colliding with each other,
2629 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2630 getting struck by lightning while you are walking to cash in your tickets.
2631 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2632 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2633 this is 340 unodecillion, but don't quote me).
2634
2635 =head2 STORING
2636
2637 When a new key/element is stored, the key (or index number) is first ran through
2638 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2639 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2640 for the first char of the signature (in this case I<b>).  If it does not exist,
2641 a new I<Bucket List> is created for our key (and the next 15 future keys that
2642 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2643 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2644 this point, unless we are replacing an existing I<Bucket>), where the actual
2645 data will be stored.
2646
2647 =head2 FETCHING
2648
2649 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2650 (or index number), then walking along the indexes.  If there are enough
2651 keys/elements in this DB level, there might be nested indexes, each linked to
2652 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2653 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2654 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2655 plain key are stored.
2656
2657
2658
2659 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2660 methods.  In this process the indexes are walked systematically, and each key
2661 fetched in increasing MD5 order (which is why it appears random).   Once the
2662 I<Bucket> is found, the value is skipped the plain key returned instead.
2663 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2664 alphabetically sorted.  This only happens on an index-level -- as soon as the
2665 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2666 so it's pretty much undefined how the keys will come out -- just like Perl's
2667 built-in hashes.
2668
2669 =head1 CODE COVERAGE
2670
2671 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2672 module's test suite.
2673
2674   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2675   File                           stmt   bran   cond    sub    pod   time  total
2676   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2677   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2678   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2679   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2680   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2681   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2682
2683 =head1 AUTHOR
2684
2685 Joseph Huckaby, L<jhuckaby@cpan.org>
2686
2687 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2688
2689 =head1 SEE ALSO
2690
2691 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2692 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2693
2694 =head1 LICENSE
2695
2696 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2697 This is free software, you may use it and distribute it under the
2698 same terms as Perl itself.
2699
2700 =cut