lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.983);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_NULL   () { 'N' }
  94 sub SIG_DATA   () { 'D' }
  95 sub SIG_INDEX  () { 'I' }
  96 sub SIG_BLIST  () { 'B' }
  97 sub SIG_SIZE   () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH   () { SIG_HASH   }
 103 sub TYPE_ARRAY  () { SIG_ARRAY  }
 104
 105 sub _get_args {
 106     my $proto = shift;
 107
 108     my $args;
 109     if (scalar(@_) > 1) {
 110         if ( @_ % 2 ) {
 111             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 112         }
 113         $args = {@_};
 114     }
 115         elsif ( ref $_[0] ) {
 116         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 117             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 118         }
 119         $args = $_[0];
 120     }
 121         else {
 122         $args = { file => shift };
 123     }
 124
 125     return $args;
 126 }
 127
 128 sub new {
 129         ##
 130         # Class constructor method for Perl OO interface.
 131         # Calls tie() and returns blessed reference to tied hash or array,
 132         # providing a hybrid OO/tie interface.
 133         ##
 134         my $class = shift;
 135         my $args = $class->_get_args( @_ );
 136
 137         ##
 138         # Check if we want a tied hash or array.
 139         ##
 140         my $self;
 141         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 142         $class = 'DBM::Deep::Array';
 143         require DBM::Deep::Array;
 144                 tie @$self, $class, %$args;
 145         }
 146         else {
 147         $class = 'DBM::Deep::Hash';
 148         require DBM::Deep::Hash;
 149                 tie %$self, $class, %$args;
 150         }
 151
 152         return bless $self, $class;
 153 }
 154
 155 sub _init {
 156     ##
 157     # Setup $self and bless into this class.
 158     ##
 159     my $class = shift;
 160     my $args = shift;
 161
 162     # These are the defaults to be optionally overridden below
 163     my $self = bless {
 164         type => TYPE_HASH,
 165         base_offset => length(SIG_FILE),
 166     }, $class;
 167
 168     foreach my $param ( keys %$self ) {
 169         next unless exists $args->{$param};
 170         $self->{$param} = delete $args->{$param}
 171     }
 172
 173     # locking implicitly enables autoflush
 174     if ($args->{locking}) { $args->{autoflush} = 1; }
 175
 176     $self->{root} = exists $args->{root}
 177         ? $args->{root}
 178         : DBM::Deep::_::Root->new( $args );
 179
 180     if (!defined($self->_fh)) { $self->_open(); }
 181
 182     return $self;
 183 }
 184
 185 sub TIEHASH {
 186     shift;
 187     require DBM::Deep::Hash;
 188     return DBM::Deep::Hash->TIEHASH( @_ );
 189 }
 190
 191 sub TIEARRAY {
 192     shift;
 193     require DBM::Deep::Array;
 194     return DBM::Deep::Array->TIEARRAY( @_ );
 195 }
 196
 197 #XXX Unneeded now ...
 198 #sub DESTROY {
 199 #}
 200
 201 sub _open {
 202         ##
 203         # Open a fh to the database, create if nonexistent.
 204         # Make sure file signature matches DBM::Deep spec.
 205         ##
 206     my $self = $_[0]->_get_self;
 207
 208     local($/,$\);
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214     my $fh;
 215     sysopen( $fh, $self->_root->{file}, $flags )
 216                 or $self->_throw_error( "Cannot sysopen file: " . $self->_root->{file} . ": $!" );
 217
 218     $self->_root->{fh} = $fh;
 219
 220     if ($self->_root->{autoflush}) {
 221         my $old = select $fh;
 222         $|=1;
 223         select $old;
 224     }
 225
 226     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 227
 228     my $signature;
 229     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 230
 231     ##
 232     # File is empty -- write signature and master index
 233     ##
 234     if (!$bytes_read) {
 235         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 236         print( $fh SIG_FILE);
 237         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 238
 239         my $plain_key = "[base]";
 240         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 241
 242         # Flush the filehandle
 243         my $old_fh = select $fh;
 244         my $old_af = $|; $| = 1; $| = $old_af;
 245         select $old_fh;
 246
 247         my @stats = stat($fh);
 248         $self->_root->{inode} = $stats[1];
 249         $self->_root->{end} = $stats[7];
 250
 251         return 1;
 252     }
 253
 254     ##
 255     # Check signature was valid
 256     ##
 257     unless ($signature eq SIG_FILE) {
 258         $self->_close();
 259         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 260     }
 261
 262         my @stats = stat($fh);
 263         $self->_root->{inode} = $stats[1];
 264     $self->_root->{end} = $stats[7];
 265
 266     ##
 267     # Get our type from master index signature
 268     ##
 269     my $tag = $self->_load_tag($self->_base_offset);
 270
 271 #XXX We probably also want to store the hash algorithm name and not assume anything
 272 #XXX The cool thing would be to allow a different hashing algorithm at every level
 273
 274     if (!$tag) {
 275         return $self->_throw_error("Corrupted file, no master index record");
 276     }
 277     if ($self->{type} ne $tag->{signature}) {
 278         return $self->_throw_error("File type mismatch");
 279     }
 280
 281     return 1;
 282 }
 283
 284 sub _close {
 285         ##
 286         # Close database fh
 287         ##
 288     my $self = $_[0]->_get_self;
 289     close $self->_root->{fh} if $self->_root->{fh};
 290     $self->_root->{fh} = undef;
 291 }
 292
 293 sub _create_tag {
 294         ##
 295         # Given offset, signature and content, create tag and write to disk
 296         ##
 297         my ($self, $offset, $sig, $content) = @_;
 298         my $size = length($content);
 299
 300     local($/,$\);
 301
 302     my $fh = $self->_fh;
 303
 304         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 305         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 306
 307         if ($offset == $self->_root->{end}) {
 308                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 309         }
 310
 311         return {
 312                 signature => $sig,
 313                 size => $size,
 314                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 315                 content => $content
 316         };
 317 }
 318
 319 sub _load_tag {
 320         ##
 321         # Given offset, load single tag and return signature, size and data
 322         ##
 323         my $self = shift;
 324         my $offset = shift;
 325
 326     local($/,$\);
 327
 328     my $fh = $self->_fh;
 329
 330         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 331         if (eof $fh) { return undef; }
 332
 333     my $b;
 334     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 335     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 336
 337         my $buffer;
 338         read( $fh, $buffer, $size);
 339
 340         return {
 341                 signature => $sig,
 342                 size => $size,
 343                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 344                 content => $buffer
 345         };
 346 }
 347
 348 sub _index_lookup {
 349         ##
 350         # Given index tag, lookup single entry in index and return .
 351         ##
 352         my $self = shift;
 353         my ($tag, $index) = @_;
 354
 355         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 356         if (!$location) { return; }
 357
 358         return $self->_load_tag( $location );
 359 }
 360
 361 sub _add_bucket {
 362         ##
 363         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 364         # plain (undigested) key and value.
 365         ##
 366         my $self = shift;
 367         my ($tag, $md5, $plain_key, $value) = @_;
 368         my $keys = $tag->{content};
 369         my $location = 0;
 370         my $result = 2;
 371
 372     local($/,$\);
 373
 374     # This verifies that only supported values will be stored.
 375     {
 376         my $r = Scalar::Util::reftype( $value );
 377         last if !defined $r;
 378
 379         last if $r eq 'HASH';
 380         last if $r eq 'ARRAY';
 381
 382         $self->_throw_error(
 383             "Storage of variables of type '$r' is not supported."
 384         );
 385     }
 386
 387     my $root = $self->_root;
 388
 389     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 390         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 391
 392     my $fh = $self->_fh;
 393
 394         ##
 395         # Iterate through buckets, seeing if this is a new entry or a replace.
 396         ##
 397         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 398                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 399                 if (!$subloc) {
 400                         ##
 401                         # Found empty bucket (end of list).  Populate and exit loop.
 402                         ##
 403                         $result = 2;
 404
 405             $location = $internal_ref
 406                 ? $value->_base_offset
 407                 : $root->{end};
 408
 409                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 410                         print( $fh $md5 . pack($LONG_PACK, $location) );
 411                         last;
 412                 }
 413
 414                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 415                 if ($md5 eq $key) {
 416                         ##
 417                         # Found existing bucket with same key.  Replace with new value.
 418                         ##
 419                         $result = 1;
 420
 421                         if ($internal_ref) {
 422                                 $location = $value->_base_offset;
 423                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 424                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 425                 return $result;
 426                         }
 427
 428             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 429             my $size;
 430             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 431
 432             ##
 433             # If value is a hash, array, or raw value with equal or less size, we can
 434             # reuse the same content area of the database.  Otherwise, we have to create
 435             # a new content area at the EOF.
 436             ##
 437             my $actual_length;
 438             my $r = Scalar::Util::reftype( $value ) || '';
 439             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 440                 $actual_length = $INDEX_SIZE;
 441
 442                 # if autobless is enabled, must also take into consideration
 443                 # the class name, as it is stored along with key/value.
 444                 if ( $root->{autobless} ) {
 445                     my $value_class = Scalar::Util::blessed($value);
 446                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 447                         $actual_length += length($value_class);
 448                     }
 449                 }
 450             }
 451             else { $actual_length = length($value); }
 452
 453             if ($actual_length <= ($size || 0)) {
 454                 $location = $subloc;
 455             }
 456             else {
 457                 $location = $root->{end};
 458                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 459                 print( $fh pack($LONG_PACK, $location) );
 460             }
 461
 462                         last;
 463                 }
 464         }
 465
 466         ##
 467         # If this is an internal reference, return now.
 468         # No need to write value or plain key
 469         ##
 470         if ($internal_ref) {
 471         return $result;
 472     }
 473
 474         ##
 475         # If bucket didn't fit into list, split into a new index level
 476         ##
 477         if (!$location) {
 478                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 479                 print( $fh pack($LONG_PACK, $root->{end}) );
 480
 481                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 482                 my @offsets = ();
 483
 484                 $keys .= $md5 . pack($LONG_PACK, 0);
 485
 486                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 487                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 488                         if ($key) {
 489                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 490                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 491
 492                                 if ($offsets[$num]) {
 493                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 494                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 495                                         my $subkeys;
 496                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 497
 498                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 499                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 500                                                 if (!$subloc) {
 501                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 502                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 503                                                         last;
 504                                                 }
 505                                         } # k loop
 506                                 }
 507                                 else {
 508                                         $offsets[$num] = $root->{end};
 509                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 510                                         print( $fh pack($LONG_PACK, $root->{end}) );
 511
 512                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 513
 514                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 515                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 516                                 }
 517                         } # key is real
 518                 } # i loop
 519
 520                 $location ||= $root->{end};
 521         } # re-index bucket list
 522
 523         ##
 524         # Seek to content area and store signature, value and plaintext key
 525         ##
 526         if ($location) {
 527                 my $content_length;
 528                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 529
 530                 ##
 531                 # Write signature based on content type, set content length and write actual value.
 532                 ##
 533         my $r = Scalar::Util::reftype($value) || '';
 534                 if ($r eq 'HASH') {
 535             if ( !$internal_ref && tied %{$value} ) {
 536                 return $self->_throw_error("Cannot store a tied value");
 537             }
 538                         print( $fh TYPE_HASH );
 539                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 540                         $content_length = $INDEX_SIZE;
 541                 }
 542                 elsif ($r eq 'ARRAY') {
 543             if ( !$internal_ref && tied @{$value} ) {
 544                 return $self->_throw_error("Cannot store a tied value");
 545             }
 546                         print( $fh TYPE_ARRAY );
 547                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 548                         $content_length = $INDEX_SIZE;
 549                 }
 550                 elsif (!defined($value)) {
 551                         print( $fh SIG_NULL );
 552                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 553                         $content_length = 0;
 554                 }
 555                 else {
 556                         print( $fh SIG_DATA );
 557                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 558                         $content_length = length($value);
 559                 }
 560
 561                 ##
 562                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 563                 ##
 564                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 565
 566                 ##
 567                 # If value is blessed, preserve class name
 568                 ##
 569                 if ( $root->{autobless} ) {
 570             my $value_class = Scalar::Util::blessed($value);
 571             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 572                 ##
 573                 # Blessed ref -- will restore later
 574                 ##
 575                 print( $fh chr(1) );
 576                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 577                 $content_length += 1;
 578                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 579             }
 580             else {
 581                 print( $fh chr(0) );
 582                 $content_length += 1;
 583             }
 584         }
 585
 586                 ##
 587                 # If this is a new content area, advance EOF counter
 588                 ##
 589                 if ($location == $root->{end}) {
 590                         $root->{end} += SIG_SIZE;
 591                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 592                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 593                 }
 594
 595                 ##
 596                 # If content is a hash or array, create new child DBM::Deep object and
 597                 # pass each key or element to it.
 598                 ##
 599                 if ($r eq 'HASH') {
 600             my %x = %$value;
 601             tie %$value, 'DBM::Deep', {
 602                                 type => TYPE_HASH,
 603                                 base_offset => $location,
 604                                 root => $root,
 605                         };
 606             %$value = %x;
 607                 }
 608                 elsif ($r eq 'ARRAY') {
 609             my @x = @$value;
 610             tie @$value, 'DBM::Deep', {
 611                                 type => TYPE_ARRAY,
 612                                 base_offset => $location,
 613                                 root => $root,
 614                         };
 615             @$value = @x;
 616                 }
 617
 618                 return $result;
 619         }
 620
 621         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 622 }
 623
 624 sub _get_bucket_value {
 625         ##
 626         # Fetch single value given tag and MD5 digested key.
 627         ##
 628         my $self = shift;
 629         my ($tag, $md5) = @_;
 630         my $keys = $tag->{content};
 631
 632     local($/,$\);
 633
 634     my $fh = $self->_fh;
 635
 636         ##
 637         # Iterate through buckets, looking for a key match
 638         ##
 639     BUCKET:
 640         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 641                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 642                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 643
 644                 if (!$subloc) {
 645                         ##
 646                         # Hit end of list, no match
 647                         ##
 648                         return;
 649                 }
 650
 651         if ( $md5 ne $key ) {
 652             next BUCKET;
 653         }
 654
 655         ##
 656         # Found match -- seek to offset and read signature
 657         ##
 658         my $signature;
 659         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 660         read( $fh, $signature, SIG_SIZE);
 661
 662         ##
 663         # If value is a hash or array, return new DBM::Deep object with correct offset
 664         ##
 665         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 666             my $obj = DBM::Deep->new(
 667                 type => $signature,
 668                 base_offset => $subloc,
 669                 root => $self->_root
 670             );
 671
 672             if ($self->_root->{autobless}) {
 673                 ##
 674                 # Skip over value and plain key to see if object needs
 675                 # to be re-blessed
 676                 ##
 677                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 678
 679                 my $size;
 680                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 681                 if ($size) { seek($fh, $size, SEEK_CUR); }
 682
 683                 my $bless_bit;
 684                 read( $fh, $bless_bit, 1);
 685                 if (ord($bless_bit)) {
 686                     ##
 687                     # Yes, object needs to be re-blessed
 688                     ##
 689                     my $class_name;
 690                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 691                     if ($size) { read( $fh, $class_name, $size); }
 692                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 693                 }
 694             }
 695
 696             return $obj;
 697         }
 698
 699         ##
 700         # Otherwise return actual value
 701         ##
 702         elsif ($signature eq SIG_DATA) {
 703             my $size;
 704             my $value = '';
 705             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 706             if ($size) { read( $fh, $value, $size); }
 707             return $value;
 708         }
 709
 710         ##
 711         # Key exists, but content is null
 712         ##
 713         else { return; }
 714         } # i loop
 715
 716         return;
 717 }
 718
 719 sub _delete_bucket {
 720         ##
 721         # Delete single key/value pair given tag and MD5 digested key.
 722         ##
 723         my $self = shift;
 724         my ($tag, $md5) = @_;
 725         my $keys = $tag->{content};
 726
 727     local($/,$\);
 728
 729     my $fh = $self->_fh;
 730
 731         ##
 732         # Iterate through buckets, looking for a key match
 733         ##
 734     BUCKET:
 735         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 736                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 737                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 738
 739                 if (!$subloc) {
 740                         ##
 741                         # Hit end of list, no match
 742                         ##
 743                         return;
 744                 }
 745
 746         if ( $md5 ne $key ) {
 747             next BUCKET;
 748         }
 749
 750         ##
 751         # Matched key -- delete bucket and return
 752         ##
 753         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 754         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 755         print( $fh chr(0) x $BUCKET_SIZE );
 756
 757         return 1;
 758         } # i loop
 759
 760         return;
 761 }
 762
 763 sub _bucket_exists {
 764         ##
 765         # Check existence of single key given tag and MD5 digested key.
 766         ##
 767         my $self = shift;
 768         my ($tag, $md5) = @_;
 769         my $keys = $tag->{content};
 770
 771         ##
 772         # Iterate through buckets, looking for a key match
 773         ##
 774     BUCKET:
 775         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 776                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 777                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 778
 779                 if (!$subloc) {
 780                         ##
 781                         # Hit end of list, no match
 782                         ##
 783                         return;
 784                 }
 785
 786         if ( $md5 ne $key ) {
 787             next BUCKET;
 788         }
 789
 790         ##
 791         # Matched key -- return true
 792         ##
 793         return 1;
 794         } # i loop
 795
 796         return;
 797 }
 798
 799 sub _find_bucket_list {
 800         ##
 801         # Locate offset for bucket list, given digested key
 802         ##
 803         my $self = shift;
 804         my $md5 = shift;
 805
 806         ##
 807         # Locate offset for bucket list using digest index system
 808         ##
 809         my $ch = 0;
 810         my $tag = $self->_load_tag($self->_base_offset);
 811         if (!$tag) { return; }
 812
 813         while ($tag->{signature} ne SIG_BLIST) {
 814                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 815                 if (!$tag) { return; }
 816                 $ch++;
 817         }
 818
 819         return $tag;
 820 }
 821
 822 sub _traverse_index {
 823         ##
 824         # Scan index and recursively step into deeper levels, looking for next key.
 825         ##
 826     my ($self, $offset, $ch, $force_return_next) = @_;
 827     $force_return_next = undef unless $force_return_next;
 828
 829     local($/,$\);
 830
 831         my $tag = $self->_load_tag( $offset );
 832
 833     my $fh = $self->_fh;
 834
 835         if ($tag->{signature} ne SIG_BLIST) {
 836                 my $content = $tag->{content};
 837                 my $start;
 838                 if ($self->{return_next}) { $start = 0; }
 839                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 840
 841                 for (my $index = $start; $index < 256; $index++) {
 842                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 843                         if ($subloc) {
 844                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 845                                 if (defined($result)) { return $result; }
 846                         }
 847                 } # index loop
 848
 849                 $self->{return_next} = 1;
 850         } # tag is an index
 851
 852         elsif ($tag->{signature} eq SIG_BLIST) {
 853                 my $keys = $tag->{content};
 854                 if ($force_return_next) { $self->{return_next} = 1; }
 855
 856                 ##
 857                 # Iterate through buckets, looking for a key match
 858                 ##
 859                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 860                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 861                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 862
 863                         if (!$subloc) {
 864                                 ##
 865                                 # End of bucket list -- return to outer loop
 866                                 ##
 867                                 $self->{return_next} = 1;
 868                                 last;
 869                         }
 870                         elsif ($key eq $self->{prev_md5}) {
 871                                 ##
 872                                 # Located previous key -- return next one found
 873                                 ##
 874                                 $self->{return_next} = 1;
 875                                 next;
 876                         }
 877                         elsif ($self->{return_next}) {
 878                                 ##
 879                                 # Seek to bucket location and skip over signature
 880                                 ##
 881                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 882
 883                                 ##
 884                                 # Skip over value to get to plain key
 885                                 ##
 886                                 my $size;
 887                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 888                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 889
 890                                 ##
 891                                 # Read in plain key and return as scalar
 892                                 ##
 893                                 my $plain_key;
 894                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 895                                 if ($size) { read( $fh, $plain_key, $size); }
 896
 897                                 return $plain_key;
 898                         }
 899                 } # bucket loop
 900
 901                 $self->{return_next} = 1;
 902         } # tag is a bucket list
 903
 904         return;
 905 }
 906
 907 sub _get_next_key {
 908         ##
 909         # Locate next key, given digested previous one
 910         ##
 911     my $self = $_[0]->_get_self;
 912
 913         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 914         $self->{return_next} = 0;
 915
 916         ##
 917         # If the previous key was not specifed, start at the top and
 918         # return the first one found.
 919         ##
 920         if (!$self->{prev_md5}) {
 921                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 922                 $self->{return_next} = 1;
 923         }
 924
 925         return $self->_traverse_index( $self->_base_offset, 0 );
 926 }
 927
 928 sub lock {
 929         ##
 930         # If db locking is set, flock() the db file.  If called multiple
 931         # times before unlock(), then the same number of unlocks() must
 932         # be called before the lock is released.
 933         ##
 934     my $self = $_[0]->_get_self;
 935         my $type = $_[1];
 936     $type = LOCK_EX unless defined $type;
 937
 938         if (!defined($self->_fh)) { return; }
 939
 940         if ($self->_root->{locking}) {
 941                 if (!$self->_root->{locked}) {
 942                         flock($self->_fh, $type);
 943
 944                         # refresh end counter in case file has changed size
 945                         my @stats = stat($self->_root->{file});
 946                         $self->_root->{end} = $stats[7];
 947
 948                         # double-check file inode, in case another process
 949                         # has optimize()d our file while we were waiting.
 950                         if ($stats[1] != $self->_root->{inode}) {
 951                                 $self->_open(); # re-open
 952                                 flock($self->_fh, $type); # re-lock
 953                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 954                         }
 955                 }
 956                 $self->_root->{locked}++;
 957
 958         return 1;
 959         }
 960
 961     return;
 962 }
 963
 964 sub unlock {
 965         ##
 966         # If db locking is set, unlock the db file.  See note in lock()
 967         # regarding calling lock() multiple times.
 968         ##
 969     my $self = $_[0]->_get_self;
 970
 971         if (!defined($self->_fh)) { return; }
 972
 973         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 974                 $self->_root->{locked}--;
 975                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 976
 977         return 1;
 978         }
 979
 980     return;
 981 }
 982
 983 sub _copy_value {
 984     my $self = shift->_get_self;
 985     my ($spot, $value) = @_;
 986
 987     if ( !ref $value ) {
 988         ${$spot} = $value;
 989     }
 990     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 991         my $type = $value->_type;
 992         ${$spot} = $type eq TYPE_HASH ? {} : [];
 993         $value->_copy_node( ${$spot} );
 994     }
 995     else {
 996         my $r = Scalar::Util::reftype( $value );
 997         my $c = Scalar::Util::blessed( $value );
 998         if ( $r eq 'ARRAY' ) {
 999             ${$spot} = [ @{$value} ];
1000         }
1001         else {
1002             ${$spot} = { %{$value} };
1003         }
1004         ${$spot} = bless ${$spot}, $c
1005             if defined $c;
1006     }
1007
1008     return 1;
1009 }
1010
1011 sub _copy_node {
1012         ##
1013         # Copy single level of keys or elements to new DB handle.
1014         # Recurse for nested structures
1015         ##
1016     my $self = shift->_get_self;
1017         my ($db_temp) = @_;
1018
1019         if ($self->_type eq TYPE_HASH) {
1020                 my $key = $self->first_key();
1021                 while ($key) {
1022                         my $value = $self->get($key);
1023             $self->_copy_value( \$db_temp->{$key}, $value );
1024                         $key = $self->next_key($key);
1025                 }
1026         }
1027         else {
1028                 my $length = $self->length();
1029                 for (my $index = 0; $index < $length; $index++) {
1030                         my $value = $self->get($index);
1031             $self->_copy_value( \$db_temp->[$index], $value );
1032                 }
1033         }
1034
1035     return 1;
1036 }
1037
1038 sub export {
1039         ##
1040         # Recursively export into standard Perl hashes and arrays.
1041         ##
1042     my $self = $_[0]->_get_self;
1043
1044         my $temp;
1045         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1046         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1047
1048         $self->lock();
1049         $self->_copy_node( $temp );
1050         $self->unlock();
1051
1052         return $temp;
1053 }
1054
1055 sub import {
1056         ##
1057         # Recursively import Perl hash/array structure
1058         ##
1059     #XXX This use of ref() seems to be ok
1060         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1061
1062     my $self = $_[0]->_get_self;
1063         my $struct = $_[1];
1064
1065     #XXX This use of ref() seems to be ok
1066         if (!ref($struct)) {
1067                 ##
1068                 # struct is not a reference, so just import based on our type
1069                 ##
1070                 shift @_;
1071
1072                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1073                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1074         }
1075
1076     my $r = Scalar::Util::reftype($struct) || '';
1077         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1078                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1079         }
1080         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1081                 $self->push( @$struct );
1082         }
1083         else {
1084                 return $self->_throw_error("Cannot import: type mismatch");
1085         }
1086
1087         return 1;
1088 }
1089
1090 sub optimize {
1091         ##
1092         # Rebuild entire database into new file, then move
1093         # it back on top of original.
1094         ##
1095     my $self = $_[0]->_get_self;
1096
1097 #XXX Need to create a new test for this
1098 #       if ($self->_root->{links} > 1) {
1099 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1100 #       }
1101
1102         my $db_temp = DBM::Deep->new(
1103                 file => $self->_root->{file} . '.tmp',
1104                 type => $self->_type
1105         );
1106         if (!$db_temp) {
1107                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1108         }
1109
1110         $self->lock();
1111         $self->_copy_node( $db_temp );
1112         undef $db_temp;
1113
1114         ##
1115         # Attempt to copy user, group and permissions over to new file
1116         ##
1117         my @stats = stat($self->_fh);
1118         my $perms = $stats[2] & 07777;
1119         my $uid = $stats[4];
1120         my $gid = $stats[5];
1121         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1122         chmod( $perms, $self->_root->{file} . '.tmp' );
1123
1124     # q.v. perlport for more information on this variable
1125     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1126                 ##
1127                 # Potential race condition when optmizing on Win32 with locking.
1128                 # The Windows filesystem requires that the filehandle be closed
1129                 # before it is overwritten with rename().  This could be redone
1130                 # with a soft copy.
1131                 ##
1132                 $self->unlock();
1133                 $self->_close();
1134         }
1135
1136         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1137                 unlink $self->_root->{file} . '.tmp';
1138                 $self->unlock();
1139                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1140         }
1141
1142         $self->unlock();
1143         $self->_close();
1144         $self->_open();
1145
1146         return 1;
1147 }
1148
1149 sub clone {
1150         ##
1151         # Make copy of object and return
1152         ##
1153     my $self = $_[0]->_get_self;
1154
1155         return DBM::Deep->new(
1156                 type => $self->_type,
1157                 base_offset => $self->_base_offset,
1158                 root => $self->_root
1159         );
1160 }
1161
1162 {
1163     my %is_legal_filter = map {
1164         $_ => ~~1,
1165     } qw(
1166         store_key store_value
1167         fetch_key fetch_value
1168     );
1169
1170     sub set_filter {
1171         ##
1172         # Setup filter function for storing or fetching the key or value
1173         ##
1174         my $self = $_[0]->_get_self;
1175         my $type = lc $_[1];
1176         my $func = $_[2] ? $_[2] : undef;
1177
1178         if ( $is_legal_filter{$type} ) {
1179             $self->_root->{"filter_$type"} = $func;
1180             return 1;
1181         }
1182
1183         return;
1184     }
1185 }
1186
1187 ##
1188 # Accessor methods
1189 ##
1190
1191 sub _root {
1192         ##
1193         # Get access to the root structure
1194         ##
1195     my $self = $_[0]->_get_self;
1196         return $self->{root};
1197 }
1198
1199 sub _fh {
1200         ##
1201         # Get access to the raw fh
1202         ##
1203     #XXX It will be useful, though, when we split out HASH and ARRAY
1204     my $self = $_[0]->_get_self;
1205         return $self->_root->{fh};
1206 }
1207
1208 sub _type {
1209         ##
1210         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1211         ##
1212     my $self = $_[0]->_get_self;
1213         return $self->{type};
1214 }
1215
1216 sub _base_offset {
1217         ##
1218         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1219         ##
1220     my $self = $_[0]->_get_self;
1221         return $self->{base_offset};
1222 }
1223
1224 sub error {
1225         ##
1226         # Get last error string, or undef if no error
1227         ##
1228         return $_[0]
1229         ? ( $_[0]->_get_self->{root}->{error} or undef )
1230         : $@;
1231 }
1232
1233 ##
1234 # Utility methods
1235 ##
1236
1237 sub _throw_error {
1238         ##
1239         # Store error string in self
1240         ##
1241         my $error_text = $_[1];
1242
1243     if ( Scalar::Util::blessed $_[0] ) {
1244         my $self = $_[0]->_get_self;
1245         $self->_root->{error} = $error_text;
1246
1247         unless ($self->_root->{debug}) {
1248             die "DBM::Deep: $error_text\n";
1249         }
1250
1251         warn "DBM::Deep: $error_text\n";
1252         return;
1253     }
1254     else {
1255         die "DBM::Deep: $error_text\n";
1256     }
1257 }
1258
1259 sub clear_error {
1260         ##
1261         # Clear error state
1262         ##
1263     my $self = $_[0]->_get_self;
1264
1265         undef $self->_root->{error};
1266 }
1267
1268 sub _precalc_sizes {
1269         ##
1270         # Precalculate index, bucket and bucket list sizes
1271         ##
1272
1273     #XXX I don't like this ...
1274     set_pack() unless defined $LONG_SIZE;
1275
1276         $INDEX_SIZE = 256 * $LONG_SIZE;
1277         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1278         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1279 }
1280
1281 sub set_pack {
1282         ##
1283         # Set pack/unpack modes (see file header for more)
1284         ##
1285     my ($long_s, $long_p, $data_s, $data_p) = @_;
1286
1287     $LONG_SIZE = $long_s ? $long_s : 4;
1288     $LONG_PACK = $long_p ? $long_p : 'N';
1289
1290     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1291     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1292
1293         _precalc_sizes();
1294 }
1295
1296 sub set_digest {
1297         ##
1298         # Set key digest function (default is MD5)
1299         ##
1300     my ($digest_func, $hash_size) = @_;
1301
1302     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1303     $HASH_SIZE = $hash_size ? $hash_size : 16;
1304
1305         _precalc_sizes();
1306 }
1307
1308 sub _is_writable {
1309     my $fh = shift;
1310     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1311 }
1312
1313 #sub _is_readable {
1314 #    my $fh = shift;
1315 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1316 #}
1317
1318 ##
1319 # tie() methods (hashes and arrays)
1320 ##
1321
1322 sub STORE {
1323         ##
1324         # Store single hash key/value or array element in database.
1325         ##
1326     my $self = $_[0]->_get_self;
1327         my $key = $_[1];
1328
1329     local($/,$\);
1330
1331     # User may be storing a hash, in which case we do not want it run
1332     # through the filtering system
1333         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1334         ? $self->_root->{filter_store_value}->($_[2])
1335         : $_[2];
1336
1337         my $md5 = $DIGEST_FUNC->($key);
1338
1339         ##
1340         # Make sure file is open
1341         ##
1342         if (!defined($self->_fh) && !$self->_open()) {
1343                 return;
1344         }
1345
1346     if ( $^O ne 'MSWin32' && !_is_writable( $self->_fh ) ) {
1347         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1348     }
1349
1350         ##
1351         # Request exclusive lock for writing
1352         ##
1353         $self->lock( LOCK_EX );
1354
1355         my $fh = $self->_fh;
1356
1357         ##
1358         # Locate offset for bucket list using digest index system
1359         ##
1360         my $tag = $self->_load_tag($self->_base_offset);
1361         if (!$tag) {
1362                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1363         }
1364
1365         my $ch = 0;
1366         while ($tag->{signature} ne SIG_BLIST) {
1367                 my $num = ord(substr($md5, $ch, 1));
1368
1369         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1370                 my $new_tag = $self->_index_lookup($tag, $num);
1371
1372                 if (!$new_tag) {
1373                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1374                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1375
1376                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1377
1378                         $tag->{ref_loc} = $ref_loc;
1379                         $tag->{ch} = $ch;
1380
1381                         last;
1382                 }
1383                 else {
1384                         $tag = $new_tag;
1385
1386                         $tag->{ref_loc} = $ref_loc;
1387                         $tag->{ch} = $ch;
1388                 }
1389                 $ch++;
1390         }
1391
1392         ##
1393         # Add key/value to bucket list
1394         ##
1395         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1396
1397         $self->unlock();
1398
1399         return $result;
1400 }
1401
1402 sub FETCH {
1403         ##
1404         # Fetch single value or element given plain key or array index
1405         ##
1406     my $self = shift->_get_self;
1407     my $key = shift;
1408
1409         ##
1410         # Make sure file is open
1411         ##
1412         if (!defined($self->_fh)) { $self->_open(); }
1413
1414         my $md5 = $DIGEST_FUNC->($key);
1415
1416         ##
1417         # Request shared lock for reading
1418         ##
1419         $self->lock( LOCK_SH );
1420
1421         my $tag = $self->_find_bucket_list( $md5 );
1422         if (!$tag) {
1423                 $self->unlock();
1424                 return;
1425         }
1426
1427         ##
1428         # Get value from bucket list
1429         ##
1430         my $result = $self->_get_bucket_value( $tag, $md5 );
1431
1432         $self->unlock();
1433
1434     #XXX What is ref() checking here?
1435     #YYY Filters only apply on scalar values, so the ref check is making
1436     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1437         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1438         ? $self->_root->{filter_fetch_value}->($result)
1439         : $result;
1440 }
1441
1442 sub DELETE {
1443         ##
1444         # Delete single key/value pair or element given plain key or array index
1445         ##
1446     my $self = $_[0]->_get_self;
1447         my $key = $_[1];
1448
1449         my $md5 = $DIGEST_FUNC->($key);
1450
1451         ##
1452         # Make sure file is open
1453         ##
1454         if (!defined($self->_fh)) { $self->_open(); }
1455
1456         ##
1457         # Request exclusive lock for writing
1458         ##
1459         $self->lock( LOCK_EX );
1460
1461         my $tag = $self->_find_bucket_list( $md5 );
1462         if (!$tag) {
1463                 $self->unlock();
1464                 return;
1465         }
1466
1467         ##
1468         # Delete bucket
1469         ##
1470     my $value = $self->_get_bucket_value( $tag, $md5 );
1471         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1472         $value = $self->_root->{filter_fetch_value}->($value);
1473     }
1474
1475         my $result = $self->_delete_bucket( $tag, $md5 );
1476
1477         ##
1478         # If this object is an array and the key deleted was on the end of the stack,
1479         # decrement the length variable.
1480         ##
1481
1482         $self->unlock();
1483
1484         return $value;
1485 }
1486
1487 sub EXISTS {
1488         ##
1489         # Check if a single key or element exists given plain key or array index
1490         ##
1491     my $self = $_[0]->_get_self;
1492         my $key = $_[1];
1493
1494         my $md5 = $DIGEST_FUNC->($key);
1495
1496         ##
1497         # Make sure file is open
1498         ##
1499         if (!defined($self->_fh)) { $self->_open(); }
1500
1501         ##
1502         # Request shared lock for reading
1503         ##
1504         $self->lock( LOCK_SH );
1505
1506         my $tag = $self->_find_bucket_list( $md5 );
1507
1508         ##
1509         # For some reason, the built-in exists() function returns '' for false
1510         ##
1511         if (!$tag) {
1512                 $self->unlock();
1513                 return '';
1514         }
1515
1516         ##
1517         # Check if bucket exists and return 1 or ''
1518         ##
1519         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1520
1521         $self->unlock();
1522
1523         return $result;
1524 }
1525
1526 sub CLEAR {
1527         ##
1528         # Clear all keys from hash, or all elements from array.
1529         ##
1530     my $self = $_[0]->_get_self;
1531
1532         ##
1533         # Make sure file is open
1534         ##
1535         if (!defined($self->_fh)) { $self->_open(); }
1536
1537         ##
1538         # Request exclusive lock for writing
1539         ##
1540         $self->lock( LOCK_EX );
1541
1542     my $fh = $self->_fh;
1543
1544         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1545         if (eof $fh) {
1546                 $self->unlock();
1547                 return;
1548         }
1549
1550         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1551
1552         $self->unlock();
1553
1554         return 1;
1555 }
1556
1557 ##
1558 # Public method aliases
1559 ##
1560 sub put { (shift)->STORE( @_ ) }
1561 sub store { (shift)->STORE( @_ ) }
1562 sub get { (shift)->FETCH( @_ ) }
1563 sub fetch { (shift)->FETCH( @_ ) }
1564 sub delete { (shift)->DELETE( @_ ) }
1565 sub exists { (shift)->EXISTS( @_ ) }
1566 sub clear { (shift)->CLEAR( @_ ) }
1567
1568 package DBM::Deep::_::Root;
1569
1570 sub new {
1571     my $class = shift;
1572     my ($args) = @_;
1573
1574     my $self = bless {
1575         file => undef,
1576         fh => undef,
1577         file_offset => 0,
1578         end => 0,
1579         autoflush => undef,
1580         locking => undef,
1581         debug => undef,
1582         filter_store_key => undef,
1583         filter_store_value => undef,
1584         filter_fetch_key => undef,
1585         filter_fetch_value => undef,
1586         autobless => undef,
1587         locked => 0,
1588         %$args,
1589     }, $class;
1590
1591     if ( $self->{fh} && !$self->{file_offset} ) {
1592         $self->{file_offset} = tell( $self->{fh} );
1593     }
1594
1595     return $self;
1596 }
1597
1598 sub DESTROY {
1599     my $self = shift;
1600     return unless $self;
1601
1602     close $self->{fh} if $self->{fh};
1603
1604     return;
1605 }
1606
1607 1;
1608
1609 __END__
1610
1611 =head1 NAME
1612
1613 DBM::Deep - A pure perl multi-level hash/array DBM
1614
1615 =head1 SYNOPSIS
1616
1617   use DBM::Deep;
1618   my $db = DBM::Deep->new( "foo.db" );
1619
1620   $db->{key} = 'value'; # tie() style
1621   print $db->{key};
1622
1623   $db->put('key' => 'value'); # OO style
1624   print $db->get('key');
1625
1626   # true multi-level support
1627   $db->{my_complex} = [
1628         'hello', { perl => 'rules' },
1629         42, 99,
1630   ];
1631
1632 =head1 DESCRIPTION
1633
1634 A unique flat-file database module, written in pure perl.  True
1635 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1636 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1637 handle millions of keys and unlimited hash levels without significant
1638 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1639 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1640 Mac OS X and Windows.
1641
1642 =head1 INSTALLATION
1643
1644 Hopefully you are using Perl's excellent CPAN module, which will download
1645 and install the module for you.  If not, get the tarball, and run these
1646 commands:
1647
1648         tar zxf DBM-Deep-*
1649         cd DBM-Deep-*
1650         perl Makefile.PL
1651         make
1652         make test
1653         make install
1654
1655 =head1 SETUP
1656
1657 Construction can be done OO-style (which is the recommended way), or using
1658 Perl's tie() function.  Both are examined here.
1659
1660 =head2 OO CONSTRUCTION
1661
1662 The recommended way to construct a DBM::Deep object is to use the new()
1663 method, which gets you a blessed, tied hash or array reference.
1664
1665         my $db = DBM::Deep->new( "foo.db" );
1666
1667 This opens a new database handle, mapped to the file "foo.db".  If this
1668 file does not exist, it will automatically be created.  DB files are
1669 opened in "r+" (read/write) mode, and the type of object returned is a
1670 hash, unless otherwise specified (see L<OPTIONS> below).
1671
1672 You can pass a number of options to the constructor to specify things like
1673 locking, autoflush, etc.  This is done by passing an inline hash:
1674
1675         my $db = DBM::Deep->new(
1676                 file => "foo.db",
1677                 locking => 1,
1678                 autoflush => 1
1679         );
1680
1681 Notice that the filename is now specified I<inside> the hash with
1682 the "file" parameter, as opposed to being the sole argument to the
1683 constructor.  This is required if any options are specified.
1684 See L<OPTIONS> below for the complete list.
1685
1686
1687
1688 You can also start with an array instead of a hash.  For this, you must
1689 specify the C<type> parameter:
1690
1691         my $db = DBM::Deep->new(
1692                 file => "foo.db",
1693                 type => DBM::Deep->TYPE_ARRAY
1694         );
1695
1696 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1697 a new DB file.  If you create a DBM::Deep object with an existing file, the
1698 C<type> will be loaded from the file header, and an error will be thrown if
1699 the wrong type is passed in.
1700
1701 =head2 TIE CONSTRUCTION
1702
1703 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1704 tie() function.  The object returned from tie() can be used to call methods,
1705 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1706 file (as expected with most tie'd objects).
1707
1708         my %hash;
1709         my $db = tie %hash, "DBM::Deep", "foo.db";
1710
1711         my @array;
1712         my $db = tie @array, "DBM::Deep", "bar.db";
1713
1714 As with the OO constructor, you can replace the DB filename parameter with
1715 a hash containing one or more options (see L<OPTIONS> just below for the
1716 complete list).
1717
1718         tie %hash, "DBM::Deep", {
1719                 file => "foo.db",
1720                 locking => 1,
1721                 autoflush => 1
1722         };
1723
1724 =head2 OPTIONS
1725
1726 There are a number of options that can be passed in when constructing your
1727 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1728
1729 =over
1730
1731 =item * file
1732
1733 Filename of the DB file to link the handle to.  You can pass a full absolute
1734 filesystem path, partial path, or a plain filename if the file is in the
1735 current working directory.  This is a required parameter (though q.v. fh).
1736
1737 =item * fh
1738
1739 If you want, you can pass in the fh instead of the file. This is most useful for doing
1740 something like:
1741
1742   my $db = DBM::Deep->new( { fh => \*DATA } );
1743
1744 You are responsible for making sure that the fh has been opened appropriately for your
1745 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1746 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1747 needs to read from the fh.
1748
1749 =item * file_offset
1750
1751 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1752 not need to set this. However, it's there if you want it.
1753
1754 If you pass in fh and do not set this, it will be set appropriately.
1755
1756 =item * type
1757
1758 This parameter specifies what type of object to create, a hash or array.  Use
1759 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1760 This only takes effect when beginning a new file.  This is an optional
1761 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1762
1763 =item * locking
1764
1765 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1766 function to lock the database in exclusive mode for writes, and shared mode for
1767 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1768 any child hashes or arrays> that use the same DB file.  This is an optional
1769 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1770
1771 =item * autoflush
1772
1773 Specifies whether autoflush is to be enabled on the underlying filehandle.
1774 This obviously slows down write operations, but is required if you may have
1775 multiple processes accessing the same DB file (also consider enable I<locking>).
1776 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1777 (disabled).
1778
1779 =item * autobless
1780
1781 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1782 restore them when fetched.  This is an B<experimental> feature, and does have
1783 side-effects.  Basically, when hashes are re-blessed into their original
1784 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1785 able to call any DBM::Deep methods on them.  You have been warned.
1786 This is an optional parameter, and defaults to 0 (disabled).
1787
1788 =item * filter_*
1789
1790 See L<FILTERS> below.
1791
1792 =item * debug
1793
1794 Setting I<debug> mode will make all errors non-fatal, dump them out to
1795 STDERR, and continue on.  This is for debugging purposes only, and probably
1796 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1797
1798 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1799
1800 =back
1801
1802 =head1 TIE INTERFACE
1803
1804 With DBM::Deep you can access your databases using Perl's standard hash/array
1805 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1806 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1807 to the right place -- the DB file.  This has nothing to do with the
1808 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1809 using regular hashes and arrays, rather than calling functions like C<get()>
1810 and C<put()> (although those work too).  It is entirely up to you how to want
1811 to access your databases.
1812
1813 =head2 HASHES
1814
1815 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1816 or even nested hashes (or arrays) using standard Perl syntax:
1817
1818         my $db = DBM::Deep->new( "foo.db" );
1819
1820         $db->{mykey} = "myvalue";
1821         $db->{myhash} = {};
1822         $db->{myhash}->{subkey} = "subvalue";
1823
1824         print $db->{myhash}->{subkey} . "\n";
1825
1826 You can even step through hash keys using the normal Perl C<keys()> function:
1827
1828         foreach my $key (keys %$db) {
1829                 print "$key: " . $db->{$key} . "\n";
1830         }
1831
1832 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1833 pushes them onto an array, all before the loop even begins.  If you have an
1834 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1835 Perl's C<each()> function, which pulls keys/values one at a time, using very
1836 little memory:
1837
1838         while (my ($key, $value) = each %$db) {
1839                 print "$key: $value\n";
1840         }
1841
1842 Please note that when using C<each()>, you should always pass a direct
1843 hash reference, not a lookup.  Meaning, you should B<never> do this:
1844
1845         # NEVER DO THIS
1846         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1847
1848 This causes an infinite loop, because for each iteration, Perl is calling
1849 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1850 it effectively keeps returning the first key over and over again. Instead,
1851 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1852
1853 =head2 ARRAYS
1854
1855 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1856 reference.  This includes inserting, removing and manipulating elements,
1857 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1858 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1859 or simply be a nested array reference inside a hash.  Example:
1860
1861         my $db = DBM::Deep->new(
1862                 file => "foo-array.db",
1863                 type => DBM::Deep->TYPE_ARRAY
1864         );
1865
1866         $db->[0] = "foo";
1867         push @$db, "bar", "baz";
1868         unshift @$db, "bah";
1869
1870         my $last_elem = pop @$db; # baz
1871         my $first_elem = shift @$db; # bah
1872         my $second_elem = $db->[1]; # bar
1873
1874         my $num_elements = scalar @$db;
1875
1876 =head1 OO INTERFACE
1877
1878 In addition to the I<tie()> interface, you can also use a standard OO interface
1879 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1880 array) has its own methods, but both types share the following common methods:
1881 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1882
1883 =over
1884
1885 =item * new() / clone()
1886
1887 These are the constructor and copy-functions.
1888
1889 =item * put() / store()
1890
1891 Stores a new hash key/value pair, or sets an array element value.  Takes two
1892 arguments, the hash key or array index, and the new value.  The value can be
1893 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1894
1895         $db->put("foo", "bar"); # for hashes
1896         $db->put(1, "bar"); # for arrays
1897
1898 =item * get() / fetch()
1899
1900 Fetches the value of a hash key or array element.  Takes one argument: the hash
1901 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1902 data type stored.
1903
1904         my $value = $db->get("foo"); # for hashes
1905         my $value = $db->get(1); # for arrays
1906
1907 =item * exists()
1908
1909 Checks if a hash key or array index exists.  Takes one argument: the hash key
1910 or array index.  Returns true if it exists, false if not.
1911
1912         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1913         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1914
1915 =item * delete()
1916
1917 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1918 key or array index.  Returns true on success, false if not found.  For arrays,
1919 the remaining elements located after the deleted element are NOT moved over.
1920 The deleted element is essentially just undefined, which is exactly how Perl's
1921 internal arrays work.  Please note that the space occupied by the deleted
1922 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1923 below for details and workarounds.
1924
1925         $db->delete("foo"); # for hashes
1926         $db->delete(1); # for arrays
1927
1928 =item * clear()
1929
1930 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1931 value.  Please note that the space occupied by the deleted keys/values or
1932 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1933 details and workarounds.
1934
1935         $db->clear(); # hashes or arrays
1936
1937 =item * lock() / unlock()
1938
1939 q.v. Locking.
1940
1941 =item * optimize()
1942
1943 Recover lost disk space.
1944
1945 =item * import() / export()
1946
1947 Data going in and out.
1948
1949 =item * set_digest() / set_pack() / set_filter()
1950
1951 q.v. adjusting the interal parameters.
1952
1953 =item * error() / clear_error()
1954
1955 Error handling methods. These are deprecated and will be removed in 1.00.
1956 .
1957 =back
1958
1959 =head2 HASHES
1960
1961 For hashes, DBM::Deep supports all the common methods described above, and the
1962 following additional methods: C<first_key()> and C<next_key()>.
1963
1964 =over
1965
1966 =item * first_key()
1967
1968 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1969 fetched in an undefined order (which appears random).  Takes no arguments,
1970 returns the key as a scalar value.
1971
1972         my $key = $db->first_key();
1973
1974 =item * next_key()
1975
1976 Returns the "next" key in the hash, given the previous one as the sole argument.
1977 Returns undef if there are no more keys to be fetched.
1978
1979         $key = $db->next_key($key);
1980
1981 =back
1982
1983 Here are some examples of using hashes:
1984
1985         my $db = DBM::Deep->new( "foo.db" );
1986
1987         $db->put("foo", "bar");
1988         print "foo: " . $db->get("foo") . "\n";
1989
1990         $db->put("baz", {}); # new child hash ref
1991         $db->get("baz")->put("buz", "biz");
1992         print "buz: " . $db->get("baz")->get("buz") . "\n";
1993
1994         my $key = $db->first_key();
1995         while ($key) {
1996                 print "$key: " . $db->get($key) . "\n";
1997                 $key = $db->next_key($key);
1998         }
1999
2000         if ($db->exists("foo")) { $db->delete("foo"); }
2001
2002 =head2 ARRAYS
2003
2004 For arrays, DBM::Deep supports all the common methods described above, and the
2005 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2006 C<unshift()> and C<splice()>.
2007
2008 =over
2009
2010 =item * length()
2011
2012 Returns the number of elements in the array.  Takes no arguments.
2013
2014         my $len = $db->length();
2015
2016 =item * push()
2017
2018 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2019 refs or array refs.  No return value.
2020
2021         $db->push("foo", "bar", {});
2022
2023 =item * pop()
2024
2025 Fetches the last element in the array, and deletes it.  Takes no arguments.
2026 Returns undef if array is empty.  Returns the element value.
2027
2028         my $elem = $db->pop();
2029
2030 =item * shift()
2031
2032 Fetches the first element in the array, deletes it, then shifts all the
2033 remaining elements over to take up the space.  Returns the element value.  This
2034 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2035 details.
2036
2037         my $elem = $db->shift();
2038
2039 =item * unshift()
2040
2041 Inserts one or more elements onto the beginning of the array, shifting all
2042 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2043 No return value.  This method is not recommended with large arrays -- see
2044 <LARGE ARRAYS> below for details.
2045
2046         $db->unshift("foo", "bar", {});
2047
2048 =item * splice()
2049
2050 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2051 -f splice> for usage -- it is too complicated to document here.  This method is
2052 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2053
2054 =back
2055
2056 Here are some examples of using arrays:
2057
2058         my $db = DBM::Deep->new(
2059                 file => "foo.db",
2060                 type => DBM::Deep->TYPE_ARRAY
2061         );
2062
2063         $db->push("bar", "baz");
2064         $db->unshift("foo");
2065         $db->put(3, "buz");
2066
2067         my $len = $db->length();
2068         print "length: $len\n"; # 4
2069
2070         for (my $k=0; $k<$len; $k++) {
2071                 print "$k: " . $db->get($k) . "\n";
2072         }
2073
2074         $db->splice(1, 2, "biz", "baf");
2075
2076         while (my $elem = shift @$db) {
2077                 print "shifted: $elem\n";
2078         }
2079
2080 =head1 LOCKING
2081
2082 Enable automatic file locking by passing a true value to the C<locking>
2083 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2084
2085         my $db = DBM::Deep->new(
2086                 file => "foo.db",
2087                 locking => 1
2088         );
2089
2090 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2091 mode for writes, and shared mode for reads.  This is required if you have
2092 multiple processes accessing the same database file, to avoid file corruption.
2093 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2094 NFS> below for more.
2095
2096 =head2 EXPLICIT LOCKING
2097
2098 You can explicitly lock a database, so it remains locked for multiple
2099 transactions.  This is done by calling the C<lock()> method, and passing an
2100 optional lock mode argument (defaults to exclusive mode).  This is particularly
2101 useful for things like counters, where the current value needs to be fetched,
2102 then incremented, then stored again.
2103
2104         $db->lock();
2105         my $counter = $db->get("counter");
2106         $counter++;
2107         $db->put("counter", $counter);
2108         $db->unlock();
2109
2110         # or...
2111
2112         $db->lock();
2113         $db->{counter}++;
2114         $db->unlock();
2115
2116 You can pass C<lock()> an optional argument, which specifies which mode to use
2117 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2118 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2119 same as the constants defined in Perl's C<Fcntl> module.
2120
2121         $db->lock( DBM::Deep->LOCK_SH );
2122         # something here
2123         $db->unlock();
2124
2125 =head1 IMPORTING/EXPORTING
2126
2127 You can import existing complex structures by calling the C<import()> method,
2128 and export an entire database into an in-memory structure using the C<export()>
2129 method.  Both are examined here.
2130
2131 =head2 IMPORTING
2132
2133 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2134 walking the structure and adding keys/elements to the database as you go,
2135 simply pass a reference to the C<import()> method.  This recursively adds
2136 everything to an existing DBM::Deep object for you.  Here is an example:
2137
2138         my $struct = {
2139                 key1 => "value1",
2140                 key2 => "value2",
2141                 array1 => [ "elem0", "elem1", "elem2" ],
2142                 hash1 => {
2143                         subkey1 => "subvalue1",
2144                         subkey2 => "subvalue2"
2145                 }
2146         };
2147
2148         my $db = DBM::Deep->new( "foo.db" );
2149         $db->import( $struct );
2150
2151         print $db->{key1} . "\n"; # prints "value1"
2152
2153 This recursively imports the entire C<$struct> object into C<$db>, including
2154 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2155 keys are merged with the existing ones, replacing if they already exist.
2156 The C<import()> method can be called on any database level (not just the base
2157 level), and works with both hash and array DB types.
2158
2159 B<Note:> Make sure your existing structure has no circular references in it.
2160 These will cause an infinite loop when importing.
2161
2162 =head2 EXPORTING
2163
2164 Calling the C<export()> method on an existing DBM::Deep object will return
2165 a reference to a new in-memory copy of the database.  The export is done
2166 recursively, so all nested hashes/arrays are all exported to standard Perl
2167 objects.  Here is an example:
2168
2169         my $db = DBM::Deep->new( "foo.db" );
2170
2171         $db->{key1} = "value1";
2172         $db->{key2} = "value2";
2173         $db->{hash1} = {};
2174         $db->{hash1}->{subkey1} = "subvalue1";
2175         $db->{hash1}->{subkey2} = "subvalue2";
2176
2177         my $struct = $db->export();
2178
2179         print $struct->{key1} . "\n"; # prints "value1"
2180
2181 This makes a complete copy of the database in memory, and returns a reference
2182 to it.  The C<export()> method can be called on any database level (not just
2183 the base level), and works with both hash and array DB types.  Be careful of
2184 large databases -- you can store a lot more data in a DBM::Deep object than an
2185 in-memory Perl structure.
2186
2187 B<Note:> Make sure your database has no circular references in it.
2188 These will cause an infinite loop when exporting.
2189
2190 =head1 FILTERS
2191
2192 DBM::Deep has a number of hooks where you can specify your own Perl function
2193 to perform filtering on incoming or outgoing data.  This is a perfect
2194 way to extend the engine, and implement things like real-time compression or
2195 encryption.  Filtering applies to the base DB level, and all child hashes /
2196 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2197 constructed, or by calling the C<set_filter()> method at any time.  There are
2198 four available filter hooks, described below:
2199
2200 =over
2201
2202 =item * filter_store_key
2203
2204 This filter is called whenever a hash key is stored.  It
2205 is passed the incoming key, and expected to return a transformed key.
2206
2207 =item * filter_store_value
2208
2209 This filter is called whenever a hash key or array element is stored.  It
2210 is passed the incoming value, and expected to return a transformed value.
2211
2212 =item * filter_fetch_key
2213
2214 This filter is called whenever a hash key is fetched (i.e. via
2215 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2216 and expected to return the plain key.
2217
2218 =item * filter_fetch_value
2219
2220 This filter is called whenever a hash key or array element is fetched.
2221 It is passed the transformed value, and expected to return the plain value.
2222
2223 =back
2224
2225 Here are the two ways to setup a filter hook:
2226
2227         my $db = DBM::Deep->new(
2228                 file => "foo.db",
2229                 filter_store_value => \&my_filter_store,
2230                 filter_fetch_value => \&my_filter_fetch
2231         );
2232
2233         # or...
2234
2235         $db->set_filter( "filter_store_value", \&my_filter_store );
2236         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2237
2238 Your filter function will be called only when dealing with SCALAR keys or
2239 values.  When nested hashes and arrays are being stored/fetched, filtering
2240 is bypassed.  Filters are called as static functions, passed a single SCALAR
2241 argument, and expected to return a single SCALAR value.  If you want to
2242 remove a filter, set the function reference to C<undef>:
2243
2244         $db->set_filter( "filter_store_value", undef );
2245
2246 =head2 REAL-TIME ENCRYPTION EXAMPLE
2247
2248 Here is a working example that uses the I<Crypt::Blowfish> module to
2249 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2250 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2251 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2252
2253         use DBM::Deep;
2254         use Crypt::Blowfish;
2255         use Crypt::CBC;
2256
2257         my $cipher = Crypt::CBC->new({
2258                 'key'             => 'my secret key',
2259                 'cipher'          => 'Blowfish',
2260                 'iv'              => '$KJh#(}q',
2261                 'regenerate_key'  => 0,
2262                 'padding'         => 'space',
2263                 'prepend_iv'      => 0
2264         });
2265
2266         my $db = DBM::Deep->new(
2267                 file => "foo-encrypt.db",
2268                 filter_store_key => \&my_encrypt,
2269                 filter_store_value => \&my_encrypt,
2270                 filter_fetch_key => \&my_decrypt,
2271                 filter_fetch_value => \&my_decrypt,
2272         );
2273
2274         $db->{key1} = "value1";
2275         $db->{key2} = "value2";
2276         print "key1: " . $db->{key1} . "\n";
2277         print "key2: " . $db->{key2} . "\n";
2278
2279         undef $db;
2280         exit;
2281
2282         sub my_encrypt {
2283                 return $cipher->encrypt( $_[0] );
2284         }
2285         sub my_decrypt {
2286                 return $cipher->decrypt( $_[0] );
2287         }
2288
2289 =head2 REAL-TIME COMPRESSION EXAMPLE
2290
2291 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2292 compression / decompression of keys & values with DBM::Deep Filters.
2293 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2294 more on I<Compress::Zlib>.
2295
2296         use DBM::Deep;
2297         use Compress::Zlib;
2298
2299         my $db = DBM::Deep->new(
2300                 file => "foo-compress.db",
2301                 filter_store_key => \&my_compress,
2302                 filter_store_value => \&my_compress,
2303                 filter_fetch_key => \&my_decompress,
2304                 filter_fetch_value => \&my_decompress,
2305         );
2306
2307         $db->{key1} = "value1";
2308         $db->{key2} = "value2";
2309         print "key1: " . $db->{key1} . "\n";
2310         print "key2: " . $db->{key2} . "\n";
2311
2312         undef $db;
2313         exit;
2314
2315         sub my_compress {
2316                 return Compress::Zlib::memGzip( $_[0] ) ;
2317         }
2318         sub my_decompress {
2319                 return Compress::Zlib::memGunzip( $_[0] ) ;
2320         }
2321
2322 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2323 actually numerical index numbers, and are not filtered.
2324
2325 =head1 ERROR HANDLING
2326
2327 Most DBM::Deep methods return a true value for success, and call die() on
2328 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2329 actual error message is stored in an internal scalar, which can be fetched by
2330 calling the C<error()> method.
2331
2332         my $db = DBM::Deep->new( "foo.db" ); # create hash
2333         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2334
2335     print $@;           # prints error message
2336         print $db->error(); # prints error message
2337
2338 You can then call C<clear_error()> to clear the current error state.
2339
2340         $db->clear_error();
2341
2342 If you set the C<debug> option to true when creating your DBM::Deep object,
2343 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2344 be used for debugging purposes and not production work. DBM::Deep expects errors
2345 to be thrown, not propagated back up the stack.
2346
2347 B<NOTE>: error() and clear_error() are considered deprecated and I<will> be removed
2348 in 1.00. Please don't use them. Instead, wrap all your functions with in eval-blocks.
2349
2350 =head1 LARGEFILE SUPPORT
2351
2352 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2353 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2354 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2355 by calling the static C<set_pack()> method before you do anything else.
2356
2357         DBM::Deep::set_pack(8, 'Q');
2358
2359 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2360 instead of 32-bit longs.  After setting these values your DB files have a
2361 theoretical maximum size of 16 XB (exabytes).
2362
2363 B<Note:> Changing these values will B<NOT> work for existing database files.
2364 Only change this for new files, and make sure it stays set consistently
2365 throughout the file's life.  If you do set these values, you can no longer
2366 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2367 back to 32-bit mode.
2368
2369 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2370 only a 32-bit Perl.  However, I have received user reports that this does
2371 indeed work!
2372
2373 =head1 LOW-LEVEL ACCESS
2374
2375 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2376 you can call the C<_fh()> method, which returns the handle:
2377
2378         my $fh = $db->_fh();
2379
2380 This method can be called on the root level of the datbase, or any child
2381 hashes or arrays.  All levels share a I<root> structure, which contains things
2382 like the filehandle, a reference counter, and all the options specified
2383 when you created the object.  You can get access to this root structure by
2384 calling the C<root()> method.
2385
2386         my $root = $db->_root();
2387
2388 This is useful for changing options after the object has already been created,
2389 such as enabling/disabling locking, or debug modes.  You can also
2390 store your own temporary user data in this structure (be wary of name
2391 collision), which is then accessible from any child hash or array.
2392
2393 =head1 CUSTOM DIGEST ALGORITHM
2394
2395 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2396 keys.  However you can override this, and use another algorithm (such as SHA-256)
2397 or even write your own.  But please note that DBM::Deep currently expects zero
2398 collisions, so your algorithm has to be I<perfect>, so to speak.
2399 Collision detection may be introduced in a later version.
2400
2401
2402
2403 You can specify a custom digest algorithm by calling the static C<set_digest()>
2404 function, passing a reference to a subroutine, and the length of the algorithm's
2405 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2406 objects.  Here is a working example that uses a 256-bit hash from the
2407 I<Digest::SHA256> module.  Please see
2408 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2409
2410         use DBM::Deep;
2411         use Digest::SHA256;
2412
2413         my $context = Digest::SHA256::new(256);
2414
2415         DBM::Deep::set_digest( \&my_digest, 32 );
2416
2417         my $db = DBM::Deep->new( "foo-sha.db" );
2418
2419         $db->{key1} = "value1";
2420         $db->{key2} = "value2";
2421         print "key1: " . $db->{key1} . "\n";
2422         print "key2: " . $db->{key2} . "\n";
2423
2424         undef $db;
2425         exit;
2426
2427         sub my_digest {
2428                 return substr( $context->hash($_[0]), 0, 32 );
2429         }
2430
2431 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2432 of bytes you specify in the C<set_digest()> function (in this case 32).
2433
2434 =head1 CIRCULAR REFERENCES
2435
2436 DBM::Deep has B<experimental> support for circular references.  Meaning you
2437 can have a nested hash key or array element that points to a parent object.
2438 This relationship is stored in the DB file, and is preserved between sessions.
2439 Here is an example:
2440
2441         my $db = DBM::Deep->new( "foo.db" );
2442
2443         $db->{foo} = "bar";
2444         $db->{circle} = $db; # ref to self
2445
2446         print $db->{foo} . "\n"; # prints "foo"
2447         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2448
2449 One catch is, passing the object to a function that recursively walks the
2450 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2451 C<export()> methods) will result in an infinite loop.  The other catch is,
2452 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2453 or C<next_key()> methods), you will get the I<target object's key>, not the
2454 ref's key.  This gets even more interesting with the above example, where
2455 the I<circle> key points to the base DB object, which technically doesn't
2456 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2457 special case.
2458
2459 =head1 CAVEATS / ISSUES / BUGS
2460
2461 This section describes all the known issues with DBM::Deep.  It you have found
2462 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2463
2464 =head2 UNUSED SPACE RECOVERY
2465
2466 One major caveat with DBM::Deep is that space occupied by existing keys and
2467 values is not recovered when they are deleted.  Meaning if you keep deleting
2468 and adding new keys, your file will continuously grow.  I am working on this,
2469 but in the meantime you can call the built-in C<optimize()> method from time to
2470 time (perhaps in a crontab or something) to recover all your unused space.
2471
2472         $db->optimize(); # returns true on success
2473
2474 This rebuilds the ENTIRE database into a new file, then moves it on top of
2475 the original.  The new file will have no unused space, thus it will take up as
2476 little disk space as possible.  Please note that this operation can take
2477 a long time for large files, and you need enough disk space to temporarily hold
2478 2 copies of your DB file.  The temporary file is created in the same directory
2479 as the original, named with a ".tmp" extension, and is deleted when the
2480 operation completes.  Oh, and if locking is enabled, the DB is automatically
2481 locked for the entire duration of the copy.
2482
2483 B<WARNING:> Only call optimize() on the top-level node of the database, and
2484 make sure there are no child references lying around.  DBM::Deep keeps a reference
2485 counter, and if it is greater than 1, optimize() will abort and return undef.
2486
2487 =head2 FILE CORRUPTION
2488
2489 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2490 for a 32-bit signature when opened, but other corruption in files can cause
2491 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2492 stuck in an infinite loop depending on the level of corruption.  File write
2493 operations are not checked for failure (for speed), so if you happen to run
2494 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2495 be addressed in a later version of DBM::Deep.
2496
2497 =head2 DB OVER NFS
2498
2499 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2500 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2501 about setting up your NFS server with a locking daemon, then using lockf() to
2502 lock your files, but your mileage may vary there as well.  From what I
2503 understand, there is no real way to do it.  However, if you need access to the
2504 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2505 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2506
2507 =head2 COPYING OBJECTS
2508
2509 Beware of copying tied objects in Perl.  Very strange things can happen.
2510 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2511 returns a new, blessed, tied hash or array to the same level in the DB.
2512
2513         my $copy = $db->clone();
2514
2515 B<Note>: Since clone() here is cloning the object, not the database location, any
2516 modifications to either $db or $copy will be visible in both.
2517
2518 =head2 LARGE ARRAYS
2519
2520 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2521 These functions cause every element in the array to move, which can be murder
2522 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2523 a different location.  This will be addressed in the forthcoming version 1.00.
2524
2525 =head2 WRITEONLY FILES
2526
2527 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2528 writeonly mode. STORE will verify that the filehandle is writable. However, there
2529 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2530 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2531
2532 =head1 PERFORMANCE
2533
2534 This section discusses DBM::Deep's speed and memory usage.
2535
2536 =head2 SPEED
2537
2538 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2539 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2540 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2541 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2542 with huge databases.  Here is some test data:
2543
2544         Adding 1,000,000 keys to new DB file...
2545
2546         At 100 keys, avg. speed is 2,703 keys/sec
2547         At 200 keys, avg. speed is 2,642 keys/sec
2548         At 300 keys, avg. speed is 2,598 keys/sec
2549         At 400 keys, avg. speed is 2,578 keys/sec
2550         At 500 keys, avg. speed is 2,722 keys/sec
2551         At 600 keys, avg. speed is 2,628 keys/sec
2552         At 700 keys, avg. speed is 2,700 keys/sec
2553         At 800 keys, avg. speed is 2,607 keys/sec
2554         At 900 keys, avg. speed is 2,190 keys/sec
2555         At 1,000 keys, avg. speed is 2,570 keys/sec
2556         At 2,000 keys, avg. speed is 2,417 keys/sec
2557         At 3,000 keys, avg. speed is 1,982 keys/sec
2558         At 4,000 keys, avg. speed is 1,568 keys/sec
2559         At 5,000 keys, avg. speed is 1,533 keys/sec
2560         At 6,000 keys, avg. speed is 1,787 keys/sec
2561         At 7,000 keys, avg. speed is 1,977 keys/sec
2562         At 8,000 keys, avg. speed is 2,028 keys/sec
2563         At 9,000 keys, avg. speed is 2,077 keys/sec
2564         At 10,000 keys, avg. speed is 2,031 keys/sec
2565         At 20,000 keys, avg. speed is 1,970 keys/sec
2566         At 30,000 keys, avg. speed is 2,050 keys/sec
2567         At 40,000 keys, avg. speed is 2,073 keys/sec
2568         At 50,000 keys, avg. speed is 1,973 keys/sec
2569         At 60,000 keys, avg. speed is 1,914 keys/sec
2570         At 70,000 keys, avg. speed is 2,091 keys/sec
2571         At 80,000 keys, avg. speed is 2,103 keys/sec
2572         At 90,000 keys, avg. speed is 1,886 keys/sec
2573         At 100,000 keys, avg. speed is 1,970 keys/sec
2574         At 200,000 keys, avg. speed is 2,053 keys/sec
2575         At 300,000 keys, avg. speed is 1,697 keys/sec
2576         At 400,000 keys, avg. speed is 1,838 keys/sec
2577         At 500,000 keys, avg. speed is 1,941 keys/sec
2578         At 600,000 keys, avg. speed is 1,930 keys/sec
2579         At 700,000 keys, avg. speed is 1,735 keys/sec
2580         At 800,000 keys, avg. speed is 1,795 keys/sec
2581         At 900,000 keys, avg. speed is 1,221 keys/sec
2582         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2583
2584 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2585 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2586 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2587 Run time was 12 min 3 sec.
2588
2589 =head2 MEMORY USAGE
2590
2591 One of the great things about DBM::Deep is that it uses very little memory.
2592 Even with huge databases (1,000,000+ keys) you will not see much increased
2593 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2594 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2595 database handle:
2596
2597           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2598         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2599
2600 Basically the process is taking 2,716K of memory.  And here is the same
2601 process after storing and fetching 1,000,000 keys:
2602
2603           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2604         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2605
2606 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2607 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2608
2609 =head1 DB FILE FORMAT
2610
2611 In case you were interested in the underlying DB file format, it is documented
2612 here in this section.  You don't need to know this to use the module, it's just
2613 included for reference.
2614
2615 =head2 SIGNATURE
2616
2617 DBM::Deep files always start with a 32-bit signature to identify the file type.
2618 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2619 checked for when the file is opened and an error will be thrown if it's not found.
2620
2621 =head2 TAG
2622
2623 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2624 has a standard header containing the type of data, the length of data, and then
2625 the data itself.  The type is a single character (1 byte), the length is a
2626 32-bit unsigned long in network byte order, and the data is, well, the data.
2627 Here is how it unfolds:
2628
2629 =head2 MASTER INDEX
2630
2631 Immediately after the 32-bit file signature is the I<Master Index> record.
2632 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2633 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2634 depending on how the DBM::Deep object was constructed.
2635
2636 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2637 number).  The first 8-bit char of the MD5 signature is the offset into the
2638 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2639 index element is a file offset of the next tag for the key/element in question,
2640 which is usually a I<Bucket List> tag (see below).
2641
2642 The next tag I<could> be another index, depending on how many keys/elements
2643 exist.  See L<RE-INDEXING> below for details.
2644
2645 =head2 BUCKET LIST
2646
2647 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2648 file offsets to where the actual data is stored.  It starts with a standard
2649 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2650 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2651 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2652 When the list fills up, a I<Re-Index> operation is performed (See
2653 L<RE-INDEXING> below).
2654
2655 =head2 BUCKET
2656
2657 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2658 index/value pair (in array mode).  It starts with a standard tag header with
2659 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2660 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2661 header.  The size reported in the tag header is only for the value, but then,
2662 just after the value is another size (32-bit unsigned long) and then the plain
2663 key itself.  Since the value is likely to be fetched more often than the plain
2664 key, I figured it would be I<slightly> faster to store the value first.
2665
2666 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2667 record for the nested structure, where the process begins all over again.
2668
2669 =head2 RE-INDEXING
2670
2671 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2672 exhausted.  Then, when another key/element comes in, the list is converted to a
2673 new index record.  However, this index will look at the next char in the MD5
2674 hash, and arrange new Bucket List pointers accordingly.  This process is called
2675 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2676 17 (16 + new one) keys/elements are removed from the old Bucket List and
2677 inserted into the new index.  Several new Bucket Lists are created in the
2678 process, as a new MD5 char from the key is being examined (it is unlikely that
2679 the keys will all share the same next char of their MD5s).
2680
2681 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2682 when the Bucket Lists will turn into indexes, but the first round tends to
2683 happen right around 4,000 keys.  You will see a I<slight> decrease in
2684 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2685 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2686 right around 900,000 keys.  This process can continue nearly indefinitely --
2687 right up until the point the I<MD5> signatures start colliding with each other,
2688 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2689 getting struck by lightning while you are walking to cash in your tickets.
2690 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2691 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2692 this is 340 unodecillion, but don't quote me).
2693
2694 =head2 STORING
2695
2696 When a new key/element is stored, the key (or index number) is first run through
2697 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2698 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2699 for the first char of the signature (in this case I<b0>).  If it does not exist,
2700 a new I<Bucket List> is created for our key (and the next 15 future keys that
2701 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2702 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2703 this point, unless we are replacing an existing I<Bucket>), where the actual
2704 data will be stored.
2705
2706 =head2 FETCHING
2707
2708 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2709 (or index number), then walking along the indexes.  If there are enough
2710 keys/elements in this DB level, there might be nested indexes, each linked to
2711 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2712 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2713 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2714 plain key are stored.
2715
2716 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2717 methods.  In this process the indexes are walked systematically, and each key
2718 fetched in increasing MD5 order (which is why it appears random).   Once the
2719 I<Bucket> is found, the value is skipped and the plain key returned instead.
2720 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2721 alphabetically sorted.  This only happens on an index-level -- as soon as the
2722 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2723 so it's pretty much undefined how the keys will come out -- just like Perl's
2724 built-in hashes.
2725
2726 =head1 CODE COVERAGE
2727
2728 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2729 B<Devel::Cover> report on this module's test suite.
2730
2731   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2732   File                           stmt   bran   cond    sub    pod   time  total
2733   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2734   blib/lib/DBM/Deep.pm           95.4   84.6   69.1   98.2  100.0   60.3   91.0
2735   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.4   98.0
2736   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   13.3   92.4
2737   Total                          96.4   85.4   73.1   98.8  100.0  100.0   92.4
2738   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2739
2740 =head1 MORE INFORMATION
2741
2742 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2743 or send email to L<DBM-Deep@googlegroups.com>.
2744
2745 =head1 AUTHORS
2746
2747 Joseph Huckaby, L<jhuckaby@cpan.org>
2748
2749 Rob Kinyon, L<rkinyon@cpan.org>
2750
2751 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2752
2753 =head1 SEE ALSO
2754
2755 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2756 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2757
2758 =head1 LICENSE
2759
2760 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2761 This is free software, you may use it and distribute it under the
2762 same terms as Perl itself.
2763
2764 =cut