lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw/:flock/;
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37 use vars qw/$VERSION/;
  38
  39 $VERSION = "0.96";
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 my ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub new {
 106         ##
 107         # Class constructor method for Perl OO interface.
 108         # Calls tie() and returns blessed reference to tied hash or array,
 109         # providing a hybrid OO/tie interface.
 110         ##
 111         my $class = shift;
 112         my $args;
 113         if (scalar(@_) > 1) { $args = {@_}; }
 114         else { $args = { file => shift }; }
 115
 116         ##
 117         # Check if we want a tied hash or array.
 118         ##
 119         my $self;
 120         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 121                 tie @$self, $class, %$args;
 122         }
 123         else {
 124                 tie %$self, $class, %$args;
 125         }
 126
 127         return bless $self, $class;
 128 }
 129
 130 {
 131     my @outer_params = qw( type base_offset );
 132     sub _init {
 133         ##
 134         # Setup $self and bless into this class.
 135         ##
 136         my $class = shift;
 137         my $args = shift;
 138
 139         my $self = {
 140             type => TYPE_HASH,
 141             base_offset => length(SIG_FILE),
 142         };
 143
 144         bless $self, $class;
 145
 146         foreach my $outer_parm ( @outer_params ) {
 147             next unless exists $args->{$outer_parm};
 148             $self->{$outer_parm} = delete $args->{$outer_parm}
 149         }
 150
 151         $self->{root} = exists $args->{root}
 152             ? $args->{root}
 153             : DBM::Deep::_::Root->new( $args );
 154
 155         if (!defined($self->fh)) { $self->_open(); }
 156
 157         return $self;
 158     }
 159 }
 160
 161 sub _get_self {
 162     tied( %{$_[0]} ) || $_[0]
 163 }
 164
 165 sub TIEHASH {
 166     ##
 167     # Tied hash constructor method, called by Perl's tie() function.
 168     ##
 169     my $class = shift;
 170     my $args;
 171     if (scalar(@_) > 1) { $args = {@_}; }
 172     #XXX This use of ref() is bad and is a bug
 173     elsif (ref($_[0])) { $args = $_[0]; }
 174     else { $args = { file => shift }; }
 175
 176     $args->{type} = TYPE_HASH;
 177
 178     return $class->_init($args);
 179 }
 180
 181 sub TIEARRAY {
 182 ##
 183 # Tied array constructor method, called by Perl's tie() function.
 184 ##
 185     my $class = shift;
 186     my $args;
 187     if (scalar(@_) > 1) { $args = {@_}; }
 188     #XXX This use of ref() is bad and is a bug
 189         elsif (ref($_[0])) { $args = $_[0]; }
 190         else { $args = { file => shift }; }
 191
 192         $args->{type} = TYPE_ARRAY;
 193
 194         return $class->_init($args);
 195 }
 196
 197 #XXX Unneeded now ...
 198 #sub DESTROY {
 199 #}
 200
 201 my %translate_mode = (
 202     'r' => '<',
 203     'r+' => '+<',
 204     'w' => '>',
 205     'w+' => '+>',
 206     'a' => '>>',
 207     'a+' => '+>>',
 208 );
 209 sub _open {
 210         ##
 211         # Open a FileHandle to the database, create if nonexistent.
 212         # Make sure file signature matches DeepDB spec.
 213         ##
 214     my $self = _get_self($_[0]);
 215
 216         if (defined($self->fh)) { $self->_close(); }
 217
 218     eval {
 219         my $filename = $self->root->{file};
 220         my $mode = $translate_mode{ $self->root->{mode} };
 221
 222         if (!(-e $filename) && $mode eq '+<') {
 223             open( FH, '>', $filename );
 224             close FH;
 225         }
 226
 227         my $fh;
 228         open( $fh, $mode, $filename )
 229             or $fh = undef;
 230         $self->root->{fh} = $fh;
 231     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 232         if (! defined($self->fh)) {
 233                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 234         }
 235
 236     my $fh = $self->fh;
 237
 238     #XXX Can we remove this by using the right sysopen() flags?
 239     binmode $fh; # for win32
 240
 241     if ($self->root->{autoflush}) {
 242         my $old = select $fh;
 243         $|=1;
 244         select $old;
 245     }
 246
 247     my $signature;
 248     seek($fh, 0, 0);
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, 0);
 256         print($fh SIG_FILE);
 257         $self->root->{end} = length(SIG_FILE);
 258         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 263
 264         # Flush the filehandle
 265         my $old_fh = select $fh;
 266         my $old_af = $|;
 267         $| = 1;
 268         $| = $old_af;
 269         select $old_fh;
 270
 271         return 1;
 272     }
 273
 274     ##
 275     # Check signature was valid
 276     ##
 277     unless ($signature eq SIG_FILE) {
 278         $self->_close();
 279         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 280     }
 281
 282     $self->root->{end} = (stat($fh))[7];
 283
 284     ##
 285     # Get our type from master index signature
 286     ##
 287     my $tag = $self->_load_tag($self->base_offset);
 288
 289 #XXX We probably also want to store the hash algorithm name and not assume anything
 290
 291     if (!$tag) {
 292         return $self->_throw_error("Corrupted file, no master index record");
 293     }
 294     if ($self->{type} ne $tag->{signature}) {
 295         return $self->_throw_error("File type mismatch");
 296     }
 297
 298     return 1;
 299 }
 300
 301 sub _close {
 302         ##
 303         # Close database FileHandle
 304         ##
 305     my $self = _get_self($_[0]);
 306     close $self->root->{fh};
 307 }
 308
 309 sub _create_tag {
 310         ##
 311         # Given offset, signature and content, create tag and write to disk
 312         ##
 313         my ($self, $offset, $sig, $content) = @_;
 314         my $size = length($content);
 315
 316     my $fh = $self->fh;
 317
 318         seek($fh, $offset, 0);
 319         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 320
 321         if ($offset == $self->root->{end}) {
 322                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 323         }
 324
 325         return {
 326                 signature => $sig,
 327                 size => $size,
 328                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 329                 content => $content
 330         };
 331 }
 332
 333 sub _load_tag {
 334         ##
 335         # Given offset, load single tag and return signature, size and data
 336         ##
 337         my $self = shift;
 338         my $offset = shift;
 339
 340     my $fh = $self->fh;
 341
 342         seek($fh, $offset, 0);
 343         if (eof $fh) { return undef; }
 344
 345         my $sig;
 346         read( $fh, $sig, SIG_SIZE);
 347
 348         my $size;
 349         read( $fh, $size, $DATA_LENGTH_SIZE);
 350         $size = unpack($DATA_LENGTH_PACK, $size);
 351
 352         my $buffer;
 353         read( $fh, $buffer, $size);
 354
 355         return {
 356                 signature => $sig,
 357                 size => $size,
 358                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 359                 content => $buffer
 360         };
 361 }
 362
 363 sub _index_lookup {
 364         ##
 365         # Given index tag, lookup single entry in index and return .
 366         ##
 367         my $self = shift;
 368         my ($tag, $index) = @_;
 369
 370         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 371         if (!$location) { return; }
 372
 373         return $self->_load_tag( $location );
 374 }
 375
 376 sub _add_bucket {
 377         ##
 378         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 379         # plain (undigested) key and value.
 380         ##
 381         my $self = shift;
 382         my ($tag, $md5, $plain_key, $value) = @_;
 383         my $keys = $tag->{content};
 384         my $location = 0;
 385         my $result = 2;
 386
 387     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 388         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 389
 390     my $fh = $self->fh;
 391
 392         ##
 393         # Iterate through buckets, seeing if this is a new entry or a replace.
 394         ##
 395         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 396                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 397                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 398                 if (!$subloc) {
 399                         ##
 400                         # Found empty bucket (end of list).  Populate and exit loop.
 401                         ##
 402                         $result = 2;
 403
 404             $location = $internal_ref
 405                 ? $value->base_offset
 406                 : $self->root->{end};
 407
 408                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 409                         print($fh $md5 . pack($LONG_PACK, $location) );
 410                         last;
 411                 }
 412                 elsif ($md5 eq $key) {
 413                         ##
 414                         # Found existing bucket with same key.  Replace with new value.
 415                         ##
 416                         $result = 1;
 417
 418                         if ($internal_ref) {
 419                                 $location = $value->base_offset;
 420                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 421                                 print($fh $md5 . pack($LONG_PACK, $location) );
 422                         }
 423                         else {
 424                                 seek($fh, $subloc + SIG_SIZE, 0);
 425                                 my $size;
 426                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 427
 428                                 ##
 429                                 # If value is a hash, array, or raw value with equal or less size, we can
 430                                 # reuse the same content area of the database.  Otherwise, we have to create
 431                                 # a new content area at the EOF.
 432                                 ##
 433                                 my $actual_length;
 434                 my $r = Scalar::Util::reftype( $value ) || '';
 435                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 436                                 else { $actual_length = length($value); }
 437
 438                                 if ($actual_length <= $size) {
 439                                         $location = $subloc;
 440                                 }
 441                                 else {
 442                                         $location = $self->root->{end};
 443                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 444                                         print($fh pack($LONG_PACK, $location) );
 445                                 }
 446                         }
 447                         last;
 448                 }
 449         } # i loop
 450
 451         ##
 452         # If this is an internal reference, return now.
 453         # No need to write value or plain key
 454         ##
 455         if ($internal_ref) {
 456         return $result;
 457     }
 458
 459         ##
 460         # If bucket didn't fit into list, split into a new index level
 461         ##
 462         if (!$location) {
 463                 seek($fh, $tag->{ref_loc}, 0);
 464                 print($fh pack($LONG_PACK, $self->root->{end}) );
 465
 466                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 467                 my @offsets = ();
 468
 469                 $keys .= $md5 . pack($LONG_PACK, 0);
 470
 471                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 472                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 473                         if ($key) {
 474                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 475                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 476
 477                                 if ($offsets[$num]) {
 478                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 479                                         seek($fh, $offset, 0);
 480                                         my $subkeys;
 481                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 482
 483                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 484                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 485                                                 if (!$subloc) {
 486                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), 0);
 487                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 488                                                         last;
 489                                                 }
 490                                         } # k loop
 491                                 }
 492                                 else {
 493                                         $offsets[$num] = $self->root->{end};
 494                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 495                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 496
 497                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 498
 499                                         seek($fh, $blist_tag->{offset}, 0);
 500                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 501                                 }
 502                         } # key is real
 503                 } # i loop
 504
 505                 $location ||= $self->root->{end};
 506         } # re-index bucket list
 507
 508         ##
 509         # Seek to content area and store signature, value and plaintext key
 510         ##
 511         if ($location) {
 512                 my $content_length;
 513                 seek($fh, $location, 0);
 514
 515                 ##
 516                 # Write signature based on content type, set content length and write actual value.
 517                 ##
 518         my $r = Scalar::Util::reftype($value) || '';
 519                 if ($r eq 'HASH') {
 520                         print($fh TYPE_HASH );
 521                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 522                         $content_length = $INDEX_SIZE;
 523                 }
 524                 elsif ($r eq 'ARRAY') {
 525                         print($fh TYPE_ARRAY );
 526                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 527                         $content_length = $INDEX_SIZE;
 528                 }
 529                 elsif (!defined($value)) {
 530                         print($fh SIG_NULL );
 531                         print($fh pack($DATA_LENGTH_PACK, 0) );
 532                         $content_length = 0;
 533                 }
 534                 else {
 535                         print($fh SIG_DATA );
 536                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 537                         $content_length = length($value);
 538                 }
 539
 540                 ##
 541                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 542                 ##
 543                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 544
 545                 ##
 546                 # If value is blessed, preserve class name
 547                 ##
 548                 if ( $self->root->{autobless} ) {
 549             my $value_class = Scalar::Util::blessed($value);
 550             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 551                 ##
 552                 # Blessed ref -- will restore later
 553                 ##
 554                 print($fh chr(1) );
 555                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 556                 $content_length += 1;
 557                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 558             }
 559             else {
 560                 print($fh chr(0) );
 561                 $content_length += 1;
 562             }
 563         }
 564
 565                 ##
 566                 # If this is a new content area, advance EOF counter
 567                 ##
 568                 if ($location == $self->root->{end}) {
 569                         $self->root->{end} += SIG_SIZE;
 570                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 571                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 572                 }
 573
 574                 ##
 575                 # If content is a hash or array, create new child DeepDB object and
 576                 # pass each key or element to it.
 577                 ##
 578                 if ($r eq 'HASH') {
 579                         my $branch = DBM::Deep->new(
 580                                 type => TYPE_HASH,
 581                                 base_offset => $location,
 582                                 root => $self->root,
 583                         );
 584                         foreach my $key (keys %{$value}) {
 585                 #$branch->{$key} = $value->{$key};
 586                 $branch->STORE( $key, $value->{$key} );
 587                         }
 588                 }
 589                 elsif ($r eq 'ARRAY') {
 590                         my $branch = DBM::Deep->new(
 591                                 type => TYPE_ARRAY,
 592                                 base_offset => $location,
 593                                 root => $self->root,
 594                         );
 595                         my $index = 0;
 596                         foreach my $element (@{$value}) {
 597                 #$branch->[$index] = $element;
 598                 $branch->STORE( $index, $element );
 599                                 $index++;
 600                         }
 601                 }
 602
 603                 return $result;
 604         }
 605
 606         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 607 }
 608
 609 sub _get_bucket_value {
 610         ##
 611         # Fetch single value given tag and MD5 digested key.
 612         ##
 613         my $self = shift;
 614         my ($tag, $md5) = @_;
 615         my $keys = $tag->{content};
 616
 617     my $fh = $self->fh;
 618
 619         ##
 620         # Iterate through buckets, looking for a key match
 621         ##
 622     BUCKET:
 623         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 624                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 625                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 626
 627                 if (!$subloc) {
 628                         ##
 629                         # Hit end of list, no match
 630                         ##
 631                         return;
 632                 }
 633
 634         if ( $md5 ne $key ) {
 635             next BUCKET;
 636         }
 637
 638         ##
 639         # Found match -- seek to offset and read signature
 640         ##
 641         my $signature;
 642         seek($fh, $subloc, 0);
 643         read( $fh, $signature, SIG_SIZE);
 644
 645         ##
 646         # If value is a hash or array, return new DeepDB object with correct offset
 647         ##
 648         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 649             my $obj = DBM::Deep->new(
 650                 type => $signature,
 651                 base_offset => $subloc,
 652                 root => $self->root
 653             );
 654
 655             if ($self->root->{autobless}) {
 656                 ##
 657                 # Skip over value and plain key to see if object needs
 658                 # to be re-blessed
 659                 ##
 660                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 661
 662                 my $size;
 663                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 664                 if ($size) { seek($fh, $size, 1); }
 665
 666                 my $bless_bit;
 667                 read( $fh, $bless_bit, 1);
 668                 if (ord($bless_bit)) {
 669                     ##
 670                     # Yes, object needs to be re-blessed
 671                     ##
 672                     my $class_name;
 673                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 674                     if ($size) { read( $fh, $class_name, $size); }
 675                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 676                 }
 677             }
 678
 679             return $obj;
 680         }
 681
 682         ##
 683         # Otherwise return actual value
 684         ##
 685         elsif ($signature eq SIG_DATA) {
 686             my $size;
 687             my $value = '';
 688             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 689             if ($size) { read( $fh, $value, $size); }
 690             return $value;
 691         }
 692
 693         ##
 694         # Key exists, but content is null
 695         ##
 696         else { return; }
 697         } # i loop
 698
 699         return;
 700 }
 701
 702 sub _delete_bucket {
 703         ##
 704         # Delete single key/value pair given tag and MD5 digested key.
 705         ##
 706         my $self = shift;
 707         my ($tag, $md5) = @_;
 708         my $keys = $tag->{content};
 709
 710     my $fh = $self->fh;
 711
 712         ##
 713         # Iterate through buckets, looking for a key match
 714         ##
 715     BUCKET:
 716         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 717                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 718                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 719
 720                 if (!$subloc) {
 721                         ##
 722                         # Hit end of list, no match
 723                         ##
 724                         return;
 725                 }
 726
 727         if ( $md5 ne $key ) {
 728             next BUCKET;
 729         }
 730
 731         ##
 732         # Matched key -- delete bucket and return
 733         ##
 734         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 735         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 736         print($fh chr(0) x $BUCKET_SIZE );
 737
 738         return 1;
 739         } # i loop
 740
 741         return;
 742 }
 743
 744 sub _bucket_exists {
 745         ##
 746         # Check existence of single key given tag and MD5 digested key.
 747         ##
 748         my $self = shift;
 749         my ($tag, $md5) = @_;
 750         my $keys = $tag->{content};
 751
 752         ##
 753         # Iterate through buckets, looking for a key match
 754         ##
 755     BUCKET:
 756         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 757                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 758                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 759
 760                 if (!$subloc) {
 761                         ##
 762                         # Hit end of list, no match
 763                         ##
 764                         return;
 765                 }
 766
 767         if ( $md5 ne $key ) {
 768             next BUCKET;
 769         }
 770
 771         ##
 772         # Matched key -- return true
 773         ##
 774         return 1;
 775         } # i loop
 776
 777         return;
 778 }
 779
 780 sub _find_bucket_list {
 781         ##
 782         # Locate offset for bucket list, given digested key
 783         ##
 784         my $self = shift;
 785         my $md5 = shift;
 786
 787         ##
 788         # Locate offset for bucket list using digest index system
 789         ##
 790         my $ch = 0;
 791         my $tag = $self->_load_tag($self->base_offset);
 792         if (!$tag) { return; }
 793
 794         while ($tag->{signature} ne SIG_BLIST) {
 795                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 796                 if (!$tag) { return; }
 797                 $ch++;
 798         }
 799
 800         return $tag;
 801 }
 802
 803 sub _traverse_index {
 804         ##
 805         # Scan index and recursively step into deeper levels, looking for next key.
 806         ##
 807     my ($self, $offset, $ch, $force_return_next) = @_;
 808     $force_return_next = undef unless $force_return_next;
 809
 810         my $tag = $self->_load_tag( $offset );
 811
 812     my $fh = $self->fh;
 813
 814         if ($tag->{signature} ne SIG_BLIST) {
 815                 my $content = $tag->{content};
 816                 my $start;
 817                 if ($self->{return_next}) { $start = 0; }
 818                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 819
 820                 for (my $index = $start; $index < 256; $index++) {
 821                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 822                         if ($subloc) {
 823                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 824                                 if (defined($result)) { return $result; }
 825                         }
 826                 } # index loop
 827
 828                 $self->{return_next} = 1;
 829         } # tag is an index
 830
 831         elsif ($tag->{signature} eq SIG_BLIST) {
 832                 my $keys = $tag->{content};
 833                 if ($force_return_next) { $self->{return_next} = 1; }
 834
 835                 ##
 836                 # Iterate through buckets, looking for a key match
 837                 ##
 838                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 839                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 840                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 841
 842                         if (!$subloc) {
 843                                 ##
 844                                 # End of bucket list -- return to outer loop
 845                                 ##
 846                                 $self->{return_next} = 1;
 847                                 last;
 848                         }
 849                         elsif ($key eq $self->{prev_md5}) {
 850                                 ##
 851                                 # Located previous key -- return next one found
 852                                 ##
 853                                 $self->{return_next} = 1;
 854                                 next;
 855                         }
 856                         elsif ($self->{return_next}) {
 857                                 ##
 858                                 # Seek to bucket location and skip over signature
 859                                 ##
 860                                 seek($fh, $subloc + SIG_SIZE, 0);
 861
 862                                 ##
 863                                 # Skip over value to get to plain key
 864                                 ##
 865                                 my $size;
 866                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 867                                 if ($size) { seek($fh, $size, 1); }
 868
 869                                 ##
 870                                 # Read in plain key and return as scalar
 871                                 ##
 872                                 my $plain_key;
 873                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 874                                 if ($size) { read( $fh, $plain_key, $size); }
 875
 876                                 return $plain_key;
 877                         }
 878                 } # bucket loop
 879
 880                 $self->{return_next} = 1;
 881         } # tag is a bucket list
 882
 883         return;
 884 }
 885
 886 sub _get_next_key {
 887         ##
 888         # Locate next key, given digested previous one
 889         ##
 890     my $self = _get_self($_[0]);
 891
 892         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 893         $self->{return_next} = 0;
 894
 895         ##
 896         # If the previous key was not specifed, start at the top and
 897         # return the first one found.
 898         ##
 899         if (!$self->{prev_md5}) {
 900                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 901                 $self->{return_next} = 1;
 902         }
 903
 904         return $self->_traverse_index( $self->base_offset, 0 );
 905 }
 906
 907 sub lock {
 908         ##
 909         # If db locking is set, flock() the db file.  If called multiple
 910         # times before unlock(), then the same number of unlocks() must
 911         # be called before the lock is released.
 912         ##
 913     my $self = _get_self($_[0]);
 914         my $type = $_[1];
 915     $type = LOCK_EX unless defined $type;
 916
 917         if ($self->root->{locking}) {
 918                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 919                 $self->root->{locked}++;
 920
 921         return 1;
 922         }
 923
 924     return;
 925 }
 926
 927 sub unlock {
 928         ##
 929         # If db locking is set, unlock the db file.  See note in lock()
 930         # regarding calling lock() multiple times.
 931         ##
 932     my $self = _get_self($_[0]);
 933
 934         if ($self->root->{locking} && $self->root->{locked} > 0) {
 935                 $self->root->{locked}--;
 936                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 937
 938         return 1;
 939         }
 940
 941     return;
 942 }
 943
 944 #XXX These uses of ref() need verified
 945 sub _copy_node {
 946         ##
 947         # Copy single level of keys or elements to new DB handle.
 948         # Recurse for nested structures
 949         ##
 950     my $self = _get_self($_[0]);
 951         my $db_temp = $_[1];
 952
 953         if ($self->type eq TYPE_HASH) {
 954                 my $key = $self->first_key();
 955                 while ($key) {
 956                         my $value = $self->get($key);
 957 #XXX This doesn't work with autobless
 958                         if (!ref($value)) { $db_temp->{$key} = $value; }
 959                         else {
 960                                 my $type = $value->type;
 961                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 962                                 else { $db_temp->{$key} = []; }
 963                                 $value->_copy_node( $db_temp->{$key} );
 964                         }
 965                         $key = $self->next_key($key);
 966                 }
 967         }
 968         else {
 969                 my $length = $self->length();
 970                 for (my $index = 0; $index < $length; $index++) {
 971                         my $value = $self->get($index);
 972                         if (!ref($value)) { $db_temp->[$index] = $value; }
 973             #XXX NO tests for this code
 974                         else {
 975                                 my $type = $value->type;
 976                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 977                                 else { $db_temp->[$index] = []; }
 978                                 $value->_copy_node( $db_temp->[$index] );
 979                         }
 980                 }
 981         }
 982 }
 983
 984 sub export {
 985         ##
 986         # Recursively export into standard Perl hashes and arrays.
 987         ##
 988     my $self = _get_self($_[0]);
 989
 990         my $temp;
 991         if ($self->type eq TYPE_HASH) { $temp = {}; }
 992         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 993
 994         $self->lock();
 995         $self->_copy_node( $temp );
 996         $self->unlock();
 997
 998         return $temp;
 999 }
1000
1001 sub import {
1002         ##
1003         # Recursively import Perl hash/array structure
1004         ##
1005     #XXX This use of ref() seems to be ok
1006         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1007
1008     my $self = _get_self($_[0]);
1009         my $struct = $_[1];
1010
1011     #XXX This use of ref() seems to be ok
1012         if (!ref($struct)) {
1013                 ##
1014                 # struct is not a reference, so just import based on our type
1015                 ##
1016                 shift @_;
1017
1018                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1019                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1020         }
1021
1022     my $r = Scalar::Util::reftype($struct) || '';
1023         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1024                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1025         }
1026         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1027                 $self->push( @$struct );
1028         }
1029         else {
1030                 return $self->_throw_error("Cannot import: type mismatch");
1031         }
1032
1033         return 1;
1034 }
1035
1036 sub optimize {
1037         ##
1038         # Rebuild entire database into new file, then move
1039         # it back on top of original.
1040         ##
1041     my $self = _get_self($_[0]);
1042
1043 #XXX Need to create a new test for this
1044 #       if ($self->root->{links} > 1) {
1045 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1046 #       }
1047
1048         my $db_temp = DBM::Deep->new(
1049                 file => $self->root->{file} . '.tmp',
1050                 type => $self->type
1051         );
1052         if (!$db_temp) {
1053                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1054         }
1055
1056         $self->lock();
1057         $self->_copy_node( $db_temp );
1058         undef $db_temp;
1059
1060         ##
1061         # Attempt to copy user, group and permissions over to new file
1062         ##
1063         my @stats = stat($self->fh);
1064         my $perms = $stats[2] & 07777;
1065         my $uid = $stats[4];
1066         my $gid = $stats[5];
1067         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1068         chmod( $perms, $self->root->{file} . '.tmp' );
1069
1070     # q.v. perlport for more information on this variable
1071     if ( $^O eq 'MSWin32' ) {
1072                 ##
1073                 # Potential race condition when optmizing on Win32 with locking.
1074                 # The Windows filesystem requires that the filehandle be closed
1075                 # before it is overwritten with rename().  This could be redone
1076                 # with a soft copy.
1077                 ##
1078                 $self->unlock();
1079                 $self->_close();
1080         }
1081
1082         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1083                 unlink $self->root->{file} . '.tmp';
1084                 $self->unlock();
1085                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1086         }
1087
1088         $self->unlock();
1089         $self->_close();
1090         $self->_open();
1091
1092         return 1;
1093 }
1094
1095 sub clone {
1096         ##
1097         # Make copy of object and return
1098         ##
1099     my $self = _get_self($_[0]);
1100
1101         return DBM::Deep->new(
1102                 type => $self->type,
1103                 base_offset => $self->base_offset,
1104                 root => $self->root
1105         );
1106 }
1107
1108 {
1109     my %is_legal_filter = map {
1110         $_ => ~~1,
1111     } qw(
1112         store_key store_value
1113         fetch_key fetch_value
1114     );
1115
1116     sub set_filter {
1117         ##
1118         # Setup filter function for storing or fetching the key or value
1119         ##
1120         my $self = _get_self($_[0]);
1121         my $type = lc $_[1];
1122         my $func = $_[2] ? $_[2] : undef;
1123
1124         if ( $is_legal_filter{$type} ) {
1125             $self->root->{"filter_$type"} = $func;
1126             return 1;
1127         }
1128
1129         return;
1130     }
1131 }
1132
1133 ##
1134 # Accessor methods
1135 ##
1136
1137 sub root {
1138         ##
1139         # Get access to the root structure
1140         ##
1141     my $self = _get_self($_[0]);
1142         return $self->{root};
1143 }
1144
1145 sub fh {
1146         ##
1147         # Get access to the raw FileHandle
1148         ##
1149     #XXX It will be useful, though, when we split out HASH and ARRAY
1150     my $self = _get_self($_[0]);
1151         return $self->root->{fh};
1152 }
1153
1154 sub type {
1155         ##
1156         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1157         ##
1158     my $self = _get_self($_[0]);
1159         return $self->{type};
1160 }
1161
1162 sub base_offset {
1163         ##
1164         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1165         ##
1166     my $self = _get_self($_[0]);
1167         return $self->{base_offset};
1168 }
1169
1170 sub error {
1171         ##
1172         # Get last error string, or undef if no error
1173         ##
1174         return $_[0]
1175         ? ( _get_self($_[0])->{root}->{error} or undef )
1176         : $@;
1177 }
1178
1179 ##
1180 # Utility methods
1181 ##
1182
1183 sub _throw_error {
1184         ##
1185         # Store error string in self
1186         ##
1187     my $self = _get_self($_[0]);
1188         my $error_text = $_[1];
1189
1190         $self->root->{error} = $error_text;
1191
1192         unless ($self->root->{debug}) {
1193         die "DBM::Deep: $error_text\n";
1194     }
1195
1196     warn "DBM::Deep: $error_text\n";
1197         return;
1198 }
1199
1200 sub clear_error {
1201         ##
1202         # Clear error state
1203         ##
1204     my $self = _get_self($_[0]);
1205
1206         undef $self->root->{error};
1207 }
1208
1209 sub precalc_sizes {
1210         ##
1211         # Precalculate index, bucket and bucket list sizes
1212         ##
1213
1214     #XXX I don't like this ...
1215     set_pack() unless defined $LONG_SIZE;
1216
1217         $INDEX_SIZE = 256 * $LONG_SIZE;
1218         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1219         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1220 }
1221
1222 sub set_pack {
1223         ##
1224         # Set pack/unpack modes (see file header for more)
1225         ##
1226     my ($long_s, $long_p, $data_s, $data_p) = @_;
1227
1228     $LONG_SIZE = $long_s ? $long_s : 4;
1229     $LONG_PACK = $long_p ? $long_p : 'N';
1230
1231     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1232     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1233
1234         precalc_sizes();
1235 }
1236
1237 sub set_digest {
1238         ##
1239         # Set key digest function (default is MD5)
1240         ##
1241     my ($digest_func, $hash_size) = @_;
1242
1243     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1244     $HASH_SIZE = $hash_size ? $hash_size : 16;
1245
1246         precalc_sizes();
1247 }
1248
1249 ##
1250 # tie() methods (hashes and arrays)
1251 ##
1252
1253 sub STORE {
1254         ##
1255         # Store single hash key/value or array element in database.
1256         ##
1257     my $self = _get_self($_[0]);
1258         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1259     #XXX What is ref() checking here?
1260     #YYY User may be storing a hash, in which case we do not want it run
1261     #YYY through the filtering system
1262         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1263
1264         my $unpacked_key = $key;
1265         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1266         my $md5 = $DIGEST_FUNC->($key);
1267
1268         ##
1269         # Make sure file is open
1270         ##
1271         if (!defined($self->fh) && !$self->_open()) {
1272                 return;
1273         }
1274         ##
1275
1276     my $fh = $self->fh;
1277
1278         ##
1279         # Request exclusive lock for writing
1280         ##
1281         $self->lock( LOCK_EX );
1282
1283         ##
1284         # If locking is enabled, set 'end' parameter again, in case another
1285         # DB instance appended to our file while we were unlocked.
1286         ##
1287         if ($self->root->{locking} || $self->root->{volatile}) {
1288                 $self->root->{end} = (stat($fh))[7];
1289         }
1290
1291         ##
1292         # Locate offset for bucket list using digest index system
1293         ##
1294         my $tag = $self->_load_tag($self->base_offset);
1295         if (!$tag) {
1296                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1297         }
1298
1299         my $ch = 0;
1300         while ($tag->{signature} ne SIG_BLIST) {
1301                 my $num = ord(substr($md5, $ch, 1));
1302                 my $new_tag = $self->_index_lookup($tag, $num);
1303                 if (!$new_tag) {
1304                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1305                         seek($fh, $ref_loc, 0);
1306                         print($fh pack($LONG_PACK, $self->root->{end}) );
1307
1308                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1309                         $tag->{ref_loc} = $ref_loc;
1310                         $tag->{ch} = $ch;
1311                         last;
1312                 }
1313                 else {
1314                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1315                         $tag = $new_tag;
1316                         $tag->{ref_loc} = $ref_loc;
1317                         $tag->{ch} = $ch;
1318                 }
1319                 $ch++;
1320         }
1321
1322         ##
1323         # Add key/value to bucket list
1324         ##
1325         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1326
1327         ##
1328         # If this object is an array, and bucket was not a replace, and key is numerical,
1329         # and index is equal or greater than current length, advance length variable.
1330         ##
1331         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1332                 $self->STORESIZE( $unpacked_key + 1 );
1333         }
1334
1335         $self->unlock();
1336
1337         return $result;
1338 }
1339
1340 sub FETCH {
1341         ##
1342         # Fetch single value or element given plain key or array index
1343         ##
1344     my $self = _get_self($_[0]);
1345
1346     my $key = $_[1];
1347     if ( $self->type eq TYPE_HASH ) {
1348         if ( my $filter = $self->root->{filter_store_key} ) {
1349             $key = $filter->( $key );
1350         }
1351     }
1352     elsif ( $self->type eq TYPE_ARRAY ) {
1353         if ( $key =~ /^\d+$/ ) {
1354             $key = pack($LONG_PACK, $key);
1355         }
1356     }
1357
1358         my $md5 = $DIGEST_FUNC->($key);
1359
1360         ##
1361         # Make sure file is open
1362         ##
1363         if (!defined($self->fh)) { $self->_open(); }
1364
1365         ##
1366         # Request shared lock for reading
1367         ##
1368         $self->lock( LOCK_SH );
1369
1370         my $tag = $self->_find_bucket_list( $md5 );
1371         if (!$tag) {
1372                 $self->unlock();
1373                 return;
1374         }
1375
1376         ##
1377         # Get value from bucket list
1378         ##
1379         my $result = $self->_get_bucket_value( $tag, $md5 );
1380
1381         $self->unlock();
1382
1383     #XXX What is ref() checking here?
1384         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1385 }
1386
1387 sub DELETE {
1388         ##
1389         # Delete single key/value pair or element given plain key or array index
1390         ##
1391     my $self = _get_self($_[0]);
1392         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1393
1394         my $unpacked_key = $key;
1395         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1396         my $md5 = $DIGEST_FUNC->($key);
1397
1398         ##
1399         # Make sure file is open
1400         ##
1401         if (!defined($self->fh)) { $self->_open(); }
1402
1403         ##
1404         # Request exclusive lock for writing
1405         ##
1406         $self->lock( LOCK_EX );
1407
1408         my $tag = $self->_find_bucket_list( $md5 );
1409         if (!$tag) {
1410                 $self->unlock();
1411                 return;
1412         }
1413
1414         ##
1415         # Delete bucket
1416         ##
1417         my $result = $self->_delete_bucket( $tag, $md5 );
1418
1419         ##
1420         # If this object is an array and the key deleted was on the end of the stack,
1421         # decrement the length variable.
1422         ##
1423         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1424                 $self->STORESIZE( $unpacked_key );
1425         }
1426
1427         $self->unlock();
1428
1429         return $result;
1430 }
1431
1432 sub EXISTS {
1433         ##
1434         # Check if a single key or element exists given plain key or array index
1435         ##
1436     my $self = _get_self($_[0]);
1437         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1438
1439         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1440         my $md5 = $DIGEST_FUNC->($key);
1441
1442         ##
1443         # Make sure file is open
1444         ##
1445         if (!defined($self->fh)) { $self->_open(); }
1446
1447         ##
1448         # Request shared lock for reading
1449         ##
1450         $self->lock( LOCK_SH );
1451
1452         my $tag = $self->_find_bucket_list( $md5 );
1453
1454         ##
1455         # For some reason, the built-in exists() function returns '' for false
1456         ##
1457         if (!$tag) {
1458                 $self->unlock();
1459                 return '';
1460         }
1461
1462         ##
1463         # Check if bucket exists and return 1 or ''
1464         ##
1465         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1466
1467         $self->unlock();
1468
1469         return $result;
1470 }
1471
1472 sub CLEAR {
1473         ##
1474         # Clear all keys from hash, or all elements from array.
1475         ##
1476     my $self = _get_self($_[0]);
1477
1478         ##
1479         # Make sure file is open
1480         ##
1481         if (!defined($self->fh)) { $self->_open(); }
1482
1483         ##
1484         # Request exclusive lock for writing
1485         ##
1486         $self->lock( LOCK_EX );
1487
1488     my $fh = $self->fh;
1489
1490         seek($fh, $self->base_offset, 0);
1491         if (eof $fh) {
1492                 $self->unlock();
1493                 return;
1494         }
1495
1496         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1497
1498         $self->unlock();
1499
1500         return 1;
1501 }
1502
1503 sub FIRSTKEY {
1504         ##
1505         # Locate and return first key (in no particular order)
1506         ##
1507     my $self = _get_self($_[0]);
1508         if ($self->type ne TYPE_HASH) {
1509                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1510         }
1511
1512         ##
1513         # Make sure file is open
1514         ##
1515         if (!defined($self->fh)) { $self->_open(); }
1516
1517         ##
1518         # Request shared lock for reading
1519         ##
1520         $self->lock( LOCK_SH );
1521
1522         my $result = $self->_get_next_key();
1523
1524         $self->unlock();
1525
1526         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1527 }
1528
1529 sub NEXTKEY {
1530         ##
1531         # Return next key (in no particular order), given previous one
1532         ##
1533     my $self = _get_self($_[0]);
1534         if ($self->type ne TYPE_HASH) {
1535                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1536         }
1537         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1538         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1539
1540         ##
1541         # Make sure file is open
1542         ##
1543         if (!defined($self->fh)) { $self->_open(); }
1544
1545         ##
1546         # Request shared lock for reading
1547         ##
1548         $self->lock( LOCK_SH );
1549
1550         my $result = $self->_get_next_key( $prev_md5 );
1551
1552         $self->unlock();
1553
1554         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1555 }
1556
1557 ##
1558 # The following methods are for arrays only
1559 ##
1560
1561 sub FETCHSIZE {
1562         ##
1563         # Return the length of the array
1564         ##
1565     my $self = _get_self($_[0]);
1566         if ($self->type ne TYPE_ARRAY) {
1567                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1568         }
1569
1570         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1571         $self->root->{filter_fetch_value} = undef;
1572
1573         my $packed_size = $self->FETCH('length');
1574
1575         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1576
1577         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1578         else { return 0; }
1579 }
1580
1581 sub STORESIZE {
1582         ##
1583         # Set the length of the array
1584         ##
1585     my $self = _get_self($_[0]);
1586         if ($self->type ne TYPE_ARRAY) {
1587                 return $self->_throw_error("STORESIZE method only supported for arrays");
1588         }
1589         my $new_length = $_[1];
1590
1591         my $SAVE_FILTER = $self->root->{filter_store_value};
1592         $self->root->{filter_store_value} = undef;
1593
1594         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1595
1596         $self->root->{filter_store_value} = $SAVE_FILTER;
1597
1598         return $result;
1599 }
1600
1601 sub POP {
1602         ##
1603         # Remove and return the last element on the array
1604         ##
1605     my $self = _get_self($_[0]);
1606         if ($self->type ne TYPE_ARRAY) {
1607                 return $self->_throw_error("POP method only supported for arrays");
1608         }
1609         my $length = $self->FETCHSIZE();
1610
1611         if ($length) {
1612                 my $content = $self->FETCH( $length - 1 );
1613                 $self->DELETE( $length - 1 );
1614                 return $content;
1615         }
1616         else {
1617                 return;
1618         }
1619 }
1620
1621 sub PUSH {
1622         ##
1623         # Add new element(s) to the end of the array
1624         ##
1625     my $self = _get_self(shift);
1626         if ($self->type ne TYPE_ARRAY) {
1627                 return $self->_throw_error("PUSH method only supported for arrays");
1628         }
1629         my $length = $self->FETCHSIZE();
1630
1631         while (my $content = shift @_) {
1632                 $self->STORE( $length, $content );
1633                 $length++;
1634         }
1635 }
1636
1637 sub SHIFT {
1638         ##
1639         # Remove and return first element on the array.
1640         # Shift over remaining elements to take up space.
1641         ##
1642     my $self = _get_self($_[0]);
1643         if ($self->type ne TYPE_ARRAY) {
1644                 return $self->_throw_error("SHIFT method only supported for arrays");
1645         }
1646         my $length = $self->FETCHSIZE();
1647
1648         if ($length) {
1649                 my $content = $self->FETCH( 0 );
1650
1651                 ##
1652                 # Shift elements over and remove last one.
1653                 ##
1654                 for (my $i = 0; $i < $length - 1; $i++) {
1655                         $self->STORE( $i, $self->FETCH($i + 1) );
1656                 }
1657                 $self->DELETE( $length - 1 );
1658
1659                 return $content;
1660         }
1661         else {
1662                 return;
1663         }
1664 }
1665
1666 sub UNSHIFT {
1667         ##
1668         # Insert new element(s) at beginning of array.
1669         # Shift over other elements to make space.
1670         ##
1671     my $self = _get_self($_[0]);shift @_;
1672         if ($self->type ne TYPE_ARRAY) {
1673                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1674         }
1675         my @new_elements = @_;
1676         my $length = $self->FETCHSIZE();
1677         my $new_size = scalar @new_elements;
1678
1679         if ($length) {
1680                 for (my $i = $length - 1; $i >= 0; $i--) {
1681                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1682                 }
1683         }
1684
1685         for (my $i = 0; $i < $new_size; $i++) {
1686                 $self->STORE( $i, $new_elements[$i] );
1687         }
1688 }
1689
1690 sub SPLICE {
1691         ##
1692         # Splices section of array with optional new section.
1693         # Returns deleted section, or last element deleted in scalar context.
1694         ##
1695     my $self = _get_self($_[0]);shift @_;
1696         if ($self->type ne TYPE_ARRAY) {
1697                 return $self->_throw_error("SPLICE method only supported for arrays");
1698         }
1699         my $length = $self->FETCHSIZE();
1700
1701         ##
1702         # Calculate offset and length of splice
1703         ##
1704         my $offset = shift || 0;
1705         if ($offset < 0) { $offset += $length; }
1706
1707         my $splice_length;
1708         if (scalar @_) { $splice_length = shift; }
1709         else { $splice_length = $length - $offset; }
1710         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1711
1712         ##
1713         # Setup array with new elements, and copy out old elements for return
1714         ##
1715         my @new_elements = @_;
1716         my $new_size = scalar @new_elements;
1717
1718         my @old_elements = ();
1719         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1720                 push @old_elements, $self->FETCH( $i );
1721         }
1722
1723         ##
1724         # Adjust array length, and shift elements to accomodate new section.
1725         ##
1726     if ( $new_size != $splice_length ) {
1727         if ($new_size > $splice_length) {
1728             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1729                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1730             }
1731         }
1732         else {
1733             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1734                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1735             }
1736             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1737                 $self->DELETE( $length - 1 );
1738                 $length--;
1739             }
1740         }
1741         }
1742
1743         ##
1744         # Insert new elements into array
1745         ##
1746         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1747                 $self->STORE( $i, shift @new_elements );
1748         }
1749
1750         ##
1751         # Return deleted section, or last element in scalar context.
1752         ##
1753         return wantarray ? @old_elements : $old_elements[-1];
1754 }
1755
1756 #XXX We don't need to define it.
1757 #XXX It will be useful, though, when we split out HASH and ARRAY
1758 #sub EXTEND {
1759         ##
1760         # Perl will call EXTEND() when the array is likely to grow.
1761         # We don't care, but include it for compatibility.
1762         ##
1763 #}
1764
1765 ##
1766 # Public method aliases
1767 ##
1768 *put = *store = *STORE;
1769 *get = *fetch = *FETCH;
1770 *delete = *DELETE;
1771 *exists = *EXISTS;
1772 *clear = *CLEAR;
1773 *first_key = *FIRSTKEY;
1774 *next_key = *NEXTKEY;
1775 *length = *FETCHSIZE;
1776 *pop = *POP;
1777 *push = *PUSH;
1778 *shift = *SHIFT;
1779 *unshift = *UNSHIFT;
1780 *splice = *SPLICE;
1781
1782 package DBM::Deep::_::Root;
1783
1784 sub new {
1785     my $class = shift;
1786     my ($args) = @_;
1787
1788     my $self = bless {
1789         file => undef,
1790         fh => undef,
1791         end => 0,
1792         autoflush => undef,
1793         locking => undef,
1794         volatile => undef,
1795         debug => undef,
1796         mode => 'r+',
1797         filter_store_key => undef,
1798         filter_store_value => undef,
1799         filter_fetch_key => undef,
1800         filter_fetch_value => undef,
1801         autobless => undef,
1802         locked => 0,
1803         %$args,
1804     }, $class;
1805
1806     return $self;
1807 }
1808
1809 sub DESTROY {
1810     my $self = shift;
1811     return unless $self;
1812
1813     close $self->{fh} if $self->{fh};
1814
1815     return;
1816 }
1817
1818 1;
1819
1820 __END__
1821
1822 =head1 NAME
1823
1824 DBM::Deep - A pure perl multi-level hash/array DBM
1825
1826 =head1 SYNOPSIS
1827
1828   use DBM::Deep;
1829   my $db = DBM::Deep->new( "foo.db" );
1830
1831   $db->{key} = 'value'; # tie() style
1832   print $db->{key};
1833
1834   $db->put('key', 'value'); # OO style
1835   print $db->get('key');
1836
1837   # true multi-level support
1838   $db->{my_complex} = [
1839         'hello', { perl => 'rules' },
1840         42, 99 ];
1841
1842 =head1 DESCRIPTION
1843
1844 A unique flat-file database module, written in pure perl.  True
1845 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1846 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1847 handle millions of keys and unlimited hash levels without significant
1848 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1849 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1850 Mac OS X and Windows.
1851
1852 =head1 INSTALLATION
1853
1854 Hopefully you are using CPAN's excellent Perl module, which will download
1855 and install the module for you.  If not, get the tarball, and run these
1856 commands:
1857
1858         tar zxf DBM-Deep-*
1859         cd DBM-Deep-*
1860         perl Makefile.PL
1861         make
1862         make test
1863         make install
1864
1865 =head1 SETUP
1866
1867 Construction can be done OO-style (which is the recommended way), or using
1868 Perl's tie() function.  Both are examined here.
1869
1870 =head2 OO CONSTRUCTION
1871
1872 The recommended way to construct a DBM::Deep object is to use the new()
1873 method, which gets you a blessed, tied hash or array reference.
1874
1875         my $db = DBM::Deep->new( "foo.db" );
1876
1877 This opens a new database handle, mapped to the file "foo.db".  If this
1878 file does not exist, it will automatically be created.  DB files are
1879 opened in "r+" (read/write) mode, and the type of object returned is a
1880 hash, unless otherwise specified (see L<OPTIONS> below).
1881
1882
1883
1884 You can pass a number of options to the constructor to specify things like
1885 locking, autoflush, etc.  This is done by passing an inline hash:
1886
1887         my $db = DBM::Deep->new(
1888                 file => "foo.db",
1889                 locking => 1,
1890                 autoflush => 1
1891         );
1892
1893 Notice that the filename is now specified I<inside> the hash with
1894 the "file" parameter, as opposed to being the sole argument to the
1895 constructor.  This is required if any options are specified.
1896 See L<OPTIONS> below for the complete list.
1897
1898
1899
1900 You can also start with an array instead of a hash.  For this, you must
1901 specify the C<type> parameter:
1902
1903         my $db = DBM::Deep->new(
1904                 file => "foo.db",
1905                 type => DBM::Deep->TYPE_ARRAY
1906         );
1907
1908 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1909 a new DB file.  If you create a DBM::Deep object with an existing file, the
1910 C<type> will be loaded from the file header, and ignored if it is passed
1911 to the constructor.
1912
1913 =head2 TIE CONSTRUCTION
1914
1915 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1916 tie() function.  This is not ideal, because you get only a basic, tied hash
1917 (or array) which is not blessed, so you can't call any functions on it.
1918
1919         my %hash;
1920         tie %hash, "DBM::Deep", "foo.db";
1921
1922         my @array;
1923         tie @array, "DBM::Deep", "bar.db";
1924
1925 As with the OO constructor, you can replace the DB filename parameter with
1926 a hash containing one or more options (see L<OPTIONS> just below for the
1927 complete list).
1928
1929         tie %hash, "DBM::Deep", {
1930                 file => "foo.db",
1931                 locking => 1,
1932                 autoflush => 1
1933         };
1934
1935 =head2 OPTIONS
1936
1937 There are a number of options that can be passed in when constructing your
1938 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1939
1940 =over
1941
1942 =item * file
1943
1944 Filename of the DB file to link the handle to.  You can pass a full absolute
1945 filesystem path, partial path, or a plain filename if the file is in the
1946 current working directory.  This is a required parameter.
1947
1948 =item * mode
1949
1950 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1951 module.  This is an optional parameter, and defaults to "r+" (read/write).
1952 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1953 created if it doesn't exist.
1954
1955 =item * type
1956
1957 This parameter specifies what type of object to create, a hash or array.  Use
1958 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1959 This only takes effect when beginning a new file.  This is an optional
1960 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1961
1962 =item * locking
1963
1964 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1965 function to lock the database in exclusive mode for writes, and shared mode for
1966 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1967 any child hashes or arrays> that use the same DB file.  This is an optional
1968 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1969
1970 =item * autoflush
1971
1972 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1973 This obviously slows down write operations, but is required if you may have
1974 multiple processes accessing the same DB file (also consider enable I<locking>
1975 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1976 parameter, and defaults to 0 (disabled).
1977
1978 =item * volatile
1979
1980 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1981 STORE() operation.  This is required if an outside force may change the size of
1982 the file between transactions.  Locking also implicitly enables volatile.  This
1983 is useful if you want to use a different locking system or write your own.  Pass
1984 any true value to enable.  This is an optional parameter, and defaults to 0
1985 (disabled).
1986
1987 =item * autobless
1988
1989 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1990 restore them when fetched.  This is an B<experimental> feature, and does have
1991 side-effects.  Basically, when hashes are re-blessed into their original
1992 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1993 able to call any DBM::Deep methods on them.  You have been warned.
1994 This is an optional parameter, and defaults to 0 (disabled).
1995
1996 =item * filter_*
1997
1998 See L<FILTERS> below.
1999
2000 =item * debug
2001
2002 Setting I<debug> mode will make all errors non-fatal, dump them out to
2003 STDERR, and continue on.  This is for debugging purposes only, and probably
2004 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
2005
2006 =item * fh
2007
2008 Instead of passing a file path, you can instead pass a handle to an pre-opened
2009 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
2010 contains your entire Perl script, as well as the data following the __DATA__
2011 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
2012 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
2013 in that.
2014
2015 =back
2016
2017 =head1 TIE INTERFACE
2018
2019 With DBM::Deep you can access your databases using Perl's standard hash/array
2020 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
2021 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
2022 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
2023 section above.  This simply tells you how to use DBM::Deep using regular hashes
2024 and arrays, rather than calling functions like C<get()> and C<put()> (although those
2025 work too).  It is entirely up to you how to want to access your databases.
2026
2027 =head2 HASHES
2028
2029 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
2030 or even nested hashes (or arrays) using standard Perl syntax:
2031
2032         my $db = DBM::Deep->new( "foo.db" );
2033
2034         $db->{mykey} = "myvalue";
2035         $db->{myhash} = {};
2036         $db->{myhash}->{subkey} = "subvalue";
2037
2038         print $db->{myhash}->{subkey} . "\n";
2039
2040 You can even step through hash keys using the normal Perl C<keys()> function:
2041
2042         foreach my $key (keys %$db) {
2043                 print "$key: " . $db->{$key} . "\n";
2044         }
2045
2046 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
2047 pushes them onto an array, all before the loop even begins.  If you have an
2048 extra large hash, this may exhaust Perl's memory.  Instead, consider using
2049 Perl's C<each()> function, which pulls keys/values one at a time, using very
2050 little memory:
2051
2052         while (my ($key, $value) = each %$db) {
2053                 print "$key: $value\n";
2054         }
2055
2056 Please note that when using C<each()>, you should always pass a direct
2057 hash reference, not a lookup.  Meaning, you should B<never> do this:
2058
2059         # NEVER DO THIS
2060         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
2061
2062 This causes an infinite loop, because for each iteration, Perl is calling
2063 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
2064 it effectively keeps returning the first key over and over again. Instead,
2065 assign a temporary variable to C<$db->{foo}>, then pass that to each().
2066
2067 =head2 ARRAYS
2068
2069 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2070 reference.  This includes inserting, removing and manipulating elements,
2071 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2072 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2073 or simply be a nested array reference inside a hash.  Example:
2074
2075         my $db = DBM::Deep->new(
2076                 file => "foo-array.db",
2077                 type => DBM::Deep->TYPE_ARRAY
2078         );
2079
2080         $db->[0] = "foo";
2081         push @$db, "bar", "baz";
2082         unshift @$db, "bah";
2083
2084         my $last_elem = pop @$db; # baz
2085         my $first_elem = shift @$db; # bah
2086         my $second_elem = $db->[1]; # bar
2087
2088         my $num_elements = scalar @$db;
2089
2090 =head1 OO INTERFACE
2091
2092 In addition to the I<tie()> interface, you can also use a standard OO interface
2093 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2094 array) has its own methods, but both types share the following common methods:
2095 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2096
2097 =over
2098
2099 =item * put()
2100
2101 Stores a new hash key/value pair, or sets an array element value.  Takes two
2102 arguments, the hash key or array index, and the new value.  The value can be
2103 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2104
2105         $db->put("foo", "bar"); # for hashes
2106         $db->put(1, "bar"); # for arrays
2107
2108 =item * get()
2109
2110 Fetches the value of a hash key or array element.  Takes one argument: the hash
2111 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2112 data type stored.
2113
2114         my $value = $db->get("foo"); # for hashes
2115         my $value = $db->get(1); # for arrays
2116
2117 =item * exists()
2118
2119 Checks if a hash key or array index exists.  Takes one argument: the hash key
2120 or array index.  Returns true if it exists, false if not.
2121
2122         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2123         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2124
2125 =item * delete()
2126
2127 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2128 key or array index.  Returns true on success, false if not found.  For arrays,
2129 the remaining elements located after the deleted element are NOT moved over.
2130 The deleted element is essentially just undefined, which is exactly how Perl's
2131 internal arrays work.  Please note that the space occupied by the deleted
2132 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2133 below for details and workarounds.
2134
2135         $db->delete("foo"); # for hashes
2136         $db->delete(1); # for arrays
2137
2138 =item * clear()
2139
2140 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2141 value.  Please note that the space occupied by the deleted keys/values or
2142 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2143 details and workarounds.
2144
2145         $db->clear(); # hashes or arrays
2146
2147 =back
2148
2149 =head2 HASHES
2150
2151 For hashes, DBM::Deep supports all the common methods described above, and the
2152 following additional methods: C<first_key()> and C<next_key()>.
2153
2154 =over
2155
2156 =item * first_key()
2157
2158 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2159 fetched in an undefined order (which appears random).  Takes no arguments,
2160 returns the key as a scalar value.
2161
2162         my $key = $db->first_key();
2163
2164 =item * next_key()
2165
2166 Returns the "next" key in the hash, given the previous one as the sole argument.
2167 Returns undef if there are no more keys to be fetched.
2168
2169         $key = $db->next_key($key);
2170
2171 =back
2172
2173 Here are some examples of using hashes:
2174
2175         my $db = DBM::Deep->new( "foo.db" );
2176
2177         $db->put("foo", "bar");
2178         print "foo: " . $db->get("foo") . "\n";
2179
2180         $db->put("baz", {}); # new child hash ref
2181         $db->get("baz")->put("buz", "biz");
2182         print "buz: " . $db->get("baz")->get("buz") . "\n";
2183
2184         my $key = $db->first_key();
2185         while ($key) {
2186                 print "$key: " . $db->get($key) . "\n";
2187                 $key = $db->next_key($key);
2188         }
2189
2190         if ($db->exists("foo")) { $db->delete("foo"); }
2191
2192 =head2 ARRAYS
2193
2194 For arrays, DBM::Deep supports all the common methods described above, and the
2195 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2196 C<unshift()> and C<splice()>.
2197
2198 =over
2199
2200 =item * length()
2201
2202 Returns the number of elements in the array.  Takes no arguments.
2203
2204         my $len = $db->length();
2205
2206 =item * push()
2207
2208 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2209 refs or array refs.  No return value.
2210
2211         $db->push("foo", "bar", {});
2212
2213 =item * pop()
2214
2215 Fetches the last element in the array, and deletes it.  Takes no arguments.
2216 Returns undef if array is empty.  Returns the element value.
2217
2218         my $elem = $db->pop();
2219
2220 =item * shift()
2221
2222 Fetches the first element in the array, deletes it, then shifts all the
2223 remaining elements over to take up the space.  Returns the element value.  This
2224 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2225 details.
2226
2227         my $elem = $db->shift();
2228
2229 =item * unshift()
2230
2231 Inserts one or more elements onto the beginning of the array, shifting all
2232 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2233 No return value.  This method is not recommended with large arrays -- see
2234 <LARGE ARRAYS> below for details.
2235
2236         $db->unshift("foo", "bar", {});
2237
2238 =item * splice()
2239
2240 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2241 -f splice> for usage -- it is too complicated to document here.  This method is
2242 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2243
2244 =back
2245
2246 Here are some examples of using arrays:
2247
2248         my $db = DBM::Deep->new(
2249                 file => "foo.db",
2250                 type => DBM::Deep->TYPE_ARRAY
2251         );
2252
2253         $db->push("bar", "baz");
2254         $db->unshift("foo");
2255         $db->put(3, "buz");
2256
2257         my $len = $db->length();
2258         print "length: $len\n"; # 4
2259
2260         for (my $k=0; $k<$len; $k++) {
2261                 print "$k: " . $db->get($k) . "\n";
2262         }
2263
2264         $db->splice(1, 2, "biz", "baf");
2265
2266         while (my $elem = shift @$db) {
2267                 print "shifted: $elem\n";
2268         }
2269
2270 =head1 LOCKING
2271
2272 Enable automatic file locking by passing a true value to the C<locking>
2273 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2274
2275         my $db = DBM::Deep->new(
2276                 file => "foo.db",
2277                 locking => 1
2278         );
2279
2280 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2281 mode for writes, and shared mode for reads.  This is required if you have
2282 multiple processes accessing the same database file, to avoid file corruption.
2283 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2284 NFS> below for more.
2285
2286 =head2 EXPLICIT LOCKING
2287
2288 You can explicitly lock a database, so it remains locked for multiple
2289 transactions.  This is done by calling the C<lock()> method, and passing an
2290 optional lock mode argument (defaults to exclusive mode).  This is particularly
2291 useful for things like counters, where the current value needs to be fetched,
2292 then incremented, then stored again.
2293
2294         $db->lock();
2295         my $counter = $db->get("counter");
2296         $counter++;
2297         $db->put("counter", $counter);
2298         $db->unlock();
2299
2300         # or...
2301
2302         $db->lock();
2303         $db->{counter}++;
2304         $db->unlock();
2305
2306 You can pass C<lock()> an optional argument, which specifies which mode to use
2307 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2308 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2309 same as the constants defined in Perl's C<Fcntl> module.
2310
2311         $db->lock( DBM::Deep->LOCK_SH );
2312         # something here
2313         $db->unlock();
2314
2315 If you want to implement your own file locking scheme, be sure to create your
2316 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2317 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2318 below for more.
2319
2320 =head1 IMPORTING/EXPORTING
2321
2322 You can import existing complex structures by calling the C<import()> method,
2323 and export an entire database into an in-memory structure using the C<export()>
2324 method.  Both are examined here.
2325
2326 =head2 IMPORTING
2327
2328 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2329 walking the structure and adding keys/elements to the database as you go,
2330 simply pass a reference to the C<import()> method.  This recursively adds
2331 everything to an existing DBM::Deep object for you.  Here is an example:
2332
2333         my $struct = {
2334                 key1 => "value1",
2335                 key2 => "value2",
2336                 array1 => [ "elem0", "elem1", "elem2" ],
2337                 hash1 => {
2338                         subkey1 => "subvalue1",
2339                         subkey2 => "subvalue2"
2340                 }
2341         };
2342
2343         my $db = DBM::Deep->new( "foo.db" );
2344         $db->import( $struct );
2345
2346         print $db->{key1} . "\n"; # prints "value1"
2347
2348 This recursively imports the entire C<$struct> object into C<$db>, including
2349 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2350 keys are merged with the existing ones, replacing if they already exist.
2351 The C<import()> method can be called on any database level (not just the base
2352 level), and works with both hash and array DB types.
2353
2354
2355
2356 B<Note:> Make sure your existing structure has no circular references in it.
2357 These will cause an infinite loop when importing.
2358
2359 =head2 EXPORTING
2360
2361 Calling the C<export()> method on an existing DBM::Deep object will return
2362 a reference to a new in-memory copy of the database.  The export is done
2363 recursively, so all nested hashes/arrays are all exported to standard Perl
2364 objects.  Here is an example:
2365
2366         my $db = DBM::Deep->new( "foo.db" );
2367
2368         $db->{key1} = "value1";
2369         $db->{key2} = "value2";
2370         $db->{hash1} = {};
2371         $db->{hash1}->{subkey1} = "subvalue1";
2372         $db->{hash1}->{subkey2} = "subvalue2";
2373
2374         my $struct = $db->export();
2375
2376         print $struct->{key1} . "\n"; # prints "value1"
2377
2378 This makes a complete copy of the database in memory, and returns a reference
2379 to it.  The C<export()> method can be called on any database level (not just
2380 the base level), and works with both hash and array DB types.  Be careful of
2381 large databases -- you can store a lot more data in a DBM::Deep object than an
2382 in-memory Perl structure.
2383
2384
2385
2386 B<Note:> Make sure your database has no circular references in it.
2387 These will cause an infinite loop when exporting.
2388
2389 =head1 FILTERS
2390
2391 DBM::Deep has a number of hooks where you can specify your own Perl function
2392 to perform filtering on incoming or outgoing data.  This is a perfect
2393 way to extend the engine, and implement things like real-time compression or
2394 encryption.  Filtering applies to the base DB level, and all child hashes /
2395 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2396 constructed, or by calling the C<set_filter()> method at any time.  There are
2397 four available filter hooks, described below:
2398
2399 =over
2400
2401 =item * filter_store_key
2402
2403 This filter is called whenever a hash key is stored.  It
2404 is passed the incoming key, and expected to return a transformed key.
2405
2406 =item * filter_store_value
2407
2408 This filter is called whenever a hash key or array element is stored.  It
2409 is passed the incoming value, and expected to return a transformed value.
2410
2411 =item * filter_fetch_key
2412
2413 This filter is called whenever a hash key is fetched (i.e. via
2414 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2415 and expected to return the plain key.
2416
2417 =item * filter_fetch_value
2418
2419 This filter is called whenever a hash key or array element is fetched.
2420 It is passed the transformed value, and expected to return the plain value.
2421
2422 =back
2423
2424 Here are the two ways to setup a filter hook:
2425
2426         my $db = DBM::Deep->new(
2427                 file => "foo.db",
2428                 filter_store_value => \&my_filter_store,
2429                 filter_fetch_value => \&my_filter_fetch
2430         );
2431
2432         # or...
2433
2434         $db->set_filter( "filter_store_value", \&my_filter_store );
2435         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2436
2437 Your filter function will be called only when dealing with SCALAR keys or
2438 values.  When nested hashes and arrays are being stored/fetched, filtering
2439 is bypassed.  Filters are called as static functions, passed a single SCALAR
2440 argument, and expected to return a single SCALAR value.  If you want to
2441 remove a filter, set the function reference to C<undef>:
2442
2443         $db->set_filter( "filter_store_value", undef );
2444
2445 =head2 REAL-TIME ENCRYPTION EXAMPLE
2446
2447 Here is a working example that uses the I<Crypt::Blowfish> module to
2448 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2449 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2450 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2451
2452         use DBM::Deep;
2453         use Crypt::Blowfish;
2454         use Crypt::CBC;
2455
2456         my $cipher = Crypt::CBC->new({
2457                 'key'             => 'my secret key',
2458                 'cipher'          => 'Blowfish',
2459                 'iv'              => '$KJh#(}q',
2460                 'regenerate_key'  => 0,
2461                 'padding'         => 'space',
2462                 'prepend_iv'      => 0
2463         });
2464
2465         my $db = DBM::Deep->new(
2466                 file => "foo-encrypt.db",
2467                 filter_store_key => \&my_encrypt,
2468                 filter_store_value => \&my_encrypt,
2469                 filter_fetch_key => \&my_decrypt,
2470                 filter_fetch_value => \&my_decrypt,
2471         );
2472
2473         $db->{key1} = "value1";
2474         $db->{key2} = "value2";
2475         print "key1: " . $db->{key1} . "\n";
2476         print "key2: " . $db->{key2} . "\n";
2477
2478         undef $db;
2479         exit;
2480
2481         sub my_encrypt {
2482                 return $cipher->encrypt( $_[0] );
2483         }
2484         sub my_decrypt {
2485                 return $cipher->decrypt( $_[0] );
2486         }
2487
2488 =head2 REAL-TIME COMPRESSION EXAMPLE
2489
2490 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2491 compression / decompression of keys & values with DBM::Deep Filters.
2492 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2493 more on I<Compress::Zlib>.
2494
2495         use DBM::Deep;
2496         use Compress::Zlib;
2497
2498         my $db = DBM::Deep->new(
2499                 file => "foo-compress.db",
2500                 filter_store_key => \&my_compress,
2501                 filter_store_value => \&my_compress,
2502                 filter_fetch_key => \&my_decompress,
2503                 filter_fetch_value => \&my_decompress,
2504         );
2505
2506         $db->{key1} = "value1";
2507         $db->{key2} = "value2";
2508         print "key1: " . $db->{key1} . "\n";
2509         print "key2: " . $db->{key2} . "\n";
2510
2511         undef $db;
2512         exit;
2513
2514         sub my_compress {
2515                 return Compress::Zlib::memGzip( $_[0] ) ;
2516         }
2517         sub my_decompress {
2518                 return Compress::Zlib::memGunzip( $_[0] ) ;
2519         }
2520
2521 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2522 actually numerical index numbers, and are not filtered.
2523
2524 =head1 ERROR HANDLING
2525
2526 Most DBM::Deep methods return a true value for success, and call die() on
2527 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2528 actual error message is stored in an internal scalar, which can be fetched by
2529 calling the C<error()> method.
2530
2531         my $db = DBM::Deep->new( "foo.db" ); # create hash
2532         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2533
2534         print $db->error(); # prints error message
2535
2536 You can then call C<clear_error()> to clear the current error state.
2537
2538         $db->clear_error();
2539
2540 If you set the C<debug> option to true when creating your DBM::Deep object,
2541 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2542 for debugging purposes.
2543
2544 =head1 LARGEFILE SUPPORT
2545
2546 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2547 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2548 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2549 by calling the static C<set_pack()> method before you do anything else.
2550
2551         DBM::Deep::set_pack(8, 'Q');
2552
2553 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2554 instead of 32-bit longs.  After setting these values your DB files have a
2555 theoretical maximum size of 16 XB (exabytes).
2556
2557
2558
2559 B<Note:> Changing these values will B<NOT> work for existing database files.
2560 Only change this for new files, and make sure it stays set consistently
2561 throughout the file's life.  If you do set these values, you can no longer
2562 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2563 back to 32-bit mode.
2564
2565
2566
2567 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2568 only a 32-bit Perl.  However, I have received user reports that this does
2569 indeed work!
2570
2571 =head1 LOW-LEVEL ACCESS
2572
2573 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2574 you can call the C<fh()> method, which returns the handle:
2575
2576         my $fh = $db->fh();
2577
2578 This method can be called on the root level of the datbase, or any child
2579 hashes or arrays.  All levels share a I<root> structure, which contains things
2580 like the FileHandle, a reference counter, and all your options you specified
2581 when you created the object.  You can get access to this root structure by
2582 calling the C<root()> method.
2583
2584         my $root = $db->root();
2585
2586 This is useful for changing options after the object has already been created,
2587 such as enabling/disabling locking, volatile or debug modes.  You can also
2588 store your own temporary user data in this structure (be wary of name
2589 collision), which is then accessible from any child hash or array.
2590
2591 =head1 CUSTOM DIGEST ALGORITHM
2592
2593 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2594 keys.  However you can override this, and use another algorithm (such as SHA-256)
2595 or even write your own.  But please note that DBM::Deep currently expects zero
2596 collisions, so your algorithm has to be I<perfect>, so to speak.
2597 Collision detection may be introduced in a later version.
2598
2599
2600
2601 You can specify a custom digest algorithm by calling the static C<set_digest()>
2602 function, passing a reference to a subroutine, and the length of the algorithm's
2603 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2604 objects.  Here is a working example that uses a 256-bit hash from the
2605 I<Digest::SHA256> module.  Please see
2606 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2607
2608         use DBM::Deep;
2609         use Digest::SHA256;
2610
2611         my $context = Digest::SHA256::new(256);
2612
2613         DBM::Deep::set_digest( \&my_digest, 32 );
2614
2615         my $db = DBM::Deep->new( "foo-sha.db" );
2616
2617         $db->{key1} = "value1";
2618         $db->{key2} = "value2";
2619         print "key1: " . $db->{key1} . "\n";
2620         print "key2: " . $db->{key2} . "\n";
2621
2622         undef $db;
2623         exit;
2624
2625         sub my_digest {
2626                 return substr( $context->hash($_[0]), 0, 32 );
2627         }
2628
2629 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2630 of bytes you specify in the C<set_digest()> function (in this case 32).
2631
2632 =head1 CIRCULAR REFERENCES
2633
2634 DBM::Deep has B<experimental> support for circular references.  Meaning you
2635 can have a nested hash key or array element that points to a parent object.
2636 This relationship is stored in the DB file, and is preserved between sessions.
2637 Here is an example:
2638
2639         my $db = DBM::Deep->new( "foo.db" );
2640
2641         $db->{foo} = "bar";
2642         $db->{circle} = $db; # ref to self
2643
2644         print $db->{foo} . "\n"; # prints "foo"
2645         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2646
2647 One catch is, passing the object to a function that recursively walks the
2648 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2649 C<export()> methods) will result in an infinite loop.  The other catch is,
2650 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2651 or C<next_key()> methods), you will get the I<target object's key>, not the
2652 ref's key.  This gets even more interesting with the above example, where
2653 the I<circle> key points to the base DB object, which technically doesn't
2654 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2655 special case.
2656
2657 =head1 CAVEATS / ISSUES / BUGS
2658
2659 This section describes all the known issues with DBM::Deep.  It you have found
2660 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2661
2662 =head2 UNUSED SPACE RECOVERY
2663
2664 One major caveat with DBM::Deep is that space occupied by existing keys and
2665 values is not recovered when they are deleted.  Meaning if you keep deleting
2666 and adding new keys, your file will continuously grow.  I am working on this,
2667 but in the meantime you can call the built-in C<optimize()> method from time to
2668 time (perhaps in a crontab or something) to recover all your unused space.
2669
2670         $db->optimize(); # returns true on success
2671
2672 This rebuilds the ENTIRE database into a new file, then moves it on top of
2673 the original.  The new file will have no unused space, thus it will take up as
2674 little disk space as possible.  Please note that this operation can take
2675 a long time for large files, and you need enough disk space to temporarily hold
2676 2 copies of your DB file.  The temporary file is created in the same directory
2677 as the original, named with a ".tmp" extension, and is deleted when the
2678 operation completes.  Oh, and if locking is enabled, the DB is automatically
2679 locked for the entire duration of the copy.
2680
2681
2682
2683 B<WARNING:> Only call optimize() on the top-level node of the database, and
2684 make sure there are no child references lying around.  DBM::Deep keeps a reference
2685 counter, and if it is greater than 1, optimize() will abort and return undef.
2686
2687 =head2 AUTOVIVIFICATION
2688
2689 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2690 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2691 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2692 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2693 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2694 this does not work:
2695
2696         $db->{foo}->{bar} = "hello";
2697
2698 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2699 being an empty hash.  Try this instead, which works fine:
2700
2701         $db->{foo} = { bar => "hello" };
2702
2703 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2704 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2705 Probably a bug in Perl.
2706
2707 =head2 FILE CORRUPTION
2708
2709 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2710 for a 32-bit signature when opened, but other corruption in files can cause
2711 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2712 stuck in an infinite loop depending on the level of corruption.  File write
2713 operations are not checked for failure (for speed), so if you happen to run
2714 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2715 be addressed in a later version of DBM::Deep.
2716
2717 =head2 DB OVER NFS
2718
2719 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2720 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2721 about setting up your NFS server with a locking daemon, then using lockf() to
2722 lock your files, but your milage may vary there as well.  From what I
2723 understand, there is no real way to do it.  However, if you need access to the
2724 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2725 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2726
2727 =head2 COPYING OBJECTS
2728
2729 Beware of copying tied objects in Perl.  Very strange things can happen.
2730 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2731 returns a new, blessed, tied hash or array to the same level in the DB.
2732
2733         my $copy = $db->clone();
2734
2735 =head2 LARGE ARRAYS
2736
2737 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2738 These functions cause every element in the array to move, which can be murder
2739 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2740 a different location.  This may be addressed in a later version.
2741
2742 =head1 PERFORMANCE
2743
2744 This section discusses DBM::Deep's speed and memory usage.
2745
2746 =head2 SPEED
2747
2748 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2749 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2750 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2751 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2752 with huge databases.  Here is some test data:
2753
2754         Adding 1,000,000 keys to new DB file...
2755
2756         At 100 keys, avg. speed is 2,703 keys/sec
2757         At 200 keys, avg. speed is 2,642 keys/sec
2758         At 300 keys, avg. speed is 2,598 keys/sec
2759         At 400 keys, avg. speed is 2,578 keys/sec
2760         At 500 keys, avg. speed is 2,722 keys/sec
2761         At 600 keys, avg. speed is 2,628 keys/sec
2762         At 700 keys, avg. speed is 2,700 keys/sec
2763         At 800 keys, avg. speed is 2,607 keys/sec
2764         At 900 keys, avg. speed is 2,190 keys/sec
2765         At 1,000 keys, avg. speed is 2,570 keys/sec
2766         At 2,000 keys, avg. speed is 2,417 keys/sec
2767         At 3,000 keys, avg. speed is 1,982 keys/sec
2768         At 4,000 keys, avg. speed is 1,568 keys/sec
2769         At 5,000 keys, avg. speed is 1,533 keys/sec
2770         At 6,000 keys, avg. speed is 1,787 keys/sec
2771         At 7,000 keys, avg. speed is 1,977 keys/sec
2772         At 8,000 keys, avg. speed is 2,028 keys/sec
2773         At 9,000 keys, avg. speed is 2,077 keys/sec
2774         At 10,000 keys, avg. speed is 2,031 keys/sec
2775         At 20,000 keys, avg. speed is 1,970 keys/sec
2776         At 30,000 keys, avg. speed is 2,050 keys/sec
2777         At 40,000 keys, avg. speed is 2,073 keys/sec
2778         At 50,000 keys, avg. speed is 1,973 keys/sec
2779         At 60,000 keys, avg. speed is 1,914 keys/sec
2780         At 70,000 keys, avg. speed is 2,091 keys/sec
2781         At 80,000 keys, avg. speed is 2,103 keys/sec
2782         At 90,000 keys, avg. speed is 1,886 keys/sec
2783         At 100,000 keys, avg. speed is 1,970 keys/sec
2784         At 200,000 keys, avg. speed is 2,053 keys/sec
2785         At 300,000 keys, avg. speed is 1,697 keys/sec
2786         At 400,000 keys, avg. speed is 1,838 keys/sec
2787         At 500,000 keys, avg. speed is 1,941 keys/sec
2788         At 600,000 keys, avg. speed is 1,930 keys/sec
2789         At 700,000 keys, avg. speed is 1,735 keys/sec
2790         At 800,000 keys, avg. speed is 1,795 keys/sec
2791         At 900,000 keys, avg. speed is 1,221 keys/sec
2792         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2793
2794 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2795 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2796 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2797 Run time was 12 min 3 sec.
2798
2799 =head2 MEMORY USAGE
2800
2801 One of the great things about DBM::Deep is that it uses very little memory.
2802 Even with huge databases (1,000,000+ keys) you will not see much increased
2803 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2804 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2805 database handle:
2806
2807           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2808         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2809
2810 Basically the process is taking 2,716K of memory.  And here is the same
2811 process after storing and fetching 1,000,000 keys:
2812
2813           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2814         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2815
2816 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2817 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2818
2819 =head1 DB FILE FORMAT
2820
2821 In case you were interested in the underlying DB file format, it is documented
2822 here in this section.  You don't need to know this to use the module, it's just
2823 included for reference.
2824
2825 =head2 SIGNATURE
2826
2827 DBM::Deep files always start with a 32-bit signature to identify the file type.
2828 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2829 checked when the file is opened.
2830
2831 =head2 TAG
2832
2833 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2834 has a standard header containing the type of data, the length of data, and then
2835 the data itself.  The type is a single character (1 byte), the length is a
2836 32-bit unsigned long in network byte order, and the data is, well, the data.
2837 Here is how it unfolds:
2838
2839 =head2 MASTER INDEX
2840
2841 Immediately after the 32-bit file signature is the I<Master Index> record.
2842 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2843 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2844 depending on how the DBM::Deep object was constructed.
2845
2846
2847
2848 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2849 number).  The first 8-bit char of the MD5 signature is the offset into the
2850 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2851 index element is a file offset of the next tag for the key/element in question,
2852 which is usually a I<Bucket List> tag (see below).
2853
2854
2855
2856 The next tag I<could> be another index, depending on how many keys/elements
2857 exist.  See L<RE-INDEXING> below for details.
2858
2859 =head2 BUCKET LIST
2860
2861 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2862 file offsets to where the actual data is stored.  It starts with a standard
2863 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2864 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2865 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2866 When the list fills up, a I<Re-Index> operation is performed (See
2867 L<RE-INDEXING> below).
2868
2869 =head2 BUCKET
2870
2871 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2872 index/value pair (in array mode).  It starts with a standard tag header with
2873 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2874 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2875 header.  The size reported in the tag header is only for the value, but then,
2876 just after the value is another size (32-bit unsigned long) and then the plain
2877 key itself.  Since the value is likely to be fetched more often than the plain
2878 key, I figured it would be I<slightly> faster to store the value first.
2879
2880
2881
2882 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2883 record for the nested structure, where the process begins all over again.
2884
2885 =head2 RE-INDEXING
2886
2887 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2888 exhausted.  Then, when another key/element comes in, the list is converted to a
2889 new index record.  However, this index will look at the next char in the MD5
2890 hash, and arrange new Bucket List pointers accordingly.  This process is called
2891 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2892 17 (16 + new one) keys/elements are removed from the old Bucket List and
2893 inserted into the new index.  Several new Bucket Lists are created in the
2894 process, as a new MD5 char from the key is being examined (it is unlikely that
2895 the keys will all share the same next char of their MD5s).
2896
2897
2898
2899 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2900 when the Bucket Lists will turn into indexes, but the first round tends to
2901 happen right around 4,000 keys.  You will see a I<slight> decrease in
2902 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2903 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2904 right around 900,000 keys.  This process can continue nearly indefinitely --
2905 right up until the point the I<MD5> signatures start colliding with each other,
2906 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2907 getting struck by lightning while you are walking to cash in your tickets.
2908 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2909 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2910 this is 340 unodecillion, but don't quote me).
2911
2912 =head2 STORING
2913
2914 When a new key/element is stored, the key (or index number) is first ran through
2915 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2916 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2917 for the first char of the signature (in this case I<b>).  If it does not exist,
2918 a new I<Bucket List> is created for our key (and the next 15 future keys that
2919 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2920 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2921 this point, unless we are replacing an existing I<Bucket>), where the actual
2922 data will be stored.
2923
2924 =head2 FETCHING
2925
2926 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2927 (or index number), then walking along the indexes.  If there are enough
2928 keys/elements in this DB level, there might be nested indexes, each linked to
2929 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2930 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2931 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2932 plain key are stored.
2933
2934
2935
2936 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2937 methods.  In this process the indexes are walked systematically, and each key
2938 fetched in increasing MD5 order (which is why it appears random).   Once the
2939 I<Bucket> is found, the value is skipped the plain key returned instead.
2940 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2941 alphabetically sorted.  This only happens on an index-level -- as soon as the
2942 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2943 so it's pretty much undefined how the keys will come out -- just like Perl's
2944 built-in hashes.
2945
2946 =head1 CODE COVERAGE
2947
2948 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2949 module's test suite.
2950
2951   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2952   File                           stmt   bran   cond    sub    pod   time  total
2953   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2954   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2955   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2956   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2957
2958 =head1 AUTHOR
2959
2960 Joseph Huckaby, L<jhuckaby@cpan.org>
2961
2962 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2963
2964 =head1 SEE ALSO
2965
2966 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2967 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2968
2969 =head1 LICENSE
2970
2971 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2972 This is free software, you may use it and distribute it under the
2973 same terms as Perl itself.
2974
2975 =cut