lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use FileHandle;
  35 use Fcntl qw/:flock/;
  36 use Digest::MD5 ();
  37 use Scalar::Util ();
  38 use vars qw/$VERSION/;
  39
  40 $VERSION = "0.96";
  41
  42 ##
  43 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  44 #       (Perl must be compiled with largefile support for files > 2 GB)
  45 #
  46 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47 #       (Perl must be compiled with largefile and 64-bit long support)
  48 ##
  49 #my $LONG_SIZE = 4;
  50 #my $LONG_PACK = 'N';
  51
  52 ##
  53 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  54 # Upgrading this is possible (see above) but probably not necessary.  If you need
  55 # more than 4 GB for a single key or value, this module is really not for you :-)
  56 ##
  57 #my $DATA_LENGTH_SIZE = 4;
  58 #my $DATA_LENGTH_PACK = 'N';
  59 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  60
  61 ##
  62 # Maximum number of buckets per list before another level of indexing is done.
  63 # Increase this value for slightly greater speed, but larger database files.
  64 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  65 ##
  66 my $MAX_BUCKETS = 16;
  67
  68 ##
  69 # Better not adjust anything below here, unless you're me :-)
  70 ##
  71
  72 ##
  73 # Setup digest function for keys
  74 ##
  75 my ($DIGEST_FUNC, $HASH_SIZE);
  76 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  77
  78 ##
  79 # Precalculate index and bucket sizes based on values above.
  80 ##
  81 #my $HASH_SIZE = 16;
  82 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  83
  84 set_digest();
  85 #set_pack();
  86 #precalc_sizes();
  87
  88 ##
  89 # Setup file and tag signatures.  These should never change.
  90 ##
  91 sub SIG_FILE  () { 'DPDB' }
  92 sub SIG_HASH  () { 'H' }
  93 sub SIG_ARRAY () { 'A' }
  94 sub SIG_NULL  () { 'N' }
  95 sub SIG_DATA  () { 'D' }
  96 sub SIG_INDEX () { 'I' }
  97 sub SIG_BLIST () { 'B' }
  98 sub SIG_SIZE  () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH  () { return SIG_HASH; }
 104 sub TYPE_ARRAY () { return SIG_ARRAY; }
 105
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116
 117         ##
 118         # Check if we want a tied hash or array.
 119         ##
 120         my $self;
 121         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 122                 tie @$self, $class, %$args;
 123         }
 124         else {
 125                 tie %$self, $class, %$args;
 126         }
 127
 128         return bless $self, $class;
 129 }
 130
 131 {
 132     my @outer_params = qw( type base_offset );
 133     sub _init {
 134         ##
 135         # Setup $self and bless into this class.
 136         ##
 137         my $class = shift;
 138         my $args = shift;
 139
 140         my $self = {
 141             type => TYPE_HASH,
 142             base_offset => length(SIG_FILE),
 143             root => {
 144                 file => undef,
 145                 fh => undef,
 146                 end => 0,
 147                 links => 0,
 148                 autoflush => undef,
 149                 locking => undef,
 150                 volatile => undef,
 151                 debug => undef,
 152                 mode => 'r+',
 153                 filter_store_key => undef,
 154                 filter_store_value => undef,
 155                 filter_fetch_key => undef,
 156                 filter_fetch_value => undef,
 157                 autobless => undef,
 158                 locked => 0,
 159                 %$args,
 160             },
 161         };
 162
 163         bless $self, $class;
 164
 165         foreach my $outer_parm ( @outer_params ) {
 166             next unless exists $args->{$outer_parm};
 167             $self->{$outer_parm} = $args->{$outer_parm}
 168         }
 169
 170         if ( exists $args->{root} ) {
 171             $self->{root} = $args->{root};
 172         }
 173         else {
 174             # This is cleanup based on the fact that the $args
 175             # coming in is for both the root and non-root items
 176             delete $self->root->{$_} for @outer_params;
 177         }
 178         $self->root->{links}++;
 179
 180         if (!defined($self->fh)) { $self->_open(); }
 181
 182         return $self;
 183     }
 184 }
 185
 186 sub _get_self { tied( %{$_[0]} ) || $_[0] }
 187
 188 sub TIEHASH {
 189     ##
 190     # Tied hash constructor method, called by Perl's tie() function.
 191     ##
 192     my $class = shift;
 193     my $args;
 194     if (scalar(@_) > 1) { $args = {@_}; }
 195     #XXX This use of ref() is bad and is a bug
 196     elsif (ref($_[0])) { $args = $_[0]; }
 197     else { $args = { file => shift }; }
 198
 199     $args->{type} = TYPE_HASH;
 200
 201     return $class->_init($args);
 202 }
 203
 204 sub TIEARRAY {
 205 ##
 206 # Tied array constructor method, called by Perl's tie() function.
 207 ##
 208     my $class = shift;
 209     my $args;
 210     if (scalar(@_) > 1) { $args = {@_}; }
 211     #XXX This use of ref() is bad and is a bug
 212         elsif (ref($_[0])) { $args = $_[0]; }
 213         else { $args = { file => shift }; }
 214
 215         $args->{type} = TYPE_ARRAY;
 216
 217         return $class->_init($args);
 218 }
 219
 220 sub DESTROY {
 221         ##
 222         # Class deconstructor.  Close file handle if there are no more refs.
 223         ##
 224     my $self = _get_self($_[0]);
 225     return unless $self;
 226
 227         $self->root->{links}--;
 228
 229         if (!$self->root->{links}) {
 230                 $self->_close();
 231         }
 232 }
 233
 234 sub _open {
 235         ##
 236         # Open a FileHandle to the database, create if nonexistent.
 237         # Make sure file signature matches DeepDB spec.
 238         ##
 239     my $self = _get_self($_[0]);
 240
 241         if (defined($self->fh)) { $self->_close(); }
 242
 243         if (!(-e $self->root->{file}) && $self->root->{mode} eq 'r+') {
 244                 my $temp = FileHandle->new( $self->root->{file}, 'w' );
 245                 undef $temp;
 246         }
 247
 248     #XXX Convert to set_fh()
 249         $self->root->{fh} = FileHandle->new( $self->root->{file}, $self->root->{mode} );
 250         if (! defined($self->fh)) {
 251                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 252         }
 253
 254     binmode $self->fh; # for win32
 255     if ($self->root->{autoflush}) {
 256         $self->fh->autoflush();
 257     }
 258
 259     my $signature;
 260     seek($self->fh, 0, 0);
 261     my $bytes_read = $self->fh->read($signature, length(SIG_FILE));
 262
 263     ##
 264     # File is empty -- write signature and master index
 265     ##
 266     if (!$bytes_read) {
 267         seek($self->fh, 0, 0);
 268         $self->fh->print(SIG_FILE);
 269         $self->root->{end} = length(SIG_FILE);
 270         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 271
 272         my $plain_key = "[base]";
 273         $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 274         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 275         $self->fh->flush();
 276
 277         return 1;
 278     }
 279
 280     ##
 281     # Check signature was valid
 282     ##
 283     unless ($signature eq SIG_FILE) {
 284         $self->_close();
 285         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 286     }
 287
 288     $self->root->{end} = (stat($self->fh))[7];
 289
 290     ##
 291     # Get our type from master index signature
 292     ##
 293     my $tag = $self->_load_tag($self->base_offset);
 294 #XXX We probably also want to store the hash algorithm name and not assume anything
 295     if (!$tag) {
 296         return $self->_throw_error("Corrupted file, no master index record");
 297     }
 298     if ($self->{type} ne $tag->{signature}) {
 299         return $self->_throw_error("File type mismatch");
 300     }
 301
 302     return 1;
 303 }
 304
 305 sub _close {
 306         ##
 307         # Close database FileHandle
 308         ##
 309     my $self = _get_self($_[0]);
 310         undef $self->root->{fh};
 311 }
 312
 313 sub _create_tag {
 314         ##
 315         # Given offset, signature and content, create tag and write to disk
 316         ##
 317         my ($self, $offset, $sig, $content) = @_;
 318         my $size = length($content);
 319
 320         seek($self->fh, $offset, 0);
 321         $self->fh->print( $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 322
 323         if ($offset == $self->root->{end}) {
 324                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 325         }
 326
 327         return {
 328                 signature => $sig,
 329                 size => $size,
 330                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 331                 content => $content
 332         };
 333 }
 334
 335 sub _load_tag {
 336         ##
 337         # Given offset, load single tag and return signature, size and data
 338         ##
 339         my $self = shift;
 340         my $offset = shift;
 341
 342         seek($self->fh, $offset, 0);
 343         if ($self->fh->eof()) { return undef; }
 344
 345         my $sig;
 346         $self->fh->read($sig, SIG_SIZE);
 347
 348         my $size;
 349         $self->fh->read($size, $DATA_LENGTH_SIZE);
 350         $size = unpack($DATA_LENGTH_PACK, $size);
 351
 352         my $buffer;
 353         $self->fh->read($buffer, $size);
 354
 355         return {
 356                 signature => $sig,
 357                 size => $size,
 358                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 359                 content => $buffer
 360         };
 361 }
 362
 363 sub _index_lookup {
 364         ##
 365         # Given index tag, lookup single entry in index and return .
 366         ##
 367         my $self = shift;
 368         my ($tag, $index) = @_;
 369
 370         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 371         if (!$location) { return; }
 372
 373         return $self->_load_tag( $location );
 374 }
 375
 376 sub _add_bucket {
 377         ##
 378         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 379         # plain (undigested) key and value.
 380         ##
 381         my $self = shift;
 382         my ($tag, $md5, $plain_key, $value) = @_;
 383         my $keys = $tag->{content};
 384         my $location = 0;
 385         my $result = 2;
 386
 387     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 388         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 389
 390         ##
 391         # Iterate through buckets, seeing if this is a new entry or a replace.
 392         ##
 393         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 394                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 395                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 396                 if (!$subloc) {
 397                         ##
 398                         # Found empty bucket (end of list).  Populate and exit loop.
 399                         ##
 400                         $result = 2;
 401
 402             $location = $internal_ref
 403                 ? $value->base_offset
 404                 : $self->root->{end};
 405
 406                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 407                         $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 408                         last;
 409                 }
 410                 elsif ($md5 eq $key) {
 411                         ##
 412                         # Found existing bucket with same key.  Replace with new value.
 413                         ##
 414                         $result = 1;
 415
 416                         if ($internal_ref) {
 417                                 $location = $value->base_offset;
 418                                 seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 419                                 $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 420                         }
 421                         else {
 422                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 423                                 my $size;
 424                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 425
 426                                 ##
 427                                 # If value is a hash, array, or raw value with equal or less size, we can
 428                                 # reuse the same content area of the database.  Otherwise, we have to create
 429                                 # a new content area at the EOF.
 430                                 ##
 431                                 my $actual_length;
 432                 my $r = Scalar::Util::reftype( $value ) || '';
 433                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 434                                 else { $actual_length = length($value); }
 435
 436                                 if ($actual_length <= $size) {
 437                                         $location = $subloc;
 438                                 }
 439                                 else {
 440                                         $location = $self->root->{end};
 441                                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 442                                         $self->fh->print( pack($LONG_PACK, $location) );
 443                                 }
 444                         }
 445                         last;
 446                 }
 447         } # i loop
 448
 449         ##
 450         # If this is an internal reference, return now.
 451         # No need to write value or plain key
 452         ##
 453         if ($internal_ref) {
 454         return $result;
 455     }
 456
 457         ##
 458         # If bucket didn't fit into list, split into a new index level
 459         ##
 460         if (!$location) {
 461                 seek($self->fh, $tag->{ref_loc}, 0);
 462                 $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 463
 464                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 465                 my @offsets = ();
 466
 467                 $keys .= $md5 . pack($LONG_PACK, 0);
 468
 469                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 470                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 471                         if ($key) {
 472                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 473                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 474
 475                                 if ($offsets[$num]) {
 476                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 477                                         seek($self->fh, $offset, 0);
 478                                         my $subkeys;
 479                                         $self->fh->read($subkeys, $BUCKET_LIST_SIZE);
 480
 481                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 482                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 483                                                 if (!$subloc) {
 484                                                         seek($self->fh, $offset + ($k * $BUCKET_SIZE), 0);
 485                                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 486                                                         last;
 487                                                 }
 488                                         } # k loop
 489                                 }
 490                                 else {
 491                                         $offsets[$num] = $self->root->{end};
 492                                         seek($self->fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 493                                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 494
 495                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 496
 497                                         seek($self->fh, $blist_tag->{offset}, 0);
 498                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 499                                 }
 500                         } # key is real
 501                 } # i loop
 502
 503                 $location ||= $self->root->{end};
 504         } # re-index bucket list
 505
 506         ##
 507         # Seek to content area and store signature, value and plaintext key
 508         ##
 509         if ($location) {
 510                 my $content_length;
 511                 seek($self->fh, $location, 0);
 512
 513                 ##
 514                 # Write signature based on content type, set content length and write actual value.
 515                 ##
 516         my $r = Scalar::Util::reftype($value) || '';
 517                 if ($r eq 'HASH') {
 518                         $self->fh->print( TYPE_HASH );
 519                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 520                         $content_length = $INDEX_SIZE;
 521                 }
 522                 elsif ($r eq 'ARRAY') {
 523                         $self->fh->print( TYPE_ARRAY );
 524                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 525                         $content_length = $INDEX_SIZE;
 526                 }
 527                 elsif (!defined($value)) {
 528                         $self->fh->print( SIG_NULL );
 529                         $self->fh->print( pack($DATA_LENGTH_PACK, 0) );
 530                         $content_length = 0;
 531                 }
 532                 else {
 533                         $self->fh->print( SIG_DATA );
 534                         $self->fh->print( pack($DATA_LENGTH_PACK, length($value)) . $value );
 535                         $content_length = length($value);
 536                 }
 537
 538                 ##
 539                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 540                 ##
 541                 $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 542
 543                 ##
 544                 # If value is blessed, preserve class name
 545                 ##
 546                 if ( $self->root->{autobless} ) {
 547             my $value_class = Scalar::Util::blessed($value);
 548             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 549                 ##
 550                 # Blessed ref -- will restore later
 551                 ##
 552                 $self->fh->print( chr(1) );
 553                 $self->fh->print( pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 554                 $content_length += 1;
 555                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 556             }
 557             else {
 558                 $self->fh->print( chr(0) );
 559                 $content_length += 1;
 560             }
 561         }
 562
 563                 ##
 564                 # If this is a new content area, advance EOF counter
 565                 ##
 566                 if ($location == $self->root->{end}) {
 567                         $self->root->{end} += SIG_SIZE;
 568                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 569                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 570                 }
 571
 572                 ##
 573                 # If content is a hash or array, create new child DeepDB object and
 574                 # pass each key or element to it.
 575                 ##
 576                 if ($r eq 'HASH') {
 577                         my $branch = DBM::Deep->new(
 578                                 type => TYPE_HASH,
 579                                 base_offset => $location,
 580                                 root => $self->root,
 581                         );
 582                         foreach my $key (keys %{$value}) {
 583                                 $branch->{$key} = $value->{$key};
 584                         }
 585                 }
 586                 elsif ($r eq 'ARRAY') {
 587                         my $branch = DBM::Deep->new(
 588                                 type => TYPE_ARRAY,
 589                                 base_offset => $location,
 590                                 root => $self->root,
 591                         );
 592                         my $index = 0;
 593                         foreach my $element (@{$value}) {
 594                                 $branch->[$index] = $element;
 595                                 $index++;
 596                         }
 597                 }
 598
 599                 return $result;
 600         }
 601
 602         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 603 }
 604
 605 sub _get_bucket_value {
 606         ##
 607         # Fetch single value given tag and MD5 digested key.
 608         ##
 609         my $self = shift;
 610         my ($tag, $md5) = @_;
 611         my $keys = $tag->{content};
 612
 613         ##
 614         # Iterate through buckets, looking for a key match
 615         ##
 616     BUCKET:
 617         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 618                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 619                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 620
 621                 if (!$subloc) {
 622                         ##
 623                         # Hit end of list, no match
 624                         ##
 625                         return;
 626                 }
 627
 628         if ( $md5 ne $key ) {
 629             next BUCKET;
 630         }
 631
 632         ##
 633         # Found match -- seek to offset and read signature
 634         ##
 635         my $signature;
 636         seek($self->fh, $subloc, 0);
 637         $self->fh->read($signature, SIG_SIZE);
 638
 639         ##
 640         # If value is a hash or array, return new DeepDB object with correct offset
 641         ##
 642         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 643             my $obj = DBM::Deep->new(
 644                 type => $signature,
 645                 base_offset => $subloc,
 646                 root => $self->root
 647             );
 648
 649             if ($self->root->{autobless}) {
 650                 ##
 651                 # Skip over value and plain key to see if object needs
 652                 # to be re-blessed
 653                 ##
 654                 seek($self->fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 655
 656                 my $size;
 657                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 658                 if ($size) { seek($self->fh, $size, 1); }
 659
 660                 my $bless_bit;
 661                 $self->fh->read($bless_bit, 1);
 662                 if (ord($bless_bit)) {
 663                     ##
 664                     # Yes, object needs to be re-blessed
 665                     ##
 666                     my $class_name;
 667                     $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 668                     if ($size) { $self->fh->read($class_name, $size); }
 669                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 670                 }
 671             }
 672
 673             return $obj;
 674         }
 675
 676         ##
 677         # Otherwise return actual value
 678         ##
 679         elsif ($signature eq SIG_DATA) {
 680             my $size;
 681             my $value = '';
 682             $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 683             if ($size) { $self->fh->read($value, $size); }
 684             return $value;
 685         }
 686
 687         ##
 688         # Key exists, but content is null
 689         ##
 690         else { return; }
 691         } # i loop
 692
 693         return;
 694 }
 695
 696 sub _delete_bucket {
 697         ##
 698         # Delete single key/value pair given tag and MD5 digested key.
 699         ##
 700         my $self = shift;
 701         my ($tag, $md5) = @_;
 702         my $keys = $tag->{content};
 703
 704         ##
 705         # Iterate through buckets, looking for a key match
 706         ##
 707     BUCKET:
 708         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 709                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 710                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 711
 712                 if (!$subloc) {
 713                         ##
 714                         # Hit end of list, no match
 715                         ##
 716                         return;
 717                 }
 718
 719         if ( $md5 ne $key ) {
 720             next BUCKET;
 721         }
 722
 723         ##
 724         # Matched key -- delete bucket and return
 725         ##
 726         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 727         $self->fh->print( substr($keys, ($i+1) * $BUCKET_SIZE ) );
 728         $self->fh->print( chr(0) x $BUCKET_SIZE );
 729
 730         return 1;
 731         } # i loop
 732
 733         return;
 734 }
 735
 736 sub _bucket_exists {
 737         ##
 738         # Check existence of single key given tag and MD5 digested key.
 739         ##
 740         my $self = shift;
 741         my ($tag, $md5) = @_;
 742         my $keys = $tag->{content};
 743
 744         ##
 745         # Iterate through buckets, looking for a key match
 746         ##
 747     BUCKET:
 748         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 749                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 750                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 751
 752                 if (!$subloc) {
 753                         ##
 754                         # Hit end of list, no match
 755                         ##
 756                         return;
 757                 }
 758
 759         if ( $md5 ne $key ) {
 760             next BUCKET;
 761         }
 762
 763         ##
 764         # Matched key -- return true
 765         ##
 766         return 1;
 767         } # i loop
 768
 769         return;
 770 }
 771
 772 sub _find_bucket_list {
 773         ##
 774         # Locate offset for bucket list, given digested key
 775         ##
 776         my $self = shift;
 777         my $md5 = shift;
 778
 779         ##
 780         # Locate offset for bucket list using digest index system
 781         ##
 782         my $ch = 0;
 783         my $tag = $self->_load_tag($self->base_offset);
 784         if (!$tag) { return; }
 785
 786         while ($tag->{signature} ne SIG_BLIST) {
 787                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 788                 if (!$tag) { return; }
 789                 $ch++;
 790         }
 791
 792         return $tag;
 793 }
 794
 795 sub _traverse_index {
 796         ##
 797         # Scan index and recursively step into deeper levels, looking for next key.
 798         ##
 799     my ($self, $offset, $ch, $force_return_next) = @_;
 800     $force_return_next = undef unless $force_return_next;
 801
 802         my $tag = $self->_load_tag( $offset );
 803
 804         if ($tag->{signature} ne SIG_BLIST) {
 805                 my $content = $tag->{content};
 806                 my $start;
 807                 if ($self->{return_next}) { $start = 0; }
 808                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 809
 810                 for (my $index = $start; $index < 256; $index++) {
 811                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 812                         if ($subloc) {
 813                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 814                                 if (defined($result)) { return $result; }
 815                         }
 816                 } # index loop
 817
 818                 $self->{return_next} = 1;
 819         } # tag is an index
 820
 821         elsif ($tag->{signature} eq SIG_BLIST) {
 822                 my $keys = $tag->{content};
 823                 if ($force_return_next) { $self->{return_next} = 1; }
 824
 825                 ##
 826                 # Iterate through buckets, looking for a key match
 827                 ##
 828                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 829                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 830                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 831
 832                         if (!$subloc) {
 833                                 ##
 834                                 # End of bucket list -- return to outer loop
 835                                 ##
 836                                 $self->{return_next} = 1;
 837                                 last;
 838                         }
 839                         elsif ($key eq $self->{prev_md5}) {
 840                                 ##
 841                                 # Located previous key -- return next one found
 842                                 ##
 843                                 $self->{return_next} = 1;
 844                                 next;
 845                         }
 846                         elsif ($self->{return_next}) {
 847                                 ##
 848                                 # Seek to bucket location and skip over signature
 849                                 ##
 850                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 851
 852                                 ##
 853                                 # Skip over value to get to plain key
 854                                 ##
 855                                 my $size;
 856                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 857                                 if ($size) { seek($self->fh, $size, 1); }
 858
 859                                 ##
 860                                 # Read in plain key and return as scalar
 861                                 ##
 862                                 my $plain_key;
 863                                 $self->fh->read($size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 864                                 if ($size) { $self->fh->read($plain_key, $size); }
 865
 866                                 return $plain_key;
 867                         }
 868                 } # bucket loop
 869
 870                 $self->{return_next} = 1;
 871         } # tag is a bucket list
 872
 873         return;
 874 }
 875
 876 sub _get_next_key {
 877         ##
 878         # Locate next key, given digested previous one
 879         ##
 880     my $self = _get_self($_[0]);
 881
 882         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 883         $self->{return_next} = 0;
 884
 885         ##
 886         # If the previous key was not specifed, start at the top and
 887         # return the first one found.
 888         ##
 889         if (!$self->{prev_md5}) {
 890                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 891                 $self->{return_next} = 1;
 892         }
 893
 894         return $self->_traverse_index( $self->base_offset, 0 );
 895 }
 896
 897 sub lock {
 898         ##
 899         # If db locking is set, flock() the db file.  If called multiple
 900         # times before unlock(), then the same number of unlocks() must
 901         # be called before the lock is released.
 902         ##
 903     my $self = _get_self($_[0]);
 904         my $type = $_[1];
 905     $type = LOCK_EX unless defined $type;
 906
 907         if ($self->root->{locking}) {
 908                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 909                 $self->root->{locked}++;
 910         }
 911 }
 912
 913 sub unlock {
 914         ##
 915         # If db locking is set, unlock the db file.  See note in lock()
 916         # regarding calling lock() multiple times.
 917         ##
 918     my $self = _get_self($_[0]);
 919
 920         if ($self->root->{locking} && $self->root->{locked} > 0) {
 921                 $self->root->{locked}--;
 922                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 923         }
 924 }
 925
 926 #XXX These uses of ref() need verified
 927 sub _copy_node {
 928         ##
 929         # Copy single level of keys or elements to new DB handle.
 930         # Recurse for nested structures
 931         ##
 932     my $self = _get_self($_[0]);
 933         my $db_temp = $_[1];
 934
 935         if ($self->type eq TYPE_HASH) {
 936                 my $key = $self->first_key();
 937                 while ($key) {
 938                         my $value = $self->get($key);
 939 #XXX This doesn't work with autobless
 940                         if (!ref($value)) { $db_temp->{$key} = $value; }
 941                         else {
 942                                 my $type = $value->type;
 943                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 944                                 else { $db_temp->{$key} = []; }
 945                                 $value->_copy_node( $db_temp->{$key} );
 946                         }
 947                         $key = $self->next_key($key);
 948                 }
 949         }
 950         else {
 951                 my $length = $self->length();
 952                 for (my $index = 0; $index < $length; $index++) {
 953                         my $value = $self->get($index);
 954                         if (!ref($value)) { $db_temp->[$index] = $value; }
 955             #XXX NO tests for this code
 956                         else {
 957                                 my $type = $value->type;
 958                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 959                                 else { $db_temp->[$index] = []; }
 960                                 $value->_copy_node( $db_temp->[$index] );
 961                         }
 962                 }
 963         }
 964 }
 965
 966 sub export {
 967         ##
 968         # Recursively export into standard Perl hashes and arrays.
 969         ##
 970     my $self = _get_self($_[0]);
 971
 972         my $temp;
 973         if ($self->type eq TYPE_HASH) { $temp = {}; }
 974         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 975
 976         $self->lock();
 977         $self->_copy_node( $temp );
 978         $self->unlock();
 979
 980         return $temp;
 981 }
 982
 983 sub import {
 984         ##
 985         # Recursively import Perl hash/array structure
 986         ##
 987     #XXX This use of ref() seems to be ok
 988         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 989
 990     my $self = _get_self($_[0]);
 991         my $struct = $_[1];
 992
 993     #XXX This use of ref() seems to be ok
 994         if (!ref($struct)) {
 995                 ##
 996                 # struct is not a reference, so just import based on our type
 997                 ##
 998                 shift @_;
 999
1000                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1001                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1002         }
1003
1004     my $r = Scalar::Util::reftype($struct) || '';
1005         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1006                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1007         }
1008         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1009                 $self->push( @$struct );
1010         }
1011         else {
1012                 return $self->_throw_error("Cannot import: type mismatch");
1013         }
1014
1015         return 1;
1016 }
1017
1018 sub optimize {
1019         ##
1020         # Rebuild entire database into new file, then move
1021         # it back on top of original.
1022         ##
1023     my $self = _get_self($_[0]);
1024         if ($self->root->{links} > 1) {
1025                 return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1026         }
1027
1028         my $db_temp = DBM::Deep->new(
1029                 file => $self->root->{file} . '.tmp',
1030                 type => $self->type
1031         );
1032         if (!$db_temp) {
1033                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1034         }
1035
1036         $self->lock();
1037         $self->_copy_node( $db_temp );
1038         undef $db_temp;
1039
1040         ##
1041         # Attempt to copy user, group and permissions over to new file
1042         ##
1043         my @stats = stat($self->fh);
1044         my $perms = $stats[2] & 07777;
1045         my $uid = $stats[4];
1046         my $gid = $stats[5];
1047         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1048         chmod( $perms, $self->root->{file} . '.tmp' );
1049
1050     # q.v. perlport for more information on this variable
1051     if ( $^O eq 'MSWin32' ) {
1052                 ##
1053                 # Potential race condition when optmizing on Win32 with locking.
1054                 # The Windows filesystem requires that the filehandle be closed
1055                 # before it is overwritten with rename().  This could be redone
1056                 # with a soft copy.
1057                 ##
1058                 $self->unlock();
1059                 $self->_close();
1060         }
1061
1062         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1063                 unlink $self->root->{file} . '.tmp';
1064                 $self->unlock();
1065                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1066         }
1067
1068         $self->unlock();
1069         $self->_close();
1070         $self->_open();
1071
1072         return 1;
1073 }
1074
1075 sub clone {
1076         ##
1077         # Make copy of object and return
1078         ##
1079     my $self = _get_self($_[0]);
1080
1081         return DBM::Deep->new(
1082                 type => $self->type,
1083                 base_offset => $self->base_offset,
1084                 root => $self->root
1085         );
1086 }
1087
1088 {
1089     my %is_legal_filter = map {
1090         $_ => ~~1,
1091     } qw(
1092         store_key store_value
1093         fetch_key fetch_value
1094     );
1095
1096     sub set_filter {
1097         ##
1098         # Setup filter function for storing or fetching the key or value
1099         ##
1100         my $self = _get_self($_[0]);
1101         my $type = lc $_[1];
1102         my $func = $_[2] ? $_[2] : undef;
1103
1104         if ( $is_legal_filter{$type} ) {
1105             $self->root->{"filter_$type"} = $func;
1106             return 1;
1107         }
1108
1109         return;
1110     }
1111 }
1112
1113 ##
1114 # Accessor methods
1115 ##
1116
1117 sub root {
1118         ##
1119         # Get access to the root structure
1120         ##
1121     my $self = _get_self($_[0]);
1122         return $self->{root};
1123 }
1124
1125 sub fh {
1126         ##
1127         # Get access to the raw FileHandle
1128         ##
1129     #XXX It will be useful, though, when we split out HASH and ARRAY
1130     my $self = _get_self($_[0]);
1131         return $self->root->{fh};
1132 }
1133
1134 sub type {
1135         ##
1136         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1137         ##
1138     my $self = _get_self($_[0]);
1139         return $self->{type};
1140 }
1141
1142 sub base_offset {
1143         ##
1144         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1145         ##
1146     my $self = _get_self($_[0]);
1147         return $self->{base_offset};
1148 }
1149
1150 sub error {
1151         ##
1152         # Get last error string, or undef if no error
1153         ##
1154         return $_[0]
1155         ? ( _get_self($_[0])->{root}->{error} or undef )
1156         : $@;
1157 }
1158
1159 ##
1160 # Utility methods
1161 ##
1162
1163 sub _throw_error {
1164         ##
1165         # Store error string in self
1166         ##
1167     my $self = _get_self($_[0]);
1168         my $error_text = $_[1];
1169
1170         $self->root->{error} = $error_text;
1171
1172         unless ($self->root->{debug}) {
1173         die "DBM::Deep: $error_text\n";
1174     }
1175
1176     warn "DBM::Deep: $error_text\n";
1177         return;
1178 }
1179
1180 sub clear_error {
1181         ##
1182         # Clear error state
1183         ##
1184     my $self = _get_self($_[0]);
1185
1186         undef $self->root->{error};
1187 }
1188
1189 sub precalc_sizes {
1190         ##
1191         # Precalculate index, bucket and bucket list sizes
1192         ##
1193
1194     #XXX I don't like this ...
1195     set_pack() unless defined $LONG_SIZE;
1196
1197         $INDEX_SIZE = 256 * $LONG_SIZE;
1198         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1199         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1200 }
1201
1202 sub set_pack {
1203         ##
1204         # Set pack/unpack modes (see file header for more)
1205         ##
1206     my ($long_s, $long_p, $data_s, $data_p) = @_;
1207
1208     $LONG_SIZE = $long_s ? $long_s : 4;
1209     $LONG_PACK = $long_p ? $long_p : 'N';
1210
1211     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1212     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1213
1214         precalc_sizes();
1215 }
1216
1217 sub set_digest {
1218         ##
1219         # Set key digest function (default is MD5)
1220         ##
1221     my ($digest_func, $hash_size) = @_;
1222
1223     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1224     $HASH_SIZE = $hash_size ? $hash_size : 16;
1225
1226         precalc_sizes();
1227 }
1228
1229 ##
1230 # tie() methods (hashes and arrays)
1231 ##
1232
1233 sub STORE {
1234         ##
1235         # Store single hash key/value or array element in database.
1236         ##
1237     my $self = _get_self($_[0]);
1238         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1239     #XXX What is ref() checking here?
1240     #YYY User may be storing a hash, in which case we do not want it run
1241     #YYY through the filtering system
1242         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1243
1244         my $unpacked_key = $key;
1245         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1246         my $md5 = $DIGEST_FUNC->($key);
1247
1248         ##
1249         # Make sure file is open
1250         ##
1251         if (!defined($self->fh) && !$self->_open()) {
1252                 return;
1253         }
1254
1255         ##
1256         # Request exclusive lock for writing
1257         ##
1258         $self->lock( LOCK_EX );
1259
1260         ##
1261         # If locking is enabled, set 'end' parameter again, in case another
1262         # DB instance appended to our file while we were unlocked.
1263         ##
1264         if ($self->root->{locking} || $self->root->{volatile}) {
1265                 $self->root->{end} = (stat($self->fh))[7];
1266         }
1267
1268         ##
1269         # Locate offset for bucket list using digest index system
1270         ##
1271         my $tag = $self->_load_tag($self->base_offset);
1272         if (!$tag) {
1273                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1274         }
1275
1276         my $ch = 0;
1277         while ($tag->{signature} ne SIG_BLIST) {
1278                 my $num = ord(substr($md5, $ch, 1));
1279                 my $new_tag = $self->_index_lookup($tag, $num);
1280                 if (!$new_tag) {
1281                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1282                         seek($self->fh, $ref_loc, 0);
1283                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
1284
1285                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1286                         $tag->{ref_loc} = $ref_loc;
1287                         $tag->{ch} = $ch;
1288                         last;
1289                 }
1290                 else {
1291                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1292                         $tag = $new_tag;
1293                         $tag->{ref_loc} = $ref_loc;
1294                         $tag->{ch} = $ch;
1295                 }
1296                 $ch++;
1297         }
1298
1299         ##
1300         # Add key/value to bucket list
1301         ##
1302         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1303
1304         ##
1305         # If this object is an array, and bucket was not a replace, and key is numerical,
1306         # and index is equal or greater than current length, advance length variable.
1307         ##
1308         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1309                 $self->STORESIZE( $unpacked_key + 1 );
1310         }
1311
1312         $self->unlock();
1313
1314         return $result;
1315 }
1316
1317 sub FETCH {
1318         ##
1319         # Fetch single value or element given plain key or array index
1320         ##
1321     my $self = _get_self($_[0]);
1322
1323     my $key = $_[1];
1324     if ( $self->type eq TYPE_HASH ) {
1325         if ( my $filter = $self->root->{filter_store_key} ) {
1326             $key = $filter->( $key );
1327         }
1328     }
1329     elsif ( $self->type eq TYPE_ARRAY ) {
1330         if ( $key =~ /^\d+$/ ) {
1331             $key = pack($LONG_PACK, $key);
1332         }
1333     }
1334
1335         my $md5 = $DIGEST_FUNC->($key);
1336
1337         ##
1338         # Make sure file is open
1339         ##
1340         if (!defined($self->fh)) { $self->_open(); }
1341
1342         ##
1343         # Request shared lock for reading
1344         ##
1345         $self->lock( LOCK_SH );
1346
1347         my $tag = $self->_find_bucket_list( $md5 );
1348         if (!$tag) {
1349                 $self->unlock();
1350                 return;
1351         }
1352
1353         ##
1354         # Get value from bucket list
1355         ##
1356         my $result = $self->_get_bucket_value( $tag, $md5 );
1357
1358         $self->unlock();
1359
1360     #XXX What is ref() checking here?
1361         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1362 }
1363
1364 sub DELETE {
1365         ##
1366         # Delete single key/value pair or element given plain key or array index
1367         ##
1368     my $self = _get_self($_[0]);
1369         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1370
1371         my $unpacked_key = $key;
1372         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1373         my $md5 = $DIGEST_FUNC->($key);
1374
1375         ##
1376         # Make sure file is open
1377         ##
1378         if (!defined($self->fh)) { $self->_open(); }
1379
1380         ##
1381         # Request exclusive lock for writing
1382         ##
1383         $self->lock( LOCK_EX );
1384
1385         my $tag = $self->_find_bucket_list( $md5 );
1386         if (!$tag) {
1387                 $self->unlock();
1388                 return;
1389         }
1390
1391         ##
1392         # Delete bucket
1393         ##
1394         my $result = $self->_delete_bucket( $tag, $md5 );
1395
1396         ##
1397         # If this object is an array and the key deleted was on the end of the stack,
1398         # decrement the length variable.
1399         ##
1400         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1401                 $self->STORESIZE( $unpacked_key );
1402         }
1403
1404         $self->unlock();
1405
1406         return $result;
1407 }
1408
1409 sub EXISTS {
1410         ##
1411         # Check if a single key or element exists given plain key or array index
1412         ##
1413     my $self = _get_self($_[0]);
1414         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1415
1416         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1417         my $md5 = $DIGEST_FUNC->($key);
1418
1419         ##
1420         # Make sure file is open
1421         ##
1422         if (!defined($self->fh)) { $self->_open(); }
1423
1424         ##
1425         # Request shared lock for reading
1426         ##
1427         $self->lock( LOCK_SH );
1428
1429         my $tag = $self->_find_bucket_list( $md5 );
1430
1431         ##
1432         # For some reason, the built-in exists() function returns '' for false
1433         ##
1434         if (!$tag) {
1435                 $self->unlock();
1436                 return '';
1437         }
1438
1439         ##
1440         # Check if bucket exists and return 1 or ''
1441         ##
1442         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1443
1444         $self->unlock();
1445
1446         return $result;
1447 }
1448
1449 sub CLEAR {
1450         ##
1451         # Clear all keys from hash, or all elements from array.
1452         ##
1453     my $self = _get_self($_[0]);
1454
1455         ##
1456         # Make sure file is open
1457         ##
1458         if (!defined($self->fh)) { $self->_open(); }
1459
1460         ##
1461         # Request exclusive lock for writing
1462         ##
1463         $self->lock( LOCK_EX );
1464
1465         seek($self->fh, $self->base_offset, 0);
1466         if ($self->fh->eof()) {
1467                 $self->unlock();
1468                 return;
1469         }
1470
1471         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1472
1473         $self->unlock();
1474
1475         return 1;
1476 }
1477
1478 sub FIRSTKEY {
1479         ##
1480         # Locate and return first key (in no particular order)
1481         ##
1482     my $self = _get_self($_[0]);
1483         if ($self->type ne TYPE_HASH) {
1484                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1485         }
1486
1487         ##
1488         # Make sure file is open
1489         ##
1490         if (!defined($self->fh)) { $self->_open(); }
1491
1492         ##
1493         # Request shared lock for reading
1494         ##
1495         $self->lock( LOCK_SH );
1496
1497         my $result = $self->_get_next_key();
1498
1499         $self->unlock();
1500
1501         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1502 }
1503
1504 sub NEXTKEY {
1505         ##
1506         # Return next key (in no particular order), given previous one
1507         ##
1508     my $self = _get_self($_[0]);
1509         if ($self->type ne TYPE_HASH) {
1510                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1511         }
1512         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1513         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1514
1515         ##
1516         # Make sure file is open
1517         ##
1518         if (!defined($self->fh)) { $self->_open(); }
1519
1520         ##
1521         # Request shared lock for reading
1522         ##
1523         $self->lock( LOCK_SH );
1524
1525         my $result = $self->_get_next_key( $prev_md5 );
1526
1527         $self->unlock();
1528
1529         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1530 }
1531
1532 ##
1533 # The following methods are for arrays only
1534 ##
1535
1536 sub FETCHSIZE {
1537         ##
1538         # Return the length of the array
1539         ##
1540     my $self = _get_self($_[0]);
1541         if ($self->type ne TYPE_ARRAY) {
1542                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1543         }
1544
1545         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1546         $self->root->{filter_fetch_value} = undef;
1547
1548         my $packed_size = $self->FETCH('length');
1549
1550         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1551
1552         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1553         else { return 0; }
1554 }
1555
1556 sub STORESIZE {
1557         ##
1558         # Set the length of the array
1559         ##
1560     my $self = _get_self($_[0]);
1561         if ($self->type ne TYPE_ARRAY) {
1562                 return $self->_throw_error("STORESIZE method only supported for arrays");
1563         }
1564         my $new_length = $_[1];
1565
1566         my $SAVE_FILTER = $self->root->{filter_store_value};
1567         $self->root->{filter_store_value} = undef;
1568
1569         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1570
1571         $self->root->{filter_store_value} = $SAVE_FILTER;
1572
1573         return $result;
1574 }
1575
1576 sub POP {
1577         ##
1578         # Remove and return the last element on the array
1579         ##
1580     my $self = _get_self($_[0]);
1581         if ($self->type ne TYPE_ARRAY) {
1582                 return $self->_throw_error("POP method only supported for arrays");
1583         }
1584         my $length = $self->FETCHSIZE();
1585
1586         if ($length) {
1587                 my $content = $self->FETCH( $length - 1 );
1588                 $self->DELETE( $length - 1 );
1589                 return $content;
1590         }
1591         else {
1592                 return;
1593         }
1594 }
1595
1596 sub PUSH {
1597         ##
1598         # Add new element(s) to the end of the array
1599         ##
1600     my $self = _get_self(shift);
1601         if ($self->type ne TYPE_ARRAY) {
1602                 return $self->_throw_error("PUSH method only supported for arrays");
1603         }
1604         my $length = $self->FETCHSIZE();
1605
1606         while (my $content = shift @_) {
1607                 $self->STORE( $length, $content );
1608                 $length++;
1609         }
1610 }
1611
1612 sub SHIFT {
1613         ##
1614         # Remove and return first element on the array.
1615         # Shift over remaining elements to take up space.
1616         ##
1617     my $self = _get_self($_[0]);
1618         if ($self->type ne TYPE_ARRAY) {
1619                 return $self->_throw_error("SHIFT method only supported for arrays");
1620         }
1621         my $length = $self->FETCHSIZE();
1622
1623         if ($length) {
1624                 my $content = $self->FETCH( 0 );
1625
1626                 ##
1627                 # Shift elements over and remove last one.
1628                 ##
1629                 for (my $i = 0; $i < $length - 1; $i++) {
1630                         $self->STORE( $i, $self->FETCH($i + 1) );
1631                 }
1632                 $self->DELETE( $length - 1 );
1633
1634                 return $content;
1635         }
1636         else {
1637                 return;
1638         }
1639 }
1640
1641 sub UNSHIFT {
1642         ##
1643         # Insert new element(s) at beginning of array.
1644         # Shift over other elements to make space.
1645         ##
1646     my $self = _get_self($_[0]);shift @_;
1647         if ($self->type ne TYPE_ARRAY) {
1648                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1649         }
1650         my @new_elements = @_;
1651         my $length = $self->FETCHSIZE();
1652         my $new_size = scalar @new_elements;
1653
1654         if ($length) {
1655                 for (my $i = $length - 1; $i >= 0; $i--) {
1656                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1657                 }
1658         }
1659
1660         for (my $i = 0; $i < $new_size; $i++) {
1661                 $self->STORE( $i, $new_elements[$i] );
1662         }
1663 }
1664
1665 sub SPLICE {
1666         ##
1667         # Splices section of array with optional new section.
1668         # Returns deleted section, or last element deleted in scalar context.
1669         ##
1670     my $self = _get_self($_[0]);shift @_;
1671         if ($self->type ne TYPE_ARRAY) {
1672                 return $self->_throw_error("SPLICE method only supported for arrays");
1673         }
1674         my $length = $self->FETCHSIZE();
1675
1676         ##
1677         # Calculate offset and length of splice
1678         ##
1679         my $offset = shift || 0;
1680         if ($offset < 0) { $offset += $length; }
1681
1682         my $splice_length;
1683         if (scalar @_) { $splice_length = shift; }
1684         else { $splice_length = $length - $offset; }
1685         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1686
1687         ##
1688         # Setup array with new elements, and copy out old elements for return
1689         ##
1690         my @new_elements = @_;
1691         my $new_size = scalar @new_elements;
1692
1693         my @old_elements = ();
1694         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1695                 push @old_elements, $self->FETCH( $i );
1696         }
1697
1698         ##
1699         # Adjust array length, and shift elements to accomodate new section.
1700         ##
1701     if ( $new_size != $splice_length ) {
1702         if ($new_size > $splice_length) {
1703             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1704                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1705             }
1706         }
1707         else {
1708             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1709                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1710             }
1711             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1712                 $self->DELETE( $length - 1 );
1713                 $length--;
1714             }
1715         }
1716         }
1717
1718         ##
1719         # Insert new elements into array
1720         ##
1721         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1722                 $self->STORE( $i, shift @new_elements );
1723         }
1724
1725         ##
1726         # Return deleted section, or last element in scalar context.
1727         ##
1728         return wantarray ? @old_elements : $old_elements[-1];
1729 }
1730
1731 #XXX We don't need to define it.
1732 #XXX It will be useful, though, when we split out HASH and ARRAY
1733 #sub EXTEND {
1734         ##
1735         # Perl will call EXTEND() when the array is likely to grow.
1736         # We don't care, but include it for compatibility.
1737         ##
1738 #}
1739
1740 ##
1741 # Public method aliases
1742 ##
1743 *put = *store = *STORE;
1744 *get = *fetch = *FETCH;
1745 *delete = *DELETE;
1746 *exists = *EXISTS;
1747 *clear = *CLEAR;
1748 *first_key = *FIRSTKEY;
1749 *next_key = *NEXTKEY;
1750 *length = *FETCHSIZE;
1751 *pop = *POP;
1752 *push = *PUSH;
1753 *shift = *SHIFT;
1754 *unshift = *UNSHIFT;
1755 *splice = *SPLICE;
1756
1757 1;
1758
1759 __END__
1760
1761 =head1 NAME
1762
1763 DBM::Deep - A pure perl multi-level hash/array DBM
1764
1765 =head1 SYNOPSIS
1766
1767   use DBM::Deep;
1768   my $db = DBM::Deep->new( "foo.db" );
1769
1770   $db->{key} = 'value'; # tie() style
1771   print $db->{key};
1772
1773   $db->put('key', 'value'); # OO style
1774   print $db->get('key');
1775
1776   # true multi-level support
1777   $db->{my_complex} = [
1778         'hello', { perl => 'rules' },
1779         42, 99 ];
1780
1781 =head1 DESCRIPTION
1782
1783 A unique flat-file database module, written in pure perl.  True
1784 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1785 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1786 handle millions of keys and unlimited hash levels without significant
1787 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1788 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1789 Mac OS X and Windows.
1790
1791 =head1 INSTALLATION
1792
1793 Hopefully you are using CPAN's excellent Perl module, which will download
1794 and install the module for you.  If not, get the tarball, and run these
1795 commands:
1796
1797         tar zxf DBM-Deep-*
1798         cd DBM-Deep-*
1799         perl Makefile.PL
1800         make
1801         make test
1802         make install
1803
1804 =head1 SETUP
1805
1806 Construction can be done OO-style (which is the recommended way), or using
1807 Perl's tie() function.  Both are examined here.
1808
1809 =head2 OO CONSTRUCTION
1810
1811 The recommended way to construct a DBM::Deep object is to use the new()
1812 method, which gets you a blessed, tied hash or array reference.
1813
1814         my $db = DBM::Deep->new( "foo.db" );
1815
1816 This opens a new database handle, mapped to the file "foo.db".  If this
1817 file does not exist, it will automatically be created.  DB files are
1818 opened in "r+" (read/write) mode, and the type of object returned is a
1819 hash, unless otherwise specified (see L<OPTIONS> below).
1820
1821
1822
1823 You can pass a number of options to the constructor to specify things like
1824 locking, autoflush, etc.  This is done by passing an inline hash:
1825
1826         my $db = DBM::Deep->new(
1827                 file => "foo.db",
1828                 locking => 1,
1829                 autoflush => 1
1830         );
1831
1832 Notice that the filename is now specified I<inside> the hash with
1833 the "file" parameter, as opposed to being the sole argument to the
1834 constructor.  This is required if any options are specified.
1835 See L<OPTIONS> below for the complete list.
1836
1837
1838
1839 You can also start with an array instead of a hash.  For this, you must
1840 specify the C<type> parameter:
1841
1842         my $db = DBM::Deep->new(
1843                 file => "foo.db",
1844                 type => DBM::Deep->TYPE_ARRAY
1845         );
1846
1847 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1848 a new DB file.  If you create a DBM::Deep object with an existing file, the
1849 C<type> will be loaded from the file header, and ignored if it is passed
1850 to the constructor.
1851
1852 =head2 TIE CONSTRUCTION
1853
1854 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1855 tie() function.  This is not ideal, because you get only a basic, tied hash
1856 (or array) which is not blessed, so you can't call any functions on it.
1857
1858         my %hash;
1859         tie %hash, "DBM::Deep", "foo.db";
1860
1861         my @array;
1862         tie @array, "DBM::Deep", "bar.db";
1863
1864 As with the OO constructor, you can replace the DB filename parameter with
1865 a hash containing one or more options (see L<OPTIONS> just below for the
1866 complete list).
1867
1868         tie %hash, "DBM::Deep", {
1869                 file => "foo.db",
1870                 locking => 1,
1871                 autoflush => 1
1872         };
1873
1874 =head2 OPTIONS
1875
1876 There are a number of options that can be passed in when constructing your
1877 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1878
1879 =over
1880
1881 =item * file
1882
1883 Filename of the DB file to link the handle to.  You can pass a full absolute
1884 filesystem path, partial path, or a plain filename if the file is in the
1885 current working directory.  This is a required parameter.
1886
1887 =item * mode
1888
1889 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1890 module.  This is an optional parameter, and defaults to "r+" (read/write).
1891 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1892 created if it doesn't exist.
1893
1894 =item * type
1895
1896 This parameter specifies what type of object to create, a hash or array.  Use
1897 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1898 This only takes effect when beginning a new file.  This is an optional
1899 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1900
1901 =item * locking
1902
1903 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1904 function to lock the database in exclusive mode for writes, and shared mode for
1905 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1906 any child hashes or arrays> that use the same DB file.  This is an optional
1907 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1908
1909 =item * autoflush
1910
1911 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1912 This obviously slows down write operations, but is required if you may have
1913 multiple processes accessing the same DB file (also consider enable I<locking>
1914 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1915 parameter, and defaults to 0 (disabled).
1916
1917 =item * volatile
1918
1919 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1920 STORE() operation.  This is required if an outside force may change the size of
1921 the file between transactions.  Locking also implicitly enables volatile.  This
1922 is useful if you want to use a different locking system or write your own.  Pass
1923 any true value to enable.  This is an optional parameter, and defaults to 0
1924 (disabled).
1925
1926 =item * autobless
1927
1928 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1929 restore them when fetched.  This is an B<experimental> feature, and does have
1930 side-effects.  Basically, when hashes are re-blessed into their original
1931 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1932 able to call any DBM::Deep methods on them.  You have been warned.
1933 This is an optional parameter, and defaults to 0 (disabled).
1934
1935 =item * filter_*
1936
1937 See L<FILTERS> below.
1938
1939 =item * debug
1940
1941 Setting I<debug> mode will make all errors non-fatal, dump them out to
1942 STDERR, and continue on.  This is for debugging purposes only, and probably
1943 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1944
1945 =item * fh
1946
1947 Instead of passing a file path, you can instead pass a handle to an pre-opened
1948 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1949 contains your entire Perl script, as well as the data following the __DATA__
1950 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1951 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1952 in that.
1953
1954 =back
1955
1956 =head1 TIE INTERFACE
1957
1958 With DBM::Deep you can access your databases using Perl's standard hash/array
1959 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1960 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1961 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1962 section above.  This simply tells you how to use DBM::Deep using regular hashes
1963 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1964 work too).  It is entirely up to you how to want to access your databases.
1965
1966 =head2 HASHES
1967
1968 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1969 or even nested hashes (or arrays) using standard Perl syntax:
1970
1971         my $db = DBM::Deep->new( "foo.db" );
1972
1973         $db->{mykey} = "myvalue";
1974         $db->{myhash} = {};
1975         $db->{myhash}->{subkey} = "subvalue";
1976
1977         print $db->{myhash}->{subkey} . "\n";
1978
1979 You can even step through hash keys using the normal Perl C<keys()> function:
1980
1981         foreach my $key (keys %$db) {
1982                 print "$key: " . $db->{$key} . "\n";
1983         }
1984
1985 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1986 pushes them onto an array, all before the loop even begins.  If you have an
1987 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1988 Perl's C<each()> function, which pulls keys/values one at a time, using very
1989 little memory:
1990
1991         while (my ($key, $value) = each %$db) {
1992                 print "$key: $value\n";
1993         }
1994
1995 Please note that when using C<each()>, you should always pass a direct
1996 hash reference, not a lookup.  Meaning, you should B<never> do this:
1997
1998         # NEVER DO THIS
1999         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
2000
2001 This causes an infinite loop, because for each iteration, Perl is calling
2002 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
2003 it effectively keeps returning the first key over and over again. Instead,
2004 assign a temporary variable to C<$db->{foo}>, then pass that to each().
2005
2006 =head2 ARRAYS
2007
2008 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2009 reference.  This includes inserting, removing and manipulating elements,
2010 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2011 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2012 or simply be a nested array reference inside a hash.  Example:
2013
2014         my $db = DBM::Deep->new(
2015                 file => "foo-array.db",
2016                 type => DBM::Deep->TYPE_ARRAY
2017         );
2018
2019         $db->[0] = "foo";
2020         push @$db, "bar", "baz";
2021         unshift @$db, "bah";
2022
2023         my $last_elem = pop @$db; # baz
2024         my $first_elem = shift @$db; # bah
2025         my $second_elem = $db->[1]; # bar
2026
2027         my $num_elements = scalar @$db;
2028
2029 =head1 OO INTERFACE
2030
2031 In addition to the I<tie()> interface, you can also use a standard OO interface
2032 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2033 array) has its own methods, but both types share the following common methods:
2034 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2035
2036 =over
2037
2038 =item * put()
2039
2040 Stores a new hash key/value pair, or sets an array element value.  Takes two
2041 arguments, the hash key or array index, and the new value.  The value can be
2042 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2043
2044         $db->put("foo", "bar"); # for hashes
2045         $db->put(1, "bar"); # for arrays
2046
2047 =item * get()
2048
2049 Fetches the value of a hash key or array element.  Takes one argument: the hash
2050 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2051 data type stored.
2052
2053         my $value = $db->get("foo"); # for hashes
2054         my $value = $db->get(1); # for arrays
2055
2056 =item * exists()
2057
2058 Checks if a hash key or array index exists.  Takes one argument: the hash key
2059 or array index.  Returns true if it exists, false if not.
2060
2061         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2062         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2063
2064 =item * delete()
2065
2066 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2067 key or array index.  Returns true on success, false if not found.  For arrays,
2068 the remaining elements located after the deleted element are NOT moved over.
2069 The deleted element is essentially just undefined, which is exactly how Perl's
2070 internal arrays work.  Please note that the space occupied by the deleted
2071 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2072 below for details and workarounds.
2073
2074         $db->delete("foo"); # for hashes
2075         $db->delete(1); # for arrays
2076
2077 =item * clear()
2078
2079 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2080 value.  Please note that the space occupied by the deleted keys/values or
2081 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2082 details and workarounds.
2083
2084         $db->clear(); # hashes or arrays
2085
2086 =back
2087
2088 =head2 HASHES
2089
2090 For hashes, DBM::Deep supports all the common methods described above, and the
2091 following additional methods: C<first_key()> and C<next_key()>.
2092
2093 =over
2094
2095 =item * first_key()
2096
2097 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2098 fetched in an undefined order (which appears random).  Takes no arguments,
2099 returns the key as a scalar value.
2100
2101         my $key = $db->first_key();
2102
2103 =item * next_key()
2104
2105 Returns the "next" key in the hash, given the previous one as the sole argument.
2106 Returns undef if there are no more keys to be fetched.
2107
2108         $key = $db->next_key($key);
2109
2110 =back
2111
2112 Here are some examples of using hashes:
2113
2114         my $db = DBM::Deep->new( "foo.db" );
2115
2116         $db->put("foo", "bar");
2117         print "foo: " . $db->get("foo") . "\n";
2118
2119         $db->put("baz", {}); # new child hash ref
2120         $db->get("baz")->put("buz", "biz");
2121         print "buz: " . $db->get("baz")->get("buz") . "\n";
2122
2123         my $key = $db->first_key();
2124         while ($key) {
2125                 print "$key: " . $db->get($key) . "\n";
2126                 $key = $db->next_key($key);
2127         }
2128
2129         if ($db->exists("foo")) { $db->delete("foo"); }
2130
2131 =head2 ARRAYS
2132
2133 For arrays, DBM::Deep supports all the common methods described above, and the
2134 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2135 C<unshift()> and C<splice()>.
2136
2137 =over
2138
2139 =item * length()
2140
2141 Returns the number of elements in the array.  Takes no arguments.
2142
2143         my $len = $db->length();
2144
2145 =item * push()
2146
2147 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2148 refs or array refs.  No return value.
2149
2150         $db->push("foo", "bar", {});
2151
2152 =item * pop()
2153
2154 Fetches the last element in the array, and deletes it.  Takes no arguments.
2155 Returns undef if array is empty.  Returns the element value.
2156
2157         my $elem = $db->pop();
2158
2159 =item * shift()
2160
2161 Fetches the first element in the array, deletes it, then shifts all the
2162 remaining elements over to take up the space.  Returns the element value.  This
2163 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2164 details.
2165
2166         my $elem = $db->shift();
2167
2168 =item * unshift()
2169
2170 Inserts one or more elements onto the beginning of the array, shifting all
2171 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2172 No return value.  This method is not recommended with large arrays -- see
2173 <LARGE ARRAYS> below for details.
2174
2175         $db->unshift("foo", "bar", {});
2176
2177 =item * splice()
2178
2179 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2180 -f splice> for usage -- it is too complicated to document here.  This method is
2181 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2182
2183 =back
2184
2185 Here are some examples of using arrays:
2186
2187         my $db = DBM::Deep->new(
2188                 file => "foo.db",
2189                 type => DBM::Deep->TYPE_ARRAY
2190         );
2191
2192         $db->push("bar", "baz");
2193         $db->unshift("foo");
2194         $db->put(3, "buz");
2195
2196         my $len = $db->length();
2197         print "length: $len\n"; # 4
2198
2199         for (my $k=0; $k<$len; $k++) {
2200                 print "$k: " . $db->get($k) . "\n";
2201         }
2202
2203         $db->splice(1, 2, "biz", "baf");
2204
2205         while (my $elem = shift @$db) {
2206                 print "shifted: $elem\n";
2207         }
2208
2209 =head1 LOCKING
2210
2211 Enable automatic file locking by passing a true value to the C<locking>
2212 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2213
2214         my $db = DBM::Deep->new(
2215                 file => "foo.db",
2216                 locking => 1
2217         );
2218
2219 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2220 mode for writes, and shared mode for reads.  This is required if you have
2221 multiple processes accessing the same database file, to avoid file corruption.
2222 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2223 NFS> below for more.
2224
2225 =head2 EXPLICIT LOCKING
2226
2227 You can explicitly lock a database, so it remains locked for multiple
2228 transactions.  This is done by calling the C<lock()> method, and passing an
2229 optional lock mode argument (defaults to exclusive mode).  This is particularly
2230 useful for things like counters, where the current value needs to be fetched,
2231 then incremented, then stored again.
2232
2233         $db->lock();
2234         my $counter = $db->get("counter");
2235         $counter++;
2236         $db->put("counter", $counter);
2237         $db->unlock();
2238
2239         # or...
2240
2241         $db->lock();
2242         $db->{counter}++;
2243         $db->unlock();
2244
2245 You can pass C<lock()> an optional argument, which specifies which mode to use
2246 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2247 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2248 same as the constants defined in Perl's C<Fcntl> module.
2249
2250         $db->lock( DBM::Deep->LOCK_SH );
2251         # something here
2252         $db->unlock();
2253
2254 If you want to implement your own file locking scheme, be sure to create your
2255 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2256 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2257 below for more.
2258
2259 =head1 IMPORTING/EXPORTING
2260
2261 You can import existing complex structures by calling the C<import()> method,
2262 and export an entire database into an in-memory structure using the C<export()>
2263 method.  Both are examined here.
2264
2265 =head2 IMPORTING
2266
2267 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2268 walking the structure and adding keys/elements to the database as you go,
2269 simply pass a reference to the C<import()> method.  This recursively adds
2270 everything to an existing DBM::Deep object for you.  Here is an example:
2271
2272         my $struct = {
2273                 key1 => "value1",
2274                 key2 => "value2",
2275                 array1 => [ "elem0", "elem1", "elem2" ],
2276                 hash1 => {
2277                         subkey1 => "subvalue1",
2278                         subkey2 => "subvalue2"
2279                 }
2280         };
2281
2282         my $db = DBM::Deep->new( "foo.db" );
2283         $db->import( $struct );
2284
2285         print $db->{key1} . "\n"; # prints "value1"
2286
2287 This recursively imports the entire C<$struct> object into C<$db>, including
2288 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2289 keys are merged with the existing ones, replacing if they already exist.
2290 The C<import()> method can be called on any database level (not just the base
2291 level), and works with both hash and array DB types.
2292
2293
2294
2295 B<Note:> Make sure your existing structure has no circular references in it.
2296 These will cause an infinite loop when importing.
2297
2298 =head2 EXPORTING
2299
2300 Calling the C<export()> method on an existing DBM::Deep object will return
2301 a reference to a new in-memory copy of the database.  The export is done
2302 recursively, so all nested hashes/arrays are all exported to standard Perl
2303 objects.  Here is an example:
2304
2305         my $db = DBM::Deep->new( "foo.db" );
2306
2307         $db->{key1} = "value1";
2308         $db->{key2} = "value2";
2309         $db->{hash1} = {};
2310         $db->{hash1}->{subkey1} = "subvalue1";
2311         $db->{hash1}->{subkey2} = "subvalue2";
2312
2313         my $struct = $db->export();
2314
2315         print $struct->{key1} . "\n"; # prints "value1"
2316
2317 This makes a complete copy of the database in memory, and returns a reference
2318 to it.  The C<export()> method can be called on any database level (not just
2319 the base level), and works with both hash and array DB types.  Be careful of
2320 large databases -- you can store a lot more data in a DBM::Deep object than an
2321 in-memory Perl structure.
2322
2323
2324
2325 B<Note:> Make sure your database has no circular references in it.
2326 These will cause an infinite loop when exporting.
2327
2328 =head1 FILTERS
2329
2330 DBM::Deep has a number of hooks where you can specify your own Perl function
2331 to perform filtering on incoming or outgoing data.  This is a perfect
2332 way to extend the engine, and implement things like real-time compression or
2333 encryption.  Filtering applies to the base DB level, and all child hashes /
2334 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2335 constructed, or by calling the C<set_filter()> method at any time.  There are
2336 four available filter hooks, described below:
2337
2338 =over
2339
2340 =item * filter_store_key
2341
2342 This filter is called whenever a hash key is stored.  It
2343 is passed the incoming key, and expected to return a transformed key.
2344
2345 =item * filter_store_value
2346
2347 This filter is called whenever a hash key or array element is stored.  It
2348 is passed the incoming value, and expected to return a transformed value.
2349
2350 =item * filter_fetch_key
2351
2352 This filter is called whenever a hash key is fetched (i.e. via
2353 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2354 and expected to return the plain key.
2355
2356 =item * filter_fetch_value
2357
2358 This filter is called whenever a hash key or array element is fetched.
2359 It is passed the transformed value, and expected to return the plain value.
2360
2361 =back
2362
2363 Here are the two ways to setup a filter hook:
2364
2365         my $db = DBM::Deep->new(
2366                 file => "foo.db",
2367                 filter_store_value => \&my_filter_store,
2368                 filter_fetch_value => \&my_filter_fetch
2369         );
2370
2371         # or...
2372
2373         $db->set_filter( "filter_store_value", \&my_filter_store );
2374         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2375
2376 Your filter function will be called only when dealing with SCALAR keys or
2377 values.  When nested hashes and arrays are being stored/fetched, filtering
2378 is bypassed.  Filters are called as static functions, passed a single SCALAR
2379 argument, and expected to return a single SCALAR value.  If you want to
2380 remove a filter, set the function reference to C<undef>:
2381
2382         $db->set_filter( "filter_store_value", undef );
2383
2384 =head2 REAL-TIME ENCRYPTION EXAMPLE
2385
2386 Here is a working example that uses the I<Crypt::Blowfish> module to
2387 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2388 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2389 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2390
2391         use DBM::Deep;
2392         use Crypt::Blowfish;
2393         use Crypt::CBC;
2394
2395         my $cipher = Crypt::CBC->new({
2396                 'key'             => 'my secret key',
2397                 'cipher'          => 'Blowfish',
2398                 'iv'              => '$KJh#(}q',
2399                 'regenerate_key'  => 0,
2400                 'padding'         => 'space',
2401                 'prepend_iv'      => 0
2402         });
2403
2404         my $db = DBM::Deep->new(
2405                 file => "foo-encrypt.db",
2406                 filter_store_key => \&my_encrypt,
2407                 filter_store_value => \&my_encrypt,
2408                 filter_fetch_key => \&my_decrypt,
2409                 filter_fetch_value => \&my_decrypt,
2410         );
2411
2412         $db->{key1} = "value1";
2413         $db->{key2} = "value2";
2414         print "key1: " . $db->{key1} . "\n";
2415         print "key2: " . $db->{key2} . "\n";
2416
2417         undef $db;
2418         exit;
2419
2420         sub my_encrypt {
2421                 return $cipher->encrypt( $_[0] );
2422         }
2423         sub my_decrypt {
2424                 return $cipher->decrypt( $_[0] );
2425         }
2426
2427 =head2 REAL-TIME COMPRESSION EXAMPLE
2428
2429 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2430 compression / decompression of keys & values with DBM::Deep Filters.
2431 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2432 more on I<Compress::Zlib>.
2433
2434         use DBM::Deep;
2435         use Compress::Zlib;
2436
2437         my $db = DBM::Deep->new(
2438                 file => "foo-compress.db",
2439                 filter_store_key => \&my_compress,
2440                 filter_store_value => \&my_compress,
2441                 filter_fetch_key => \&my_decompress,
2442                 filter_fetch_value => \&my_decompress,
2443         );
2444
2445         $db->{key1} = "value1";
2446         $db->{key2} = "value2";
2447         print "key1: " . $db->{key1} . "\n";
2448         print "key2: " . $db->{key2} . "\n";
2449
2450         undef $db;
2451         exit;
2452
2453         sub my_compress {
2454                 return Compress::Zlib::memGzip( $_[0] ) ;
2455         }
2456         sub my_decompress {
2457                 return Compress::Zlib::memGunzip( $_[0] ) ;
2458         }
2459
2460 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2461 actually numerical index numbers, and are not filtered.
2462
2463 =head1 ERROR HANDLING
2464
2465 Most DBM::Deep methods return a true value for success, and call die() on
2466 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2467 actual error message is stored in an internal scalar, which can be fetched by
2468 calling the C<error()> method.
2469
2470         my $db = DBM::Deep->new( "foo.db" ); # create hash
2471         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2472
2473         print $db->error(); # prints error message
2474
2475 You can then call C<clear_error()> to clear the current error state.
2476
2477         $db->clear_error();
2478
2479 If you set the C<debug> option to true when creating your DBM::Deep object,
2480 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2481 for debugging purposes.
2482
2483 =head1 LARGEFILE SUPPORT
2484
2485 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2486 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2487 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2488 by calling the static C<set_pack()> method before you do anything else.
2489
2490         DBM::Deep::set_pack(8, 'Q');
2491
2492 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2493 instead of 32-bit longs.  After setting these values your DB files have a
2494 theoretical maximum size of 16 XB (exabytes).
2495
2496
2497
2498 B<Note:> Changing these values will B<NOT> work for existing database files.
2499 Only change this for new files, and make sure it stays set consistently
2500 throughout the file's life.  If you do set these values, you can no longer
2501 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2502 back to 32-bit mode.
2503
2504
2505
2506 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2507 only a 32-bit Perl.  However, I have received user reports that this does
2508 indeed work!
2509
2510 =head1 LOW-LEVEL ACCESS
2511
2512 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2513 you can call the C<fh()> method, which returns the handle:
2514
2515         my $fh = $db->fh();
2516
2517 This method can be called on the root level of the datbase, or any child
2518 hashes or arrays.  All levels share a I<root> structure, which contains things
2519 like the FileHandle, a reference counter, and all your options you specified
2520 when you created the object.  You can get access to this root structure by
2521 calling the C<root()> method.
2522
2523         my $root = $db->root();
2524
2525 This is useful for changing options after the object has already been created,
2526 such as enabling/disabling locking, volatile or debug modes.  You can also
2527 store your own temporary user data in this structure (be wary of name
2528 collision), which is then accessible from any child hash or array.
2529
2530 =head1 CUSTOM DIGEST ALGORITHM
2531
2532 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2533 keys.  However you can override this, and use another algorithm (such as SHA-256)
2534 or even write your own.  But please note that DBM::Deep currently expects zero
2535 collisions, so your algorithm has to be I<perfect>, so to speak.
2536 Collision detection may be introduced in a later version.
2537
2538
2539
2540 You can specify a custom digest algorithm by calling the static C<set_digest()>
2541 function, passing a reference to a subroutine, and the length of the algorithm's
2542 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2543 objects.  Here is a working example that uses a 256-bit hash from the
2544 I<Digest::SHA256> module.  Please see
2545 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2546
2547         use DBM::Deep;
2548         use Digest::SHA256;
2549
2550         my $context = Digest::SHA256::new(256);
2551
2552         DBM::Deep::set_digest( \&my_digest, 32 );
2553
2554         my $db = DBM::Deep->new( "foo-sha.db" );
2555
2556         $db->{key1} = "value1";
2557         $db->{key2} = "value2";
2558         print "key1: " . $db->{key1} . "\n";
2559         print "key2: " . $db->{key2} . "\n";
2560
2561         undef $db;
2562         exit;
2563
2564         sub my_digest {
2565                 return substr( $context->hash($_[0]), 0, 32 );
2566         }
2567
2568 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2569 of bytes you specify in the C<set_digest()> function (in this case 32).
2570
2571 =head1 CIRCULAR REFERENCES
2572
2573 DBM::Deep has B<experimental> support for circular references.  Meaning you
2574 can have a nested hash key or array element that points to a parent object.
2575 This relationship is stored in the DB file, and is preserved between sessions.
2576 Here is an example:
2577
2578         my $db = DBM::Deep->new( "foo.db" );
2579
2580         $db->{foo} = "bar";
2581         $db->{circle} = $db; # ref to self
2582
2583         print $db->{foo} . "\n"; # prints "foo"
2584         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2585
2586 One catch is, passing the object to a function that recursively walks the
2587 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2588 C<export()> methods) will result in an infinite loop.  The other catch is,
2589 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2590 or C<next_key()> methods), you will get the I<target object's key>, not the
2591 ref's key.  This gets even more interesting with the above example, where
2592 the I<circle> key points to the base DB object, which technically doesn't
2593 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2594 special case.
2595
2596 =head1 CAVEATS / ISSUES / BUGS
2597
2598 This section describes all the known issues with DBM::Deep.  It you have found
2599 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2600
2601 =head2 UNUSED SPACE RECOVERY
2602
2603 One major caveat with DBM::Deep is that space occupied by existing keys and
2604 values is not recovered when they are deleted.  Meaning if you keep deleting
2605 and adding new keys, your file will continuously grow.  I am working on this,
2606 but in the meantime you can call the built-in C<optimize()> method from time to
2607 time (perhaps in a crontab or something) to recover all your unused space.
2608
2609         $db->optimize(); # returns true on success
2610
2611 This rebuilds the ENTIRE database into a new file, then moves it on top of
2612 the original.  The new file will have no unused space, thus it will take up as
2613 little disk space as possible.  Please note that this operation can take
2614 a long time for large files, and you need enough disk space to temporarily hold
2615 2 copies of your DB file.  The temporary file is created in the same directory
2616 as the original, named with a ".tmp" extension, and is deleted when the
2617 operation completes.  Oh, and if locking is enabled, the DB is automatically
2618 locked for the entire duration of the copy.
2619
2620
2621
2622 B<WARNING:> Only call optimize() on the top-level node of the database, and
2623 make sure there are no child references lying around.  DBM::Deep keeps a reference
2624 counter, and if it is greater than 1, optimize() will abort and return undef.
2625
2626 =head2 AUTOVIVIFICATION
2627
2628 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2629 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2630 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2631 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2632 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2633 this does not work:
2634
2635         $db->{foo}->{bar} = "hello";
2636
2637 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2638 being an empty hash.  Try this instead, which works fine:
2639
2640         $db->{foo} = { bar => "hello" };
2641
2642 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2643 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2644 Probably a bug in Perl.
2645
2646 =head2 FILE CORRUPTION
2647
2648 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2649 for a 32-bit signature when opened, but other corruption in files can cause
2650 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2651 stuck in an infinite loop depending on the level of corruption.  File write
2652 operations are not checked for failure (for speed), so if you happen to run
2653 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2654 be addressed in a later version of DBM::Deep.
2655
2656 =head2 DB OVER NFS
2657
2658 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2659 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2660 about setting up your NFS server with a locking daemon, then using lockf() to
2661 lock your files, but your milage may vary there as well.  From what I
2662 understand, there is no real way to do it.  However, if you need access to the
2663 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2664 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2665
2666 =head2 COPYING OBJECTS
2667
2668 Beware of copying tied objects in Perl.  Very strange things can happen.
2669 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2670 returns a new, blessed, tied hash or array to the same level in the DB.
2671
2672         my $copy = $db->clone();
2673
2674 =head2 LARGE ARRAYS
2675
2676 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2677 These functions cause every element in the array to move, which can be murder
2678 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2679 a different location.  This may be addressed in a later version.
2680
2681 =head1 PERFORMANCE
2682
2683 This section discusses DBM::Deep's speed and memory usage.
2684
2685 =head2 SPEED
2686
2687 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2688 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2689 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2690 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2691 with huge databases.  Here is some test data:
2692
2693         Adding 1,000,000 keys to new DB file...
2694
2695         At 100 keys, avg. speed is 2,703 keys/sec
2696         At 200 keys, avg. speed is 2,642 keys/sec
2697         At 300 keys, avg. speed is 2,598 keys/sec
2698         At 400 keys, avg. speed is 2,578 keys/sec
2699         At 500 keys, avg. speed is 2,722 keys/sec
2700         At 600 keys, avg. speed is 2,628 keys/sec
2701         At 700 keys, avg. speed is 2,700 keys/sec
2702         At 800 keys, avg. speed is 2,607 keys/sec
2703         At 900 keys, avg. speed is 2,190 keys/sec
2704         At 1,000 keys, avg. speed is 2,570 keys/sec
2705         At 2,000 keys, avg. speed is 2,417 keys/sec
2706         At 3,000 keys, avg. speed is 1,982 keys/sec
2707         At 4,000 keys, avg. speed is 1,568 keys/sec
2708         At 5,000 keys, avg. speed is 1,533 keys/sec
2709         At 6,000 keys, avg. speed is 1,787 keys/sec
2710         At 7,000 keys, avg. speed is 1,977 keys/sec
2711         At 8,000 keys, avg. speed is 2,028 keys/sec
2712         At 9,000 keys, avg. speed is 2,077 keys/sec
2713         At 10,000 keys, avg. speed is 2,031 keys/sec
2714         At 20,000 keys, avg. speed is 1,970 keys/sec
2715         At 30,000 keys, avg. speed is 2,050 keys/sec
2716         At 40,000 keys, avg. speed is 2,073 keys/sec
2717         At 50,000 keys, avg. speed is 1,973 keys/sec
2718         At 60,000 keys, avg. speed is 1,914 keys/sec
2719         At 70,000 keys, avg. speed is 2,091 keys/sec
2720         At 80,000 keys, avg. speed is 2,103 keys/sec
2721         At 90,000 keys, avg. speed is 1,886 keys/sec
2722         At 100,000 keys, avg. speed is 1,970 keys/sec
2723         At 200,000 keys, avg. speed is 2,053 keys/sec
2724         At 300,000 keys, avg. speed is 1,697 keys/sec
2725         At 400,000 keys, avg. speed is 1,838 keys/sec
2726         At 500,000 keys, avg. speed is 1,941 keys/sec
2727         At 600,000 keys, avg. speed is 1,930 keys/sec
2728         At 700,000 keys, avg. speed is 1,735 keys/sec
2729         At 800,000 keys, avg. speed is 1,795 keys/sec
2730         At 900,000 keys, avg. speed is 1,221 keys/sec
2731         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2732
2733 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2734 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2735 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2736 Run time was 12 min 3 sec.
2737
2738 =head2 MEMORY USAGE
2739
2740 One of the great things about DBM::Deep is that it uses very little memory.
2741 Even with huge databases (1,000,000+ keys) you will not see much increased
2742 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2743 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2744 database handle:
2745
2746           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2747         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2748
2749 Basically the process is taking 2,716K of memory.  And here is the same
2750 process after storing and fetching 1,000,000 keys:
2751
2752           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2753         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2754
2755 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2756 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2757
2758 =head1 DB FILE FORMAT
2759
2760 In case you were interested in the underlying DB file format, it is documented
2761 here in this section.  You don't need to know this to use the module, it's just
2762 included for reference.
2763
2764 =head2 SIGNATURE
2765
2766 DBM::Deep files always start with a 32-bit signature to identify the file type.
2767 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2768 checked when the file is opened.
2769
2770 =head2 TAG
2771
2772 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2773 has a standard header containing the type of data, the length of data, and then
2774 the data itself.  The type is a single character (1 byte), the length is a
2775 32-bit unsigned long in network byte order, and the data is, well, the data.
2776 Here is how it unfolds:
2777
2778 =head2 MASTER INDEX
2779
2780 Immediately after the 32-bit file signature is the I<Master Index> record.
2781 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2782 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2783 depending on how the DBM::Deep object was constructed.
2784
2785
2786
2787 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2788 number).  The first 8-bit char of the MD5 signature is the offset into the
2789 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2790 index element is a file offset of the next tag for the key/element in question,
2791 which is usually a I<Bucket List> tag (see below).
2792
2793
2794
2795 The next tag I<could> be another index, depending on how many keys/elements
2796 exist.  See L<RE-INDEXING> below for details.
2797
2798 =head2 BUCKET LIST
2799
2800 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2801 file offsets to where the actual data is stored.  It starts with a standard
2802 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2803 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2804 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2805 When the list fills up, a I<Re-Index> operation is performed (See
2806 L<RE-INDEXING> below).
2807
2808 =head2 BUCKET
2809
2810 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2811 index/value pair (in array mode).  It starts with a standard tag header with
2812 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2813 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2814 header.  The size reported in the tag header is only for the value, but then,
2815 just after the value is another size (32-bit unsigned long) and then the plain
2816 key itself.  Since the value is likely to be fetched more often than the plain
2817 key, I figured it would be I<slightly> faster to store the value first.
2818
2819
2820
2821 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2822 record for the nested structure, where the process begins all over again.
2823
2824 =head2 RE-INDEXING
2825
2826 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2827 exhausted.  Then, when another key/element comes in, the list is converted to a
2828 new index record.  However, this index will look at the next char in the MD5
2829 hash, and arrange new Bucket List pointers accordingly.  This process is called
2830 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2831 17 (16 + new one) keys/elements are removed from the old Bucket List and
2832 inserted into the new index.  Several new Bucket Lists are created in the
2833 process, as a new MD5 char from the key is being examined (it is unlikely that
2834 the keys will all share the same next char of their MD5s).
2835
2836
2837
2838 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2839 when the Bucket Lists will turn into indexes, but the first round tends to
2840 happen right around 4,000 keys.  You will see a I<slight> decrease in
2841 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2842 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2843 right around 900,000 keys.  This process can continue nearly indefinitely --
2844 right up until the point the I<MD5> signatures start colliding with each other,
2845 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2846 getting struck by lightning while you are walking to cash in your tickets.
2847 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2848 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2849 this is 340 unodecillion, but don't quote me).
2850
2851 =head2 STORING
2852
2853 When a new key/element is stored, the key (or index number) is first ran through
2854 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2855 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2856 for the first char of the signature (in this case I<b>).  If it does not exist,
2857 a new I<Bucket List> is created for our key (and the next 15 future keys that
2858 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2859 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2860 this point, unless we are replacing an existing I<Bucket>), where the actual
2861 data will be stored.
2862
2863 =head2 FETCHING
2864
2865 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2866 (or index number), then walking along the indexes.  If there are enough
2867 keys/elements in this DB level, there might be nested indexes, each linked to
2868 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2869 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2870 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2871 plain key are stored.
2872
2873
2874
2875 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2876 methods.  In this process the indexes are walked systematically, and each key
2877 fetched in increasing MD5 order (which is why it appears random).   Once the
2878 I<Bucket> is found, the value is skipped the plain key returned instead.
2879 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2880 alphabetically sorted.  This only happens on an index-level -- as soon as the
2881 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2882 so it's pretty much undefined how the keys will come out -- just like Perl's
2883 built-in hashes.
2884
2885 =head1 CODE COVERAGE
2886
2887 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2888 module's test suite.
2889
2890   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2891   File                           stmt   bran   cond    sub    pod   time  total
2892   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2893   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2894   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2895   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2896
2897 =head1 AUTHOR
2898
2899 Joseph Huckaby, L<jhuckaby@cpan.org>
2900
2901 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2902
2903 =head1 SEE ALSO
2904
2905 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2906 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2907
2908 =head1 LICENSE
2909
2910 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2911 This is free software, you may use it and distribute it under the
2912 same terms as Perl itself.
2913
2914 =cut