lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub new {
 106         ##
 107         # Class constructor method for Perl OO interface.
 108         # Calls tie() and returns blessed reference to tied hash or array,
 109         # providing a hybrid OO/tie interface.
 110         ##
 111         my $class = shift;
 112         my $args;
 113         if (scalar(@_) > 1) { $args = {@_}; }
 114         else { $args = { file => shift }; }
 115
 116         ##
 117         # Check if we want a tied hash or array.
 118         ##
 119         my $self;
 120         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 121         $class = 'DBM::Deep::Array';
 122         require DBM::Deep::Array;
 123                 tie @$self, $class, %$args;
 124         }
 125         else {
 126         $class = 'DBM::Deep::Hash';
 127         require DBM::Deep::Hash;
 128                 tie %$self, $class, %$args;
 129         }
 130
 131         return bless $self, $class;
 132 }
 133
 134 sub _init {
 135     ##
 136     # Setup $self and bless into this class.
 137     ##
 138     my $class = shift;
 139     my $args = shift;
 140
 141     # These are the defaults to be optionally overridden below
 142     my $self = bless {
 143         type => TYPE_HASH,
 144         base_offset => length(SIG_FILE),
 145     }, $class;
 146
 147     foreach my $param ( keys %$self ) {
 148         next unless exists $args->{$param};
 149         $self->{$param} = delete $args->{$param}
 150     }
 151
 152     $self->{root} = exists $args->{root}
 153         ? $args->{root}
 154         : DBM::Deep::_::Root->new( $args );
 155
 156     if (!defined($self->fh)) { $self->_open(); }
 157
 158     return $self;
 159 }
 160
 161 sub TIEHASH {
 162     shift;
 163     require DBM::Deep::Hash;
 164     return DBM::Deep::Hash->TIEHASH( @_ );
 165 }
 166
 167 sub TIEARRAY {
 168     shift;
 169     require DBM::Deep::Array;
 170     return DBM::Deep::Array->TIEARRAY( @_ );
 171 }
 172
 173 #XXX Unneeded now ...
 174 #sub DESTROY {
 175 #}
 176
 177 sub _open {
 178         ##
 179         # Open a FileHandle to the database, create if nonexistent.
 180         # Make sure file signature matches DeepDB spec.
 181         ##
 182     my $self = $_[0]->_get_self;
 183
 184         if (defined($self->fh)) { $self->_close(); }
 185
 186     eval {
 187         # Theoretically, adding O_BINARY should remove the need for the binmode
 188         # Of course, testing it is going to be ... interesting.
 189         my $flags = O_RDWR | O_CREAT | O_BINARY;
 190
 191         #XXX Can the mode be anything but r+, w+, or a+??
 192         #XXX ie, it has to be in read-write mode
 193         #XXX So, should we verify that the mode is legitimate?
 194
 195         #XXX Maybe the mode thingy should just go away. There's no good
 196         #XXX reason for it ...
 197         if ( $self->root->{mode} eq 'w+' ) {
 198             $flags |= O_TRUNC;
 199         }
 200
 201         my $fh;
 202         sysopen( $fh, $self->root->{file}, $flags )
 203             or $fh = undef;
 204         $self->root->{fh} = $fh;
 205     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 206         if (! defined($self->fh)) {
 207                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 208         }
 209
 210     my $fh = $self->fh;
 211
 212     #XXX Can we remove this by using the right sysopen() flags?
 213     # Maybe ... q.v. above
 214     binmode $fh; # for win32
 215
 216     if ($self->root->{autoflush}) {
 217         my $old = select $fh;
 218         $|=1;
 219         select $old;
 220     }
 221
 222     # Set the
 223     seek($fh, 0, SEEK_SET);
 224
 225     my $signature;
 226     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 227
 228     ##
 229     # File is empty -- write signature and master index
 230     ##
 231     if (!$bytes_read) {
 232         seek($fh, 0, SEEK_SET);
 233         print($fh SIG_FILE);
 234         $self->root->{end} = length(SIG_FILE);
 235         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 236
 237         my $plain_key = "[base]";
 238         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 239         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 240
 241         # Flush the filehandle
 242         my $old_fh = select $fh;
 243         my $old_af = $|;
 244         $| = 1;
 245         $| = $old_af;
 246         select $old_fh;
 247
 248         return 1;
 249     }
 250
 251     ##
 252     # Check signature was valid
 253     ##
 254     unless ($signature eq SIG_FILE) {
 255         $self->_close();
 256         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 257     }
 258
 259     $self->root->{end} = (stat($fh))[7];
 260
 261     ##
 262     # Get our type from master index signature
 263     ##
 264     my $tag = $self->_load_tag($self->base_offset);
 265
 266 #XXX We probably also want to store the hash algorithm name and not assume anything
 267
 268     if (!$tag) {
 269         return $self->_throw_error("Corrupted file, no master index record");
 270     }
 271     if ($self->{type} ne $tag->{signature}) {
 272         return $self->_throw_error("File type mismatch");
 273     }
 274
 275     return 1;
 276 }
 277
 278 sub _close {
 279         ##
 280         # Close database FileHandle
 281         ##
 282     my $self = $_[0]->_get_self;
 283     close $self->root->{fh};
 284 }
 285
 286 sub _create_tag {
 287         ##
 288         # Given offset, signature and content, create tag and write to disk
 289         ##
 290         my ($self, $offset, $sig, $content) = @_;
 291         my $size = length($content);
 292
 293     my $fh = $self->fh;
 294
 295         seek($fh, $offset, SEEK_SET);
 296         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 297
 298         if ($offset == $self->root->{end}) {
 299                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 300         }
 301
 302         return {
 303                 signature => $sig,
 304                 size => $size,
 305                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 306                 content => $content
 307         };
 308 }
 309
 310 sub _load_tag {
 311         ##
 312         # Given offset, load single tag and return signature, size and data
 313         ##
 314         my $self = shift;
 315         my $offset = shift;
 316
 317     my $fh = $self->fh;
 318
 319         seek($fh, $offset, SEEK_SET);
 320         if (eof $fh) { return undef; }
 321
 322         my $sig;
 323         read( $fh, $sig, SIG_SIZE);
 324
 325         my $size;
 326         read( $fh, $size, $DATA_LENGTH_SIZE);
 327         $size = unpack($DATA_LENGTH_PACK, $size);
 328
 329         my $buffer;
 330         read( $fh, $buffer, $size);
 331
 332         return {
 333                 signature => $sig,
 334                 size => $size,
 335                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 336                 content => $buffer
 337         };
 338 }
 339
 340 sub _index_lookup {
 341         ##
 342         # Given index tag, lookup single entry in index and return .
 343         ##
 344         my $self = shift;
 345         my ($tag, $index) = @_;
 346
 347         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 348         if (!$location) { return; }
 349
 350         return $self->_load_tag( $location );
 351 }
 352
 353 sub _add_bucket {
 354         ##
 355         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 356         # plain (undigested) key and value.
 357         ##
 358         my $self = shift;
 359         my ($tag, $md5, $plain_key, $value) = @_;
 360         my $keys = $tag->{content};
 361         my $location = 0;
 362         my $result = 2;
 363
 364     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 365         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 366
 367     my $fh = $self->fh;
 368
 369         ##
 370         # Iterate through buckets, seeing if this is a new entry or a replace.
 371         ##
 372         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 373                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 374                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 375                 if (!$subloc) {
 376                         ##
 377                         # Found empty bucket (end of list).  Populate and exit loop.
 378                         ##
 379                         $result = 2;
 380
 381             $location = $internal_ref
 382                 ? $value->base_offset
 383                 : $self->root->{end};
 384
 385                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 386                         print($fh $md5 . pack($LONG_PACK, $location) );
 387                         last;
 388                 }
 389                 elsif ($md5 eq $key) {
 390                         ##
 391                         # Found existing bucket with same key.  Replace with new value.
 392                         ##
 393                         $result = 1;
 394
 395                         if ($internal_ref) {
 396                                 $location = $value->base_offset;
 397                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 398                                 print($fh $md5 . pack($LONG_PACK, $location) );
 399                         }
 400                         else {
 401                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 402                                 my $size;
 403                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 404
 405                                 ##
 406                                 # If value is a hash, array, or raw value with equal or less size, we can
 407                                 # reuse the same content area of the database.  Otherwise, we have to create
 408                                 # a new content area at the EOF.
 409                                 ##
 410                                 my $actual_length;
 411                 my $r = Scalar::Util::reftype( $value ) || '';
 412                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 413                                 else { $actual_length = length($value); }
 414
 415                                 if ($actual_length <= $size) {
 416                                         $location = $subloc;
 417                                 }
 418                                 else {
 419                                         $location = $self->root->{end};
 420                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 421                                         print($fh pack($LONG_PACK, $location) );
 422                                 }
 423                         }
 424                         last;
 425                 }
 426         } # i loop
 427
 428         ##
 429         # If this is an internal reference, return now.
 430         # No need to write value or plain key
 431         ##
 432         if ($internal_ref) {
 433         return $result;
 434     }
 435
 436         ##
 437         # If bucket didn't fit into list, split into a new index level
 438         ##
 439         if (!$location) {
 440                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 441                 print($fh pack($LONG_PACK, $self->root->{end}) );
 442
 443                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 444                 my @offsets = ();
 445
 446                 $keys .= $md5 . pack($LONG_PACK, 0);
 447
 448                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 449                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 450                         if ($key) {
 451                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 452                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 453
 454                                 if ($offsets[$num]) {
 455                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 456                                         seek($fh, $offset, SEEK_SET);
 457                                         my $subkeys;
 458                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 459
 460                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 461                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 462                                                 if (!$subloc) {
 463                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 464                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 465                                                         last;
 466                                                 }
 467                                         } # k loop
 468                                 }
 469                                 else {
 470                                         $offsets[$num] = $self->root->{end};
 471                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 472                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 473
 474                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 475
 476                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 477                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 478                                 }
 479                         } # key is real
 480                 } # i loop
 481
 482                 $location ||= $self->root->{end};
 483         } # re-index bucket list
 484
 485         ##
 486         # Seek to content area and store signature, value and plaintext key
 487         ##
 488         if ($location) {
 489                 my $content_length;
 490                 seek($fh, $location, SEEK_SET);
 491
 492                 ##
 493                 # Write signature based on content type, set content length and write actual value.
 494                 ##
 495         my $r = Scalar::Util::reftype($value) || '';
 496                 if ($r eq 'HASH') {
 497                         print($fh TYPE_HASH );
 498                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 499                         $content_length = $INDEX_SIZE;
 500                 }
 501                 elsif ($r eq 'ARRAY') {
 502                         print($fh TYPE_ARRAY );
 503                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 504                         $content_length = $INDEX_SIZE;
 505                 }
 506                 elsif (!defined($value)) {
 507                         print($fh SIG_NULL );
 508                         print($fh pack($DATA_LENGTH_PACK, 0) );
 509                         $content_length = 0;
 510                 }
 511                 else {
 512                         print($fh SIG_DATA );
 513                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 514                         $content_length = length($value);
 515                 }
 516
 517                 ##
 518                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 519                 ##
 520                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 521
 522                 ##
 523                 # If value is blessed, preserve class name
 524                 ##
 525                 if ( $self->root->{autobless} ) {
 526             my $value_class = Scalar::Util::blessed($value);
 527             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 528                 ##
 529                 # Blessed ref -- will restore later
 530                 ##
 531                 print($fh chr(1) );
 532                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 533                 $content_length += 1;
 534                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 535             }
 536             else {
 537                 print($fh chr(0) );
 538                 $content_length += 1;
 539             }
 540         }
 541
 542                 ##
 543                 # If this is a new content area, advance EOF counter
 544                 ##
 545                 if ($location == $self->root->{end}) {
 546                         $self->root->{end} += SIG_SIZE;
 547                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 548                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 549                 }
 550
 551                 ##
 552                 # If content is a hash or array, create new child DeepDB object and
 553                 # pass each key or element to it.
 554                 ##
 555                 if ($r eq 'HASH') {
 556                         my $branch = DBM::Deep->new(
 557                                 type => TYPE_HASH,
 558                                 base_offset => $location,
 559                                 root => $self->root,
 560                         );
 561                         foreach my $key (keys %{$value}) {
 562                 #$branch->{$key} = $value->{$key};
 563                 $branch->STORE( $key, $value->{$key} );
 564                         }
 565                 }
 566                 elsif ($r eq 'ARRAY') {
 567                         my $branch = DBM::Deep->new(
 568                                 type => TYPE_ARRAY,
 569                                 base_offset => $location,
 570                                 root => $self->root,
 571                         );
 572                         my $index = 0;
 573                         foreach my $element (@{$value}) {
 574                 #$branch->[$index] = $element;
 575                 $branch->STORE( $index, $element );
 576                                 $index++;
 577                         }
 578                 }
 579
 580                 return $result;
 581         }
 582
 583         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 584 }
 585
 586 sub _get_bucket_value {
 587         ##
 588         # Fetch single value given tag and MD5 digested key.
 589         ##
 590         my $self = shift;
 591         my ($tag, $md5) = @_;
 592         my $keys = $tag->{content};
 593
 594     my $fh = $self->fh;
 595
 596         ##
 597         # Iterate through buckets, looking for a key match
 598         ##
 599     BUCKET:
 600         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 601                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 602                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 603
 604                 if (!$subloc) {
 605                         ##
 606                         # Hit end of list, no match
 607                         ##
 608                         return;
 609                 }
 610
 611         if ( $md5 ne $key ) {
 612             next BUCKET;
 613         }
 614
 615         ##
 616         # Found match -- seek to offset and read signature
 617         ##
 618         my $signature;
 619         seek($fh, $subloc, SEEK_SET);
 620         read( $fh, $signature, SIG_SIZE);
 621
 622         ##
 623         # If value is a hash or array, return new DeepDB object with correct offset
 624         ##
 625         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 626             my $obj = DBM::Deep->new(
 627                 type => $signature,
 628                 base_offset => $subloc,
 629                 root => $self->root
 630             );
 631
 632             if ($self->root->{autobless}) {
 633                 ##
 634                 # Skip over value and plain key to see if object needs
 635                 # to be re-blessed
 636                 ##
 637                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 638
 639                 my $size;
 640                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 641                 if ($size) { seek($fh, $size, SEEK_CUR); }
 642
 643                 my $bless_bit;
 644                 read( $fh, $bless_bit, 1);
 645                 if (ord($bless_bit)) {
 646                     ##
 647                     # Yes, object needs to be re-blessed
 648                     ##
 649                     my $class_name;
 650                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 651                     if ($size) { read( $fh, $class_name, $size); }
 652                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 653                 }
 654             }
 655
 656             return $obj;
 657         }
 658
 659         ##
 660         # Otherwise return actual value
 661         ##
 662         elsif ($signature eq SIG_DATA) {
 663             my $size;
 664             my $value = '';
 665             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 666             if ($size) { read( $fh, $value, $size); }
 667             return $value;
 668         }
 669
 670         ##
 671         # Key exists, but content is null
 672         ##
 673         else { return; }
 674         } # i loop
 675
 676         return;
 677 }
 678
 679 sub _delete_bucket {
 680         ##
 681         # Delete single key/value pair given tag and MD5 digested key.
 682         ##
 683         my $self = shift;
 684         my ($tag, $md5) = @_;
 685         my $keys = $tag->{content};
 686
 687     my $fh = $self->fh;
 688
 689         ##
 690         # Iterate through buckets, looking for a key match
 691         ##
 692     BUCKET:
 693         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 694                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 695                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 696
 697                 if (!$subloc) {
 698                         ##
 699                         # Hit end of list, no match
 700                         ##
 701                         return;
 702                 }
 703
 704         if ( $md5 ne $key ) {
 705             next BUCKET;
 706         }
 707
 708         ##
 709         # Matched key -- delete bucket and return
 710         ##
 711         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 712         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 713         print($fh chr(0) x $BUCKET_SIZE );
 714
 715         return 1;
 716         } # i loop
 717
 718         return;
 719 }
 720
 721 sub _bucket_exists {
 722         ##
 723         # Check existence of single key given tag and MD5 digested key.
 724         ##
 725         my $self = shift;
 726         my ($tag, $md5) = @_;
 727         my $keys = $tag->{content};
 728
 729         ##
 730         # Iterate through buckets, looking for a key match
 731         ##
 732     BUCKET:
 733         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 734                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 735                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 736
 737                 if (!$subloc) {
 738                         ##
 739                         # Hit end of list, no match
 740                         ##
 741                         return;
 742                 }
 743
 744         if ( $md5 ne $key ) {
 745             next BUCKET;
 746         }
 747
 748         ##
 749         # Matched key -- return true
 750         ##
 751         return 1;
 752         } # i loop
 753
 754         return;
 755 }
 756
 757 sub _find_bucket_list {
 758         ##
 759         # Locate offset for bucket list, given digested key
 760         ##
 761         my $self = shift;
 762         my $md5 = shift;
 763
 764         ##
 765         # Locate offset for bucket list using digest index system
 766         ##
 767         my $ch = 0;
 768         my $tag = $self->_load_tag($self->base_offset);
 769         if (!$tag) { return; }
 770
 771         while ($tag->{signature} ne SIG_BLIST) {
 772                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 773                 if (!$tag) { return; }
 774                 $ch++;
 775         }
 776
 777         return $tag;
 778 }
 779
 780 sub _traverse_index {
 781         ##
 782         # Scan index and recursively step into deeper levels, looking for next key.
 783         ##
 784     my ($self, $offset, $ch, $force_return_next) = @_;
 785     $force_return_next = undef unless $force_return_next;
 786
 787         my $tag = $self->_load_tag( $offset );
 788
 789     my $fh = $self->fh;
 790
 791         if ($tag->{signature} ne SIG_BLIST) {
 792                 my $content = $tag->{content};
 793                 my $start;
 794                 if ($self->{return_next}) { $start = 0; }
 795                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 796
 797                 for (my $index = $start; $index < 256; $index++) {
 798                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 799                         if ($subloc) {
 800                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 801                                 if (defined($result)) { return $result; }
 802                         }
 803                 } # index loop
 804
 805                 $self->{return_next} = 1;
 806         } # tag is an index
 807
 808         elsif ($tag->{signature} eq SIG_BLIST) {
 809                 my $keys = $tag->{content};
 810                 if ($force_return_next) { $self->{return_next} = 1; }
 811
 812                 ##
 813                 # Iterate through buckets, looking for a key match
 814                 ##
 815                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 816                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 817                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 818
 819                         if (!$subloc) {
 820                                 ##
 821                                 # End of bucket list -- return to outer loop
 822                                 ##
 823                                 $self->{return_next} = 1;
 824                                 last;
 825                         }
 826                         elsif ($key eq $self->{prev_md5}) {
 827                                 ##
 828                                 # Located previous key -- return next one found
 829                                 ##
 830                                 $self->{return_next} = 1;
 831                                 next;
 832                         }
 833                         elsif ($self->{return_next}) {
 834                                 ##
 835                                 # Seek to bucket location and skip over signature
 836                                 ##
 837                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 838
 839                                 ##
 840                                 # Skip over value to get to plain key
 841                                 ##
 842                                 my $size;
 843                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 844                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 845
 846                                 ##
 847                                 # Read in plain key and return as scalar
 848                                 ##
 849                                 my $plain_key;
 850                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 851                                 if ($size) { read( $fh, $plain_key, $size); }
 852
 853                                 return $plain_key;
 854                         }
 855                 } # bucket loop
 856
 857                 $self->{return_next} = 1;
 858         } # tag is a bucket list
 859
 860         return;
 861 }
 862
 863 sub _get_next_key {
 864         ##
 865         # Locate next key, given digested previous one
 866         ##
 867     my $self = $_[0]->_get_self;
 868
 869         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 870         $self->{return_next} = 0;
 871
 872         ##
 873         # If the previous key was not specifed, start at the top and
 874         # return the first one found.
 875         ##
 876         if (!$self->{prev_md5}) {
 877                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 878                 $self->{return_next} = 1;
 879         }
 880
 881         return $self->_traverse_index( $self->base_offset, 0 );
 882 }
 883
 884 sub lock {
 885         ##
 886         # If db locking is set, flock() the db file.  If called multiple
 887         # times before unlock(), then the same number of unlocks() must
 888         # be called before the lock is released.
 889         ##
 890     my $self = $_[0]->_get_self;
 891         my $type = $_[1];
 892     $type = LOCK_EX unless defined $type;
 893
 894         if ($self->root->{locking}) {
 895                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 896                 $self->root->{locked}++;
 897
 898         return 1;
 899         }
 900
 901     return;
 902 }
 903
 904 sub unlock {
 905         ##
 906         # If db locking is set, unlock the db file.  See note in lock()
 907         # regarding calling lock() multiple times.
 908         ##
 909     my $self = $_[0]->_get_self;
 910
 911         if ($self->root->{locking} && $self->root->{locked} > 0) {
 912                 $self->root->{locked}--;
 913                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 914
 915         return 1;
 916         }
 917
 918     return;
 919 }
 920
 921 #XXX These uses of ref() need verified
 922 sub _copy_node {
 923         ##
 924         # Copy single level of keys or elements to new DB handle.
 925         # Recurse for nested structures
 926         ##
 927     my $self = $_[0]->_get_self;
 928         my $db_temp = $_[1];
 929
 930         if ($self->type eq TYPE_HASH) {
 931                 my $key = $self->first_key();
 932                 while ($key) {
 933                         my $value = $self->get($key);
 934 #XXX This doesn't work with autobless
 935                         if (!ref($value)) { $db_temp->{$key} = $value; }
 936                         else {
 937                                 my $type = $value->type;
 938                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 939                                 else { $db_temp->{$key} = []; }
 940                                 $value->_copy_node( $db_temp->{$key} );
 941                         }
 942                         $key = $self->next_key($key);
 943                 }
 944         }
 945         else {
 946                 my $length = $self->length();
 947                 for (my $index = 0; $index < $length; $index++) {
 948                         my $value = $self->get($index);
 949                         if (!ref($value)) { $db_temp->[$index] = $value; }
 950             #XXX NO tests for this code
 951                         else {
 952                                 my $type = $value->type;
 953                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 954                                 else { $db_temp->[$index] = []; }
 955                                 $value->_copy_node( $db_temp->[$index] );
 956                         }
 957                 }
 958         }
 959 }
 960
 961 sub export {
 962         ##
 963         # Recursively export into standard Perl hashes and arrays.
 964         ##
 965     my $self = $_[0]->_get_self;
 966
 967         my $temp;
 968         if ($self->type eq TYPE_HASH) { $temp = {}; }
 969         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 970
 971         $self->lock();
 972         $self->_copy_node( $temp );
 973         $self->unlock();
 974
 975         return $temp;
 976 }
 977
 978 sub import {
 979         ##
 980         # Recursively import Perl hash/array structure
 981         ##
 982     #XXX This use of ref() seems to be ok
 983         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 984
 985     my $self = $_[0]->_get_self;
 986         my $struct = $_[1];
 987
 988     #XXX This use of ref() seems to be ok
 989         if (!ref($struct)) {
 990                 ##
 991                 # struct is not a reference, so just import based on our type
 992                 ##
 993                 shift @_;
 994
 995                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
 996                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
 997         }
 998
 999     my $r = Scalar::Util::reftype($struct) || '';
1000         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1001                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1002         }
1003         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1004                 $self->push( @$struct );
1005         }
1006         else {
1007                 return $self->_throw_error("Cannot import: type mismatch");
1008         }
1009
1010         return 1;
1011 }
1012
1013 sub optimize {
1014         ##
1015         # Rebuild entire database into new file, then move
1016         # it back on top of original.
1017         ##
1018     my $self = $_[0]->_get_self;
1019
1020 #XXX Need to create a new test for this
1021 #       if ($self->root->{links} > 1) {
1022 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1023 #       }
1024
1025         my $db_temp = DBM::Deep->new(
1026                 file => $self->root->{file} . '.tmp',
1027                 type => $self->type
1028         );
1029         if (!$db_temp) {
1030                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1031         }
1032
1033         $self->lock();
1034         $self->_copy_node( $db_temp );
1035         undef $db_temp;
1036
1037         ##
1038         # Attempt to copy user, group and permissions over to new file
1039         ##
1040         my @stats = stat($self->fh);
1041         my $perms = $stats[2] & 07777;
1042         my $uid = $stats[4];
1043         my $gid = $stats[5];
1044         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1045         chmod( $perms, $self->root->{file} . '.tmp' );
1046
1047     # q.v. perlport for more information on this variable
1048     if ( $^O eq 'MSWin32' ) {
1049                 ##
1050                 # Potential race condition when optmizing on Win32 with locking.
1051                 # The Windows filesystem requires that the filehandle be closed
1052                 # before it is overwritten with rename().  This could be redone
1053                 # with a soft copy.
1054                 ##
1055                 $self->unlock();
1056                 $self->_close();
1057         }
1058
1059         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1060                 unlink $self->root->{file} . '.tmp';
1061                 $self->unlock();
1062                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1063         }
1064
1065         $self->unlock();
1066         $self->_close();
1067         $self->_open();
1068
1069         return 1;
1070 }
1071
1072 sub clone {
1073         ##
1074         # Make copy of object and return
1075         ##
1076     my $self = $_[0]->_get_self;
1077
1078         return DBM::Deep->new(
1079                 type => $self->type,
1080                 base_offset => $self->base_offset,
1081                 root => $self->root
1082         );
1083 }
1084
1085 {
1086     my %is_legal_filter = map {
1087         $_ => ~~1,
1088     } qw(
1089         store_key store_value
1090         fetch_key fetch_value
1091     );
1092
1093     sub set_filter {
1094         ##
1095         # Setup filter function for storing or fetching the key or value
1096         ##
1097         my $self = $_[0]->_get_self;
1098         my $type = lc $_[1];
1099         my $func = $_[2] ? $_[2] : undef;
1100
1101         if ( $is_legal_filter{$type} ) {
1102             $self->root->{"filter_$type"} = $func;
1103             return 1;
1104         }
1105
1106         return;
1107     }
1108 }
1109
1110 ##
1111 # Accessor methods
1112 ##
1113
1114 sub root {
1115         ##
1116         # Get access to the root structure
1117         ##
1118     my $self = $_[0]->_get_self;
1119         return $self->{root};
1120 }
1121
1122 sub fh {
1123         ##
1124         # Get access to the raw FileHandle
1125         ##
1126     #XXX It will be useful, though, when we split out HASH and ARRAY
1127     my $self = $_[0]->_get_self;
1128         return $self->root->{fh};
1129 }
1130
1131 sub type {
1132         ##
1133         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1134         ##
1135     my $self = $_[0]->_get_self;
1136         return $self->{type};
1137 }
1138
1139 sub base_offset {
1140         ##
1141         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1142         ##
1143     my $self = $_[0]->_get_self;
1144         return $self->{base_offset};
1145 }
1146
1147 sub error {
1148         ##
1149         # Get last error string, or undef if no error
1150         ##
1151         return $_[0]
1152         #? ( _get_self($_[0])->{root}->{error} or undef )
1153         ? ( $_[0]->_get_self->{root}->{error} or undef )
1154         : $@;
1155 }
1156
1157 ##
1158 # Utility methods
1159 ##
1160
1161 sub _throw_error {
1162         ##
1163         # Store error string in self
1164         ##
1165     my $self = $_[0]->_get_self;
1166         my $error_text = $_[1];
1167
1168         $self->root->{error} = $error_text;
1169
1170         unless ($self->root->{debug}) {
1171         die "DBM::Deep: $error_text\n";
1172     }
1173
1174     warn "DBM::Deep: $error_text\n";
1175         return;
1176 }
1177
1178 sub clear_error {
1179         ##
1180         # Clear error state
1181         ##
1182     my $self = $_[0]->_get_self;
1183
1184         undef $self->root->{error};
1185 }
1186
1187 sub precalc_sizes {
1188         ##
1189         # Precalculate index, bucket and bucket list sizes
1190         ##
1191
1192     #XXX I don't like this ...
1193     set_pack() unless defined $LONG_SIZE;
1194
1195         $INDEX_SIZE = 256 * $LONG_SIZE;
1196         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1197         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1198 }
1199
1200 sub set_pack {
1201         ##
1202         # Set pack/unpack modes (see file header for more)
1203         ##
1204     my ($long_s, $long_p, $data_s, $data_p) = @_;
1205
1206     $LONG_SIZE = $long_s ? $long_s : 4;
1207     $LONG_PACK = $long_p ? $long_p : 'N';
1208
1209     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1210     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1211
1212         precalc_sizes();
1213 }
1214
1215 sub set_digest {
1216         ##
1217         # Set key digest function (default is MD5)
1218         ##
1219     my ($digest_func, $hash_size) = @_;
1220
1221     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1222     $HASH_SIZE = $hash_size ? $hash_size : 16;
1223
1224         precalc_sizes();
1225 }
1226
1227 ##
1228 # tie() methods (hashes and arrays)
1229 ##
1230
1231 sub STORE {
1232         ##
1233         # Store single hash key/value or array element in database.
1234         ##
1235     my $self = $_[0]->_get_self;
1236         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1237     #XXX What is ref() checking here?
1238     #YYY User may be storing a hash, in which case we do not want it run
1239     #YYY through the filtering system
1240         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1241
1242         my $unpacked_key = $key;
1243         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1244         my $md5 = $DIGEST_FUNC->($key);
1245
1246         ##
1247         # Make sure file is open
1248         ##
1249         if (!defined($self->fh) && !$self->_open()) {
1250                 return;
1251         }
1252         ##
1253
1254     my $fh = $self->fh;
1255
1256         ##
1257         # Request exclusive lock for writing
1258         ##
1259         $self->lock( LOCK_EX );
1260
1261         ##
1262         # If locking is enabled, set 'end' parameter again, in case another
1263         # DB instance appended to our file while we were unlocked.
1264         ##
1265         if ($self->root->{locking} || $self->root->{volatile}) {
1266                 $self->root->{end} = (stat($fh))[7];
1267         }
1268
1269         ##
1270         # Locate offset for bucket list using digest index system
1271         ##
1272         my $tag = $self->_load_tag($self->base_offset);
1273         if (!$tag) {
1274                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1275         }
1276
1277         my $ch = 0;
1278         while ($tag->{signature} ne SIG_BLIST) {
1279                 my $num = ord(substr($md5, $ch, 1));
1280                 my $new_tag = $self->_index_lookup($tag, $num);
1281                 if (!$new_tag) {
1282                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1283                         seek($fh, $ref_loc, SEEK_SET);
1284                         print($fh pack($LONG_PACK, $self->root->{end}) );
1285
1286                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1287                         $tag->{ref_loc} = $ref_loc;
1288                         $tag->{ch} = $ch;
1289                         last;
1290                 }
1291                 else {
1292                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1293                         $tag = $new_tag;
1294                         $tag->{ref_loc} = $ref_loc;
1295                         $tag->{ch} = $ch;
1296                 }
1297                 $ch++;
1298         }
1299
1300         ##
1301         # Add key/value to bucket list
1302         ##
1303         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1304
1305         ##
1306         # If this object is an array, and bucket was not a replace, and key is numerical,
1307         # and index is equal or greater than current length, advance length variable.
1308         ##
1309         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1310                 $self->STORESIZE( $unpacked_key + 1 );
1311         }
1312
1313         $self->unlock();
1314
1315         return $result;
1316 }
1317
1318 sub FETCH {
1319         ##
1320         # Fetch single value or element given plain key or array index
1321         ##
1322     my $self = $_[0]->_get_self;
1323
1324     my $key = $_[1];
1325     if ( $self->type eq TYPE_HASH ) {
1326         if ( my $filter = $self->root->{filter_store_key} ) {
1327             $key = $filter->( $key );
1328         }
1329     }
1330     elsif ( $self->type eq TYPE_ARRAY ) {
1331         if ( $key =~ /^\d+$/ ) {
1332             $key = pack($LONG_PACK, $key);
1333         }
1334     }
1335
1336         my $md5 = $DIGEST_FUNC->($key);
1337
1338         ##
1339         # Make sure file is open
1340         ##
1341         if (!defined($self->fh)) { $self->_open(); }
1342
1343         ##
1344         # Request shared lock for reading
1345         ##
1346         $self->lock( LOCK_SH );
1347
1348         my $tag = $self->_find_bucket_list( $md5 );
1349         if (!$tag) {
1350                 $self->unlock();
1351                 return;
1352         }
1353
1354         ##
1355         # Get value from bucket list
1356         ##
1357         my $result = $self->_get_bucket_value( $tag, $md5 );
1358
1359         $self->unlock();
1360
1361     #XXX What is ref() checking here?
1362         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1363 }
1364
1365 sub DELETE {
1366         ##
1367         # Delete single key/value pair or element given plain key or array index
1368         ##
1369     my $self = $_[0]->_get_self;
1370         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1371
1372         my $unpacked_key = $key;
1373         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1374         my $md5 = $DIGEST_FUNC->($key);
1375
1376         ##
1377         # Make sure file is open
1378         ##
1379         if (!defined($self->fh)) { $self->_open(); }
1380
1381         ##
1382         # Request exclusive lock for writing
1383         ##
1384         $self->lock( LOCK_EX );
1385
1386         my $tag = $self->_find_bucket_list( $md5 );
1387         if (!$tag) {
1388                 $self->unlock();
1389                 return;
1390         }
1391
1392         ##
1393         # Delete bucket
1394         ##
1395         my $result = $self->_delete_bucket( $tag, $md5 );
1396
1397         ##
1398         # If this object is an array and the key deleted was on the end of the stack,
1399         # decrement the length variable.
1400         ##
1401         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1402                 $self->STORESIZE( $unpacked_key );
1403         }
1404
1405         $self->unlock();
1406
1407         return $result;
1408 }
1409
1410 sub EXISTS {
1411         ##
1412         # Check if a single key or element exists given plain key or array index
1413         ##
1414     my $self = $_[0]->_get_self;
1415         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1416
1417         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1418         my $md5 = $DIGEST_FUNC->($key);
1419
1420         ##
1421         # Make sure file is open
1422         ##
1423         if (!defined($self->fh)) { $self->_open(); }
1424
1425         ##
1426         # Request shared lock for reading
1427         ##
1428         $self->lock( LOCK_SH );
1429
1430         my $tag = $self->_find_bucket_list( $md5 );
1431
1432         ##
1433         # For some reason, the built-in exists() function returns '' for false
1434         ##
1435         if (!$tag) {
1436                 $self->unlock();
1437                 return '';
1438         }
1439
1440         ##
1441         # Check if bucket exists and return 1 or ''
1442         ##
1443         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1444
1445         $self->unlock();
1446
1447         return $result;
1448 }
1449
1450 sub CLEAR {
1451         ##
1452         # Clear all keys from hash, or all elements from array.
1453         ##
1454     my $self = $_[0]->_get_self;
1455
1456         ##
1457         # Make sure file is open
1458         ##
1459         if (!defined($self->fh)) { $self->_open(); }
1460
1461         ##
1462         # Request exclusive lock for writing
1463         ##
1464         $self->lock( LOCK_EX );
1465
1466     my $fh = $self->fh;
1467
1468         seek($fh, $self->base_offset, SEEK_SET);
1469         if (eof $fh) {
1470                 $self->unlock();
1471                 return;
1472         }
1473
1474         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1475
1476         $self->unlock();
1477
1478         return 1;
1479 }
1480
1481 ##
1482 # Public method aliases
1483 ##
1484 *put = *store = *STORE;
1485 *get = *fetch = *FETCH;
1486 *delete = *DELETE;
1487 *exists = *EXISTS;
1488 *clear = *CLEAR;
1489
1490 package DBM::Deep::_::Root;
1491
1492 sub new {
1493     my $class = shift;
1494     my ($args) = @_;
1495
1496     my $self = bless {
1497         file => undef,
1498         fh => undef,
1499         end => 0,
1500         autoflush => undef,
1501         locking => undef,
1502         volatile => undef,
1503         debug => undef,
1504         mode => 'r+',
1505         filter_store_key => undef,
1506         filter_store_value => undef,
1507         filter_fetch_key => undef,
1508         filter_fetch_value => undef,
1509         autobless => undef,
1510         locked => 0,
1511         %$args,
1512     }, $class;
1513
1514     return $self;
1515 }
1516
1517 sub DESTROY {
1518     my $self = shift;
1519     return unless $self;
1520
1521     close $self->{fh} if $self->{fh};
1522
1523     return;
1524 }
1525
1526 1;
1527
1528 __END__
1529
1530 =head1 NAME
1531
1532 DBM::Deep - A pure perl multi-level hash/array DBM
1533
1534 =head1 SYNOPSIS
1535
1536   use DBM::Deep;
1537   my $db = DBM::Deep->new( "foo.db" );
1538
1539   $db->{key} = 'value'; # tie() style
1540   print $db->{key};
1541
1542   $db->put('key', 'value'); # OO style
1543   print $db->get('key');
1544
1545   # true multi-level support
1546   $db->{my_complex} = [
1547         'hello', { perl => 'rules' },
1548         42, 99 ];
1549
1550 =head1 DESCRIPTION
1551
1552 A unique flat-file database module, written in pure perl.  True
1553 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1554 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1555 handle millions of keys and unlimited hash levels without significant
1556 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1557 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1558 Mac OS X and Windows.
1559
1560 =head1 INSTALLATION
1561
1562 Hopefully you are using CPAN's excellent Perl module, which will download
1563 and install the module for you.  If not, get the tarball, and run these
1564 commands:
1565
1566         tar zxf DBM-Deep-*
1567         cd DBM-Deep-*
1568         perl Makefile.PL
1569         make
1570         make test
1571         make install
1572
1573 =head1 SETUP
1574
1575 Construction can be done OO-style (which is the recommended way), or using
1576 Perl's tie() function.  Both are examined here.
1577
1578 =head2 OO CONSTRUCTION
1579
1580 The recommended way to construct a DBM::Deep object is to use the new()
1581 method, which gets you a blessed, tied hash or array reference.
1582
1583         my $db = DBM::Deep->new( "foo.db" );
1584
1585 This opens a new database handle, mapped to the file "foo.db".  If this
1586 file does not exist, it will automatically be created.  DB files are
1587 opened in "r+" (read/write) mode, and the type of object returned is a
1588 hash, unless otherwise specified (see L<OPTIONS> below).
1589
1590
1591
1592 You can pass a number of options to the constructor to specify things like
1593 locking, autoflush, etc.  This is done by passing an inline hash:
1594
1595         my $db = DBM::Deep->new(
1596                 file => "foo.db",
1597                 locking => 1,
1598                 autoflush => 1
1599         );
1600
1601 Notice that the filename is now specified I<inside> the hash with
1602 the "file" parameter, as opposed to being the sole argument to the
1603 constructor.  This is required if any options are specified.
1604 See L<OPTIONS> below for the complete list.
1605
1606
1607
1608 You can also start with an array instead of a hash.  For this, you must
1609 specify the C<type> parameter:
1610
1611         my $db = DBM::Deep->new(
1612                 file => "foo.db",
1613                 type => DBM::Deep->TYPE_ARRAY
1614         );
1615
1616 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1617 a new DB file.  If you create a DBM::Deep object with an existing file, the
1618 C<type> will be loaded from the file header, and ignored if it is passed
1619 to the constructor.
1620
1621 =head2 TIE CONSTRUCTION
1622
1623 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1624 tie() function.  This is not ideal, because you get only a basic, tied hash
1625 (or array) which is not blessed, so you can't call any functions on it.
1626
1627         my %hash;
1628         tie %hash, "DBM::Deep", "foo.db";
1629
1630         my @array;
1631         tie @array, "DBM::Deep", "bar.db";
1632
1633 As with the OO constructor, you can replace the DB filename parameter with
1634 a hash containing one or more options (see L<OPTIONS> just below for the
1635 complete list).
1636
1637         tie %hash, "DBM::Deep", {
1638                 file => "foo.db",
1639                 locking => 1,
1640                 autoflush => 1
1641         };
1642
1643 =head2 OPTIONS
1644
1645 There are a number of options that can be passed in when constructing your
1646 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1647
1648 =over
1649
1650 =item * file
1651
1652 Filename of the DB file to link the handle to.  You can pass a full absolute
1653 filesystem path, partial path, or a plain filename if the file is in the
1654 current working directory.  This is a required parameter.
1655
1656 =item * mode
1657
1658 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1659 module.  This is an optional parameter, and defaults to "r+" (read/write).
1660 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1661 created if it doesn't exist.
1662
1663 =item * type
1664
1665 This parameter specifies what type of object to create, a hash or array.  Use
1666 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1667 This only takes effect when beginning a new file.  This is an optional
1668 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1669
1670 =item * locking
1671
1672 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1673 function to lock the database in exclusive mode for writes, and shared mode for
1674 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1675 any child hashes or arrays> that use the same DB file.  This is an optional
1676 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1677
1678 =item * autoflush
1679
1680 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1681 This obviously slows down write operations, but is required if you may have
1682 multiple processes accessing the same DB file (also consider enable I<locking>
1683 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1684 parameter, and defaults to 0 (disabled).
1685
1686 =item * volatile
1687
1688 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1689 STORE() operation.  This is required if an outside force may change the size of
1690 the file between transactions.  Locking also implicitly enables volatile.  This
1691 is useful if you want to use a different locking system or write your own.  Pass
1692 any true value to enable.  This is an optional parameter, and defaults to 0
1693 (disabled).
1694
1695 =item * autobless
1696
1697 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1698 restore them when fetched.  This is an B<experimental> feature, and does have
1699 side-effects.  Basically, when hashes are re-blessed into their original
1700 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1701 able to call any DBM::Deep methods on them.  You have been warned.
1702 This is an optional parameter, and defaults to 0 (disabled).
1703
1704 =item * filter_*
1705
1706 See L<FILTERS> below.
1707
1708 =item * debug
1709
1710 Setting I<debug> mode will make all errors non-fatal, dump them out to
1711 STDERR, and continue on.  This is for debugging purposes only, and probably
1712 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1713
1714 =item * fh
1715
1716 Instead of passing a file path, you can instead pass a handle to an pre-opened
1717 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1718 contains your entire Perl script, as well as the data following the __DATA__
1719 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1720 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1721 in that.
1722
1723 =back
1724
1725 =head1 TIE INTERFACE
1726
1727 With DBM::Deep you can access your databases using Perl's standard hash/array
1728 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1729 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1730 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1731 section above.  This simply tells you how to use DBM::Deep using regular hashes
1732 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1733 work too).  It is entirely up to you how to want to access your databases.
1734
1735 =head2 HASHES
1736
1737 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1738 or even nested hashes (or arrays) using standard Perl syntax:
1739
1740         my $db = DBM::Deep->new( "foo.db" );
1741
1742         $db->{mykey} = "myvalue";
1743         $db->{myhash} = {};
1744         $db->{myhash}->{subkey} = "subvalue";
1745
1746         print $db->{myhash}->{subkey} . "\n";
1747
1748 You can even step through hash keys using the normal Perl C<keys()> function:
1749
1750         foreach my $key (keys %$db) {
1751                 print "$key: " . $db->{$key} . "\n";
1752         }
1753
1754 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1755 pushes them onto an array, all before the loop even begins.  If you have an
1756 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1757 Perl's C<each()> function, which pulls keys/values one at a time, using very
1758 little memory:
1759
1760         while (my ($key, $value) = each %$db) {
1761                 print "$key: $value\n";
1762         }
1763
1764 Please note that when using C<each()>, you should always pass a direct
1765 hash reference, not a lookup.  Meaning, you should B<never> do this:
1766
1767         # NEVER DO THIS
1768         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1769
1770 This causes an infinite loop, because for each iteration, Perl is calling
1771 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1772 it effectively keeps returning the first key over and over again. Instead,
1773 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1774
1775 =head2 ARRAYS
1776
1777 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1778 reference.  This includes inserting, removing and manipulating elements,
1779 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1780 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1781 or simply be a nested array reference inside a hash.  Example:
1782
1783         my $db = DBM::Deep->new(
1784                 file => "foo-array.db",
1785                 type => DBM::Deep->TYPE_ARRAY
1786         );
1787
1788         $db->[0] = "foo";
1789         push @$db, "bar", "baz";
1790         unshift @$db, "bah";
1791
1792         my $last_elem = pop @$db; # baz
1793         my $first_elem = shift @$db; # bah
1794         my $second_elem = $db->[1]; # bar
1795
1796         my $num_elements = scalar @$db;
1797
1798 =head1 OO INTERFACE
1799
1800 In addition to the I<tie()> interface, you can also use a standard OO interface
1801 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1802 array) has its own methods, but both types share the following common methods:
1803 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1804
1805 =over
1806
1807 =item * put()
1808
1809 Stores a new hash key/value pair, or sets an array element value.  Takes two
1810 arguments, the hash key or array index, and the new value.  The value can be
1811 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1812
1813         $db->put("foo", "bar"); # for hashes
1814         $db->put(1, "bar"); # for arrays
1815
1816 =item * get()
1817
1818 Fetches the value of a hash key or array element.  Takes one argument: the hash
1819 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1820 data type stored.
1821
1822         my $value = $db->get("foo"); # for hashes
1823         my $value = $db->get(1); # for arrays
1824
1825 =item * exists()
1826
1827 Checks if a hash key or array index exists.  Takes one argument: the hash key
1828 or array index.  Returns true if it exists, false if not.
1829
1830         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1831         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1832
1833 =item * delete()
1834
1835 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1836 key or array index.  Returns true on success, false if not found.  For arrays,
1837 the remaining elements located after the deleted element are NOT moved over.
1838 The deleted element is essentially just undefined, which is exactly how Perl's
1839 internal arrays work.  Please note that the space occupied by the deleted
1840 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1841 below for details and workarounds.
1842
1843         $db->delete("foo"); # for hashes
1844         $db->delete(1); # for arrays
1845
1846 =item * clear()
1847
1848 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1849 value.  Please note that the space occupied by the deleted keys/values or
1850 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1851 details and workarounds.
1852
1853         $db->clear(); # hashes or arrays
1854
1855 =back
1856
1857 =head2 HASHES
1858
1859 For hashes, DBM::Deep supports all the common methods described above, and the
1860 following additional methods: C<first_key()> and C<next_key()>.
1861
1862 =over
1863
1864 =item * first_key()
1865
1866 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1867 fetched in an undefined order (which appears random).  Takes no arguments,
1868 returns the key as a scalar value.
1869
1870         my $key = $db->first_key();
1871
1872 =item * next_key()
1873
1874 Returns the "next" key in the hash, given the previous one as the sole argument.
1875 Returns undef if there are no more keys to be fetched.
1876
1877         $key = $db->next_key($key);
1878
1879 =back
1880
1881 Here are some examples of using hashes:
1882
1883         my $db = DBM::Deep->new( "foo.db" );
1884
1885         $db->put("foo", "bar");
1886         print "foo: " . $db->get("foo") . "\n";
1887
1888         $db->put("baz", {}); # new child hash ref
1889         $db->get("baz")->put("buz", "biz");
1890         print "buz: " . $db->get("baz")->get("buz") . "\n";
1891
1892         my $key = $db->first_key();
1893         while ($key) {
1894                 print "$key: " . $db->get($key) . "\n";
1895                 $key = $db->next_key($key);
1896         }
1897
1898         if ($db->exists("foo")) { $db->delete("foo"); }
1899
1900 =head2 ARRAYS
1901
1902 For arrays, DBM::Deep supports all the common methods described above, and the
1903 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1904 C<unshift()> and C<splice()>.
1905
1906 =over
1907
1908 =item * length()
1909
1910 Returns the number of elements in the array.  Takes no arguments.
1911
1912         my $len = $db->length();
1913
1914 =item * push()
1915
1916 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1917 refs or array refs.  No return value.
1918
1919         $db->push("foo", "bar", {});
1920
1921 =item * pop()
1922
1923 Fetches the last element in the array, and deletes it.  Takes no arguments.
1924 Returns undef if array is empty.  Returns the element value.
1925
1926         my $elem = $db->pop();
1927
1928 =item * shift()
1929
1930 Fetches the first element in the array, deletes it, then shifts all the
1931 remaining elements over to take up the space.  Returns the element value.  This
1932 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1933 details.
1934
1935         my $elem = $db->shift();
1936
1937 =item * unshift()
1938
1939 Inserts one or more elements onto the beginning of the array, shifting all
1940 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1941 No return value.  This method is not recommended with large arrays -- see
1942 <LARGE ARRAYS> below for details.
1943
1944         $db->unshift("foo", "bar", {});
1945
1946 =item * splice()
1947
1948 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1949 -f splice> for usage -- it is too complicated to document here.  This method is
1950 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1951
1952 =back
1953
1954 Here are some examples of using arrays:
1955
1956         my $db = DBM::Deep->new(
1957                 file => "foo.db",
1958                 type => DBM::Deep->TYPE_ARRAY
1959         );
1960
1961         $db->push("bar", "baz");
1962         $db->unshift("foo");
1963         $db->put(3, "buz");
1964
1965         my $len = $db->length();
1966         print "length: $len\n"; # 4
1967
1968         for (my $k=0; $k<$len; $k++) {
1969                 print "$k: " . $db->get($k) . "\n";
1970         }
1971
1972         $db->splice(1, 2, "biz", "baf");
1973
1974         while (my $elem = shift @$db) {
1975                 print "shifted: $elem\n";
1976         }
1977
1978 =head1 LOCKING
1979
1980 Enable automatic file locking by passing a true value to the C<locking>
1981 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1982
1983         my $db = DBM::Deep->new(
1984                 file => "foo.db",
1985                 locking => 1
1986         );
1987
1988 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1989 mode for writes, and shared mode for reads.  This is required if you have
1990 multiple processes accessing the same database file, to avoid file corruption.
1991 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1992 NFS> below for more.
1993
1994 =head2 EXPLICIT LOCKING
1995
1996 You can explicitly lock a database, so it remains locked for multiple
1997 transactions.  This is done by calling the C<lock()> method, and passing an
1998 optional lock mode argument (defaults to exclusive mode).  This is particularly
1999 useful for things like counters, where the current value needs to be fetched,
2000 then incremented, then stored again.
2001
2002         $db->lock();
2003         my $counter = $db->get("counter");
2004         $counter++;
2005         $db->put("counter", $counter);
2006         $db->unlock();
2007
2008         # or...
2009
2010         $db->lock();
2011         $db->{counter}++;
2012         $db->unlock();
2013
2014 You can pass C<lock()> an optional argument, which specifies which mode to use
2015 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2016 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2017 same as the constants defined in Perl's C<Fcntl> module.
2018
2019         $db->lock( DBM::Deep->LOCK_SH );
2020         # something here
2021         $db->unlock();
2022
2023 If you want to implement your own file locking scheme, be sure to create your
2024 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2025 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2026 below for more.
2027
2028 =head1 IMPORTING/EXPORTING
2029
2030 You can import existing complex structures by calling the C<import()> method,
2031 and export an entire database into an in-memory structure using the C<export()>
2032 method.  Both are examined here.
2033
2034 =head2 IMPORTING
2035
2036 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2037 walking the structure and adding keys/elements to the database as you go,
2038 simply pass a reference to the C<import()> method.  This recursively adds
2039 everything to an existing DBM::Deep object for you.  Here is an example:
2040
2041         my $struct = {
2042                 key1 => "value1",
2043                 key2 => "value2",
2044                 array1 => [ "elem0", "elem1", "elem2" ],
2045                 hash1 => {
2046                         subkey1 => "subvalue1",
2047                         subkey2 => "subvalue2"
2048                 }
2049         };
2050
2051         my $db = DBM::Deep->new( "foo.db" );
2052         $db->import( $struct );
2053
2054         print $db->{key1} . "\n"; # prints "value1"
2055
2056 This recursively imports the entire C<$struct> object into C<$db>, including
2057 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2058 keys are merged with the existing ones, replacing if they already exist.
2059 The C<import()> method can be called on any database level (not just the base
2060 level), and works with both hash and array DB types.
2061
2062
2063
2064 B<Note:> Make sure your existing structure has no circular references in it.
2065 These will cause an infinite loop when importing.
2066
2067 =head2 EXPORTING
2068
2069 Calling the C<export()> method on an existing DBM::Deep object will return
2070 a reference to a new in-memory copy of the database.  The export is done
2071 recursively, so all nested hashes/arrays are all exported to standard Perl
2072 objects.  Here is an example:
2073
2074         my $db = DBM::Deep->new( "foo.db" );
2075
2076         $db->{key1} = "value1";
2077         $db->{key2} = "value2";
2078         $db->{hash1} = {};
2079         $db->{hash1}->{subkey1} = "subvalue1";
2080         $db->{hash1}->{subkey2} = "subvalue2";
2081
2082         my $struct = $db->export();
2083
2084         print $struct->{key1} . "\n"; # prints "value1"
2085
2086 This makes a complete copy of the database in memory, and returns a reference
2087 to it.  The C<export()> method can be called on any database level (not just
2088 the base level), and works with both hash and array DB types.  Be careful of
2089 large databases -- you can store a lot more data in a DBM::Deep object than an
2090 in-memory Perl structure.
2091
2092
2093
2094 B<Note:> Make sure your database has no circular references in it.
2095 These will cause an infinite loop when exporting.
2096
2097 =head1 FILTERS
2098
2099 DBM::Deep has a number of hooks where you can specify your own Perl function
2100 to perform filtering on incoming or outgoing data.  This is a perfect
2101 way to extend the engine, and implement things like real-time compression or
2102 encryption.  Filtering applies to the base DB level, and all child hashes /
2103 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2104 constructed, or by calling the C<set_filter()> method at any time.  There are
2105 four available filter hooks, described below:
2106
2107 =over
2108
2109 =item * filter_store_key
2110
2111 This filter is called whenever a hash key is stored.  It
2112 is passed the incoming key, and expected to return a transformed key.
2113
2114 =item * filter_store_value
2115
2116 This filter is called whenever a hash key or array element is stored.  It
2117 is passed the incoming value, and expected to return a transformed value.
2118
2119 =item * filter_fetch_key
2120
2121 This filter is called whenever a hash key is fetched (i.e. via
2122 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2123 and expected to return the plain key.
2124
2125 =item * filter_fetch_value
2126
2127 This filter is called whenever a hash key or array element is fetched.
2128 It is passed the transformed value, and expected to return the plain value.
2129
2130 =back
2131
2132 Here are the two ways to setup a filter hook:
2133
2134         my $db = DBM::Deep->new(
2135                 file => "foo.db",
2136                 filter_store_value => \&my_filter_store,
2137                 filter_fetch_value => \&my_filter_fetch
2138         );
2139
2140         # or...
2141
2142         $db->set_filter( "filter_store_value", \&my_filter_store );
2143         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2144
2145 Your filter function will be called only when dealing with SCALAR keys or
2146 values.  When nested hashes and arrays are being stored/fetched, filtering
2147 is bypassed.  Filters are called as static functions, passed a single SCALAR
2148 argument, and expected to return a single SCALAR value.  If you want to
2149 remove a filter, set the function reference to C<undef>:
2150
2151         $db->set_filter( "filter_store_value", undef );
2152
2153 =head2 REAL-TIME ENCRYPTION EXAMPLE
2154
2155 Here is a working example that uses the I<Crypt::Blowfish> module to
2156 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2157 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2158 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2159
2160         use DBM::Deep;
2161         use Crypt::Blowfish;
2162         use Crypt::CBC;
2163
2164         my $cipher = Crypt::CBC->new({
2165                 'key'             => 'my secret key',
2166                 'cipher'          => 'Blowfish',
2167                 'iv'              => '$KJh#(}q',
2168                 'regenerate_key'  => 0,
2169                 'padding'         => 'space',
2170                 'prepend_iv'      => 0
2171         });
2172
2173         my $db = DBM::Deep->new(
2174                 file => "foo-encrypt.db",
2175                 filter_store_key => \&my_encrypt,
2176                 filter_store_value => \&my_encrypt,
2177                 filter_fetch_key => \&my_decrypt,
2178                 filter_fetch_value => \&my_decrypt,
2179         );
2180
2181         $db->{key1} = "value1";
2182         $db->{key2} = "value2";
2183         print "key1: " . $db->{key1} . "\n";
2184         print "key2: " . $db->{key2} . "\n";
2185
2186         undef $db;
2187         exit;
2188
2189         sub my_encrypt {
2190                 return $cipher->encrypt( $_[0] );
2191         }
2192         sub my_decrypt {
2193                 return $cipher->decrypt( $_[0] );
2194         }
2195
2196 =head2 REAL-TIME COMPRESSION EXAMPLE
2197
2198 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2199 compression / decompression of keys & values with DBM::Deep Filters.
2200 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2201 more on I<Compress::Zlib>.
2202
2203         use DBM::Deep;
2204         use Compress::Zlib;
2205
2206         my $db = DBM::Deep->new(
2207                 file => "foo-compress.db",
2208                 filter_store_key => \&my_compress,
2209                 filter_store_value => \&my_compress,
2210                 filter_fetch_key => \&my_decompress,
2211                 filter_fetch_value => \&my_decompress,
2212         );
2213
2214         $db->{key1} = "value1";
2215         $db->{key2} = "value2";
2216         print "key1: " . $db->{key1} . "\n";
2217         print "key2: " . $db->{key2} . "\n";
2218
2219         undef $db;
2220         exit;
2221
2222         sub my_compress {
2223                 return Compress::Zlib::memGzip( $_[0] ) ;
2224         }
2225         sub my_decompress {
2226                 return Compress::Zlib::memGunzip( $_[0] ) ;
2227         }
2228
2229 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2230 actually numerical index numbers, and are not filtered.
2231
2232 =head1 ERROR HANDLING
2233
2234 Most DBM::Deep methods return a true value for success, and call die() on
2235 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2236 actual error message is stored in an internal scalar, which can be fetched by
2237 calling the C<error()> method.
2238
2239         my $db = DBM::Deep->new( "foo.db" ); # create hash
2240         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2241
2242         print $db->error(); # prints error message
2243
2244 You can then call C<clear_error()> to clear the current error state.
2245
2246         $db->clear_error();
2247
2248 If you set the C<debug> option to true when creating your DBM::Deep object,
2249 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2250 for debugging purposes.
2251
2252 =head1 LARGEFILE SUPPORT
2253
2254 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2255 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2256 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2257 by calling the static C<set_pack()> method before you do anything else.
2258
2259         DBM::Deep::set_pack(8, 'Q');
2260
2261 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2262 instead of 32-bit longs.  After setting these values your DB files have a
2263 theoretical maximum size of 16 XB (exabytes).
2264
2265
2266
2267 B<Note:> Changing these values will B<NOT> work for existing database files.
2268 Only change this for new files, and make sure it stays set consistently
2269 throughout the file's life.  If you do set these values, you can no longer
2270 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2271 back to 32-bit mode.
2272
2273
2274
2275 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2276 only a 32-bit Perl.  However, I have received user reports that this does
2277 indeed work!
2278
2279 =head1 LOW-LEVEL ACCESS
2280
2281 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2282 you can call the C<fh()> method, which returns the handle:
2283
2284         my $fh = $db->fh();
2285
2286 This method can be called on the root level of the datbase, or any child
2287 hashes or arrays.  All levels share a I<root> structure, which contains things
2288 like the FileHandle, a reference counter, and all your options you specified
2289 when you created the object.  You can get access to this root structure by
2290 calling the C<root()> method.
2291
2292         my $root = $db->root();
2293
2294 This is useful for changing options after the object has already been created,
2295 such as enabling/disabling locking, volatile or debug modes.  You can also
2296 store your own temporary user data in this structure (be wary of name
2297 collision), which is then accessible from any child hash or array.
2298
2299 =head1 CUSTOM DIGEST ALGORITHM
2300
2301 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2302 keys.  However you can override this, and use another algorithm (such as SHA-256)
2303 or even write your own.  But please note that DBM::Deep currently expects zero
2304 collisions, so your algorithm has to be I<perfect>, so to speak.
2305 Collision detection may be introduced in a later version.
2306
2307
2308
2309 You can specify a custom digest algorithm by calling the static C<set_digest()>
2310 function, passing a reference to a subroutine, and the length of the algorithm's
2311 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2312 objects.  Here is a working example that uses a 256-bit hash from the
2313 I<Digest::SHA256> module.  Please see
2314 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2315
2316         use DBM::Deep;
2317         use Digest::SHA256;
2318
2319         my $context = Digest::SHA256::new(256);
2320
2321         DBM::Deep::set_digest( \&my_digest, 32 );
2322
2323         my $db = DBM::Deep->new( "foo-sha.db" );
2324
2325         $db->{key1} = "value1";
2326         $db->{key2} = "value2";
2327         print "key1: " . $db->{key1} . "\n";
2328         print "key2: " . $db->{key2} . "\n";
2329
2330         undef $db;
2331         exit;
2332
2333         sub my_digest {
2334                 return substr( $context->hash($_[0]), 0, 32 );
2335         }
2336
2337 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2338 of bytes you specify in the C<set_digest()> function (in this case 32).
2339
2340 =head1 CIRCULAR REFERENCES
2341
2342 DBM::Deep has B<experimental> support for circular references.  Meaning you
2343 can have a nested hash key or array element that points to a parent object.
2344 This relationship is stored in the DB file, and is preserved between sessions.
2345 Here is an example:
2346
2347         my $db = DBM::Deep->new( "foo.db" );
2348
2349         $db->{foo} = "bar";
2350         $db->{circle} = $db; # ref to self
2351
2352         print $db->{foo} . "\n"; # prints "foo"
2353         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2354
2355 One catch is, passing the object to a function that recursively walks the
2356 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2357 C<export()> methods) will result in an infinite loop.  The other catch is,
2358 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2359 or C<next_key()> methods), you will get the I<target object's key>, not the
2360 ref's key.  This gets even more interesting with the above example, where
2361 the I<circle> key points to the base DB object, which technically doesn't
2362 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2363 special case.
2364
2365 =head1 CAVEATS / ISSUES / BUGS
2366
2367 This section describes all the known issues with DBM::Deep.  It you have found
2368 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2369
2370 =head2 UNUSED SPACE RECOVERY
2371
2372 One major caveat with DBM::Deep is that space occupied by existing keys and
2373 values is not recovered when they are deleted.  Meaning if you keep deleting
2374 and adding new keys, your file will continuously grow.  I am working on this,
2375 but in the meantime you can call the built-in C<optimize()> method from time to
2376 time (perhaps in a crontab or something) to recover all your unused space.
2377
2378         $db->optimize(); # returns true on success
2379
2380 This rebuilds the ENTIRE database into a new file, then moves it on top of
2381 the original.  The new file will have no unused space, thus it will take up as
2382 little disk space as possible.  Please note that this operation can take
2383 a long time for large files, and you need enough disk space to temporarily hold
2384 2 copies of your DB file.  The temporary file is created in the same directory
2385 as the original, named with a ".tmp" extension, and is deleted when the
2386 operation completes.  Oh, and if locking is enabled, the DB is automatically
2387 locked for the entire duration of the copy.
2388
2389
2390
2391 B<WARNING:> Only call optimize() on the top-level node of the database, and
2392 make sure there are no child references lying around.  DBM::Deep keeps a reference
2393 counter, and if it is greater than 1, optimize() will abort and return undef.
2394
2395 =head2 AUTOVIVIFICATION
2396
2397 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2398 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2399 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2400 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2401 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2402 this does not work:
2403
2404         $db->{foo}->{bar} = "hello";
2405
2406 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2407 being an empty hash.  Try this instead, which works fine:
2408
2409         $db->{foo} = { bar => "hello" };
2410
2411 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2412 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2413 Probably a bug in Perl.
2414
2415 =head2 FILE CORRUPTION
2416
2417 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2418 for a 32-bit signature when opened, but other corruption in files can cause
2419 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2420 stuck in an infinite loop depending on the level of corruption.  File write
2421 operations are not checked for failure (for speed), so if you happen to run
2422 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2423 be addressed in a later version of DBM::Deep.
2424
2425 =head2 DB OVER NFS
2426
2427 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2428 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2429 about setting up your NFS server with a locking daemon, then using lockf() to
2430 lock your files, but your milage may vary there as well.  From what I
2431 understand, there is no real way to do it.  However, if you need access to the
2432 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2433 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2434
2435 =head2 COPYING OBJECTS
2436
2437 Beware of copying tied objects in Perl.  Very strange things can happen.
2438 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2439 returns a new, blessed, tied hash or array to the same level in the DB.
2440
2441         my $copy = $db->clone();
2442
2443 =head2 LARGE ARRAYS
2444
2445 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2446 These functions cause every element in the array to move, which can be murder
2447 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2448 a different location.  This may be addressed in a later version.
2449
2450 =head1 PERFORMANCE
2451
2452 This section discusses DBM::Deep's speed and memory usage.
2453
2454 =head2 SPEED
2455
2456 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2457 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2458 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2459 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2460 with huge databases.  Here is some test data:
2461
2462         Adding 1,000,000 keys to new DB file...
2463
2464         At 100 keys, avg. speed is 2,703 keys/sec
2465         At 200 keys, avg. speed is 2,642 keys/sec
2466         At 300 keys, avg. speed is 2,598 keys/sec
2467         At 400 keys, avg. speed is 2,578 keys/sec
2468         At 500 keys, avg. speed is 2,722 keys/sec
2469         At 600 keys, avg. speed is 2,628 keys/sec
2470         At 700 keys, avg. speed is 2,700 keys/sec
2471         At 800 keys, avg. speed is 2,607 keys/sec
2472         At 900 keys, avg. speed is 2,190 keys/sec
2473         At 1,000 keys, avg. speed is 2,570 keys/sec
2474         At 2,000 keys, avg. speed is 2,417 keys/sec
2475         At 3,000 keys, avg. speed is 1,982 keys/sec
2476         At 4,000 keys, avg. speed is 1,568 keys/sec
2477         At 5,000 keys, avg. speed is 1,533 keys/sec
2478         At 6,000 keys, avg. speed is 1,787 keys/sec
2479         At 7,000 keys, avg. speed is 1,977 keys/sec
2480         At 8,000 keys, avg. speed is 2,028 keys/sec
2481         At 9,000 keys, avg. speed is 2,077 keys/sec
2482         At 10,000 keys, avg. speed is 2,031 keys/sec
2483         At 20,000 keys, avg. speed is 1,970 keys/sec
2484         At 30,000 keys, avg. speed is 2,050 keys/sec
2485         At 40,000 keys, avg. speed is 2,073 keys/sec
2486         At 50,000 keys, avg. speed is 1,973 keys/sec
2487         At 60,000 keys, avg. speed is 1,914 keys/sec
2488         At 70,000 keys, avg. speed is 2,091 keys/sec
2489         At 80,000 keys, avg. speed is 2,103 keys/sec
2490         At 90,000 keys, avg. speed is 1,886 keys/sec
2491         At 100,000 keys, avg. speed is 1,970 keys/sec
2492         At 200,000 keys, avg. speed is 2,053 keys/sec
2493         At 300,000 keys, avg. speed is 1,697 keys/sec
2494         At 400,000 keys, avg. speed is 1,838 keys/sec
2495         At 500,000 keys, avg. speed is 1,941 keys/sec
2496         At 600,000 keys, avg. speed is 1,930 keys/sec
2497         At 700,000 keys, avg. speed is 1,735 keys/sec
2498         At 800,000 keys, avg. speed is 1,795 keys/sec
2499         At 900,000 keys, avg. speed is 1,221 keys/sec
2500         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2501
2502 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2503 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2504 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2505 Run time was 12 min 3 sec.
2506
2507 =head2 MEMORY USAGE
2508
2509 One of the great things about DBM::Deep is that it uses very little memory.
2510 Even with huge databases (1,000,000+ keys) you will not see much increased
2511 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2512 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2513 database handle:
2514
2515           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2516         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2517
2518 Basically the process is taking 2,716K of memory.  And here is the same
2519 process after storing and fetching 1,000,000 keys:
2520
2521           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2522         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2523
2524 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2525 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2526
2527 =head1 DB FILE FORMAT
2528
2529 In case you were interested in the underlying DB file format, it is documented
2530 here in this section.  You don't need to know this to use the module, it's just
2531 included for reference.
2532
2533 =head2 SIGNATURE
2534
2535 DBM::Deep files always start with a 32-bit signature to identify the file type.
2536 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2537 checked when the file is opened.
2538
2539 =head2 TAG
2540
2541 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2542 has a standard header containing the type of data, the length of data, and then
2543 the data itself.  The type is a single character (1 byte), the length is a
2544 32-bit unsigned long in network byte order, and the data is, well, the data.
2545 Here is how it unfolds:
2546
2547 =head2 MASTER INDEX
2548
2549 Immediately after the 32-bit file signature is the I<Master Index> record.
2550 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2551 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2552 depending on how the DBM::Deep object was constructed.
2553
2554
2555
2556 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2557 number).  The first 8-bit char of the MD5 signature is the offset into the
2558 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2559 index element is a file offset of the next tag for the key/element in question,
2560 which is usually a I<Bucket List> tag (see below).
2561
2562
2563
2564 The next tag I<could> be another index, depending on how many keys/elements
2565 exist.  See L<RE-INDEXING> below for details.
2566
2567 =head2 BUCKET LIST
2568
2569 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2570 file offsets to where the actual data is stored.  It starts with a standard
2571 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2572 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2573 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2574 When the list fills up, a I<Re-Index> operation is performed (See
2575 L<RE-INDEXING> below).
2576
2577 =head2 BUCKET
2578
2579 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2580 index/value pair (in array mode).  It starts with a standard tag header with
2581 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2582 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2583 header.  The size reported in the tag header is only for the value, but then,
2584 just after the value is another size (32-bit unsigned long) and then the plain
2585 key itself.  Since the value is likely to be fetched more often than the plain
2586 key, I figured it would be I<slightly> faster to store the value first.
2587
2588
2589
2590 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2591 record for the nested structure, where the process begins all over again.
2592
2593 =head2 RE-INDEXING
2594
2595 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2596 exhausted.  Then, when another key/element comes in, the list is converted to a
2597 new index record.  However, this index will look at the next char in the MD5
2598 hash, and arrange new Bucket List pointers accordingly.  This process is called
2599 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2600 17 (16 + new one) keys/elements are removed from the old Bucket List and
2601 inserted into the new index.  Several new Bucket Lists are created in the
2602 process, as a new MD5 char from the key is being examined (it is unlikely that
2603 the keys will all share the same next char of their MD5s).
2604
2605
2606
2607 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2608 when the Bucket Lists will turn into indexes, but the first round tends to
2609 happen right around 4,000 keys.  You will see a I<slight> decrease in
2610 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2611 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2612 right around 900,000 keys.  This process can continue nearly indefinitely --
2613 right up until the point the I<MD5> signatures start colliding with each other,
2614 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2615 getting struck by lightning while you are walking to cash in your tickets.
2616 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2617 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2618 this is 340 unodecillion, but don't quote me).
2619
2620 =head2 STORING
2621
2622 When a new key/element is stored, the key (or index number) is first ran through
2623 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2624 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2625 for the first char of the signature (in this case I<b>).  If it does not exist,
2626 a new I<Bucket List> is created for our key (and the next 15 future keys that
2627 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2628 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2629 this point, unless we are replacing an existing I<Bucket>), where the actual
2630 data will be stored.
2631
2632 =head2 FETCHING
2633
2634 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2635 (or index number), then walking along the indexes.  If there are enough
2636 keys/elements in this DB level, there might be nested indexes, each linked to
2637 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2638 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2639 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2640 plain key are stored.
2641
2642
2643
2644 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2645 methods.  In this process the indexes are walked systematically, and each key
2646 fetched in increasing MD5 order (which is why it appears random).   Once the
2647 I<Bucket> is found, the value is skipped the plain key returned instead.
2648 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2649 alphabetically sorted.  This only happens on an index-level -- as soon as the
2650 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2651 so it's pretty much undefined how the keys will come out -- just like Perl's
2652 built-in hashes.
2653
2654 =head1 CODE COVERAGE
2655
2656 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2657 module's test suite.
2658
2659   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2660   File                           stmt   bran   cond    sub    pod   time  total
2661   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2662   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2663   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2664   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2665   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2666   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2667
2668 =head1 AUTHOR
2669
2670 Joseph Huckaby, L<jhuckaby@cpan.org>
2671
2672 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2673
2674 =head1 SEE ALSO
2675
2676 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2677 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2678
2679 =head1 LICENSE
2680
2681 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2682 This is free software, you may use it and distribute it under the
2683 same terms as Perl itself.
2684
2685 =cut