lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use FileHandle;
  35 use Fcntl qw/:flock/;
  36 use Digest::MD5 ();
  37 use Scalar::Util ();
  38 use vars qw/$VERSION/;
  39
  40 $VERSION = "0.96";
  41
  42 ##
  43 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  44 #       (Perl must be compiled with largefile support for files > 2 GB)
  45 #
  46 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47 #       (Perl must be compiled with largefile and 64-bit long support)
  48 ##
  49 #my $LONG_SIZE = 4;
  50 #my $LONG_PACK = 'N';
  51
  52 ##
  53 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  54 # Upgrading this is possible (see above) but probably not necessary.  If you need
  55 # more than 4 GB for a single key or value, this module is really not for you :-)
  56 ##
  57 #my $DATA_LENGTH_SIZE = 4;
  58 #my $DATA_LENGTH_PACK = 'N';
  59 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  60
  61 ##
  62 # Maximum number of buckets per list before another level of indexing is done.
  63 # Increase this value for slightly greater speed, but larger database files.
  64 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  65 ##
  66 my $MAX_BUCKETS = 16;
  67
  68 ##
  69 # Better not adjust anything below here, unless you're me :-)
  70 ##
  71
  72 ##
  73 # Setup digest function for keys
  74 ##
  75 my ($DIGEST_FUNC, $HASH_SIZE);
  76 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  77
  78 ##
  79 # Precalculate index and bucket sizes based on values above.
  80 ##
  81 #my $HASH_SIZE = 16;
  82 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  83
  84 set_digest();
  85 #set_pack();
  86 #precalc_sizes();
  87
  88 ##
  89 # Setup file and tag signatures.  These should never change.
  90 ##
  91 sub SIG_FILE  () { 'DPDB' }
  92 sub SIG_HASH  () { 'H' }
  93 sub SIG_ARRAY () { 'A' }
  94 sub SIG_NULL  () { 'N' }
  95 sub SIG_DATA  () { 'D' }
  96 sub SIG_INDEX () { 'I' }
  97 sub SIG_BLIST () { 'B' }
  98 sub SIG_SIZE  () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 *TYPE_HASH = \&SIG_HASH;
 104 *TYPE_ARRAY = \&SIG_ARRAY;
 105
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116
 117         ##
 118         # Check if we want a tied hash or array.
 119         ##
 120         my $self;
 121         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 122                 tie @$self, $class, %$args;
 123         }
 124         else {
 125                 tie %$self, $class, %$args;
 126         }
 127
 128         return bless $self, $class;
 129 }
 130
 131 {
 132     my @outer_params = qw( type base_offset );
 133     sub _init {
 134         ##
 135         # Setup $self and bless into this class.
 136         ##
 137         my $class = shift;
 138         my $args = shift;
 139
 140         my $self = {
 141             type => TYPE_HASH,
 142             base_offset => length(SIG_FILE),
 143             root => {
 144                 file => undef,
 145                 fh => undef,
 146                 end => 0,
 147                 links => 0,
 148                 autoflush => undef,
 149                 locking => undef,
 150                 volatile => undef,
 151                 debug => undef,
 152                 mode => 'r+',
 153                 filter_store_key => undef,
 154                 filter_store_value => undef,
 155                 filter_fetch_key => undef,
 156                 filter_fetch_value => undef,
 157                 autobless => undef,
 158                 locked => 0,
 159                 %$args,
 160             },
 161         };
 162
 163         bless $self, $class;
 164
 165         foreach my $outer_parm ( @outer_params ) {
 166             next unless exists $args->{$outer_parm};
 167             $self->{$outer_parm} = $args->{$outer_parm}
 168         }
 169
 170         if ( exists $args->{root} ) {
 171             $self->{root} = $args->{root};
 172         }
 173         else {
 174             # This is cleanup based on the fact that the $args
 175             # coming in is for both the root and non-root items
 176             delete $self->root->{$_} for @outer_params;
 177         }
 178         $self->root->{links}++;
 179
 180         if (!defined($self->fh)) { $self->_open(); }
 181
 182         return $self;
 183     }
 184 }
 185
 186 sub _get_self { tied( %{$_[0]} ) || $_[0] }
 187
 188 sub TIEHASH {
 189     ##
 190     # Tied hash constructor method, called by Perl's tie() function.
 191     ##
 192     my $class = shift;
 193     my $args;
 194     if (scalar(@_) > 1) { $args = {@_}; }
 195     #XXX This use of ref() is bad and is a bug
 196     elsif (ref($_[0])) { $args = $_[0]; }
 197     else { $args = { file => shift }; }
 198
 199     $args->{type} = TYPE_HASH;
 200
 201     return $class->_init($args);
 202 }
 203
 204 sub TIEARRAY {
 205 ##
 206 # Tied array constructor method, called by Perl's tie() function.
 207 ##
 208     my $class = shift;
 209     my $args;
 210     if (scalar(@_) > 1) { $args = {@_}; }
 211     #XXX This use of ref() is bad and is a bug
 212         elsif (ref($_[0])) { $args = $_[0]; }
 213         else { $args = { file => shift }; }
 214
 215         $args->{type} = TYPE_ARRAY;
 216
 217         return $class->_init($args);
 218 }
 219
 220 sub DESTROY {
 221         ##
 222         # Class deconstructor.  Close file handle if there are no more refs.
 223         ##
 224     my $self = _get_self($_[0]);
 225     return unless $self;
 226
 227         $self->root->{links}--;
 228
 229         if (!$self->root->{links}) {
 230                 $self->_close();
 231         }
 232 }
 233
 234 sub _open {
 235         ##
 236         # Open a FileHandle to the database, create if nonexistent.
 237         # Make sure file signature matches DeepDB spec.
 238         ##
 239     my $self = _get_self($_[0]);
 240
 241         if (defined($self->fh)) { $self->_close(); }
 242
 243         if (!(-e $self->root->{file}) && $self->root->{mode} eq 'r+') {
 244                 my $temp = FileHandle->new( $self->root->{file}, 'w' );
 245                 undef $temp;
 246         }
 247
 248     #XXX Convert to set_fh()
 249         $self->root->{fh} = FileHandle->new( $self->root->{file}, $self->root->{mode} );
 250         if (! defined($self->fh)) {
 251                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 252         }
 253
 254     binmode $self->fh; # for win32
 255     if ($self->root->{autoflush}) {
 256         $self->fh->autoflush();
 257     }
 258
 259     my $signature;
 260     seek($self->fh, 0, 0);
 261     my $bytes_read = $self->fh->read($signature, length(SIG_FILE));
 262
 263     ##
 264     # File is empty -- write signature and master index
 265     ##
 266     if (!$bytes_read) {
 267         seek($self->fh, 0, 0);
 268         $self->fh->print(SIG_FILE);
 269         $self->root->{end} = length(SIG_FILE);
 270         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 271
 272         my $plain_key = "[base]";
 273         $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 274         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 275         $self->fh->flush();
 276
 277         return 1;
 278     }
 279
 280     ##
 281     # Check signature was valid
 282     ##
 283     unless ($signature eq SIG_FILE) {
 284         $self->_close();
 285         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 286     }
 287
 288     $self->root->{end} = (stat($self->fh))[7];
 289
 290     ##
 291     # Get our type from master index signature
 292     ##
 293     my $tag = $self->_load_tag($self->base_offset);
 294 #XXX We probably also want to store the hash algorithm name and not assume anything
 295     if (!$tag) {
 296         return $self->_throw_error("Corrupted file, no master index record");
 297     }
 298     if ($self->{type} ne $tag->{signature}) {
 299         return $self->_throw_error("File type mismatch");
 300     }
 301
 302     return 1;
 303 }
 304
 305 sub _close {
 306         ##
 307         # Close database FileHandle
 308         ##
 309     my $self = _get_self($_[0]);
 310         undef $self->root->{fh};
 311 }
 312
 313 sub _create_tag {
 314         ##
 315         # Given offset, signature and content, create tag and write to disk
 316         ##
 317         my ($self, $offset, $sig, $content) = @_;
 318         my $size = length($content);
 319
 320         seek($self->fh, $offset, 0);
 321         $self->fh->print( $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 322
 323         if ($offset == $self->root->{end}) {
 324                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 325         }
 326
 327         return {
 328                 signature => $sig,
 329                 size => $size,
 330                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 331                 content => $content
 332         };
 333 }
 334
 335 sub _load_tag {
 336         ##
 337         # Given offset, load single tag and return signature, size and data
 338         ##
 339         my $self = shift;
 340         my $offset = shift;
 341
 342         seek($self->fh, $offset, 0);
 343         if ($self->fh->eof()) { return undef; }
 344
 345         my $sig;
 346         $self->fh->read($sig, SIG_SIZE);
 347
 348         my $size;
 349         $self->fh->read($size, $DATA_LENGTH_SIZE);
 350         $size = unpack($DATA_LENGTH_PACK, $size);
 351
 352         my $buffer;
 353         $self->fh->read($buffer, $size);
 354
 355         return {
 356                 signature => $sig,
 357                 size => $size,
 358                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 359                 content => $buffer
 360         };
 361 }
 362
 363 sub _index_lookup {
 364         ##
 365         # Given index tag, lookup single entry in index and return .
 366         ##
 367         my $self = shift;
 368         my ($tag, $index) = @_;
 369
 370         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 371         if (!$location) { return; }
 372
 373         return $self->_load_tag( $location );
 374 }
 375
 376 sub _add_bucket {
 377         ##
 378         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 379         # plain (undigested) key and value.
 380         ##
 381         my $self = shift;
 382         my ($tag, $md5, $plain_key, $value) = @_;
 383         my $keys = $tag->{content};
 384         my $location = 0;
 385         my $result = 2;
 386
 387     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 388         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 389
 390         ##
 391         # Iterate through buckets, seeing if this is a new entry or a replace.
 392         ##
 393         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 394                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 395                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 396                 if (!$subloc) {
 397                         ##
 398                         # Found empty bucket (end of list).  Populate and exit loop.
 399                         ##
 400                         $result = 2;
 401
 402             $location = $internal_ref
 403                 ? $value->base_offset
 404                 :$location = $self->root->{end};
 405
 406                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 407                         $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 408                         last;
 409                 }
 410                 elsif ($md5 eq $key) {
 411                         ##
 412                         # Found existing bucket with same key.  Replace with new value.
 413                         ##
 414                         $result = 1;
 415
 416                         if ($internal_ref) {
 417                                 $location = $value->base_offset;
 418                                 seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 419                                 $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 420                         }
 421                         else {
 422                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 423                                 my $size;
 424                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 425
 426                                 ##
 427                                 # If value is a hash, array, or raw value with equal or less size, we can
 428                                 # reuse the same content area of the database.  Otherwise, we have to create
 429                                 # a new content area at the EOF.
 430                                 ##
 431                                 my $actual_length;
 432                 my $r = Scalar::Util::reftype( $value ) || '';
 433                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 434                                 else { $actual_length = length($value); }
 435
 436                                 if ($actual_length <= $size) {
 437                                         $location = $subloc;
 438                                 }
 439                                 else {
 440                                         $location = $self->root->{end};
 441                                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 442                                         $self->fh->print( pack($LONG_PACK, $location) );
 443                                 }
 444                         }
 445                         last;
 446                 }
 447         } # i loop
 448
 449         ##
 450         # If this is an internal reference, return now.
 451         # No need to write value or plain key
 452         ##
 453         if ($internal_ref) {
 454         return $result;
 455     }
 456
 457         ##
 458         # If bucket didn't fit into list, split into a new index level
 459         ##
 460         if (!$location) {
 461                 seek($self->fh, $tag->{ref_loc}, 0);
 462                 $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 463
 464                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 465                 my @offsets = ();
 466
 467                 $keys .= $md5 . pack($LONG_PACK, 0);
 468
 469                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 470                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 471                         if ($key) {
 472                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 473                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 474
 475                                 if ($offsets[$num]) {
 476                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 477                                         seek($self->fh, $offset, 0);
 478                                         my $subkeys;
 479                                         $self->fh->read($subkeys, $BUCKET_LIST_SIZE);
 480
 481                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 482                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 483                                                 if (!$subloc) {
 484                                                         seek($self->fh, $offset + ($k * $BUCKET_SIZE), 0);
 485                                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 486                                                         last;
 487                                                 }
 488                                         } # k loop
 489                                 }
 490                                 else {
 491                                         $offsets[$num] = $self->root->{end};
 492                                         seek($self->fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 493                                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 494
 495                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 496
 497                                         seek($self->fh, $blist_tag->{offset}, 0);
 498                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 499                                 }
 500                         } # key is real
 501                 } # i loop
 502
 503                 $location ||= $self->root->{end};
 504         } # re-index bucket list
 505
 506         ##
 507         # Seek to content area and store signature, value and plaintext key
 508         ##
 509         if ($location) {
 510                 my $content_length;
 511                 seek($self->fh, $location, 0);
 512
 513                 ##
 514                 # Write signature based on content type, set content length and write actual value.
 515                 ##
 516         my $r = Scalar::Util::reftype($value) || '';
 517                 if ($r eq 'HASH') {
 518                         $self->fh->print( TYPE_HASH );
 519                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 520                         $content_length = $INDEX_SIZE;
 521                 }
 522                 elsif ($r eq 'ARRAY') {
 523                         $self->fh->print( TYPE_ARRAY );
 524                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 525                         $content_length = $INDEX_SIZE;
 526                 }
 527                 elsif (!defined($value)) {
 528                         $self->fh->print( SIG_NULL );
 529                         $self->fh->print( pack($DATA_LENGTH_PACK, 0) );
 530                         $content_length = 0;
 531                 }
 532                 else {
 533                         $self->fh->print( SIG_DATA );
 534                         $self->fh->print( pack($DATA_LENGTH_PACK, length($value)) . $value );
 535                         $content_length = length($value);
 536                 }
 537
 538                 ##
 539                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 540                 ##
 541                 $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 542
 543                 ##
 544                 # If value is blessed, preserve class name
 545                 ##
 546                 my $value_class = Scalar::Util::blessed($value);
 547                 if ($self->root->{autobless} && defined $value_class && $value_class ne 'DBM::Deep' ) {
 548             ##
 549             # Blessed ref -- will restore later
 550             ##
 551             $self->fh->print( chr(1) );
 552             $self->fh->print( pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 553             $content_length += 1;
 554             $content_length += $DATA_LENGTH_SIZE + length($value_class);
 555                 }
 556
 557                 ##
 558                 # If this is a new content area, advance EOF counter
 559                 ##
 560                 if ($location == $self->root->{end}) {
 561                         $self->root->{end} += SIG_SIZE;
 562                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 563                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 564                 }
 565
 566                 ##
 567                 # If content is a hash or array, create new child DeepDB object and
 568                 # pass each key or element to it.
 569                 ##
 570                 if ($r eq 'HASH') {
 571                         my $branch = DBM::Deep->new(
 572                                 type => TYPE_HASH,
 573                                 base_offset => $location,
 574                                 root => $self->root,
 575                         );
 576                         foreach my $key (keys %{$value}) {
 577                                 $branch->{$key} = $value->{$key};
 578                         }
 579                 }
 580                 elsif ($r eq 'ARRAY') {
 581                         my $branch = DBM::Deep->new(
 582                                 type => TYPE_ARRAY,
 583                                 base_offset => $location,
 584                                 root => $self->root,
 585                         );
 586                         my $index = 0;
 587                         foreach my $element (@{$value}) {
 588                                 $branch->[$index] = $element;
 589                                 $index++;
 590                         }
 591                 }
 592
 593                 return $result;
 594         }
 595
 596         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 597 }
 598
 599 sub _get_bucket_value {
 600         ##
 601         # Fetch single value given tag and MD5 digested key.
 602         ##
 603         my $self = shift;
 604         my ($tag, $md5) = @_;
 605         my $keys = $tag->{content};
 606
 607         ##
 608         # Iterate through buckets, looking for a key match
 609         ##
 610     BUCKET:
 611         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 612                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 613                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 614
 615                 if (!$subloc) {
 616                         ##
 617                         # Hit end of list, no match
 618                         ##
 619                         return;
 620                 }
 621
 622         if ( $md5 ne $key ) {
 623             next BUCKET;
 624         }
 625
 626         ##
 627         # Found match -- seek to offset and read signature
 628         ##
 629         my $signature;
 630         seek($self->fh, $subloc, 0);
 631         $self->fh->read($signature, SIG_SIZE);
 632
 633         ##
 634         # If value is a hash or array, return new DeepDB object with correct offset
 635         ##
 636         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 637             my $obj = DBM::Deep->new(
 638                 type => $signature,
 639                 base_offset => $subloc,
 640                 root => $self->root
 641             );
 642
 643             if ($self->root->{autobless}) {
 644                 ##
 645                 # Skip over value and plain key to see if object needs
 646                 # to be re-blessed
 647                 ##
 648                 seek($self->fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 649
 650                 my $size;
 651                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 652                 if ($size) { seek($self->fh, $size, 1); }
 653
 654                 my $bless_bit;
 655                 $self->fh->read($bless_bit, 1);
 656                 if (ord($bless_bit)) {
 657                     ##
 658                     # Yes, object needs to be re-blessed
 659                     ##
 660                     my $class_name;
 661                     $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 662                     if ($size) { $self->fh->read($class_name, $size); }
 663                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 664                 }
 665             }
 666
 667             return $obj;
 668         }
 669
 670         ##
 671         # Otherwise return actual value
 672         ##
 673         elsif ($signature eq SIG_DATA) {
 674             my $size;
 675             my $value = '';
 676             $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 677             if ($size) { $self->fh->read($value, $size); }
 678             return $value;
 679         }
 680
 681         ##
 682         # Key exists, but content is null
 683         ##
 684         else { return; }
 685         } # i loop
 686
 687         return;
 688 }
 689
 690 sub _delete_bucket {
 691         ##
 692         # Delete single key/value pair given tag and MD5 digested key.
 693         ##
 694         my $self = shift;
 695         my ($tag, $md5) = @_;
 696         my $keys = $tag->{content};
 697
 698         ##
 699         # Iterate through buckets, looking for a key match
 700         ##
 701     BUCKET:
 702         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 703                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 704                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 705
 706                 if (!$subloc) {
 707                         ##
 708                         # Hit end of list, no match
 709                         ##
 710                         return;
 711                 }
 712
 713         if ( $md5 ne $key ) {
 714             next BUCKET;
 715         }
 716
 717         ##
 718         # Matched key -- delete bucket and return
 719         ##
 720         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 721         $self->fh->print( substr($keys, ($i+1) * $BUCKET_SIZE ) );
 722         $self->fh->print( chr(0) x $BUCKET_SIZE );
 723
 724         return 1;
 725         } # i loop
 726
 727         return;
 728 }
 729
 730 sub _bucket_exists {
 731         ##
 732         # Check existence of single key given tag and MD5 digested key.
 733         ##
 734         my $self = shift;
 735         my ($tag, $md5) = @_;
 736         my $keys = $tag->{content};
 737
 738         ##
 739         # Iterate through buckets, looking for a key match
 740         ##
 741     BUCKET:
 742         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 743                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 744                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 745
 746                 if (!$subloc) {
 747                         ##
 748                         # Hit end of list, no match
 749                         ##
 750                         return;
 751                 }
 752
 753         if ( $md5 ne $key ) {
 754             next BUCKET;
 755         }
 756
 757         ##
 758         # Matched key -- return true
 759         ##
 760         return 1;
 761         } # i loop
 762
 763         return;
 764 }
 765
 766 sub _find_bucket_list {
 767         ##
 768         # Locate offset for bucket list, given digested key
 769         ##
 770         my $self = shift;
 771         my $md5 = shift;
 772
 773         ##
 774         # Locate offset for bucket list using digest index system
 775         ##
 776         my $ch = 0;
 777         my $tag = $self->_load_tag($self->base_offset);
 778         if (!$tag) { return; }
 779
 780         while ($tag->{signature} ne SIG_BLIST) {
 781                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 782                 if (!$tag) { return; }
 783                 $ch++;
 784         }
 785
 786         return $tag;
 787 }
 788
 789 sub _traverse_index {
 790         ##
 791         # Scan index and recursively step into deeper levels, looking for next key.
 792         ##
 793     my ($self, $offset, $ch, $force_return_next) = @_;
 794     $force_return_next = undef unless $force_return_next;
 795
 796         my $tag = $self->_load_tag( $offset );
 797
 798         if ($tag->{signature} ne SIG_BLIST) {
 799                 my $content = $tag->{content};
 800                 my $start;
 801                 if ($self->{return_next}) { $start = 0; }
 802                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 803
 804                 for (my $index = $start; $index < 256; $index++) {
 805                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 806                         if ($subloc) {
 807                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 808                                 if (defined($result)) { return $result; }
 809                         }
 810                 } # index loop
 811
 812                 $self->{return_next} = 1;
 813         } # tag is an index
 814
 815         elsif ($tag->{signature} eq SIG_BLIST) {
 816                 my $keys = $tag->{content};
 817                 if ($force_return_next) { $self->{return_next} = 1; }
 818
 819                 ##
 820                 # Iterate through buckets, looking for a key match
 821                 ##
 822                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 823                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 824                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 825
 826                         if (!$subloc) {
 827                                 ##
 828                                 # End of bucket list -- return to outer loop
 829                                 ##
 830                                 $self->{return_next} = 1;
 831                                 last;
 832                         }
 833                         elsif ($key eq $self->{prev_md5}) {
 834                                 ##
 835                                 # Located previous key -- return next one found
 836                                 ##
 837                                 $self->{return_next} = 1;
 838                                 next;
 839                         }
 840                         elsif ($self->{return_next}) {
 841                                 ##
 842                                 # Seek to bucket location and skip over signature
 843                                 ##
 844                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 845
 846                                 ##
 847                                 # Skip over value to get to plain key
 848                                 ##
 849                                 my $size;
 850                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 851                                 if ($size) { seek($self->fh, $size, 1); }
 852
 853                                 ##
 854                                 # Read in plain key and return as scalar
 855                                 ##
 856                                 my $plain_key;
 857                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 858                                 if ($size) { $self->fh->read($plain_key, $size); }
 859
 860                                 return $plain_key;
 861                         }
 862                 } # bucket loop
 863
 864                 $self->{return_next} = 1;
 865         } # tag is a bucket list
 866
 867         return;
 868 }
 869
 870 sub _get_next_key {
 871         ##
 872         # Locate next key, given digested previous one
 873         ##
 874     my $self = _get_self($_[0]);
 875
 876         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 877         $self->{return_next} = 0;
 878
 879         ##
 880         # If the previous key was not specifed, start at the top and
 881         # return the first one found.
 882         ##
 883         if (!$self->{prev_md5}) {
 884                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 885                 $self->{return_next} = 1;
 886         }
 887
 888         return $self->_traverse_index( $self->base_offset, 0 );
 889 }
 890
 891 sub lock {
 892         ##
 893         # If db locking is set, flock() the db file.  If called multiple
 894         # times before unlock(), then the same number of unlocks() must
 895         # be called before the lock is released.
 896         ##
 897     my $self = _get_self($_[0]);
 898         my $type = $_[1];
 899     $type = LOCK_EX unless defined $type;
 900
 901         if ($self->root->{locking}) {
 902                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 903                 $self->root->{locked}++;
 904         }
 905 }
 906
 907 sub unlock {
 908         ##
 909         # If db locking is set, unlock the db file.  See note in lock()
 910         # regarding calling lock() multiple times.
 911         ##
 912     my $self = _get_self($_[0]);
 913
 914         if ($self->root->{locking} && $self->root->{locked} > 0) {
 915                 $self->root->{locked}--;
 916                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 917         }
 918 }
 919
 920 #XXX These uses of ref() need verified
 921 sub _copy_node {
 922         ##
 923         # Copy single level of keys or elements to new DB handle.
 924         # Recurse for nested structures
 925         ##
 926     my $self = _get_self($_[0]);
 927         my $db_temp = $_[1];
 928
 929         if ($self->type eq TYPE_HASH) {
 930                 my $key = $self->first_key();
 931                 while ($key) {
 932                         my $value = $self->get($key);
 933                         if (!ref($value)) { $db_temp->{$key} = $value; }
 934                         else {
 935                                 my $type = $value->type;
 936                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 937                                 else { $db_temp->{$key} = []; }
 938                                 $value->_copy_node( $db_temp->{$key} );
 939                         }
 940                         $key = $self->next_key($key);
 941                 }
 942         }
 943         else {
 944                 my $length = $self->length();
 945                 for (my $index = 0; $index < $length; $index++) {
 946                         my $value = $self->get($index);
 947                         if (!ref($value)) { $db_temp->[$index] = $value; }
 948             #XXX NO tests for this code
 949                         else {
 950                                 my $type = $value->type;
 951                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 952                                 else { $db_temp->[$index] = []; }
 953                                 $value->_copy_node( $db_temp->[$index] );
 954                         }
 955                 }
 956         }
 957 }
 958
 959 sub export {
 960         ##
 961         # Recursively export into standard Perl hashes and arrays.
 962         ##
 963     my $self = _get_self($_[0]);
 964
 965         my $temp;
 966         if ($self->type eq TYPE_HASH) { $temp = {}; }
 967         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 968
 969         $self->lock();
 970         $self->_copy_node( $temp );
 971         $self->unlock();
 972
 973         return $temp;
 974 }
 975
 976 sub import {
 977         ##
 978         # Recursively import Perl hash/array structure
 979         ##
 980     #XXX This use of ref() seems to be ok
 981         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 982
 983     my $self = _get_self($_[0]);
 984         my $struct = $_[1];
 985
 986     #XXX This use of ref() seems to be ok
 987         if (!ref($struct)) {
 988                 ##
 989                 # struct is not a reference, so just import based on our type
 990                 ##
 991                 shift @_;
 992
 993                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
 994                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
 995         }
 996
 997     my $r = Scalar::Util::reftype($struct) || '';
 998         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
 999                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1000         }
1001         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1002                 $self->push( @$struct );
1003         }
1004         else {
1005                 return $self->_throw_error("Cannot import: type mismatch");
1006         }
1007
1008         return 1;
1009 }
1010
1011 sub optimize {
1012         ##
1013         # Rebuild entire database into new file, then move
1014         # it back on top of original.
1015         ##
1016     my $self = _get_self($_[0]);
1017         if ($self->root->{links} > 1) {
1018                 return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1019         }
1020
1021         my $db_temp = DBM::Deep->new(
1022                 file => $self->root->{file} . '.tmp',
1023                 type => $self->type
1024         );
1025         if (!$db_temp) {
1026                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1027         }
1028
1029         $self->lock();
1030         $self->_copy_node( $db_temp );
1031         undef $db_temp;
1032
1033         ##
1034         # Attempt to copy user, group and permissions over to new file
1035         ##
1036         my @stats = stat($self->fh);
1037         my $perms = $stats[2] & 07777;
1038         my $uid = $stats[4];
1039         my $gid = $stats[5];
1040         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1041         chmod( $perms, $self->root->{file} . '.tmp' );
1042
1043     # q.v. perlport for more information on this variable
1044     if ( $^O eq 'MSWin32' ) {
1045                 ##
1046                 # Potential race condition when optmizing on Win32 with locking.
1047                 # The Windows filesystem requires that the filehandle be closed
1048                 # before it is overwritten with rename().  This could be redone
1049                 # with a soft copy.
1050                 ##
1051                 $self->unlock();
1052                 $self->_close();
1053         }
1054
1055         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1056                 unlink $self->root->{file} . '.tmp';
1057                 $self->unlock();
1058                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1059         }
1060
1061         $self->unlock();
1062         $self->_close();
1063         $self->_open();
1064
1065         return 1;
1066 }
1067
1068 sub clone {
1069         ##
1070         # Make copy of object and return
1071         ##
1072     my $self = _get_self($_[0]);
1073
1074         return DBM::Deep->new(
1075                 type => $self->type,
1076                 base_offset => $self->base_offset,
1077                 root => $self->root
1078         );
1079 }
1080
1081 {
1082     my %is_legal_filter = map {
1083         $_ => ~~1,
1084     } qw(
1085         store_key store_value
1086         fetch_key fetch_value
1087     );
1088
1089     sub set_filter {
1090         ##
1091         # Setup filter function for storing or fetching the key or value
1092         ##
1093         my $self = _get_self($_[0]);
1094         my $type = lc $_[1];
1095         my $func = $_[2] ? $_[2] : undef;
1096
1097         if ( $is_legal_filter{$type} ) {
1098             $self->root->{"filter_$type"} = $func;
1099             return 1;
1100         }
1101
1102         return;
1103     }
1104 }
1105
1106 ##
1107 # Accessor methods
1108 ##
1109
1110 sub root {
1111         ##
1112         # Get access to the root structure
1113         ##
1114     my $self = _get_self($_[0]);
1115         return $self->{root};
1116 }
1117
1118 sub fh {
1119         ##
1120         # Get access to the raw FileHandle
1121         ##
1122     #XXX It will be useful, though, when we split out HASH and ARRAY
1123     my $self = _get_self($_[0]);
1124         return $self->root->{fh};
1125 }
1126
1127 sub type {
1128         ##
1129         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1130         ##
1131     my $self = _get_self($_[0]);
1132         return $self->{type};
1133 }
1134
1135 sub base_offset {
1136         ##
1137         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1138         ##
1139     my $self = _get_self($_[0]);
1140         return $self->{base_offset};
1141 }
1142
1143 sub error {
1144         ##
1145         # Get last error string, or undef if no error
1146         ##
1147         return $_[0]
1148         ? ( _get_self($_[0])->{root}->{error} or undef )
1149         : $@;
1150 }
1151
1152 ##
1153 # Utility methods
1154 ##
1155
1156 sub _throw_error {
1157         ##
1158         # Store error string in self
1159         ##
1160     my $self = _get_self($_[0]);
1161         my $error_text = $_[1];
1162
1163         $self->root->{error} = $error_text;
1164
1165         unless ($self->root->{debug}) {
1166         die "DBM::Deep: $error_text\n";
1167     }
1168
1169     warn "DBM::Deep: $error_text\n";
1170         return;
1171 }
1172
1173 sub clear_error {
1174         ##
1175         # Clear error state
1176         ##
1177     my $self = _get_self($_[0]);
1178
1179         undef $self->root->{error};
1180 }
1181
1182 sub precalc_sizes {
1183         ##
1184         # Precalculate index, bucket and bucket list sizes
1185         ##
1186
1187     #XXX I don't like this ...
1188     set_pack() unless defined $LONG_SIZE;
1189
1190         $INDEX_SIZE = 256 * $LONG_SIZE;
1191         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1192         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1193 }
1194
1195 sub set_pack {
1196         ##
1197         # Set pack/unpack modes (see file header for more)
1198         ##
1199     my ($long_s, $long_p, $data_s, $data_p) = @_;
1200
1201     $LONG_SIZE = $long_s ? $long_s : 4;
1202     $LONG_PACK = $long_p ? $long_p : 'N';
1203
1204     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1205     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1206
1207         precalc_sizes();
1208 }
1209
1210 sub set_digest {
1211         ##
1212         # Set key digest function (default is MD5)
1213         ##
1214     my ($digest_func, $hash_size) = @_;
1215
1216     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1217     $HASH_SIZE = $hash_size ? $hash_size : 16;
1218
1219         precalc_sizes();
1220 }
1221
1222 ##
1223 # tie() methods (hashes and arrays)
1224 ##
1225
1226 sub STORE {
1227         ##
1228         # Store single hash key/value or array element in database.
1229         ##
1230     my $self = _get_self($_[0]);
1231         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1232     #XXX What is ref() checking here?
1233     #YYY User may be storing a hash, in which case we do not want it run
1234     #YYY through the filtering system
1235         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1236
1237         my $unpacked_key = $key;
1238         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1239         my $md5 = $DIGEST_FUNC->($key);
1240
1241         ##
1242         # Make sure file is open
1243         ##
1244         if (!defined($self->fh) && !$self->_open()) {
1245                 return;
1246         }
1247
1248         ##
1249         # Request exclusive lock for writing
1250         ##
1251         $self->lock( LOCK_EX );
1252
1253         ##
1254         # If locking is enabled, set 'end' parameter again, in case another
1255         # DB instance appended to our file while we were unlocked.
1256         ##
1257         if ($self->root->{locking} || $self->root->{volatile}) {
1258                 $self->root->{end} = (stat($self->fh))[7];
1259         }
1260
1261         ##
1262         # Locate offset for bucket list using digest index system
1263         ##
1264         my $tag = $self->_load_tag($self->base_offset);
1265         if (!$tag) {
1266                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1267         }
1268
1269         my $ch = 0;
1270         while ($tag->{signature} ne SIG_BLIST) {
1271                 my $num = ord(substr($md5, $ch, 1));
1272                 my $new_tag = $self->_index_lookup($tag, $num);
1273                 if (!$new_tag) {
1274                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1275                         seek($self->fh, $ref_loc, 0);
1276                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
1277
1278                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1279                         $tag->{ref_loc} = $ref_loc;
1280                         $tag->{ch} = $ch;
1281                         last;
1282                 }
1283                 else {
1284                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1285                         $tag = $new_tag;
1286                         $tag->{ref_loc} = $ref_loc;
1287                         $tag->{ch} = $ch;
1288                 }
1289                 $ch++;
1290         }
1291
1292         ##
1293         # Add key/value to bucket list
1294         ##
1295         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1296
1297         ##
1298         # If this object is an array, and bucket was not a replace, and key is numerical,
1299         # and index is equal or greater than current length, advance length variable.
1300         ##
1301         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1302                 $self->STORESIZE( $unpacked_key + 1 );
1303         }
1304
1305         $self->unlock();
1306
1307         return $result;
1308 }
1309
1310 sub FETCH {
1311         ##
1312         # Fetch single value or element given plain key or array index
1313         ##
1314     my $self = _get_self($_[0]);
1315
1316     my $key = $_[1];
1317     if ( $self->type eq TYPE_HASH ) {
1318         if ( my $filter = $self->root->{filter_store_key} ) {
1319             $key = $filter->( $key );
1320         }
1321     }
1322     elsif ( $self->type eq TYPE_ARRAY ) {
1323         if ( $key =~ /^\d+$/ ) {
1324             $key = pack($LONG_PACK, $key);
1325         }
1326     }
1327
1328         my $md5 = $DIGEST_FUNC->($key);
1329
1330         ##
1331         # Make sure file is open
1332         ##
1333         if (!defined($self->fh)) { $self->_open(); }
1334
1335         ##
1336         # Request shared lock for reading
1337         ##
1338         $self->lock( LOCK_SH );
1339
1340         my $tag = $self->_find_bucket_list( $md5 );
1341         if (!$tag) {
1342                 $self->unlock();
1343                 return;
1344         }
1345
1346         ##
1347         # Get value from bucket list
1348         ##
1349         my $result = $self->_get_bucket_value( $tag, $md5 );
1350
1351         $self->unlock();
1352
1353     #XXX What is ref() checking here?
1354         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1355 }
1356
1357 sub DELETE {
1358         ##
1359         # Delete single key/value pair or element given plain key or array index
1360         ##
1361     my $self = _get_self($_[0]);
1362         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1363
1364         my $unpacked_key = $key;
1365         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1366         my $md5 = $DIGEST_FUNC->($key);
1367
1368         ##
1369         # Make sure file is open
1370         ##
1371         if (!defined($self->fh)) { $self->_open(); }
1372
1373         ##
1374         # Request exclusive lock for writing
1375         ##
1376         $self->lock( LOCK_EX );
1377
1378         my $tag = $self->_find_bucket_list( $md5 );
1379         if (!$tag) {
1380                 $self->unlock();
1381                 return;
1382         }
1383
1384         ##
1385         # Delete bucket
1386         ##
1387         my $result = $self->_delete_bucket( $tag, $md5 );
1388
1389         ##
1390         # If this object is an array and the key deleted was on the end of the stack,
1391         # decrement the length variable.
1392         ##
1393         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1394                 $self->STORESIZE( $unpacked_key );
1395         }
1396
1397         $self->unlock();
1398
1399         return $result;
1400 }
1401
1402 sub EXISTS {
1403         ##
1404         # Check if a single key or element exists given plain key or array index
1405         ##
1406     my $self = _get_self($_[0]);
1407         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1408
1409         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1410         my $md5 = $DIGEST_FUNC->($key);
1411
1412         ##
1413         # Make sure file is open
1414         ##
1415         if (!defined($self->fh)) { $self->_open(); }
1416
1417         ##
1418         # Request shared lock for reading
1419         ##
1420         $self->lock( LOCK_SH );
1421
1422         my $tag = $self->_find_bucket_list( $md5 );
1423
1424         ##
1425         # For some reason, the built-in exists() function returns '' for false
1426         ##
1427         if (!$tag) {
1428                 $self->unlock();
1429                 return '';
1430         }
1431
1432         ##
1433         # Check if bucket exists and return 1 or ''
1434         ##
1435         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1436
1437         $self->unlock();
1438
1439         return $result;
1440 }
1441
1442 sub CLEAR {
1443         ##
1444         # Clear all keys from hash, or all elements from array.
1445         ##
1446     my $self = _get_self($_[0]);
1447
1448         ##
1449         # Make sure file is open
1450         ##
1451         if (!defined($self->fh)) { $self->_open(); }
1452
1453         ##
1454         # Request exclusive lock for writing
1455         ##
1456         $self->lock( LOCK_EX );
1457
1458         seek($self->fh, $self->base_offset, 0);
1459         if ($self->fh->eof()) {
1460                 $self->unlock();
1461                 return;
1462         }
1463
1464         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1465
1466         $self->unlock();
1467
1468         return 1;
1469 }
1470
1471 sub FIRSTKEY {
1472         ##
1473         # Locate and return first key (in no particular order)
1474         ##
1475     my $self = _get_self($_[0]);
1476         if ($self->type ne TYPE_HASH) {
1477                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1478         }
1479
1480         ##
1481         # Make sure file is open
1482         ##
1483         if (!defined($self->fh)) { $self->_open(); }
1484
1485         ##
1486         # Request shared lock for reading
1487         ##
1488         $self->lock( LOCK_SH );
1489
1490         my $result = $self->_get_next_key();
1491
1492         $self->unlock();
1493
1494         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1495 }
1496
1497 sub NEXTKEY {
1498         ##
1499         # Return next key (in no particular order), given previous one
1500         ##
1501     my $self = _get_self($_[0]);
1502         if ($self->type ne TYPE_HASH) {
1503                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1504         }
1505         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1506         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1507
1508         ##
1509         # Make sure file is open
1510         ##
1511         if (!defined($self->fh)) { $self->_open(); }
1512
1513         ##
1514         # Request shared lock for reading
1515         ##
1516         $self->lock( LOCK_SH );
1517
1518         my $result = $self->_get_next_key( $prev_md5 );
1519
1520         $self->unlock();
1521
1522         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1523 }
1524
1525 ##
1526 # The following methods are for arrays only
1527 ##
1528
1529 sub FETCHSIZE {
1530         ##
1531         # Return the length of the array
1532         ##
1533     my $self = _get_self($_[0]);
1534         if ($self->type ne TYPE_ARRAY) {
1535                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1536         }
1537
1538         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1539         $self->root->{filter_fetch_value} = undef;
1540
1541         my $packed_size = $self->FETCH('length');
1542
1543         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1544
1545         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1546         else { return 0; }
1547 }
1548
1549 sub STORESIZE {
1550         ##
1551         # Set the length of the array
1552         ##
1553     my $self = _get_self($_[0]);
1554         if ($self->type ne TYPE_ARRAY) {
1555                 return $self->_throw_error("STORESIZE method only supported for arrays");
1556         }
1557         my $new_length = $_[1];
1558
1559         my $SAVE_FILTER = $self->root->{filter_store_value};
1560         $self->root->{filter_store_value} = undef;
1561
1562         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1563
1564         $self->root->{filter_store_value} = $SAVE_FILTER;
1565
1566         return $result;
1567 }
1568
1569 sub POP {
1570         ##
1571         # Remove and return the last element on the array
1572         ##
1573     my $self = _get_self($_[0]);
1574         if ($self->type ne TYPE_ARRAY) {
1575                 return $self->_throw_error("POP method only supported for arrays");
1576         }
1577         my $length = $self->FETCHSIZE();
1578
1579         if ($length) {
1580                 my $content = $self->FETCH( $length - 1 );
1581                 $self->DELETE( $length - 1 );
1582                 return $content;
1583         }
1584         else {
1585                 return;
1586         }
1587 }
1588
1589 sub PUSH {
1590         ##
1591         # Add new element(s) to the end of the array
1592         ##
1593     my $self = _get_self(shift);
1594         if ($self->type ne TYPE_ARRAY) {
1595                 return $self->_throw_error("PUSH method only supported for arrays");
1596         }
1597         my $length = $self->FETCHSIZE();
1598
1599         while (my $content = shift @_) {
1600                 $self->STORE( $length, $content );
1601                 $length++;
1602         }
1603 }
1604
1605 sub SHIFT {
1606         ##
1607         # Remove and return first element on the array.
1608         # Shift over remaining elements to take up space.
1609         ##
1610     my $self = _get_self($_[0]);
1611         if ($self->type ne TYPE_ARRAY) {
1612                 return $self->_throw_error("SHIFT method only supported for arrays");
1613         }
1614         my $length = $self->FETCHSIZE();
1615
1616         if ($length) {
1617                 my $content = $self->FETCH( 0 );
1618
1619                 ##
1620                 # Shift elements over and remove last one.
1621                 ##
1622                 for (my $i = 0; $i < $length - 1; $i++) {
1623                         $self->STORE( $i, $self->FETCH($i + 1) );
1624                 }
1625                 $self->DELETE( $length - 1 );
1626
1627                 return $content;
1628         }
1629         else {
1630                 return;
1631         }
1632 }
1633
1634 sub UNSHIFT {
1635         ##
1636         # Insert new element(s) at beginning of array.
1637         # Shift over other elements to make space.
1638         ##
1639     my $self = _get_self($_[0]);shift @_;
1640         if ($self->type ne TYPE_ARRAY) {
1641                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1642         }
1643         my @new_elements = @_;
1644         my $length = $self->FETCHSIZE();
1645         my $new_size = scalar @new_elements;
1646
1647         if ($length) {
1648                 for (my $i = $length - 1; $i >= 0; $i--) {
1649                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1650                 }
1651         }
1652
1653         for (my $i = 0; $i < $new_size; $i++) {
1654                 $self->STORE( $i, $new_elements[$i] );
1655         }
1656 }
1657
1658 sub SPLICE {
1659         ##
1660         # Splices section of array with optional new section.
1661         # Returns deleted section, or last element deleted in scalar context.
1662         ##
1663     my $self = _get_self($_[0]);shift @_;
1664         if ($self->type ne TYPE_ARRAY) {
1665                 return $self->_throw_error("SPLICE method only supported for arrays");
1666         }
1667         my $length = $self->FETCHSIZE();
1668
1669         ##
1670         # Calculate offset and length of splice
1671         ##
1672         my $offset = shift || 0;
1673         if ($offset < 0) { $offset += $length; }
1674
1675         my $splice_length;
1676         if (scalar @_) { $splice_length = shift; }
1677         else { $splice_length = $length - $offset; }
1678         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1679
1680         ##
1681         # Setup array with new elements, and copy out old elements for return
1682         ##
1683         my @new_elements = @_;
1684         my $new_size = scalar @new_elements;
1685
1686         my @old_elements = ();
1687         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1688                 push @old_elements, $self->FETCH( $i );
1689         }
1690
1691         ##
1692         # Adjust array length, and shift elements to accomodate new section.
1693         ##
1694     if ( $new_size != $splice_length ) {
1695         if ($new_size > $splice_length) {
1696             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1697                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1698             }
1699         }
1700         else {
1701             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1702                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1703             }
1704             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1705                 $self->DELETE( $length - 1 );
1706                 $length--;
1707             }
1708         }
1709         }
1710
1711         ##
1712         # Insert new elements into array
1713         ##
1714         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1715                 $self->STORE( $i, shift @new_elements );
1716         }
1717
1718         ##
1719         # Return deleted section, or last element in scalar context.
1720         ##
1721         return wantarray ? @old_elements : $old_elements[-1];
1722 }
1723
1724 #XXX We don't need to define it.
1725 #XXX It will be useful, though, when we split out HASH and ARRAY
1726 #sub EXTEND {
1727         ##
1728         # Perl will call EXTEND() when the array is likely to grow.
1729         # We don't care, but include it for compatibility.
1730         ##
1731 #}
1732
1733 ##
1734 # Public method aliases
1735 ##
1736 *put = *store = *STORE;
1737 *get = *fetch = *FETCH;
1738 *delete = *DELETE;
1739 *exists = *EXISTS;
1740 *clear = *CLEAR;
1741 *first_key = *FIRSTKEY;
1742 *next_key = *NEXTKEY;
1743 *length = *FETCHSIZE;
1744 *pop = *POP;
1745 *push = *PUSH;
1746 *shift = *SHIFT;
1747 *unshift = *UNSHIFT;
1748 *splice = *SPLICE;
1749
1750 1;
1751
1752 __END__
1753
1754 =head1 NAME
1755
1756 DBM::Deep - A pure perl multi-level hash/array DBM
1757
1758 =head1 SYNOPSIS
1759
1760   use DBM::Deep;
1761   my $db = DBM::Deep->new( "foo.db" );
1762
1763   $db->{key} = 'value'; # tie() style
1764   print $db->{key};
1765
1766   $db->put('key', 'value'); # OO style
1767   print $db->get('key');
1768
1769   # true multi-level support
1770   $db->{my_complex} = [
1771         'hello', { perl => 'rules' },
1772         42, 99 ];
1773
1774 =head1 DESCRIPTION
1775
1776 A unique flat-file database module, written in pure perl.  True
1777 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1778 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1779 handle millions of keys and unlimited hash levels without significant
1780 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1781 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1782 Mac OS X and Windows.
1783
1784 =head1 INSTALLATION
1785
1786 Hopefully you are using CPAN's excellent Perl module, which will download
1787 and install the module for you.  If not, get the tarball, and run these
1788 commands:
1789
1790         tar zxf DBM-Deep-*
1791         cd DBM-Deep-*
1792         perl Makefile.PL
1793         make
1794         make test
1795         make install
1796
1797 =head1 SETUP
1798
1799 Construction can be done OO-style (which is the recommended way), or using
1800 Perl's tie() function.  Both are examined here.
1801
1802 =head2 OO CONSTRUCTION
1803
1804 The recommended way to construct a DBM::Deep object is to use the new()
1805 method, which gets you a blessed, tied hash or array reference.
1806
1807         my $db = DBM::Deep->new( "foo.db" );
1808
1809 This opens a new database handle, mapped to the file "foo.db".  If this
1810 file does not exist, it will automatically be created.  DB files are
1811 opened in "r+" (read/write) mode, and the type of object returned is a
1812 hash, unless otherwise specified (see L<OPTIONS> below).
1813
1814
1815
1816 You can pass a number of options to the constructor to specify things like
1817 locking, autoflush, etc.  This is done by passing an inline hash:
1818
1819         my $db = DBM::Deep->new(
1820                 file => "foo.db",
1821                 locking => 1,
1822                 autoflush => 1
1823         );
1824
1825 Notice that the filename is now specified I<inside> the hash with
1826 the "file" parameter, as opposed to being the sole argument to the
1827 constructor.  This is required if any options are specified.
1828 See L<OPTIONS> below for the complete list.
1829
1830
1831
1832 You can also start with an array instead of a hash.  For this, you must
1833 specify the C<type> parameter:
1834
1835         my $db = DBM::Deep->new(
1836                 file => "foo.db",
1837                 type => DBM::Deep->TYPE_ARRAY
1838         );
1839
1840 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1841 a new DB file.  If you create a DBM::Deep object with an existing file, the
1842 C<type> will be loaded from the file header, and ignored if it is passed
1843 to the constructor.
1844
1845 =head2 TIE CONSTRUCTION
1846
1847 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1848 tie() function.  This is not ideal, because you get only a basic, tied hash
1849 (or array) which is not blessed, so you can't call any functions on it.
1850
1851         my %hash;
1852         tie %hash, "DBM::Deep", "foo.db";
1853
1854         my @array;
1855         tie @array, "DBM::Deep", "bar.db";
1856
1857 As with the OO constructor, you can replace the DB filename parameter with
1858 a hash containing one or more options (see L<OPTIONS> just below for the
1859 complete list).
1860
1861         tie %hash, "DBM::Deep", {
1862                 file => "foo.db",
1863                 locking => 1,
1864                 autoflush => 1
1865         };
1866
1867 =head2 OPTIONS
1868
1869 There are a number of options that can be passed in when constructing your
1870 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1871
1872 =over
1873
1874 =item * file
1875
1876 Filename of the DB file to link the handle to.  You can pass a full absolute
1877 filesystem path, partial path, or a plain filename if the file is in the
1878 current working directory.  This is a required parameter.
1879
1880 =item * mode
1881
1882 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1883 module.  This is an optional parameter, and defaults to "r+" (read/write).
1884 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1885 created if it doesn't exist.
1886
1887 =item * type
1888
1889 This parameter specifies what type of object to create, a hash or array.  Use
1890 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1891 This only takes effect when beginning a new file.  This is an optional
1892 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1893
1894 =item * locking
1895
1896 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1897 function to lock the database in exclusive mode for writes, and shared mode for
1898 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1899 any child hashes or arrays> that use the same DB file.  This is an optional
1900 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1901
1902 =item * autoflush
1903
1904 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1905 This obviously slows down write operations, but is required if you may have
1906 multiple processes accessing the same DB file (also consider enable I<locking>
1907 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1908 parameter, and defaults to 0 (disabled).
1909
1910 =item * volatile
1911
1912 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1913 STORE() operation.  This is required if an outside force may change the size of
1914 the file between transactions.  Locking also implicitly enables volatile.  This
1915 is useful if you want to use a different locking system or write your own.  Pass
1916 any true value to enable.  This is an optional parameter, and defaults to 0
1917 (disabled).
1918
1919 =item * autobless
1920
1921 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1922 restore them when fetched.  This is an B<experimental> feature, and does have
1923 side-effects.  Basically, when hashes are re-blessed into their original
1924 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1925 able to call any DBM::Deep methods on them.  You have been warned.
1926 This is an optional parameter, and defaults to 0 (disabled).
1927
1928 =item * filter_*
1929
1930 See L<FILTERS> below.
1931
1932 =item * debug
1933
1934 Setting I<debug> mode will make all errors non-fatal, dump them out to
1935 STDERR, and continue on.  This is for debugging purposes only, and probably
1936 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1937
1938 =item * fh
1939
1940 Instead of passing a file path, you can instead pass a handle to an pre-opened
1941 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1942 contains your entire Perl script, as well as the data following the __DATA__
1943 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1944 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1945 in that.
1946
1947 =back
1948
1949 =head1 TIE INTERFACE
1950
1951 With DBM::Deep you can access your databases using Perl's standard hash/array
1952 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1953 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1954 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1955 section above.  This simply tells you how to use DBM::Deep using regular hashes
1956 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1957 work too).  It is entirely up to you how to want to access your databases.
1958
1959 =head2 HASHES
1960
1961 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1962 or even nested hashes (or arrays) using standard Perl syntax:
1963
1964         my $db = DBM::Deep->new( "foo.db" );
1965
1966         $db->{mykey} = "myvalue";
1967         $db->{myhash} = {};
1968         $db->{myhash}->{subkey} = "subvalue";
1969
1970         print $db->{myhash}->{subkey} . "\n";
1971
1972 You can even step through hash keys using the normal Perl C<keys()> function:
1973
1974         foreach my $key (keys %$db) {
1975                 print "$key: " . $db->{$key} . "\n";
1976         }
1977
1978 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1979 pushes them onto an array, all before the loop even begins.  If you have an
1980 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1981 Perl's C<each()> function, which pulls keys/values one at a time, using very
1982 little memory:
1983
1984         while (my ($key, $value) = each %$db) {
1985                 print "$key: $value\n";
1986         }
1987
1988 Please note that when using C<each()>, you should always pass a direct
1989 hash reference, not a lookup.  Meaning, you should B<never> do this:
1990
1991         # NEVER DO THIS
1992         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1993
1994 This causes an infinite loop, because for each iteration, Perl is calling
1995 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1996 it effectively keeps returning the first key over and over again. Instead,
1997 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1998
1999 =head2 ARRAYS
2000
2001 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2002 reference.  This includes inserting, removing and manipulating elements,
2003 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2004 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2005 or simply be a nested array reference inside a hash.  Example:
2006
2007         my $db = DBM::Deep->new(
2008                 file => "foo-array.db",
2009                 type => DBM::Deep->TYPE_ARRAY
2010         );
2011
2012         $db->[0] = "foo";
2013         push @$db, "bar", "baz";
2014         unshift @$db, "bah";
2015
2016         my $last_elem = pop @$db; # baz
2017         my $first_elem = shift @$db; # bah
2018         my $second_elem = $db->[1]; # bar
2019
2020         my $num_elements = scalar @$db;
2021
2022 =head1 OO INTERFACE
2023
2024 In addition to the I<tie()> interface, you can also use a standard OO interface
2025 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2026 array) has its own methods, but both types share the following common methods:
2027 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2028
2029 =over
2030
2031 =item * put()
2032
2033 Stores a new hash key/value pair, or sets an array element value.  Takes two
2034 arguments, the hash key or array index, and the new value.  The value can be
2035 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2036
2037         $db->put("foo", "bar"); # for hashes
2038         $db->put(1, "bar"); # for arrays
2039
2040 =item * get()
2041
2042 Fetches the value of a hash key or array element.  Takes one argument: the hash
2043 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2044 data type stored.
2045
2046         my $value = $db->get("foo"); # for hashes
2047         my $value = $db->get(1); # for arrays
2048
2049 =item * exists()
2050
2051 Checks if a hash key or array index exists.  Takes one argument: the hash key
2052 or array index.  Returns true if it exists, false if not.
2053
2054         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2055         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2056
2057 =item * delete()
2058
2059 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2060 key or array index.  Returns true on success, false if not found.  For arrays,
2061 the remaining elements located after the deleted element are NOT moved over.
2062 The deleted element is essentially just undefined, which is exactly how Perl's
2063 internal arrays work.  Please note that the space occupied by the deleted
2064 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2065 below for details and workarounds.
2066
2067         $db->delete("foo"); # for hashes
2068         $db->delete(1); # for arrays
2069
2070 =item * clear()
2071
2072 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2073 value.  Please note that the space occupied by the deleted keys/values or
2074 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2075 details and workarounds.
2076
2077         $db->clear(); # hashes or arrays
2078
2079 =back
2080
2081 =head2 HASHES
2082
2083 For hashes, DBM::Deep supports all the common methods described above, and the
2084 following additional methods: C<first_key()> and C<next_key()>.
2085
2086 =over
2087
2088 =item * first_key()
2089
2090 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2091 fetched in an undefined order (which appears random).  Takes no arguments,
2092 returns the key as a scalar value.
2093
2094         my $key = $db->first_key();
2095
2096 =item * next_key()
2097
2098 Returns the "next" key in the hash, given the previous one as the sole argument.
2099 Returns undef if there are no more keys to be fetched.
2100
2101         $key = $db->next_key($key);
2102
2103 =back
2104
2105 Here are some examples of using hashes:
2106
2107         my $db = DBM::Deep->new( "foo.db" );
2108
2109         $db->put("foo", "bar");
2110         print "foo: " . $db->get("foo") . "\n";
2111
2112         $db->put("baz", {}); # new child hash ref
2113         $db->get("baz")->put("buz", "biz");
2114         print "buz: " . $db->get("baz")->get("buz") . "\n";
2115
2116         my $key = $db->first_key();
2117         while ($key) {
2118                 print "$key: " . $db->get($key) . "\n";
2119                 $key = $db->next_key($key);
2120         }
2121
2122         if ($db->exists("foo")) { $db->delete("foo"); }
2123
2124 =head2 ARRAYS
2125
2126 For arrays, DBM::Deep supports all the common methods described above, and the
2127 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2128 C<unshift()> and C<splice()>.
2129
2130 =over
2131
2132 =item * length()
2133
2134 Returns the number of elements in the array.  Takes no arguments.
2135
2136         my $len = $db->length();
2137
2138 =item * push()
2139
2140 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2141 refs or array refs.  No return value.
2142
2143         $db->push("foo", "bar", {});
2144
2145 =item * pop()
2146
2147 Fetches the last element in the array, and deletes it.  Takes no arguments.
2148 Returns undef if array is empty.  Returns the element value.
2149
2150         my $elem = $db->pop();
2151
2152 =item * shift()
2153
2154 Fetches the first element in the array, deletes it, then shifts all the
2155 remaining elements over to take up the space.  Returns the element value.  This
2156 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2157 details.
2158
2159         my $elem = $db->shift();
2160
2161 =item * unshift()
2162
2163 Inserts one or more elements onto the beginning of the array, shifting all
2164 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2165 No return value.  This method is not recommended with large arrays -- see
2166 <LARGE ARRAYS> below for details.
2167
2168         $db->unshift("foo", "bar", {});
2169
2170 =item * splice()
2171
2172 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2173 -f splice> for usage -- it is too complicated to document here.  This method is
2174 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2175
2176 =back
2177
2178 Here are some examples of using arrays:
2179
2180         my $db = DBM::Deep->new(
2181                 file => "foo.db",
2182                 type => DBM::Deep->TYPE_ARRAY
2183         );
2184
2185         $db->push("bar", "baz");
2186         $db->unshift("foo");
2187         $db->put(3, "buz");
2188
2189         my $len = $db->length();
2190         print "length: $len\n"; # 4
2191
2192         for (my $k=0; $k<$len; $k++) {
2193                 print "$k: " . $db->get($k) . "\n";
2194         }
2195
2196         $db->splice(1, 2, "biz", "baf");
2197
2198         while (my $elem = shift @$db) {
2199                 print "shifted: $elem\n";
2200         }
2201
2202 =head1 LOCKING
2203
2204 Enable automatic file locking by passing a true value to the C<locking>
2205 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2206
2207         my $db = DBM::Deep->new(
2208                 file => "foo.db",
2209                 locking => 1
2210         );
2211
2212 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2213 mode for writes, and shared mode for reads.  This is required if you have
2214 multiple processes accessing the same database file, to avoid file corruption.
2215 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2216 NFS> below for more.
2217
2218 =head2 EXPLICIT LOCKING
2219
2220 You can explicitly lock a database, so it remains locked for multiple
2221 transactions.  This is done by calling the C<lock()> method, and passing an
2222 optional lock mode argument (defaults to exclusive mode).  This is particularly
2223 useful for things like counters, where the current value needs to be fetched,
2224 then incremented, then stored again.
2225
2226         $db->lock();
2227         my $counter = $db->get("counter");
2228         $counter++;
2229         $db->put("counter", $counter);
2230         $db->unlock();
2231
2232         # or...
2233
2234         $db->lock();
2235         $db->{counter}++;
2236         $db->unlock();
2237
2238 You can pass C<lock()> an optional argument, which specifies which mode to use
2239 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2240 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2241 same as the constants defined in Perl's C<Fcntl> module.
2242
2243         $db->lock( DBM::Deep->LOCK_SH );
2244         # something here
2245         $db->unlock();
2246
2247 If you want to implement your own file locking scheme, be sure to create your
2248 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2249 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2250 below for more.
2251
2252 =head1 IMPORTING/EXPORTING
2253
2254 You can import existing complex structures by calling the C<import()> method,
2255 and export an entire database into an in-memory structure using the C<export()>
2256 method.  Both are examined here.
2257
2258 =head2 IMPORTING
2259
2260 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2261 walking the structure and adding keys/elements to the database as you go,
2262 simply pass a reference to the C<import()> method.  This recursively adds
2263 everything to an existing DBM::Deep object for you.  Here is an example:
2264
2265         my $struct = {
2266                 key1 => "value1",
2267                 key2 => "value2",
2268                 array1 => [ "elem0", "elem1", "elem2" ],
2269                 hash1 => {
2270                         subkey1 => "subvalue1",
2271                         subkey2 => "subvalue2"
2272                 }
2273         };
2274
2275         my $db = DBM::Deep->new( "foo.db" );
2276         $db->import( $struct );
2277
2278         print $db->{key1} . "\n"; # prints "value1"
2279
2280 This recursively imports the entire C<$struct> object into C<$db>, including
2281 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2282 keys are merged with the existing ones, replacing if they already exist.
2283 The C<import()> method can be called on any database level (not just the base
2284 level), and works with both hash and array DB types.
2285
2286
2287
2288 B<Note:> Make sure your existing structure has no circular references in it.
2289 These will cause an infinite loop when importing.
2290
2291 =head2 EXPORTING
2292
2293 Calling the C<export()> method on an existing DBM::Deep object will return
2294 a reference to a new in-memory copy of the database.  The export is done
2295 recursively, so all nested hashes/arrays are all exported to standard Perl
2296 objects.  Here is an example:
2297
2298         my $db = DBM::Deep->new( "foo.db" );
2299
2300         $db->{key1} = "value1";
2301         $db->{key2} = "value2";
2302         $db->{hash1} = {};
2303         $db->{hash1}->{subkey1} = "subvalue1";
2304         $db->{hash1}->{subkey2} = "subvalue2";
2305
2306         my $struct = $db->export();
2307
2308         print $struct->{key1} . "\n"; # prints "value1"
2309
2310 This makes a complete copy of the database in memory, and returns a reference
2311 to it.  The C<export()> method can be called on any database level (not just
2312 the base level), and works with both hash and array DB types.  Be careful of
2313 large databases -- you can store a lot more data in a DBM::Deep object than an
2314 in-memory Perl structure.
2315
2316
2317
2318 B<Note:> Make sure your database has no circular references in it.
2319 These will cause an infinite loop when exporting.
2320
2321 =head1 FILTERS
2322
2323 DBM::Deep has a number of hooks where you can specify your own Perl function
2324 to perform filtering on incoming or outgoing data.  This is a perfect
2325 way to extend the engine, and implement things like real-time compression or
2326 encryption.  Filtering applies to the base DB level, and all child hashes /
2327 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2328 constructed, or by calling the C<set_filter()> method at any time.  There are
2329 four available filter hooks, described below:
2330
2331 =over
2332
2333 =item * filter_store_key
2334
2335 This filter is called whenever a hash key is stored.  It
2336 is passed the incoming key, and expected to return a transformed key.
2337
2338 =item * filter_store_value
2339
2340 This filter is called whenever a hash key or array element is stored.  It
2341 is passed the incoming value, and expected to return a transformed value.
2342
2343 =item * filter_fetch_key
2344
2345 This filter is called whenever a hash key is fetched (i.e. via
2346 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2347 and expected to return the plain key.
2348
2349 =item * filter_fetch_value
2350
2351 This filter is called whenever a hash key or array element is fetched.
2352 It is passed the transformed value, and expected to return the plain value.
2353
2354 =back
2355
2356 Here are the two ways to setup a filter hook:
2357
2358         my $db = DBM::Deep->new(
2359                 file => "foo.db",
2360                 filter_store_value => \&my_filter_store,
2361                 filter_fetch_value => \&my_filter_fetch
2362         );
2363
2364         # or...
2365
2366         $db->set_filter( "filter_store_value", \&my_filter_store );
2367         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2368
2369 Your filter function will be called only when dealing with SCALAR keys or
2370 values.  When nested hashes and arrays are being stored/fetched, filtering
2371 is bypassed.  Filters are called as static functions, passed a single SCALAR
2372 argument, and expected to return a single SCALAR value.  If you want to
2373 remove a filter, set the function reference to C<undef>:
2374
2375         $db->set_filter( "filter_store_value", undef );
2376
2377 =head2 REAL-TIME ENCRYPTION EXAMPLE
2378
2379 Here is a working example that uses the I<Crypt::Blowfish> module to
2380 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2381 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2382 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2383
2384         use DBM::Deep;
2385         use Crypt::Blowfish;
2386         use Crypt::CBC;
2387
2388         my $cipher = Crypt::CBC->new({
2389                 'key'             => 'my secret key',
2390                 'cipher'          => 'Blowfish',
2391                 'iv'              => '$KJh#(}q',
2392                 'regenerate_key'  => 0,
2393                 'padding'         => 'space',
2394                 'prepend_iv'      => 0
2395         });
2396
2397         my $db = DBM::Deep->new(
2398                 file => "foo-encrypt.db",
2399                 filter_store_key => \&my_encrypt,
2400                 filter_store_value => \&my_encrypt,
2401                 filter_fetch_key => \&my_decrypt,
2402                 filter_fetch_value => \&my_decrypt,
2403         );
2404
2405         $db->{key1} = "value1";
2406         $db->{key2} = "value2";
2407         print "key1: " . $db->{key1} . "\n";
2408         print "key2: " . $db->{key2} . "\n";
2409
2410         undef $db;
2411         exit;
2412
2413         sub my_encrypt {
2414                 return $cipher->encrypt( $_[0] );
2415         }
2416         sub my_decrypt {
2417                 return $cipher->decrypt( $_[0] );
2418         }
2419
2420 =head2 REAL-TIME COMPRESSION EXAMPLE
2421
2422 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2423 compression / decompression of keys & values with DBM::Deep Filters.
2424 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2425 more on I<Compress::Zlib>.
2426
2427         use DBM::Deep;
2428         use Compress::Zlib;
2429
2430         my $db = DBM::Deep->new(
2431                 file => "foo-compress.db",
2432                 filter_store_key => \&my_compress,
2433                 filter_store_value => \&my_compress,
2434                 filter_fetch_key => \&my_decompress,
2435                 filter_fetch_value => \&my_decompress,
2436         );
2437
2438         $db->{key1} = "value1";
2439         $db->{key2} = "value2";
2440         print "key1: " . $db->{key1} . "\n";
2441         print "key2: " . $db->{key2} . "\n";
2442
2443         undef $db;
2444         exit;
2445
2446         sub my_compress {
2447                 return Compress::Zlib::memGzip( $_[0] ) ;
2448         }
2449         sub my_decompress {
2450                 return Compress::Zlib::memGunzip( $_[0] ) ;
2451         }
2452
2453 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2454 actually numerical index numbers, and are not filtered.
2455
2456 =head1 ERROR HANDLING
2457
2458 Most DBM::Deep methods return a true value for success, and call die() on
2459 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2460 actual error message is stored in an internal scalar, which can be fetched by
2461 calling the C<error()> method.
2462
2463         my $db = DBM::Deep->new( "foo.db" ); # create hash
2464         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2465
2466         print $db->error(); # prints error message
2467
2468 You can then call C<clear_error()> to clear the current error state.
2469
2470         $db->clear_error();
2471
2472 If you set the C<debug> option to true when creating your DBM::Deep object,
2473 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2474 for debugging purposes.
2475
2476 =head1 LARGEFILE SUPPORT
2477
2478 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2479 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2480 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2481 by calling the static C<set_pack()> method before you do anything else.
2482
2483         DBM::Deep::set_pack(8, 'Q');
2484
2485 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2486 instead of 32-bit longs.  After setting these values your DB files have a
2487 theoretical maximum size of 16 XB (exabytes).
2488
2489
2490
2491 B<Note:> Changing these values will B<NOT> work for existing database files.
2492 Only change this for new files, and make sure it stays set consistently
2493 throughout the file's life.  If you do set these values, you can no longer
2494 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2495 back to 32-bit mode.
2496
2497
2498
2499 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2500 only a 32-bit Perl.  However, I have received user reports that this does
2501 indeed work!
2502
2503 =head1 LOW-LEVEL ACCESS
2504
2505 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2506 you can call the C<fh()> method, which returns the handle:
2507
2508         my $fh = $db->fh();
2509
2510 This method can be called on the root level of the datbase, or any child
2511 hashes or arrays.  All levels share a I<root> structure, which contains things
2512 like the FileHandle, a reference counter, and all your options you specified
2513 when you created the object.  You can get access to this root structure by
2514 calling the C<root()> method.
2515
2516         my $root = $db->root();
2517
2518 This is useful for changing options after the object has already been created,
2519 such as enabling/disabling locking, volatile or debug modes.  You can also
2520 store your own temporary user data in this structure (be wary of name
2521 collision), which is then accessible from any child hash or array.
2522
2523 =head1 CUSTOM DIGEST ALGORITHM
2524
2525 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2526 keys.  However you can override this, and use another algorithm (such as SHA-256)
2527 or even write your own.  But please note that DBM::Deep currently expects zero
2528 collisions, so your algorithm has to be I<perfect>, so to speak.
2529 Collision detection may be introduced in a later version.
2530
2531
2532
2533 You can specify a custom digest algorithm by calling the static C<set_digest()>
2534 function, passing a reference to a subroutine, and the length of the algorithm's
2535 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2536 objects.  Here is a working example that uses a 256-bit hash from the
2537 I<Digest::SHA256> module.  Please see
2538 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2539
2540         use DBM::Deep;
2541         use Digest::SHA256;
2542
2543         my $context = Digest::SHA256::new(256);
2544
2545         DBM::Deep::set_digest( \&my_digest, 32 );
2546
2547         my $db = DBM::Deep->new( "foo-sha.db" );
2548
2549         $db->{key1} = "value1";
2550         $db->{key2} = "value2";
2551         print "key1: " . $db->{key1} . "\n";
2552         print "key2: " . $db->{key2} . "\n";
2553
2554         undef $db;
2555         exit;
2556
2557         sub my_digest {
2558                 return substr( $context->hash($_[0]), 0, 32 );
2559         }
2560
2561 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2562 of bytes you specify in the C<set_digest()> function (in this case 32).
2563
2564 =head1 CIRCULAR REFERENCES
2565
2566 DBM::Deep has B<experimental> support for circular references.  Meaning you
2567 can have a nested hash key or array element that points to a parent object.
2568 This relationship is stored in the DB file, and is preserved between sessions.
2569 Here is an example:
2570
2571         my $db = DBM::Deep->new( "foo.db" );
2572
2573         $db->{foo} = "bar";
2574         $db->{circle} = $db; # ref to self
2575
2576         print $db->{foo} . "\n"; # prints "foo"
2577         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2578
2579 One catch is, passing the object to a function that recursively walks the
2580 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2581 C<export()> methods) will result in an infinite loop.  The other catch is,
2582 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2583 or C<next_key()> methods), you will get the I<target object's key>, not the
2584 ref's key.  This gets even more interesting with the above example, where
2585 the I<circle> key points to the base DB object, which technically doesn't
2586 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2587 special case.
2588
2589 =head1 CAVEATS / ISSUES / BUGS
2590
2591 This section describes all the known issues with DBM::Deep.  It you have found
2592 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2593
2594 =head2 UNUSED SPACE RECOVERY
2595
2596 One major caveat with DBM::Deep is that space occupied by existing keys and
2597 values is not recovered when they are deleted.  Meaning if you keep deleting
2598 and adding new keys, your file will continuously grow.  I am working on this,
2599 but in the meantime you can call the built-in C<optimize()> method from time to
2600 time (perhaps in a crontab or something) to recover all your unused space.
2601
2602         $db->optimize(); # returns true on success
2603
2604 This rebuilds the ENTIRE database into a new file, then moves it on top of
2605 the original.  The new file will have no unused space, thus it will take up as
2606 little disk space as possible.  Please note that this operation can take
2607 a long time for large files, and you need enough disk space to temporarily hold
2608 2 copies of your DB file.  The temporary file is created in the same directory
2609 as the original, named with a ".tmp" extension, and is deleted when the
2610 operation completes.  Oh, and if locking is enabled, the DB is automatically
2611 locked for the entire duration of the copy.
2612
2613
2614
2615 B<WARNING:> Only call optimize() on the top-level node of the database, and
2616 make sure there are no child references lying around.  DBM::Deep keeps a reference
2617 counter, and if it is greater than 1, optimize() will abort and return undef.
2618
2619 =head2 AUTOVIVIFICATION
2620
2621 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2622 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2623 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2624 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2625 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2626 this does not work:
2627
2628         $db->{foo}->{bar} = "hello";
2629
2630 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2631 being an empty hash.  Try this instead, which works fine:
2632
2633         $db->{foo} = { bar => "hello" };
2634
2635 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2636 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2637 Probably a bug in Perl.
2638
2639 =head2 FILE CORRUPTION
2640
2641 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2642 for a 32-bit signature when opened, but other corruption in files can cause
2643 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2644 stuck in an infinite loop depending on the level of corruption.  File write
2645 operations are not checked for failure (for speed), so if you happen to run
2646 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2647 be addressed in a later version of DBM::Deep.
2648
2649 =head2 DB OVER NFS
2650
2651 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2652 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2653 about setting up your NFS server with a locking daemon, then using lockf() to
2654 lock your files, but your milage may vary there as well.  From what I
2655 understand, there is no real way to do it.  However, if you need access to the
2656 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2657 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2658
2659 =head2 COPYING OBJECTS
2660
2661 Beware of copying tied objects in Perl.  Very strange things can happen.
2662 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2663 returns a new, blessed, tied hash or array to the same level in the DB.
2664
2665         my $copy = $db->clone();
2666
2667 =head2 LARGE ARRAYS
2668
2669 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2670 These functions cause every element in the array to move, which can be murder
2671 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2672 a different location.  This may be addressed in a later version.
2673
2674 =head1 PERFORMANCE
2675
2676 This section discusses DBM::Deep's speed and memory usage.
2677
2678 =head2 SPEED
2679
2680 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2681 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2682 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2683 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2684 with huge databases.  Here is some test data:
2685
2686         Adding 1,000,000 keys to new DB file...
2687
2688         At 100 keys, avg. speed is 2,703 keys/sec
2689         At 200 keys, avg. speed is 2,642 keys/sec
2690         At 300 keys, avg. speed is 2,598 keys/sec
2691         At 400 keys, avg. speed is 2,578 keys/sec
2692         At 500 keys, avg. speed is 2,722 keys/sec
2693         At 600 keys, avg. speed is 2,628 keys/sec
2694         At 700 keys, avg. speed is 2,700 keys/sec
2695         At 800 keys, avg. speed is 2,607 keys/sec
2696         At 900 keys, avg. speed is 2,190 keys/sec
2697         At 1,000 keys, avg. speed is 2,570 keys/sec
2698         At 2,000 keys, avg. speed is 2,417 keys/sec
2699         At 3,000 keys, avg. speed is 1,982 keys/sec
2700         At 4,000 keys, avg. speed is 1,568 keys/sec
2701         At 5,000 keys, avg. speed is 1,533 keys/sec
2702         At 6,000 keys, avg. speed is 1,787 keys/sec
2703         At 7,000 keys, avg. speed is 1,977 keys/sec
2704         At 8,000 keys, avg. speed is 2,028 keys/sec
2705         At 9,000 keys, avg. speed is 2,077 keys/sec
2706         At 10,000 keys, avg. speed is 2,031 keys/sec
2707         At 20,000 keys, avg. speed is 1,970 keys/sec
2708         At 30,000 keys, avg. speed is 2,050 keys/sec
2709         At 40,000 keys, avg. speed is 2,073 keys/sec
2710         At 50,000 keys, avg. speed is 1,973 keys/sec
2711         At 60,000 keys, avg. speed is 1,914 keys/sec
2712         At 70,000 keys, avg. speed is 2,091 keys/sec
2713         At 80,000 keys, avg. speed is 2,103 keys/sec
2714         At 90,000 keys, avg. speed is 1,886 keys/sec
2715         At 100,000 keys, avg. speed is 1,970 keys/sec
2716         At 200,000 keys, avg. speed is 2,053 keys/sec
2717         At 300,000 keys, avg. speed is 1,697 keys/sec
2718         At 400,000 keys, avg. speed is 1,838 keys/sec
2719         At 500,000 keys, avg. speed is 1,941 keys/sec
2720         At 600,000 keys, avg. speed is 1,930 keys/sec
2721         At 700,000 keys, avg. speed is 1,735 keys/sec
2722         At 800,000 keys, avg. speed is 1,795 keys/sec
2723         At 900,000 keys, avg. speed is 1,221 keys/sec
2724         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2725
2726 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2727 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2728 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2729 Run time was 12 min 3 sec.
2730
2731 =head2 MEMORY USAGE
2732
2733 One of the great things about DBM::Deep is that it uses very little memory.
2734 Even with huge databases (1,000,000+ keys) you will not see much increased
2735 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2736 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2737 database handle:
2738
2739           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2740         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2741
2742 Basically the process is taking 2,716K of memory.  And here is the same
2743 process after storing and fetching 1,000,000 keys:
2744
2745           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2746         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2747
2748 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2749 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2750
2751 =head1 DB FILE FORMAT
2752
2753 In case you were interested in the underlying DB file format, it is documented
2754 here in this section.  You don't need to know this to use the module, it's just
2755 included for reference.
2756
2757 =head2 SIGNATURE
2758
2759 DBM::Deep files always start with a 32-bit signature to identify the file type.
2760 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2761 checked when the file is opened.
2762
2763 =head2 TAG
2764
2765 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2766 has a standard header containing the type of data, the length of data, and then
2767 the data itself.  The type is a single character (1 byte), the length is a
2768 32-bit unsigned long in network byte order, and the data is, well, the data.
2769 Here is how it unfolds:
2770
2771 =head2 MASTER INDEX
2772
2773 Immediately after the 32-bit file signature is the I<Master Index> record.
2774 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2775 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2776 depending on how the DBM::Deep object was constructed.
2777
2778
2779
2780 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2781 number).  The first 8-bit char of the MD5 signature is the offset into the
2782 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2783 index element is a file offset of the next tag for the key/element in question,
2784 which is usually a I<Bucket List> tag (see below).
2785
2786
2787
2788 The next tag I<could> be another index, depending on how many keys/elements
2789 exist.  See L<RE-INDEXING> below for details.
2790
2791 =head2 BUCKET LIST
2792
2793 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2794 file offsets to where the actual data is stored.  It starts with a standard
2795 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2796 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2797 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2798 When the list fills up, a I<Re-Index> operation is performed (See
2799 L<RE-INDEXING> below).
2800
2801 =head2 BUCKET
2802
2803 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2804 index/value pair (in array mode).  It starts with a standard tag header with
2805 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2806 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2807 header.  The size reported in the tag header is only for the value, but then,
2808 just after the value is another size (32-bit unsigned long) and then the plain
2809 key itself.  Since the value is likely to be fetched more often than the plain
2810 key, I figured it would be I<slightly> faster to store the value first.
2811
2812
2813
2814 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2815 record for the nested structure, where the process begins all over again.
2816
2817 =head2 RE-INDEXING
2818
2819 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2820 exhausted.  Then, when another key/element comes in, the list is converted to a
2821 new index record.  However, this index will look at the next char in the MD5
2822 hash, and arrange new Bucket List pointers accordingly.  This process is called
2823 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2824 17 (16 + new one) keys/elements are removed from the old Bucket List and
2825 inserted into the new index.  Several new Bucket Lists are created in the
2826 process, as a new MD5 char from the key is being examined (it is unlikely that
2827 the keys will all share the same next char of their MD5s).
2828
2829
2830
2831 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2832 when the Bucket Lists will turn into indexes, but the first round tends to
2833 happen right around 4,000 keys.  You will see a I<slight> decrease in
2834 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2835 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2836 right around 900,000 keys.  This process can continue nearly indefinitely --
2837 right up until the point the I<MD5> signatures start colliding with each other,
2838 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2839 getting struck by lightning while you are walking to cash in your tickets.
2840 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2841 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2842 this is 340 unodecillion, but don't quote me).
2843
2844 =head2 STORING
2845
2846 When a new key/element is stored, the key (or index number) is first ran through
2847 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2848 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2849 for the first char of the signature (in this case I<b>).  If it does not exist,
2850 a new I<Bucket List> is created for our key (and the next 15 future keys that
2851 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2852 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2853 this point, unless we are replacing an existing I<Bucket>), where the actual
2854 data will be stored.
2855
2856 =head2 FETCHING
2857
2858 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2859 (or index number), then walking along the indexes.  If there are enough
2860 keys/elements in this DB level, there might be nested indexes, each linked to
2861 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2862 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2863 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2864 plain key are stored.
2865
2866
2867
2868 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2869 methods.  In this process the indexes are walked systematically, and each key
2870 fetched in increasing MD5 order (which is why it appears random).   Once the
2871 I<Bucket> is found, the value is skipped the plain key returned instead.
2872 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2873 alphabetically sorted.  This only happens on an index-level -- as soon as the
2874 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2875 so it's pretty much undefined how the keys will come out -- just like Perl's
2876 built-in hashes.
2877
2878 =head1 CODE COVERAGE
2879
2880 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2881 module's test suite.
2882
2883   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2884   File                           stmt   bran   cond    sub    pod   time  total
2885   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2886   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2887   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2888   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2889
2890 =head1 AUTHOR
2891
2892 Joseph Huckaby, L<jhuckaby@cpan.org>
2893
2894 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2895
2896 =head1 SEE ALSO
2897
2898 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2899 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2900
2901 =head1 LICENSE
2902
2903 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2904 This is free software, you may use it and distribute it under the
2905 same terms as Perl itself.
2906
2907 =cut