lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use DBM::Deep::Engine;
  39
  40 use vars qw( $VERSION );
  41 $VERSION = q(0.99_01);
  42
  43 ##
  44 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  45 #       (Perl must be compiled with largefile support for files > 2 GB)
  46 #
  47 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  48 #       (Perl must be compiled with largefile and 64-bit long support)
  49 ##
  50 #my $LONG_SIZE = 4;
  51 #my $LONG_PACK = 'N';
  52
  53 ##
  54 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  55 # Upgrading this is possible (see above) but probably not necessary.  If you need
  56 # more than 4 GB for a single key or value, this module is really not for you :-)
  57 ##
  58 #my $DATA_LENGTH_SIZE = 4;
  59 #my $DATA_LENGTH_PACK = 'N';
  60 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  61
  62 ##
  63 # Maximum number of buckets per list before another level of indexing is done.
  64 # Increase this value for slightly greater speed, but larger database files.
  65 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  66 ##
  67 my $MAX_BUCKETS = 16;
  68
  69 ##
  70 # Better not adjust anything below here, unless you're me :-)
  71 ##
  72
  73 ##
  74 # Setup digest function for keys
  75 ##
  76 our ($DIGEST_FUNC, $HASH_SIZE);
  77 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  78
  79 ##
  80 # Precalculate index and bucket sizes based on values above.
  81 ##
  82 #my $HASH_SIZE = 16;
  83 our ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  84
  85 set_digest();
  86 #set_pack();
  87 #_precalc_sizes();
  88
  89 ##
  90 # Setup file and tag signatures.  These should never change.
  91 ##
  92 sub SIG_FILE   () { 'DPDB' }
  93 sub SIG_HASH   () { 'H' }
  94 sub SIG_ARRAY  () { 'A' }
  95 sub SIG_SCALAR () { 'S' }
  96 sub SIG_NULL   () { 'N' }
  97 sub SIG_DATA   () { 'D' }
  98 sub SIG_INDEX  () { 'I' }
  99 sub SIG_BLIST  () { 'B' }
 100 sub SIG_SIZE   () {  1  }
 101
 102 ##
 103 # Setup constants for users to pass to new()
 104 ##
 105 sub TYPE_HASH   () { SIG_HASH   }
 106 sub TYPE_ARRAY  () { SIG_ARRAY  }
 107 sub TYPE_SCALAR () { SIG_SCALAR }
 108
 109 sub _get_args {
 110     my $proto = shift;
 111
 112     my $args;
 113     if (scalar(@_) > 1) {
 114         if ( @_ % 2 ) {
 115             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 116         }
 117         $args = {@_};
 118     }
 119         elsif ( ref $_[0] ) {
 120         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 121             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 122         }
 123         $args = $_[0];
 124     }
 125         else {
 126         $args = { file => shift };
 127     }
 128
 129     return $args;
 130 }
 131
 132 sub new {
 133         ##
 134         # Class constructor method for Perl OO interface.
 135         # Calls tie() and returns blessed reference to tied hash or array,
 136         # providing a hybrid OO/tie interface.
 137         ##
 138         my $class = shift;
 139         my $args = $class->_get_args( @_ );
 140
 141         ##
 142         # Check if we want a tied hash or array.
 143         ##
 144         my $self;
 145         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 146         $class = 'DBM::Deep::Array';
 147         require DBM::Deep::Array;
 148                 tie @$self, $class, %$args;
 149         }
 150         else {
 151         $class = 'DBM::Deep::Hash';
 152         require DBM::Deep::Hash;
 153                 tie %$self, $class, %$args;
 154         }
 155
 156         return bless $self, $class;
 157 }
 158
 159 sub _init {
 160     ##
 161     # Setup $self and bless into this class.
 162     ##
 163     my $class = shift;
 164     my $args = shift;
 165
 166     # These are the defaults to be optionally overridden below
 167     my $self = bless {
 168         type        => TYPE_HASH,
 169         base_offset => length(SIG_FILE),
 170         engine      => 'DBM::Deep::Engine',
 171     }, $class;
 172
 173     foreach my $param ( keys %$self ) {
 174         next unless exists $args->{$param};
 175         $self->{$param} = delete $args->{$param}
 176     }
 177
 178     # locking implicitly enables autoflush
 179     if ($args->{locking}) { $args->{autoflush} = 1; }
 180
 181     $self->{root} = exists $args->{root}
 182         ? $args->{root}
 183         : DBM::Deep::_::Root->new( $args );
 184
 185     if (!defined($self->_fh)) { $self->{engine}->open( $self ); }
 186
 187     return $self;
 188 }
 189
 190 sub TIEHASH {
 191     shift;
 192     require DBM::Deep::Hash;
 193     return DBM::Deep::Hash->TIEHASH( @_ );
 194 }
 195
 196 sub TIEARRAY {
 197     shift;
 198     require DBM::Deep::Array;
 199     return DBM::Deep::Array->TIEARRAY( @_ );
 200 }
 201
 202 #XXX Unneeded now ...
 203 #sub DESTROY {
 204 #}
 205
 206 sub _create_tag {
 207         ##
 208         # Given offset, signature and content, create tag and write to disk
 209         ##
 210         my ($self, $offset, $sig, $content) = @_;
 211         my $size = length($content);
 212
 213     my $fh = $self->_fh;
 214
 215         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 216         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 217
 218         if ($offset == $self->_root->{end}) {
 219                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 220         }
 221
 222         return {
 223                 signature => $sig,
 224                 size => $size,
 225                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 226                 content => $content
 227         };
 228 }
 229
 230 sub _load_tag {
 231         ##
 232         # Given offset, load single tag and return signature, size and data
 233         ##
 234         my $self = shift;
 235         my $offset = shift;
 236
 237     my $fh = $self->_fh;
 238
 239         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 240         if (eof $fh) { return undef; }
 241
 242     my $b;
 243     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 244     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 245
 246         my $buffer;
 247         read( $fh, $buffer, $size);
 248
 249         return {
 250                 signature => $sig,
 251                 size => $size,
 252                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 253                 content => $buffer
 254         };
 255 }
 256
 257 sub _index_lookup {
 258         ##
 259         # Given index tag, lookup single entry in index and return .
 260         ##
 261         my $self = shift;
 262         my ($tag, $index) = @_;
 263
 264         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 265         if (!$location) { return; }
 266
 267         return $self->_load_tag( $location );
 268 }
 269
 270 sub _add_bucket {
 271         ##
 272         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 273         # plain (undigested) key and value.
 274         ##
 275         my $self = shift;
 276         my ($tag, $md5, $plain_key, $value) = @_;
 277         my $keys = $tag->{content};
 278         my $location = 0;
 279         my $result = 2;
 280
 281     my $root = $self->_root;
 282
 283     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 284         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 285
 286     my $fh = $self->_fh;
 287
 288         ##
 289         # Iterate through buckets, seeing if this is a new entry or a replace.
 290         ##
 291         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 292                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 293                 if (!$subloc) {
 294                         ##
 295                         # Found empty bucket (end of list).  Populate and exit loop.
 296                         ##
 297                         $result = 2;
 298
 299             $location = $internal_ref
 300                 ? $value->_base_offset
 301                 : $root->{end};
 302
 303                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 304                         print( $fh $md5 . pack($LONG_PACK, $location) );
 305                         last;
 306                 }
 307
 308                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 309                 if ($md5 eq $key) {
 310                         ##
 311                         # Found existing bucket with same key.  Replace with new value.
 312                         ##
 313                         $result = 1;
 314
 315                         if ($internal_ref) {
 316                                 $location = $value->_base_offset;
 317                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 318                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 319                 return $result;
 320                         }
 321
 322             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 323             my $size;
 324             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 325
 326             ##
 327             # If value is a hash, array, or raw value with equal or less size, we can
 328             # reuse the same content area of the database.  Otherwise, we have to create
 329             # a new content area at the EOF.
 330             ##
 331             my $actual_length;
 332             my $r = Scalar::Util::reftype( $value ) || '';
 333             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 334                 $actual_length = $INDEX_SIZE;
 335
 336                 # if autobless is enabled, must also take into consideration
 337                 # the class name, as it is stored along with key/value.
 338                 if ( $root->{autobless} ) {
 339                     my $value_class = Scalar::Util::blessed($value);
 340                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 341                         $actual_length += length($value_class);
 342                     }
 343                 }
 344             }
 345             else { $actual_length = length($value); }
 346
 347             if ($actual_length <= $size) {
 348                 $location = $subloc;
 349             }
 350             else {
 351                 $location = $root->{end};
 352                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 353                 print( $fh pack($LONG_PACK, $location) );
 354             }
 355
 356                         last;
 357                 }
 358         }
 359
 360         ##
 361         # If this is an internal reference, return now.
 362         # No need to write value or plain key
 363         ##
 364         if ($internal_ref) {
 365         return $result;
 366     }
 367
 368         ##
 369         # If bucket didn't fit into list, split into a new index level
 370         ##
 371         if (!$location) {
 372                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 373                 print( $fh pack($LONG_PACK, $root->{end}) );
 374
 375                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 376                 my @offsets = ();
 377
 378                 $keys .= $md5 . pack($LONG_PACK, 0);
 379
 380                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 381                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 382                         if ($key) {
 383                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 384                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 385
 386                                 if ($offsets[$num]) {
 387                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 388                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 389                                         my $subkeys;
 390                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 391
 392                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 393                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 394                                                 if (!$subloc) {
 395                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 396                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 397                                                         last;
 398                                                 }
 399                                         } # k loop
 400                                 }
 401                                 else {
 402                                         $offsets[$num] = $root->{end};
 403                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 404                                         print( $fh pack($LONG_PACK, $root->{end}) );
 405
 406                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 407
 408                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 409                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 410                                 }
 411                         } # key is real
 412                 } # i loop
 413
 414                 $location ||= $root->{end};
 415         } # re-index bucket list
 416
 417         ##
 418         # Seek to content area and store signature, value and plaintext key
 419         ##
 420         if ($location) {
 421                 my $content_length;
 422                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 423
 424                 ##
 425                 # Write signature based on content type, set content length and write actual value.
 426                 ##
 427         my $r = Scalar::Util::reftype($value) || '';
 428                 if ($r eq 'HASH') {
 429                         print( $fh TYPE_HASH );
 430                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 431                         $content_length = $INDEX_SIZE;
 432                 }
 433                 elsif ($r eq 'ARRAY') {
 434                         print( $fh TYPE_ARRAY );
 435                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 436                         $content_length = $INDEX_SIZE;
 437                 }
 438                 elsif (!defined($value)) {
 439                         print( $fh SIG_NULL );
 440                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 441                         $content_length = 0;
 442                 }
 443                 else {
 444                         print( $fh SIG_DATA );
 445                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 446                         $content_length = length($value);
 447                 }
 448
 449                 ##
 450                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 451                 ##
 452                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 453
 454                 ##
 455                 # If value is blessed, preserve class name
 456                 ##
 457                 if ( $root->{autobless} ) {
 458             my $value_class = Scalar::Util::blessed($value);
 459             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 460                 ##
 461                 # Blessed ref -- will restore later
 462                 ##
 463                 print( $fh chr(1) );
 464                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 465                 $content_length += 1;
 466                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 467             }
 468             else {
 469                 print( $fh chr(0) );
 470                 $content_length += 1;
 471             }
 472         }
 473
 474                 ##
 475                 # If this is a new content area, advance EOF counter
 476                 ##
 477                 if ($location == $root->{end}) {
 478                         $root->{end} += SIG_SIZE;
 479                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 480                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 481                 }
 482
 483                 ##
 484                 # If content is a hash or array, create new child DBM::Deep object and
 485                 # pass each key or element to it.
 486                 ##
 487                 if ($r eq 'HASH') {
 488                         my $branch = DBM::Deep->new(
 489                                 type => TYPE_HASH,
 490                                 base_offset => $location,
 491                                 root => $root,
 492                         );
 493                         foreach my $key (keys %{$value}) {
 494                 $branch->STORE( $key, $value->{$key} );
 495                         }
 496                 }
 497                 elsif ($r eq 'ARRAY') {
 498                         my $branch = DBM::Deep->new(
 499                                 type => TYPE_ARRAY,
 500                                 base_offset => $location,
 501                                 root => $root,
 502                         );
 503                         my $index = 0;
 504                         foreach my $element (@{$value}) {
 505                 $branch->STORE( $index, $element );
 506                                 $index++;
 507                         }
 508                 }
 509
 510                 return $result;
 511         }
 512
 513         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 514 }
 515
 516 sub _get_bucket_value {
 517         ##
 518         # Fetch single value given tag and MD5 digested key.
 519         ##
 520         my $self = shift;
 521         my ($tag, $md5) = @_;
 522         my $keys = $tag->{content};
 523
 524     my $fh = $self->_fh;
 525
 526         ##
 527         # Iterate through buckets, looking for a key match
 528         ##
 529     BUCKET:
 530         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 531                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 532                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 533
 534                 if (!$subloc) {
 535                         ##
 536                         # Hit end of list, no match
 537                         ##
 538                         return;
 539                 }
 540
 541         if ( $md5 ne $key ) {
 542             next BUCKET;
 543         }
 544
 545         ##
 546         # Found match -- seek to offset and read signature
 547         ##
 548         my $signature;
 549         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 550         read( $fh, $signature, SIG_SIZE);
 551
 552         ##
 553         # If value is a hash or array, return new DBM::Deep object with correct offset
 554         ##
 555         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 556             my $obj = DBM::Deep->new(
 557                 type => $signature,
 558                 base_offset => $subloc,
 559                 root => $self->_root
 560             );
 561
 562             if ($self->_root->{autobless}) {
 563                 ##
 564                 # Skip over value and plain key to see if object needs
 565                 # to be re-blessed
 566                 ##
 567                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 568
 569                 my $size;
 570                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 571                 if ($size) { seek($fh, $size, SEEK_CUR); }
 572
 573                 my $bless_bit;
 574                 read( $fh, $bless_bit, 1);
 575                 if (ord($bless_bit)) {
 576                     ##
 577                     # Yes, object needs to be re-blessed
 578                     ##
 579                     my $class_name;
 580                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 581                     if ($size) { read( $fh, $class_name, $size); }
 582                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 583                 }
 584             }
 585
 586             return $obj;
 587         }
 588
 589         ##
 590         # Otherwise return actual value
 591         ##
 592         elsif ($signature eq SIG_DATA) {
 593             my $size;
 594             my $value = '';
 595             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 596             if ($size) { read( $fh, $value, $size); }
 597             return $value;
 598         }
 599
 600         ##
 601         # Key exists, but content is null
 602         ##
 603         else { return; }
 604         } # i loop
 605
 606         return;
 607 }
 608
 609 sub _delete_bucket {
 610         ##
 611         # Delete single key/value pair given tag and MD5 digested key.
 612         ##
 613         my $self = shift;
 614         my ($tag, $md5) = @_;
 615         my $keys = $tag->{content};
 616
 617     my $fh = $self->_fh;
 618
 619         ##
 620         # Iterate through buckets, looking for a key match
 621         ##
 622     BUCKET:
 623         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 624                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 625                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 626
 627                 if (!$subloc) {
 628                         ##
 629                         # Hit end of list, no match
 630                         ##
 631                         return;
 632                 }
 633
 634         if ( $md5 ne $key ) {
 635             next BUCKET;
 636         }
 637
 638         ##
 639         # Matched key -- delete bucket and return
 640         ##
 641         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 642         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 643         print( $fh chr(0) x $BUCKET_SIZE );
 644
 645         return 1;
 646         } # i loop
 647
 648         return;
 649 }
 650
 651 sub _bucket_exists {
 652         ##
 653         # Check existence of single key given tag and MD5 digested key.
 654         ##
 655         my $self = shift;
 656         my ($tag, $md5) = @_;
 657         my $keys = $tag->{content};
 658
 659         ##
 660         # Iterate through buckets, looking for a key match
 661         ##
 662     BUCKET:
 663         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 664                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 665                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 666
 667                 if (!$subloc) {
 668                         ##
 669                         # Hit end of list, no match
 670                         ##
 671                         return;
 672                 }
 673
 674         if ( $md5 ne $key ) {
 675             next BUCKET;
 676         }
 677
 678         ##
 679         # Matched key -- return true
 680         ##
 681         return 1;
 682         } # i loop
 683
 684         return;
 685 }
 686
 687 sub _find_bucket_list {
 688         ##
 689         # Locate offset for bucket list, given digested key
 690         ##
 691         my $self = shift;
 692         my $md5 = shift;
 693
 694         ##
 695         # Locate offset for bucket list using digest index system
 696         ##
 697         my $ch = 0;
 698         my $tag = $self->_load_tag($self->_base_offset);
 699         if (!$tag) { return; }
 700
 701         while ($tag->{signature} ne SIG_BLIST) {
 702                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 703                 if (!$tag) { return; }
 704                 $ch++;
 705         }
 706
 707         return $tag;
 708 }
 709
 710 sub _traverse_index {
 711         ##
 712         # Scan index and recursively step into deeper levels, looking for next key.
 713         ##
 714     my ($self, $offset, $ch, $force_return_next) = @_;
 715     $force_return_next = undef unless $force_return_next;
 716
 717         my $tag = $self->_load_tag( $offset );
 718
 719     my $fh = $self->_fh;
 720
 721         if ($tag->{signature} ne SIG_BLIST) {
 722                 my $content = $tag->{content};
 723                 my $start;
 724                 if ($self->{return_next}) { $start = 0; }
 725                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 726
 727                 for (my $index = $start; $index < 256; $index++) {
 728                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 729                         if ($subloc) {
 730                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 731                                 if (defined($result)) { return $result; }
 732                         }
 733                 } # index loop
 734
 735                 $self->{return_next} = 1;
 736         } # tag is an index
 737
 738         elsif ($tag->{signature} eq SIG_BLIST) {
 739                 my $keys = $tag->{content};
 740                 if ($force_return_next) { $self->{return_next} = 1; }
 741
 742                 ##
 743                 # Iterate through buckets, looking for a key match
 744                 ##
 745                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 746                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 747                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 748
 749                         if (!$subloc) {
 750                                 ##
 751                                 # End of bucket list -- return to outer loop
 752                                 ##
 753                                 $self->{return_next} = 1;
 754                                 last;
 755                         }
 756                         elsif ($key eq $self->{prev_md5}) {
 757                                 ##
 758                                 # Located previous key -- return next one found
 759                                 ##
 760                                 $self->{return_next} = 1;
 761                                 next;
 762                         }
 763                         elsif ($self->{return_next}) {
 764                                 ##
 765                                 # Seek to bucket location and skip over signature
 766                                 ##
 767                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 768
 769                                 ##
 770                                 # Skip over value to get to plain key
 771                                 ##
 772                                 my $size;
 773                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 774                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 775
 776                                 ##
 777                                 # Read in plain key and return as scalar
 778                                 ##
 779                                 my $plain_key;
 780                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 781                                 if ($size) { read( $fh, $plain_key, $size); }
 782
 783                                 return $plain_key;
 784                         }
 785                 } # bucket loop
 786
 787                 $self->{return_next} = 1;
 788         } # tag is a bucket list
 789
 790         return;
 791 }
 792
 793 sub _get_next_key {
 794         ##
 795         # Locate next key, given digested previous one
 796         ##
 797     my $self = $_[0]->_get_self;
 798
 799         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 800         $self->{return_next} = 0;
 801
 802         ##
 803         # If the previous key was not specifed, start at the top and
 804         # return the first one found.
 805         ##
 806         if (!$self->{prev_md5}) {
 807                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 808                 $self->{return_next} = 1;
 809         }
 810
 811         return $self->_traverse_index( $self->_base_offset, 0 );
 812 }
 813
 814 sub lock {
 815         ##
 816         # If db locking is set, flock() the db file.  If called multiple
 817         # times before unlock(), then the same number of unlocks() must
 818         # be called before the lock is released.
 819         ##
 820     my $self = $_[0]->_get_self;
 821         my $type = $_[1];
 822     $type = LOCK_EX unless defined $type;
 823
 824         if (!defined($self->_fh)) { return; }
 825
 826         if ($self->_root->{locking}) {
 827                 if (!$self->_root->{locked}) {
 828                         flock($self->_fh, $type);
 829
 830                         # refresh end counter in case file has changed size
 831                         my @stats = stat($self->_root->{file});
 832                         $self->_root->{end} = $stats[7];
 833
 834                         # double-check file inode, in case another process
 835                         # has optimize()d our file while we were waiting.
 836                         if ($stats[1] != $self->_root->{inode}) {
 837                                 $self->{engine}->open( $self ); # re-open
 838                                 flock($self->_fh, $type); # re-lock
 839                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 840                         }
 841                 }
 842                 $self->_root->{locked}++;
 843
 844         return 1;
 845         }
 846
 847     return;
 848 }
 849
 850 sub unlock {
 851         ##
 852         # If db locking is set, unlock the db file.  See note in lock()
 853         # regarding calling lock() multiple times.
 854         ##
 855     my $self = $_[0]->_get_self;
 856
 857         if (!defined($self->_fh)) { return; }
 858
 859         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 860                 $self->_root->{locked}--;
 861                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 862
 863         return 1;
 864         }
 865
 866     return;
 867 }
 868
 869 sub _copy_value {
 870     my $self = shift->_get_self;
 871     my ($spot, $value) = @_;
 872
 873     if ( !ref $value ) {
 874         ${$spot} = $value;
 875     }
 876     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 877         my $type = $value->_type;
 878         ${$spot} = $type eq TYPE_HASH ? {} : [];
 879         $value->_copy_node( ${$spot} );
 880     }
 881     else {
 882         my $r = Scalar::Util::reftype( $value );
 883         my $c = Scalar::Util::blessed( $value );
 884         if ( $r eq 'ARRAY' ) {
 885             ${$spot} = [ @{$value} ];
 886         }
 887         else {
 888             ${$spot} = { %{$value} };
 889         }
 890         ${$spot} = bless ${$spot}, $c
 891             if defined $c;
 892     }
 893
 894     return 1;
 895 }
 896
 897 sub _copy_node {
 898         ##
 899         # Copy single level of keys or elements to new DB handle.
 900         # Recurse for nested structures
 901         ##
 902     my $self = shift->_get_self;
 903         my ($db_temp) = @_;
 904
 905         if ($self->_type eq TYPE_HASH) {
 906                 my $key = $self->first_key();
 907                 while ($key) {
 908                         my $value = $self->get($key);
 909             $self->_copy_value( \$db_temp->{$key}, $value );
 910                         $key = $self->next_key($key);
 911                 }
 912         }
 913         else {
 914                 my $length = $self->length();
 915                 for (my $index = 0; $index < $length; $index++) {
 916                         my $value = $self->get($index);
 917             $self->_copy_value( \$db_temp->[$index], $value );
 918                 }
 919         }
 920
 921     return 1;
 922 }
 923
 924 sub export {
 925         ##
 926         # Recursively export into standard Perl hashes and arrays.
 927         ##
 928     my $self = $_[0]->_get_self;
 929
 930         my $temp;
 931         if ($self->_type eq TYPE_HASH) { $temp = {}; }
 932         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
 933
 934         $self->lock();
 935         $self->_copy_node( $temp );
 936         $self->unlock();
 937
 938         return $temp;
 939 }
 940
 941 sub import {
 942         ##
 943         # Recursively import Perl hash/array structure
 944         ##
 945     #XXX This use of ref() seems to be ok
 946         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 947
 948     my $self = $_[0]->_get_self;
 949         my $struct = $_[1];
 950
 951     #XXX This use of ref() seems to be ok
 952         if (!ref($struct)) {
 953                 ##
 954                 # struct is not a reference, so just import based on our type
 955                 ##
 956                 shift @_;
 957
 958                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
 959                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
 960         }
 961
 962     my $r = Scalar::Util::reftype($struct) || '';
 963         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
 964                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
 965         }
 966         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
 967                 $self->push( @$struct );
 968         }
 969         else {
 970                 return $self->_throw_error("Cannot import: type mismatch");
 971         }
 972
 973         return 1;
 974 }
 975
 976 sub optimize {
 977         ##
 978         # Rebuild entire database into new file, then move
 979         # it back on top of original.
 980         ##
 981     my $self = $_[0]->_get_self;
 982
 983 #XXX Need to create a new test for this
 984 #       if ($self->_root->{links} > 1) {
 985 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
 986 #       }
 987
 988         my $db_temp = DBM::Deep->new(
 989                 file => $self->_root->{file} . '.tmp',
 990                 type => $self->_type
 991         );
 992         if (!$db_temp) {
 993                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
 994         }
 995
 996         $self->lock();
 997         $self->_copy_node( $db_temp );
 998         undef $db_temp;
 999
1000         ##
1001         # Attempt to copy user, group and permissions over to new file
1002         ##
1003         my @stats = stat($self->_fh);
1004         my $perms = $stats[2] & 07777;
1005         my $uid = $stats[4];
1006         my $gid = $stats[5];
1007         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1008         chmod( $perms, $self->_root->{file} . '.tmp' );
1009
1010     # q.v. perlport for more information on this variable
1011     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1012                 ##
1013                 # Potential race condition when optmizing on Win32 with locking.
1014                 # The Windows filesystem requires that the filehandle be closed
1015                 # before it is overwritten with rename().  This could be redone
1016                 # with a soft copy.
1017                 ##
1018                 $self->unlock();
1019                 $self->{engine}->close( $self );
1020         }
1021
1022         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1023                 unlink $self->_root->{file} . '.tmp';
1024                 $self->unlock();
1025                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1026         }
1027
1028         $self->unlock();
1029         $self->{engine}->close( $self );
1030         $self->{engine}->open( $self );
1031
1032         return 1;
1033 }
1034
1035 sub clone {
1036         ##
1037         # Make copy of object and return
1038         ##
1039     my $self = $_[0]->_get_self;
1040
1041         return DBM::Deep->new(
1042                 type => $self->_type,
1043                 base_offset => $self->_base_offset,
1044                 root => $self->_root
1045         );
1046 }
1047
1048 {
1049     my %is_legal_filter = map {
1050         $_ => ~~1,
1051     } qw(
1052         store_key store_value
1053         fetch_key fetch_value
1054     );
1055
1056     sub set_filter {
1057         ##
1058         # Setup filter function for storing or fetching the key or value
1059         ##
1060         my $self = $_[0]->_get_self;
1061         my $type = lc $_[1];
1062         my $func = $_[2] ? $_[2] : undef;
1063
1064         if ( $is_legal_filter{$type} ) {
1065             $self->_root->{"filter_$type"} = $func;
1066             return 1;
1067         }
1068
1069         return;
1070     }
1071 }
1072
1073 ##
1074 # Accessor methods
1075 ##
1076
1077 sub _root {
1078         ##
1079         # Get access to the root structure
1080         ##
1081     my $self = $_[0]->_get_self;
1082         return $self->{root};
1083 }
1084
1085 sub _fh {
1086         ##
1087         # Get access to the raw fh
1088         ##
1089     #XXX It will be useful, though, when we split out HASH and ARRAY
1090     my $self = $_[0]->_get_self;
1091         return $self->_root->{fh};
1092 }
1093
1094 sub _type {
1095         ##
1096         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1097         ##
1098     my $self = $_[0]->_get_self;
1099         return $self->{type};
1100 }
1101
1102 sub _base_offset {
1103         ##
1104         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1105         ##
1106     my $self = $_[0]->_get_self;
1107         return $self->{base_offset};
1108 }
1109
1110 ##
1111 # Utility methods
1112 ##
1113
1114 sub _throw_error {
1115     die "DBM::Deep: $_[1]\n";
1116 }
1117
1118 sub _precalc_sizes {
1119         ##
1120         # Precalculate index, bucket and bucket list sizes
1121         ##
1122
1123     #XXX I don't like this ...
1124     set_pack() unless defined $LONG_SIZE;
1125
1126         $INDEX_SIZE = 256 * $LONG_SIZE;
1127         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1128         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1129 }
1130
1131 sub set_pack {
1132         ##
1133         # Set pack/unpack modes (see file header for more)
1134         ##
1135     my ($long_s, $long_p, $data_s, $data_p) = @_;
1136
1137     $LONG_SIZE = $long_s ? $long_s : 4;
1138     $LONG_PACK = $long_p ? $long_p : 'N';
1139
1140     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1141     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1142
1143         _precalc_sizes();
1144 }
1145
1146 sub set_digest {
1147         ##
1148         # Set key digest function (default is MD5)
1149         ##
1150     my ($digest_func, $hash_size) = @_;
1151
1152     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1153     $HASH_SIZE = $hash_size ? $hash_size : 16;
1154
1155         _precalc_sizes();
1156 }
1157
1158 sub _is_writable {
1159     my $fh = shift;
1160     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1161 }
1162
1163 #sub _is_readable {
1164 #    my $fh = shift;
1165 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1166 #}
1167
1168 ##
1169 # tie() methods (hashes and arrays)
1170 ##
1171
1172 sub STORE {
1173         ##
1174         # Store single hash key/value or array element in database.
1175         ##
1176     my $self = $_[0]->_get_self;
1177         my $key = $_[1];
1178
1179     # User may be storing a hash, in which case we do not want it run
1180     # through the filtering system
1181         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1182         ? $self->_root->{filter_store_value}->($_[2])
1183         : $_[2];
1184
1185         my $md5 = $DIGEST_FUNC->($key);
1186
1187     unless ( _is_writable( $self->_fh ) ) {
1188         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1189     }
1190
1191         ##
1192         # Request exclusive lock for writing
1193         ##
1194         $self->lock( LOCK_EX );
1195
1196         my $fh = $self->_fh;
1197
1198         ##
1199         # Locate offset for bucket list using digest index system
1200         ##
1201         my $tag = $self->_load_tag($self->_base_offset);
1202         if (!$tag) {
1203                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1204         }
1205
1206         my $ch = 0;
1207         while ($tag->{signature} ne SIG_BLIST) {
1208                 my $num = ord(substr($md5, $ch, 1));
1209
1210         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1211                 my $new_tag = $self->_index_lookup($tag, $num);
1212
1213                 if (!$new_tag) {
1214                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1215                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1216
1217                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1218
1219                         $tag->{ref_loc} = $ref_loc;
1220                         $tag->{ch} = $ch;
1221
1222                         last;
1223                 }
1224                 else {
1225                         $tag = $new_tag;
1226
1227                         $tag->{ref_loc} = $ref_loc;
1228                         $tag->{ch} = $ch;
1229                 }
1230                 $ch++;
1231         }
1232
1233         ##
1234         # Add key/value to bucket list
1235         ##
1236         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1237
1238         $self->unlock();
1239
1240         return $result;
1241 }
1242
1243 sub FETCH {
1244         ##
1245         # Fetch single value or element given plain key or array index
1246         ##
1247     my $self = shift->_get_self;
1248     my $key = shift;
1249
1250         my $md5 = $DIGEST_FUNC->($key);
1251
1252         ##
1253         # Request shared lock for reading
1254         ##
1255         $self->lock( LOCK_SH );
1256
1257         my $tag = $self->_find_bucket_list( $md5 );
1258         if (!$tag) {
1259                 $self->unlock();
1260                 return;
1261         }
1262
1263         ##
1264         # Get value from bucket list
1265         ##
1266         my $result = $self->_get_bucket_value( $tag, $md5 );
1267
1268         $self->unlock();
1269
1270     #XXX What is ref() checking here?
1271     #YYY Filters only apply on scalar values, so the ref check is making
1272     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1273         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1274         ? $self->_root->{filter_fetch_value}->($result)
1275         : $result;
1276 }
1277
1278 sub DELETE {
1279         ##
1280         # Delete single key/value pair or element given plain key or array index
1281         ##
1282     my $self = $_[0]->_get_self;
1283         my $key = $_[1];
1284
1285         my $md5 = $DIGEST_FUNC->($key);
1286
1287         ##
1288         # Request exclusive lock for writing
1289         ##
1290         $self->lock( LOCK_EX );
1291
1292         my $tag = $self->_find_bucket_list( $md5 );
1293         if (!$tag) {
1294                 $self->unlock();
1295                 return;
1296         }
1297
1298         ##
1299         # Delete bucket
1300         ##
1301     my $value = $self->_get_bucket_value( $tag, $md5 );
1302         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1303         $value = $self->_root->{filter_fetch_value}->($value);
1304     }
1305
1306         my $result = $self->_delete_bucket( $tag, $md5 );
1307
1308         ##
1309         # If this object is an array and the key deleted was on the end of the stack,
1310         # decrement the length variable.
1311         ##
1312
1313         $self->unlock();
1314
1315         return $value;
1316 }
1317
1318 sub EXISTS {
1319         ##
1320         # Check if a single key or element exists given plain key or array index
1321         ##
1322     my $self = $_[0]->_get_self;
1323         my $key = $_[1];
1324
1325         my $md5 = $DIGEST_FUNC->($key);
1326
1327         ##
1328         # Request shared lock for reading
1329         ##
1330         $self->lock( LOCK_SH );
1331
1332         my $tag = $self->_find_bucket_list( $md5 );
1333
1334         ##
1335         # For some reason, the built-in exists() function returns '' for false
1336         ##
1337         if (!$tag) {
1338                 $self->unlock();
1339                 return '';
1340         }
1341
1342         ##
1343         # Check if bucket exists and return 1 or ''
1344         ##
1345         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1346
1347         $self->unlock();
1348
1349         return $result;
1350 }
1351
1352 sub CLEAR {
1353         ##
1354         # Clear all keys from hash, or all elements from array.
1355         ##
1356     my $self = $_[0]->_get_self;
1357
1358         ##
1359         # Request exclusive lock for writing
1360         ##
1361         $self->lock( LOCK_EX );
1362
1363     my $fh = $self->_fh;
1364
1365         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1366         if (eof $fh) {
1367                 $self->unlock();
1368                 return;
1369         }
1370
1371         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1372
1373         $self->unlock();
1374
1375         return 1;
1376 }
1377
1378 ##
1379 # Public method aliases
1380 ##
1381 sub put { (shift)->STORE( @_ ) }
1382 sub store { (shift)->STORE( @_ ) }
1383 sub get { (shift)->FETCH( @_ ) }
1384 sub fetch { (shift)->FETCH( @_ ) }
1385 sub delete { (shift)->DELETE( @_ ) }
1386 sub exists { (shift)->EXISTS( @_ ) }
1387 sub clear { (shift)->CLEAR( @_ ) }
1388
1389 package DBM::Deep::_::Root;
1390
1391 sub new {
1392     my $class = shift;
1393     my ($args) = @_;
1394
1395     my $self = bless {
1396         file => undef,
1397         fh => undef,
1398         file_offset => 0,
1399         end => 0,
1400         autoflush => undef,
1401         locking => undef,
1402         debug => undef,
1403         filter_store_key => undef,
1404         filter_store_value => undef,
1405         filter_fetch_key => undef,
1406         filter_fetch_value => undef,
1407         autobless => undef,
1408         locked => 0,
1409         %$args,
1410     }, $class;
1411
1412     if ( $self->{fh} && !$self->{file_offset} ) {
1413         $self->{file_offset} = tell( $self->{fh} );
1414     }
1415
1416     return $self;
1417 }
1418
1419 sub DESTROY {
1420     my $self = shift;
1421     return unless $self;
1422
1423     close $self->{fh} if $self->{fh};
1424
1425     return;
1426 }
1427
1428 1;
1429
1430 __END__
1431
1432 =head1 NAME
1433
1434 DBM::Deep - A pure perl multi-level hash/array DBM
1435
1436 =head1 SYNOPSIS
1437
1438   use DBM::Deep;
1439   my $db = DBM::Deep->new( "foo.db" );
1440
1441   $db->{key} = 'value'; # tie() style
1442   print $db->{key};
1443
1444   $db->put('key' => 'value'); # OO style
1445   print $db->get('key');
1446
1447   # true multi-level support
1448   $db->{my_complex} = [
1449         'hello', { perl => 'rules' },
1450         42, 99,
1451   ];
1452
1453 =head1 DESCRIPTION
1454
1455 A unique flat-file database module, written in pure perl.  True
1456 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1457 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1458 handle millions of keys and unlimited hash levels without significant
1459 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1460 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1461 Mac OS X and Windows.
1462
1463 =head1 INSTALLATION
1464
1465 Hopefully you are using Perl's excellent CPAN module, which will download
1466 and install the module for you.  If not, get the tarball, and run these
1467 commands:
1468
1469         tar zxf DBM-Deep-*
1470         cd DBM-Deep-*
1471         perl Makefile.PL
1472         make
1473         make test
1474         make install
1475
1476 =head1 SETUP
1477
1478 Construction can be done OO-style (which is the recommended way), or using
1479 Perl's tie() function.  Both are examined here.
1480
1481 =head2 OO CONSTRUCTION
1482
1483 The recommended way to construct a DBM::Deep object is to use the new()
1484 method, which gets you a blessed, tied hash or array reference.
1485
1486         my $db = DBM::Deep->new( "foo.db" );
1487
1488 This opens a new database handle, mapped to the file "foo.db".  If this
1489 file does not exist, it will automatically be created.  DB files are
1490 opened in "r+" (read/write) mode, and the type of object returned is a
1491 hash, unless otherwise specified (see L<OPTIONS> below).
1492
1493 You can pass a number of options to the constructor to specify things like
1494 locking, autoflush, etc.  This is done by passing an inline hash:
1495
1496         my $db = DBM::Deep->new(
1497                 file => "foo.db",
1498                 locking => 1,
1499                 autoflush => 1
1500         );
1501
1502 Notice that the filename is now specified I<inside> the hash with
1503 the "file" parameter, as opposed to being the sole argument to the
1504 constructor.  This is required if any options are specified.
1505 See L<OPTIONS> below for the complete list.
1506
1507
1508
1509 You can also start with an array instead of a hash.  For this, you must
1510 specify the C<type> parameter:
1511
1512         my $db = DBM::Deep->new(
1513                 file => "foo.db",
1514                 type => DBM::Deep->TYPE_ARRAY
1515         );
1516
1517 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1518 a new DB file.  If you create a DBM::Deep object with an existing file, the
1519 C<type> will be loaded from the file header, and an error will be thrown if
1520 the wrong type is passed in.
1521
1522 =head2 TIE CONSTRUCTION
1523
1524 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1525 tie() function.  The object returned from tie() can be used to call methods,
1526 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1527 file (as expected with most tie'd objects).
1528
1529         my %hash;
1530         my $db = tie %hash, "DBM::Deep", "foo.db";
1531
1532         my @array;
1533         my $db = tie @array, "DBM::Deep", "bar.db";
1534
1535 As with the OO constructor, you can replace the DB filename parameter with
1536 a hash containing one or more options (see L<OPTIONS> just below for the
1537 complete list).
1538
1539         tie %hash, "DBM::Deep", {
1540                 file => "foo.db",
1541                 locking => 1,
1542                 autoflush => 1
1543         };
1544
1545 =head2 OPTIONS
1546
1547 There are a number of options that can be passed in when constructing your
1548 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1549
1550 =over
1551
1552 =item * file
1553
1554 Filename of the DB file to link the handle to.  You can pass a full absolute
1555 filesystem path, partial path, or a plain filename if the file is in the
1556 current working directory.  This is a required parameter (though q.v. fh).
1557
1558 =item * fh
1559
1560 If you want, you can pass in the fh instead of the file. This is most useful for doing
1561 something like:
1562
1563   my $db = DBM::Deep->new( { fh => \*DATA } );
1564
1565 You are responsible for making sure that the fh has been opened appropriately for your
1566 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1567 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1568 needs to read from the fh.
1569
1570 =item * file_offset
1571
1572 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1573 not need to set this. However, it's there if you want it.
1574
1575 If you pass in fh and do not set this, it will be set appropriately.
1576
1577 =item * type
1578
1579 This parameter specifies what type of object to create, a hash or array.  Use
1580 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1581 This only takes effect when beginning a new file.  This is an optional
1582 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1583
1584 =item * locking
1585
1586 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1587 function to lock the database in exclusive mode for writes, and shared mode for
1588 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1589 any child hashes or arrays> that use the same DB file.  This is an optional
1590 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1591
1592 =item * autoflush
1593
1594 Specifies whether autoflush is to be enabled on the underlying filehandle.
1595 This obviously slows down write operations, but is required if you may have
1596 multiple processes accessing the same DB file (also consider enable I<locking>).
1597 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1598 (disabled).
1599
1600 =item * autobless
1601
1602 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1603 restore them when fetched.  This is an B<experimental> feature, and does have
1604 side-effects.  Basically, when hashes are re-blessed into their original
1605 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1606 able to call any DBM::Deep methods on them.  You have been warned.
1607 This is an optional parameter, and defaults to 0 (disabled).
1608
1609 =item * filter_*
1610
1611 See L<FILTERS> below.
1612
1613 =item * debug
1614
1615 Setting I<debug> mode will make all errors non-fatal, dump them out to
1616 STDERR, and continue on.  This is for debugging purposes only, and probably
1617 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1618
1619 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1620
1621 =back
1622
1623 =head1 TIE INTERFACE
1624
1625 With DBM::Deep you can access your databases using Perl's standard hash/array
1626 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1627 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1628 to the right place -- the DB file.  This has nothing to do with the
1629 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1630 using regular hashes and arrays, rather than calling functions like C<get()>
1631 and C<put()> (although those work too).  It is entirely up to you how to want
1632 to access your databases.
1633
1634 =head2 HASHES
1635
1636 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1637 or even nested hashes (or arrays) using standard Perl syntax:
1638
1639         my $db = DBM::Deep->new( "foo.db" );
1640
1641         $db->{mykey} = "myvalue";
1642         $db->{myhash} = {};
1643         $db->{myhash}->{subkey} = "subvalue";
1644
1645         print $db->{myhash}->{subkey} . "\n";
1646
1647 You can even step through hash keys using the normal Perl C<keys()> function:
1648
1649         foreach my $key (keys %$db) {
1650                 print "$key: " . $db->{$key} . "\n";
1651         }
1652
1653 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1654 pushes them onto an array, all before the loop even begins.  If you have an
1655 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1656 Perl's C<each()> function, which pulls keys/values one at a time, using very
1657 little memory:
1658
1659         while (my ($key, $value) = each %$db) {
1660                 print "$key: $value\n";
1661         }
1662
1663 Please note that when using C<each()>, you should always pass a direct
1664 hash reference, not a lookup.  Meaning, you should B<never> do this:
1665
1666         # NEVER DO THIS
1667         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1668
1669 This causes an infinite loop, because for each iteration, Perl is calling
1670 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1671 it effectively keeps returning the first key over and over again. Instead,
1672 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1673
1674 =head2 ARRAYS
1675
1676 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1677 reference.  This includes inserting, removing and manipulating elements,
1678 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1679 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1680 or simply be a nested array reference inside a hash.  Example:
1681
1682         my $db = DBM::Deep->new(
1683                 file => "foo-array.db",
1684                 type => DBM::Deep->TYPE_ARRAY
1685         );
1686
1687         $db->[0] = "foo";
1688         push @$db, "bar", "baz";
1689         unshift @$db, "bah";
1690
1691         my $last_elem = pop @$db; # baz
1692         my $first_elem = shift @$db; # bah
1693         my $second_elem = $db->[1]; # bar
1694
1695         my $num_elements = scalar @$db;
1696
1697 =head1 OO INTERFACE
1698
1699 In addition to the I<tie()> interface, you can also use a standard OO interface
1700 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1701 array) has its own methods, but both types share the following common methods:
1702 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1703
1704 =over
1705
1706 =item * new() / clone()
1707
1708 These are the constructor and copy-functions.
1709
1710 =item * put() / store()
1711
1712 Stores a new hash key/value pair, or sets an array element value.  Takes two
1713 arguments, the hash key or array index, and the new value.  The value can be
1714 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1715
1716         $db->put("foo", "bar"); # for hashes
1717         $db->put(1, "bar"); # for arrays
1718
1719 =item * get() / fetch()
1720
1721 Fetches the value of a hash key or array element.  Takes one argument: the hash
1722 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1723 data type stored.
1724
1725         my $value = $db->get("foo"); # for hashes
1726         my $value = $db->get(1); # for arrays
1727
1728 =item * exists()
1729
1730 Checks if a hash key or array index exists.  Takes one argument: the hash key
1731 or array index.  Returns true if it exists, false if not.
1732
1733         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1734         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1735
1736 =item * delete()
1737
1738 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1739 key or array index.  Returns true on success, false if not found.  For arrays,
1740 the remaining elements located after the deleted element are NOT moved over.
1741 The deleted element is essentially just undefined, which is exactly how Perl's
1742 internal arrays work.  Please note that the space occupied by the deleted
1743 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1744 below for details and workarounds.
1745
1746         $db->delete("foo"); # for hashes
1747         $db->delete(1); # for arrays
1748
1749 =item * clear()
1750
1751 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1752 value.  Please note that the space occupied by the deleted keys/values or
1753 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1754 details and workarounds.
1755
1756         $db->clear(); # hashes or arrays
1757
1758 =item * lock() / unlock()
1759
1760 q.v. Locking.
1761
1762 =item * optimize()
1763
1764 Recover lost disk space.
1765
1766 =item * import() / export()
1767
1768 Data going in and out.
1769
1770 =item * set_digest() / set_pack() / set_filter()
1771
1772 q.v. adjusting the interal parameters.
1773
1774 =back
1775
1776 =head2 HASHES
1777
1778 For hashes, DBM::Deep supports all the common methods described above, and the
1779 following additional methods: C<first_key()> and C<next_key()>.
1780
1781 =over
1782
1783 =item * first_key()
1784
1785 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1786 fetched in an undefined order (which appears random).  Takes no arguments,
1787 returns the key as a scalar value.
1788
1789         my $key = $db->first_key();
1790
1791 =item * next_key()
1792
1793 Returns the "next" key in the hash, given the previous one as the sole argument.
1794 Returns undef if there are no more keys to be fetched.
1795
1796         $key = $db->next_key($key);
1797
1798 =back
1799
1800 Here are some examples of using hashes:
1801
1802         my $db = DBM::Deep->new( "foo.db" );
1803
1804         $db->put("foo", "bar");
1805         print "foo: " . $db->get("foo") . "\n";
1806
1807         $db->put("baz", {}); # new child hash ref
1808         $db->get("baz")->put("buz", "biz");
1809         print "buz: " . $db->get("baz")->get("buz") . "\n";
1810
1811         my $key = $db->first_key();
1812         while ($key) {
1813                 print "$key: " . $db->get($key) . "\n";
1814                 $key = $db->next_key($key);
1815         }
1816
1817         if ($db->exists("foo")) { $db->delete("foo"); }
1818
1819 =head2 ARRAYS
1820
1821 For arrays, DBM::Deep supports all the common methods described above, and the
1822 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1823 C<unshift()> and C<splice()>.
1824
1825 =over
1826
1827 =item * length()
1828
1829 Returns the number of elements in the array.  Takes no arguments.
1830
1831         my $len = $db->length();
1832
1833 =item * push()
1834
1835 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1836 refs or array refs.  No return value.
1837
1838         $db->push("foo", "bar", {});
1839
1840 =item * pop()
1841
1842 Fetches the last element in the array, and deletes it.  Takes no arguments.
1843 Returns undef if array is empty.  Returns the element value.
1844
1845         my $elem = $db->pop();
1846
1847 =item * shift()
1848
1849 Fetches the first element in the array, deletes it, then shifts all the
1850 remaining elements over to take up the space.  Returns the element value.  This
1851 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1852 details.
1853
1854         my $elem = $db->shift();
1855
1856 =item * unshift()
1857
1858 Inserts one or more elements onto the beginning of the array, shifting all
1859 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1860 No return value.  This method is not recommended with large arrays -- see
1861 <LARGE ARRAYS> below for details.
1862
1863         $db->unshift("foo", "bar", {});
1864
1865 =item * splice()
1866
1867 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1868 -f splice> for usage -- it is too complicated to document here.  This method is
1869 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1870
1871 =back
1872
1873 Here are some examples of using arrays:
1874
1875         my $db = DBM::Deep->new(
1876                 file => "foo.db",
1877                 type => DBM::Deep->TYPE_ARRAY
1878         );
1879
1880         $db->push("bar", "baz");
1881         $db->unshift("foo");
1882         $db->put(3, "buz");
1883
1884         my $len = $db->length();
1885         print "length: $len\n"; # 4
1886
1887         for (my $k=0; $k<$len; $k++) {
1888                 print "$k: " . $db->get($k) . "\n";
1889         }
1890
1891         $db->splice(1, 2, "biz", "baf");
1892
1893         while (my $elem = shift @$db) {
1894                 print "shifted: $elem\n";
1895         }
1896
1897 =head1 LOCKING
1898
1899 Enable automatic file locking by passing a true value to the C<locking>
1900 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1901
1902         my $db = DBM::Deep->new(
1903                 file => "foo.db",
1904                 locking => 1
1905         );
1906
1907 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
1908 mode for writes, and shared mode for reads.  This is required if you have
1909 multiple processes accessing the same database file, to avoid file corruption.
1910 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1911 NFS> below for more.
1912
1913 =head2 EXPLICIT LOCKING
1914
1915 You can explicitly lock a database, so it remains locked for multiple
1916 transactions.  This is done by calling the C<lock()> method, and passing an
1917 optional lock mode argument (defaults to exclusive mode).  This is particularly
1918 useful for things like counters, where the current value needs to be fetched,
1919 then incremented, then stored again.
1920
1921         $db->lock();
1922         my $counter = $db->get("counter");
1923         $counter++;
1924         $db->put("counter", $counter);
1925         $db->unlock();
1926
1927         # or...
1928
1929         $db->lock();
1930         $db->{counter}++;
1931         $db->unlock();
1932
1933 You can pass C<lock()> an optional argument, which specifies which mode to use
1934 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
1935 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
1936 same as the constants defined in Perl's C<Fcntl> module.
1937
1938         $db->lock( DBM::Deep->LOCK_SH );
1939         # something here
1940         $db->unlock();
1941
1942 =head1 IMPORTING/EXPORTING
1943
1944 You can import existing complex structures by calling the C<import()> method,
1945 and export an entire database into an in-memory structure using the C<export()>
1946 method.  Both are examined here.
1947
1948 =head2 IMPORTING
1949
1950 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
1951 walking the structure and adding keys/elements to the database as you go,
1952 simply pass a reference to the C<import()> method.  This recursively adds
1953 everything to an existing DBM::Deep object for you.  Here is an example:
1954
1955         my $struct = {
1956                 key1 => "value1",
1957                 key2 => "value2",
1958                 array1 => [ "elem0", "elem1", "elem2" ],
1959                 hash1 => {
1960                         subkey1 => "subvalue1",
1961                         subkey2 => "subvalue2"
1962                 }
1963         };
1964
1965         my $db = DBM::Deep->new( "foo.db" );
1966         $db->import( $struct );
1967
1968         print $db->{key1} . "\n"; # prints "value1"
1969
1970 This recursively imports the entire C<$struct> object into C<$db>, including
1971 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
1972 keys are merged with the existing ones, replacing if they already exist.
1973 The C<import()> method can be called on any database level (not just the base
1974 level), and works with both hash and array DB types.
1975
1976 B<Note:> Make sure your existing structure has no circular references in it.
1977 These will cause an infinite loop when importing.
1978
1979 =head2 EXPORTING
1980
1981 Calling the C<export()> method on an existing DBM::Deep object will return
1982 a reference to a new in-memory copy of the database.  The export is done
1983 recursively, so all nested hashes/arrays are all exported to standard Perl
1984 objects.  Here is an example:
1985
1986         my $db = DBM::Deep->new( "foo.db" );
1987
1988         $db->{key1} = "value1";
1989         $db->{key2} = "value2";
1990         $db->{hash1} = {};
1991         $db->{hash1}->{subkey1} = "subvalue1";
1992         $db->{hash1}->{subkey2} = "subvalue2";
1993
1994         my $struct = $db->export();
1995
1996         print $struct->{key1} . "\n"; # prints "value1"
1997
1998 This makes a complete copy of the database in memory, and returns a reference
1999 to it.  The C<export()> method can be called on any database level (not just
2000 the base level), and works with both hash and array DB types.  Be careful of
2001 large databases -- you can store a lot more data in a DBM::Deep object than an
2002 in-memory Perl structure.
2003
2004 B<Note:> Make sure your database has no circular references in it.
2005 These will cause an infinite loop when exporting.
2006
2007 =head1 FILTERS
2008
2009 DBM::Deep has a number of hooks where you can specify your own Perl function
2010 to perform filtering on incoming or outgoing data.  This is a perfect
2011 way to extend the engine, and implement things like real-time compression or
2012 encryption.  Filtering applies to the base DB level, and all child hashes /
2013 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2014 constructed, or by calling the C<set_filter()> method at any time.  There are
2015 four available filter hooks, described below:
2016
2017 =over
2018
2019 =item * filter_store_key
2020
2021 This filter is called whenever a hash key is stored.  It
2022 is passed the incoming key, and expected to return a transformed key.
2023
2024 =item * filter_store_value
2025
2026 This filter is called whenever a hash key or array element is stored.  It
2027 is passed the incoming value, and expected to return a transformed value.
2028
2029 =item * filter_fetch_key
2030
2031 This filter is called whenever a hash key is fetched (i.e. via
2032 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2033 and expected to return the plain key.
2034
2035 =item * filter_fetch_value
2036
2037 This filter is called whenever a hash key or array element is fetched.
2038 It is passed the transformed value, and expected to return the plain value.
2039
2040 =back
2041
2042 Here are the two ways to setup a filter hook:
2043
2044         my $db = DBM::Deep->new(
2045                 file => "foo.db",
2046                 filter_store_value => \&my_filter_store,
2047                 filter_fetch_value => \&my_filter_fetch
2048         );
2049
2050         # or...
2051
2052         $db->set_filter( "filter_store_value", \&my_filter_store );
2053         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2054
2055 Your filter function will be called only when dealing with SCALAR keys or
2056 values.  When nested hashes and arrays are being stored/fetched, filtering
2057 is bypassed.  Filters are called as static functions, passed a single SCALAR
2058 argument, and expected to return a single SCALAR value.  If you want to
2059 remove a filter, set the function reference to C<undef>:
2060
2061         $db->set_filter( "filter_store_value", undef );
2062
2063 =head2 REAL-TIME ENCRYPTION EXAMPLE
2064
2065 Here is a working example that uses the I<Crypt::Blowfish> module to
2066 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2067 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2068 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2069
2070         use DBM::Deep;
2071         use Crypt::Blowfish;
2072         use Crypt::CBC;
2073
2074         my $cipher = Crypt::CBC->new({
2075                 'key'             => 'my secret key',
2076                 'cipher'          => 'Blowfish',
2077                 'iv'              => '$KJh#(}q',
2078                 'regenerate_key'  => 0,
2079                 'padding'         => 'space',
2080                 'prepend_iv'      => 0
2081         });
2082
2083         my $db = DBM::Deep->new(
2084                 file => "foo-encrypt.db",
2085                 filter_store_key => \&my_encrypt,
2086                 filter_store_value => \&my_encrypt,
2087                 filter_fetch_key => \&my_decrypt,
2088                 filter_fetch_value => \&my_decrypt,
2089         );
2090
2091         $db->{key1} = "value1";
2092         $db->{key2} = "value2";
2093         print "key1: " . $db->{key1} . "\n";
2094         print "key2: " . $db->{key2} . "\n";
2095
2096         undef $db;
2097         exit;
2098
2099         sub my_encrypt {
2100                 return $cipher->encrypt( $_[0] );
2101         }
2102         sub my_decrypt {
2103                 return $cipher->decrypt( $_[0] );
2104         }
2105
2106 =head2 REAL-TIME COMPRESSION EXAMPLE
2107
2108 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2109 compression / decompression of keys & values with DBM::Deep Filters.
2110 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2111 more on I<Compress::Zlib>.
2112
2113         use DBM::Deep;
2114         use Compress::Zlib;
2115
2116         my $db = DBM::Deep->new(
2117                 file => "foo-compress.db",
2118                 filter_store_key => \&my_compress,
2119                 filter_store_value => \&my_compress,
2120                 filter_fetch_key => \&my_decompress,
2121                 filter_fetch_value => \&my_decompress,
2122         );
2123
2124         $db->{key1} = "value1";
2125         $db->{key2} = "value2";
2126         print "key1: " . $db->{key1} . "\n";
2127         print "key2: " . $db->{key2} . "\n";
2128
2129         undef $db;
2130         exit;
2131
2132         sub my_compress {
2133                 return Compress::Zlib::memGzip( $_[0] ) ;
2134         }
2135         sub my_decompress {
2136                 return Compress::Zlib::memGunzip( $_[0] ) ;
2137         }
2138
2139 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2140 actually numerical index numbers, and are not filtered.
2141
2142 =head1 ERROR HANDLING
2143
2144 Most DBM::Deep methods return a true value for success, and call die() on
2145 failure.  You can wrap calls in an eval block to catch the die.
2146
2147         my $db = DBM::Deep->new( "foo.db" ); # create hash
2148         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2149
2150     print $@;           # prints error message
2151
2152 =head1 LARGEFILE SUPPORT
2153
2154 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2155 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2156 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2157 by calling the static C<set_pack()> method before you do anything else.
2158
2159         DBM::Deep::set_pack(8, 'Q');
2160
2161 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2162 instead of 32-bit longs.  After setting these values your DB files have a
2163 theoretical maximum size of 16 XB (exabytes).
2164
2165 B<Note:> Changing these values will B<NOT> work for existing database files.
2166 Only change this for new files, and make sure it stays set consistently
2167 throughout the file's life.  If you do set these values, you can no longer
2168 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2169 back to 32-bit mode.
2170
2171 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2172 only a 32-bit Perl.  However, I have received user reports that this does
2173 indeed work!
2174
2175 =head1 LOW-LEVEL ACCESS
2176
2177 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2178 you can call the C<_fh()> method, which returns the handle:
2179
2180         my $fh = $db->_fh();
2181
2182 This method can be called on the root level of the datbase, or any child
2183 hashes or arrays.  All levels share a I<root> structure, which contains things
2184 like the filehandle, a reference counter, and all the options specified
2185 when you created the object.  You can get access to this root structure by
2186 calling the C<root()> method.
2187
2188         my $root = $db->_root();
2189
2190 This is useful for changing options after the object has already been created,
2191 such as enabling/disabling locking, or debug modes.  You can also
2192 store your own temporary user data in this structure (be wary of name
2193 collision), which is then accessible from any child hash or array.
2194
2195 =head1 CUSTOM DIGEST ALGORITHM
2196
2197 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2198 keys.  However you can override this, and use another algorithm (such as SHA-256)
2199 or even write your own.  But please note that DBM::Deep currently expects zero
2200 collisions, so your algorithm has to be I<perfect>, so to speak.
2201 Collision detection may be introduced in a later version.
2202
2203
2204
2205 You can specify a custom digest algorithm by calling the static C<set_digest()>
2206 function, passing a reference to a subroutine, and the length of the algorithm's
2207 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2208 objects.  Here is a working example that uses a 256-bit hash from the
2209 I<Digest::SHA256> module.  Please see
2210 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2211
2212         use DBM::Deep;
2213         use Digest::SHA256;
2214
2215         my $context = Digest::SHA256::new(256);
2216
2217         DBM::Deep::set_digest( \&my_digest, 32 );
2218
2219         my $db = DBM::Deep->new( "foo-sha.db" );
2220
2221         $db->{key1} = "value1";
2222         $db->{key2} = "value2";
2223         print "key1: " . $db->{key1} . "\n";
2224         print "key2: " . $db->{key2} . "\n";
2225
2226         undef $db;
2227         exit;
2228
2229         sub my_digest {
2230                 return substr( $context->hash($_[0]), 0, 32 );
2231         }
2232
2233 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2234 of bytes you specify in the C<set_digest()> function (in this case 32).
2235
2236 =head1 CIRCULAR REFERENCES
2237
2238 DBM::Deep has B<experimental> support for circular references.  Meaning you
2239 can have a nested hash key or array element that points to a parent object.
2240 This relationship is stored in the DB file, and is preserved between sessions.
2241 Here is an example:
2242
2243         my $db = DBM::Deep->new( "foo.db" );
2244
2245         $db->{foo} = "bar";
2246         $db->{circle} = $db; # ref to self
2247
2248         print $db->{foo} . "\n"; # prints "foo"
2249         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2250
2251 One catch is, passing the object to a function that recursively walks the
2252 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2253 C<export()> methods) will result in an infinite loop.  The other catch is,
2254 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2255 or C<next_key()> methods), you will get the I<target object's key>, not the
2256 ref's key.  This gets even more interesting with the above example, where
2257 the I<circle> key points to the base DB object, which technically doesn't
2258 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2259 special case.
2260
2261 =head1 CAVEATS / ISSUES / BUGS
2262
2263 This section describes all the known issues with DBM::Deep.  It you have found
2264 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2265
2266 =head2 UNUSED SPACE RECOVERY
2267
2268 One major caveat with DBM::Deep is that space occupied by existing keys and
2269 values is not recovered when they are deleted.  Meaning if you keep deleting
2270 and adding new keys, your file will continuously grow.  I am working on this,
2271 but in the meantime you can call the built-in C<optimize()> method from time to
2272 time (perhaps in a crontab or something) to recover all your unused space.
2273
2274         $db->optimize(); # returns true on success
2275
2276 This rebuilds the ENTIRE database into a new file, then moves it on top of
2277 the original.  The new file will have no unused space, thus it will take up as
2278 little disk space as possible.  Please note that this operation can take
2279 a long time for large files, and you need enough disk space to temporarily hold
2280 2 copies of your DB file.  The temporary file is created in the same directory
2281 as the original, named with a ".tmp" extension, and is deleted when the
2282 operation completes.  Oh, and if locking is enabled, the DB is automatically
2283 locked for the entire duration of the copy.
2284
2285 B<WARNING:> Only call optimize() on the top-level node of the database, and
2286 make sure there are no child references lying around.  DBM::Deep keeps a reference
2287 counter, and if it is greater than 1, optimize() will abort and return undef.
2288
2289 =head2 AUTOVIVIFICATION
2290
2291 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2292 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2293 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2294 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2295 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2296 this does not work:
2297
2298         $db->{foo}->{bar} = "hello";
2299
2300 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2301 being an empty hash.  Try this instead, which works fine:
2302
2303         $db->{foo} = { bar => "hello" };
2304
2305 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2306 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2307 Probably a bug in Perl.
2308
2309 =head2 FILE CORRUPTION
2310
2311 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2312 for a 32-bit signature when opened, but other corruption in files can cause
2313 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2314 stuck in an infinite loop depending on the level of corruption.  File write
2315 operations are not checked for failure (for speed), so if you happen to run
2316 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2317 be addressed in a later version of DBM::Deep.
2318
2319 =head2 DB OVER NFS
2320
2321 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2322 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2323 about setting up your NFS server with a locking daemon, then using lockf() to
2324 lock your files, but your mileage may vary there as well.  From what I
2325 understand, there is no real way to do it.  However, if you need access to the
2326 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2327 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2328
2329 =head2 COPYING OBJECTS
2330
2331 Beware of copying tied objects in Perl.  Very strange things can happen.
2332 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2333 returns a new, blessed, tied hash or array to the same level in the DB.
2334
2335         my $copy = $db->clone();
2336
2337 B<Note>: Since clone() here is cloning the object, not the database location, any
2338 modifications to either $db or $copy will be visible in both.
2339
2340 =head2 LARGE ARRAYS
2341
2342 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2343 These functions cause every element in the array to move, which can be murder
2344 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2345 a different location.  This will be addressed in the forthcoming version 1.00.
2346
2347 =head2 WRITEONLY FILES
2348
2349 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2350 writeonly mode. STORE will verify that the filehandle is writable. However, there
2351 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2352 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2353
2354 =head1 PERFORMANCE
2355
2356 This section discusses DBM::Deep's speed and memory usage.
2357
2358 =head2 SPEED
2359
2360 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2361 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2362 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2363 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2364 with huge databases.  Here is some test data:
2365
2366         Adding 1,000,000 keys to new DB file...
2367
2368         At 100 keys, avg. speed is 2,703 keys/sec
2369         At 200 keys, avg. speed is 2,642 keys/sec
2370         At 300 keys, avg. speed is 2,598 keys/sec
2371         At 400 keys, avg. speed is 2,578 keys/sec
2372         At 500 keys, avg. speed is 2,722 keys/sec
2373         At 600 keys, avg. speed is 2,628 keys/sec
2374         At 700 keys, avg. speed is 2,700 keys/sec
2375         At 800 keys, avg. speed is 2,607 keys/sec
2376         At 900 keys, avg. speed is 2,190 keys/sec
2377         At 1,000 keys, avg. speed is 2,570 keys/sec
2378         At 2,000 keys, avg. speed is 2,417 keys/sec
2379         At 3,000 keys, avg. speed is 1,982 keys/sec
2380         At 4,000 keys, avg. speed is 1,568 keys/sec
2381         At 5,000 keys, avg. speed is 1,533 keys/sec
2382         At 6,000 keys, avg. speed is 1,787 keys/sec
2383         At 7,000 keys, avg. speed is 1,977 keys/sec
2384         At 8,000 keys, avg. speed is 2,028 keys/sec
2385         At 9,000 keys, avg. speed is 2,077 keys/sec
2386         At 10,000 keys, avg. speed is 2,031 keys/sec
2387         At 20,000 keys, avg. speed is 1,970 keys/sec
2388         At 30,000 keys, avg. speed is 2,050 keys/sec
2389         At 40,000 keys, avg. speed is 2,073 keys/sec
2390         At 50,000 keys, avg. speed is 1,973 keys/sec
2391         At 60,000 keys, avg. speed is 1,914 keys/sec
2392         At 70,000 keys, avg. speed is 2,091 keys/sec
2393         At 80,000 keys, avg. speed is 2,103 keys/sec
2394         At 90,000 keys, avg. speed is 1,886 keys/sec
2395         At 100,000 keys, avg. speed is 1,970 keys/sec
2396         At 200,000 keys, avg. speed is 2,053 keys/sec
2397         At 300,000 keys, avg. speed is 1,697 keys/sec
2398         At 400,000 keys, avg. speed is 1,838 keys/sec
2399         At 500,000 keys, avg. speed is 1,941 keys/sec
2400         At 600,000 keys, avg. speed is 1,930 keys/sec
2401         At 700,000 keys, avg. speed is 1,735 keys/sec
2402         At 800,000 keys, avg. speed is 1,795 keys/sec
2403         At 900,000 keys, avg. speed is 1,221 keys/sec
2404         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2405
2406 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2407 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2408 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2409 Run time was 12 min 3 sec.
2410
2411 =head2 MEMORY USAGE
2412
2413 One of the great things about DBM::Deep is that it uses very little memory.
2414 Even with huge databases (1,000,000+ keys) you will not see much increased
2415 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2416 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2417 database handle:
2418
2419           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2420         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2421
2422 Basically the process is taking 2,716K of memory.  And here is the same
2423 process after storing and fetching 1,000,000 keys:
2424
2425           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2426         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2427
2428 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2429 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2430
2431 =head1 DB FILE FORMAT
2432
2433 In case you were interested in the underlying DB file format, it is documented
2434 here in this section.  You don't need to know this to use the module, it's just
2435 included for reference.
2436
2437 =head2 SIGNATURE
2438
2439 DBM::Deep files always start with a 32-bit signature to identify the file type.
2440 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2441 checked for when the file is opened and an error will be thrown if it's not found.
2442
2443 =head2 TAG
2444
2445 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2446 has a standard header containing the type of data, the length of data, and then
2447 the data itself.  The type is a single character (1 byte), the length is a
2448 32-bit unsigned long in network byte order, and the data is, well, the data.
2449 Here is how it unfolds:
2450
2451 =head2 MASTER INDEX
2452
2453 Immediately after the 32-bit file signature is the I<Master Index> record.
2454 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2455 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2456 depending on how the DBM::Deep object was constructed.
2457
2458 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2459 number).  The first 8-bit char of the MD5 signature is the offset into the
2460 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2461 index element is a file offset of the next tag for the key/element in question,
2462 which is usually a I<Bucket List> tag (see below).
2463
2464 The next tag I<could> be another index, depending on how many keys/elements
2465 exist.  See L<RE-INDEXING> below for details.
2466
2467 =head2 BUCKET LIST
2468
2469 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2470 file offsets to where the actual data is stored.  It starts with a standard
2471 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2472 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2473 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2474 When the list fills up, a I<Re-Index> operation is performed (See
2475 L<RE-INDEXING> below).
2476
2477 =head2 BUCKET
2478
2479 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2480 index/value pair (in array mode).  It starts with a standard tag header with
2481 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2482 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2483 header.  The size reported in the tag header is only for the value, but then,
2484 just after the value is another size (32-bit unsigned long) and then the plain
2485 key itself.  Since the value is likely to be fetched more often than the plain
2486 key, I figured it would be I<slightly> faster to store the value first.
2487
2488 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2489 record for the nested structure, where the process begins all over again.
2490
2491 =head2 RE-INDEXING
2492
2493 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2494 exhausted.  Then, when another key/element comes in, the list is converted to a
2495 new index record.  However, this index will look at the next char in the MD5
2496 hash, and arrange new Bucket List pointers accordingly.  This process is called
2497 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2498 17 (16 + new one) keys/elements are removed from the old Bucket List and
2499 inserted into the new index.  Several new Bucket Lists are created in the
2500 process, as a new MD5 char from the key is being examined (it is unlikely that
2501 the keys will all share the same next char of their MD5s).
2502
2503 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2504 when the Bucket Lists will turn into indexes, but the first round tends to
2505 happen right around 4,000 keys.  You will see a I<slight> decrease in
2506 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2507 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2508 right around 900,000 keys.  This process can continue nearly indefinitely --
2509 right up until the point the I<MD5> signatures start colliding with each other,
2510 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2511 getting struck by lightning while you are walking to cash in your tickets.
2512 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2513 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2514 this is 340 unodecillion, but don't quote me).
2515
2516 =head2 STORING
2517
2518 When a new key/element is stored, the key (or index number) is first run through
2519 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2520 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2521 for the first char of the signature (in this case I<b0>).  If it does not exist,
2522 a new I<Bucket List> is created for our key (and the next 15 future keys that
2523 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2524 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2525 this point, unless we are replacing an existing I<Bucket>), where the actual
2526 data will be stored.
2527
2528 =head2 FETCHING
2529
2530 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2531 (or index number), then walking along the indexes.  If there are enough
2532 keys/elements in this DB level, there might be nested indexes, each linked to
2533 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2534 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2535 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2536 plain key are stored.
2537
2538 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2539 methods.  In this process the indexes are walked systematically, and each key
2540 fetched in increasing MD5 order (which is why it appears random).   Once the
2541 I<Bucket> is found, the value is skipped and the plain key returned instead.
2542 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2543 alphabetically sorted.  This only happens on an index-level -- as soon as the
2544 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2545 so it's pretty much undefined how the keys will come out -- just like Perl's
2546 built-in hashes.
2547
2548 =head1 CODE COVERAGE
2549
2550 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2551 B<Devel::Cover> report on this module's test suite.
2552
2553   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2554   File                           stmt   bran   cond    sub    pod   time  total
2555   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2556   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2557   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2558   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2559   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2560   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2561
2562 =head1 MORE INFORMATION
2563
2564 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2565 or send email to L<DBM-Deep@googlegroups.com>.
2566
2567 =head1 AUTHORS
2568
2569 Joseph Huckaby, L<jhuckaby@cpan.org>
2570
2571 Rob Kinyon, L<rkinyon@cpan.org>
2572
2573 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2574
2575 =head1 SEE ALSO
2576
2577 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2578 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2579
2580 =head1 LICENSE
2581
2582 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2583 This is free software, you may use it and distribute it under the
2584 same terms as Perl itself.
2585
2586 =cut