lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.97);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a fh to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         my $fh;
 215         sysopen( $fh, $self->root->{file}, $flags )
 216             or $fh = undef;
 217         $self->root->{fh} = $fh;
 218     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 219         if (! defined($self->fh)) {
 220                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 221         }
 222
 223     my $fh = $self->fh;
 224
 225     #XXX Can we remove this by using the right sysopen() flags?
 226     # Maybe ... q.v. above
 227     binmode $fh; # for win32
 228
 229     if ($self->root->{autoflush}) {
 230         my $old = select $fh;
 231         $|=1;
 232         select $old;
 233     }
 234
 235     # Set the
 236     seek($fh, 0, SEEK_SET);
 237
 238     my $signature;
 239     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 240
 241     ##
 242     # File is empty -- write signature and master index
 243     ##
 244     if (!$bytes_read) {
 245         seek($fh, 0, SEEK_SET);
 246         print($fh SIG_FILE);
 247         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 248
 249         my $plain_key = "[base]";
 250         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 251
 252         # Flush the filehandle
 253         my $old_fh = select $fh;
 254         my $old_af = $|;
 255         $| = 1;
 256         $| = $old_af;
 257         select $old_fh;
 258
 259         my @stats = stat($fh);
 260         $self->root->{inode} = $stats[1];
 261         $self->root->{end} = $stats[7];
 262
 263         return 1;
 264     }
 265
 266     ##
 267     # Check signature was valid
 268     ##
 269     unless ($signature eq SIG_FILE) {
 270         $self->_close();
 271         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 272     }
 273
 274         my @stats = stat($fh);
 275         $self->root->{inode} = $stats[1];
 276     $self->root->{end} = $stats[7];
 277
 278     ##
 279     # Get our type from master index signature
 280     ##
 281     my $tag = $self->_load_tag($self->base_offset);
 282
 283 #XXX We probably also want to store the hash algorithm name and not assume anything
 284 #XXX The cool thing would be to allow a different hashing algorithm at every level
 285
 286     if (!$tag) {
 287         return $self->_throw_error("Corrupted file, no master index record");
 288     }
 289     if ($self->{type} ne $tag->{signature}) {
 290         return $self->_throw_error("File type mismatch");
 291     }
 292
 293     return 1;
 294 }
 295
 296 sub _close {
 297         ##
 298         # Close database fh
 299         ##
 300     my $self = $_[0]->_get_self;
 301     close $self->root->{fh} if $self->root->{fh};
 302     $self->root->{fh} = undef;
 303 }
 304
 305 sub _create_tag {
 306         ##
 307         # Given offset, signature and content, create tag and write to disk
 308         ##
 309         my ($self, $offset, $sig, $content) = @_;
 310         my $size = length($content);
 311
 312     my $fh = $self->fh;
 313
 314         seek($fh, $offset, SEEK_SET);
 315         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 316
 317         if ($offset == $self->root->{end}) {
 318                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 319         }
 320
 321         return {
 322                 signature => $sig,
 323                 size => $size,
 324                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 325                 content => $content
 326         };
 327 }
 328
 329 sub _load_tag {
 330         ##
 331         # Given offset, load single tag and return signature, size and data
 332         ##
 333         my $self = shift;
 334         my $offset = shift;
 335
 336     my $fh = $self->fh;
 337
 338         seek($fh, $offset, SEEK_SET);
 339         if (eof $fh) { return undef; }
 340
 341         my $sig;
 342         read( $fh, $sig, SIG_SIZE);
 343
 344         my $size;
 345         read( $fh, $size, $DATA_LENGTH_SIZE);
 346         $size = unpack($DATA_LENGTH_PACK, $size);
 347
 348         my $buffer;
 349         read( $fh, $buffer, $size);
 350
 351         return {
 352                 signature => $sig,
 353                 size => $size,
 354                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 355                 content => $buffer
 356         };
 357 }
 358
 359 sub _index_lookup {
 360         ##
 361         # Given index tag, lookup single entry in index and return .
 362         ##
 363         my $self = shift;
 364         my ($tag, $index) = @_;
 365
 366         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 367         if (!$location) { return; }
 368
 369         return $self->_load_tag( $location );
 370 }
 371
 372 sub _add_bucket {
 373         ##
 374         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 375         # plain (undigested) key and value.
 376         ##
 377         my $self = shift;
 378         my ($tag, $md5, $plain_key, $value) = @_;
 379         my $keys = $tag->{content};
 380         my $location = 0;
 381         my $result = 2;
 382
 383         # added ref() check first to avoid eval and runtime exception for every
 384         # scalar value being stored.  performance tweak.
 385     my $is_dbm_deep = ref($value) && eval { $value->isa( 'DBM::Deep' ) };
 386
 387         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 388
 389     my $fh = $self->fh;
 390
 391         ##
 392         # Iterate through buckets, seeing if this is a new entry or a replace.
 393         ##
 394         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 395                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 396                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 397                 if (!$subloc) {
 398                         ##
 399                         # Found empty bucket (end of list).  Populate and exit loop.
 400                         ##
 401                         $result = 2;
 402
 403             $location = $internal_ref
 404                 ? $value->base_offset
 405                 : $self->root->{end};
 406
 407                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 408                         print($fh $md5 . pack($LONG_PACK, $location) );
 409                         last;
 410                 }
 411                 elsif ($md5 eq $key) {
 412                         ##
 413                         # Found existing bucket with same key.  Replace with new value.
 414                         ##
 415                         $result = 1;
 416
 417                         if ($internal_ref) {
 418                                 $location = $value->base_offset;
 419                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 420                                 print($fh $md5 . pack($LONG_PACK, $location) );
 421                         }
 422                         else {
 423                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 424                                 my $size;
 425                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 426
 427                                 ##
 428                                 # If value is a hash, array, or raw value with equal or less size, we can
 429                                 # reuse the same content area of the database.  Otherwise, we have to create
 430                                 # a new content area at the EOF.
 431                                 ##
 432                                 my $actual_length;
 433                 my $r = Scalar::Util::reftype( $value ) || '';
 434                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 435                         $actual_length = $INDEX_SIZE;
 436
 437                         # if autobless is enabled, must also take into consideration
 438                         # the class name, as it is stored along with key/value.
 439                         if ( $self->root->{autobless} ) {
 440                                                 my $value_class = Scalar::Util::blessed($value);
 441                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 442                                                         $actual_length += length($value_class);
 443                                                 }
 444                                         } # autobless
 445                 }
 446                                 else { $actual_length = length($value); }
 447
 448                                 if ($actual_length <= $size) {
 449                                         $location = $subloc;
 450                                 }
 451                                 else {
 452                                         $location = $self->root->{end};
 453                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 454                                         print($fh pack($LONG_PACK, $location) );
 455                                 }
 456                         }
 457                         last;
 458                 }
 459         } # i loop
 460
 461         ##
 462         # If this is an internal reference, return now.
 463         # No need to write value or plain key
 464         ##
 465         if ($internal_ref) {
 466         return $result;
 467     }
 468
 469         ##
 470         # If bucket didn't fit into list, split into a new index level
 471         ##
 472         if (!$location) {
 473                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 474                 print($fh pack($LONG_PACK, $self->root->{end}) );
 475
 476                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 477                 my @offsets = ();
 478
 479                 $keys .= $md5 . pack($LONG_PACK, 0);
 480
 481                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 482                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 483                         if ($key) {
 484                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 485                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 486
 487                                 if ($offsets[$num]) {
 488                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 489                                         seek($fh, $offset, SEEK_SET);
 490                                         my $subkeys;
 491                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 492
 493                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 494                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 495                                                 if (!$subloc) {
 496                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 497                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 498                                                         last;
 499                                                 }
 500                                         } # k loop
 501                                 }
 502                                 else {
 503                                         $offsets[$num] = $self->root->{end};
 504                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 505                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 506
 507                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 508
 509                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 510                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 511                                 }
 512                         } # key is real
 513                 } # i loop
 514
 515                 $location ||= $self->root->{end};
 516         } # re-index bucket list
 517
 518         ##
 519         # Seek to content area and store signature, value and plaintext key
 520         ##
 521         if ($location) {
 522                 my $content_length;
 523                 seek($fh, $location, SEEK_SET);
 524
 525                 ##
 526                 # Write signature based on content type, set content length and write actual value.
 527                 ##
 528         my $r = Scalar::Util::reftype($value) || '';
 529                 if ($r eq 'HASH') {
 530                         print($fh TYPE_HASH );
 531                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 532                         $content_length = $INDEX_SIZE;
 533                 }
 534                 elsif ($r eq 'ARRAY') {
 535                         print($fh TYPE_ARRAY );
 536                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 537                         $content_length = $INDEX_SIZE;
 538                 }
 539                 elsif (!defined($value)) {
 540                         print($fh SIG_NULL );
 541                         print($fh pack($DATA_LENGTH_PACK, 0) );
 542                         $content_length = 0;
 543                 }
 544                 else {
 545                         print($fh SIG_DATA );
 546                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 547                         $content_length = length($value);
 548                 }
 549
 550                 ##
 551                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 552                 ##
 553                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 554
 555                 ##
 556                 # If value is blessed, preserve class name
 557                 ##
 558                 if ( $self->root->{autobless} ) {
 559             my $value_class = Scalar::Util::blessed($value);
 560             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 561                 ##
 562                 # Blessed ref -- will restore later
 563                 ##
 564                 print($fh chr(1) );
 565                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 566                 $content_length += 1;
 567                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 568             }
 569             else {
 570                 print($fh chr(0) );
 571                 $content_length += 1;
 572             }
 573         }
 574
 575                 ##
 576                 # If this is a new content area, advance EOF counter
 577                 ##
 578                 if ($location == $self->root->{end}) {
 579                         $self->root->{end} += SIG_SIZE;
 580                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 581                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 582                 }
 583
 584                 ##
 585                 # If content is a hash or array, create new child DeepDB object and
 586                 # pass each key or element to it.
 587                 ##
 588                 if ($r eq 'HASH') {
 589                         my $branch = DBM::Deep->new(
 590                                 type => TYPE_HASH,
 591                                 base_offset => $location,
 592                                 root => $self->root,
 593                         );
 594                         foreach my $key (keys %{$value}) {
 595                 #$branch->{$key} = $value->{$key};
 596                 $branch->STORE( $key, $value->{$key} );
 597                         }
 598                 }
 599                 elsif ($r eq 'ARRAY') {
 600                         my $branch = DBM::Deep->new(
 601                                 type => TYPE_ARRAY,
 602                                 base_offset => $location,
 603                                 root => $self->root,
 604                         );
 605                         my $index = 0;
 606                         foreach my $element (@{$value}) {
 607                 #$branch->[$index] = $element;
 608                 $branch->STORE( $index, $element );
 609                                 $index++;
 610                         }
 611                 }
 612
 613                 return $result;
 614         }
 615
 616         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 617 }
 618
 619 sub _get_bucket_value {
 620         ##
 621         # Fetch single value given tag and MD5 digested key.
 622         ##
 623         my $self = shift;
 624         my ($tag, $md5) = @_;
 625         my $keys = $tag->{content};
 626
 627     my $fh = $self->fh;
 628
 629         ##
 630         # Iterate through buckets, looking for a key match
 631         ##
 632     BUCKET:
 633         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 634                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 635                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 636
 637                 if (!$subloc) {
 638                         ##
 639                         # Hit end of list, no match
 640                         ##
 641                         return;
 642                 }
 643
 644         if ( $md5 ne $key ) {
 645             next BUCKET;
 646         }
 647
 648         ##
 649         # Found match -- seek to offset and read signature
 650         ##
 651         my $signature;
 652         seek($fh, $subloc, SEEK_SET);
 653         read( $fh, $signature, SIG_SIZE);
 654
 655         ##
 656         # If value is a hash or array, return new DeepDB object with correct offset
 657         ##
 658         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 659             my $obj = DBM::Deep->new(
 660                 type => $signature,
 661                 base_offset => $subloc,
 662                 root => $self->root
 663             );
 664
 665             if ($self->root->{autobless}) {
 666                 ##
 667                 # Skip over value and plain key to see if object needs
 668                 # to be re-blessed
 669                 ##
 670                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 671
 672                 my $size;
 673                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 674                 if ($size) { seek($fh, $size, SEEK_CUR); }
 675
 676                 my $bless_bit;
 677                 read( $fh, $bless_bit, 1);
 678                 if (ord($bless_bit)) {
 679                     ##
 680                     # Yes, object needs to be re-blessed
 681                     ##
 682                     my $class_name;
 683                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 684                     if ($size) { read( $fh, $class_name, $size); }
 685                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 686                 }
 687             }
 688
 689             return $obj;
 690         }
 691
 692         ##
 693         # Otherwise return actual value
 694         ##
 695         elsif ($signature eq SIG_DATA) {
 696             my $size;
 697             my $value = '';
 698             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 699             if ($size) { read( $fh, $value, $size); }
 700             return $value;
 701         }
 702
 703         ##
 704         # Key exists, but content is null
 705         ##
 706         else { return; }
 707         } # i loop
 708
 709         return;
 710 }
 711
 712 sub _delete_bucket {
 713         ##
 714         # Delete single key/value pair given tag and MD5 digested key.
 715         ##
 716         my $self = shift;
 717         my ($tag, $md5) = @_;
 718         my $keys = $tag->{content};
 719
 720     my $fh = $self->fh;
 721
 722         ##
 723         # Iterate through buckets, looking for a key match
 724         ##
 725     BUCKET:
 726         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 727                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 728                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 729
 730                 if (!$subloc) {
 731                         ##
 732                         # Hit end of list, no match
 733                         ##
 734                         return;
 735                 }
 736
 737         if ( $md5 ne $key ) {
 738             next BUCKET;
 739         }
 740
 741         ##
 742         # Matched key -- delete bucket and return
 743         ##
 744         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 745         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 746         print($fh chr(0) x $BUCKET_SIZE );
 747
 748         return 1;
 749         } # i loop
 750
 751         return;
 752 }
 753
 754 sub _bucket_exists {
 755         ##
 756         # Check existence of single key given tag and MD5 digested key.
 757         ##
 758         my $self = shift;
 759         my ($tag, $md5) = @_;
 760         my $keys = $tag->{content};
 761
 762         ##
 763         # Iterate through buckets, looking for a key match
 764         ##
 765     BUCKET:
 766         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 767                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 768                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 769
 770                 if (!$subloc) {
 771                         ##
 772                         # Hit end of list, no match
 773                         ##
 774                         return;
 775                 }
 776
 777         if ( $md5 ne $key ) {
 778             next BUCKET;
 779         }
 780
 781         ##
 782         # Matched key -- return true
 783         ##
 784         return 1;
 785         } # i loop
 786
 787         return;
 788 }
 789
 790 sub _find_bucket_list {
 791         ##
 792         # Locate offset for bucket list, given digested key
 793         ##
 794         my $self = shift;
 795         my $md5 = shift;
 796
 797         ##
 798         # Locate offset for bucket list using digest index system
 799         ##
 800         my $ch = 0;
 801         my $tag = $self->_load_tag($self->base_offset);
 802         if (!$tag) { return; }
 803
 804         while ($tag->{signature} ne SIG_BLIST) {
 805                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 806                 if (!$tag) { return; }
 807                 $ch++;
 808         }
 809
 810         return $tag;
 811 }
 812
 813 sub _traverse_index {
 814         ##
 815         # Scan index and recursively step into deeper levels, looking for next key.
 816         ##
 817     my ($self, $offset, $ch, $force_return_next) = @_;
 818     $force_return_next = undef unless $force_return_next;
 819
 820         my $tag = $self->_load_tag( $offset );
 821
 822     my $fh = $self->fh;
 823
 824         if ($tag->{signature} ne SIG_BLIST) {
 825                 my $content = $tag->{content};
 826                 my $start;
 827                 if ($self->{return_next}) { $start = 0; }
 828                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 829
 830                 for (my $index = $start; $index < 256; $index++) {
 831                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 832                         if ($subloc) {
 833                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 834                                 if (defined($result)) { return $result; }
 835                         }
 836                 } # index loop
 837
 838                 $self->{return_next} = 1;
 839         } # tag is an index
 840
 841         elsif ($tag->{signature} eq SIG_BLIST) {
 842                 my $keys = $tag->{content};
 843                 if ($force_return_next) { $self->{return_next} = 1; }
 844
 845                 ##
 846                 # Iterate through buckets, looking for a key match
 847                 ##
 848                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 849                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 850                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 851
 852                         if (!$subloc) {
 853                                 ##
 854                                 # End of bucket list -- return to outer loop
 855                                 ##
 856                                 $self->{return_next} = 1;
 857                                 last;
 858                         }
 859                         elsif ($key eq $self->{prev_md5}) {
 860                                 ##
 861                                 # Located previous key -- return next one found
 862                                 ##
 863                                 $self->{return_next} = 1;
 864                                 next;
 865                         }
 866                         elsif ($self->{return_next}) {
 867                                 ##
 868                                 # Seek to bucket location and skip over signature
 869                                 ##
 870                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 871
 872                                 ##
 873                                 # Skip over value to get to plain key
 874                                 ##
 875                                 my $size;
 876                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 877                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 878
 879                                 ##
 880                                 # Read in plain key and return as scalar
 881                                 ##
 882                                 my $plain_key;
 883                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 884                                 if ($size) { read( $fh, $plain_key, $size); }
 885
 886                                 return $plain_key;
 887                         }
 888                 } # bucket loop
 889
 890                 $self->{return_next} = 1;
 891         } # tag is a bucket list
 892
 893         return;
 894 }
 895
 896 sub _get_next_key {
 897         ##
 898         # Locate next key, given digested previous one
 899         ##
 900     my $self = $_[0]->_get_self;
 901
 902         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 903         $self->{return_next} = 0;
 904
 905         ##
 906         # If the previous key was not specifed, start at the top and
 907         # return the first one found.
 908         ##
 909         if (!$self->{prev_md5}) {
 910                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 911                 $self->{return_next} = 1;
 912         }
 913
 914         return $self->_traverse_index( $self->base_offset, 0 );
 915 }
 916
 917 sub lock {
 918         ##
 919         # If db locking is set, flock() the db file.  If called multiple
 920         # times before unlock(), then the same number of unlocks() must
 921         # be called before the lock is released.
 922         ##
 923     my $self = $_[0]->_get_self;
 924         my $type = $_[1];
 925     $type = LOCK_EX unless defined $type;
 926
 927         if (!defined($self->fh)) { return; }
 928
 929         if ($self->root->{locking}) {
 930                 if (!$self->root->{locked}) {
 931                         flock($self->fh, $type);
 932
 933                         # double-check file inode, in case another process
 934                         # has optimize()d our file while we were waiting.
 935                         if ((stat($self->root->{file}))[1] != $self->root->{inode}) {
 936                                 $self->_open(); # re-open
 937                                 flock($self->fh, $type); # re-lock
 938                         }
 939                 }
 940                 $self->root->{locked}++;
 941
 942         return 1;
 943         }
 944
 945     return;
 946 }
 947
 948 sub unlock {
 949         ##
 950         # If db locking is set, unlock the db file.  See note in lock()
 951         # regarding calling lock() multiple times.
 952         ##
 953     my $self = $_[0]->_get_self;
 954
 955         if (!defined($self->fh)) { return; }
 956
 957         if ($self->root->{locking} && $self->root->{locked} > 0) {
 958                 $self->root->{locked}--;
 959                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 960
 961         return 1;
 962         }
 963
 964     return;
 965 }
 966
 967 #XXX These uses of ref() need verified
 968 sub _copy_node {
 969         ##
 970         # Copy single level of keys or elements to new DB handle.
 971         # Recurse for nested structures
 972         ##
 973     my $self = $_[0]->_get_self;
 974         my $db_temp = $_[1];
 975
 976         if ($self->type eq TYPE_HASH) {
 977                 my $key = $self->first_key();
 978                 while ($key) {
 979                         my $value = $self->get($key);
 980 #XXX This doesn't work with autobless
 981                         if (!ref($value)) { $db_temp->{$key} = $value; }
 982                         else {
 983                                 my $type = $value->type;
 984                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 985                                 else { $db_temp->{$key} = []; }
 986                                 $value->_copy_node( $db_temp->{$key} );
 987                         }
 988                         $key = $self->next_key($key);
 989                 }
 990         }
 991         else {
 992                 my $length = $self->length();
 993                 for (my $index = 0; $index < $length; $index++) {
 994                         my $value = $self->get($index);
 995                         if (!ref($value)) { $db_temp->[$index] = $value; }
 996             #XXX NO tests for this code
 997                         else {
 998                                 my $type = $value->type;
 999                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
1000                                 else { $db_temp->[$index] = []; }
1001                                 $value->_copy_node( $db_temp->[$index] );
1002                         }
1003                 }
1004         }
1005 }
1006
1007 sub export {
1008         ##
1009         # Recursively export into standard Perl hashes and arrays.
1010         ##
1011     my $self = $_[0]->_get_self;
1012
1013         my $temp;
1014         if ($self->type eq TYPE_HASH) { $temp = {}; }
1015         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1016
1017         $self->lock();
1018         $self->_copy_node( $temp );
1019         $self->unlock();
1020
1021         return $temp;
1022 }
1023
1024 sub import {
1025         ##
1026         # Recursively import Perl hash/array structure
1027         ##
1028     #XXX This use of ref() seems to be ok
1029         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1030
1031     my $self = $_[0]->_get_self;
1032         my $struct = $_[1];
1033
1034     #XXX This use of ref() seems to be ok
1035         if (!ref($struct)) {
1036                 ##
1037                 # struct is not a reference, so just import based on our type
1038                 ##
1039                 shift @_;
1040
1041                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1042                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1043         }
1044
1045     my $r = Scalar::Util::reftype($struct) || '';
1046         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1047                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1048         }
1049         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1050                 $self->push( @$struct );
1051         }
1052         else {
1053                 return $self->_throw_error("Cannot import: type mismatch");
1054         }
1055
1056         return 1;
1057 }
1058
1059 sub optimize {
1060         ##
1061         # Rebuild entire database into new file, then move
1062         # it back on top of original.
1063         ##
1064     my $self = $_[0]->_get_self;
1065
1066 #XXX Need to create a new test for this
1067 #       if ($self->root->{links} > 1) {
1068 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1069 #       }
1070
1071         my $db_temp = DBM::Deep->new(
1072                 file => $self->root->{file} . '.tmp',
1073                 type => $self->type
1074         );
1075         if (!$db_temp) {
1076                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1077         }
1078
1079         $self->lock();
1080         $self->_copy_node( $db_temp );
1081         undef $db_temp;
1082
1083         ##
1084         # Attempt to copy user, group and permissions over to new file
1085         ##
1086         my @stats = stat($self->fh);
1087         my $perms = $stats[2] & 07777;
1088         my $uid = $stats[4];
1089         my $gid = $stats[5];
1090         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1091         chmod( $perms, $self->root->{file} . '.tmp' );
1092
1093     # q.v. perlport for more information on this variable
1094     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1095                 ##
1096                 # Potential race condition when optmizing on Win32 with locking.
1097                 # The Windows filesystem requires that the filehandle be closed
1098                 # before it is overwritten with rename().  This could be redone
1099                 # with a soft copy.
1100                 ##
1101                 $self->unlock();
1102                 $self->_close();
1103         }
1104
1105         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1106                 unlink $self->root->{file} . '.tmp';
1107                 $self->unlock();
1108                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1109         }
1110
1111         $self->unlock();
1112         $self->_close();
1113         $self->_open();
1114
1115         return 1;
1116 }
1117
1118 sub clone {
1119         ##
1120         # Make copy of object and return
1121         ##
1122     my $self = $_[0]->_get_self;
1123
1124         return DBM::Deep->new(
1125                 type => $self->type,
1126                 base_offset => $self->base_offset,
1127                 root => $self->root
1128         );
1129 }
1130
1131 {
1132     my %is_legal_filter = map {
1133         $_ => ~~1,
1134     } qw(
1135         store_key store_value
1136         fetch_key fetch_value
1137     );
1138
1139     sub set_filter {
1140         ##
1141         # Setup filter function for storing or fetching the key or value
1142         ##
1143         my $self = $_[0]->_get_self;
1144         my $type = lc $_[1];
1145         my $func = $_[2] ? $_[2] : undef;
1146
1147         if ( $is_legal_filter{$type} ) {
1148             $self->root->{"filter_$type"} = $func;
1149             return 1;
1150         }
1151
1152         return;
1153     }
1154 }
1155
1156 ##
1157 # Accessor methods
1158 ##
1159
1160 sub root {
1161         ##
1162         # Get access to the root structure
1163         ##
1164     my $self = $_[0]->_get_self;
1165         return $self->{root};
1166 }
1167
1168 sub fh {
1169         ##
1170         # Get access to the raw fh
1171         ##
1172     #XXX It will be useful, though, when we split out HASH and ARRAY
1173     my $self = $_[0]->_get_self;
1174         return $self->root->{fh};
1175 }
1176
1177 sub type {
1178         ##
1179         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1180         ##
1181     my $self = $_[0]->_get_self;
1182         return $self->{type};
1183 }
1184
1185 sub base_offset {
1186         ##
1187         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1188         ##
1189     my $self = $_[0]->_get_self;
1190         return $self->{base_offset};
1191 }
1192
1193 sub error {
1194         ##
1195         # Get last error string, or undef if no error
1196         ##
1197         return $_[0]
1198         #? ( _get_self($_[0])->{root}->{error} or undef )
1199         ? ( $_[0]->_get_self->{root}->{error} or undef )
1200         : $@;
1201 }
1202
1203 ##
1204 # Utility methods
1205 ##
1206
1207 sub _throw_error {
1208         ##
1209         # Store error string in self
1210         ##
1211     my $self = $_[0]->_get_self;
1212         my $error_text = $_[1];
1213
1214     if ( Scalar::Util::blessed $self ) {
1215         $self->root->{error} = $error_text;
1216
1217         unless ($self->root->{debug}) {
1218             die "DBM::Deep: $error_text\n";
1219         }
1220
1221         warn "DBM::Deep: $error_text\n";
1222         return;
1223     }
1224     else {
1225         die "DBM::Deep: $error_text\n";
1226     }
1227 }
1228
1229 sub clear_error {
1230         ##
1231         # Clear error state
1232         ##
1233     my $self = $_[0]->_get_self;
1234
1235         undef $self->root->{error};
1236 }
1237
1238 sub precalc_sizes {
1239         ##
1240         # Precalculate index, bucket and bucket list sizes
1241         ##
1242
1243     #XXX I don't like this ...
1244     set_pack() unless defined $LONG_SIZE;
1245
1246         $INDEX_SIZE = 256 * $LONG_SIZE;
1247         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1248         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1249 }
1250
1251 sub set_pack {
1252         ##
1253         # Set pack/unpack modes (see file header for more)
1254         ##
1255     my ($long_s, $long_p, $data_s, $data_p) = @_;
1256
1257     $LONG_SIZE = $long_s ? $long_s : 4;
1258     $LONG_PACK = $long_p ? $long_p : 'N';
1259
1260     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1261     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1262
1263         precalc_sizes();
1264 }
1265
1266 sub set_digest {
1267         ##
1268         # Set key digest function (default is MD5)
1269         ##
1270     my ($digest_func, $hash_size) = @_;
1271
1272     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1273     $HASH_SIZE = $hash_size ? $hash_size : 16;
1274
1275         precalc_sizes();
1276 }
1277
1278 ##
1279 # tie() methods (hashes and arrays)
1280 ##
1281
1282 sub STORE {
1283         ##
1284         # Store single hash key/value or array element in database.
1285         ##
1286     my $self = $_[0]->_get_self;
1287         my $key = $_[1];
1288
1289     # User may be storing a hash, in which case we do not want it run
1290     # through the filtering system
1291         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1292         ? $self->root->{filter_store_value}->($_[2])
1293         : $_[2];
1294
1295         my $md5 = $DIGEST_FUNC->($key);
1296
1297         ##
1298         # Make sure file is open
1299         ##
1300         if (!defined($self->fh) && !$self->_open()) {
1301                 return;
1302         }
1303         ##
1304
1305         ##
1306         # Request exclusive lock for writing
1307         ##
1308         $self->lock( LOCK_EX );
1309
1310         my $fh = $self->fh;
1311
1312         ##
1313         # If locking is enabled, set 'end' parameter again, in case another
1314         # DB instance appended to our file while we were unlocked.
1315         ##
1316         if ($self->root->{locking} || $self->root->{volatile}) {
1317                 $self->root->{end} = (stat($fh))[7];
1318         }
1319
1320         ##
1321         # Locate offset for bucket list using digest index system
1322         ##
1323         my $tag = $self->_load_tag($self->base_offset);
1324         if (!$tag) {
1325                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1326         }
1327
1328         my $ch = 0;
1329         while ($tag->{signature} ne SIG_BLIST) {
1330                 my $num = ord(substr($md5, $ch, 1));
1331                 my $new_tag = $self->_index_lookup($tag, $num);
1332                 if (!$new_tag) {
1333                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1334                         seek($fh, $ref_loc, SEEK_SET);
1335                         print($fh pack($LONG_PACK, $self->root->{end}) );
1336
1337                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1338                         $tag->{ref_loc} = $ref_loc;
1339                         $tag->{ch} = $ch;
1340                         last;
1341                 }
1342                 else {
1343                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1344                         $tag = $new_tag;
1345                         $tag->{ref_loc} = $ref_loc;
1346                         $tag->{ch} = $ch;
1347                 }
1348                 $ch++;
1349         }
1350
1351         ##
1352         # Add key/value to bucket list
1353         ##
1354         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1355
1356         $self->unlock();
1357
1358         return $result;
1359 }
1360
1361 sub FETCH {
1362         ##
1363         # Fetch single value or element given plain key or array index
1364         ##
1365     my $self = shift->_get_self;
1366     my $key = shift;
1367
1368         ##
1369         # Make sure file is open
1370         ##
1371         if (!defined($self->fh)) { $self->_open(); }
1372
1373         my $md5 = $DIGEST_FUNC->($key);
1374
1375         ##
1376         # Request shared lock for reading
1377         ##
1378         $self->lock( LOCK_SH );
1379
1380         my $tag = $self->_find_bucket_list( $md5 );
1381         if (!$tag) {
1382                 $self->unlock();
1383                 return;
1384         }
1385
1386         ##
1387         # Get value from bucket list
1388         ##
1389         my $result = $self->_get_bucket_value( $tag, $md5 );
1390
1391         $self->unlock();
1392
1393     #XXX What is ref() checking here?
1394     #YYY Filters only apply on scalar values, so the ref check is making
1395     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1396         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1397         ? $self->root->{filter_fetch_value}->($result)
1398         : $result;
1399 }
1400
1401 sub DELETE {
1402         ##
1403         # Delete single key/value pair or element given plain key or array index
1404         ##
1405     my $self = $_[0]->_get_self;
1406         my $key = $_[1];
1407
1408         my $md5 = $DIGEST_FUNC->($key);
1409
1410         ##
1411         # Make sure file is open
1412         ##
1413         if (!defined($self->fh)) { $self->_open(); }
1414
1415         ##
1416         # Request exclusive lock for writing
1417         ##
1418         $self->lock( LOCK_EX );
1419
1420         my $tag = $self->_find_bucket_list( $md5 );
1421         if (!$tag) {
1422                 $self->unlock();
1423                 return;
1424         }
1425
1426         ##
1427         # Delete bucket
1428         ##
1429     my $value = $self->_get_bucket_value( $tag, $md5 );
1430         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1431         $value = $self->root->{filter_fetch_value}->($value);
1432     }
1433
1434         my $result = $self->_delete_bucket( $tag, $md5 );
1435
1436         ##
1437         # If this object is an array and the key deleted was on the end of the stack,
1438         # decrement the length variable.
1439         ##
1440
1441         $self->unlock();
1442
1443         return $value;
1444 }
1445
1446 sub EXISTS {
1447         ##
1448         # Check if a single key or element exists given plain key or array index
1449         ##
1450     my $self = $_[0]->_get_self;
1451         my $key = $_[1];
1452
1453         my $md5 = $DIGEST_FUNC->($key);
1454
1455         ##
1456         # Make sure file is open
1457         ##
1458         if (!defined($self->fh)) { $self->_open(); }
1459
1460         ##
1461         # Request shared lock for reading
1462         ##
1463         $self->lock( LOCK_SH );
1464
1465         my $tag = $self->_find_bucket_list( $md5 );
1466
1467         ##
1468         # For some reason, the built-in exists() function returns '' for false
1469         ##
1470         if (!$tag) {
1471                 $self->unlock();
1472                 return '';
1473         }
1474
1475         ##
1476         # Check if bucket exists and return 1 or ''
1477         ##
1478         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1479
1480         $self->unlock();
1481
1482         return $result;
1483 }
1484
1485 sub CLEAR {
1486         ##
1487         # Clear all keys from hash, or all elements from array.
1488         ##
1489     my $self = $_[0]->_get_self;
1490
1491         ##
1492         # Make sure file is open
1493         ##
1494         if (!defined($self->fh)) { $self->_open(); }
1495
1496         ##
1497         # Request exclusive lock for writing
1498         ##
1499         $self->lock( LOCK_EX );
1500
1501     my $fh = $self->fh;
1502
1503         seek($fh, $self->base_offset, SEEK_SET);
1504         if (eof $fh) {
1505                 $self->unlock();
1506                 return;
1507         }
1508
1509         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1510
1511         $self->unlock();
1512
1513         return 1;
1514 }
1515
1516 ##
1517 # Public method aliases
1518 ##
1519 sub put { (shift)->STORE( @_ ) }
1520 sub store { (shift)->STORE( @_ ) }
1521 sub get { (shift)->FETCH( @_ ) }
1522 sub fetch { (shift)->FETCH( @_ ) }
1523 sub delete { (shift)->DELETE( @_ ) }
1524 sub exists { (shift)->EXISTS( @_ ) }
1525 sub clear { (shift)->CLEAR( @_ ) }
1526
1527 package DBM::Deep::_::Root;
1528
1529 sub new {
1530     my $class = shift;
1531     my ($args) = @_;
1532
1533     my $self = bless {
1534         file => undef,
1535         fh => undef,
1536         end => 0,
1537         autoflush => undef,
1538         locking => undef,
1539         volatile => undef,
1540         debug => undef,
1541         filter_store_key => undef,
1542         filter_store_value => undef,
1543         filter_fetch_key => undef,
1544         filter_fetch_value => undef,
1545         autobless => undef,
1546         locked => 0,
1547         %$args,
1548     }, $class;
1549
1550     return $self;
1551 }
1552
1553 sub DESTROY {
1554     my $self = shift;
1555     return unless $self;
1556
1557     close $self->{fh} if $self->{fh};
1558
1559     return;
1560 }
1561
1562 1;
1563
1564 __END__
1565
1566 =head1 NAME
1567
1568 DBM::Deep - A pure perl multi-level hash/array DBM
1569
1570 =head1 SYNOPSIS
1571
1572   use DBM::Deep;
1573   my $db = DBM::Deep->new( "foo.db" );
1574
1575   $db->{key} = 'value'; # tie() style
1576   print $db->{key};
1577
1578   $db->put('key', 'value'); # OO style
1579   print $db->get('key');
1580
1581   # true multi-level support
1582   $db->{my_complex} = [
1583         'hello', { perl => 'rules' },
1584         42, 99,
1585   ];
1586
1587 =head1 DESCRIPTION
1588
1589 A unique flat-file database module, written in pure perl.  True
1590 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1591 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1592 handle millions of keys and unlimited hash levels without significant
1593 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1594 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1595 Mac OS X and Windows.
1596
1597 =head1 INSTALLATION
1598
1599 Hopefully you are using Perl's excellent CPAN module, which will download
1600 and install the module for you.  If not, get the tarball, and run these
1601 commands:
1602
1603         tar zxf DBM-Deep-*
1604         cd DBM-Deep-*
1605         perl Makefile.PL
1606         make
1607         make test
1608         make install
1609
1610 =head1 SETUP
1611
1612 Construction can be done OO-style (which is the recommended way), or using
1613 Perl's tie() function.  Both are examined here.
1614
1615 =head2 OO CONSTRUCTION
1616
1617 The recommended way to construct a DBM::Deep object is to use the new()
1618 method, which gets you a blessed, tied hash or array reference.
1619
1620         my $db = DBM::Deep->new( "foo.db" );
1621
1622 This opens a new database handle, mapped to the file "foo.db".  If this
1623 file does not exist, it will automatically be created.  DB files are
1624 opened in "r+" (read/write) mode, and the type of object returned is a
1625 hash, unless otherwise specified (see L<OPTIONS> below).
1626
1627 You can pass a number of options to the constructor to specify things like
1628 locking, autoflush, etc.  This is done by passing an inline hash:
1629
1630         my $db = DBM::Deep->new(
1631                 file => "foo.db",
1632                 locking => 1,
1633                 autoflush => 1
1634         );
1635
1636 Notice that the filename is now specified I<inside> the hash with
1637 the "file" parameter, as opposed to being the sole argument to the
1638 constructor.  This is required if any options are specified.
1639 See L<OPTIONS> below for the complete list.
1640
1641
1642
1643 You can also start with an array instead of a hash.  For this, you must
1644 specify the C<type> parameter:
1645
1646         my $db = DBM::Deep->new(
1647                 file => "foo.db",
1648                 type => DBM::Deep->TYPE_ARRAY
1649         );
1650
1651 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1652 a new DB file.  If you create a DBM::Deep object with an existing file, the
1653 C<type> will be loaded from the file header, and an error will be thrown if
1654 the wrong type is passed in.
1655
1656 =head2 TIE CONSTRUCTION
1657
1658 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1659 tie() function.  The object returned from tie() can be used to call methods,
1660 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1661 file (as expected with most tie'd objects).
1662
1663         my %hash;
1664         my $db = tie %hash, "DBM::Deep", "foo.db";
1665
1666         my @array;
1667         my $db = tie @array, "DBM::Deep", "bar.db";
1668
1669 As with the OO constructor, you can replace the DB filename parameter with
1670 a hash containing one or more options (see L<OPTIONS> just below for the
1671 complete list).
1672
1673         tie %hash, "DBM::Deep", {
1674                 file => "foo.db",
1675                 locking => 1,
1676                 autoflush => 1
1677         };
1678
1679 =head2 OPTIONS
1680
1681 There are a number of options that can be passed in when constructing your
1682 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1683
1684 =over
1685
1686 =item * file
1687
1688 Filename of the DB file to link the handle to.  You can pass a full absolute
1689 filesystem path, partial path, or a plain filename if the file is in the
1690 current working directory.  This is a required parameter.
1691
1692 =item * type
1693
1694 This parameter specifies what type of object to create, a hash or array.  Use
1695 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1696 This only takes effect when beginning a new file.  This is an optional
1697 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1698
1699 =item * locking
1700
1701 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1702 function to lock the database in exclusive mode for writes, and shared mode for
1703 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1704 any child hashes or arrays> that use the same DB file.  This is an optional
1705 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1706
1707 =item * autoflush
1708
1709 Specifies whether autoflush is to be enabled on the underlying filehandle.
1710 This obviously slows down write operations, but is required if you may have
1711 multiple processes accessing the same DB file (also consider enable I<locking>
1712 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1713 parameter, and defaults to 0 (disabled).
1714
1715 =item * volatile
1716
1717 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1718 STORE() operation.  This is required if an outside force may change the size of
1719 the file between transactions.  Locking also implicitly enables volatile.  This
1720 is useful if you want to use a different locking system or write your own.  Pass
1721 any true value to enable.  This is an optional parameter, and defaults to 0
1722 (disabled).
1723
1724 =item * autobless
1725
1726 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1727 restore them when fetched.  This is an B<experimental> feature, and does have
1728 side-effects.  Basically, when hashes are re-blessed into their original
1729 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1730 able to call any DBM::Deep methods on them.  You have been warned.
1731 This is an optional parameter, and defaults to 0 (disabled).
1732
1733 =item * filter_*
1734
1735 See L<FILTERS> below.
1736
1737 =item * debug
1738
1739 Setting I<debug> mode will make all errors non-fatal, dump them out to
1740 STDERR, and continue on.  This is for debugging purposes only, and probably
1741 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1742
1743 =item * fh
1744
1745 Instead of passing a file path, you can instead pass a handle to an pre-opened
1746 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1747 contains your entire Perl script, as well as the data following the __DATA__
1748 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1749 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1750 in that.  Also please note optimize() will NOT work when passing in only a
1751 handle.  Pass in a real filename in order to use optimize().
1752
1753 =back
1754
1755 =head1 TIE INTERFACE
1756
1757 With DBM::Deep you can access your databases using Perl's standard hash/array
1758 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1759 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1760 to the right place -- the DB file.  This has nothing to do with the
1761 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1762 using regular hashes and arrays, rather than calling functions like C<get()>
1763 and C<put()> (although those work too).  It is entirely up to you how to want
1764 to access your databases.
1765
1766 =head2 HASHES
1767
1768 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1769 or even nested hashes (or arrays) using standard Perl syntax:
1770
1771         my $db = DBM::Deep->new( "foo.db" );
1772
1773         $db->{mykey} = "myvalue";
1774         $db->{myhash} = {};
1775         $db->{myhash}->{subkey} = "subvalue";
1776
1777         print $db->{myhash}->{subkey} . "\n";
1778
1779 You can even step through hash keys using the normal Perl C<keys()> function:
1780
1781         foreach my $key (keys %$db) {
1782                 print "$key: " . $db->{$key} . "\n";
1783         }
1784
1785 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1786 pushes them onto an array, all before the loop even begins.  If you have an
1787 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1788 Perl's C<each()> function, which pulls keys/values one at a time, using very
1789 little memory:
1790
1791         while (my ($key, $value) = each %$db) {
1792                 print "$key: $value\n";
1793         }
1794
1795 Please note that when using C<each()>, you should always pass a direct
1796 hash reference, not a lookup.  Meaning, you should B<never> do this:
1797
1798         # NEVER DO THIS
1799         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1800
1801 This causes an infinite loop, because for each iteration, Perl is calling
1802 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1803 it effectively keeps returning the first key over and over again. Instead,
1804 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1805
1806 =head2 ARRAYS
1807
1808 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1809 reference.  This includes inserting, removing and manipulating elements,
1810 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1811 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1812 or simply be a nested array reference inside a hash.  Example:
1813
1814         my $db = DBM::Deep->new(
1815                 file => "foo-array.db",
1816                 type => DBM::Deep->TYPE_ARRAY
1817         );
1818
1819         $db->[0] = "foo";
1820         push @$db, "bar", "baz";
1821         unshift @$db, "bah";
1822
1823         my $last_elem = pop @$db; # baz
1824         my $first_elem = shift @$db; # bah
1825         my $second_elem = $db->[1]; # bar
1826
1827         my $num_elements = scalar @$db;
1828
1829 =head1 OO INTERFACE
1830
1831 In addition to the I<tie()> interface, you can also use a standard OO interface
1832 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1833 array) has its own methods, but both types share the following common methods:
1834 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1835
1836 =over
1837
1838 =item * put() / store()
1839
1840 Stores a new hash key/value pair, or sets an array element value.  Takes two
1841 arguments, the hash key or array index, and the new value.  The value can be
1842 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1843
1844         $db->put("foo", "bar"); # for hashes
1845         $db->put(1, "bar"); # for arrays
1846
1847 =item * get() / fetch()
1848
1849 Fetches the value of a hash key or array element.  Takes one argument: the hash
1850 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1851 data type stored.
1852
1853         my $value = $db->get("foo"); # for hashes
1854         my $value = $db->get(1); # for arrays
1855
1856 =item * exists()
1857
1858 Checks if a hash key or array index exists.  Takes one argument: the hash key
1859 or array index.  Returns true if it exists, false if not.
1860
1861         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1862         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1863
1864 =item * delete()
1865
1866 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1867 key or array index.  Returns true on success, false if not found.  For arrays,
1868 the remaining elements located after the deleted element are NOT moved over.
1869 The deleted element is essentially just undefined, which is exactly how Perl's
1870 internal arrays work.  Please note that the space occupied by the deleted
1871 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1872 below for details and workarounds.
1873
1874         $db->delete("foo"); # for hashes
1875         $db->delete(1); # for arrays
1876
1877 =item * clear()
1878
1879 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1880 value.  Please note that the space occupied by the deleted keys/values or
1881 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1882 details and workarounds.
1883
1884         $db->clear(); # hashes or arrays
1885
1886 =back
1887
1888 =head2 HASHES
1889
1890 For hashes, DBM::Deep supports all the common methods described above, and the
1891 following additional methods: C<first_key()> and C<next_key()>.
1892
1893 =over
1894
1895 =item * first_key()
1896
1897 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1898 fetched in an undefined order (which appears random).  Takes no arguments,
1899 returns the key as a scalar value.
1900
1901         my $key = $db->first_key();
1902
1903 =item * next_key()
1904
1905 Returns the "next" key in the hash, given the previous one as the sole argument.
1906 Returns undef if there are no more keys to be fetched.
1907
1908         $key = $db->next_key($key);
1909
1910 =back
1911
1912 Here are some examples of using hashes:
1913
1914         my $db = DBM::Deep->new( "foo.db" );
1915
1916         $db->put("foo", "bar");
1917         print "foo: " . $db->get("foo") . "\n";
1918
1919         $db->put("baz", {}); # new child hash ref
1920         $db->get("baz")->put("buz", "biz");
1921         print "buz: " . $db->get("baz")->get("buz") . "\n";
1922
1923         my $key = $db->first_key();
1924         while ($key) {
1925                 print "$key: " . $db->get($key) . "\n";
1926                 $key = $db->next_key($key);
1927         }
1928
1929         if ($db->exists("foo")) { $db->delete("foo"); }
1930
1931 =head2 ARRAYS
1932
1933 For arrays, DBM::Deep supports all the common methods described above, and the
1934 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1935 C<unshift()> and C<splice()>.
1936
1937 =over
1938
1939 =item * length()
1940
1941 Returns the number of elements in the array.  Takes no arguments.
1942
1943         my $len = $db->length();
1944
1945 =item * push()
1946
1947 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1948 refs or array refs.  No return value.
1949
1950         $db->push("foo", "bar", {});
1951
1952 =item * pop()
1953
1954 Fetches the last element in the array, and deletes it.  Takes no arguments.
1955 Returns undef if array is empty.  Returns the element value.
1956
1957         my $elem = $db->pop();
1958
1959 =item * shift()
1960
1961 Fetches the first element in the array, deletes it, then shifts all the
1962 remaining elements over to take up the space.  Returns the element value.  This
1963 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1964 details.
1965
1966         my $elem = $db->shift();
1967
1968 =item * unshift()
1969
1970 Inserts one or more elements onto the beginning of the array, shifting all
1971 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1972 No return value.  This method is not recommended with large arrays -- see
1973 <LARGE ARRAYS> below for details.
1974
1975         $db->unshift("foo", "bar", {});
1976
1977 =item * splice()
1978
1979 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1980 -f splice> for usage -- it is too complicated to document here.  This method is
1981 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1982
1983 =back
1984
1985 Here are some examples of using arrays:
1986
1987         my $db = DBM::Deep->new(
1988                 file => "foo.db",
1989                 type => DBM::Deep->TYPE_ARRAY
1990         );
1991
1992         $db->push("bar", "baz");
1993         $db->unshift("foo");
1994         $db->put(3, "buz");
1995
1996         my $len = $db->length();
1997         print "length: $len\n"; # 4
1998
1999         for (my $k=0; $k<$len; $k++) {
2000                 print "$k: " . $db->get($k) . "\n";
2001         }
2002
2003         $db->splice(1, 2, "biz", "baf");
2004
2005         while (my $elem = shift @$db) {
2006                 print "shifted: $elem\n";
2007         }
2008
2009 =head1 LOCKING
2010
2011 Enable automatic file locking by passing a true value to the C<locking>
2012 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2013
2014         my $db = DBM::Deep->new(
2015                 file => "foo.db",
2016                 locking => 1
2017         );
2018
2019 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2020 mode for writes, and shared mode for reads.  This is required if you have
2021 multiple processes accessing the same database file, to avoid file corruption.
2022 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2023 NFS> below for more.
2024
2025 =head2 EXPLICIT LOCKING
2026
2027 You can explicitly lock a database, so it remains locked for multiple
2028 transactions.  This is done by calling the C<lock()> method, and passing an
2029 optional lock mode argument (defaults to exclusive mode).  This is particularly
2030 useful for things like counters, where the current value needs to be fetched,
2031 then incremented, then stored again.
2032
2033         $db->lock();
2034         my $counter = $db->get("counter");
2035         $counter++;
2036         $db->put("counter", $counter);
2037         $db->unlock();
2038
2039         # or...
2040
2041         $db->lock();
2042         $db->{counter}++;
2043         $db->unlock();
2044
2045 You can pass C<lock()> an optional argument, which specifies which mode to use
2046 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2047 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2048 same as the constants defined in Perl's C<Fcntl> module.
2049
2050         $db->lock( DBM::Deep->LOCK_SH );
2051         # something here
2052         $db->unlock();
2053
2054 If you want to implement your own file locking scheme, be sure to create your
2055 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2056 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2057 below for more.
2058
2059 =head1 IMPORTING/EXPORTING
2060
2061 You can import existing complex structures by calling the C<import()> method,
2062 and export an entire database into an in-memory structure using the C<export()>
2063 method.  Both are examined here.
2064
2065 =head2 IMPORTING
2066
2067 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2068 walking the structure and adding keys/elements to the database as you go,
2069 simply pass a reference to the C<import()> method.  This recursively adds
2070 everything to an existing DBM::Deep object for you.  Here is an example:
2071
2072         my $struct = {
2073                 key1 => "value1",
2074                 key2 => "value2",
2075                 array1 => [ "elem0", "elem1", "elem2" ],
2076                 hash1 => {
2077                         subkey1 => "subvalue1",
2078                         subkey2 => "subvalue2"
2079                 }
2080         };
2081
2082         my $db = DBM::Deep->new( "foo.db" );
2083         $db->import( $struct );
2084
2085         print $db->{key1} . "\n"; # prints "value1"
2086
2087 This recursively imports the entire C<$struct> object into C<$db>, including
2088 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2089 keys are merged with the existing ones, replacing if they already exist.
2090 The C<import()> method can be called on any database level (not just the base
2091 level), and works with both hash and array DB types.
2092
2093 B<Note:> Make sure your existing structure has no circular references in it.
2094 These will cause an infinite loop when importing.
2095
2096 =head2 EXPORTING
2097
2098 Calling the C<export()> method on an existing DBM::Deep object will return
2099 a reference to a new in-memory copy of the database.  The export is done
2100 recursively, so all nested hashes/arrays are all exported to standard Perl
2101 objects.  Here is an example:
2102
2103         my $db = DBM::Deep->new( "foo.db" );
2104
2105         $db->{key1} = "value1";
2106         $db->{key2} = "value2";
2107         $db->{hash1} = {};
2108         $db->{hash1}->{subkey1} = "subvalue1";
2109         $db->{hash1}->{subkey2} = "subvalue2";
2110
2111         my $struct = $db->export();
2112
2113         print $struct->{key1} . "\n"; # prints "value1"
2114
2115 This makes a complete copy of the database in memory, and returns a reference
2116 to it.  The C<export()> method can be called on any database level (not just
2117 the base level), and works with both hash and array DB types.  Be careful of
2118 large databases -- you can store a lot more data in a DBM::Deep object than an
2119 in-memory Perl structure.
2120
2121 B<Note:> Make sure your database has no circular references in it.
2122 These will cause an infinite loop when exporting.
2123
2124 =head1 FILTERS
2125
2126 DBM::Deep has a number of hooks where you can specify your own Perl function
2127 to perform filtering on incoming or outgoing data.  This is a perfect
2128 way to extend the engine, and implement things like real-time compression or
2129 encryption.  Filtering applies to the base DB level, and all child hashes /
2130 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2131 constructed, or by calling the C<set_filter()> method at any time.  There are
2132 four available filter hooks, described below:
2133
2134 =over
2135
2136 =item * filter_store_key
2137
2138 This filter is called whenever a hash key is stored.  It
2139 is passed the incoming key, and expected to return a transformed key.
2140
2141 =item * filter_store_value
2142
2143 This filter is called whenever a hash key or array element is stored.  It
2144 is passed the incoming value, and expected to return a transformed value.
2145
2146 =item * filter_fetch_key
2147
2148 This filter is called whenever a hash key is fetched (i.e. via
2149 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2150 and expected to return the plain key.
2151
2152 =item * filter_fetch_value
2153
2154 This filter is called whenever a hash key or array element is fetched.
2155 It is passed the transformed value, and expected to return the plain value.
2156
2157 =back
2158
2159 Here are the two ways to setup a filter hook:
2160
2161         my $db = DBM::Deep->new(
2162                 file => "foo.db",
2163                 filter_store_value => \&my_filter_store,
2164                 filter_fetch_value => \&my_filter_fetch
2165         );
2166
2167         # or...
2168
2169         $db->set_filter( "filter_store_value", \&my_filter_store );
2170         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2171
2172 Your filter function will be called only when dealing with SCALAR keys or
2173 values.  When nested hashes and arrays are being stored/fetched, filtering
2174 is bypassed.  Filters are called as static functions, passed a single SCALAR
2175 argument, and expected to return a single SCALAR value.  If you want to
2176 remove a filter, set the function reference to C<undef>:
2177
2178         $db->set_filter( "filter_store_value", undef );
2179
2180 =head2 REAL-TIME ENCRYPTION EXAMPLE
2181
2182 Here is a working example that uses the I<Crypt::Blowfish> module to
2183 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2184 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2185 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2186
2187         use DBM::Deep;
2188         use Crypt::Blowfish;
2189         use Crypt::CBC;
2190
2191         my $cipher = Crypt::CBC->new({
2192                 'key'             => 'my secret key',
2193                 'cipher'          => 'Blowfish',
2194                 'iv'              => '$KJh#(}q',
2195                 'regenerate_key'  => 0,
2196                 'padding'         => 'space',
2197                 'prepend_iv'      => 0
2198         });
2199
2200         my $db = DBM::Deep->new(
2201                 file => "foo-encrypt.db",
2202                 filter_store_key => \&my_encrypt,
2203                 filter_store_value => \&my_encrypt,
2204                 filter_fetch_key => \&my_decrypt,
2205                 filter_fetch_value => \&my_decrypt,
2206         );
2207
2208         $db->{key1} = "value1";
2209         $db->{key2} = "value2";
2210         print "key1: " . $db->{key1} . "\n";
2211         print "key2: " . $db->{key2} . "\n";
2212
2213         undef $db;
2214         exit;
2215
2216         sub my_encrypt {
2217                 return $cipher->encrypt( $_[0] );
2218         }
2219         sub my_decrypt {
2220                 return $cipher->decrypt( $_[0] );
2221         }
2222
2223 =head2 REAL-TIME COMPRESSION EXAMPLE
2224
2225 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2226 compression / decompression of keys & values with DBM::Deep Filters.
2227 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2228 more on I<Compress::Zlib>.
2229
2230         use DBM::Deep;
2231         use Compress::Zlib;
2232
2233         my $db = DBM::Deep->new(
2234                 file => "foo-compress.db",
2235                 filter_store_key => \&my_compress,
2236                 filter_store_value => \&my_compress,
2237                 filter_fetch_key => \&my_decompress,
2238                 filter_fetch_value => \&my_decompress,
2239         );
2240
2241         $db->{key1} = "value1";
2242         $db->{key2} = "value2";
2243         print "key1: " . $db->{key1} . "\n";
2244         print "key2: " . $db->{key2} . "\n";
2245
2246         undef $db;
2247         exit;
2248
2249         sub my_compress {
2250                 return Compress::Zlib::memGzip( $_[0] ) ;
2251         }
2252         sub my_decompress {
2253                 return Compress::Zlib::memGunzip( $_[0] ) ;
2254         }
2255
2256 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2257 actually numerical index numbers, and are not filtered.
2258
2259 =head1 ERROR HANDLING
2260
2261 Most DBM::Deep methods return a true value for success, and call die() on
2262 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2263 actual error message is stored in an internal scalar, which can be fetched by
2264 calling the C<error()> method.
2265
2266         my $db = DBM::Deep->new( "foo.db" ); # create hash
2267         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2268
2269     print $@;           # prints error message
2270         print $db->error(); # prints error message
2271
2272 You can then call C<clear_error()> to clear the current error state.
2273
2274         $db->clear_error();
2275
2276 If you set the C<debug> option to true when creating your DBM::Deep object,
2277 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2278 be used for debugging purposes and not production work. DBM::Deep expects errors
2279 to be thrown, not propagated back up the stack.
2280
2281 =head1 LARGEFILE SUPPORT
2282
2283 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2284 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2285 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2286 by calling the static C<set_pack()> method before you do anything else.
2287
2288         DBM::Deep::set_pack(8, 'Q');
2289
2290 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2291 instead of 32-bit longs.  After setting these values your DB files have a
2292 theoretical maximum size of 16 XB (exabytes).
2293
2294 B<Note:> Changing these values will B<NOT> work for existing database files.
2295 Only change this for new files, and make sure it stays set consistently
2296 throughout the file's life.  If you do set these values, you can no longer
2297 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2298 back to 32-bit mode.
2299
2300 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2301 only a 32-bit Perl.  However, I have received user reports that this does
2302 indeed work!
2303
2304 =head1 LOW-LEVEL ACCESS
2305
2306 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2307 you can call the C<fh()> method, which returns the handle:
2308
2309         my $fh = $db->fh();
2310
2311 This method can be called on the root level of the datbase, or any child
2312 hashes or arrays.  All levels share a I<root> structure, which contains things
2313 like the filehandle, a reference counter, and all the options specified
2314 when you created the object.  You can get access to this root structure by
2315 calling the C<root()> method.
2316
2317         my $root = $db->root();
2318
2319 This is useful for changing options after the object has already been created,
2320 such as enabling/disabling locking, volatile or debug modes.  You can also
2321 store your own temporary user data in this structure (be wary of name
2322 collision), which is then accessible from any child hash or array.
2323
2324 =head1 CUSTOM DIGEST ALGORITHM
2325
2326 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2327 keys.  However you can override this, and use another algorithm (such as SHA-256)
2328 or even write your own.  But please note that DBM::Deep currently expects zero
2329 collisions, so your algorithm has to be I<perfect>, so to speak.
2330 Collision detection may be introduced in a later version.
2331
2332
2333
2334 You can specify a custom digest algorithm by calling the static C<set_digest()>
2335 function, passing a reference to a subroutine, and the length of the algorithm's
2336 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2337 objects.  Here is a working example that uses a 256-bit hash from the
2338 I<Digest::SHA256> module.  Please see
2339 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2340
2341         use DBM::Deep;
2342         use Digest::SHA256;
2343
2344         my $context = Digest::SHA256::new(256);
2345
2346         DBM::Deep::set_digest( \&my_digest, 32 );
2347
2348         my $db = DBM::Deep->new( "foo-sha.db" );
2349
2350         $db->{key1} = "value1";
2351         $db->{key2} = "value2";
2352         print "key1: " . $db->{key1} . "\n";
2353         print "key2: " . $db->{key2} . "\n";
2354
2355         undef $db;
2356         exit;
2357
2358         sub my_digest {
2359                 return substr( $context->hash($_[0]), 0, 32 );
2360         }
2361
2362 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2363 of bytes you specify in the C<set_digest()> function (in this case 32).
2364
2365 =head1 CIRCULAR REFERENCES
2366
2367 DBM::Deep has B<experimental> support for circular references.  Meaning you
2368 can have a nested hash key or array element that points to a parent object.
2369 This relationship is stored in the DB file, and is preserved between sessions.
2370 Here is an example:
2371
2372         my $db = DBM::Deep->new( "foo.db" );
2373
2374         $db->{foo} = "bar";
2375         $db->{circle} = $db; # ref to self
2376
2377         print $db->{foo} . "\n"; # prints "foo"
2378         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2379
2380 One catch is, passing the object to a function that recursively walks the
2381 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2382 C<export()> methods) will result in an infinite loop.  The other catch is,
2383 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2384 or C<next_key()> methods), you will get the I<target object's key>, not the
2385 ref's key.  This gets even more interesting with the above example, where
2386 the I<circle> key points to the base DB object, which technically doesn't
2387 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2388 special case.
2389
2390 =head1 CAVEATS / ISSUES / BUGS
2391
2392 This section describes all the known issues with DBM::Deep.  It you have found
2393 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2394
2395 =head2 UNUSED SPACE RECOVERY
2396
2397 One major caveat with DBM::Deep is that space occupied by existing keys and
2398 values is not recovered when they are deleted.  Meaning if you keep deleting
2399 and adding new keys, your file will continuously grow.  I am working on this,
2400 but in the meantime you can call the built-in C<optimize()> method from time to
2401 time (perhaps in a crontab or something) to recover all your unused space.
2402
2403         $db->optimize(); # returns true on success
2404
2405 This rebuilds the ENTIRE database into a new file, then moves it on top of
2406 the original.  The new file will have no unused space, thus it will take up as
2407 little disk space as possible.  Please note that this operation can take
2408 a long time for large files, and you need enough disk space to temporarily hold
2409 2 copies of your DB file.  The temporary file is created in the same directory
2410 as the original, named with a ".tmp" extension, and is deleted when the
2411 operation completes.  Oh, and if locking is enabled, the DB is automatically
2412 locked for the entire duration of the copy.
2413
2414
2415
2416 B<WARNING:> Only call optimize() on the top-level node of the database, and
2417 make sure there are no child references lying around.  DBM::Deep keeps a reference
2418 counter, and if it is greater than 1, optimize() will abort and return undef.
2419
2420 =head2 AUTOVIVIFICATION
2421
2422 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2423 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2424 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2425 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2426 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2427 this does not work:
2428
2429         $db->{foo}->{bar} = "hello";
2430
2431 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2432 being an empty hash.  Try this instead, which works fine:
2433
2434         $db->{foo} = { bar => "hello" };
2435
2436 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2437 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2438 Probably a bug in Perl.
2439
2440 =head2 FILE CORRUPTION
2441
2442 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2443 for a 32-bit signature when opened, but other corruption in files can cause
2444 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2445 stuck in an infinite loop depending on the level of corruption.  File write
2446 operations are not checked for failure (for speed), so if you happen to run
2447 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2448 be addressed in a later version of DBM::Deep.
2449
2450 =head2 DB OVER NFS
2451
2452 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2453 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2454 about setting up your NFS server with a locking daemon, then using lockf() to
2455 lock your files, but your mileage may vary there as well.  From what I
2456 understand, there is no real way to do it.  However, if you need access to the
2457 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2458 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2459
2460 =head2 COPYING OBJECTS
2461
2462 Beware of copying tied objects in Perl.  Very strange things can happen.
2463 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2464 returns a new, blessed, tied hash or array to the same level in the DB.
2465
2466         my $copy = $db->clone();
2467
2468 B<Note>: Since clone() here is cloning the object, not the database location, any
2469 modifications to either $db or $copy will be visible in both.
2470
2471 =head2 LARGE ARRAYS
2472
2473 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2474 These functions cause every element in the array to move, which can be murder
2475 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2476 a different location.  This will be addressed in the forthcoming version 1.00.
2477
2478 =head1 PERFORMANCE
2479
2480 This section discusses DBM::Deep's speed and memory usage.
2481
2482 =head2 SPEED
2483
2484 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2485 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2486 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2487 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2488 with huge databases.  Here is some test data:
2489
2490         Adding 1,000,000 keys to new DB file...
2491
2492         At 100 keys, avg. speed is 2,703 keys/sec
2493         At 200 keys, avg. speed is 2,642 keys/sec
2494         At 300 keys, avg. speed is 2,598 keys/sec
2495         At 400 keys, avg. speed is 2,578 keys/sec
2496         At 500 keys, avg. speed is 2,722 keys/sec
2497         At 600 keys, avg. speed is 2,628 keys/sec
2498         At 700 keys, avg. speed is 2,700 keys/sec
2499         At 800 keys, avg. speed is 2,607 keys/sec
2500         At 900 keys, avg. speed is 2,190 keys/sec
2501         At 1,000 keys, avg. speed is 2,570 keys/sec
2502         At 2,000 keys, avg. speed is 2,417 keys/sec
2503         At 3,000 keys, avg. speed is 1,982 keys/sec
2504         At 4,000 keys, avg. speed is 1,568 keys/sec
2505         At 5,000 keys, avg. speed is 1,533 keys/sec
2506         At 6,000 keys, avg. speed is 1,787 keys/sec
2507         At 7,000 keys, avg. speed is 1,977 keys/sec
2508         At 8,000 keys, avg. speed is 2,028 keys/sec
2509         At 9,000 keys, avg. speed is 2,077 keys/sec
2510         At 10,000 keys, avg. speed is 2,031 keys/sec
2511         At 20,000 keys, avg. speed is 1,970 keys/sec
2512         At 30,000 keys, avg. speed is 2,050 keys/sec
2513         At 40,000 keys, avg. speed is 2,073 keys/sec
2514         At 50,000 keys, avg. speed is 1,973 keys/sec
2515         At 60,000 keys, avg. speed is 1,914 keys/sec
2516         At 70,000 keys, avg. speed is 2,091 keys/sec
2517         At 80,000 keys, avg. speed is 2,103 keys/sec
2518         At 90,000 keys, avg. speed is 1,886 keys/sec
2519         At 100,000 keys, avg. speed is 1,970 keys/sec
2520         At 200,000 keys, avg. speed is 2,053 keys/sec
2521         At 300,000 keys, avg. speed is 1,697 keys/sec
2522         At 400,000 keys, avg. speed is 1,838 keys/sec
2523         At 500,000 keys, avg. speed is 1,941 keys/sec
2524         At 600,000 keys, avg. speed is 1,930 keys/sec
2525         At 700,000 keys, avg. speed is 1,735 keys/sec
2526         At 800,000 keys, avg. speed is 1,795 keys/sec
2527         At 900,000 keys, avg. speed is 1,221 keys/sec
2528         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2529
2530 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2531 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2532 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2533 Run time was 12 min 3 sec.
2534
2535 =head2 MEMORY USAGE
2536
2537 One of the great things about DBM::Deep is that it uses very little memory.
2538 Even with huge databases (1,000,000+ keys) you will not see much increased
2539 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2540 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2541 database handle:
2542
2543           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2544         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2545
2546 Basically the process is taking 2,716K of memory.  And here is the same
2547 process after storing and fetching 1,000,000 keys:
2548
2549           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2550         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2551
2552 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2553 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2554
2555 =head1 DB FILE FORMAT
2556
2557 In case you were interested in the underlying DB file format, it is documented
2558 here in this section.  You don't need to know this to use the module, it's just
2559 included for reference.
2560
2561 =head2 SIGNATURE
2562
2563 DBM::Deep files always start with a 32-bit signature to identify the file type.
2564 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2565 checked for when the file is opened and an error will be thrown if it's not found.
2566
2567 =head2 TAG
2568
2569 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2570 has a standard header containing the type of data, the length of data, and then
2571 the data itself.  The type is a single character (1 byte), the length is a
2572 32-bit unsigned long in network byte order, and the data is, well, the data.
2573 Here is how it unfolds:
2574
2575 =head2 MASTER INDEX
2576
2577 Immediately after the 32-bit file signature is the I<Master Index> record.
2578 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2579 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2580 depending on how the DBM::Deep object was constructed.
2581
2582 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2583 number).  The first 8-bit char of the MD5 signature is the offset into the
2584 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2585 index element is a file offset of the next tag for the key/element in question,
2586 which is usually a I<Bucket List> tag (see below).
2587
2588 The next tag I<could> be another index, depending on how many keys/elements
2589 exist.  See L<RE-INDEXING> below for details.
2590
2591 =head2 BUCKET LIST
2592
2593 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2594 file offsets to where the actual data is stored.  It starts with a standard
2595 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2596 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2597 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2598 When the list fills up, a I<Re-Index> operation is performed (See
2599 L<RE-INDEXING> below).
2600
2601 =head2 BUCKET
2602
2603 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2604 index/value pair (in array mode).  It starts with a standard tag header with
2605 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2606 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2607 header.  The size reported in the tag header is only for the value, but then,
2608 just after the value is another size (32-bit unsigned long) and then the plain
2609 key itself.  Since the value is likely to be fetched more often than the plain
2610 key, I figured it would be I<slightly> faster to store the value first.
2611
2612 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2613 record for the nested structure, where the process begins all over again.
2614
2615 =head2 RE-INDEXING
2616
2617 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2618 exhausted.  Then, when another key/element comes in, the list is converted to a
2619 new index record.  However, this index will look at the next char in the MD5
2620 hash, and arrange new Bucket List pointers accordingly.  This process is called
2621 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2622 17 (16 + new one) keys/elements are removed from the old Bucket List and
2623 inserted into the new index.  Several new Bucket Lists are created in the
2624 process, as a new MD5 char from the key is being examined (it is unlikely that
2625 the keys will all share the same next char of their MD5s).
2626
2627 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2628 when the Bucket Lists will turn into indexes, but the first round tends to
2629 happen right around 4,000 keys.  You will see a I<slight> decrease in
2630 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2631 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2632 right around 900,000 keys.  This process can continue nearly indefinitely --
2633 right up until the point the I<MD5> signatures start colliding with each other,
2634 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2635 getting struck by lightning while you are walking to cash in your tickets.
2636 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2637 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2638 this is 340 unodecillion, but don't quote me).
2639
2640 =head2 STORING
2641
2642 When a new key/element is stored, the key (or index number) is first run through
2643 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2644 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2645 for the first char of the signature (in this case I<b>).  If it does not exist,
2646 a new I<Bucket List> is created for our key (and the next 15 future keys that
2647 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2648 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2649 this point, unless we are replacing an existing I<Bucket>), where the actual
2650 data will be stored.
2651
2652 =head2 FETCHING
2653
2654 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2655 (or index number), then walking along the indexes.  If there are enough
2656 keys/elements in this DB level, there might be nested indexes, each linked to
2657 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2658 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2659 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2660 plain key are stored.
2661
2662 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2663 methods.  In this process the indexes are walked systematically, and each key
2664 fetched in increasing MD5 order (which is why it appears random).   Once the
2665 I<Bucket> is found, the value is skipped the plain key returned instead.
2666 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2667 alphabetically sorted.  This only happens on an index-level -- as soon as the
2668 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2669 so it's pretty much undefined how the keys will come out -- just like Perl's
2670 built-in hashes.
2671
2672 =head1 CODE COVERAGE
2673
2674 We use B<Devel::Cover> to test the code coverage of my tests, below is the
2675 B<Devel::Cover> report on this module's test suite.
2676
2677 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2678 File                           stmt   bran   cond    sub    pod   time  total
2679 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2680 blib/lib/DBM/Deep.pm           93.7   82.5   71.9   96.5   25.9   82.8   87.9
2681 blib/lib/DBM/Deep/Array.pm     98.8   88.0   90.9  100.0    n/a   12.8   96.3
2682 blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    4.4   92.3
2683 Total                          94.8   83.2   76.5   97.6   25.9  100.0   89.7
2684 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2685
2686 =head1 AUTHORS
2687
2688 Joseph Huckaby, L<jhuckaby@cpan.org>
2689 Rob Kinyon, L<rkinyon@cpan.org>
2690
2691 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2692
2693 =head1 SEE ALSO
2694
2695 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2696 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2697
2698 =head1 LICENSE
2699
2700 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2701 This is free software, you may use it and distribute it under the
2702 same terms as Perl itself.
2703
2704 =cut