lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = "0.96";
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub _get_self { $_[0] }
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116
 117         ##
 118         # Check if we want a tied hash or array.
 119         ##
 120         my $self;
 121         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 122         $class = 'DBM::Deep::Array';
 123         require DBM::Deep::Array;
 124                 tie @$self, $class, %$args;
 125         }
 126         else {
 127         $class = 'DBM::Deep::Hash';
 128         require DBM::Deep::Hash;
 129                 tie %$self, $class, %$args;
 130         }
 131
 132         return bless $self, $class;
 133 }
 134
 135 {
 136     my @outer_params = qw( type base_offset );
 137     sub _init {
 138         ##
 139         # Setup $self and bless into this class.
 140         ##
 141         my $class = shift;
 142         my $args = shift;
 143
 144         my $self = {
 145             type => TYPE_HASH,
 146             base_offset => length(SIG_FILE),
 147         };
 148
 149         bless $self, $class;
 150
 151         foreach my $outer_parm ( @outer_params ) {
 152             next unless exists $args->{$outer_parm};
 153             $self->{$outer_parm} = delete $args->{$outer_parm}
 154         }
 155
 156         $self->{root} = exists $args->{root}
 157             ? $args->{root}
 158             : DBM::Deep::_::Root->new( $args );
 159
 160         if (!defined($self->fh)) { $self->_open(); }
 161
 162         return $self;
 163     }
 164 }
 165
 166 sub TIEHASH {
 167     shift;
 168     require DBM::Deep::Hash;
 169     return DBM::Deep::Hash->TIEHASH( @_ );
 170 }
 171
 172 sub TIEARRAY {
 173     shift;
 174     require DBM::Deep::Array;
 175     return DBM::Deep::Array->TIEARRAY( @_ );
 176 }
 177
 178 #XXX Unneeded now ...
 179 #sub DESTROY {
 180 #}
 181
 182 sub _open {
 183         ##
 184         # Open a FileHandle to the database, create if nonexistent.
 185         # Make sure file signature matches DeepDB spec.
 186         ##
 187     my $self = $_[0]->_get_self;#_get_self($_[0]);
 188
 189         if (defined($self->fh)) { $self->_close(); }
 190
 191     eval {
 192         # Theoretically, adding O_BINARY should remove the need for the binmode
 193         # Of course, testing it is going to be ... interesting.
 194         my $flags = O_RDWR | O_CREAT | O_BINARY;
 195
 196         #XXX Can the mode be anything but r+, w+, or a+??
 197         #XXX ie, it has to be in read-write mode
 198         #XXX So, should we verify that the mode is legitimate?
 199
 200         #XXX Maybe the mode thingy should just go away. There's no good
 201         #XXX reason for it ...
 202         if ( $self->root->{mode} eq 'w+' ) {
 203             $flags |= O_TRUNC;
 204         }
 205
 206         my $fh;
 207         sysopen( $fh, $self->root->{file}, $flags )
 208             or $fh = undef;
 209         $self->root->{fh} = $fh;
 210     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 211         if (! defined($self->fh)) {
 212                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 213         }
 214
 215     my $fh = $self->fh;
 216
 217     #XXX Can we remove this by using the right sysopen() flags?
 218     # Maybe ... q.v. above
 219     binmode $fh; # for win32
 220
 221     if ($self->root->{autoflush}) {
 222         my $old = select $fh;
 223         $|=1;
 224         select $old;
 225     }
 226
 227     # Set the
 228     seek($fh, 0, SEEK_SET);
 229
 230     my $signature;
 231     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 232
 233     ##
 234     # File is empty -- write signature and master index
 235     ##
 236     if (!$bytes_read) {
 237         seek($fh, 0, SEEK_SET);
 238         print($fh SIG_FILE);
 239         $self->root->{end} = length(SIG_FILE);
 240         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 241
 242         my $plain_key = "[base]";
 243         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 244         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 245
 246         # Flush the filehandle
 247         my $old_fh = select $fh;
 248         my $old_af = $|;
 249         $| = 1;
 250         $| = $old_af;
 251         select $old_fh;
 252
 253         return 1;
 254     }
 255
 256     ##
 257     # Check signature was valid
 258     ##
 259     unless ($signature eq SIG_FILE) {
 260         $self->_close();
 261         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 262     }
 263
 264     $self->root->{end} = (stat($fh))[7];
 265
 266     ##
 267     # Get our type from master index signature
 268     ##
 269     my $tag = $self->_load_tag($self->base_offset);
 270
 271 #XXX We probably also want to store the hash algorithm name and not assume anything
 272
 273     if (!$tag) {
 274         return $self->_throw_error("Corrupted file, no master index record");
 275     }
 276     if ($self->{type} ne $tag->{signature}) {
 277         return $self->_throw_error("File type mismatch");
 278     }
 279
 280     return 1;
 281 }
 282
 283 sub _close {
 284         ##
 285         # Close database FileHandle
 286         ##
 287     my $self = $_[0]->_get_self;#_get_self($_[0]);
 288     close $self->root->{fh};
 289 }
 290
 291 sub _create_tag {
 292         ##
 293         # Given offset, signature and content, create tag and write to disk
 294         ##
 295         my ($self, $offset, $sig, $content) = @_;
 296         my $size = length($content);
 297
 298     my $fh = $self->fh;
 299
 300         seek($fh, $offset, SEEK_SET);
 301         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 302
 303         if ($offset == $self->root->{end}) {
 304                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 305         }
 306
 307         return {
 308                 signature => $sig,
 309                 size => $size,
 310                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 311                 content => $content
 312         };
 313 }
 314
 315 sub _load_tag {
 316         ##
 317         # Given offset, load single tag and return signature, size and data
 318         ##
 319         my $self = shift;
 320         my $offset = shift;
 321
 322     my $fh = $self->fh;
 323
 324         seek($fh, $offset, SEEK_SET);
 325         if (eof $fh) { return undef; }
 326
 327         my $sig;
 328         read( $fh, $sig, SIG_SIZE);
 329
 330         my $size;
 331         read( $fh, $size, $DATA_LENGTH_SIZE);
 332         $size = unpack($DATA_LENGTH_PACK, $size);
 333
 334         my $buffer;
 335         read( $fh, $buffer, $size);
 336
 337         return {
 338                 signature => $sig,
 339                 size => $size,
 340                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 341                 content => $buffer
 342         };
 343 }
 344
 345 sub _index_lookup {
 346         ##
 347         # Given index tag, lookup single entry in index and return .
 348         ##
 349         my $self = shift;
 350         my ($tag, $index) = @_;
 351
 352         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 353         if (!$location) { return; }
 354
 355         return $self->_load_tag( $location );
 356 }
 357
 358 sub _add_bucket {
 359         ##
 360         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 361         # plain (undigested) key and value.
 362         ##
 363         my $self = shift;
 364         my ($tag, $md5, $plain_key, $value) = @_;
 365         my $keys = $tag->{content};
 366         my $location = 0;
 367         my $result = 2;
 368
 369     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 370         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 371
 372     my $fh = $self->fh;
 373
 374         ##
 375         # Iterate through buckets, seeing if this is a new entry or a replace.
 376         ##
 377         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 378                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 379                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 380                 if (!$subloc) {
 381                         ##
 382                         # Found empty bucket (end of list).  Populate and exit loop.
 383                         ##
 384                         $result = 2;
 385
 386             $location = $internal_ref
 387                 ? $value->base_offset
 388                 : $self->root->{end};
 389
 390                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 391                         print($fh $md5 . pack($LONG_PACK, $location) );
 392                         last;
 393                 }
 394                 elsif ($md5 eq $key) {
 395                         ##
 396                         # Found existing bucket with same key.  Replace with new value.
 397                         ##
 398                         $result = 1;
 399
 400                         if ($internal_ref) {
 401                                 $location = $value->base_offset;
 402                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 403                                 print($fh $md5 . pack($LONG_PACK, $location) );
 404                         }
 405                         else {
 406                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 407                                 my $size;
 408                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 409
 410                                 ##
 411                                 # If value is a hash, array, or raw value with equal or less size, we can
 412                                 # reuse the same content area of the database.  Otherwise, we have to create
 413                                 # a new content area at the EOF.
 414                                 ##
 415                                 my $actual_length;
 416                 my $r = Scalar::Util::reftype( $value ) || '';
 417                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 418                                 else { $actual_length = length($value); }
 419
 420                                 if ($actual_length <= $size) {
 421                                         $location = $subloc;
 422                                 }
 423                                 else {
 424                                         $location = $self->root->{end};
 425                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 426                                         print($fh pack($LONG_PACK, $location) );
 427                                 }
 428                         }
 429                         last;
 430                 }
 431         } # i loop
 432
 433         ##
 434         # If this is an internal reference, return now.
 435         # No need to write value or plain key
 436         ##
 437         if ($internal_ref) {
 438         return $result;
 439     }
 440
 441         ##
 442         # If bucket didn't fit into list, split into a new index level
 443         ##
 444         if (!$location) {
 445                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 446                 print($fh pack($LONG_PACK, $self->root->{end}) );
 447
 448                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 449                 my @offsets = ();
 450
 451                 $keys .= $md5 . pack($LONG_PACK, 0);
 452
 453                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 454                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 455                         if ($key) {
 456                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 457                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 458
 459                                 if ($offsets[$num]) {
 460                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 461                                         seek($fh, $offset, SEEK_SET);
 462                                         my $subkeys;
 463                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 464
 465                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 466                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 467                                                 if (!$subloc) {
 468                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 469                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 470                                                         last;
 471                                                 }
 472                                         } # k loop
 473                                 }
 474                                 else {
 475                                         $offsets[$num] = $self->root->{end};
 476                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 477                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 478
 479                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 480
 481                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 482                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 483                                 }
 484                         } # key is real
 485                 } # i loop
 486
 487                 $location ||= $self->root->{end};
 488         } # re-index bucket list
 489
 490         ##
 491         # Seek to content area and store signature, value and plaintext key
 492         ##
 493         if ($location) {
 494                 my $content_length;
 495                 seek($fh, $location, SEEK_SET);
 496
 497                 ##
 498                 # Write signature based on content type, set content length and write actual value.
 499                 ##
 500         my $r = Scalar::Util::reftype($value) || '';
 501                 if ($r eq 'HASH') {
 502                         print($fh TYPE_HASH );
 503                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 504                         $content_length = $INDEX_SIZE;
 505                 }
 506                 elsif ($r eq 'ARRAY') {
 507                         print($fh TYPE_ARRAY );
 508                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 509                         $content_length = $INDEX_SIZE;
 510                 }
 511                 elsif (!defined($value)) {
 512                         print($fh SIG_NULL );
 513                         print($fh pack($DATA_LENGTH_PACK, 0) );
 514                         $content_length = 0;
 515                 }
 516                 else {
 517                         print($fh SIG_DATA );
 518                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 519                         $content_length = length($value);
 520                 }
 521
 522                 ##
 523                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 524                 ##
 525                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 526
 527                 ##
 528                 # If value is blessed, preserve class name
 529                 ##
 530                 if ( $self->root->{autobless} ) {
 531             my $value_class = Scalar::Util::blessed($value);
 532             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 533                 ##
 534                 # Blessed ref -- will restore later
 535                 ##
 536                 print($fh chr(1) );
 537                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 538                 $content_length += 1;
 539                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 540             }
 541             else {
 542                 print($fh chr(0) );
 543                 $content_length += 1;
 544             }
 545         }
 546
 547                 ##
 548                 # If this is a new content area, advance EOF counter
 549                 ##
 550                 if ($location == $self->root->{end}) {
 551                         $self->root->{end} += SIG_SIZE;
 552                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 553                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 554                 }
 555
 556                 ##
 557                 # If content is a hash or array, create new child DeepDB object and
 558                 # pass each key or element to it.
 559                 ##
 560                 if ($r eq 'HASH') {
 561                         my $branch = DBM::Deep->new(
 562                                 type => TYPE_HASH,
 563                                 base_offset => $location,
 564                                 root => $self->root,
 565                         );
 566                         foreach my $key (keys %{$value}) {
 567                 #$branch->{$key} = $value->{$key};
 568                 $branch->STORE( $key, $value->{$key} );
 569                         }
 570                 }
 571                 elsif ($r eq 'ARRAY') {
 572                         my $branch = DBM::Deep->new(
 573                                 type => TYPE_ARRAY,
 574                                 base_offset => $location,
 575                                 root => $self->root,
 576                         );
 577                         my $index = 0;
 578                         foreach my $element (@{$value}) {
 579                 #$branch->[$index] = $element;
 580                 $branch->STORE( $index, $element );
 581                                 $index++;
 582                         }
 583                 }
 584
 585                 return $result;
 586         }
 587
 588         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 589 }
 590
 591 sub _get_bucket_value {
 592         ##
 593         # Fetch single value given tag and MD5 digested key.
 594         ##
 595         my $self = shift;
 596         my ($tag, $md5) = @_;
 597         my $keys = $tag->{content};
 598
 599     my $fh = $self->fh;
 600
 601         ##
 602         # Iterate through buckets, looking for a key match
 603         ##
 604     BUCKET:
 605         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 606                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 607                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 608
 609                 if (!$subloc) {
 610                         ##
 611                         # Hit end of list, no match
 612                         ##
 613                         return;
 614                 }
 615
 616         if ( $md5 ne $key ) {
 617             next BUCKET;
 618         }
 619
 620         ##
 621         # Found match -- seek to offset and read signature
 622         ##
 623         my $signature;
 624         seek($fh, $subloc, SEEK_SET);
 625         read( $fh, $signature, SIG_SIZE);
 626
 627         ##
 628         # If value is a hash or array, return new DeepDB object with correct offset
 629         ##
 630         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 631             my $obj = DBM::Deep->new(
 632                 type => $signature,
 633                 base_offset => $subloc,
 634                 root => $self->root
 635             );
 636
 637             if ($self->root->{autobless}) {
 638                 ##
 639                 # Skip over value and plain key to see if object needs
 640                 # to be re-blessed
 641                 ##
 642                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 643
 644                 my $size;
 645                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 646                 if ($size) { seek($fh, $size, SEEK_CUR); }
 647
 648                 my $bless_bit;
 649                 read( $fh, $bless_bit, 1);
 650                 if (ord($bless_bit)) {
 651                     ##
 652                     # Yes, object needs to be re-blessed
 653                     ##
 654                     my $class_name;
 655                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 656                     if ($size) { read( $fh, $class_name, $size); }
 657                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 658                 }
 659             }
 660
 661             return $obj;
 662         }
 663
 664         ##
 665         # Otherwise return actual value
 666         ##
 667         elsif ($signature eq SIG_DATA) {
 668             my $size;
 669             my $value = '';
 670             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 671             if ($size) { read( $fh, $value, $size); }
 672             return $value;
 673         }
 674
 675         ##
 676         # Key exists, but content is null
 677         ##
 678         else { return; }
 679         } # i loop
 680
 681         return;
 682 }
 683
 684 sub _delete_bucket {
 685         ##
 686         # Delete single key/value pair given tag and MD5 digested key.
 687         ##
 688         my $self = shift;
 689         my ($tag, $md5) = @_;
 690         my $keys = $tag->{content};
 691
 692     my $fh = $self->fh;
 693
 694         ##
 695         # Iterate through buckets, looking for a key match
 696         ##
 697     BUCKET:
 698         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 699                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 700                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 701
 702                 if (!$subloc) {
 703                         ##
 704                         # Hit end of list, no match
 705                         ##
 706                         return;
 707                 }
 708
 709         if ( $md5 ne $key ) {
 710             next BUCKET;
 711         }
 712
 713         ##
 714         # Matched key -- delete bucket and return
 715         ##
 716         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 717         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 718         print($fh chr(0) x $BUCKET_SIZE );
 719
 720         return 1;
 721         } # i loop
 722
 723         return;
 724 }
 725
 726 sub _bucket_exists {
 727         ##
 728         # Check existence of single key given tag and MD5 digested key.
 729         ##
 730         my $self = shift;
 731         my ($tag, $md5) = @_;
 732         my $keys = $tag->{content};
 733
 734         ##
 735         # Iterate through buckets, looking for a key match
 736         ##
 737     BUCKET:
 738         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 739                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 740                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 741
 742                 if (!$subloc) {
 743                         ##
 744                         # Hit end of list, no match
 745                         ##
 746                         return;
 747                 }
 748
 749         if ( $md5 ne $key ) {
 750             next BUCKET;
 751         }
 752
 753         ##
 754         # Matched key -- return true
 755         ##
 756         return 1;
 757         } # i loop
 758
 759         return;
 760 }
 761
 762 sub _find_bucket_list {
 763         ##
 764         # Locate offset for bucket list, given digested key
 765         ##
 766         my $self = shift;
 767         my $md5 = shift;
 768
 769         ##
 770         # Locate offset for bucket list using digest index system
 771         ##
 772         my $ch = 0;
 773         my $tag = $self->_load_tag($self->base_offset);
 774         if (!$tag) { return; }
 775
 776         while ($tag->{signature} ne SIG_BLIST) {
 777                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 778                 if (!$tag) { return; }
 779                 $ch++;
 780         }
 781
 782         return $tag;
 783 }
 784
 785 sub _traverse_index {
 786         ##
 787         # Scan index and recursively step into deeper levels, looking for next key.
 788         ##
 789     my ($self, $offset, $ch, $force_return_next) = @_;
 790     $force_return_next = undef unless $force_return_next;
 791
 792         my $tag = $self->_load_tag( $offset );
 793
 794     my $fh = $self->fh;
 795
 796         if ($tag->{signature} ne SIG_BLIST) {
 797                 my $content = $tag->{content};
 798                 my $start;
 799                 if ($self->{return_next}) { $start = 0; }
 800                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 801
 802                 for (my $index = $start; $index < 256; $index++) {
 803                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 804                         if ($subloc) {
 805                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 806                                 if (defined($result)) { return $result; }
 807                         }
 808                 } # index loop
 809
 810                 $self->{return_next} = 1;
 811         } # tag is an index
 812
 813         elsif ($tag->{signature} eq SIG_BLIST) {
 814                 my $keys = $tag->{content};
 815                 if ($force_return_next) { $self->{return_next} = 1; }
 816
 817                 ##
 818                 # Iterate through buckets, looking for a key match
 819                 ##
 820                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 821                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 822                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 823
 824                         if (!$subloc) {
 825                                 ##
 826                                 # End of bucket list -- return to outer loop
 827                                 ##
 828                                 $self->{return_next} = 1;
 829                                 last;
 830                         }
 831                         elsif ($key eq $self->{prev_md5}) {
 832                                 ##
 833                                 # Located previous key -- return next one found
 834                                 ##
 835                                 $self->{return_next} = 1;
 836                                 next;
 837                         }
 838                         elsif ($self->{return_next}) {
 839                                 ##
 840                                 # Seek to bucket location and skip over signature
 841                                 ##
 842                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 843
 844                                 ##
 845                                 # Skip over value to get to plain key
 846                                 ##
 847                                 my $size;
 848                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 849                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 850
 851                                 ##
 852                                 # Read in plain key and return as scalar
 853                                 ##
 854                                 my $plain_key;
 855                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 856                                 if ($size) { read( $fh, $plain_key, $size); }
 857
 858                                 return $plain_key;
 859                         }
 860                 } # bucket loop
 861
 862                 $self->{return_next} = 1;
 863         } # tag is a bucket list
 864
 865         return;
 866 }
 867
 868 sub _get_next_key {
 869         ##
 870         # Locate next key, given digested previous one
 871         ##
 872     my $self = $_[0]->_get_self;#_get_self($_[0]);
 873
 874         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 875         $self->{return_next} = 0;
 876
 877         ##
 878         # If the previous key was not specifed, start at the top and
 879         # return the first one found.
 880         ##
 881         if (!$self->{prev_md5}) {
 882                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 883                 $self->{return_next} = 1;
 884         }
 885
 886         return $self->_traverse_index( $self->base_offset, 0 );
 887 }
 888
 889 sub lock {
 890         ##
 891         # If db locking is set, flock() the db file.  If called multiple
 892         # times before unlock(), then the same number of unlocks() must
 893         # be called before the lock is released.
 894         ##
 895     my $self = $_[0]->_get_self;#_get_self($_[0]);
 896         my $type = $_[1];
 897     $type = LOCK_EX unless defined $type;
 898
 899         if ($self->root->{locking}) {
 900                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 901                 $self->root->{locked}++;
 902
 903         return 1;
 904         }
 905
 906     return;
 907 }
 908
 909 sub unlock {
 910         ##
 911         # If db locking is set, unlock the db file.  See note in lock()
 912         # regarding calling lock() multiple times.
 913         ##
 914     my $self = $_[0]->_get_self;#_get_self($_[0]);
 915
 916         if ($self->root->{locking} && $self->root->{locked} > 0) {
 917                 $self->root->{locked}--;
 918                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 919
 920         return 1;
 921         }
 922
 923     return;
 924 }
 925
 926 #XXX These uses of ref() need verified
 927 sub _copy_node {
 928         ##
 929         # Copy single level of keys or elements to new DB handle.
 930         # Recurse for nested structures
 931         ##
 932     my $self = $_[0]->_get_self;#_get_self($_[0]);
 933         my $db_temp = $_[1];
 934
 935         if ($self->type eq TYPE_HASH) {
 936                 my $key = $self->first_key();
 937                 while ($key) {
 938                         my $value = $self->get($key);
 939 #XXX This doesn't work with autobless
 940                         if (!ref($value)) { $db_temp->{$key} = $value; }
 941                         else {
 942                                 my $type = $value->type;
 943                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 944                                 else { $db_temp->{$key} = []; }
 945                                 $value->_copy_node( $db_temp->{$key} );
 946                         }
 947                         $key = $self->next_key($key);
 948                 }
 949         }
 950         else {
 951                 my $length = $self->length();
 952                 for (my $index = 0; $index < $length; $index++) {
 953                         my $value = $self->get($index);
 954                         if (!ref($value)) { $db_temp->[$index] = $value; }
 955             #XXX NO tests for this code
 956                         else {
 957                                 my $type = $value->type;
 958                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 959                                 else { $db_temp->[$index] = []; }
 960                                 $value->_copy_node( $db_temp->[$index] );
 961                         }
 962                 }
 963         }
 964 }
 965
 966 sub export {
 967         ##
 968         # Recursively export into standard Perl hashes and arrays.
 969         ##
 970     my $self = $_[0]->_get_self;#_get_self($_[0]);
 971
 972         my $temp;
 973         if ($self->type eq TYPE_HASH) { $temp = {}; }
 974         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 975
 976         $self->lock();
 977         $self->_copy_node( $temp );
 978         $self->unlock();
 979
 980         return $temp;
 981 }
 982
 983 sub import {
 984         ##
 985         # Recursively import Perl hash/array structure
 986         ##
 987     #XXX This use of ref() seems to be ok
 988         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 989
 990     my $self = $_[0]->_get_self;#_get_self($_[0]);
 991         my $struct = $_[1];
 992
 993     #XXX This use of ref() seems to be ok
 994         if (!ref($struct)) {
 995                 ##
 996                 # struct is not a reference, so just import based on our type
 997                 ##
 998                 shift @_;
 999
1000                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1001                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1002         }
1003
1004     my $r = Scalar::Util::reftype($struct) || '';
1005         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1006                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1007         }
1008         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1009                 $self->push( @$struct );
1010         }
1011         else {
1012                 return $self->_throw_error("Cannot import: type mismatch");
1013         }
1014
1015         return 1;
1016 }
1017
1018 sub optimize {
1019         ##
1020         # Rebuild entire database into new file, then move
1021         # it back on top of original.
1022         ##
1023     my $self = $_[0]->_get_self;#_get_self($_[0]);
1024
1025 #XXX Need to create a new test for this
1026 #       if ($self->root->{links} > 1) {
1027 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1028 #       }
1029
1030         my $db_temp = DBM::Deep->new(
1031                 file => $self->root->{file} . '.tmp',
1032                 type => $self->type
1033         );
1034         if (!$db_temp) {
1035                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1036         }
1037
1038         $self->lock();
1039         $self->_copy_node( $db_temp );
1040         undef $db_temp;
1041
1042         ##
1043         # Attempt to copy user, group and permissions over to new file
1044         ##
1045         my @stats = stat($self->fh);
1046         my $perms = $stats[2] & 07777;
1047         my $uid = $stats[4];
1048         my $gid = $stats[5];
1049         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1050         chmod( $perms, $self->root->{file} . '.tmp' );
1051
1052     # q.v. perlport for more information on this variable
1053     if ( $^O eq 'MSWin32' ) {
1054                 ##
1055                 # Potential race condition when optmizing on Win32 with locking.
1056                 # The Windows filesystem requires that the filehandle be closed
1057                 # before it is overwritten with rename().  This could be redone
1058                 # with a soft copy.
1059                 ##
1060                 $self->unlock();
1061                 $self->_close();
1062         }
1063
1064         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1065                 unlink $self->root->{file} . '.tmp';
1066                 $self->unlock();
1067                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1068         }
1069
1070         $self->unlock();
1071         $self->_close();
1072         $self->_open();
1073
1074         return 1;
1075 }
1076
1077 sub clone {
1078         ##
1079         # Make copy of object and return
1080         ##
1081     my $self = $_[0]->_get_self;#_get_self($_[0]);
1082
1083         return DBM::Deep->new(
1084                 type => $self->type,
1085                 base_offset => $self->base_offset,
1086                 root => $self->root
1087         );
1088 }
1089
1090 {
1091     my %is_legal_filter = map {
1092         $_ => ~~1,
1093     } qw(
1094         store_key store_value
1095         fetch_key fetch_value
1096     );
1097
1098     sub set_filter {
1099         ##
1100         # Setup filter function for storing or fetching the key or value
1101         ##
1102         my $self = $_[0]->_get_self;#_get_self($_[0]);
1103         my $type = lc $_[1];
1104         my $func = $_[2] ? $_[2] : undef;
1105
1106         if ( $is_legal_filter{$type} ) {
1107             $self->root->{"filter_$type"} = $func;
1108             return 1;
1109         }
1110
1111         return;
1112     }
1113 }
1114
1115 ##
1116 # Accessor methods
1117 ##
1118
1119 sub root {
1120         ##
1121         # Get access to the root structure
1122         ##
1123     my $self = $_[0]->_get_self;#_get_self($_[0]);
1124         return $self->{root};
1125 }
1126
1127 sub fh {
1128         ##
1129         # Get access to the raw FileHandle
1130         ##
1131     #XXX It will be useful, though, when we split out HASH and ARRAY
1132     my $self = $_[0]->_get_self;#_get_self($_[0]);
1133         return $self->root->{fh};
1134 }
1135
1136 sub type {
1137         ##
1138         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1139         ##
1140     my $self = $_[0]->_get_self;#_get_self($_[0]);
1141         return $self->{type};
1142 }
1143
1144 sub base_offset {
1145         ##
1146         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1147         ##
1148     my $self = $_[0]->_get_self;#_get_self($_[0]);
1149         return $self->{base_offset};
1150 }
1151
1152 sub error {
1153         ##
1154         # Get last error string, or undef if no error
1155         ##
1156         return $_[0]
1157         #? ( _get_self($_[0])->{root}->{error} or undef )
1158         ? ( $_[0]->_get_self->{root}->{error} or undef )
1159         : $@;
1160 }
1161
1162 ##
1163 # Utility methods
1164 ##
1165
1166 sub _throw_error {
1167         ##
1168         # Store error string in self
1169         ##
1170     my $self = $_[0]->_get_self;#_get_self($_[0]);
1171         my $error_text = $_[1];
1172
1173         $self->root->{error} = $error_text;
1174
1175         unless ($self->root->{debug}) {
1176         die "DBM::Deep: $error_text\n";
1177     }
1178
1179     warn "DBM::Deep: $error_text\n";
1180         return;
1181 }
1182
1183 sub clear_error {
1184         ##
1185         # Clear error state
1186         ##
1187     my $self = $_[0]->_get_self;#_get_self($_[0]);
1188
1189         undef $self->root->{error};
1190 }
1191
1192 sub precalc_sizes {
1193         ##
1194         # Precalculate index, bucket and bucket list sizes
1195         ##
1196
1197     #XXX I don't like this ...
1198     set_pack() unless defined $LONG_SIZE;
1199
1200         $INDEX_SIZE = 256 * $LONG_SIZE;
1201         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1202         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1203 }
1204
1205 sub set_pack {
1206         ##
1207         # Set pack/unpack modes (see file header for more)
1208         ##
1209     my ($long_s, $long_p, $data_s, $data_p) = @_;
1210
1211     $LONG_SIZE = $long_s ? $long_s : 4;
1212     $LONG_PACK = $long_p ? $long_p : 'N';
1213
1214     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1215     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1216
1217         precalc_sizes();
1218 }
1219
1220 sub set_digest {
1221         ##
1222         # Set key digest function (default is MD5)
1223         ##
1224     my ($digest_func, $hash_size) = @_;
1225
1226     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1227     $HASH_SIZE = $hash_size ? $hash_size : 16;
1228
1229         precalc_sizes();
1230 }
1231
1232 ##
1233 # tie() methods (hashes and arrays)
1234 ##
1235
1236 sub STORE {
1237         ##
1238         # Store single hash key/value or array element in database.
1239         ##
1240     my $self = $_[0]->_get_self;#_get_self($_[0]);
1241         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1242     #XXX What is ref() checking here?
1243     #YYY User may be storing a hash, in which case we do not want it run
1244     #YYY through the filtering system
1245         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1246
1247         my $unpacked_key = $key;
1248         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1249         my $md5 = $DIGEST_FUNC->($key);
1250
1251         ##
1252         # Make sure file is open
1253         ##
1254         if (!defined($self->fh) && !$self->_open()) {
1255                 return;
1256         }
1257         ##
1258
1259     my $fh = $self->fh;
1260
1261         ##
1262         # Request exclusive lock for writing
1263         ##
1264         $self->lock( LOCK_EX );
1265
1266         ##
1267         # If locking is enabled, set 'end' parameter again, in case another
1268         # DB instance appended to our file while we were unlocked.
1269         ##
1270         if ($self->root->{locking} || $self->root->{volatile}) {
1271                 $self->root->{end} = (stat($fh))[7];
1272         }
1273
1274         ##
1275         # Locate offset for bucket list using digest index system
1276         ##
1277         my $tag = $self->_load_tag($self->base_offset);
1278         if (!$tag) {
1279                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1280         }
1281
1282         my $ch = 0;
1283         while ($tag->{signature} ne SIG_BLIST) {
1284                 my $num = ord(substr($md5, $ch, 1));
1285                 my $new_tag = $self->_index_lookup($tag, $num);
1286                 if (!$new_tag) {
1287                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1288                         seek($fh, $ref_loc, SEEK_SET);
1289                         print($fh pack($LONG_PACK, $self->root->{end}) );
1290
1291                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1292                         $tag->{ref_loc} = $ref_loc;
1293                         $tag->{ch} = $ch;
1294                         last;
1295                 }
1296                 else {
1297                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1298                         $tag = $new_tag;
1299                         $tag->{ref_loc} = $ref_loc;
1300                         $tag->{ch} = $ch;
1301                 }
1302                 $ch++;
1303         }
1304
1305         ##
1306         # Add key/value to bucket list
1307         ##
1308         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1309
1310         ##
1311         # If this object is an array, and bucket was not a replace, and key is numerical,
1312         # and index is equal or greater than current length, advance length variable.
1313         ##
1314         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1315                 $self->STORESIZE( $unpacked_key + 1 );
1316         }
1317
1318         $self->unlock();
1319
1320         return $result;
1321 }
1322
1323 sub FETCH {
1324         ##
1325         # Fetch single value or element given plain key or array index
1326         ##
1327     my $self = $_[0]->_get_self;#_get_self($_[0]);
1328
1329     my $key = $_[1];
1330     if ( $self->type eq TYPE_HASH ) {
1331         if ( my $filter = $self->root->{filter_store_key} ) {
1332             $key = $filter->( $key );
1333         }
1334     }
1335     elsif ( $self->type eq TYPE_ARRAY ) {
1336         if ( $key =~ /^\d+$/ ) {
1337             $key = pack($LONG_PACK, $key);
1338         }
1339     }
1340
1341         my $md5 = $DIGEST_FUNC->($key);
1342
1343         ##
1344         # Make sure file is open
1345         ##
1346         if (!defined($self->fh)) { $self->_open(); }
1347
1348         ##
1349         # Request shared lock for reading
1350         ##
1351         $self->lock( LOCK_SH );
1352
1353         my $tag = $self->_find_bucket_list( $md5 );
1354         if (!$tag) {
1355                 $self->unlock();
1356                 return;
1357         }
1358
1359         ##
1360         # Get value from bucket list
1361         ##
1362         my $result = $self->_get_bucket_value( $tag, $md5 );
1363
1364         $self->unlock();
1365
1366     #XXX What is ref() checking here?
1367         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1368 }
1369
1370 sub DELETE {
1371         ##
1372         # Delete single key/value pair or element given plain key or array index
1373         ##
1374     my $self = $_[0]->_get_self;#_get_self($_[0]);
1375         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1376
1377         my $unpacked_key = $key;
1378         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1379         my $md5 = $DIGEST_FUNC->($key);
1380
1381         ##
1382         # Make sure file is open
1383         ##
1384         if (!defined($self->fh)) { $self->_open(); }
1385
1386         ##
1387         # Request exclusive lock for writing
1388         ##
1389         $self->lock( LOCK_EX );
1390
1391         my $tag = $self->_find_bucket_list( $md5 );
1392         if (!$tag) {
1393                 $self->unlock();
1394                 return;
1395         }
1396
1397         ##
1398         # Delete bucket
1399         ##
1400         my $result = $self->_delete_bucket( $tag, $md5 );
1401
1402         ##
1403         # If this object is an array and the key deleted was on the end of the stack,
1404         # decrement the length variable.
1405         ##
1406         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1407                 $self->STORESIZE( $unpacked_key );
1408         }
1409
1410         $self->unlock();
1411
1412         return $result;
1413 }
1414
1415 sub EXISTS {
1416         ##
1417         # Check if a single key or element exists given plain key or array index
1418         ##
1419     my $self = $_[0]->_get_self;#_get_self($_[0]);
1420         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1421
1422         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1423         my $md5 = $DIGEST_FUNC->($key);
1424
1425         ##
1426         # Make sure file is open
1427         ##
1428         if (!defined($self->fh)) { $self->_open(); }
1429
1430         ##
1431         # Request shared lock for reading
1432         ##
1433         $self->lock( LOCK_SH );
1434
1435         my $tag = $self->_find_bucket_list( $md5 );
1436
1437         ##
1438         # For some reason, the built-in exists() function returns '' for false
1439         ##
1440         if (!$tag) {
1441                 $self->unlock();
1442                 return '';
1443         }
1444
1445         ##
1446         # Check if bucket exists and return 1 or ''
1447         ##
1448         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1449
1450         $self->unlock();
1451
1452         return $result;
1453 }
1454
1455 sub CLEAR {
1456         ##
1457         # Clear all keys from hash, or all elements from array.
1458         ##
1459     my $self = $_[0]->_get_self;#_get_self($_[0]);
1460
1461         ##
1462         # Make sure file is open
1463         ##
1464         if (!defined($self->fh)) { $self->_open(); }
1465
1466         ##
1467         # Request exclusive lock for writing
1468         ##
1469         $self->lock( LOCK_EX );
1470
1471     my $fh = $self->fh;
1472
1473         seek($fh, $self->base_offset, SEEK_SET);
1474         if (eof $fh) {
1475                 $self->unlock();
1476                 return;
1477         }
1478
1479         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1480
1481         $self->unlock();
1482
1483         return 1;
1484 }
1485
1486 ##
1487 # Public method aliases
1488 ##
1489 *put = *store = *STORE;
1490 *get = *fetch = *FETCH;
1491 *delete = *DELETE;
1492 *exists = *EXISTS;
1493 *clear = *CLEAR;
1494
1495 package DBM::Deep::_::Root;
1496
1497 sub new {
1498     my $class = shift;
1499     my ($args) = @_;
1500
1501     my $self = bless {
1502         file => undef,
1503         fh => undef,
1504         end => 0,
1505         autoflush => undef,
1506         locking => undef,
1507         volatile => undef,
1508         debug => undef,
1509         mode => 'r+',
1510         filter_store_key => undef,
1511         filter_store_value => undef,
1512         filter_fetch_key => undef,
1513         filter_fetch_value => undef,
1514         autobless => undef,
1515         locked => 0,
1516         %$args,
1517     }, $class;
1518
1519     return $self;
1520 }
1521
1522 sub DESTROY {
1523     my $self = shift;
1524     return unless $self;
1525
1526     close $self->{fh} if $self->{fh};
1527
1528     return;
1529 }
1530
1531 1;
1532
1533 __END__
1534
1535 =head1 NAME
1536
1537 DBM::Deep - A pure perl multi-level hash/array DBM
1538
1539 =head1 SYNOPSIS
1540
1541   use DBM::Deep;
1542   my $db = DBM::Deep->new( "foo.db" );
1543
1544   $db->{key} = 'value'; # tie() style
1545   print $db->{key};
1546
1547   $db->put('key', 'value'); # OO style
1548   print $db->get('key');
1549
1550   # true multi-level support
1551   $db->{my_complex} = [
1552         'hello', { perl => 'rules' },
1553         42, 99 ];
1554
1555 =head1 DESCRIPTION
1556
1557 A unique flat-file database module, written in pure perl.  True
1558 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1559 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1560 handle millions of keys and unlimited hash levels without significant
1561 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1562 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1563 Mac OS X and Windows.
1564
1565 =head1 INSTALLATION
1566
1567 Hopefully you are using CPAN's excellent Perl module, which will download
1568 and install the module for you.  If not, get the tarball, and run these
1569 commands:
1570
1571         tar zxf DBM-Deep-*
1572         cd DBM-Deep-*
1573         perl Makefile.PL
1574         make
1575         make test
1576         make install
1577
1578 =head1 SETUP
1579
1580 Construction can be done OO-style (which is the recommended way), or using
1581 Perl's tie() function.  Both are examined here.
1582
1583 =head2 OO CONSTRUCTION
1584
1585 The recommended way to construct a DBM::Deep object is to use the new()
1586 method, which gets you a blessed, tied hash or array reference.
1587
1588         my $db = DBM::Deep->new( "foo.db" );
1589
1590 This opens a new database handle, mapped to the file "foo.db".  If this
1591 file does not exist, it will automatically be created.  DB files are
1592 opened in "r+" (read/write) mode, and the type of object returned is a
1593 hash, unless otherwise specified (see L<OPTIONS> below).
1594
1595
1596
1597 You can pass a number of options to the constructor to specify things like
1598 locking, autoflush, etc.  This is done by passing an inline hash:
1599
1600         my $db = DBM::Deep->new(
1601                 file => "foo.db",
1602                 locking => 1,
1603                 autoflush => 1
1604         );
1605
1606 Notice that the filename is now specified I<inside> the hash with
1607 the "file" parameter, as opposed to being the sole argument to the
1608 constructor.  This is required if any options are specified.
1609 See L<OPTIONS> below for the complete list.
1610
1611
1612
1613 You can also start with an array instead of a hash.  For this, you must
1614 specify the C<type> parameter:
1615
1616         my $db = DBM::Deep->new(
1617                 file => "foo.db",
1618                 type => DBM::Deep->TYPE_ARRAY
1619         );
1620
1621 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1622 a new DB file.  If you create a DBM::Deep object with an existing file, the
1623 C<type> will be loaded from the file header, and ignored if it is passed
1624 to the constructor.
1625
1626 =head2 TIE CONSTRUCTION
1627
1628 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1629 tie() function.  This is not ideal, because you get only a basic, tied hash
1630 (or array) which is not blessed, so you can't call any functions on it.
1631
1632         my %hash;
1633         tie %hash, "DBM::Deep", "foo.db";
1634
1635         my @array;
1636         tie @array, "DBM::Deep", "bar.db";
1637
1638 As with the OO constructor, you can replace the DB filename parameter with
1639 a hash containing one or more options (see L<OPTIONS> just below for the
1640 complete list).
1641
1642         tie %hash, "DBM::Deep", {
1643                 file => "foo.db",
1644                 locking => 1,
1645                 autoflush => 1
1646         };
1647
1648 =head2 OPTIONS
1649
1650 There are a number of options that can be passed in when constructing your
1651 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1652
1653 =over
1654
1655 =item * file
1656
1657 Filename of the DB file to link the handle to.  You can pass a full absolute
1658 filesystem path, partial path, or a plain filename if the file is in the
1659 current working directory.  This is a required parameter.
1660
1661 =item * mode
1662
1663 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1664 module.  This is an optional parameter, and defaults to "r+" (read/write).
1665 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1666 created if it doesn't exist.
1667
1668 =item * type
1669
1670 This parameter specifies what type of object to create, a hash or array.  Use
1671 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1672 This only takes effect when beginning a new file.  This is an optional
1673 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1674
1675 =item * locking
1676
1677 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1678 function to lock the database in exclusive mode for writes, and shared mode for
1679 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1680 any child hashes or arrays> that use the same DB file.  This is an optional
1681 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1682
1683 =item * autoflush
1684
1685 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1686 This obviously slows down write operations, but is required if you may have
1687 multiple processes accessing the same DB file (also consider enable I<locking>
1688 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1689 parameter, and defaults to 0 (disabled).
1690
1691 =item * volatile
1692
1693 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1694 STORE() operation.  This is required if an outside force may change the size of
1695 the file between transactions.  Locking also implicitly enables volatile.  This
1696 is useful if you want to use a different locking system or write your own.  Pass
1697 any true value to enable.  This is an optional parameter, and defaults to 0
1698 (disabled).
1699
1700 =item * autobless
1701
1702 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1703 restore them when fetched.  This is an B<experimental> feature, and does have
1704 side-effects.  Basically, when hashes are re-blessed into their original
1705 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1706 able to call any DBM::Deep methods on them.  You have been warned.
1707 This is an optional parameter, and defaults to 0 (disabled).
1708
1709 =item * filter_*
1710
1711 See L<FILTERS> below.
1712
1713 =item * debug
1714
1715 Setting I<debug> mode will make all errors non-fatal, dump them out to
1716 STDERR, and continue on.  This is for debugging purposes only, and probably
1717 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1718
1719 =item * fh
1720
1721 Instead of passing a file path, you can instead pass a handle to an pre-opened
1722 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1723 contains your entire Perl script, as well as the data following the __DATA__
1724 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1725 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1726 in that.
1727
1728 =back
1729
1730 =head1 TIE INTERFACE
1731
1732 With DBM::Deep you can access your databases using Perl's standard hash/array
1733 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1734 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1735 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1736 section above.  This simply tells you how to use DBM::Deep using regular hashes
1737 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1738 work too).  It is entirely up to you how to want to access your databases.
1739
1740 =head2 HASHES
1741
1742 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1743 or even nested hashes (or arrays) using standard Perl syntax:
1744
1745         my $db = DBM::Deep->new( "foo.db" );
1746
1747         $db->{mykey} = "myvalue";
1748         $db->{myhash} = {};
1749         $db->{myhash}->{subkey} = "subvalue";
1750
1751         print $db->{myhash}->{subkey} . "\n";
1752
1753 You can even step through hash keys using the normal Perl C<keys()> function:
1754
1755         foreach my $key (keys %$db) {
1756                 print "$key: " . $db->{$key} . "\n";
1757         }
1758
1759 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1760 pushes them onto an array, all before the loop even begins.  If you have an
1761 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1762 Perl's C<each()> function, which pulls keys/values one at a time, using very
1763 little memory:
1764
1765         while (my ($key, $value) = each %$db) {
1766                 print "$key: $value\n";
1767         }
1768
1769 Please note that when using C<each()>, you should always pass a direct
1770 hash reference, not a lookup.  Meaning, you should B<never> do this:
1771
1772         # NEVER DO THIS
1773         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1774
1775 This causes an infinite loop, because for each iteration, Perl is calling
1776 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1777 it effectively keeps returning the first key over and over again. Instead,
1778 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1779
1780 =head2 ARRAYS
1781
1782 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1783 reference.  This includes inserting, removing and manipulating elements,
1784 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1785 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1786 or simply be a nested array reference inside a hash.  Example:
1787
1788         my $db = DBM::Deep->new(
1789                 file => "foo-array.db",
1790                 type => DBM::Deep->TYPE_ARRAY
1791         );
1792
1793         $db->[0] = "foo";
1794         push @$db, "bar", "baz";
1795         unshift @$db, "bah";
1796
1797         my $last_elem = pop @$db; # baz
1798         my $first_elem = shift @$db; # bah
1799         my $second_elem = $db->[1]; # bar
1800
1801         my $num_elements = scalar @$db;
1802
1803 =head1 OO INTERFACE
1804
1805 In addition to the I<tie()> interface, you can also use a standard OO interface
1806 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1807 array) has its own methods, but both types share the following common methods:
1808 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1809
1810 =over
1811
1812 =item * put()
1813
1814 Stores a new hash key/value pair, or sets an array element value.  Takes two
1815 arguments, the hash key or array index, and the new value.  The value can be
1816 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1817
1818         $db->put("foo", "bar"); # for hashes
1819         $db->put(1, "bar"); # for arrays
1820
1821 =item * get()
1822
1823 Fetches the value of a hash key or array element.  Takes one argument: the hash
1824 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1825 data type stored.
1826
1827         my $value = $db->get("foo"); # for hashes
1828         my $value = $db->get(1); # for arrays
1829
1830 =item * exists()
1831
1832 Checks if a hash key or array index exists.  Takes one argument: the hash key
1833 or array index.  Returns true if it exists, false if not.
1834
1835         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1836         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1837
1838 =item * delete()
1839
1840 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1841 key or array index.  Returns true on success, false if not found.  For arrays,
1842 the remaining elements located after the deleted element are NOT moved over.
1843 The deleted element is essentially just undefined, which is exactly how Perl's
1844 internal arrays work.  Please note that the space occupied by the deleted
1845 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1846 below for details and workarounds.
1847
1848         $db->delete("foo"); # for hashes
1849         $db->delete(1); # for arrays
1850
1851 =item * clear()
1852
1853 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1854 value.  Please note that the space occupied by the deleted keys/values or
1855 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1856 details and workarounds.
1857
1858         $db->clear(); # hashes or arrays
1859
1860 =back
1861
1862 =head2 HASHES
1863
1864 For hashes, DBM::Deep supports all the common methods described above, and the
1865 following additional methods: C<first_key()> and C<next_key()>.
1866
1867 =over
1868
1869 =item * first_key()
1870
1871 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1872 fetched in an undefined order (which appears random).  Takes no arguments,
1873 returns the key as a scalar value.
1874
1875         my $key = $db->first_key();
1876
1877 =item * next_key()
1878
1879 Returns the "next" key in the hash, given the previous one as the sole argument.
1880 Returns undef if there are no more keys to be fetched.
1881
1882         $key = $db->next_key($key);
1883
1884 =back
1885
1886 Here are some examples of using hashes:
1887
1888         my $db = DBM::Deep->new( "foo.db" );
1889
1890         $db->put("foo", "bar");
1891         print "foo: " . $db->get("foo") . "\n";
1892
1893         $db->put("baz", {}); # new child hash ref
1894         $db->get("baz")->put("buz", "biz");
1895         print "buz: " . $db->get("baz")->get("buz") . "\n";
1896
1897         my $key = $db->first_key();
1898         while ($key) {
1899                 print "$key: " . $db->get($key) . "\n";
1900                 $key = $db->next_key($key);
1901         }
1902
1903         if ($db->exists("foo")) { $db->delete("foo"); }
1904
1905 =head2 ARRAYS
1906
1907 For arrays, DBM::Deep supports all the common methods described above, and the
1908 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1909 C<unshift()> and C<splice()>.
1910
1911 =over
1912
1913 =item * length()
1914
1915 Returns the number of elements in the array.  Takes no arguments.
1916
1917         my $len = $db->length();
1918
1919 =item * push()
1920
1921 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1922 refs or array refs.  No return value.
1923
1924         $db->push("foo", "bar", {});
1925
1926 =item * pop()
1927
1928 Fetches the last element in the array, and deletes it.  Takes no arguments.
1929 Returns undef if array is empty.  Returns the element value.
1930
1931         my $elem = $db->pop();
1932
1933 =item * shift()
1934
1935 Fetches the first element in the array, deletes it, then shifts all the
1936 remaining elements over to take up the space.  Returns the element value.  This
1937 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1938 details.
1939
1940         my $elem = $db->shift();
1941
1942 =item * unshift()
1943
1944 Inserts one or more elements onto the beginning of the array, shifting all
1945 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1946 No return value.  This method is not recommended with large arrays -- see
1947 <LARGE ARRAYS> below for details.
1948
1949         $db->unshift("foo", "bar", {});
1950
1951 =item * splice()
1952
1953 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1954 -f splice> for usage -- it is too complicated to document here.  This method is
1955 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1956
1957 =back
1958
1959 Here are some examples of using arrays:
1960
1961         my $db = DBM::Deep->new(
1962                 file => "foo.db",
1963                 type => DBM::Deep->TYPE_ARRAY
1964         );
1965
1966         $db->push("bar", "baz");
1967         $db->unshift("foo");
1968         $db->put(3, "buz");
1969
1970         my $len = $db->length();
1971         print "length: $len\n"; # 4
1972
1973         for (my $k=0; $k<$len; $k++) {
1974                 print "$k: " . $db->get($k) . "\n";
1975         }
1976
1977         $db->splice(1, 2, "biz", "baf");
1978
1979         while (my $elem = shift @$db) {
1980                 print "shifted: $elem\n";
1981         }
1982
1983 =head1 LOCKING
1984
1985 Enable automatic file locking by passing a true value to the C<locking>
1986 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1987
1988         my $db = DBM::Deep->new(
1989                 file => "foo.db",
1990                 locking => 1
1991         );
1992
1993 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1994 mode for writes, and shared mode for reads.  This is required if you have
1995 multiple processes accessing the same database file, to avoid file corruption.
1996 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1997 NFS> below for more.
1998
1999 =head2 EXPLICIT LOCKING
2000
2001 You can explicitly lock a database, so it remains locked for multiple
2002 transactions.  This is done by calling the C<lock()> method, and passing an
2003 optional lock mode argument (defaults to exclusive mode).  This is particularly
2004 useful for things like counters, where the current value needs to be fetched,
2005 then incremented, then stored again.
2006
2007         $db->lock();
2008         my $counter = $db->get("counter");
2009         $counter++;
2010         $db->put("counter", $counter);
2011         $db->unlock();
2012
2013         # or...
2014
2015         $db->lock();
2016         $db->{counter}++;
2017         $db->unlock();
2018
2019 You can pass C<lock()> an optional argument, which specifies which mode to use
2020 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2021 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2022 same as the constants defined in Perl's C<Fcntl> module.
2023
2024         $db->lock( DBM::Deep->LOCK_SH );
2025         # something here
2026         $db->unlock();
2027
2028 If you want to implement your own file locking scheme, be sure to create your
2029 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2030 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2031 below for more.
2032
2033 =head1 IMPORTING/EXPORTING
2034
2035 You can import existing complex structures by calling the C<import()> method,
2036 and export an entire database into an in-memory structure using the C<export()>
2037 method.  Both are examined here.
2038
2039 =head2 IMPORTING
2040
2041 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2042 walking the structure and adding keys/elements to the database as you go,
2043 simply pass a reference to the C<import()> method.  This recursively adds
2044 everything to an existing DBM::Deep object for you.  Here is an example:
2045
2046         my $struct = {
2047                 key1 => "value1",
2048                 key2 => "value2",
2049                 array1 => [ "elem0", "elem1", "elem2" ],
2050                 hash1 => {
2051                         subkey1 => "subvalue1",
2052                         subkey2 => "subvalue2"
2053                 }
2054         };
2055
2056         my $db = DBM::Deep->new( "foo.db" );
2057         $db->import( $struct );
2058
2059         print $db->{key1} . "\n"; # prints "value1"
2060
2061 This recursively imports the entire C<$struct> object into C<$db>, including
2062 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2063 keys are merged with the existing ones, replacing if they already exist.
2064 The C<import()> method can be called on any database level (not just the base
2065 level), and works with both hash and array DB types.
2066
2067
2068
2069 B<Note:> Make sure your existing structure has no circular references in it.
2070 These will cause an infinite loop when importing.
2071
2072 =head2 EXPORTING
2073
2074 Calling the C<export()> method on an existing DBM::Deep object will return
2075 a reference to a new in-memory copy of the database.  The export is done
2076 recursively, so all nested hashes/arrays are all exported to standard Perl
2077 objects.  Here is an example:
2078
2079         my $db = DBM::Deep->new( "foo.db" );
2080
2081         $db->{key1} = "value1";
2082         $db->{key2} = "value2";
2083         $db->{hash1} = {};
2084         $db->{hash1}->{subkey1} = "subvalue1";
2085         $db->{hash1}->{subkey2} = "subvalue2";
2086
2087         my $struct = $db->export();
2088
2089         print $struct->{key1} . "\n"; # prints "value1"
2090
2091 This makes a complete copy of the database in memory, and returns a reference
2092 to it.  The C<export()> method can be called on any database level (not just
2093 the base level), and works with both hash and array DB types.  Be careful of
2094 large databases -- you can store a lot more data in a DBM::Deep object than an
2095 in-memory Perl structure.
2096
2097
2098
2099 B<Note:> Make sure your database has no circular references in it.
2100 These will cause an infinite loop when exporting.
2101
2102 =head1 FILTERS
2103
2104 DBM::Deep has a number of hooks where you can specify your own Perl function
2105 to perform filtering on incoming or outgoing data.  This is a perfect
2106 way to extend the engine, and implement things like real-time compression or
2107 encryption.  Filtering applies to the base DB level, and all child hashes /
2108 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2109 constructed, or by calling the C<set_filter()> method at any time.  There are
2110 four available filter hooks, described below:
2111
2112 =over
2113
2114 =item * filter_store_key
2115
2116 This filter is called whenever a hash key is stored.  It
2117 is passed the incoming key, and expected to return a transformed key.
2118
2119 =item * filter_store_value
2120
2121 This filter is called whenever a hash key or array element is stored.  It
2122 is passed the incoming value, and expected to return a transformed value.
2123
2124 =item * filter_fetch_key
2125
2126 This filter is called whenever a hash key is fetched (i.e. via
2127 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2128 and expected to return the plain key.
2129
2130 =item * filter_fetch_value
2131
2132 This filter is called whenever a hash key or array element is fetched.
2133 It is passed the transformed value, and expected to return the plain value.
2134
2135 =back
2136
2137 Here are the two ways to setup a filter hook:
2138
2139         my $db = DBM::Deep->new(
2140                 file => "foo.db",
2141                 filter_store_value => \&my_filter_store,
2142                 filter_fetch_value => \&my_filter_fetch
2143         );
2144
2145         # or...
2146
2147         $db->set_filter( "filter_store_value", \&my_filter_store );
2148         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2149
2150 Your filter function will be called only when dealing with SCALAR keys or
2151 values.  When nested hashes and arrays are being stored/fetched, filtering
2152 is bypassed.  Filters are called as static functions, passed a single SCALAR
2153 argument, and expected to return a single SCALAR value.  If you want to
2154 remove a filter, set the function reference to C<undef>:
2155
2156         $db->set_filter( "filter_store_value", undef );
2157
2158 =head2 REAL-TIME ENCRYPTION EXAMPLE
2159
2160 Here is a working example that uses the I<Crypt::Blowfish> module to
2161 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2162 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2163 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2164
2165         use DBM::Deep;
2166         use Crypt::Blowfish;
2167         use Crypt::CBC;
2168
2169         my $cipher = Crypt::CBC->new({
2170                 'key'             => 'my secret key',
2171                 'cipher'          => 'Blowfish',
2172                 'iv'              => '$KJh#(}q',
2173                 'regenerate_key'  => 0,
2174                 'padding'         => 'space',
2175                 'prepend_iv'      => 0
2176         });
2177
2178         my $db = DBM::Deep->new(
2179                 file => "foo-encrypt.db",
2180                 filter_store_key => \&my_encrypt,
2181                 filter_store_value => \&my_encrypt,
2182                 filter_fetch_key => \&my_decrypt,
2183                 filter_fetch_value => \&my_decrypt,
2184         );
2185
2186         $db->{key1} = "value1";
2187         $db->{key2} = "value2";
2188         print "key1: " . $db->{key1} . "\n";
2189         print "key2: " . $db->{key2} . "\n";
2190
2191         undef $db;
2192         exit;
2193
2194         sub my_encrypt {
2195                 return $cipher->encrypt( $_[0] );
2196         }
2197         sub my_decrypt {
2198                 return $cipher->decrypt( $_[0] );
2199         }
2200
2201 =head2 REAL-TIME COMPRESSION EXAMPLE
2202
2203 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2204 compression / decompression of keys & values with DBM::Deep Filters.
2205 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2206 more on I<Compress::Zlib>.
2207
2208         use DBM::Deep;
2209         use Compress::Zlib;
2210
2211         my $db = DBM::Deep->new(
2212                 file => "foo-compress.db",
2213                 filter_store_key => \&my_compress,
2214                 filter_store_value => \&my_compress,
2215                 filter_fetch_key => \&my_decompress,
2216                 filter_fetch_value => \&my_decompress,
2217         );
2218
2219         $db->{key1} = "value1";
2220         $db->{key2} = "value2";
2221         print "key1: " . $db->{key1} . "\n";
2222         print "key2: " . $db->{key2} . "\n";
2223
2224         undef $db;
2225         exit;
2226
2227         sub my_compress {
2228                 return Compress::Zlib::memGzip( $_[0] ) ;
2229         }
2230         sub my_decompress {
2231                 return Compress::Zlib::memGunzip( $_[0] ) ;
2232         }
2233
2234 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2235 actually numerical index numbers, and are not filtered.
2236
2237 =head1 ERROR HANDLING
2238
2239 Most DBM::Deep methods return a true value for success, and call die() on
2240 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2241 actual error message is stored in an internal scalar, which can be fetched by
2242 calling the C<error()> method.
2243
2244         my $db = DBM::Deep->new( "foo.db" ); # create hash
2245         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2246
2247         print $db->error(); # prints error message
2248
2249 You can then call C<clear_error()> to clear the current error state.
2250
2251         $db->clear_error();
2252
2253 If you set the C<debug> option to true when creating your DBM::Deep object,
2254 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2255 for debugging purposes.
2256
2257 =head1 LARGEFILE SUPPORT
2258
2259 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2260 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2261 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2262 by calling the static C<set_pack()> method before you do anything else.
2263
2264         DBM::Deep::set_pack(8, 'Q');
2265
2266 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2267 instead of 32-bit longs.  After setting these values your DB files have a
2268 theoretical maximum size of 16 XB (exabytes).
2269
2270
2271
2272 B<Note:> Changing these values will B<NOT> work for existing database files.
2273 Only change this for new files, and make sure it stays set consistently
2274 throughout the file's life.  If you do set these values, you can no longer
2275 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2276 back to 32-bit mode.
2277
2278
2279
2280 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2281 only a 32-bit Perl.  However, I have received user reports that this does
2282 indeed work!
2283
2284 =head1 LOW-LEVEL ACCESS
2285
2286 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2287 you can call the C<fh()> method, which returns the handle:
2288
2289         my $fh = $db->fh();
2290
2291 This method can be called on the root level of the datbase, or any child
2292 hashes or arrays.  All levels share a I<root> structure, which contains things
2293 like the FileHandle, a reference counter, and all your options you specified
2294 when you created the object.  You can get access to this root structure by
2295 calling the C<root()> method.
2296
2297         my $root = $db->root();
2298
2299 This is useful for changing options after the object has already been created,
2300 such as enabling/disabling locking, volatile or debug modes.  You can also
2301 store your own temporary user data in this structure (be wary of name
2302 collision), which is then accessible from any child hash or array.
2303
2304 =head1 CUSTOM DIGEST ALGORITHM
2305
2306 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2307 keys.  However you can override this, and use another algorithm (such as SHA-256)
2308 or even write your own.  But please note that DBM::Deep currently expects zero
2309 collisions, so your algorithm has to be I<perfect>, so to speak.
2310 Collision detection may be introduced in a later version.
2311
2312
2313
2314 You can specify a custom digest algorithm by calling the static C<set_digest()>
2315 function, passing a reference to a subroutine, and the length of the algorithm's
2316 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2317 objects.  Here is a working example that uses a 256-bit hash from the
2318 I<Digest::SHA256> module.  Please see
2319 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2320
2321         use DBM::Deep;
2322         use Digest::SHA256;
2323
2324         my $context = Digest::SHA256::new(256);
2325
2326         DBM::Deep::set_digest( \&my_digest, 32 );
2327
2328         my $db = DBM::Deep->new( "foo-sha.db" );
2329
2330         $db->{key1} = "value1";
2331         $db->{key2} = "value2";
2332         print "key1: " . $db->{key1} . "\n";
2333         print "key2: " . $db->{key2} . "\n";
2334
2335         undef $db;
2336         exit;
2337
2338         sub my_digest {
2339                 return substr( $context->hash($_[0]), 0, 32 );
2340         }
2341
2342 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2343 of bytes you specify in the C<set_digest()> function (in this case 32).
2344
2345 =head1 CIRCULAR REFERENCES
2346
2347 DBM::Deep has B<experimental> support for circular references.  Meaning you
2348 can have a nested hash key or array element that points to a parent object.
2349 This relationship is stored in the DB file, and is preserved between sessions.
2350 Here is an example:
2351
2352         my $db = DBM::Deep->new( "foo.db" );
2353
2354         $db->{foo} = "bar";
2355         $db->{circle} = $db; # ref to self
2356
2357         print $db->{foo} . "\n"; # prints "foo"
2358         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2359
2360 One catch is, passing the object to a function that recursively walks the
2361 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2362 C<export()> methods) will result in an infinite loop.  The other catch is,
2363 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2364 or C<next_key()> methods), you will get the I<target object's key>, not the
2365 ref's key.  This gets even more interesting with the above example, where
2366 the I<circle> key points to the base DB object, which technically doesn't
2367 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2368 special case.
2369
2370 =head1 CAVEATS / ISSUES / BUGS
2371
2372 This section describes all the known issues with DBM::Deep.  It you have found
2373 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2374
2375 =head2 UNUSED SPACE RECOVERY
2376
2377 One major caveat with DBM::Deep is that space occupied by existing keys and
2378 values is not recovered when they are deleted.  Meaning if you keep deleting
2379 and adding new keys, your file will continuously grow.  I am working on this,
2380 but in the meantime you can call the built-in C<optimize()> method from time to
2381 time (perhaps in a crontab or something) to recover all your unused space.
2382
2383         $db->optimize(); # returns true on success
2384
2385 This rebuilds the ENTIRE database into a new file, then moves it on top of
2386 the original.  The new file will have no unused space, thus it will take up as
2387 little disk space as possible.  Please note that this operation can take
2388 a long time for large files, and you need enough disk space to temporarily hold
2389 2 copies of your DB file.  The temporary file is created in the same directory
2390 as the original, named with a ".tmp" extension, and is deleted when the
2391 operation completes.  Oh, and if locking is enabled, the DB is automatically
2392 locked for the entire duration of the copy.
2393
2394
2395
2396 B<WARNING:> Only call optimize() on the top-level node of the database, and
2397 make sure there are no child references lying around.  DBM::Deep keeps a reference
2398 counter, and if it is greater than 1, optimize() will abort and return undef.
2399
2400 =head2 AUTOVIVIFICATION
2401
2402 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2403 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2404 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2405 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2406 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2407 this does not work:
2408
2409         $db->{foo}->{bar} = "hello";
2410
2411 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2412 being an empty hash.  Try this instead, which works fine:
2413
2414         $db->{foo} = { bar => "hello" };
2415
2416 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2417 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2418 Probably a bug in Perl.
2419
2420 =head2 FILE CORRUPTION
2421
2422 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2423 for a 32-bit signature when opened, but other corruption in files can cause
2424 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2425 stuck in an infinite loop depending on the level of corruption.  File write
2426 operations are not checked for failure (for speed), so if you happen to run
2427 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2428 be addressed in a later version of DBM::Deep.
2429
2430 =head2 DB OVER NFS
2431
2432 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2433 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2434 about setting up your NFS server with a locking daemon, then using lockf() to
2435 lock your files, but your milage may vary there as well.  From what I
2436 understand, there is no real way to do it.  However, if you need access to the
2437 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2438 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2439
2440 =head2 COPYING OBJECTS
2441
2442 Beware of copying tied objects in Perl.  Very strange things can happen.
2443 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2444 returns a new, blessed, tied hash or array to the same level in the DB.
2445
2446         my $copy = $db->clone();
2447
2448 =head2 LARGE ARRAYS
2449
2450 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2451 These functions cause every element in the array to move, which can be murder
2452 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2453 a different location.  This may be addressed in a later version.
2454
2455 =head1 PERFORMANCE
2456
2457 This section discusses DBM::Deep's speed and memory usage.
2458
2459 =head2 SPEED
2460
2461 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2462 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2463 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2464 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2465 with huge databases.  Here is some test data:
2466
2467         Adding 1,000,000 keys to new DB file...
2468
2469         At 100 keys, avg. speed is 2,703 keys/sec
2470         At 200 keys, avg. speed is 2,642 keys/sec
2471         At 300 keys, avg. speed is 2,598 keys/sec
2472         At 400 keys, avg. speed is 2,578 keys/sec
2473         At 500 keys, avg. speed is 2,722 keys/sec
2474         At 600 keys, avg. speed is 2,628 keys/sec
2475         At 700 keys, avg. speed is 2,700 keys/sec
2476         At 800 keys, avg. speed is 2,607 keys/sec
2477         At 900 keys, avg. speed is 2,190 keys/sec
2478         At 1,000 keys, avg. speed is 2,570 keys/sec
2479         At 2,000 keys, avg. speed is 2,417 keys/sec
2480         At 3,000 keys, avg. speed is 1,982 keys/sec
2481         At 4,000 keys, avg. speed is 1,568 keys/sec
2482         At 5,000 keys, avg. speed is 1,533 keys/sec
2483         At 6,000 keys, avg. speed is 1,787 keys/sec
2484         At 7,000 keys, avg. speed is 1,977 keys/sec
2485         At 8,000 keys, avg. speed is 2,028 keys/sec
2486         At 9,000 keys, avg. speed is 2,077 keys/sec
2487         At 10,000 keys, avg. speed is 2,031 keys/sec
2488         At 20,000 keys, avg. speed is 1,970 keys/sec
2489         At 30,000 keys, avg. speed is 2,050 keys/sec
2490         At 40,000 keys, avg. speed is 2,073 keys/sec
2491         At 50,000 keys, avg. speed is 1,973 keys/sec
2492         At 60,000 keys, avg. speed is 1,914 keys/sec
2493         At 70,000 keys, avg. speed is 2,091 keys/sec
2494         At 80,000 keys, avg. speed is 2,103 keys/sec
2495         At 90,000 keys, avg. speed is 1,886 keys/sec
2496         At 100,000 keys, avg. speed is 1,970 keys/sec
2497         At 200,000 keys, avg. speed is 2,053 keys/sec
2498         At 300,000 keys, avg. speed is 1,697 keys/sec
2499         At 400,000 keys, avg. speed is 1,838 keys/sec
2500         At 500,000 keys, avg. speed is 1,941 keys/sec
2501         At 600,000 keys, avg. speed is 1,930 keys/sec
2502         At 700,000 keys, avg. speed is 1,735 keys/sec
2503         At 800,000 keys, avg. speed is 1,795 keys/sec
2504         At 900,000 keys, avg. speed is 1,221 keys/sec
2505         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2506
2507 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2508 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2509 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2510 Run time was 12 min 3 sec.
2511
2512 =head2 MEMORY USAGE
2513
2514 One of the great things about DBM::Deep is that it uses very little memory.
2515 Even with huge databases (1,000,000+ keys) you will not see much increased
2516 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2517 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2518 database handle:
2519
2520           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2521         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2522
2523 Basically the process is taking 2,716K of memory.  And here is the same
2524 process after storing and fetching 1,000,000 keys:
2525
2526           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2527         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2528
2529 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2530 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2531
2532 =head1 DB FILE FORMAT
2533
2534 In case you were interested in the underlying DB file format, it is documented
2535 here in this section.  You don't need to know this to use the module, it's just
2536 included for reference.
2537
2538 =head2 SIGNATURE
2539
2540 DBM::Deep files always start with a 32-bit signature to identify the file type.
2541 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2542 checked when the file is opened.
2543
2544 =head2 TAG
2545
2546 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2547 has a standard header containing the type of data, the length of data, and then
2548 the data itself.  The type is a single character (1 byte), the length is a
2549 32-bit unsigned long in network byte order, and the data is, well, the data.
2550 Here is how it unfolds:
2551
2552 =head2 MASTER INDEX
2553
2554 Immediately after the 32-bit file signature is the I<Master Index> record.
2555 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2556 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2557 depending on how the DBM::Deep object was constructed.
2558
2559
2560
2561 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2562 number).  The first 8-bit char of the MD5 signature is the offset into the
2563 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2564 index element is a file offset of the next tag for the key/element in question,
2565 which is usually a I<Bucket List> tag (see below).
2566
2567
2568
2569 The next tag I<could> be another index, depending on how many keys/elements
2570 exist.  See L<RE-INDEXING> below for details.
2571
2572 =head2 BUCKET LIST
2573
2574 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2575 file offsets to where the actual data is stored.  It starts with a standard
2576 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2577 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2578 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2579 When the list fills up, a I<Re-Index> operation is performed (See
2580 L<RE-INDEXING> below).
2581
2582 =head2 BUCKET
2583
2584 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2585 index/value pair (in array mode).  It starts with a standard tag header with
2586 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2587 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2588 header.  The size reported in the tag header is only for the value, but then,
2589 just after the value is another size (32-bit unsigned long) and then the plain
2590 key itself.  Since the value is likely to be fetched more often than the plain
2591 key, I figured it would be I<slightly> faster to store the value first.
2592
2593
2594
2595 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2596 record for the nested structure, where the process begins all over again.
2597
2598 =head2 RE-INDEXING
2599
2600 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2601 exhausted.  Then, when another key/element comes in, the list is converted to a
2602 new index record.  However, this index will look at the next char in the MD5
2603 hash, and arrange new Bucket List pointers accordingly.  This process is called
2604 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2605 17 (16 + new one) keys/elements are removed from the old Bucket List and
2606 inserted into the new index.  Several new Bucket Lists are created in the
2607 process, as a new MD5 char from the key is being examined (it is unlikely that
2608 the keys will all share the same next char of their MD5s).
2609
2610
2611
2612 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2613 when the Bucket Lists will turn into indexes, but the first round tends to
2614 happen right around 4,000 keys.  You will see a I<slight> decrease in
2615 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2616 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2617 right around 900,000 keys.  This process can continue nearly indefinitely --
2618 right up until the point the I<MD5> signatures start colliding with each other,
2619 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2620 getting struck by lightning while you are walking to cash in your tickets.
2621 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2622 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2623 this is 340 unodecillion, but don't quote me).
2624
2625 =head2 STORING
2626
2627 When a new key/element is stored, the key (or index number) is first ran through
2628 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2629 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2630 for the first char of the signature (in this case I<b>).  If it does not exist,
2631 a new I<Bucket List> is created for our key (and the next 15 future keys that
2632 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2633 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2634 this point, unless we are replacing an existing I<Bucket>), where the actual
2635 data will be stored.
2636
2637 =head2 FETCHING
2638
2639 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2640 (or index number), then walking along the indexes.  If there are enough
2641 keys/elements in this DB level, there might be nested indexes, each linked to
2642 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2643 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2644 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2645 plain key are stored.
2646
2647
2648
2649 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2650 methods.  In this process the indexes are walked systematically, and each key
2651 fetched in increasing MD5 order (which is why it appears random).   Once the
2652 I<Bucket> is found, the value is skipped the plain key returned instead.
2653 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2654 alphabetically sorted.  This only happens on an index-level -- as soon as the
2655 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2656 so it's pretty much undefined how the keys will come out -- just like Perl's
2657 built-in hashes.
2658
2659 =head1 CODE COVERAGE
2660
2661 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2662 module's test suite.
2663
2664   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2665   File                           stmt   bran   cond    sub    pod   time  total
2666   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2667   blib/lib/DBM/Deep.pm           94.1   82.9   74.5   98.0   10.5   98.1   88.2
2668   blib/lib/DBM/Deep/Array.pm     97.8   83.3   50.0  100.0    n/a    1.6   94.4
2669   blib/lib/DBM/Deep/Hash.pm      93.3   85.7  100.0  100.0    n/a    0.3   92.7
2670   Total                          94.5   83.1   75.5   98.4   10.5  100.0   89.0
2671   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2672
2673 =head1 AUTHOR
2674
2675 Joseph Huckaby, L<jhuckaby@cpan.org>
2676
2677 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2678
2679 =head1 SEE ALSO
2680
2681 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2682 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2683
2684 =head1 LICENSE
2685
2686 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2687 This is free software, you may use it and distribute it under the
2688 same terms as Perl itself.
2689
2690 =cut