lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.982);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #_precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { SIG_HASH   }
 104 sub TYPE_ARRAY  () { SIG_ARRAY  }
 105
 106 sub _get_args {
 107     my $proto = shift;
 108
 109     my $args;
 110     if (scalar(@_) > 1) {
 111         if ( @_ % 2 ) {
 112             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 113         }
 114         $args = {@_};
 115     }
 116         elsif ( ref $_[0] ) {
 117         unless ( eval { local $SIG{'__DIE__'}; %{$_[0]} || 1 } ) {
 118             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 119         }
 120         $args = $_[0];
 121     }
 122         else {
 123         $args = { file => shift };
 124     }
 125
 126     return $args;
 127 }
 128
 129 sub new {
 130         ##
 131         # Class constructor method for Perl OO interface.
 132         # Calls tie() and returns blessed reference to tied hash or array,
 133         # providing a hybrid OO/tie interface.
 134         ##
 135         my $class = shift;
 136         my $args = $class->_get_args( @_ );
 137
 138         ##
 139         # Check if we want a tied hash or array.
 140         ##
 141         my $self;
 142         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 143         $class = 'DBM::Deep::Array';
 144         require DBM::Deep::Array;
 145                 tie @$self, $class, %$args;
 146         }
 147         else {
 148         $class = 'DBM::Deep::Hash';
 149         require DBM::Deep::Hash;
 150                 tie %$self, $class, %$args;
 151         }
 152
 153         return bless $self, $class;
 154 }
 155
 156 sub _init {
 157     ##
 158     # Setup $self and bless into this class.
 159     ##
 160     my $class = shift;
 161     my $args = shift;
 162
 163     # These are the defaults to be optionally overridden below
 164     my $self = bless {
 165         type => TYPE_HASH,
 166         base_offset => length(SIG_FILE),
 167     }, $class;
 168
 169     foreach my $param ( keys %$self ) {
 170         next unless exists $args->{$param};
 171         $self->{$param} = delete $args->{$param}
 172     }
 173
 174     # locking implicitly enables autoflush
 175     if ($args->{locking}) { $args->{autoflush} = 1; }
 176
 177     $self->{root} = exists $args->{root}
 178         ? $args->{root}
 179         : DBM::Deep::_::Root->new( $args );
 180
 181     if (!defined($self->_fh)) { $self->_open(); }
 182
 183     return $self;
 184 }
 185
 186 sub TIEHASH {
 187     shift;
 188     require DBM::Deep::Hash;
 189     return DBM::Deep::Hash->TIEHASH( @_ );
 190 }
 191
 192 sub TIEARRAY {
 193     shift;
 194     require DBM::Deep::Array;
 195     return DBM::Deep::Array->TIEARRAY( @_ );
 196 }
 197
 198 #XXX Unneeded now ...
 199 #sub DESTROY {
 200 #}
 201
 202 sub _open {
 203         ##
 204         # Open a fh to the database, create if nonexistent.
 205         # Make sure file signature matches DBM::Deep spec.
 206         ##
 207     my $self = $_[0]->_get_self;
 208
 209         if (defined($self->_fh)) { $self->_close(); }
 210
 211     my $flags = O_RDWR | O_CREAT | O_BINARY;
 212
 213     my $fh;
 214     sysopen( $fh, $self->_root->{file}, $flags )
 215                 or $self->_throw_error( "Cannot sysopen file: " . $self->_root->{file} . ": $!" );
 216
 217     $self->_root->{fh} = $fh;
 218
 219     if ($self->_root->{autoflush}) {
 220         my $old = select $fh;
 221         $|=1;
 222         select $old;
 223     }
 224
 225     seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 226
 227     my $signature;
 228     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 229
 230     ##
 231     # File is empty -- write signature and master index
 232     ##
 233     if (!$bytes_read) {
 234         seek($fh, 0 + $self->_root->{file_offset}, SEEK_SET);
 235         print( $fh SIG_FILE);
 236         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
 237
 238         my $plain_key = "[base]";
 239         print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 240
 241         # Flush the filehandle
 242         my $old_fh = select $fh;
 243         my $old_af = $|; $| = 1; $| = $old_af;
 244         select $old_fh;
 245
 246         my @stats = stat($fh);
 247         $self->_root->{inode} = $stats[1];
 248         $self->_root->{end} = $stats[7];
 249
 250         return 1;
 251     }
 252
 253     ##
 254     # Check signature was valid
 255     ##
 256     unless ($signature eq SIG_FILE) {
 257         $self->_close();
 258         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 259     }
 260
 261         my @stats = stat($fh);
 262         $self->_root->{inode} = $stats[1];
 263     $self->_root->{end} = $stats[7];
 264
 265     ##
 266     # Get our type from master index signature
 267     ##
 268     my $tag = $self->_load_tag($self->_base_offset);
 269
 270 #XXX We probably also want to store the hash algorithm name and not assume anything
 271 #XXX The cool thing would be to allow a different hashing algorithm at every level
 272
 273     if (!$tag) {
 274         return $self->_throw_error("Corrupted file, no master index record");
 275     }
 276     if ($self->{type} ne $tag->{signature}) {
 277         return $self->_throw_error("File type mismatch");
 278     }
 279
 280     return 1;
 281 }
 282
 283 sub _close {
 284         ##
 285         # Close database fh
 286         ##
 287     my $self = $_[0]->_get_self;
 288     close $self->_root->{fh} if $self->_root->{fh};
 289     $self->_root->{fh} = undef;
 290 }
 291
 292 sub _create_tag {
 293         ##
 294         # Given offset, signature and content, create tag and write to disk
 295         ##
 296         my ($self, $offset, $sig, $content) = @_;
 297         my $size = length($content);
 298
 299     my $fh = $self->_fh;
 300
 301         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 302         print( $fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 303
 304         if ($offset == $self->_root->{end}) {
 305                 $self->_root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 306         }
 307
 308         return {
 309                 signature => $sig,
 310                 size => $size,
 311                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 312                 content => $content
 313         };
 314 }
 315
 316 sub _load_tag {
 317         ##
 318         # Given offset, load single tag and return signature, size and data
 319         ##
 320         my $self = shift;
 321         my $offset = shift;
 322
 323     my $fh = $self->_fh;
 324
 325         seek($fh, $offset + $self->_root->{file_offset}, SEEK_SET);
 326         if (eof $fh) { return undef; }
 327
 328     my $b;
 329     read( $fh, $b, SIG_SIZE + $DATA_LENGTH_SIZE );
 330     my ($sig, $size) = unpack( "A $DATA_LENGTH_PACK", $b );
 331
 332         my $buffer;
 333         read( $fh, $buffer, $size);
 334
 335         return {
 336                 signature => $sig,
 337                 size => $size,
 338                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 339                 content => $buffer
 340         };
 341 }
 342
 343 sub _index_lookup {
 344         ##
 345         # Given index tag, lookup single entry in index and return .
 346         ##
 347         my $self = shift;
 348         my ($tag, $index) = @_;
 349
 350         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 351         if (!$location) { return; }
 352
 353         return $self->_load_tag( $location );
 354 }
 355
 356 sub _add_bucket {
 357         ##
 358         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 359         # plain (undigested) key and value.
 360         ##
 361         my $self = shift;
 362         my ($tag, $md5, $plain_key, $value) = @_;
 363         my $keys = $tag->{content};
 364         my $location = 0;
 365         my $result = 2;
 366
 367     my $root = $self->_root;
 368
 369     my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ) };
 370         my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 371
 372     my $fh = $self->_fh;
 373
 374         ##
 375         # Iterate through buckets, seeing if this is a new entry or a replace.
 376         ##
 377         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 378                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 379                 if (!$subloc) {
 380                         ##
 381                         # Found empty bucket (end of list).  Populate and exit loop.
 382                         ##
 383                         $result = 2;
 384
 385             $location = $internal_ref
 386                 ? $value->_base_offset
 387                 : $root->{end};
 388
 389                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 390                         print( $fh $md5 . pack($LONG_PACK, $location) );
 391                         last;
 392                 }
 393
 394                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 395                 if ($md5 eq $key) {
 396                         ##
 397                         # Found existing bucket with same key.  Replace with new value.
 398                         ##
 399                         $result = 1;
 400
 401                         if ($internal_ref) {
 402                                 $location = $value->_base_offset;
 403                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 404                                 print( $fh $md5 . pack($LONG_PACK, $location) );
 405                 return $result;
 406                         }
 407
 408             seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 409             my $size;
 410             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 411
 412             ##
 413             # If value is a hash, array, or raw value with equal or less size, we can
 414             # reuse the same content area of the database.  Otherwise, we have to create
 415             # a new content area at the EOF.
 416             ##
 417             my $actual_length;
 418             my $r = Scalar::Util::reftype( $value ) || '';
 419             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 420                 $actual_length = $INDEX_SIZE;
 421
 422                 # if autobless is enabled, must also take into consideration
 423                 # the class name, as it is stored along with key/value.
 424                 if ( $root->{autobless} ) {
 425                     my $value_class = Scalar::Util::blessed($value);
 426                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 427                         $actual_length += length($value_class);
 428                     }
 429                 }
 430             }
 431             else { $actual_length = length($value); }
 432
 433             if ($actual_length <= $size) {
 434                 $location = $subloc;
 435             }
 436             else {
 437                 $location = $root->{end};
 438                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE + $root->{file_offset}, SEEK_SET);
 439                 print( $fh pack($LONG_PACK, $location) );
 440             }
 441
 442                         last;
 443                 }
 444         }
 445
 446         ##
 447         # If this is an internal reference, return now.
 448         # No need to write value or plain key
 449         ##
 450         if ($internal_ref) {
 451         return $result;
 452     }
 453
 454         ##
 455         # If bucket didn't fit into list, split into a new index level
 456         ##
 457         if (!$location) {
 458                 seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 459                 print( $fh pack($LONG_PACK, $root->{end}) );
 460
 461                 my $index_tag = $self->_create_tag($root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 462                 my @offsets = ();
 463
 464                 $keys .= $md5 . pack($LONG_PACK, 0);
 465
 466                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 467                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 468                         if ($key) {
 469                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 470                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 471
 472                                 if ($offsets[$num]) {
 473                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 474                                         seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 475                                         my $subkeys;
 476                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 477
 478                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 479                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 480                                                 if (!$subloc) {
 481                                                         seek($fh, $offset + ($k * $BUCKET_SIZE) + $root->{file_offset}, SEEK_SET);
 482                                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 483                                                         last;
 484                                                 }
 485                                         } # k loop
 486                                 }
 487                                 else {
 488                                         $offsets[$num] = $root->{end};
 489                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE) + $root->{file_offset}, SEEK_SET);
 490                                         print( $fh pack($LONG_PACK, $root->{end}) );
 491
 492                                         my $blist_tag = $self->_create_tag($root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 493
 494                                         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 495                                         print( $fh $key . pack($LONG_PACK, $old_subloc || $root->{end}) );
 496                                 }
 497                         } # key is real
 498                 } # i loop
 499
 500                 $location ||= $root->{end};
 501         } # re-index bucket list
 502
 503         ##
 504         # Seek to content area and store signature, value and plaintext key
 505         ##
 506         if ($location) {
 507                 my $content_length;
 508                 seek($fh, $location + $root->{file_offset}, SEEK_SET);
 509
 510                 ##
 511                 # Write signature based on content type, set content length and write actual value.
 512                 ##
 513         my $r = Scalar::Util::reftype($value) || '';
 514                 if ($r eq 'HASH') {
 515                         print( $fh TYPE_HASH );
 516                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 517                         $content_length = $INDEX_SIZE;
 518                 }
 519                 elsif ($r eq 'ARRAY') {
 520                         print( $fh TYPE_ARRAY );
 521                         print( $fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 522                         $content_length = $INDEX_SIZE;
 523                 }
 524                 elsif (!defined($value)) {
 525                         print( $fh SIG_NULL );
 526                         print( $fh pack($DATA_LENGTH_PACK, 0) );
 527                         $content_length = 0;
 528                 }
 529                 else {
 530                         print( $fh SIG_DATA );
 531                         print( $fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 532                         $content_length = length($value);
 533                 }
 534
 535                 ##
 536                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 537                 ##
 538                 print( $fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 539
 540                 ##
 541                 # If value is blessed, preserve class name
 542                 ##
 543                 if ( $root->{autobless} ) {
 544             my $value_class = Scalar::Util::blessed($value);
 545             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 546                 ##
 547                 # Blessed ref -- will restore later
 548                 ##
 549                 print( $fh chr(1) );
 550                 print( $fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 551                 $content_length += 1;
 552                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 553             }
 554             else {
 555                 print( $fh chr(0) );
 556                 $content_length += 1;
 557             }
 558         }
 559
 560                 ##
 561                 # If this is a new content area, advance EOF counter
 562                 ##
 563                 if ($location == $root->{end}) {
 564                         $root->{end} += SIG_SIZE;
 565                         $root->{end} += $DATA_LENGTH_SIZE + $content_length;
 566                         $root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 567                 }
 568
 569                 ##
 570                 # If content is a hash or array, create new child DBM::Deep object and
 571                 # pass each key or element to it.
 572                 ##
 573                 if ($r eq 'HASH') {
 574             my %x = %$value;
 575             tie %$value, 'DBM::Deep', {
 576                                 type => TYPE_HASH,
 577                                 base_offset => $location,
 578                                 root => $root,
 579                         };
 580             %$value = %x;
 581                 }
 582                 elsif ($r eq 'ARRAY') {
 583             my @x = @$value;
 584             tie @$value, 'DBM::Deep', {
 585                                 type => TYPE_ARRAY,
 586                                 base_offset => $location,
 587                                 root => $root,
 588                         };
 589             @$value = @x;
 590                 }
 591
 592                 return $result;
 593         }
 594
 595         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 596 }
 597
 598 sub _get_bucket_value {
 599         ##
 600         # Fetch single value given tag and MD5 digested key.
 601         ##
 602         my $self = shift;
 603         my ($tag, $md5) = @_;
 604         my $keys = $tag->{content};
 605
 606     my $fh = $self->_fh;
 607
 608         ##
 609         # Iterate through buckets, looking for a key match
 610         ##
 611     BUCKET:
 612         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 613                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 614                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 615
 616                 if (!$subloc) {
 617                         ##
 618                         # Hit end of list, no match
 619                         ##
 620                         return;
 621                 }
 622
 623         if ( $md5 ne $key ) {
 624             next BUCKET;
 625         }
 626
 627         ##
 628         # Found match -- seek to offset and read signature
 629         ##
 630         my $signature;
 631         seek($fh, $subloc + $self->_root->{file_offset}, SEEK_SET);
 632         read( $fh, $signature, SIG_SIZE);
 633
 634         ##
 635         # If value is a hash or array, return new DBM::Deep object with correct offset
 636         ##
 637         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 638             my $obj = DBM::Deep->new(
 639                 type => $signature,
 640                 base_offset => $subloc,
 641                 root => $self->_root
 642             );
 643
 644             if ($self->_root->{autobless}) {
 645                 ##
 646                 # Skip over value and plain key to see if object needs
 647                 # to be re-blessed
 648                 ##
 649                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 650
 651                 my $size;
 652                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 653                 if ($size) { seek($fh, $size, SEEK_CUR); }
 654
 655                 my $bless_bit;
 656                 read( $fh, $bless_bit, 1);
 657                 if (ord($bless_bit)) {
 658                     ##
 659                     # Yes, object needs to be re-blessed
 660                     ##
 661                     my $class_name;
 662                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 663                     if ($size) { read( $fh, $class_name, $size); }
 664                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 665                 }
 666             }
 667
 668             return $obj;
 669         }
 670
 671         ##
 672         # Otherwise return actual value
 673         ##
 674         elsif ($signature eq SIG_DATA) {
 675             my $size;
 676             my $value = '';
 677             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 678             if ($size) { read( $fh, $value, $size); }
 679             return $value;
 680         }
 681
 682         ##
 683         # Key exists, but content is null
 684         ##
 685         else { return; }
 686         } # i loop
 687
 688         return;
 689 }
 690
 691 sub _delete_bucket {
 692         ##
 693         # Delete single key/value pair given tag and MD5 digested key.
 694         ##
 695         my $self = shift;
 696         my ($tag, $md5) = @_;
 697         my $keys = $tag->{content};
 698
 699     my $fh = $self->_fh;
 700
 701         ##
 702         # Iterate through buckets, looking for a key match
 703         ##
 704     BUCKET:
 705         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 706                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 707                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 708
 709                 if (!$subloc) {
 710                         ##
 711                         # Hit end of list, no match
 712                         ##
 713                         return;
 714                 }
 715
 716         if ( $md5 ne $key ) {
 717             next BUCKET;
 718         }
 719
 720         ##
 721         # Matched key -- delete bucket and return
 722         ##
 723         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $self->_root->{file_offset}, SEEK_SET);
 724         print( $fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 725         print( $fh chr(0) x $BUCKET_SIZE );
 726
 727         return 1;
 728         } # i loop
 729
 730         return;
 731 }
 732
 733 sub _bucket_exists {
 734         ##
 735         # Check existence of single key given tag and MD5 digested key.
 736         ##
 737         my $self = shift;
 738         my ($tag, $md5) = @_;
 739         my $keys = $tag->{content};
 740
 741         ##
 742         # Iterate through buckets, looking for a key match
 743         ##
 744     BUCKET:
 745         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 746                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 747                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 748
 749                 if (!$subloc) {
 750                         ##
 751                         # Hit end of list, no match
 752                         ##
 753                         return;
 754                 }
 755
 756         if ( $md5 ne $key ) {
 757             next BUCKET;
 758         }
 759
 760         ##
 761         # Matched key -- return true
 762         ##
 763         return 1;
 764         } # i loop
 765
 766         return;
 767 }
 768
 769 sub _find_bucket_list {
 770         ##
 771         # Locate offset for bucket list, given digested key
 772         ##
 773         my $self = shift;
 774         my $md5 = shift;
 775
 776         ##
 777         # Locate offset for bucket list using digest index system
 778         ##
 779         my $ch = 0;
 780         my $tag = $self->_load_tag($self->_base_offset);
 781         if (!$tag) { return; }
 782
 783         while ($tag->{signature} ne SIG_BLIST) {
 784                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 785                 if (!$tag) { return; }
 786                 $ch++;
 787         }
 788
 789         return $tag;
 790 }
 791
 792 sub _traverse_index {
 793         ##
 794         # Scan index and recursively step into deeper levels, looking for next key.
 795         ##
 796     my ($self, $offset, $ch, $force_return_next) = @_;
 797     $force_return_next = undef unless $force_return_next;
 798
 799         my $tag = $self->_load_tag( $offset );
 800
 801     my $fh = $self->_fh;
 802
 803         if ($tag->{signature} ne SIG_BLIST) {
 804                 my $content = $tag->{content};
 805                 my $start;
 806                 if ($self->{return_next}) { $start = 0; }
 807                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 808
 809                 for (my $index = $start; $index < 256; $index++) {
 810                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 811                         if ($subloc) {
 812                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 813                                 if (defined($result)) { return $result; }
 814                         }
 815                 } # index loop
 816
 817                 $self->{return_next} = 1;
 818         } # tag is an index
 819
 820         elsif ($tag->{signature} eq SIG_BLIST) {
 821                 my $keys = $tag->{content};
 822                 if ($force_return_next) { $self->{return_next} = 1; }
 823
 824                 ##
 825                 # Iterate through buckets, looking for a key match
 826                 ##
 827                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 828                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 829                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 830
 831                         if (!$subloc) {
 832                                 ##
 833                                 # End of bucket list -- return to outer loop
 834                                 ##
 835                                 $self->{return_next} = 1;
 836                                 last;
 837                         }
 838                         elsif ($key eq $self->{prev_md5}) {
 839                                 ##
 840                                 # Located previous key -- return next one found
 841                                 ##
 842                                 $self->{return_next} = 1;
 843                                 next;
 844                         }
 845                         elsif ($self->{return_next}) {
 846                                 ##
 847                                 # Seek to bucket location and skip over signature
 848                                 ##
 849                                 seek($fh, $subloc + SIG_SIZE + $self->_root->{file_offset}, SEEK_SET);
 850
 851                                 ##
 852                                 # Skip over value to get to plain key
 853                                 ##
 854                                 my $size;
 855                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 856                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 857
 858                                 ##
 859                                 # Read in plain key and return as scalar
 860                                 ##
 861                                 my $plain_key;
 862                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 863                                 if ($size) { read( $fh, $plain_key, $size); }
 864
 865                                 return $plain_key;
 866                         }
 867                 } # bucket loop
 868
 869                 $self->{return_next} = 1;
 870         } # tag is a bucket list
 871
 872         return;
 873 }
 874
 875 sub _get_next_key {
 876         ##
 877         # Locate next key, given digested previous one
 878         ##
 879     my $self = $_[0]->_get_self;
 880
 881         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 882         $self->{return_next} = 0;
 883
 884         ##
 885         # If the previous key was not specifed, start at the top and
 886         # return the first one found.
 887         ##
 888         if (!$self->{prev_md5}) {
 889                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 890                 $self->{return_next} = 1;
 891         }
 892
 893         return $self->_traverse_index( $self->_base_offset, 0 );
 894 }
 895
 896 sub lock {
 897         ##
 898         # If db locking is set, flock() the db file.  If called multiple
 899         # times before unlock(), then the same number of unlocks() must
 900         # be called before the lock is released.
 901         ##
 902     my $self = $_[0]->_get_self;
 903         my $type = $_[1];
 904     $type = LOCK_EX unless defined $type;
 905
 906         if (!defined($self->_fh)) { return; }
 907
 908         if ($self->_root->{locking}) {
 909                 if (!$self->_root->{locked}) {
 910                         flock($self->_fh, $type);
 911
 912                         # refresh end counter in case file has changed size
 913                         my @stats = stat($self->_root->{file});
 914                         $self->_root->{end} = $stats[7];
 915
 916                         # double-check file inode, in case another process
 917                         # has optimize()d our file while we were waiting.
 918                         if ($stats[1] != $self->_root->{inode}) {
 919                                 $self->_open(); # re-open
 920                                 flock($self->_fh, $type); # re-lock
 921                                 $self->_root->{end} = (stat($self->_fh))[7]; # re-end
 922                         }
 923                 }
 924                 $self->_root->{locked}++;
 925
 926         return 1;
 927         }
 928
 929     return;
 930 }
 931
 932 sub unlock {
 933         ##
 934         # If db locking is set, unlock the db file.  See note in lock()
 935         # regarding calling lock() multiple times.
 936         ##
 937     my $self = $_[0]->_get_self;
 938
 939         if (!defined($self->_fh)) { return; }
 940
 941         if ($self->_root->{locking} && $self->_root->{locked} > 0) {
 942                 $self->_root->{locked}--;
 943                 if (!$self->_root->{locked}) { flock($self->_fh, LOCK_UN); }
 944
 945         return 1;
 946         }
 947
 948     return;
 949 }
 950
 951 sub _copy_value {
 952     my $self = shift->_get_self;
 953     my ($spot, $value) = @_;
 954
 955     if ( !ref $value ) {
 956         ${$spot} = $value;
 957     }
 958     elsif ( eval { local $SIG{__DIE__}; $value->isa( 'DBM::Deep' ) } ) {
 959         my $type = $value->_type;
 960         ${$spot} = $type eq TYPE_HASH ? {} : [];
 961         $value->_copy_node( ${$spot} );
 962     }
 963     else {
 964         my $r = Scalar::Util::reftype( $value );
 965         my $c = Scalar::Util::blessed( $value );
 966         if ( $r eq 'ARRAY' ) {
 967             ${$spot} = [ @{$value} ];
 968         }
 969         else {
 970             ${$spot} = { %{$value} };
 971         }
 972         ${$spot} = bless ${$spot}, $c
 973             if defined $c;
 974     }
 975
 976     return 1;
 977 }
 978
 979 sub _copy_node {
 980         ##
 981         # Copy single level of keys or elements to new DB handle.
 982         # Recurse for nested structures
 983         ##
 984     my $self = shift->_get_self;
 985         my ($db_temp) = @_;
 986
 987         if ($self->_type eq TYPE_HASH) {
 988                 my $key = $self->first_key();
 989                 while ($key) {
 990                         my $value = $self->get($key);
 991             $self->_copy_value( \$db_temp->{$key}, $value );
 992                         $key = $self->next_key($key);
 993                 }
 994         }
 995         else {
 996                 my $length = $self->length();
 997                 for (my $index = 0; $index < $length; $index++) {
 998                         my $value = $self->get($index);
 999             $self->_copy_value( \$db_temp->[$index], $value );
1000                 }
1001         }
1002
1003     return 1;
1004 }
1005
1006 sub export {
1007         ##
1008         # Recursively export into standard Perl hashes and arrays.
1009         ##
1010     my $self = $_[0]->_get_self;
1011
1012         my $temp;
1013         if ($self->_type eq TYPE_HASH) { $temp = {}; }
1014         elsif ($self->_type eq TYPE_ARRAY) { $temp = []; }
1015
1016         $self->lock();
1017         $self->_copy_node( $temp );
1018         $self->unlock();
1019
1020         return $temp;
1021 }
1022
1023 sub import {
1024         ##
1025         # Recursively import Perl hash/array structure
1026         ##
1027     #XXX This use of ref() seems to be ok
1028         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1029
1030     my $self = $_[0]->_get_self;
1031         my $struct = $_[1];
1032
1033     #XXX This use of ref() seems to be ok
1034         if (!ref($struct)) {
1035                 ##
1036                 # struct is not a reference, so just import based on our type
1037                 ##
1038                 shift @_;
1039
1040                 if ($self->_type eq TYPE_HASH) { $struct = {@_}; }
1041                 elsif ($self->_type eq TYPE_ARRAY) { $struct = [@_]; }
1042         }
1043
1044     my $r = Scalar::Util::reftype($struct) || '';
1045         if ($r eq "HASH" && $self->_type eq TYPE_HASH) {
1046                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1047         }
1048         elsif ($r eq "ARRAY" && $self->_type eq TYPE_ARRAY) {
1049                 $self->push( @$struct );
1050         }
1051         else {
1052                 return $self->_throw_error("Cannot import: type mismatch");
1053         }
1054
1055         return 1;
1056 }
1057
1058 sub optimize {
1059         ##
1060         # Rebuild entire database into new file, then move
1061         # it back on top of original.
1062         ##
1063     my $self = $_[0]->_get_self;
1064
1065 #XXX Need to create a new test for this
1066 #       if ($self->_root->{links} > 1) {
1067 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1068 #       }
1069
1070         my $db_temp = DBM::Deep->new(
1071                 file => $self->_root->{file} . '.tmp',
1072                 type => $self->_type
1073         );
1074         if (!$db_temp) {
1075                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1076         }
1077
1078         $self->lock();
1079         $self->_copy_node( $db_temp );
1080         undef $db_temp;
1081
1082         ##
1083         # Attempt to copy user, group and permissions over to new file
1084         ##
1085         my @stats = stat($self->_fh);
1086         my $perms = $stats[2] & 07777;
1087         my $uid = $stats[4];
1088         my $gid = $stats[5];
1089         chown( $uid, $gid, $self->_root->{file} . '.tmp' );
1090         chmod( $perms, $self->_root->{file} . '.tmp' );
1091
1092     # q.v. perlport for more information on this variable
1093     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1094                 ##
1095                 # Potential race condition when optmizing on Win32 with locking.
1096                 # The Windows filesystem requires that the filehandle be closed
1097                 # before it is overwritten with rename().  This could be redone
1098                 # with a soft copy.
1099                 ##
1100                 $self->unlock();
1101                 $self->_close();
1102         }
1103
1104         if (!rename $self->_root->{file} . '.tmp', $self->_root->{file}) {
1105                 unlink $self->_root->{file} . '.tmp';
1106                 $self->unlock();
1107                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1108         }
1109
1110         $self->unlock();
1111         $self->_close();
1112         $self->_open();
1113
1114         return 1;
1115 }
1116
1117 sub clone {
1118         ##
1119         # Make copy of object and return
1120         ##
1121     my $self = $_[0]->_get_self;
1122
1123         return DBM::Deep->new(
1124                 type => $self->_type,
1125                 base_offset => $self->_base_offset,
1126                 root => $self->_root
1127         );
1128 }
1129
1130 {
1131     my %is_legal_filter = map {
1132         $_ => ~~1,
1133     } qw(
1134         store_key store_value
1135         fetch_key fetch_value
1136     );
1137
1138     sub set_filter {
1139         ##
1140         # Setup filter function for storing or fetching the key or value
1141         ##
1142         my $self = $_[0]->_get_self;
1143         my $type = lc $_[1];
1144         my $func = $_[2] ? $_[2] : undef;
1145
1146         if ( $is_legal_filter{$type} ) {
1147             $self->_root->{"filter_$type"} = $func;
1148             return 1;
1149         }
1150
1151         return;
1152     }
1153 }
1154
1155 ##
1156 # Accessor methods
1157 ##
1158
1159 sub _root {
1160         ##
1161         # Get access to the root structure
1162         ##
1163     my $self = $_[0]->_get_self;
1164         return $self->{root};
1165 }
1166
1167 sub _fh {
1168         ##
1169         # Get access to the raw fh
1170         ##
1171     #XXX It will be useful, though, when we split out HASH and ARRAY
1172     my $self = $_[0]->_get_self;
1173         return $self->_root->{fh};
1174 }
1175
1176 sub _type {
1177         ##
1178         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1179         ##
1180     my $self = $_[0]->_get_self;
1181         return $self->{type};
1182 }
1183
1184 sub _base_offset {
1185         ##
1186         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1187         ##
1188     my $self = $_[0]->_get_self;
1189         return $self->{base_offset};
1190 }
1191
1192 sub error {
1193         ##
1194         # Get last error string, or undef if no error
1195         ##
1196         return $_[0]
1197         ? ( $_[0]->_get_self->{root}->{error} or undef )
1198         : $@;
1199 }
1200
1201 ##
1202 # Utility methods
1203 ##
1204
1205 sub _throw_error {
1206         ##
1207         # Store error string in self
1208         ##
1209         my $error_text = $_[1];
1210
1211     if ( Scalar::Util::blessed $_[0] ) {
1212         my $self = $_[0]->_get_self;
1213         $self->_root->{error} = $error_text;
1214
1215         unless ($self->_root->{debug}) {
1216             die "DBM::Deep: $error_text\n";
1217         }
1218
1219         warn "DBM::Deep: $error_text\n";
1220         return;
1221     }
1222     else {
1223         die "DBM::Deep: $error_text\n";
1224     }
1225 }
1226
1227 sub clear_error {
1228         ##
1229         # Clear error state
1230         ##
1231     my $self = $_[0]->_get_self;
1232
1233         undef $self->_root->{error};
1234 }
1235
1236 sub _precalc_sizes {
1237         ##
1238         # Precalculate index, bucket and bucket list sizes
1239         ##
1240
1241     #XXX I don't like this ...
1242     set_pack() unless defined $LONG_SIZE;
1243
1244         $INDEX_SIZE = 256 * $LONG_SIZE;
1245         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1246         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1247 }
1248
1249 sub set_pack {
1250         ##
1251         # Set pack/unpack modes (see file header for more)
1252         ##
1253     my ($long_s, $long_p, $data_s, $data_p) = @_;
1254
1255     $LONG_SIZE = $long_s ? $long_s : 4;
1256     $LONG_PACK = $long_p ? $long_p : 'N';
1257
1258     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1259     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1260
1261         _precalc_sizes();
1262 }
1263
1264 sub set_digest {
1265         ##
1266         # Set key digest function (default is MD5)
1267         ##
1268     my ($digest_func, $hash_size) = @_;
1269
1270     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1271     $HASH_SIZE = $hash_size ? $hash_size : 16;
1272
1273         _precalc_sizes();
1274 }
1275
1276 sub _is_writable {
1277     my $fh = shift;
1278     (O_WRONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1279 }
1280
1281 #sub _is_readable {
1282 #    my $fh = shift;
1283 #    (O_RDONLY | O_RDWR) & fcntl( $fh, F_GETFL, my $slush = 0);
1284 #}
1285
1286 ##
1287 # tie() methods (hashes and arrays)
1288 ##
1289
1290 sub STORE {
1291         ##
1292         # Store single hash key/value or array element in database.
1293         ##
1294     my $self = $_[0]->_get_self;
1295         my $key = $_[1];
1296
1297     # User may be storing a hash, in which case we do not want it run
1298     # through the filtering system
1299         my $value = ($self->_root->{filter_store_value} && !ref($_[2]))
1300         ? $self->_root->{filter_store_value}->($_[2])
1301         : $_[2];
1302
1303         my $md5 = $DIGEST_FUNC->($key);
1304
1305         ##
1306         # Make sure file is open
1307         ##
1308         if (!defined($self->_fh) && !$self->_open()) {
1309                 return;
1310         }
1311
1312     if ( $^O ne 'MSWin32' && !_is_writable( $self->_fh ) ) {
1313         $self->_throw_error( 'Cannot write to a readonly filehandle' );
1314     }
1315
1316         ##
1317         # Request exclusive lock for writing
1318         ##
1319         $self->lock( LOCK_EX );
1320
1321         my $fh = $self->_fh;
1322
1323         ##
1324         # Locate offset for bucket list using digest index system
1325         ##
1326         my $tag = $self->_load_tag($self->_base_offset);
1327         if (!$tag) {
1328                 $tag = $self->_create_tag($self->_base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1329         }
1330
1331         my $ch = 0;
1332         while ($tag->{signature} ne SIG_BLIST) {
1333                 my $num = ord(substr($md5, $ch, 1));
1334
1335         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1336                 my $new_tag = $self->_index_lookup($tag, $num);
1337
1338                 if (!$new_tag) {
1339                         seek($fh, $ref_loc + $self->_root->{file_offset}, SEEK_SET);
1340                         print( $fh pack($LONG_PACK, $self->_root->{end}) );
1341
1342                         $tag = $self->_create_tag($self->_root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1343
1344                         $tag->{ref_loc} = $ref_loc;
1345                         $tag->{ch} = $ch;
1346
1347                         last;
1348                 }
1349                 else {
1350                         $tag = $new_tag;
1351
1352                         $tag->{ref_loc} = $ref_loc;
1353                         $tag->{ch} = $ch;
1354                 }
1355                 $ch++;
1356         }
1357
1358         ##
1359         # Add key/value to bucket list
1360         ##
1361         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1362
1363         $self->unlock();
1364
1365         return $result;
1366 }
1367
1368 sub FETCH {
1369         ##
1370         # Fetch single value or element given plain key or array index
1371         ##
1372     my $self = shift->_get_self;
1373     my $key = shift;
1374
1375         ##
1376         # Make sure file is open
1377         ##
1378         if (!defined($self->_fh)) { $self->_open(); }
1379
1380         my $md5 = $DIGEST_FUNC->($key);
1381
1382         ##
1383         # Request shared lock for reading
1384         ##
1385         $self->lock( LOCK_SH );
1386
1387         my $tag = $self->_find_bucket_list( $md5 );
1388         if (!$tag) {
1389                 $self->unlock();
1390                 return;
1391         }
1392
1393         ##
1394         # Get value from bucket list
1395         ##
1396         my $result = $self->_get_bucket_value( $tag, $md5 );
1397
1398         $self->unlock();
1399
1400     #XXX What is ref() checking here?
1401     #YYY Filters only apply on scalar values, so the ref check is making
1402     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1403         return ($result && !ref($result) && $self->_root->{filter_fetch_value})
1404         ? $self->_root->{filter_fetch_value}->($result)
1405         : $result;
1406 }
1407
1408 sub DELETE {
1409         ##
1410         # Delete single key/value pair or element given plain key or array index
1411         ##
1412     my $self = $_[0]->_get_self;
1413         my $key = $_[1];
1414
1415         my $md5 = $DIGEST_FUNC->($key);
1416
1417         ##
1418         # Make sure file is open
1419         ##
1420         if (!defined($self->_fh)) { $self->_open(); }
1421
1422         ##
1423         # Request exclusive lock for writing
1424         ##
1425         $self->lock( LOCK_EX );
1426
1427         my $tag = $self->_find_bucket_list( $md5 );
1428         if (!$tag) {
1429                 $self->unlock();
1430                 return;
1431         }
1432
1433         ##
1434         # Delete bucket
1435         ##
1436     my $value = $self->_get_bucket_value( $tag, $md5 );
1437         if ($value && !ref($value) && $self->_root->{filter_fetch_value}) {
1438         $value = $self->_root->{filter_fetch_value}->($value);
1439     }
1440
1441         my $result = $self->_delete_bucket( $tag, $md5 );
1442
1443         ##
1444         # If this object is an array and the key deleted was on the end of the stack,
1445         # decrement the length variable.
1446         ##
1447
1448         $self->unlock();
1449
1450         return $value;
1451 }
1452
1453 sub EXISTS {
1454         ##
1455         # Check if a single key or element exists given plain key or array index
1456         ##
1457     my $self = $_[0]->_get_self;
1458         my $key = $_[1];
1459
1460         my $md5 = $DIGEST_FUNC->($key);
1461
1462         ##
1463         # Make sure file is open
1464         ##
1465         if (!defined($self->_fh)) { $self->_open(); }
1466
1467         ##
1468         # Request shared lock for reading
1469         ##
1470         $self->lock( LOCK_SH );
1471
1472         my $tag = $self->_find_bucket_list( $md5 );
1473
1474         ##
1475         # For some reason, the built-in exists() function returns '' for false
1476         ##
1477         if (!$tag) {
1478                 $self->unlock();
1479                 return '';
1480         }
1481
1482         ##
1483         # Check if bucket exists and return 1 or ''
1484         ##
1485         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1486
1487         $self->unlock();
1488
1489         return $result;
1490 }
1491
1492 sub CLEAR {
1493         ##
1494         # Clear all keys from hash, or all elements from array.
1495         ##
1496     my $self = $_[0]->_get_self;
1497
1498         ##
1499         # Make sure file is open
1500         ##
1501         if (!defined($self->_fh)) { $self->_open(); }
1502
1503         ##
1504         # Request exclusive lock for writing
1505         ##
1506         $self->lock( LOCK_EX );
1507
1508     my $fh = $self->_fh;
1509
1510         seek($fh, $self->_base_offset + $self->_root->{file_offset}, SEEK_SET);
1511         if (eof $fh) {
1512                 $self->unlock();
1513                 return;
1514         }
1515
1516         $self->_create_tag($self->_base_offset, $self->_type, chr(0) x $INDEX_SIZE);
1517
1518         $self->unlock();
1519
1520         return 1;
1521 }
1522
1523 ##
1524 # Public method aliases
1525 ##
1526 sub put { (shift)->STORE( @_ ) }
1527 sub store { (shift)->STORE( @_ ) }
1528 sub get { (shift)->FETCH( @_ ) }
1529 sub fetch { (shift)->FETCH( @_ ) }
1530 sub delete { (shift)->DELETE( @_ ) }
1531 sub exists { (shift)->EXISTS( @_ ) }
1532 sub clear { (shift)->CLEAR( @_ ) }
1533
1534 package DBM::Deep::_::Root;
1535
1536 sub new {
1537     my $class = shift;
1538     my ($args) = @_;
1539
1540     my $self = bless {
1541         file => undef,
1542         fh => undef,
1543         file_offset => 0,
1544         end => 0,
1545         autoflush => undef,
1546         locking => undef,
1547         debug => undef,
1548         filter_store_key => undef,
1549         filter_store_value => undef,
1550         filter_fetch_key => undef,
1551         filter_fetch_value => undef,
1552         autobless => undef,
1553         locked => 0,
1554         %$args,
1555     }, $class;
1556
1557     if ( $self->{fh} && !$self->{file_offset} ) {
1558         $self->{file_offset} = tell( $self->{fh} );
1559     }
1560
1561     return $self;
1562 }
1563
1564 sub DESTROY {
1565     my $self = shift;
1566     return unless $self;
1567
1568     close $self->{fh} if $self->{fh};
1569
1570     return;
1571 }
1572
1573 1;
1574
1575 __END__
1576
1577 =head1 NAME
1578
1579 DBM::Deep - A pure perl multi-level hash/array DBM
1580
1581 =head1 SYNOPSIS
1582
1583   use DBM::Deep;
1584   my $db = DBM::Deep->new( "foo.db" );
1585
1586   $db->{key} = 'value'; # tie() style
1587   print $db->{key};
1588
1589   $db->put('key' => 'value'); # OO style
1590   print $db->get('key');
1591
1592   # true multi-level support
1593   $db->{my_complex} = [
1594         'hello', { perl => 'rules' },
1595         42, 99,
1596   ];
1597
1598 =head1 DESCRIPTION
1599
1600 A unique flat-file database module, written in pure perl.  True
1601 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1602 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1603 handle millions of keys and unlimited hash levels without significant
1604 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1605 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1606 Mac OS X and Windows.
1607
1608 =head1 INSTALLATION
1609
1610 Hopefully you are using Perl's excellent CPAN module, which will download
1611 and install the module for you.  If not, get the tarball, and run these
1612 commands:
1613
1614         tar zxf DBM-Deep-*
1615         cd DBM-Deep-*
1616         perl Makefile.PL
1617         make
1618         make test
1619         make install
1620
1621 =head1 SETUP
1622
1623 Construction can be done OO-style (which is the recommended way), or using
1624 Perl's tie() function.  Both are examined here.
1625
1626 =head2 OO CONSTRUCTION
1627
1628 The recommended way to construct a DBM::Deep object is to use the new()
1629 method, which gets you a blessed, tied hash or array reference.
1630
1631         my $db = DBM::Deep->new( "foo.db" );
1632
1633 This opens a new database handle, mapped to the file "foo.db".  If this
1634 file does not exist, it will automatically be created.  DB files are
1635 opened in "r+" (read/write) mode, and the type of object returned is a
1636 hash, unless otherwise specified (see L<OPTIONS> below).
1637
1638 You can pass a number of options to the constructor to specify things like
1639 locking, autoflush, etc.  This is done by passing an inline hash:
1640
1641         my $db = DBM::Deep->new(
1642                 file => "foo.db",
1643                 locking => 1,
1644                 autoflush => 1
1645         );
1646
1647 Notice that the filename is now specified I<inside> the hash with
1648 the "file" parameter, as opposed to being the sole argument to the
1649 constructor.  This is required if any options are specified.
1650 See L<OPTIONS> below for the complete list.
1651
1652
1653
1654 You can also start with an array instead of a hash.  For this, you must
1655 specify the C<type> parameter:
1656
1657         my $db = DBM::Deep->new(
1658                 file => "foo.db",
1659                 type => DBM::Deep->TYPE_ARRAY
1660         );
1661
1662 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1663 a new DB file.  If you create a DBM::Deep object with an existing file, the
1664 C<type> will be loaded from the file header, and an error will be thrown if
1665 the wrong type is passed in.
1666
1667 =head2 TIE CONSTRUCTION
1668
1669 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1670 tie() function.  The object returned from tie() can be used to call methods,
1671 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1672 file (as expected with most tie'd objects).
1673
1674         my %hash;
1675         my $db = tie %hash, "DBM::Deep", "foo.db";
1676
1677         my @array;
1678         my $db = tie @array, "DBM::Deep", "bar.db";
1679
1680 As with the OO constructor, you can replace the DB filename parameter with
1681 a hash containing one or more options (see L<OPTIONS> just below for the
1682 complete list).
1683
1684         tie %hash, "DBM::Deep", {
1685                 file => "foo.db",
1686                 locking => 1,
1687                 autoflush => 1
1688         };
1689
1690 =head2 OPTIONS
1691
1692 There are a number of options that can be passed in when constructing your
1693 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1694
1695 =over
1696
1697 =item * file
1698
1699 Filename of the DB file to link the handle to.  You can pass a full absolute
1700 filesystem path, partial path, or a plain filename if the file is in the
1701 current working directory.  This is a required parameter (though q.v. fh).
1702
1703 =item * fh
1704
1705 If you want, you can pass in the fh instead of the file. This is most useful for doing
1706 something like:
1707
1708   my $db = DBM::Deep->new( { fh => \*DATA } );
1709
1710 You are responsible for making sure that the fh has been opened appropriately for your
1711 needs. If you open it read-only and attempt to write, an exception will be thrown. If you
1712 open it write-only or append-only, an exception will be thrown immediately as DBM::Deep
1713 needs to read from the fh.
1714
1715 =item * file_offset
1716
1717 This is the offset within the file that the DBM::Deep db starts. Most of the time, you will
1718 not need to set this. However, it's there if you want it.
1719
1720 If you pass in fh and do not set this, it will be set appropriately.
1721
1722 =item * type
1723
1724 This parameter specifies what type of object to create, a hash or array.  Use
1725 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1726 This only takes effect when beginning a new file.  This is an optional
1727 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1728
1729 =item * locking
1730
1731 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1732 function to lock the database in exclusive mode for writes, and shared mode for
1733 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1734 any child hashes or arrays> that use the same DB file.  This is an optional
1735 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1736
1737 =item * autoflush
1738
1739 Specifies whether autoflush is to be enabled on the underlying filehandle.
1740 This obviously slows down write operations, but is required if you may have
1741 multiple processes accessing the same DB file (also consider enable I<locking>).
1742 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1743 (disabled).
1744
1745 =item * autobless
1746
1747 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1748 restore them when fetched.  This is an B<experimental> feature, and does have
1749 side-effects.  Basically, when hashes are re-blessed into their original
1750 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1751 able to call any DBM::Deep methods on them.  You have been warned.
1752 This is an optional parameter, and defaults to 0 (disabled).
1753
1754 =item * filter_*
1755
1756 See L<FILTERS> below.
1757
1758 =item * debug
1759
1760 Setting I<debug> mode will make all errors non-fatal, dump them out to
1761 STDERR, and continue on.  This is for debugging purposes only, and probably
1762 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1763
1764 B<NOTE>: This parameter is considered deprecated and should not be used anymore.
1765
1766 =back
1767
1768 =head1 TIE INTERFACE
1769
1770 With DBM::Deep you can access your databases using Perl's standard hash/array
1771 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1772 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1773 to the right place -- the DB file.  This has nothing to do with the
1774 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1775 using regular hashes and arrays, rather than calling functions like C<get()>
1776 and C<put()> (although those work too).  It is entirely up to you how to want
1777 to access your databases.
1778
1779 =head2 HASHES
1780
1781 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1782 or even nested hashes (or arrays) using standard Perl syntax:
1783
1784         my $db = DBM::Deep->new( "foo.db" );
1785
1786         $db->{mykey} = "myvalue";
1787         $db->{myhash} = {};
1788         $db->{myhash}->{subkey} = "subvalue";
1789
1790         print $db->{myhash}->{subkey} . "\n";
1791
1792 You can even step through hash keys using the normal Perl C<keys()> function:
1793
1794         foreach my $key (keys %$db) {
1795                 print "$key: " . $db->{$key} . "\n";
1796         }
1797
1798 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1799 pushes them onto an array, all before the loop even begins.  If you have an
1800 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1801 Perl's C<each()> function, which pulls keys/values one at a time, using very
1802 little memory:
1803
1804         while (my ($key, $value) = each %$db) {
1805                 print "$key: $value\n";
1806         }
1807
1808 Please note that when using C<each()>, you should always pass a direct
1809 hash reference, not a lookup.  Meaning, you should B<never> do this:
1810
1811         # NEVER DO THIS
1812         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1813
1814 This causes an infinite loop, because for each iteration, Perl is calling
1815 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1816 it effectively keeps returning the first key over and over again. Instead,
1817 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1818
1819 =head2 ARRAYS
1820
1821 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1822 reference.  This includes inserting, removing and manipulating elements,
1823 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1824 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1825 or simply be a nested array reference inside a hash.  Example:
1826
1827         my $db = DBM::Deep->new(
1828                 file => "foo-array.db",
1829                 type => DBM::Deep->TYPE_ARRAY
1830         );
1831
1832         $db->[0] = "foo";
1833         push @$db, "bar", "baz";
1834         unshift @$db, "bah";
1835
1836         my $last_elem = pop @$db; # baz
1837         my $first_elem = shift @$db; # bah
1838         my $second_elem = $db->[1]; # bar
1839
1840         my $num_elements = scalar @$db;
1841
1842 =head1 OO INTERFACE
1843
1844 In addition to the I<tie()> interface, you can also use a standard OO interface
1845 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1846 array) has its own methods, but both types share the following common methods:
1847 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1848
1849 =over
1850
1851 =item * new() / clone()
1852
1853 These are the constructor and copy-functions.
1854
1855 =item * put() / store()
1856
1857 Stores a new hash key/value pair, or sets an array element value.  Takes two
1858 arguments, the hash key or array index, and the new value.  The value can be
1859 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1860
1861         $db->put("foo", "bar"); # for hashes
1862         $db->put(1, "bar"); # for arrays
1863
1864 =item * get() / fetch()
1865
1866 Fetches the value of a hash key or array element.  Takes one argument: the hash
1867 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1868 data type stored.
1869
1870         my $value = $db->get("foo"); # for hashes
1871         my $value = $db->get(1); # for arrays
1872
1873 =item * exists()
1874
1875 Checks if a hash key or array index exists.  Takes one argument: the hash key
1876 or array index.  Returns true if it exists, false if not.
1877
1878         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1879         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1880
1881 =item * delete()
1882
1883 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1884 key or array index.  Returns true on success, false if not found.  For arrays,
1885 the remaining elements located after the deleted element are NOT moved over.
1886 The deleted element is essentially just undefined, which is exactly how Perl's
1887 internal arrays work.  Please note that the space occupied by the deleted
1888 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1889 below for details and workarounds.
1890
1891         $db->delete("foo"); # for hashes
1892         $db->delete(1); # for arrays
1893
1894 =item * clear()
1895
1896 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1897 value.  Please note that the space occupied by the deleted keys/values or
1898 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1899 details and workarounds.
1900
1901         $db->clear(); # hashes or arrays
1902
1903 =item * lock() / unlock()
1904
1905 q.v. Locking.
1906
1907 =item * optimize()
1908
1909 Recover lost disk space.
1910
1911 =item * import() / export()
1912
1913 Data going in and out.
1914
1915 =item * set_digest() / set_pack() / set_filter()
1916
1917 q.v. adjusting the interal parameters.
1918
1919 =item * error() / clear_error()
1920
1921 Error handling methods. These are deprecated and will be removed in 1.00.
1922 .
1923 =back
1924
1925 =head2 HASHES
1926
1927 For hashes, DBM::Deep supports all the common methods described above, and the
1928 following additional methods: C<first_key()> and C<next_key()>.
1929
1930 =over
1931
1932 =item * first_key()
1933
1934 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1935 fetched in an undefined order (which appears random).  Takes no arguments,
1936 returns the key as a scalar value.
1937
1938         my $key = $db->first_key();
1939
1940 =item * next_key()
1941
1942 Returns the "next" key in the hash, given the previous one as the sole argument.
1943 Returns undef if there are no more keys to be fetched.
1944
1945         $key = $db->next_key($key);
1946
1947 =back
1948
1949 Here are some examples of using hashes:
1950
1951         my $db = DBM::Deep->new( "foo.db" );
1952
1953         $db->put("foo", "bar");
1954         print "foo: " . $db->get("foo") . "\n";
1955
1956         $db->put("baz", {}); # new child hash ref
1957         $db->get("baz")->put("buz", "biz");
1958         print "buz: " . $db->get("baz")->get("buz") . "\n";
1959
1960         my $key = $db->first_key();
1961         while ($key) {
1962                 print "$key: " . $db->get($key) . "\n";
1963                 $key = $db->next_key($key);
1964         }
1965
1966         if ($db->exists("foo")) { $db->delete("foo"); }
1967
1968 =head2 ARRAYS
1969
1970 For arrays, DBM::Deep supports all the common methods described above, and the
1971 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1972 C<unshift()> and C<splice()>.
1973
1974 =over
1975
1976 =item * length()
1977
1978 Returns the number of elements in the array.  Takes no arguments.
1979
1980         my $len = $db->length();
1981
1982 =item * push()
1983
1984 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1985 refs or array refs.  No return value.
1986
1987         $db->push("foo", "bar", {});
1988
1989 =item * pop()
1990
1991 Fetches the last element in the array, and deletes it.  Takes no arguments.
1992 Returns undef if array is empty.  Returns the element value.
1993
1994         my $elem = $db->pop();
1995
1996 =item * shift()
1997
1998 Fetches the first element in the array, deletes it, then shifts all the
1999 remaining elements over to take up the space.  Returns the element value.  This
2000 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2001 details.
2002
2003         my $elem = $db->shift();
2004
2005 =item * unshift()
2006
2007 Inserts one or more elements onto the beginning of the array, shifting all
2008 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2009 No return value.  This method is not recommended with large arrays -- see
2010 <LARGE ARRAYS> below for details.
2011
2012         $db->unshift("foo", "bar", {});
2013
2014 =item * splice()
2015
2016 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2017 -f splice> for usage -- it is too complicated to document here.  This method is
2018 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2019
2020 =back
2021
2022 Here are some examples of using arrays:
2023
2024         my $db = DBM::Deep->new(
2025                 file => "foo.db",
2026                 type => DBM::Deep->TYPE_ARRAY
2027         );
2028
2029         $db->push("bar", "baz");
2030         $db->unshift("foo");
2031         $db->put(3, "buz");
2032
2033         my $len = $db->length();
2034         print "length: $len\n"; # 4
2035
2036         for (my $k=0; $k<$len; $k++) {
2037                 print "$k: " . $db->get($k) . "\n";
2038         }
2039
2040         $db->splice(1, 2, "biz", "baf");
2041
2042         while (my $elem = shift @$db) {
2043                 print "shifted: $elem\n";
2044         }
2045
2046 =head1 LOCKING
2047
2048 Enable automatic file locking by passing a true value to the C<locking>
2049 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2050
2051         my $db = DBM::Deep->new(
2052                 file => "foo.db",
2053                 locking => 1
2054         );
2055
2056 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2057 mode for writes, and shared mode for reads.  This is required if you have
2058 multiple processes accessing the same database file, to avoid file corruption.
2059 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2060 NFS> below for more.
2061
2062 =head2 EXPLICIT LOCKING
2063
2064 You can explicitly lock a database, so it remains locked for multiple
2065 transactions.  This is done by calling the C<lock()> method, and passing an
2066 optional lock mode argument (defaults to exclusive mode).  This is particularly
2067 useful for things like counters, where the current value needs to be fetched,
2068 then incremented, then stored again.
2069
2070         $db->lock();
2071         my $counter = $db->get("counter");
2072         $counter++;
2073         $db->put("counter", $counter);
2074         $db->unlock();
2075
2076         # or...
2077
2078         $db->lock();
2079         $db->{counter}++;
2080         $db->unlock();
2081
2082 You can pass C<lock()> an optional argument, which specifies which mode to use
2083 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2084 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2085 same as the constants defined in Perl's C<Fcntl> module.
2086
2087         $db->lock( DBM::Deep->LOCK_SH );
2088         # something here
2089         $db->unlock();
2090
2091 =head1 IMPORTING/EXPORTING
2092
2093 You can import existing complex structures by calling the C<import()> method,
2094 and export an entire database into an in-memory structure using the C<export()>
2095 method.  Both are examined here.
2096
2097 =head2 IMPORTING
2098
2099 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2100 walking the structure and adding keys/elements to the database as you go,
2101 simply pass a reference to the C<import()> method.  This recursively adds
2102 everything to an existing DBM::Deep object for you.  Here is an example:
2103
2104         my $struct = {
2105                 key1 => "value1",
2106                 key2 => "value2",
2107                 array1 => [ "elem0", "elem1", "elem2" ],
2108                 hash1 => {
2109                         subkey1 => "subvalue1",
2110                         subkey2 => "subvalue2"
2111                 }
2112         };
2113
2114         my $db = DBM::Deep->new( "foo.db" );
2115         $db->import( $struct );
2116
2117         print $db->{key1} . "\n"; # prints "value1"
2118
2119 This recursively imports the entire C<$struct> object into C<$db>, including
2120 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2121 keys are merged with the existing ones, replacing if they already exist.
2122 The C<import()> method can be called on any database level (not just the base
2123 level), and works with both hash and array DB types.
2124
2125 B<Note:> Make sure your existing structure has no circular references in it.
2126 These will cause an infinite loop when importing.
2127
2128 =head2 EXPORTING
2129
2130 Calling the C<export()> method on an existing DBM::Deep object will return
2131 a reference to a new in-memory copy of the database.  The export is done
2132 recursively, so all nested hashes/arrays are all exported to standard Perl
2133 objects.  Here is an example:
2134
2135         my $db = DBM::Deep->new( "foo.db" );
2136
2137         $db->{key1} = "value1";
2138         $db->{key2} = "value2";
2139         $db->{hash1} = {};
2140         $db->{hash1}->{subkey1} = "subvalue1";
2141         $db->{hash1}->{subkey2} = "subvalue2";
2142
2143         my $struct = $db->export();
2144
2145         print $struct->{key1} . "\n"; # prints "value1"
2146
2147 This makes a complete copy of the database in memory, and returns a reference
2148 to it.  The C<export()> method can be called on any database level (not just
2149 the base level), and works with both hash and array DB types.  Be careful of
2150 large databases -- you can store a lot more data in a DBM::Deep object than an
2151 in-memory Perl structure.
2152
2153 B<Note:> Make sure your database has no circular references in it.
2154 These will cause an infinite loop when exporting.
2155
2156 =head1 FILTERS
2157
2158 DBM::Deep has a number of hooks where you can specify your own Perl function
2159 to perform filtering on incoming or outgoing data.  This is a perfect
2160 way to extend the engine, and implement things like real-time compression or
2161 encryption.  Filtering applies to the base DB level, and all child hashes /
2162 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2163 constructed, or by calling the C<set_filter()> method at any time.  There are
2164 four available filter hooks, described below:
2165
2166 =over
2167
2168 =item * filter_store_key
2169
2170 This filter is called whenever a hash key is stored.  It
2171 is passed the incoming key, and expected to return a transformed key.
2172
2173 =item * filter_store_value
2174
2175 This filter is called whenever a hash key or array element is stored.  It
2176 is passed the incoming value, and expected to return a transformed value.
2177
2178 =item * filter_fetch_key
2179
2180 This filter is called whenever a hash key is fetched (i.e. via
2181 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2182 and expected to return the plain key.
2183
2184 =item * filter_fetch_value
2185
2186 This filter is called whenever a hash key or array element is fetched.
2187 It is passed the transformed value, and expected to return the plain value.
2188
2189 =back
2190
2191 Here are the two ways to setup a filter hook:
2192
2193         my $db = DBM::Deep->new(
2194                 file => "foo.db",
2195                 filter_store_value => \&my_filter_store,
2196                 filter_fetch_value => \&my_filter_fetch
2197         );
2198
2199         # or...
2200
2201         $db->set_filter( "filter_store_value", \&my_filter_store );
2202         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2203
2204 Your filter function will be called only when dealing with SCALAR keys or
2205 values.  When nested hashes and arrays are being stored/fetched, filtering
2206 is bypassed.  Filters are called as static functions, passed a single SCALAR
2207 argument, and expected to return a single SCALAR value.  If you want to
2208 remove a filter, set the function reference to C<undef>:
2209
2210         $db->set_filter( "filter_store_value", undef );
2211
2212 =head2 REAL-TIME ENCRYPTION EXAMPLE
2213
2214 Here is a working example that uses the I<Crypt::Blowfish> module to
2215 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2216 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2217 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2218
2219         use DBM::Deep;
2220         use Crypt::Blowfish;
2221         use Crypt::CBC;
2222
2223         my $cipher = Crypt::CBC->new({
2224                 'key'             => 'my secret key',
2225                 'cipher'          => 'Blowfish',
2226                 'iv'              => '$KJh#(}q',
2227                 'regenerate_key'  => 0,
2228                 'padding'         => 'space',
2229                 'prepend_iv'      => 0
2230         });
2231
2232         my $db = DBM::Deep->new(
2233                 file => "foo-encrypt.db",
2234                 filter_store_key => \&my_encrypt,
2235                 filter_store_value => \&my_encrypt,
2236                 filter_fetch_key => \&my_decrypt,
2237                 filter_fetch_value => \&my_decrypt,
2238         );
2239
2240         $db->{key1} = "value1";
2241         $db->{key2} = "value2";
2242         print "key1: " . $db->{key1} . "\n";
2243         print "key2: " . $db->{key2} . "\n";
2244
2245         undef $db;
2246         exit;
2247
2248         sub my_encrypt {
2249                 return $cipher->encrypt( $_[0] );
2250         }
2251         sub my_decrypt {
2252                 return $cipher->decrypt( $_[0] );
2253         }
2254
2255 =head2 REAL-TIME COMPRESSION EXAMPLE
2256
2257 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2258 compression / decompression of keys & values with DBM::Deep Filters.
2259 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2260 more on I<Compress::Zlib>.
2261
2262         use DBM::Deep;
2263         use Compress::Zlib;
2264
2265         my $db = DBM::Deep->new(
2266                 file => "foo-compress.db",
2267                 filter_store_key => \&my_compress,
2268                 filter_store_value => \&my_compress,
2269                 filter_fetch_key => \&my_decompress,
2270                 filter_fetch_value => \&my_decompress,
2271         );
2272
2273         $db->{key1} = "value1";
2274         $db->{key2} = "value2";
2275         print "key1: " . $db->{key1} . "\n";
2276         print "key2: " . $db->{key2} . "\n";
2277
2278         undef $db;
2279         exit;
2280
2281         sub my_compress {
2282                 return Compress::Zlib::memGzip( $_[0] ) ;
2283         }
2284         sub my_decompress {
2285                 return Compress::Zlib::memGunzip( $_[0] ) ;
2286         }
2287
2288 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2289 actually numerical index numbers, and are not filtered.
2290
2291 =head1 ERROR HANDLING
2292
2293 Most DBM::Deep methods return a true value for success, and call die() on
2294 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2295 actual error message is stored in an internal scalar, which can be fetched by
2296 calling the C<error()> method.
2297
2298         my $db = DBM::Deep->new( "foo.db" ); # create hash
2299         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2300
2301     print $@;           # prints error message
2302         print $db->error(); # prints error message
2303
2304 You can then call C<clear_error()> to clear the current error state.
2305
2306         $db->clear_error();
2307
2308 If you set the C<debug> option to true when creating your DBM::Deep object,
2309 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2310 be used for debugging purposes and not production work. DBM::Deep expects errors
2311 to be thrown, not propagated back up the stack.
2312
2313 B<NOTE>: error() and clear_error() are considered deprecated and I<will> be removed
2314 in 1.00. Please don't use them. Instead, wrap all your functions with in eval-blocks.
2315
2316 =head1 LARGEFILE SUPPORT
2317
2318 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2319 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2320 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2321 by calling the static C<set_pack()> method before you do anything else.
2322
2323         DBM::Deep::set_pack(8, 'Q');
2324
2325 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2326 instead of 32-bit longs.  After setting these values your DB files have a
2327 theoretical maximum size of 16 XB (exabytes).
2328
2329 B<Note:> Changing these values will B<NOT> work for existing database files.
2330 Only change this for new files, and make sure it stays set consistently
2331 throughout the file's life.  If you do set these values, you can no longer
2332 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2333 back to 32-bit mode.
2334
2335 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2336 only a 32-bit Perl.  However, I have received user reports that this does
2337 indeed work!
2338
2339 =head1 LOW-LEVEL ACCESS
2340
2341 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2342 you can call the C<_fh()> method, which returns the handle:
2343
2344         my $fh = $db->_fh();
2345
2346 This method can be called on the root level of the datbase, or any child
2347 hashes or arrays.  All levels share a I<root> structure, which contains things
2348 like the filehandle, a reference counter, and all the options specified
2349 when you created the object.  You can get access to this root structure by
2350 calling the C<root()> method.
2351
2352         my $root = $db->_root();
2353
2354 This is useful for changing options after the object has already been created,
2355 such as enabling/disabling locking, or debug modes.  You can also
2356 store your own temporary user data in this structure (be wary of name
2357 collision), which is then accessible from any child hash or array.
2358
2359 =head1 CUSTOM DIGEST ALGORITHM
2360
2361 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2362 keys.  However you can override this, and use another algorithm (such as SHA-256)
2363 or even write your own.  But please note that DBM::Deep currently expects zero
2364 collisions, so your algorithm has to be I<perfect>, so to speak.
2365 Collision detection may be introduced in a later version.
2366
2367
2368
2369 You can specify a custom digest algorithm by calling the static C<set_digest()>
2370 function, passing a reference to a subroutine, and the length of the algorithm's
2371 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2372 objects.  Here is a working example that uses a 256-bit hash from the
2373 I<Digest::SHA256> module.  Please see
2374 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2375
2376         use DBM::Deep;
2377         use Digest::SHA256;
2378
2379         my $context = Digest::SHA256::new(256);
2380
2381         DBM::Deep::set_digest( \&my_digest, 32 );
2382
2383         my $db = DBM::Deep->new( "foo-sha.db" );
2384
2385         $db->{key1} = "value1";
2386         $db->{key2} = "value2";
2387         print "key1: " . $db->{key1} . "\n";
2388         print "key2: " . $db->{key2} . "\n";
2389
2390         undef $db;
2391         exit;
2392
2393         sub my_digest {
2394                 return substr( $context->hash($_[0]), 0, 32 );
2395         }
2396
2397 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2398 of bytes you specify in the C<set_digest()> function (in this case 32).
2399
2400 =head1 CIRCULAR REFERENCES
2401
2402 DBM::Deep has B<experimental> support for circular references.  Meaning you
2403 can have a nested hash key or array element that points to a parent object.
2404 This relationship is stored in the DB file, and is preserved between sessions.
2405 Here is an example:
2406
2407         my $db = DBM::Deep->new( "foo.db" );
2408
2409         $db->{foo} = "bar";
2410         $db->{circle} = $db; # ref to self
2411
2412         print $db->{foo} . "\n"; # prints "foo"
2413         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2414
2415 One catch is, passing the object to a function that recursively walks the
2416 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2417 C<export()> methods) will result in an infinite loop.  The other catch is,
2418 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2419 or C<next_key()> methods), you will get the I<target object's key>, not the
2420 ref's key.  This gets even more interesting with the above example, where
2421 the I<circle> key points to the base DB object, which technically doesn't
2422 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2423 special case.
2424
2425 =head1 CAVEATS / ISSUES / BUGS
2426
2427 This section describes all the known issues with DBM::Deep.  It you have found
2428 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2429
2430 =head2 UNUSED SPACE RECOVERY
2431
2432 One major caveat with DBM::Deep is that space occupied by existing keys and
2433 values is not recovered when they are deleted.  Meaning if you keep deleting
2434 and adding new keys, your file will continuously grow.  I am working on this,
2435 but in the meantime you can call the built-in C<optimize()> method from time to
2436 time (perhaps in a crontab or something) to recover all your unused space.
2437
2438         $db->optimize(); # returns true on success
2439
2440 This rebuilds the ENTIRE database into a new file, then moves it on top of
2441 the original.  The new file will have no unused space, thus it will take up as
2442 little disk space as possible.  Please note that this operation can take
2443 a long time for large files, and you need enough disk space to temporarily hold
2444 2 copies of your DB file.  The temporary file is created in the same directory
2445 as the original, named with a ".tmp" extension, and is deleted when the
2446 operation completes.  Oh, and if locking is enabled, the DB is automatically
2447 locked for the entire duration of the copy.
2448
2449 B<WARNING:> Only call optimize() on the top-level node of the database, and
2450 make sure there are no child references lying around.  DBM::Deep keeps a reference
2451 counter, and if it is greater than 1, optimize() will abort and return undef.
2452
2453 =head2 FILE CORRUPTION
2454
2455 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2456 for a 32-bit signature when opened, but other corruption in files can cause
2457 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2458 stuck in an infinite loop depending on the level of corruption.  File write
2459 operations are not checked for failure (for speed), so if you happen to run
2460 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2461 be addressed in a later version of DBM::Deep.
2462
2463 =head2 DB OVER NFS
2464
2465 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2466 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2467 about setting up your NFS server with a locking daemon, then using lockf() to
2468 lock your files, but your mileage may vary there as well.  From what I
2469 understand, there is no real way to do it.  However, if you need access to the
2470 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2471 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2472
2473 =head2 COPYING OBJECTS
2474
2475 Beware of copying tied objects in Perl.  Very strange things can happen.
2476 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2477 returns a new, blessed, tied hash or array to the same level in the DB.
2478
2479         my $copy = $db->clone();
2480
2481 B<Note>: Since clone() here is cloning the object, not the database location, any
2482 modifications to either $db or $copy will be visible in both.
2483
2484 =head2 LARGE ARRAYS
2485
2486 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2487 These functions cause every element in the array to move, which can be murder
2488 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2489 a different location.  This will be addressed in the forthcoming version 1.00.
2490
2491 =head2 WRITEONLY FILES
2492
2493 If you pass in a filehandle to new(), you may have opened it in either a readonly or
2494 writeonly mode. STORE will verify that the filehandle is writable. However, there
2495 doesn't seem to be a good way to determine if a filehandle is readable. And, if the
2496 filehandle isn't readable, it's not clear what will happen. So, don't do that.
2497
2498 =head1 PERFORMANCE
2499
2500 This section discusses DBM::Deep's speed and memory usage.
2501
2502 =head2 SPEED
2503
2504 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2505 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2506 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2507 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2508 with huge databases.  Here is some test data:
2509
2510         Adding 1,000,000 keys to new DB file...
2511
2512         At 100 keys, avg. speed is 2,703 keys/sec
2513         At 200 keys, avg. speed is 2,642 keys/sec
2514         At 300 keys, avg. speed is 2,598 keys/sec
2515         At 400 keys, avg. speed is 2,578 keys/sec
2516         At 500 keys, avg. speed is 2,722 keys/sec
2517         At 600 keys, avg. speed is 2,628 keys/sec
2518         At 700 keys, avg. speed is 2,700 keys/sec
2519         At 800 keys, avg. speed is 2,607 keys/sec
2520         At 900 keys, avg. speed is 2,190 keys/sec
2521         At 1,000 keys, avg. speed is 2,570 keys/sec
2522         At 2,000 keys, avg. speed is 2,417 keys/sec
2523         At 3,000 keys, avg. speed is 1,982 keys/sec
2524         At 4,000 keys, avg. speed is 1,568 keys/sec
2525         At 5,000 keys, avg. speed is 1,533 keys/sec
2526         At 6,000 keys, avg. speed is 1,787 keys/sec
2527         At 7,000 keys, avg. speed is 1,977 keys/sec
2528         At 8,000 keys, avg. speed is 2,028 keys/sec
2529         At 9,000 keys, avg. speed is 2,077 keys/sec
2530         At 10,000 keys, avg. speed is 2,031 keys/sec
2531         At 20,000 keys, avg. speed is 1,970 keys/sec
2532         At 30,000 keys, avg. speed is 2,050 keys/sec
2533         At 40,000 keys, avg. speed is 2,073 keys/sec
2534         At 50,000 keys, avg. speed is 1,973 keys/sec
2535         At 60,000 keys, avg. speed is 1,914 keys/sec
2536         At 70,000 keys, avg. speed is 2,091 keys/sec
2537         At 80,000 keys, avg. speed is 2,103 keys/sec
2538         At 90,000 keys, avg. speed is 1,886 keys/sec
2539         At 100,000 keys, avg. speed is 1,970 keys/sec
2540         At 200,000 keys, avg. speed is 2,053 keys/sec
2541         At 300,000 keys, avg. speed is 1,697 keys/sec
2542         At 400,000 keys, avg. speed is 1,838 keys/sec
2543         At 500,000 keys, avg. speed is 1,941 keys/sec
2544         At 600,000 keys, avg. speed is 1,930 keys/sec
2545         At 700,000 keys, avg. speed is 1,735 keys/sec
2546         At 800,000 keys, avg. speed is 1,795 keys/sec
2547         At 900,000 keys, avg. speed is 1,221 keys/sec
2548         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2549
2550 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2551 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2552 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2553 Run time was 12 min 3 sec.
2554
2555 =head2 MEMORY USAGE
2556
2557 One of the great things about DBM::Deep is that it uses very little memory.
2558 Even with huge databases (1,000,000+ keys) you will not see much increased
2559 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2560 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2561 database handle:
2562
2563           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2564         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2565
2566 Basically the process is taking 2,716K of memory.  And here is the same
2567 process after storing and fetching 1,000,000 keys:
2568
2569           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2570         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2571
2572 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2573 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2574
2575 =head1 DB FILE FORMAT
2576
2577 In case you were interested in the underlying DB file format, it is documented
2578 here in this section.  You don't need to know this to use the module, it's just
2579 included for reference.
2580
2581 =head2 SIGNATURE
2582
2583 DBM::Deep files always start with a 32-bit signature to identify the file type.
2584 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2585 checked for when the file is opened and an error will be thrown if it's not found.
2586
2587 =head2 TAG
2588
2589 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2590 has a standard header containing the type of data, the length of data, and then
2591 the data itself.  The type is a single character (1 byte), the length is a
2592 32-bit unsigned long in network byte order, and the data is, well, the data.
2593 Here is how it unfolds:
2594
2595 =head2 MASTER INDEX
2596
2597 Immediately after the 32-bit file signature is the I<Master Index> record.
2598 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2599 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2600 depending on how the DBM::Deep object was constructed.
2601
2602 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2603 number).  The first 8-bit char of the MD5 signature is the offset into the
2604 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2605 index element is a file offset of the next tag for the key/element in question,
2606 which is usually a I<Bucket List> tag (see below).
2607
2608 The next tag I<could> be another index, depending on how many keys/elements
2609 exist.  See L<RE-INDEXING> below for details.
2610
2611 =head2 BUCKET LIST
2612
2613 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2614 file offsets to where the actual data is stored.  It starts with a standard
2615 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2616 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2617 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2618 When the list fills up, a I<Re-Index> operation is performed (See
2619 L<RE-INDEXING> below).
2620
2621 =head2 BUCKET
2622
2623 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2624 index/value pair (in array mode).  It starts with a standard tag header with
2625 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2626 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2627 header.  The size reported in the tag header is only for the value, but then,
2628 just after the value is another size (32-bit unsigned long) and then the plain
2629 key itself.  Since the value is likely to be fetched more often than the plain
2630 key, I figured it would be I<slightly> faster to store the value first.
2631
2632 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2633 record for the nested structure, where the process begins all over again.
2634
2635 =head2 RE-INDEXING
2636
2637 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2638 exhausted.  Then, when another key/element comes in, the list is converted to a
2639 new index record.  However, this index will look at the next char in the MD5
2640 hash, and arrange new Bucket List pointers accordingly.  This process is called
2641 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2642 17 (16 + new one) keys/elements are removed from the old Bucket List and
2643 inserted into the new index.  Several new Bucket Lists are created in the
2644 process, as a new MD5 char from the key is being examined (it is unlikely that
2645 the keys will all share the same next char of their MD5s).
2646
2647 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2648 when the Bucket Lists will turn into indexes, but the first round tends to
2649 happen right around 4,000 keys.  You will see a I<slight> decrease in
2650 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2651 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2652 right around 900,000 keys.  This process can continue nearly indefinitely --
2653 right up until the point the I<MD5> signatures start colliding with each other,
2654 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2655 getting struck by lightning while you are walking to cash in your tickets.
2656 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2657 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2658 this is 340 unodecillion, but don't quote me).
2659
2660 =head2 STORING
2661
2662 When a new key/element is stored, the key (or index number) is first run through
2663 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2664 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2665 for the first char of the signature (in this case I<b0>).  If it does not exist,
2666 a new I<Bucket List> is created for our key (and the next 15 future keys that
2667 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2668 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2669 this point, unless we are replacing an existing I<Bucket>), where the actual
2670 data will be stored.
2671
2672 =head2 FETCHING
2673
2674 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2675 (or index number), then walking along the indexes.  If there are enough
2676 keys/elements in this DB level, there might be nested indexes, each linked to
2677 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2678 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2679 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2680 plain key are stored.
2681
2682 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2683 methods.  In this process the indexes are walked systematically, and each key
2684 fetched in increasing MD5 order (which is why it appears random).   Once the
2685 I<Bucket> is found, the value is skipped and the plain key returned instead.
2686 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2687 alphabetically sorted.  This only happens on an index-level -- as soon as the
2688 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2689 so it's pretty much undefined how the keys will come out -- just like Perl's
2690 built-in hashes.
2691
2692 =head1 CODE COVERAGE
2693
2694 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2695 B<Devel::Cover> report on this module's test suite.
2696
2697   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2698   File                           stmt   bran   cond    sub    pod   time  total
2699   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2700   blib/lib/DBM/Deep.pm           95.2   83.8   70.0   98.2  100.0   58.0   91.0
2701   blib/lib/DBM/Deep/Array.pm    100.0   91.1  100.0  100.0    n/a   26.7   98.0
2702   blib/lib/DBM/Deep/Hash.pm      95.3   80.0  100.0  100.0    n/a   15.3   92.4
2703   Total                          96.2   84.8   74.4   98.8  100.0  100.0   92.4
2704   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2705
2706 =head1 MORE INFORMATION
2707
2708 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2709 or send email to L<DBM-Deep@googlegroups.com>.
2710
2711 =head1 AUTHORS
2712
2713 Joseph Huckaby, L<jhuckaby@cpan.org>
2714
2715 Rob Kinyon, L<rkinyon@cpan.org>
2716
2717 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2718
2719 =head1 SEE ALSO
2720
2721 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2722 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2723
2724 =head1 LICENSE
2725
2726 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2727 This is free software, you may use it and distribute it under the
2728 same terms as Perl itself.
2729
2730 =cut