lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.98);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->_fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     eval {
 213         local $SIG{'__DIE__'};
 214         # Theoretically, adding O_BINARY should remove the need for the binmode
 215         # Of course, testing it is going to be ... interesting.
 216         my $flags = O_RDWR | O_CREAT | O_BINARY;
 217
 218         my $fh;
 219         sysopen( $fh, $self->_root->{file}, $flags )
 220             or $fh = undef;
 221         $self->_root->{fh} = $fh;
 222     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 223         if (! defined($self->_fh)) {
 224                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 225         }
 226
 227     my $fh = $self->_fh;
 228
 229     #XXX Can we remove this by using the right sysopen() flags?
 230     # Maybe ... q.v. above
 231     binmode $fh; # for win32
 232
 233     if ($self->_root->{autoflush}) {
 234         my $old = select $fh;
 235         $|=1;
 236         select $old;
 237     }
 238
 239     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 249         print($fh SIG_FILE);
 250         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|; $| = 1; $| = $old_af;
 258         select $old_fh;
 259
 260         my @stats = stat($fh);
 261         $self->_root->{inode} = $stats[1];
 262         $self->_root->{end} = $stats[7];
 263
 264         return 1;
 265     }
 266
 267     ##
 268     # Check signature was valid
 269     ##
 270     unless ($signature eq SIG_FILE) {
 271         $self->_close();
 272         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 273     }
 274
 275         my @stats = stat($fh);
 276         $self->_root->{inode} = $stats[1];
 277     $self->_root->{end} = $stats[7];
 278
 279     ##
 280     # Get our type from master index signature
 281     ##
 282     my $tag = $self->_load_tag($self->_base_offset);
 283
 284 #XXX We probably also want to store the hash algorithm name and not assume anything
 285 #XXX The cool thing would be to allow a different hashing algorithm at every level
 286
 287     if (!$tag) {
 288         return $self->_throw_error("Corrupted file, no master index record");
 289     }
 290     if ($self->{type} ne $tag->{signature}) {
 291         return $self->_throw_error("File type mismatch");
 292     }
 293
 294     return 1;
 295 }
 296
 297 sub _close {
 298         ##
 299         # Close database fh
 300         ##
 301     my $self = $_[0]->_get_self;
 302     close $self->_root->{fh} if $self->_root->{fh};
 303     $self->_root->{fh} = undef;
 304 }
 305
 306 sub _create_tag {
 307         ##
 308         # Given offset, signature and content, create tag and write to disk
 309         ##
 310         my ($self, $offset, $sig, $content) = @_;
 311         my $size = length($content);
 312
 313     my $fh = $self->_fh;
 314
 315         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 316         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 317
 318         if ($offset == $self->_root->{end}) {
 319                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 320         }
 321
 322         return {
 323                 signature => $sig,
 324                 size => $size,
 325                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 326                 content => $content
 327         };
 328 }
 329
 330 sub _load_tag {
 331         ##
 332         # Given offset, load single tag and return signature, size and data
 333         ##
 334         my $self = shift;
 335         my $offset = shift;
 336
 337     my $fh = $self->_fh;
 338
 339         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 340         if (eof $fh) { return undef; }
 341
 342     my $b;
 343     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 344     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 345
 346         my $buffer;
 347         read( $fh, $buffer, $size);
 348
 349         return {
 350                 signature => $sig,
 351                 size => $size,
 352                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 353                 content => $buffer
 354         };
 355 }
 356
 357 sub _index_lookup {
 358         ##
 359         # Given index tag, lookup single entry in index and return .
 360         ##
 361         my $self = shift;
 362         my ($tag, $index) = @_;
 363
 364         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 365         if (!$location) { return; }
 366
 367         return $self->_load_tag( $location );
 368 }
 369
 370 sub _add_bucket {
 371         ##
 372         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 373         # plain (undigested) key and value.
 374         ##
 375         my $self = shift;
 376         my ($tag, $md5, $plain_key, $value) = @_;
 377         my $keys = $tag->{content};
 378         my $location = 0;
 379         my $result = 2;
 380
 381         # added ref() check first to avoid eval and runtime exception for every
 382         # scalar value being stored.  performance tweak.
 383     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 384
 385         my $internal_ref = $is_dbm_deep && ($value->_root eq $self->_root);
 386
 387     my $fh = $self->_fh;
 388
 389         ##
 390         # Iterate through buckets, seeing if this is a new entry or a replace.
 391         ##
 392         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 393                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 394                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 395                 if (!$subloc) {
 396                         ##
 397                         # Found empty bucket (end of list).  Populate and exit loop.
 398                         ##
 399                         $result = 2;
 400
 401             $location = $internal_ref
 402                 ? $value->_base_offset
 403                 : $self->_root->{end};
 404
 405                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 406                         print($fh $md5 . pack($LONG_PACK, $location) );
 407                         last;
 408                 }
 409                 elsif ($md5 eq $key) {
 410                         ##
 411                         # Found existing bucket with same key.  Replace with new value.
 412                         ##
 413                         $result = 1;
 414
 415                         if ($internal_ref) {
 416                                 $location = $value->_base_offset;
 417                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 418                                 print($fh $md5 . pack($LONG_PACK, $location) );
 419                         }
 420                         else {
 421                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 422                                 my $size;
 423                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 424
 425                                 ##
 426                                 # If value is a hash, array, or raw value with equal or less size, we can
 427                                 # reuse the same content area of the database.  Otherwise, we have to create
 428                                 # a new content area at the EOF.
 429                                 ##
 430                                 my $actual_length;
 431                 my $r = Scalar::Util::reftype( $value ) || '';
 432                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 433                         $actual_length = $INDEX_SIZE;
 434
 435                         # if autobless is enabled, must also take into consideration
 436                         # the class name, as it is stored along with key/value.
 437                         if ( $self->_root->{autobless} ) {
 438                                                 my $value_class = Scalar::Util::blessed($value);
 439                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 440                                                         $actual_length += length($value_class);
 441                                                 }
 442                                         } # autobless
 443                 }
 444                                 else { $actual_length = length($value); }
 445
 446                                 if ($actual_length <= $size) {
 447                                         $location = $subloc;
 448                                 }
 449                                 else {
 450                                         $location = $self->_root->{end};
 451                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $self->_root->{file_offset}, SEEK_SET);
 452                                         print($fh pack($LONG_PACK, $location) );
 453                                 }
 454                         }
 455                         last;
 456                 }
 457         } # i loop
 458
 459         ##
 460         # If this is an internal reference, return now.
 461         # No need to write value or plain key
 462         ##
 463         if ($internal_ref) {
 464         return $result;
 465     }
 466
 467         ##
 468         # If bucket didn't fit into list, split into a new index level
 469         ##
 470         if (!$location) {
 471                 seek($fh, $tag->{ref_loc} + $self->_root->{file_offset}, SEEK_SET);
 472                 print($fh pack($LONG_PACK, $self->_root->{end}) );
 473
 474                 my $index_tag = $self->_create_tag($self->_root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 475                 my @offsets = ();
 476
 477                 $keys .= $md5 . pack($LONG_PACK, 0);
 478
 479                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 480                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 481                         if ($key) {
 482                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 483                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 484
 485                                 if ($offsets[$num]) {
 486                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 487                                         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 488                                         my $subkeys;
 489                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 490
 491                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 492                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 493                                                 if (!$subloc) {
 494                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 495                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->_root->{end}) );
 496                                                         last;
 497                                                 }
 498                                         } # k loop
 499                                 }
 500                                 else {
 501                                         $offsets[$num] = $self->_root->{end};
 502                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 503                                         print($fh pack($LONG_PACK, $self->_root->{end}) );
 504
 505                                         my $blist_tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 506
 507                                         seek($fh, $blist_tag->{offset} + $self->_root->{file_offset}, SEEK_SET);
 508                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->_root->{end}) );
 509                                 }
 510                         } # key is real
 511                 } # i loop
 512
 513                 $location ||= $self->_root->{end};
 514         } # re-index bucket list
 515
 516         ##
 517         # Seek to content area and store signature, value and plaintext key
 518         ##
 519         if ($location) {
 520                 my $content_length;
 521                 seek($fh, $location + $self->_root->{file_offset}, SEEK_SET);
 522
 523                 ##
 524                 # Write signature based on content type, set content length and write actual value.
 525                 ##
 526         my $r = Scalar::Util::reftype($value) || '';
 527                 if ($r eq 'HASH') {
 528                         print($fh TYPE_HASH );
 529                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 530                         $content_length = $INDEX_SIZE;
 531                 }
 532                 elsif ($r eq 'ARRAY') {
 533                         print($fh TYPE_ARRAY );
 534                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 535                         $content_length = $INDEX_SIZE;
 536                 }
 537                 elsif (!defined($value)) {
 538                         print($fh SIG_NULL );
 539                         print($fh pack($DATA_LENGTH_PACK, 0) );
 540                         $content_length = 0;
 541                 }
 542                 else {
 543                         print($fh SIG_DATA );
 544                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 545                         $content_length = length($value);
 546                 }
 547
 548                 ##
 549                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 550                 ##
 551                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 552
 553                 ##
 554                 # If value is blessed, preserve class name
 555                 ##
 556                 if ( $self->_root->{autobless} ) {
 557             my $value_class = Scalar::Util::blessed($value);
 558             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 559                 ##
 560                 # Blessed ref -- will restore later
 561                 ##
 562                 print($fh chr(1) );
 563                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 564                 $content_length += 1;
 565                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 566             }
 567             else {
 568                 print($fh chr(0) );
 569                 $content_length += 1;
 570             }
 571         }
 572
 573                 ##
 574                 # If this is a new content area, advance EOF counter
 575                 ##
 576                 if ($location == $self->_root->{end}) {
 577                         $self->_root->{end} += SIG_SIZE;
 578                         $self->_root->{end} += $DATA_LENGTH_SIZE + $content_length;
 579                         $self->_root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 580                 }
 581
 582                 ##
 583                 # If content is a hash or array, create new child DBM::Deep object and
 584                 # pass each key or element to it.
 585                 ##
 586                 if ($r eq 'HASH') {
 587                         my $branch = DBM::Deep->new(
 588                                 type => TYPE_HASH,
 589                                 base_offset => $location,
 590                                 root => $self->_root,
 591                         );
 592                         foreach my $key (keys %{$value}) {
 593                 $branch->STORE( $key, $value->{$key} );
 594                         }
 595                 }
 596                 elsif ($r eq 'ARRAY') {
 597                         my $branch = DBM::Deep->new(
 598                                 type => TYPE_ARRAY,
 599                                 base_offset => $location,
 600                                 root => $self->_root,
 601                         );
 602                         my $index = 0;
 603                         foreach my $element (@{$value}) {
 604                 $branch->STORE( $index, $element );
 605                                 $index++;
 606                         }
 607                 }
 608
 609                 return $result;
 610         }
 611
 612         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 613 }
 614
 615 sub _get_bucket_value {
 616         ##
 617         # Fetch single value given tag and MD5 digested key.
 618         ##
 619         my $self = shift;
 620         my ($tag, $md5) = @_;
 621         my $keys = $tag->{content};
 622
 623     my $fh = $self->_fh;
 624
 625         ##
 626         # Iterate through buckets, looking for a key match
 627         ##
 628     BUCKET:
 629         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 630                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 631                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 632
 633                 if (!$subloc) {
 634                         ##
 635                         # Hit end of list, no match
 636                         ##
 637                         return;
 638                 }
 639
 640         if ( $md5 ne $key ) {
 641             next BUCKET;
 642         }
 643
 644         ##
 645         # Found match -- seek to offset and read signature
 646         ##
 647         my $signature;
 648         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 649         read( $fh, $signature, SIG_SIZE);
 650
 651         ##
 652         # If value is a hash or array, return new DBM::Deep object with correct offset
 653         ##
 654         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 655             my $obj = DBM::Deep->new(
 656                 type => $signature,
 657                 base_offset => $subloc,
 658                 root => $self->_root
 659             );
 660
 661             if ($self->_root->{autobless}) {
 662                 ##
 663                 # Skip over value and plain key to see if object needs
 664                 # to be re-blessed
 665                 ##
 666                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 667
 668                 my $size;
 669                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 670                 if ($size) { seek($fh, $size, SEEK_CUR); }
 671
 672                 my $bless_bit;
 673                 read( $fh, $bless_bit, 1);
 674                 if (ord($bless_bit)) {
 675                     ##
 676                     # Yes, object needs to be re-blessed
 677                     ##
 678                     my $class_name;
 679                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 680                     if ($size) { read( $fh, $class_name, $size); }
 681                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 682                 }
 683             }
 684
 685             return $obj;
 686         }
 687
 688         ##
 689         # Otherwise return actual value
 690         ##
 691         elsif ($signature eq SIG_DATA) {
 692             my $size;
 693             my $value = '';
 694             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 695             if ($size) { read( $fh, $value, $size); }
 696             return $value;
 697         }
 698
 699         ##
 700         # Key exists, but content is null
 701         ##
 702         else { return; }
 703         } # i loop
 704
 705         return;
 706 }
 707
 708 sub _delete_bucket {
 709         ##
 710         # Delete single key/value pair given tag and MD5 digested key.
 711         ##
 712         my $self = shift;
 713         my ($tag, $md5) = @_;
 714         my $keys = $tag->{content};
 715
 716     my $fh = $self->_fh;
 717
 718         ##
 719         # Iterate through buckets, looking for a key match
 720         ##
 721     BUCKET:
 722         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 723                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 724                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 725
 726                 if (!$subloc) {
 727                         ##
 728                         # Hit end of list, no match
 729                         ##
 730                         return;
 731                 }
 732
 733         if ( $md5 ne $key ) {
 734             next BUCKET;
 735         }
 736
 737         ##
 738         # Matched key -- delete bucket and return
 739         ##
 740         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 741         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 742         print($fh chr(0) x $BUCKET_SIZE );
 743
 744         return 1;
 745         } # i loop
 746
 747         return;
 748 }
 749
 750 sub _bucket_exists {
 751         ##
 752         # Check existence of single key given tag and MD5 digested key.
 753         ##
 754         my $self = shift;
 755         my ($tag, $md5) = @_;
 756         my $keys = $tag->{content};
 757
 758         ##
 759         # Iterate through buckets, looking for a key match
 760         ##
 761     BUCKET:
 762         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 763                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 764                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 765
 766                 if (!$subloc) {
 767                         ##
 768                         # Hit end of list, no match
 769                         ##
 770                         return;
 771                 }
 772
 773         if ( $md5 ne $key ) {
 774             next BUCKET;
 775         }
 776
 777         ##
 778         # Matched key -- return true
 779         ##
 780         return 1;
 781         } # i loop
 782
 783         return;
 784 }
 785
 786 sub _find_bucket_list {
 787         ##
 788         # Locate offset for bucket list, given digested key
 789         ##
 790         my $self = shift;
 791         my $md5 = shift;
 792
 793         ##
 794         # Locate offset for bucket list using digest index system
 795         ##
 796         my $ch = 0;
 797         my $tag = $self->_load_tag($self->_base_offset);
 798         if (!$tag) { return; }
 799
 800         while ($tag->{signature} ne SIG_BLIST) {
 801                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 802                 if (!$tag) { return; }
 803                 $ch++;
 804         }
 805
 806         return $tag;
 807 }
 808
 809 sub _traverse_index {
 810         ##
 811         # Scan index and recursively step into deeper levels, looking for next key.
 812         ##
 813     my ($self, $offset, $ch, $force_return_next) = @_;
 814     $force_return_next = undef unless $force_return_next;
 815
 816         my $tag = $self->_load_tag( $offset );
 817
 818     my $fh = $self->_fh;
 819
 820         if ($tag->{signature} ne SIG_BLIST) {
 821                 my $content = $tag->{content};
 822                 my $start;
 823                 if ($self->{return_next}) { $start = 0; }
 824                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 825
 826                 for (my $index = $start; $index < 256; $index++) {
 827                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 828                         if ($subloc) {
 829                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 830                                 if (defined($result)) { return $result; }
 831                         }
 832                 } # index loop
 833
 834                 $self->{return_next} = 1;
 835         } # tag is an index
 836
 837         elsif ($tag->{signature} eq SIG_BLIST) {
 838                 my $keys = $tag->{content};
 839                 if ($force_return_next) { $self->{return_next} = 1; }
 840
 841                 ##
 842                 # Iterate through buckets, looking for a key match
 843                 ##
 844                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 845                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 846                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 847
 848                         if (!$subloc) {
 849                                 ##
 850                                 # End of bucket list -- return to outer loop
 851                                 ##
 852                                 $self->{return_next} = 1;
 853                                 last;
 854                         }
 855                         elsif ($key eq $self->{prev_md5}) {
 856                                 ##
 857                                 # Located previous key -- return next one found
 858                                 ##
 859                                 $self->{return_next} = 1;
 860                                 next;
 861                         }
 862                         elsif ($self->{return_next}) {
 863                                 ##
 864                                 # Seek to bucket location and skip over signature
 865                                 ##
 866                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 867
 868                                 ##
 869                                 # Skip over value to get to plain key
 870                                 ##
 871                                 my $size;
 872                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 873                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 874
 875                                 ##
 876                                 # Read in plain key and return as scalar
 877                                 ##
 878                                 my $plain_key;
 879                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 880                                 if ($size) { read( $fh, $plain_key, $size); }
 881
 882                                 return $plain_key;
 883                         }
 884                 } # bucket loop
 885
 886                 $self->{return_next} = 1;
 887         } # tag is a bucket list
 888
 889         return;
 890 }
 891
 892 sub _get_next_key {
 893         ##
 894         # Locate next key, given digested previous one
 895         ##
 896     my $self = $_[0]->_get_self;
 897
 898         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 899         $self->{return_next} = 0;
 900
 901         ##
 902         # If the previous key was not specifed, start at the top and
 903         # return the first one found.
 904         ##
 905         if (!$self->{prev_md5}) {
 906                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 907                 $self->{return_next} = 1;
 908         }
 909
 910         return $self->_traverse_index( $self->_base_offset, 0 );
 911 }
 912
 913 sub lock {
 914         ##
 915         # If db locking is set, flock() the db file.  If called multiple
 916         # times before unlock(), then the same number of unlocks() must
 917         # be called before the lock is released.
 918         ##
 919     my $self = $_[0]->_get_self;
 920         my $type = $_[1];
 921     $type = LOCK_EX unless defined $type;
 922
 923         if (!defined($self->_fh)) { return; }
 924
 925         if ($self->_root->{locking}) {
 926                 if (!$self->_root->{locked}) {
 927                         flock($self->_fh, $type);
 928
 929                         # refresh end counter in case file has changed size
 930                         my @stats = stat($self->_root->{file});
 931                         $self->_root->{end} = $stats[7];
 932
 933                         # double-check file inode, in case another process
 934                         # has optimize()d our file while we were waiting.
 935                         if ($stats[1] != $self->_root->{inode}) {
 936                                 $self->_open(); # re-open
 937                                 flock($self->_fh, $type); # re-lock
 938                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 939                         }
 940                 }
 941                 $self->_root->{locked}++;
 942
 943         return 1;
 944         }
 945
 946     return;
 947 }
 948
 949 sub unlock {
 950         ##
 951         # If db locking is set, unlock the db file.  See note in lock()
 952         # regarding calling lock() multiple times.
 953         ##
 954     my $self = $_[0]->_get_self;
 955
 956         if (!defined($self->_fh)) { return; }
 957
 958         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 959                 $self->_root->{locked}--;
 960                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 961
 962         return 1;
 963         }
 964
 965     return;
 966 }
 967
 968 sub _copy_value {
 969     my $self = shift->_get_self;
 970     my ($spot, $value) = @_;
 971
 972     if ( !ref $value ) {
 973         ${$spot} = $value;
 974     }
 975     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 976         my $type = $value->_type;
 977         ${$spot} = $type eq TYPE_HASH ? {} : [];
 978         $value->_copy_node( ${$spot} );
 979     }
 980     else {
 981         my $r = Scalar::Util::reftype( $value );
 982         my $c = Scalar::Util::blessed( $value );
 983         if ( $r eq 'ARRAY' ) {
 984             ${$spot} = [ @{$value} ];
 985         }
 986         else {
 987             ${$spot} = { %{$value} };
 988         }
 989         ${$spot} = bless ${$spot}, $c
 990             if defined $c;
 991     }
 992
 993     return 1;
 994 }
 995
 996 sub _copy_node {
 997         ##
 998         # Copy single level of keys or elements to new DB handle.
 999         # Recurse for nested structures
1000         ##
1001     my $self = shift->_get_self;
1002         my ($db_temp) = @_;
1003
1004         if ($self->_type eq TYPE_HASH) {
1005                 my $key = $self->first_key();
1006                 while ($key) {
1007                         my $value = $self->get($key);
1008             $self->_copy_value( \$db_temp->{$key}, $value );
1009                         $key = $self->next_key($key);
1010                 }
1011         }
1012         else {
1013                 my $length = $self->length();
1014                 for (my $index = 0; $index < $length; $index++) {
1015                         my $value = $self->get($index);
1016             $self->_copy_value( \$db_temp->[$index], $value );
1017                 }
1018         }
1019
1020     return 1;
1021 }
1022
1023 sub export {
1024         ##
1025         # Recursively export into standard Perl hashes and arrays.
1026         ##
1027     my $self = $_[0]->_get_self;
1028
1029         my $temp;
1030         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1031         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1032
1033         $self->lock();
1034         $self->_copy_node( $temp );
1035         $self->unlock();
1036
1037         return $temp;
1038 }
1039
1040 sub import {
1041         ##
1042         # Recursively import Perl hash/array structure
1043         ##
1044     #XXX This use of ref() seems to be ok
1045         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1046
1047     my $self = $_[0]->_get_self;
1048         my $struct = $_[1];
1049
1050     #XXX This use of ref() seems to be ok
1051         if (!ref($struct)) {
1052                 ##
1053                 # struct is not a reference, so just import based on our type
1054                 ##
1055                 shift @_;
1056
1057                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1058                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1059         }
1060
1061     my $r = Scalar::Util::reftype($struct) || '';
1062         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1063                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1064         }
1065         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1066                 $self->push( @$struct );
1067         }
1068         else {
1069                 return $self->_throw_error("Cannot import: type mismatch");
1070         }
1071
1072         return 1;
1073 }
1074
1075 sub optimize {
1076         ##
1077         # Rebuild entire database into new file, then move
1078         # it back on top of original.
1079         ##
1080     my $self = $_[0]->_get_self;
1081
1082 #XXX Need to create a new test for this
1083 #       if ($self->_root->{links} > 1) {
1084 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1085 #       }
1086
1087         my $db_temp = DBM::Deep->new(
1088                 file => $self->_root->{file} . '.tmp',
1089                 type => $self->_type
1090         );
1091         if (!$db_temp) {
1092                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1093         }
1094
1095         $self->lock();
1096         $self->_copy_node( $db_temp );
1097         undef $db_temp;
1098
1099         ##
1100         # Attempt to copy user, group and permissions over to new file
1101         ##
1102         my @stats = stat($self->_fh);
1103         my $perms = $stats[2] & 07777;
1104         my $uid = $stats[4];
1105         my $gid = $stats[5];
1106         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1107         chmod( $perms, $self->_root->{file} . '.tmp' );
1108
1109     # q.v. perlport for more information on this variable
1110     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1111                 ##
1112                 # Potential race condition when optmizing on Win32 with locking.
1113                 # The Windows filesystem requires that the filehandle be closed
1114                 # before it is overwritten with rename().  This could be redone
1115                 # with a soft copy.
1116                 ##
1117                 $self->unlock();
1118                 $self->_close();
1119         }
1120
1121         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1122                 unlink $self->_root->{file} . '.tmp';
1123                 $self->unlock();
1124                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1125         }
1126
1127         $self->unlock();
1128         $self->_close();
1129         $self->_open();
1130
1131         return 1;
1132 }
1133
1134 sub clone {
1135         ##
1136         # Make copy of object and return
1137         ##
1138     my $self = $_[0]->_get_self;
1139
1140         return DBM::Deep->new(
1141                 type => $self->_type,
1142                 base_offset => $self->_base_offset,
1143                 root => $self->_root
1144         );
1145 }
1146
1147 {
1148     my %is_legal_filter = map {
1149         $_ => ~~1,
1150     } qw(
1151         store_key store_value
1152         fetch_key fetch_value
1153     );
1154
1155     sub set_filter {
1156         ##
1157         # Setup filter function for storing or fetching the key or value
1158         ##
1159         my $self = $_[0]->_get_self;
1160         my $type = lc $_[1];
1161         my $func = $_[2] ? $_[2] : undef;
1162
1163         if ( $is_legal_filter{$type} ) {
1164             $self->_root->{"filter_$type"} = $func;
1165             return 1;
1166         }
1167
1168         return;
1169     }
1170 }
1171
1172 ##
1173 # Accessor methods
1174 ##
1175
1176 sub _root {
1177         ##
1178         # Get access to the root structure
1179         ##
1180     my $self = $_[0]->_get_self;
1181         return $self->{root};
1182 }
1183
1184 sub _fh {
1185         ##
1186         # Get access to the raw fh
1187         ##
1188     #XXX It will be useful, though, when we split out HASH and ARRAY
1189     my $self = $_[0]->_get_self;
1190         return $self->_root->{fh};
1191 }
1192
1193 sub _type {
1194         ##
1195         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1196         ##
1197     my $self = $_[0]->_get_self;
1198         return $self->{type};
1199 }
1200
1201 sub _base_offset {
1202         ##
1203         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1204         ##
1205     my $self = $_[0]->_get_self;
1206         return $self->{base_offset};
1207 }
1208
1209 sub error {
1210         ##
1211         # Get last error string, or undef if no error
1212         ##
1213         return $_[0]
1214         #? ( _get_self($_[0])->{root}->{error} or undef )
1215         ? ( $_[0]->_get_self->{root}->{error} or undef )
1216         : $@;
1217 }
1218
1219 ##
1220 # Utility methods
1221 ##
1222
1223 sub _throw_error {
1224         ##
1225         # Store error string in self
1226         ##
1227         my $error_text = $_[1];
1228
1229     if ( Scalar::Util::blessed $_[0] ) {
1230         my $self = $_[0]->_get_self;
1231         $self->_root->{error} = $error_text;
1232
1233         unless ($self->_root->{debug}) {
1234             die "DBM::Deep: $error_text\n";
1235         }
1236
1237         warn "DBM::Deep: $error_text\n";
1238         return;
1239     }
1240     else {
1241         die "DBM::Deep: $error_text\n";
1242     }
1243 }
1244
1245 sub clear_error {
1246         ##
1247         # Clear error state
1248         ##
1249     my $self = $_[0]->_get_self;
1250
1251         undef $self->_root->{error};
1252 }
1253
1254 sub _precalc_sizes {
1255         ##
1256         # Precalculate index, bucket and bucket list sizes
1257         ##
1258
1259     #XXX I don't like this ...
1260     set_pack() unless defined $LONG_SIZE;
1261
1262         $INDEX_SIZE = 256 * $LONG_SIZE;
1263         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1264         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1265 }
1266
1267 sub set_pack {
1268         ##
1269         # Set pack/unpack modes (see file header for more)
1270         ##
1271     my ($long_s, $long_p, $data_s, $data_p) = @_;
1272
1273     $LONG_SIZE = $long_s ? $long_s : 4;
1274     $LONG_PACK = $long_p ? $long_p : 'N';
1275
1276     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1277     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1278
1279         _precalc_sizes();
1280 }
1281
1282 sub set_digest {
1283         ##
1284         # Set key digest function (default is MD5)
1285         ##
1286     my ($digest_func, $hash_size) = @_;
1287
1288     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1289     $HASH_SIZE = $hash_size ? $hash_size : 16;
1290
1291         _precalc_sizes();
1292 }
1293
1294 ##
1295 # tie() methods (hashes and arrays)
1296 ##
1297
1298 sub STORE {
1299         ##
1300         # Store single hash key/value or array element in database.
1301         ##
1302     my $self = $_[0]->_get_self;
1303         my $key = $_[1];
1304
1305     # User may be storing a hash, in which case we do not want it run
1306     # through the filtering system
1307         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1308         ? $self->_root->{filter_store_value}->($_[2])
1309         : $_[2];
1310
1311         my $md5 = $DIGEST_FUNC->($key);
1312
1313         ##
1314         # Make sure file is open
1315         ##
1316         if (!defined($self->_fh) && !$self->_open()) {
1317                 return;
1318         }
1319         ##
1320
1321         ##
1322         # Request exclusive lock for writing
1323         ##
1324         $self->lock( LOCK_EX );
1325
1326         my $fh = $self->_fh;
1327
1328         ##
1329         # Locate offset for bucket list using digest index system
1330         ##
1331         my $tag = $self->_load_tag($self->_base_offset);
1332         if (!$tag) {
1333                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1334         }
1335
1336         my $ch = 0;
1337         while ($tag->{signature} ne SIG_BLIST) {
1338                 my $num = ord(substr($md5, $ch, 1));
1339                 my $new_tag = $self->_index_lookup($tag, $num);
1340                 if (!$new_tag) {
1341                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1342                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1343                         print($fh pack($LONG_PACK, $self->_root->{end}) );
1344
1345                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1346                         $tag->{ref_loc} = $ref_loc;
1347                         $tag->{ch} = $ch;
1348                         last;
1349                 }
1350                 else {
1351                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1352                         $tag = $new_tag;
1353                         $tag->{ref_loc} = $ref_loc;
1354                         $tag->{ch} = $ch;
1355                 }
1356                 $ch++;
1357         }
1358
1359         ##
1360         # Add key/value to bucket list
1361         ##
1362         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1363
1364         $self->unlock();
1365
1366         return $result;
1367 }
1368
1369 sub FETCH {
1370         ##
1371         # Fetch single value or element given plain key or array index
1372         ##
1373     my $self = shift->_get_self;
1374     my $key = shift;
1375
1376         ##
1377         # Make sure file is open
1378         ##
1379         if (!defined($self->_fh)) { $self->_open(); }
1380
1381         my $md5 = $DIGEST_FUNC->($key);
1382
1383         ##
1384         # Request shared lock for reading
1385         ##
1386         $self->lock( LOCK_SH );
1387
1388         my $tag = $self->_find_bucket_list( $md5 );
1389         if (!$tag) {
1390                 $self->unlock();
1391                 return;
1392         }
1393
1394         ##
1395         # Get value from bucket list
1396         ##
1397         my $result = $self->_get_bucket_value( $tag, $md5 );
1398
1399         $self->unlock();
1400
1401     #XXX What is ref() checking here?
1402     #YYY Filters only apply on scalar values, so the ref check is making
1403     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1404         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1405         ? $self->_root->{filter_fetch_value}->($result)
1406         : $result;
1407 }
1408
1409 sub DELETE {
1410         ##
1411         # Delete single key/value pair or element given plain key or array index
1412         ##
1413     my $self = $_[0]->_get_self;
1414         my $key = $_[1];
1415
1416         my $md5 = $DIGEST_FUNC->($key);
1417
1418         ##
1419         # Make sure file is open
1420         ##
1421         if (!defined($self->_fh)) { $self->_open(); }
1422
1423         ##
1424         # Request exclusive lock for writing
1425         ##
1426         $self->lock( LOCK_EX );
1427
1428         my $tag = $self->_find_bucket_list( $md5 );
1429         if (!$tag) {
1430                 $self->unlock();
1431                 return;
1432         }
1433
1434         ##
1435         # Delete bucket
1436         ##
1437     my $value = $self->_get_bucket_value( $tag, $md5 );
1438         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1439         $value = $self->_root->{filter_fetch_value}->($value);
1440     }
1441
1442         my $result = $self->_delete_bucket( $tag, $md5 );
1443
1444         ##
1445         # If this object is an array and the key deleted was on the end of the stack,
1446         # decrement the length variable.
1447         ##
1448
1449         $self->unlock();
1450
1451         return $value;
1452 }
1453
1454 sub EXISTS {
1455         ##
1456         # Check if a single key or element exists given plain key or array index
1457         ##
1458     my $self = $_[0]->_get_self;
1459         my $key = $_[1];
1460
1461         my $md5 = $DIGEST_FUNC->($key);
1462
1463         ##
1464         # Make sure file is open
1465         ##
1466         if (!defined($self->_fh)) { $self->_open(); }
1467
1468         ##
1469         # Request shared lock for reading
1470         ##
1471         $self->lock( LOCK_SH );
1472
1473         my $tag = $self->_find_bucket_list( $md5 );
1474
1475         ##
1476         # For some reason, the built-in exists() function returns '' for false
1477         ##
1478         if (!$tag) {
1479                 $self->unlock();
1480                 return '';
1481         }
1482
1483         ##
1484         # Check if bucket exists and return 1 or ''
1485         ##
1486         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1487
1488         $self->unlock();
1489
1490         return $result;
1491 }
1492
1493 sub CLEAR {
1494         ##
1495         # Clear all keys from hash, or all elements from array.
1496         ##
1497     my $self = $_[0]->_get_self;
1498
1499         ##
1500         # Make sure file is open
1501         ##
1502         if (!defined($self->_fh)) { $self->_open(); }
1503
1504         ##
1505         # Request exclusive lock for writing
1506         ##
1507         $self->lock( LOCK_EX );
1508
1509     my $fh = $self->_fh;
1510
1511         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1512         if (eof $fh) {
1513                 $self->unlock();
1514                 return;
1515         }
1516
1517         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1518
1519         $self->unlock();
1520
1521         return 1;
1522 }
1523
1524 ##
1525 # Public method aliases
1526 ##
1527 sub put { (shift)->STORE( @_ ) }
1528 sub store { (shift)->STORE( @_ ) }
1529 sub get { (shift)->FETCH( @_ ) }
1530 sub fetch { (shift)->FETCH( @_ ) }
1531 sub delete { (shift)->DELETE( @_ ) }
1532 sub exists { (shift)->EXISTS( @_ ) }
1533 sub clear { (shift)->CLEAR( @_ ) }
1534
1535 package DBM::Deep::_::Root;
1536
1537 sub new {
1538     my $class = shift;
1539     my ($args) = @_;
1540
1541     my $self = bless {
1542         file => undef,
1543         fh => undef,
1544         file_offset => 0,
1545         end => 0,
1546         autoflush => undef,
1547         locking => undef,
1548         debug => undef,
1549         filter_store_key => undef,
1550         filter_store_value => undef,
1551         filter_fetch_key => undef,
1552         filter_fetch_value => undef,
1553         autobless => undef,
1554         locked => 0,
1555         %$args,
1556     }, $class;
1557
1558     if ( $self->{fh} && !$self->{file_offset} ) {
1559         $self->{file_offset} = tell( $self->{fh} );
1560     }
1561
1562     return $self;
1563 }
1564
1565 sub DESTROY {
1566     my $self = shift;
1567     return unless $self;
1568
1569     close $self->{fh} if $self->{fh};
1570
1571     return;
1572 }
1573
1574 1;
1575
1576 __END__
1577
1578 =head1 NAME
1579
1580 DBM::Deep - A pure perl multi-level hash/array DBM
1581
1582 =head1 SYNOPSIS
1583
1584   use DBM::Deep;
1585   my $db = DBM::Deep->new( "foo.db" );
1586
1587   $db->{key} = 'value'; # tie() style
1588   print $db->{key};
1589
1590   $db->put('key' => 'value'); # OO style
1591   print $db->get('key');
1592
1593   # true multi-level support
1594   $db->{my_complex} = [
1595         'hello', { perl => 'rules' },
1596         42, 99,
1597   ];
1598
1599 =head1 DESCRIPTION
1600
1601 A unique flat-file database module, written in pure perl.  True
1602 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1603 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1604 handle millions of keys and unlimited hash levels without significant
1605 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1606 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1607 Mac OS X and Windows.
1608
1609 =head1 INSTALLATION
1610
1611 Hopefully you are using Perl's excellent CPAN module, which will download
1612 and install the module for you.  If not, get the tarball, and run these
1613 commands:
1614
1615         tar zxf DBM-Deep-*
1616         cd DBM-Deep-*
1617         perl Makefile.PL
1618         make
1619         make test
1620         make install
1621
1622 =head1 SETUP
1623
1624 Construction can be done OO-style (which is the recommended way), or using
1625 Perl's tie() function.  Both are examined here.
1626
1627 =head2 OO CONSTRUCTION
1628
1629 The recommended way to construct a DBM::Deep object is to use the new()
1630 method, which gets you a blessed, tied hash or array reference.
1631
1632         my $db = DBM::Deep->new( "foo.db" );
1633
1634 This opens a new database handle, mapped to the file "foo.db".  If this
1635 file does not exist, it will automatically be created.  DB files are
1636 opened in "r+" (read/write) mode, and the type of object returned is a
1637 hash, unless otherwise specified (see L<OPTIONS> below).
1638
1639 You can pass a number of options to the constructor to specify things like
1640 locking, autoflush, etc.  This is done by passing an inline hash:
1641
1642         my $db = DBM::Deep->new(
1643                 file => "foo.db",
1644                 locking => 1,
1645                 autoflush => 1
1646         );
1647
1648 Notice that the filename is now specified I<inside> the hash with
1649 the "file" parameter, as opposed to being the sole argument to the
1650 constructor.  This is required if any options are specified.
1651 See L<OPTIONS> below for the complete list.
1652
1653
1654
1655 You can also start with an array instead of a hash.  For this, you must
1656 specify the C<type> parameter:
1657
1658         my $db = DBM::Deep->new(
1659                 file => "foo.db",
1660                 type => DBM::Deep->TYPE_ARRAY
1661         );
1662
1663 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1664 a new DB file.  If you create a DBM::Deep object with an existing file, the
1665 C<type> will be loaded from the file header, and an error will be thrown if
1666 the wrong type is passed in.
1667
1668 =head2 TIE CONSTRUCTION
1669
1670 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1671 tie() function.  The object returned from tie() can be used to call methods,
1672 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1673 file (as expected with most tie'd objects).
1674
1675         my %hash;
1676         my $db = tie %hash, "DBM::Deep", "foo.db";
1677
1678         my @array;
1679         my $db = tie @array, "DBM::Deep", "bar.db";
1680
1681 As with the OO constructor, you can replace the DB filename parameter with
1682 a hash containing one or more options (see L<OPTIONS> just below for the
1683 complete list).
1684
1685         tie %hash, "DBM::Deep", {
1686                 file => "foo.db",
1687                 locking => 1,
1688                 autoflush => 1
1689         };
1690
1691 =head2 OPTIONS
1692
1693 There are a number of options that can be passed in when constructing your
1694 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1695
1696 =over
1697
1698 =item * file
1699
1700 Filename of the DB file to link the handle to.  You can pass a full absolute
1701 filesystem path, partial path, or a plain filename if the file is in the
1702 current working directory.  This is a required parameter (though q.v. fh).
1703
1704 =item * fh
1705
1706 If you want, you can pass in the fh instead of the file. This is most useful for doing
1707 something like:
1708
1709   my $db = DBM::Deep->new( { fh => \*DATA } );
1710
1711 You are responsible for making sure that the fh has been opened appropriately for your
1712 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1713 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1714 needs to read from the fh.
1715
1716 =item * file_offset
1717
1718 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1719 not need to set this. However, it's there if you want it.
1720
1721 If you pass in fh and do not set this, it will be set appropriately.
1722
1723 =item * type
1724
1725 This parameter specifies what type of object to create, a hash or array.  Use
1726 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1727 This only takes effect when beginning a new file.  This is an optional
1728 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1729
1730 =item * locking
1731
1732 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1733 function to lock the database in exclusive mode for writes, and shared mode for
1734 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1735 any child hashes or arrays> that use the same DB file.  This is an optional
1736 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1737
1738 =item * autoflush
1739
1740 Specifies whether autoflush is to be enabled on the underlying filehandle.
1741 This obviously slows down write operations, but is required if you may have
1742 multiple processes accessing the same DB file (also consider enable I<locking>).
1743 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1744 (disabled).
1745
1746 =item * autobless
1747
1748 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1749 restore them when fetched.  This is an B<experimental> feature, and does have
1750 side-effects.  Basically, when hashes are re-blessed into their original
1751 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1752 able to call any DBM::Deep methods on them.  You have been warned.
1753 This is an optional parameter, and defaults to 0 (disabled).
1754
1755 =item * filter_*
1756
1757 See L<FILTERS> below.
1758
1759 =item * debug
1760
1761 Setting I<debug> mode will make all errors non-fatal, dump them out to
1762 STDERR, and continue on.  This is for debugging purposes only, and probably
1763 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1764
1765 =item * fh
1766
1767 Instead of passing a file path, you can instead pass a handle to an pre-opened
1768 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1769 contains your entire Perl script, as well as the data following the __DATA__
1770 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1771 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1772 in that.  Also please note optimize() will NOT work when passing in only a
1773 handle.  Pass in a real filename in order to use optimize().
1774
1775 =back
1776
1777 =head1 TIE INTERFACE
1778
1779 With DBM::Deep you can access your databases using Perl's standard hash/array
1780 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1781 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1782 to the right place -- the DB file.  This has nothing to do with the
1783 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1784 using regular hashes and arrays, rather than calling functions like C<get()>
1785 and C<put()> (although those work too).  It is entirely up to you how to want
1786 to access your databases.
1787
1788 =head2 HASHES
1789
1790 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1791 or even nested hashes (or arrays) using standard Perl syntax:
1792
1793         my $db = DBM::Deep->new( "foo.db" );
1794
1795         $db->{mykey} = "myvalue";
1796         $db->{myhash} = {};
1797         $db->{myhash}->{subkey} = "subvalue";
1798
1799         print $db->{myhash}->{subkey} . "\n";
1800
1801 You can even step through hash keys using the normal Perl C<keys()> function:
1802
1803         foreach my $key (keys %$db) {
1804                 print "$key: " . $db->{$key} . "\n";
1805         }
1806
1807 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1808 pushes them onto an array, all before the loop even begins.  If you have an
1809 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1810 Perl's C<each()> function, which pulls keys/values one at a time, using very
1811 little memory:
1812
1813         while (my ($key, $value) = each %$db) {
1814                 print "$key: $value\n";
1815         }
1816
1817 Please note that when using C<each()>, you should always pass a direct
1818 hash reference, not a lookup.  Meaning, you should B<never> do this:
1819
1820         # NEVER DO THIS
1821         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1822
1823 This causes an infinite loop, because for each iteration, Perl is calling
1824 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1825 it effectively keeps returning the first key over and over again. Instead,
1826 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1827
1828 =head2 ARRAYS
1829
1830 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1831 reference.  This includes inserting, removing and manipulating elements,
1832 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1833 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1834 or simply be a nested array reference inside a hash.  Example:
1835
1836         my $db = DBM::Deep->new(
1837                 file => "foo-array.db",
1838                 type => DBM::Deep->TYPE_ARRAY
1839         );
1840
1841         $db->[0] = "foo";
1842         push @$db, "bar", "baz";
1843         unshift @$db, "bah";
1844
1845         my $last_elem = pop @$db; # baz
1846         my $first_elem = shift @$db; # bah
1847         my $second_elem = $db->[1]; # bar
1848
1849         my $num_elements = scalar @$db;
1850
1851 =head1 OO INTERFACE
1852
1853 In addition to the I<tie()> interface, you can also use a standard OO interface
1854 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1855 array) has its own methods, but both types share the following common methods:
1856 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1857
1858 =over
1859
1860 =item * new() / clone()
1861
1862 These are the constructor and copy-functions.
1863
1864 =item * put() / store()
1865
1866 Stores a new hash key/value pair, or sets an array element value.  Takes two
1867 arguments, the hash key or array index, and the new value.  The value can be
1868 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1869
1870         $db->put("foo", "bar"); # for hashes
1871         $db->put(1, "bar"); # for arrays
1872
1873 =item * get() / fetch()
1874
1875 Fetches the value of a hash key or array element.  Takes one argument: the hash
1876 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1877 data type stored.
1878
1879         my $value = $db->get("foo"); # for hashes
1880         my $value = $db->get(1); # for arrays
1881
1882 =item * exists()
1883
1884 Checks if a hash key or array index exists.  Takes one argument: the hash key
1885 or array index.  Returns true if it exists, false if not.
1886
1887         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1888         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1889
1890 =item * delete()
1891
1892 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1893 key or array index.  Returns true on success, false if not found.  For arrays,
1894 the remaining elements located after the deleted element are NOT moved over.
1895 The deleted element is essentially just undefined, which is exactly how Perl's
1896 internal arrays work.  Please note that the space occupied by the deleted
1897 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1898 below for details and workarounds.
1899
1900         $db->delete("foo"); # for hashes
1901         $db->delete(1); # for arrays
1902
1903 =item * clear()
1904
1905 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1906 value.  Please note that the space occupied by the deleted keys/values or
1907 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1908 details and workarounds.
1909
1910         $db->clear(); # hashes or arrays
1911
1912 =item * lock() / unlock()
1913
1914 q.v. Locking.
1915
1916 =item * optimize()
1917
1918 Recover lost disk space.
1919
1920 =item * import() / export()
1921
1922 Data going in and out.
1923
1924 =item * set_digest() / set_pack() / set_filter()
1925
1926 q.v. adjusting the interal parameters.
1927
1928 =item * error() / clear_error()
1929
1930 Error handling methods (may be deprecated).
1931 .
1932 =back
1933
1934 =head2 HASHES
1935
1936 For hashes, DBM::Deep supports all the common methods described above, and the
1937 following additional methods: C<first_key()> and C<next_key()>.
1938
1939 =over
1940
1941 =item * first_key()
1942
1943 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1944 fetched in an undefined order (which appears random).  Takes no arguments,
1945 returns the key as a scalar value.
1946
1947         my $key = $db->first_key();
1948
1949 =item * next_key()
1950
1951 Returns the "next" key in the hash, given the previous one as the sole argument.
1952 Returns undef if there are no more keys to be fetched.
1953
1954         $key = $db->next_key($key);
1955
1956 =back
1957
1958 Here are some examples of using hashes:
1959
1960         my $db = DBM::Deep->new( "foo.db" );
1961
1962         $db->put("foo", "bar");
1963         print "foo: " . $db->get("foo") . "\n";
1964
1965         $db->put("baz", {}); # new child hash ref
1966         $db->get("baz")->put("buz", "biz");
1967         print "buz: " . $db->get("baz")->get("buz") . "\n";
1968
1969         my $key = $db->first_key();
1970         while ($key) {
1971                 print "$key: " . $db->get($key) . "\n";
1972                 $key = $db->next_key($key);
1973         }
1974
1975         if ($db->exists("foo")) { $db->delete("foo"); }
1976
1977 =head2 ARRAYS
1978
1979 For arrays, DBM::Deep supports all the common methods described above, and the
1980 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1981 C<unshift()> and C<splice()>.
1982
1983 =over
1984
1985 =item * length()
1986
1987 Returns the number of elements in the array.  Takes no arguments.
1988
1989         my $len = $db->length();
1990
1991 =item * push()
1992
1993 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1994 refs or array refs.  No return value.
1995
1996         $db->push("foo", "bar", {});
1997
1998 =item * pop()
1999
2000 Fetches the last element in the array, and deletes it.  Takes no arguments.
2001 Returns undef if array is empty.  Returns the element value.
2002
2003         my $elem = $db->pop();
2004
2005 =item * shift()
2006
2007 Fetches the first element in the array, deletes it, then shifts all the
2008 remaining elements over to take up the space.  Returns the element value.  This
2009 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2010 details.
2011
2012         my $elem = $db->shift();
2013
2014 =item * unshift()
2015
2016 Inserts one or more elements onto the beginning of the array, shifting all
2017 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2018 No return value.  This method is not recommended with large arrays -- see
2019 <LARGE ARRAYS> below for details.
2020
2021         $db->unshift("foo", "bar", {});
2022
2023 =item * splice()
2024
2025 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2026 -f splice> for usage -- it is too complicated to document here.  This method is
2027 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2028
2029 =back
2030
2031 Here are some examples of using arrays:
2032
2033         my $db = DBM::Deep->new(
2034                 file => "foo.db",
2035                 type => DBM::Deep->TYPE_ARRAY
2036         );
2037
2038         $db->push("bar", "baz");
2039         $db->unshift("foo");
2040         $db->put(3, "buz");
2041
2042         my $len = $db->length();
2043         print "length: $len\n"; # 4
2044
2045         for (my $k=0; $k<$len; $k++) {
2046                 print "$k: " . $db->get($k) . "\n";
2047         }
2048
2049         $db->splice(1, 2, "biz", "baf");
2050
2051         while (my $elem = shift @$db) {
2052                 print "shifted: $elem\n";
2053         }
2054
2055 =head1 LOCKING
2056
2057 Enable automatic file locking by passing a true value to the C<locking>
2058 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2059
2060         my $db = DBM::Deep->new(
2061                 file => "foo.db",
2062                 locking => 1
2063         );
2064
2065 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2066 mode for writes, and shared mode for reads.  This is required if you have
2067 multiple processes accessing the same database file, to avoid file corruption.
2068 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2069 NFS> below for more.
2070
2071 =head2 EXPLICIT LOCKING
2072
2073 You can explicitly lock a database, so it remains locked for multiple
2074 transactions.  This is done by calling the C<lock()> method, and passing an
2075 optional lock mode argument (defaults to exclusive mode).  This is particularly
2076 useful for things like counters, where the current value needs to be fetched,
2077 then incremented, then stored again.
2078
2079         $db->lock();
2080         my $counter = $db->get("counter");
2081         $counter++;
2082         $db->put("counter", $counter);
2083         $db->unlock();
2084
2085         # or...
2086
2087         $db->lock();
2088         $db->{counter}++;
2089         $db->unlock();
2090
2091 You can pass C<lock()> an optional argument, which specifies which mode to use
2092 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2093 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2094 same as the constants defined in Perl's C<Fcntl> module.
2095
2096         $db->lock( DBM::Deep->LOCK_SH );
2097         # something here
2098         $db->unlock();
2099
2100 =head1 IMPORTING/EXPORTING
2101
2102 You can import existing complex structures by calling the C<import()> method,
2103 and export an entire database into an in-memory structure using the C<export()>
2104 method.  Both are examined here.
2105
2106 =head2 IMPORTING
2107
2108 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2109 walking the structure and adding keys/elements to the database as you go,
2110 simply pass a reference to the C<import()> method.  This recursively adds
2111 everything to an existing DBM::Deep object for you.  Here is an example:
2112
2113         my $struct = {
2114                 key1 => "value1",
2115                 key2 => "value2",
2116                 array1 => [ "elem0", "elem1", "elem2" ],
2117                 hash1 => {
2118                         subkey1 => "subvalue1",
2119                         subkey2 => "subvalue2"
2120                 }
2121         };
2122
2123         my $db = DBM::Deep->new( "foo.db" );
2124         $db->import( $struct );
2125
2126         print $db->{key1} . "\n"; # prints "value1"
2127
2128 This recursively imports the entire C<$struct> object into C<$db>, including
2129 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2130 keys are merged with the existing ones, replacing if they already exist.
2131 The C<import()> method can be called on any database level (not just the base
2132 level), and works with both hash and array DB types.
2133
2134 B<Note:> Make sure your existing structure has no circular references in it.
2135 These will cause an infinite loop when importing.
2136
2137 =head2 EXPORTING
2138
2139 Calling the C<export()> method on an existing DBM::Deep object will return
2140 a reference to a new in-memory copy of the database.  The export is done
2141 recursively, so all nested hashes/arrays are all exported to standard Perl
2142 objects.  Here is an example:
2143
2144         my $db = DBM::Deep->new( "foo.db" );
2145
2146         $db->{key1} = "value1";
2147         $db->{key2} = "value2";
2148         $db->{hash1} = {};
2149         $db->{hash1}->{subkey1} = "subvalue1";
2150         $db->{hash1}->{subkey2} = "subvalue2";
2151
2152         my $struct = $db->export();
2153
2154         print $struct->{key1} . "\n"; # prints "value1"
2155
2156 This makes a complete copy of the database in memory, and returns a reference
2157 to it.  The C<export()> method can be called on any database level (not just
2158 the base level), and works with both hash and array DB types.  Be careful of
2159 large databases -- you can store a lot more data in a DBM::Deep object than an
2160 in-memory Perl structure.
2161
2162 B<Note:> Make sure your database has no circular references in it.
2163 These will cause an infinite loop when exporting.
2164
2165 =head1 FILTERS
2166
2167 DBM::Deep has a number of hooks where you can specify your own Perl function
2168 to perform filtering on incoming or outgoing data.  This is a perfect
2169 way to extend the engine, and implement things like real-time compression or
2170 encryption.  Filtering applies to the base DB level, and all child hashes /
2171 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2172 constructed, or by calling the C<set_filter()> method at any time.  There are
2173 four available filter hooks, described below:
2174
2175 =over
2176
2177 =item * filter_store_key
2178
2179 This filter is called whenever a hash key is stored.  It
2180 is passed the incoming key, and expected to return a transformed key.
2181
2182 =item * filter_store_value
2183
2184 This filter is called whenever a hash key or array element is stored.  It
2185 is passed the incoming value, and expected to return a transformed value.
2186
2187 =item * filter_fetch_key
2188
2189 This filter is called whenever a hash key is fetched (i.e. via
2190 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2191 and expected to return the plain key.
2192
2193 =item * filter_fetch_value
2194
2195 This filter is called whenever a hash key or array element is fetched.
2196 It is passed the transformed value, and expected to return the plain value.
2197
2198 =back
2199
2200 Here are the two ways to setup a filter hook:
2201
2202         my $db = DBM::Deep->new(
2203                 file => "foo.db",
2204                 filter_store_value => \&my_filter_store,
2205                 filter_fetch_value => \&my_filter_fetch
2206         );
2207
2208         # or...
2209
2210         $db->set_filter( "filter_store_value", \&my_filter_store );
2211         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2212
2213 Your filter function will be called only when dealing with SCALAR keys or
2214 values.  When nested hashes and arrays are being stored/fetched, filtering
2215 is bypassed.  Filters are called as static functions, passed a single SCALAR
2216 argument, and expected to return a single SCALAR value.  If you want to
2217 remove a filter, set the function reference to C<undef>:
2218
2219         $db->set_filter( "filter_store_value", undef );
2220
2221 =head2 REAL-TIME ENCRYPTION EXAMPLE
2222
2223 Here is a working example that uses the I<Crypt::Blowfish> module to
2224 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2225 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2226 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2227
2228         use DBM::Deep;
2229         use Crypt::Blowfish;
2230         use Crypt::CBC;
2231
2232         my $cipher = Crypt::CBC->new({
2233                 'key'             => 'my secret key',
2234                 'cipher'          => 'Blowfish',
2235                 'iv'              => '$KJh#(}q',
2236                 'regenerate_key'  => 0,
2237                 'padding'         => 'space',
2238                 'prepend_iv'      => 0
2239         });
2240
2241         my $db = DBM::Deep->new(
2242                 file => "foo-encrypt.db",
2243                 filter_store_key => \&my_encrypt,
2244                 filter_store_value => \&my_encrypt,
2245                 filter_fetch_key => \&my_decrypt,
2246                 filter_fetch_value => \&my_decrypt,
2247         );
2248
2249         $db->{key1} = "value1";
2250         $db->{key2} = "value2";
2251         print "key1: " . $db->{key1} . "\n";
2252         print "key2: " . $db->{key2} . "\n";
2253
2254         undef $db;
2255         exit;
2256
2257         sub my_encrypt {
2258                 return $cipher->encrypt( $_[0] );
2259         }
2260         sub my_decrypt {
2261                 return $cipher->decrypt( $_[0] );
2262         }
2263
2264 =head2 REAL-TIME COMPRESSION EXAMPLE
2265
2266 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2267 compression / decompression of keys & values with DBM::Deep Filters.
2268 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2269 more on I<Compress::Zlib>.
2270
2271         use DBM::Deep;
2272         use Compress::Zlib;
2273
2274         my $db = DBM::Deep->new(
2275                 file => "foo-compress.db",
2276                 filter_store_key => \&my_compress,
2277                 filter_store_value => \&my_compress,
2278                 filter_fetch_key => \&my_decompress,
2279                 filter_fetch_value => \&my_decompress,
2280         );
2281
2282         $db->{key1} = "value1";
2283         $db->{key2} = "value2";
2284         print "key1: " . $db->{key1} . "\n";
2285         print "key2: " . $db->{key2} . "\n";
2286
2287         undef $db;
2288         exit;
2289
2290         sub my_compress {
2291                 return Compress::Zlib::memGzip( $_[0] ) ;
2292         }
2293         sub my_decompress {
2294                 return Compress::Zlib::memGunzip( $_[0] ) ;
2295         }
2296
2297 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2298 actually numerical index numbers, and are not filtered.
2299
2300 =head1 ERROR HANDLING
2301
2302 Most DBM::Deep methods return a true value for success, and call die() on
2303 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2304 actual error message is stored in an internal scalar, which can be fetched by
2305 calling the C<error()> method.
2306
2307         my $db = DBM::Deep->new( "foo.db" ); # create hash
2308         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2309
2310     print $@;           # prints error message
2311         print $db->error(); # prints error message
2312
2313 You can then call C<clear_error()> to clear the current error state.
2314
2315         $db->clear_error();
2316
2317 If you set the C<debug> option to true when creating your DBM::Deep object,
2318 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2319 be used for debugging purposes and not production work. DBM::Deep expects errors
2320 to be thrown, not propagated back up the stack.
2321
2322 =head1 LARGEFILE SUPPORT
2323
2324 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2325 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2326 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2327 by calling the static C<set_pack()> method before you do anything else.
2328
2329         DBM::Deep::set_pack(8, 'Q');
2330
2331 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2332 instead of 32-bit longs.  After setting these values your DB files have a
2333 theoretical maximum size of 16 XB (exabytes).
2334
2335 B<Note:> Changing these values will B<NOT> work for existing database files.
2336 Only change this for new files, and make sure it stays set consistently
2337 throughout the file's life.  If you do set these values, you can no longer
2338 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2339 back to 32-bit mode.
2340
2341 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2342 only a 32-bit Perl.  However, I have received user reports that this does
2343 indeed work!
2344
2345 =head1 LOW-LEVEL ACCESS
2346
2347 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2348 you can call the C<_fh()> method, which returns the handle:
2349
2350         my $fh = $db->_fh();
2351
2352 This method can be called on the root level of the datbase, or any child
2353 hashes or arrays.  All levels share a I<root> structure, which contains things
2354 like the filehandle, a reference counter, and all the options specified
2355 when you created the object.  You can get access to this root structure by
2356 calling the C<root()> method.
2357
2358         my $root = $db->_root();
2359
2360 This is useful for changing options after the object has already been created,
2361 such as enabling/disabling locking, or debug modes.  You can also
2362 store your own temporary user data in this structure (be wary of name
2363 collision), which is then accessible from any child hash or array.
2364
2365 =head1 CUSTOM DIGEST ALGORITHM
2366
2367 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2368 keys.  However you can override this, and use another algorithm (such as SHA-256)
2369 or even write your own.  But please note that DBM::Deep currently expects zero
2370 collisions, so your algorithm has to be I<perfect>, so to speak.
2371 Collision detection may be introduced in a later version.
2372
2373
2374
2375 You can specify a custom digest algorithm by calling the static C<set_digest()>
2376 function, passing a reference to a subroutine, and the length of the algorithm's
2377 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2378 objects.  Here is a working example that uses a 256-bit hash from the
2379 I<Digest::SHA256> module.  Please see
2380 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2381
2382         use DBM::Deep;
2383         use Digest::SHA256;
2384
2385         my $context = Digest::SHA256::new(256);
2386
2387         DBM::Deep::set_digest( \&my_digest, 32 );
2388
2389         my $db = DBM::Deep->new( "foo-sha.db" );
2390
2391         $db->{key1} = "value1";
2392         $db->{key2} = "value2";
2393         print "key1: " . $db->{key1} . "\n";
2394         print "key2: " . $db->{key2} . "\n";
2395
2396         undef $db;
2397         exit;
2398
2399         sub my_digest {
2400                 return substr( $context->hash($_[0]), 0, 32 );
2401         }
2402
2403 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2404 of bytes you specify in the C<set_digest()> function (in this case 32).
2405
2406 =head1 CIRCULAR REFERENCES
2407
2408 DBM::Deep has B<experimental> support for circular references.  Meaning you
2409 can have a nested hash key or array element that points to a parent object.
2410 This relationship is stored in the DB file, and is preserved between sessions.
2411 Here is an example:
2412
2413         my $db = DBM::Deep->new( "foo.db" );
2414
2415         $db->{foo} = "bar";
2416         $db->{circle} = $db; # ref to self
2417
2418         print $db->{foo} . "\n"; # prints "foo"
2419         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2420
2421 One catch is, passing the object to a function that recursively walks the
2422 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2423 C<export()> methods) will result in an infinite loop.  The other catch is,
2424 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2425 or C<next_key()> methods), you will get the I<target object's key>, not the
2426 ref's key.  This gets even more interesting with the above example, where
2427 the I<circle> key points to the base DB object, which technically doesn't
2428 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2429 special case.
2430
2431 =head1 CAVEATS / ISSUES / BUGS
2432
2433 This section describes all the known issues with DBM::Deep.  It you have found
2434 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2435
2436 =head2 UNUSED SPACE RECOVERY
2437
2438 One major caveat with DBM::Deep is that space occupied by existing keys and
2439 values is not recovered when they are deleted.  Meaning if you keep deleting
2440 and adding new keys, your file will continuously grow.  I am working on this,
2441 but in the meantime you can call the built-in C<optimize()> method from time to
2442 time (perhaps in a crontab or something) to recover all your unused space.
2443
2444         $db->optimize(); # returns true on success
2445
2446 This rebuilds the ENTIRE database into a new file, then moves it on top of
2447 the original.  The new file will have no unused space, thus it will take up as
2448 little disk space as possible.  Please note that this operation can take
2449 a long time for large files, and you need enough disk space to temporarily hold
2450 2 copies of your DB file.  The temporary file is created in the same directory
2451 as the original, named with a ".tmp" extension, and is deleted when the
2452 operation completes.  Oh, and if locking is enabled, the DB is automatically
2453 locked for the entire duration of the copy.
2454
2455 B<WARNING:> Only call optimize() on the top-level node of the database, and
2456 make sure there are no child references lying around.  DBM::Deep keeps a reference
2457 counter, and if it is greater than 1, optimize() will abort and return undef.
2458
2459 =head2 AUTOVIVIFICATION
2460
2461 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2462 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2463 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2464 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2465 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2466 this does not work:
2467
2468         $db->{foo}->{bar} = "hello";
2469
2470 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2471 being an empty hash.  Try this instead, which works fine:
2472
2473         $db->{foo} = { bar => "hello" };
2474
2475 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2476 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2477 Probably a bug in Perl.
2478
2479 =head2 FILE CORRUPTION
2480
2481 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2482 for a 32-bit signature when opened, but other corruption in files can cause
2483 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2484 stuck in an infinite loop depending on the level of corruption.  File write
2485 operations are not checked for failure (for speed), so if you happen to run
2486 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2487 be addressed in a later version of DBM::Deep.
2488
2489 =head2 DB OVER NFS
2490
2491 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2492 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2493 about setting up your NFS server with a locking daemon, then using lockf() to
2494 lock your files, but your mileage may vary there as well.  From what I
2495 understand, there is no real way to do it.  However, if you need access to the
2496 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2497 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2498
2499 =head2 COPYING OBJECTS
2500
2501 Beware of copying tied objects in Perl.  Very strange things can happen.
2502 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2503 returns a new, blessed, tied hash or array to the same level in the DB.
2504
2505         my $copy = $db->clone();
2506
2507 B<Note>: Since clone() here is cloning the object, not the database location, any
2508 modifications to either $db or $copy will be visible in both.
2509
2510 =head2 LARGE ARRAYS
2511
2512 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2513 These functions cause every element in the array to move, which can be murder
2514 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2515 a different location.  This will be addressed in the forthcoming version 1.00.
2516
2517 =head1 PERFORMANCE
2518
2519 This section discusses DBM::Deep's speed and memory usage.
2520
2521 =head2 SPEED
2522
2523 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2524 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2525 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2526 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2527 with huge databases.  Here is some test data:
2528
2529         Adding 1,000,000 keys to new DB file...
2530
2531         At 100 keys, avg. speed is 2,703 keys/sec
2532         At 200 keys, avg. speed is 2,642 keys/sec
2533         At 300 keys, avg. speed is 2,598 keys/sec
2534         At 400 keys, avg. speed is 2,578 keys/sec
2535         At 500 keys, avg. speed is 2,722 keys/sec
2536         At 600 keys, avg. speed is 2,628 keys/sec
2537         At 700 keys, avg. speed is 2,700 keys/sec
2538         At 800 keys, avg. speed is 2,607 keys/sec
2539         At 900 keys, avg. speed is 2,190 keys/sec
2540         At 1,000 keys, avg. speed is 2,570 keys/sec
2541         At 2,000 keys, avg. speed is 2,417 keys/sec
2542         At 3,000 keys, avg. speed is 1,982 keys/sec
2543         At 4,000 keys, avg. speed is 1,568 keys/sec
2544         At 5,000 keys, avg. speed is 1,533 keys/sec
2545         At 6,000 keys, avg. speed is 1,787 keys/sec
2546         At 7,000 keys, avg. speed is 1,977 keys/sec
2547         At 8,000 keys, avg. speed is 2,028 keys/sec
2548         At 9,000 keys, avg. speed is 2,077 keys/sec
2549         At 10,000 keys, avg. speed is 2,031 keys/sec
2550         At 20,000 keys, avg. speed is 1,970 keys/sec
2551         At 30,000 keys, avg. speed is 2,050 keys/sec
2552         At 40,000 keys, avg. speed is 2,073 keys/sec
2553         At 50,000 keys, avg. speed is 1,973 keys/sec
2554         At 60,000 keys, avg. speed is 1,914 keys/sec
2555         At 70,000 keys, avg. speed is 2,091 keys/sec
2556         At 80,000 keys, avg. speed is 2,103 keys/sec
2557         At 90,000 keys, avg. speed is 1,886 keys/sec
2558         At 100,000 keys, avg. speed is 1,970 keys/sec
2559         At 200,000 keys, avg. speed is 2,053 keys/sec
2560         At 300,000 keys, avg. speed is 1,697 keys/sec
2561         At 400,000 keys, avg. speed is 1,838 keys/sec
2562         At 500,000 keys, avg. speed is 1,941 keys/sec
2563         At 600,000 keys, avg. speed is 1,930 keys/sec
2564         At 700,000 keys, avg. speed is 1,735 keys/sec
2565         At 800,000 keys, avg. speed is 1,795 keys/sec
2566         At 900,000 keys, avg. speed is 1,221 keys/sec
2567         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2568
2569 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2570 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2571 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2572 Run time was 12 min 3 sec.
2573
2574 =head2 MEMORY USAGE
2575
2576 One of the great things about DBM::Deep is that it uses very little memory.
2577 Even with huge databases (1,000,000+ keys) you will not see much increased
2578 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2579 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2580 database handle:
2581
2582           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2583         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2584
2585 Basically the process is taking 2,716K of memory.  And here is the same
2586 process after storing and fetching 1,000,000 keys:
2587
2588           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2589         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2590
2591 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2592 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2593
2594 =head1 DB FILE FORMAT
2595
2596 In case you were interested in the underlying DB file format, it is documented
2597 here in this section.  You don't need to know this to use the module, it's just
2598 included for reference.
2599
2600 =head2 SIGNATURE
2601
2602 DBM::Deep files always start with a 32-bit signature to identify the file type.
2603 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2604 checked for when the file is opened and an error will be thrown if it's not found.
2605
2606 =head2 TAG
2607
2608 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2609 has a standard header containing the type of data, the length of data, and then
2610 the data itself.  The type is a single character (1 byte), the length is a
2611 32-bit unsigned long in network byte order, and the data is, well, the data.
2612 Here is how it unfolds:
2613
2614 =head2 MASTER INDEX
2615
2616 Immediately after the 32-bit file signature is the I<Master Index> record.
2617 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2618 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2619 depending on how the DBM::Deep object was constructed.
2620
2621 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2622 number).  The first 8-bit char of the MD5 signature is the offset into the
2623 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2624 index element is a file offset of the next tag for the key/element in question,
2625 which is usually a I<Bucket List> tag (see below).
2626
2627 The next tag I<could> be another index, depending on how many keys/elements
2628 exist.  See L<RE-INDEXING> below for details.
2629
2630 =head2 BUCKET LIST
2631
2632 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2633 file offsets to where the actual data is stored.  It starts with a standard
2634 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2635 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2636 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2637 When the list fills up, a I<Re-Index> operation is performed (See
2638 L<RE-INDEXING> below).
2639
2640 =head2 BUCKET
2641
2642 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2643 index/value pair (in array mode).  It starts with a standard tag header with
2644 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2645 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2646 header.  The size reported in the tag header is only for the value, but then,
2647 just after the value is another size (32-bit unsigned long) and then the plain
2648 key itself.  Since the value is likely to be fetched more often than the plain
2649 key, I figured it would be I<slightly> faster to store the value first.
2650
2651 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2652 record for the nested structure, where the process begins all over again.
2653
2654 =head2 RE-INDEXING
2655
2656 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2657 exhausted.  Then, when another key/element comes in, the list is converted to a
2658 new index record.  However, this index will look at the next char in the MD5
2659 hash, and arrange new Bucket List pointers accordingly.  This process is called
2660 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2661 17 (16 + new one) keys/elements are removed from the old Bucket List and
2662 inserted into the new index.  Several new Bucket Lists are created in the
2663 process, as a new MD5 char from the key is being examined (it is unlikely that
2664 the keys will all share the same next char of their MD5s).
2665
2666 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2667 when the Bucket Lists will turn into indexes, but the first round tends to
2668 happen right around 4,000 keys.  You will see a I<slight> decrease in
2669 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2670 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2671 right around 900,000 keys.  This process can continue nearly indefinitely --
2672 right up until the point the I<MD5> signatures start colliding with each other,
2673 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2674 getting struck by lightning while you are walking to cash in your tickets.
2675 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2676 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2677 this is 340 unodecillion, but don't quote me).
2678
2679 =head2 STORING
2680
2681 When a new key/element is stored, the key (or index number) is first run through
2682 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2683 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2684 for the first char of the signature (in this case I<b0>).  If it does not exist,
2685 a new I<Bucket List> is created for our key (and the next 15 future keys that
2686 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2687 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2688 this point, unless we are replacing an existing I<Bucket>), where the actual
2689 data will be stored.
2690
2691 =head2 FETCHING
2692
2693 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2694 (or index number), then walking along the indexes.  If there are enough
2695 keys/elements in this DB level, there might be nested indexes, each linked to
2696 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2697 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2698 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2699 plain key are stored.
2700
2701 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2702 methods.  In this process the indexes are walked systematically, and each key
2703 fetched in increasing MD5 order (which is why it appears random).   Once the
2704 I<Bucket> is found, the value is skipped and the plain key returned instead.
2705 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2706 alphabetically sorted.  This only happens on an index-level -- as soon as the
2707 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2708 so it's pretty much undefined how the keys will come out -- just like Perl's
2709 built-in hashes.
2710
2711 =head1 CODE COVERAGE
2712
2713 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2714 B<Devel::Cover> report on this module's test suite.
2715
2716   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2717   File                           stmt   bran   cond    sub    pod   time  total
2718   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2719   blib/lib/DBM/Deep.pm           95.0   83.2   68.7   98.2  100.0   57.8   90.7
2720   blib/lib/DBM/Deep/Array.pm     98.9   88.9   87.5  100.0    n/a   27.4   96.4
2721   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   14.8   92.4
2722   Total                          95.8   83.9   72.8   98.8  100.0  100.0   91.8
2723   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2724
2725 =head1 MORE INFORMATION
2726
2727 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2728 or send email to L<DBM-Deep@googlegroups.com>.
2729
2730 =head1 AUTHORS
2731
2732 Joseph Huckaby, L<jhuckaby@cpan.org>
2733
2734 Rob Kinyon, L<rkinyon@cpan.org>
2735
2736 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2737
2738 =head1 SEE ALSO
2739
2740 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2741 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2742
2743 =head1 LICENSE
2744
2745 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2746 This is free software, you may use it and distribute it under the
2747 same terms as Perl itself.
2748
2749 =cut