lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.98);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105 sub TYPE_SCALAR () { SIG_SCALAR }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( ref $_[0] ) {
 118         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->_fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->_fh)) { $self->_close(); }
 211
 212     eval {
 213         local $SIG{'__DIE__'};
 214         # Theoretically, adding O_BINARY should remove the need for the binmode
 215         # Of course, testing it is going to be ... interesting.
 216         my $flags = O_RDWR | O_CREAT | O_BINARY;
 217
 218         my $fh;
 219         sysopen( $fh, $self->_root->{file}, $flags )
 220             or $fh = undef;
 221         $self->_root->{fh} = $fh;
 222     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 223         if (! defined($self->_fh)) {
 224                 return $self->_throw_error("Cannot sysopen file: " . $self->_root->{file} . ": $!");
 225         }
 226
 227     my $fh = $self->_fh;
 228
 229     #XXX Can we remove this by using the right sysopen() flags?
 230     # Maybe ... q.v. above
 231     binmode $fh; # for win32
 232
 233     if ($self->_root->{autoflush}) {
 234         my $old = select $fh;
 235         $|=1;
 236         select $old;
 237     }
 238
 239     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 249         print($fh SIG_FILE);
 250         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|;
 258         $| = 1;
 259         $| = $old_af;
 260         select $old_fh;
 261
 262         my @stats = stat($fh);
 263         $self->_root->{inode} = $stats[1];
 264         $self->_root->{end} = $stats[7];
 265
 266         return 1;
 267     }
 268
 269     ##
 270     # Check signature was valid
 271     ##
 272     unless ($signature eq SIG_FILE) {
 273         $self->_close();
 274         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 275     }
 276
 277         my @stats = stat($fh);
 278         $self->_root->{inode} = $stats[1];
 279     $self->_root->{end} = $stats[7];
 280
 281     ##
 282     # Get our type from master index signature
 283     ##
 284     my $tag = $self->_load_tag($self->_base_offset);
 285
 286 #XXX We probably also want to store the hash algorithm name and not assume anything
 287 #XXX The cool thing would be to allow a different hashing algorithm at every level
 288
 289     if (!$tag) {
 290         return $self->_throw_error("Corrupted file, no master index record");
 291     }
 292     if ($self->{type} ne $tag->{signature}) {
 293         return $self->_throw_error("File type mismatch");
 294     }
 295
 296     return 1;
 297 }
 298
 299 sub _close {
 300         ##
 301         # Close database fh
 302         ##
 303     my $self = $_[0]->_get_self;
 304     close $self->_root->{fh} if $self->_root->{fh};
 305     $self->_root->{fh} = undef;
 306 }
 307
 308 sub _create_tag {
 309         ##
 310         # Given offset, signature and content, create tag and write to disk
 311         ##
 312         my ($self, $offset, $sig, $content) = @_;
 313         my $size = length($content);
 314
 315     my $fh = $self->_fh;
 316
 317         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 318         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 319
 320         if ($offset == $self->_root->{end}) {
 321                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 322         }
 323
 324         return {
 325                 signature => $sig,
 326                 size => $size,
 327                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 328                 content => $content
 329         };
 330 }
 331
 332 sub _load_tag {
 333         ##
 334         # Given offset, load single tag and return signature, size and data
 335         ##
 336         my $self = shift;
 337         my $offset = shift;
 338
 339     my $fh = $self->_fh;
 340
 341         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 342         if (eof $fh) { return undef; }
 343
 344         my $sig;
 345         read( $fh, $sig, SIG_SIZE);
 346
 347         my $size;
 348         read( $fh, $size, $DATA_LENGTH_SIZE);
 349         $size = unpack($DATA_LENGTH_PACK, $size);
 350
 351         my $buffer;
 352         read( $fh, $buffer, $size);
 353
 354         return {
 355                 signature => $sig,
 356                 size => $size,
 357                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 358                 content => $buffer
 359         };
 360 }
 361
 362 sub _index_lookup {
 363         ##
 364         # Given index tag, lookup single entry in index and return .
 365         ##
 366         my $self = shift;
 367         my ($tag, $index) = @_;
 368
 369         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 370         if (!$location) { return; }
 371
 372         return $self->_load_tag( $location );
 373 }
 374
 375 sub _add_bucket {
 376         ##
 377         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 378         # plain (undigested) key and value.
 379         ##
 380         my $self = shift;
 381         my ($tag, $md5, $plain_key, $value) = @_;
 382         my $keys = $tag->{content};
 383         my $location = 0;
 384         my $result = 2;
 385
 386         # added ref() check first to avoid eval and runtime exception for every
 387         # scalar value being stored.  performance tweak.
 388     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 389
 390         my $internal_ref = $is_dbm_deep && ($value->_root eq $self->_root);
 391
 392     my $fh = $self->_fh;
 393
 394         ##
 395         # Iterate through buckets, seeing if this is a new entry or a replace.
 396         ##
 397         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 398                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 399                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 400                 if (!$subloc) {
 401                         ##
 402                         # Found empty bucket (end of list).  Populate and exit loop.
 403                         ##
 404                         $result = 2;
 405
 406             $location = $internal_ref
 407                 ? $value->_base_offset
 408                 : $self->_root->{end};
 409
 410                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 411                         print($fh $md5 . pack($LONG_PACK, $location) );
 412                         last;
 413                 }
 414                 elsif ($md5 eq $key) {
 415                         ##
 416                         # Found existing bucket with same key.  Replace with new value.
 417                         ##
 418                         $result = 1;
 419
 420                         if ($internal_ref) {
 421                                 $location = $value->_base_offset;
 422                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 423                                 print($fh $md5 . pack($LONG_PACK, $location) );
 424                         }
 425                         else {
 426                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 427                                 my $size;
 428                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 429
 430                                 ##
 431                                 # If value is a hash, array, or raw value with equal or less size, we can
 432                                 # reuse the same content area of the database.  Otherwise, we have to create
 433                                 # a new content area at the EOF.
 434                                 ##
 435                                 my $actual_length;
 436                 my $r = Scalar::Util::reftype( $value ) || '';
 437                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 438                         $actual_length = $INDEX_SIZE;
 439
 440                         # if autobless is enabled, must also take into consideration
 441                         # the class name, as it is stored along with key/value.
 442                         if ( $self->_root->{autobless} ) {
 443                                                 my $value_class = Scalar::Util::blessed($value);
 444                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 445                                                         $actual_length += length($value_class);
 446                                                 }
 447                                         } # autobless
 448                 }
 449                                 else { $actual_length = length($value); }
 450
 451                                 if ($actual_length <= $size) {
 452                                         $location = $subloc;
 453                                 }
 454                                 else {
 455                                         $location = $self->_root->{end};
 456                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $self->_root->{file_offset}, SEEK_SET);
 457                                         print($fh pack($LONG_PACK, $location) );
 458                                 }
 459                         }
 460                         last;
 461                 }
 462         } # i loop
 463
 464         ##
 465         # If this is an internal reference, return now.
 466         # No need to write value or plain key
 467         ##
 468         if ($internal_ref) {
 469         return $result;
 470     }
 471
 472         ##
 473         # If bucket didn't fit into list, split into a new index level
 474         ##
 475         if (!$location) {
 476                 seek($fh, $tag->{ref_loc} + $self->_root->{file_offset}, SEEK_SET);
 477                 print($fh pack($LONG_PACK, $self->_root->{end}) );
 478
 479                 my $index_tag = $self->_create_tag($self->_root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 480                 my @offsets = ();
 481
 482                 $keys .= $md5 . pack($LONG_PACK, 0);
 483
 484                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 485                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 486                         if ($key) {
 487                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 488                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 489
 490                                 if ($offsets[$num]) {
 491                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 492                                         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 493                                         my $subkeys;
 494                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 495
 496                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 497                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 498                                                 if (!$subloc) {
 499                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 500                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->_root->{end}) );
 501                                                         last;
 502                                                 }
 503                                         } # k loop
 504                                 }
 505                                 else {
 506                                         $offsets[$num] = $self->_root->{end};
 507                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 508                                         print($fh pack($LONG_PACK, $self->_root->{end}) );
 509
 510                                         my $blist_tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 511
 512                                         seek($fh, $blist_tag->{offset} + $self->_root->{file_offset}, SEEK_SET);
 513                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->_root->{end}) );
 514                                 }
 515                         } # key is real
 516                 } # i loop
 517
 518                 $location ||= $self->_root->{end};
 519         } # re-index bucket list
 520
 521         ##
 522         # Seek to content area and store signature, value and plaintext key
 523         ##
 524         if ($location) {
 525                 my $content_length;
 526                 seek($fh, $location + $self->_root->{file_offset}, SEEK_SET);
 527
 528                 ##
 529                 # Write signature based on content type, set content length and write actual value.
 530                 ##
 531         my $r = Scalar::Util::reftype($value) || '';
 532                 if ($r eq 'HASH') {
 533                         print($fh TYPE_HASH );
 534                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 535                         $content_length = $INDEX_SIZE;
 536                 }
 537                 elsif ($r eq 'ARRAY') {
 538                         print($fh TYPE_ARRAY );
 539                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 540                         $content_length = $INDEX_SIZE;
 541                 }
 542                 elsif (!defined($value)) {
 543                         print($fh SIG_NULL );
 544                         print($fh pack($DATA_LENGTH_PACK, 0) );
 545                         $content_length = 0;
 546                 }
 547                 else {
 548                         print($fh SIG_DATA );
 549                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 550                         $content_length = length($value);
 551                 }
 552
 553                 ##
 554                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 555                 ##
 556                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 557
 558                 ##
 559                 # If value is blessed, preserve class name
 560                 ##
 561                 if ( $self->_root->{autobless} ) {
 562             my $value_class = Scalar::Util::blessed($value);
 563             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 564                 ##
 565                 # Blessed ref -- will restore later
 566                 ##
 567                 print($fh chr(1) );
 568                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 569                 $content_length += 1;
 570                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 571             }
 572             else {
 573                 print($fh chr(0) );
 574                 $content_length += 1;
 575             }
 576         }
 577
 578                 ##
 579                 # If this is a new content area, advance EOF counter
 580                 ##
 581                 if ($location == $self->_root->{end}) {
 582                         $self->_root->{end} += SIG_SIZE;
 583                         $self->_root->{end} += $DATA_LENGTH_SIZE + $content_length;
 584                         $self->_root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 585                 }
 586
 587                 ##
 588                 # If content is a hash or array, create new child DBM::Deep object and
 589                 # pass each key or element to it.
 590                 ##
 591                 if ($r eq 'HASH') {
 592                         my $branch = DBM::Deep->new(
 593                                 type => TYPE_HASH,
 594                                 base_offset => $location,
 595                                 root => $self->_root,
 596                         );
 597                         foreach my $key (keys %{$value}) {
 598                 $branch->STORE( $key, $value->{$key} );
 599                         }
 600                 }
 601                 elsif ($r eq 'ARRAY') {
 602                         my $branch = DBM::Deep->new(
 603                                 type => TYPE_ARRAY,
 604                                 base_offset => $location,
 605                                 root => $self->_root,
 606                         );
 607                         my $index = 0;
 608                         foreach my $element (@{$value}) {
 609                 $branch->STORE( $index, $element );
 610                                 $index++;
 611                         }
 612                 }
 613
 614                 return $result;
 615         }
 616
 617         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 618 }
 619
 620 sub _get_bucket_value {
 621         ##
 622         # Fetch single value given tag and MD5 digested key.
 623         ##
 624         my $self = shift;
 625         my ($tag, $md5) = @_;
 626         my $keys = $tag->{content};
 627
 628     my $fh = $self->_fh;
 629
 630         ##
 631         # Iterate through buckets, looking for a key match
 632         ##
 633     BUCKET:
 634         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 635                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 636                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 637
 638                 if (!$subloc) {
 639                         ##
 640                         # Hit end of list, no match
 641                         ##
 642                         return;
 643                 }
 644
 645         if ( $md5 ne $key ) {
 646             next BUCKET;
 647         }
 648
 649         ##
 650         # Found match -- seek to offset and read signature
 651         ##
 652         my $signature;
 653         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 654         read( $fh, $signature, SIG_SIZE);
 655
 656         ##
 657         # If value is a hash or array, return new DBM::Deep object with correct offset
 658         ##
 659         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 660             my $obj = DBM::Deep->new(
 661                 type => $signature,
 662                 base_offset => $subloc,
 663                 root => $self->_root
 664             );
 665
 666             if ($self->_root->{autobless}) {
 667                 ##
 668                 # Skip over value and plain key to see if object needs
 669                 # to be re-blessed
 670                 ##
 671                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 672
 673                 my $size;
 674                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 675                 if ($size) { seek($fh, $size, SEEK_CUR); }
 676
 677                 my $bless_bit;
 678                 read( $fh, $bless_bit, 1);
 679                 if (ord($bless_bit)) {
 680                     ##
 681                     # Yes, object needs to be re-blessed
 682                     ##
 683                     my $class_name;
 684                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 685                     if ($size) { read( $fh, $class_name, $size); }
 686                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 687                 }
 688             }
 689
 690             return $obj;
 691         }
 692
 693         ##
 694         # Otherwise return actual value
 695         ##
 696         elsif ($signature eq SIG_DATA) {
 697             my $size;
 698             my $value = '';
 699             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 700             if ($size) { read( $fh, $value, $size); }
 701             return $value;
 702         }
 703
 704         ##
 705         # Key exists, but content is null
 706         ##
 707         else { return; }
 708         } # i loop
 709
 710         return;
 711 }
 712
 713 sub _delete_bucket {
 714         ##
 715         # Delete single key/value pair given tag and MD5 digested key.
 716         ##
 717         my $self = shift;
 718         my ($tag, $md5) = @_;
 719         my $keys = $tag->{content};
 720
 721     my $fh = $self->_fh;
 722
 723         ##
 724         # Iterate through buckets, looking for a key match
 725         ##
 726     BUCKET:
 727         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 728                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 729                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 730
 731                 if (!$subloc) {
 732                         ##
 733                         # Hit end of list, no match
 734                         ##
 735                         return;
 736                 }
 737
 738         if ( $md5 ne $key ) {
 739             next BUCKET;
 740         }
 741
 742         ##
 743         # Matched key -- delete bucket and return
 744         ##
 745         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 746         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 747         print($fh chr(0) x $BUCKET_SIZE );
 748
 749         return 1;
 750         } # i loop
 751
 752         return;
 753 }
 754
 755 sub _bucket_exists {
 756         ##
 757         # Check existence of single key given tag and MD5 digested key.
 758         ##
 759         my $self = shift;
 760         my ($tag, $md5) = @_;
 761         my $keys = $tag->{content};
 762
 763         ##
 764         # Iterate through buckets, looking for a key match
 765         ##
 766     BUCKET:
 767         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 768                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 769                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 770
 771                 if (!$subloc) {
 772                         ##
 773                         # Hit end of list, no match
 774                         ##
 775                         return;
 776                 }
 777
 778         if ( $md5 ne $key ) {
 779             next BUCKET;
 780         }
 781
 782         ##
 783         # Matched key -- return true
 784         ##
 785         return 1;
 786         } # i loop
 787
 788         return;
 789 }
 790
 791 sub _find_bucket_list {
 792         ##
 793         # Locate offset for bucket list, given digested key
 794         ##
 795         my $self = shift;
 796         my $md5 = shift;
 797
 798         ##
 799         # Locate offset for bucket list using digest index system
 800         ##
 801         my $ch = 0;
 802         my $tag = $self->_load_tag($self->_base_offset);
 803         if (!$tag) { return; }
 804
 805         while ($tag->{signature} ne SIG_BLIST) {
 806                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 807                 if (!$tag) { return; }
 808                 $ch++;
 809         }
 810
 811         return $tag;
 812 }
 813
 814 sub _traverse_index {
 815         ##
 816         # Scan index and recursively step into deeper levels, looking for next key.
 817         ##
 818     my ($self, $offset, $ch, $force_return_next) = @_;
 819     $force_return_next = undef unless $force_return_next;
 820
 821         my $tag = $self->_load_tag( $offset );
 822
 823     my $fh = $self->_fh;
 824
 825         if ($tag->{signature} ne SIG_BLIST) {
 826                 my $content = $tag->{content};
 827                 my $start;
 828                 if ($self->{return_next}) { $start = 0; }
 829                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 830
 831                 for (my $index = $start; $index < 256; $index++) {
 832                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 833                         if ($subloc) {
 834                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 835                                 if (defined($result)) { return $result; }
 836                         }
 837                 } # index loop
 838
 839                 $self->{return_next} = 1;
 840         } # tag is an index
 841
 842         elsif ($tag->{signature} eq SIG_BLIST) {
 843                 my $keys = $tag->{content};
 844                 if ($force_return_next) { $self->{return_next} = 1; }
 845
 846                 ##
 847                 # Iterate through buckets, looking for a key match
 848                 ##
 849                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 850                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 851                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 852
 853                         if (!$subloc) {
 854                                 ##
 855                                 # End of bucket list -- return to outer loop
 856                                 ##
 857                                 $self->{return_next} = 1;
 858                                 last;
 859                         }
 860                         elsif ($key eq $self->{prev_md5}) {
 861                                 ##
 862                                 # Located previous key -- return next one found
 863                                 ##
 864                                 $self->{return_next} = 1;
 865                                 next;
 866                         }
 867                         elsif ($self->{return_next}) {
 868                                 ##
 869                                 # Seek to bucket location and skip over signature
 870                                 ##
 871                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 872
 873                                 ##
 874                                 # Skip over value to get to plain key
 875                                 ##
 876                                 my $size;
 877                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 878                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 879
 880                                 ##
 881                                 # Read in plain key and return as scalar
 882                                 ##
 883                                 my $plain_key;
 884                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 885                                 if ($size) { read( $fh, $plain_key, $size); }
 886
 887                                 return $plain_key;
 888                         }
 889                 } # bucket loop
 890
 891                 $self->{return_next} = 1;
 892         } # tag is a bucket list
 893
 894         return;
 895 }
 896
 897 sub _get_next_key {
 898         ##
 899         # Locate next key, given digested previous one
 900         ##
 901     my $self = $_[0]->_get_self;
 902
 903         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 904         $self->{return_next} = 0;
 905
 906         ##
 907         # If the previous key was not specifed, start at the top and
 908         # return the first one found.
 909         ##
 910         if (!$self->{prev_md5}) {
 911                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 912                 $self->{return_next} = 1;
 913         }
 914
 915         return $self->_traverse_index( $self->_base_offset, 0 );
 916 }
 917
 918 sub lock {
 919         ##
 920         # If db locking is set, flock() the db file.  If called multiple
 921         # times before unlock(), then the same number of unlocks() must
 922         # be called before the lock is released.
 923         ##
 924     my $self = $_[0]->_get_self;
 925         my $type = $_[1];
 926     $type = LOCK_EX unless defined $type;
 927
 928         if (!defined($self->_fh)) { return; }
 929
 930         if ($self->_root->{locking}) {
 931                 if (!$self->_root->{locked}) {
 932                         flock($self->_fh, $type);
 933
 934                         # refresh end counter in case file has changed size
 935                         my @stats = stat($self->_root->{file});
 936                         $self->_root->{end} = $stats[7];
 937
 938                         # double-check file inode, in case another process
 939                         # has optimize()d our file while we were waiting.
 940                         if ($stats[1] != $self->_root->{inode}) {
 941                                 $self->_open(); # re-open
 942                                 flock($self->_fh, $type); # re-lock
 943                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 944                         }
 945                 }
 946                 $self->_root->{locked}++;
 947
 948         return 1;
 949         }
 950
 951     return;
 952 }
 953
 954 sub unlock {
 955         ##
 956         # If db locking is set, unlock the db file.  See note in lock()
 957         # regarding calling lock() multiple times.
 958         ##
 959     my $self = $_[0]->_get_self;
 960
 961         if (!defined($self->_fh)) { return; }
 962
 963         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 964                 $self->_root->{locked}--;
 965                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 966
 967         return 1;
 968         }
 969
 970     return;
 971 }
 972
 973 sub _copy_value {
 974     my $self = shift->_get_self;
 975     my ($spot, $value) = @_;
 976
 977     if ( !ref $value ) {
 978         ${$spot} = $value;
 979     }
 980     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 981         my $type = $value->_type;
 982         ${$spot} = $type eq TYPE_HASH ? {} : [];
 983         $value->_copy_node( ${$spot} );
 984     }
 985     else {
 986         my $r = Scalar::Util::reftype( $value );
 987         my $c = Scalar::Util::blessed( $value );
 988         if ( $r eq 'ARRAY' ) {
 989             ${$spot} = [ @{$value} ];
 990         }
 991         else {
 992             ${$spot} = { %{$value} };
 993         }
 994         ${$spot} = bless ${$spot}, $c
 995             if defined $c;
 996     }
 997
 998     return 1;
 999 }
1000
1001 sub _copy_node {
1002         ##
1003         # Copy single level of keys or elements to new DB handle.
1004         # Recurse for nested structures
1005         ##
1006     my $self = shift->_get_self;
1007         my ($db_temp) = @_;
1008
1009         if ($self->_type eq TYPE_HASH) {
1010                 my $key = $self->first_key();
1011                 while ($key) {
1012                         my $value = $self->get($key);
1013             $self->_copy_value( \$db_temp->{$key}, $value );
1014                         $key = $self->next_key($key);
1015                 }
1016         }
1017         else {
1018                 my $length = $self->length();
1019                 for (my $index = 0; $index < $length; $index++) {
1020                         my $value = $self->get($index);
1021             $self->_copy_value( \$db_temp->[$index], $value );
1022                 }
1023         }
1024
1025     return 1;
1026 }
1027
1028 sub export {
1029         ##
1030         # Recursively export into standard Perl hashes and arrays.
1031         ##
1032     my $self = $_[0]->_get_self;
1033
1034         my $temp;
1035         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1036         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1037
1038         $self->lock();
1039         $self->_copy_node( $temp );
1040         $self->unlock();
1041
1042         return $temp;
1043 }
1044
1045 sub import {
1046         ##
1047         # Recursively import Perl hash/array structure
1048         ##
1049     #XXX This use of ref() seems to be ok
1050         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1051
1052     my $self = $_[0]->_get_self;
1053         my $struct = $_[1];
1054
1055     #XXX This use of ref() seems to be ok
1056         if (!ref($struct)) {
1057                 ##
1058                 # struct is not a reference, so just import based on our type
1059                 ##
1060                 shift @_;
1061
1062                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1063                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1064         }
1065
1066     my $r = Scalar::Util::reftype($struct) || '';
1067         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1068                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1069         }
1070         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1071                 $self->push( @$struct );
1072         }
1073         else {
1074                 return $self->_throw_error("Cannot import: type mismatch");
1075         }
1076
1077         return 1;
1078 }
1079
1080 sub optimize {
1081         ##
1082         # Rebuild entire database into new file, then move
1083         # it back on top of original.
1084         ##
1085     my $self = $_[0]->_get_self;
1086
1087 #XXX Need to create a new test for this
1088 #       if ($self->_root->{links} > 1) {
1089 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1090 #       }
1091
1092         my $db_temp = DBM::Deep->new(
1093                 file => $self->_root->{file} . '.tmp',
1094                 type => $self->_type
1095         );
1096         if (!$db_temp) {
1097                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1098         }
1099
1100         $self->lock();
1101         $self->_copy_node( $db_temp );
1102         undef $db_temp;
1103
1104         ##
1105         # Attempt to copy user, group and permissions over to new file
1106         ##
1107         my @stats = stat($self->_fh);
1108         my $perms = $stats[2] & 07777;
1109         my $uid = $stats[4];
1110         my $gid = $stats[5];
1111         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1112         chmod( $perms, $self->_root->{file} . '.tmp' );
1113
1114     # q.v. perlport for more information on this variable
1115     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1116                 ##
1117                 # Potential race condition when optmizing on Win32 with locking.
1118                 # The Windows filesystem requires that the filehandle be closed
1119                 # before it is overwritten with rename().  This could be redone
1120                 # with a soft copy.
1121                 ##
1122                 $self->unlock();
1123                 $self->_close();
1124         }
1125
1126         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1127                 unlink $self->_root->{file} . '.tmp';
1128                 $self->unlock();
1129                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1130         }
1131
1132         $self->unlock();
1133         $self->_close();
1134         $self->_open();
1135
1136         return 1;
1137 }
1138
1139 sub clone {
1140         ##
1141         # Make copy of object and return
1142         ##
1143     my $self = $_[0]->_get_self;
1144
1145         return DBM::Deep->new(
1146                 type => $self->_type,
1147                 base_offset => $self->_base_offset,
1148                 root => $self->_root
1149         );
1150 }
1151
1152 {
1153     my %is_legal_filter = map {
1154         $_ => ~~1,
1155     } qw(
1156         store_key store_value
1157         fetch_key fetch_value
1158     );
1159
1160     sub set_filter {
1161         ##
1162         # Setup filter function for storing or fetching the key or value
1163         ##
1164         my $self = $_[0]->_get_self;
1165         my $type = lc $_[1];
1166         my $func = $_[2] ? $_[2] : undef;
1167
1168         if ( $is_legal_filter{$type} ) {
1169             $self->_root->{"filter_$type"} = $func;
1170             return 1;
1171         }
1172
1173         return;
1174     }
1175 }
1176
1177 ##
1178 # Accessor methods
1179 ##
1180
1181 sub _root {
1182         ##
1183         # Get access to the root structure
1184         ##
1185     my $self = $_[0]->_get_self;
1186         return $self->{root};
1187 }
1188
1189 sub _fh {
1190         ##
1191         # Get access to the raw fh
1192         ##
1193     #XXX It will be useful, though, when we split out HASH and ARRAY
1194     my $self = $_[0]->_get_self;
1195         return $self->_root->{fh};
1196 }
1197
1198 sub _type {
1199         ##
1200         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1201         ##
1202     my $self = $_[0]->_get_self;
1203         return $self->{type};
1204 }
1205
1206 sub _base_offset {
1207         ##
1208         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1209         ##
1210     my $self = $_[0]->_get_self;
1211         return $self->{base_offset};
1212 }
1213
1214 sub error {
1215         ##
1216         # Get last error string, or undef if no error
1217         ##
1218         return $_[0]
1219         #? ( _get_self($_[0])->{root}->{error} or undef )
1220         ? ( $_[0]->_get_self->{root}->{error} or undef )
1221         : $@;
1222 }
1223
1224 ##
1225 # Utility methods
1226 ##
1227
1228 sub _throw_error {
1229         ##
1230         # Store error string in self
1231         ##
1232         my $error_text = $_[1];
1233
1234     if ( Scalar::Util::blessed $_[0] ) {
1235         my $self = $_[0]->_get_self;
1236         $self->_root->{error} = $error_text;
1237
1238         unless ($self->_root->{debug}) {
1239             die "DBM::Deep: $error_text\n";
1240         }
1241
1242         warn "DBM::Deep: $error_text\n";
1243         return;
1244     }
1245     else {
1246         die "DBM::Deep: $error_text\n";
1247     }
1248 }
1249
1250 sub clear_error {
1251         ##
1252         # Clear error state
1253         ##
1254     my $self = $_[0]->_get_self;
1255
1256         undef $self->_root->{error};
1257 }
1258
1259 sub _precalc_sizes {
1260         ##
1261         # Precalculate index, bucket and bucket list sizes
1262         ##
1263
1264     #XXX I don't like this ...
1265     set_pack() unless defined $LONG_SIZE;
1266
1267         $INDEX_SIZE = 256 * $LONG_SIZE;
1268         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1269         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1270 }
1271
1272 sub set_pack {
1273         ##
1274         # Set pack/unpack modes (see file header for more)
1275         ##
1276     my ($long_s, $long_p, $data_s, $data_p) = @_;
1277
1278     $LONG_SIZE = $long_s ? $long_s : 4;
1279     $LONG_PACK = $long_p ? $long_p : 'N';
1280
1281     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1282     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1283
1284         _precalc_sizes();
1285 }
1286
1287 sub set_digest {
1288         ##
1289         # Set key digest function (default is MD5)
1290         ##
1291     my ($digest_func, $hash_size) = @_;
1292
1293     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1294     $HASH_SIZE = $hash_size ? $hash_size : 16;
1295
1296         _precalc_sizes();
1297 }
1298
1299 ##
1300 # tie() methods (hashes and arrays)
1301 ##
1302
1303 sub STORE {
1304         ##
1305         # Store single hash key/value or array element in database.
1306         ##
1307     my $self = $_[0]->_get_self;
1308         my $key = $_[1];
1309
1310     # User may be storing a hash, in which case we do not want it run
1311     # through the filtering system
1312         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1313         ? $self->_root->{filter_store_value}->($_[2])
1314         : $_[2];
1315
1316         my $md5 = $DIGEST_FUNC->($key);
1317
1318         ##
1319         # Make sure file is open
1320         ##
1321         if (!defined($self->_fh) && !$self->_open()) {
1322                 return;
1323         }
1324         ##
1325
1326         ##
1327         # Request exclusive lock for writing
1328         ##
1329         $self->lock( LOCK_EX );
1330
1331         my $fh = $self->_fh;
1332
1333         ##
1334         # Locate offset for bucket list using digest index system
1335         ##
1336         my $tag = $self->_load_tag($self->_base_offset);
1337         if (!$tag) {
1338                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1339         }
1340
1341         my $ch = 0;
1342         while ($tag->{signature} ne SIG_BLIST) {
1343                 my $num = ord(substr($md5, $ch, 1));
1344                 my $new_tag = $self->_index_lookup($tag, $num);
1345                 if (!$new_tag) {
1346                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1347                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1348                         print($fh pack($LONG_PACK, $self->_root->{end}) );
1349
1350                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1351                         $tag->{ref_loc} = $ref_loc;
1352                         $tag->{ch} = $ch;
1353                         last;
1354                 }
1355                 else {
1356                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1357                         $tag = $new_tag;
1358                         $tag->{ref_loc} = $ref_loc;
1359                         $tag->{ch} = $ch;
1360                 }
1361                 $ch++;
1362         }
1363
1364         ##
1365         # Add key/value to bucket list
1366         ##
1367         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1368
1369         $self->unlock();
1370
1371         return $result;
1372 }
1373
1374 sub FETCH {
1375         ##
1376         # Fetch single value or element given plain key or array index
1377         ##
1378     my $self = shift->_get_self;
1379     my $key = shift;
1380
1381         ##
1382         # Make sure file is open
1383         ##
1384         if (!defined($self->_fh)) { $self->_open(); }
1385
1386         my $md5 = $DIGEST_FUNC->($key);
1387
1388         ##
1389         # Request shared lock for reading
1390         ##
1391         $self->lock( LOCK_SH );
1392
1393         my $tag = $self->_find_bucket_list( $md5 );
1394         if (!$tag) {
1395                 $self->unlock();
1396                 return;
1397         }
1398
1399         ##
1400         # Get value from bucket list
1401         ##
1402         my $result = $self->_get_bucket_value( $tag, $md5 );
1403
1404         $self->unlock();
1405
1406     #XXX What is ref() checking here?
1407     #YYY Filters only apply on scalar values, so the ref check is making
1408     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1409         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1410         ? $self->_root->{filter_fetch_value}->($result)
1411         : $result;
1412 }
1413
1414 sub DELETE {
1415         ##
1416         # Delete single key/value pair or element given plain key or array index
1417         ##
1418     my $self = $_[0]->_get_self;
1419         my $key = $_[1];
1420
1421         my $md5 = $DIGEST_FUNC->($key);
1422
1423         ##
1424         # Make sure file is open
1425         ##
1426         if (!defined($self->_fh)) { $self->_open(); }
1427
1428         ##
1429         # Request exclusive lock for writing
1430         ##
1431         $self->lock( LOCK_EX );
1432
1433         my $tag = $self->_find_bucket_list( $md5 );
1434         if (!$tag) {
1435                 $self->unlock();
1436                 return;
1437         }
1438
1439         ##
1440         # Delete bucket
1441         ##
1442     my $value = $self->_get_bucket_value( $tag, $md5 );
1443         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1444         $value = $self->_root->{filter_fetch_value}->($value);
1445     }
1446
1447         my $result = $self->_delete_bucket( $tag, $md5 );
1448
1449         ##
1450         # If this object is an array and the key deleted was on the end of the stack,
1451         # decrement the length variable.
1452         ##
1453
1454         $self->unlock();
1455
1456         return $value;
1457 }
1458
1459 sub EXISTS {
1460         ##
1461         # Check if a single key or element exists given plain key or array index
1462         ##
1463     my $self = $_[0]->_get_self;
1464         my $key = $_[1];
1465
1466         my $md5 = $DIGEST_FUNC->($key);
1467
1468         ##
1469         # Make sure file is open
1470         ##
1471         if (!defined($self->_fh)) { $self->_open(); }
1472
1473         ##
1474         # Request shared lock for reading
1475         ##
1476         $self->lock( LOCK_SH );
1477
1478         my $tag = $self->_find_bucket_list( $md5 );
1479
1480         ##
1481         # For some reason, the built-in exists() function returns '' for false
1482         ##
1483         if (!$tag) {
1484                 $self->unlock();
1485                 return '';
1486         }
1487
1488         ##
1489         # Check if bucket exists and return 1 or ''
1490         ##
1491         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1492
1493         $self->unlock();
1494
1495         return $result;
1496 }
1497
1498 sub CLEAR {
1499         ##
1500         # Clear all keys from hash, or all elements from array.
1501         ##
1502     my $self = $_[0]->_get_self;
1503
1504         ##
1505         # Make sure file is open
1506         ##
1507         if (!defined($self->_fh)) { $self->_open(); }
1508
1509         ##
1510         # Request exclusive lock for writing
1511         ##
1512         $self->lock( LOCK_EX );
1513
1514     my $fh = $self->_fh;
1515
1516         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1517         if (eof $fh) {
1518                 $self->unlock();
1519                 return;
1520         }
1521
1522         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1523
1524         $self->unlock();
1525
1526         return 1;
1527 }
1528
1529 ##
1530 # Public method aliases
1531 ##
1532 sub put { (shift)->STORE( @_ ) }
1533 sub store { (shift)->STORE( @_ ) }
1534 sub get { (shift)->FETCH( @_ ) }
1535 sub fetch { (shift)->FETCH( @_ ) }
1536 sub delete { (shift)->DELETE( @_ ) }
1537 sub exists { (shift)->EXISTS( @_ ) }
1538 sub clear { (shift)->CLEAR( @_ ) }
1539
1540 package DBM::Deep::_::Root;
1541
1542 sub new {
1543     my $class = shift;
1544     my ($args) = @_;
1545
1546     my $self = bless {
1547         file => undef,
1548         fh => undef,
1549         file_offset => 0,
1550         end => 0,
1551         autoflush => undef,
1552         locking => undef,
1553         debug => undef,
1554         filter_store_key => undef,
1555         filter_store_value => undef,
1556         filter_fetch_key => undef,
1557         filter_fetch_value => undef,
1558         autobless => undef,
1559         locked => 0,
1560         %$args,
1561     }, $class;
1562
1563     if ( $self->{fh} && !$self->{file_offset} ) {
1564         $self->{file_offset} = tell( $self->{fh} );
1565     }
1566
1567     return $self;
1568 }
1569
1570 sub DESTROY {
1571     my $self = shift;
1572     return unless $self;
1573
1574     close $self->{fh} if $self->{fh};
1575
1576     return;
1577 }
1578
1579 1;
1580
1581 __END__
1582
1583 =head1 NAME
1584
1585 DBM::Deep - A pure perl multi-level hash/array DBM
1586
1587 =head1 SYNOPSIS
1588
1589   use DBM::Deep;
1590   my $db = DBM::Deep->new( "foo.db" );
1591
1592   $db->{key} = 'value'; # tie() style
1593   print $db->{key};
1594
1595   $db->put('key' => 'value'); # OO style
1596   print $db->get('key');
1597
1598   # true multi-level support
1599   $db->{my_complex} = [
1600         'hello', { perl => 'rules' },
1601         42, 99,
1602   ];
1603
1604 =head1 DESCRIPTION
1605
1606 A unique flat-file database module, written in pure perl.  True
1607 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1608 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1609 handle millions of keys and unlimited hash levels without significant
1610 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1611 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1612 Mac OS X and Windows.
1613
1614 =head1 INSTALLATION
1615
1616 Hopefully you are using Perl's excellent CPAN module, which will download
1617 and install the module for you.  If not, get the tarball, and run these
1618 commands:
1619
1620         tar zxf DBM-Deep-*
1621         cd DBM-Deep-*
1622         perl Makefile.PL
1623         make
1624         make test
1625         make install
1626
1627 =head1 SETUP
1628
1629 Construction can be done OO-style (which is the recommended way), or using
1630 Perl's tie() function.  Both are examined here.
1631
1632 =head2 OO CONSTRUCTION
1633
1634 The recommended way to construct a DBM::Deep object is to use the new()
1635 method, which gets you a blessed, tied hash or array reference.
1636
1637         my $db = DBM::Deep->new( "foo.db" );
1638
1639 This opens a new database handle, mapped to the file "foo.db".  If this
1640 file does not exist, it will automatically be created.  DB files are
1641 opened in "r+" (read/write) mode, and the type of object returned is a
1642 hash, unless otherwise specified (see L<OPTIONS> below).
1643
1644 You can pass a number of options to the constructor to specify things like
1645 locking, autoflush, etc.  This is done by passing an inline hash:
1646
1647         my $db = DBM::Deep->new(
1648                 file => "foo.db",
1649                 locking => 1,
1650                 autoflush => 1
1651         );
1652
1653 Notice that the filename is now specified I<inside> the hash with
1654 the "file" parameter, as opposed to being the sole argument to the
1655 constructor.  This is required if any options are specified.
1656 See L<OPTIONS> below for the complete list.
1657
1658
1659
1660 You can also start with an array instead of a hash.  For this, you must
1661 specify the C<type> parameter:
1662
1663         my $db = DBM::Deep->new(
1664                 file => "foo.db",
1665                 type => DBM::Deep->TYPE_ARRAY
1666         );
1667
1668 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1669 a new DB file.  If you create a DBM::Deep object with an existing file, the
1670 C<type> will be loaded from the file header, and an error will be thrown if
1671 the wrong type is passed in.
1672
1673 =head2 TIE CONSTRUCTION
1674
1675 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1676 tie() function.  The object returned from tie() can be used to call methods,
1677 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1678 file (as expected with most tie'd objects).
1679
1680         my %hash;
1681         my $db = tie %hash, "DBM::Deep", "foo.db";
1682
1683         my @array;
1684         my $db = tie @array, "DBM::Deep", "bar.db";
1685
1686 As with the OO constructor, you can replace the DB filename parameter with
1687 a hash containing one or more options (see L<OPTIONS> just below for the
1688 complete list).
1689
1690         tie %hash, "DBM::Deep", {
1691                 file => "foo.db",
1692                 locking => 1,
1693                 autoflush => 1
1694         };
1695
1696 =head2 OPTIONS
1697
1698 There are a number of options that can be passed in when constructing your
1699 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1700
1701 =over
1702
1703 =item * file
1704
1705 Filename of the DB file to link the handle to.  You can pass a full absolute
1706 filesystem path, partial path, or a plain filename if the file is in the
1707 current working directory.  This is a required parameter (though q.v. fh).
1708
1709 =item * fh
1710
1711 If you want, you can pass in the fh instead of the file. This is most useful for doing
1712 something like:
1713
1714   my $db = DBM::Deep->new( { fh => \*DATA } );
1715
1716 You are responsible for making sure that the fh has been opened appropriately for your
1717 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1718 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1719 needs to read from the fh.
1720
1721 =item * file_offset
1722
1723 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1724 not need to set this. However, it's there if you want it.
1725
1726 If you pass in fh and do not set this, it will be set appropriately.
1727
1728 =item * type
1729
1730 This parameter specifies what type of object to create, a hash or array.  Use
1731 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1732 This only takes effect when beginning a new file.  This is an optional
1733 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1734
1735 =item * locking
1736
1737 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1738 function to lock the database in exclusive mode for writes, and shared mode for
1739 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1740 any child hashes or arrays> that use the same DB file.  This is an optional
1741 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1742
1743 =item * autoflush
1744
1745 Specifies whether autoflush is to be enabled on the underlying filehandle.
1746 This obviously slows down write operations, but is required if you may have
1747 multiple processes accessing the same DB file (also consider enable I<locking>).
1748 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1749 (disabled).
1750
1751 =item * autobless
1752
1753 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1754 restore them when fetched.  This is an B<experimental> feature, and does have
1755 side-effects.  Basically, when hashes are re-blessed into their original
1756 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1757 able to call any DBM::Deep methods on them.  You have been warned.
1758 This is an optional parameter, and defaults to 0 (disabled).
1759
1760 =item * filter_*
1761
1762 See L<FILTERS> below.
1763
1764 =item * debug
1765
1766 Setting I<debug> mode will make all errors non-fatal, dump them out to
1767 STDERR, and continue on.  This is for debugging purposes only, and probably
1768 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1769
1770 =item * fh
1771
1772 Instead of passing a file path, you can instead pass a handle to an pre-opened
1773 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1774 contains your entire Perl script, as well as the data following the __DATA__
1775 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1776 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1777 in that.  Also please note optimize() will NOT work when passing in only a
1778 handle.  Pass in a real filename in order to use optimize().
1779
1780 =back
1781
1782 =head1 TIE INTERFACE
1783
1784 With DBM::Deep you can access your databases using Perl's standard hash/array
1785 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1786 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1787 to the right place -- the DB file.  This has nothing to do with the
1788 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1789 using regular hashes and arrays, rather than calling functions like C<get()>
1790 and C<put()> (although those work too).  It is entirely up to you how to want
1791 to access your databases.
1792
1793 =head2 HASHES
1794
1795 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1796 or even nested hashes (or arrays) using standard Perl syntax:
1797
1798         my $db = DBM::Deep->new( "foo.db" );
1799
1800         $db->{mykey} = "myvalue";
1801         $db->{myhash} = {};
1802         $db->{myhash}->{subkey} = "subvalue";
1803
1804         print $db->{myhash}->{subkey} . "\n";
1805
1806 You can even step through hash keys using the normal Perl C<keys()> function:
1807
1808         foreach my $key (keys %$db) {
1809                 print "$key: " . $db->{$key} . "\n";
1810         }
1811
1812 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1813 pushes them onto an array, all before the loop even begins.  If you have an
1814 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1815 Perl's C<each()> function, which pulls keys/values one at a time, using very
1816 little memory:
1817
1818         while (my ($key, $value) = each %$db) {
1819                 print "$key: $value\n";
1820         }
1821
1822 Please note that when using C<each()>, you should always pass a direct
1823 hash reference, not a lookup.  Meaning, you should B<never> do this:
1824
1825         # NEVER DO THIS
1826         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1827
1828 This causes an infinite loop, because for each iteration, Perl is calling
1829 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1830 it effectively keeps returning the first key over and over again. Instead,
1831 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1832
1833 =head2 ARRAYS
1834
1835 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1836 reference.  This includes inserting, removing and manipulating elements,
1837 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1838 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1839 or simply be a nested array reference inside a hash.  Example:
1840
1841         my $db = DBM::Deep->new(
1842                 file => "foo-array.db",
1843                 type => DBM::Deep->TYPE_ARRAY
1844         );
1845
1846         $db->[0] = "foo";
1847         push @$db, "bar", "baz";
1848         unshift @$db, "bah";
1849
1850         my $last_elem = pop @$db; # baz
1851         my $first_elem = shift @$db; # bah
1852         my $second_elem = $db->[1]; # bar
1853
1854         my $num_elements = scalar @$db;
1855
1856 =head1 OO INTERFACE
1857
1858 In addition to the I<tie()> interface, you can also use a standard OO interface
1859 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1860 array) has its own methods, but both types share the following common methods:
1861 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1862
1863 =over
1864
1865 =item * new() / clone()
1866
1867 These are the constructor and copy-functions.
1868
1869 =item * put() / store()
1870
1871 Stores a new hash key/value pair, or sets an array element value.  Takes two
1872 arguments, the hash key or array index, and the new value.  The value can be
1873 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1874
1875         $db->put("foo", "bar"); # for hashes
1876         $db->put(1, "bar"); # for arrays
1877
1878 =item * get() / fetch()
1879
1880 Fetches the value of a hash key or array element.  Takes one argument: the hash
1881 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1882 data type stored.
1883
1884         my $value = $db->get("foo"); # for hashes
1885         my $value = $db->get(1); # for arrays
1886
1887 =item * exists()
1888
1889 Checks if a hash key or array index exists.  Takes one argument: the hash key
1890 or array index.  Returns true if it exists, false if not.
1891
1892         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1893         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1894
1895 =item * delete()
1896
1897 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1898 key or array index.  Returns true on success, false if not found.  For arrays,
1899 the remaining elements located after the deleted element are NOT moved over.
1900 The deleted element is essentially just undefined, which is exactly how Perl's
1901 internal arrays work.  Please note that the space occupied by the deleted
1902 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1903 below for details and workarounds.
1904
1905         $db->delete("foo"); # for hashes
1906         $db->delete(1); # for arrays
1907
1908 =item * clear()
1909
1910 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1911 value.  Please note that the space occupied by the deleted keys/values or
1912 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1913 details and workarounds.
1914
1915         $db->clear(); # hashes or arrays
1916
1917 =item * lock() / unlock()
1918
1919 q.v. Locking.
1920
1921 =item * optimize()
1922
1923 Recover lost disk space.
1924
1925 =item * import() / export()
1926
1927 Data going in and out.
1928
1929 =item * set_digest() / set_pack() / set_filter()
1930
1931 q.v. adjusting the interal parameters.
1932
1933 =item * error() / clear_error()
1934
1935 Error handling methods (may be deprecated).
1936 .
1937 =back
1938
1939 =head2 HASHES
1940
1941 For hashes, DBM::Deep supports all the common methods described above, and the
1942 following additional methods: C<first_key()> and C<next_key()>.
1943
1944 =over
1945
1946 =item * first_key()
1947
1948 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1949 fetched in an undefined order (which appears random).  Takes no arguments,
1950 returns the key as a scalar value.
1951
1952         my $key = $db->first_key();
1953
1954 =item * next_key()
1955
1956 Returns the "next" key in the hash, given the previous one as the sole argument.
1957 Returns undef if there are no more keys to be fetched.
1958
1959         $key = $db->next_key($key);
1960
1961 =back
1962
1963 Here are some examples of using hashes:
1964
1965         my $db = DBM::Deep->new( "foo.db" );
1966
1967         $db->put("foo", "bar");
1968         print "foo: " . $db->get("foo") . "\n";
1969
1970         $db->put("baz", {}); # new child hash ref
1971         $db->get("baz")->put("buz", "biz");
1972         print "buz: " . $db->get("baz")->get("buz") . "\n";
1973
1974         my $key = $db->first_key();
1975         while ($key) {
1976                 print "$key: " . $db->get($key) . "\n";
1977                 $key = $db->next_key($key);
1978         }
1979
1980         if ($db->exists("foo")) { $db->delete("foo"); }
1981
1982 =head2 ARRAYS
1983
1984 For arrays, DBM::Deep supports all the common methods described above, and the
1985 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1986 C<unshift()> and C<splice()>.
1987
1988 =over
1989
1990 =item * length()
1991
1992 Returns the number of elements in the array.  Takes no arguments.
1993
1994         my $len = $db->length();
1995
1996 =item * push()
1997
1998 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1999 refs or array refs.  No return value.
2000
2001         $db->push("foo", "bar", {});
2002
2003 =item * pop()
2004
2005 Fetches the last element in the array, and deletes it.  Takes no arguments.
2006 Returns undef if array is empty.  Returns the element value.
2007
2008         my $elem = $db->pop();
2009
2010 =item * shift()
2011
2012 Fetches the first element in the array, deletes it, then shifts all the
2013 remaining elements over to take up the space.  Returns the element value.  This
2014 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2015 details.
2016
2017         my $elem = $db->shift();
2018
2019 =item * unshift()
2020
2021 Inserts one or more elements onto the beginning of the array, shifting all
2022 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2023 No return value.  This method is not recommended with large arrays -- see
2024 <LARGE ARRAYS> below for details.
2025
2026         $db->unshift("foo", "bar", {});
2027
2028 =item * splice()
2029
2030 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2031 -f splice> for usage -- it is too complicated to document here.  This method is
2032 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2033
2034 =back
2035
2036 Here are some examples of using arrays:
2037
2038         my $db = DBM::Deep->new(
2039                 file => "foo.db",
2040                 type => DBM::Deep->TYPE_ARRAY
2041         );
2042
2043         $db->push("bar", "baz");
2044         $db->unshift("foo");
2045         $db->put(3, "buz");
2046
2047         my $len = $db->length();
2048         print "length: $len\n"; # 4
2049
2050         for (my $k=0; $k<$len; $k++) {
2051                 print "$k: " . $db->get($k) . "\n";
2052         }
2053
2054         $db->splice(1, 2, "biz", "baf");
2055
2056         while (my $elem = shift @$db) {
2057                 print "shifted: $elem\n";
2058         }
2059
2060 =head1 LOCKING
2061
2062 Enable automatic file locking by passing a true value to the C<locking>
2063 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2064
2065         my $db = DBM::Deep->new(
2066                 file => "foo.db",
2067                 locking => 1
2068         );
2069
2070 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2071 mode for writes, and shared mode for reads.  This is required if you have
2072 multiple processes accessing the same database file, to avoid file corruption.
2073 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2074 NFS> below for more.
2075
2076 =head2 EXPLICIT LOCKING
2077
2078 You can explicitly lock a database, so it remains locked for multiple
2079 transactions.  This is done by calling the C<lock()> method, and passing an
2080 optional lock mode argument (defaults to exclusive mode).  This is particularly
2081 useful for things like counters, where the current value needs to be fetched,
2082 then incremented, then stored again.
2083
2084         $db->lock();
2085         my $counter = $db->get("counter");
2086         $counter++;
2087         $db->put("counter", $counter);
2088         $db->unlock();
2089
2090         # or...
2091
2092         $db->lock();
2093         $db->{counter}++;
2094         $db->unlock();
2095
2096 You can pass C<lock()> an optional argument, which specifies which mode to use
2097 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2098 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2099 same as the constants defined in Perl's C<Fcntl> module.
2100
2101         $db->lock( DBM::Deep->LOCK_SH );
2102         # something here
2103         $db->unlock();
2104
2105 =head1 IMPORTING/EXPORTING
2106
2107 You can import existing complex structures by calling the C<import()> method,
2108 and export an entire database into an in-memory structure using the C<export()>
2109 method.  Both are examined here.
2110
2111 =head2 IMPORTING
2112
2113 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2114 walking the structure and adding keys/elements to the database as you go,
2115 simply pass a reference to the C<import()> method.  This recursively adds
2116 everything to an existing DBM::Deep object for you.  Here is an example:
2117
2118         my $struct = {
2119                 key1 => "value1",
2120                 key2 => "value2",
2121                 array1 => [ "elem0", "elem1", "elem2" ],
2122                 hash1 => {
2123                         subkey1 => "subvalue1",
2124                         subkey2 => "subvalue2"
2125                 }
2126         };
2127
2128         my $db = DBM::Deep->new( "foo.db" );
2129         $db->import( $struct );
2130
2131         print $db->{key1} . "\n"; # prints "value1"
2132
2133 This recursively imports the entire C<$struct> object into C<$db>, including
2134 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2135 keys are merged with the existing ones, replacing if they already exist.
2136 The C<import()> method can be called on any database level (not just the base
2137 level), and works with both hash and array DB types.
2138
2139 B<Note:> Make sure your existing structure has no circular references in it.
2140 These will cause an infinite loop when importing.
2141
2142 =head2 EXPORTING
2143
2144 Calling the C<export()> method on an existing DBM::Deep object will return
2145 a reference to a new in-memory copy of the database.  The export is done
2146 recursively, so all nested hashes/arrays are all exported to standard Perl
2147 objects.  Here is an example:
2148
2149         my $db = DBM::Deep->new( "foo.db" );
2150
2151         $db->{key1} = "value1";
2152         $db->{key2} = "value2";
2153         $db->{hash1} = {};
2154         $db->{hash1}->{subkey1} = "subvalue1";
2155         $db->{hash1}->{subkey2} = "subvalue2";
2156
2157         my $struct = $db->export();
2158
2159         print $struct->{key1} . "\n"; # prints "value1"
2160
2161 This makes a complete copy of the database in memory, and returns a reference
2162 to it.  The C<export()> method can be called on any database level (not just
2163 the base level), and works with both hash and array DB types.  Be careful of
2164 large databases -- you can store a lot more data in a DBM::Deep object than an
2165 in-memory Perl structure.
2166
2167 B<Note:> Make sure your database has no circular references in it.
2168 These will cause an infinite loop when exporting.
2169
2170 =head1 FILTERS
2171
2172 DBM::Deep has a number of hooks where you can specify your own Perl function
2173 to perform filtering on incoming or outgoing data.  This is a perfect
2174 way to extend the engine, and implement things like real-time compression or
2175 encryption.  Filtering applies to the base DB level, and all child hashes /
2176 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2177 constructed, or by calling the C<set_filter()> method at any time.  There are
2178 four available filter hooks, described below:
2179
2180 =over
2181
2182 =item * filter_store_key
2183
2184 This filter is called whenever a hash key is stored.  It
2185 is passed the incoming key, and expected to return a transformed key.
2186
2187 =item * filter_store_value
2188
2189 This filter is called whenever a hash key or array element is stored.  It
2190 is passed the incoming value, and expected to return a transformed value.
2191
2192 =item * filter_fetch_key
2193
2194 This filter is called whenever a hash key is fetched (i.e. via
2195 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2196 and expected to return the plain key.
2197
2198 =item * filter_fetch_value
2199
2200 This filter is called whenever a hash key or array element is fetched.
2201 It is passed the transformed value, and expected to return the plain value.
2202
2203 =back
2204
2205 Here are the two ways to setup a filter hook:
2206
2207         my $db = DBM::Deep->new(
2208                 file => "foo.db",
2209                 filter_store_value => \&my_filter_store,
2210                 filter_fetch_value => \&my_filter_fetch
2211         );
2212
2213         # or...
2214
2215         $db->set_filter( "filter_store_value", \&my_filter_store );
2216         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2217
2218 Your filter function will be called only when dealing with SCALAR keys or
2219 values.  When nested hashes and arrays are being stored/fetched, filtering
2220 is bypassed.  Filters are called as static functions, passed a single SCALAR
2221 argument, and expected to return a single SCALAR value.  If you want to
2222 remove a filter, set the function reference to C<undef>:
2223
2224         $db->set_filter( "filter_store_value", undef );
2225
2226 =head2 REAL-TIME ENCRYPTION EXAMPLE
2227
2228 Here is a working example that uses the I<Crypt::Blowfish> module to
2229 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2230 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2231 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2232
2233         use DBM::Deep;
2234         use Crypt::Blowfish;
2235         use Crypt::CBC;
2236
2237         my $cipher = Crypt::CBC->new({
2238                 'key'             => 'my secret key',
2239                 'cipher'          => 'Blowfish',
2240                 'iv'              => '$KJh#(}q',
2241                 'regenerate_key'  => 0,
2242                 'padding'         => 'space',
2243                 'prepend_iv'      => 0
2244         });
2245
2246         my $db = DBM::Deep->new(
2247                 file => "foo-encrypt.db",
2248                 filter_store_key => \&my_encrypt,
2249                 filter_store_value => \&my_encrypt,
2250                 filter_fetch_key => \&my_decrypt,
2251                 filter_fetch_value => \&my_decrypt,
2252         );
2253
2254         $db->{key1} = "value1";
2255         $db->{key2} = "value2";
2256         print "key1: " . $db->{key1} . "\n";
2257         print "key2: " . $db->{key2} . "\n";
2258
2259         undef $db;
2260         exit;
2261
2262         sub my_encrypt {
2263                 return $cipher->encrypt( $_[0] );
2264         }
2265         sub my_decrypt {
2266                 return $cipher->decrypt( $_[0] );
2267         }
2268
2269 =head2 REAL-TIME COMPRESSION EXAMPLE
2270
2271 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2272 compression / decompression of keys & values with DBM::Deep Filters.
2273 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2274 more on I<Compress::Zlib>.
2275
2276         use DBM::Deep;
2277         use Compress::Zlib;
2278
2279         my $db = DBM::Deep->new(
2280                 file => "foo-compress.db",
2281                 filter_store_key => \&my_compress,
2282                 filter_store_value => \&my_compress,
2283                 filter_fetch_key => \&my_decompress,
2284                 filter_fetch_value => \&my_decompress,
2285         );
2286
2287         $db->{key1} = "value1";
2288         $db->{key2} = "value2";
2289         print "key1: " . $db->{key1} . "\n";
2290         print "key2: " . $db->{key2} . "\n";
2291
2292         undef $db;
2293         exit;
2294
2295         sub my_compress {
2296                 return Compress::Zlib::memGzip( $_[0] ) ;
2297         }
2298         sub my_decompress {
2299                 return Compress::Zlib::memGunzip( $_[0] ) ;
2300         }
2301
2302 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2303 actually numerical index numbers, and are not filtered.
2304
2305 =head1 ERROR HANDLING
2306
2307 Most DBM::Deep methods return a true value for success, and call die() on
2308 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2309 actual error message is stored in an internal scalar, which can be fetched by
2310 calling the C<error()> method.
2311
2312         my $db = DBM::Deep->new( "foo.db" ); # create hash
2313         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2314
2315     print $@;           # prints error message
2316         print $db->error(); # prints error message
2317
2318 You can then call C<clear_error()> to clear the current error state.
2319
2320         $db->clear_error();
2321
2322 If you set the C<debug> option to true when creating your DBM::Deep object,
2323 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2324 be used for debugging purposes and not production work. DBM::Deep expects errors
2325 to be thrown, not propagated back up the stack.
2326
2327 =head1 LARGEFILE SUPPORT
2328
2329 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2330 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2331 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2332 by calling the static C<set_pack()> method before you do anything else.
2333
2334         DBM::Deep::set_pack(8, 'Q');
2335
2336 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2337 instead of 32-bit longs.  After setting these values your DB files have a
2338 theoretical maximum size of 16 XB (exabytes).
2339
2340 B<Note:> Changing these values will B<NOT> work for existing database files.
2341 Only change this for new files, and make sure it stays set consistently
2342 throughout the file's life.  If you do set these values, you can no longer
2343 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2344 back to 32-bit mode.
2345
2346 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2347 only a 32-bit Perl.  However, I have received user reports that this does
2348 indeed work!
2349
2350 =head1 LOW-LEVEL ACCESS
2351
2352 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2353 you can call the C<_fh()> method, which returns the handle:
2354
2355         my $fh = $db->_fh();
2356
2357 This method can be called on the root level of the datbase, or any child
2358 hashes or arrays.  All levels share a I<root> structure, which contains things
2359 like the filehandle, a reference counter, and all the options specified
2360 when you created the object.  You can get access to this root structure by
2361 calling the C<root()> method.
2362
2363         my $root = $db->_root();
2364
2365 This is useful for changing options after the object has already been created,
2366 such as enabling/disabling locking, or debug modes.  You can also
2367 store your own temporary user data in this structure (be wary of name
2368 collision), which is then accessible from any child hash or array.
2369
2370 =head1 CUSTOM DIGEST ALGORITHM
2371
2372 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2373 keys.  However you can override this, and use another algorithm (such as SHA-256)
2374 or even write your own.  But please note that DBM::Deep currently expects zero
2375 collisions, so your algorithm has to be I<perfect>, so to speak.
2376 Collision detection may be introduced in a later version.
2377
2378
2379
2380 You can specify a custom digest algorithm by calling the static C<set_digest()>
2381 function, passing a reference to a subroutine, and the length of the algorithm's
2382 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2383 objects.  Here is a working example that uses a 256-bit hash from the
2384 I<Digest::SHA256> module.  Please see
2385 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2386
2387         use DBM::Deep;
2388         use Digest::SHA256;
2389
2390         my $context = Digest::SHA256::new(256);
2391
2392         DBM::Deep::set_digest( \&my_digest, 32 );
2393
2394         my $db = DBM::Deep->new( "foo-sha.db" );
2395
2396         $db->{key1} = "value1";
2397         $db->{key2} = "value2";
2398         print "key1: " . $db->{key1} . "\n";
2399         print "key2: " . $db->{key2} . "\n";
2400
2401         undef $db;
2402         exit;
2403
2404         sub my_digest {
2405                 return substr( $context->hash($_[0]), 0, 32 );
2406         }
2407
2408 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2409 of bytes you specify in the C<set_digest()> function (in this case 32).
2410
2411 =head1 CIRCULAR REFERENCES
2412
2413 DBM::Deep has B<experimental> support for circular references.  Meaning you
2414 can have a nested hash key or array element that points to a parent object.
2415 This relationship is stored in the DB file, and is preserved between sessions.
2416 Here is an example:
2417
2418         my $db = DBM::Deep->new( "foo.db" );
2419
2420         $db->{foo} = "bar";
2421         $db->{circle} = $db; # ref to self
2422
2423         print $db->{foo} . "\n"; # prints "foo"
2424         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2425
2426 One catch is, passing the object to a function that recursively walks the
2427 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2428 C<export()> methods) will result in an infinite loop.  The other catch is,
2429 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2430 or C<next_key()> methods), you will get the I<target object's key>, not the
2431 ref's key.  This gets even more interesting with the above example, where
2432 the I<circle> key points to the base DB object, which technically doesn't
2433 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2434 special case.
2435
2436 =head1 CAVEATS / ISSUES / BUGS
2437
2438 This section describes all the known issues with DBM::Deep.  It you have found
2439 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2440
2441 =head2 UNUSED SPACE RECOVERY
2442
2443 One major caveat with DBM::Deep is that space occupied by existing keys and
2444 values is not recovered when they are deleted.  Meaning if you keep deleting
2445 and adding new keys, your file will continuously grow.  I am working on this,
2446 but in the meantime you can call the built-in C<optimize()> method from time to
2447 time (perhaps in a crontab or something) to recover all your unused space.
2448
2449         $db->optimize(); # returns true on success
2450
2451 This rebuilds the ENTIRE database into a new file, then moves it on top of
2452 the original.  The new file will have no unused space, thus it will take up as
2453 little disk space as possible.  Please note that this operation can take
2454 a long time for large files, and you need enough disk space to temporarily hold
2455 2 copies of your DB file.  The temporary file is created in the same directory
2456 as the original, named with a ".tmp" extension, and is deleted when the
2457 operation completes.  Oh, and if locking is enabled, the DB is automatically
2458 locked for the entire duration of the copy.
2459
2460 B<WARNING:> Only call optimize() on the top-level node of the database, and
2461 make sure there are no child references lying around.  DBM::Deep keeps a reference
2462 counter, and if it is greater than 1, optimize() will abort and return undef.
2463
2464 =head2 AUTOVIVIFICATION
2465
2466 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2467 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2468 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2469 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2470 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2471 this does not work:
2472
2473         $db->{foo}->{bar} = "hello";
2474
2475 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2476 being an empty hash.  Try this instead, which works fine:
2477
2478         $db->{foo} = { bar => "hello" };
2479
2480 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2481 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2482 Probably a bug in Perl.
2483
2484 =head2 FILE CORRUPTION
2485
2486 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2487 for a 32-bit signature when opened, but other corruption in files can cause
2488 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2489 stuck in an infinite loop depending on the level of corruption.  File write
2490 operations are not checked for failure (for speed), so if you happen to run
2491 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2492 be addressed in a later version of DBM::Deep.
2493
2494 =head2 DB OVER NFS
2495
2496 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2497 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2498 about setting up your NFS server with a locking daemon, then using lockf() to
2499 lock your files, but your mileage may vary there as well.  From what I
2500 understand, there is no real way to do it.  However, if you need access to the
2501 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2502 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2503
2504 =head2 COPYING OBJECTS
2505
2506 Beware of copying tied objects in Perl.  Very strange things can happen.
2507 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2508 returns a new, blessed, tied hash or array to the same level in the DB.
2509
2510         my $copy = $db->clone();
2511
2512 B<Note>: Since clone() here is cloning the object, not the database location, any
2513 modifications to either $db or $copy will be visible in both.
2514
2515 =head2 LARGE ARRAYS
2516
2517 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2518 These functions cause every element in the array to move, which can be murder
2519 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2520 a different location.  This will be addressed in the forthcoming version 1.00.
2521
2522 =head1 PERFORMANCE
2523
2524 This section discusses DBM::Deep's speed and memory usage.
2525
2526 =head2 SPEED
2527
2528 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2529 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2530 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2531 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2532 with huge databases.  Here is some test data:
2533
2534         Adding 1,000,000 keys to new DB file...
2535
2536         At 100 keys, avg. speed is 2,703 keys/sec
2537         At 200 keys, avg. speed is 2,642 keys/sec
2538         At 300 keys, avg. speed is 2,598 keys/sec
2539         At 400 keys, avg. speed is 2,578 keys/sec
2540         At 500 keys, avg. speed is 2,722 keys/sec
2541         At 600 keys, avg. speed is 2,628 keys/sec
2542         At 700 keys, avg. speed is 2,700 keys/sec
2543         At 800 keys, avg. speed is 2,607 keys/sec
2544         At 900 keys, avg. speed is 2,190 keys/sec
2545         At 1,000 keys, avg. speed is 2,570 keys/sec
2546         At 2,000 keys, avg. speed is 2,417 keys/sec
2547         At 3,000 keys, avg. speed is 1,982 keys/sec
2548         At 4,000 keys, avg. speed is 1,568 keys/sec
2549         At 5,000 keys, avg. speed is 1,533 keys/sec
2550         At 6,000 keys, avg. speed is 1,787 keys/sec
2551         At 7,000 keys, avg. speed is 1,977 keys/sec
2552         At 8,000 keys, avg. speed is 2,028 keys/sec
2553         At 9,000 keys, avg. speed is 2,077 keys/sec
2554         At 10,000 keys, avg. speed is 2,031 keys/sec
2555         At 20,000 keys, avg. speed is 1,970 keys/sec
2556         At 30,000 keys, avg. speed is 2,050 keys/sec
2557         At 40,000 keys, avg. speed is 2,073 keys/sec
2558         At 50,000 keys, avg. speed is 1,973 keys/sec
2559         At 60,000 keys, avg. speed is 1,914 keys/sec
2560         At 70,000 keys, avg. speed is 2,091 keys/sec
2561         At 80,000 keys, avg. speed is 2,103 keys/sec
2562         At 90,000 keys, avg. speed is 1,886 keys/sec
2563         At 100,000 keys, avg. speed is 1,970 keys/sec
2564         At 200,000 keys, avg. speed is 2,053 keys/sec
2565         At 300,000 keys, avg. speed is 1,697 keys/sec
2566         At 400,000 keys, avg. speed is 1,838 keys/sec
2567         At 500,000 keys, avg. speed is 1,941 keys/sec
2568         At 600,000 keys, avg. speed is 1,930 keys/sec
2569         At 700,000 keys, avg. speed is 1,735 keys/sec
2570         At 800,000 keys, avg. speed is 1,795 keys/sec
2571         At 900,000 keys, avg. speed is 1,221 keys/sec
2572         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2573
2574 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2575 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2576 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2577 Run time was 12 min 3 sec.
2578
2579 =head2 MEMORY USAGE
2580
2581 One of the great things about DBM::Deep is that it uses very little memory.
2582 Even with huge databases (1,000,000+ keys) you will not see much increased
2583 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2584 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2585 database handle:
2586
2587           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2588         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2589
2590 Basically the process is taking 2,716K of memory.  And here is the same
2591 process after storing and fetching 1,000,000 keys:
2592
2593           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2594         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2595
2596 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2597 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2598
2599 =head1 DB FILE FORMAT
2600
2601 In case you were interested in the underlying DB file format, it is documented
2602 here in this section.  You don't need to know this to use the module, it's just
2603 included for reference.
2604
2605 =head2 SIGNATURE
2606
2607 DBM::Deep files always start with a 32-bit signature to identify the file type.
2608 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2609 checked for when the file is opened and an error will be thrown if it's not found.
2610
2611 =head2 TAG
2612
2613 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2614 has a standard header containing the type of data, the length of data, and then
2615 the data itself.  The type is a single character (1 byte), the length is a
2616 32-bit unsigned long in network byte order, and the data is, well, the data.
2617 Here is how it unfolds:
2618
2619 =head2 MASTER INDEX
2620
2621 Immediately after the 32-bit file signature is the I<Master Index> record.
2622 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2623 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2624 depending on how the DBM::Deep object was constructed.
2625
2626 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2627 number).  The first 8-bit char of the MD5 signature is the offset into the
2628 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2629 index element is a file offset of the next tag for the key/element in question,
2630 which is usually a I<Bucket List> tag (see below).
2631
2632 The next tag I<could> be another index, depending on how many keys/elements
2633 exist.  See L<RE-INDEXING> below for details.
2634
2635 =head2 BUCKET LIST
2636
2637 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2638 file offsets to where the actual data is stored.  It starts with a standard
2639 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2640 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2641 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2642 When the list fills up, a I<Re-Index> operation is performed (See
2643 L<RE-INDEXING> below).
2644
2645 =head2 BUCKET
2646
2647 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2648 index/value pair (in array mode).  It starts with a standard tag header with
2649 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2650 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2651 header.  The size reported in the tag header is only for the value, but then,
2652 just after the value is another size (32-bit unsigned long) and then the plain
2653 key itself.  Since the value is likely to be fetched more often than the plain
2654 key, I figured it would be I<slightly> faster to store the value first.
2655
2656 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2657 record for the nested structure, where the process begins all over again.
2658
2659 =head2 RE-INDEXING
2660
2661 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2662 exhausted.  Then, when another key/element comes in, the list is converted to a
2663 new index record.  However, this index will look at the next char in the MD5
2664 hash, and arrange new Bucket List pointers accordingly.  This process is called
2665 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2666 17 (16 + new one) keys/elements are removed from the old Bucket List and
2667 inserted into the new index.  Several new Bucket Lists are created in the
2668 process, as a new MD5 char from the key is being examined (it is unlikely that
2669 the keys will all share the same next char of their MD5s).
2670
2671 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2672 when the Bucket Lists will turn into indexes, but the first round tends to
2673 happen right around 4,000 keys.  You will see a I<slight> decrease in
2674 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2675 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2676 right around 900,000 keys.  This process can continue nearly indefinitely --
2677 right up until the point the I<MD5> signatures start colliding with each other,
2678 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2679 getting struck by lightning while you are walking to cash in your tickets.
2680 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2681 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2682 this is 340 unodecillion, but don't quote me).
2683
2684 =head2 STORING
2685
2686 When a new key/element is stored, the key (or index number) is first run through
2687 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2688 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2689 for the first char of the signature (in this case I<b0>).  If it does not exist,
2690 a new I<Bucket List> is created for our key (and the next 15 future keys that
2691 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2692 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2693 this point, unless we are replacing an existing I<Bucket>), where the actual
2694 data will be stored.
2695
2696 =head2 FETCHING
2697
2698 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2699 (or index number), then walking along the indexes.  If there are enough
2700 keys/elements in this DB level, there might be nested indexes, each linked to
2701 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2702 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2703 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2704 plain key are stored.
2705
2706 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2707 methods.  In this process the indexes are walked systematically, and each key
2708 fetched in increasing MD5 order (which is why it appears random).   Once the
2709 I<Bucket> is found, the value is skipped and the plain key returned instead.
2710 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2711 alphabetically sorted.  This only happens on an index-level -- as soon as the
2712 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2713 so it's pretty much undefined how the keys will come out -- just like Perl's
2714 built-in hashes.
2715
2716 =head1 CODE COVERAGE
2717
2718 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2719 B<Devel::Cover> report on this module's test suite.
2720
2721   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2722   File                           stmt   bran   cond    sub    pod   time  total
2723   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2724   blib/lib/DBM/Deep.pm           95.0   83.2   68.7   98.2  100.0   57.8   90.7
2725   blib/lib/DBM/Deep/Array.pm     98.9   88.9   87.5  100.0    n/a   27.4   96.4
2726   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   14.8   92.4
2727   Total                          95.8   83.9   72.8   98.8  100.0  100.0   91.8
2728   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2729
2730 =head1 MORE INFORMATION
2731
2732 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2733 or send email to L<DBM-Deep@googlegroups.com>.
2734
2735 =head1 AUTHORS
2736
2737 Joseph Huckaby, L<jhuckaby@cpan.org>
2738
2739 Rob Kinyon, L<rkinyon@cpan.org>
2740
2741 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2742
2743 =head1 SEE ALSO
2744
2745 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2746 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2747
2748 =head1 LICENSE
2749
2750 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2751 This is free software, you may use it and distribute it under the
2752 same terms as Perl itself.
2753
2754 =cut