lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw(:DEFAULT :flock :seek);
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37 use vars qw/$VERSION/;
  38
  39 $VERSION = "0.96";
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub new {
 106         ##
 107         # Class constructor method for Perl OO interface.
 108         # Calls tie() and returns blessed reference to tied hash or array,
 109         # providing a hybrid OO/tie interface.
 110         ##
 111         my $class = shift;
 112         my $args;
 113         if (scalar(@_) > 1) { $args = {@_}; }
 114         else { $args = { file => shift }; }
 115
 116         ##
 117         # Check if we want a tied hash or array.
 118         ##
 119         my $self;
 120         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 121         $class = 'DBM::Deep::Array';
 122         require DBM::Deep::Array;
 123                 tie @$self, $class, %$args;
 124         }
 125         else {
 126         $class = 'DBM::Deep::Hash';
 127         require DBM::Deep::Hash;
 128                 tie %$self, $class, %$args;
 129         }
 130
 131         return bless $self, $class;
 132 }
 133
 134 {
 135     my @outer_params = qw( type base_offset );
 136     sub _init {
 137         ##
 138         # Setup $self and bless into this class.
 139         ##
 140         my $class = shift;
 141         my $args = shift;
 142
 143         my $self = {
 144             type => TYPE_HASH,
 145             base_offset => length(SIG_FILE),
 146         };
 147
 148         bless $self, $class;
 149
 150         foreach my $outer_parm ( @outer_params ) {
 151             next unless exists $args->{$outer_parm};
 152             $self->{$outer_parm} = delete $args->{$outer_parm}
 153         }
 154
 155         $self->{root} = exists $args->{root}
 156             ? $args->{root}
 157             : DBM::Deep::_::Root->new( $args );
 158
 159         if (!defined($self->fh)) { $self->_open(); }
 160
 161         return $self;
 162     }
 163 }
 164
 165 sub _get_self {
 166     tied( %{$_[0]} ) || $_[0]
 167 }
 168
 169 sub TIEHASH {
 170     shift;
 171     require DBM::Deep::Hash;
 172     return DBM::Deep::Hash->TIEHASH( @_ );
 173 }
 174
 175 sub TIEARRAY {
 176     shift;
 177     require DBM::Deep::Array;
 178     return DBM::Deep::Array->TIEARRAY( @_ );
 179 }
 180
 181 #XXX Unneeded now ...
 182 #sub DESTROY {
 183 #}
 184
 185 my %translate_mode = (
 186     'r' => '<',
 187     'r+' => '+<',
 188     'w' => '>',
 189     'w+' => '+>',
 190     'a' => '>>',
 191     'a+' => '+>>',
 192 );
 193 sub _open {
 194         ##
 195         # Open a FileHandle to the database, create if nonexistent.
 196         # Make sure file signature matches DeepDB spec.
 197         ##
 198     my $self = _get_self($_[0]);
 199
 200         if (defined($self->fh)) { $self->_close(); }
 201
 202     eval {
 203         my $filename = $self->root->{file};
 204         #XXX Can the mode be anything but r+, w+, or a+??
 205         #XXX ie, it has to be in read-write mode
 206         my $mode = $translate_mode{ $self->root->{mode} };
 207
 208         if (!(-e $filename) && $mode eq '+<') {
 209             sysopen( FH, $filename, O_CREAT | O_WRONLY, 0666 );
 210             close FH;
 211         }
 212
 213         my $fh;
 214         sysopen( $fh, $filename, O_RDWR )
 215             or $fh = undef;
 216         $self->root->{fh} = $fh;
 217     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 218         if (! defined($self->fh)) {
 219                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 220         }
 221
 222     my $fh = $self->fh;
 223
 224     #XXX Can we remove this by using the right sysopen() flags?
 225     #XXX I don't think so - there's an item in fopen(3) about rb+, but I'm not sure
 226     #XXX That will work.
 227     binmode $fh; # for win32
 228
 229     if ($self->root->{autoflush}) {
 230         my $old = select $fh;
 231         $|=1;
 232         select $old;
 233     }
 234
 235     my $signature;
 236     seek($fh, 0, SEEK_SET);
 237     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 238
 239     ##
 240     # File is empty -- write signature and master index
 241     ##
 242     if (!$bytes_read) {
 243         seek($fh, 0, SEEK_SET);
 244         print($fh SIG_FILE);
 245         $self->root->{end} = length(SIG_FILE);
 246         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 247
 248         my $plain_key = "[base]";
 249         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 250         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 251
 252         # Flush the filehandle
 253         my $old_fh = select $fh;
 254         my $old_af = $|;
 255         $| = 1;
 256         $| = $old_af;
 257         select $old_fh;
 258
 259         return 1;
 260     }
 261
 262     ##
 263     # Check signature was valid
 264     ##
 265     unless ($signature eq SIG_FILE) {
 266         $self->_close();
 267         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 268     }
 269
 270     $self->root->{end} = (stat($fh))[7];
 271
 272     ##
 273     # Get our type from master index signature
 274     ##
 275     my $tag = $self->_load_tag($self->base_offset);
 276
 277 #XXX We probably also want to store the hash algorithm name and not assume anything
 278
 279     if (!$tag) {
 280         return $self->_throw_error("Corrupted file, no master index record");
 281     }
 282     if ($self->{type} ne $tag->{signature}) {
 283         return $self->_throw_error("File type mismatch");
 284     }
 285
 286     return 1;
 287 }
 288
 289 sub _close {
 290         ##
 291         # Close database FileHandle
 292         ##
 293     my $self = _get_self($_[0]);
 294     close $self->root->{fh};
 295 }
 296
 297 sub _create_tag {
 298         ##
 299         # Given offset, signature and content, create tag and write to disk
 300         ##
 301         my ($self, $offset, $sig, $content) = @_;
 302         my $size = length($content);
 303
 304     my $fh = $self->fh;
 305
 306         seek($fh, $offset, SEEK_SET);
 307         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 308
 309         if ($offset == $self->root->{end}) {
 310                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 311         }
 312
 313         return {
 314                 signature => $sig,
 315                 size => $size,
 316                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 317                 content => $content
 318         };
 319 }
 320
 321 sub _load_tag {
 322         ##
 323         # Given offset, load single tag and return signature, size and data
 324         ##
 325         my $self = shift;
 326         my $offset = shift;
 327
 328     my $fh = $self->fh;
 329
 330         seek($fh, $offset, SEEK_SET);
 331         if (eof $fh) { return undef; }
 332
 333         my $sig;
 334         read( $fh, $sig, SIG_SIZE);
 335
 336         my $size;
 337         read( $fh, $size, $DATA_LENGTH_SIZE);
 338         $size = unpack($DATA_LENGTH_PACK, $size);
 339
 340         my $buffer;
 341         read( $fh, $buffer, $size);
 342
 343         return {
 344                 signature => $sig,
 345                 size => $size,
 346                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 347                 content => $buffer
 348         };
 349 }
 350
 351 sub _index_lookup {
 352         ##
 353         # Given index tag, lookup single entry in index and return .
 354         ##
 355         my $self = shift;
 356         my ($tag, $index) = @_;
 357
 358         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 359         if (!$location) { return; }
 360
 361         return $self->_load_tag( $location );
 362 }
 363
 364 sub _add_bucket {
 365         ##
 366         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 367         # plain (undigested) key and value.
 368         ##
 369         my $self = shift;
 370         my ($tag, $md5, $plain_key, $value) = @_;
 371         my $keys = $tag->{content};
 372         my $location = 0;
 373         my $result = 2;
 374
 375     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 376         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 377
 378     my $fh = $self->fh;
 379
 380         ##
 381         # Iterate through buckets, seeing if this is a new entry or a replace.
 382         ##
 383         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 384                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 385                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 386                 if (!$subloc) {
 387                         ##
 388                         # Found empty bucket (end of list).  Populate and exit loop.
 389                         ##
 390                         $result = 2;
 391
 392             $location = $internal_ref
 393                 ? $value->base_offset
 394                 : $self->root->{end};
 395
 396                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 397                         print($fh $md5 . pack($LONG_PACK, $location) );
 398                         last;
 399                 }
 400                 elsif ($md5 eq $key) {
 401                         ##
 402                         # Found existing bucket with same key.  Replace with new value.
 403                         ##
 404                         $result = 1;
 405
 406                         if ($internal_ref) {
 407                                 $location = $value->base_offset;
 408                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 409                                 print($fh $md5 . pack($LONG_PACK, $location) );
 410                         }
 411                         else {
 412                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 413                                 my $size;
 414                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 415
 416                                 ##
 417                                 # If value is a hash, array, or raw value with equal or less size, we can
 418                                 # reuse the same content area of the database.  Otherwise, we have to create
 419                                 # a new content area at the EOF.
 420                                 ##
 421                                 my $actual_length;
 422                 my $r = Scalar::Util::reftype( $value ) || '';
 423                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 424                                 else { $actual_length = length($value); }
 425
 426                                 if ($actual_length <= $size) {
 427                                         $location = $subloc;
 428                                 }
 429                                 else {
 430                                         $location = $self->root->{end};
 431                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 432                                         print($fh pack($LONG_PACK, $location) );
 433                                 }
 434                         }
 435                         last;
 436                 }
 437         } # i loop
 438
 439         ##
 440         # If this is an internal reference, return now.
 441         # No need to write value or plain key
 442         ##
 443         if ($internal_ref) {
 444         return $result;
 445     }
 446
 447         ##
 448         # If bucket didn't fit into list, split into a new index level
 449         ##
 450         if (!$location) {
 451                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 452                 print($fh pack($LONG_PACK, $self->root->{end}) );
 453
 454                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 455                 my @offsets = ();
 456
 457                 $keys .= $md5 . pack($LONG_PACK, 0);
 458
 459                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 460                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 461                         if ($key) {
 462                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 463                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 464
 465                                 if ($offsets[$num]) {
 466                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 467                                         seek($fh, $offset, SEEK_SET);
 468                                         my $subkeys;
 469                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 470
 471                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 472                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 473                                                 if (!$subloc) {
 474                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 475                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 476                                                         last;
 477                                                 }
 478                                         } # k loop
 479                                 }
 480                                 else {
 481                                         $offsets[$num] = $self->root->{end};
 482                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 483                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 484
 485                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 486
 487                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 488                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 489                                 }
 490                         } # key is real
 491                 } # i loop
 492
 493                 $location ||= $self->root->{end};
 494         } # re-index bucket list
 495
 496         ##
 497         # Seek to content area and store signature, value and plaintext key
 498         ##
 499         if ($location) {
 500                 my $content_length;
 501                 seek($fh, $location, SEEK_SET);
 502
 503                 ##
 504                 # Write signature based on content type, set content length and write actual value.
 505                 ##
 506         my $r = Scalar::Util::reftype($value) || '';
 507                 if ($r eq 'HASH') {
 508                         print($fh TYPE_HASH );
 509                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 510                         $content_length = $INDEX_SIZE;
 511                 }
 512                 elsif ($r eq 'ARRAY') {
 513                         print($fh TYPE_ARRAY );
 514                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 515                         $content_length = $INDEX_SIZE;
 516                 }
 517                 elsif (!defined($value)) {
 518                         print($fh SIG_NULL );
 519                         print($fh pack($DATA_LENGTH_PACK, 0) );
 520                         $content_length = 0;
 521                 }
 522                 else {
 523                         print($fh SIG_DATA );
 524                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 525                         $content_length = length($value);
 526                 }
 527
 528                 ##
 529                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 530                 ##
 531                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 532
 533                 ##
 534                 # If value is blessed, preserve class name
 535                 ##
 536                 if ( $self->root->{autobless} ) {
 537             my $value_class = Scalar::Util::blessed($value);
 538             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 539                 ##
 540                 # Blessed ref -- will restore later
 541                 ##
 542                 print($fh chr(1) );
 543                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 544                 $content_length += 1;
 545                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 546             }
 547             else {
 548                 print($fh chr(0) );
 549                 $content_length += 1;
 550             }
 551         }
 552
 553                 ##
 554                 # If this is a new content area, advance EOF counter
 555                 ##
 556                 if ($location == $self->root->{end}) {
 557                         $self->root->{end} += SIG_SIZE;
 558                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 559                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 560                 }
 561
 562                 ##
 563                 # If content is a hash or array, create new child DeepDB object and
 564                 # pass each key or element to it.
 565                 ##
 566                 if ($r eq 'HASH') {
 567                         my $branch = DBM::Deep->new(
 568                                 type => TYPE_HASH,
 569                                 base_offset => $location,
 570                                 root => $self->root,
 571                         );
 572                         foreach my $key (keys %{$value}) {
 573                 #$branch->{$key} = $value->{$key};
 574                 $branch->STORE( $key, $value->{$key} );
 575                         }
 576                 }
 577                 elsif ($r eq 'ARRAY') {
 578                         my $branch = DBM::Deep->new(
 579                                 type => TYPE_ARRAY,
 580                                 base_offset => $location,
 581                                 root => $self->root,
 582                         );
 583                         my $index = 0;
 584                         foreach my $element (@{$value}) {
 585                 #$branch->[$index] = $element;
 586                 $branch->STORE( $index, $element );
 587                                 $index++;
 588                         }
 589                 }
 590
 591                 return $result;
 592         }
 593
 594         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 595 }
 596
 597 sub _get_bucket_value {
 598         ##
 599         # Fetch single value given tag and MD5 digested key.
 600         ##
 601         my $self = shift;
 602         my ($tag, $md5) = @_;
 603         my $keys = $tag->{content};
 604
 605     my $fh = $self->fh;
 606
 607         ##
 608         # Iterate through buckets, looking for a key match
 609         ##
 610     BUCKET:
 611         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 612                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 613                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 614
 615                 if (!$subloc) {
 616                         ##
 617                         # Hit end of list, no match
 618                         ##
 619                         return;
 620                 }
 621
 622         if ( $md5 ne $key ) {
 623             next BUCKET;
 624         }
 625
 626         ##
 627         # Found match -- seek to offset and read signature
 628         ##
 629         my $signature;
 630         seek($fh, $subloc, SEEK_SET);
 631         read( $fh, $signature, SIG_SIZE);
 632
 633         ##
 634         # If value is a hash or array, return new DeepDB object with correct offset
 635         ##
 636         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 637             my $obj = DBM::Deep->new(
 638                 type => $signature,
 639                 base_offset => $subloc,
 640                 root => $self->root
 641             );
 642
 643             if ($self->root->{autobless}) {
 644                 ##
 645                 # Skip over value and plain key to see if object needs
 646                 # to be re-blessed
 647                 ##
 648                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 649
 650                 my $size;
 651                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 652                 if ($size) { seek($fh, $size, SEEK_CUR); }
 653
 654                 my $bless_bit;
 655                 read( $fh, $bless_bit, 1);
 656                 if (ord($bless_bit)) {
 657                     ##
 658                     # Yes, object needs to be re-blessed
 659                     ##
 660                     my $class_name;
 661                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 662                     if ($size) { read( $fh, $class_name, $size); }
 663                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 664                 }
 665             }
 666
 667             return $obj;
 668         }
 669
 670         ##
 671         # Otherwise return actual value
 672         ##
 673         elsif ($signature eq SIG_DATA) {
 674             my $size;
 675             my $value = '';
 676             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 677             if ($size) { read( $fh, $value, $size); }
 678             return $value;
 679         }
 680
 681         ##
 682         # Key exists, but content is null
 683         ##
 684         else { return; }
 685         } # i loop
 686
 687         return;
 688 }
 689
 690 sub _delete_bucket {
 691         ##
 692         # Delete single key/value pair given tag and MD5 digested key.
 693         ##
 694         my $self = shift;
 695         my ($tag, $md5) = @_;
 696         my $keys = $tag->{content};
 697
 698     my $fh = $self->fh;
 699
 700         ##
 701         # Iterate through buckets, looking for a key match
 702         ##
 703     BUCKET:
 704         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 705                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 706                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 707
 708                 if (!$subloc) {
 709                         ##
 710                         # Hit end of list, no match
 711                         ##
 712                         return;
 713                 }
 714
 715         if ( $md5 ne $key ) {
 716             next BUCKET;
 717         }
 718
 719         ##
 720         # Matched key -- delete bucket and return
 721         ##
 722         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 723         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 724         print($fh chr(0) x $BUCKET_SIZE );
 725
 726         return 1;
 727         } # i loop
 728
 729         return;
 730 }
 731
 732 sub _bucket_exists {
 733         ##
 734         # Check existence of single key given tag and MD5 digested key.
 735         ##
 736         my $self = shift;
 737         my ($tag, $md5) = @_;
 738         my $keys = $tag->{content};
 739
 740         ##
 741         # Iterate through buckets, looking for a key match
 742         ##
 743     BUCKET:
 744         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 745                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 746                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 747
 748                 if (!$subloc) {
 749                         ##
 750                         # Hit end of list, no match
 751                         ##
 752                         return;
 753                 }
 754
 755         if ( $md5 ne $key ) {
 756             next BUCKET;
 757         }
 758
 759         ##
 760         # Matched key -- return true
 761         ##
 762         return 1;
 763         } # i loop
 764
 765         return;
 766 }
 767
 768 sub _find_bucket_list {
 769         ##
 770         # Locate offset for bucket list, given digested key
 771         ##
 772         my $self = shift;
 773         my $md5 = shift;
 774
 775         ##
 776         # Locate offset for bucket list using digest index system
 777         ##
 778         my $ch = 0;
 779         my $tag = $self->_load_tag($self->base_offset);
 780         if (!$tag) { return; }
 781
 782         while ($tag->{signature} ne SIG_BLIST) {
 783                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 784                 if (!$tag) { return; }
 785                 $ch++;
 786         }
 787
 788         return $tag;
 789 }
 790
 791 sub _traverse_index {
 792         ##
 793         # Scan index and recursively step into deeper levels, looking for next key.
 794         ##
 795     my ($self, $offset, $ch, $force_return_next) = @_;
 796     $force_return_next = undef unless $force_return_next;
 797
 798         my $tag = $self->_load_tag( $offset );
 799
 800     my $fh = $self->fh;
 801
 802         if ($tag->{signature} ne SIG_BLIST) {
 803                 my $content = $tag->{content};
 804                 my $start;
 805                 if ($self->{return_next}) { $start = 0; }
 806                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 807
 808                 for (my $index = $start; $index < 256; $index++) {
 809                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 810                         if ($subloc) {
 811                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 812                                 if (defined($result)) { return $result; }
 813                         }
 814                 } # index loop
 815
 816                 $self->{return_next} = 1;
 817         } # tag is an index
 818
 819         elsif ($tag->{signature} eq SIG_BLIST) {
 820                 my $keys = $tag->{content};
 821                 if ($force_return_next) { $self->{return_next} = 1; }
 822
 823                 ##
 824                 # Iterate through buckets, looking for a key match
 825                 ##
 826                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 827                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 828                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 829
 830                         if (!$subloc) {
 831                                 ##
 832                                 # End of bucket list -- return to outer loop
 833                                 ##
 834                                 $self->{return_next} = 1;
 835                                 last;
 836                         }
 837                         elsif ($key eq $self->{prev_md5}) {
 838                                 ##
 839                                 # Located previous key -- return next one found
 840                                 ##
 841                                 $self->{return_next} = 1;
 842                                 next;
 843                         }
 844                         elsif ($self->{return_next}) {
 845                                 ##
 846                                 # Seek to bucket location and skip over signature
 847                                 ##
 848                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 849
 850                                 ##
 851                                 # Skip over value to get to plain key
 852                                 ##
 853                                 my $size;
 854                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 855                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 856
 857                                 ##
 858                                 # Read in plain key and return as scalar
 859                                 ##
 860                                 my $plain_key;
 861                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 862                                 if ($size) { read( $fh, $plain_key, $size); }
 863
 864                                 return $plain_key;
 865                         }
 866                 } # bucket loop
 867
 868                 $self->{return_next} = 1;
 869         } # tag is a bucket list
 870
 871         return;
 872 }
 873
 874 sub _get_next_key {
 875         ##
 876         # Locate next key, given digested previous one
 877         ##
 878     my $self = _get_self($_[0]);
 879
 880         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 881         $self->{return_next} = 0;
 882
 883         ##
 884         # If the previous key was not specifed, start at the top and
 885         # return the first one found.
 886         ##
 887         if (!$self->{prev_md5}) {
 888                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 889                 $self->{return_next} = 1;
 890         }
 891
 892         return $self->_traverse_index( $self->base_offset, 0 );
 893 }
 894
 895 sub lock {
 896         ##
 897         # If db locking is set, flock() the db file.  If called multiple
 898         # times before unlock(), then the same number of unlocks() must
 899         # be called before the lock is released.
 900         ##
 901     my $self = _get_self($_[0]);
 902         my $type = $_[1];
 903     $type = LOCK_EX unless defined $type;
 904
 905         if ($self->root->{locking}) {
 906                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 907                 $self->root->{locked}++;
 908
 909         return 1;
 910         }
 911
 912     return;
 913 }
 914
 915 sub unlock {
 916         ##
 917         # If db locking is set, unlock the db file.  See note in lock()
 918         # regarding calling lock() multiple times.
 919         ##
 920     my $self = _get_self($_[0]);
 921
 922         if ($self->root->{locking} && $self->root->{locked} > 0) {
 923                 $self->root->{locked}--;
 924                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 925
 926         return 1;
 927         }
 928
 929     return;
 930 }
 931
 932 #XXX These uses of ref() need verified
 933 sub _copy_node {
 934         ##
 935         # Copy single level of keys or elements to new DB handle.
 936         # Recurse for nested structures
 937         ##
 938     my $self = _get_self($_[0]);
 939         my $db_temp = $_[1];
 940
 941         if ($self->type eq TYPE_HASH) {
 942                 my $key = $self->first_key();
 943                 while ($key) {
 944                         my $value = $self->get($key);
 945 #XXX This doesn't work with autobless
 946                         if (!ref($value)) { $db_temp->{$key} = $value; }
 947                         else {
 948                                 my $type = $value->type;
 949                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 950                                 else { $db_temp->{$key} = []; }
 951                                 $value->_copy_node( $db_temp->{$key} );
 952                         }
 953                         $key = $self->next_key($key);
 954                 }
 955         }
 956         else {
 957                 my $length = $self->length();
 958                 for (my $index = 0; $index < $length; $index++) {
 959                         my $value = $self->get($index);
 960                         if (!ref($value)) { $db_temp->[$index] = $value; }
 961             #XXX NO tests for this code
 962                         else {
 963                                 my $type = $value->type;
 964                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 965                                 else { $db_temp->[$index] = []; }
 966                                 $value->_copy_node( $db_temp->[$index] );
 967                         }
 968                 }
 969         }
 970 }
 971
 972 sub export {
 973         ##
 974         # Recursively export into standard Perl hashes and arrays.
 975         ##
 976     my $self = _get_self($_[0]);
 977
 978         my $temp;
 979         if ($self->type eq TYPE_HASH) { $temp = {}; }
 980         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 981
 982         $self->lock();
 983         $self->_copy_node( $temp );
 984         $self->unlock();
 985
 986         return $temp;
 987 }
 988
 989 sub import {
 990         ##
 991         # Recursively import Perl hash/array structure
 992         ##
 993     #XXX This use of ref() seems to be ok
 994         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 995
 996     my $self = _get_self($_[0]);
 997         my $struct = $_[1];
 998
 999     #XXX This use of ref() seems to be ok
1000         if (!ref($struct)) {
1001                 ##
1002                 # struct is not a reference, so just import based on our type
1003                 ##
1004                 shift @_;
1005
1006                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1007                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1008         }
1009
1010     my $r = Scalar::Util::reftype($struct) || '';
1011         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1012                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1013         }
1014         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1015                 $self->push( @$struct );
1016         }
1017         else {
1018                 return $self->_throw_error("Cannot import: type mismatch");
1019         }
1020
1021         return 1;
1022 }
1023
1024 sub optimize {
1025         ##
1026         # Rebuild entire database into new file, then move
1027         # it back on top of original.
1028         ##
1029     my $self = _get_self($_[0]);
1030
1031 #XXX Need to create a new test for this
1032 #       if ($self->root->{links} > 1) {
1033 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1034 #       }
1035
1036         my $db_temp = DBM::Deep->new(
1037                 file => $self->root->{file} . '.tmp',
1038                 type => $self->type
1039         );
1040         if (!$db_temp) {
1041                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1042         }
1043
1044         $self->lock();
1045         $self->_copy_node( $db_temp );
1046         undef $db_temp;
1047
1048         ##
1049         # Attempt to copy user, group and permissions over to new file
1050         ##
1051         my @stats = stat($self->fh);
1052         my $perms = $stats[2] & 07777;
1053         my $uid = $stats[4];
1054         my $gid = $stats[5];
1055         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1056         chmod( $perms, $self->root->{file} . '.tmp' );
1057
1058     # q.v. perlport for more information on this variable
1059     if ( $^O eq 'MSWin32' ) {
1060                 ##
1061                 # Potential race condition when optmizing on Win32 with locking.
1062                 # The Windows filesystem requires that the filehandle be closed
1063                 # before it is overwritten with rename().  This could be redone
1064                 # with a soft copy.
1065                 ##
1066                 $self->unlock();
1067                 $self->_close();
1068         }
1069
1070         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1071                 unlink $self->root->{file} . '.tmp';
1072                 $self->unlock();
1073                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1074         }
1075
1076         $self->unlock();
1077         $self->_close();
1078         $self->_open();
1079
1080         return 1;
1081 }
1082
1083 sub clone {
1084         ##
1085         # Make copy of object and return
1086         ##
1087     my $self = _get_self($_[0]);
1088
1089         return DBM::Deep->new(
1090                 type => $self->type,
1091                 base_offset => $self->base_offset,
1092                 root => $self->root
1093         );
1094 }
1095
1096 {
1097     my %is_legal_filter = map {
1098         $_ => ~~1,
1099     } qw(
1100         store_key store_value
1101         fetch_key fetch_value
1102     );
1103
1104     sub set_filter {
1105         ##
1106         # Setup filter function for storing or fetching the key or value
1107         ##
1108         my $self = _get_self($_[0]);
1109         my $type = lc $_[1];
1110         my $func = $_[2] ? $_[2] : undef;
1111
1112         if ( $is_legal_filter{$type} ) {
1113             $self->root->{"filter_$type"} = $func;
1114             return 1;
1115         }
1116
1117         return;
1118     }
1119 }
1120
1121 ##
1122 # Accessor methods
1123 ##
1124
1125 sub root {
1126         ##
1127         # Get access to the root structure
1128         ##
1129     my $self = _get_self($_[0]);
1130         return $self->{root};
1131 }
1132
1133 sub fh {
1134         ##
1135         # Get access to the raw FileHandle
1136         ##
1137     #XXX It will be useful, though, when we split out HASH and ARRAY
1138     my $self = _get_self($_[0]);
1139         return $self->root->{fh};
1140 }
1141
1142 sub type {
1143         ##
1144         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1145         ##
1146     my $self = _get_self($_[0]);
1147         return $self->{type};
1148 }
1149
1150 sub base_offset {
1151         ##
1152         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1153         ##
1154     my $self = _get_self($_[0]);
1155         return $self->{base_offset};
1156 }
1157
1158 sub error {
1159         ##
1160         # Get last error string, or undef if no error
1161         ##
1162         return $_[0]
1163         ? ( _get_self($_[0])->{root}->{error} or undef )
1164         : $@;
1165 }
1166
1167 ##
1168 # Utility methods
1169 ##
1170
1171 sub _throw_error {
1172         ##
1173         # Store error string in self
1174         ##
1175     my $self = _get_self($_[0]);
1176         my $error_text = $_[1];
1177
1178         $self->root->{error} = $error_text;
1179
1180         unless ($self->root->{debug}) {
1181         die "DBM::Deep: $error_text\n";
1182     }
1183
1184     warn "DBM::Deep: $error_text\n";
1185         return;
1186 }
1187
1188 sub clear_error {
1189         ##
1190         # Clear error state
1191         ##
1192     my $self = _get_self($_[0]);
1193
1194         undef $self->root->{error};
1195 }
1196
1197 sub precalc_sizes {
1198         ##
1199         # Precalculate index, bucket and bucket list sizes
1200         ##
1201
1202     #XXX I don't like this ...
1203     set_pack() unless defined $LONG_SIZE;
1204
1205         $INDEX_SIZE = 256 * $LONG_SIZE;
1206         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1207         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1208 }
1209
1210 sub set_pack {
1211         ##
1212         # Set pack/unpack modes (see file header for more)
1213         ##
1214     my ($long_s, $long_p, $data_s, $data_p) = @_;
1215
1216     $LONG_SIZE = $long_s ? $long_s : 4;
1217     $LONG_PACK = $long_p ? $long_p : 'N';
1218
1219     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1220     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1221
1222         precalc_sizes();
1223 }
1224
1225 sub set_digest {
1226         ##
1227         # Set key digest function (default is MD5)
1228         ##
1229     my ($digest_func, $hash_size) = @_;
1230
1231     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1232     $HASH_SIZE = $hash_size ? $hash_size : 16;
1233
1234         precalc_sizes();
1235 }
1236
1237 ##
1238 # tie() methods (hashes and arrays)
1239 ##
1240
1241 sub STORE {
1242         ##
1243         # Store single hash key/value or array element in database.
1244         ##
1245     my $self = _get_self($_[0]);
1246         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1247     #XXX What is ref() checking here?
1248     #YYY User may be storing a hash, in which case we do not want it run
1249     #YYY through the filtering system
1250         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1251
1252         my $unpacked_key = $key;
1253         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1254         my $md5 = $DIGEST_FUNC->($key);
1255
1256         ##
1257         # Make sure file is open
1258         ##
1259         if (!defined($self->fh) && !$self->_open()) {
1260                 return;
1261         }
1262         ##
1263
1264     my $fh = $self->fh;
1265
1266         ##
1267         # Request exclusive lock for writing
1268         ##
1269         $self->lock( LOCK_EX );
1270
1271         ##
1272         # If locking is enabled, set 'end' parameter again, in case another
1273         # DB instance appended to our file while we were unlocked.
1274         ##
1275         if ($self->root->{locking} || $self->root->{volatile}) {
1276                 $self->root->{end} = (stat($fh))[7];
1277         }
1278
1279         ##
1280         # Locate offset for bucket list using digest index system
1281         ##
1282         my $tag = $self->_load_tag($self->base_offset);
1283         if (!$tag) {
1284                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1285         }
1286
1287         my $ch = 0;
1288         while ($tag->{signature} ne SIG_BLIST) {
1289                 my $num = ord(substr($md5, $ch, 1));
1290                 my $new_tag = $self->_index_lookup($tag, $num);
1291                 if (!$new_tag) {
1292                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1293                         seek($fh, $ref_loc, SEEK_SET);
1294                         print($fh pack($LONG_PACK, $self->root->{end}) );
1295
1296                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1297                         $tag->{ref_loc} = $ref_loc;
1298                         $tag->{ch} = $ch;
1299                         last;
1300                 }
1301                 else {
1302                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1303                         $tag = $new_tag;
1304                         $tag->{ref_loc} = $ref_loc;
1305                         $tag->{ch} = $ch;
1306                 }
1307                 $ch++;
1308         }
1309
1310         ##
1311         # Add key/value to bucket list
1312         ##
1313         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1314
1315         ##
1316         # If this object is an array, and bucket was not a replace, and key is numerical,
1317         # and index is equal or greater than current length, advance length variable.
1318         ##
1319         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1320                 $self->STORESIZE( $unpacked_key + 1 );
1321         }
1322
1323         $self->unlock();
1324
1325         return $result;
1326 }
1327
1328 sub FETCH {
1329         ##
1330         # Fetch single value or element given plain key or array index
1331         ##
1332     my $self = _get_self($_[0]);
1333
1334     my $key = $_[1];
1335     if ( $self->type eq TYPE_HASH ) {
1336         if ( my $filter = $self->root->{filter_store_key} ) {
1337             $key = $filter->( $key );
1338         }
1339     }
1340     elsif ( $self->type eq TYPE_ARRAY ) {
1341         if ( $key =~ /^\d+$/ ) {
1342             $key = pack($LONG_PACK, $key);
1343         }
1344     }
1345
1346         my $md5 = $DIGEST_FUNC->($key);
1347
1348         ##
1349         # Make sure file is open
1350         ##
1351         if (!defined($self->fh)) { $self->_open(); }
1352
1353         ##
1354         # Request shared lock for reading
1355         ##
1356         $self->lock( LOCK_SH );
1357
1358         my $tag = $self->_find_bucket_list( $md5 );
1359         if (!$tag) {
1360                 $self->unlock();
1361                 return;
1362         }
1363
1364         ##
1365         # Get value from bucket list
1366         ##
1367         my $result = $self->_get_bucket_value( $tag, $md5 );
1368
1369         $self->unlock();
1370
1371     #XXX What is ref() checking here?
1372         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1373 }
1374
1375 sub DELETE {
1376         ##
1377         # Delete single key/value pair or element given plain key or array index
1378         ##
1379     my $self = _get_self($_[0]);
1380         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1381
1382         my $unpacked_key = $key;
1383         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1384         my $md5 = $DIGEST_FUNC->($key);
1385
1386         ##
1387         # Make sure file is open
1388         ##
1389         if (!defined($self->fh)) { $self->_open(); }
1390
1391         ##
1392         # Request exclusive lock for writing
1393         ##
1394         $self->lock( LOCK_EX );
1395
1396         my $tag = $self->_find_bucket_list( $md5 );
1397         if (!$tag) {
1398                 $self->unlock();
1399                 return;
1400         }
1401
1402         ##
1403         # Delete bucket
1404         ##
1405         my $result = $self->_delete_bucket( $tag, $md5 );
1406
1407         ##
1408         # If this object is an array and the key deleted was on the end of the stack,
1409         # decrement the length variable.
1410         ##
1411         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1412                 $self->STORESIZE( $unpacked_key );
1413         }
1414
1415         $self->unlock();
1416
1417         return $result;
1418 }
1419
1420 sub EXISTS {
1421         ##
1422         # Check if a single key or element exists given plain key or array index
1423         ##
1424     my $self = _get_self($_[0]);
1425         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1426
1427         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1428         my $md5 = $DIGEST_FUNC->($key);
1429
1430         ##
1431         # Make sure file is open
1432         ##
1433         if (!defined($self->fh)) { $self->_open(); }
1434
1435         ##
1436         # Request shared lock for reading
1437         ##
1438         $self->lock( LOCK_SH );
1439
1440         my $tag = $self->_find_bucket_list( $md5 );
1441
1442         ##
1443         # For some reason, the built-in exists() function returns '' for false
1444         ##
1445         if (!$tag) {
1446                 $self->unlock();
1447                 return '';
1448         }
1449
1450         ##
1451         # Check if bucket exists and return 1 or ''
1452         ##
1453         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1454
1455         $self->unlock();
1456
1457         return $result;
1458 }
1459
1460 sub CLEAR {
1461         ##
1462         # Clear all keys from hash, or all elements from array.
1463         ##
1464     my $self = _get_self($_[0]);
1465
1466         ##
1467         # Make sure file is open
1468         ##
1469         if (!defined($self->fh)) { $self->_open(); }
1470
1471         ##
1472         # Request exclusive lock for writing
1473         ##
1474         $self->lock( LOCK_EX );
1475
1476     my $fh = $self->fh;
1477
1478         seek($fh, $self->base_offset, SEEK_SET);
1479         if (eof $fh) {
1480                 $self->unlock();
1481                 return;
1482         }
1483
1484         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1485
1486         $self->unlock();
1487
1488         return 1;
1489 }
1490
1491 ##
1492 # Public method aliases
1493 ##
1494 *put = *store = *STORE;
1495 *get = *fetch = *FETCH;
1496 *delete = *DELETE;
1497 *exists = *EXISTS;
1498 *clear = *CLEAR;
1499
1500 package DBM::Deep::_::Root;
1501
1502 sub new {
1503     my $class = shift;
1504     my ($args) = @_;
1505
1506     my $self = bless {
1507         file => undef,
1508         fh => undef,
1509         end => 0,
1510         autoflush => undef,
1511         locking => undef,
1512         volatile => undef,
1513         debug => undef,
1514         mode => 'r+',
1515         filter_store_key => undef,
1516         filter_store_value => undef,
1517         filter_fetch_key => undef,
1518         filter_fetch_value => undef,
1519         autobless => undef,
1520         locked => 0,
1521         %$args,
1522     }, $class;
1523
1524     return $self;
1525 }
1526
1527 sub DESTROY {
1528     my $self = shift;
1529     return unless $self;
1530
1531     close $self->{fh} if $self->{fh};
1532
1533     return;
1534 }
1535
1536 1;
1537
1538 __END__
1539
1540 =head1 NAME
1541
1542 DBM::Deep - A pure perl multi-level hash/array DBM
1543
1544 =head1 SYNOPSIS
1545
1546   use DBM::Deep;
1547   my $db = DBM::Deep->new( "foo.db" );
1548
1549   $db->{key} = 'value'; # tie() style
1550   print $db->{key};
1551
1552   $db->put('key', 'value'); # OO style
1553   print $db->get('key');
1554
1555   # true multi-level support
1556   $db->{my_complex} = [
1557         'hello', { perl => 'rules' },
1558         42, 99 ];
1559
1560 =head1 DESCRIPTION
1561
1562 A unique flat-file database module, written in pure perl.  True
1563 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1564 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1565 handle millions of keys and unlimited hash levels without significant
1566 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1567 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1568 Mac OS X and Windows.
1569
1570 =head1 INSTALLATION
1571
1572 Hopefully you are using CPAN's excellent Perl module, which will download
1573 and install the module for you.  If not, get the tarball, and run these
1574 commands:
1575
1576         tar zxf DBM-Deep-*
1577         cd DBM-Deep-*
1578         perl Makefile.PL
1579         make
1580         make test
1581         make install
1582
1583 =head1 SETUP
1584
1585 Construction can be done OO-style (which is the recommended way), or using
1586 Perl's tie() function.  Both are examined here.
1587
1588 =head2 OO CONSTRUCTION
1589
1590 The recommended way to construct a DBM::Deep object is to use the new()
1591 method, which gets you a blessed, tied hash or array reference.
1592
1593         my $db = DBM::Deep->new( "foo.db" );
1594
1595 This opens a new database handle, mapped to the file "foo.db".  If this
1596 file does not exist, it will automatically be created.  DB files are
1597 opened in "r+" (read/write) mode, and the type of object returned is a
1598 hash, unless otherwise specified (see L<OPTIONS> below).
1599
1600
1601
1602 You can pass a number of options to the constructor to specify things like
1603 locking, autoflush, etc.  This is done by passing an inline hash:
1604
1605         my $db = DBM::Deep->new(
1606                 file => "foo.db",
1607                 locking => 1,
1608                 autoflush => 1
1609         );
1610
1611 Notice that the filename is now specified I<inside> the hash with
1612 the "file" parameter, as opposed to being the sole argument to the
1613 constructor.  This is required if any options are specified.
1614 See L<OPTIONS> below for the complete list.
1615
1616
1617
1618 You can also start with an array instead of a hash.  For this, you must
1619 specify the C<type> parameter:
1620
1621         my $db = DBM::Deep->new(
1622                 file => "foo.db",
1623                 type => DBM::Deep->TYPE_ARRAY
1624         );
1625
1626 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1627 a new DB file.  If you create a DBM::Deep object with an existing file, the
1628 C<type> will be loaded from the file header, and ignored if it is passed
1629 to the constructor.
1630
1631 =head2 TIE CONSTRUCTION
1632
1633 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1634 tie() function.  This is not ideal, because you get only a basic, tied hash
1635 (or array) which is not blessed, so you can't call any functions on it.
1636
1637         my %hash;
1638         tie %hash, "DBM::Deep", "foo.db";
1639
1640         my @array;
1641         tie @array, "DBM::Deep", "bar.db";
1642
1643 As with the OO constructor, you can replace the DB filename parameter with
1644 a hash containing one or more options (see L<OPTIONS> just below for the
1645 complete list).
1646
1647         tie %hash, "DBM::Deep", {
1648                 file => "foo.db",
1649                 locking => 1,
1650                 autoflush => 1
1651         };
1652
1653 =head2 OPTIONS
1654
1655 There are a number of options that can be passed in when constructing your
1656 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1657
1658 =over
1659
1660 =item * file
1661
1662 Filename of the DB file to link the handle to.  You can pass a full absolute
1663 filesystem path, partial path, or a plain filename if the file is in the
1664 current working directory.  This is a required parameter.
1665
1666 =item * mode
1667
1668 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1669 module.  This is an optional parameter, and defaults to "r+" (read/write).
1670 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1671 created if it doesn't exist.
1672
1673 =item * type
1674
1675 This parameter specifies what type of object to create, a hash or array.  Use
1676 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1677 This only takes effect when beginning a new file.  This is an optional
1678 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1679
1680 =item * locking
1681
1682 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1683 function to lock the database in exclusive mode for writes, and shared mode for
1684 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1685 any child hashes or arrays> that use the same DB file.  This is an optional
1686 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1687
1688 =item * autoflush
1689
1690 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1691 This obviously slows down write operations, but is required if you may have
1692 multiple processes accessing the same DB file (also consider enable I<locking>
1693 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1694 parameter, and defaults to 0 (disabled).
1695
1696 =item * volatile
1697
1698 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1699 STORE() operation.  This is required if an outside force may change the size of
1700 the file between transactions.  Locking also implicitly enables volatile.  This
1701 is useful if you want to use a different locking system or write your own.  Pass
1702 any true value to enable.  This is an optional parameter, and defaults to 0
1703 (disabled).
1704
1705 =item * autobless
1706
1707 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1708 restore them when fetched.  This is an B<experimental> feature, and does have
1709 side-effects.  Basically, when hashes are re-blessed into their original
1710 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1711 able to call any DBM::Deep methods on them.  You have been warned.
1712 This is an optional parameter, and defaults to 0 (disabled).
1713
1714 =item * filter_*
1715
1716 See L<FILTERS> below.
1717
1718 =item * debug
1719
1720 Setting I<debug> mode will make all errors non-fatal, dump them out to
1721 STDERR, and continue on.  This is for debugging purposes only, and probably
1722 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1723
1724 =item * fh
1725
1726 Instead of passing a file path, you can instead pass a handle to an pre-opened
1727 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1728 contains your entire Perl script, as well as the data following the __DATA__
1729 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1730 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1731 in that.
1732
1733 =back
1734
1735 =head1 TIE INTERFACE
1736
1737 With DBM::Deep you can access your databases using Perl's standard hash/array
1738 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1739 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1740 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1741 section above.  This simply tells you how to use DBM::Deep using regular hashes
1742 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1743 work too).  It is entirely up to you how to want to access your databases.
1744
1745 =head2 HASHES
1746
1747 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1748 or even nested hashes (or arrays) using standard Perl syntax:
1749
1750         my $db = DBM::Deep->new( "foo.db" );
1751
1752         $db->{mykey} = "myvalue";
1753         $db->{myhash} = {};
1754         $db->{myhash}->{subkey} = "subvalue";
1755
1756         print $db->{myhash}->{subkey} . "\n";
1757
1758 You can even step through hash keys using the normal Perl C<keys()> function:
1759
1760         foreach my $key (keys %$db) {
1761                 print "$key: " . $db->{$key} . "\n";
1762         }
1763
1764 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1765 pushes them onto an array, all before the loop even begins.  If you have an
1766 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1767 Perl's C<each()> function, which pulls keys/values one at a time, using very
1768 little memory:
1769
1770         while (my ($key, $value) = each %$db) {
1771                 print "$key: $value\n";
1772         }
1773
1774 Please note that when using C<each()>, you should always pass a direct
1775 hash reference, not a lookup.  Meaning, you should B<never> do this:
1776
1777         # NEVER DO THIS
1778         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1779
1780 This causes an infinite loop, because for each iteration, Perl is calling
1781 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1782 it effectively keeps returning the first key over and over again. Instead,
1783 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1784
1785 =head2 ARRAYS
1786
1787 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1788 reference.  This includes inserting, removing and manipulating elements,
1789 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1790 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1791 or simply be a nested array reference inside a hash.  Example:
1792
1793         my $db = DBM::Deep->new(
1794                 file => "foo-array.db",
1795                 type => DBM::Deep->TYPE_ARRAY
1796         );
1797
1798         $db->[0] = "foo";
1799         push @$db, "bar", "baz";
1800         unshift @$db, "bah";
1801
1802         my $last_elem = pop @$db; # baz
1803         my $first_elem = shift @$db; # bah
1804         my $second_elem = $db->[1]; # bar
1805
1806         my $num_elements = scalar @$db;
1807
1808 =head1 OO INTERFACE
1809
1810 In addition to the I<tie()> interface, you can also use a standard OO interface
1811 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1812 array) has its own methods, but both types share the following common methods:
1813 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1814
1815 =over
1816
1817 =item * put()
1818
1819 Stores a new hash key/value pair, or sets an array element value.  Takes two
1820 arguments, the hash key or array index, and the new value.  The value can be
1821 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1822
1823         $db->put("foo", "bar"); # for hashes
1824         $db->put(1, "bar"); # for arrays
1825
1826 =item * get()
1827
1828 Fetches the value of a hash key or array element.  Takes one argument: the hash
1829 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1830 data type stored.
1831
1832         my $value = $db->get("foo"); # for hashes
1833         my $value = $db->get(1); # for arrays
1834
1835 =item * exists()
1836
1837 Checks if a hash key or array index exists.  Takes one argument: the hash key
1838 or array index.  Returns true if it exists, false if not.
1839
1840         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1841         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1842
1843 =item * delete()
1844
1845 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1846 key or array index.  Returns true on success, false if not found.  For arrays,
1847 the remaining elements located after the deleted element are NOT moved over.
1848 The deleted element is essentially just undefined, which is exactly how Perl's
1849 internal arrays work.  Please note that the space occupied by the deleted
1850 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1851 below for details and workarounds.
1852
1853         $db->delete("foo"); # for hashes
1854         $db->delete(1); # for arrays
1855
1856 =item * clear()
1857
1858 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1859 value.  Please note that the space occupied by the deleted keys/values or
1860 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1861 details and workarounds.
1862
1863         $db->clear(); # hashes or arrays
1864
1865 =back
1866
1867 =head2 HASHES
1868
1869 For hashes, DBM::Deep supports all the common methods described above, and the
1870 following additional methods: C<first_key()> and C<next_key()>.
1871
1872 =over
1873
1874 =item * first_key()
1875
1876 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1877 fetched in an undefined order (which appears random).  Takes no arguments,
1878 returns the key as a scalar value.
1879
1880         my $key = $db->first_key();
1881
1882 =item * next_key()
1883
1884 Returns the "next" key in the hash, given the previous one as the sole argument.
1885 Returns undef if there are no more keys to be fetched.
1886
1887         $key = $db->next_key($key);
1888
1889 =back
1890
1891 Here are some examples of using hashes:
1892
1893         my $db = DBM::Deep->new( "foo.db" );
1894
1895         $db->put("foo", "bar");
1896         print "foo: " . $db->get("foo") . "\n";
1897
1898         $db->put("baz", {}); # new child hash ref
1899         $db->get("baz")->put("buz", "biz");
1900         print "buz: " . $db->get("baz")->get("buz") . "\n";
1901
1902         my $key = $db->first_key();
1903         while ($key) {
1904                 print "$key: " . $db->get($key) . "\n";
1905                 $key = $db->next_key($key);
1906         }
1907
1908         if ($db->exists("foo")) { $db->delete("foo"); }
1909
1910 =head2 ARRAYS
1911
1912 For arrays, DBM::Deep supports all the common methods described above, and the
1913 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1914 C<unshift()> and C<splice()>.
1915
1916 =over
1917
1918 =item * length()
1919
1920 Returns the number of elements in the array.  Takes no arguments.
1921
1922         my $len = $db->length();
1923
1924 =item * push()
1925
1926 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1927 refs or array refs.  No return value.
1928
1929         $db->push("foo", "bar", {});
1930
1931 =item * pop()
1932
1933 Fetches the last element in the array, and deletes it.  Takes no arguments.
1934 Returns undef if array is empty.  Returns the element value.
1935
1936         my $elem = $db->pop();
1937
1938 =item * shift()
1939
1940 Fetches the first element in the array, deletes it, then shifts all the
1941 remaining elements over to take up the space.  Returns the element value.  This
1942 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1943 details.
1944
1945         my $elem = $db->shift();
1946
1947 =item * unshift()
1948
1949 Inserts one or more elements onto the beginning of the array, shifting all
1950 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1951 No return value.  This method is not recommended with large arrays -- see
1952 <LARGE ARRAYS> below for details.
1953
1954         $db->unshift("foo", "bar", {});
1955
1956 =item * splice()
1957
1958 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1959 -f splice> for usage -- it is too complicated to document here.  This method is
1960 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1961
1962 =back
1963
1964 Here are some examples of using arrays:
1965
1966         my $db = DBM::Deep->new(
1967                 file => "foo.db",
1968                 type => DBM::Deep->TYPE_ARRAY
1969         );
1970
1971         $db->push("bar", "baz");
1972         $db->unshift("foo");
1973         $db->put(3, "buz");
1974
1975         my $len = $db->length();
1976         print "length: $len\n"; # 4
1977
1978         for (my $k=0; $k<$len; $k++) {
1979                 print "$k: " . $db->get($k) . "\n";
1980         }
1981
1982         $db->splice(1, 2, "biz", "baf");
1983
1984         while (my $elem = shift @$db) {
1985                 print "shifted: $elem\n";
1986         }
1987
1988 =head1 LOCKING
1989
1990 Enable automatic file locking by passing a true value to the C<locking>
1991 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1992
1993         my $db = DBM::Deep->new(
1994                 file => "foo.db",
1995                 locking => 1
1996         );
1997
1998 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1999 mode for writes, and shared mode for reads.  This is required if you have
2000 multiple processes accessing the same database file, to avoid file corruption.
2001 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2002 NFS> below for more.
2003
2004 =head2 EXPLICIT LOCKING
2005
2006 You can explicitly lock a database, so it remains locked for multiple
2007 transactions.  This is done by calling the C<lock()> method, and passing an
2008 optional lock mode argument (defaults to exclusive mode).  This is particularly
2009 useful for things like counters, where the current value needs to be fetched,
2010 then incremented, then stored again.
2011
2012         $db->lock();
2013         my $counter = $db->get("counter");
2014         $counter++;
2015         $db->put("counter", $counter);
2016         $db->unlock();
2017
2018         # or...
2019
2020         $db->lock();
2021         $db->{counter}++;
2022         $db->unlock();
2023
2024 You can pass C<lock()> an optional argument, which specifies which mode to use
2025 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2026 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2027 same as the constants defined in Perl's C<Fcntl> module.
2028
2029         $db->lock( DBM::Deep->LOCK_SH );
2030         # something here
2031         $db->unlock();
2032
2033 If you want to implement your own file locking scheme, be sure to create your
2034 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2035 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2036 below for more.
2037
2038 =head1 IMPORTING/EXPORTING
2039
2040 You can import existing complex structures by calling the C<import()> method,
2041 and export an entire database into an in-memory structure using the C<export()>
2042 method.  Both are examined here.
2043
2044 =head2 IMPORTING
2045
2046 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2047 walking the structure and adding keys/elements to the database as you go,
2048 simply pass a reference to the C<import()> method.  This recursively adds
2049 everything to an existing DBM::Deep object for you.  Here is an example:
2050
2051         my $struct = {
2052                 key1 => "value1",
2053                 key2 => "value2",
2054                 array1 => [ "elem0", "elem1", "elem2" ],
2055                 hash1 => {
2056                         subkey1 => "subvalue1",
2057                         subkey2 => "subvalue2"
2058                 }
2059         };
2060
2061         my $db = DBM::Deep->new( "foo.db" );
2062         $db->import( $struct );
2063
2064         print $db->{key1} . "\n"; # prints "value1"
2065
2066 This recursively imports the entire C<$struct> object into C<$db>, including
2067 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2068 keys are merged with the existing ones, replacing if they already exist.
2069 The C<import()> method can be called on any database level (not just the base
2070 level), and works with both hash and array DB types.
2071
2072
2073
2074 B<Note:> Make sure your existing structure has no circular references in it.
2075 These will cause an infinite loop when importing.
2076
2077 =head2 EXPORTING
2078
2079 Calling the C<export()> method on an existing DBM::Deep object will return
2080 a reference to a new in-memory copy of the database.  The export is done
2081 recursively, so all nested hashes/arrays are all exported to standard Perl
2082 objects.  Here is an example:
2083
2084         my $db = DBM::Deep->new( "foo.db" );
2085
2086         $db->{key1} = "value1";
2087         $db->{key2} = "value2";
2088         $db->{hash1} = {};
2089         $db->{hash1}->{subkey1} = "subvalue1";
2090         $db->{hash1}->{subkey2} = "subvalue2";
2091
2092         my $struct = $db->export();
2093
2094         print $struct->{key1} . "\n"; # prints "value1"
2095
2096 This makes a complete copy of the database in memory, and returns a reference
2097 to it.  The C<export()> method can be called on any database level (not just
2098 the base level), and works with both hash and array DB types.  Be careful of
2099 large databases -- you can store a lot more data in a DBM::Deep object than an
2100 in-memory Perl structure.
2101
2102
2103
2104 B<Note:> Make sure your database has no circular references in it.
2105 These will cause an infinite loop when exporting.
2106
2107 =head1 FILTERS
2108
2109 DBM::Deep has a number of hooks where you can specify your own Perl function
2110 to perform filtering on incoming or outgoing data.  This is a perfect
2111 way to extend the engine, and implement things like real-time compression or
2112 encryption.  Filtering applies to the base DB level, and all child hashes /
2113 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2114 constructed, or by calling the C<set_filter()> method at any time.  There are
2115 four available filter hooks, described below:
2116
2117 =over
2118
2119 =item * filter_store_key
2120
2121 This filter is called whenever a hash key is stored.  It
2122 is passed the incoming key, and expected to return a transformed key.
2123
2124 =item * filter_store_value
2125
2126 This filter is called whenever a hash key or array element is stored.  It
2127 is passed the incoming value, and expected to return a transformed value.
2128
2129 =item * filter_fetch_key
2130
2131 This filter is called whenever a hash key is fetched (i.e. via
2132 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2133 and expected to return the plain key.
2134
2135 =item * filter_fetch_value
2136
2137 This filter is called whenever a hash key or array element is fetched.
2138 It is passed the transformed value, and expected to return the plain value.
2139
2140 =back
2141
2142 Here are the two ways to setup a filter hook:
2143
2144         my $db = DBM::Deep->new(
2145                 file => "foo.db",
2146                 filter_store_value => \&my_filter_store,
2147                 filter_fetch_value => \&my_filter_fetch
2148         );
2149
2150         # or...
2151
2152         $db->set_filter( "filter_store_value", \&my_filter_store );
2153         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2154
2155 Your filter function will be called only when dealing with SCALAR keys or
2156 values.  When nested hashes and arrays are being stored/fetched, filtering
2157 is bypassed.  Filters are called as static functions, passed a single SCALAR
2158 argument, and expected to return a single SCALAR value.  If you want to
2159 remove a filter, set the function reference to C<undef>:
2160
2161         $db->set_filter( "filter_store_value", undef );
2162
2163 =head2 REAL-TIME ENCRYPTION EXAMPLE
2164
2165 Here is a working example that uses the I<Crypt::Blowfish> module to
2166 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2167 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2168 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2169
2170         use DBM::Deep;
2171         use Crypt::Blowfish;
2172         use Crypt::CBC;
2173
2174         my $cipher = Crypt::CBC->new({
2175                 'key'             => 'my secret key',
2176                 'cipher'          => 'Blowfish',
2177                 'iv'              => '$KJh#(}q',
2178                 'regenerate_key'  => 0,
2179                 'padding'         => 'space',
2180                 'prepend_iv'      => 0
2181         });
2182
2183         my $db = DBM::Deep->new(
2184                 file => "foo-encrypt.db",
2185                 filter_store_key => \&my_encrypt,
2186                 filter_store_value => \&my_encrypt,
2187                 filter_fetch_key => \&my_decrypt,
2188                 filter_fetch_value => \&my_decrypt,
2189         );
2190
2191         $db->{key1} = "value1";
2192         $db->{key2} = "value2";
2193         print "key1: " . $db->{key1} . "\n";
2194         print "key2: " . $db->{key2} . "\n";
2195
2196         undef $db;
2197         exit;
2198
2199         sub my_encrypt {
2200                 return $cipher->encrypt( $_[0] );
2201         }
2202         sub my_decrypt {
2203                 return $cipher->decrypt( $_[0] );
2204         }
2205
2206 =head2 REAL-TIME COMPRESSION EXAMPLE
2207
2208 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2209 compression / decompression of keys & values with DBM::Deep Filters.
2210 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2211 more on I<Compress::Zlib>.
2212
2213         use DBM::Deep;
2214         use Compress::Zlib;
2215
2216         my $db = DBM::Deep->new(
2217                 file => "foo-compress.db",
2218                 filter_store_key => \&my_compress,
2219                 filter_store_value => \&my_compress,
2220                 filter_fetch_key => \&my_decompress,
2221                 filter_fetch_value => \&my_decompress,
2222         );
2223
2224         $db->{key1} = "value1";
2225         $db->{key2} = "value2";
2226         print "key1: " . $db->{key1} . "\n";
2227         print "key2: " . $db->{key2} . "\n";
2228
2229         undef $db;
2230         exit;
2231
2232         sub my_compress {
2233                 return Compress::Zlib::memGzip( $_[0] ) ;
2234         }
2235         sub my_decompress {
2236                 return Compress::Zlib::memGunzip( $_[0] ) ;
2237         }
2238
2239 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2240 actually numerical index numbers, and are not filtered.
2241
2242 =head1 ERROR HANDLING
2243
2244 Most DBM::Deep methods return a true value for success, and call die() on
2245 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2246 actual error message is stored in an internal scalar, which can be fetched by
2247 calling the C<error()> method.
2248
2249         my $db = DBM::Deep->new( "foo.db" ); # create hash
2250         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2251
2252         print $db->error(); # prints error message
2253
2254 You can then call C<clear_error()> to clear the current error state.
2255
2256         $db->clear_error();
2257
2258 If you set the C<debug> option to true when creating your DBM::Deep object,
2259 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2260 for debugging purposes.
2261
2262 =head1 LARGEFILE SUPPORT
2263
2264 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2265 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2266 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2267 by calling the static C<set_pack()> method before you do anything else.
2268
2269         DBM::Deep::set_pack(8, 'Q');
2270
2271 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2272 instead of 32-bit longs.  After setting these values your DB files have a
2273 theoretical maximum size of 16 XB (exabytes).
2274
2275
2276
2277 B<Note:> Changing these values will B<NOT> work for existing database files.
2278 Only change this for new files, and make sure it stays set consistently
2279 throughout the file's life.  If you do set these values, you can no longer
2280 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2281 back to 32-bit mode.
2282
2283
2284
2285 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2286 only a 32-bit Perl.  However, I have received user reports that this does
2287 indeed work!
2288
2289 =head1 LOW-LEVEL ACCESS
2290
2291 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2292 you can call the C<fh()> method, which returns the handle:
2293
2294         my $fh = $db->fh();
2295
2296 This method can be called on the root level of the datbase, or any child
2297 hashes or arrays.  All levels share a I<root> structure, which contains things
2298 like the FileHandle, a reference counter, and all your options you specified
2299 when you created the object.  You can get access to this root structure by
2300 calling the C<root()> method.
2301
2302         my $root = $db->root();
2303
2304 This is useful for changing options after the object has already been created,
2305 such as enabling/disabling locking, volatile or debug modes.  You can also
2306 store your own temporary user data in this structure (be wary of name
2307 collision), which is then accessible from any child hash or array.
2308
2309 =head1 CUSTOM DIGEST ALGORITHM
2310
2311 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2312 keys.  However you can override this, and use another algorithm (such as SHA-256)
2313 or even write your own.  But please note that DBM::Deep currently expects zero
2314 collisions, so your algorithm has to be I<perfect>, so to speak.
2315 Collision detection may be introduced in a later version.
2316
2317
2318
2319 You can specify a custom digest algorithm by calling the static C<set_digest()>
2320 function, passing a reference to a subroutine, and the length of the algorithm's
2321 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2322 objects.  Here is a working example that uses a 256-bit hash from the
2323 I<Digest::SHA256> module.  Please see
2324 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2325
2326         use DBM::Deep;
2327         use Digest::SHA256;
2328
2329         my $context = Digest::SHA256::new(256);
2330
2331         DBM::Deep::set_digest( \&my_digest, 32 );
2332
2333         my $db = DBM::Deep->new( "foo-sha.db" );
2334
2335         $db->{key1} = "value1";
2336         $db->{key2} = "value2";
2337         print "key1: " . $db->{key1} . "\n";
2338         print "key2: " . $db->{key2} . "\n";
2339
2340         undef $db;
2341         exit;
2342
2343         sub my_digest {
2344                 return substr( $context->hash($_[0]), 0, 32 );
2345         }
2346
2347 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2348 of bytes you specify in the C<set_digest()> function (in this case 32).
2349
2350 =head1 CIRCULAR REFERENCES
2351
2352 DBM::Deep has B<experimental> support for circular references.  Meaning you
2353 can have a nested hash key or array element that points to a parent object.
2354 This relationship is stored in the DB file, and is preserved between sessions.
2355 Here is an example:
2356
2357         my $db = DBM::Deep->new( "foo.db" );
2358
2359         $db->{foo} = "bar";
2360         $db->{circle} = $db; # ref to self
2361
2362         print $db->{foo} . "\n"; # prints "foo"
2363         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2364
2365 One catch is, passing the object to a function that recursively walks the
2366 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2367 C<export()> methods) will result in an infinite loop.  The other catch is,
2368 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2369 or C<next_key()> methods), you will get the I<target object's key>, not the
2370 ref's key.  This gets even more interesting with the above example, where
2371 the I<circle> key points to the base DB object, which technically doesn't
2372 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2373 special case.
2374
2375 =head1 CAVEATS / ISSUES / BUGS
2376
2377 This section describes all the known issues with DBM::Deep.  It you have found
2378 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2379
2380 =head2 UNUSED SPACE RECOVERY
2381
2382 One major caveat with DBM::Deep is that space occupied by existing keys and
2383 values is not recovered when they are deleted.  Meaning if you keep deleting
2384 and adding new keys, your file will continuously grow.  I am working on this,
2385 but in the meantime you can call the built-in C<optimize()> method from time to
2386 time (perhaps in a crontab or something) to recover all your unused space.
2387
2388         $db->optimize(); # returns true on success
2389
2390 This rebuilds the ENTIRE database into a new file, then moves it on top of
2391 the original.  The new file will have no unused space, thus it will take up as
2392 little disk space as possible.  Please note that this operation can take
2393 a long time for large files, and you need enough disk space to temporarily hold
2394 2 copies of your DB file.  The temporary file is created in the same directory
2395 as the original, named with a ".tmp" extension, and is deleted when the
2396 operation completes.  Oh, and if locking is enabled, the DB is automatically
2397 locked for the entire duration of the copy.
2398
2399
2400
2401 B<WARNING:> Only call optimize() on the top-level node of the database, and
2402 make sure there are no child references lying around.  DBM::Deep keeps a reference
2403 counter, and if it is greater than 1, optimize() will abort and return undef.
2404
2405 =head2 AUTOVIVIFICATION
2406
2407 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2408 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2409 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2410 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2411 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2412 this does not work:
2413
2414         $db->{foo}->{bar} = "hello";
2415
2416 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2417 being an empty hash.  Try this instead, which works fine:
2418
2419         $db->{foo} = { bar => "hello" };
2420
2421 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2422 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2423 Probably a bug in Perl.
2424
2425 =head2 FILE CORRUPTION
2426
2427 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2428 for a 32-bit signature when opened, but other corruption in files can cause
2429 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2430 stuck in an infinite loop depending on the level of corruption.  File write
2431 operations are not checked for failure (for speed), so if you happen to run
2432 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2433 be addressed in a later version of DBM::Deep.
2434
2435 =head2 DB OVER NFS
2436
2437 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2438 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2439 about setting up your NFS server with a locking daemon, then using lockf() to
2440 lock your files, but your milage may vary there as well.  From what I
2441 understand, there is no real way to do it.  However, if you need access to the
2442 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2443 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2444
2445 =head2 COPYING OBJECTS
2446
2447 Beware of copying tied objects in Perl.  Very strange things can happen.
2448 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2449 returns a new, blessed, tied hash or array to the same level in the DB.
2450
2451         my $copy = $db->clone();
2452
2453 =head2 LARGE ARRAYS
2454
2455 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2456 These functions cause every element in the array to move, which can be murder
2457 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2458 a different location.  This may be addressed in a later version.
2459
2460 =head1 PERFORMANCE
2461
2462 This section discusses DBM::Deep's speed and memory usage.
2463
2464 =head2 SPEED
2465
2466 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2467 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2468 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2469 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2470 with huge databases.  Here is some test data:
2471
2472         Adding 1,000,000 keys to new DB file...
2473
2474         At 100 keys, avg. speed is 2,703 keys/sec
2475         At 200 keys, avg. speed is 2,642 keys/sec
2476         At 300 keys, avg. speed is 2,598 keys/sec
2477         At 400 keys, avg. speed is 2,578 keys/sec
2478         At 500 keys, avg. speed is 2,722 keys/sec
2479         At 600 keys, avg. speed is 2,628 keys/sec
2480         At 700 keys, avg. speed is 2,700 keys/sec
2481         At 800 keys, avg. speed is 2,607 keys/sec
2482         At 900 keys, avg. speed is 2,190 keys/sec
2483         At 1,000 keys, avg. speed is 2,570 keys/sec
2484         At 2,000 keys, avg. speed is 2,417 keys/sec
2485         At 3,000 keys, avg. speed is 1,982 keys/sec
2486         At 4,000 keys, avg. speed is 1,568 keys/sec
2487         At 5,000 keys, avg. speed is 1,533 keys/sec
2488         At 6,000 keys, avg. speed is 1,787 keys/sec
2489         At 7,000 keys, avg. speed is 1,977 keys/sec
2490         At 8,000 keys, avg. speed is 2,028 keys/sec
2491         At 9,000 keys, avg. speed is 2,077 keys/sec
2492         At 10,000 keys, avg. speed is 2,031 keys/sec
2493         At 20,000 keys, avg. speed is 1,970 keys/sec
2494         At 30,000 keys, avg. speed is 2,050 keys/sec
2495         At 40,000 keys, avg. speed is 2,073 keys/sec
2496         At 50,000 keys, avg. speed is 1,973 keys/sec
2497         At 60,000 keys, avg. speed is 1,914 keys/sec
2498         At 70,000 keys, avg. speed is 2,091 keys/sec
2499         At 80,000 keys, avg. speed is 2,103 keys/sec
2500         At 90,000 keys, avg. speed is 1,886 keys/sec
2501         At 100,000 keys, avg. speed is 1,970 keys/sec
2502         At 200,000 keys, avg. speed is 2,053 keys/sec
2503         At 300,000 keys, avg. speed is 1,697 keys/sec
2504         At 400,000 keys, avg. speed is 1,838 keys/sec
2505         At 500,000 keys, avg. speed is 1,941 keys/sec
2506         At 600,000 keys, avg. speed is 1,930 keys/sec
2507         At 700,000 keys, avg. speed is 1,735 keys/sec
2508         At 800,000 keys, avg. speed is 1,795 keys/sec
2509         At 900,000 keys, avg. speed is 1,221 keys/sec
2510         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2511
2512 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2513 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2514 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2515 Run time was 12 min 3 sec.
2516
2517 =head2 MEMORY USAGE
2518
2519 One of the great things about DBM::Deep is that it uses very little memory.
2520 Even with huge databases (1,000,000+ keys) you will not see much increased
2521 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2522 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2523 database handle:
2524
2525           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2526         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2527
2528 Basically the process is taking 2,716K of memory.  And here is the same
2529 process after storing and fetching 1,000,000 keys:
2530
2531           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2532         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2533
2534 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2535 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2536
2537 =head1 DB FILE FORMAT
2538
2539 In case you were interested in the underlying DB file format, it is documented
2540 here in this section.  You don't need to know this to use the module, it's just
2541 included for reference.
2542
2543 =head2 SIGNATURE
2544
2545 DBM::Deep files always start with a 32-bit signature to identify the file type.
2546 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2547 checked when the file is opened.
2548
2549 =head2 TAG
2550
2551 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2552 has a standard header containing the type of data, the length of data, and then
2553 the data itself.  The type is a single character (1 byte), the length is a
2554 32-bit unsigned long in network byte order, and the data is, well, the data.
2555 Here is how it unfolds:
2556
2557 =head2 MASTER INDEX
2558
2559 Immediately after the 32-bit file signature is the I<Master Index> record.
2560 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2561 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2562 depending on how the DBM::Deep object was constructed.
2563
2564
2565
2566 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2567 number).  The first 8-bit char of the MD5 signature is the offset into the
2568 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2569 index element is a file offset of the next tag for the key/element in question,
2570 which is usually a I<Bucket List> tag (see below).
2571
2572
2573
2574 The next tag I<could> be another index, depending on how many keys/elements
2575 exist.  See L<RE-INDEXING> below for details.
2576
2577 =head2 BUCKET LIST
2578
2579 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2580 file offsets to where the actual data is stored.  It starts with a standard
2581 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2582 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2583 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2584 When the list fills up, a I<Re-Index> operation is performed (See
2585 L<RE-INDEXING> below).
2586
2587 =head2 BUCKET
2588
2589 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2590 index/value pair (in array mode).  It starts with a standard tag header with
2591 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2592 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2593 header.  The size reported in the tag header is only for the value, but then,
2594 just after the value is another size (32-bit unsigned long) and then the plain
2595 key itself.  Since the value is likely to be fetched more often than the plain
2596 key, I figured it would be I<slightly> faster to store the value first.
2597
2598
2599
2600 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2601 record for the nested structure, where the process begins all over again.
2602
2603 =head2 RE-INDEXING
2604
2605 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2606 exhausted.  Then, when another key/element comes in, the list is converted to a
2607 new index record.  However, this index will look at the next char in the MD5
2608 hash, and arrange new Bucket List pointers accordingly.  This process is called
2609 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2610 17 (16 + new one) keys/elements are removed from the old Bucket List and
2611 inserted into the new index.  Several new Bucket Lists are created in the
2612 process, as a new MD5 char from the key is being examined (it is unlikely that
2613 the keys will all share the same next char of their MD5s).
2614
2615
2616
2617 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2618 when the Bucket Lists will turn into indexes, but the first round tends to
2619 happen right around 4,000 keys.  You will see a I<slight> decrease in
2620 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2621 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2622 right around 900,000 keys.  This process can continue nearly indefinitely --
2623 right up until the point the I<MD5> signatures start colliding with each other,
2624 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2625 getting struck by lightning while you are walking to cash in your tickets.
2626 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2627 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2628 this is 340 unodecillion, but don't quote me).
2629
2630 =head2 STORING
2631
2632 When a new key/element is stored, the key (or index number) is first ran through
2633 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2634 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2635 for the first char of the signature (in this case I<b>).  If it does not exist,
2636 a new I<Bucket List> is created for our key (and the next 15 future keys that
2637 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2638 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2639 this point, unless we are replacing an existing I<Bucket>), where the actual
2640 data will be stored.
2641
2642 =head2 FETCHING
2643
2644 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2645 (or index number), then walking along the indexes.  If there are enough
2646 keys/elements in this DB level, there might be nested indexes, each linked to
2647 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2648 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2649 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2650 plain key are stored.
2651
2652
2653
2654 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2655 methods.  In this process the indexes are walked systematically, and each key
2656 fetched in increasing MD5 order (which is why it appears random).   Once the
2657 I<Bucket> is found, the value is skipped the plain key returned instead.
2658 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2659 alphabetically sorted.  This only happens on an index-level -- as soon as the
2660 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2661 so it's pretty much undefined how the keys will come out -- just like Perl's
2662 built-in hashes.
2663
2664 =head1 CODE COVERAGE
2665
2666 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2667 module's test suite.
2668
2669   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2670   File                           stmt   bran   cond    sub    pod   time  total
2671   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2672   blib/lib/DBM/Deep.pm           94.1   82.9   74.5   98.0   10.5   98.1   88.2
2673   blib/lib/DBM/Deep/Array.pm     97.8   83.3   50.0  100.0    n/a    1.6   94.4
2674   blib/lib/DBM/Deep/Hash.pm      93.3   85.7  100.0  100.0    n/a    0.3   92.7
2675   Total                          94.5   83.1   75.5   98.4   10.5  100.0   89.0
2676   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2677
2678 =head1 AUTHOR
2679
2680 Joseph Huckaby, L<jhuckaby@cpan.org>
2681
2682 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2683
2684 =head1 SEE ALSO
2685
2686 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2687 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2688
2689 =head1 LICENSE
2690
2691 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2692 This is free software, you may use it and distribute it under the
2693 same terms as Perl itself.
2694
2695 =cut