7 # Multi-level database module for storing hash trees, arrays and simple
8 # key/value pairs into FTP-able, cross-platform binary database files.
10 # Type `perldoc DBM::Deep` for complete documentation.
14 # tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
16 # my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
18 # $db->{my_scalar} = 'hello world';
19 # $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
20 # $db->{my_array} = [ 1, 2, 3, time() ];
21 # $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
22 # push @{$db->{my_array}}, 'another value';
23 # my @key_list = keys %{$db->{my_hash}};
24 # print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
27 # (c) 2002-2006 Joseph Huckaby. All Rights Reserved.
28 # This program is free software; you can redistribute it and/or
29 # modify it under the same terms as Perl itself.
37 our $VERSION = q(0.99_03);
39 use Fcntl qw( :DEFAULT :flock :seek );
41 use Clone::Any '_clone_data';
43 use FileHandle::Fmode ();
46 use DBM::Deep::Engine3;
50 # Setup constants for users to pass to new()
52 sub TYPE_HASH () { DBM::Deep::Engine3->SIG_HASH }
53 sub TYPE_ARRAY () { DBM::Deep::Engine3->SIG_ARRAY }
55 # This is used in all the children of this class in their TIE<type> methods.
62 $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
67 unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
68 $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
73 $args = { file => shift };
81 # Class constructor method for Perl OO interface.
82 # Calls tie() and returns blessed reference to tied hash or array,
83 # providing a hybrid OO/tie interface.
86 my $args = $class->_get_args( @_ );
89 # Check if we want a tied hash or array.
92 if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
93 $class = 'DBM::Deep::Array';
94 require DBM::Deep::Array;
95 tie @$self, $class, %$args;
98 $class = 'DBM::Deep::Hash';
99 require DBM::Deep::Hash;
100 tie %$self, $class, %$args;
103 return bless $self, $class;
106 # This initializer is called from the various TIE* methods. new() calls tie(),
107 # which allows for a single point of entry.
112 $args->{storage} = DBM::Deep::File->new( $args )
113 unless exists $args->{storage};
115 # locking implicitly enables autoflush
116 if ($args->{locking}) { $args->{autoflush} = 1; }
118 # These are the defaults to be optionally overridden below
121 base_offset => undef,
128 $self->{engine} = DBM::Deep::Engine3->new( { %{$args}, obj => $self } );
130 # Grab the parameters we want to use
131 foreach my $param ( keys %$self ) {
132 next unless exists $args->{$param};
133 $self->{$param} = $args->{$param};
137 local $SIG{'__DIE__'};
140 $self->_engine->setup_fh( $self );
141 $self->_storage->set_inode;
145 eval { local $SIG{'__DIE__'}; $self->unlock; };
154 require DBM::Deep::Hash;
155 return DBM::Deep::Hash->TIEHASH( @_ );
160 require DBM::Deep::Array;
161 return DBM::Deep::Array->TIEARRAY( @_ );
165 my $self = shift->_get_self;
166 return $self->_storage->lock( $self, @_ );
170 my $self = shift->_get_self;
171 return $self->_storage->unlock( $self, @_ );
175 my $self = shift->_get_self;
176 my ($spot, $value) = @_;
181 elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
182 ${$spot} = $value->_repr;
183 $value->_copy_node( ${$spot} );
186 my $r = Scalar::Util::reftype( $value );
187 my $c = Scalar::Util::blessed( $value );
188 if ( $r eq 'ARRAY' ) {
189 ${$spot} = [ @{$value} ];
192 ${$spot} = { %{$value} };
194 ${$spot} = bless ${$spot}, $c
202 die "Must be implemented in a child class\n";
206 die "Must be implemented in a child class\n";
211 # Recursively export into standard Perl hashes and arrays.
213 my $self = shift->_get_self;
215 my $temp = $self->_repr;
218 $self->_copy_node( $temp );
221 my $classname = $self->_engine->get_classname( $self->_storage->transaction_id, $self->_base_offset );
222 if ( defined $classname ) {
223 bless $temp, $classname;
231 # Recursively import Perl hash/array structure
233 if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
235 my $self = shift->_get_self;
238 # struct is not a reference, so just import based on our type
240 $struct = $self->_repr( @_ );
243 #XXX This isn't the best solution. Better would be to use Data::Walker,
244 #XXX but that's a lot more thinking than I want to do right now.
247 $self->_import( _clone_data( $struct ) );
257 #XXX Need to keep track of who has a fh to this file in order to
258 #XXX close them all prior to optimize on Win32/cygwin
261 # Rebuild entire database into new file, then move
262 # it back on top of original.
264 my $self = shift->_get_self;
266 #XXX Need to create a new test for this
267 # if ($self->_storage->{links} > 1) {
268 # $self->_throw_error("Cannot optimize: reference count is greater than 1");
271 #XXX Do we have to lock the tempfile?
273 my $db_temp = DBM::Deep->new(
274 file => $self->_storage->{file} . '.tmp',
279 $self->_copy_node( $db_temp );
283 # Attempt to copy user, group and permissions over to new file
285 my @stats = stat($self->_fh);
286 my $perms = $stats[2] & 07777;
289 chown( $uid, $gid, $self->_storage->{file} . '.tmp' );
290 chmod( $perms, $self->_storage->{file} . '.tmp' );
292 # q.v. perlport for more information on this variable
293 if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
295 # Potential race condition when optmizing on Win32 with locking.
296 # The Windows filesystem requires that the filehandle be closed
297 # before it is overwritten with rename(). This could be redone
301 $self->_storage->close;
304 if (!rename $self->_storage->{file} . '.tmp', $self->_storage->{file}) {
305 unlink $self->_storage->{file} . '.tmp';
307 $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
311 $self->_storage->close;
312 $self->_storage->open;
313 $self->_engine->setup_fh( $self );
320 # Make copy of object and return
322 my $self = shift->_get_self;
324 return DBM::Deep->new(
325 type => $self->_type,
326 base_offset => $self->_base_offset,
327 storage => $self->_storage,
328 parent => $self->{parent},
329 parent_key => $self->{parent_key},
334 my %is_legal_filter = map {
337 store_key store_value
338 fetch_key fetch_value
343 # Setup filter function for storing or fetching the key or value
345 my $self = shift->_get_self;
349 if ( $is_legal_filter{$type} ) {
350 $self->_storage->{"filter_$type"} = $func;
359 my $self = shift->_get_self;
360 return $self->_storage->begin_transaction;
364 my $self = shift->_get_self;
365 return $self->_storage->end_transaction;
369 my $self = shift->_get_self;
370 return $self->_storage->commit_transaction;
378 my $self = $_[0]->_get_self;
379 return $self->{engine};
383 my $self = $_[0]->_get_self;
384 return $self->{storage};
388 my $self = $_[0]->_get_self;
389 return $self->{type};
393 my $self = $_[0]->_get_self;
394 return $self->{base_offset};
398 my $self = $_[0]->_get_self;
399 return $self->_storage->{fh};
407 die "DBM::Deep: $_[1]\n";
414 #XXX This if() is redundant
415 if ( my $parent = $self->{parent} ) {
417 while ( $parent->{parent} ) {
419 $parent->_type eq TYPE_HASH
420 ? "\{q{$child->{parent_key}}\}"
421 : "\[$child->{parent_key}\]"
425 $parent = $parent->{parent};
429 $base = "\$db->get( q{$child->{parent_key}} )->" . $base;
432 $base = "\$db->get( q{$child->{parent_key}} )";
440 # Store single hash key/value or array element in database.
442 my $self = shift->_get_self;
443 my ($key, $value, $orig_key) = @_;
444 $orig_key = $key unless defined $orig_key;
446 if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
447 $self->_throw_error( 'Cannot write to a readonly filehandle' );
450 #XXX The second condition needs to disappear
451 if ( !( $self->_type eq TYPE_ARRAY && $orig_key eq 'length') ) {
454 my $r = Scalar::Util::reftype( $value ) || '';
455 if ( $r eq 'HASH' ) {
458 elsif ( $r eq 'ARRAY' ) {
461 elsif ( defined $value ) {
468 if ( my $c = Scalar::Util::blessed( $value ) ) {
469 $rhs = "bless $rhs, '$c'";
472 my $lhs = $self->_find_parent;
474 if ( $self->_type eq TYPE_HASH ) {
475 $lhs .= "->\{q{$orig_key}\}";
478 $lhs .= "->\[$orig_key\]";
484 $lhs = "\$db->put(q{$orig_key},$rhs);";
487 $self->_storage->audit($lhs);
491 # Request exclusive lock for writing
493 $self->lock( LOCK_EX );
495 # User may be storing a complex value, in which case we do not want it run
496 # through the filtering system.
497 if ( !ref($value) && $self->_storage->{filter_store_value} ) {
498 $value = $self->_storage->{filter_store_value}->( $value );
501 $self->_engine->write_value( $self->_storage->transaction_id, $self->_base_offset, $key, $value, $orig_key );
510 # Fetch single value or element given plain key or array index
512 my $self = shift->_get_self;
513 my ($key, $orig_key) = @_;
514 $orig_key = $key unless defined $orig_key;
517 # Request shared lock for reading
519 $self->lock( LOCK_SH );
521 my $result = $self->_engine->read_value( $self->_storage->transaction_id, $self->_base_offset, $key, $orig_key );
525 # Filters only apply to scalar values, so the ref check is making
526 # sure the fetched bucket is a scalar, not a child hash or array.
527 return ($result && !ref($result) && $self->_storage->{filter_fetch_value})
528 ? $self->_storage->{filter_fetch_value}->($result)
534 # Delete single key/value pair or element given plain key or array index
536 my $self = shift->_get_self;
537 my ($key, $orig_key) = @_;
538 $orig_key = $key unless defined $orig_key;
540 if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
541 $self->_throw_error( 'Cannot write to a readonly filehandle' );
544 if ( defined $orig_key ) {
545 my $lhs = $self->_find_parent;
547 $self->_storage->audit( "delete $lhs;" );
550 $self->_storage->audit( "\$db->delete('$orig_key');" );
555 # Request exclusive lock for writing
557 $self->lock( LOCK_EX );
562 my $value = $self->_engine->delete_key( $self->_storage->transaction_id, $self->_base_offset, $key, $orig_key );
564 if (defined $value && !ref($value) && $self->_storage->{filter_fetch_value}) {
565 $value = $self->_storage->{filter_fetch_value}->($value);
575 # Check if a single key or element exists given plain key or array index
577 my $self = shift->_get_self;
581 # Request shared lock for reading
583 $self->lock( LOCK_SH );
585 my $result = $self->_engine->key_exists( $self->_storage->transaction_id, $self->_base_offset, $key );
594 # Clear all keys from hash, or all elements from array.
596 my $self = shift->_get_self;
598 if ( !FileHandle::Fmode::is_W( $self->_fh ) ) {
599 $self->_throw_error( 'Cannot write to a readonly filehandle' );
603 my $lhs = $self->_find_parent;
605 if ( $self->_type eq TYPE_HASH ) {
606 $lhs = '%{' . $lhs . '}';
609 $lhs = '@{' . $lhs . '}';
612 $self->_storage->audit( "$lhs = ();" );
616 # Request exclusive lock for writing
618 $self->lock( LOCK_EX );
620 if ( $self->_type eq TYPE_HASH ) {
621 my $key = $self->first_key;
623 # Retrieve the key before deleting because we depend on next_key
624 my $next_key = $self->next_key( $key );
625 $self->_engine->delete_key( $self->_storage->transaction_id, $self->_base_offset, $key, $key );
630 my $size = $self->FETCHSIZE;
631 for my $key ( 0 .. $size - 1 ) {
632 $self->_engine->delete_key( $self->_storage->transaction_id, $self->_base_offset, $key, $key );
634 $self->STORESIZE( 0 );
636 #XXX This needs updating to use _release_space
637 # $self->_engine->write_tag(
638 # $self->_base_offset, $self->_type,
639 # chr(0)x$self->_engine->{index_size},
648 # Public method aliases
650 sub put { (shift)->STORE( @_ ) }
651 sub store { (shift)->STORE( @_ ) }
652 sub get { (shift)->FETCH( @_ ) }
653 sub fetch { (shift)->FETCH( @_ ) }
654 sub delete { (shift)->DELETE( @_ ) }
655 sub exists { (shift)->EXISTS( @_ ) }
656 sub clear { (shift)->CLEAR( @_ ) }
663 DBM::Deep - A pure perl multi-level hash/array DBM
668 my $db = DBM::Deep->new( "foo.db" );
670 $db->{key} = 'value';
673 $db->put('key' => 'value');
674 print $db->get('key');
676 # true multi-level support
677 $db->{my_complex} = [
678 'hello', { perl => 'rules' },
682 tie my %db, 'DBM::Deep', 'foo.db';
686 tied(%db)->put('key' => 'value');
687 print tied(%db)->get('key');
691 A unique flat-file database module, written in pure perl. True multi-level
692 hash/array support (unlike MLDBM, which is faked), hybrid OO / tie()
693 interface, cross-platform FTPable files, ACID transactions, and is quite fast.
694 Can handle millions of keys and unlimited levels without significant
695 slow-down. Written from the ground-up in pure perl -- this is NOT a wrapper
696 around a C-based DBM. Out-of-the-box compatibility with Unix, Mac OS X and
699 =head1 VERSION DIFFERENCES
701 B<NOTE>: 0.99_01 and above have significant file format differences from 0.983 and
702 before. There will be a backwards-compatibility layer in 1.00, but that is
703 slated for a later 0.99_x release. This version is B<NOT> backwards compatible
704 with 0.983 and before.
708 Construction can be done OO-style (which is the recommended way), or using
709 Perl's tie() function. Both are examined here.
711 =head2 OO CONSTRUCTION
713 The recommended way to construct a DBM::Deep object is to use the new()
714 method, which gets you a blessed I<and> tied hash (or array) reference.
716 my $db = DBM::Deep->new( "foo.db" );
718 This opens a new database handle, mapped to the file "foo.db". If this
719 file does not exist, it will automatically be created. DB files are
720 opened in "r+" (read/write) mode, and the type of object returned is a
721 hash, unless otherwise specified (see L<OPTIONS> below).
723 You can pass a number of options to the constructor to specify things like
724 locking, autoflush, etc. This is done by passing an inline hash (or hashref):
726 my $db = DBM::Deep->new(
732 Notice that the filename is now specified I<inside> the hash with
733 the "file" parameter, as opposed to being the sole argument to the
734 constructor. This is required if any options are specified.
735 See L<OPTIONS> below for the complete list.
737 You can also start with an array instead of a hash. For this, you must
738 specify the C<type> parameter:
740 my $db = DBM::Deep->new(
742 type => DBM::Deep->TYPE_ARRAY
745 B<Note:> Specifing the C<type> parameter only takes effect when beginning
746 a new DB file. If you create a DBM::Deep object with an existing file, the
747 C<type> will be loaded from the file header, and an error will be thrown if
748 the wrong type is passed in.
750 =head2 TIE CONSTRUCTION
752 Alternately, you can create a DBM::Deep handle by using Perl's built-in
753 tie() function. The object returned from tie() can be used to call methods,
754 such as lock() and unlock(). (That object can be retrieved from the tied
755 variable at any time using tied() - please see L<perltie/> for more info.
758 my $db = tie %hash, "DBM::Deep", "foo.db";
761 my $db = tie @array, "DBM::Deep", "bar.db";
763 As with the OO constructor, you can replace the DB filename parameter with
764 a hash containing one or more options (see L<OPTIONS> just below for the
767 tie %hash, "DBM::Deep", {
775 There are a number of options that can be passed in when constructing your
776 DBM::Deep objects. These apply to both the OO- and tie- based approaches.
782 Filename of the DB file to link the handle to. You can pass a full absolute
783 filesystem path, partial path, or a plain filename if the file is in the
784 current working directory. This is a required parameter (though q.v. fh).
788 If you want, you can pass in the fh instead of the file. This is most useful for doing
791 my $db = DBM::Deep->new( { fh => \*DATA } );
793 You are responsible for making sure that the fh has been opened appropriately for your
794 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
795 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
796 needs to read from the fh.
798 =item * audit_file / audit_fh
800 These are just like file/fh, except for auditing. Please see L</AUDITING> for
805 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
806 not need to set this. However, it's there if you want it.
808 If you pass in fh and do not set this, it will be set appropriately.
812 This parameter specifies what type of object to create, a hash or array. Use
813 one of these two constants:
817 =item * C<DBM::Deep-E<gt>TYPE_HASH>
819 =item * C<DBM::Deep-E<gt>TYPE_ARRAY>.
823 This only takes effect when beginning a new file. This is an optional
824 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
828 Specifies whether locking is to be enabled. DBM::Deep uses Perl's flock()
829 function to lock the database in exclusive mode for writes, and shared mode
830 for reads. Pass any true value to enable. This affects the base DB handle
831 I<and any child hashes or arrays> that use the same DB file. This is an
832 optional parameter, and defaults to 0 (disabled). See L<LOCKING> below for
837 Specifies whether autoflush is to be enabled on the underlying filehandle.
838 This obviously slows down write operations, but is required if you may have
839 multiple processes accessing the same DB file (also consider enable I<locking>).
840 Pass any true value to enable. This is an optional parameter, and defaults to 0
845 If I<autobless> mode is enabled, DBM::Deep will preserve the class something
846 is blessed into, and restores it when fetched. This is an optional parameter, and defaults to 1 (enabled).
848 B<Note:> If you use the OO-interface, you will not be able to call any methods
849 of DBM::Deep on the blessed item. This is considered to be a feature.
853 See L</FILTERS> below.
859 With DBM::Deep you can access your databases using Perl's standard hash/array
860 syntax. Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
861 treat them as such. DBM::Deep will intercept all reads/writes and direct them
862 to the right place -- the DB file. This has nothing to do with the
863 L<TIE CONSTRUCTION> section above. This simply tells you how to use DBM::Deep
864 using regular hashes and arrays, rather than calling functions like C<get()>
865 and C<put()> (although those work too). It is entirely up to you how to want
866 to access your databases.
870 You can treat any DBM::Deep object like a normal Perl hash reference. Add keys,
871 or even nested hashes (or arrays) using standard Perl syntax:
873 my $db = DBM::Deep->new( "foo.db" );
875 $db->{mykey} = "myvalue";
877 $db->{myhash}->{subkey} = "subvalue";
879 print $db->{myhash}->{subkey} . "\n";
881 You can even step through hash keys using the normal Perl C<keys()> function:
883 foreach my $key (keys %$db) {
884 print "$key: " . $db->{$key} . "\n";
887 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
888 pushes them onto an array, all before the loop even begins. If you have an
889 extremely large hash, this may exhaust Perl's memory. Instead, consider using
890 Perl's C<each()> function, which pulls keys/values one at a time, using very
893 while (my ($key, $value) = each %$db) {
894 print "$key: $value\n";
897 Please note that when using C<each()>, you should always pass a direct
898 hash reference, not a lookup. Meaning, you should B<never> do this:
901 while (my ($key, $value) = each %{$db->{foo}}) { # BAD
903 This causes an infinite loop, because for each iteration, Perl is calling
904 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
905 it effectively keeps returning the first key over and over again. Instead,
906 assign a temporary variable to C<$db->{foo}>, then pass that to each().
910 As with hashes, you can treat any DBM::Deep object like a normal Perl array
911 reference. This includes inserting, removing and manipulating elements,
912 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
913 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
914 or simply be a nested array reference inside a hash. Example:
916 my $db = DBM::Deep->new(
917 file => "foo-array.db",
918 type => DBM::Deep->TYPE_ARRAY
922 push @$db, "bar", "baz";
925 my $last_elem = pop @$db; # baz
926 my $first_elem = shift @$db; # bah
927 my $second_elem = $db->[1]; # bar
929 my $num_elements = scalar @$db;
933 In addition to the I<tie()> interface, you can also use a standard OO interface
934 to manipulate all aspects of DBM::Deep databases. Each type of object (hash or
935 array) has its own methods, but both types share the following common methods:
936 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>. C<fetch()> and
937 C<store(> are aliases to C<put()> and C<get()>, respectively.
941 =item * new() / clone()
943 These are the constructor and copy-functions.
945 =item * put() / store()
947 Stores a new hash key/value pair, or sets an array element value. Takes two
948 arguments, the hash key or array index, and the new value. The value can be
949 a scalar, hash ref or array ref. Returns true on success, false on failure.
951 $db->put("foo", "bar"); # for hashes
952 $db->put(1, "bar"); # for arrays
954 =item * get() / fetch()
956 Fetches the value of a hash key or array element. Takes one argument: the hash
957 key or array index. Returns a scalar, hash ref or array ref, depending on the
960 my $value = $db->get("foo"); # for hashes
961 my $value = $db->get(1); # for arrays
965 Checks if a hash key or array index exists. Takes one argument: the hash key
966 or array index. Returns true if it exists, false if not.
968 if ($db->exists("foo")) { print "yay!\n"; } # for hashes
969 if ($db->exists(1)) { print "yay!\n"; } # for arrays
973 Deletes one hash key/value pair or array element. Takes one argument: the hash
974 key or array index. Returns true on success, false if not found. For arrays,
975 the remaining elements located after the deleted element are NOT moved over.
976 The deleted element is essentially just undefined, which is exactly how Perl's
977 internal arrays work. Please note that the space occupied by the deleted
978 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
979 below for details and workarounds.
981 $db->delete("foo"); # for hashes
982 $db->delete(1); # for arrays
986 Deletes B<all> hash keys or array elements. Takes no arguments. No return
987 value. Please note that the space occupied by the deleted keys/values or
988 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
989 details and workarounds.
991 $db->clear(); # hashes or arrays
993 =item * lock() / unlock()
999 Recover lost disk space. This is important to do, especially if you use
1002 =item * import() / export()
1004 Data going in and out.
1010 For hashes, DBM::Deep supports all the common methods described above, and the
1011 following additional methods: C<first_key()> and C<next_key()>.
1017 Returns the "first" key in the hash. As with built-in Perl hashes, keys are
1018 fetched in an undefined order (which appears random). Takes no arguments,
1019 returns the key as a scalar value.
1021 my $key = $db->first_key();
1025 Returns the "next" key in the hash, given the previous one as the sole argument.
1026 Returns undef if there are no more keys to be fetched.
1028 $key = $db->next_key($key);
1032 Here are some examples of using hashes:
1034 my $db = DBM::Deep->new( "foo.db" );
1036 $db->put("foo", "bar");
1037 print "foo: " . $db->get("foo") . "\n";
1039 $db->put("baz", {}); # new child hash ref
1040 $db->get("baz")->put("buz", "biz");
1041 print "buz: " . $db->get("baz")->get("buz") . "\n";
1043 my $key = $db->first_key();
1045 print "$key: " . $db->get($key) . "\n";
1046 $key = $db->next_key($key);
1049 if ($db->exists("foo")) { $db->delete("foo"); }
1053 For arrays, DBM::Deep supports all the common methods described above, and the
1054 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1055 C<unshift()> and C<splice()>.
1061 Returns the number of elements in the array. Takes no arguments.
1063 my $len = $db->length();
1067 Adds one or more elements onto the end of the array. Accepts scalars, hash
1068 refs or array refs. No return value.
1070 $db->push("foo", "bar", {});
1074 Fetches the last element in the array, and deletes it. Takes no arguments.
1075 Returns undef if array is empty. Returns the element value.
1077 my $elem = $db->pop();
1081 Fetches the first element in the array, deletes it, then shifts all the
1082 remaining elements over to take up the space. Returns the element value. This
1083 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1086 my $elem = $db->shift();
1090 Inserts one or more elements onto the beginning of the array, shifting all
1091 existing elements over to make room. Accepts scalars, hash refs or array refs.
1092 No return value. This method is not recommended with large arrays -- see
1093 <LARGE ARRAYS> below for details.
1095 $db->unshift("foo", "bar", {});
1099 Performs exactly like Perl's built-in function of the same name. See L<perldoc
1100 -f splice> for usage -- it is too complicated to document here. This method is
1101 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1105 Here are some examples of using arrays:
1107 my $db = DBM::Deep->new(
1109 type => DBM::Deep->TYPE_ARRAY
1112 $db->push("bar", "baz");
1113 $db->unshift("foo");
1116 my $len = $db->length();
1117 print "length: $len\n"; # 4
1119 for (my $k=0; $k<$len; $k++) {
1120 print "$k: " . $db->get($k) . "\n";
1123 $db->splice(1, 2, "biz", "baf");
1125 while (my $elem = shift @$db) {
1126 print "shifted: $elem\n";
1131 Enable automatic file locking by passing a true value to the C<locking>
1132 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1134 my $db = DBM::Deep->new(
1139 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
1140 mode for writes, and shared mode for reads. This is required if you have
1141 multiple processes accessing the same database file, to avoid file corruption.
1142 Please note that C<flock()> does NOT work for files over NFS. See L<DB OVER
1143 NFS> below for more.
1145 =head2 EXPLICIT LOCKING
1147 You can explicitly lock a database, so it remains locked for multiple
1148 transactions. This is done by calling the C<lock()> method, and passing an
1149 optional lock mode argument (defaults to exclusive mode). This is particularly
1150 useful for things like counters, where the current value needs to be fetched,
1151 then incremented, then stored again.
1154 my $counter = $db->get("counter");
1156 $db->put("counter", $counter);
1165 You can pass C<lock()> an optional argument, which specifies which mode to use
1166 (exclusive or shared). Use one of these two constants:
1167 C<DBM::Deep-E<gt>LOCK_EX> or C<DBM::Deep-E<gt>LOCK_SH>. These are passed
1168 directly to C<flock()>, and are the same as the constants defined in Perl's
1171 $db->lock( $db->LOCK_SH );
1175 =head1 IMPORTING/EXPORTING
1177 You can import existing complex structures by calling the C<import()> method,
1178 and export an entire database into an in-memory structure using the C<export()>
1179 method. Both are examined here.
1183 Say you have an existing hash with nested hashes/arrays inside it. Instead of
1184 walking the structure and adding keys/elements to the database as you go,
1185 simply pass a reference to the C<import()> method. This recursively adds
1186 everything to an existing DBM::Deep object for you. Here is an example:
1191 array1 => [ "elem0", "elem1", "elem2" ],
1193 subkey1 => "subvalue1",
1194 subkey2 => "subvalue2"
1198 my $db = DBM::Deep->new( "foo.db" );
1199 $db->import( $struct );
1201 print $db->{key1} . "\n"; # prints "value1"
1203 This recursively imports the entire C<$struct> object into C<$db>, including
1204 all nested hashes and arrays. If the DBM::Deep object contains exsiting data,
1205 keys are merged with the existing ones, replacing if they already exist.
1206 The C<import()> method can be called on any database level (not just the base
1207 level), and works with both hash and array DB types.
1209 B<Note:> Make sure your existing structure has no circular references in it.
1210 These will cause an infinite loop when importing. There are plans to fix this
1215 Calling the C<export()> method on an existing DBM::Deep object will return
1216 a reference to a new in-memory copy of the database. The export is done
1217 recursively, so all nested hashes/arrays are all exported to standard Perl
1218 objects. Here is an example:
1220 my $db = DBM::Deep->new( "foo.db" );
1222 $db->{key1} = "value1";
1223 $db->{key2} = "value2";
1225 $db->{hash1}->{subkey1} = "subvalue1";
1226 $db->{hash1}->{subkey2} = "subvalue2";
1228 my $struct = $db->export();
1230 print $struct->{key1} . "\n"; # prints "value1"
1232 This makes a complete copy of the database in memory, and returns a reference
1233 to it. The C<export()> method can be called on any database level (not just
1234 the base level), and works with both hash and array DB types. Be careful of
1235 large databases -- you can store a lot more data in a DBM::Deep object than an
1236 in-memory Perl structure.
1238 B<Note:> Make sure your database has no circular references in it.
1239 These will cause an infinite loop when exporting. There are plans to fix this
1244 DBM::Deep has a number of hooks where you can specify your own Perl function
1245 to perform filtering on incoming or outgoing data. This is a perfect
1246 way to extend the engine, and implement things like real-time compression or
1247 encryption. Filtering applies to the base DB level, and all child hashes /
1248 arrays. Filter hooks can be specified when your DBM::Deep object is first
1249 constructed, or by calling the C<set_filter()> method at any time. There are
1250 four available filter hooks, described below:
1254 =item * filter_store_key
1256 This filter is called whenever a hash key is stored. It
1257 is passed the incoming key, and expected to return a transformed key.
1259 =item * filter_store_value
1261 This filter is called whenever a hash key or array element is stored. It
1262 is passed the incoming value, and expected to return a transformed value.
1264 =item * filter_fetch_key
1266 This filter is called whenever a hash key is fetched (i.e. via
1267 C<first_key()> or C<next_key()>). It is passed the transformed key,
1268 and expected to return the plain key.
1270 =item * filter_fetch_value
1272 This filter is called whenever a hash key or array element is fetched.
1273 It is passed the transformed value, and expected to return the plain value.
1277 Here are the two ways to setup a filter hook:
1279 my $db = DBM::Deep->new(
1281 filter_store_value => \&my_filter_store,
1282 filter_fetch_value => \&my_filter_fetch
1287 $db->set_filter( "filter_store_value", \&my_filter_store );
1288 $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
1290 Your filter function will be called only when dealing with SCALAR keys or
1291 values. When nested hashes and arrays are being stored/fetched, filtering
1292 is bypassed. Filters are called as static functions, passed a single SCALAR
1293 argument, and expected to return a single SCALAR value. If you want to
1294 remove a filter, set the function reference to C<undef>:
1296 $db->set_filter( "filter_store_value", undef );
1298 =head2 REAL-TIME ENCRYPTION EXAMPLE
1300 Here is a working example that uses the I<Crypt::Blowfish> module to
1301 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
1302 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
1303 on I<Crypt::Blowfish>. You'll also need the I<Crypt::CBC> module.
1306 use Crypt::Blowfish;
1309 my $cipher = Crypt::CBC->new({
1310 'key' => 'my secret key',
1311 'cipher' => 'Blowfish',
1313 'regenerate_key' => 0,
1314 'padding' => 'space',
1318 my $db = DBM::Deep->new(
1319 file => "foo-encrypt.db",
1320 filter_store_key => \&my_encrypt,
1321 filter_store_value => \&my_encrypt,
1322 filter_fetch_key => \&my_decrypt,
1323 filter_fetch_value => \&my_decrypt,
1326 $db->{key1} = "value1";
1327 $db->{key2} = "value2";
1328 print "key1: " . $db->{key1} . "\n";
1329 print "key2: " . $db->{key2} . "\n";
1335 return $cipher->encrypt( $_[0] );
1338 return $cipher->decrypt( $_[0] );
1341 =head2 REAL-TIME COMPRESSION EXAMPLE
1343 Here is a working example that uses the I<Compress::Zlib> module to do real-time
1344 compression / decompression of keys & values with DBM::Deep Filters.
1345 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
1346 more on I<Compress::Zlib>.
1351 my $db = DBM::Deep->new(
1352 file => "foo-compress.db",
1353 filter_store_key => \&my_compress,
1354 filter_store_value => \&my_compress,
1355 filter_fetch_key => \&my_decompress,
1356 filter_fetch_value => \&my_decompress,
1359 $db->{key1} = "value1";
1360 $db->{key2} = "value2";
1361 print "key1: " . $db->{key1} . "\n";
1362 print "key2: " . $db->{key2} . "\n";
1368 return Compress::Zlib::memGzip( $_[0] ) ;
1371 return Compress::Zlib::memGunzip( $_[0] ) ;
1374 B<Note:> Filtering of keys only applies to hashes. Array "keys" are
1375 actually numerical index numbers, and are not filtered.
1377 =head1 ERROR HANDLING
1379 Most DBM::Deep methods return a true value for success, and call die() on
1380 failure. You can wrap calls in an eval block to catch the die.
1382 my $db = DBM::Deep->new( "foo.db" ); # create hash
1383 eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
1385 print $@; # prints error message
1387 =head1 LARGEFILE SUPPORT
1389 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
1390 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
1391 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
1392 by specifying the 'pack_size' parameter when constructing the file.
1395 filename => $filename,
1396 pack_size => 'large',
1399 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
1400 instead of 32-bit longs. After setting these values your DB files have a
1401 theoretical maximum size of 16 XB (exabytes).
1403 You can also use C<pack_size =E<gt> 'small'> in order to use 16-bit file
1406 B<Note:> Changing these values will B<NOT> work for existing database files.
1407 Only change this for new files. Once the value has been set, it is stored in
1408 the file's header and cannot be changed for the life of the file. These
1409 parameters are per-file, meaning you can access 32-bit and 64-bit files, as
1412 B<Note:> We have not personally tested files larger than 2 GB -- all my
1413 systems have only a 32-bit Perl. However, I have received user reports that
1414 this does indeed work!
1416 =head1 LOW-LEVEL ACCESS
1418 If you require low-level access to the underlying filehandle that DBM::Deep uses,
1419 you can call the C<_fh()> method, which returns the handle:
1421 my $fh = $db->_fh();
1423 This method can be called on the root level of the datbase, or any child
1424 hashes or arrays. All levels share a I<root> structure, which contains things
1425 like the filehandle, a reference counter, and all the options specified
1426 when you created the object. You can get access to this file object by
1427 calling the C<_storage()> method.
1429 my $file_obj = $db->_storage();
1431 This is useful for changing options after the object has already been created,
1432 such as enabling/disabling locking. You can also store your own temporary user
1433 data in this structure (be wary of name collision), which is then accessible from
1434 any child hash or array.
1436 =head1 CUSTOM DIGEST ALGORITHM
1438 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
1439 keys. However you can override this, and use another algorithm (such as SHA-256)
1440 or even write your own. But please note that DBM::Deep currently expects zero
1441 collisions, so your algorithm has to be I<perfect>, so to speak. Collision
1442 detection may be introduced in a later version.
1444 You can specify a custom digest algorithm by passing it into the parameter
1445 list for new(), passing a reference to a subroutine as the 'digest' parameter,
1446 and the length of the algorithm's hashes (in bytes) as the 'hash_size'
1447 parameter. Here is a working example that uses a 256-bit hash from the
1448 I<Digest::SHA256> module. Please see
1449 L<http://search.cpan.org/search?module=Digest::SHA256> for more information.
1454 my $context = Digest::SHA256::new(256);
1456 my $db = DBM::Deep->new(
1457 filename => "foo-sha.db",
1458 digest => \&my_digest,
1462 $db->{key1} = "value1";
1463 $db->{key2} = "value2";
1464 print "key1: " . $db->{key1} . "\n";
1465 print "key2: " . $db->{key2} . "\n";
1471 return substr( $context->hash($_[0]), 0, 32 );
1474 B<Note:> Your returned digest strings must be B<EXACTLY> the number
1475 of bytes you specify in the hash_size parameter (in this case 32).
1477 B<Note:> If you do choose to use a custom digest algorithm, you must set it
1478 every time you access this file. Otherwise, the default (MD5) will be used.
1480 =head1 CIRCULAR REFERENCES
1482 DBM::Deep has B<experimental> support for circular references. Meaning you
1483 can have a nested hash key or array element that points to a parent object.
1484 This relationship is stored in the DB file, and is preserved between sessions.
1487 my $db = DBM::Deep->new( "foo.db" );
1490 $db->{circle} = $db; # ref to self
1492 print $db->{foo} . "\n"; # prints "bar"
1493 print $db->{circle}->{foo} . "\n"; # prints "bar" again
1495 B<Note>: Passing the object to a function that recursively walks the
1496 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
1497 C<export()> methods) will result in an infinite loop. This will be fixed in
1502 New in 0.99_01 is the ability to audit your databases actions. By passing in
1503 audit_file (or audit_fh) to the constructor, all actions will be logged to
1504 that file. The format is one that is suitable for eval'ing against the
1505 database to replay the actions. Please see t/33_audit_trail.t for an example
1510 New in 0.99_01 is ACID transactions. Every DBM::Deep object is completely
1511 transaction-ready - it is not an option you have to turn on. Three new methods
1512 have been added to support them. They are:
1516 =item * begin_work()
1518 This starts a transaction.
1522 This applies the changes done within the transaction to the mainline and ends
1527 This discards the changes done within the transaction to the mainline and ends
1532 Transactions in DBM::Deep are done using the MVCC method, the same method used
1533 by the InnoDB MySQL table type.
1535 =head1 CAVEATS / ISSUES / BUGS
1537 This section describes all the known issues with DBM::Deep. It you have found
1538 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
1540 =head2 UNUSED SPACE RECOVERY
1542 One major caveat with DBM::Deep is that space occupied by existing keys and
1543 values is not recovered when they are deleted. Meaning if you keep deleting
1544 and adding new keys, your file will continuously grow. I am working on this,
1545 but in the meantime you can call the built-in C<optimize()> method from time to
1546 time (perhaps in a crontab or something) to recover all your unused space.
1548 $db->optimize(); # returns true on success
1550 This rebuilds the ENTIRE database into a new file, then moves it on top of
1551 the original. The new file will have no unused space, thus it will take up as
1552 little disk space as possible. Please note that this operation can take
1553 a long time for large files, and you need enough disk space to temporarily hold
1554 2 copies of your DB file. The temporary file is created in the same directory
1555 as the original, named with a ".tmp" extension, and is deleted when the
1556 operation completes. Oh, and if locking is enabled, the DB is automatically
1557 locked for the entire duration of the copy.
1559 B<WARNING:> Only call optimize() on the top-level node of the database, and
1560 make sure there are no child references lying around. DBM::Deep keeps a reference
1561 counter, and if it is greater than 1, optimize() will abort and return undef.
1565 (The reasons given assume a high level of Perl understanding, specifically of
1566 references. You can safely skip this section.)
1568 Currently, the only references supported are HASH and ARRAY. The other reference
1569 types (SCALAR, CODE, GLOB, and REF) cannot be supported for various reasons.
1575 These are things like filehandles and other sockets. They can't be supported
1576 because it's completely unclear how DBM::Deep should serialize them.
1578 =item * SCALAR / REF
1580 The discussion here refers to the following type of example:
1587 # In some other process ...
1589 my $val = ${ $db->{key1} };
1591 is( $val, 50, "What actually gets stored in the DB file?" );
1593 The problem is one of synchronization. When the variable being referred to
1594 changes value, the reference isn't notified. This means that the new value won't
1595 be stored in the datafile for other processes to read. There is no TIEREF.
1597 It is theoretically possible to store references to values already within a
1598 DBM::Deep object because everything already is synchronized, but the change to
1599 the internals would be quite large. Specifically, DBM::Deep would have to tie
1600 every single value that is stored. This would bloat the RAM footprint of
1601 DBM::Deep at least twofold (if not more) and be a significant performance drain,
1602 all to support a feature that has never been requested.
1606 L<Data::Dump::Streamer/> provides a mechanism for serializing coderefs,
1607 including saving off all closure state. However, just as for SCALAR and REF,
1608 that closure state may change without notifying the DBM::Deep object storing
1613 =head2 FILE CORRUPTION
1615 The current level of error handling in DBM::Deep is minimal. Files I<are> checked
1616 for a 32-bit signature when opened, but other corruption in files can cause
1617 segmentation faults. DBM::Deep may try to seek() past the end of a file, or get
1618 stuck in an infinite loop depending on the level of corruption. File write
1619 operations are not checked for failure (for speed), so if you happen to run
1620 out of disk space, DBM::Deep will probably fail in a bad way. These things will
1621 be addressed in a later version of DBM::Deep.
1625 Beware of using DBM::Deep files over NFS. DBM::Deep uses flock(), which works
1626 well on local filesystems, but will NOT protect you from file corruption over
1627 NFS. I've heard about setting up your NFS server with a locking daemon, then
1628 using lockf() to lock your files, but your mileage may vary there as well.
1629 From what I understand, there is no real way to do it. However, if you need
1630 access to the underlying filehandle in DBM::Deep for using some other kind of
1631 locking scheme like lockf(), see the L<LOW-LEVEL ACCESS> section above.
1633 =head2 COPYING OBJECTS
1635 Beware of copying tied objects in Perl. Very strange things can happen.
1636 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
1637 returns a new, blessed, tied hash or array to the same level in the DB.
1639 my $copy = $db->clone();
1641 B<Note>: Since clone() here is cloning the object, not the database location, any
1642 modifications to either $db or $copy will be visible to both.
1646 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
1647 These functions cause every element in the array to move, which can be murder
1648 on DBM::Deep, as every element has to be fetched from disk, then stored again in
1649 a different location. This will be addressed in the forthcoming version 1.00.
1651 =head2 WRITEONLY FILES
1653 If you pass in a filehandle to new(), you may have opened it in either a readonly or
1654 writeonly mode. STORE will verify that the filehandle is writable. However, there
1655 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
1656 filehandle isn't readable, it's not clear what will happen. So, don't do that.
1658 =head1 CODE COVERAGE
1660 B<Devel::Cover> is used to test the code coverage of the tests. Below is the
1661 B<Devel::Cover> report on this distribution's test suite.
1663 ---------------------------- ------ ------ ------ ------ ------ ------ ------
1664 File stmt bran cond sub pod time total
1665 ---------------------------- ------ ------ ------ ------ ------ ------ ------
1666 blib/lib/DBM/Deep.pm 96.2 89.0 75.0 95.8 89.5 36.0 92.9
1667 blib/lib/DBM/Deep/Array.pm 96.1 88.3 100.0 96.4 100.0 15.9 94.7
1668 blib/lib/DBM/Deep/Engine.pm 96.6 86.6 89.5 100.0 0.0 20.0 91.0
1669 blib/lib/DBM/Deep/File.pm 99.4 88.3 55.6 100.0 0.0 19.6 89.5
1670 blib/lib/DBM/Deep/Hash.pm 98.5 83.3 100.0 100.0 100.0 8.5 96.3
1671 Total 96.9 87.4 81.2 98.0 38.5 100.0 92.1
1672 ---------------------------- ------ ------ ------ ------ ------ ------ ------
1674 =head1 MORE INFORMATION
1676 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
1677 or send email to L<DBM-Deep@googlegroups.com>. You can also visit #dbm-deep on
1680 The source code repository is at L<http://svn.perl.org/modules/DBM-Deep>
1684 Rob Kinyon, L<rkinyon@cpan.org>
1686 Originally written by Joseph Huckaby, L<jhuckaby@cpan.org>
1688 Special thanks to Adam Sah and Rich Gaushell! You know why :-)
1692 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
1693 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
1697 Copyright (c) 2002-2006 Joseph Huckaby. All Rights Reserved.
1698 This is free software, you may use it and distribute it under the
1699 same terms as Perl itself.