lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.97);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a FileHandle to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         #XXX Can the mode be anything but r+, w+, or a+??
 215         #XXX ie, it has to be in read-write mode
 216         #XXX So, should we verify that the mode is legitimate?
 217
 218         #XXX Maybe the mode thingy should just go away. There's no good
 219         #XXX reason for it ...
 220         if ( $self->root->{mode} eq 'w+' ) {
 221             $flags |= O_TRUNC;
 222         }
 223
 224         my $fh;
 225         sysopen( $fh, $self->root->{file}, $flags )
 226             or $fh = undef;
 227         $self->root->{fh} = $fh;
 228     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 229         if (! defined($self->fh)) {
 230                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 231         }
 232
 233     my $fh = $self->fh;
 234
 235     #XXX Can we remove this by using the right sysopen() flags?
 236     # Maybe ... q.v. above
 237     binmode $fh; # for win32
 238
 239     if ($self->root->{autoflush}) {
 240         my $old = select $fh;
 241         $|=1;
 242         select $old;
 243     }
 244
 245     # Set the
 246     seek($fh, 0, SEEK_SET);
 247
 248     my $signature;
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, SEEK_SET);
 256         print($fh SIG_FILE);
 257         $self->root->{end} = length(SIG_FILE);
 258         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 263
 264         # Flush the filehandle
 265         my $old_fh = select $fh;
 266         my $old_af = $|;
 267         $| = 1;
 268         $| = $old_af;
 269         select $old_fh;
 270
 271         return 1;
 272     }
 273
 274     ##
 275     # Check signature was valid
 276     ##
 277     unless ($signature eq SIG_FILE) {
 278         $self->_close();
 279         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 280     }
 281
 282         my @stats = stat($fh);
 283         $self->root->{inode} = $stats[1];
 284     $self->root->{end} = $stats[7];
 285
 286     ##
 287     # Get our type from master index signature
 288     ##
 289     my $tag = $self->_load_tag($self->base_offset);
 290
 291 #XXX We probably also want to store the hash algorithm name and not assume anything
 292 #XXX The cool thing would be to allow a different hashing algorithm at every level
 293
 294     if (!$tag) {
 295         return $self->_throw_error("Corrupted file, no master index record");
 296     }
 297     if ($self->{type} ne $tag->{signature}) {
 298         return $self->_throw_error("File type mismatch");
 299     }
 300
 301     return 1;
 302 }
 303
 304 sub _close {
 305         ##
 306         # Close database FileHandle
 307         ##
 308     my $self = $_[0]->_get_self;
 309     close $self->root->{fh};
 310     $self->root->{fh} = undef;
 311 }
 312
 313 sub _create_tag {
 314         ##
 315         # Given offset, signature and content, create tag and write to disk
 316         ##
 317         my ($self, $offset, $sig, $content) = @_;
 318         my $size = length($content);
 319
 320     my $fh = $self->fh;
 321
 322         seek($fh, $offset, SEEK_SET);
 323         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 324
 325         if ($offset == $self->root->{end}) {
 326                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 327         }
 328
 329         return {
 330                 signature => $sig,
 331                 size => $size,
 332                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 333                 content => $content
 334         };
 335 }
 336
 337 sub _load_tag {
 338         ##
 339         # Given offset, load single tag and return signature, size and data
 340         ##
 341         my $self = shift;
 342         my $offset = shift;
 343
 344     my $fh = $self->fh;
 345
 346         seek($fh, $offset, SEEK_SET);
 347         if (eof $fh) { return undef; }
 348
 349         my $sig;
 350         read( $fh, $sig, SIG_SIZE);
 351
 352         my $size;
 353         read( $fh, $size, $DATA_LENGTH_SIZE);
 354         $size = unpack($DATA_LENGTH_PACK, $size);
 355
 356         my $buffer;
 357         read( $fh, $buffer, $size);
 358
 359         return {
 360                 signature => $sig,
 361                 size => $size,
 362                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 363                 content => $buffer
 364         };
 365 }
 366
 367 sub _index_lookup {
 368         ##
 369         # Given index tag, lookup single entry in index and return .
 370         ##
 371         my $self = shift;
 372         my ($tag, $index) = @_;
 373
 374         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 375         if (!$location) { return; }
 376
 377         return $self->_load_tag( $location );
 378 }
 379
 380 sub _add_bucket {
 381         ##
 382         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 383         # plain (undigested) key and value.
 384         ##
 385         my $self = shift;
 386         my ($tag, $md5, $plain_key, $value) = @_;
 387         my $keys = $tag->{content};
 388         my $location = 0;
 389         my $result = 2;
 390
 391         # added ref() check first to avoid eval and runtime exception for every
 392         # scalar value being stored.  performance tweak.
 393     my $is_dbm_deep = ref($value) && eval { $value->isa( 'DBM::Deep' ) };
 394
 395         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 396
 397     my $fh = $self->fh;
 398
 399         ##
 400         # Iterate through buckets, seeing if this is a new entry or a replace.
 401         ##
 402         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 403                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 404                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 405                 if (!$subloc) {
 406                         ##
 407                         # Found empty bucket (end of list).  Populate and exit loop.
 408                         ##
 409                         $result = 2;
 410
 411             $location = $internal_ref
 412                 ? $value->base_offset
 413                 : $self->root->{end};
 414
 415                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 416                         print($fh $md5 . pack($LONG_PACK, $location) );
 417                         last;
 418                 }
 419                 elsif ($md5 eq $key) {
 420                         ##
 421                         # Found existing bucket with same key.  Replace with new value.
 422                         ##
 423                         $result = 1;
 424
 425                         if ($internal_ref) {
 426                                 $location = $value->base_offset;
 427                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 428                                 print($fh $md5 . pack($LONG_PACK, $location) );
 429                         }
 430                         else {
 431                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 432                                 my $size;
 433                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 434
 435                                 ##
 436                                 # If value is a hash, array, or raw value with equal or less size, we can
 437                                 # reuse the same content area of the database.  Otherwise, we have to create
 438                                 # a new content area at the EOF.
 439                                 ##
 440                                 my $actual_length;
 441                 my $r = Scalar::Util::reftype( $value ) || '';
 442                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 443                         $actual_length = $INDEX_SIZE;
 444
 445                         # if autobless is enabled, must also take into consideration
 446                         # the class name, as it is stored along with key/value.
 447                         if ( $self->root->{autobless} ) {
 448                                                 my $value_class = Scalar::Util::blessed($value);
 449                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 450                                                         $actual_length += length($value_class);
 451                                                 }
 452                                         } # autobless
 453                 }
 454                                 else { $actual_length = length($value); }
 455
 456                                 if ($actual_length <= $size) {
 457                                         $location = $subloc;
 458                                 }
 459                                 else {
 460                                         $location = $self->root->{end};
 461                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 462                                         print($fh pack($LONG_PACK, $location) );
 463                                 }
 464                         }
 465                         last;
 466                 }
 467         } # i loop
 468
 469         ##
 470         # If this is an internal reference, return now.
 471         # No need to write value or plain key
 472         ##
 473         if ($internal_ref) {
 474         return $result;
 475     }
 476
 477         ##
 478         # If bucket didn't fit into list, split into a new index level
 479         ##
 480         if (!$location) {
 481                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 482                 print($fh pack($LONG_PACK, $self->root->{end}) );
 483
 484                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 485                 my @offsets = ();
 486
 487                 $keys .= $md5 . pack($LONG_PACK, 0);
 488
 489                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 490                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 491                         if ($key) {
 492                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 493                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 494
 495                                 if ($offsets[$num]) {
 496                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 497                                         seek($fh, $offset, SEEK_SET);
 498                                         my $subkeys;
 499                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 500
 501                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 502                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 503                                                 if (!$subloc) {
 504                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 505                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 506                                                         last;
 507                                                 }
 508                                         } # k loop
 509                                 }
 510                                 else {
 511                                         $offsets[$num] = $self->root->{end};
 512                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 513                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 514
 515                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 516
 517                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 518                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 519                                 }
 520                         } # key is real
 521                 } # i loop
 522
 523                 $location ||= $self->root->{end};
 524         } # re-index bucket list
 525
 526         ##
 527         # Seek to content area and store signature, value and plaintext key
 528         ##
 529         if ($location) {
 530                 my $content_length;
 531                 seek($fh, $location, SEEK_SET);
 532
 533                 ##
 534                 # Write signature based on content type, set content length and write actual value.
 535                 ##
 536         my $r = Scalar::Util::reftype($value) || '';
 537                 if ($r eq 'HASH') {
 538                         print($fh TYPE_HASH );
 539                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 540                         $content_length = $INDEX_SIZE;
 541                 }
 542                 elsif ($r eq 'ARRAY') {
 543                         print($fh TYPE_ARRAY );
 544                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 545                         $content_length = $INDEX_SIZE;
 546                 }
 547                 elsif (!defined($value)) {
 548                         print($fh SIG_NULL );
 549                         print($fh pack($DATA_LENGTH_PACK, 0) );
 550                         $content_length = 0;
 551                 }
 552                 else {
 553                         print($fh SIG_DATA );
 554                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 555                         $content_length = length($value);
 556                 }
 557
 558                 ##
 559                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 560                 ##
 561                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 562
 563                 ##
 564                 # If value is blessed, preserve class name
 565                 ##
 566                 if ( $self->root->{autobless} ) {
 567             my $value_class = Scalar::Util::blessed($value);
 568             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 569                 ##
 570                 # Blessed ref -- will restore later
 571                 ##
 572                 print($fh chr(1) );
 573                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 574                 $content_length += 1;
 575                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 576             }
 577             else {
 578                 print($fh chr(0) );
 579                 $content_length += 1;
 580             }
 581         }
 582
 583                 ##
 584                 # If this is a new content area, advance EOF counter
 585                 ##
 586                 if ($location == $self->root->{end}) {
 587                         $self->root->{end} += SIG_SIZE;
 588                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 589                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 590                 }
 591
 592                 ##
 593                 # If content is a hash or array, create new child DeepDB object and
 594                 # pass each key or element to it.
 595                 ##
 596                 if ($r eq 'HASH') {
 597                         my $branch = DBM::Deep->new(
 598                                 type => TYPE_HASH,
 599                                 base_offset => $location,
 600                                 root => $self->root,
 601                         );
 602                         foreach my $key (keys %{$value}) {
 603                 #$branch->{$key} = $value->{$key};
 604                 $branch->STORE( $key, $value->{$key} );
 605                         }
 606                 }
 607                 elsif ($r eq 'ARRAY') {
 608                         my $branch = DBM::Deep->new(
 609                                 type => TYPE_ARRAY,
 610                                 base_offset => $location,
 611                                 root => $self->root,
 612                         );
 613                         my $index = 0;
 614                         foreach my $element (@{$value}) {
 615                 #$branch->[$index] = $element;
 616                 $branch->STORE( $index, $element );
 617                                 $index++;
 618                         }
 619                 }
 620
 621                 return $result;
 622         }
 623
 624         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 625 }
 626
 627 sub _get_bucket_value {
 628         ##
 629         # Fetch single value given tag and MD5 digested key.
 630         ##
 631         my $self = shift;
 632         my ($tag, $md5) = @_;
 633         my $keys = $tag->{content};
 634
 635     my $fh = $self->fh;
 636
 637         ##
 638         # Iterate through buckets, looking for a key match
 639         ##
 640     BUCKET:
 641         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 642                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 643                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 644
 645                 if (!$subloc) {
 646                         ##
 647                         # Hit end of list, no match
 648                         ##
 649                         return;
 650                 }
 651
 652         if ( $md5 ne $key ) {
 653             next BUCKET;
 654         }
 655
 656         ##
 657         # Found match -- seek to offset and read signature
 658         ##
 659         my $signature;
 660         seek($fh, $subloc, SEEK_SET);
 661         read( $fh, $signature, SIG_SIZE);
 662
 663         ##
 664         # If value is a hash or array, return new DeepDB object with correct offset
 665         ##
 666         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 667             my $obj = DBM::Deep->new(
 668                 type => $signature,
 669                 base_offset => $subloc,
 670                 root => $self->root
 671             );
 672
 673             if ($self->root->{autobless}) {
 674                 ##
 675                 # Skip over value and plain key to see if object needs
 676                 # to be re-blessed
 677                 ##
 678                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 679
 680                 my $size;
 681                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 682                 if ($size) { seek($fh, $size, SEEK_CUR); }
 683
 684                 my $bless_bit;
 685                 read( $fh, $bless_bit, 1);
 686                 if (ord($bless_bit)) {
 687                     ##
 688                     # Yes, object needs to be re-blessed
 689                     ##
 690                     my $class_name;
 691                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 692                     if ($size) { read( $fh, $class_name, $size); }
 693                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 694                 }
 695             }
 696
 697             return $obj;
 698         }
 699
 700         ##
 701         # Otherwise return actual value
 702         ##
 703         elsif ($signature eq SIG_DATA) {
 704             my $size;
 705             my $value = '';
 706             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 707             if ($size) { read( $fh, $value, $size); }
 708             return $value;
 709         }
 710
 711         ##
 712         # Key exists, but content is null
 713         ##
 714         else { return; }
 715         } # i loop
 716
 717         return;
 718 }
 719
 720 sub _delete_bucket {
 721         ##
 722         # Delete single key/value pair given tag and MD5 digested key.
 723         ##
 724         my $self = shift;
 725         my ($tag, $md5) = @_;
 726         my $keys = $tag->{content};
 727
 728     my $fh = $self->fh;
 729
 730         ##
 731         # Iterate through buckets, looking for a key match
 732         ##
 733     BUCKET:
 734         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 735                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 736                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 737
 738                 if (!$subloc) {
 739                         ##
 740                         # Hit end of list, no match
 741                         ##
 742                         return;
 743                 }
 744
 745         if ( $md5 ne $key ) {
 746             next BUCKET;
 747         }
 748
 749         ##
 750         # Matched key -- delete bucket and return
 751         ##
 752         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 753         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 754         print($fh chr(0) x $BUCKET_SIZE );
 755
 756         return 1;
 757         } # i loop
 758
 759         return;
 760 }
 761
 762 sub _bucket_exists {
 763         ##
 764         # Check existence of single key given tag and MD5 digested key.
 765         ##
 766         my $self = shift;
 767         my ($tag, $md5) = @_;
 768         my $keys = $tag->{content};
 769
 770         ##
 771         # Iterate through buckets, looking for a key match
 772         ##
 773     BUCKET:
 774         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 775                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 776                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 777
 778                 if (!$subloc) {
 779                         ##
 780                         # Hit end of list, no match
 781                         ##
 782                         return;
 783                 }
 784
 785         if ( $md5 ne $key ) {
 786             next BUCKET;
 787         }
 788
 789         ##
 790         # Matched key -- return true
 791         ##
 792         return 1;
 793         } # i loop
 794
 795         return;
 796 }
 797
 798 sub _find_bucket_list {
 799         ##
 800         # Locate offset for bucket list, given digested key
 801         ##
 802         my $self = shift;
 803         my $md5 = shift;
 804
 805         ##
 806         # Locate offset for bucket list using digest index system
 807         ##
 808         my $ch = 0;
 809         my $tag = $self->_load_tag($self->base_offset);
 810         if (!$tag) { return; }
 811
 812         while ($tag->{signature} ne SIG_BLIST) {
 813                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 814                 if (!$tag) { return; }
 815                 $ch++;
 816         }
 817
 818         return $tag;
 819 }
 820
 821 sub _traverse_index {
 822         ##
 823         # Scan index and recursively step into deeper levels, looking for next key.
 824         ##
 825     my ($self, $offset, $ch, $force_return_next) = @_;
 826     $force_return_next = undef unless $force_return_next;
 827
 828         my $tag = $self->_load_tag( $offset );
 829
 830     my $fh = $self->fh;
 831
 832         if ($tag->{signature} ne SIG_BLIST) {
 833                 my $content = $tag->{content};
 834                 my $start;
 835                 if ($self->{return_next}) { $start = 0; }
 836                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 837
 838                 for (my $index = $start; $index < 256; $index++) {
 839                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 840                         if ($subloc) {
 841                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 842                                 if (defined($result)) { return $result; }
 843                         }
 844                 } # index loop
 845
 846                 $self->{return_next} = 1;
 847         } # tag is an index
 848
 849         elsif ($tag->{signature} eq SIG_BLIST) {
 850                 my $keys = $tag->{content};
 851                 if ($force_return_next) { $self->{return_next} = 1; }
 852
 853                 ##
 854                 # Iterate through buckets, looking for a key match
 855                 ##
 856                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 857                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 858                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 859
 860                         if (!$subloc) {
 861                                 ##
 862                                 # End of bucket list -- return to outer loop
 863                                 ##
 864                                 $self->{return_next} = 1;
 865                                 last;
 866                         }
 867                         elsif ($key eq $self->{prev_md5}) {
 868                                 ##
 869                                 # Located previous key -- return next one found
 870                                 ##
 871                                 $self->{return_next} = 1;
 872                                 next;
 873                         }
 874                         elsif ($self->{return_next}) {
 875                                 ##
 876                                 # Seek to bucket location and skip over signature
 877                                 ##
 878                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 879
 880                                 ##
 881                                 # Skip over value to get to plain key
 882                                 ##
 883                                 my $size;
 884                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 885                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 886
 887                                 ##
 888                                 # Read in plain key and return as scalar
 889                                 ##
 890                                 my $plain_key;
 891                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 892                                 if ($size) { read( $fh, $plain_key, $size); }
 893
 894                                 return $plain_key;
 895                         }
 896                 } # bucket loop
 897
 898                 $self->{return_next} = 1;
 899         } # tag is a bucket list
 900
 901         return;
 902 }
 903
 904 sub _get_next_key {
 905         ##
 906         # Locate next key, given digested previous one
 907         ##
 908     my $self = $_[0]->_get_self;
 909
 910         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 911         $self->{return_next} = 0;
 912
 913         ##
 914         # If the previous key was not specifed, start at the top and
 915         # return the first one found.
 916         ##
 917         if (!$self->{prev_md5}) {
 918                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 919                 $self->{return_next} = 1;
 920         }
 921
 922         return $self->_traverse_index( $self->base_offset, 0 );
 923 }
 924
 925 sub lock {
 926         ##
 927         # If db locking is set, flock() the db file.  If called multiple
 928         # times before unlock(), then the same number of unlocks() must
 929         # be called before the lock is released.
 930         ##
 931     my $self = $_[0]->_get_self;
 932         my $type = $_[1];
 933     $type = LOCK_EX unless defined $type;
 934
 935         if (!defined($self->fh)) { return; }
 936
 937         if ($self->root->{locking}) {
 938                 if (!$self->root->{locked}) {
 939                         flock($self->fh, $type);
 940
 941                         # double-check file inode, in case another process
 942                         # has optimize()d our file while we were waiting.
 943                         if ((stat($self->root->{file}))[1] != $self->root->{inode}) {
 944                                 $self->_open(); # re-open
 945                                 flock($self->fh, $type); # re-lock
 946                         }
 947                 }
 948                 $self->root->{locked}++;
 949
 950         return 1;
 951         }
 952
 953     return;
 954 }
 955
 956 sub unlock {
 957         ##
 958         # If db locking is set, unlock the db file.  See note in lock()
 959         # regarding calling lock() multiple times.
 960         ##
 961     my $self = $_[0]->_get_self;
 962
 963         if (!defined($self->fh)) { return; }
 964
 965         if ($self->root->{locking} && $self->root->{locked} > 0) {
 966                 $self->root->{locked}--;
 967                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 968
 969         return 1;
 970         }
 971
 972     return;
 973 }
 974
 975 #XXX These uses of ref() need verified
 976 sub _copy_node {
 977         ##
 978         # Copy single level of keys or elements to new DB handle.
 979         # Recurse for nested structures
 980         ##
 981     my $self = $_[0]->_get_self;
 982         my $db_temp = $_[1];
 983
 984         if ($self->type eq TYPE_HASH) {
 985                 my $key = $self->first_key();
 986                 while ($key) {
 987                         my $value = $self->get($key);
 988 #XXX This doesn't work with autobless
 989                         if (!ref($value)) { $db_temp->{$key} = $value; }
 990                         else {
 991                                 my $type = $value->type;
 992                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 993                                 else { $db_temp->{$key} = []; }
 994                                 $value->_copy_node( $db_temp->{$key} );
 995                         }
 996                         $key = $self->next_key($key);
 997                 }
 998         }
 999         else {
1000                 my $length = $self->length();
1001                 for (my $index = 0; $index < $length; $index++) {
1002                         my $value = $self->get($index);
1003                         if (!ref($value)) { $db_temp->[$index] = $value; }
1004             #XXX NO tests for this code
1005                         else {
1006                                 my $type = $value->type;
1007                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
1008                                 else { $db_temp->[$index] = []; }
1009                                 $value->_copy_node( $db_temp->[$index] );
1010                         }
1011                 }
1012         }
1013 }
1014
1015 sub export {
1016         ##
1017         # Recursively export into standard Perl hashes and arrays.
1018         ##
1019     my $self = $_[0]->_get_self;
1020
1021         my $temp;
1022         if ($self->type eq TYPE_HASH) { $temp = {}; }
1023         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1024
1025         $self->lock();
1026         $self->_copy_node( $temp );
1027         $self->unlock();
1028
1029         return $temp;
1030 }
1031
1032 sub import {
1033         ##
1034         # Recursively import Perl hash/array structure
1035         ##
1036     #XXX This use of ref() seems to be ok
1037         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1038
1039     my $self = $_[0]->_get_self;
1040         my $struct = $_[1];
1041
1042     #XXX This use of ref() seems to be ok
1043         if (!ref($struct)) {
1044                 ##
1045                 # struct is not a reference, so just import based on our type
1046                 ##
1047                 shift @_;
1048
1049                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1050                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1051         }
1052
1053     my $r = Scalar::Util::reftype($struct) || '';
1054         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1055                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1056         }
1057         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1058                 $self->push( @$struct );
1059         }
1060         else {
1061                 return $self->_throw_error("Cannot import: type mismatch");
1062         }
1063
1064         return 1;
1065 }
1066
1067 sub optimize {
1068         ##
1069         # Rebuild entire database into new file, then move
1070         # it back on top of original.
1071         ##
1072     my $self = $_[0]->_get_self;
1073
1074 #XXX Need to create a new test for this
1075 #       if ($self->root->{links} > 1) {
1076 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1077 #       }
1078
1079         my $db_temp = DBM::Deep->new(
1080                 file => $self->root->{file} . '.tmp',
1081                 type => $self->type
1082         );
1083         if (!$db_temp) {
1084                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1085         }
1086
1087         $self->lock();
1088         $self->_copy_node( $db_temp );
1089         undef $db_temp;
1090
1091         ##
1092         # Attempt to copy user, group and permissions over to new file
1093         ##
1094         my @stats = stat($self->fh);
1095         my $perms = $stats[2] & 07777;
1096         my $uid = $stats[4];
1097         my $gid = $stats[5];
1098         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1099         chmod( $perms, $self->root->{file} . '.tmp' );
1100
1101     # q.v. perlport for more information on this variable
1102     if ( $^O eq 'MSWin32' ) {
1103                 ##
1104                 # Potential race condition when optmizing on Win32 with locking.
1105                 # The Windows filesystem requires that the filehandle be closed
1106                 # before it is overwritten with rename().  This could be redone
1107                 # with a soft copy.
1108                 ##
1109                 $self->unlock();
1110                 $self->_close();
1111         }
1112
1113         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1114                 unlink $self->root->{file} . '.tmp';
1115                 $self->unlock();
1116                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1117         }
1118
1119         $self->unlock();
1120         $self->_close();
1121         $self->_open();
1122
1123         return 1;
1124 }
1125
1126 sub clone {
1127         ##
1128         # Make copy of object and return
1129         ##
1130     my $self = $_[0]->_get_self;
1131
1132         return DBM::Deep->new(
1133                 type => $self->type,
1134                 base_offset => $self->base_offset,
1135                 root => $self->root
1136         );
1137 }
1138
1139 {
1140     my %is_legal_filter = map {
1141         $_ => ~~1,
1142     } qw(
1143         store_key store_value
1144         fetch_key fetch_value
1145     );
1146
1147     sub set_filter {
1148         ##
1149         # Setup filter function for storing or fetching the key or value
1150         ##
1151         my $self = $_[0]->_get_self;
1152         my $type = lc $_[1];
1153         my $func = $_[2] ? $_[2] : undef;
1154
1155         if ( $is_legal_filter{$type} ) {
1156             $self->root->{"filter_$type"} = $func;
1157             return 1;
1158         }
1159
1160         return;
1161     }
1162 }
1163
1164 ##
1165 # Accessor methods
1166 ##
1167
1168 sub root {
1169         ##
1170         # Get access to the root structure
1171         ##
1172     my $self = $_[0]->_get_self;
1173         return $self->{root};
1174 }
1175
1176 sub fh {
1177         ##
1178         # Get access to the raw FileHandle
1179         ##
1180     #XXX It will be useful, though, when we split out HASH and ARRAY
1181     my $self = $_[0]->_get_self;
1182         return $self->root->{fh};
1183 }
1184
1185 sub type {
1186         ##
1187         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1188         ##
1189     my $self = $_[0]->_get_self;
1190         return $self->{type};
1191 }
1192
1193 sub base_offset {
1194         ##
1195         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1196         ##
1197     my $self = $_[0]->_get_self;
1198         return $self->{base_offset};
1199 }
1200
1201 sub error {
1202         ##
1203         # Get last error string, or undef if no error
1204         ##
1205         return $_[0]
1206         #? ( _get_self($_[0])->{root}->{error} or undef )
1207         ? ( $_[0]->_get_self->{root}->{error} or undef )
1208         : $@;
1209 }
1210
1211 ##
1212 # Utility methods
1213 ##
1214
1215 sub _throw_error {
1216         ##
1217         # Store error string in self
1218         ##
1219     my $self = $_[0]->_get_self;
1220         my $error_text = $_[1];
1221
1222     if ( Scalar::Util::blessed $self ) {
1223         $self->root->{error} = $error_text;
1224
1225         unless ($self->root->{debug}) {
1226             die "DBM::Deep: $error_text\n";
1227         }
1228
1229         warn "DBM::Deep: $error_text\n";
1230         return;
1231     }
1232     else {
1233         die "DBM::Deep: $error_text\n";
1234     }
1235 }
1236
1237 sub clear_error {
1238         ##
1239         # Clear error state
1240         ##
1241     my $self = $_[0]->_get_self;
1242
1243         undef $self->root->{error};
1244 }
1245
1246 sub precalc_sizes {
1247         ##
1248         # Precalculate index, bucket and bucket list sizes
1249         ##
1250
1251     #XXX I don't like this ...
1252     set_pack() unless defined $LONG_SIZE;
1253
1254         $INDEX_SIZE = 256 * $LONG_SIZE;
1255         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1256         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1257 }
1258
1259 sub set_pack {
1260         ##
1261         # Set pack/unpack modes (see file header for more)
1262         ##
1263     my ($long_s, $long_p, $data_s, $data_p) = @_;
1264
1265     $LONG_SIZE = $long_s ? $long_s : 4;
1266     $LONG_PACK = $long_p ? $long_p : 'N';
1267
1268     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1269     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1270
1271         precalc_sizes();
1272 }
1273
1274 sub set_digest {
1275         ##
1276         # Set key digest function (default is MD5)
1277         ##
1278     my ($digest_func, $hash_size) = @_;
1279
1280     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1281     $HASH_SIZE = $hash_size ? $hash_size : 16;
1282
1283         precalc_sizes();
1284 }
1285
1286 ##
1287 # tie() methods (hashes and arrays)
1288 ##
1289
1290 sub STORE {
1291         ##
1292         # Store single hash key/value or array element in database.
1293         ##
1294     my $self = $_[0]->_get_self;
1295         my $key = $_[1];
1296
1297     # User may be storing a hash, in which case we do not want it run
1298     # through the filtering system
1299         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1300         ? $self->root->{filter_store_value}->($_[2])
1301         : $_[2];
1302
1303         my $md5 = $DIGEST_FUNC->($key);
1304
1305         ##
1306         # Make sure file is open
1307         ##
1308         if (!defined($self->fh) && !$self->_open()) {
1309                 return;
1310         }
1311         ##
1312
1313         ##
1314         # Request exclusive lock for writing
1315         ##
1316         $self->lock( LOCK_EX );
1317
1318         my $fh = $self->fh;
1319
1320         ##
1321         # If locking is enabled, set 'end' parameter again, in case another
1322         # DB instance appended to our file while we were unlocked.
1323         ##
1324         if ($self->root->{locking} || $self->root->{volatile}) {
1325                 $self->root->{end} = (stat($fh))[7];
1326         }
1327
1328         ##
1329         # Locate offset for bucket list using digest index system
1330         ##
1331         my $tag = $self->_load_tag($self->base_offset);
1332         if (!$tag) {
1333                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1334         }
1335
1336         my $ch = 0;
1337         while ($tag->{signature} ne SIG_BLIST) {
1338                 my $num = ord(substr($md5, $ch, 1));
1339                 my $new_tag = $self->_index_lookup($tag, $num);
1340                 if (!$new_tag) {
1341                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1342                         seek($fh, $ref_loc, SEEK_SET);
1343                         print($fh pack($LONG_PACK, $self->root->{end}) );
1344
1345                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1346                         $tag->{ref_loc} = $ref_loc;
1347                         $tag->{ch} = $ch;
1348                         last;
1349                 }
1350                 else {
1351                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1352                         $tag = $new_tag;
1353                         $tag->{ref_loc} = $ref_loc;
1354                         $tag->{ch} = $ch;
1355                 }
1356                 $ch++;
1357         }
1358
1359         ##
1360         # Add key/value to bucket list
1361         ##
1362         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1363
1364         $self->unlock();
1365
1366         return $result;
1367 }
1368
1369 sub FETCH {
1370         ##
1371         # Fetch single value or element given plain key or array index
1372         ##
1373     my $self = shift->_get_self;
1374     my $key = shift;
1375
1376         ##
1377         # Make sure file is open
1378         ##
1379         if (!defined($self->fh)) { $self->_open(); }
1380
1381         my $md5 = $DIGEST_FUNC->($key);
1382
1383         ##
1384         # Request shared lock for reading
1385         ##
1386         $self->lock( LOCK_SH );
1387
1388         my $tag = $self->_find_bucket_list( $md5 );
1389         if (!$tag) {
1390                 $self->unlock();
1391                 return;
1392         }
1393
1394         ##
1395         # Get value from bucket list
1396         ##
1397         my $result = $self->_get_bucket_value( $tag, $md5 );
1398
1399         $self->unlock();
1400
1401     #XXX What is ref() checking here?
1402     #YYY Filters only apply on scalar values, so the ref check is making
1403     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1404         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1405         ? $self->root->{filter_fetch_value}->($result)
1406         : $result;
1407 }
1408
1409 sub DELETE {
1410         ##
1411         # Delete single key/value pair or element given plain key or array index
1412         ##
1413     my $self = $_[0]->_get_self;
1414         my $key = $_[1];
1415
1416         my $md5 = $DIGEST_FUNC->($key);
1417
1418         ##
1419         # Make sure file is open
1420         ##
1421         if (!defined($self->fh)) { $self->_open(); }
1422
1423         ##
1424         # Request exclusive lock for writing
1425         ##
1426         $self->lock( LOCK_EX );
1427
1428         my $tag = $self->_find_bucket_list( $md5 );
1429         if (!$tag) {
1430                 $self->unlock();
1431                 return;
1432         }
1433
1434         ##
1435         # Delete bucket
1436         ##
1437     my $value = $self->_get_bucket_value( $tag, $md5 );
1438         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1439         $value = $self->root->{filter_fetch_value}->($value);
1440     }
1441
1442         my $result = $self->_delete_bucket( $tag, $md5 );
1443
1444         ##
1445         # If this object is an array and the key deleted was on the end of the stack,
1446         # decrement the length variable.
1447         ##
1448
1449         $self->unlock();
1450
1451         return $value;
1452 }
1453
1454 sub EXISTS {
1455         ##
1456         # Check if a single key or element exists given plain key or array index
1457         ##
1458     my $self = $_[0]->_get_self;
1459         my $key = $_[1];
1460
1461         my $md5 = $DIGEST_FUNC->($key);
1462
1463         ##
1464         # Make sure file is open
1465         ##
1466         if (!defined($self->fh)) { $self->_open(); }
1467
1468         ##
1469         # Request shared lock for reading
1470         ##
1471         $self->lock( LOCK_SH );
1472
1473         my $tag = $self->_find_bucket_list( $md5 );
1474
1475         ##
1476         # For some reason, the built-in exists() function returns '' for false
1477         ##
1478         if (!$tag) {
1479                 $self->unlock();
1480                 return '';
1481         }
1482
1483         ##
1484         # Check if bucket exists and return 1 or ''
1485         ##
1486         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1487
1488         $self->unlock();
1489
1490         return $result;
1491 }
1492
1493 sub CLEAR {
1494         ##
1495         # Clear all keys from hash, or all elements from array.
1496         ##
1497     my $self = $_[0]->_get_self;
1498
1499         ##
1500         # Make sure file is open
1501         ##
1502         if (!defined($self->fh)) { $self->_open(); }
1503
1504         ##
1505         # Request exclusive lock for writing
1506         ##
1507         $self->lock( LOCK_EX );
1508
1509     my $fh = $self->fh;
1510
1511         seek($fh, $self->base_offset, SEEK_SET);
1512         if (eof $fh) {
1513                 $self->unlock();
1514                 return;
1515         }
1516
1517         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1518
1519         $self->unlock();
1520
1521         return 1;
1522 }
1523
1524 ##
1525 # Public method aliases
1526 ##
1527 sub put { (shift)->STORE( @_ ) }
1528 sub store { (shift)->STORE( @_ ) }
1529 sub get { (shift)->FETCH( @_ ) }
1530 sub fetch { (shift)->FETCH( @_ ) }
1531 sub delete { (shift)->DELETE( @_ ) }
1532 sub exists { (shift)->EXISTS( @_ ) }
1533 sub clear { (shift)->CLEAR( @_ ) }
1534
1535 package DBM::Deep::_::Root;
1536
1537 sub new {
1538     my $class = shift;
1539     my ($args) = @_;
1540
1541     my $self = bless {
1542         file => undef,
1543         fh => undef,
1544         end => 0,
1545         autoflush => undef,
1546         locking => undef,
1547         volatile => undef,
1548         debug => undef,
1549         mode => 'r+',
1550         filter_store_key => undef,
1551         filter_store_value => undef,
1552         filter_fetch_key => undef,
1553         filter_fetch_value => undef,
1554         autobless => undef,
1555         locked => 0,
1556         %$args,
1557     }, $class;
1558
1559     return $self;
1560 }
1561
1562 sub DESTROY {
1563     my $self = shift;
1564     return unless $self;
1565
1566     close $self->{fh} if $self->{fh};
1567
1568     return;
1569 }
1570
1571 1;
1572
1573 __END__
1574
1575 =head1 NAME
1576
1577 DBM::Deep - A pure perl multi-level hash/array DBM
1578
1579 =head1 SYNOPSIS
1580
1581   use DBM::Deep;
1582   my $db = DBM::Deep->new( "foo.db" );
1583
1584   $db->{key} = 'value'; # tie() style
1585   print $db->{key};
1586
1587   $db->put('key', 'value'); # OO style
1588   print $db->get('key');
1589
1590   # true multi-level support
1591   $db->{my_complex} = [
1592         'hello', { perl => 'rules' },
1593         42, 99 ];
1594
1595 =head1 DESCRIPTION
1596
1597 A unique flat-file database module, written in pure perl.  True
1598 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1599 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1600 handle millions of keys and unlimited hash levels without significant
1601 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1602 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1603 Mac OS X and Windows.
1604
1605 =head1 INSTALLATION
1606
1607 Hopefully you are using CPAN's excellent Perl module, which will download
1608 and install the module for you.  If not, get the tarball, and run these
1609 commands:
1610
1611         tar zxf DBM-Deep-*
1612         cd DBM-Deep-*
1613         perl Makefile.PL
1614         make
1615         make test
1616         make install
1617
1618 =head1 SETUP
1619
1620 Construction can be done OO-style (which is the recommended way), or using
1621 Perl's tie() function.  Both are examined here.
1622
1623 =head2 OO CONSTRUCTION
1624
1625 The recommended way to construct a DBM::Deep object is to use the new()
1626 method, which gets you a blessed, tied hash or array reference.
1627
1628         my $db = DBM::Deep->new( "foo.db" );
1629
1630 This opens a new database handle, mapped to the file "foo.db".  If this
1631 file does not exist, it will automatically be created.  DB files are
1632 opened in "r+" (read/write) mode, and the type of object returned is a
1633 hash, unless otherwise specified (see L<OPTIONS> below).
1634
1635
1636
1637 You can pass a number of options to the constructor to specify things like
1638 locking, autoflush, etc.  This is done by passing an inline hash:
1639
1640         my $db = DBM::Deep->new(
1641                 file => "foo.db",
1642                 locking => 1,
1643                 autoflush => 1
1644         );
1645
1646 Notice that the filename is now specified I<inside> the hash with
1647 the "file" parameter, as opposed to being the sole argument to the
1648 constructor.  This is required if any options are specified.
1649 See L<OPTIONS> below for the complete list.
1650
1651
1652
1653 You can also start with an array instead of a hash.  For this, you must
1654 specify the C<type> parameter:
1655
1656         my $db = DBM::Deep->new(
1657                 file => "foo.db",
1658                 type => DBM::Deep->TYPE_ARRAY
1659         );
1660
1661 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1662 a new DB file.  If you create a DBM::Deep object with an existing file, the
1663 C<type> will be loaded from the file header, and ignored if it is passed
1664 to the constructor.
1665
1666 =head2 TIE CONSTRUCTION
1667
1668 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1669 tie() function.  This is not ideal, because you get only a basic, tied hash
1670 (or array) which is not blessed, so you can't call any functions on it.
1671
1672         my %hash;
1673         tie %hash, "DBM::Deep", "foo.db";
1674
1675         my @array;
1676         tie @array, "DBM::Deep", "bar.db";
1677
1678 As with the OO constructor, you can replace the DB filename parameter with
1679 a hash containing one or more options (see L<OPTIONS> just below for the
1680 complete list).
1681
1682         tie %hash, "DBM::Deep", {
1683                 file => "foo.db",
1684                 locking => 1,
1685                 autoflush => 1
1686         };
1687
1688 =head2 OPTIONS
1689
1690 There are a number of options that can be passed in when constructing your
1691 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1692
1693 =over
1694
1695 =item * file
1696
1697 Filename of the DB file to link the handle to.  You can pass a full absolute
1698 filesystem path, partial path, or a plain filename if the file is in the
1699 current working directory.  This is a required parameter.
1700
1701 =item * mode
1702
1703 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1704 module.  This is an optional parameter, and defaults to "r+" (read/write).
1705 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1706 created if it doesn't exist.
1707
1708 =item * type
1709
1710 This parameter specifies what type of object to create, a hash or array.  Use
1711 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1712 This only takes effect when beginning a new file.  This is an optional
1713 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1714
1715 =item * locking
1716
1717 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1718 function to lock the database in exclusive mode for writes, and shared mode for
1719 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1720 any child hashes or arrays> that use the same DB file.  This is an optional
1721 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1722
1723 =item * autoflush
1724
1725 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1726 This obviously slows down write operations, but is required if you may have
1727 multiple processes accessing the same DB file (also consider enable I<locking>
1728 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1729 parameter, and defaults to 0 (disabled).
1730
1731 =item * volatile
1732
1733 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1734 STORE() operation.  This is required if an outside force may change the size of
1735 the file between transactions.  Locking also implicitly enables volatile.  This
1736 is useful if you want to use a different locking system or write your own.  Pass
1737 any true value to enable.  This is an optional parameter, and defaults to 0
1738 (disabled).
1739
1740 =item * autobless
1741
1742 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1743 restore them when fetched.  This is an B<experimental> feature, and does have
1744 side-effects.  Basically, when hashes are re-blessed into their original
1745 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1746 able to call any DBM::Deep methods on them.  You have been warned.
1747 This is an optional parameter, and defaults to 0 (disabled).
1748
1749 =item * filter_*
1750
1751 See L<FILTERS> below.
1752
1753 =item * debug
1754
1755 Setting I<debug> mode will make all errors non-fatal, dump them out to
1756 STDERR, and continue on.  This is for debugging purposes only, and probably
1757 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1758
1759 =item * fh
1760
1761 Instead of passing a file path, you can instead pass a handle to an pre-opened
1762 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1763 contains your entire Perl script, as well as the data following the __DATA__
1764 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1765 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1766 in that.  Also please note optimize() will NOT work when passing in only a
1767 handle.  Pass in a real filename in order to use optimize().
1768
1769 =back
1770
1771 =head1 TIE INTERFACE
1772
1773 With DBM::Deep you can access your databases using Perl's standard hash/array
1774 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1775 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1776 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1777 section above.  This simply tells you how to use DBM::Deep using regular hashes
1778 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1779 work too).  It is entirely up to you how to want to access your databases.
1780
1781 =head2 HASHES
1782
1783 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1784 or even nested hashes (or arrays) using standard Perl syntax:
1785
1786         my $db = DBM::Deep->new( "foo.db" );
1787
1788         $db->{mykey} = "myvalue";
1789         $db->{myhash} = {};
1790         $db->{myhash}->{subkey} = "subvalue";
1791
1792         print $db->{myhash}->{subkey} . "\n";
1793
1794 You can even step through hash keys using the normal Perl C<keys()> function:
1795
1796         foreach my $key (keys %$db) {
1797                 print "$key: " . $db->{$key} . "\n";
1798         }
1799
1800 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1801 pushes them onto an array, all before the loop even begins.  If you have an
1802 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1803 Perl's C<each()> function, which pulls keys/values one at a time, using very
1804 little memory:
1805
1806         while (my ($key, $value) = each %$db) {
1807                 print "$key: $value\n";
1808         }
1809
1810 Please note that when using C<each()>, you should always pass a direct
1811 hash reference, not a lookup.  Meaning, you should B<never> do this:
1812
1813         # NEVER DO THIS
1814         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1815
1816 This causes an infinite loop, because for each iteration, Perl is calling
1817 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1818 it effectively keeps returning the first key over and over again. Instead,
1819 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1820
1821 =head2 ARRAYS
1822
1823 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1824 reference.  This includes inserting, removing and manipulating elements,
1825 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1826 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1827 or simply be a nested array reference inside a hash.  Example:
1828
1829         my $db = DBM::Deep->new(
1830                 file => "foo-array.db",
1831                 type => DBM::Deep->TYPE_ARRAY
1832         );
1833
1834         $db->[0] = "foo";
1835         push @$db, "bar", "baz";
1836         unshift @$db, "bah";
1837
1838         my $last_elem = pop @$db; # baz
1839         my $first_elem = shift @$db; # bah
1840         my $second_elem = $db->[1]; # bar
1841
1842         my $num_elements = scalar @$db;
1843
1844 =head1 OO INTERFACE
1845
1846 In addition to the I<tie()> interface, you can also use a standard OO interface
1847 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1848 array) has its own methods, but both types share the following common methods:
1849 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1850
1851 =over
1852
1853 =item * put()
1854
1855 Stores a new hash key/value pair, or sets an array element value.  Takes two
1856 arguments, the hash key or array index, and the new value.  The value can be
1857 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1858
1859         $db->put("foo", "bar"); # for hashes
1860         $db->put(1, "bar"); # for arrays
1861
1862 =item * get()
1863
1864 Fetches the value of a hash key or array element.  Takes one argument: the hash
1865 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1866 data type stored.
1867
1868         my $value = $db->get("foo"); # for hashes
1869         my $value = $db->get(1); # for arrays
1870
1871 =item * exists()
1872
1873 Checks if a hash key or array index exists.  Takes one argument: the hash key
1874 or array index.  Returns true if it exists, false if not.
1875
1876         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1877         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1878
1879 =item * delete()
1880
1881 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1882 key or array index.  Returns true on success, false if not found.  For arrays,
1883 the remaining elements located after the deleted element are NOT moved over.
1884 The deleted element is essentially just undefined, which is exactly how Perl's
1885 internal arrays work.  Please note that the space occupied by the deleted
1886 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1887 below for details and workarounds.
1888
1889         $db->delete("foo"); # for hashes
1890         $db->delete(1); # for arrays
1891
1892 =item * clear()
1893
1894 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1895 value.  Please note that the space occupied by the deleted keys/values or
1896 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1897 details and workarounds.
1898
1899         $db->clear(); # hashes or arrays
1900
1901 =back
1902
1903 =head2 HASHES
1904
1905 For hashes, DBM::Deep supports all the common methods described above, and the
1906 following additional methods: C<first_key()> and C<next_key()>.
1907
1908 =over
1909
1910 =item * first_key()
1911
1912 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1913 fetched in an undefined order (which appears random).  Takes no arguments,
1914 returns the key as a scalar value.
1915
1916         my $key = $db->first_key();
1917
1918 =item * next_key()
1919
1920 Returns the "next" key in the hash, given the previous one as the sole argument.
1921 Returns undef if there are no more keys to be fetched.
1922
1923         $key = $db->next_key($key);
1924
1925 =back
1926
1927 Here are some examples of using hashes:
1928
1929         my $db = DBM::Deep->new( "foo.db" );
1930
1931         $db->put("foo", "bar");
1932         print "foo: " . $db->get("foo") . "\n";
1933
1934         $db->put("baz", {}); # new child hash ref
1935         $db->get("baz")->put("buz", "biz");
1936         print "buz: " . $db->get("baz")->get("buz") . "\n";
1937
1938         my $key = $db->first_key();
1939         while ($key) {
1940                 print "$key: " . $db->get($key) . "\n";
1941                 $key = $db->next_key($key);
1942         }
1943
1944         if ($db->exists("foo")) { $db->delete("foo"); }
1945
1946 =head2 ARRAYS
1947
1948 For arrays, DBM::Deep supports all the common methods described above, and the
1949 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1950 C<unshift()> and C<splice()>.
1951
1952 =over
1953
1954 =item * length()
1955
1956 Returns the number of elements in the array.  Takes no arguments.
1957
1958         my $len = $db->length();
1959
1960 =item * push()
1961
1962 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1963 refs or array refs.  No return value.
1964
1965         $db->push("foo", "bar", {});
1966
1967 =item * pop()
1968
1969 Fetches the last element in the array, and deletes it.  Takes no arguments.
1970 Returns undef if array is empty.  Returns the element value.
1971
1972         my $elem = $db->pop();
1973
1974 =item * shift()
1975
1976 Fetches the first element in the array, deletes it, then shifts all the
1977 remaining elements over to take up the space.  Returns the element value.  This
1978 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1979 details.
1980
1981         my $elem = $db->shift();
1982
1983 =item * unshift()
1984
1985 Inserts one or more elements onto the beginning of the array, shifting all
1986 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1987 No return value.  This method is not recommended with large arrays -- see
1988 <LARGE ARRAYS> below for details.
1989
1990         $db->unshift("foo", "bar", {});
1991
1992 =item * splice()
1993
1994 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1995 -f splice> for usage -- it is too complicated to document here.  This method is
1996 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1997
1998 =back
1999
2000 Here are some examples of using arrays:
2001
2002         my $db = DBM::Deep->new(
2003                 file => "foo.db",
2004                 type => DBM::Deep->TYPE_ARRAY
2005         );
2006
2007         $db->push("bar", "baz");
2008         $db->unshift("foo");
2009         $db->put(3, "buz");
2010
2011         my $len = $db->length();
2012         print "length: $len\n"; # 4
2013
2014         for (my $k=0; $k<$len; $k++) {
2015                 print "$k: " . $db->get($k) . "\n";
2016         }
2017
2018         $db->splice(1, 2, "biz", "baf");
2019
2020         while (my $elem = shift @$db) {
2021                 print "shifted: $elem\n";
2022         }
2023
2024 =head1 LOCKING
2025
2026 Enable automatic file locking by passing a true value to the C<locking>
2027 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2028
2029         my $db = DBM::Deep->new(
2030                 file => "foo.db",
2031                 locking => 1
2032         );
2033
2034 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2035 mode for writes, and shared mode for reads.  This is required if you have
2036 multiple processes accessing the same database file, to avoid file corruption.
2037 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2038 NFS> below for more.
2039
2040 =head2 EXPLICIT LOCKING
2041
2042 You can explicitly lock a database, so it remains locked for multiple
2043 transactions.  This is done by calling the C<lock()> method, and passing an
2044 optional lock mode argument (defaults to exclusive mode).  This is particularly
2045 useful for things like counters, where the current value needs to be fetched,
2046 then incremented, then stored again.
2047
2048         $db->lock();
2049         my $counter = $db->get("counter");
2050         $counter++;
2051         $db->put("counter", $counter);
2052         $db->unlock();
2053
2054         # or...
2055
2056         $db->lock();
2057         $db->{counter}++;
2058         $db->unlock();
2059
2060 You can pass C<lock()> an optional argument, which specifies which mode to use
2061 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2062 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2063 same as the constants defined in Perl's C<Fcntl> module.
2064
2065         $db->lock( DBM::Deep->LOCK_SH );
2066         # something here
2067         $db->unlock();
2068
2069 If you want to implement your own file locking scheme, be sure to create your
2070 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2071 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2072 below for more.
2073
2074 =head1 IMPORTING/EXPORTING
2075
2076 You can import existing complex structures by calling the C<import()> method,
2077 and export an entire database into an in-memory structure using the C<export()>
2078 method.  Both are examined here.
2079
2080 =head2 IMPORTING
2081
2082 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2083 walking the structure and adding keys/elements to the database as you go,
2084 simply pass a reference to the C<import()> method.  This recursively adds
2085 everything to an existing DBM::Deep object for you.  Here is an example:
2086
2087         my $struct = {
2088                 key1 => "value1",
2089                 key2 => "value2",
2090                 array1 => [ "elem0", "elem1", "elem2" ],
2091                 hash1 => {
2092                         subkey1 => "subvalue1",
2093                         subkey2 => "subvalue2"
2094                 }
2095         };
2096
2097         my $db = DBM::Deep->new( "foo.db" );
2098         $db->import( $struct );
2099
2100         print $db->{key1} . "\n"; # prints "value1"
2101
2102 This recursively imports the entire C<$struct> object into C<$db>, including
2103 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2104 keys are merged with the existing ones, replacing if they already exist.
2105 The C<import()> method can be called on any database level (not just the base
2106 level), and works with both hash and array DB types.
2107
2108
2109
2110 B<Note:> Make sure your existing structure has no circular references in it.
2111 These will cause an infinite loop when importing.
2112
2113 =head2 EXPORTING
2114
2115 Calling the C<export()> method on an existing DBM::Deep object will return
2116 a reference to a new in-memory copy of the database.  The export is done
2117 recursively, so all nested hashes/arrays are all exported to standard Perl
2118 objects.  Here is an example:
2119
2120         my $db = DBM::Deep->new( "foo.db" );
2121
2122         $db->{key1} = "value1";
2123         $db->{key2} = "value2";
2124         $db->{hash1} = {};
2125         $db->{hash1}->{subkey1} = "subvalue1";
2126         $db->{hash1}->{subkey2} = "subvalue2";
2127
2128         my $struct = $db->export();
2129
2130         print $struct->{key1} . "\n"; # prints "value1"
2131
2132 This makes a complete copy of the database in memory, and returns a reference
2133 to it.  The C<export()> method can be called on any database level (not just
2134 the base level), and works with both hash and array DB types.  Be careful of
2135 large databases -- you can store a lot more data in a DBM::Deep object than an
2136 in-memory Perl structure.
2137
2138
2139
2140 B<Note:> Make sure your database has no circular references in it.
2141 These will cause an infinite loop when exporting.
2142
2143 =head1 FILTERS
2144
2145 DBM::Deep has a number of hooks where you can specify your own Perl function
2146 to perform filtering on incoming or outgoing data.  This is a perfect
2147 way to extend the engine, and implement things like real-time compression or
2148 encryption.  Filtering applies to the base DB level, and all child hashes /
2149 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2150 constructed, or by calling the C<set_filter()> method at any time.  There are
2151 four available filter hooks, described below:
2152
2153 =over
2154
2155 =item * filter_store_key
2156
2157 This filter is called whenever a hash key is stored.  It
2158 is passed the incoming key, and expected to return a transformed key.
2159
2160 =item * filter_store_value
2161
2162 This filter is called whenever a hash key or array element is stored.  It
2163 is passed the incoming value, and expected to return a transformed value.
2164
2165 =item * filter_fetch_key
2166
2167 This filter is called whenever a hash key is fetched (i.e. via
2168 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2169 and expected to return the plain key.
2170
2171 =item * filter_fetch_value
2172
2173 This filter is called whenever a hash key or array element is fetched.
2174 It is passed the transformed value, and expected to return the plain value.
2175
2176 =back
2177
2178 Here are the two ways to setup a filter hook:
2179
2180         my $db = DBM::Deep->new(
2181                 file => "foo.db",
2182                 filter_store_value => \&my_filter_store,
2183                 filter_fetch_value => \&my_filter_fetch
2184         );
2185
2186         # or...
2187
2188         $db->set_filter( "filter_store_value", \&my_filter_store );
2189         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2190
2191 Your filter function will be called only when dealing with SCALAR keys or
2192 values.  When nested hashes and arrays are being stored/fetched, filtering
2193 is bypassed.  Filters are called as static functions, passed a single SCALAR
2194 argument, and expected to return a single SCALAR value.  If you want to
2195 remove a filter, set the function reference to C<undef>:
2196
2197         $db->set_filter( "filter_store_value", undef );
2198
2199 =head2 REAL-TIME ENCRYPTION EXAMPLE
2200
2201 Here is a working example that uses the I<Crypt::Blowfish> module to
2202 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2203 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2204 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2205
2206         use DBM::Deep;
2207         use Crypt::Blowfish;
2208         use Crypt::CBC;
2209
2210         my $cipher = Crypt::CBC->new({
2211                 'key'             => 'my secret key',
2212                 'cipher'          => 'Blowfish',
2213                 'iv'              => '$KJh#(}q',
2214                 'regenerate_key'  => 0,
2215                 'padding'         => 'space',
2216                 'prepend_iv'      => 0
2217         });
2218
2219         my $db = DBM::Deep->new(
2220                 file => "foo-encrypt.db",
2221                 filter_store_key => \&my_encrypt,
2222                 filter_store_value => \&my_encrypt,
2223                 filter_fetch_key => \&my_decrypt,
2224                 filter_fetch_value => \&my_decrypt,
2225         );
2226
2227         $db->{key1} = "value1";
2228         $db->{key2} = "value2";
2229         print "key1: " . $db->{key1} . "\n";
2230         print "key2: " . $db->{key2} . "\n";
2231
2232         undef $db;
2233         exit;
2234
2235         sub my_encrypt {
2236                 return $cipher->encrypt( $_[0] );
2237         }
2238         sub my_decrypt {
2239                 return $cipher->decrypt( $_[0] );
2240         }
2241
2242 =head2 REAL-TIME COMPRESSION EXAMPLE
2243
2244 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2245 compression / decompression of keys & values with DBM::Deep Filters.
2246 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2247 more on I<Compress::Zlib>.
2248
2249         use DBM::Deep;
2250         use Compress::Zlib;
2251
2252         my $db = DBM::Deep->new(
2253                 file => "foo-compress.db",
2254                 filter_store_key => \&my_compress,
2255                 filter_store_value => \&my_compress,
2256                 filter_fetch_key => \&my_decompress,
2257                 filter_fetch_value => \&my_decompress,
2258         );
2259
2260         $db->{key1} = "value1";
2261         $db->{key2} = "value2";
2262         print "key1: " . $db->{key1} . "\n";
2263         print "key2: " . $db->{key2} . "\n";
2264
2265         undef $db;
2266         exit;
2267
2268         sub my_compress {
2269                 return Compress::Zlib::memGzip( $_[0] ) ;
2270         }
2271         sub my_decompress {
2272                 return Compress::Zlib::memGunzip( $_[0] ) ;
2273         }
2274
2275 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2276 actually numerical index numbers, and are not filtered.
2277
2278 =head1 ERROR HANDLING
2279
2280 Most DBM::Deep methods return a true value for success, and call die() on
2281 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2282 actual error message is stored in an internal scalar, which can be fetched by
2283 calling the C<error()> method.
2284
2285         my $db = DBM::Deep->new( "foo.db" ); # create hash
2286         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2287
2288         print $db->error(); # prints error message
2289
2290 You can then call C<clear_error()> to clear the current error state.
2291
2292         $db->clear_error();
2293
2294 If you set the C<debug> option to true when creating your DBM::Deep object,
2295 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2296 for debugging purposes.
2297
2298 =head1 LARGEFILE SUPPORT
2299
2300 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2301 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2302 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2303 by calling the static C<set_pack()> method before you do anything else.
2304
2305         DBM::Deep::set_pack(8, 'Q');
2306
2307 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2308 instead of 32-bit longs.  After setting these values your DB files have a
2309 theoretical maximum size of 16 XB (exabytes).
2310
2311
2312
2313 B<Note:> Changing these values will B<NOT> work for existing database files.
2314 Only change this for new files, and make sure it stays set consistently
2315 throughout the file's life.  If you do set these values, you can no longer
2316 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2317 back to 32-bit mode.
2318
2319
2320
2321 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2322 only a 32-bit Perl.  However, I have received user reports that this does
2323 indeed work!
2324
2325 =head1 LOW-LEVEL ACCESS
2326
2327 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2328 you can call the C<fh()> method, which returns the handle:
2329
2330         my $fh = $db->fh();
2331
2332 This method can be called on the root level of the datbase, or any child
2333 hashes or arrays.  All levels share a I<root> structure, which contains things
2334 like the FileHandle, a reference counter, and all your options you specified
2335 when you created the object.  You can get access to this root structure by
2336 calling the C<root()> method.
2337
2338         my $root = $db->root();
2339
2340 This is useful for changing options after the object has already been created,
2341 such as enabling/disabling locking, volatile or debug modes.  You can also
2342 store your own temporary user data in this structure (be wary of name
2343 collision), which is then accessible from any child hash or array.
2344
2345 =head1 CUSTOM DIGEST ALGORITHM
2346
2347 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2348 keys.  However you can override this, and use another algorithm (such as SHA-256)
2349 or even write your own.  But please note that DBM::Deep currently expects zero
2350 collisions, so your algorithm has to be I<perfect>, so to speak.
2351 Collision detection may be introduced in a later version.
2352
2353
2354
2355 You can specify a custom digest algorithm by calling the static C<set_digest()>
2356 function, passing a reference to a subroutine, and the length of the algorithm's
2357 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2358 objects.  Here is a working example that uses a 256-bit hash from the
2359 I<Digest::SHA256> module.  Please see
2360 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2361
2362         use DBM::Deep;
2363         use Digest::SHA256;
2364
2365         my $context = Digest::SHA256::new(256);
2366
2367         DBM::Deep::set_digest( \&my_digest, 32 );
2368
2369         my $db = DBM::Deep->new( "foo-sha.db" );
2370
2371         $db->{key1} = "value1";
2372         $db->{key2} = "value2";
2373         print "key1: " . $db->{key1} . "\n";
2374         print "key2: " . $db->{key2} . "\n";
2375
2376         undef $db;
2377         exit;
2378
2379         sub my_digest {
2380                 return substr( $context->hash($_[0]), 0, 32 );
2381         }
2382
2383 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2384 of bytes you specify in the C<set_digest()> function (in this case 32).
2385
2386 =head1 CIRCULAR REFERENCES
2387
2388 DBM::Deep has B<experimental> support for circular references.  Meaning you
2389 can have a nested hash key or array element that points to a parent object.
2390 This relationship is stored in the DB file, and is preserved between sessions.
2391 Here is an example:
2392
2393         my $db = DBM::Deep->new( "foo.db" );
2394
2395         $db->{foo} = "bar";
2396         $db->{circle} = $db; # ref to self
2397
2398         print $db->{foo} . "\n"; # prints "foo"
2399         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2400
2401 One catch is, passing the object to a function that recursively walks the
2402 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2403 C<export()> methods) will result in an infinite loop.  The other catch is,
2404 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2405 or C<next_key()> methods), you will get the I<target object's key>, not the
2406 ref's key.  This gets even more interesting with the above example, where
2407 the I<circle> key points to the base DB object, which technically doesn't
2408 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2409 special case.
2410
2411 =head1 CAVEATS / ISSUES / BUGS
2412
2413 This section describes all the known issues with DBM::Deep.  It you have found
2414 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2415
2416 =head2 UNUSED SPACE RECOVERY
2417
2418 One major caveat with DBM::Deep is that space occupied by existing keys and
2419 values is not recovered when they are deleted.  Meaning if you keep deleting
2420 and adding new keys, your file will continuously grow.  I am working on this,
2421 but in the meantime you can call the built-in C<optimize()> method from time to
2422 time (perhaps in a crontab or something) to recover all your unused space.
2423
2424         $db->optimize(); # returns true on success
2425
2426 This rebuilds the ENTIRE database into a new file, then moves it on top of
2427 the original.  The new file will have no unused space, thus it will take up as
2428 little disk space as possible.  Please note that this operation can take
2429 a long time for large files, and you need enough disk space to temporarily hold
2430 2 copies of your DB file.  The temporary file is created in the same directory
2431 as the original, named with a ".tmp" extension, and is deleted when the
2432 operation completes.  Oh, and if locking is enabled, the DB is automatically
2433 locked for the entire duration of the copy.
2434
2435
2436
2437 B<WARNING:> Only call optimize() on the top-level node of the database, and
2438 make sure there are no child references lying around.  DBM::Deep keeps a reference
2439 counter, and if it is greater than 1, optimize() will abort and return undef.
2440
2441 =head2 AUTOVIVIFICATION
2442
2443 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2444 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2445 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2446 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2447 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2448 this does not work:
2449
2450         $db->{foo}->{bar} = "hello";
2451
2452 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2453 being an empty hash.  Try this instead, which works fine:
2454
2455         $db->{foo} = { bar => "hello" };
2456
2457 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2458 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2459 Probably a bug in Perl.
2460
2461 =head2 FILE CORRUPTION
2462
2463 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2464 for a 32-bit signature when opened, but other corruption in files can cause
2465 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2466 stuck in an infinite loop depending on the level of corruption.  File write
2467 operations are not checked for failure (for speed), so if you happen to run
2468 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2469 be addressed in a later version of DBM::Deep.
2470
2471 =head2 DB OVER NFS
2472
2473 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2474 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2475 about setting up your NFS server with a locking daemon, then using lockf() to
2476 lock your files, but your milage may vary there as well.  From what I
2477 understand, there is no real way to do it.  However, if you need access to the
2478 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2479 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2480
2481 =head2 COPYING OBJECTS
2482
2483 Beware of copying tied objects in Perl.  Very strange things can happen.
2484 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2485 returns a new, blessed, tied hash or array to the same level in the DB.
2486
2487         my $copy = $db->clone();
2488
2489 =head2 LARGE ARRAYS
2490
2491 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2492 These functions cause every element in the array to move, which can be murder
2493 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2494 a different location.  This may be addressed in a later version.
2495
2496 =head1 PERFORMANCE
2497
2498 This section discusses DBM::Deep's speed and memory usage.
2499
2500 =head2 SPEED
2501
2502 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2503 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2504 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2505 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2506 with huge databases.  Here is some test data:
2507
2508         Adding 1,000,000 keys to new DB file...
2509
2510         At 100 keys, avg. speed is 2,703 keys/sec
2511         At 200 keys, avg. speed is 2,642 keys/sec
2512         At 300 keys, avg. speed is 2,598 keys/sec
2513         At 400 keys, avg. speed is 2,578 keys/sec
2514         At 500 keys, avg. speed is 2,722 keys/sec
2515         At 600 keys, avg. speed is 2,628 keys/sec
2516         At 700 keys, avg. speed is 2,700 keys/sec
2517         At 800 keys, avg. speed is 2,607 keys/sec
2518         At 900 keys, avg. speed is 2,190 keys/sec
2519         At 1,000 keys, avg. speed is 2,570 keys/sec
2520         At 2,000 keys, avg. speed is 2,417 keys/sec
2521         At 3,000 keys, avg. speed is 1,982 keys/sec
2522         At 4,000 keys, avg. speed is 1,568 keys/sec
2523         At 5,000 keys, avg. speed is 1,533 keys/sec
2524         At 6,000 keys, avg. speed is 1,787 keys/sec
2525         At 7,000 keys, avg. speed is 1,977 keys/sec
2526         At 8,000 keys, avg. speed is 2,028 keys/sec
2527         At 9,000 keys, avg. speed is 2,077 keys/sec
2528         At 10,000 keys, avg. speed is 2,031 keys/sec
2529         At 20,000 keys, avg. speed is 1,970 keys/sec
2530         At 30,000 keys, avg. speed is 2,050 keys/sec
2531         At 40,000 keys, avg. speed is 2,073 keys/sec
2532         At 50,000 keys, avg. speed is 1,973 keys/sec
2533         At 60,000 keys, avg. speed is 1,914 keys/sec
2534         At 70,000 keys, avg. speed is 2,091 keys/sec
2535         At 80,000 keys, avg. speed is 2,103 keys/sec
2536         At 90,000 keys, avg. speed is 1,886 keys/sec
2537         At 100,000 keys, avg. speed is 1,970 keys/sec
2538         At 200,000 keys, avg. speed is 2,053 keys/sec
2539         At 300,000 keys, avg. speed is 1,697 keys/sec
2540         At 400,000 keys, avg. speed is 1,838 keys/sec
2541         At 500,000 keys, avg. speed is 1,941 keys/sec
2542         At 600,000 keys, avg. speed is 1,930 keys/sec
2543         At 700,000 keys, avg. speed is 1,735 keys/sec
2544         At 800,000 keys, avg. speed is 1,795 keys/sec
2545         At 900,000 keys, avg. speed is 1,221 keys/sec
2546         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2547
2548 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2549 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2550 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2551 Run time was 12 min 3 sec.
2552
2553 =head2 MEMORY USAGE
2554
2555 One of the great things about DBM::Deep is that it uses very little memory.
2556 Even with huge databases (1,000,000+ keys) you will not see much increased
2557 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2558 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2559 database handle:
2560
2561           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2562         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2563
2564 Basically the process is taking 2,716K of memory.  And here is the same
2565 process after storing and fetching 1,000,000 keys:
2566
2567           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2568         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2569
2570 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2571 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2572
2573 =head1 DB FILE FORMAT
2574
2575 In case you were interested in the underlying DB file format, it is documented
2576 here in this section.  You don't need to know this to use the module, it's just
2577 included for reference.
2578
2579 =head2 SIGNATURE
2580
2581 DBM::Deep files always start with a 32-bit signature to identify the file type.
2582 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2583 checked when the file is opened.
2584
2585 =head2 TAG
2586
2587 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2588 has a standard header containing the type of data, the length of data, and then
2589 the data itself.  The type is a single character (1 byte), the length is a
2590 32-bit unsigned long in network byte order, and the data is, well, the data.
2591 Here is how it unfolds:
2592
2593 =head2 MASTER INDEX
2594
2595 Immediately after the 32-bit file signature is the I<Master Index> record.
2596 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2597 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2598 depending on how the DBM::Deep object was constructed.
2599
2600
2601
2602 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2603 number).  The first 8-bit char of the MD5 signature is the offset into the
2604 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2605 index element is a file offset of the next tag for the key/element in question,
2606 which is usually a I<Bucket List> tag (see below).
2607
2608
2609
2610 The next tag I<could> be another index, depending on how many keys/elements
2611 exist.  See L<RE-INDEXING> below for details.
2612
2613 =head2 BUCKET LIST
2614
2615 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2616 file offsets to where the actual data is stored.  It starts with a standard
2617 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2618 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2619 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2620 When the list fills up, a I<Re-Index> operation is performed (See
2621 L<RE-INDEXING> below).
2622
2623 =head2 BUCKET
2624
2625 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2626 index/value pair (in array mode).  It starts with a standard tag header with
2627 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2628 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2629 header.  The size reported in the tag header is only for the value, but then,
2630 just after the value is another size (32-bit unsigned long) and then the plain
2631 key itself.  Since the value is likely to be fetched more often than the plain
2632 key, I figured it would be I<slightly> faster to store the value first.
2633
2634
2635
2636 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2637 record for the nested structure, where the process begins all over again.
2638
2639 =head2 RE-INDEXING
2640
2641 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2642 exhausted.  Then, when another key/element comes in, the list is converted to a
2643 new index record.  However, this index will look at the next char in the MD5
2644 hash, and arrange new Bucket List pointers accordingly.  This process is called
2645 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2646 17 (16 + new one) keys/elements are removed from the old Bucket List and
2647 inserted into the new index.  Several new Bucket Lists are created in the
2648 process, as a new MD5 char from the key is being examined (it is unlikely that
2649 the keys will all share the same next char of their MD5s).
2650
2651
2652
2653 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2654 when the Bucket Lists will turn into indexes, but the first round tends to
2655 happen right around 4,000 keys.  You will see a I<slight> decrease in
2656 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2657 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2658 right around 900,000 keys.  This process can continue nearly indefinitely --
2659 right up until the point the I<MD5> signatures start colliding with each other,
2660 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2661 getting struck by lightning while you are walking to cash in your tickets.
2662 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2663 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2664 this is 340 unodecillion, but don't quote me).
2665
2666 =head2 STORING
2667
2668 When a new key/element is stored, the key (or index number) is first ran through
2669 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2670 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2671 for the first char of the signature (in this case I<b>).  If it does not exist,
2672 a new I<Bucket List> is created for our key (and the next 15 future keys that
2673 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2674 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2675 this point, unless we are replacing an existing I<Bucket>), where the actual
2676 data will be stored.
2677
2678 =head2 FETCHING
2679
2680 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2681 (or index number), then walking along the indexes.  If there are enough
2682 keys/elements in this DB level, there might be nested indexes, each linked to
2683 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2684 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2685 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2686 plain key are stored.
2687
2688
2689
2690 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2691 methods.  In this process the indexes are walked systematically, and each key
2692 fetched in increasing MD5 order (which is why it appears random).   Once the
2693 I<Bucket> is found, the value is skipped the plain key returned instead.
2694 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2695 alphabetically sorted.  This only happens on an index-level -- as soon as the
2696 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2697 so it's pretty much undefined how the keys will come out -- just like Perl's
2698 built-in hashes.
2699
2700 =head1 CODE COVERAGE
2701
2702 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover>
2703 report on this module's test suite.
2704
2705 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2706 File                           stmt   bran   cond    sub    pod   time  total
2707 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2708 blib/lib/DBM/Deep.pm           93.7   82.5   71.9   96.5   25.9   82.8   87.9
2709 blib/lib/DBM/Deep/Array.pm     98.8   88.0   90.9  100.0    n/a   12.8   96.3
2710 blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    4.4   92.3
2711 Total                          94.8   83.2   76.5   97.6   25.9  100.0   89.7
2712 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2713
2714 =head1 AUTHORS
2715
2716 Joseph Huckaby, L<jhuckaby@cpan.org>
2717 Rob Kinyon, L<rkinyon@cpan.org>
2718
2719 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2720
2721 =head1 SEE ALSO
2722
2723 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2724 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2725
2726 =head1 LICENSE
2727
2728 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2729 This is free software, you may use it and distribute it under the
2730 same terms as Perl itself.
2731
2732 =cut