lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.981_02);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type        => TYPE_HASH,
 167         parent      => undef,
 168         parent_key  => undef,
 169         base_offset => length(SIG_FILE),
 170     }, $class;
 171
 172     foreach my $param ( keys %$self ) {
 173         next unless exists $args->{$param};
 174         $self->{$param} = delete $args->{$param}
 175     }
 176
 177     # locking implicitly enables autoflush
 178     if ($args->{locking}) { $args->{autoflush} = 1; }
 179
 180     $self->{root} = exists $args->{root}
 181         ? $args->{root}
 182         : DBM::Deep::_::Root->new( $args );
 183
 184     if (!defined($self->_fh)) { $self->_open(); }
 185
 186     return $self;
 187 }
 188
 189 sub TIEHASH {
 190     shift;
 191     require DBM::Deep::Hash;
 192     return DBM::Deep::Hash->TIEHASH( @_ );
 193 }
 194
 195 sub TIEARRAY {
 196     shift;
 197     require DBM::Deep::Array;
 198     return DBM::Deep::Array->TIEARRAY( @_ );
 199 }
 200
 201 #XXX Unneeded now ...
 202 #sub DESTROY {
 203 #}
 204
 205 sub _open {
 206         ##
 207         # Open a fh to the database, create if nonexistent.
 208         # Make sure file signature matches DBM::Deep spec.
 209         ##
 210     my $self = $_[0]->_get_self;
 211
 212         if (defined($self->_fh)) { $self->_close(); }
 213
 214     eval {
 215         local $SIG{'__DIE__'};
 216         # Theoretically, adding O_BINARY should remove the need for the binmode
 217         # Of course, testing it is going to be ... interesting.
 218         my $flags = O_RDWR | O_CREAT | O_BINARY;
 219
 220         my $fh;
 221         sysopen( $fh, $self->_root->{file}, $flags )
 222             or $fh = undef;
 223         $self->_root->{fh} = $fh;
 224     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 225         if (! defined($self->_fh)) {
 226                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 227         }
 228
 229     my $fh = $self->_fh;
 230
 231     #XXX Can we remove this by using the right sysopen() flags?
 232     # Maybe ... q.v. above
 233     binmode $fh; # for win32
 234
 235     if ($self->_root->{autoflush}) {
 236         my $old = select $fh;
 237         $|=1;
 238         select $old;
 239     }
 240
 241     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 242
 243     my $signature;
 244     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 245
 246     ##
 247     # File is empty -- write signature and master index
 248     ##
 249     if (!$bytes_read) {
 250         if ( my $afh = $self->_root->{audit_fh} ) {
 251             flock( $afh, LOCK_EX );
 252             print( $afh "# Database created on " . localtime(time) . $/ );
 253             flock( $afh, LOCK_UN );
 254         }
 255
 256         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 257         print( $fh SIG_FILE);
 258         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262
 263         # Flush the filehandle
 264         my $old_fh = select $fh;
 265         my $old_af = $|; $| = 1; $| = $old_af;
 266         select $old_fh;
 267
 268         my @stats = stat($fh);
 269         $self->_root->{inode} = $stats[1];
 270         $self->_root->{end} = $stats[7];
 271
 272         return 1;
 273     }
 274
 275     ##
 276     # Check signature was valid
 277     ##
 278     unless ($signature eq SIG_FILE) {
 279         $self->_close();
 280         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 281     }
 282
 283         my @stats = stat($fh);
 284         $self->_root->{inode} = $stats[1];
 285     $self->_root->{end} = $stats[7];
 286
 287     ##
 288     # Get our type from master index signature
 289     ##
 290     my $tag = $self->_load_tag($self->_base_offset);
 291
 292 #XXX We probably also want to store the hash algorithm name and not assume anything
 293 #XXX The cool thing would be to allow a different hashing algorithm at every level
 294
 295     if (!$tag) {
 296         return $self->_throw_error("Corrupted file, no master index record");
 297     }
 298     if ($self->{type} ne $tag->{signature}) {
 299         return $self->_throw_error("File type mismatch");
 300     }
 301
 302     return 1;
 303 }
 304
 305 sub _close {
 306         ##
 307         # Close database fh
 308         ##
 309     my $self = $_[0]->_get_self;
 310     close $self->_root->{fh} if $self->_root->{fh};
 311     $self->_root->{fh} = undef;
 312 }
 313
 314 sub _create_tag {
 315         ##
 316         # Given offset, signature and content, create tag and write to disk
 317         ##
 318         my ($self, $offset, $sig, $content) = @_;
 319         my $size = length($content);
 320
 321     my $fh = $self->_fh;
 322
 323         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 324         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 325
 326         if ($offset == $self->_root->{end}) {
 327                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 328         }
 329
 330         return {
 331                 signature => $sig,
 332                 size => $size,
 333                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 334                 content => $content
 335         };
 336 }
 337
 338 sub _load_tag {
 339         ##
 340         # Given offset, load single tag and return signature, size and data
 341         ##
 342         my $self = shift;
 343         my $offset = shift;
 344
 345     my $fh = $self->_fh;
 346
 347         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 348         if (eof $fh) { return undef; }
 349
 350     my $b;
 351     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 352     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 353
 354         my $buffer;
 355         read( $fh, $buffer, $size);
 356
 357         return {
 358                 signature => $sig,
 359                 size => $size,
 360                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 361                 content => $buffer
 362         };
 363 }
 364
 365 sub _index_lookup {
 366         ##
 367         # Given index tag, lookup single entry in index and return .
 368         ##
 369         my $self = shift;
 370         my ($tag, $index) = @_;
 371
 372         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 373         if (!$location) { return; }
 374
 375         return $self->_load_tag( $location );
 376 }
 377
 378 sub _add_bucket {
 379         ##
 380         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 381         # plain (undigested) key and value.
 382         ##
 383         my $self = shift;
 384         my ($tag, $md5, $plain_key, $value, $orig_key) = @_;
 385         my $keys = $tag->{content};
 386         my $location = 0;
 387         my $result = 2;
 388
 389     my $root = $self->_root;
 390
 391     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 392         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 393
 394     my $fh = $self->_fh;
 395
 396         ##
 397         # Iterate through buckets, seeing if this is a new entry or a replace.
 398         ##
 399         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 400                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 401                 if (!$subloc) {
 402                         ##
 403                         # Found empty bucket (end of list).  Populate and exit loop.
 404                         ##
 405                         $result = 2;
 406
 407             $location = $internal_ref
 408                 ? $value->_base_offset
 409                 : $root->{end};
 410
 411                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 412                         print( $fh $md5 . pack($LONG_PACK, $location) );
 413                         last;
 414                 }
 415
 416                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 417                 if ($md5 eq $key) {
 418                         ##
 419                         # Found existing bucket with same key.  Replace with new value.
 420                         ##
 421                         $result = 1;
 422
 423                         if ($internal_ref) {
 424                                 $location = $value->_base_offset;
 425                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 426                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 427                 return $result;
 428                         }
 429
 430             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 431             my $size;
 432             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 433
 434             ##
 435             # If value is a hash, array, or raw value with equal or less size, we can
 436             # reuse the same content area of the database.  Otherwise, we have to create
 437             # a new content area at the EOF.
 438             ##
 439             my $actual_length;
 440             my $r = Scalar::Util::reftype( $value ) || '';
 441             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 442                 $actual_length = $INDEX_SIZE;
 443
 444                 # if autobless is enabled, must also take into consideration
 445                 # the class name, as it is stored along with key/value.
 446                 if ( $root->{autobless} ) {
 447                     my $value_class = Scalar::Util::blessed($value);
 448                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 449                         $actual_length += length($value_class);
 450                     }
 451                 }
 452             }
 453             else { $actual_length = length($value); }
 454
 455             if ($actual_length <= $size) {
 456                 $location = $subloc;
 457             }
 458             else {
 459                 $location = $root->{end};
 460                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 461                 print( $fh pack($LONG_PACK, $location) );
 462             }
 463
 464                         last;
 465                 }
 466         }
 467
 468         ##
 469         # If this is an internal reference, return now.
 470         # No need to write value or plain key
 471         ##
 472         if ($internal_ref) {
 473         return $result;
 474     }
 475
 476         ##
 477         # If bucket didn't fit into list, split into a new index level
 478         ##
 479         if (!$location) {
 480                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 481                 print( $fh pack($LONG_PACK, $root->{end}) );
 482
 483                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 484                 my @offsets = ();
 485
 486                 $keys .= $md5 . pack($LONG_PACK, 0);
 487
 488                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 489                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 490                         if ($key) {
 491                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 492                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 493
 494                                 if ($offsets[$num]) {
 495                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 496                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 497                                         my $subkeys;
 498                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 499
 500                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 501                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 502                                                 if (!$subloc) {
 503                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 504                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 505                                                         last;
 506                                                 }
 507                                         } # k loop
 508                                 }
 509                                 else {
 510                                         $offsets[$num] = $root->{end};
 511                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 512                                         print( $fh pack($LONG_PACK, $root->{end}) );
 513
 514                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 515
 516                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 517                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 518                                 }
 519                         } # key is real
 520                 } # i loop
 521
 522                 $location ||= $root->{end};
 523         } # re-index bucket list
 524
 525         ##
 526         # Seek to content area and store signature, value and plaintext key
 527         ##
 528         if ($location) {
 529                 my $content_length;
 530                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 531
 532                 ##
 533                 # Write signature based on content type, set content length and write actual value.
 534                 ##
 535         my $r = Scalar::Util::reftype($value) || '';
 536                 if ($r eq 'HASH') {
 537                         print( $fh TYPE_HASH );
 538                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 539                         $content_length = $INDEX_SIZE;
 540                 }
 541                 elsif ($r eq 'ARRAY') {
 542                         print( $fh TYPE_ARRAY );
 543                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 544                         $content_length = $INDEX_SIZE;
 545                 }
 546                 elsif (!defined($value)) {
 547                         print( $fh SIG_NULL );
 548                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 549                         $content_length = 0;
 550                 }
 551                 else {
 552                         print( $fh SIG_DATA );
 553                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 554                         $content_length = length($value);
 555                 }
 556
 557                 ##
 558                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 559                 ##
 560                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 561
 562                 ##
 563                 # If value is blessed, preserve class name
 564                 ##
 565                 if ( $root->{autobless} ) {
 566             my $value_class = Scalar::Util::blessed($value);
 567             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 568                 ##
 569                 # Blessed ref -- will restore later
 570                 ##
 571                 print( $fh chr(1) );
 572                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 573                 $content_length += 1;
 574                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 575             }
 576             else {
 577                 print( $fh chr(0) );
 578                 $content_length += 1;
 579             }
 580         }
 581
 582                 ##
 583                 # If this is a new content area, advance EOF counter
 584                 ##
 585                 if ($location == $root->{end}) {
 586                         $root->{end} += SIG_SIZE;
 587                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 588                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 589                 }
 590
 591                 ##
 592                 # If content is a hash or array, create new child DBM::Deep object and
 593                 # pass each key or element to it.
 594                 ##
 595                 if ($r eq 'HASH') {
 596                         my $branch = DBM::Deep->new(
 597                                 type => TYPE_HASH,
 598                                 base_offset => $location,
 599                                 root => $root,
 600                 parent => $self,
 601                 parent_key => $orig_key,
 602                         );
 603                         foreach my $key (keys %{$value}) {
 604                 $branch->STORE( $key, $value->{$key} );
 605                         }
 606                 }
 607                 elsif ($r eq 'ARRAY') {
 608                         my $branch = DBM::Deep->new(
 609                                 type => TYPE_ARRAY,
 610                                 base_offset => $location,
 611                                 root => $root,
 612                 parent => $self,
 613                 parent_key => $orig_key,
 614                         );
 615                         my $index = 0;
 616                         foreach my $element (@{$value}) {
 617                 $branch->STORE( $index, $element );
 618                                 $index++;
 619                         }
 620                 }
 621
 622                 return $result;
 623         }
 624
 625         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 626 }
 627
 628 sub _get_bucket_value {
 629         ##
 630         # Fetch single value given tag and MD5 digested key.
 631         ##
 632         my $self = shift;
 633         my ($tag, $md5, $plain_key) = @_;
 634         my $keys = $tag->{content};
 635
 636     my $fh = $self->_fh;
 637
 638         ##
 639         # Iterate through buckets, looking for a key match
 640         ##
 641     BUCKET:
 642         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 643                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 644                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 645
 646                 if (!$subloc) {
 647                         ##
 648                         # Hit end of list, no match
 649                         ## return;
 650                 }
 651
 652         if ( $md5 ne $key ) {
 653             next BUCKET;
 654         }
 655
 656         ##
 657         # Found match -- seek to offset and read signature
 658         ##
 659         my $signature;
 660         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 661         read( $fh, $signature, SIG_SIZE);
 662
 663         ##
 664         # If value is a hash or array, return new DBM::Deep object with correct offset
 665         ##
 666         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 667             my $obj = DBM::Deep->new(
 668                 type => $signature,
 669                 base_offset => $subloc,
 670                 root => $self->_root,
 671                 parent => $self,
 672                 parent_key => $plain_key,
 673             );
 674
 675             if ($self->_root->{autobless}) {
 676                 ##
 677                 # Skip over value and plain key to see if object needs
 678                 # to be re-blessed
 679                 ##
 680                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 681
 682                 my $size;
 683                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 684                 if ($size) { seek($fh, $size, SEEK_CUR); }
 685
 686                 my $bless_bit;
 687                 read( $fh, $bless_bit, 1);
 688                 if (ord($bless_bit)) {
 689                     ##
 690                     # Yes, object needs to be re-blessed
 691                     ##
 692                     my $class_name;
 693                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 694                     if ($size) { read( $fh, $class_name, $size); }
 695                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 696                 }
 697             }
 698
 699             return $obj;
 700         }
 701
 702         ##
 703         # Otherwise return actual value
 704         ##
 705         elsif ($signature eq SIG_DATA) {
 706             my $size;
 707             my $value = '';
 708             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 709             if ($size) { read( $fh, $value, $size); }
 710             return $value;
 711         }
 712
 713         ##
 714         # Key exists, but content is null
 715         ##
 716         else { return; }
 717         } # i loop
 718
 719         return;
 720 }
 721
 722 sub _delete_bucket {
 723         ##
 724         # Delete single key/value pair given tag and MD5 digested key.
 725         ##
 726         my $self = shift;
 727         my ($tag, $md5) = @_;
 728         my $keys = $tag->{content};
 729
 730     my $fh = $self->_fh;
 731
 732         ##
 733         # Iterate through buckets, looking for a key match
 734         ##
 735     BUCKET:
 736         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 737                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 738                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 739
 740                 if (!$subloc) {
 741                         ##
 742                         # Hit end of list, no match
 743                         ##
 744                         return;
 745                 }
 746
 747         if ( $md5 ne $key ) {
 748             next BUCKET;
 749         }
 750
 751         ##
 752         # Matched key -- delete bucket and return
 753         ##
 754         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 755         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 756         print( $fh chr(0) x $BUCKET_SIZE );
 757
 758         return 1;
 759         } # i loop
 760
 761         return;
 762 }
 763
 764 sub _bucket_exists {
 765         ##
 766         # Check existence of single key given tag and MD5 digested key.
 767         ##
 768         my $self = shift;
 769         my ($tag, $md5) = @_;
 770         my $keys = $tag->{content};
 771
 772         ##
 773         # Iterate through buckets, looking for a key match
 774         ##
 775     BUCKET:
 776         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 777                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 778                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 779
 780                 if (!$subloc) {
 781                         ##
 782                         # Hit end of list, no match
 783                         ##
 784                         return;
 785                 }
 786
 787         if ( $md5 ne $key ) {
 788             next BUCKET;
 789         }
 790
 791         ##
 792         # Matched key -- return true
 793         ##
 794         return 1;
 795         } # i loop
 796
 797         return;
 798 }
 799
 800 sub _find_bucket_list {
 801         ##
 802         # Locate offset for bucket list, given digested key
 803         ##
 804         my $self = shift;
 805         my $md5 = shift;
 806
 807         ##
 808         # Locate offset for bucket list using digest index system
 809         ##
 810         my $ch = 0;
 811         my $tag = $self->_load_tag($self->_base_offset);
 812         if (!$tag) { return; }
 813
 814         while ($tag->{signature} ne SIG_BLIST) {
 815                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 816                 if (!$tag) { return; }
 817                 $ch++;
 818         }
 819
 820         return $tag;
 821 }
 822
 823 sub _traverse_index {
 824         ##
 825         # Scan index and recursively step into deeper levels, looking for next key.
 826         ##
 827     my ($self, $offset, $ch, $force_return_next) = @_;
 828     $force_return_next = undef unless $force_return_next;
 829
 830         my $tag = $self->_load_tag( $offset );
 831
 832     my $fh = $self->_fh;
 833
 834         if ($tag->{signature} ne SIG_BLIST) {
 835                 my $content = $tag->{content};
 836                 my $start;
 837                 if ($self->{return_next}) { $start = 0; }
 838                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 839
 840                 for (my $index = $start; $index < 256; $index++) {
 841                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 842                         if ($subloc) {
 843                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 844                                 if (defined($result)) { return $result; }
 845                         }
 846                 } # index loop
 847
 848                 $self->{return_next} = 1;
 849         } # tag is an index
 850
 851         elsif ($tag->{signature} eq SIG_BLIST) {
 852                 my $keys = $tag->{content};
 853                 if ($force_return_next) { $self->{return_next} = 1; }
 854
 855                 ##
 856                 # Iterate through buckets, looking for a key match
 857                 ##
 858                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 859                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 860                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 861
 862                         if (!$subloc) {
 863                                 ##
 864                                 # End of bucket list -- return to outer loop
 865                                 ##
 866                                 $self->{return_next} = 1;
 867                                 last;
 868                         }
 869                         elsif ($key eq $self->{prev_md5}) {
 870                                 ##
 871                                 # Located previous key -- return next one found
 872                                 ##
 873                                 $self->{return_next} = 1;
 874                                 next;
 875                         }
 876                         elsif ($self->{return_next}) {
 877                                 ##
 878                                 # Seek to bucket location and skip over signature
 879                                 ##
 880                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 881
 882                                 ##
 883                                 # Skip over value to get to plain key
 884                                 ##
 885                                 my $size;
 886                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 887                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 888
 889                                 ##
 890                                 # Read in plain key and return as scalar
 891                                 ##
 892                                 my $plain_key;
 893                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 894                                 if ($size) { read( $fh, $plain_key, $size); }
 895
 896                                 return $plain_key;
 897                         }
 898                 } # bucket loop
 899
 900                 $self->{return_next} = 1;
 901         } # tag is a bucket list
 902
 903         return;
 904 }
 905
 906 sub _get_next_key {
 907         ##
 908         # Locate next key, given digested previous one
 909         ##
 910     my $self = $_[0]->_get_self;
 911
 912         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 913         $self->{return_next} = 0;
 914
 915         ##
 916         # If the previous key was not specifed, start at the top and
 917         # return the first one found.
 918         ##
 919         if (!$self->{prev_md5}) {
 920                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 921                 $self->{return_next} = 1;
 922         }
 923
 924         return $self->_traverse_index( $self->_base_offset, 0 );
 925 }
 926
 927 sub lock {
 928         ##
 929         # If db locking is set, flock() the db file.  If called multiple
 930         # times before unlock(), then the same number of unlocks() must
 931         # be called before the lock is released.
 932         ##
 933     my $self = $_[0]->_get_self;
 934         my $type = $_[1];
 935     $type = LOCK_EX unless defined $type;
 936
 937         if (!defined($self->_fh)) { return; }
 938
 939         if ($self->_root->{locking}) {
 940                 if (!$self->_root->{locked}) {
 941                         flock($self->_fh, $type);
 942
 943                         # refresh end counter in case file has changed size
 944                         my @stats = stat($self->_root->{file});
 945                         $self->_root->{end} = $stats[7];
 946
 947                         # double-check file inode, in case another process
 948                         # has optimize()d our file while we were waiting.
 949                         if ($stats[1] != $self->_root->{inode}) {
 950                                 $self->_open(); # re-open
 951                                 flock($self->_fh, $type); # re-lock
 952                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 953                         }
 954                 }
 955                 $self->_root->{locked}++;
 956
 957         return 1;
 958         }
 959
 960     return;
 961 }
 962
 963 sub unlock {
 964         ##
 965         # If db locking is set, unlock the db file.  See note in lock()
 966         # regarding calling lock() multiple times.
 967         ##
 968     my $self = $_[0]->_get_self;
 969
 970         if (!defined($self->_fh)) { return; }
 971
 972         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 973                 $self->_root->{locked}--;
 974                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 975
 976         return 1;
 977         }
 978
 979     return;
 980 }
 981
 982 sub _copy_value {
 983     my $self = shift->_get_self;
 984     my ($spot, $value) = @_;
 985
 986     if ( !ref $value ) {
 987         ${$spot} = $value;
 988     }
 989     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 990         my $type = $value->_type;
 991         ${$spot} = $type eq TYPE_HASH ? {} : [];
 992         $value->_copy_node( ${$spot} );
 993     }
 994     else {
 995         my $r = Scalar::Util::reftype( $value );
 996         my $c = Scalar::Util::blessed( $value );
 997         if ( $r eq 'ARRAY' ) {
 998             ${$spot} = [ @{$value} ];
 999         }
1000         else {
1001             ${$spot} = { %{$value} };
1002         }
1003         ${$spot} = bless ${$spot}, $c
1004             if defined $c;
1005     }
1006
1007     return 1;
1008 }
1009
1010 sub _copy_node {
1011         ##
1012         # Copy single level of keys or elements to new DB handle.
1013         # Recurse for nested structures
1014         ##
1015     my $self = shift->_get_self;
1016         my ($db_temp) = @_;
1017
1018         if ($self->_type eq TYPE_HASH) {
1019                 my $key = $self->first_key();
1020                 while ($key) {
1021                         my $value = $self->get($key);
1022             $self->_copy_value( \$db_temp->{$key}, $value );
1023                         $key = $self->next_key($key);
1024                 }
1025         }
1026         else {
1027                 my $length = $self->length();
1028                 for (my $index = 0; $index < $length; $index++) {
1029                         my $value = $self->get($index);
1030             $self->_copy_value( \$db_temp->[$index], $value );
1031                 }
1032         }
1033
1034     return 1;
1035 }
1036
1037 sub export {
1038         ##
1039         # Recursively export into standard Perl hashes and arrays.
1040         ##
1041     my $self = $_[0]->_get_self;
1042
1043         my $temp;
1044         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1045         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1046
1047         $self->lock();
1048         $self->_copy_node( $temp );
1049         $self->unlock();
1050
1051         return $temp;
1052 }
1053
1054 sub import {
1055         ##
1056         # Recursively import Perl hash/array structure
1057         ##
1058     #XXX This use of ref() seems to be ok
1059         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1060
1061     my $self = $_[0]->_get_self;
1062         my $struct = $_[1];
1063
1064     #XXX This use of ref() seems to be ok
1065         if (!ref($struct)) {
1066                 ##
1067                 # struct is not a reference, so just import based on our type
1068                 ##
1069                 shift @_;
1070
1071                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1072                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1073         }
1074
1075     my $r = Scalar::Util::reftype($struct) || '';
1076         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1077                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1078         }
1079         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1080                 $self->push( @$struct );
1081         }
1082         else {
1083                 return $self->_throw_error("Cannot import: type mismatch");
1084         }
1085
1086         return 1;
1087 }
1088
1089 sub optimize {
1090         ##
1091         # Rebuild entire database into new file, then move
1092         # it back on top of original.
1093         ##
1094     my $self = $_[0]->_get_self;
1095
1096 #XXX Need to create a new test for this
1097 #       if ($self->_root->{links} > 1) {
1098 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1099 #       }
1100
1101         my $db_temp = DBM::Deep->new(
1102                 file => $self->_root->{file} . '.tmp',
1103                 type => $self->_type
1104         );
1105         if (!$db_temp) {
1106                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1107         }
1108
1109         $self->lock();
1110         $self->_copy_node( $db_temp );
1111         undef $db_temp;
1112
1113         ##
1114         # Attempt to copy user, group and permissions over to new file
1115         ##
1116         my @stats = stat($self->_fh);
1117         my $perms = $stats[2] & 07777;
1118         my $uid = $stats[4];
1119         my $gid = $stats[5];
1120         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1121         chmod( $perms, $self->_root->{file} . '.tmp' );
1122
1123     # q.v. perlport for more information on this variable
1124     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1125                 ##
1126                 # Potential race condition when optmizing on Win32 with locking.
1127                 # The Windows filesystem requires that the filehandle be closed
1128                 # before it is overwritten with rename().  This could be redone
1129                 # with a soft copy.
1130                 ##
1131                 $self->unlock();
1132                 $self->_close();
1133         }
1134
1135         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1136                 unlink $self->_root->{file} . '.tmp';
1137                 $self->unlock();
1138                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1139         }
1140
1141         $self->unlock();
1142         $self->_close();
1143         $self->_open();
1144
1145         return 1;
1146 }
1147
1148 sub clone {
1149         ##
1150         # Make copy of object and return
1151         ##
1152     my $self = $_[0]->_get_self;
1153
1154         return DBM::Deep->new(
1155                 type => $self->_type,
1156                 base_offset => $self->_base_offset,
1157                 root => $self->_root,
1158         parent => $self->{parent},
1159         parent_key => $self->{parent_key},
1160         );
1161 }
1162
1163 {
1164     my %is_legal_filter = map {
1165         $_ => ~~1,
1166     } qw(
1167         store_key store_value
1168         fetch_key fetch_value
1169     );
1170
1171     sub set_filter {
1172         ##
1173         # Setup filter function for storing or fetching the key or value
1174         ##
1175         my $self = $_[0]->_get_self;
1176         my $type = lc $_[1];
1177         my $func = $_[2] ? $_[2] : undef;
1178
1179         if ( $is_legal_filter{$type} ) {
1180             $self->_root->{"filter_$type"} = $func;
1181             return 1;
1182         }
1183
1184         return;
1185     }
1186 }
1187
1188 ##
1189 # Accessor methods
1190 ##
1191
1192 sub _root {
1193         ##
1194         # Get access to the root structure
1195         ##
1196     my $self = $_[0]->_get_self;
1197         return $self->{root};
1198 }
1199
1200 sub _fh {
1201         ##
1202         # Get access to the raw fh
1203         ##
1204     #XXX It will be useful, though, when we split out HASH and ARRAY
1205     my $self = $_[0]->_get_self;
1206         return $self->_root->{fh};
1207 }
1208
1209 sub _type {
1210         ##
1211         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1212         ##
1213     my $self = $_[0]->_get_self;
1214         return $self->{type};
1215 }
1216
1217 sub _base_offset {
1218         ##
1219         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1220         ##
1221     my $self = $_[0]->_get_self;
1222         return $self->{base_offset};
1223 }
1224
1225 sub error {
1226         ##
1227         # Get last error string, or undef if no error
1228         ##
1229         return $_[0]
1230         ? ( $_[0]->_get_self->{root}->{error} or undef )
1231         : $@;
1232 }
1233
1234 ##
1235 # Utility methods
1236 ##
1237
1238 sub _throw_error {
1239         ##
1240         # Store error string in self
1241         ##
1242         my $error_text = $_[1];
1243
1244     if ( Scalar::Util::blessed $_[0] ) {
1245         my $self = $_[0]->_get_self;
1246         $self->_root->{error} = $error_text;
1247
1248         unless ($self->_root->{debug}) {
1249             die "DBM::Deep: $error_text\n";
1250         }
1251
1252         warn "DBM::Deep: $error_text\n";
1253         return;
1254     }
1255     else {
1256         die "DBM::Deep: $error_text\n";
1257     }
1258 }
1259
1260 sub clear_error {
1261         ##
1262         # Clear error state
1263         ##
1264     my $self = $_[0]->_get_self;
1265
1266         undef $self->_root->{error};
1267 }
1268
1269 sub _precalc_sizes {
1270         ##
1271         # Precalculate index, bucket and bucket list sizes
1272         ##
1273
1274     #XXX I don't like this ...
1275     set_pack() unless defined $LONG_SIZE;
1276
1277         $INDEX_SIZE = 256 * $LONG_SIZE;
1278         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1279         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1280 }
1281
1282 sub set_pack {
1283         ##
1284         # Set pack/unpack modes (see file header for more)
1285         ##
1286     my ($long_s, $long_p, $data_s, $data_p) = @_;
1287
1288     $LONG_SIZE = $long_s ? $long_s : 4;
1289     $LONG_PACK = $long_p ? $long_p : 'N';
1290
1291     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1292     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1293
1294         _precalc_sizes();
1295 }
1296
1297 sub set_digest {
1298         ##
1299         # Set key digest function (default is MD5)
1300         ##
1301     my ($digest_func, $hash_size) = @_;
1302
1303     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1304     $HASH_SIZE = $hash_size ? $hash_size : 16;
1305
1306         _precalc_sizes();
1307 }
1308
1309 sub _is_writable {
1310     my $fh = shift;
1311     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1312 }
1313
1314 #sub _is_readable {
1315 #    my $fh = shift;
1316 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1317 #}
1318
1319 ##
1320 # tie() methods (hashes and arrays)
1321 ##
1322
1323 sub _find_parent {
1324     my $self = shift;
1325     if ( $self->{parent} ) {
1326         my $base = $self->{parent}->_find_parent();
1327         if ( $self->{parent}->_type eq TYPE_HASH ) {
1328             return $base . "\{$self->{parent_key}\}";
1329         }
1330         return $base . "\[$self->{parent_key}\]";
1331     }
1332     return '$db->';
1333 }
1334
1335 sub STORE {
1336         ##
1337         # Store single hash key/value or array element in database.
1338         ##
1339     my $self = $_[0]->_get_self;
1340         my $key = $_[1];
1341
1342     # User may be storing a hash, in which case we do not want it run
1343     # through the filtering system
1344         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1345         ? $self->_root->{filter_store_value}->($_[2])
1346         : $_[2];
1347
1348     if ( my $afh = $self->_root->{audit_fh} ) {
1349         unless ( $self->_type eq SIG_ARRAY && $key eq 'length' ) {
1350             my $lhs = $self->_find_parent;
1351             if ( $self->_type eq SIG_HASH ) {
1352                 $lhs .= "\{$key\}";
1353             }
1354             else {
1355                 $lhs .= "\[$_[3]\]";
1356             }
1357
1358             my $rhs;
1359
1360             my $r = Scalar::Util::reftype( $_[2] ) || '';
1361             if ( $r eq 'HASH' ) {
1362                 $rhs = '{}';
1363             }
1364             elsif ( $r eq 'ARRAY' ) {
1365                 $rhs = '[]';
1366             }
1367             else {
1368                 $rhs = "'$_[2]'";
1369             }
1370
1371             if ( my $c = Scalar::Util::blessed( $_[2] ) ) {
1372                 $rhs = "bless $rhs, '$c'";
1373             }
1374
1375             flock( $afh, LOCK_EX );
1376             print( $afh "$lhs = $rhs; # " . localtime(time) . "\n" );
1377             flock( $afh, LOCK_UN );
1378         }
1379     }
1380
1381         my $md5 = $DIGEST_FUNC->($key);
1382
1383         ##
1384         # Make sure file is open
1385         ##
1386         if (!defined($self->_fh) && !$self->_open()) {
1387                 return;
1388         }
1389
1390     unless ( _is_writable( $self->_fh ) ) {
1391         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1392     }
1393
1394         ##
1395         # Request exclusive lock for writing
1396         ##
1397         $self->lock( LOCK_EX );
1398
1399         my $fh = $self->_fh;
1400
1401         ##
1402         # Locate offset for bucket list using digest index system
1403         ##
1404         my $tag = $self->_load_tag($self->_base_offset);
1405         if (!$tag) {
1406                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1407         }
1408
1409         my $ch = 0;
1410         while ($tag->{signature} ne SIG_BLIST) {
1411                 my $num = ord(substr($md5, $ch, 1));
1412
1413         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1414                 my $new_tag = $self->_index_lookup($tag, $num);
1415
1416                 if (!$new_tag) {
1417                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1418                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1419
1420                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1421
1422                         $tag->{ref_loc} = $ref_loc;
1423                         $tag->{ch} = $ch;
1424
1425                         last;
1426                 }
1427                 else {
1428                         $tag = $new_tag;
1429
1430                         $tag->{ref_loc} = $ref_loc;
1431                         $tag->{ch} = $ch;
1432                 }
1433                 $ch++;
1434         }
1435
1436         ##
1437         # Add key/value to bucket list
1438         ##
1439         my $result = $self->_add_bucket( $tag, $md5, $key, $value, $_[3] || $key );
1440
1441         $self->unlock();
1442
1443         return $result;
1444 }
1445
1446 sub FETCH {
1447         ##
1448         # Fetch single value or element given plain key or array index
1449         ##
1450     my $self = shift->_get_self;
1451     my $key = shift;
1452
1453         ##
1454         # Make sure file is open
1455         ##
1456         if (!defined($self->_fh)) { $self->_open(); }
1457
1458         my $md5 = $DIGEST_FUNC->($key);
1459
1460         ##
1461         # Request shared lock for reading
1462         ##
1463         $self->lock( LOCK_SH );
1464
1465         my $tag = $self->_find_bucket_list( $md5 );
1466         if (!$tag) {
1467                 $self->unlock();
1468                 return;
1469         }
1470
1471         ##
1472         # Get value from bucket list
1473         ##
1474         my $result = $self->_get_bucket_value( $tag, $md5, $key );
1475
1476         $self->unlock();
1477
1478     #XXX What is ref() checking here?
1479     #YYY Filters only apply on scalar values, so the ref check is making
1480     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1481         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1482         ? $self->_root->{filter_fetch_value}->($result)
1483         : $result;
1484 }
1485
1486 sub DELETE {
1487         ##
1488         # Delete single key/value pair or element given plain key or array index
1489         ##
1490     my $self = shift->_get_self;
1491         my ($key, $orig_key) = @_;
1492
1493     if ( my $afh = $self->_root->{audit_fh} ) {
1494         unless ( $self->_type eq SIG_ARRAY && $key eq 'length' ) {
1495             my $lhs = $self->_find_parent;
1496             if ( $self->_type eq SIG_HASH ) {
1497                 $lhs .= "\{$key\}";
1498             }
1499             else {
1500                 $lhs .= "\[$_[3]\]";
1501             }
1502
1503             flock( $afh, LOCK_EX );
1504             print( $afh "delete $lhs; # " . localtime(time) . "\n" );
1505             flock( $afh, LOCK_UN );
1506         }
1507     }
1508
1509         my $md5 = $DIGEST_FUNC->($key);
1510
1511         ##
1512         # Make sure file is open
1513         ##
1514         if (!defined($self->_fh)) { $self->_open(); }
1515
1516         ##
1517         # Request exclusive lock for writing
1518         ##
1519         $self->lock( LOCK_EX );
1520
1521         my $tag = $self->_find_bucket_list( $md5 );
1522         if (!$tag) {
1523                 $self->unlock();
1524                 return;
1525         }
1526
1527         ##
1528         # Delete bucket
1529         ##
1530     my $value = $self->_get_bucket_value( $tag, $md5, $key );
1531         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1532         $value = $self->_root->{filter_fetch_value}->($value);
1533     }
1534
1535         my $result = $self->_delete_bucket( $tag, $md5 );
1536
1537         ##
1538         # If this object is an array and the key deleted was on the end of the stack,
1539         # decrement the length variable.
1540         ##
1541
1542         $self->unlock();
1543
1544         return $value;
1545 }
1546
1547 sub EXISTS {
1548         ##
1549         # Check if a single key or element exists given plain key or array index
1550         ##
1551     my $self = $_[0]->_get_self;
1552         my $key = $_[1];
1553
1554         my $md5 = $DIGEST_FUNC->($key);
1555
1556         ##
1557         # Make sure file is open
1558         ##
1559         if (!defined($self->_fh)) { $self->_open(); }
1560
1561         ##
1562         # Request shared lock for reading
1563         ##
1564         $self->lock( LOCK_SH );
1565
1566         my $tag = $self->_find_bucket_list( $md5 );
1567
1568         ##
1569         # For some reason, the built-in exists() function returns '' for false
1570         ##
1571         if (!$tag) {
1572                 $self->unlock();
1573                 return '';
1574         }
1575
1576         ##
1577         # Check if bucket exists and return 1 or ''
1578         ##
1579         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1580
1581         $self->unlock();
1582
1583         return $result;
1584 }
1585
1586 sub CLEAR {
1587         ##
1588         # Clear all keys from hash, or all elements from array.
1589         ##
1590     my $self = $_[0]->_get_self;
1591
1592     if ( my $afh = $self->_root->{audit_fh} ) {
1593         my $lhs = $self->_find_parent;
1594
1595         my $rhs;
1596         if ( $self->_type eq SIG_HASH ) {
1597             $rhs = '{}';
1598         }
1599         elsif ( $self->_type eq SIG_ARRAY ) {
1600             $rhs = '[]';
1601         }
1602
1603         flock( $afh, LOCK_EX );
1604         print( $afh "$lhs = $rhs; # " . localtime(time) . "\n" );
1605         flock( $afh, LOCK_UN );
1606     }
1607
1608         ##
1609         # Make sure file is open
1610         ##
1611         if (!defined($self->_fh)) { $self->_open(); }
1612
1613         ##
1614         # Request exclusive lock for writing
1615         ##
1616         $self->lock( LOCK_EX );
1617
1618     my $fh = $self->_fh;
1619
1620         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1621         if (eof $fh) {
1622                 $self->unlock();
1623                 return;
1624         }
1625
1626         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1627
1628         $self->unlock();
1629
1630         return 1;
1631 }
1632
1633 ##
1634 # Public method aliases
1635 ##
1636 sub put { (shift)->STORE( @_ ) }
1637 sub store { (shift)->STORE( @_ ) }
1638 sub get { (shift)->FETCH( @_ ) }
1639 sub fetch { (shift)->FETCH( @_ ) }
1640 sub delete { (shift)->DELETE( @_ ) }
1641 sub exists { (shift)->EXISTS( @_ ) }
1642 sub clear { (shift)->CLEAR( @_ ) }
1643
1644 package DBM::Deep::_::Root;
1645
1646 use Fcntl;
1647
1648 sub new {
1649     my $class = shift;
1650     my ($args) = @_;
1651
1652     my $self = bless {
1653         file => undef,
1654         fh => undef,
1655         file_offset => 0,
1656         end => 0,
1657         autoflush => undef,
1658         locking => undef,
1659         debug => undef,
1660         filter_store_key => undef,
1661         filter_store_value => undef,
1662         filter_fetch_key => undef,
1663         filter_fetch_value => undef,
1664         autobless => undef,
1665         locked => 0,
1666         %$args,
1667     }, $class;
1668
1669     if ( $self->{fh} && !$self->{file_offset} ) {
1670         $self->{file_offset} = tell( $self->{fh} );
1671     }
1672
1673     if ( $self->{audit_file} && !$self->{audit_fh} ) {
1674         my $flags = O_WRONLY | O_APPEND | O_CREAT;
1675
1676         my $fh;
1677         sysopen( $fh, $self->{audit_file}, $flags )
1678             or die "Cannot open audit file: $!";
1679
1680         my $old = select $fh;
1681         $|=1;
1682         select $old;
1683
1684         $self->{audit_fh} = $fh;
1685     }
1686
1687     return $self;
1688 }
1689
1690 sub DESTROY {
1691     my $self = shift;
1692     return unless $self;
1693
1694     close $self->{fh} if $self->{fh};
1695
1696     return;
1697 }
1698
1699 1;
1700
1701 __END__
1702
1703 =head1 NAME
1704
1705 DBM::Deep - A pure perl multi-level hash/array DBM
1706
1707 =head1 SYNOPSIS
1708
1709   use DBM::Deep;
1710   my $db = DBM::Deep->new( "foo.db" );
1711
1712   $db->{key} = 'value'; # tie() style
1713   print $db->{key};
1714
1715   $db->put('key' => 'value'); # OO style
1716   print $db->get('key');
1717
1718   # true multi-level support
1719   $db->{my_complex} = [
1720         'hello', { perl => 'rules' },
1721         42, 99,
1722   ];
1723
1724 =head1 DESCRIPTION
1725
1726 A unique flat-file database module, written in pure perl.  True
1727 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1728 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1729 handle millions of keys and unlimited hash levels without significant
1730 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1731 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1732 Mac OS X and Windows.
1733
1734 =head1 INSTALLATION
1735
1736 Hopefully you are using Perl's excellent CPAN module, which will download
1737 and install the module for you.  If not, get the tarball, and run these
1738 commands:
1739
1740         tar zxf DBM-Deep-*
1741         cd DBM-Deep-*
1742         perl Makefile.PL
1743         make
1744         make test
1745         make install
1746
1747 =head1 SETUP
1748
1749 Construction can be done OO-style (which is the recommended way), or using
1750 Perl's tie() function.  Both are examined here.
1751
1752 =head2 OO CONSTRUCTION
1753
1754 The recommended way to construct a DBM::Deep object is to use the new()
1755 method, which gets you a blessed, tied hash or array reference.
1756
1757         my $db = DBM::Deep->new( "foo.db" );
1758
1759 This opens a new database handle, mapped to the file "foo.db".  If this
1760 file does not exist, it will automatically be created.  DB files are
1761 opened in "r+" (read/write) mode, and the type of object returned is a
1762 hash, unless otherwise specified (see L<OPTIONS> below).
1763
1764 You can pass a number of options to the constructor to specify things like
1765 locking, autoflush, etc.  This is done by passing an inline hash:
1766
1767         my $db = DBM::Deep->new(
1768                 file => "foo.db",
1769                 locking => 1,
1770                 autoflush => 1
1771         );
1772
1773 Notice that the filename is now specified I<inside> the hash with
1774 the "file" parameter, as opposed to being the sole argument to the
1775 constructor.  This is required if any options are specified.
1776 See L<OPTIONS> below for the complete list.
1777
1778
1779
1780 You can also start with an array instead of a hash.  For this, you must
1781 specify the C<type> parameter:
1782
1783         my $db = DBM::Deep->new(
1784                 file => "foo.db",
1785                 type => DBM::Deep->TYPE_ARRAY
1786         );
1787
1788 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1789 a new DB file.  If you create a DBM::Deep object with an existing file, the
1790 C<type> will be loaded from the file header, and an error will be thrown if
1791 the wrong type is passed in.
1792
1793 =head2 TIE CONSTRUCTION
1794
1795 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1796 tie() function.  The object returned from tie() can be used to call methods,
1797 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1798 file (as expected with most tie'd objects).
1799
1800         my %hash;
1801         my $db = tie %hash, "DBM::Deep", "foo.db";
1802
1803         my @array;
1804         my $db = tie @array, "DBM::Deep", "bar.db";
1805
1806 As with the OO constructor, you can replace the DB filename parameter with
1807 a hash containing one or more options (see L<OPTIONS> just below for the
1808 complete list).
1809
1810         tie %hash, "DBM::Deep", {
1811                 file => "foo.db",
1812                 locking => 1,
1813                 autoflush => 1
1814         };
1815
1816 =head2 OPTIONS
1817
1818 There are a number of options that can be passed in when constructing your
1819 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1820
1821 =over
1822
1823 =item * file
1824
1825 Filename of the DB file to link the handle to.  You can pass a full absolute
1826 filesystem path, partial path, or a plain filename if the file is in the
1827 current working directory.  This is a required parameter (though q.v. fh).
1828
1829 =item * fh
1830
1831 If you want, you can pass in the fh instead of the file. This is most useful for doing
1832 something like:
1833
1834   my $db = DBM::Deep->new( { fh => \*DATA } );
1835
1836 You are responsible for making sure that the fh has been opened appropriately for your
1837 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1838 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1839 needs to read from the fh.
1840
1841 =item * file_offset
1842
1843 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1844 not need to set this. However, it's there if you want it.
1845
1846 If you pass in fh and do not set this, it will be set appropriately.
1847
1848 =item * type
1849
1850 This parameter specifies what type of object to create, a hash or array.  Use
1851 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1852 This only takes effect when beginning a new file.  This is an optional
1853 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1854
1855 =item * locking
1856
1857 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1858 function to lock the database in exclusive mode for writes, and shared mode for
1859 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1860 any child hashes or arrays> that use the same DB file.  This is an optional
1861 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1862
1863 =item * autoflush
1864
1865 Specifies whether autoflush is to be enabled on the underlying filehandle.
1866 This obviously slows down write operations, but is required if you may have
1867 multiple processes accessing the same DB file (also consider enable I<locking>).
1868 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1869 (disabled).
1870
1871 =item * autobless
1872
1873 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1874 restore them when fetched.  This is an B<experimental> feature, and does have
1875 side-effects.  Basically, when hashes are re-blessed into their original
1876 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1877 able to call any DBM::Deep methods on them.  You have been warned.
1878 This is an optional parameter, and defaults to 0 (disabled).
1879
1880 =item * filter_*
1881
1882 See L<FILTERS> below.
1883
1884 =item * debug
1885
1886 Setting I<debug> mode will make all errors non-fatal, dump them out to
1887 STDERR, and continue on.  This is for debugging purposes only, and probably
1888 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1889
1890 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1891
1892 =item * audit_file / audit_fh
1893
1894 If you set either of these, an auditlog will be written to. If you set
1895 audit_file, audit_fh will be set to the open() on the audit_file.
1896
1897 The auditing information will look something like:
1898
1899   $db->{foo} = 'floober';
1900   $db->{bar} = {};
1901   $db->{bar}{a} = [];
1902   $db->{bar}{a}[0] = '5';
1903
1904 The idea is that if your DB file is corrupted, you can recover it by doing
1905 something like:
1906
1907   my $db = DBM::Deep->new( $new_filename );
1908   do( $audit_file );
1909
1910 It is your responsability to make sure that the same auditlog is opened with the
1911 same DB file every time the DB file is opened. This will change when 1.00 is
1912 released.
1913
1914 =back
1915
1916 =head1 TIE INTERFACE
1917
1918 With DBM::Deep you can access your databases using Perl's standard hash/array
1919 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1920 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1921 to the right place -- the DB file.  This has nothing to do with the
1922 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1923 using regular hashes and arrays, rather than calling functions like C<get()>
1924 and C<put()> (although those work too).  It is entirely up to you how to want
1925 to access your databases.
1926
1927 =head2 HASHES
1928
1929 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1930 or even nested hashes (or arrays) using standard Perl syntax:
1931
1932         my $db = DBM::Deep->new( "foo.db" );
1933
1934         $db->{mykey} = "myvalue";
1935         $db->{myhash} = {};
1936         $db->{myhash}->{subkey} = "subvalue";
1937
1938         print $db->{myhash}->{subkey} . "\n";
1939
1940 You can even step through hash keys using the normal Perl C<keys()> function:
1941
1942         foreach my $key (keys %$db) {
1943                 print "$key: " . $db->{$key} . "\n";
1944         }
1945
1946 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1947 pushes them onto an array, all before the loop even begins.  If you have an
1948 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1949 Perl's C<each()> function, which pulls keys/values one at a time, using very
1950 little memory:
1951
1952         while (my ($key, $value) = each %$db) {
1953                 print "$key: $value\n";
1954         }
1955
1956 Please note that when using C<each()>, you should always pass a direct
1957 hash reference, not a lookup.  Meaning, you should B<never> do this:
1958
1959         # NEVER DO THIS
1960         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1961
1962 This causes an infinite loop, because for each iteration, Perl is calling
1963 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1964 it effectively keeps returning the first key over and over again. Instead,
1965 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1966
1967 =head2 ARRAYS
1968
1969 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1970 reference.  This includes inserting, removing and manipulating elements,
1971 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1972 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1973 or simply be a nested array reference inside a hash.  Example:
1974
1975         my $db = DBM::Deep->new(
1976                 file => "foo-array.db",
1977                 type => DBM::Deep->TYPE_ARRAY
1978         );
1979
1980         $db->[0] = "foo";
1981         push @$db, "bar", "baz";
1982         unshift @$db, "bah";
1983
1984         my $last_elem = pop @$db; # baz
1985         my $first_elem = shift @$db; # bah
1986         my $second_elem = $db->[1]; # bar
1987
1988         my $num_elements = scalar @$db;
1989
1990 =head1 OO INTERFACE
1991
1992 In addition to the I<tie()> interface, you can also use a standard OO interface
1993 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1994 array) has its own methods, but both types share the following common methods:
1995 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1996
1997 =over
1998
1999 =item * new() / clone()
2000
2001 These are the constructor and copy-functions.
2002
2003 =item * put() / store()
2004
2005 Stores a new hash key/value pair, or sets an array element value.  Takes two
2006 arguments, the hash key or array index, and the new value.  The value can be
2007 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2008
2009         $db->put("foo", "bar"); # for hashes
2010         $db->put(1, "bar"); # for arrays
2011
2012 =item * get() / fetch()
2013
2014 Fetches the value of a hash key or array element.  Takes one argument: the hash
2015 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2016 data type stored.
2017
2018         my $value = $db->get("foo"); # for hashes
2019         my $value = $db->get(1); # for arrays
2020
2021 =item * exists()
2022
2023 Checks if a hash key or array index exists.  Takes one argument: the hash key
2024 or array index.  Returns true if it exists, false if not.
2025
2026         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2027         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2028
2029 =item * delete()
2030
2031 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2032 key or array index.  Returns true on success, false if not found.  For arrays,
2033 the remaining elements located after the deleted element are NOT moved over.
2034 The deleted element is essentially just undefined, which is exactly how Perl's
2035 internal arrays work.  Please note that the space occupied by the deleted
2036 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2037 below for details and workarounds.
2038
2039         $db->delete("foo"); # for hashes
2040         $db->delete(1); # for arrays
2041
2042 =item * clear()
2043
2044 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2045 value.  Please note that the space occupied by the deleted keys/values or
2046 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2047 details and workarounds.
2048
2049         $db->clear(); # hashes or arrays
2050
2051 =item * lock() / unlock()
2052
2053 q.v. Locking.
2054
2055 =item * optimize()
2056
2057 Recover lost disk space.
2058
2059 =item * import() / export()
2060
2061 Data going in and out.
2062
2063 =item * set_digest() / set_pack() / set_filter()
2064
2065 q.v. adjusting the interal parameters.
2066
2067 =item * error() / clear_error()
2068
2069 Error handling methods. These are deprecated and will be removed in 1.00.
2070 .
2071 =back
2072
2073 =head2 HASHES
2074
2075 For hashes, DBM::Deep supports all the common methods described above, and the
2076 following additional methods: C<first_key()> and C<next_key()>.
2077
2078 =over
2079
2080 =item * first_key()
2081
2082 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2083 fetched in an undefined order (which appears random).  Takes no arguments,
2084 returns the key as a scalar value.
2085
2086         my $key = $db->first_key();
2087
2088 =item * next_key()
2089
2090 Returns the "next" key in the hash, given the previous one as the sole argument.
2091 Returns undef if there are no more keys to be fetched.
2092
2093         $key = $db->next_key($key);
2094
2095 =back
2096
2097 Here are some examples of using hashes:
2098
2099         my $db = DBM::Deep->new( "foo.db" );
2100
2101         $db->put("foo", "bar");
2102         print "foo: " . $db->get("foo") . "\n";
2103
2104         $db->put("baz", {}); # new child hash ref
2105         $db->get("baz")->put("buz", "biz");
2106         print "buz: " . $db->get("baz")->get("buz") . "\n";
2107
2108         my $key = $db->first_key();
2109         while ($key) {
2110                 print "$key: " . $db->get($key) . "\n";
2111                 $key = $db->next_key($key);
2112         }
2113
2114         if ($db->exists("foo")) { $db->delete("foo"); }
2115
2116 =head2 ARRAYS
2117
2118 For arrays, DBM::Deep supports all the common methods described above, and the
2119 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2120 C<unshift()> and C<splice()>.
2121
2122 =over
2123
2124 =item * length()
2125
2126 Returns the number of elements in the array.  Takes no arguments.
2127
2128         my $len = $db->length();
2129
2130 =item * push()
2131
2132 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2133 refs or array refs.  No return value.
2134
2135         $db->push("foo", "bar", {});
2136
2137 =item * pop()
2138
2139 Fetches the last element in the array, and deletes it.  Takes no arguments.
2140 Returns undef if array is empty.  Returns the element value.
2141
2142         my $elem = $db->pop();
2143
2144 =item * shift()
2145
2146 Fetches the first element in the array, deletes it, then shifts all the
2147 remaining elements over to take up the space.  Returns the element value.  This
2148 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2149 details.
2150
2151         my $elem = $db->shift();
2152
2153 =item * unshift()
2154
2155 Inserts one or more elements onto the beginning of the array, shifting all
2156 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2157 No return value.  This method is not recommended with large arrays -- see
2158 <LARGE ARRAYS> below for details.
2159
2160         $db->unshift("foo", "bar", {});
2161
2162 =item * splice()
2163
2164 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2165 -f splice> for usage -- it is too complicated to document here.  This method is
2166 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2167
2168 =back
2169
2170 Here are some examples of using arrays:
2171
2172         my $db = DBM::Deep->new(
2173                 file => "foo.db",
2174                 type => DBM::Deep->TYPE_ARRAY
2175         );
2176
2177         $db->push("bar", "baz");
2178         $db->unshift("foo");
2179         $db->put(3, "buz");
2180
2181         my $len = $db->length();
2182         print "length: $len\n"; # 4
2183
2184         for (my $k=0; $k<$len; $k++) {
2185                 print "$k: " . $db->get($k) . "\n";
2186         }
2187
2188         $db->splice(1, 2, "biz", "baf");
2189
2190         while (my $elem = shift @$db) {
2191                 print "shifted: $elem\n";
2192         }
2193
2194 =head1 LOCKING
2195
2196 Enable automatic file locking by passing a true value to the C<locking>
2197 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2198
2199         my $db = DBM::Deep->new(
2200                 file => "foo.db",
2201                 locking => 1
2202         );
2203
2204 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2205 mode for writes, and shared mode for reads.  This is required if you have
2206 multiple processes accessing the same database file, to avoid file corruption.
2207 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2208 NFS> below for more.
2209
2210 =head2 EXPLICIT LOCKING
2211
2212 You can explicitly lock a database, so it remains locked for multiple
2213 transactions.  This is done by calling the C<lock()> method, and passing an
2214 optional lock mode argument (defaults to exclusive mode).  This is particularly
2215 useful for things like counters, where the current value needs to be fetched,
2216 then incremented, then stored again.
2217
2218         $db->lock();
2219         my $counter = $db->get("counter");
2220         $counter++;
2221         $db->put("counter", $counter);
2222         $db->unlock();
2223
2224         # or...
2225
2226         $db->lock();
2227         $db->{counter}++;
2228         $db->unlock();
2229
2230 You can pass C<lock()> an optional argument, which specifies which mode to use
2231 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2232 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2233 same as the constants defined in Perl's C<Fcntl> module.
2234
2235         $db->lock( DBM::Deep->LOCK_SH );
2236         # something here
2237         $db->unlock();
2238
2239 =head1 IMPORTING/EXPORTING
2240
2241 You can import existing complex structures by calling the C<import()> method,
2242 and export an entire database into an in-memory structure using the C<export()>
2243 method.  Both are examined here.
2244
2245 =head2 IMPORTING
2246
2247 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2248 walking the structure and adding keys/elements to the database as you go,
2249 simply pass a reference to the C<import()> method.  This recursively adds
2250 everything to an existing DBM::Deep object for you.  Here is an example:
2251
2252         my $struct = {
2253                 key1 => "value1",
2254                 key2 => "value2",
2255                 array1 => [ "elem0", "elem1", "elem2" ],
2256                 hash1 => {
2257                         subkey1 => "subvalue1",
2258                         subkey2 => "subvalue2"
2259                 }
2260         };
2261
2262         my $db = DBM::Deep->new( "foo.db" );
2263         $db->import( $struct );
2264
2265         print $db->{key1} . "\n"; # prints "value1"
2266
2267 This recursively imports the entire C<$struct> object into C<$db>, including
2268 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2269 keys are merged with the existing ones, replacing if they already exist.
2270 The C<import()> method can be called on any database level (not just the base
2271 level), and works with both hash and array DB types.
2272
2273 B<Note:> Make sure your existing structure has no circular references in it.
2274 These will cause an infinite loop when importing.
2275
2276 =head2 EXPORTING
2277
2278 Calling the C<export()> method on an existing DBM::Deep object will return
2279 a reference to a new in-memory copy of the database.  The export is done
2280 recursively, so all nested hashes/arrays are all exported to standard Perl
2281 objects.  Here is an example:
2282
2283         my $db = DBM::Deep->new( "foo.db" );
2284
2285         $db->{key1} = "value1";
2286         $db->{key2} = "value2";
2287         $db->{hash1} = {};
2288         $db->{hash1}->{subkey1} = "subvalue1";
2289         $db->{hash1}->{subkey2} = "subvalue2";
2290
2291         my $struct = $db->export();
2292
2293         print $struct->{key1} . "\n"; # prints "value1"
2294
2295 This makes a complete copy of the database in memory, and returns a reference
2296 to it.  The C<export()> method can be called on any database level (not just
2297 the base level), and works with both hash and array DB types.  Be careful of
2298 large databases -- you can store a lot more data in a DBM::Deep object than an
2299 in-memory Perl structure.
2300
2301 B<Note:> Make sure your database has no circular references in it.
2302 These will cause an infinite loop when exporting.
2303
2304 =head1 FILTERS
2305
2306 DBM::Deep has a number of hooks where you can specify your own Perl function
2307 to perform filtering on incoming or outgoing data.  This is a perfect
2308 way to extend the engine, and implement things like real-time compression or
2309 encryption.  Filtering applies to the base DB level, and all child hashes /
2310 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2311 constructed, or by calling the C<set_filter()> method at any time.  There are
2312 four available filter hooks, described below:
2313
2314 =over
2315
2316 =item * filter_store_key
2317
2318 This filter is called whenever a hash key is stored.  It
2319 is passed the incoming key, and expected to return a transformed key.
2320
2321 =item * filter_store_value
2322
2323 This filter is called whenever a hash key or array element is stored.  It
2324 is passed the incoming value, and expected to return a transformed value.
2325
2326 =item * filter_fetch_key
2327
2328 This filter is called whenever a hash key is fetched (i.e. via
2329 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2330 and expected to return the plain key.
2331
2332 =item * filter_fetch_value
2333
2334 This filter is called whenever a hash key or array element is fetched.
2335 It is passed the transformed value, and expected to return the plain value.
2336
2337 =back
2338
2339 Here are the two ways to setup a filter hook:
2340
2341         my $db = DBM::Deep->new(
2342                 file => "foo.db",
2343                 filter_store_value => \&my_filter_store,
2344                 filter_fetch_value => \&my_filter_fetch
2345         );
2346
2347         # or...
2348
2349         $db->set_filter( "filter_store_value", \&my_filter_store );
2350         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2351
2352 Your filter function will be called only when dealing with SCALAR keys or
2353 values.  When nested hashes and arrays are being stored/fetched, filtering
2354 is bypassed.  Filters are called as static functions, passed a single SCALAR
2355 argument, and expected to return a single SCALAR value.  If you want to
2356 remove a filter, set the function reference to C<undef>:
2357
2358         $db->set_filter( "filter_store_value", undef );
2359
2360 =head2 REAL-TIME ENCRYPTION EXAMPLE
2361
2362 Here is a working example that uses the I<Crypt::Blowfish> module to
2363 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2364 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2365 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2366
2367         use DBM::Deep;
2368         use Crypt::Blowfish;
2369         use Crypt::CBC;
2370
2371         my $cipher = Crypt::CBC->new({
2372                 'key'             => 'my secret key',
2373                 'cipher'          => 'Blowfish',
2374                 'iv'              => '$KJh#(}q',
2375                 'regenerate_key'  => 0,
2376                 'padding'         => 'space',
2377                 'prepend_iv'      => 0
2378         });
2379
2380         my $db = DBM::Deep->new(
2381                 file => "foo-encrypt.db",
2382                 filter_store_key => \&my_encrypt,
2383                 filter_store_value => \&my_encrypt,
2384                 filter_fetch_key => \&my_decrypt,
2385                 filter_fetch_value => \&my_decrypt,
2386         );
2387
2388         $db->{key1} = "value1";
2389         $db->{key2} = "value2";
2390         print "key1: " . $db->{key1} . "\n";
2391         print "key2: " . $db->{key2} . "\n";
2392
2393         undef $db;
2394         exit;
2395
2396         sub my_encrypt {
2397                 return $cipher->encrypt( $_[0] );
2398         }
2399         sub my_decrypt {
2400                 return $cipher->decrypt( $_[0] );
2401         }
2402
2403 =head2 REAL-TIME COMPRESSION EXAMPLE
2404
2405 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2406 compression / decompression of keys & values with DBM::Deep Filters.
2407 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2408 more on I<Compress::Zlib>.
2409
2410         use DBM::Deep;
2411         use Compress::Zlib;
2412
2413         my $db = DBM::Deep->new(
2414                 file => "foo-compress.db",
2415                 filter_store_key => \&my_compress,
2416                 filter_store_value => \&my_compress,
2417                 filter_fetch_key => \&my_decompress,
2418                 filter_fetch_value => \&my_decompress,
2419         );
2420
2421         $db->{key1} = "value1";
2422         $db->{key2} = "value2";
2423         print "key1: " . $db->{key1} . "\n";
2424         print "key2: " . $db->{key2} . "\n";
2425
2426         undef $db;
2427         exit;
2428
2429         sub my_compress {
2430                 return Compress::Zlib::memGzip( $_[0] ) ;
2431         }
2432         sub my_decompress {
2433                 return Compress::Zlib::memGunzip( $_[0] ) ;
2434         }
2435
2436 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2437 actually numerical index numbers, and are not filtered.
2438
2439 =head1 ERROR HANDLING
2440
2441 Most DBM::Deep methods return a true value for success, and call die() on
2442 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2443 actual error message is stored in an internal scalar, which can be fetched by
2444 calling the C<error()> method.
2445
2446         my $db = DBM::Deep->new( "foo.db" ); # create hash
2447         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2448
2449     print $@;           # prints error message
2450         print $db->error(); # prints error message
2451
2452 You can then call C<clear_error()> to clear the current error state.
2453
2454         $db->clear_error();
2455
2456 If you set the C<debug> option to true when creating your DBM::Deep object,
2457 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2458 be used for debugging purposes and not production work. DBM::Deep expects errors
2459 to be thrown, not propagated back up the stack.
2460
2461 B<NOTE>: error() and clear_error() are considered deprecated and I<will> be removed
2462 in 1.00. Please don't use them. Instead, wrap all your functions with in eval-blocks.
2463
2464 =head1 LARGEFILE SUPPORT
2465
2466 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2467 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2468 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2469 by calling the static C<set_pack()> method before you do anything else.
2470
2471         DBM::Deep::set_pack(8, 'Q');
2472
2473 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2474 instead of 32-bit longs.  After setting these values your DB files have a
2475 theoretical maximum size of 16 XB (exabytes).
2476
2477 B<Note:> Changing these values will B<NOT> work for existing database files.
2478 Only change this for new files, and make sure it stays set consistently
2479 throughout the file's life.  If you do set these values, you can no longer
2480 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2481 back to 32-bit mode.
2482
2483 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2484 only a 32-bit Perl.  However, I have received user reports that this does
2485 indeed work!
2486
2487 =head1 LOW-LEVEL ACCESS
2488
2489 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2490 you can call the C<_fh()> method, which returns the handle:
2491
2492         my $fh = $db->_fh();
2493
2494 This method can be called on the root level of the datbase, or any child
2495 hashes or arrays.  All levels share a I<root> structure, which contains things
2496 like the filehandle, a reference counter, and all the options specified
2497 when you created the object.  You can get access to this root structure by
2498 calling the C<root()> method.
2499
2500         my $root = $db->_root();
2501
2502 This is useful for changing options after the object has already been created,
2503 such as enabling/disabling locking, or debug modes.  You can also
2504 store your own temporary user data in this structure (be wary of name
2505 collision), which is then accessible from any child hash or array.
2506
2507 =head1 CUSTOM DIGEST ALGORITHM
2508
2509 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2510 keys.  However you can override this, and use another algorithm (such as SHA-256)
2511 or even write your own.  But please note that DBM::Deep currently expects zero
2512 collisions, so your algorithm has to be I<perfect>, so to speak.
2513 Collision detection may be introduced in a later version.
2514
2515
2516
2517 You can specify a custom digest algorithm by calling the static C<set_digest()>
2518 function, passing a reference to a subroutine, and the length of the algorithm's
2519 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2520 objects.  Here is a working example that uses a 256-bit hash from the
2521 I<Digest::SHA256> module.  Please see
2522 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2523
2524         use DBM::Deep;
2525         use Digest::SHA256;
2526
2527         my $context = Digest::SHA256::new(256);
2528
2529         DBM::Deep::set_digest( \&my_digest, 32 );
2530
2531         my $db = DBM::Deep->new( "foo-sha.db" );
2532
2533         $db->{key1} = "value1";
2534         $db->{key2} = "value2";
2535         print "key1: " . $db->{key1} . "\n";
2536         print "key2: " . $db->{key2} . "\n";
2537
2538         undef $db;
2539         exit;
2540
2541         sub my_digest {
2542                 return substr( $context->hash($_[0]), 0, 32 );
2543         }
2544
2545 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2546 of bytes you specify in the C<set_digest()> function (in this case 32).
2547
2548 =head1 CIRCULAR REFERENCES
2549
2550 DBM::Deep has B<experimental> support for circular references.  Meaning you
2551 can have a nested hash key or array element that points to a parent object.
2552 This relationship is stored in the DB file, and is preserved between sessions.
2553 Here is an example:
2554
2555         my $db = DBM::Deep->new( "foo.db" );
2556
2557         $db->{foo} = "bar";
2558         $db->{circle} = $db; # ref to self
2559
2560         print $db->{foo} . "\n"; # prints "foo"
2561         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2562
2563 One catch is, passing the object to a function that recursively walks the
2564 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2565 C<export()> methods) will result in an infinite loop.  The other catch is,
2566 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2567 or C<next_key()> methods), you will get the I<target object's key>, not the
2568 ref's key.  This gets even more interesting with the above example, where
2569 the I<circle> key points to the base DB object, which technically doesn't
2570 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2571 special case.
2572
2573 =head1 CAVEATS / ISSUES / BUGS
2574
2575 This section describes all the known issues with DBM::Deep.  It you have found
2576 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2577
2578 =head2 UNUSED SPACE RECOVERY
2579
2580 One major caveat with DBM::Deep is that space occupied by existing keys and
2581 values is not recovered when they are deleted.  Meaning if you keep deleting
2582 and adding new keys, your file will continuously grow.  I am working on this,
2583 but in the meantime you can call the built-in C<optimize()> method from time to
2584 time (perhaps in a crontab or something) to recover all your unused space.
2585
2586         $db->optimize(); # returns true on success
2587
2588 This rebuilds the ENTIRE database into a new file, then moves it on top of
2589 the original.  The new file will have no unused space, thus it will take up as
2590 little disk space as possible.  Please note that this operation can take
2591 a long time for large files, and you need enough disk space to temporarily hold
2592 2 copies of your DB file.  The temporary file is created in the same directory
2593 as the original, named with a ".tmp" extension, and is deleted when the
2594 operation completes.  Oh, and if locking is enabled, the DB is automatically
2595 locked for the entire duration of the copy.
2596
2597 B<WARNING:> Only call optimize() on the top-level node of the database, and
2598 make sure there are no child references lying around.  DBM::Deep keeps a reference
2599 counter, and if it is greater than 1, optimize() will abort and return undef.
2600
2601 =head2 AUTOVIVIFICATION
2602
2603 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2604 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2605 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2606 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2607 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2608 this does not work:
2609
2610         $db->{foo}->{bar} = "hello";
2611
2612 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2613 being an empty hash.  Try this instead, which works fine:
2614
2615         $db->{foo} = { bar => "hello" };
2616
2617 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2618 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2619 Probably a bug in Perl.
2620
2621 =head2 FILE CORRUPTION
2622
2623 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2624 for a 32-bit signature when opened, but other corruption in files can cause
2625 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2626 stuck in an infinite loop depending on the level of corruption.  File write
2627 operations are not checked for failure (for speed), so if you happen to run
2628 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2629 be addressed in a later version of DBM::Deep.
2630
2631 =head2 DB OVER NFS
2632
2633 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2634 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2635 about setting up your NFS server with a locking daemon, then using lockf() to
2636 lock your files, but your mileage may vary there as well.  From what I
2637 understand, there is no real way to do it.  However, if you need access to the
2638 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2639 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2640
2641 =head2 COPYING OBJECTS
2642
2643 Beware of copying tied objects in Perl.  Very strange things can happen.
2644 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2645 returns a new, blessed, tied hash or array to the same level in the DB.
2646
2647         my $copy = $db->clone();
2648
2649 B<Note>: Since clone() here is cloning the object, not the database location, any
2650 modifications to either $db or $copy will be visible in both.
2651
2652 =head2 LARGE ARRAYS
2653
2654 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2655 These functions cause every element in the array to move, which can be murder
2656 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2657 a different location.  This will be addressed in the forthcoming version 1.00.
2658
2659 =head2 WRITEONLY FILES
2660
2661 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2662 writeonly mode. STORE will verify that the filehandle is writable. However, there
2663 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2664 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2665
2666 =head1 PERFORMANCE
2667
2668 This section discusses DBM::Deep's speed and memory usage.
2669
2670 =head2 SPEED
2671
2672 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2673 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2674 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2675 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2676 with huge databases.  Here is some test data:
2677
2678         Adding 1,000,000 keys to new DB file...
2679
2680         At 100 keys, avg. speed is 2,703 keys/sec
2681         At 200 keys, avg. speed is 2,642 keys/sec
2682         At 300 keys, avg. speed is 2,598 keys/sec
2683         At 400 keys, avg. speed is 2,578 keys/sec
2684         At 500 keys, avg. speed is 2,722 keys/sec
2685         At 600 keys, avg. speed is 2,628 keys/sec
2686         At 700 keys, avg. speed is 2,700 keys/sec
2687         At 800 keys, avg. speed is 2,607 keys/sec
2688         At 900 keys, avg. speed is 2,190 keys/sec
2689         At 1,000 keys, avg. speed is 2,570 keys/sec
2690         At 2,000 keys, avg. speed is 2,417 keys/sec
2691         At 3,000 keys, avg. speed is 1,982 keys/sec
2692         At 4,000 keys, avg. speed is 1,568 keys/sec
2693         At 5,000 keys, avg. speed is 1,533 keys/sec
2694         At 6,000 keys, avg. speed is 1,787 keys/sec
2695         At 7,000 keys, avg. speed is 1,977 keys/sec
2696         At 8,000 keys, avg. speed is 2,028 keys/sec
2697         At 9,000 keys, avg. speed is 2,077 keys/sec
2698         At 10,000 keys, avg. speed is 2,031 keys/sec
2699         At 20,000 keys, avg. speed is 1,970 keys/sec
2700         At 30,000 keys, avg. speed is 2,050 keys/sec
2701         At 40,000 keys, avg. speed is 2,073 keys/sec
2702         At 50,000 keys, avg. speed is 1,973 keys/sec
2703         At 60,000 keys, avg. speed is 1,914 keys/sec
2704         At 70,000 keys, avg. speed is 2,091 keys/sec
2705         At 80,000 keys, avg. speed is 2,103 keys/sec
2706         At 90,000 keys, avg. speed is 1,886 keys/sec
2707         At 100,000 keys, avg. speed is 1,970 keys/sec
2708         At 200,000 keys, avg. speed is 2,053 keys/sec
2709         At 300,000 keys, avg. speed is 1,697 keys/sec
2710         At 400,000 keys, avg. speed is 1,838 keys/sec
2711         At 500,000 keys, avg. speed is 1,941 keys/sec
2712         At 600,000 keys, avg. speed is 1,930 keys/sec
2713         At 700,000 keys, avg. speed is 1,735 keys/sec
2714         At 800,000 keys, avg. speed is 1,795 keys/sec
2715         At 900,000 keys, avg. speed is 1,221 keys/sec
2716         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2717
2718 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2719 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2720 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2721 Run time was 12 min 3 sec.
2722
2723 =head2 MEMORY USAGE
2724
2725 One of the great things about DBM::Deep is that it uses very little memory.
2726 Even with huge databases (1,000,000+ keys) you will not see much increased
2727 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2728 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2729 database handle:
2730
2731           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2732         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2733
2734 Basically the process is taking 2,716K of memory.  And here is the same
2735 process after storing and fetching 1,000,000 keys:
2736
2737           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2738         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2739
2740 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2741 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2742
2743 =head1 DB FILE FORMAT
2744
2745 In case you were interested in the underlying DB file format, it is documented
2746 here in this section.  You don't need to know this to use the module, it's just
2747 included for reference.
2748
2749 =head2 SIGNATURE
2750
2751 DBM::Deep files always start with a 32-bit signature to identify the file type.
2752 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2753 checked for when the file is opened and an error will be thrown if it's not found.
2754
2755 =head2 TAG
2756
2757 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2758 has a standard header containing the type of data, the length of data, and then
2759 the data itself.  The type is a single character (1 byte), the length is a
2760 32-bit unsigned long in network byte order, and the data is, well, the data.
2761 Here is how it unfolds:
2762
2763 =head2 MASTER INDEX
2764
2765 Immediately after the 32-bit file signature is the I<Master Index> record.
2766 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2767 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2768 depending on how the DBM::Deep object was constructed.
2769
2770 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2771 number).  The first 8-bit char of the MD5 signature is the offset into the
2772 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2773 index element is a file offset of the next tag for the key/element in question,
2774 which is usually a I<Bucket List> tag (see below).
2775
2776 The next tag I<could> be another index, depending on how many keys/elements
2777 exist.  See L<RE-INDEXING> below for details.
2778
2779 =head2 BUCKET LIST
2780
2781 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2782 file offsets to where the actual data is stored.  It starts with a standard
2783 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2784 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2785 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2786 When the list fills up, a I<Re-Index> operation is performed (See
2787 L<RE-INDEXING> below).
2788
2789 =head2 BUCKET
2790
2791 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2792 index/value pair (in array mode).  It starts with a standard tag header with
2793 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2794 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2795 header.  The size reported in the tag header is only for the value, but then,
2796 just after the value is another size (32-bit unsigned long) and then the plain
2797 key itself.  Since the value is likely to be fetched more often than the plain
2798 key, I figured it would be I<slightly> faster to store the value first.
2799
2800 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2801 record for the nested structure, where the process begins all over again.
2802
2803 =head2 RE-INDEXING
2804
2805 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2806 exhausted.  Then, when another key/element comes in, the list is converted to a
2807 new index record.  However, this index will look at the next char in the MD5
2808 hash, and arrange new Bucket List pointers accordingly.  This process is called
2809 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2810 17 (16 + new one) keys/elements are removed from the old Bucket List and
2811 inserted into the new index.  Several new Bucket Lists are created in the
2812 process, as a new MD5 char from the key is being examined (it is unlikely that
2813 the keys will all share the same next char of their MD5s).
2814
2815 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2816 when the Bucket Lists will turn into indexes, but the first round tends to
2817 happen right around 4,000 keys.  You will see a I<slight> decrease in
2818 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2819 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2820 right around 900,000 keys.  This process can continue nearly indefinitely --
2821 right up until the point the I<MD5> signatures start colliding with each other,
2822 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2823 getting struck by lightning while you are walking to cash in your tickets.
2824 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2825 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2826 this is 340 unodecillion, but don't quote me).
2827
2828 =head2 STORING
2829
2830 When a new key/element is stored, the key (or index number) is first run through
2831 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2832 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2833 for the first char of the signature (in this case I<b0>).  If it does not exist,
2834 a new I<Bucket List> is created for our key (and the next 15 future keys that
2835 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2836 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2837 this point, unless we are replacing an existing I<Bucket>), where the actual
2838 data will be stored.
2839
2840 =head2 FETCHING
2841
2842 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2843 (or index number), then walking along the indexes.  If there are enough
2844 keys/elements in this DB level, there might be nested indexes, each linked to
2845 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2846 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2847 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2848 plain key are stored.
2849
2850 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2851 methods.  In this process the indexes are walked systematically, and each key
2852 fetched in increasing MD5 order (which is why it appears random).   Once the
2853 I<Bucket> is found, the value is skipped and the plain key returned instead.
2854 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2855 alphabetically sorted.  This only happens on an index-level -- as soon as the
2856 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2857 so it's pretty much undefined how the keys will come out -- just like Perl's
2858 built-in hashes.
2859
2860 =head1 CODE COVERAGE
2861
2862 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2863 B<Devel::Cover> report on this module's test suite.
2864
2865   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2866   File                           stmt   bran   cond    sub    pod   time  total
2867   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2868   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2869   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2870   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2871   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2872   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2873
2874 =head1 MORE INFORMATION
2875
2876 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2877 or send email to L<DBM-Deep@googlegroups.com>.
2878
2879 =head1 AUTHORS
2880
2881 Joseph Huckaby, L<jhuckaby@cpan.org>
2882
2883 Rob Kinyon, L<rkinyon@cpan.org>
2884
2885 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2886
2887 =head1 SEE ALSO
2888
2889 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2890 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2891
2892 =head1 LICENSE
2893
2894 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2895 This is free software, you may use it and distribute it under the
2896 same terms as Perl itself.
2897
2898 =cut