lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.98);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->_fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     eval {
 213         local $SIG{'__DIE__'};
 214         # Theoretically, adding O_BINARY should remove the need for the binmode
 215         # Of course, testing it is going to be ... interesting.
 216         my $flags = O_RDWR | O_CREAT | O_BINARY;
 217
 218         my $fh;
 219         sysopen( $fh, $self->_root->{file}, $flags )
 220             or $fh = undef;
 221         $self->_root->{fh} = $fh;
 222     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 223         if (! defined($self->_fh)) {
 224                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 225         }
 226
 227     my $fh = $self->_fh;
 228
 229     #XXX Can we remove this by using the right sysopen() flags?
 230     # Maybe ... q.v. above
 231     binmode $fh; # for win32
 232
 233     if ($self->_root->{autoflush}) {
 234         my $old = select $fh;
 235         $|=1;
 236         select $old;
 237     }
 238
 239     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 249         print( $fh SIG_FILE);
 250         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|; $| = 1; $| = $old_af;
 258         select $old_fh;
 259
 260         my @stats = stat($fh);
 261         $self->_root->{inode} = $stats[1];
 262         $self->_root->{end} = $stats[7];
 263
 264         return 1;
 265     }
 266
 267     ##
 268     # Check signature was valid
 269     ##
 270     unless ($signature eq SIG_FILE) {
 271         $self->_close();
 272         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 273     }
 274
 275         my @stats = stat($fh);
 276         $self->_root->{inode} = $stats[1];
 277     $self->_root->{end} = $stats[7];
 278
 279     ##
 280     # Get our type from master index signature
 281     ##
 282     my $tag = $self->_load_tag($self->_base_offset);
 283
 284 #XXX We probably also want to store the hash algorithm name and not assume anything
 285 #XXX The cool thing would be to allow a different hashing algorithm at every level
 286
 287     if (!$tag) {
 288         return $self->_throw_error("Corrupted file, no master index record");
 289     }
 290     if ($self->{type} ne $tag->{signature}) {
 291         return $self->_throw_error("File type mismatch");
 292     }
 293
 294     return 1;
 295 }
 296
 297 sub _close {
 298         ##
 299         # Close database fh
 300         ##
 301     my $self = $_[0]->_get_self;
 302     close $self->_root->{fh} if $self->_root->{fh};
 303     $self->_root->{fh} = undef;
 304 }
 305
 306 sub _create_tag {
 307         ##
 308         # Given offset, signature and content, create tag and write to disk
 309         ##
 310         my ($self, $offset, $sig, $content) = @_;
 311         my $size = length($content);
 312
 313     my $fh = $self->_fh;
 314
 315         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 316         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 317
 318         if ($offset == $self->_root->{end}) {
 319                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 320         }
 321
 322         return {
 323                 signature => $sig,
 324                 size => $size,
 325                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 326                 content => $content
 327         };
 328 }
 329
 330 sub _load_tag {
 331         ##
 332         # Given offset, load single tag and return signature, size and data
 333         ##
 334         my $self = shift;
 335         my $offset = shift;
 336
 337     my $fh = $self->_fh;
 338
 339         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 340         if (eof $fh) { return undef; }
 341
 342     my $b;
 343     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 344     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 345
 346         my $buffer;
 347         read( $fh, $buffer, $size);
 348
 349         return {
 350                 signature => $sig,
 351                 size => $size,
 352                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 353                 content => $buffer
 354         };
 355 }
 356
 357 sub _index_lookup {
 358         ##
 359         # Given index tag, lookup single entry in index and return .
 360         ##
 361         my $self = shift;
 362         my ($tag, $index) = @_;
 363
 364         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 365         if (!$location) { return; }
 366
 367         return $self->_load_tag( $location );
 368 }
 369
 370 sub _add_bucket {
 371         ##
 372         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 373         # plain (undigested) key and value.
 374         ##
 375         my $self = shift;
 376         my ($tag, $md5, $plain_key, $value) = @_;
 377         my $keys = $tag->{content};
 378         my $location = 0;
 379         my $result = 2;
 380
 381     my $root = $self->_root;
 382
 383     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 384         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 385
 386     my $fh = $self->_fh;
 387
 388         ##
 389         # Iterate through buckets, seeing if this is a new entry or a replace.
 390         ##
 391         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 392                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 393                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 394                 if (!$subloc) {
 395                         ##
 396                         # Found empty bucket (end of list).  Populate and exit loop.
 397                         ##
 398                         $result = 2;
 399
 400             $location = $internal_ref
 401                 ? $value->_base_offset
 402                 : $root->{end};
 403
 404                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 405                         print( $fh $md5 . pack($LONG_PACK, $location) );
 406                         last;
 407                 }
 408                 elsif ($md5 eq $key) {
 409                         ##
 410                         # Found existing bucket with same key.  Replace with new value.
 411                         ##
 412                         $result = 1;
 413
 414                         if ($internal_ref) {
 415                                 $location = $value->_base_offset;
 416                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 417                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 418                         }
 419                         else {
 420                                 seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 421                                 my $size;
 422                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 423
 424                                 ##
 425                                 # If value is a hash, array, or raw value with equal or less size, we can
 426                                 # reuse the same content area of the database.  Otherwise, we have to create
 427                                 # a new content area at the EOF.
 428                                 ##
 429                                 my $actual_length;
 430                 my $r = Scalar::Util::reftype( $value ) || '';
 431                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 432                         $actual_length = $INDEX_SIZE;
 433
 434                         # if autobless is enabled, must also take into consideration
 435                         # the class name, as it is stored along with key/value.
 436                         if ( $root->{autobless} ) {
 437                                                 my $value_class = Scalar::Util::blessed($value);
 438                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 439                                                         $actual_length += length($value_class);
 440                                                 }
 441                                         } # autobless
 442                 }
 443                                 else { $actual_length = length($value); }
 444
 445                                 if ($actual_length <= $size) {
 446                                         $location = $subloc;
 447                                 }
 448                                 else {
 449                                         $location = $root->{end};
 450                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 451                                         print( $fh pack($LONG_PACK, $location) );
 452                                 }
 453                         }
 454                         last;
 455                 }
 456         } # i loop
 457
 458         ##
 459         # If this is an internal reference, return now.
 460         # No need to write value or plain key
 461         ##
 462         if ($internal_ref) {
 463         return $result;
 464     }
 465
 466         ##
 467         # If bucket didn't fit into list, split into a new index level
 468         ##
 469         if (!$location) {
 470                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 471                 print( $fh pack($LONG_PACK, $root->{end}) );
 472
 473                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 474                 my @offsets = ();
 475
 476                 $keys .= $md5 . pack($LONG_PACK, 0);
 477
 478                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 479                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 480                         if ($key) {
 481                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 482                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 483
 484                                 if ($offsets[$num]) {
 485                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 486                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 487                                         my $subkeys;
 488                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 489
 490                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 491                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 492                                                 if (!$subloc) {
 493                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 494                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 495                                                         last;
 496                                                 }
 497                                         } # k loop
 498                                 }
 499                                 else {
 500                                         $offsets[$num] = $root->{end};
 501                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 502                                         print( $fh pack($LONG_PACK, $root->{end}) );
 503
 504                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 505
 506                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 507                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 508                                 }
 509                         } # key is real
 510                 } # i loop
 511
 512                 $location ||= $root->{end};
 513         } # re-index bucket list
 514
 515         ##
 516         # Seek to content area and store signature, value and plaintext key
 517         ##
 518         if ($location) {
 519                 my $content_length;
 520                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 521
 522                 ##
 523                 # Write signature based on content type, set content length and write actual value.
 524                 ##
 525         my $r = Scalar::Util::reftype($value) || '';
 526                 if ($r eq 'HASH') {
 527                         print( $fh TYPE_HASH );
 528                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 529                         $content_length = $INDEX_SIZE;
 530                 }
 531                 elsif ($r eq 'ARRAY') {
 532                         print( $fh TYPE_ARRAY );
 533                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 534                         $content_length = $INDEX_SIZE;
 535                 }
 536                 elsif (!defined($value)) {
 537                         print( $fh SIG_NULL );
 538                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 539                         $content_length = 0;
 540                 }
 541                 else {
 542                         print( $fh SIG_DATA );
 543                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 544                         $content_length = length($value);
 545                 }
 546
 547                 ##
 548                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 549                 ##
 550                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 551
 552                 ##
 553                 # If value is blessed, preserve class name
 554                 ##
 555                 if ( $root->{autobless} ) {
 556             my $value_class = Scalar::Util::blessed($value);
 557             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 558                 ##
 559                 # Blessed ref -- will restore later
 560                 ##
 561                 print( $fh chr(1) );
 562                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 563                 $content_length += 1;
 564                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 565             }
 566             else {
 567                 print( $fh chr(0) );
 568                 $content_length += 1;
 569             }
 570         }
 571
 572                 ##
 573                 # If this is a new content area, advance EOF counter
 574                 ##
 575                 if ($location == $root->{end}) {
 576                         $root->{end} += SIG_SIZE;
 577                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 578                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 579                 }
 580
 581                 ##
 582                 # If content is a hash or array, create new child DBM::Deep object and
 583                 # pass each key or element to it.
 584                 ##
 585                 if ($r eq 'HASH') {
 586                         my $branch = DBM::Deep->new(
 587                                 type => TYPE_HASH,
 588                                 base_offset => $location,
 589                                 root => $root,
 590                         );
 591                         foreach my $key (keys %{$value}) {
 592                 $branch->STORE( $key, $value->{$key} );
 593                         }
 594                 }
 595                 elsif ($r eq 'ARRAY') {
 596                         my $branch = DBM::Deep->new(
 597                                 type => TYPE_ARRAY,
 598                                 base_offset => $location,
 599                                 root => $root,
 600                         );
 601                         my $index = 0;
 602                         foreach my $element (@{$value}) {
 603                 $branch->STORE( $index, $element );
 604                                 $index++;
 605                         }
 606                 }
 607
 608                 return $result;
 609         }
 610
 611         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 612 }
 613
 614 sub _get_bucket_value {
 615         ##
 616         # Fetch single value given tag and MD5 digested key.
 617         ##
 618         my $self = shift;
 619         my ($tag, $md5) = @_;
 620         my $keys = $tag->{content};
 621
 622     my $fh = $self->_fh;
 623
 624         ##
 625         # Iterate through buckets, looking for a key match
 626         ##
 627     BUCKET:
 628         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 629                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 630                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 631
 632                 if (!$subloc) {
 633                         ##
 634                         # Hit end of list, no match
 635                         ##
 636                         return;
 637                 }
 638
 639         if ( $md5 ne $key ) {
 640             next BUCKET;
 641         }
 642
 643         ##
 644         # Found match -- seek to offset and read signature
 645         ##
 646         my $signature;
 647         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 648         read( $fh, $signature, SIG_SIZE);
 649
 650         ##
 651         # If value is a hash or array, return new DBM::Deep object with correct offset
 652         ##
 653         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 654             my $obj = DBM::Deep->new(
 655                 type => $signature,
 656                 base_offset => $subloc,
 657                 root => $self->_root
 658             );
 659
 660             if ($self->_root->{autobless}) {
 661                 ##
 662                 # Skip over value and plain key to see if object needs
 663                 # to be re-blessed
 664                 ##
 665                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 666
 667                 my $size;
 668                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 669                 if ($size) { seek($fh, $size, SEEK_CUR); }
 670
 671                 my $bless_bit;
 672                 read( $fh, $bless_bit, 1);
 673                 if (ord($bless_bit)) {
 674                     ##
 675                     # Yes, object needs to be re-blessed
 676                     ##
 677                     my $class_name;
 678                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 679                     if ($size) { read( $fh, $class_name, $size); }
 680                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 681                 }
 682             }
 683
 684             return $obj;
 685         }
 686
 687         ##
 688         # Otherwise return actual value
 689         ##
 690         elsif ($signature eq SIG_DATA) {
 691             my $size;
 692             my $value = '';
 693             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 694             if ($size) { read( $fh, $value, $size); }
 695             return $value;
 696         }
 697
 698         ##
 699         # Key exists, but content is null
 700         ##
 701         else { return; }
 702         } # i loop
 703
 704         return;
 705 }
 706
 707 sub _delete_bucket {
 708         ##
 709         # Delete single key/value pair given tag and MD5 digested key.
 710         ##
 711         my $self = shift;
 712         my ($tag, $md5) = @_;
 713         my $keys = $tag->{content};
 714
 715     my $fh = $self->_fh;
 716
 717         ##
 718         # Iterate through buckets, looking for a key match
 719         ##
 720     BUCKET:
 721         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 722                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 723                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 724
 725                 if (!$subloc) {
 726                         ##
 727                         # Hit end of list, no match
 728                         ##
 729                         return;
 730                 }
 731
 732         if ( $md5 ne $key ) {
 733             next BUCKET;
 734         }
 735
 736         ##
 737         # Matched key -- delete bucket and return
 738         ##
 739         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 740         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 741         print( $fh chr(0) x $BUCKET_SIZE );
 742
 743         return 1;
 744         } # i loop
 745
 746         return;
 747 }
 748
 749 sub _bucket_exists {
 750         ##
 751         # Check existence of single key given tag and MD5 digested key.
 752         ##
 753         my $self = shift;
 754         my ($tag, $md5) = @_;
 755         my $keys = $tag->{content};
 756
 757         ##
 758         # Iterate through buckets, looking for a key match
 759         ##
 760     BUCKET:
 761         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 762                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 763                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 764
 765                 if (!$subloc) {
 766                         ##
 767                         # Hit end of list, no match
 768                         ##
 769                         return;
 770                 }
 771
 772         if ( $md5 ne $key ) {
 773             next BUCKET;
 774         }
 775
 776         ##
 777         # Matched key -- return true
 778         ##
 779         return 1;
 780         } # i loop
 781
 782         return;
 783 }
 784
 785 sub _find_bucket_list {
 786         ##
 787         # Locate offset for bucket list, given digested key
 788         ##
 789         my $self = shift;
 790         my $md5 = shift;
 791
 792         ##
 793         # Locate offset for bucket list using digest index system
 794         ##
 795         my $ch = 0;
 796         my $tag = $self->_load_tag($self->_base_offset);
 797         if (!$tag) { return; }
 798
 799         while ($tag->{signature} ne SIG_BLIST) {
 800                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 801                 if (!$tag) { return; }
 802                 $ch++;
 803         }
 804
 805         return $tag;
 806 }
 807
 808 sub _traverse_index {
 809         ##
 810         # Scan index and recursively step into deeper levels, looking for next key.
 811         ##
 812     my ($self, $offset, $ch, $force_return_next) = @_;
 813     $force_return_next = undef unless $force_return_next;
 814
 815         my $tag = $self->_load_tag( $offset );
 816
 817     my $fh = $self->_fh;
 818
 819         if ($tag->{signature} ne SIG_BLIST) {
 820                 my $content = $tag->{content};
 821                 my $start;
 822                 if ($self->{return_next}) { $start = 0; }
 823                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 824
 825                 for (my $index = $start; $index < 256; $index++) {
 826                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 827                         if ($subloc) {
 828                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 829                                 if (defined($result)) { return $result; }
 830                         }
 831                 } # index loop
 832
 833                 $self->{return_next} = 1;
 834         } # tag is an index
 835
 836         elsif ($tag->{signature} eq SIG_BLIST) {
 837                 my $keys = $tag->{content};
 838                 if ($force_return_next) { $self->{return_next} = 1; }
 839
 840                 ##
 841                 # Iterate through buckets, looking for a key match
 842                 ##
 843                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 844                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 845                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 846
 847                         if (!$subloc) {
 848                                 ##
 849                                 # End of bucket list -- return to outer loop
 850                                 ##
 851                                 $self->{return_next} = 1;
 852                                 last;
 853                         }
 854                         elsif ($key eq $self->{prev_md5}) {
 855                                 ##
 856                                 # Located previous key -- return next one found
 857                                 ##
 858                                 $self->{return_next} = 1;
 859                                 next;
 860                         }
 861                         elsif ($self->{return_next}) {
 862                                 ##
 863                                 # Seek to bucket location and skip over signature
 864                                 ##
 865                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 866
 867                                 ##
 868                                 # Skip over value to get to plain key
 869                                 ##
 870                                 my $size;
 871                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 872                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 873
 874                                 ##
 875                                 # Read in plain key and return as scalar
 876                                 ##
 877                                 my $plain_key;
 878                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 879                                 if ($size) { read( $fh, $plain_key, $size); }
 880
 881                                 return $plain_key;
 882                         }
 883                 } # bucket loop
 884
 885                 $self->{return_next} = 1;
 886         } # tag is a bucket list
 887
 888         return;
 889 }
 890
 891 sub _get_next_key {
 892         ##
 893         # Locate next key, given digested previous one
 894         ##
 895     my $self = $_[0]->_get_self;
 896
 897         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 898         $self->{return_next} = 0;
 899
 900         ##
 901         # If the previous key was not specifed, start at the top and
 902         # return the first one found.
 903         ##
 904         if (!$self->{prev_md5}) {
 905                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 906                 $self->{return_next} = 1;
 907         }
 908
 909         return $self->_traverse_index( $self->_base_offset, 0 );
 910 }
 911
 912 sub lock {
 913         ##
 914         # If db locking is set, flock() the db file.  If called multiple
 915         # times before unlock(), then the same number of unlocks() must
 916         # be called before the lock is released.
 917         ##
 918     my $self = $_[0]->_get_self;
 919         my $type = $_[1];
 920     $type = LOCK_EX unless defined $type;
 921
 922         if (!defined($self->_fh)) { return; }
 923
 924         if ($self->_root->{locking}) {
 925                 if (!$self->_root->{locked}) {
 926                         flock($self->_fh, $type);
 927
 928                         # refresh end counter in case file has changed size
 929                         my @stats = stat($self->_root->{file});
 930                         $self->_root->{end} = $stats[7];
 931
 932                         # double-check file inode, in case another process
 933                         # has optimize()d our file while we were waiting.
 934                         if ($stats[1] != $self->_root->{inode}) {
 935                                 $self->_open(); # re-open
 936                                 flock($self->_fh, $type); # re-lock
 937                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 938                         }
 939                 }
 940                 $self->_root->{locked}++;
 941
 942         return 1;
 943         }
 944
 945     return;
 946 }
 947
 948 sub unlock {
 949         ##
 950         # If db locking is set, unlock the db file.  See note in lock()
 951         # regarding calling lock() multiple times.
 952         ##
 953     my $self = $_[0]->_get_self;
 954
 955         if (!defined($self->_fh)) { return; }
 956
 957         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 958                 $self->_root->{locked}--;
 959                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 960
 961         return 1;
 962         }
 963
 964     return;
 965 }
 966
 967 sub _copy_value {
 968     my $self = shift->_get_self;
 969     my ($spot, $value) = @_;
 970
 971     if ( !ref $value ) {
 972         ${$spot} = $value;
 973     }
 974     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 975         my $type = $value->_type;
 976         ${$spot} = $type eq TYPE_HASH ? {} : [];
 977         $value->_copy_node( ${$spot} );
 978     }
 979     else {
 980         my $r = Scalar::Util::reftype( $value );
 981         my $c = Scalar::Util::blessed( $value );
 982         if ( $r eq 'ARRAY' ) {
 983             ${$spot} = [ @{$value} ];
 984         }
 985         else {
 986             ${$spot} = { %{$value} };
 987         }
 988         ${$spot} = bless ${$spot}, $c
 989             if defined $c;
 990     }
 991
 992     return 1;
 993 }
 994
 995 sub _copy_node {
 996         ##
 997         # Copy single level of keys or elements to new DB handle.
 998         # Recurse for nested structures
 999         ##
1000     my $self = shift->_get_self;
1001         my ($db_temp) = @_;
1002
1003         if ($self->_type eq TYPE_HASH) {
1004                 my $key = $self->first_key();
1005                 while ($key) {
1006                         my $value = $self->get($key);
1007             $self->_copy_value( \$db_temp->{$key}, $value );
1008                         $key = $self->next_key($key);
1009                 }
1010         }
1011         else {
1012                 my $length = $self->length();
1013                 for (my $index = 0; $index < $length; $index++) {
1014                         my $value = $self->get($index);
1015             $self->_copy_value( \$db_temp->[$index], $value );
1016                 }
1017         }
1018
1019     return 1;
1020 }
1021
1022 sub export {
1023         ##
1024         # Recursively export into standard Perl hashes and arrays.
1025         ##
1026     my $self = $_[0]->_get_self;
1027
1028         my $temp;
1029         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1030         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1031
1032         $self->lock();
1033         $self->_copy_node( $temp );
1034         $self->unlock();
1035
1036         return $temp;
1037 }
1038
1039 sub import {
1040         ##
1041         # Recursively import Perl hash/array structure
1042         ##
1043     #XXX This use of ref() seems to be ok
1044         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1045
1046     my $self = $_[0]->_get_self;
1047         my $struct = $_[1];
1048
1049     #XXX This use of ref() seems to be ok
1050         if (!ref($struct)) {
1051                 ##
1052                 # struct is not a reference, so just import based on our type
1053                 ##
1054                 shift @_;
1055
1056                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1057                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1058         }
1059
1060     my $r = Scalar::Util::reftype($struct) || '';
1061         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1062                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1063         }
1064         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1065                 $self->push( @$struct );
1066         }
1067         else {
1068                 return $self->_throw_error("Cannot import: type mismatch");
1069         }
1070
1071         return 1;
1072 }
1073
1074 sub optimize {
1075         ##
1076         # Rebuild entire database into new file, then move
1077         # it back on top of original.
1078         ##
1079     my $self = $_[0]->_get_self;
1080
1081 #XXX Need to create a new test for this
1082 #       if ($self->_root->{links} > 1) {
1083 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1084 #       }
1085
1086         my $db_temp = DBM::Deep->new(
1087                 file => $self->_root->{file} . '.tmp',
1088                 type => $self->_type
1089         );
1090         if (!$db_temp) {
1091                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1092         }
1093
1094         $self->lock();
1095         $self->_copy_node( $db_temp );
1096         undef $db_temp;
1097
1098         ##
1099         # Attempt to copy user, group and permissions over to new file
1100         ##
1101         my @stats = stat($self->_fh);
1102         my $perms = $stats[2] & 07777;
1103         my $uid = $stats[4];
1104         my $gid = $stats[5];
1105         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1106         chmod( $perms, $self->_root->{file} . '.tmp' );
1107
1108     # q.v. perlport for more information on this variable
1109     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1110                 ##
1111                 # Potential race condition when optmizing on Win32 with locking.
1112                 # The Windows filesystem requires that the filehandle be closed
1113                 # before it is overwritten with rename().  This could be redone
1114                 # with a soft copy.
1115                 ##
1116                 $self->unlock();
1117                 $self->_close();
1118         }
1119
1120         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1121                 unlink $self->_root->{file} . '.tmp';
1122                 $self->unlock();
1123                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1124         }
1125
1126         $self->unlock();
1127         $self->_close();
1128         $self->_open();
1129
1130         return 1;
1131 }
1132
1133 sub clone {
1134         ##
1135         # Make copy of object and return
1136         ##
1137     my $self = $_[0]->_get_self;
1138
1139         return DBM::Deep->new(
1140                 type => $self->_type,
1141                 base_offset => $self->_base_offset,
1142                 root => $self->_root
1143         );
1144 }
1145
1146 {
1147     my %is_legal_filter = map {
1148         $_ => ~~1,
1149     } qw(
1150         store_key store_value
1151         fetch_key fetch_value
1152     );
1153
1154     sub set_filter {
1155         ##
1156         # Setup filter function for storing or fetching the key or value
1157         ##
1158         my $self = $_[0]->_get_self;
1159         my $type = lc $_[1];
1160         my $func = $_[2] ? $_[2] : undef;
1161
1162         if ( $is_legal_filter{$type} ) {
1163             $self->_root->{"filter_$type"} = $func;
1164             return 1;
1165         }
1166
1167         return;
1168     }
1169 }
1170
1171 ##
1172 # Accessor methods
1173 ##
1174
1175 sub _root {
1176         ##
1177         # Get access to the root structure
1178         ##
1179     my $self = $_[0]->_get_self;
1180         return $self->{root};
1181 }
1182
1183 sub _fh {
1184         ##
1185         # Get access to the raw fh
1186         ##
1187     #XXX It will be useful, though, when we split out HASH and ARRAY
1188     my $self = $_[0]->_get_self;
1189         return $self->_root->{fh};
1190 }
1191
1192 sub _type {
1193         ##
1194         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1195         ##
1196     my $self = $_[0]->_get_self;
1197         return $self->{type};
1198 }
1199
1200 sub _base_offset {
1201         ##
1202         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1203         ##
1204     my $self = $_[0]->_get_self;
1205         return $self->{base_offset};
1206 }
1207
1208 sub error {
1209         ##
1210         # Get last error string, or undef if no error
1211         ##
1212         return $_[0]
1213         #? ( _get_self($_[0])->{root}->{error} or undef )
1214         ? ( $_[0]->_get_self->{root}->{error} or undef )
1215         : $@;
1216 }
1217
1218 ##
1219 # Utility methods
1220 ##
1221
1222 sub _throw_error {
1223         ##
1224         # Store error string in self
1225         ##
1226         my $error_text = $_[1];
1227
1228     if ( Scalar::Util::blessed $_[0] ) {
1229         my $self = $_[0]->_get_self;
1230         $self->_root->{error} = $error_text;
1231
1232         unless ($self->_root->{debug}) {
1233             die "DBM::Deep: $error_text\n";
1234         }
1235
1236         warn "DBM::Deep: $error_text\n";
1237         return;
1238     }
1239     else {
1240         die "DBM::Deep: $error_text\n";
1241     }
1242 }
1243
1244 sub clear_error {
1245         ##
1246         # Clear error state
1247         ##
1248     my $self = $_[0]->_get_self;
1249
1250         undef $self->_root->{error};
1251 }
1252
1253 sub _precalc_sizes {
1254         ##
1255         # Precalculate index, bucket and bucket list sizes
1256         ##
1257
1258     #XXX I don't like this ...
1259     set_pack() unless defined $LONG_SIZE;
1260
1261         $INDEX_SIZE = 256 * $LONG_SIZE;
1262         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1263         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1264 }
1265
1266 sub set_pack {
1267         ##
1268         # Set pack/unpack modes (see file header for more)
1269         ##
1270     my ($long_s, $long_p, $data_s, $data_p) = @_;
1271
1272     $LONG_SIZE = $long_s ? $long_s : 4;
1273     $LONG_PACK = $long_p ? $long_p : 'N';
1274
1275     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1276     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1277
1278         _precalc_sizes();
1279 }
1280
1281 sub set_digest {
1282         ##
1283         # Set key digest function (default is MD5)
1284         ##
1285     my ($digest_func, $hash_size) = @_;
1286
1287     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1288     $HASH_SIZE = $hash_size ? $hash_size : 16;
1289
1290         _precalc_sizes();
1291 }
1292
1293 ##
1294 # tie() methods (hashes and arrays)
1295 ##
1296
1297 sub STORE {
1298         ##
1299         # Store single hash key/value or array element in database.
1300         ##
1301     my $self = $_[0]->_get_self;
1302         my $key = $_[1];
1303
1304     # User may be storing a hash, in which case we do not want it run
1305     # through the filtering system
1306         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1307         ? $self->_root->{filter_store_value}->($_[2])
1308         : $_[2];
1309
1310         my $md5 = $DIGEST_FUNC->($key);
1311
1312         ##
1313         # Make sure file is open
1314         ##
1315         if (!defined($self->_fh) && !$self->_open()) {
1316                 return;
1317         }
1318         ##
1319
1320         ##
1321         # Request exclusive lock for writing
1322         ##
1323         $self->lock( LOCK_EX );
1324
1325         my $fh = $self->_fh;
1326
1327         ##
1328         # Locate offset for bucket list using digest index system
1329         ##
1330         my $tag = $self->_load_tag($self->_base_offset);
1331         if (!$tag) {
1332                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1333         }
1334
1335         my $ch = 0;
1336         while ($tag->{signature} ne SIG_BLIST) {
1337                 my $num = ord(substr($md5, $ch, 1));
1338
1339         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1340                 my $new_tag = $self->_index_lookup($tag, $num);
1341
1342                 if (!$new_tag) {
1343                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1344                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1345
1346                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1347
1348                         $tag->{ref_loc} = $ref_loc;
1349                         $tag->{ch} = $ch;
1350
1351                         last;
1352                 }
1353                 else {
1354                         $tag = $new_tag;
1355
1356                         $tag->{ref_loc} = $ref_loc;
1357                         $tag->{ch} = $ch;
1358                 }
1359                 $ch++;
1360         }
1361
1362         ##
1363         # Add key/value to bucket list
1364         ##
1365         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1366
1367         $self->unlock();
1368
1369         return $result;
1370 }
1371
1372 sub FETCH {
1373         ##
1374         # Fetch single value or element given plain key or array index
1375         ##
1376     my $self = shift->_get_self;
1377     my $key = shift;
1378
1379         ##
1380         # Make sure file is open
1381         ##
1382         if (!defined($self->_fh)) { $self->_open(); }
1383
1384         my $md5 = $DIGEST_FUNC->($key);
1385
1386         ##
1387         # Request shared lock for reading
1388         ##
1389         $self->lock( LOCK_SH );
1390
1391         my $tag = $self->_find_bucket_list( $md5 );
1392         if (!$tag) {
1393                 $self->unlock();
1394                 return;
1395         }
1396
1397         ##
1398         # Get value from bucket list
1399         ##
1400         my $result = $self->_get_bucket_value( $tag, $md5 );
1401
1402         $self->unlock();
1403
1404     #XXX What is ref() checking here?
1405     #YYY Filters only apply on scalar values, so the ref check is making
1406     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1407         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1408         ? $self->_root->{filter_fetch_value}->($result)
1409         : $result;
1410 }
1411
1412 sub DELETE {
1413         ##
1414         # Delete single key/value pair or element given plain key or array index
1415         ##
1416     my $self = $_[0]->_get_self;
1417         my $key = $_[1];
1418
1419         my $md5 = $DIGEST_FUNC->($key);
1420
1421         ##
1422         # Make sure file is open
1423         ##
1424         if (!defined($self->_fh)) { $self->_open(); }
1425
1426         ##
1427         # Request exclusive lock for writing
1428         ##
1429         $self->lock( LOCK_EX );
1430
1431         my $tag = $self->_find_bucket_list( $md5 );
1432         if (!$tag) {
1433                 $self->unlock();
1434                 return;
1435         }
1436
1437         ##
1438         # Delete bucket
1439         ##
1440     my $value = $self->_get_bucket_value( $tag, $md5 );
1441         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1442         $value = $self->_root->{filter_fetch_value}->($value);
1443     }
1444
1445         my $result = $self->_delete_bucket( $tag, $md5 );
1446
1447         ##
1448         # If this object is an array and the key deleted was on the end of the stack,
1449         # decrement the length variable.
1450         ##
1451
1452         $self->unlock();
1453
1454         return $value;
1455 }
1456
1457 sub EXISTS {
1458         ##
1459         # Check if a single key or element exists given plain key or array index
1460         ##
1461     my $self = $_[0]->_get_self;
1462         my $key = $_[1];
1463
1464         my $md5 = $DIGEST_FUNC->($key);
1465
1466         ##
1467         # Make sure file is open
1468         ##
1469         if (!defined($self->_fh)) { $self->_open(); }
1470
1471         ##
1472         # Request shared lock for reading
1473         ##
1474         $self->lock( LOCK_SH );
1475
1476         my $tag = $self->_find_bucket_list( $md5 );
1477
1478         ##
1479         # For some reason, the built-in exists() function returns '' for false
1480         ##
1481         if (!$tag) {
1482                 $self->unlock();
1483                 return '';
1484         }
1485
1486         ##
1487         # Check if bucket exists and return 1 or ''
1488         ##
1489         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1490
1491         $self->unlock();
1492
1493         return $result;
1494 }
1495
1496 sub CLEAR {
1497         ##
1498         # Clear all keys from hash, or all elements from array.
1499         ##
1500     my $self = $_[0]->_get_self;
1501
1502         ##
1503         # Make sure file is open
1504         ##
1505         if (!defined($self->_fh)) { $self->_open(); }
1506
1507         ##
1508         # Request exclusive lock for writing
1509         ##
1510         $self->lock( LOCK_EX );
1511
1512     my $fh = $self->_fh;
1513
1514         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1515         if (eof $fh) {
1516                 $self->unlock();
1517                 return;
1518         }
1519
1520         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1521
1522         $self->unlock();
1523
1524         return 1;
1525 }
1526
1527 ##
1528 # Public method aliases
1529 ##
1530 sub put { (shift)->STORE( @_ ) }
1531 sub store { (shift)->STORE( @_ ) }
1532 sub get { (shift)->FETCH( @_ ) }
1533 sub fetch { (shift)->FETCH( @_ ) }
1534 sub delete { (shift)->DELETE( @_ ) }
1535 sub exists { (shift)->EXISTS( @_ ) }
1536 sub clear { (shift)->CLEAR( @_ ) }
1537
1538 package DBM::Deep::_::Root;
1539
1540 sub new {
1541     my $class = shift;
1542     my ($args) = @_;
1543
1544     my $self = bless {
1545         file => undef,
1546         fh => undef,
1547         file_offset => 0,
1548         end => 0,
1549         autoflush => undef,
1550         locking => undef,
1551         debug => undef,
1552         filter_store_key => undef,
1553         filter_store_value => undef,
1554         filter_fetch_key => undef,
1555         filter_fetch_value => undef,
1556         autobless => undef,
1557         locked => 0,
1558         %$args,
1559     }, $class;
1560
1561     if ( $self->{fh} && !$self->{file_offset} ) {
1562         $self->{file_offset} = tell( $self->{fh} );
1563     }
1564
1565     return $self;
1566 }
1567
1568 sub DESTROY {
1569     my $self = shift;
1570     return unless $self;
1571
1572     close $self->{fh} if $self->{fh};
1573
1574     return;
1575 }
1576
1577 1;
1578
1579 __END__
1580
1581 =head1 NAME
1582
1583 DBM::Deep - A pure perl multi-level hash/array DBM
1584
1585 =head1 SYNOPSIS
1586
1587   use DBM::Deep;
1588   my $db = DBM::Deep->new( "foo.db" );
1589
1590   $db->{key} = 'value'; # tie() style
1591   print $db->{key};
1592
1593   $db->put('key' => 'value'); # OO style
1594   print $db->get('key');
1595
1596   # true multi-level support
1597   $db->{my_complex} = [
1598         'hello', { perl => 'rules' },
1599         42, 99,
1600   ];
1601
1602 =head1 DESCRIPTION
1603
1604 A unique flat-file database module, written in pure perl.  True
1605 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1606 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1607 handle millions of keys and unlimited hash levels without significant
1608 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1609 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1610 Mac OS X and Windows.
1611
1612 =head1 INSTALLATION
1613
1614 Hopefully you are using Perl's excellent CPAN module, which will download
1615 and install the module for you.  If not, get the tarball, and run these
1616 commands:
1617
1618         tar zxf DBM-Deep-*
1619         cd DBM-Deep-*
1620         perl Makefile.PL
1621         make
1622         make test
1623         make install
1624
1625 =head1 SETUP
1626
1627 Construction can be done OO-style (which is the recommended way), or using
1628 Perl's tie() function.  Both are examined here.
1629
1630 =head2 OO CONSTRUCTION
1631
1632 The recommended way to construct a DBM::Deep object is to use the new()
1633 method, which gets you a blessed, tied hash or array reference.
1634
1635         my $db = DBM::Deep->new( "foo.db" );
1636
1637 This opens a new database handle, mapped to the file "foo.db".  If this
1638 file does not exist, it will automatically be created.  DB files are
1639 opened in "r+" (read/write) mode, and the type of object returned is a
1640 hash, unless otherwise specified (see L<OPTIONS> below).
1641
1642 You can pass a number of options to the constructor to specify things like
1643 locking, autoflush, etc.  This is done by passing an inline hash:
1644
1645         my $db = DBM::Deep->new(
1646                 file => "foo.db",
1647                 locking => 1,
1648                 autoflush => 1
1649         );
1650
1651 Notice that the filename is now specified I<inside> the hash with
1652 the "file" parameter, as opposed to being the sole argument to the
1653 constructor.  This is required if any options are specified.
1654 See L<OPTIONS> below for the complete list.
1655
1656
1657
1658 You can also start with an array instead of a hash.  For this, you must
1659 specify the C<type> parameter:
1660
1661         my $db = DBM::Deep->new(
1662                 file => "foo.db",
1663                 type => DBM::Deep->TYPE_ARRAY
1664         );
1665
1666 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1667 a new DB file.  If you create a DBM::Deep object with an existing file, the
1668 C<type> will be loaded from the file header, and an error will be thrown if
1669 the wrong type is passed in.
1670
1671 =head2 TIE CONSTRUCTION
1672
1673 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1674 tie() function.  The object returned from tie() can be used to call methods,
1675 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1676 file (as expected with most tie'd objects).
1677
1678         my %hash;
1679         my $db = tie %hash, "DBM::Deep", "foo.db";
1680
1681         my @array;
1682         my $db = tie @array, "DBM::Deep", "bar.db";
1683
1684 As with the OO constructor, you can replace the DB filename parameter with
1685 a hash containing one or more options (see L<OPTIONS> just below for the
1686 complete list).
1687
1688         tie %hash, "DBM::Deep", {
1689                 file => "foo.db",
1690                 locking => 1,
1691                 autoflush => 1
1692         };
1693
1694 =head2 OPTIONS
1695
1696 There are a number of options that can be passed in when constructing your
1697 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1698
1699 =over
1700
1701 =item * file
1702
1703 Filename of the DB file to link the handle to.  You can pass a full absolute
1704 filesystem path, partial path, or a plain filename if the file is in the
1705 current working directory.  This is a required parameter (though q.v. fh).
1706
1707 =item * fh
1708
1709 If you want, you can pass in the fh instead of the file. This is most useful for doing
1710 something like:
1711
1712   my $db = DBM::Deep->new( { fh => \*DATA } );
1713
1714 You are responsible for making sure that the fh has been opened appropriately for your
1715 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1716 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1717 needs to read from the fh.
1718
1719 =item * file_offset
1720
1721 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1722 not need to set this. However, it's there if you want it.
1723
1724 If you pass in fh and do not set this, it will be set appropriately.
1725
1726 =item * type
1727
1728 This parameter specifies what type of object to create, a hash or array.  Use
1729 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1730 This only takes effect when beginning a new file.  This is an optional
1731 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1732
1733 =item * locking
1734
1735 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1736 function to lock the database in exclusive mode for writes, and shared mode for
1737 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1738 any child hashes or arrays> that use the same DB file.  This is an optional
1739 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1740
1741 =item * autoflush
1742
1743 Specifies whether autoflush is to be enabled on the underlying filehandle.
1744 This obviously slows down write operations, but is required if you may have
1745 multiple processes accessing the same DB file (also consider enable I<locking>).
1746 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1747 (disabled).
1748
1749 =item * autobless
1750
1751 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1752 restore them when fetched.  This is an B<experimental> feature, and does have
1753 side-effects.  Basically, when hashes are re-blessed into their original
1754 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1755 able to call any DBM::Deep methods on them.  You have been warned.
1756 This is an optional parameter, and defaults to 0 (disabled).
1757
1758 =item * filter_*
1759
1760 See L<FILTERS> below.
1761
1762 =item * debug
1763
1764 Setting I<debug> mode will make all errors non-fatal, dump them out to
1765 STDERR, and continue on.  This is for debugging purposes only, and probably
1766 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1767
1768 =item * fh
1769
1770 Instead of passing a file path, you can instead pass a handle to an pre-opened
1771 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1772 contains your entire Perl script, as well as the data following the __DATA__
1773 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1774 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1775 in that.  Also please note optimize() will NOT work when passing in only a
1776 handle.  Pass in a real filename in order to use optimize().
1777
1778 =back
1779
1780 =head1 TIE INTERFACE
1781
1782 With DBM::Deep you can access your databases using Perl's standard hash/array
1783 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1784 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1785 to the right place -- the DB file.  This has nothing to do with the
1786 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1787 using regular hashes and arrays, rather than calling functions like C<get()>
1788 and C<put()> (although those work too).  It is entirely up to you how to want
1789 to access your databases.
1790
1791 =head2 HASHES
1792
1793 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1794 or even nested hashes (or arrays) using standard Perl syntax:
1795
1796         my $db = DBM::Deep->new( "foo.db" );
1797
1798         $db->{mykey} = "myvalue";
1799         $db->{myhash} = {};
1800         $db->{myhash}->{subkey} = "subvalue";
1801
1802         print $db->{myhash}->{subkey} . "\n";
1803
1804 You can even step through hash keys using the normal Perl C<keys()> function:
1805
1806         foreach my $key (keys %$db) {
1807                 print "$key: " . $db->{$key} . "\n";
1808         }
1809
1810 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1811 pushes them onto an array, all before the loop even begins.  If you have an
1812 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1813 Perl's C<each()> function, which pulls keys/values one at a time, using very
1814 little memory:
1815
1816         while (my ($key, $value) = each %$db) {
1817                 print "$key: $value\n";
1818         }
1819
1820 Please note that when using C<each()>, you should always pass a direct
1821 hash reference, not a lookup.  Meaning, you should B<never> do this:
1822
1823         # NEVER DO THIS
1824         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1825
1826 This causes an infinite loop, because for each iteration, Perl is calling
1827 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1828 it effectively keeps returning the first key over and over again. Instead,
1829 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1830
1831 =head2 ARRAYS
1832
1833 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1834 reference.  This includes inserting, removing and manipulating elements,
1835 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1836 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1837 or simply be a nested array reference inside a hash.  Example:
1838
1839         my $db = DBM::Deep->new(
1840                 file => "foo-array.db",
1841                 type => DBM::Deep->TYPE_ARRAY
1842         );
1843
1844         $db->[0] = "foo";
1845         push @$db, "bar", "baz";
1846         unshift @$db, "bah";
1847
1848         my $last_elem = pop @$db; # baz
1849         my $first_elem = shift @$db; # bah
1850         my $second_elem = $db->[1]; # bar
1851
1852         my $num_elements = scalar @$db;
1853
1854 =head1 OO INTERFACE
1855
1856 In addition to the I<tie()> interface, you can also use a standard OO interface
1857 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1858 array) has its own methods, but both types share the following common methods:
1859 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1860
1861 =over
1862
1863 =item * new() / clone()
1864
1865 These are the constructor and copy-functions.
1866
1867 =item * put() / store()
1868
1869 Stores a new hash key/value pair, or sets an array element value.  Takes two
1870 arguments, the hash key or array index, and the new value.  The value can be
1871 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1872
1873         $db->put("foo", "bar"); # for hashes
1874         $db->put(1, "bar"); # for arrays
1875
1876 =item * get() / fetch()
1877
1878 Fetches the value of a hash key or array element.  Takes one argument: the hash
1879 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1880 data type stored.
1881
1882         my $value = $db->get("foo"); # for hashes
1883         my $value = $db->get(1); # for arrays
1884
1885 =item * exists()
1886
1887 Checks if a hash key or array index exists.  Takes one argument: the hash key
1888 or array index.  Returns true if it exists, false if not.
1889
1890         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1891         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1892
1893 =item * delete()
1894
1895 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1896 key or array index.  Returns true on success, false if not found.  For arrays,
1897 the remaining elements located after the deleted element are NOT moved over.
1898 The deleted element is essentially just undefined, which is exactly how Perl's
1899 internal arrays work.  Please note that the space occupied by the deleted
1900 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1901 below for details and workarounds.
1902
1903         $db->delete("foo"); # for hashes
1904         $db->delete(1); # for arrays
1905
1906 =item * clear()
1907
1908 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1909 value.  Please note that the space occupied by the deleted keys/values or
1910 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1911 details and workarounds.
1912
1913         $db->clear(); # hashes or arrays
1914
1915 =item * lock() / unlock()
1916
1917 q.v. Locking.
1918
1919 =item * optimize()
1920
1921 Recover lost disk space.
1922
1923 =item * import() / export()
1924
1925 Data going in and out.
1926
1927 =item * set_digest() / set_pack() / set_filter()
1928
1929 q.v. adjusting the interal parameters.
1930
1931 =item * error() / clear_error()
1932
1933 Error handling methods (may be deprecated).
1934 .
1935 =back
1936
1937 =head2 HASHES
1938
1939 For hashes, DBM::Deep supports all the common methods described above, and the
1940 following additional methods: C<first_key()> and C<next_key()>.
1941
1942 =over
1943
1944 =item * first_key()
1945
1946 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1947 fetched in an undefined order (which appears random).  Takes no arguments,
1948 returns the key as a scalar value.
1949
1950         my $key = $db->first_key();
1951
1952 =item * next_key()
1953
1954 Returns the "next" key in the hash, given the previous one as the sole argument.
1955 Returns undef if there are no more keys to be fetched.
1956
1957         $key = $db->next_key($key);
1958
1959 =back
1960
1961 Here are some examples of using hashes:
1962
1963         my $db = DBM::Deep->new( "foo.db" );
1964
1965         $db->put("foo", "bar");
1966         print "foo: " . $db->get("foo") . "\n";
1967
1968         $db->put("baz", {}); # new child hash ref
1969         $db->get("baz")->put("buz", "biz");
1970         print "buz: " . $db->get("baz")->get("buz") . "\n";
1971
1972         my $key = $db->first_key();
1973         while ($key) {
1974                 print "$key: " . $db->get($key) . "\n";
1975                 $key = $db->next_key($key);
1976         }
1977
1978         if ($db->exists("foo")) { $db->delete("foo"); }
1979
1980 =head2 ARRAYS
1981
1982 For arrays, DBM::Deep supports all the common methods described above, and the
1983 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1984 C<unshift()> and C<splice()>.
1985
1986 =over
1987
1988 =item * length()
1989
1990 Returns the number of elements in the array.  Takes no arguments.
1991
1992         my $len = $db->length();
1993
1994 =item * push()
1995
1996 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1997 refs or array refs.  No return value.
1998
1999         $db->push("foo", "bar", {});
2000
2001 =item * pop()
2002
2003 Fetches the last element in the array, and deletes it.  Takes no arguments.
2004 Returns undef if array is empty.  Returns the element value.
2005
2006         my $elem = $db->pop();
2007
2008 =item * shift()
2009
2010 Fetches the first element in the array, deletes it, then shifts all the
2011 remaining elements over to take up the space.  Returns the element value.  This
2012 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2013 details.
2014
2015         my $elem = $db->shift();
2016
2017 =item * unshift()
2018
2019 Inserts one or more elements onto the beginning of the array, shifting all
2020 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2021 No return value.  This method is not recommended with large arrays -- see
2022 <LARGE ARRAYS> below for details.
2023
2024         $db->unshift("foo", "bar", {});
2025
2026 =item * splice()
2027
2028 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2029 -f splice> for usage -- it is too complicated to document here.  This method is
2030 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2031
2032 =back
2033
2034 Here are some examples of using arrays:
2035
2036         my $db = DBM::Deep->new(
2037                 file => "foo.db",
2038                 type => DBM::Deep->TYPE_ARRAY
2039         );
2040
2041         $db->push("bar", "baz");
2042         $db->unshift("foo");
2043         $db->put(3, "buz");
2044
2045         my $len = $db->length();
2046         print "length: $len\n"; # 4
2047
2048         for (my $k=0; $k<$len; $k++) {
2049                 print "$k: " . $db->get($k) . "\n";
2050         }
2051
2052         $db->splice(1, 2, "biz", "baf");
2053
2054         while (my $elem = shift @$db) {
2055                 print "shifted: $elem\n";
2056         }
2057
2058 =head1 LOCKING
2059
2060 Enable automatic file locking by passing a true value to the C<locking>
2061 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2062
2063         my $db = DBM::Deep->new(
2064                 file => "foo.db",
2065                 locking => 1
2066         );
2067
2068 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2069 mode for writes, and shared mode for reads.  This is required if you have
2070 multiple processes accessing the same database file, to avoid file corruption.
2071 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2072 NFS> below for more.
2073
2074 =head2 EXPLICIT LOCKING
2075
2076 You can explicitly lock a database, so it remains locked for multiple
2077 transactions.  This is done by calling the C<lock()> method, and passing an
2078 optional lock mode argument (defaults to exclusive mode).  This is particularly
2079 useful for things like counters, where the current value needs to be fetched,
2080 then incremented, then stored again.
2081
2082         $db->lock();
2083         my $counter = $db->get("counter");
2084         $counter++;
2085         $db->put("counter", $counter);
2086         $db->unlock();
2087
2088         # or...
2089
2090         $db->lock();
2091         $db->{counter}++;
2092         $db->unlock();
2093
2094 You can pass C<lock()> an optional argument, which specifies which mode to use
2095 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2096 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2097 same as the constants defined in Perl's C<Fcntl> module.
2098
2099         $db->lock( DBM::Deep->LOCK_SH );
2100         # something here
2101         $db->unlock();
2102
2103 =head1 IMPORTING/EXPORTING
2104
2105 You can import existing complex structures by calling the C<import()> method,
2106 and export an entire database into an in-memory structure using the C<export()>
2107 method.  Both are examined here.
2108
2109 =head2 IMPORTING
2110
2111 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2112 walking the structure and adding keys/elements to the database as you go,
2113 simply pass a reference to the C<import()> method.  This recursively adds
2114 everything to an existing DBM::Deep object for you.  Here is an example:
2115
2116         my $struct = {
2117                 key1 => "value1",
2118                 key2 => "value2",
2119                 array1 => [ "elem0", "elem1", "elem2" ],
2120                 hash1 => {
2121                         subkey1 => "subvalue1",
2122                         subkey2 => "subvalue2"
2123                 }
2124         };
2125
2126         my $db = DBM::Deep->new( "foo.db" );
2127         $db->import( $struct );
2128
2129         print $db->{key1} . "\n"; # prints "value1"
2130
2131 This recursively imports the entire C<$struct> object into C<$db>, including
2132 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2133 keys are merged with the existing ones, replacing if they already exist.
2134 The C<import()> method can be called on any database level (not just the base
2135 level), and works with both hash and array DB types.
2136
2137 B<Note:> Make sure your existing structure has no circular references in it.
2138 These will cause an infinite loop when importing.
2139
2140 =head2 EXPORTING
2141
2142 Calling the C<export()> method on an existing DBM::Deep object will return
2143 a reference to a new in-memory copy of the database.  The export is done
2144 recursively, so all nested hashes/arrays are all exported to standard Perl
2145 objects.  Here is an example:
2146
2147         my $db = DBM::Deep->new( "foo.db" );
2148
2149         $db->{key1} = "value1";
2150         $db->{key2} = "value2";
2151         $db->{hash1} = {};
2152         $db->{hash1}->{subkey1} = "subvalue1";
2153         $db->{hash1}->{subkey2} = "subvalue2";
2154
2155         my $struct = $db->export();
2156
2157         print $struct->{key1} . "\n"; # prints "value1"
2158
2159 This makes a complete copy of the database in memory, and returns a reference
2160 to it.  The C<export()> method can be called on any database level (not just
2161 the base level), and works with both hash and array DB types.  Be careful of
2162 large databases -- you can store a lot more data in a DBM::Deep object than an
2163 in-memory Perl structure.
2164
2165 B<Note:> Make sure your database has no circular references in it.
2166 These will cause an infinite loop when exporting.
2167
2168 =head1 FILTERS
2169
2170 DBM::Deep has a number of hooks where you can specify your own Perl function
2171 to perform filtering on incoming or outgoing data.  This is a perfect
2172 way to extend the engine, and implement things like real-time compression or
2173 encryption.  Filtering applies to the base DB level, and all child hashes /
2174 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2175 constructed, or by calling the C<set_filter()> method at any time.  There are
2176 four available filter hooks, described below:
2177
2178 =over
2179
2180 =item * filter_store_key
2181
2182 This filter is called whenever a hash key is stored.  It
2183 is passed the incoming key, and expected to return a transformed key.
2184
2185 =item * filter_store_value
2186
2187 This filter is called whenever a hash key or array element is stored.  It
2188 is passed the incoming value, and expected to return a transformed value.
2189
2190 =item * filter_fetch_key
2191
2192 This filter is called whenever a hash key is fetched (i.e. via
2193 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2194 and expected to return the plain key.
2195
2196 =item * filter_fetch_value
2197
2198 This filter is called whenever a hash key or array element is fetched.
2199 It is passed the transformed value, and expected to return the plain value.
2200
2201 =back
2202
2203 Here are the two ways to setup a filter hook:
2204
2205         my $db = DBM::Deep->new(
2206                 file => "foo.db",
2207                 filter_store_value => \&my_filter_store,
2208                 filter_fetch_value => \&my_filter_fetch
2209         );
2210
2211         # or...
2212
2213         $db->set_filter( "filter_store_value", \&my_filter_store );
2214         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2215
2216 Your filter function will be called only when dealing with SCALAR keys or
2217 values.  When nested hashes and arrays are being stored/fetched, filtering
2218 is bypassed.  Filters are called as static functions, passed a single SCALAR
2219 argument, and expected to return a single SCALAR value.  If you want to
2220 remove a filter, set the function reference to C<undef>:
2221
2222         $db->set_filter( "filter_store_value", undef );
2223
2224 =head2 REAL-TIME ENCRYPTION EXAMPLE
2225
2226 Here is a working example that uses the I<Crypt::Blowfish> module to
2227 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2228 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2229 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2230
2231         use DBM::Deep;
2232         use Crypt::Blowfish;
2233         use Crypt::CBC;
2234
2235         my $cipher = Crypt::CBC->new({
2236                 'key'             => 'my secret key',
2237                 'cipher'          => 'Blowfish',
2238                 'iv'              => '$KJh#(}q',
2239                 'regenerate_key'  => 0,
2240                 'padding'         => 'space',
2241                 'prepend_iv'      => 0
2242         });
2243
2244         my $db = DBM::Deep->new(
2245                 file => "foo-encrypt.db",
2246                 filter_store_key => \&my_encrypt,
2247                 filter_store_value => \&my_encrypt,
2248                 filter_fetch_key => \&my_decrypt,
2249                 filter_fetch_value => \&my_decrypt,
2250         );
2251
2252         $db->{key1} = "value1";
2253         $db->{key2} = "value2";
2254         print "key1: " . $db->{key1} . "\n";
2255         print "key2: " . $db->{key2} . "\n";
2256
2257         undef $db;
2258         exit;
2259
2260         sub my_encrypt {
2261                 return $cipher->encrypt( $_[0] );
2262         }
2263         sub my_decrypt {
2264                 return $cipher->decrypt( $_[0] );
2265         }
2266
2267 =head2 REAL-TIME COMPRESSION EXAMPLE
2268
2269 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2270 compression / decompression of keys & values with DBM::Deep Filters.
2271 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2272 more on I<Compress::Zlib>.
2273
2274         use DBM::Deep;
2275         use Compress::Zlib;
2276
2277         my $db = DBM::Deep->new(
2278                 file => "foo-compress.db",
2279                 filter_store_key => \&my_compress,
2280                 filter_store_value => \&my_compress,
2281                 filter_fetch_key => \&my_decompress,
2282                 filter_fetch_value => \&my_decompress,
2283         );
2284
2285         $db->{key1} = "value1";
2286         $db->{key2} = "value2";
2287         print "key1: " . $db->{key1} . "\n";
2288         print "key2: " . $db->{key2} . "\n";
2289
2290         undef $db;
2291         exit;
2292
2293         sub my_compress {
2294                 return Compress::Zlib::memGzip( $_[0] ) ;
2295         }
2296         sub my_decompress {
2297                 return Compress::Zlib::memGunzip( $_[0] ) ;
2298         }
2299
2300 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2301 actually numerical index numbers, and are not filtered.
2302
2303 =head1 ERROR HANDLING
2304
2305 Most DBM::Deep methods return a true value for success, and call die() on
2306 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2307 actual error message is stored in an internal scalar, which can be fetched by
2308 calling the C<error()> method.
2309
2310         my $db = DBM::Deep->new( "foo.db" ); # create hash
2311         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2312
2313     print $@;           # prints error message
2314         print $db->error(); # prints error message
2315
2316 You can then call C<clear_error()> to clear the current error state.
2317
2318         $db->clear_error();
2319
2320 If you set the C<debug> option to true when creating your DBM::Deep object,
2321 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2322 be used for debugging purposes and not production work. DBM::Deep expects errors
2323 to be thrown, not propagated back up the stack.
2324
2325 =head1 LARGEFILE SUPPORT
2326
2327 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2328 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2329 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2330 by calling the static C<set_pack()> method before you do anything else.
2331
2332         DBM::Deep::set_pack(8, 'Q');
2333
2334 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2335 instead of 32-bit longs.  After setting these values your DB files have a
2336 theoretical maximum size of 16 XB (exabytes).
2337
2338 B<Note:> Changing these values will B<NOT> work for existing database files.
2339 Only change this for new files, and make sure it stays set consistently
2340 throughout the file's life.  If you do set these values, you can no longer
2341 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2342 back to 32-bit mode.
2343
2344 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2345 only a 32-bit Perl.  However, I have received user reports that this does
2346 indeed work!
2347
2348 =head1 LOW-LEVEL ACCESS
2349
2350 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2351 you can call the C<_fh()> method, which returns the handle:
2352
2353         my $fh = $db->_fh();
2354
2355 This method can be called on the root level of the datbase, or any child
2356 hashes or arrays.  All levels share a I<root> structure, which contains things
2357 like the filehandle, a reference counter, and all the options specified
2358 when you created the object.  You can get access to this root structure by
2359 calling the C<root()> method.
2360
2361         my $root = $db->_root();
2362
2363 This is useful for changing options after the object has already been created,
2364 such as enabling/disabling locking, or debug modes.  You can also
2365 store your own temporary user data in this structure (be wary of name
2366 collision), which is then accessible from any child hash or array.
2367
2368 =head1 CUSTOM DIGEST ALGORITHM
2369
2370 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2371 keys.  However you can override this, and use another algorithm (such as SHA-256)
2372 or even write your own.  But please note that DBM::Deep currently expects zero
2373 collisions, so your algorithm has to be I<perfect>, so to speak.
2374 Collision detection may be introduced in a later version.
2375
2376
2377
2378 You can specify a custom digest algorithm by calling the static C<set_digest()>
2379 function, passing a reference to a subroutine, and the length of the algorithm's
2380 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2381 objects.  Here is a working example that uses a 256-bit hash from the
2382 I<Digest::SHA256> module.  Please see
2383 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2384
2385         use DBM::Deep;
2386         use Digest::SHA256;
2387
2388         my $context = Digest::SHA256::new(256);
2389
2390         DBM::Deep::set_digest( \&my_digest, 32 );
2391
2392         my $db = DBM::Deep->new( "foo-sha.db" );
2393
2394         $db->{key1} = "value1";
2395         $db->{key2} = "value2";
2396         print "key1: " . $db->{key1} . "\n";
2397         print "key2: " . $db->{key2} . "\n";
2398
2399         undef $db;
2400         exit;
2401
2402         sub my_digest {
2403                 return substr( $context->hash($_[0]), 0, 32 );
2404         }
2405
2406 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2407 of bytes you specify in the C<set_digest()> function (in this case 32).
2408
2409 =head1 CIRCULAR REFERENCES
2410
2411 DBM::Deep has B<experimental> support for circular references.  Meaning you
2412 can have a nested hash key or array element that points to a parent object.
2413 This relationship is stored in the DB file, and is preserved between sessions.
2414 Here is an example:
2415
2416         my $db = DBM::Deep->new( "foo.db" );
2417
2418         $db->{foo} = "bar";
2419         $db->{circle} = $db; # ref to self
2420
2421         print $db->{foo} . "\n"; # prints "foo"
2422         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2423
2424 One catch is, passing the object to a function that recursively walks the
2425 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2426 C<export()> methods) will result in an infinite loop.  The other catch is,
2427 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2428 or C<next_key()> methods), you will get the I<target object's key>, not the
2429 ref's key.  This gets even more interesting with the above example, where
2430 the I<circle> key points to the base DB object, which technically doesn't
2431 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2432 special case.
2433
2434 =head1 CAVEATS / ISSUES / BUGS
2435
2436 This section describes all the known issues with DBM::Deep.  It you have found
2437 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2438
2439 =head2 UNUSED SPACE RECOVERY
2440
2441 One major caveat with DBM::Deep is that space occupied by existing keys and
2442 values is not recovered when they are deleted.  Meaning if you keep deleting
2443 and adding new keys, your file will continuously grow.  I am working on this,
2444 but in the meantime you can call the built-in C<optimize()> method from time to
2445 time (perhaps in a crontab or something) to recover all your unused space.
2446
2447         $db->optimize(); # returns true on success
2448
2449 This rebuilds the ENTIRE database into a new file, then moves it on top of
2450 the original.  The new file will have no unused space, thus it will take up as
2451 little disk space as possible.  Please note that this operation can take
2452 a long time for large files, and you need enough disk space to temporarily hold
2453 2 copies of your DB file.  The temporary file is created in the same directory
2454 as the original, named with a ".tmp" extension, and is deleted when the
2455 operation completes.  Oh, and if locking is enabled, the DB is automatically
2456 locked for the entire duration of the copy.
2457
2458 B<WARNING:> Only call optimize() on the top-level node of the database, and
2459 make sure there are no child references lying around.  DBM::Deep keeps a reference
2460 counter, and if it is greater than 1, optimize() will abort and return undef.
2461
2462 =head2 AUTOVIVIFICATION
2463
2464 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2465 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2466 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2467 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2468 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2469 this does not work:
2470
2471         $db->{foo}->{bar} = "hello";
2472
2473 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2474 being an empty hash.  Try this instead, which works fine:
2475
2476         $db->{foo} = { bar => "hello" };
2477
2478 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2479 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2480 Probably a bug in Perl.
2481
2482 =head2 FILE CORRUPTION
2483
2484 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2485 for a 32-bit signature when opened, but other corruption in files can cause
2486 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2487 stuck in an infinite loop depending on the level of corruption.  File write
2488 operations are not checked for failure (for speed), so if you happen to run
2489 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2490 be addressed in a later version of DBM::Deep.
2491
2492 =head2 DB OVER NFS
2493
2494 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2495 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2496 about setting up your NFS server with a locking daemon, then using lockf() to
2497 lock your files, but your mileage may vary there as well.  From what I
2498 understand, there is no real way to do it.  However, if you need access to the
2499 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2500 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2501
2502 =head2 COPYING OBJECTS
2503
2504 Beware of copying tied objects in Perl.  Very strange things can happen.
2505 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2506 returns a new, blessed, tied hash or array to the same level in the DB.
2507
2508         my $copy = $db->clone();
2509
2510 B<Note>: Since clone() here is cloning the object, not the database location, any
2511 modifications to either $db or $copy will be visible in both.
2512
2513 =head2 LARGE ARRAYS
2514
2515 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2516 These functions cause every element in the array to move, which can be murder
2517 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2518 a different location.  This will be addressed in the forthcoming version 1.00.
2519
2520 =head1 PERFORMANCE
2521
2522 This section discusses DBM::Deep's speed and memory usage.
2523
2524 =head2 SPEED
2525
2526 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2527 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2528 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2529 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2530 with huge databases.  Here is some test data:
2531
2532         Adding 1,000,000 keys to new DB file...
2533
2534         At 100 keys, avg. speed is 2,703 keys/sec
2535         At 200 keys, avg. speed is 2,642 keys/sec
2536         At 300 keys, avg. speed is 2,598 keys/sec
2537         At 400 keys, avg. speed is 2,578 keys/sec
2538         At 500 keys, avg. speed is 2,722 keys/sec
2539         At 600 keys, avg. speed is 2,628 keys/sec
2540         At 700 keys, avg. speed is 2,700 keys/sec
2541         At 800 keys, avg. speed is 2,607 keys/sec
2542         At 900 keys, avg. speed is 2,190 keys/sec
2543         At 1,000 keys, avg. speed is 2,570 keys/sec
2544         At 2,000 keys, avg. speed is 2,417 keys/sec
2545         At 3,000 keys, avg. speed is 1,982 keys/sec
2546         At 4,000 keys, avg. speed is 1,568 keys/sec
2547         At 5,000 keys, avg. speed is 1,533 keys/sec
2548         At 6,000 keys, avg. speed is 1,787 keys/sec
2549         At 7,000 keys, avg. speed is 1,977 keys/sec
2550         At 8,000 keys, avg. speed is 2,028 keys/sec
2551         At 9,000 keys, avg. speed is 2,077 keys/sec
2552         At 10,000 keys, avg. speed is 2,031 keys/sec
2553         At 20,000 keys, avg. speed is 1,970 keys/sec
2554         At 30,000 keys, avg. speed is 2,050 keys/sec
2555         At 40,000 keys, avg. speed is 2,073 keys/sec
2556         At 50,000 keys, avg. speed is 1,973 keys/sec
2557         At 60,000 keys, avg. speed is 1,914 keys/sec
2558         At 70,000 keys, avg. speed is 2,091 keys/sec
2559         At 80,000 keys, avg. speed is 2,103 keys/sec
2560         At 90,000 keys, avg. speed is 1,886 keys/sec
2561         At 100,000 keys, avg. speed is 1,970 keys/sec
2562         At 200,000 keys, avg. speed is 2,053 keys/sec
2563         At 300,000 keys, avg. speed is 1,697 keys/sec
2564         At 400,000 keys, avg. speed is 1,838 keys/sec
2565         At 500,000 keys, avg. speed is 1,941 keys/sec
2566         At 600,000 keys, avg. speed is 1,930 keys/sec
2567         At 700,000 keys, avg. speed is 1,735 keys/sec
2568         At 800,000 keys, avg. speed is 1,795 keys/sec
2569         At 900,000 keys, avg. speed is 1,221 keys/sec
2570         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2571
2572 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2573 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2574 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2575 Run time was 12 min 3 sec.
2576
2577 =head2 MEMORY USAGE
2578
2579 One of the great things about DBM::Deep is that it uses very little memory.
2580 Even with huge databases (1,000,000+ keys) you will not see much increased
2581 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2582 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2583 database handle:
2584
2585           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2586         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2587
2588 Basically the process is taking 2,716K of memory.  And here is the same
2589 process after storing and fetching 1,000,000 keys:
2590
2591           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2592         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2593
2594 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2595 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2596
2597 =head1 DB FILE FORMAT
2598
2599 In case you were interested in the underlying DB file format, it is documented
2600 here in this section.  You don't need to know this to use the module, it's just
2601 included for reference.
2602
2603 =head2 SIGNATURE
2604
2605 DBM::Deep files always start with a 32-bit signature to identify the file type.
2606 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2607 checked for when the file is opened and an error will be thrown if it's not found.
2608
2609 =head2 TAG
2610
2611 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2612 has a standard header containing the type of data, the length of data, and then
2613 the data itself.  The type is a single character (1 byte), the length is a
2614 32-bit unsigned long in network byte order, and the data is, well, the data.
2615 Here is how it unfolds:
2616
2617 =head2 MASTER INDEX
2618
2619 Immediately after the 32-bit file signature is the I<Master Index> record.
2620 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2621 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2622 depending on how the DBM::Deep object was constructed.
2623
2624 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2625 number).  The first 8-bit char of the MD5 signature is the offset into the
2626 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2627 index element is a file offset of the next tag for the key/element in question,
2628 which is usually a I<Bucket List> tag (see below).
2629
2630 The next tag I<could> be another index, depending on how many keys/elements
2631 exist.  See L<RE-INDEXING> below for details.
2632
2633 =head2 BUCKET LIST
2634
2635 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2636 file offsets to where the actual data is stored.  It starts with a standard
2637 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2638 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2639 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2640 When the list fills up, a I<Re-Index> operation is performed (See
2641 L<RE-INDEXING> below).
2642
2643 =head2 BUCKET
2644
2645 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2646 index/value pair (in array mode).  It starts with a standard tag header with
2647 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2648 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2649 header.  The size reported in the tag header is only for the value, but then,
2650 just after the value is another size (32-bit unsigned long) and then the plain
2651 key itself.  Since the value is likely to be fetched more often than the plain
2652 key, I figured it would be I<slightly> faster to store the value first.
2653
2654 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2655 record for the nested structure, where the process begins all over again.
2656
2657 =head2 RE-INDEXING
2658
2659 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2660 exhausted.  Then, when another key/element comes in, the list is converted to a
2661 new index record.  However, this index will look at the next char in the MD5
2662 hash, and arrange new Bucket List pointers accordingly.  This process is called
2663 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2664 17 (16 + new one) keys/elements are removed from the old Bucket List and
2665 inserted into the new index.  Several new Bucket Lists are created in the
2666 process, as a new MD5 char from the key is being examined (it is unlikely that
2667 the keys will all share the same next char of their MD5s).
2668
2669 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2670 when the Bucket Lists will turn into indexes, but the first round tends to
2671 happen right around 4,000 keys.  You will see a I<slight> decrease in
2672 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2673 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2674 right around 900,000 keys.  This process can continue nearly indefinitely --
2675 right up until the point the I<MD5> signatures start colliding with each other,
2676 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2677 getting struck by lightning while you are walking to cash in your tickets.
2678 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2679 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2680 this is 340 unodecillion, but don't quote me).
2681
2682 =head2 STORING
2683
2684 When a new key/element is stored, the key (or index number) is first run through
2685 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2686 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2687 for the first char of the signature (in this case I<b0>).  If it does not exist,
2688 a new I<Bucket List> is created for our key (and the next 15 future keys that
2689 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2690 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2691 this point, unless we are replacing an existing I<Bucket>), where the actual
2692 data will be stored.
2693
2694 =head2 FETCHING
2695
2696 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2697 (or index number), then walking along the indexes.  If there are enough
2698 keys/elements in this DB level, there might be nested indexes, each linked to
2699 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2700 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2701 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2702 plain key are stored.
2703
2704 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2705 methods.  In this process the indexes are walked systematically, and each key
2706 fetched in increasing MD5 order (which is why it appears random).   Once the
2707 I<Bucket> is found, the value is skipped and the plain key returned instead.
2708 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2709 alphabetically sorted.  This only happens on an index-level -- as soon as the
2710 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2711 so it's pretty much undefined how the keys will come out -- just like Perl's
2712 built-in hashes.
2713
2714 =head1 CODE COVERAGE
2715
2716 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2717 B<Devel::Cover> report on this module's test suite.
2718
2719   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2720   File                           stmt   bran   cond    sub    pod   time  total
2721   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2722   blib/lib/DBM/Deep.pm           95.0   83.2   68.7   98.2  100.0   57.8   90.7
2723   blib/lib/DBM/Deep/Array.pm     98.9   88.9   87.5  100.0    n/a   27.4   96.4
2724   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   14.8   92.4
2725   Total                          95.8   83.9   72.8   98.8  100.0  100.0   91.8
2726   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2727
2728 =head1 MORE INFORMATION
2729
2730 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2731 or send email to L<DBM-Deep@googlegroups.com>.
2732
2733 =head1 AUTHORS
2734
2735 Joseph Huckaby, L<jhuckaby@cpan.org>
2736
2737 Rob Kinyon, L<rkinyon@cpan.org>
2738
2739 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2740
2741 =head1 SEE ALSO
2742
2743 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2744 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2745
2746 =head1 LICENSE
2747
2748 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2749 This is free software, you may use it and distribute it under the
2750 same terms as Perl itself.
2751
2752 =cut