lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub new {
 108         ##
 109         # Class constructor method for Perl OO interface.
 110         # Calls tie() and returns blessed reference to tied hash or array,
 111         # providing a hybrid OO/tie interface.
 112         ##
 113         my $class = shift;
 114         my $args;
 115         if (scalar(@_) > 1) { $args = {@_}; }
 116         else { $args = { file => shift }; }
 117
 118         ##
 119         # Check if we want a tied hash or array.
 120         ##
 121         my $self;
 122         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 123         $class = 'DBM::Deep::Array';
 124         require DBM::Deep::Array;
 125                 tie @$self, $class, %$args;
 126         }
 127         else {
 128         $class = 'DBM::Deep::Hash';
 129         require DBM::Deep::Hash;
 130                 tie %$self, $class, %$args;
 131         }
 132
 133         return bless $self, $class;
 134 }
 135
 136 sub _init {
 137     ##
 138     # Setup $self and bless into this class.
 139     ##
 140     my $class = shift;
 141     my $args = shift;
 142
 143     # These are the defaults to be optionally overridden below
 144     my $self = bless {
 145         type => TYPE_HASH,
 146         base_offset => length(SIG_FILE),
 147     }, $class;
 148
 149     foreach my $param ( keys %$self ) {
 150         next unless exists $args->{$param};
 151         $self->{$param} = delete $args->{$param}
 152     }
 153
 154     $self->{root} = exists $args->{root}
 155         ? $args->{root}
 156         : DBM::Deep::_::Root->new( $args );
 157
 158     if (!defined($self->fh)) { $self->_open(); }
 159
 160     return $self;
 161 }
 162
 163 sub TIEHASH {
 164     shift;
 165     require DBM::Deep::Hash;
 166     return DBM::Deep::Hash->TIEHASH( @_ );
 167 }
 168
 169 sub TIEARRAY {
 170     shift;
 171     require DBM::Deep::Array;
 172     return DBM::Deep::Array->TIEARRAY( @_ );
 173 }
 174
 175 #XXX Unneeded now ...
 176 #sub DESTROY {
 177 #}
 178
 179 sub _open {
 180         ##
 181         # Open a FileHandle to the database, create if nonexistent.
 182         # Make sure file signature matches DeepDB spec.
 183         ##
 184     my $self = $_[0]->_get_self;
 185
 186         if (defined($self->fh)) { $self->_close(); }
 187
 188     eval {
 189         # Theoretically, adding O_BINARY should remove the need for the binmode
 190         # Of course, testing it is going to be ... interesting.
 191         my $flags = O_RDWR | O_CREAT | O_BINARY;
 192
 193         #XXX Can the mode be anything but r+, w+, or a+??
 194         #XXX ie, it has to be in read-write mode
 195         #XXX So, should we verify that the mode is legitimate?
 196
 197         #XXX Maybe the mode thingy should just go away. There's no good
 198         #XXX reason for it ...
 199         if ( $self->root->{mode} eq 'w+' ) {
 200             $flags |= O_TRUNC;
 201         }
 202
 203         my $fh;
 204         sysopen( $fh, $self->root->{file}, $flags )
 205             or $fh = undef;
 206         $self->root->{fh} = $fh;
 207     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 208         if (! defined($self->fh)) {
 209                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 210         }
 211
 212     my $fh = $self->fh;
 213
 214     #XXX Can we remove this by using the right sysopen() flags?
 215     # Maybe ... q.v. above
 216     binmode $fh; # for win32
 217
 218     if ($self->root->{autoflush}) {
 219         my $old = select $fh;
 220         $|=1;
 221         select $old;
 222     }
 223
 224     # Set the
 225     seek($fh, 0, SEEK_SET);
 226
 227     my $signature;
 228     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 229
 230     ##
 231     # File is empty -- write signature and master index
 232     ##
 233     if (!$bytes_read) {
 234         seek($fh, 0, SEEK_SET);
 235         print($fh SIG_FILE);
 236         $self->root->{end} = length(SIG_FILE);
 237         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 238
 239         my $plain_key = "[base]";
 240         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 241         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 242
 243         # Flush the filehandle
 244         my $old_fh = select $fh;
 245         my $old_af = $|;
 246         $| = 1;
 247         $| = $old_af;
 248         select $old_fh;
 249
 250         return 1;
 251     }
 252
 253     ##
 254     # Check signature was valid
 255     ##
 256     unless ($signature eq SIG_FILE) {
 257         $self->_close();
 258         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 259     }
 260
 261     $self->root->{end} = (stat($fh))[7];
 262
 263     ##
 264     # Get our type from master index signature
 265     ##
 266     my $tag = $self->_load_tag($self->base_offset);
 267
 268 #XXX We probably also want to store the hash algorithm name and not assume anything
 269 #XXX The cool thing would be to allow a different hashing algorithm at every level
 270
 271     if (!$tag) {
 272         return $self->_throw_error("Corrupted file, no master index record");
 273     }
 274     if ($self->{type} ne $tag->{signature}) {
 275         return $self->_throw_error("File type mismatch");
 276     }
 277
 278     return 1;
 279 }
 280
 281 sub _close {
 282         ##
 283         # Close database FileHandle
 284         ##
 285     my $self = $_[0]->_get_self;
 286     close $self->root->{fh};
 287 }
 288
 289 sub _create_tag {
 290         ##
 291         # Given offset, signature and content, create tag and write to disk
 292         ##
 293         my ($self, $offset, $sig, $content) = @_;
 294         my $size = length($content);
 295
 296     my $fh = $self->fh;
 297
 298         seek($fh, $offset, SEEK_SET);
 299         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 300
 301         if ($offset == $self->root->{end}) {
 302                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 303         }
 304
 305         return {
 306                 signature => $sig,
 307                 size => $size,
 308                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 309                 content => $content
 310         };
 311 }
 312
 313 sub _load_tag {
 314         ##
 315         # Given offset, load single tag and return signature, size and data
 316         ##
 317         my $self = shift;
 318         my $offset = shift;
 319
 320     my $fh = $self->fh;
 321
 322         seek($fh, $offset, SEEK_SET);
 323         if (eof $fh) { return undef; }
 324
 325         my $sig;
 326         read( $fh, $sig, SIG_SIZE);
 327
 328         my $size;
 329         read( $fh, $size, $DATA_LENGTH_SIZE);
 330         $size = unpack($DATA_LENGTH_PACK, $size);
 331
 332         my $buffer;
 333         read( $fh, $buffer, $size);
 334
 335         return {
 336                 signature => $sig,
 337                 size => $size,
 338                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 339                 content => $buffer
 340         };
 341 }
 342
 343 sub _index_lookup {
 344         ##
 345         # Given index tag, lookup single entry in index and return .
 346         ##
 347         my $self = shift;
 348         my ($tag, $index) = @_;
 349
 350         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 351         if (!$location) { return; }
 352
 353         return $self->_load_tag( $location );
 354 }
 355
 356 sub _add_bucket {
 357         ##
 358         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 359         # plain (undigested) key and value.
 360         ##
 361         my $self = shift;
 362         my ($tag, $md5, $plain_key, $value) = @_;
 363         my $keys = $tag->{content};
 364         my $location = 0;
 365         my $result = 2;
 366
 367     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 368         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 369
 370     my $fh = $self->fh;
 371
 372         ##
 373         # Iterate through buckets, seeing if this is a new entry or a replace.
 374         ##
 375         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 376                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 377                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 378                 if (!$subloc) {
 379                         ##
 380                         # Found empty bucket (end of list).  Populate and exit loop.
 381                         ##
 382                         $result = 2;
 383
 384             $location = $internal_ref
 385                 ? $value->base_offset
 386                 : $self->root->{end};
 387
 388                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 389                         print($fh $md5 . pack($LONG_PACK, $location) );
 390                         last;
 391                 }
 392                 elsif ($md5 eq $key) {
 393                         ##
 394                         # Found existing bucket with same key.  Replace with new value.
 395                         ##
 396                         $result = 1;
 397
 398                         if ($internal_ref) {
 399                                 $location = $value->base_offset;
 400                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 401                                 print($fh $md5 . pack($LONG_PACK, $location) );
 402                         }
 403                         else {
 404                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 405                                 my $size;
 406                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 407
 408                                 ##
 409                                 # If value is a hash, array, or raw value with equal or less size, we can
 410                                 # reuse the same content area of the database.  Otherwise, we have to create
 411                                 # a new content area at the EOF.
 412                                 ##
 413                                 my $actual_length;
 414                 my $r = Scalar::Util::reftype( $value ) || '';
 415                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 416                                 else { $actual_length = length($value); }
 417
 418                                 if ($actual_length <= $size) {
 419                                         $location = $subloc;
 420                                 }
 421                                 else {
 422                                         $location = $self->root->{end};
 423                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 424                                         print($fh pack($LONG_PACK, $location) );
 425                                 }
 426                         }
 427                         last;
 428                 }
 429         } # i loop
 430
 431         ##
 432         # If this is an internal reference, return now.
 433         # No need to write value or plain key
 434         ##
 435         if ($internal_ref) {
 436         return $result;
 437     }
 438
 439         ##
 440         # If bucket didn't fit into list, split into a new index level
 441         ##
 442         if (!$location) {
 443                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 444                 print($fh pack($LONG_PACK, $self->root->{end}) );
 445
 446                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 447                 my @offsets = ();
 448
 449                 $keys .= $md5 . pack($LONG_PACK, 0);
 450
 451                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 452                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 453                         if ($key) {
 454                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 455                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 456
 457                                 if ($offsets[$num]) {
 458                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 459                                         seek($fh, $offset, SEEK_SET);
 460                                         my $subkeys;
 461                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 462
 463                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 464                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 465                                                 if (!$subloc) {
 466                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 467                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 468                                                         last;
 469                                                 }
 470                                         } # k loop
 471                                 }
 472                                 else {
 473                                         $offsets[$num] = $self->root->{end};
 474                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 475                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 476
 477                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 478
 479                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 480                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 481                                 }
 482                         } # key is real
 483                 } # i loop
 484
 485                 $location ||= $self->root->{end};
 486         } # re-index bucket list
 487
 488         ##
 489         # Seek to content area and store signature, value and plaintext key
 490         ##
 491         if ($location) {
 492                 my $content_length;
 493                 seek($fh, $location, SEEK_SET);
 494
 495                 ##
 496                 # Write signature based on content type, set content length and write actual value.
 497                 ##
 498         my $r = Scalar::Util::reftype($value) || '';
 499                 if ($r eq 'HASH') {
 500                         print($fh TYPE_HASH );
 501                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 502                         $content_length = $INDEX_SIZE;
 503                 }
 504                 elsif ($r eq 'ARRAY') {
 505                         print($fh TYPE_ARRAY );
 506                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 507                         $content_length = $INDEX_SIZE;
 508                 }
 509                 elsif (!defined($value)) {
 510                         print($fh SIG_NULL );
 511                         print($fh pack($DATA_LENGTH_PACK, 0) );
 512                         $content_length = 0;
 513                 }
 514                 else {
 515                         print($fh SIG_DATA );
 516                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 517                         $content_length = length($value);
 518                 }
 519
 520                 ##
 521                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 522                 ##
 523                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 524
 525                 ##
 526                 # If value is blessed, preserve class name
 527                 ##
 528                 if ( $self->root->{autobless} ) {
 529             my $value_class = Scalar::Util::blessed($value);
 530             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 531                 ##
 532                 # Blessed ref -- will restore later
 533                 ##
 534                 print($fh chr(1) );
 535                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 536                 $content_length += 1;
 537                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 538             }
 539             else {
 540                 print($fh chr(0) );
 541                 $content_length += 1;
 542             }
 543         }
 544
 545                 ##
 546                 # If this is a new content area, advance EOF counter
 547                 ##
 548                 if ($location == $self->root->{end}) {
 549                         $self->root->{end} += SIG_SIZE;
 550                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 551                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 552                 }
 553
 554                 ##
 555                 # If content is a hash or array, create new child DeepDB object and
 556                 # pass each key or element to it.
 557                 ##
 558                 if ($r eq 'HASH') {
 559                         my $branch = DBM::Deep->new(
 560                                 type => TYPE_HASH,
 561                                 base_offset => $location,
 562                                 root => $self->root,
 563                         );
 564                         foreach my $key (keys %{$value}) {
 565                 #$branch->{$key} = $value->{$key};
 566                 $branch->STORE( $key, $value->{$key} );
 567                         }
 568                 }
 569                 elsif ($r eq 'ARRAY') {
 570                         my $branch = DBM::Deep->new(
 571                                 type => TYPE_ARRAY,
 572                                 base_offset => $location,
 573                                 root => $self->root,
 574                         );
 575                         my $index = 0;
 576                         foreach my $element (@{$value}) {
 577                 #$branch->[$index] = $element;
 578                 $branch->STORE( $index, $element );
 579                                 $index++;
 580                         }
 581                 }
 582
 583                 return $result;
 584         }
 585
 586         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 587 }
 588
 589 sub _get_bucket_value {
 590         ##
 591         # Fetch single value given tag and MD5 digested key.
 592         ##
 593         my $self = shift;
 594         my ($tag, $md5) = @_;
 595         my $keys = $tag->{content};
 596
 597     my $fh = $self->fh;
 598
 599         ##
 600         # Iterate through buckets, looking for a key match
 601         ##
 602     BUCKET:
 603         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 604                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 605                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 606
 607                 if (!$subloc) {
 608                         ##
 609                         # Hit end of list, no match
 610                         ##
 611                         return;
 612                 }
 613
 614         if ( $md5 ne $key ) {
 615             next BUCKET;
 616         }
 617
 618         ##
 619         # Found match -- seek to offset and read signature
 620         ##
 621         my $signature;
 622         seek($fh, $subloc, SEEK_SET);
 623         read( $fh, $signature, SIG_SIZE);
 624
 625         ##
 626         # If value is a hash or array, return new DeepDB object with correct offset
 627         ##
 628         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 629             my $obj = DBM::Deep->new(
 630                 type => $signature,
 631                 base_offset => $subloc,
 632                 root => $self->root
 633             );
 634
 635             if ($self->root->{autobless}) {
 636                 ##
 637                 # Skip over value and plain key to see if object needs
 638                 # to be re-blessed
 639                 ##
 640                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 641
 642                 my $size;
 643                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 644                 if ($size) { seek($fh, $size, SEEK_CUR); }
 645
 646                 my $bless_bit;
 647                 read( $fh, $bless_bit, 1);
 648                 if (ord($bless_bit)) {
 649                     ##
 650                     # Yes, object needs to be re-blessed
 651                     ##
 652                     my $class_name;
 653                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 654                     if ($size) { read( $fh, $class_name, $size); }
 655                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 656                 }
 657             }
 658
 659             return $obj;
 660         }
 661
 662         ##
 663         # Otherwise return actual value
 664         ##
 665         elsif ($signature eq SIG_DATA) {
 666             my $size;
 667             my $value = '';
 668             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 669             if ($size) { read( $fh, $value, $size); }
 670             return $value;
 671         }
 672
 673         ##
 674         # Key exists, but content is null
 675         ##
 676         else { return; }
 677         } # i loop
 678
 679         return;
 680 }
 681
 682 sub _delete_bucket {
 683         ##
 684         # Delete single key/value pair given tag and MD5 digested key.
 685         ##
 686         my $self = shift;
 687         my ($tag, $md5) = @_;
 688         my $keys = $tag->{content};
 689
 690     my $fh = $self->fh;
 691
 692         ##
 693         # Iterate through buckets, looking for a key match
 694         ##
 695     BUCKET:
 696         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 697                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 698                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 699
 700                 if (!$subloc) {
 701                         ##
 702                         # Hit end of list, no match
 703                         ##
 704                         return;
 705                 }
 706
 707         if ( $md5 ne $key ) {
 708             next BUCKET;
 709         }
 710
 711         ##
 712         # Matched key -- delete bucket and return
 713         ##
 714         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 715         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 716         print($fh chr(0) x $BUCKET_SIZE );
 717
 718         return 1;
 719         } # i loop
 720
 721         return;
 722 }
 723
 724 sub _bucket_exists {
 725         ##
 726         # Check existence of single key given tag and MD5 digested key.
 727         ##
 728         my $self = shift;
 729         my ($tag, $md5) = @_;
 730         my $keys = $tag->{content};
 731
 732         ##
 733         # Iterate through buckets, looking for a key match
 734         ##
 735     BUCKET:
 736         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 737                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 738                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 739
 740                 if (!$subloc) {
 741                         ##
 742                         # Hit end of list, no match
 743                         ##
 744                         return;
 745                 }
 746
 747         if ( $md5 ne $key ) {
 748             next BUCKET;
 749         }
 750
 751         ##
 752         # Matched key -- return true
 753         ##
 754         return 1;
 755         } # i loop
 756
 757         return;
 758 }
 759
 760 sub _find_bucket_list {
 761         ##
 762         # Locate offset for bucket list, given digested key
 763         ##
 764         my $self = shift;
 765         my $md5 = shift;
 766
 767         ##
 768         # Locate offset for bucket list using digest index system
 769         ##
 770         my $ch = 0;
 771         my $tag = $self->_load_tag($self->base_offset);
 772         if (!$tag) { return; }
 773
 774         while ($tag->{signature} ne SIG_BLIST) {
 775                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 776                 if (!$tag) { return; }
 777                 $ch++;
 778         }
 779
 780         return $tag;
 781 }
 782
 783 sub _traverse_index {
 784         ##
 785         # Scan index and recursively step into deeper levels, looking for next key.
 786         ##
 787     my ($self, $offset, $ch, $force_return_next) = @_;
 788     $force_return_next = undef unless $force_return_next;
 789
 790         my $tag = $self->_load_tag( $offset );
 791
 792     my $fh = $self->fh;
 793
 794         if ($tag->{signature} ne SIG_BLIST) {
 795                 my $content = $tag->{content};
 796                 my $start;
 797                 if ($self->{return_next}) { $start = 0; }
 798                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 799
 800                 for (my $index = $start; $index < 256; $index++) {
 801                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 802                         if ($subloc) {
 803                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 804                                 if (defined($result)) { return $result; }
 805                         }
 806                 } # index loop
 807
 808                 $self->{return_next} = 1;
 809         } # tag is an index
 810
 811         elsif ($tag->{signature} eq SIG_BLIST) {
 812                 my $keys = $tag->{content};
 813                 if ($force_return_next) { $self->{return_next} = 1; }
 814
 815                 ##
 816                 # Iterate through buckets, looking for a key match
 817                 ##
 818                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 819                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 820                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 821
 822                         if (!$subloc) {
 823                                 ##
 824                                 # End of bucket list -- return to outer loop
 825                                 ##
 826                                 $self->{return_next} = 1;
 827                                 last;
 828                         }
 829                         elsif ($key eq $self->{prev_md5}) {
 830                                 ##
 831                                 # Located previous key -- return next one found
 832                                 ##
 833                                 $self->{return_next} = 1;
 834                                 next;
 835                         }
 836                         elsif ($self->{return_next}) {
 837                                 ##
 838                                 # Seek to bucket location and skip over signature
 839                                 ##
 840                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 841
 842                                 ##
 843                                 # Skip over value to get to plain key
 844                                 ##
 845                                 my $size;
 846                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 847                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 848
 849                                 ##
 850                                 # Read in plain key and return as scalar
 851                                 ##
 852                                 my $plain_key;
 853                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 854                                 if ($size) { read( $fh, $plain_key, $size); }
 855
 856                                 return $plain_key;
 857                         }
 858                 } # bucket loop
 859
 860                 $self->{return_next} = 1;
 861         } # tag is a bucket list
 862
 863         return;
 864 }
 865
 866 sub _get_next_key {
 867         ##
 868         # Locate next key, given digested previous one
 869         ##
 870     my $self = $_[0]->_get_self;
 871
 872         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 873         $self->{return_next} = 0;
 874
 875         ##
 876         # If the previous key was not specifed, start at the top and
 877         # return the first one found.
 878         ##
 879         if (!$self->{prev_md5}) {
 880                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 881                 $self->{return_next} = 1;
 882         }
 883
 884         return $self->_traverse_index( $self->base_offset, 0 );
 885 }
 886
 887 sub lock {
 888         ##
 889         # If db locking is set, flock() the db file.  If called multiple
 890         # times before unlock(), then the same number of unlocks() must
 891         # be called before the lock is released.
 892         ##
 893     my $self = $_[0]->_get_self;
 894         my $type = $_[1];
 895     $type = LOCK_EX unless defined $type;
 896
 897         if ($self->root->{locking}) {
 898                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 899                 $self->root->{locked}++;
 900
 901         return 1;
 902         }
 903
 904     return;
 905 }
 906
 907 sub unlock {
 908         ##
 909         # If db locking is set, unlock the db file.  See note in lock()
 910         # regarding calling lock() multiple times.
 911         ##
 912     my $self = $_[0]->_get_self;
 913
 914         if ($self->root->{locking} && $self->root->{locked} > 0) {
 915                 $self->root->{locked}--;
 916                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 917
 918         return 1;
 919         }
 920
 921     return;
 922 }
 923
 924 #XXX These uses of ref() need verified
 925 sub _copy_node {
 926         ##
 927         # Copy single level of keys or elements to new DB handle.
 928         # Recurse for nested structures
 929         ##
 930     my $self = $_[0]->_get_self;
 931         my $db_temp = $_[1];
 932
 933         if ($self->type eq TYPE_HASH) {
 934                 my $key = $self->first_key();
 935                 while ($key) {
 936                         my $value = $self->get($key);
 937 #XXX This doesn't work with autobless
 938                         if (!ref($value)) { $db_temp->{$key} = $value; }
 939                         else {
 940                                 my $type = $value->type;
 941                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 942                                 else { $db_temp->{$key} = []; }
 943                                 $value->_copy_node( $db_temp->{$key} );
 944                         }
 945                         $key = $self->next_key($key);
 946                 }
 947         }
 948         else {
 949                 my $length = $self->length();
 950                 for (my $index = 0; $index < $length; $index++) {
 951                         my $value = $self->get($index);
 952                         if (!ref($value)) { $db_temp->[$index] = $value; }
 953             #XXX NO tests for this code
 954                         else {
 955                                 my $type = $value->type;
 956                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 957                                 else { $db_temp->[$index] = []; }
 958                                 $value->_copy_node( $db_temp->[$index] );
 959                         }
 960                 }
 961         }
 962 }
 963
 964 sub export {
 965         ##
 966         # Recursively export into standard Perl hashes and arrays.
 967         ##
 968     my $self = $_[0]->_get_self;
 969
 970         my $temp;
 971         if ($self->type eq TYPE_HASH) { $temp = {}; }
 972         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 973
 974         $self->lock();
 975         $self->_copy_node( $temp );
 976         $self->unlock();
 977
 978         return $temp;
 979 }
 980
 981 sub import {
 982         ##
 983         # Recursively import Perl hash/array structure
 984         ##
 985     #XXX This use of ref() seems to be ok
 986         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 987
 988     my $self = $_[0]->_get_self;
 989         my $struct = $_[1];
 990
 991     #XXX This use of ref() seems to be ok
 992         if (!ref($struct)) {
 993                 ##
 994                 # struct is not a reference, so just import based on our type
 995                 ##
 996                 shift @_;
 997
 998                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
 999                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1000         }
1001
1002     my $r = Scalar::Util::reftype($struct) || '';
1003         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1004                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1005         }
1006         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1007                 $self->push( @$struct );
1008         }
1009         else {
1010                 return $self->_throw_error("Cannot import: type mismatch");
1011         }
1012
1013         return 1;
1014 }
1015
1016 sub optimize {
1017         ##
1018         # Rebuild entire database into new file, then move
1019         # it back on top of original.
1020         ##
1021     my $self = $_[0]->_get_self;
1022
1023 #XXX Need to create a new test for this
1024 #       if ($self->root->{links} > 1) {
1025 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1026 #       }
1027
1028         my $db_temp = DBM::Deep->new(
1029                 file => $self->root->{file} . '.tmp',
1030                 type => $self->type
1031         );
1032         if (!$db_temp) {
1033                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1034         }
1035
1036         $self->lock();
1037         $self->_copy_node( $db_temp );
1038         undef $db_temp;
1039
1040         ##
1041         # Attempt to copy user, group and permissions over to new file
1042         ##
1043         my @stats = stat($self->fh);
1044         my $perms = $stats[2] & 07777;
1045         my $uid = $stats[4];
1046         my $gid = $stats[5];
1047         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1048         chmod( $perms, $self->root->{file} . '.tmp' );
1049
1050     # q.v. perlport for more information on this variable
1051     if ( $^O eq 'MSWin32' ) {
1052                 ##
1053                 # Potential race condition when optmizing on Win32 with locking.
1054                 # The Windows filesystem requires that the filehandle be closed
1055                 # before it is overwritten with rename().  This could be redone
1056                 # with a soft copy.
1057                 ##
1058                 $self->unlock();
1059                 $self->_close();
1060         }
1061
1062         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1063                 unlink $self->root->{file} . '.tmp';
1064                 $self->unlock();
1065                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1066         }
1067
1068         $self->unlock();
1069         $self->_close();
1070         $self->_open();
1071
1072         return 1;
1073 }
1074
1075 sub clone {
1076         ##
1077         # Make copy of object and return
1078         ##
1079     my $self = $_[0]->_get_self;
1080
1081         return DBM::Deep->new(
1082                 type => $self->type,
1083                 base_offset => $self->base_offset,
1084                 root => $self->root
1085         );
1086 }
1087
1088 {
1089     my %is_legal_filter = map {
1090         $_ => ~~1,
1091     } qw(
1092         store_key store_value
1093         fetch_key fetch_value
1094     );
1095
1096     sub set_filter {
1097         ##
1098         # Setup filter function for storing or fetching the key or value
1099         ##
1100         my $self = $_[0]->_get_self;
1101         my $type = lc $_[1];
1102         my $func = $_[2] ? $_[2] : undef;
1103
1104         if ( $is_legal_filter{$type} ) {
1105             $self->root->{"filter_$type"} = $func;
1106             return 1;
1107         }
1108
1109         return;
1110     }
1111 }
1112
1113 ##
1114 # Accessor methods
1115 ##
1116
1117 sub root {
1118         ##
1119         # Get access to the root structure
1120         ##
1121     my $self = $_[0]->_get_self;
1122         return $self->{root};
1123 }
1124
1125 sub fh {
1126         ##
1127         # Get access to the raw FileHandle
1128         ##
1129     #XXX It will be useful, though, when we split out HASH and ARRAY
1130     my $self = $_[0]->_get_self;
1131         return $self->root->{fh};
1132 }
1133
1134 sub type {
1135         ##
1136         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1137         ##
1138     my $self = $_[0]->_get_self;
1139         return $self->{type};
1140 }
1141
1142 sub base_offset {
1143         ##
1144         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1145         ##
1146     my $self = $_[0]->_get_self;
1147         return $self->{base_offset};
1148 }
1149
1150 sub error {
1151         ##
1152         # Get last error string, or undef if no error
1153         ##
1154         return $_[0]
1155         #? ( _get_self($_[0])->{root}->{error} or undef )
1156         ? ( $_[0]->_get_self->{root}->{error} or undef )
1157         : $@;
1158 }
1159
1160 ##
1161 # Utility methods
1162 ##
1163
1164 sub _throw_error {
1165         ##
1166         # Store error string in self
1167         ##
1168     my $self = $_[0]->_get_self;
1169         my $error_text = $_[1];
1170
1171     if ( Scalar::Util::blessed $self ) {
1172         $self->root->{error} = $error_text;
1173
1174         unless ($self->root->{debug}) {
1175             die "DBM::Deep: $error_text\n";
1176         }
1177
1178         warn "DBM::Deep: $error_text\n";
1179         return;
1180     }
1181     else {
1182         die "DBM::Deep: $error_text\n";
1183     }
1184 }
1185
1186 sub clear_error {
1187         ##
1188         # Clear error state
1189         ##
1190     my $self = $_[0]->_get_self;
1191
1192         undef $self->root->{error};
1193 }
1194
1195 sub precalc_sizes {
1196         ##
1197         # Precalculate index, bucket and bucket list sizes
1198         ##
1199
1200     #XXX I don't like this ...
1201     set_pack() unless defined $LONG_SIZE;
1202
1203         $INDEX_SIZE = 256 * $LONG_SIZE;
1204         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1205         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1206 }
1207
1208 sub set_pack {
1209         ##
1210         # Set pack/unpack modes (see file header for more)
1211         ##
1212     my ($long_s, $long_p, $data_s, $data_p) = @_;
1213
1214     $LONG_SIZE = $long_s ? $long_s : 4;
1215     $LONG_PACK = $long_p ? $long_p : 'N';
1216
1217     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1218     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1219
1220         precalc_sizes();
1221 }
1222
1223 sub set_digest {
1224         ##
1225         # Set key digest function (default is MD5)
1226         ##
1227     my ($digest_func, $hash_size) = @_;
1228
1229     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1230     $HASH_SIZE = $hash_size ? $hash_size : 16;
1231
1232         precalc_sizes();
1233 }
1234
1235 ##
1236 # tie() methods (hashes and arrays)
1237 ##
1238
1239 sub STORE {
1240         ##
1241         # Store single hash key/value or array element in database.
1242         ##
1243     my $self = $_[0]->_get_self;
1244         my $key = $_[1];
1245
1246     #XXX What is ref() checking here?
1247     #YYY User may be storing a hash, in which case we do not want it run
1248     #YYY through the filtering system
1249         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1250         ? $self->root->{filter_store_value}->($_[2])
1251         : $_[2];
1252
1253         my $unpacked_key = $key;
1254         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1255
1256         my $md5 = $DIGEST_FUNC->($key);
1257
1258         ##
1259         # Make sure file is open
1260         ##
1261         if (!defined($self->fh) && !$self->_open()) {
1262                 return;
1263         }
1264         ##
1265
1266     my $fh = $self->fh;
1267
1268         ##
1269         # Request exclusive lock for writing
1270         ##
1271         $self->lock( LOCK_EX );
1272
1273         ##
1274         # If locking is enabled, set 'end' parameter again, in case another
1275         # DB instance appended to our file while we were unlocked.
1276         ##
1277         if ($self->root->{locking} || $self->root->{volatile}) {
1278                 $self->root->{end} = (stat($fh))[7];
1279         }
1280
1281         ##
1282         # Locate offset for bucket list using digest index system
1283         ##
1284         my $tag = $self->_load_tag($self->base_offset);
1285         if (!$tag) {
1286                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1287         }
1288
1289         my $ch = 0;
1290         while ($tag->{signature} ne SIG_BLIST) {
1291                 my $num = ord(substr($md5, $ch, 1));
1292                 my $new_tag = $self->_index_lookup($tag, $num);
1293                 if (!$new_tag) {
1294                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1295                         seek($fh, $ref_loc, SEEK_SET);
1296                         print($fh pack($LONG_PACK, $self->root->{end}) );
1297
1298                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1299                         $tag->{ref_loc} = $ref_loc;
1300                         $tag->{ch} = $ch;
1301                         last;
1302                 }
1303                 else {
1304                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1305                         $tag = $new_tag;
1306                         $tag->{ref_loc} = $ref_loc;
1307                         $tag->{ch} = $ch;
1308                 }
1309                 $ch++;
1310         }
1311
1312         ##
1313         # Add key/value to bucket list
1314         ##
1315         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1316
1317         ##
1318         # If this object is an array, and bucket was not a replace, and key is numerical,
1319         # and index is equal or greater than current length, advance length variable.
1320         ##
1321         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1322                 $self->STORESIZE( $unpacked_key + 1 );
1323         }
1324
1325         $self->unlock();
1326
1327         return $result;
1328 }
1329
1330 sub FETCH {
1331         ##
1332         # Fetch single value or element given plain key or array index
1333         ##
1334     my $self = $_[0]->_get_self;
1335
1336     my $key = $_[1];
1337     if ( $self->type eq TYPE_HASH ) {
1338         if ( my $filter = $self->root->{filter_store_key} ) {
1339             $key = $filter->( $key );
1340         }
1341     }
1342     elsif ( $self->type eq TYPE_ARRAY ) {
1343         if ( $key =~ /^\d+$/ ) {
1344             $key = pack($LONG_PACK, $key);
1345         }
1346     }
1347
1348         my $md5 = $DIGEST_FUNC->($key);
1349
1350         ##
1351         # Make sure file is open
1352         ##
1353         if (!defined($self->fh)) { $self->_open(); }
1354
1355         ##
1356         # Request shared lock for reading
1357         ##
1358         $self->lock( LOCK_SH );
1359
1360         my $tag = $self->_find_bucket_list( $md5 );
1361         if (!$tag) {
1362                 $self->unlock();
1363                 return;
1364         }
1365
1366         ##
1367         # Get value from bucket list
1368         ##
1369         my $result = $self->_get_bucket_value( $tag, $md5 );
1370
1371         $self->unlock();
1372
1373     #XXX What is ref() checking here?
1374         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1375 }
1376
1377 sub DELETE {
1378         ##
1379         # Delete single key/value pair or element given plain key or array index
1380         ##
1381     my $self = $_[0]->_get_self;
1382         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1383
1384         my $unpacked_key = $key;
1385         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1386         my $md5 = $DIGEST_FUNC->($key);
1387
1388         ##
1389         # Make sure file is open
1390         ##
1391         if (!defined($self->fh)) { $self->_open(); }
1392
1393         ##
1394         # Request exclusive lock for writing
1395         ##
1396         $self->lock( LOCK_EX );
1397
1398         my $tag = $self->_find_bucket_list( $md5 );
1399         if (!$tag) {
1400                 $self->unlock();
1401                 return;
1402         }
1403
1404         ##
1405         # Delete bucket
1406         ##
1407     my $value = $self->FETCH( $unpacked_key );
1408         my $result = $self->_delete_bucket( $tag, $md5 );
1409
1410         ##
1411         # If this object is an array and the key deleted was on the end of the stack,
1412         # decrement the length variable.
1413         ##
1414         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1415                 $self->STORESIZE( $unpacked_key );
1416         }
1417
1418         $self->unlock();
1419
1420         return $value;
1421 }
1422
1423 sub EXISTS {
1424         ##
1425         # Check if a single key or element exists given plain key or array index
1426         ##
1427     my $self = $_[0]->_get_self;
1428         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1429
1430         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1431         my $md5 = $DIGEST_FUNC->($key);
1432
1433         ##
1434         # Make sure file is open
1435         ##
1436         if (!defined($self->fh)) { $self->_open(); }
1437
1438         ##
1439         # Request shared lock for reading
1440         ##
1441         $self->lock( LOCK_SH );
1442
1443         my $tag = $self->_find_bucket_list( $md5 );
1444
1445         ##
1446         # For some reason, the built-in exists() function returns '' for false
1447         ##
1448         if (!$tag) {
1449                 $self->unlock();
1450                 return '';
1451         }
1452
1453         ##
1454         # Check if bucket exists and return 1 or ''
1455         ##
1456         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1457
1458         $self->unlock();
1459
1460         return $result;
1461 }
1462
1463 sub CLEAR {
1464         ##
1465         # Clear all keys from hash, or all elements from array.
1466         ##
1467     my $self = $_[0]->_get_self;
1468
1469         ##
1470         # Make sure file is open
1471         ##
1472         if (!defined($self->fh)) { $self->_open(); }
1473
1474         ##
1475         # Request exclusive lock for writing
1476         ##
1477         $self->lock( LOCK_EX );
1478
1479     my $fh = $self->fh;
1480
1481         seek($fh, $self->base_offset, SEEK_SET);
1482         if (eof $fh) {
1483                 $self->unlock();
1484                 return;
1485         }
1486
1487         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1488
1489         $self->unlock();
1490
1491         return 1;
1492 }
1493
1494 ##
1495 # Public method aliases
1496 ##
1497 *put = *store = *STORE;
1498 *get = *fetch = *FETCH;
1499 *delete = *DELETE;
1500 *exists = *EXISTS;
1501 *clear = *CLEAR;
1502
1503 package DBM::Deep::_::Root;
1504
1505 sub new {
1506     my $class = shift;
1507     my ($args) = @_;
1508
1509     my $self = bless {
1510         file => undef,
1511         fh => undef,
1512         end => 0,
1513         autoflush => undef,
1514         locking => undef,
1515         volatile => undef,
1516         debug => undef,
1517         mode => 'r+',
1518         filter_store_key => undef,
1519         filter_store_value => undef,
1520         filter_fetch_key => undef,
1521         filter_fetch_value => undef,
1522         autobless => undef,
1523         locked => 0,
1524         %$args,
1525     }, $class;
1526
1527     return $self;
1528 }
1529
1530 sub DESTROY {
1531     my $self = shift;
1532     return unless $self;
1533
1534     close $self->{fh} if $self->{fh};
1535
1536     return;
1537 }
1538
1539 1;
1540
1541 __END__
1542
1543 =head1 NAME
1544
1545 DBM::Deep - A pure perl multi-level hash/array DBM
1546
1547 =head1 SYNOPSIS
1548
1549   use DBM::Deep;
1550   my $db = DBM::Deep->new( "foo.db" );
1551
1552   $db->{key} = 'value'; # tie() style
1553   print $db->{key};
1554
1555   $db->put('key', 'value'); # OO style
1556   print $db->get('key');
1557
1558   # true multi-level support
1559   $db->{my_complex} = [
1560         'hello', { perl => 'rules' },
1561         42, 99 ];
1562
1563 =head1 DESCRIPTION
1564
1565 A unique flat-file database module, written in pure perl.  True
1566 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1567 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1568 handle millions of keys and unlimited hash levels without significant
1569 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1570 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1571 Mac OS X and Windows.
1572
1573 =head1 INSTALLATION
1574
1575 Hopefully you are using CPAN's excellent Perl module, which will download
1576 and install the module for you.  If not, get the tarball, and run these
1577 commands:
1578
1579         tar zxf DBM-Deep-*
1580         cd DBM-Deep-*
1581         perl Makefile.PL
1582         make
1583         make test
1584         make install
1585
1586 =head1 SETUP
1587
1588 Construction can be done OO-style (which is the recommended way), or using
1589 Perl's tie() function.  Both are examined here.
1590
1591 =head2 OO CONSTRUCTION
1592
1593 The recommended way to construct a DBM::Deep object is to use the new()
1594 method, which gets you a blessed, tied hash or array reference.
1595
1596         my $db = DBM::Deep->new( "foo.db" );
1597
1598 This opens a new database handle, mapped to the file "foo.db".  If this
1599 file does not exist, it will automatically be created.  DB files are
1600 opened in "r+" (read/write) mode, and the type of object returned is a
1601 hash, unless otherwise specified (see L<OPTIONS> below).
1602
1603
1604
1605 You can pass a number of options to the constructor to specify things like
1606 locking, autoflush, etc.  This is done by passing an inline hash:
1607
1608         my $db = DBM::Deep->new(
1609                 file => "foo.db",
1610                 locking => 1,
1611                 autoflush => 1
1612         );
1613
1614 Notice that the filename is now specified I<inside> the hash with
1615 the "file" parameter, as opposed to being the sole argument to the
1616 constructor.  This is required if any options are specified.
1617 See L<OPTIONS> below for the complete list.
1618
1619
1620
1621 You can also start with an array instead of a hash.  For this, you must
1622 specify the C<type> parameter:
1623
1624         my $db = DBM::Deep->new(
1625                 file => "foo.db",
1626                 type => DBM::Deep->TYPE_ARRAY
1627         );
1628
1629 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1630 a new DB file.  If you create a DBM::Deep object with an existing file, the
1631 C<type> will be loaded from the file header, and ignored if it is passed
1632 to the constructor.
1633
1634 =head2 TIE CONSTRUCTION
1635
1636 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1637 tie() function.  This is not ideal, because you get only a basic, tied hash
1638 (or array) which is not blessed, so you can't call any functions on it.
1639
1640         my %hash;
1641         tie %hash, "DBM::Deep", "foo.db";
1642
1643         my @array;
1644         tie @array, "DBM::Deep", "bar.db";
1645
1646 As with the OO constructor, you can replace the DB filename parameter with
1647 a hash containing one or more options (see L<OPTIONS> just below for the
1648 complete list).
1649
1650         tie %hash, "DBM::Deep", {
1651                 file => "foo.db",
1652                 locking => 1,
1653                 autoflush => 1
1654         };
1655
1656 =head2 OPTIONS
1657
1658 There are a number of options that can be passed in when constructing your
1659 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1660
1661 =over
1662
1663 =item * file
1664
1665 Filename of the DB file to link the handle to.  You can pass a full absolute
1666 filesystem path, partial path, or a plain filename if the file is in the
1667 current working directory.  This is a required parameter.
1668
1669 =item * mode
1670
1671 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1672 module.  This is an optional parameter, and defaults to "r+" (read/write).
1673 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1674 created if it doesn't exist.
1675
1676 =item * type
1677
1678 This parameter specifies what type of object to create, a hash or array.  Use
1679 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1680 This only takes effect when beginning a new file.  This is an optional
1681 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1682
1683 =item * locking
1684
1685 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1686 function to lock the database in exclusive mode for writes, and shared mode for
1687 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1688 any child hashes or arrays> that use the same DB file.  This is an optional
1689 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1690
1691 =item * autoflush
1692
1693 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1694 This obviously slows down write operations, but is required if you may have
1695 multiple processes accessing the same DB file (also consider enable I<locking>
1696 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1697 parameter, and defaults to 0 (disabled).
1698
1699 =item * volatile
1700
1701 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1702 STORE() operation.  This is required if an outside force may change the size of
1703 the file between transactions.  Locking also implicitly enables volatile.  This
1704 is useful if you want to use a different locking system or write your own.  Pass
1705 any true value to enable.  This is an optional parameter, and defaults to 0
1706 (disabled).
1707
1708 =item * autobless
1709
1710 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1711 restore them when fetched.  This is an B<experimental> feature, and does have
1712 side-effects.  Basically, when hashes are re-blessed into their original
1713 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1714 able to call any DBM::Deep methods on them.  You have been warned.
1715 This is an optional parameter, and defaults to 0 (disabled).
1716
1717 =item * filter_*
1718
1719 See L<FILTERS> below.
1720
1721 =item * debug
1722
1723 Setting I<debug> mode will make all errors non-fatal, dump them out to
1724 STDERR, and continue on.  This is for debugging purposes only, and probably
1725 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1726
1727 =item * fh
1728
1729 Instead of passing a file path, you can instead pass a handle to an pre-opened
1730 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1731 contains your entire Perl script, as well as the data following the __DATA__
1732 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1733 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1734 in that.
1735
1736 =back
1737
1738 =head1 TIE INTERFACE
1739
1740 With DBM::Deep you can access your databases using Perl's standard hash/array
1741 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1742 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1743 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1744 section above.  This simply tells you how to use DBM::Deep using regular hashes
1745 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1746 work too).  It is entirely up to you how to want to access your databases.
1747
1748 =head2 HASHES
1749
1750 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1751 or even nested hashes (or arrays) using standard Perl syntax:
1752
1753         my $db = DBM::Deep->new( "foo.db" );
1754
1755         $db->{mykey} = "myvalue";
1756         $db->{myhash} = {};
1757         $db->{myhash}->{subkey} = "subvalue";
1758
1759         print $db->{myhash}->{subkey} . "\n";
1760
1761 You can even step through hash keys using the normal Perl C<keys()> function:
1762
1763         foreach my $key (keys %$db) {
1764                 print "$key: " . $db->{$key} . "\n";
1765         }
1766
1767 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1768 pushes them onto an array, all before the loop even begins.  If you have an
1769 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1770 Perl's C<each()> function, which pulls keys/values one at a time, using very
1771 little memory:
1772
1773         while (my ($key, $value) = each %$db) {
1774                 print "$key: $value\n";
1775         }
1776
1777 Please note that when using C<each()>, you should always pass a direct
1778 hash reference, not a lookup.  Meaning, you should B<never> do this:
1779
1780         # NEVER DO THIS
1781         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1782
1783 This causes an infinite loop, because for each iteration, Perl is calling
1784 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1785 it effectively keeps returning the first key over and over again. Instead,
1786 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1787
1788 =head2 ARRAYS
1789
1790 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1791 reference.  This includes inserting, removing and manipulating elements,
1792 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1793 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1794 or simply be a nested array reference inside a hash.  Example:
1795
1796         my $db = DBM::Deep->new(
1797                 file => "foo-array.db",
1798                 type => DBM::Deep->TYPE_ARRAY
1799         );
1800
1801         $db->[0] = "foo";
1802         push @$db, "bar", "baz";
1803         unshift @$db, "bah";
1804
1805         my $last_elem = pop @$db; # baz
1806         my $first_elem = shift @$db; # bah
1807         my $second_elem = $db->[1]; # bar
1808
1809         my $num_elements = scalar @$db;
1810
1811 =head1 OO INTERFACE
1812
1813 In addition to the I<tie()> interface, you can also use a standard OO interface
1814 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1815 array) has its own methods, but both types share the following common methods:
1816 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1817
1818 =over
1819
1820 =item * put()
1821
1822 Stores a new hash key/value pair, or sets an array element value.  Takes two
1823 arguments, the hash key or array index, and the new value.  The value can be
1824 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1825
1826         $db->put("foo", "bar"); # for hashes
1827         $db->put(1, "bar"); # for arrays
1828
1829 =item * get()
1830
1831 Fetches the value of a hash key or array element.  Takes one argument: the hash
1832 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1833 data type stored.
1834
1835         my $value = $db->get("foo"); # for hashes
1836         my $value = $db->get(1); # for arrays
1837
1838 =item * exists()
1839
1840 Checks if a hash key or array index exists.  Takes one argument: the hash key
1841 or array index.  Returns true if it exists, false if not.
1842
1843         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1844         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1845
1846 =item * delete()
1847
1848 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1849 key or array index.  Returns true on success, false if not found.  For arrays,
1850 the remaining elements located after the deleted element are NOT moved over.
1851 The deleted element is essentially just undefined, which is exactly how Perl's
1852 internal arrays work.  Please note that the space occupied by the deleted
1853 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1854 below for details and workarounds.
1855
1856         $db->delete("foo"); # for hashes
1857         $db->delete(1); # for arrays
1858
1859 =item * clear()
1860
1861 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1862 value.  Please note that the space occupied by the deleted keys/values or
1863 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1864 details and workarounds.
1865
1866         $db->clear(); # hashes or arrays
1867
1868 =back
1869
1870 =head2 HASHES
1871
1872 For hashes, DBM::Deep supports all the common methods described above, and the
1873 following additional methods: C<first_key()> and C<next_key()>.
1874
1875 =over
1876
1877 =item * first_key()
1878
1879 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1880 fetched in an undefined order (which appears random).  Takes no arguments,
1881 returns the key as a scalar value.
1882
1883         my $key = $db->first_key();
1884
1885 =item * next_key()
1886
1887 Returns the "next" key in the hash, given the previous one as the sole argument.
1888 Returns undef if there are no more keys to be fetched.
1889
1890         $key = $db->next_key($key);
1891
1892 =back
1893
1894 Here are some examples of using hashes:
1895
1896         my $db = DBM::Deep->new( "foo.db" );
1897
1898         $db->put("foo", "bar");
1899         print "foo: " . $db->get("foo") . "\n";
1900
1901         $db->put("baz", {}); # new child hash ref
1902         $db->get("baz")->put("buz", "biz");
1903         print "buz: " . $db->get("baz")->get("buz") . "\n";
1904
1905         my $key = $db->first_key();
1906         while ($key) {
1907                 print "$key: " . $db->get($key) . "\n";
1908                 $key = $db->next_key($key);
1909         }
1910
1911         if ($db->exists("foo")) { $db->delete("foo"); }
1912
1913 =head2 ARRAYS
1914
1915 For arrays, DBM::Deep supports all the common methods described above, and the
1916 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1917 C<unshift()> and C<splice()>.
1918
1919 =over
1920
1921 =item * length()
1922
1923 Returns the number of elements in the array.  Takes no arguments.
1924
1925         my $len = $db->length();
1926
1927 =item * push()
1928
1929 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1930 refs or array refs.  No return value.
1931
1932         $db->push("foo", "bar", {});
1933
1934 =item * pop()
1935
1936 Fetches the last element in the array, and deletes it.  Takes no arguments.
1937 Returns undef if array is empty.  Returns the element value.
1938
1939         my $elem = $db->pop();
1940
1941 =item * shift()
1942
1943 Fetches the first element in the array, deletes it, then shifts all the
1944 remaining elements over to take up the space.  Returns the element value.  This
1945 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1946 details.
1947
1948         my $elem = $db->shift();
1949
1950 =item * unshift()
1951
1952 Inserts one or more elements onto the beginning of the array, shifting all
1953 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1954 No return value.  This method is not recommended with large arrays -- see
1955 <LARGE ARRAYS> below for details.
1956
1957         $db->unshift("foo", "bar", {});
1958
1959 =item * splice()
1960
1961 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1962 -f splice> for usage -- it is too complicated to document here.  This method is
1963 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1964
1965 =back
1966
1967 Here are some examples of using arrays:
1968
1969         my $db = DBM::Deep->new(
1970                 file => "foo.db",
1971                 type => DBM::Deep->TYPE_ARRAY
1972         );
1973
1974         $db->push("bar", "baz");
1975         $db->unshift("foo");
1976         $db->put(3, "buz");
1977
1978         my $len = $db->length();
1979         print "length: $len\n"; # 4
1980
1981         for (my $k=0; $k<$len; $k++) {
1982                 print "$k: " . $db->get($k) . "\n";
1983         }
1984
1985         $db->splice(1, 2, "biz", "baf");
1986
1987         while (my $elem = shift @$db) {
1988                 print "shifted: $elem\n";
1989         }
1990
1991 =head1 LOCKING
1992
1993 Enable automatic file locking by passing a true value to the C<locking>
1994 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1995
1996         my $db = DBM::Deep->new(
1997                 file => "foo.db",
1998                 locking => 1
1999         );
2000
2001 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2002 mode for writes, and shared mode for reads.  This is required if you have
2003 multiple processes accessing the same database file, to avoid file corruption.
2004 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2005 NFS> below for more.
2006
2007 =head2 EXPLICIT LOCKING
2008
2009 You can explicitly lock a database, so it remains locked for multiple
2010 transactions.  This is done by calling the C<lock()> method, and passing an
2011 optional lock mode argument (defaults to exclusive mode).  This is particularly
2012 useful for things like counters, where the current value needs to be fetched,
2013 then incremented, then stored again.
2014
2015         $db->lock();
2016         my $counter = $db->get("counter");
2017         $counter++;
2018         $db->put("counter", $counter);
2019         $db->unlock();
2020
2021         # or...
2022
2023         $db->lock();
2024         $db->{counter}++;
2025         $db->unlock();
2026
2027 You can pass C<lock()> an optional argument, which specifies which mode to use
2028 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2029 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2030 same as the constants defined in Perl's C<Fcntl> module.
2031
2032         $db->lock( DBM::Deep->LOCK_SH );
2033         # something here
2034         $db->unlock();
2035
2036 If you want to implement your own file locking scheme, be sure to create your
2037 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2038 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2039 below for more.
2040
2041 =head1 IMPORTING/EXPORTING
2042
2043 You can import existing complex structures by calling the C<import()> method,
2044 and export an entire database into an in-memory structure using the C<export()>
2045 method.  Both are examined here.
2046
2047 =head2 IMPORTING
2048
2049 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2050 walking the structure and adding keys/elements to the database as you go,
2051 simply pass a reference to the C<import()> method.  This recursively adds
2052 everything to an existing DBM::Deep object for you.  Here is an example:
2053
2054         my $struct = {
2055                 key1 => "value1",
2056                 key2 => "value2",
2057                 array1 => [ "elem0", "elem1", "elem2" ],
2058                 hash1 => {
2059                         subkey1 => "subvalue1",
2060                         subkey2 => "subvalue2"
2061                 }
2062         };
2063
2064         my $db = DBM::Deep->new( "foo.db" );
2065         $db->import( $struct );
2066
2067         print $db->{key1} . "\n"; # prints "value1"
2068
2069 This recursively imports the entire C<$struct> object into C<$db>, including
2070 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2071 keys are merged with the existing ones, replacing if they already exist.
2072 The C<import()> method can be called on any database level (not just the base
2073 level), and works with both hash and array DB types.
2074
2075
2076
2077 B<Note:> Make sure your existing structure has no circular references in it.
2078 These will cause an infinite loop when importing.
2079
2080 =head2 EXPORTING
2081
2082 Calling the C<export()> method on an existing DBM::Deep object will return
2083 a reference to a new in-memory copy of the database.  The export is done
2084 recursively, so all nested hashes/arrays are all exported to standard Perl
2085 objects.  Here is an example:
2086
2087         my $db = DBM::Deep->new( "foo.db" );
2088
2089         $db->{key1} = "value1";
2090         $db->{key2} = "value2";
2091         $db->{hash1} = {};
2092         $db->{hash1}->{subkey1} = "subvalue1";
2093         $db->{hash1}->{subkey2} = "subvalue2";
2094
2095         my $struct = $db->export();
2096
2097         print $struct->{key1} . "\n"; # prints "value1"
2098
2099 This makes a complete copy of the database in memory, and returns a reference
2100 to it.  The C<export()> method can be called on any database level (not just
2101 the base level), and works with both hash and array DB types.  Be careful of
2102 large databases -- you can store a lot more data in a DBM::Deep object than an
2103 in-memory Perl structure.
2104
2105
2106
2107 B<Note:> Make sure your database has no circular references in it.
2108 These will cause an infinite loop when exporting.
2109
2110 =head1 FILTERS
2111
2112 DBM::Deep has a number of hooks where you can specify your own Perl function
2113 to perform filtering on incoming or outgoing data.  This is a perfect
2114 way to extend the engine, and implement things like real-time compression or
2115 encryption.  Filtering applies to the base DB level, and all child hashes /
2116 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2117 constructed, or by calling the C<set_filter()> method at any time.  There are
2118 four available filter hooks, described below:
2119
2120 =over
2121
2122 =item * filter_store_key
2123
2124 This filter is called whenever a hash key is stored.  It
2125 is passed the incoming key, and expected to return a transformed key.
2126
2127 =item * filter_store_value
2128
2129 This filter is called whenever a hash key or array element is stored.  It
2130 is passed the incoming value, and expected to return a transformed value.
2131
2132 =item * filter_fetch_key
2133
2134 This filter is called whenever a hash key is fetched (i.e. via
2135 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2136 and expected to return the plain key.
2137
2138 =item * filter_fetch_value
2139
2140 This filter is called whenever a hash key or array element is fetched.
2141 It is passed the transformed value, and expected to return the plain value.
2142
2143 =back
2144
2145 Here are the two ways to setup a filter hook:
2146
2147         my $db = DBM::Deep->new(
2148                 file => "foo.db",
2149                 filter_store_value => \&my_filter_store,
2150                 filter_fetch_value => \&my_filter_fetch
2151         );
2152
2153         # or...
2154
2155         $db->set_filter( "filter_store_value", \&my_filter_store );
2156         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2157
2158 Your filter function will be called only when dealing with SCALAR keys or
2159 values.  When nested hashes and arrays are being stored/fetched, filtering
2160 is bypassed.  Filters are called as static functions, passed a single SCALAR
2161 argument, and expected to return a single SCALAR value.  If you want to
2162 remove a filter, set the function reference to C<undef>:
2163
2164         $db->set_filter( "filter_store_value", undef );
2165
2166 =head2 REAL-TIME ENCRYPTION EXAMPLE
2167
2168 Here is a working example that uses the I<Crypt::Blowfish> module to
2169 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2170 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2171 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2172
2173         use DBM::Deep;
2174         use Crypt::Blowfish;
2175         use Crypt::CBC;
2176
2177         my $cipher = Crypt::CBC->new({
2178                 'key'             => 'my secret key',
2179                 'cipher'          => 'Blowfish',
2180                 'iv'              => '$KJh#(}q',
2181                 'regenerate_key'  => 0,
2182                 'padding'         => 'space',
2183                 'prepend_iv'      => 0
2184         });
2185
2186         my $db = DBM::Deep->new(
2187                 file => "foo-encrypt.db",
2188                 filter_store_key => \&my_encrypt,
2189                 filter_store_value => \&my_encrypt,
2190                 filter_fetch_key => \&my_decrypt,
2191                 filter_fetch_value => \&my_decrypt,
2192         );
2193
2194         $db->{key1} = "value1";
2195         $db->{key2} = "value2";
2196         print "key1: " . $db->{key1} . "\n";
2197         print "key2: " . $db->{key2} . "\n";
2198
2199         undef $db;
2200         exit;
2201
2202         sub my_encrypt {
2203                 return $cipher->encrypt( $_[0] );
2204         }
2205         sub my_decrypt {
2206                 return $cipher->decrypt( $_[0] );
2207         }
2208
2209 =head2 REAL-TIME COMPRESSION EXAMPLE
2210
2211 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2212 compression / decompression of keys & values with DBM::Deep Filters.
2213 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2214 more on I<Compress::Zlib>.
2215
2216         use DBM::Deep;
2217         use Compress::Zlib;
2218
2219         my $db = DBM::Deep->new(
2220                 file => "foo-compress.db",
2221                 filter_store_key => \&my_compress,
2222                 filter_store_value => \&my_compress,
2223                 filter_fetch_key => \&my_decompress,
2224                 filter_fetch_value => \&my_decompress,
2225         );
2226
2227         $db->{key1} = "value1";
2228         $db->{key2} = "value2";
2229         print "key1: " . $db->{key1} . "\n";
2230         print "key2: " . $db->{key2} . "\n";
2231
2232         undef $db;
2233         exit;
2234
2235         sub my_compress {
2236                 return Compress::Zlib::memGzip( $_[0] ) ;
2237         }
2238         sub my_decompress {
2239                 return Compress::Zlib::memGunzip( $_[0] ) ;
2240         }
2241
2242 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2243 actually numerical index numbers, and are not filtered.
2244
2245 =head1 ERROR HANDLING
2246
2247 Most DBM::Deep methods return a true value for success, and call die() on
2248 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2249 actual error message is stored in an internal scalar, which can be fetched by
2250 calling the C<error()> method.
2251
2252         my $db = DBM::Deep->new( "foo.db" ); # create hash
2253         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2254
2255         print $db->error(); # prints error message
2256
2257 You can then call C<clear_error()> to clear the current error state.
2258
2259         $db->clear_error();
2260
2261 If you set the C<debug> option to true when creating your DBM::Deep object,
2262 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2263 for debugging purposes.
2264
2265 =head1 LARGEFILE SUPPORT
2266
2267 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2268 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2269 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2270 by calling the static C<set_pack()> method before you do anything else.
2271
2272         DBM::Deep::set_pack(8, 'Q');
2273
2274 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2275 instead of 32-bit longs.  After setting these values your DB files have a
2276 theoretical maximum size of 16 XB (exabytes).
2277
2278
2279
2280 B<Note:> Changing these values will B<NOT> work for existing database files.
2281 Only change this for new files, and make sure it stays set consistently
2282 throughout the file's life.  If you do set these values, you can no longer
2283 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2284 back to 32-bit mode.
2285
2286
2287
2288 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2289 only a 32-bit Perl.  However, I have received user reports that this does
2290 indeed work!
2291
2292 =head1 LOW-LEVEL ACCESS
2293
2294 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2295 you can call the C<fh()> method, which returns the handle:
2296
2297         my $fh = $db->fh();
2298
2299 This method can be called on the root level of the datbase, or any child
2300 hashes or arrays.  All levels share a I<root> structure, which contains things
2301 like the FileHandle, a reference counter, and all your options you specified
2302 when you created the object.  You can get access to this root structure by
2303 calling the C<root()> method.
2304
2305         my $root = $db->root();
2306
2307 This is useful for changing options after the object has already been created,
2308 such as enabling/disabling locking, volatile or debug modes.  You can also
2309 store your own temporary user data in this structure (be wary of name
2310 collision), which is then accessible from any child hash or array.
2311
2312 =head1 CUSTOM DIGEST ALGORITHM
2313
2314 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2315 keys.  However you can override this, and use another algorithm (such as SHA-256)
2316 or even write your own.  But please note that DBM::Deep currently expects zero
2317 collisions, so your algorithm has to be I<perfect>, so to speak.
2318 Collision detection may be introduced in a later version.
2319
2320
2321
2322 You can specify a custom digest algorithm by calling the static C<set_digest()>
2323 function, passing a reference to a subroutine, and the length of the algorithm's
2324 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2325 objects.  Here is a working example that uses a 256-bit hash from the
2326 I<Digest::SHA256> module.  Please see
2327 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2328
2329         use DBM::Deep;
2330         use Digest::SHA256;
2331
2332         my $context = Digest::SHA256::new(256);
2333
2334         DBM::Deep::set_digest( \&my_digest, 32 );
2335
2336         my $db = DBM::Deep->new( "foo-sha.db" );
2337
2338         $db->{key1} = "value1";
2339         $db->{key2} = "value2";
2340         print "key1: " . $db->{key1} . "\n";
2341         print "key2: " . $db->{key2} . "\n";
2342
2343         undef $db;
2344         exit;
2345
2346         sub my_digest {
2347                 return substr( $context->hash($_[0]), 0, 32 );
2348         }
2349
2350 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2351 of bytes you specify in the C<set_digest()> function (in this case 32).
2352
2353 =head1 CIRCULAR REFERENCES
2354
2355 DBM::Deep has B<experimental> support for circular references.  Meaning you
2356 can have a nested hash key or array element that points to a parent object.
2357 This relationship is stored in the DB file, and is preserved between sessions.
2358 Here is an example:
2359
2360         my $db = DBM::Deep->new( "foo.db" );
2361
2362         $db->{foo} = "bar";
2363         $db->{circle} = $db; # ref to self
2364
2365         print $db->{foo} . "\n"; # prints "foo"
2366         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2367
2368 One catch is, passing the object to a function that recursively walks the
2369 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2370 C<export()> methods) will result in an infinite loop.  The other catch is,
2371 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2372 or C<next_key()> methods), you will get the I<target object's key>, not the
2373 ref's key.  This gets even more interesting with the above example, where
2374 the I<circle> key points to the base DB object, which technically doesn't
2375 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2376 special case.
2377
2378 =head1 CAVEATS / ISSUES / BUGS
2379
2380 This section describes all the known issues with DBM::Deep.  It you have found
2381 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2382
2383 =head2 UNUSED SPACE RECOVERY
2384
2385 One major caveat with DBM::Deep is that space occupied by existing keys and
2386 values is not recovered when they are deleted.  Meaning if you keep deleting
2387 and adding new keys, your file will continuously grow.  I am working on this,
2388 but in the meantime you can call the built-in C<optimize()> method from time to
2389 time (perhaps in a crontab or something) to recover all your unused space.
2390
2391         $db->optimize(); # returns true on success
2392
2393 This rebuilds the ENTIRE database into a new file, then moves it on top of
2394 the original.  The new file will have no unused space, thus it will take up as
2395 little disk space as possible.  Please note that this operation can take
2396 a long time for large files, and you need enough disk space to temporarily hold
2397 2 copies of your DB file.  The temporary file is created in the same directory
2398 as the original, named with a ".tmp" extension, and is deleted when the
2399 operation completes.  Oh, and if locking is enabled, the DB is automatically
2400 locked for the entire duration of the copy.
2401
2402
2403
2404 B<WARNING:> Only call optimize() on the top-level node of the database, and
2405 make sure there are no child references lying around.  DBM::Deep keeps a reference
2406 counter, and if it is greater than 1, optimize() will abort and return undef.
2407
2408 =head2 AUTOVIVIFICATION
2409
2410 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2411 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2412 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2413 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2414 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2415 this does not work:
2416
2417         $db->{foo}->{bar} = "hello";
2418
2419 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2420 being an empty hash.  Try this instead, which works fine:
2421
2422         $db->{foo} = { bar => "hello" };
2423
2424 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2425 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2426 Probably a bug in Perl.
2427
2428 =head2 FILE CORRUPTION
2429
2430 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2431 for a 32-bit signature when opened, but other corruption in files can cause
2432 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2433 stuck in an infinite loop depending on the level of corruption.  File write
2434 operations are not checked for failure (for speed), so if you happen to run
2435 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2436 be addressed in a later version of DBM::Deep.
2437
2438 =head2 DB OVER NFS
2439
2440 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2441 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2442 about setting up your NFS server with a locking daemon, then using lockf() to
2443 lock your files, but your milage may vary there as well.  From what I
2444 understand, there is no real way to do it.  However, if you need access to the
2445 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2446 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2447
2448 =head2 COPYING OBJECTS
2449
2450 Beware of copying tied objects in Perl.  Very strange things can happen.
2451 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2452 returns a new, blessed, tied hash or array to the same level in the DB.
2453
2454         my $copy = $db->clone();
2455
2456 =head2 LARGE ARRAYS
2457
2458 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2459 These functions cause every element in the array to move, which can be murder
2460 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2461 a different location.  This may be addressed in a later version.
2462
2463 =head1 PERFORMANCE
2464
2465 This section discusses DBM::Deep's speed and memory usage.
2466
2467 =head2 SPEED
2468
2469 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2470 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2471 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2472 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2473 with huge databases.  Here is some test data:
2474
2475         Adding 1,000,000 keys to new DB file...
2476
2477         At 100 keys, avg. speed is 2,703 keys/sec
2478         At 200 keys, avg. speed is 2,642 keys/sec
2479         At 300 keys, avg. speed is 2,598 keys/sec
2480         At 400 keys, avg. speed is 2,578 keys/sec
2481         At 500 keys, avg. speed is 2,722 keys/sec
2482         At 600 keys, avg. speed is 2,628 keys/sec
2483         At 700 keys, avg. speed is 2,700 keys/sec
2484         At 800 keys, avg. speed is 2,607 keys/sec
2485         At 900 keys, avg. speed is 2,190 keys/sec
2486         At 1,000 keys, avg. speed is 2,570 keys/sec
2487         At 2,000 keys, avg. speed is 2,417 keys/sec
2488         At 3,000 keys, avg. speed is 1,982 keys/sec
2489         At 4,000 keys, avg. speed is 1,568 keys/sec
2490         At 5,000 keys, avg. speed is 1,533 keys/sec
2491         At 6,000 keys, avg. speed is 1,787 keys/sec
2492         At 7,000 keys, avg. speed is 1,977 keys/sec
2493         At 8,000 keys, avg. speed is 2,028 keys/sec
2494         At 9,000 keys, avg. speed is 2,077 keys/sec
2495         At 10,000 keys, avg. speed is 2,031 keys/sec
2496         At 20,000 keys, avg. speed is 1,970 keys/sec
2497         At 30,000 keys, avg. speed is 2,050 keys/sec
2498         At 40,000 keys, avg. speed is 2,073 keys/sec
2499         At 50,000 keys, avg. speed is 1,973 keys/sec
2500         At 60,000 keys, avg. speed is 1,914 keys/sec
2501         At 70,000 keys, avg. speed is 2,091 keys/sec
2502         At 80,000 keys, avg. speed is 2,103 keys/sec
2503         At 90,000 keys, avg. speed is 1,886 keys/sec
2504         At 100,000 keys, avg. speed is 1,970 keys/sec
2505         At 200,000 keys, avg. speed is 2,053 keys/sec
2506         At 300,000 keys, avg. speed is 1,697 keys/sec
2507         At 400,000 keys, avg. speed is 1,838 keys/sec
2508         At 500,000 keys, avg. speed is 1,941 keys/sec
2509         At 600,000 keys, avg. speed is 1,930 keys/sec
2510         At 700,000 keys, avg. speed is 1,735 keys/sec
2511         At 800,000 keys, avg. speed is 1,795 keys/sec
2512         At 900,000 keys, avg. speed is 1,221 keys/sec
2513         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2514
2515 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2516 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2517 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2518 Run time was 12 min 3 sec.
2519
2520 =head2 MEMORY USAGE
2521
2522 One of the great things about DBM::Deep is that it uses very little memory.
2523 Even with huge databases (1,000,000+ keys) you will not see much increased
2524 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2525 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2526 database handle:
2527
2528           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2529         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2530
2531 Basically the process is taking 2,716K of memory.  And here is the same
2532 process after storing and fetching 1,000,000 keys:
2533
2534           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2535         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2536
2537 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2538 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2539
2540 =head1 DB FILE FORMAT
2541
2542 In case you were interested in the underlying DB file format, it is documented
2543 here in this section.  You don't need to know this to use the module, it's just
2544 included for reference.
2545
2546 =head2 SIGNATURE
2547
2548 DBM::Deep files always start with a 32-bit signature to identify the file type.
2549 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2550 checked when the file is opened.
2551
2552 =head2 TAG
2553
2554 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2555 has a standard header containing the type of data, the length of data, and then
2556 the data itself.  The type is a single character (1 byte), the length is a
2557 32-bit unsigned long in network byte order, and the data is, well, the data.
2558 Here is how it unfolds:
2559
2560 =head2 MASTER INDEX
2561
2562 Immediately after the 32-bit file signature is the I<Master Index> record.
2563 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2564 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2565 depending on how the DBM::Deep object was constructed.
2566
2567
2568
2569 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2570 number).  The first 8-bit char of the MD5 signature is the offset into the
2571 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2572 index element is a file offset of the next tag for the key/element in question,
2573 which is usually a I<Bucket List> tag (see below).
2574
2575
2576
2577 The next tag I<could> be another index, depending on how many keys/elements
2578 exist.  See L<RE-INDEXING> below for details.
2579
2580 =head2 BUCKET LIST
2581
2582 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2583 file offsets to where the actual data is stored.  It starts with a standard
2584 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2585 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2586 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2587 When the list fills up, a I<Re-Index> operation is performed (See
2588 L<RE-INDEXING> below).
2589
2590 =head2 BUCKET
2591
2592 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2593 index/value pair (in array mode).  It starts with a standard tag header with
2594 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2595 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2596 header.  The size reported in the tag header is only for the value, but then,
2597 just after the value is another size (32-bit unsigned long) and then the plain
2598 key itself.  Since the value is likely to be fetched more often than the plain
2599 key, I figured it would be I<slightly> faster to store the value first.
2600
2601
2602
2603 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2604 record for the nested structure, where the process begins all over again.
2605
2606 =head2 RE-INDEXING
2607
2608 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2609 exhausted.  Then, when another key/element comes in, the list is converted to a
2610 new index record.  However, this index will look at the next char in the MD5
2611 hash, and arrange new Bucket List pointers accordingly.  This process is called
2612 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2613 17 (16 + new one) keys/elements are removed from the old Bucket List and
2614 inserted into the new index.  Several new Bucket Lists are created in the
2615 process, as a new MD5 char from the key is being examined (it is unlikely that
2616 the keys will all share the same next char of their MD5s).
2617
2618
2619
2620 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2621 when the Bucket Lists will turn into indexes, but the first round tends to
2622 happen right around 4,000 keys.  You will see a I<slight> decrease in
2623 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2624 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2625 right around 900,000 keys.  This process can continue nearly indefinitely --
2626 right up until the point the I<MD5> signatures start colliding with each other,
2627 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2628 getting struck by lightning while you are walking to cash in your tickets.
2629 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2630 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2631 this is 340 unodecillion, but don't quote me).
2632
2633 =head2 STORING
2634
2635 When a new key/element is stored, the key (or index number) is first ran through
2636 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2637 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2638 for the first char of the signature (in this case I<b>).  If it does not exist,
2639 a new I<Bucket List> is created for our key (and the next 15 future keys that
2640 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2641 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2642 this point, unless we are replacing an existing I<Bucket>), where the actual
2643 data will be stored.
2644
2645 =head2 FETCHING
2646
2647 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2648 (or index number), then walking along the indexes.  If there are enough
2649 keys/elements in this DB level, there might be nested indexes, each linked to
2650 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2651 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2652 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2653 plain key are stored.
2654
2655
2656
2657 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2658 methods.  In this process the indexes are walked systematically, and each key
2659 fetched in increasing MD5 order (which is why it appears random).   Once the
2660 I<Bucket> is found, the value is skipped the plain key returned instead.
2661 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2662 alphabetically sorted.  This only happens on an index-level -- as soon as the
2663 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2664 so it's pretty much undefined how the keys will come out -- just like Perl's
2665 built-in hashes.
2666
2667 =head1 CODE COVERAGE
2668
2669 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2670 module's test suite.
2671
2672   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2673   File                           stmt   bran   cond    sub    pod   time  total
2674   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2675   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2676   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2677   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2678   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2679   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2680
2681 =head1 AUTHOR
2682
2683 Joseph Huckaby, L<jhuckaby@cpan.org>
2684
2685 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2686
2687 =head1 SEE ALSO
2688
2689 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2690 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2691
2692 =head1 LICENSE
2693
2694 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2695 This is free software, you may use it and distribute it under the
2696 same terms as Perl itself.
2697
2698 =cut