lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.98);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->_fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     eval {
 213         local $SIG{'__DIE__'};
 214         # Theoretically, adding O_BINARY should remove the need for the binmode
 215         # Of course, testing it is going to be ... interesting.
 216         my $flags = O_RDWR | O_CREAT | O_BINARY;
 217
 218         my $fh;
 219         sysopen( $fh, $self->_root->{file}, $flags )
 220             or $fh = undef;
 221         $self->_root->{fh} = $fh;
 222     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 223         if (! defined($self->_fh)) {
 224                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 225         }
 226
 227     my $fh = $self->_fh;
 228
 229     #XXX Can we remove this by using the right sysopen() flags?
 230     # Maybe ... q.v. above
 231     binmode $fh; # for win32
 232
 233     if ($self->_root->{autoflush}) {
 234         my $old = select $fh;
 235         $|=1;
 236         select $old;
 237     }
 238
 239     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 249         print( $fh SIG_FILE);
 250         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|; $| = 1; $| = $old_af;
 258         select $old_fh;
 259
 260         my @stats = stat($fh);
 261         $self->_root->{inode} = $stats[1];
 262         $self->_root->{end} = $stats[7];
 263
 264         return 1;
 265     }
 266
 267     ##
 268     # Check signature was valid
 269     ##
 270     unless ($signature eq SIG_FILE) {
 271         $self->_close();
 272         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 273     }
 274
 275         my @stats = stat($fh);
 276         $self->_root->{inode} = $stats[1];
 277     $self->_root->{end} = $stats[7];
 278
 279     ##
 280     # Get our type from master index signature
 281     ##
 282     my $tag = $self->_load_tag($self->_base_offset);
 283
 284 #XXX We probably also want to store the hash algorithm name and not assume anything
 285 #XXX The cool thing would be to allow a different hashing algorithm at every level
 286
 287     if (!$tag) {
 288         return $self->_throw_error("Corrupted file, no master index record");
 289     }
 290     if ($self->{type} ne $tag->{signature}) {
 291         return $self->_throw_error("File type mismatch");
 292     }
 293
 294     return 1;
 295 }
 296
 297 sub _close {
 298         ##
 299         # Close database fh
 300         ##
 301     my $self = $_[0]->_get_self;
 302     close $self->_root->{fh} if $self->_root->{fh};
 303     $self->_root->{fh} = undef;
 304 }
 305
 306 sub _create_tag {
 307         ##
 308         # Given offset, signature and content, create tag and write to disk
 309         ##
 310         my ($self, $offset, $sig, $content) = @_;
 311         my $size = length($content);
 312
 313     my $fh = $self->_fh;
 314
 315         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 316         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 317
 318         if ($offset == $self->_root->{end}) {
 319                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 320         }
 321
 322         return {
 323                 signature => $sig,
 324                 size => $size,
 325                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 326                 content => $content
 327         };
 328 }
 329
 330 sub _load_tag {
 331         ##
 332         # Given offset, load single tag and return signature, size and data
 333         ##
 334         my $self = shift;
 335         my $offset = shift;
 336
 337     my $fh = $self->_fh;
 338
 339         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 340         if (eof $fh) { return undef; }
 341
 342     my $b;
 343     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 344     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 345
 346         my $buffer;
 347         read( $fh, $buffer, $size);
 348
 349         return {
 350                 signature => $sig,
 351                 size => $size,
 352                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 353                 content => $buffer
 354         };
 355 }
 356
 357 sub _index_lookup {
 358         ##
 359         # Given index tag, lookup single entry in index and return .
 360         ##
 361         my $self = shift;
 362         my ($tag, $index) = @_;
 363
 364         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 365         if (!$location) { return; }
 366
 367         return $self->_load_tag( $location );
 368 }
 369
 370 sub _add_bucket {
 371         ##
 372         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 373         # plain (undigested) key and value.
 374         ##
 375         my $self = shift;
 376         my ($tag, $md5, $plain_key, $value) = @_;
 377         my $keys = $tag->{content};
 378         my $location = 0;
 379         my $result = 2;
 380
 381     my $root = $self->_root;
 382
 383     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 384         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 385
 386     my $fh = $self->_fh;
 387
 388         ##
 389         # Iterate through buckets, seeing if this is a new entry or a replace.
 390         ##
 391         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 392                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 393                 if (!$subloc) {
 394                         ##
 395                         # Found empty bucket (end of list).  Populate and exit loop.
 396                         ##
 397                         $result = 2;
 398
 399             $location = $internal_ref
 400                 ? $value->_base_offset
 401                 : $root->{end};
 402
 403                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 404                         print( $fh $md5 . pack($LONG_PACK, $location) );
 405                         last;
 406                 }
 407
 408                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 409                 if ($md5 eq $key) {
 410                         ##
 411                         # Found existing bucket with same key.  Replace with new value.
 412                         ##
 413                         $result = 1;
 414
 415                         if ($internal_ref) {
 416                                 $location = $value->_base_offset;
 417                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 418                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 419                 return $result;
 420                         }
 421
 422             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 423             my $size;
 424             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 425
 426             ##
 427             # If value is a hash, array, or raw value with equal or less size, we can
 428             # reuse the same content area of the database.  Otherwise, we have to create
 429             # a new content area at the EOF.
 430             ##
 431             my $actual_length;
 432             my $r = Scalar::Util::reftype( $value ) || '';
 433             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 434                 $actual_length = $INDEX_SIZE;
 435
 436                 # if autobless is enabled, must also take into consideration
 437                 # the class name, as it is stored along with key/value.
 438                 if ( $root->{autobless} ) {
 439                     my $value_class = Scalar::Util::blessed($value);
 440                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 441                         $actual_length += length($value_class);
 442                     }
 443                 }
 444             }
 445             else { $actual_length = length($value); }
 446
 447             if ($actual_length <= $size) {
 448                 $location = $subloc;
 449             }
 450             else {
 451                 $location = $root->{end};
 452                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 453                 print( $fh pack($LONG_PACK, $location) );
 454             }
 455
 456                         last;
 457                 }
 458         }
 459
 460         ##
 461         # If this is an internal reference, return now.
 462         # No need to write value or plain key
 463         ##
 464         if ($internal_ref) {
 465         return $result;
 466     }
 467
 468         ##
 469         # If bucket didn't fit into list, split into a new index level
 470         ##
 471         if (!$location) {
 472                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 473                 print( $fh pack($LONG_PACK, $root->{end}) );
 474
 475                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 476                 my @offsets = ();
 477
 478                 $keys .= $md5 . pack($LONG_PACK, 0);
 479
 480                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 481                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 482                         if ($key) {
 483                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 484                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 485
 486                                 if ($offsets[$num]) {
 487                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 488                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 489                                         my $subkeys;
 490                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 491
 492                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 493                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 494                                                 if (!$subloc) {
 495                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 496                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 497                                                         last;
 498                                                 }
 499                                         } # k loop
 500                                 }
 501                                 else {
 502                                         $offsets[$num] = $root->{end};
 503                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 504                                         print( $fh pack($LONG_PACK, $root->{end}) );
 505
 506                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 507
 508                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 509                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 510                                 }
 511                         } # key is real
 512                 } # i loop
 513
 514                 $location ||= $root->{end};
 515         } # re-index bucket list
 516
 517         ##
 518         # Seek to content area and store signature, value and plaintext key
 519         ##
 520         if ($location) {
 521                 my $content_length;
 522                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 523
 524                 ##
 525                 # Write signature based on content type, set content length and write actual value.
 526                 ##
 527         my $r = Scalar::Util::reftype($value) || '';
 528                 if ($r eq 'HASH') {
 529                         print( $fh TYPE_HASH );
 530                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 531                         $content_length = $INDEX_SIZE;
 532                 }
 533                 elsif ($r eq 'ARRAY') {
 534                         print( $fh TYPE_ARRAY );
 535                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 536                         $content_length = $INDEX_SIZE;
 537                 }
 538                 elsif (!defined($value)) {
 539                         print( $fh SIG_NULL );
 540                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 541                         $content_length = 0;
 542                 }
 543                 else {
 544                         print( $fh SIG_DATA );
 545                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 546                         $content_length = length($value);
 547                 }
 548
 549                 ##
 550                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 551                 ##
 552                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 553
 554                 ##
 555                 # If value is blessed, preserve class name
 556                 ##
 557                 if ( $root->{autobless} ) {
 558             my $value_class = Scalar::Util::blessed($value);
 559             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 560                 ##
 561                 # Blessed ref -- will restore later
 562                 ##
 563                 print( $fh chr(1) );
 564                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 565                 $content_length += 1;
 566                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 567             }
 568             else {
 569                 print( $fh chr(0) );
 570                 $content_length += 1;
 571             }
 572         }
 573
 574                 ##
 575                 # If this is a new content area, advance EOF counter
 576                 ##
 577                 if ($location == $root->{end}) {
 578                         $root->{end} += SIG_SIZE;
 579                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 580                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 581                 }
 582
 583                 ##
 584                 # If content is a hash or array, create new child DBM::Deep object and
 585                 # pass each key or element to it.
 586                 ##
 587                 if ($r eq 'HASH') {
 588                         my $branch = DBM::Deep->new(
 589                                 type => TYPE_HASH,
 590                                 base_offset => $location,
 591                                 root => $root,
 592                         );
 593                         foreach my $key (keys %{$value}) {
 594                 $branch->STORE( $key, $value->{$key} );
 595                         }
 596                 }
 597                 elsif ($r eq 'ARRAY') {
 598                         my $branch = DBM::Deep->new(
 599                                 type => TYPE_ARRAY,
 600                                 base_offset => $location,
 601                                 root => $root,
 602                         );
 603                         my $index = 0;
 604                         foreach my $element (@{$value}) {
 605                 $branch->STORE( $index, $element );
 606                                 $index++;
 607                         }
 608                 }
 609
 610                 return $result;
 611         }
 612
 613         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 614 }
 615
 616 sub _get_bucket_value {
 617         ##
 618         # Fetch single value given tag and MD5 digested key.
 619         ##
 620         my $self = shift;
 621         my ($tag, $md5) = @_;
 622         my $keys = $tag->{content};
 623
 624     my $fh = $self->_fh;
 625
 626         ##
 627         # Iterate through buckets, looking for a key match
 628         ##
 629     BUCKET:
 630         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 631                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 632                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 633
 634                 if (!$subloc) {
 635                         ##
 636                         # Hit end of list, no match
 637                         ##
 638                         return;
 639                 }
 640
 641         if ( $md5 ne $key ) {
 642             next BUCKET;
 643         }
 644
 645         ##
 646         # Found match -- seek to offset and read signature
 647         ##
 648         my $signature;
 649         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 650         read( $fh, $signature, SIG_SIZE);
 651
 652         ##
 653         # If value is a hash or array, return new DBM::Deep object with correct offset
 654         ##
 655         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 656             my $obj = DBM::Deep->new(
 657                 type => $signature,
 658                 base_offset => $subloc,
 659                 root => $self->_root
 660             );
 661
 662             if ($self->_root->{autobless}) {
 663                 ##
 664                 # Skip over value and plain key to see if object needs
 665                 # to be re-blessed
 666                 ##
 667                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 668
 669                 my $size;
 670                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 671                 if ($size) { seek($fh, $size, SEEK_CUR); }
 672
 673                 my $bless_bit;
 674                 read( $fh, $bless_bit, 1);
 675                 if (ord($bless_bit)) {
 676                     ##
 677                     # Yes, object needs to be re-blessed
 678                     ##
 679                     my $class_name;
 680                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 681                     if ($size) { read( $fh, $class_name, $size); }
 682                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 683                 }
 684             }
 685
 686             return $obj;
 687         }
 688
 689         ##
 690         # Otherwise return actual value
 691         ##
 692         elsif ($signature eq SIG_DATA) {
 693             my $size;
 694             my $value = '';
 695             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 696             if ($size) { read( $fh, $value, $size); }
 697             return $value;
 698         }
 699
 700         ##
 701         # Key exists, but content is null
 702         ##
 703         else { return; }
 704         } # i loop
 705
 706         return;
 707 }
 708
 709 sub _delete_bucket {
 710         ##
 711         # Delete single key/value pair given tag and MD5 digested key.
 712         ##
 713         my $self = shift;
 714         my ($tag, $md5) = @_;
 715         my $keys = $tag->{content};
 716
 717     my $fh = $self->_fh;
 718
 719         ##
 720         # Iterate through buckets, looking for a key match
 721         ##
 722     BUCKET:
 723         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 724                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 725                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 726
 727                 if (!$subloc) {
 728                         ##
 729                         # Hit end of list, no match
 730                         ##
 731                         return;
 732                 }
 733
 734         if ( $md5 ne $key ) {
 735             next BUCKET;
 736         }
 737
 738         ##
 739         # Matched key -- delete bucket and return
 740         ##
 741         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 742         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 743         print( $fh chr(0) x $BUCKET_SIZE );
 744
 745         return 1;
 746         } # i loop
 747
 748         return;
 749 }
 750
 751 sub _bucket_exists {
 752         ##
 753         # Check existence of single key given tag and MD5 digested key.
 754         ##
 755         my $self = shift;
 756         my ($tag, $md5) = @_;
 757         my $keys = $tag->{content};
 758
 759         ##
 760         # Iterate through buckets, looking for a key match
 761         ##
 762     BUCKET:
 763         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 764                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 765                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 766
 767                 if (!$subloc) {
 768                         ##
 769                         # Hit end of list, no match
 770                         ##
 771                         return;
 772                 }
 773
 774         if ( $md5 ne $key ) {
 775             next BUCKET;
 776         }
 777
 778         ##
 779         # Matched key -- return true
 780         ##
 781         return 1;
 782         } # i loop
 783
 784         return;
 785 }
 786
 787 sub _find_bucket_list {
 788         ##
 789         # Locate offset for bucket list, given digested key
 790         ##
 791         my $self = shift;
 792         my $md5 = shift;
 793
 794         ##
 795         # Locate offset for bucket list using digest index system
 796         ##
 797         my $ch = 0;
 798         my $tag = $self->_load_tag($self->_base_offset);
 799         if (!$tag) { return; }
 800
 801         while ($tag->{signature} ne SIG_BLIST) {
 802                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 803                 if (!$tag) { return; }
 804                 $ch++;
 805         }
 806
 807         return $tag;
 808 }
 809
 810 sub _traverse_index {
 811         ##
 812         # Scan index and recursively step into deeper levels, looking for next key.
 813         ##
 814     my ($self, $offset, $ch, $force_return_next) = @_;
 815     $force_return_next = undef unless $force_return_next;
 816
 817         my $tag = $self->_load_tag( $offset );
 818
 819     my $fh = $self->_fh;
 820
 821         if ($tag->{signature} ne SIG_BLIST) {
 822                 my $content = $tag->{content};
 823                 my $start;
 824                 if ($self->{return_next}) { $start = 0; }
 825                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 826
 827                 for (my $index = $start; $index < 256; $index++) {
 828                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 829                         if ($subloc) {
 830                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 831                                 if (defined($result)) { return $result; }
 832                         }
 833                 } # index loop
 834
 835                 $self->{return_next} = 1;
 836         } # tag is an index
 837
 838         elsif ($tag->{signature} eq SIG_BLIST) {
 839                 my $keys = $tag->{content};
 840                 if ($force_return_next) { $self->{return_next} = 1; }
 841
 842                 ##
 843                 # Iterate through buckets, looking for a key match
 844                 ##
 845                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 846                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 847                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 848
 849                         if (!$subloc) {
 850                                 ##
 851                                 # End of bucket list -- return to outer loop
 852                                 ##
 853                                 $self->{return_next} = 1;
 854                                 last;
 855                         }
 856                         elsif ($key eq $self->{prev_md5}) {
 857                                 ##
 858                                 # Located previous key -- return next one found
 859                                 ##
 860                                 $self->{return_next} = 1;
 861                                 next;
 862                         }
 863                         elsif ($self->{return_next}) {
 864                                 ##
 865                                 # Seek to bucket location and skip over signature
 866                                 ##
 867                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 868
 869                                 ##
 870                                 # Skip over value to get to plain key
 871                                 ##
 872                                 my $size;
 873                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 874                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 875
 876                                 ##
 877                                 # Read in plain key and return as scalar
 878                                 ##
 879                                 my $plain_key;
 880                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 881                                 if ($size) { read( $fh, $plain_key, $size); }
 882
 883                                 return $plain_key;
 884                         }
 885                 } # bucket loop
 886
 887                 $self->{return_next} = 1;
 888         } # tag is a bucket list
 889
 890         return;
 891 }
 892
 893 sub _get_next_key {
 894         ##
 895         # Locate next key, given digested previous one
 896         ##
 897     my $self = $_[0]->_get_self;
 898
 899         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 900         $self->{return_next} = 0;
 901
 902         ##
 903         # If the previous key was not specifed, start at the top and
 904         # return the first one found.
 905         ##
 906         if (!$self->{prev_md5}) {
 907                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 908                 $self->{return_next} = 1;
 909         }
 910
 911         return $self->_traverse_index( $self->_base_offset, 0 );
 912 }
 913
 914 sub lock {
 915         ##
 916         # If db locking is set, flock() the db file.  If called multiple
 917         # times before unlock(), then the same number of unlocks() must
 918         # be called before the lock is released.
 919         ##
 920     my $self = $_[0]->_get_self;
 921         my $type = $_[1];
 922     $type = LOCK_EX unless defined $type;
 923
 924         if (!defined($self->_fh)) { return; }
 925
 926         if ($self->_root->{locking}) {
 927                 if (!$self->_root->{locked}) {
 928                         flock($self->_fh, $type);
 929
 930                         # refresh end counter in case file has changed size
 931                         my @stats = stat($self->_root->{file});
 932                         $self->_root->{end} = $stats[7];
 933
 934                         # double-check file inode, in case another process
 935                         # has optimize()d our file while we were waiting.
 936                         if ($stats[1] != $self->_root->{inode}) {
 937                                 $self->_open(); # re-open
 938                                 flock($self->_fh, $type); # re-lock
 939                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 940                         }
 941                 }
 942                 $self->_root->{locked}++;
 943
 944         return 1;
 945         }
 946
 947     return;
 948 }
 949
 950 sub unlock {
 951         ##
 952         # If db locking is set, unlock the db file.  See note in lock()
 953         # regarding calling lock() multiple times.
 954         ##
 955     my $self = $_[0]->_get_self;
 956
 957         if (!defined($self->_fh)) { return; }
 958
 959         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 960                 $self->_root->{locked}--;
 961                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 962
 963         return 1;
 964         }
 965
 966     return;
 967 }
 968
 969 sub _copy_value {
 970     my $self = shift->_get_self;
 971     my ($spot, $value) = @_;
 972
 973     if ( !ref $value ) {
 974         ${$spot} = $value;
 975     }
 976     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 977         my $type = $value->_type;
 978         ${$spot} = $type eq TYPE_HASH ? {} : [];
 979         $value->_copy_node( ${$spot} );
 980     }
 981     else {
 982         my $r = Scalar::Util::reftype( $value );
 983         my $c = Scalar::Util::blessed( $value );
 984         if ( $r eq 'ARRAY' ) {
 985             ${$spot} = [ @{$value} ];
 986         }
 987         else {
 988             ${$spot} = { %{$value} };
 989         }
 990         ${$spot} = bless ${$spot}, $c
 991             if defined $c;
 992     }
 993
 994     return 1;
 995 }
 996
 997 sub _copy_node {
 998         ##
 999         # Copy single level of keys or elements to new DB handle.
1000         # Recurse for nested structures
1001         ##
1002     my $self = shift->_get_self;
1003         my ($db_temp) = @_;
1004
1005         if ($self->_type eq TYPE_HASH) {
1006                 my $key = $self->first_key();
1007                 while ($key) {
1008                         my $value = $self->get($key);
1009             $self->_copy_value( \$db_temp->{$key}, $value );
1010                         $key = $self->next_key($key);
1011                 }
1012         }
1013         else {
1014                 my $length = $self->length();
1015                 for (my $index = 0; $index < $length; $index++) {
1016                         my $value = $self->get($index);
1017             $self->_copy_value( \$db_temp->[$index], $value );
1018                 }
1019         }
1020
1021     return 1;
1022 }
1023
1024 sub export {
1025         ##
1026         # Recursively export into standard Perl hashes and arrays.
1027         ##
1028     my $self = $_[0]->_get_self;
1029
1030         my $temp;
1031         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1032         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1033
1034         $self->lock();
1035         $self->_copy_node( $temp );
1036         $self->unlock();
1037
1038         return $temp;
1039 }
1040
1041 sub import {
1042         ##
1043         # Recursively import Perl hash/array structure
1044         ##
1045     #XXX This use of ref() seems to be ok
1046         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1047
1048     my $self = $_[0]->_get_self;
1049         my $struct = $_[1];
1050
1051     #XXX This use of ref() seems to be ok
1052         if (!ref($struct)) {
1053                 ##
1054                 # struct is not a reference, so just import based on our type
1055                 ##
1056                 shift @_;
1057
1058                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1059                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1060         }
1061
1062     my $r = Scalar::Util::reftype($struct) || '';
1063         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1064                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1065         }
1066         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1067                 $self->push( @$struct );
1068         }
1069         else {
1070                 return $self->_throw_error("Cannot import: type mismatch");
1071         }
1072
1073         return 1;
1074 }
1075
1076 sub optimize {
1077         ##
1078         # Rebuild entire database into new file, then move
1079         # it back on top of original.
1080         ##
1081     my $self = $_[0]->_get_self;
1082
1083 #XXX Need to create a new test for this
1084 #       if ($self->_root->{links} > 1) {
1085 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1086 #       }
1087
1088         my $db_temp = DBM::Deep->new(
1089                 file => $self->_root->{file} . '.tmp',
1090                 type => $self->_type
1091         );
1092         if (!$db_temp) {
1093                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1094         }
1095
1096         $self->lock();
1097         $self->_copy_node( $db_temp );
1098         undef $db_temp;
1099
1100         ##
1101         # Attempt to copy user, group and permissions over to new file
1102         ##
1103         my @stats = stat($self->_fh);
1104         my $perms = $stats[2] & 07777;
1105         my $uid = $stats[4];
1106         my $gid = $stats[5];
1107         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1108         chmod( $perms, $self->_root->{file} . '.tmp' );
1109
1110     # q.v. perlport for more information on this variable
1111     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1112                 ##
1113                 # Potential race condition when optmizing on Win32 with locking.
1114                 # The Windows filesystem requires that the filehandle be closed
1115                 # before it is overwritten with rename().  This could be redone
1116                 # with a soft copy.
1117                 ##
1118                 $self->unlock();
1119                 $self->_close();
1120         }
1121
1122         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1123                 unlink $self->_root->{file} . '.tmp';
1124                 $self->unlock();
1125                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1126         }
1127
1128         $self->unlock();
1129         $self->_close();
1130         $self->_open();
1131
1132         return 1;
1133 }
1134
1135 sub clone {
1136         ##
1137         # Make copy of object and return
1138         ##
1139     my $self = $_[0]->_get_self;
1140
1141         return DBM::Deep->new(
1142                 type => $self->_type,
1143                 base_offset => $self->_base_offset,
1144                 root => $self->_root
1145         );
1146 }
1147
1148 {
1149     my %is_legal_filter = map {
1150         $_ => ~~1,
1151     } qw(
1152         store_key store_value
1153         fetch_key fetch_value
1154     );
1155
1156     sub set_filter {
1157         ##
1158         # Setup filter function for storing or fetching the key or value
1159         ##
1160         my $self = $_[0]->_get_self;
1161         my $type = lc $_[1];
1162         my $func = $_[2] ? $_[2] : undef;
1163
1164         if ( $is_legal_filter{$type} ) {
1165             $self->_root->{"filter_$type"} = $func;
1166             return 1;
1167         }
1168
1169         return;
1170     }
1171 }
1172
1173 ##
1174 # Accessor methods
1175 ##
1176
1177 sub _root {
1178         ##
1179         # Get access to the root structure
1180         ##
1181     my $self = $_[0]->_get_self;
1182         return $self->{root};
1183 }
1184
1185 sub _fh {
1186         ##
1187         # Get access to the raw fh
1188         ##
1189     #XXX It will be useful, though, when we split out HASH and ARRAY
1190     my $self = $_[0]->_get_self;
1191         return $self->_root->{fh};
1192 }
1193
1194 sub _type {
1195         ##
1196         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1197         ##
1198     my $self = $_[0]->_get_self;
1199         return $self->{type};
1200 }
1201
1202 sub _base_offset {
1203         ##
1204         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1205         ##
1206     my $self = $_[0]->_get_self;
1207         return $self->{base_offset};
1208 }
1209
1210 sub error {
1211         ##
1212         # Get last error string, or undef if no error
1213         ##
1214         return $_[0]
1215         ? ( $_[0]->_get_self->{root}->{error} or undef )
1216         : $@;
1217 }
1218
1219 ##
1220 # Utility methods
1221 ##
1222
1223 sub _throw_error {
1224         ##
1225         # Store error string in self
1226         ##
1227         my $error_text = $_[1];
1228
1229     if ( Scalar::Util::blessed $_[0] ) {
1230         my $self = $_[0]->_get_self;
1231         $self->_root->{error} = $error_text;
1232
1233         unless ($self->_root->{debug}) {
1234             die "DBM::Deep: $error_text\n";
1235         }
1236
1237         warn "DBM::Deep: $error_text\n";
1238         return;
1239     }
1240     else {
1241         die "DBM::Deep: $error_text\n";
1242     }
1243 }
1244
1245 sub clear_error {
1246         ##
1247         # Clear error state
1248         ##
1249     my $self = $_[0]->_get_self;
1250
1251         undef $self->_root->{error};
1252 }
1253
1254 sub _precalc_sizes {
1255         ##
1256         # Precalculate index, bucket and bucket list sizes
1257         ##
1258
1259     #XXX I don't like this ...
1260     set_pack() unless defined $LONG_SIZE;
1261
1262         $INDEX_SIZE = 256 * $LONG_SIZE;
1263         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1264         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1265 }
1266
1267 sub set_pack {
1268         ##
1269         # Set pack/unpack modes (see file header for more)
1270         ##
1271     my ($long_s, $long_p, $data_s, $data_p) = @_;
1272
1273     $LONG_SIZE = $long_s ? $long_s : 4;
1274     $LONG_PACK = $long_p ? $long_p : 'N';
1275
1276     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1277     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1278
1279         _precalc_sizes();
1280 }
1281
1282 sub set_digest {
1283         ##
1284         # Set key digest function (default is MD5)
1285         ##
1286     my ($digest_func, $hash_size) = @_;
1287
1288     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1289     $HASH_SIZE = $hash_size ? $hash_size : 16;
1290
1291         _precalc_sizes();
1292 }
1293
1294 ##
1295 # tie() methods (hashes and arrays)
1296 ##
1297
1298 sub STORE {
1299         ##
1300         # Store single hash key/value or array element in database.
1301         ##
1302     my $self = $_[0]->_get_self;
1303         my $key = $_[1];
1304
1305     # User may be storing a hash, in which case we do not want it run
1306     # through the filtering system
1307         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1308         ? $self->_root->{filter_store_value}->($_[2])
1309         : $_[2];
1310
1311         my $md5 = $DIGEST_FUNC->($key);
1312
1313         ##
1314         # Make sure file is open
1315         ##
1316         if (!defined($self->_fh) && !$self->_open()) {
1317                 return;
1318         }
1319         ##
1320
1321         ##
1322         # Request exclusive lock for writing
1323         ##
1324         $self->lock( LOCK_EX );
1325
1326         my $fh = $self->_fh;
1327
1328         ##
1329         # Locate offset for bucket list using digest index system
1330         ##
1331         my $tag = $self->_load_tag($self->_base_offset);
1332         if (!$tag) {
1333                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1334         }
1335
1336         my $ch = 0;
1337         while ($tag->{signature} ne SIG_BLIST) {
1338                 my $num = ord(substr($md5, $ch, 1));
1339
1340         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1341                 my $new_tag = $self->_index_lookup($tag, $num);
1342
1343                 if (!$new_tag) {
1344                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1345                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1346
1347                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1348
1349                         $tag->{ref_loc} = $ref_loc;
1350                         $tag->{ch} = $ch;
1351
1352                         last;
1353                 }
1354                 else {
1355                         $tag = $new_tag;
1356
1357                         $tag->{ref_loc} = $ref_loc;
1358                         $tag->{ch} = $ch;
1359                 }
1360                 $ch++;
1361         }
1362
1363         ##
1364         # Add key/value to bucket list
1365         ##
1366         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1367
1368         $self->unlock();
1369
1370         return $result;
1371 }
1372
1373 sub FETCH {
1374         ##
1375         # Fetch single value or element given plain key or array index
1376         ##
1377     my $self = shift->_get_self;
1378     my $key = shift;
1379
1380         ##
1381         # Make sure file is open
1382         ##
1383         if (!defined($self->_fh)) { $self->_open(); }
1384
1385         my $md5 = $DIGEST_FUNC->($key);
1386
1387         ##
1388         # Request shared lock for reading
1389         ##
1390         $self->lock( LOCK_SH );
1391
1392         my $tag = $self->_find_bucket_list( $md5 );
1393         if (!$tag) {
1394                 $self->unlock();
1395                 return;
1396         }
1397
1398         ##
1399         # Get value from bucket list
1400         ##
1401         my $result = $self->_get_bucket_value( $tag, $md5 );
1402
1403         $self->unlock();
1404
1405     #XXX What is ref() checking here?
1406     #YYY Filters only apply on scalar values, so the ref check is making
1407     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1408         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1409         ? $self->_root->{filter_fetch_value}->($result)
1410         : $result;
1411 }
1412
1413 sub DELETE {
1414         ##
1415         # Delete single key/value pair or element given plain key or array index
1416         ##
1417     my $self = $_[0]->_get_self;
1418         my $key = $_[1];
1419
1420         my $md5 = $DIGEST_FUNC->($key);
1421
1422         ##
1423         # Make sure file is open
1424         ##
1425         if (!defined($self->_fh)) { $self->_open(); }
1426
1427         ##
1428         # Request exclusive lock for writing
1429         ##
1430         $self->lock( LOCK_EX );
1431
1432         my $tag = $self->_find_bucket_list( $md5 );
1433         if (!$tag) {
1434                 $self->unlock();
1435                 return;
1436         }
1437
1438         ##
1439         # Delete bucket
1440         ##
1441     my $value = $self->_get_bucket_value( $tag, $md5 );
1442         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1443         $value = $self->_root->{filter_fetch_value}->($value);
1444     }
1445
1446         my $result = $self->_delete_bucket( $tag, $md5 );
1447
1448         ##
1449         # If this object is an array and the key deleted was on the end of the stack,
1450         # decrement the length variable.
1451         ##
1452
1453         $self->unlock();
1454
1455         return $value;
1456 }
1457
1458 sub EXISTS {
1459         ##
1460         # Check if a single key or element exists given plain key or array index
1461         ##
1462     my $self = $_[0]->_get_self;
1463         my $key = $_[1];
1464
1465         my $md5 = $DIGEST_FUNC->($key);
1466
1467         ##
1468         # Make sure file is open
1469         ##
1470         if (!defined($self->_fh)) { $self->_open(); }
1471
1472         ##
1473         # Request shared lock for reading
1474         ##
1475         $self->lock( LOCK_SH );
1476
1477         my $tag = $self->_find_bucket_list( $md5 );
1478
1479         ##
1480         # For some reason, the built-in exists() function returns '' for false
1481         ##
1482         if (!$tag) {
1483                 $self->unlock();
1484                 return '';
1485         }
1486
1487         ##
1488         # Check if bucket exists and return 1 or ''
1489         ##
1490         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1491
1492         $self->unlock();
1493
1494         return $result;
1495 }
1496
1497 sub CLEAR {
1498         ##
1499         # Clear all keys from hash, or all elements from array.
1500         ##
1501     my $self = $_[0]->_get_self;
1502
1503         ##
1504         # Make sure file is open
1505         ##
1506         if (!defined($self->_fh)) { $self->_open(); }
1507
1508         ##
1509         # Request exclusive lock for writing
1510         ##
1511         $self->lock( LOCK_EX );
1512
1513     my $fh = $self->_fh;
1514
1515         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1516         if (eof $fh) {
1517                 $self->unlock();
1518                 return;
1519         }
1520
1521         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1522
1523         $self->unlock();
1524
1525         return 1;
1526 }
1527
1528 ##
1529 # Public method aliases
1530 ##
1531 sub put { (shift)->STORE( @_ ) }
1532 sub store { (shift)->STORE( @_ ) }
1533 sub get { (shift)->FETCH( @_ ) }
1534 sub fetch { (shift)->FETCH( @_ ) }
1535 sub delete { (shift)->DELETE( @_ ) }
1536 sub exists { (shift)->EXISTS( @_ ) }
1537 sub clear { (shift)->CLEAR( @_ ) }
1538
1539 package DBM::Deep::_::Root;
1540
1541 sub new {
1542     my $class = shift;
1543     my ($args) = @_;
1544
1545     my $self = bless {
1546         file => undef,
1547         fh => undef,
1548         file_offset => 0,
1549         end => 0,
1550         autoflush => undef,
1551         locking => undef,
1552         debug => undef,
1553         filter_store_key => undef,
1554         filter_store_value => undef,
1555         filter_fetch_key => undef,
1556         filter_fetch_value => undef,
1557         autobless => undef,
1558         locked => 0,
1559         %$args,
1560     }, $class;
1561
1562     if ( $self->{fh} && !$self->{file_offset} ) {
1563         $self->{file_offset} = tell( $self->{fh} );
1564     }
1565
1566     return $self;
1567 }
1568
1569 sub DESTROY {
1570     my $self = shift;
1571     return unless $self;
1572
1573     close $self->{fh} if $self->{fh};
1574
1575     return;
1576 }
1577
1578 1;
1579
1580 __END__
1581
1582 =head1 NAME
1583
1584 DBM::Deep - A pure perl multi-level hash/array DBM
1585
1586 =head1 SYNOPSIS
1587
1588   use DBM::Deep;
1589   my $db = DBM::Deep->new( "foo.db" );
1590
1591   $db->{key} = 'value'; # tie() style
1592   print $db->{key};
1593
1594   $db->put('key' => 'value'); # OO style
1595   print $db->get('key');
1596
1597   # true multi-level support
1598   $db->{my_complex} = [
1599         'hello', { perl => 'rules' },
1600         42, 99,
1601   ];
1602
1603 =head1 DESCRIPTION
1604
1605 A unique flat-file database module, written in pure perl.  True
1606 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1607 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1608 handle millions of keys and unlimited hash levels without significant
1609 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1610 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1611 Mac OS X and Windows.
1612
1613 =head1 INSTALLATION
1614
1615 Hopefully you are using Perl's excellent CPAN module, which will download
1616 and install the module for you.  If not, get the tarball, and run these
1617 commands:
1618
1619         tar zxf DBM-Deep-*
1620         cd DBM-Deep-*
1621         perl Makefile.PL
1622         make
1623         make test
1624         make install
1625
1626 =head1 SETUP
1627
1628 Construction can be done OO-style (which is the recommended way), or using
1629 Perl's tie() function.  Both are examined here.
1630
1631 =head2 OO CONSTRUCTION
1632
1633 The recommended way to construct a DBM::Deep object is to use the new()
1634 method, which gets you a blessed, tied hash or array reference.
1635
1636         my $db = DBM::Deep->new( "foo.db" );
1637
1638 This opens a new database handle, mapped to the file "foo.db".  If this
1639 file does not exist, it will automatically be created.  DB files are
1640 opened in "r+" (read/write) mode, and the type of object returned is a
1641 hash, unless otherwise specified (see L<OPTIONS> below).
1642
1643 You can pass a number of options to the constructor to specify things like
1644 locking, autoflush, etc.  This is done by passing an inline hash:
1645
1646         my $db = DBM::Deep->new(
1647                 file => "foo.db",
1648                 locking => 1,
1649                 autoflush => 1
1650         );
1651
1652 Notice that the filename is now specified I<inside> the hash with
1653 the "file" parameter, as opposed to being the sole argument to the
1654 constructor.  This is required if any options are specified.
1655 See L<OPTIONS> below for the complete list.
1656
1657
1658
1659 You can also start with an array instead of a hash.  For this, you must
1660 specify the C<type> parameter:
1661
1662         my $db = DBM::Deep->new(
1663                 file => "foo.db",
1664                 type => DBM::Deep->TYPE_ARRAY
1665         );
1666
1667 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1668 a new DB file.  If you create a DBM::Deep object with an existing file, the
1669 C<type> will be loaded from the file header, and an error will be thrown if
1670 the wrong type is passed in.
1671
1672 =head2 TIE CONSTRUCTION
1673
1674 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1675 tie() function.  The object returned from tie() can be used to call methods,
1676 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1677 file (as expected with most tie'd objects).
1678
1679         my %hash;
1680         my $db = tie %hash, "DBM::Deep", "foo.db";
1681
1682         my @array;
1683         my $db = tie @array, "DBM::Deep", "bar.db";
1684
1685 As with the OO constructor, you can replace the DB filename parameter with
1686 a hash containing one or more options (see L<OPTIONS> just below for the
1687 complete list).
1688
1689         tie %hash, "DBM::Deep", {
1690                 file => "foo.db",
1691                 locking => 1,
1692                 autoflush => 1
1693         };
1694
1695 =head2 OPTIONS
1696
1697 There are a number of options that can be passed in when constructing your
1698 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1699
1700 =over
1701
1702 =item * file
1703
1704 Filename of the DB file to link the handle to.  You can pass a full absolute
1705 filesystem path, partial path, or a plain filename if the file is in the
1706 current working directory.  This is a required parameter (though q.v. fh).
1707
1708 =item * fh
1709
1710 If you want, you can pass in the fh instead of the file. This is most useful for doing
1711 something like:
1712
1713   my $db = DBM::Deep->new( { fh => \*DATA } );
1714
1715 You are responsible for making sure that the fh has been opened appropriately for your
1716 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1717 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1718 needs to read from the fh.
1719
1720 =item * file_offset
1721
1722 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1723 not need to set this. However, it's there if you want it.
1724
1725 If you pass in fh and do not set this, it will be set appropriately.
1726
1727 =item * type
1728
1729 This parameter specifies what type of object to create, a hash or array.  Use
1730 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1731 This only takes effect when beginning a new file.  This is an optional
1732 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1733
1734 =item * locking
1735
1736 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1737 function to lock the database in exclusive mode for writes, and shared mode for
1738 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1739 any child hashes or arrays> that use the same DB file.  This is an optional
1740 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1741
1742 =item * autoflush
1743
1744 Specifies whether autoflush is to be enabled on the underlying filehandle.
1745 This obviously slows down write operations, but is required if you may have
1746 multiple processes accessing the same DB file (also consider enable I<locking>).
1747 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1748 (disabled).
1749
1750 =item * autobless
1751
1752 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1753 restore them when fetched.  This is an B<experimental> feature, and does have
1754 side-effects.  Basically, when hashes are re-blessed into their original
1755 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1756 able to call any DBM::Deep methods on them.  You have been warned.
1757 This is an optional parameter, and defaults to 0 (disabled).
1758
1759 =item * filter_*
1760
1761 See L<FILTERS> below.
1762
1763 =item * debug
1764
1765 Setting I<debug> mode will make all errors non-fatal, dump them out to
1766 STDERR, and continue on.  This is for debugging purposes only, and probably
1767 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1768
1769 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1770
1771 =back
1772
1773 =head1 TIE INTERFACE
1774
1775 With DBM::Deep you can access your databases using Perl's standard hash/array
1776 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1777 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1778 to the right place -- the DB file.  This has nothing to do with the
1779 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1780 using regular hashes and arrays, rather than calling functions like C<get()>
1781 and C<put()> (although those work too).  It is entirely up to you how to want
1782 to access your databases.
1783
1784 =head2 HASHES
1785
1786 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1787 or even nested hashes (or arrays) using standard Perl syntax:
1788
1789         my $db = DBM::Deep->new( "foo.db" );
1790
1791         $db->{mykey} = "myvalue";
1792         $db->{myhash} = {};
1793         $db->{myhash}->{subkey} = "subvalue";
1794
1795         print $db->{myhash}->{subkey} . "\n";
1796
1797 You can even step through hash keys using the normal Perl C<keys()> function:
1798
1799         foreach my $key (keys %$db) {
1800                 print "$key: " . $db->{$key} . "\n";
1801         }
1802
1803 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1804 pushes them onto an array, all before the loop even begins.  If you have an
1805 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1806 Perl's C<each()> function, which pulls keys/values one at a time, using very
1807 little memory:
1808
1809         while (my ($key, $value) = each %$db) {
1810                 print "$key: $value\n";
1811         }
1812
1813 Please note that when using C<each()>, you should always pass a direct
1814 hash reference, not a lookup.  Meaning, you should B<never> do this:
1815
1816         # NEVER DO THIS
1817         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1818
1819 This causes an infinite loop, because for each iteration, Perl is calling
1820 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1821 it effectively keeps returning the first key over and over again. Instead,
1822 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1823
1824 =head2 ARRAYS
1825
1826 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1827 reference.  This includes inserting, removing and manipulating elements,
1828 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1829 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1830 or simply be a nested array reference inside a hash.  Example:
1831
1832         my $db = DBM::Deep->new(
1833                 file => "foo-array.db",
1834                 type => DBM::Deep->TYPE_ARRAY
1835         );
1836
1837         $db->[0] = "foo";
1838         push @$db, "bar", "baz";
1839         unshift @$db, "bah";
1840
1841         my $last_elem = pop @$db; # baz
1842         my $first_elem = shift @$db; # bah
1843         my $second_elem = $db->[1]; # bar
1844
1845         my $num_elements = scalar @$db;
1846
1847 =head1 OO INTERFACE
1848
1849 In addition to the I<tie()> interface, you can also use a standard OO interface
1850 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1851 array) has its own methods, but both types share the following common methods:
1852 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1853
1854 =over
1855
1856 =item * new() / clone()
1857
1858 These are the constructor and copy-functions.
1859
1860 =item * put() / store()
1861
1862 Stores a new hash key/value pair, or sets an array element value.  Takes two
1863 arguments, the hash key or array index, and the new value.  The value can be
1864 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1865
1866         $db->put("foo", "bar"); # for hashes
1867         $db->put(1, "bar"); # for arrays
1868
1869 =item * get() / fetch()
1870
1871 Fetches the value of a hash key or array element.  Takes one argument: the hash
1872 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1873 data type stored.
1874
1875         my $value = $db->get("foo"); # for hashes
1876         my $value = $db->get(1); # for arrays
1877
1878 =item * exists()
1879
1880 Checks if a hash key or array index exists.  Takes one argument: the hash key
1881 or array index.  Returns true if it exists, false if not.
1882
1883         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1884         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1885
1886 =item * delete()
1887
1888 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1889 key or array index.  Returns true on success, false if not found.  For arrays,
1890 the remaining elements located after the deleted element are NOT moved over.
1891 The deleted element is essentially just undefined, which is exactly how Perl's
1892 internal arrays work.  Please note that the space occupied by the deleted
1893 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1894 below for details and workarounds.
1895
1896         $db->delete("foo"); # for hashes
1897         $db->delete(1); # for arrays
1898
1899 =item * clear()
1900
1901 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1902 value.  Please note that the space occupied by the deleted keys/values or
1903 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1904 details and workarounds.
1905
1906         $db->clear(); # hashes or arrays
1907
1908 =item * lock() / unlock()
1909
1910 q.v. Locking.
1911
1912 =item * optimize()
1913
1914 Recover lost disk space.
1915
1916 =item * import() / export()
1917
1918 Data going in and out.
1919
1920 =item * set_digest() / set_pack() / set_filter()
1921
1922 q.v. adjusting the interal parameters.
1923
1924 =item * error() / clear_error()
1925
1926 Error handling methods. These are deprecated and will be removed in 1.00.
1927 .
1928 =back
1929
1930 =head2 HASHES
1931
1932 For hashes, DBM::Deep supports all the common methods described above, and the
1933 following additional methods: C<first_key()> and C<next_key()>.
1934
1935 =over
1936
1937 =item * first_key()
1938
1939 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1940 fetched in an undefined order (which appears random).  Takes no arguments,
1941 returns the key as a scalar value.
1942
1943         my $key = $db->first_key();
1944
1945 =item * next_key()
1946
1947 Returns the "next" key in the hash, given the previous one as the sole argument.
1948 Returns undef if there are no more keys to be fetched.
1949
1950         $key = $db->next_key($key);
1951
1952 =back
1953
1954 Here are some examples of using hashes:
1955
1956         my $db = DBM::Deep->new( "foo.db" );
1957
1958         $db->put("foo", "bar");
1959         print "foo: " . $db->get("foo") . "\n";
1960
1961         $db->put("baz", {}); # new child hash ref
1962         $db->get("baz")->put("buz", "biz");
1963         print "buz: " . $db->get("baz")->get("buz") . "\n";
1964
1965         my $key = $db->first_key();
1966         while ($key) {
1967                 print "$key: " . $db->get($key) . "\n";
1968                 $key = $db->next_key($key);
1969         }
1970
1971         if ($db->exists("foo")) { $db->delete("foo"); }
1972
1973 =head2 ARRAYS
1974
1975 For arrays, DBM::Deep supports all the common methods described above, and the
1976 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1977 C<unshift()> and C<splice()>.
1978
1979 =over
1980
1981 =item * length()
1982
1983 Returns the number of elements in the array.  Takes no arguments.
1984
1985         my $len = $db->length();
1986
1987 =item * push()
1988
1989 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1990 refs or array refs.  No return value.
1991
1992         $db->push("foo", "bar", {});
1993
1994 =item * pop()
1995
1996 Fetches the last element in the array, and deletes it.  Takes no arguments.
1997 Returns undef if array is empty.  Returns the element value.
1998
1999         my $elem = $db->pop();
2000
2001 =item * shift()
2002
2003 Fetches the first element in the array, deletes it, then shifts all the
2004 remaining elements over to take up the space.  Returns the element value.  This
2005 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2006 details.
2007
2008         my $elem = $db->shift();
2009
2010 =item * unshift()
2011
2012 Inserts one or more elements onto the beginning of the array, shifting all
2013 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2014 No return value.  This method is not recommended with large arrays -- see
2015 <LARGE ARRAYS> below for details.
2016
2017         $db->unshift("foo", "bar", {});
2018
2019 =item * splice()
2020
2021 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2022 -f splice> for usage -- it is too complicated to document here.  This method is
2023 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2024
2025 =back
2026
2027 Here are some examples of using arrays:
2028
2029         my $db = DBM::Deep->new(
2030                 file => "foo.db",
2031                 type => DBM::Deep->TYPE_ARRAY
2032         );
2033
2034         $db->push("bar", "baz");
2035         $db->unshift("foo");
2036         $db->put(3, "buz");
2037
2038         my $len = $db->length();
2039         print "length: $len\n"; # 4
2040
2041         for (my $k=0; $k<$len; $k++) {
2042                 print "$k: " . $db->get($k) . "\n";
2043         }
2044
2045         $db->splice(1, 2, "biz", "baf");
2046
2047         while (my $elem = shift @$db) {
2048                 print "shifted: $elem\n";
2049         }
2050
2051 =head1 LOCKING
2052
2053 Enable automatic file locking by passing a true value to the C<locking>
2054 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2055
2056         my $db = DBM::Deep->new(
2057                 file => "foo.db",
2058                 locking => 1
2059         );
2060
2061 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2062 mode for writes, and shared mode for reads.  This is required if you have
2063 multiple processes accessing the same database file, to avoid file corruption.
2064 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2065 NFS> below for more.
2066
2067 =head2 EXPLICIT LOCKING
2068
2069 You can explicitly lock a database, so it remains locked for multiple
2070 transactions.  This is done by calling the C<lock()> method, and passing an
2071 optional lock mode argument (defaults to exclusive mode).  This is particularly
2072 useful for things like counters, where the current value needs to be fetched,
2073 then incremented, then stored again.
2074
2075         $db->lock();
2076         my $counter = $db->get("counter");
2077         $counter++;
2078         $db->put("counter", $counter);
2079         $db->unlock();
2080
2081         # or...
2082
2083         $db->lock();
2084         $db->{counter}++;
2085         $db->unlock();
2086
2087 You can pass C<lock()> an optional argument, which specifies which mode to use
2088 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2089 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2090 same as the constants defined in Perl's C<Fcntl> module.
2091
2092         $db->lock( DBM::Deep->LOCK_SH );
2093         # something here
2094         $db->unlock();
2095
2096 =head1 IMPORTING/EXPORTING
2097
2098 You can import existing complex structures by calling the C<import()> method,
2099 and export an entire database into an in-memory structure using the C<export()>
2100 method.  Both are examined here.
2101
2102 =head2 IMPORTING
2103
2104 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2105 walking the structure and adding keys/elements to the database as you go,
2106 simply pass a reference to the C<import()> method.  This recursively adds
2107 everything to an existing DBM::Deep object for you.  Here is an example:
2108
2109         my $struct = {
2110                 key1 => "value1",
2111                 key2 => "value2",
2112                 array1 => [ "elem0", "elem1", "elem2" ],
2113                 hash1 => {
2114                         subkey1 => "subvalue1",
2115                         subkey2 => "subvalue2"
2116                 }
2117         };
2118
2119         my $db = DBM::Deep->new( "foo.db" );
2120         $db->import( $struct );
2121
2122         print $db->{key1} . "\n"; # prints "value1"
2123
2124 This recursively imports the entire C<$struct> object into C<$db>, including
2125 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2126 keys are merged with the existing ones, replacing if they already exist.
2127 The C<import()> method can be called on any database level (not just the base
2128 level), and works with both hash and array DB types.
2129
2130 B<Note:> Make sure your existing structure has no circular references in it.
2131 These will cause an infinite loop when importing.
2132
2133 =head2 EXPORTING
2134
2135 Calling the C<export()> method on an existing DBM::Deep object will return
2136 a reference to a new in-memory copy of the database.  The export is done
2137 recursively, so all nested hashes/arrays are all exported to standard Perl
2138 objects.  Here is an example:
2139
2140         my $db = DBM::Deep->new( "foo.db" );
2141
2142         $db->{key1} = "value1";
2143         $db->{key2} = "value2";
2144         $db->{hash1} = {};
2145         $db->{hash1}->{subkey1} = "subvalue1";
2146         $db->{hash1}->{subkey2} = "subvalue2";
2147
2148         my $struct = $db->export();
2149
2150         print $struct->{key1} . "\n"; # prints "value1"
2151
2152 This makes a complete copy of the database in memory, and returns a reference
2153 to it.  The C<export()> method can be called on any database level (not just
2154 the base level), and works with both hash and array DB types.  Be careful of
2155 large databases -- you can store a lot more data in a DBM::Deep object than an
2156 in-memory Perl structure.
2157
2158 B<Note:> Make sure your database has no circular references in it.
2159 These will cause an infinite loop when exporting.
2160
2161 =head1 FILTERS
2162
2163 DBM::Deep has a number of hooks where you can specify your own Perl function
2164 to perform filtering on incoming or outgoing data.  This is a perfect
2165 way to extend the engine, and implement things like real-time compression or
2166 encryption.  Filtering applies to the base DB level, and all child hashes /
2167 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2168 constructed, or by calling the C<set_filter()> method at any time.  There are
2169 four available filter hooks, described below:
2170
2171 =over
2172
2173 =item * filter_store_key
2174
2175 This filter is called whenever a hash key is stored.  It
2176 is passed the incoming key, and expected to return a transformed key.
2177
2178 =item * filter_store_value
2179
2180 This filter is called whenever a hash key or array element is stored.  It
2181 is passed the incoming value, and expected to return a transformed value.
2182
2183 =item * filter_fetch_key
2184
2185 This filter is called whenever a hash key is fetched (i.e. via
2186 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2187 and expected to return the plain key.
2188
2189 =item * filter_fetch_value
2190
2191 This filter is called whenever a hash key or array element is fetched.
2192 It is passed the transformed value, and expected to return the plain value.
2193
2194 =back
2195
2196 Here are the two ways to setup a filter hook:
2197
2198         my $db = DBM::Deep->new(
2199                 file => "foo.db",
2200                 filter_store_value => \&my_filter_store,
2201                 filter_fetch_value => \&my_filter_fetch
2202         );
2203
2204         # or...
2205
2206         $db->set_filter( "filter_store_value", \&my_filter_store );
2207         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2208
2209 Your filter function will be called only when dealing with SCALAR keys or
2210 values.  When nested hashes and arrays are being stored/fetched, filtering
2211 is bypassed.  Filters are called as static functions, passed a single SCALAR
2212 argument, and expected to return a single SCALAR value.  If you want to
2213 remove a filter, set the function reference to C<undef>:
2214
2215         $db->set_filter( "filter_store_value", undef );
2216
2217 =head2 REAL-TIME ENCRYPTION EXAMPLE
2218
2219 Here is a working example that uses the I<Crypt::Blowfish> module to
2220 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2221 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2222 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2223
2224         use DBM::Deep;
2225         use Crypt::Blowfish;
2226         use Crypt::CBC;
2227
2228         my $cipher = Crypt::CBC->new({
2229                 'key'             => 'my secret key',
2230                 'cipher'          => 'Blowfish',
2231                 'iv'              => '$KJh#(}q',
2232                 'regenerate_key'  => 0,
2233                 'padding'         => 'space',
2234                 'prepend_iv'      => 0
2235         });
2236
2237         my $db = DBM::Deep->new(
2238                 file => "foo-encrypt.db",
2239                 filter_store_key => \&my_encrypt,
2240                 filter_store_value => \&my_encrypt,
2241                 filter_fetch_key => \&my_decrypt,
2242                 filter_fetch_value => \&my_decrypt,
2243         );
2244
2245         $db->{key1} = "value1";
2246         $db->{key2} = "value2";
2247         print "key1: " . $db->{key1} . "\n";
2248         print "key2: " . $db->{key2} . "\n";
2249
2250         undef $db;
2251         exit;
2252
2253         sub my_encrypt {
2254                 return $cipher->encrypt( $_[0] );
2255         }
2256         sub my_decrypt {
2257                 return $cipher->decrypt( $_[0] );
2258         }
2259
2260 =head2 REAL-TIME COMPRESSION EXAMPLE
2261
2262 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2263 compression / decompression of keys & values with DBM::Deep Filters.
2264 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2265 more on I<Compress::Zlib>.
2266
2267         use DBM::Deep;
2268         use Compress::Zlib;
2269
2270         my $db = DBM::Deep->new(
2271                 file => "foo-compress.db",
2272                 filter_store_key => \&my_compress,
2273                 filter_store_value => \&my_compress,
2274                 filter_fetch_key => \&my_decompress,
2275                 filter_fetch_value => \&my_decompress,
2276         );
2277
2278         $db->{key1} = "value1";
2279         $db->{key2} = "value2";
2280         print "key1: " . $db->{key1} . "\n";
2281         print "key2: " . $db->{key2} . "\n";
2282
2283         undef $db;
2284         exit;
2285
2286         sub my_compress {
2287                 return Compress::Zlib::memGzip( $_[0] ) ;
2288         }
2289         sub my_decompress {
2290                 return Compress::Zlib::memGunzip( $_[0] ) ;
2291         }
2292
2293 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2294 actually numerical index numbers, and are not filtered.
2295
2296 =head1 ERROR HANDLING
2297
2298 Most DBM::Deep methods return a true value for success, and call die() on
2299 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2300 actual error message is stored in an internal scalar, which can be fetched by
2301 calling the C<error()> method.
2302
2303         my $db = DBM::Deep->new( "foo.db" ); # create hash
2304         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2305
2306     print $@;           # prints error message
2307         print $db->error(); # prints error message
2308
2309 You can then call C<clear_error()> to clear the current error state.
2310
2311         $db->clear_error();
2312
2313 If you set the C<debug> option to true when creating your DBM::Deep object,
2314 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2315 be used for debugging purposes and not production work. DBM::Deep expects errors
2316 to be thrown, not propagated back up the stack.
2317
2318 B<NOTE>: error() and clear_error() are considered deprecated and I<will> be removed
2319 in 1.00. Please don't use them. Instead, wrap all your functions with in eval-blocks.
2320
2321 =head1 LARGEFILE SUPPORT
2322
2323 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2324 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2325 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2326 by calling the static C<set_pack()> method before you do anything else.
2327
2328         DBM::Deep::set_pack(8, 'Q');
2329
2330 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2331 instead of 32-bit longs.  After setting these values your DB files have a
2332 theoretical maximum size of 16 XB (exabytes).
2333
2334 B<Note:> Changing these values will B<NOT> work for existing database files.
2335 Only change this for new files, and make sure it stays set consistently
2336 throughout the file's life.  If you do set these values, you can no longer
2337 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2338 back to 32-bit mode.
2339
2340 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2341 only a 32-bit Perl.  However, I have received user reports that this does
2342 indeed work!
2343
2344 =head1 LOW-LEVEL ACCESS
2345
2346 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2347 you can call the C<_fh()> method, which returns the handle:
2348
2349         my $fh = $db->_fh();
2350
2351 This method can be called on the root level of the datbase, or any child
2352 hashes or arrays.  All levels share a I<root> structure, which contains things
2353 like the filehandle, a reference counter, and all the options specified
2354 when you created the object.  You can get access to this root structure by
2355 calling the C<root()> method.
2356
2357         my $root = $db->_root();
2358
2359 This is useful for changing options after the object has already been created,
2360 such as enabling/disabling locking, or debug modes.  You can also
2361 store your own temporary user data in this structure (be wary of name
2362 collision), which is then accessible from any child hash or array.
2363
2364 =head1 CUSTOM DIGEST ALGORITHM
2365
2366 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2367 keys.  However you can override this, and use another algorithm (such as SHA-256)
2368 or even write your own.  But please note that DBM::Deep currently expects zero
2369 collisions, so your algorithm has to be I<perfect>, so to speak.
2370 Collision detection may be introduced in a later version.
2371
2372
2373
2374 You can specify a custom digest algorithm by calling the static C<set_digest()>
2375 function, passing a reference to a subroutine, and the length of the algorithm's
2376 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2377 objects.  Here is a working example that uses a 256-bit hash from the
2378 I<Digest::SHA256> module.  Please see
2379 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2380
2381         use DBM::Deep;
2382         use Digest::SHA256;
2383
2384         my $context = Digest::SHA256::new(256);
2385
2386         DBM::Deep::set_digest( \&my_digest, 32 );
2387
2388         my $db = DBM::Deep->new( "foo-sha.db" );
2389
2390         $db->{key1} = "value1";
2391         $db->{key2} = "value2";
2392         print "key1: " . $db->{key1} . "\n";
2393         print "key2: " . $db->{key2} . "\n";
2394
2395         undef $db;
2396         exit;
2397
2398         sub my_digest {
2399                 return substr( $context->hash($_[0]), 0, 32 );
2400         }
2401
2402 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2403 of bytes you specify in the C<set_digest()> function (in this case 32).
2404
2405 =head1 CIRCULAR REFERENCES
2406
2407 DBM::Deep has B<experimental> support for circular references.  Meaning you
2408 can have a nested hash key or array element that points to a parent object.
2409 This relationship is stored in the DB file, and is preserved between sessions.
2410 Here is an example:
2411
2412         my $db = DBM::Deep->new( "foo.db" );
2413
2414         $db->{foo} = "bar";
2415         $db->{circle} = $db; # ref to self
2416
2417         print $db->{foo} . "\n"; # prints "foo"
2418         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2419
2420 One catch is, passing the object to a function that recursively walks the
2421 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2422 C<export()> methods) will result in an infinite loop.  The other catch is,
2423 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2424 or C<next_key()> methods), you will get the I<target object's key>, not the
2425 ref's key.  This gets even more interesting with the above example, where
2426 the I<circle> key points to the base DB object, which technically doesn't
2427 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2428 special case.
2429
2430 =head1 CAVEATS / ISSUES / BUGS
2431
2432 This section describes all the known issues with DBM::Deep.  It you have found
2433 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2434
2435 =head2 UNUSED SPACE RECOVERY
2436
2437 One major caveat with DBM::Deep is that space occupied by existing keys and
2438 values is not recovered when they are deleted.  Meaning if you keep deleting
2439 and adding new keys, your file will continuously grow.  I am working on this,
2440 but in the meantime you can call the built-in C<optimize()> method from time to
2441 time (perhaps in a crontab or something) to recover all your unused space.
2442
2443         $db->optimize(); # returns true on success
2444
2445 This rebuilds the ENTIRE database into a new file, then moves it on top of
2446 the original.  The new file will have no unused space, thus it will take up as
2447 little disk space as possible.  Please note that this operation can take
2448 a long time for large files, and you need enough disk space to temporarily hold
2449 2 copies of your DB file.  The temporary file is created in the same directory
2450 as the original, named with a ".tmp" extension, and is deleted when the
2451 operation completes.  Oh, and if locking is enabled, the DB is automatically
2452 locked for the entire duration of the copy.
2453
2454 B<WARNING:> Only call optimize() on the top-level node of the database, and
2455 make sure there are no child references lying around.  DBM::Deep keeps a reference
2456 counter, and if it is greater than 1, optimize() will abort and return undef.
2457
2458 =head2 AUTOVIVIFICATION
2459
2460 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2461 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2462 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2463 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2464 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2465 this does not work:
2466
2467         $db->{foo}->{bar} = "hello";
2468
2469 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2470 being an empty hash.  Try this instead, which works fine:
2471
2472         $db->{foo} = { bar => "hello" };
2473
2474 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2475 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2476 Probably a bug in Perl.
2477
2478 =head2 FILE CORRUPTION
2479
2480 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2481 for a 32-bit signature when opened, but other corruption in files can cause
2482 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2483 stuck in an infinite loop depending on the level of corruption.  File write
2484 operations are not checked for failure (for speed), so if you happen to run
2485 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2486 be addressed in a later version of DBM::Deep.
2487
2488 =head2 DB OVER NFS
2489
2490 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2491 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2492 about setting up your NFS server with a locking daemon, then using lockf() to
2493 lock your files, but your mileage may vary there as well.  From what I
2494 understand, there is no real way to do it.  However, if you need access to the
2495 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2496 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2497
2498 =head2 COPYING OBJECTS
2499
2500 Beware of copying tied objects in Perl.  Very strange things can happen.
2501 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2502 returns a new, blessed, tied hash or array to the same level in the DB.
2503
2504         my $copy = $db->clone();
2505
2506 B<Note>: Since clone() here is cloning the object, not the database location, any
2507 modifications to either $db or $copy will be visible in both.
2508
2509 =head2 LARGE ARRAYS
2510
2511 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2512 These functions cause every element in the array to move, which can be murder
2513 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2514 a different location.  This will be addressed in the forthcoming version 1.00.
2515
2516 =head1 PERFORMANCE
2517
2518 This section discusses DBM::Deep's speed and memory usage.
2519
2520 =head2 SPEED
2521
2522 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2523 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2524 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2525 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2526 with huge databases.  Here is some test data:
2527
2528         Adding 1,000,000 keys to new DB file...
2529
2530         At 100 keys, avg. speed is 2,703 keys/sec
2531         At 200 keys, avg. speed is 2,642 keys/sec
2532         At 300 keys, avg. speed is 2,598 keys/sec
2533         At 400 keys, avg. speed is 2,578 keys/sec
2534         At 500 keys, avg. speed is 2,722 keys/sec
2535         At 600 keys, avg. speed is 2,628 keys/sec
2536         At 700 keys, avg. speed is 2,700 keys/sec
2537         At 800 keys, avg. speed is 2,607 keys/sec
2538         At 900 keys, avg. speed is 2,190 keys/sec
2539         At 1,000 keys, avg. speed is 2,570 keys/sec
2540         At 2,000 keys, avg. speed is 2,417 keys/sec
2541         At 3,000 keys, avg. speed is 1,982 keys/sec
2542         At 4,000 keys, avg. speed is 1,568 keys/sec
2543         At 5,000 keys, avg. speed is 1,533 keys/sec
2544         At 6,000 keys, avg. speed is 1,787 keys/sec
2545         At 7,000 keys, avg. speed is 1,977 keys/sec
2546         At 8,000 keys, avg. speed is 2,028 keys/sec
2547         At 9,000 keys, avg. speed is 2,077 keys/sec
2548         At 10,000 keys, avg. speed is 2,031 keys/sec
2549         At 20,000 keys, avg. speed is 1,970 keys/sec
2550         At 30,000 keys, avg. speed is 2,050 keys/sec
2551         At 40,000 keys, avg. speed is 2,073 keys/sec
2552         At 50,000 keys, avg. speed is 1,973 keys/sec
2553         At 60,000 keys, avg. speed is 1,914 keys/sec
2554         At 70,000 keys, avg. speed is 2,091 keys/sec
2555         At 80,000 keys, avg. speed is 2,103 keys/sec
2556         At 90,000 keys, avg. speed is 1,886 keys/sec
2557         At 100,000 keys, avg. speed is 1,970 keys/sec
2558         At 200,000 keys, avg. speed is 2,053 keys/sec
2559         At 300,000 keys, avg. speed is 1,697 keys/sec
2560         At 400,000 keys, avg. speed is 1,838 keys/sec
2561         At 500,000 keys, avg. speed is 1,941 keys/sec
2562         At 600,000 keys, avg. speed is 1,930 keys/sec
2563         At 700,000 keys, avg. speed is 1,735 keys/sec
2564         At 800,000 keys, avg. speed is 1,795 keys/sec
2565         At 900,000 keys, avg. speed is 1,221 keys/sec
2566         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2567
2568 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2569 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2570 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2571 Run time was 12 min 3 sec.
2572
2573 =head2 MEMORY USAGE
2574
2575 One of the great things about DBM::Deep is that it uses very little memory.
2576 Even with huge databases (1,000,000+ keys) you will not see much increased
2577 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2578 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2579 database handle:
2580
2581           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2582         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2583
2584 Basically the process is taking 2,716K of memory.  And here is the same
2585 process after storing and fetching 1,000,000 keys:
2586
2587           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2588         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2589
2590 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2591 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2592
2593 =head1 DB FILE FORMAT
2594
2595 In case you were interested in the underlying DB file format, it is documented
2596 here in this section.  You don't need to know this to use the module, it's just
2597 included for reference.
2598
2599 =head2 SIGNATURE
2600
2601 DBM::Deep files always start with a 32-bit signature to identify the file type.
2602 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2603 checked for when the file is opened and an error will be thrown if it's not found.
2604
2605 =head2 TAG
2606
2607 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2608 has a standard header containing the type of data, the length of data, and then
2609 the data itself.  The type is a single character (1 byte), the length is a
2610 32-bit unsigned long in network byte order, and the data is, well, the data.
2611 Here is how it unfolds:
2612
2613 =head2 MASTER INDEX
2614
2615 Immediately after the 32-bit file signature is the I<Master Index> record.
2616 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2617 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2618 depending on how the DBM::Deep object was constructed.
2619
2620 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2621 number).  The first 8-bit char of the MD5 signature is the offset into the
2622 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2623 index element is a file offset of the next tag for the key/element in question,
2624 which is usually a I<Bucket List> tag (see below).
2625
2626 The next tag I<could> be another index, depending on how many keys/elements
2627 exist.  See L<RE-INDEXING> below for details.
2628
2629 =head2 BUCKET LIST
2630
2631 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2632 file offsets to where the actual data is stored.  It starts with a standard
2633 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2634 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2635 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2636 When the list fills up, a I<Re-Index> operation is performed (See
2637 L<RE-INDEXING> below).
2638
2639 =head2 BUCKET
2640
2641 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2642 index/value pair (in array mode).  It starts with a standard tag header with
2643 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2644 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2645 header.  The size reported in the tag header is only for the value, but then,
2646 just after the value is another size (32-bit unsigned long) and then the plain
2647 key itself.  Since the value is likely to be fetched more often than the plain
2648 key, I figured it would be I<slightly> faster to store the value first.
2649
2650 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2651 record for the nested structure, where the process begins all over again.
2652
2653 =head2 RE-INDEXING
2654
2655 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2656 exhausted.  Then, when another key/element comes in, the list is converted to a
2657 new index record.  However, this index will look at the next char in the MD5
2658 hash, and arrange new Bucket List pointers accordingly.  This process is called
2659 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2660 17 (16 + new one) keys/elements are removed from the old Bucket List and
2661 inserted into the new index.  Several new Bucket Lists are created in the
2662 process, as a new MD5 char from the key is being examined (it is unlikely that
2663 the keys will all share the same next char of their MD5s).
2664
2665 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2666 when the Bucket Lists will turn into indexes, but the first round tends to
2667 happen right around 4,000 keys.  You will see a I<slight> decrease in
2668 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2669 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2670 right around 900,000 keys.  This process can continue nearly indefinitely --
2671 right up until the point the I<MD5> signatures start colliding with each other,
2672 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2673 getting struck by lightning while you are walking to cash in your tickets.
2674 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2675 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2676 this is 340 unodecillion, but don't quote me).
2677
2678 =head2 STORING
2679
2680 When a new key/element is stored, the key (or index number) is first run through
2681 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2682 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2683 for the first char of the signature (in this case I<b0>).  If it does not exist,
2684 a new I<Bucket List> is created for our key (and the next 15 future keys that
2685 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2686 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2687 this point, unless we are replacing an existing I<Bucket>), where the actual
2688 data will be stored.
2689
2690 =head2 FETCHING
2691
2692 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2693 (or index number), then walking along the indexes.  If there are enough
2694 keys/elements in this DB level, there might be nested indexes, each linked to
2695 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2696 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2697 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2698 plain key are stored.
2699
2700 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2701 methods.  In this process the indexes are walked systematically, and each key
2702 fetched in increasing MD5 order (which is why it appears random).   Once the
2703 I<Bucket> is found, the value is skipped and the plain key returned instead.
2704 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2705 alphabetically sorted.  This only happens on an index-level -- as soon as the
2706 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2707 so it's pretty much undefined how the keys will come out -- just like Perl's
2708 built-in hashes.
2709
2710 =head1 CODE COVERAGE
2711
2712 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2713 B<Devel::Cover> report on this module's test suite.
2714
2715   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2716   File                           stmt   bran   cond    sub    pod   time  total
2717   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2718   blib/lib/DBM/Deep.pm           95.0   83.2   68.7   98.2  100.0   57.8   90.7
2719   blib/lib/DBM/Deep/Array.pm     98.9   88.9   87.5  100.0    n/a   27.4   96.4
2720   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   14.8   92.4
2721   Total                          95.8   83.9   72.8   98.8  100.0  100.0   91.8
2722   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2723
2724 =head1 MORE INFORMATION
2725
2726 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2727 or send email to L<DBM-Deep@googlegroups.com>.
2728
2729 =head1 AUTHORS
2730
2731 Joseph Huckaby, L<jhuckaby@cpan.org>
2732
2733 Rob Kinyon, L<rkinyon@cpan.org>
2734
2735 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2736
2737 =head1 SEE ALSO
2738
2739 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2740 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2741
2742 =head1 LICENSE
2743
2744 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2745 This is free software, you may use it and distribute it under the
2746 same terms as Perl itself.
2747
2748 =cut