lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a FileHandle to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         #XXX Can the mode be anything but r+, w+, or a+??
 215         #XXX ie, it has to be in read-write mode
 216         #XXX So, should we verify that the mode is legitimate?
 217
 218         #XXX Maybe the mode thingy should just go away. There's no good
 219         #XXX reason for it ...
 220         if ( $self->root->{mode} eq 'w+' ) {
 221             $flags |= O_TRUNC;
 222         }
 223
 224         my $fh;
 225         sysopen( $fh, $self->root->{file}, $flags )
 226             or $fh = undef;
 227         $self->root->{fh} = $fh;
 228     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 229         if (! defined($self->fh)) {
 230                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 231         }
 232
 233     my $fh = $self->fh;
 234
 235     #XXX Can we remove this by using the right sysopen() flags?
 236     # Maybe ... q.v. above
 237     binmode $fh; # for win32
 238
 239     if ($self->root->{autoflush}) {
 240         my $old = select $fh;
 241         $|=1;
 242         select $old;
 243     }
 244
 245     # Set the
 246     seek($fh, 0, SEEK_SET);
 247
 248     my $signature;
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, SEEK_SET);
 256         print($fh SIG_FILE);
 257         $self->root->{end} = length(SIG_FILE);
 258         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 263
 264         # Flush the filehandle
 265         my $old_fh = select $fh;
 266         my $old_af = $|;
 267         $| = 1;
 268         $| = $old_af;
 269         select $old_fh;
 270
 271         return 1;
 272     }
 273
 274     ##
 275     # Check signature was valid
 276     ##
 277     unless ($signature eq SIG_FILE) {
 278         $self->_close();
 279         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 280     }
 281
 282     $self->root->{end} = (stat($fh))[7];
 283
 284     ##
 285     # Get our type from master index signature
 286     ##
 287     my $tag = $self->_load_tag($self->base_offset);
 288
 289 #XXX We probably also want to store the hash algorithm name and not assume anything
 290 #XXX The cool thing would be to allow a different hashing algorithm at every level
 291
 292     if (!$tag) {
 293         return $self->_throw_error("Corrupted file, no master index record");
 294     }
 295     if ($self->{type} ne $tag->{signature}) {
 296         return $self->_throw_error("File type mismatch");
 297     }
 298
 299     return 1;
 300 }
 301
 302 sub _close {
 303         ##
 304         # Close database FileHandle
 305         ##
 306     my $self = $_[0]->_get_self;
 307     close $self->root->{fh};
 308     $self->root->{fh} = undef;
 309 }
 310
 311 sub _create_tag {
 312         ##
 313         # Given offset, signature and content, create tag and write to disk
 314         ##
 315         my ($self, $offset, $sig, $content) = @_;
 316         my $size = length($content);
 317
 318     my $fh = $self->fh;
 319
 320         seek($fh, $offset, SEEK_SET);
 321         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 322
 323         if ($offset == $self->root->{end}) {
 324                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 325         }
 326
 327         return {
 328                 signature => $sig,
 329                 size => $size,
 330                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 331                 content => $content
 332         };
 333 }
 334
 335 sub _load_tag {
 336         ##
 337         # Given offset, load single tag and return signature, size and data
 338         ##
 339         my $self = shift;
 340         my $offset = shift;
 341
 342     my $fh = $self->fh;
 343
 344         seek($fh, $offset, SEEK_SET);
 345         if (eof $fh) { return undef; }
 346
 347         my $sig;
 348         read( $fh, $sig, SIG_SIZE);
 349
 350         my $size;
 351         read( $fh, $size, $DATA_LENGTH_SIZE);
 352         $size = unpack($DATA_LENGTH_PACK, $size);
 353
 354         my $buffer;
 355         read( $fh, $buffer, $size);
 356
 357         return {
 358                 signature => $sig,
 359                 size => $size,
 360                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 361                 content => $buffer
 362         };
 363 }
 364
 365 sub _index_lookup {
 366         ##
 367         # Given index tag, lookup single entry in index and return .
 368         ##
 369         my $self = shift;
 370         my ($tag, $index) = @_;
 371
 372         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 373         if (!$location) { return; }
 374
 375         return $self->_load_tag( $location );
 376 }
 377
 378 sub _add_bucket {
 379         ##
 380         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 381         # plain (undigested) key and value.
 382         ##
 383         my $self = shift;
 384         my ($tag, $md5, $plain_key, $value) = @_;
 385         my $keys = $tag->{content};
 386         my $location = 0;
 387         my $result = 2;
 388
 389     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 390         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 391
 392     my $fh = $self->fh;
 393
 394         ##
 395         # Iterate through buckets, seeing if this is a new entry or a replace.
 396         ##
 397         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 398                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 399                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 400                 if (!$subloc) {
 401                         ##
 402                         # Found empty bucket (end of list).  Populate and exit loop.
 403                         ##
 404                         $result = 2;
 405
 406             $location = $internal_ref
 407                 ? $value->base_offset
 408                 : $self->root->{end};
 409
 410                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 411                         print($fh $md5 . pack($LONG_PACK, $location) );
 412                         last;
 413                 }
 414                 elsif ($md5 eq $key) {
 415                         ##
 416                         # Found existing bucket with same key.  Replace with new value.
 417                         ##
 418                         $result = 1;
 419
 420                         if ($internal_ref) {
 421                                 $location = $value->base_offset;
 422                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 423                                 print($fh $md5 . pack($LONG_PACK, $location) );
 424                         }
 425                         else {
 426                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 427                                 my $size;
 428                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 429
 430                                 ##
 431                                 # If value is a hash, array, or raw value with equal or less size, we can
 432                                 # reuse the same content area of the database.  Otherwise, we have to create
 433                                 # a new content area at the EOF.
 434                                 ##
 435                                 my $actual_length;
 436                 my $r = Scalar::Util::reftype( $value ) || '';
 437                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 438                                 else { $actual_length = length($value); }
 439
 440                                 if ($actual_length <= $size) {
 441                                         $location = $subloc;
 442                                 }
 443                                 else {
 444                                         $location = $self->root->{end};
 445                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 446                                         print($fh pack($LONG_PACK, $location) );
 447                                 }
 448                         }
 449                         last;
 450                 }
 451         } # i loop
 452
 453         ##
 454         # If this is an internal reference, return now.
 455         # No need to write value or plain key
 456         ##
 457         if ($internal_ref) {
 458         return $result;
 459     }
 460
 461         ##
 462         # If bucket didn't fit into list, split into a new index level
 463         ##
 464         if (!$location) {
 465                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 466                 print($fh pack($LONG_PACK, $self->root->{end}) );
 467
 468                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 469                 my @offsets = ();
 470
 471                 $keys .= $md5 . pack($LONG_PACK, 0);
 472
 473                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 474                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 475                         if ($key) {
 476                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 477                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 478
 479                                 if ($offsets[$num]) {
 480                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 481                                         seek($fh, $offset, SEEK_SET);
 482                                         my $subkeys;
 483                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 484
 485                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 486                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 487                                                 if (!$subloc) {
 488                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 489                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 490                                                         last;
 491                                                 }
 492                                         } # k loop
 493                                 }
 494                                 else {
 495                                         $offsets[$num] = $self->root->{end};
 496                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 497                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 498
 499                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 500
 501                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 502                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 503                                 }
 504                         } # key is real
 505                 } # i loop
 506
 507                 $location ||= $self->root->{end};
 508         } # re-index bucket list
 509
 510         ##
 511         # Seek to content area and store signature, value and plaintext key
 512         ##
 513         if ($location) {
 514                 my $content_length;
 515                 seek($fh, $location, SEEK_SET);
 516
 517                 ##
 518                 # Write signature based on content type, set content length and write actual value.
 519                 ##
 520         my $r = Scalar::Util::reftype($value) || '';
 521                 if ($r eq 'HASH') {
 522                         print($fh TYPE_HASH );
 523                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 524                         $content_length = $INDEX_SIZE;
 525                 }
 526                 elsif ($r eq 'ARRAY') {
 527                         print($fh TYPE_ARRAY );
 528                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 529                         $content_length = $INDEX_SIZE;
 530                 }
 531                 elsif (!defined($value)) {
 532                         print($fh SIG_NULL );
 533                         print($fh pack($DATA_LENGTH_PACK, 0) );
 534                         $content_length = 0;
 535                 }
 536                 else {
 537                         print($fh SIG_DATA );
 538                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 539                         $content_length = length($value);
 540                 }
 541
 542                 ##
 543                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 544                 ##
 545                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 546
 547                 ##
 548                 # If value is blessed, preserve class name
 549                 ##
 550                 if ( $self->root->{autobless} ) {
 551             my $value_class = Scalar::Util::blessed($value);
 552             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 553                 ##
 554                 # Blessed ref -- will restore later
 555                 ##
 556                 print($fh chr(1) );
 557                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 558                 $content_length += 1;
 559                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 560             }
 561             else {
 562                 print($fh chr(0) );
 563                 $content_length += 1;
 564             }
 565         }
 566
 567                 ##
 568                 # If this is a new content area, advance EOF counter
 569                 ##
 570                 if ($location == $self->root->{end}) {
 571                         $self->root->{end} += SIG_SIZE;
 572                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 573                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 574                 }
 575
 576                 ##
 577                 # If content is a hash or array, create new child DeepDB object and
 578                 # pass each key or element to it.
 579                 ##
 580                 if ($r eq 'HASH') {
 581                         my $branch = DBM::Deep->new(
 582                                 type => TYPE_HASH,
 583                                 base_offset => $location,
 584                                 root => $self->root,
 585                         );
 586                         foreach my $key (keys %{$value}) {
 587                 #$branch->{$key} = $value->{$key};
 588                 $branch->STORE( $key, $value->{$key} );
 589                         }
 590                 }
 591                 elsif ($r eq 'ARRAY') {
 592                         my $branch = DBM::Deep->new(
 593                                 type => TYPE_ARRAY,
 594                                 base_offset => $location,
 595                                 root => $self->root,
 596                         );
 597                         my $index = 0;
 598                         foreach my $element (@{$value}) {
 599                 #$branch->[$index] = $element;
 600                 $branch->STORE( $index, $element );
 601                                 $index++;
 602                         }
 603                 }
 604
 605                 return $result;
 606         }
 607
 608         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 609 }
 610
 611 sub _get_bucket_value {
 612         ##
 613         # Fetch single value given tag and MD5 digested key.
 614         ##
 615         my $self = shift;
 616         my ($tag, $md5) = @_;
 617         my $keys = $tag->{content};
 618
 619     my $fh = $self->fh;
 620
 621         ##
 622         # Iterate through buckets, looking for a key match
 623         ##
 624     BUCKET:
 625         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 626                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 627                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 628
 629                 if (!$subloc) {
 630                         ##
 631                         # Hit end of list, no match
 632                         ##
 633                         return;
 634                 }
 635
 636         if ( $md5 ne $key ) {
 637             next BUCKET;
 638         }
 639
 640         ##
 641         # Found match -- seek to offset and read signature
 642         ##
 643         my $signature;
 644         seek($fh, $subloc, SEEK_SET);
 645         read( $fh, $signature, SIG_SIZE);
 646
 647         ##
 648         # If value is a hash or array, return new DeepDB object with correct offset
 649         ##
 650         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 651             my $obj = DBM::Deep->new(
 652                 type => $signature,
 653                 base_offset => $subloc,
 654                 root => $self->root
 655             );
 656
 657             if ($self->root->{autobless}) {
 658                 ##
 659                 # Skip over value and plain key to see if object needs
 660                 # to be re-blessed
 661                 ##
 662                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 663
 664                 my $size;
 665                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 666                 if ($size) { seek($fh, $size, SEEK_CUR); }
 667
 668                 my $bless_bit;
 669                 read( $fh, $bless_bit, 1);
 670                 if (ord($bless_bit)) {
 671                     ##
 672                     # Yes, object needs to be re-blessed
 673                     ##
 674                     my $class_name;
 675                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 676                     if ($size) { read( $fh, $class_name, $size); }
 677                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 678                 }
 679             }
 680
 681             return $obj;
 682         }
 683
 684         ##
 685         # Otherwise return actual value
 686         ##
 687         elsif ($signature eq SIG_DATA) {
 688             my $size;
 689             my $value = '';
 690             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 691             if ($size) { read( $fh, $value, $size); }
 692             return $value;
 693         }
 694
 695         ##
 696         # Key exists, but content is null
 697         ##
 698         else { return; }
 699         } # i loop
 700
 701         return;
 702 }
 703
 704 sub _delete_bucket {
 705         ##
 706         # Delete single key/value pair given tag and MD5 digested key.
 707         ##
 708         my $self = shift;
 709         my ($tag, $md5) = @_;
 710         my $keys = $tag->{content};
 711
 712     my $fh = $self->fh;
 713
 714         ##
 715         # Iterate through buckets, looking for a key match
 716         ##
 717     BUCKET:
 718         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 719                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 720                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 721
 722                 if (!$subloc) {
 723                         ##
 724                         # Hit end of list, no match
 725                         ##
 726                         return;
 727                 }
 728
 729         if ( $md5 ne $key ) {
 730             next BUCKET;
 731         }
 732
 733         ##
 734         # Matched key -- delete bucket and return
 735         ##
 736         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 737         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 738         print($fh chr(0) x $BUCKET_SIZE );
 739
 740         return 1;
 741         } # i loop
 742
 743         return;
 744 }
 745
 746 sub _bucket_exists {
 747         ##
 748         # Check existence of single key given tag and MD5 digested key.
 749         ##
 750         my $self = shift;
 751         my ($tag, $md5) = @_;
 752         my $keys = $tag->{content};
 753
 754         ##
 755         # Iterate through buckets, looking for a key match
 756         ##
 757     BUCKET:
 758         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 759                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 760                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 761
 762                 if (!$subloc) {
 763                         ##
 764                         # Hit end of list, no match
 765                         ##
 766                         return;
 767                 }
 768
 769         if ( $md5 ne $key ) {
 770             next BUCKET;
 771         }
 772
 773         ##
 774         # Matched key -- return true
 775         ##
 776         return 1;
 777         } # i loop
 778
 779         return;
 780 }
 781
 782 sub _find_bucket_list {
 783         ##
 784         # Locate offset for bucket list, given digested key
 785         ##
 786         my $self = shift;
 787         my $md5 = shift;
 788
 789         ##
 790         # Locate offset for bucket list using digest index system
 791         ##
 792         my $ch = 0;
 793         my $tag = $self->_load_tag($self->base_offset);
 794         if (!$tag) { return; }
 795
 796         while ($tag->{signature} ne SIG_BLIST) {
 797                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 798                 if (!$tag) { return; }
 799                 $ch++;
 800         }
 801
 802         return $tag;
 803 }
 804
 805 sub _traverse_index {
 806         ##
 807         # Scan index and recursively step into deeper levels, looking for next key.
 808         ##
 809     my ($self, $offset, $ch, $force_return_next) = @_;
 810     $force_return_next = undef unless $force_return_next;
 811
 812         my $tag = $self->_load_tag( $offset );
 813
 814     my $fh = $self->fh;
 815
 816         if ($tag->{signature} ne SIG_BLIST) {
 817                 my $content = $tag->{content};
 818                 my $start;
 819                 if ($self->{return_next}) { $start = 0; }
 820                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 821
 822                 for (my $index = $start; $index < 256; $index++) {
 823                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 824                         if ($subloc) {
 825                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 826                                 if (defined($result)) { return $result; }
 827                         }
 828                 } # index loop
 829
 830                 $self->{return_next} = 1;
 831         } # tag is an index
 832
 833         elsif ($tag->{signature} eq SIG_BLIST) {
 834                 my $keys = $tag->{content};
 835                 if ($force_return_next) { $self->{return_next} = 1; }
 836
 837                 ##
 838                 # Iterate through buckets, looking for a key match
 839                 ##
 840                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 841                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 842                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 843
 844                         if (!$subloc) {
 845                                 ##
 846                                 # End of bucket list -- return to outer loop
 847                                 ##
 848                                 $self->{return_next} = 1;
 849                                 last;
 850                         }
 851                         elsif ($key eq $self->{prev_md5}) {
 852                                 ##
 853                                 # Located previous key -- return next one found
 854                                 ##
 855                                 $self->{return_next} = 1;
 856                                 next;
 857                         }
 858                         elsif ($self->{return_next}) {
 859                                 ##
 860                                 # Seek to bucket location and skip over signature
 861                                 ##
 862                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 863
 864                                 ##
 865                                 # Skip over value to get to plain key
 866                                 ##
 867                                 my $size;
 868                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 869                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 870
 871                                 ##
 872                                 # Read in plain key and return as scalar
 873                                 ##
 874                                 my $plain_key;
 875                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 876                                 if ($size) { read( $fh, $plain_key, $size); }
 877
 878                                 return $plain_key;
 879                         }
 880                 } # bucket loop
 881
 882                 $self->{return_next} = 1;
 883         } # tag is a bucket list
 884
 885         return;
 886 }
 887
 888 sub _get_next_key {
 889         ##
 890         # Locate next key, given digested previous one
 891         ##
 892     my $self = $_[0]->_get_self;
 893
 894         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 895         $self->{return_next} = 0;
 896
 897         ##
 898         # If the previous key was not specifed, start at the top and
 899         # return the first one found.
 900         ##
 901         if (!$self->{prev_md5}) {
 902                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 903                 $self->{return_next} = 1;
 904         }
 905
 906         return $self->_traverse_index( $self->base_offset, 0 );
 907 }
 908
 909 sub lock {
 910         ##
 911         # If db locking is set, flock() the db file.  If called multiple
 912         # times before unlock(), then the same number of unlocks() must
 913         # be called before the lock is released.
 914         ##
 915     my $self = $_[0]->_get_self;
 916         my $type = $_[1];
 917     $type = LOCK_EX unless defined $type;
 918
 919         if (!defined($self->fh)) { return; }
 920
 921         if ($self->root->{locking}) {
 922                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 923                 $self->root->{locked}++;
 924
 925         return 1;
 926         }
 927
 928     return;
 929 }
 930
 931 sub unlock {
 932         ##
 933         # If db locking is set, unlock the db file.  See note in lock()
 934         # regarding calling lock() multiple times.
 935         ##
 936     my $self = $_[0]->_get_self;
 937
 938         if (!defined($self->fh)) { return; }
 939
 940         if ($self->root->{locking} && $self->root->{locked} > 0) {
 941                 $self->root->{locked}--;
 942                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 943
 944         return 1;
 945         }
 946
 947     return;
 948 }
 949
 950 #XXX These uses of ref() need verified
 951 sub _copy_node {
 952         ##
 953         # Copy single level of keys or elements to new DB handle.
 954         # Recurse for nested structures
 955         ##
 956     my $self = $_[0]->_get_self;
 957         my $db_temp = $_[1];
 958
 959         if ($self->type eq TYPE_HASH) {
 960                 my $key = $self->first_key();
 961                 while ($key) {
 962                         my $value = $self->get($key);
 963 #XXX This doesn't work with autobless
 964                         if (!ref($value)) { $db_temp->{$key} = $value; }
 965                         else {
 966                                 my $type = $value->type;
 967                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 968                                 else { $db_temp->{$key} = []; }
 969                                 $value->_copy_node( $db_temp->{$key} );
 970                         }
 971                         $key = $self->next_key($key);
 972                 }
 973         }
 974         else {
 975                 my $length = $self->length();
 976                 for (my $index = 0; $index < $length; $index++) {
 977                         my $value = $self->get($index);
 978                         if (!ref($value)) { $db_temp->[$index] = $value; }
 979             #XXX NO tests for this code
 980                         else {
 981                                 my $type = $value->type;
 982                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 983                                 else { $db_temp->[$index] = []; }
 984                                 $value->_copy_node( $db_temp->[$index] );
 985                         }
 986                 }
 987         }
 988 }
 989
 990 sub export {
 991         ##
 992         # Recursively export into standard Perl hashes and arrays.
 993         ##
 994     my $self = $_[0]->_get_self;
 995
 996         my $temp;
 997         if ($self->type eq TYPE_HASH) { $temp = {}; }
 998         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 999
1000         $self->lock();
1001         $self->_copy_node( $temp );
1002         $self->unlock();
1003
1004         return $temp;
1005 }
1006
1007 sub import {
1008         ##
1009         # Recursively import Perl hash/array structure
1010         ##
1011     #XXX This use of ref() seems to be ok
1012         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1013
1014     my $self = $_[0]->_get_self;
1015         my $struct = $_[1];
1016
1017     #XXX This use of ref() seems to be ok
1018         if (!ref($struct)) {
1019                 ##
1020                 # struct is not a reference, so just import based on our type
1021                 ##
1022                 shift @_;
1023
1024                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1025                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1026         }
1027
1028     my $r = Scalar::Util::reftype($struct) || '';
1029         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1030                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1031         }
1032         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1033                 $self->push( @$struct );
1034         }
1035         else {
1036                 return $self->_throw_error("Cannot import: type mismatch");
1037         }
1038
1039         return 1;
1040 }
1041
1042 sub optimize {
1043         ##
1044         # Rebuild entire database into new file, then move
1045         # it back on top of original.
1046         ##
1047     my $self = $_[0]->_get_self;
1048
1049 #XXX Need to create a new test for this
1050 #       if ($self->root->{links} > 1) {
1051 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1052 #       }
1053
1054         my $db_temp = DBM::Deep->new(
1055                 file => $self->root->{file} . '.tmp',
1056                 type => $self->type
1057         );
1058         if (!$db_temp) {
1059                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1060         }
1061
1062         $self->lock();
1063         $self->_copy_node( $db_temp );
1064         undef $db_temp;
1065
1066         ##
1067         # Attempt to copy user, group and permissions over to new file
1068         ##
1069         my @stats = stat($self->fh);
1070         my $perms = $stats[2] & 07777;
1071         my $uid = $stats[4];
1072         my $gid = $stats[5];
1073         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1074         chmod( $perms, $self->root->{file} . '.tmp' );
1075
1076     # q.v. perlport for more information on this variable
1077     if ( $^O eq 'MSWin32' ) {
1078                 ##
1079                 # Potential race condition when optmizing on Win32 with locking.
1080                 # The Windows filesystem requires that the filehandle be closed
1081                 # before it is overwritten with rename().  This could be redone
1082                 # with a soft copy.
1083                 ##
1084                 $self->unlock();
1085                 $self->_close();
1086         }
1087
1088         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1089                 unlink $self->root->{file} . '.tmp';
1090                 $self->unlock();
1091                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1092         }
1093
1094         $self->unlock();
1095         $self->_close();
1096         $self->_open();
1097
1098         return 1;
1099 }
1100
1101 sub clone {
1102         ##
1103         # Make copy of object and return
1104         ##
1105     my $self = $_[0]->_get_self;
1106
1107         return DBM::Deep->new(
1108                 type => $self->type,
1109                 base_offset => $self->base_offset,
1110                 root => $self->root
1111         );
1112 }
1113
1114 {
1115     my %is_legal_filter = map {
1116         $_ => ~~1,
1117     } qw(
1118         store_key store_value
1119         fetch_key fetch_value
1120     );
1121
1122     sub set_filter {
1123         ##
1124         # Setup filter function for storing or fetching the key or value
1125         ##
1126         my $self = $_[0]->_get_self;
1127         my $type = lc $_[1];
1128         my $func = $_[2] ? $_[2] : undef;
1129
1130         if ( $is_legal_filter{$type} ) {
1131             $self->root->{"filter_$type"} = $func;
1132             return 1;
1133         }
1134
1135         return;
1136     }
1137 }
1138
1139 ##
1140 # Accessor methods
1141 ##
1142
1143 sub root {
1144         ##
1145         # Get access to the root structure
1146         ##
1147     my $self = $_[0]->_get_self;
1148         return $self->{root};
1149 }
1150
1151 sub fh {
1152         ##
1153         # Get access to the raw FileHandle
1154         ##
1155     #XXX It will be useful, though, when we split out HASH and ARRAY
1156     my $self = $_[0]->_get_self;
1157         return $self->root->{fh};
1158 }
1159
1160 sub type {
1161         ##
1162         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1163         ##
1164     my $self = $_[0]->_get_self;
1165         return $self->{type};
1166 }
1167
1168 sub base_offset {
1169         ##
1170         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1171         ##
1172     my $self = $_[0]->_get_self;
1173         return $self->{base_offset};
1174 }
1175
1176 sub error {
1177         ##
1178         # Get last error string, or undef if no error
1179         ##
1180         return $_[0]
1181         #? ( _get_self($_[0])->{root}->{error} or undef )
1182         ? ( $_[0]->_get_self->{root}->{error} or undef )
1183         : $@;
1184 }
1185
1186 ##
1187 # Utility methods
1188 ##
1189
1190 sub _throw_error {
1191         ##
1192         # Store error string in self
1193         ##
1194     my $self = $_[0]->_get_self;
1195         my $error_text = $_[1];
1196
1197     if ( Scalar::Util::blessed $self ) {
1198         $self->root->{error} = $error_text;
1199
1200         unless ($self->root->{debug}) {
1201             die "DBM::Deep: $error_text\n";
1202         }
1203
1204         warn "DBM::Deep: $error_text\n";
1205         return;
1206     }
1207     else {
1208         die "DBM::Deep: $error_text\n";
1209     }
1210 }
1211
1212 sub clear_error {
1213         ##
1214         # Clear error state
1215         ##
1216     my $self = $_[0]->_get_self;
1217
1218         undef $self->root->{error};
1219 }
1220
1221 sub precalc_sizes {
1222         ##
1223         # Precalculate index, bucket and bucket list sizes
1224         ##
1225
1226     #XXX I don't like this ...
1227     set_pack() unless defined $LONG_SIZE;
1228
1229         $INDEX_SIZE = 256 * $LONG_SIZE;
1230         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1231         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1232 }
1233
1234 sub set_pack {
1235         ##
1236         # Set pack/unpack modes (see file header for more)
1237         ##
1238     my ($long_s, $long_p, $data_s, $data_p) = @_;
1239
1240     $LONG_SIZE = $long_s ? $long_s : 4;
1241     $LONG_PACK = $long_p ? $long_p : 'N';
1242
1243     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1244     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1245
1246         precalc_sizes();
1247 }
1248
1249 sub set_digest {
1250         ##
1251         # Set key digest function (default is MD5)
1252         ##
1253     my ($digest_func, $hash_size) = @_;
1254
1255     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1256     $HASH_SIZE = $hash_size ? $hash_size : 16;
1257
1258         precalc_sizes();
1259 }
1260
1261 ##
1262 # tie() methods (hashes and arrays)
1263 ##
1264
1265 sub STORE {
1266         ##
1267         # Store single hash key/value or array element in database.
1268         ##
1269     my $self = $_[0]->_get_self;
1270         my $key = $_[1];
1271
1272     #XXX What is ref() checking here?
1273     #YYY User may be storing a hash, in which case we do not want it run
1274     #YYY through the filtering system
1275         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1276         ? $self->root->{filter_store_value}->($_[2])
1277         : $_[2];
1278
1279         my $md5 = $DIGEST_FUNC->($key);
1280
1281         ##
1282         # Make sure file is open
1283         ##
1284         if (!defined($self->fh) && !$self->_open()) {
1285                 return;
1286         }
1287         ##
1288
1289     my $fh = $self->fh;
1290
1291         ##
1292         # Request exclusive lock for writing
1293         ##
1294         $self->lock( LOCK_EX );
1295
1296         ##
1297         # If locking is enabled, set 'end' parameter again, in case another
1298         # DB instance appended to our file while we were unlocked.
1299         ##
1300         if ($self->root->{locking} || $self->root->{volatile}) {
1301                 $self->root->{end} = (stat($fh))[7];
1302         }
1303
1304         ##
1305         # Locate offset for bucket list using digest index system
1306         ##
1307         my $tag = $self->_load_tag($self->base_offset);
1308         if (!$tag) {
1309                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1310         }
1311
1312         my $ch = 0;
1313         while ($tag->{signature} ne SIG_BLIST) {
1314                 my $num = ord(substr($md5, $ch, 1));
1315                 my $new_tag = $self->_index_lookup($tag, $num);
1316                 if (!$new_tag) {
1317                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1318                         seek($fh, $ref_loc, SEEK_SET);
1319                         print($fh pack($LONG_PACK, $self->root->{end}) );
1320
1321                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1322                         $tag->{ref_loc} = $ref_loc;
1323                         $tag->{ch} = $ch;
1324                         last;
1325                 }
1326                 else {
1327                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1328                         $tag = $new_tag;
1329                         $tag->{ref_loc} = $ref_loc;
1330                         $tag->{ch} = $ch;
1331                 }
1332                 $ch++;
1333         }
1334
1335         ##
1336         # Add key/value to bucket list
1337         ##
1338         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1339
1340         $self->unlock();
1341
1342         return $result;
1343 }
1344
1345 sub FETCH {
1346         ##
1347         # Fetch single value or element given plain key or array index
1348         ##
1349     my $self = shift->_get_self;
1350     my $key = shift;
1351
1352         ##
1353         # Make sure file is open
1354         ##
1355         if (!defined($self->fh)) { $self->_open(); }
1356
1357         my $md5 = $DIGEST_FUNC->($key);
1358
1359         ##
1360         # Request shared lock for reading
1361         ##
1362         $self->lock( LOCK_SH );
1363
1364         my $tag = $self->_find_bucket_list( $md5 );
1365         if (!$tag) {
1366                 $self->unlock();
1367                 return;
1368         }
1369
1370         ##
1371         # Get value from bucket list
1372         ##
1373         my $result = $self->_get_bucket_value( $tag, $md5 );
1374
1375         $self->unlock();
1376
1377     #XXX What is ref() checking here?
1378         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1379         ? $self->root->{filter_fetch_value}->($result)
1380         : $result;
1381 }
1382
1383 sub DELETE {
1384         ##
1385         # Delete single key/value pair or element given plain key or array index
1386         ##
1387     my $self = $_[0]->_get_self;
1388         my $key = $_[1];
1389
1390         my $unpacked_key = $key;
1391         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1392         my $md5 = $DIGEST_FUNC->($key);
1393
1394         ##
1395         # Make sure file is open
1396         ##
1397         if (!defined($self->fh)) { $self->_open(); }
1398
1399         ##
1400         # Request exclusive lock for writing
1401         ##
1402         $self->lock( LOCK_EX );
1403
1404         my $tag = $self->_find_bucket_list( $md5 );
1405         if (!$tag) {
1406                 $self->unlock();
1407                 return;
1408         }
1409
1410         ##
1411         # Delete bucket
1412         ##
1413     my $value = $self->FETCH( $unpacked_key );
1414         my $result = $self->_delete_bucket( $tag, $md5 );
1415
1416         ##
1417         # If this object is an array and the key deleted was on the end of the stack,
1418         # decrement the length variable.
1419         ##
1420         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1421                 $self->STORESIZE( $unpacked_key );
1422         }
1423
1424         $self->unlock();
1425
1426         return $value;
1427 }
1428
1429 sub EXISTS {
1430         ##
1431         # Check if a single key or element exists given plain key or array index
1432         ##
1433     my $self = $_[0]->_get_self;
1434         my $key = $_[1];
1435
1436         my $md5 = $DIGEST_FUNC->($key);
1437
1438         ##
1439         # Make sure file is open
1440         ##
1441         if (!defined($self->fh)) { $self->_open(); }
1442
1443         ##
1444         # Request shared lock for reading
1445         ##
1446         $self->lock( LOCK_SH );
1447
1448         my $tag = $self->_find_bucket_list( $md5 );
1449
1450         ##
1451         # For some reason, the built-in exists() function returns '' for false
1452         ##
1453         if (!$tag) {
1454                 $self->unlock();
1455                 return '';
1456         }
1457
1458         ##
1459         # Check if bucket exists and return 1 or ''
1460         ##
1461         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1462
1463         $self->unlock();
1464
1465         return $result;
1466 }
1467
1468 sub CLEAR {
1469         ##
1470         # Clear all keys from hash, or all elements from array.
1471         ##
1472     my $self = $_[0]->_get_self;
1473
1474         ##
1475         # Make sure file is open
1476         ##
1477         if (!defined($self->fh)) { $self->_open(); }
1478
1479         ##
1480         # Request exclusive lock for writing
1481         ##
1482         $self->lock( LOCK_EX );
1483
1484     my $fh = $self->fh;
1485
1486         seek($fh, $self->base_offset, SEEK_SET);
1487         if (eof $fh) {
1488                 $self->unlock();
1489                 return;
1490         }
1491
1492         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1493
1494         $self->unlock();
1495
1496         return 1;
1497 }
1498
1499 ##
1500 # Public method aliases
1501 ##
1502 sub put { (shift)->STORE( @_ ) }
1503 sub store { (shift)->STORE( @_ ) }
1504 sub get { (shift)->FETCH( @_ ) }
1505 sub fetch { (shift)->FETCH( @_ ) }
1506 sub delete { (shift)->DELETE( @_ ) }
1507 sub exists { (shift)->EXISTS( @_ ) }
1508 sub clear { (shift)->CLEAR( @_ ) }
1509
1510 package DBM::Deep::_::Root;
1511
1512 sub new {
1513     my $class = shift;
1514     my ($args) = @_;
1515
1516     my $self = bless {
1517         file => undef,
1518         fh => undef,
1519         end => 0,
1520         autoflush => undef,
1521         locking => undef,
1522         volatile => undef,
1523         debug => undef,
1524         mode => 'r+',
1525         filter_store_key => undef,
1526         filter_store_value => undef,
1527         filter_fetch_key => undef,
1528         filter_fetch_value => undef,
1529         autobless => undef,
1530         locked => 0,
1531         %$args,
1532     }, $class;
1533
1534     return $self;
1535 }
1536
1537 sub DESTROY {
1538     my $self = shift;
1539     return unless $self;
1540
1541     close $self->{fh} if $self->{fh};
1542
1543     return;
1544 }
1545
1546 1;
1547
1548 __END__
1549
1550 =head1 NAME
1551
1552 DBM::Deep - A pure perl multi-level hash/array DBM
1553
1554 =head1 SYNOPSIS
1555
1556   use DBM::Deep;
1557   my $db = DBM::Deep->new( "foo.db" );
1558
1559   $db->{key} = 'value'; # tie() style
1560   print $db->{key};
1561
1562   $db->put('key', 'value'); # OO style
1563   print $db->get('key');
1564
1565   # true multi-level support
1566   $db->{my_complex} = [
1567         'hello', { perl => 'rules' },
1568         42, 99 ];
1569
1570 =head1 DESCRIPTION
1571
1572 A unique flat-file database module, written in pure perl.  True
1573 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1574 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1575 handle millions of keys and unlimited hash levels without significant
1576 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1577 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1578 Mac OS X and Windows.
1579
1580 =head1 INSTALLATION
1581
1582 Hopefully you are using CPAN's excellent Perl module, which will download
1583 and install the module for you.  If not, get the tarball, and run these
1584 commands:
1585
1586         tar zxf DBM-Deep-*
1587         cd DBM-Deep-*
1588         perl Makefile.PL
1589         make
1590         make test
1591         make install
1592
1593 =head1 SETUP
1594
1595 Construction can be done OO-style (which is the recommended way), or using
1596 Perl's tie() function.  Both are examined here.
1597
1598 =head2 OO CONSTRUCTION
1599
1600 The recommended way to construct a DBM::Deep object is to use the new()
1601 method, which gets you a blessed, tied hash or array reference.
1602
1603         my $db = DBM::Deep->new( "foo.db" );
1604
1605 This opens a new database handle, mapped to the file "foo.db".  If this
1606 file does not exist, it will automatically be created.  DB files are
1607 opened in "r+" (read/write) mode, and the type of object returned is a
1608 hash, unless otherwise specified (see L<OPTIONS> below).
1609
1610
1611
1612 You can pass a number of options to the constructor to specify things like
1613 locking, autoflush, etc.  This is done by passing an inline hash:
1614
1615         my $db = DBM::Deep->new(
1616                 file => "foo.db",
1617                 locking => 1,
1618                 autoflush => 1
1619         );
1620
1621 Notice that the filename is now specified I<inside> the hash with
1622 the "file" parameter, as opposed to being the sole argument to the
1623 constructor.  This is required if any options are specified.
1624 See L<OPTIONS> below for the complete list.
1625
1626
1627
1628 You can also start with an array instead of a hash.  For this, you must
1629 specify the C<type> parameter:
1630
1631         my $db = DBM::Deep->new(
1632                 file => "foo.db",
1633                 type => DBM::Deep->TYPE_ARRAY
1634         );
1635
1636 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1637 a new DB file.  If you create a DBM::Deep object with an existing file, the
1638 C<type> will be loaded from the file header, and ignored if it is passed
1639 to the constructor.
1640
1641 =head2 TIE CONSTRUCTION
1642
1643 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1644 tie() function.  This is not ideal, because you get only a basic, tied hash
1645 (or array) which is not blessed, so you can't call any functions on it.
1646
1647         my %hash;
1648         tie %hash, "DBM::Deep", "foo.db";
1649
1650         my @array;
1651         tie @array, "DBM::Deep", "bar.db";
1652
1653 As with the OO constructor, you can replace the DB filename parameter with
1654 a hash containing one or more options (see L<OPTIONS> just below for the
1655 complete list).
1656
1657         tie %hash, "DBM::Deep", {
1658                 file => "foo.db",
1659                 locking => 1,
1660                 autoflush => 1
1661         };
1662
1663 =head2 OPTIONS
1664
1665 There are a number of options that can be passed in when constructing your
1666 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1667
1668 =over
1669
1670 =item * file
1671
1672 Filename of the DB file to link the handle to.  You can pass a full absolute
1673 filesystem path, partial path, or a plain filename if the file is in the
1674 current working directory.  This is a required parameter.
1675
1676 =item * mode
1677
1678 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1679 module.  This is an optional parameter, and defaults to "r+" (read/write).
1680 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1681 created if it doesn't exist.
1682
1683 =item * type
1684
1685 This parameter specifies what type of object to create, a hash or array.  Use
1686 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1687 This only takes effect when beginning a new file.  This is an optional
1688 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1689
1690 =item * locking
1691
1692 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1693 function to lock the database in exclusive mode for writes, and shared mode for
1694 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1695 any child hashes or arrays> that use the same DB file.  This is an optional
1696 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1697
1698 =item * autoflush
1699
1700 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1701 This obviously slows down write operations, but is required if you may have
1702 multiple processes accessing the same DB file (also consider enable I<locking>
1703 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1704 parameter, and defaults to 0 (disabled).
1705
1706 =item * volatile
1707
1708 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1709 STORE() operation.  This is required if an outside force may change the size of
1710 the file between transactions.  Locking also implicitly enables volatile.  This
1711 is useful if you want to use a different locking system or write your own.  Pass
1712 any true value to enable.  This is an optional parameter, and defaults to 0
1713 (disabled).
1714
1715 =item * autobless
1716
1717 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1718 restore them when fetched.  This is an B<experimental> feature, and does have
1719 side-effects.  Basically, when hashes are re-blessed into their original
1720 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1721 able to call any DBM::Deep methods on them.  You have been warned.
1722 This is an optional parameter, and defaults to 0 (disabled).
1723
1724 =item * filter_*
1725
1726 See L<FILTERS> below.
1727
1728 =item * debug
1729
1730 Setting I<debug> mode will make all errors non-fatal, dump them out to
1731 STDERR, and continue on.  This is for debugging purposes only, and probably
1732 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1733
1734 =item * fh
1735
1736 Instead of passing a file path, you can instead pass a handle to an pre-opened
1737 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1738 contains your entire Perl script, as well as the data following the __DATA__
1739 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1740 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1741 in that.
1742
1743 =back
1744
1745 =head1 TIE INTERFACE
1746
1747 With DBM::Deep you can access your databases using Perl's standard hash/array
1748 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1749 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1750 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1751 section above.  This simply tells you how to use DBM::Deep using regular hashes
1752 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1753 work too).  It is entirely up to you how to want to access your databases.
1754
1755 =head2 HASHES
1756
1757 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1758 or even nested hashes (or arrays) using standard Perl syntax:
1759
1760         my $db = DBM::Deep->new( "foo.db" );
1761
1762         $db->{mykey} = "myvalue";
1763         $db->{myhash} = {};
1764         $db->{myhash}->{subkey} = "subvalue";
1765
1766         print $db->{myhash}->{subkey} . "\n";
1767
1768 You can even step through hash keys using the normal Perl C<keys()> function:
1769
1770         foreach my $key (keys %$db) {
1771                 print "$key: " . $db->{$key} . "\n";
1772         }
1773
1774 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1775 pushes them onto an array, all before the loop even begins.  If you have an
1776 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1777 Perl's C<each()> function, which pulls keys/values one at a time, using very
1778 little memory:
1779
1780         while (my ($key, $value) = each %$db) {
1781                 print "$key: $value\n";
1782         }
1783
1784 Please note that when using C<each()>, you should always pass a direct
1785 hash reference, not a lookup.  Meaning, you should B<never> do this:
1786
1787         # NEVER DO THIS
1788         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1789
1790 This causes an infinite loop, because for each iteration, Perl is calling
1791 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1792 it effectively keeps returning the first key over and over again. Instead,
1793 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1794
1795 =head2 ARRAYS
1796
1797 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1798 reference.  This includes inserting, removing and manipulating elements,
1799 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1800 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1801 or simply be a nested array reference inside a hash.  Example:
1802
1803         my $db = DBM::Deep->new(
1804                 file => "foo-array.db",
1805                 type => DBM::Deep->TYPE_ARRAY
1806         );
1807
1808         $db->[0] = "foo";
1809         push @$db, "bar", "baz";
1810         unshift @$db, "bah";
1811
1812         my $last_elem = pop @$db; # baz
1813         my $first_elem = shift @$db; # bah
1814         my $second_elem = $db->[1]; # bar
1815
1816         my $num_elements = scalar @$db;
1817
1818 =head1 OO INTERFACE
1819
1820 In addition to the I<tie()> interface, you can also use a standard OO interface
1821 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1822 array) has its own methods, but both types share the following common methods:
1823 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1824
1825 =over
1826
1827 =item * put()
1828
1829 Stores a new hash key/value pair, or sets an array element value.  Takes two
1830 arguments, the hash key or array index, and the new value.  The value can be
1831 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1832
1833         $db->put("foo", "bar"); # for hashes
1834         $db->put(1, "bar"); # for arrays
1835
1836 =item * get()
1837
1838 Fetches the value of a hash key or array element.  Takes one argument: the hash
1839 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1840 data type stored.
1841
1842         my $value = $db->get("foo"); # for hashes
1843         my $value = $db->get(1); # for arrays
1844
1845 =item * exists()
1846
1847 Checks if a hash key or array index exists.  Takes one argument: the hash key
1848 or array index.  Returns true if it exists, false if not.
1849
1850         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1851         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1852
1853 =item * delete()
1854
1855 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1856 key or array index.  Returns true on success, false if not found.  For arrays,
1857 the remaining elements located after the deleted element are NOT moved over.
1858 The deleted element is essentially just undefined, which is exactly how Perl's
1859 internal arrays work.  Please note that the space occupied by the deleted
1860 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1861 below for details and workarounds.
1862
1863         $db->delete("foo"); # for hashes
1864         $db->delete(1); # for arrays
1865
1866 =item * clear()
1867
1868 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1869 value.  Please note that the space occupied by the deleted keys/values or
1870 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1871 details and workarounds.
1872
1873         $db->clear(); # hashes or arrays
1874
1875 =back
1876
1877 =head2 HASHES
1878
1879 For hashes, DBM::Deep supports all the common methods described above, and the
1880 following additional methods: C<first_key()> and C<next_key()>.
1881
1882 =over
1883
1884 =item * first_key()
1885
1886 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1887 fetched in an undefined order (which appears random).  Takes no arguments,
1888 returns the key as a scalar value.
1889
1890         my $key = $db->first_key();
1891
1892 =item * next_key()
1893
1894 Returns the "next" key in the hash, given the previous one as the sole argument.
1895 Returns undef if there are no more keys to be fetched.
1896
1897         $key = $db->next_key($key);
1898
1899 =back
1900
1901 Here are some examples of using hashes:
1902
1903         my $db = DBM::Deep->new( "foo.db" );
1904
1905         $db->put("foo", "bar");
1906         print "foo: " . $db->get("foo") . "\n";
1907
1908         $db->put("baz", {}); # new child hash ref
1909         $db->get("baz")->put("buz", "biz");
1910         print "buz: " . $db->get("baz")->get("buz") . "\n";
1911
1912         my $key = $db->first_key();
1913         while ($key) {
1914                 print "$key: " . $db->get($key) . "\n";
1915                 $key = $db->next_key($key);
1916         }
1917
1918         if ($db->exists("foo")) { $db->delete("foo"); }
1919
1920 =head2 ARRAYS
1921
1922 For arrays, DBM::Deep supports all the common methods described above, and the
1923 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1924 C<unshift()> and C<splice()>.
1925
1926 =over
1927
1928 =item * length()
1929
1930 Returns the number of elements in the array.  Takes no arguments.
1931
1932         my $len = $db->length();
1933
1934 =item * push()
1935
1936 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1937 refs or array refs.  No return value.
1938
1939         $db->push("foo", "bar", {});
1940
1941 =item * pop()
1942
1943 Fetches the last element in the array, and deletes it.  Takes no arguments.
1944 Returns undef if array is empty.  Returns the element value.
1945
1946         my $elem = $db->pop();
1947
1948 =item * shift()
1949
1950 Fetches the first element in the array, deletes it, then shifts all the
1951 remaining elements over to take up the space.  Returns the element value.  This
1952 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1953 details.
1954
1955         my $elem = $db->shift();
1956
1957 =item * unshift()
1958
1959 Inserts one or more elements onto the beginning of the array, shifting all
1960 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1961 No return value.  This method is not recommended with large arrays -- see
1962 <LARGE ARRAYS> below for details.
1963
1964         $db->unshift("foo", "bar", {});
1965
1966 =item * splice()
1967
1968 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1969 -f splice> for usage -- it is too complicated to document here.  This method is
1970 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1971
1972 =back
1973
1974 Here are some examples of using arrays:
1975
1976         my $db = DBM::Deep->new(
1977                 file => "foo.db",
1978                 type => DBM::Deep->TYPE_ARRAY
1979         );
1980
1981         $db->push("bar", "baz");
1982         $db->unshift("foo");
1983         $db->put(3, "buz");
1984
1985         my $len = $db->length();
1986         print "length: $len\n"; # 4
1987
1988         for (my $k=0; $k<$len; $k++) {
1989                 print "$k: " . $db->get($k) . "\n";
1990         }
1991
1992         $db->splice(1, 2, "biz", "baf");
1993
1994         while (my $elem = shift @$db) {
1995                 print "shifted: $elem\n";
1996         }
1997
1998 =head1 LOCKING
1999
2000 Enable automatic file locking by passing a true value to the C<locking>
2001 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2002
2003         my $db = DBM::Deep->new(
2004                 file => "foo.db",
2005                 locking => 1
2006         );
2007
2008 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2009 mode for writes, and shared mode for reads.  This is required if you have
2010 multiple processes accessing the same database file, to avoid file corruption.
2011 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2012 NFS> below for more.
2013
2014 =head2 EXPLICIT LOCKING
2015
2016 You can explicitly lock a database, so it remains locked for multiple
2017 transactions.  This is done by calling the C<lock()> method, and passing an
2018 optional lock mode argument (defaults to exclusive mode).  This is particularly
2019 useful for things like counters, where the current value needs to be fetched,
2020 then incremented, then stored again.
2021
2022         $db->lock();
2023         my $counter = $db->get("counter");
2024         $counter++;
2025         $db->put("counter", $counter);
2026         $db->unlock();
2027
2028         # or...
2029
2030         $db->lock();
2031         $db->{counter}++;
2032         $db->unlock();
2033
2034 You can pass C<lock()> an optional argument, which specifies which mode to use
2035 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2036 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2037 same as the constants defined in Perl's C<Fcntl> module.
2038
2039         $db->lock( DBM::Deep->LOCK_SH );
2040         # something here
2041         $db->unlock();
2042
2043 If you want to implement your own file locking scheme, be sure to create your
2044 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2045 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2046 below for more.
2047
2048 =head1 IMPORTING/EXPORTING
2049
2050 You can import existing complex structures by calling the C<import()> method,
2051 and export an entire database into an in-memory structure using the C<export()>
2052 method.  Both are examined here.
2053
2054 =head2 IMPORTING
2055
2056 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2057 walking the structure and adding keys/elements to the database as you go,
2058 simply pass a reference to the C<import()> method.  This recursively adds
2059 everything to an existing DBM::Deep object for you.  Here is an example:
2060
2061         my $struct = {
2062                 key1 => "value1",
2063                 key2 => "value2",
2064                 array1 => [ "elem0", "elem1", "elem2" ],
2065                 hash1 => {
2066                         subkey1 => "subvalue1",
2067                         subkey2 => "subvalue2"
2068                 }
2069         };
2070
2071         my $db = DBM::Deep->new( "foo.db" );
2072         $db->import( $struct );
2073
2074         print $db->{key1} . "\n"; # prints "value1"
2075
2076 This recursively imports the entire C<$struct> object into C<$db>, including
2077 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2078 keys are merged with the existing ones, replacing if they already exist.
2079 The C<import()> method can be called on any database level (not just the base
2080 level), and works with both hash and array DB types.
2081
2082
2083
2084 B<Note:> Make sure your existing structure has no circular references in it.
2085 These will cause an infinite loop when importing.
2086
2087 =head2 EXPORTING
2088
2089 Calling the C<export()> method on an existing DBM::Deep object will return
2090 a reference to a new in-memory copy of the database.  The export is done
2091 recursively, so all nested hashes/arrays are all exported to standard Perl
2092 objects.  Here is an example:
2093
2094         my $db = DBM::Deep->new( "foo.db" );
2095
2096         $db->{key1} = "value1";
2097         $db->{key2} = "value2";
2098         $db->{hash1} = {};
2099         $db->{hash1}->{subkey1} = "subvalue1";
2100         $db->{hash1}->{subkey2} = "subvalue2";
2101
2102         my $struct = $db->export();
2103
2104         print $struct->{key1} . "\n"; # prints "value1"
2105
2106 This makes a complete copy of the database in memory, and returns a reference
2107 to it.  The C<export()> method can be called on any database level (not just
2108 the base level), and works with both hash and array DB types.  Be careful of
2109 large databases -- you can store a lot more data in a DBM::Deep object than an
2110 in-memory Perl structure.
2111
2112
2113
2114 B<Note:> Make sure your database has no circular references in it.
2115 These will cause an infinite loop when exporting.
2116
2117 =head1 FILTERS
2118
2119 DBM::Deep has a number of hooks where you can specify your own Perl function
2120 to perform filtering on incoming or outgoing data.  This is a perfect
2121 way to extend the engine, and implement things like real-time compression or
2122 encryption.  Filtering applies to the base DB level, and all child hashes /
2123 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2124 constructed, or by calling the C<set_filter()> method at any time.  There are
2125 four available filter hooks, described below:
2126
2127 =over
2128
2129 =item * filter_store_key
2130
2131 This filter is called whenever a hash key is stored.  It
2132 is passed the incoming key, and expected to return a transformed key.
2133
2134 =item * filter_store_value
2135
2136 This filter is called whenever a hash key or array element is stored.  It
2137 is passed the incoming value, and expected to return a transformed value.
2138
2139 =item * filter_fetch_key
2140
2141 This filter is called whenever a hash key is fetched (i.e. via
2142 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2143 and expected to return the plain key.
2144
2145 =item * filter_fetch_value
2146
2147 This filter is called whenever a hash key or array element is fetched.
2148 It is passed the transformed value, and expected to return the plain value.
2149
2150 =back
2151
2152 Here are the two ways to setup a filter hook:
2153
2154         my $db = DBM::Deep->new(
2155                 file => "foo.db",
2156                 filter_store_value => \&my_filter_store,
2157                 filter_fetch_value => \&my_filter_fetch
2158         );
2159
2160         # or...
2161
2162         $db->set_filter( "filter_store_value", \&my_filter_store );
2163         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2164
2165 Your filter function will be called only when dealing with SCALAR keys or
2166 values.  When nested hashes and arrays are being stored/fetched, filtering
2167 is bypassed.  Filters are called as static functions, passed a single SCALAR
2168 argument, and expected to return a single SCALAR value.  If you want to
2169 remove a filter, set the function reference to C<undef>:
2170
2171         $db->set_filter( "filter_store_value", undef );
2172
2173 =head2 REAL-TIME ENCRYPTION EXAMPLE
2174
2175 Here is a working example that uses the I<Crypt::Blowfish> module to
2176 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2177 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2178 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2179
2180         use DBM::Deep;
2181         use Crypt::Blowfish;
2182         use Crypt::CBC;
2183
2184         my $cipher = Crypt::CBC->new({
2185                 'key'             => 'my secret key',
2186                 'cipher'          => 'Blowfish',
2187                 'iv'              => '$KJh#(}q',
2188                 'regenerate_key'  => 0,
2189                 'padding'         => 'space',
2190                 'prepend_iv'      => 0
2191         });
2192
2193         my $db = DBM::Deep->new(
2194                 file => "foo-encrypt.db",
2195                 filter_store_key => \&my_encrypt,
2196                 filter_store_value => \&my_encrypt,
2197                 filter_fetch_key => \&my_decrypt,
2198                 filter_fetch_value => \&my_decrypt,
2199         );
2200
2201         $db->{key1} = "value1";
2202         $db->{key2} = "value2";
2203         print "key1: " . $db->{key1} . "\n";
2204         print "key2: " . $db->{key2} . "\n";
2205
2206         undef $db;
2207         exit;
2208
2209         sub my_encrypt {
2210                 return $cipher->encrypt( $_[0] );
2211         }
2212         sub my_decrypt {
2213                 return $cipher->decrypt( $_[0] );
2214         }
2215
2216 =head2 REAL-TIME COMPRESSION EXAMPLE
2217
2218 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2219 compression / decompression of keys & values with DBM::Deep Filters.
2220 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2221 more on I<Compress::Zlib>.
2222
2223         use DBM::Deep;
2224         use Compress::Zlib;
2225
2226         my $db = DBM::Deep->new(
2227                 file => "foo-compress.db",
2228                 filter_store_key => \&my_compress,
2229                 filter_store_value => \&my_compress,
2230                 filter_fetch_key => \&my_decompress,
2231                 filter_fetch_value => \&my_decompress,
2232         );
2233
2234         $db->{key1} = "value1";
2235         $db->{key2} = "value2";
2236         print "key1: " . $db->{key1} . "\n";
2237         print "key2: " . $db->{key2} . "\n";
2238
2239         undef $db;
2240         exit;
2241
2242         sub my_compress {
2243                 return Compress::Zlib::memGzip( $_[0] ) ;
2244         }
2245         sub my_decompress {
2246                 return Compress::Zlib::memGunzip( $_[0] ) ;
2247         }
2248
2249 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2250 actually numerical index numbers, and are not filtered.
2251
2252 =head1 ERROR HANDLING
2253
2254 Most DBM::Deep methods return a true value for success, and call die() on
2255 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2256 actual error message is stored in an internal scalar, which can be fetched by
2257 calling the C<error()> method.
2258
2259         my $db = DBM::Deep->new( "foo.db" ); # create hash
2260         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2261
2262         print $db->error(); # prints error message
2263
2264 You can then call C<clear_error()> to clear the current error state.
2265
2266         $db->clear_error();
2267
2268 If you set the C<debug> option to true when creating your DBM::Deep object,
2269 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2270 for debugging purposes.
2271
2272 =head1 LARGEFILE SUPPORT
2273
2274 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2275 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2276 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2277 by calling the static C<set_pack()> method before you do anything else.
2278
2279         DBM::Deep::set_pack(8, 'Q');
2280
2281 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2282 instead of 32-bit longs.  After setting these values your DB files have a
2283 theoretical maximum size of 16 XB (exabytes).
2284
2285
2286
2287 B<Note:> Changing these values will B<NOT> work for existing database files.
2288 Only change this for new files, and make sure it stays set consistently
2289 throughout the file's life.  If you do set these values, you can no longer
2290 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2291 back to 32-bit mode.
2292
2293
2294
2295 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2296 only a 32-bit Perl.  However, I have received user reports that this does
2297 indeed work!
2298
2299 =head1 LOW-LEVEL ACCESS
2300
2301 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2302 you can call the C<fh()> method, which returns the handle:
2303
2304         my $fh = $db->fh();
2305
2306 This method can be called on the root level of the datbase, or any child
2307 hashes or arrays.  All levels share a I<root> structure, which contains things
2308 like the FileHandle, a reference counter, and all your options you specified
2309 when you created the object.  You can get access to this root structure by
2310 calling the C<root()> method.
2311
2312         my $root = $db->root();
2313
2314 This is useful for changing options after the object has already been created,
2315 such as enabling/disabling locking, volatile or debug modes.  You can also
2316 store your own temporary user data in this structure (be wary of name
2317 collision), which is then accessible from any child hash or array.
2318
2319 =head1 CUSTOM DIGEST ALGORITHM
2320
2321 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2322 keys.  However you can override this, and use another algorithm (such as SHA-256)
2323 or even write your own.  But please note that DBM::Deep currently expects zero
2324 collisions, so your algorithm has to be I<perfect>, so to speak.
2325 Collision detection may be introduced in a later version.
2326
2327
2328
2329 You can specify a custom digest algorithm by calling the static C<set_digest()>
2330 function, passing a reference to a subroutine, and the length of the algorithm's
2331 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2332 objects.  Here is a working example that uses a 256-bit hash from the
2333 I<Digest::SHA256> module.  Please see
2334 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2335
2336         use DBM::Deep;
2337         use Digest::SHA256;
2338
2339         my $context = Digest::SHA256::new(256);
2340
2341         DBM::Deep::set_digest( \&my_digest, 32 );
2342
2343         my $db = DBM::Deep->new( "foo-sha.db" );
2344
2345         $db->{key1} = "value1";
2346         $db->{key2} = "value2";
2347         print "key1: " . $db->{key1} . "\n";
2348         print "key2: " . $db->{key2} . "\n";
2349
2350         undef $db;
2351         exit;
2352
2353         sub my_digest {
2354                 return substr( $context->hash($_[0]), 0, 32 );
2355         }
2356
2357 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2358 of bytes you specify in the C<set_digest()> function (in this case 32).
2359
2360 =head1 CIRCULAR REFERENCES
2361
2362 DBM::Deep has B<experimental> support for circular references.  Meaning you
2363 can have a nested hash key or array element that points to a parent object.
2364 This relationship is stored in the DB file, and is preserved between sessions.
2365 Here is an example:
2366
2367         my $db = DBM::Deep->new( "foo.db" );
2368
2369         $db->{foo} = "bar";
2370         $db->{circle} = $db; # ref to self
2371
2372         print $db->{foo} . "\n"; # prints "foo"
2373         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2374
2375 One catch is, passing the object to a function that recursively walks the
2376 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2377 C<export()> methods) will result in an infinite loop.  The other catch is,
2378 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2379 or C<next_key()> methods), you will get the I<target object's key>, not the
2380 ref's key.  This gets even more interesting with the above example, where
2381 the I<circle> key points to the base DB object, which technically doesn't
2382 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2383 special case.
2384
2385 =head1 CAVEATS / ISSUES / BUGS
2386
2387 This section describes all the known issues with DBM::Deep.  It you have found
2388 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2389
2390 =head2 UNUSED SPACE RECOVERY
2391
2392 One major caveat with DBM::Deep is that space occupied by existing keys and
2393 values is not recovered when they are deleted.  Meaning if you keep deleting
2394 and adding new keys, your file will continuously grow.  I am working on this,
2395 but in the meantime you can call the built-in C<optimize()> method from time to
2396 time (perhaps in a crontab or something) to recover all your unused space.
2397
2398         $db->optimize(); # returns true on success
2399
2400 This rebuilds the ENTIRE database into a new file, then moves it on top of
2401 the original.  The new file will have no unused space, thus it will take up as
2402 little disk space as possible.  Please note that this operation can take
2403 a long time for large files, and you need enough disk space to temporarily hold
2404 2 copies of your DB file.  The temporary file is created in the same directory
2405 as the original, named with a ".tmp" extension, and is deleted when the
2406 operation completes.  Oh, and if locking is enabled, the DB is automatically
2407 locked for the entire duration of the copy.
2408
2409
2410
2411 B<WARNING:> Only call optimize() on the top-level node of the database, and
2412 make sure there are no child references lying around.  DBM::Deep keeps a reference
2413 counter, and if it is greater than 1, optimize() will abort and return undef.
2414
2415 =head2 AUTOVIVIFICATION
2416
2417 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2418 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2419 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2420 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2421 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2422 this does not work:
2423
2424         $db->{foo}->{bar} = "hello";
2425
2426 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2427 being an empty hash.  Try this instead, which works fine:
2428
2429         $db->{foo} = { bar => "hello" };
2430
2431 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2432 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2433 Probably a bug in Perl.
2434
2435 =head2 FILE CORRUPTION
2436
2437 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2438 for a 32-bit signature when opened, but other corruption in files can cause
2439 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2440 stuck in an infinite loop depending on the level of corruption.  File write
2441 operations are not checked for failure (for speed), so if you happen to run
2442 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2443 be addressed in a later version of DBM::Deep.
2444
2445 =head2 DB OVER NFS
2446
2447 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2448 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2449 about setting up your NFS server with a locking daemon, then using lockf() to
2450 lock your files, but your milage may vary there as well.  From what I
2451 understand, there is no real way to do it.  However, if you need access to the
2452 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2453 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2454
2455 =head2 COPYING OBJECTS
2456
2457 Beware of copying tied objects in Perl.  Very strange things can happen.
2458 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2459 returns a new, blessed, tied hash or array to the same level in the DB.
2460
2461         my $copy = $db->clone();
2462
2463 =head2 LARGE ARRAYS
2464
2465 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2466 These functions cause every element in the array to move, which can be murder
2467 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2468 a different location.  This may be addressed in a later version.
2469
2470 =head1 PERFORMANCE
2471
2472 This section discusses DBM::Deep's speed and memory usage.
2473
2474 =head2 SPEED
2475
2476 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2477 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2478 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2479 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2480 with huge databases.  Here is some test data:
2481
2482         Adding 1,000,000 keys to new DB file...
2483
2484         At 100 keys, avg. speed is 2,703 keys/sec
2485         At 200 keys, avg. speed is 2,642 keys/sec
2486         At 300 keys, avg. speed is 2,598 keys/sec
2487         At 400 keys, avg. speed is 2,578 keys/sec
2488         At 500 keys, avg. speed is 2,722 keys/sec
2489         At 600 keys, avg. speed is 2,628 keys/sec
2490         At 700 keys, avg. speed is 2,700 keys/sec
2491         At 800 keys, avg. speed is 2,607 keys/sec
2492         At 900 keys, avg. speed is 2,190 keys/sec
2493         At 1,000 keys, avg. speed is 2,570 keys/sec
2494         At 2,000 keys, avg. speed is 2,417 keys/sec
2495         At 3,000 keys, avg. speed is 1,982 keys/sec
2496         At 4,000 keys, avg. speed is 1,568 keys/sec
2497         At 5,000 keys, avg. speed is 1,533 keys/sec
2498         At 6,000 keys, avg. speed is 1,787 keys/sec
2499         At 7,000 keys, avg. speed is 1,977 keys/sec
2500         At 8,000 keys, avg. speed is 2,028 keys/sec
2501         At 9,000 keys, avg. speed is 2,077 keys/sec
2502         At 10,000 keys, avg. speed is 2,031 keys/sec
2503         At 20,000 keys, avg. speed is 1,970 keys/sec
2504         At 30,000 keys, avg. speed is 2,050 keys/sec
2505         At 40,000 keys, avg. speed is 2,073 keys/sec
2506         At 50,000 keys, avg. speed is 1,973 keys/sec
2507         At 60,000 keys, avg. speed is 1,914 keys/sec
2508         At 70,000 keys, avg. speed is 2,091 keys/sec
2509         At 80,000 keys, avg. speed is 2,103 keys/sec
2510         At 90,000 keys, avg. speed is 1,886 keys/sec
2511         At 100,000 keys, avg. speed is 1,970 keys/sec
2512         At 200,000 keys, avg. speed is 2,053 keys/sec
2513         At 300,000 keys, avg. speed is 1,697 keys/sec
2514         At 400,000 keys, avg. speed is 1,838 keys/sec
2515         At 500,000 keys, avg. speed is 1,941 keys/sec
2516         At 600,000 keys, avg. speed is 1,930 keys/sec
2517         At 700,000 keys, avg. speed is 1,735 keys/sec
2518         At 800,000 keys, avg. speed is 1,795 keys/sec
2519         At 900,000 keys, avg. speed is 1,221 keys/sec
2520         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2521
2522 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2523 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2524 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2525 Run time was 12 min 3 sec.
2526
2527 =head2 MEMORY USAGE
2528
2529 One of the great things about DBM::Deep is that it uses very little memory.
2530 Even with huge databases (1,000,000+ keys) you will not see much increased
2531 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2532 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2533 database handle:
2534
2535           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2536         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2537
2538 Basically the process is taking 2,716K of memory.  And here is the same
2539 process after storing and fetching 1,000,000 keys:
2540
2541           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2542         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2543
2544 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2545 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2546
2547 =head1 DB FILE FORMAT
2548
2549 In case you were interested in the underlying DB file format, it is documented
2550 here in this section.  You don't need to know this to use the module, it's just
2551 included for reference.
2552
2553 =head2 SIGNATURE
2554
2555 DBM::Deep files always start with a 32-bit signature to identify the file type.
2556 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2557 checked when the file is opened.
2558
2559 =head2 TAG
2560
2561 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2562 has a standard header containing the type of data, the length of data, and then
2563 the data itself.  The type is a single character (1 byte), the length is a
2564 32-bit unsigned long in network byte order, and the data is, well, the data.
2565 Here is how it unfolds:
2566
2567 =head2 MASTER INDEX
2568
2569 Immediately after the 32-bit file signature is the I<Master Index> record.
2570 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2571 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2572 depending on how the DBM::Deep object was constructed.
2573
2574
2575
2576 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2577 number).  The first 8-bit char of the MD5 signature is the offset into the
2578 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2579 index element is a file offset of the next tag for the key/element in question,
2580 which is usually a I<Bucket List> tag (see below).
2581
2582
2583
2584 The next tag I<could> be another index, depending on how many keys/elements
2585 exist.  See L<RE-INDEXING> below for details.
2586
2587 =head2 BUCKET LIST
2588
2589 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2590 file offsets to where the actual data is stored.  It starts with a standard
2591 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2592 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2593 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2594 When the list fills up, a I<Re-Index> operation is performed (See
2595 L<RE-INDEXING> below).
2596
2597 =head2 BUCKET
2598
2599 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2600 index/value pair (in array mode).  It starts with a standard tag header with
2601 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2602 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2603 header.  The size reported in the tag header is only for the value, but then,
2604 just after the value is another size (32-bit unsigned long) and then the plain
2605 key itself.  Since the value is likely to be fetched more often than the plain
2606 key, I figured it would be I<slightly> faster to store the value first.
2607
2608
2609
2610 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2611 record for the nested structure, where the process begins all over again.
2612
2613 =head2 RE-INDEXING
2614
2615 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2616 exhausted.  Then, when another key/element comes in, the list is converted to a
2617 new index record.  However, this index will look at the next char in the MD5
2618 hash, and arrange new Bucket List pointers accordingly.  This process is called
2619 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2620 17 (16 + new one) keys/elements are removed from the old Bucket List and
2621 inserted into the new index.  Several new Bucket Lists are created in the
2622 process, as a new MD5 char from the key is being examined (it is unlikely that
2623 the keys will all share the same next char of their MD5s).
2624
2625
2626
2627 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2628 when the Bucket Lists will turn into indexes, but the first round tends to
2629 happen right around 4,000 keys.  You will see a I<slight> decrease in
2630 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2631 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2632 right around 900,000 keys.  This process can continue nearly indefinitely --
2633 right up until the point the I<MD5> signatures start colliding with each other,
2634 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2635 getting struck by lightning while you are walking to cash in your tickets.
2636 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2637 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2638 this is 340 unodecillion, but don't quote me).
2639
2640 =head2 STORING
2641
2642 When a new key/element is stored, the key (or index number) is first ran through
2643 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2644 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2645 for the first char of the signature (in this case I<b>).  If it does not exist,
2646 a new I<Bucket List> is created for our key (and the next 15 future keys that
2647 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2648 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2649 this point, unless we are replacing an existing I<Bucket>), where the actual
2650 data will be stored.
2651
2652 =head2 FETCHING
2653
2654 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2655 (or index number), then walking along the indexes.  If there are enough
2656 keys/elements in this DB level, there might be nested indexes, each linked to
2657 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2658 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2659 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2660 plain key are stored.
2661
2662
2663
2664 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2665 methods.  In this process the indexes are walked systematically, and each key
2666 fetched in increasing MD5 order (which is why it appears random).   Once the
2667 I<Bucket> is found, the value is skipped the plain key returned instead.
2668 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2669 alphabetically sorted.  This only happens on an index-level -- as soon as the
2670 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2671 so it's pretty much undefined how the keys will come out -- just like Perl's
2672 built-in hashes.
2673
2674 =head1 CODE COVERAGE
2675
2676 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2677 module's test suite.
2678
2679   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2680   File                           stmt   bran   cond    sub    pod   time  total
2681   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2682   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2683   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2684   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2685   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2686   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2687
2688 =head1 AUTHOR
2689
2690 Joseph Huckaby, L<jhuckaby@cpan.org>
2691
2692 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2693
2694 =head1 SEE ALSO
2695
2696 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2697 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2698
2699 =head1 LICENSE
2700
2701 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2702 This is free software, you may use it and distribute it under the
2703 same terms as Perl itself.
2704
2705 =cut