lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 use 5.006_000;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = q(1.0004);
   9
  10 use Fcntl qw( :flock );
  11
  12 use Clone ();
  13 use Digest::MD5 ();
  14 use FileHandle::Fmode ();
  15 use Scalar::Util ();
  16
  17 use DBM::Deep::Engine;
  18 use DBM::Deep::File;
  19
  20 ##
  21 # Setup constants for users to pass to new()
  22 ##
  23 sub TYPE_HASH   () { DBM::Deep::Engine->SIG_HASH  }
  24 sub TYPE_ARRAY  () { DBM::Deep::Engine->SIG_ARRAY }
  25
  26 # This is used in all the children of this class in their TIE<type> methods.
  27 sub _get_args {
  28     my $proto = shift;
  29
  30     my $args;
  31     if (scalar(@_) > 1) {
  32         if ( @_ % 2 ) {
  33             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
  34         }
  35         $args = {@_};
  36     }
  37     elsif ( ref $_[0] ) {
  38         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
  39             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
  40         }
  41         $args = $_[0];
  42     }
  43     else {
  44         $args = { file => shift };
  45     }
  46
  47     return $args;
  48 }
  49
  50 sub new {
  51     ##
  52     # Class constructor method for Perl OO interface.
  53     # Calls tie() and returns blessed reference to tied hash or array,
  54     # providing a hybrid OO/tie interface.
  55     ##
  56     my $class = shift;
  57     my $args = $class->_get_args( @_ );
  58
  59     ##
  60     # Check if we want a tied hash or array.
  61     ##
  62     my $self;
  63     if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
  64         $class = 'DBM::Deep::Array';
  65         require DBM::Deep::Array;
  66         tie @$self, $class, %$args;
  67     }
  68     else {
  69         $class = 'DBM::Deep::Hash';
  70         require DBM::Deep::Hash;
  71         tie %$self, $class, %$args;
  72     }
  73
  74     return bless $self, $class;
  75 }
  76
  77 # This initializer is called from the various TIE* methods. new() calls tie(),
  78 # which allows for a single point of entry.
  79 sub _init {
  80     my $class = shift;
  81     my ($args) = @_;
  82
  83     $args->{storage} = DBM::Deep::File->new( $args )
  84         unless exists $args->{storage};
  85
  86     # locking implicitly enables autoflush
  87     if ($args->{locking}) { $args->{autoflush} = 1; }
  88
  89     # These are the defaults to be optionally overridden below
  90     my $self = bless {
  91         type        => TYPE_HASH,
  92         base_offset => undef,
  93         staleness   => undef,
  94
  95         storage     => undef,
  96         engine      => undef,
  97     }, $class;
  98
  99     $args->{engine} = DBM::Deep::Engine->new( { %{$args}, obj => $self } )
 100         unless exists $args->{engine};
 101
 102     # Grab the parameters we want to use
 103     foreach my $param ( keys %$self ) {
 104         next unless exists $args->{$param};
 105         $self->{$param} = $args->{$param};
 106     }
 107
 108     eval {
 109       local $SIG{'__DIE__'};
 110
 111       $self->lock;
 112       $self->_engine->setup_fh( $self );
 113       $self->_storage->set_inode;
 114       $self->unlock;
 115     }; if ( $@ ) {
 116       my $e = $@;
 117       eval { local $SIG{'__DIE__'}; $self->unlock; };
 118       die $e;
 119     }
 120
 121     return $self;
 122 }
 123
 124 sub TIEHASH {
 125     shift;
 126     require DBM::Deep::Hash;
 127     return DBM::Deep::Hash->TIEHASH( @_ );
 128 }
 129
 130 sub TIEARRAY {
 131     shift;
 132     require DBM::Deep::Array;
 133     return DBM::Deep::Array->TIEARRAY( @_ );
 134 }
 135
 136 sub lock {
 137     my $self = shift->_get_self;
 138     return $self->_storage->lock( $self, @_ );
 139 }
 140
 141 sub unlock {
 142     my $self = shift->_get_self;
 143     return $self->_storage->unlock( $self, @_ );
 144 }
 145
 146 sub _copy_value {
 147     my $self = shift->_get_self;
 148     my ($spot, $value) = @_;
 149
 150     if ( !ref $value ) {
 151         ${$spot} = $value;
 152     }
 153     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 154         ${$spot} = $value->_repr;
 155         $value->_copy_node( ${$spot} );
 156     }
 157     else {
 158         my $r = Scalar::Util::reftype( $value );
 159         my $c = Scalar::Util::blessed( $value );
 160         if ( $r eq 'ARRAY' ) {
 161             ${$spot} = [ @{$value} ];
 162         }
 163         else {
 164             ${$spot} = { %{$value} };
 165         }
 166         ${$spot} = bless ${$spot}, $c
 167             if defined $c;
 168     }
 169
 170     return 1;
 171 }
 172
 173 #sub _copy_node {
 174 #    die "Must be implemented in a child class\n";
 175 #}
 176 #
 177 #sub _repr {
 178 #    die "Must be implemented in a child class\n";
 179 #}
 180
 181 sub export {
 182     ##
 183     # Recursively export into standard Perl hashes and arrays.
 184     ##
 185     my $self = shift->_get_self;
 186
 187     my $temp = $self->_repr;
 188
 189     $self->lock();
 190     $self->_copy_node( $temp );
 191     $self->unlock();
 192
 193     my $classname = $self->_engine->get_classname( $self );
 194     if ( defined $classname ) {
 195       bless $temp, $classname;
 196     }
 197
 198     return $temp;
 199 }
 200
 201 sub import {
 202     ##
 203     # Recursively import Perl hash/array structure
 204     ##
 205     if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 206
 207     my $self = shift->_get_self;
 208     my ($struct) = @_;
 209
 210     # struct is not a reference, so just import based on our type
 211     if (!ref($struct)) {
 212         $struct = $self->_repr( @_ );
 213     }
 214
 215     #XXX This isn't the best solution. Better would be to use Data::Walker,
 216     #XXX but that's a lot more thinking than I want to do right now.
 217     eval {
 218         local $SIG{'__DIE__'};
 219         $self->_import( Clone::clone( $struct ) );
 220     }; if ( my $e = $@ ) {
 221         die $e;
 222     }
 223
 224     return 1;
 225 }
 226
 227 #XXX Need to keep track of who has a fh to this file in order to
 228 #XXX close them all prior to optimize on Win32/cygwin
 229 sub optimize {
 230     ##
 231     # Rebuild entire database into new file, then move
 232     # it back on top of original.
 233     ##
 234     my $self = shift->_get_self;
 235
 236 #XXX Need to create a new test for this
 237 #    if ($self->_storage->{links} > 1) {
 238 #        $self->_throw_error("Cannot optimize: reference count is greater than 1");
 239 #    }
 240
 241     #XXX Do we have to lock the tempfile?
 242
 243     my $db_temp = DBM::Deep->new(
 244         file => $self->_storage->{file} . '.tmp',
 245         type => $self->_type,
 246
 247         # Bring over all the parameters that we need to bring over
 248         ( map { $_ => $self->_engine->$_ } qw(
 249             byte_size max_buckets data_sector_size num_txns
 250         )),
 251     );
 252
 253     $self->lock();
 254     #DBM::Deep::Engine::Sector::Reference->_clear_cache;
 255     $self->_copy_node( $db_temp );
 256     undef $db_temp;
 257
 258     ##
 259     # Attempt to copy user, group and permissions over to new file
 260     ##
 261     my @stats = stat($self->_fh);
 262     my $perms = $stats[2] & 07777;
 263     my $uid = $stats[4];
 264     my $gid = $stats[5];
 265     chown( $uid, $gid, $self->_storage->{file} . '.tmp' );
 266     chmod( $perms, $self->_storage->{file} . '.tmp' );
 267
 268     # q.v. perlport for more information on this variable
 269     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
 270         ##
 271         # Potential race condition when optmizing on Win32 with locking.
 272         # The Windows filesystem requires that the filehandle be closed
 273         # before it is overwritten with rename().  This could be redone
 274         # with a soft copy.
 275         ##
 276         $self->unlock();
 277         $self->_storage->close;
 278     }
 279
 280     if (!rename $self->_storage->{file} . '.tmp', $self->_storage->{file}) {
 281         unlink $self->_storage->{file} . '.tmp';
 282         $self->unlock();
 283         $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
 284     }
 285
 286     $self->unlock();
 287     $self->_storage->close;
 288
 289     $self->_storage->open;
 290     $self->lock();
 291     $self->_engine->setup_fh( $self );
 292     $self->unlock();
 293
 294     return 1;
 295 }
 296
 297 sub clone {
 298     ##
 299     # Make copy of object and return
 300     ##
 301     my $self = shift->_get_self;
 302
 303     return DBM::Deep->new(
 304         type        => $self->_type,
 305         base_offset => $self->_base_offset,
 306         staleness   => $self->_staleness,
 307         storage     => $self->_storage,
 308         engine      => $self->_engine,
 309     );
 310 }
 311
 312 #XXX Migrate this to the engine, where it really belongs and go through some
 313 # API - stop poking in the innards of someone else..
 314 {
 315     my %is_legal_filter = map {
 316         $_ => ~~1,
 317     } qw(
 318         store_key store_value
 319         fetch_key fetch_value
 320     );
 321
 322     sub set_filter {
 323         my $self = shift->_get_self;
 324         my $type = lc shift;
 325         my $func = shift;
 326
 327         if ( $is_legal_filter{$type} ) {
 328             $self->_storage->{"filter_$type"} = $func;
 329             return 1;
 330         }
 331
 332         return;
 333     }
 334
 335     sub filter_store_key   { $_[0]->set_filter( store_key   => $_[1] ); }
 336     sub filter_store_value { $_[0]->set_filter( store_value => $_[1] ); }
 337     sub filter_fetch_key   { $_[0]->set_filter( fetch_key   => $_[1] ); }
 338     sub filter_fetch_value { $_[0]->set_filter( fetch_value => $_[1] ); }
 339 }
 340
 341 sub begin_work {
 342     my $self = shift->_get_self;
 343     return $self->_engine->begin_work( $self, @_ );
 344 }
 345
 346 sub rollback {
 347     my $self = shift->_get_self;
 348     return $self->_engine->rollback( $self, @_ );
 349 }
 350
 351 sub commit {
 352     my $self = shift->_get_self;
 353     return $self->_engine->commit( $self, @_ );
 354 }
 355
 356 ##
 357 # Accessor methods
 358 ##
 359
 360 sub _engine {
 361     my $self = $_[0]->_get_self;
 362     return $self->{engine};
 363 }
 364
 365 sub _storage {
 366     my $self = $_[0]->_get_self;
 367     return $self->{storage};
 368 }
 369
 370 sub _type {
 371     my $self = $_[0]->_get_self;
 372     return $self->{type};
 373 }
 374
 375 sub _base_offset {
 376     my $self = $_[0]->_get_self;
 377     return $self->{base_offset};
 378 }
 379
 380 sub _staleness {
 381     my $self = $_[0]->_get_self;
 382     return $self->{staleness};
 383 }
 384
 385 sub _fh {
 386     my $self = $_[0]->_get_self;
 387     return $self->_storage->{fh};
 388 }
 389
 390 ##
 391 # Utility methods
 392 ##
 393
 394 sub _throw_error {
 395     my $n = 0;
 396     while( 1 ) {
 397         my @caller = caller( ++$n );
 398         next if $caller[0] =~ m/^DBM::Deep/;
 399
 400         die "DBM::Deep: $_[1] at $0 line $caller[2]\n";
 401     }
 402 }
 403
 404 sub STORE {
 405     ##
 406     # Store single hash key/value or array element in database.
 407     ##
 408     my $self = shift->_get_self;
 409     my ($key, $value) = @_;
 410
 411     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 412         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 413     }
 414
 415     ##
 416     # Request exclusive lock for writing
 417     ##
 418     $self->lock( LOCK_EX );
 419
 420     # User may be storing a complex value, in which case we do not want it run
 421     # through the filtering system.
 422     if ( !ref($value) && $self->_storage->{filter_store_value} ) {
 423         $value = $self->_storage->{filter_store_value}->( $value );
 424     }
 425
 426     $self->_engine->write_value( $self, $key, $value);
 427
 428     $self->unlock();
 429
 430     return 1;
 431 }
 432
 433 sub FETCH {
 434     ##
 435     # Fetch single value or element given plain key or array index
 436     ##
 437     my $self = shift->_get_self;
 438     my ($key) = @_;
 439
 440     ##
 441     # Request shared lock for reading
 442     ##
 443     $self->lock( LOCK_SH );
 444
 445     my $result = $self->_engine->read_value( $self, $key);
 446
 447     $self->unlock();
 448
 449     # Filters only apply to scalar values, so the ref check is making
 450     # sure the fetched bucket is a scalar, not a child hash or array.
 451     return ($result && !ref($result) && $self->_storage->{filter_fetch_value})
 452         ? $self->_storage->{filter_fetch_value}->($result)
 453         : $result;
 454 }
 455
 456 sub DELETE {
 457     ##
 458     # Delete single key/value pair or element given plain key or array index
 459     ##
 460     my $self = shift->_get_self;
 461     my ($key) = @_;
 462
 463     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 464         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 465     }
 466
 467     ##
 468     # Request exclusive lock for writing
 469     ##
 470     $self->lock( LOCK_EX );
 471
 472     ##
 473     # Delete bucket
 474     ##
 475     my $value = $self->_engine->delete_key( $self, $key);
 476
 477     if (defined $value && !ref($value) && $self->_storage->{filter_fetch_value}) {
 478         $value = $self->_storage->{filter_fetch_value}->($value);
 479     }
 480
 481     $self->unlock();
 482
 483     return $value;
 484 }
 485
 486 sub EXISTS {
 487     ##
 488     # Check if a single key or element exists given plain key or array index
 489     ##
 490     my $self = shift->_get_self;
 491     my ($key) = @_;
 492
 493     ##
 494     # Request shared lock for reading
 495     ##
 496     $self->lock( LOCK_SH );
 497
 498     my $result = $self->_engine->key_exists( $self, $key );
 499
 500     $self->unlock();
 501
 502     return $result;
 503 }
 504
 505 sub CLEAR {
 506     ##
 507     # Clear all keys from hash, or all elements from array.
 508     ##
 509     my $self = shift->_get_self;
 510
 511     if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
 512         $self->_throw_error( 'Cannot write to a readonly filehandle' );
 513     }
 514
 515     ##
 516     # Request exclusive lock for writing
 517     ##
 518     $self->lock( LOCK_EX );
 519
 520     #XXX Rewrite this dreck to do it in the engine as a tight loop vs.
 521     # iterating over keys - such a WASTE - is this required for transactional
 522     # clearning?! Surely that can be detected in the engine ...
 523     if ( $self->_type eq TYPE_HASH ) {
 524         my $key = $self->first_key;
 525         while ( $key ) {
 526             # Retrieve the key before deleting because we depend on next_key
 527             my $next_key = $self->next_key( $key );
 528             $self->_engine->delete_key( $self, $key, $key );
 529             $key = $next_key;
 530         }
 531     }
 532     else {
 533         my $size = $self->FETCHSIZE;
 534         for my $key ( 0 .. $size - 1 ) {
 535             $self->_engine->delete_key( $self, $key, $key );
 536         }
 537         $self->STORESIZE( 0 );
 538     }
 539
 540     $self->unlock();
 541
 542     return 1;
 543 }
 544
 545 ##
 546 # Public method aliases
 547 ##
 548 sub put { (shift)->STORE( @_ ) }
 549 sub store { (shift)->STORE( @_ ) }
 550 sub get { (shift)->FETCH( @_ ) }
 551 sub fetch { (shift)->FETCH( @_ ) }
 552 sub delete { (shift)->DELETE( @_ ) }
 553 sub exists { (shift)->EXISTS( @_ ) }
 554 sub clear { (shift)->CLEAR( @_ ) }
 555
 556 sub _dump_file {shift->_get_self->_engine->_dump_file;}
 557
 558 1;
 559 __END__