lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.97);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a FileHandle to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         #XXX Can the mode be anything but r+, w+, or a+??
 215         #XXX ie, it has to be in read-write mode
 216         #XXX So, should we verify that the mode is legitimate?
 217
 218         #XXX Maybe the mode thingy should just go away. There's no good
 219         #XXX reason for it ...
 220         if ( $self->root->{mode} eq 'w+' ) {
 221             $flags |= O_TRUNC;
 222         }
 223
 224         my $fh;
 225         sysopen( $fh, $self->root->{file}, $flags )
 226             or $fh = undef;
 227         $self->root->{fh} = $fh;
 228     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 229         if (! defined($self->fh)) {
 230                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 231         }
 232
 233     my $fh = $self->fh;
 234
 235     #XXX Can we remove this by using the right sysopen() flags?
 236     # Maybe ... q.v. above
 237     binmode $fh; # for win32
 238
 239     if ($self->root->{autoflush}) {
 240         my $old = select $fh;
 241         $|=1;
 242         select $old;
 243     }
 244
 245     # Set the
 246     seek($fh, 0, SEEK_SET);
 247
 248     my $signature;
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, SEEK_SET);
 256         print($fh SIG_FILE);
 257         $self->root->{end} = length(SIG_FILE);
 258         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 263
 264         # Flush the filehandle
 265         my $old_fh = select $fh;
 266         my $old_af = $|;
 267         $| = 1;
 268         $| = $old_af;
 269         select $old_fh;
 270
 271         return 1;
 272     }
 273
 274     ##
 275     # Check signature was valid
 276     ##
 277     unless ($signature eq SIG_FILE) {
 278         $self->_close();
 279         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 280     }
 281
 282         my @stats = stat($fh);
 283         $self->root->{inode} = $stats[1];
 284     $self->root->{end} = $stats[7];
 285
 286     ##
 287     # Get our type from master index signature
 288     ##
 289     my $tag = $self->_load_tag($self->base_offset);
 290
 291 #XXX We probably also want to store the hash algorithm name and not assume anything
 292 #XXX The cool thing would be to allow a different hashing algorithm at every level
 293
 294     if (!$tag) {
 295         return $self->_throw_error("Corrupted file, no master index record");
 296     }
 297     if ($self->{type} ne $tag->{signature}) {
 298         return $self->_throw_error("File type mismatch");
 299     }
 300
 301     return 1;
 302 }
 303
 304 sub _close {
 305         ##
 306         # Close database FileHandle
 307         ##
 308     my $self = $_[0]->_get_self;
 309     close $self->root->{fh};
 310     $self->root->{fh} = undef;
 311 }
 312
 313 sub _create_tag {
 314         ##
 315         # Given offset, signature and content, create tag and write to disk
 316         ##
 317         my ($self, $offset, $sig, $content) = @_;
 318         my $size = length($content);
 319
 320     my $fh = $self->fh;
 321
 322         seek($fh, $offset, SEEK_SET);
 323         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 324
 325         if ($offset == $self->root->{end}) {
 326                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 327         }
 328
 329         return {
 330                 signature => $sig,
 331                 size => $size,
 332                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 333                 content => $content
 334         };
 335 }
 336
 337 sub _load_tag {
 338         ##
 339         # Given offset, load single tag and return signature, size and data
 340         ##
 341         my $self = shift;
 342         my $offset = shift;
 343
 344     my $fh = $self->fh;
 345
 346         seek($fh, $offset, SEEK_SET);
 347         if (eof $fh) { return undef; }
 348
 349         my $sig;
 350         read( $fh, $sig, SIG_SIZE);
 351
 352         my $size;
 353         read( $fh, $size, $DATA_LENGTH_SIZE);
 354         $size = unpack($DATA_LENGTH_PACK, $size);
 355
 356         my $buffer;
 357         read( $fh, $buffer, $size);
 358
 359         return {
 360                 signature => $sig,
 361                 size => $size,
 362                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 363                 content => $buffer
 364         };
 365 }
 366
 367 sub _index_lookup {
 368         ##
 369         # Given index tag, lookup single entry in index and return .
 370         ##
 371         my $self = shift;
 372         my ($tag, $index) = @_;
 373
 374         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 375         if (!$location) { return; }
 376
 377         return $self->_load_tag( $location );
 378 }
 379
 380 sub _add_bucket {
 381         ##
 382         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 383         # plain (undigested) key and value.
 384         ##
 385         my $self = shift;
 386         my ($tag, $md5, $plain_key, $value) = @_;
 387         my $keys = $tag->{content};
 388         my $location = 0;
 389         my $result = 2;
 390
 391     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 392         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 393
 394     my $fh = $self->fh;
 395
 396         ##
 397         # Iterate through buckets, seeing if this is a new entry or a replace.
 398         ##
 399         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 400                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 401                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 402                 if (!$subloc) {
 403                         ##
 404                         # Found empty bucket (end of list).  Populate and exit loop.
 405                         ##
 406                         $result = 2;
 407
 408             $location = $internal_ref
 409                 ? $value->base_offset
 410                 : $self->root->{end};
 411
 412                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 413                         print($fh $md5 . pack($LONG_PACK, $location) );
 414                         last;
 415                 }
 416                 elsif ($md5 eq $key) {
 417                         ##
 418                         # Found existing bucket with same key.  Replace with new value.
 419                         ##
 420                         $result = 1;
 421
 422                         if ($internal_ref) {
 423                                 $location = $value->base_offset;
 424                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 425                                 print($fh $md5 . pack($LONG_PACK, $location) );
 426                         }
 427                         else {
 428                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 429                                 my $size;
 430                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 431
 432                                 ##
 433                                 # If value is a hash, array, or raw value with equal or less size, we can
 434                                 # reuse the same content area of the database.  Otherwise, we have to create
 435                                 # a new content area at the EOF.
 436                                 ##
 437                                 my $actual_length;
 438                 my $r = Scalar::Util::reftype( $value ) || '';
 439                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 440                                 else { $actual_length = length($value); }
 441
 442                                 if ($actual_length <= $size) {
 443                                         $location = $subloc;
 444                                 }
 445                                 else {
 446                                         $location = $self->root->{end};
 447                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 448                                         print($fh pack($LONG_PACK, $location) );
 449                                 }
 450                         }
 451                         last;
 452                 }
 453         } # i loop
 454
 455         ##
 456         # If this is an internal reference, return now.
 457         # No need to write value or plain key
 458         ##
 459         if ($internal_ref) {
 460         return $result;
 461     }
 462
 463         ##
 464         # If bucket didn't fit into list, split into a new index level
 465         ##
 466         if (!$location) {
 467                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 468                 print($fh pack($LONG_PACK, $self->root->{end}) );
 469
 470                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 471                 my @offsets = ();
 472
 473                 $keys .= $md5 . pack($LONG_PACK, 0);
 474
 475                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 476                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 477                         if ($key) {
 478                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 479                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 480
 481                                 if ($offsets[$num]) {
 482                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 483                                         seek($fh, $offset, SEEK_SET);
 484                                         my $subkeys;
 485                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 486
 487                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 488                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 489                                                 if (!$subloc) {
 490                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 491                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 492                                                         last;
 493                                                 }
 494                                         } # k loop
 495                                 }
 496                                 else {
 497                                         $offsets[$num] = $self->root->{end};
 498                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 499                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 500
 501                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 502
 503                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 504                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 505                                 }
 506                         } # key is real
 507                 } # i loop
 508
 509                 $location ||= $self->root->{end};
 510         } # re-index bucket list
 511
 512         ##
 513         # Seek to content area and store signature, value and plaintext key
 514         ##
 515         if ($location) {
 516                 my $content_length;
 517                 seek($fh, $location, SEEK_SET);
 518
 519                 ##
 520                 # Write signature based on content type, set content length and write actual value.
 521                 ##
 522         my $r = Scalar::Util::reftype($value) || '';
 523                 if ($r eq 'HASH') {
 524                         print($fh TYPE_HASH );
 525                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 526                         $content_length = $INDEX_SIZE;
 527                 }
 528                 elsif ($r eq 'ARRAY') {
 529                         print($fh TYPE_ARRAY );
 530                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 531                         $content_length = $INDEX_SIZE;
 532                 }
 533                 elsif (!defined($value)) {
 534                         print($fh SIG_NULL );
 535                         print($fh pack($DATA_LENGTH_PACK, 0) );
 536                         $content_length = 0;
 537                 }
 538                 else {
 539                         print($fh SIG_DATA );
 540                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 541                         $content_length = length($value);
 542                 }
 543
 544                 ##
 545                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 546                 ##
 547                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 548
 549                 ##
 550                 # If value is blessed, preserve class name
 551                 ##
 552                 if ( $self->root->{autobless} ) {
 553             my $value_class = Scalar::Util::blessed($value);
 554             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 555                 ##
 556                 # Blessed ref -- will restore later
 557                 ##
 558                 print($fh chr(1) );
 559                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 560                 $content_length += 1;
 561                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 562             }
 563             else {
 564                 print($fh chr(0) );
 565                 $content_length += 1;
 566             }
 567         }
 568
 569                 ##
 570                 # If this is a new content area, advance EOF counter
 571                 ##
 572                 if ($location == $self->root->{end}) {
 573                         $self->root->{end} += SIG_SIZE;
 574                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 575                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 576                 }
 577
 578                 ##
 579                 # If content is a hash or array, create new child DeepDB object and
 580                 # pass each key or element to it.
 581                 ##
 582                 if ($r eq 'HASH') {
 583                         my $branch = DBM::Deep->new(
 584                                 type => TYPE_HASH,
 585                                 base_offset => $location,
 586                                 root => $self->root,
 587                         );
 588                         foreach my $key (keys %{$value}) {
 589                 #$branch->{$key} = $value->{$key};
 590                 $branch->STORE( $key, $value->{$key} );
 591                         }
 592                 }
 593                 elsif ($r eq 'ARRAY') {
 594                         my $branch = DBM::Deep->new(
 595                                 type => TYPE_ARRAY,
 596                                 base_offset => $location,
 597                                 root => $self->root,
 598                         );
 599                         my $index = 0;
 600                         foreach my $element (@{$value}) {
 601                 #$branch->[$index] = $element;
 602                 $branch->STORE( $index, $element );
 603                                 $index++;
 604                         }
 605                 }
 606
 607                 return $result;
 608         }
 609
 610         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 611 }
 612
 613 sub _get_bucket_value {
 614         ##
 615         # Fetch single value given tag and MD5 digested key.
 616         ##
 617         my $self = shift;
 618         my ($tag, $md5) = @_;
 619         my $keys = $tag->{content};
 620
 621     my $fh = $self->fh;
 622
 623         ##
 624         # Iterate through buckets, looking for a key match
 625         ##
 626     BUCKET:
 627         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 628                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 629                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 630
 631                 if (!$subloc) {
 632                         ##
 633                         # Hit end of list, no match
 634                         ##
 635                         return;
 636                 }
 637
 638         if ( $md5 ne $key ) {
 639             next BUCKET;
 640         }
 641
 642         ##
 643         # Found match -- seek to offset and read signature
 644         ##
 645         my $signature;
 646         seek($fh, $subloc, SEEK_SET);
 647         read( $fh, $signature, SIG_SIZE);
 648
 649         ##
 650         # If value is a hash or array, return new DeepDB object with correct offset
 651         ##
 652         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 653             my $obj = DBM::Deep->new(
 654                 type => $signature,
 655                 base_offset => $subloc,
 656                 root => $self->root
 657             );
 658
 659             if ($self->root->{autobless}) {
 660                 ##
 661                 # Skip over value and plain key to see if object needs
 662                 # to be re-blessed
 663                 ##
 664                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 665
 666                 my $size;
 667                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 668                 if ($size) { seek($fh, $size, SEEK_CUR); }
 669
 670                 my $bless_bit;
 671                 read( $fh, $bless_bit, 1);
 672                 if (ord($bless_bit)) {
 673                     ##
 674                     # Yes, object needs to be re-blessed
 675                     ##
 676                     my $class_name;
 677                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 678                     if ($size) { read( $fh, $class_name, $size); }
 679                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 680                 }
 681             }
 682
 683             return $obj;
 684         }
 685
 686         ##
 687         # Otherwise return actual value
 688         ##
 689         elsif ($signature eq SIG_DATA) {
 690             my $size;
 691             my $value = '';
 692             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 693             if ($size) { read( $fh, $value, $size); }
 694             return $value;
 695         }
 696
 697         ##
 698         # Key exists, but content is null
 699         ##
 700         else { return; }
 701         } # i loop
 702
 703         return;
 704 }
 705
 706 sub _delete_bucket {
 707         ##
 708         # Delete single key/value pair given tag and MD5 digested key.
 709         ##
 710         my $self = shift;
 711         my ($tag, $md5) = @_;
 712         my $keys = $tag->{content};
 713
 714     my $fh = $self->fh;
 715
 716         ##
 717         # Iterate through buckets, looking for a key match
 718         ##
 719     BUCKET:
 720         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 721                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 722                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 723
 724                 if (!$subloc) {
 725                         ##
 726                         # Hit end of list, no match
 727                         ##
 728                         return;
 729                 }
 730
 731         if ( $md5 ne $key ) {
 732             next BUCKET;
 733         }
 734
 735         ##
 736         # Matched key -- delete bucket and return
 737         ##
 738         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 739         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 740         print($fh chr(0) x $BUCKET_SIZE );
 741
 742         return 1;
 743         } # i loop
 744
 745         return;
 746 }
 747
 748 sub _bucket_exists {
 749         ##
 750         # Check existence of single key given tag and MD5 digested key.
 751         ##
 752         my $self = shift;
 753         my ($tag, $md5) = @_;
 754         my $keys = $tag->{content};
 755
 756         ##
 757         # Iterate through buckets, looking for a key match
 758         ##
 759     BUCKET:
 760         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 761                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 762                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 763
 764                 if (!$subloc) {
 765                         ##
 766                         # Hit end of list, no match
 767                         ##
 768                         return;
 769                 }
 770
 771         if ( $md5 ne $key ) {
 772             next BUCKET;
 773         }
 774
 775         ##
 776         # Matched key -- return true
 777         ##
 778         return 1;
 779         } # i loop
 780
 781         return;
 782 }
 783
 784 sub _find_bucket_list {
 785         ##
 786         # Locate offset for bucket list, given digested key
 787         ##
 788         my $self = shift;
 789         my $md5 = shift;
 790
 791         ##
 792         # Locate offset for bucket list using digest index system
 793         ##
 794         my $ch = 0;
 795         my $tag = $self->_load_tag($self->base_offset);
 796         if (!$tag) { return; }
 797
 798         while ($tag->{signature} ne SIG_BLIST) {
 799                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 800                 if (!$tag) { return; }
 801                 $ch++;
 802         }
 803
 804         return $tag;
 805 }
 806
 807 sub _traverse_index {
 808         ##
 809         # Scan index and recursively step into deeper levels, looking for next key.
 810         ##
 811     my ($self, $offset, $ch, $force_return_next) = @_;
 812     $force_return_next = undef unless $force_return_next;
 813
 814         my $tag = $self->_load_tag( $offset );
 815
 816     my $fh = $self->fh;
 817
 818         if ($tag->{signature} ne SIG_BLIST) {
 819                 my $content = $tag->{content};
 820                 my $start;
 821                 if ($self->{return_next}) { $start = 0; }
 822                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 823
 824                 for (my $index = $start; $index < 256; $index++) {
 825                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 826                         if ($subloc) {
 827                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 828                                 if (defined($result)) { return $result; }
 829                         }
 830                 } # index loop
 831
 832                 $self->{return_next} = 1;
 833         } # tag is an index
 834
 835         elsif ($tag->{signature} eq SIG_BLIST) {
 836                 my $keys = $tag->{content};
 837                 if ($force_return_next) { $self->{return_next} = 1; }
 838
 839                 ##
 840                 # Iterate through buckets, looking for a key match
 841                 ##
 842                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 843                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 844                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 845
 846                         if (!$subloc) {
 847                                 ##
 848                                 # End of bucket list -- return to outer loop
 849                                 ##
 850                                 $self->{return_next} = 1;
 851                                 last;
 852                         }
 853                         elsif ($key eq $self->{prev_md5}) {
 854                                 ##
 855                                 # Located previous key -- return next one found
 856                                 ##
 857                                 $self->{return_next} = 1;
 858                                 next;
 859                         }
 860                         elsif ($self->{return_next}) {
 861                                 ##
 862                                 # Seek to bucket location and skip over signature
 863                                 ##
 864                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 865
 866                                 ##
 867                                 # Skip over value to get to plain key
 868                                 ##
 869                                 my $size;
 870                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 871                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 872
 873                                 ##
 874                                 # Read in plain key and return as scalar
 875                                 ##
 876                                 my $plain_key;
 877                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 878                                 if ($size) { read( $fh, $plain_key, $size); }
 879
 880                                 return $plain_key;
 881                         }
 882                 } # bucket loop
 883
 884                 $self->{return_next} = 1;
 885         } # tag is a bucket list
 886
 887         return;
 888 }
 889
 890 sub _get_next_key {
 891         ##
 892         # Locate next key, given digested previous one
 893         ##
 894     my $self = $_[0]->_get_self;
 895
 896         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 897         $self->{return_next} = 0;
 898
 899         ##
 900         # If the previous key was not specifed, start at the top and
 901         # return the first one found.
 902         ##
 903         if (!$self->{prev_md5}) {
 904                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 905                 $self->{return_next} = 1;
 906         }
 907
 908         return $self->_traverse_index( $self->base_offset, 0 );
 909 }
 910
 911 sub lock {
 912         ##
 913         # If db locking is set, flock() the db file.  If called multiple
 914         # times before unlock(), then the same number of unlocks() must
 915         # be called before the lock is released.
 916         ##
 917     my $self = $_[0]->_get_self;
 918         my $type = $_[1];
 919     $type = LOCK_EX unless defined $type;
 920
 921         if (!defined($self->fh)) { return; }
 922
 923         if ($self->root->{locking}) {
 924                 if (!$self->root->{locked}) {
 925                         flock($self->fh, $type);
 926
 927                         # double-check file inode, in case another process
 928                         # has optimize()d our file while we were waiting.
 929                         if ((stat($self->root->{file}))[1] != $self->root->{inode}) {
 930                                 $self->_open(); # re-open
 931                                 flock($self->fh, $type); # re-lock
 932                         }
 933                 }
 934                 $self->root->{locked}++;
 935
 936         return 1;
 937         }
 938
 939     return;
 940 }
 941
 942 sub unlock {
 943         ##
 944         # If db locking is set, unlock the db file.  See note in lock()
 945         # regarding calling lock() multiple times.
 946         ##
 947     my $self = $_[0]->_get_self;
 948
 949         if (!defined($self->fh)) { return; }
 950
 951         if ($self->root->{locking} && $self->root->{locked} > 0) {
 952                 $self->root->{locked}--;
 953                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 954
 955         return 1;
 956         }
 957
 958     return;
 959 }
 960
 961 #XXX These uses of ref() need verified
 962 sub _copy_node {
 963         ##
 964         # Copy single level of keys or elements to new DB handle.
 965         # Recurse for nested structures
 966         ##
 967     my $self = $_[0]->_get_self;
 968         my $db_temp = $_[1];
 969
 970         if ($self->type eq TYPE_HASH) {
 971                 my $key = $self->first_key();
 972                 while ($key) {
 973                         my $value = $self->get($key);
 974 #XXX This doesn't work with autobless
 975                         if (!ref($value)) { $db_temp->{$key} = $value; }
 976                         else {
 977                                 my $type = $value->type;
 978                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 979                                 else { $db_temp->{$key} = []; }
 980                                 $value->_copy_node( $db_temp->{$key} );
 981                         }
 982                         $key = $self->next_key($key);
 983                 }
 984         }
 985         else {
 986                 my $length = $self->length();
 987                 for (my $index = 0; $index < $length; $index++) {
 988                         my $value = $self->get($index);
 989                         if (!ref($value)) { $db_temp->[$index] = $value; }
 990             #XXX NO tests for this code
 991                         else {
 992                                 my $type = $value->type;
 993                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 994                                 else { $db_temp->[$index] = []; }
 995                                 $value->_copy_node( $db_temp->[$index] );
 996                         }
 997                 }
 998         }
 999 }
1000
1001 sub export {
1002         ##
1003         # Recursively export into standard Perl hashes and arrays.
1004         ##
1005     my $self = $_[0]->_get_self;
1006
1007         my $temp;
1008         if ($self->type eq TYPE_HASH) { $temp = {}; }
1009         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1010
1011         $self->lock();
1012         $self->_copy_node( $temp );
1013         $self->unlock();
1014
1015         return $temp;
1016 }
1017
1018 sub import {
1019         ##
1020         # Recursively import Perl hash/array structure
1021         ##
1022     #XXX This use of ref() seems to be ok
1023         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1024
1025     my $self = $_[0]->_get_self;
1026         my $struct = $_[1];
1027
1028     #XXX This use of ref() seems to be ok
1029         if (!ref($struct)) {
1030                 ##
1031                 # struct is not a reference, so just import based on our type
1032                 ##
1033                 shift @_;
1034
1035                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1036                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1037         }
1038
1039     my $r = Scalar::Util::reftype($struct) || '';
1040         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1041                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1042         }
1043         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1044                 $self->push( @$struct );
1045         }
1046         else {
1047                 return $self->_throw_error("Cannot import: type mismatch");
1048         }
1049
1050         return 1;
1051 }
1052
1053 sub optimize {
1054         ##
1055         # Rebuild entire database into new file, then move
1056         # it back on top of original.
1057         ##
1058     my $self = $_[0]->_get_self;
1059
1060 #XXX Need to create a new test for this
1061 #       if ($self->root->{links} > 1) {
1062 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1063 #       }
1064
1065         my $db_temp = DBM::Deep->new(
1066                 file => $self->root->{file} . '.tmp',
1067                 type => $self->type
1068         );
1069         if (!$db_temp) {
1070                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1071         }
1072
1073         $self->lock();
1074         $self->_copy_node( $db_temp );
1075         undef $db_temp;
1076
1077         ##
1078         # Attempt to copy user, group and permissions over to new file
1079         ##
1080         my @stats = stat($self->fh);
1081         my $perms = $stats[2] & 07777;
1082         my $uid = $stats[4];
1083         my $gid = $stats[5];
1084         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1085         chmod( $perms, $self->root->{file} . '.tmp' );
1086
1087     # q.v. perlport for more information on this variable
1088     if ( $^O eq 'MSWin32' ) {
1089                 ##
1090                 # Potential race condition when optmizing on Win32 with locking.
1091                 # The Windows filesystem requires that the filehandle be closed
1092                 # before it is overwritten with rename().  This could be redone
1093                 # with a soft copy.
1094                 ##
1095                 $self->unlock();
1096                 $self->_close();
1097         }
1098
1099         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1100                 unlink $self->root->{file} . '.tmp';
1101                 $self->unlock();
1102                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1103         }
1104
1105         $self->unlock();
1106         $self->_close();
1107         $self->_open();
1108
1109         return 1;
1110 }
1111
1112 sub clone {
1113         ##
1114         # Make copy of object and return
1115         ##
1116     my $self = $_[0]->_get_self;
1117
1118         return DBM::Deep->new(
1119                 type => $self->type,
1120                 base_offset => $self->base_offset,
1121                 root => $self->root
1122         );
1123 }
1124
1125 {
1126     my %is_legal_filter = map {
1127         $_ => ~~1,
1128     } qw(
1129         store_key store_value
1130         fetch_key fetch_value
1131     );
1132
1133     sub set_filter {
1134         ##
1135         # Setup filter function for storing or fetching the key or value
1136         ##
1137         my $self = $_[0]->_get_self;
1138         my $type = lc $_[1];
1139         my $func = $_[2] ? $_[2] : undef;
1140
1141         if ( $is_legal_filter{$type} ) {
1142             $self->root->{"filter_$type"} = $func;
1143             return 1;
1144         }
1145
1146         return;
1147     }
1148 }
1149
1150 ##
1151 # Accessor methods
1152 ##
1153
1154 sub root {
1155         ##
1156         # Get access to the root structure
1157         ##
1158     my $self = $_[0]->_get_self;
1159         return $self->{root};
1160 }
1161
1162 sub fh {
1163         ##
1164         # Get access to the raw FileHandle
1165         ##
1166     #XXX It will be useful, though, when we split out HASH and ARRAY
1167     my $self = $_[0]->_get_self;
1168         return $self->root->{fh};
1169 }
1170
1171 sub type {
1172         ##
1173         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1174         ##
1175     my $self = $_[0]->_get_self;
1176         return $self->{type};
1177 }
1178
1179 sub base_offset {
1180         ##
1181         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1182         ##
1183     my $self = $_[0]->_get_self;
1184         return $self->{base_offset};
1185 }
1186
1187 sub error {
1188         ##
1189         # Get last error string, or undef if no error
1190         ##
1191         return $_[0]
1192         #? ( _get_self($_[0])->{root}->{error} or undef )
1193         ? ( $_[0]->_get_self->{root}->{error} or undef )
1194         : $@;
1195 }
1196
1197 ##
1198 # Utility methods
1199 ##
1200
1201 sub _throw_error {
1202         ##
1203         # Store error string in self
1204         ##
1205     my $self = $_[0]->_get_self;
1206         my $error_text = $_[1];
1207
1208     if ( Scalar::Util::blessed $self ) {
1209         $self->root->{error} = $error_text;
1210
1211         unless ($self->root->{debug}) {
1212             die "DBM::Deep: $error_text\n";
1213         }
1214
1215         warn "DBM::Deep: $error_text\n";
1216         return;
1217     }
1218     else {
1219         die "DBM::Deep: $error_text\n";
1220     }
1221 }
1222
1223 sub clear_error {
1224         ##
1225         # Clear error state
1226         ##
1227     my $self = $_[0]->_get_self;
1228
1229         undef $self->root->{error};
1230 }
1231
1232 sub precalc_sizes {
1233         ##
1234         # Precalculate index, bucket and bucket list sizes
1235         ##
1236
1237     #XXX I don't like this ...
1238     set_pack() unless defined $LONG_SIZE;
1239
1240         $INDEX_SIZE = 256 * $LONG_SIZE;
1241         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1242         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1243 }
1244
1245 sub set_pack {
1246         ##
1247         # Set pack/unpack modes (see file header for more)
1248         ##
1249     my ($long_s, $long_p, $data_s, $data_p) = @_;
1250
1251     $LONG_SIZE = $long_s ? $long_s : 4;
1252     $LONG_PACK = $long_p ? $long_p : 'N';
1253
1254     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1255     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1256
1257         precalc_sizes();
1258 }
1259
1260 sub set_digest {
1261         ##
1262         # Set key digest function (default is MD5)
1263         ##
1264     my ($digest_func, $hash_size) = @_;
1265
1266     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1267     $HASH_SIZE = $hash_size ? $hash_size : 16;
1268
1269         precalc_sizes();
1270 }
1271
1272 ##
1273 # tie() methods (hashes and arrays)
1274 ##
1275
1276 sub STORE {
1277         ##
1278         # Store single hash key/value or array element in database.
1279         ##
1280     my $self = $_[0]->_get_self;
1281         my $key = $_[1];
1282
1283     # User may be storing a hash, in which case we do not want it run
1284     # through the filtering system
1285         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1286         ? $self->root->{filter_store_value}->($_[2])
1287         : $_[2];
1288
1289         my $md5 = $DIGEST_FUNC->($key);
1290
1291         ##
1292         # Make sure file is open
1293         ##
1294         if (!defined($self->fh) && !$self->_open()) {
1295                 return;
1296         }
1297         ##
1298
1299         ##
1300         # Request exclusive lock for writing
1301         ##
1302         $self->lock( LOCK_EX );
1303
1304         my $fh = $self->fh;
1305
1306         ##
1307         # If locking is enabled, set 'end' parameter again, in case another
1308         # DB instance appended to our file while we were unlocked.
1309         ##
1310         if ($self->root->{locking} || $self->root->{volatile}) {
1311                 $self->root->{end} = (stat($fh))[7];
1312         }
1313
1314         ##
1315         # Locate offset for bucket list using digest index system
1316         ##
1317         my $tag = $self->_load_tag($self->base_offset);
1318         if (!$tag) {
1319                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1320         }
1321
1322         my $ch = 0;
1323         while ($tag->{signature} ne SIG_BLIST) {
1324                 my $num = ord(substr($md5, $ch, 1));
1325                 my $new_tag = $self->_index_lookup($tag, $num);
1326                 if (!$new_tag) {
1327                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1328                         seek($fh, $ref_loc, SEEK_SET);
1329                         print($fh pack($LONG_PACK, $self->root->{end}) );
1330
1331                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1332                         $tag->{ref_loc} = $ref_loc;
1333                         $tag->{ch} = $ch;
1334                         last;
1335                 }
1336                 else {
1337                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1338                         $tag = $new_tag;
1339                         $tag->{ref_loc} = $ref_loc;
1340                         $tag->{ch} = $ch;
1341                 }
1342                 $ch++;
1343         }
1344
1345         ##
1346         # Add key/value to bucket list
1347         ##
1348         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1349
1350         $self->unlock();
1351
1352         return $result;
1353 }
1354
1355 sub FETCH {
1356         ##
1357         # Fetch single value or element given plain key or array index
1358         ##
1359     my $self = shift->_get_self;
1360     my $key = shift;
1361
1362         ##
1363         # Make sure file is open
1364         ##
1365         if (!defined($self->fh)) { $self->_open(); }
1366
1367         my $md5 = $DIGEST_FUNC->($key);
1368
1369         ##
1370         # Request shared lock for reading
1371         ##
1372         $self->lock( LOCK_SH );
1373
1374         my $tag = $self->_find_bucket_list( $md5 );
1375         if (!$tag) {
1376                 $self->unlock();
1377                 return;
1378         }
1379
1380         ##
1381         # Get value from bucket list
1382         ##
1383         my $result = $self->_get_bucket_value( $tag, $md5 );
1384
1385         $self->unlock();
1386
1387     #XXX What is ref() checking here?
1388         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1389         ? $self->root->{filter_fetch_value}->($result)
1390         : $result;
1391 }
1392
1393 sub DELETE {
1394         ##
1395         # Delete single key/value pair or element given plain key or array index
1396         ##
1397     my $self = $_[0]->_get_self;
1398         my $key = $_[1];
1399
1400         my $md5 = $DIGEST_FUNC->($key);
1401
1402         ##
1403         # Make sure file is open
1404         ##
1405         if (!defined($self->fh)) { $self->_open(); }
1406
1407         ##
1408         # Request exclusive lock for writing
1409         ##
1410         $self->lock( LOCK_EX );
1411
1412         my $tag = $self->_find_bucket_list( $md5 );
1413         if (!$tag) {
1414                 $self->unlock();
1415                 return;
1416         }
1417
1418         ##
1419         # Delete bucket
1420         ##
1421     my $value = $self->_get_bucket_value( $tag, $md5 );
1422         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1423         $value = $self->root->{filter_fetch_value}->($value);
1424     }
1425
1426         my $result = $self->_delete_bucket( $tag, $md5 );
1427
1428         ##
1429         # If this object is an array and the key deleted was on the end of the stack,
1430         # decrement the length variable.
1431         ##
1432
1433         $self->unlock();
1434
1435         return $value;
1436 }
1437
1438 sub EXISTS {
1439         ##
1440         # Check if a single key or element exists given plain key or array index
1441         ##
1442     my $self = $_[0]->_get_self;
1443         my $key = $_[1];
1444
1445         my $md5 = $DIGEST_FUNC->($key);
1446
1447         ##
1448         # Make sure file is open
1449         ##
1450         if (!defined($self->fh)) { $self->_open(); }
1451
1452         ##
1453         # Request shared lock for reading
1454         ##
1455         $self->lock( LOCK_SH );
1456
1457         my $tag = $self->_find_bucket_list( $md5 );
1458
1459         ##
1460         # For some reason, the built-in exists() function returns '' for false
1461         ##
1462         if (!$tag) {
1463                 $self->unlock();
1464                 return '';
1465         }
1466
1467         ##
1468         # Check if bucket exists and return 1 or ''
1469         ##
1470         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1471
1472         $self->unlock();
1473
1474         return $result;
1475 }
1476
1477 sub CLEAR {
1478         ##
1479         # Clear all keys from hash, or all elements from array.
1480         ##
1481     my $self = $_[0]->_get_self;
1482
1483         ##
1484         # Make sure file is open
1485         ##
1486         if (!defined($self->fh)) { $self->_open(); }
1487
1488         ##
1489         # Request exclusive lock for writing
1490         ##
1491         $self->lock( LOCK_EX );
1492
1493     my $fh = $self->fh;
1494
1495         seek($fh, $self->base_offset, SEEK_SET);
1496         if (eof $fh) {
1497                 $self->unlock();
1498                 return;
1499         }
1500
1501         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1502
1503         $self->unlock();
1504
1505         return 1;
1506 }
1507
1508 ##
1509 # Public method aliases
1510 ##
1511 sub put { (shift)->STORE( @_ ) }
1512 sub store { (shift)->STORE( @_ ) }
1513 sub get { (shift)->FETCH( @_ ) }
1514 sub fetch { (shift)->FETCH( @_ ) }
1515 sub delete { (shift)->DELETE( @_ ) }
1516 sub exists { (shift)->EXISTS( @_ ) }
1517 sub clear { (shift)->CLEAR( @_ ) }
1518
1519 package DBM::Deep::_::Root;
1520
1521 sub new {
1522     my $class = shift;
1523     my ($args) = @_;
1524
1525     my $self = bless {
1526         file => undef,
1527         fh => undef,
1528         end => 0,
1529         autoflush => undef,
1530         locking => undef,
1531         volatile => undef,
1532         debug => undef,
1533         mode => 'r+',
1534         filter_store_key => undef,
1535         filter_store_value => undef,
1536         filter_fetch_key => undef,
1537         filter_fetch_value => undef,
1538         autobless => undef,
1539         locked => 0,
1540         %$args,
1541     }, $class;
1542
1543     return $self;
1544 }
1545
1546 sub DESTROY {
1547     my $self = shift;
1548     return unless $self;
1549
1550     close $self->{fh} if $self->{fh};
1551
1552     return;
1553 }
1554
1555 1;
1556
1557 __END__
1558
1559 =head1 NAME
1560
1561 DBM::Deep - A pure perl multi-level hash/array DBM
1562
1563 =head1 SYNOPSIS
1564
1565   use DBM::Deep;
1566   my $db = DBM::Deep->new( "foo.db" );
1567
1568   $db->{key} = 'value'; # tie() style
1569   print $db->{key};
1570
1571   $db->put('key', 'value'); # OO style
1572   print $db->get('key');
1573
1574   # true multi-level support
1575   $db->{my_complex} = [
1576         'hello', { perl => 'rules' },
1577         42, 99 ];
1578
1579 =head1 DESCRIPTION
1580
1581 A unique flat-file database module, written in pure perl.  True
1582 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1583 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1584 handle millions of keys and unlimited hash levels without significant
1585 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1586 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1587 Mac OS X and Windows.
1588
1589 =head1 INSTALLATION
1590
1591 Hopefully you are using CPAN's excellent Perl module, which will download
1592 and install the module for you.  If not, get the tarball, and run these
1593 commands:
1594
1595         tar zxf DBM-Deep-*
1596         cd DBM-Deep-*
1597         perl Makefile.PL
1598         make
1599         make test
1600         make install
1601
1602 =head1 SETUP
1603
1604 Construction can be done OO-style (which is the recommended way), or using
1605 Perl's tie() function.  Both are examined here.
1606
1607 =head2 OO CONSTRUCTION
1608
1609 The recommended way to construct a DBM::Deep object is to use the new()
1610 method, which gets you a blessed, tied hash or array reference.
1611
1612         my $db = DBM::Deep->new( "foo.db" );
1613
1614 This opens a new database handle, mapped to the file "foo.db".  If this
1615 file does not exist, it will automatically be created.  DB files are
1616 opened in "r+" (read/write) mode, and the type of object returned is a
1617 hash, unless otherwise specified (see L<OPTIONS> below).
1618
1619
1620
1621 You can pass a number of options to the constructor to specify things like
1622 locking, autoflush, etc.  This is done by passing an inline hash:
1623
1624         my $db = DBM::Deep->new(
1625                 file => "foo.db",
1626                 locking => 1,
1627                 autoflush => 1
1628         );
1629
1630 Notice that the filename is now specified I<inside> the hash with
1631 the "file" parameter, as opposed to being the sole argument to the
1632 constructor.  This is required if any options are specified.
1633 See L<OPTIONS> below for the complete list.
1634
1635
1636
1637 You can also start with an array instead of a hash.  For this, you must
1638 specify the C<type> parameter:
1639
1640         my $db = DBM::Deep->new(
1641                 file => "foo.db",
1642                 type => DBM::Deep->TYPE_ARRAY
1643         );
1644
1645 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1646 a new DB file.  If you create a DBM::Deep object with an existing file, the
1647 C<type> will be loaded from the file header, and ignored if it is passed
1648 to the constructor.
1649
1650 =head2 TIE CONSTRUCTION
1651
1652 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1653 tie() function.  This is not ideal, because you get only a basic, tied hash
1654 (or array) which is not blessed, so you can't call any functions on it.
1655
1656         my %hash;
1657         tie %hash, "DBM::Deep", "foo.db";
1658
1659         my @array;
1660         tie @array, "DBM::Deep", "bar.db";
1661
1662 As with the OO constructor, you can replace the DB filename parameter with
1663 a hash containing one or more options (see L<OPTIONS> just below for the
1664 complete list).
1665
1666         tie %hash, "DBM::Deep", {
1667                 file => "foo.db",
1668                 locking => 1,
1669                 autoflush => 1
1670         };
1671
1672 =head2 OPTIONS
1673
1674 There are a number of options that can be passed in when constructing your
1675 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1676
1677 =over
1678
1679 =item * file
1680
1681 Filename of the DB file to link the handle to.  You can pass a full absolute
1682 filesystem path, partial path, or a plain filename if the file is in the
1683 current working directory.  This is a required parameter.
1684
1685 =item * mode
1686
1687 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1688 module.  This is an optional parameter, and defaults to "r+" (read/write).
1689 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1690 created if it doesn't exist.
1691
1692 =item * type
1693
1694 This parameter specifies what type of object to create, a hash or array.  Use
1695 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1696 This only takes effect when beginning a new file.  This is an optional
1697 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1698
1699 =item * locking
1700
1701 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1702 function to lock the database in exclusive mode for writes, and shared mode for
1703 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1704 any child hashes or arrays> that use the same DB file.  This is an optional
1705 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1706
1707 =item * autoflush
1708
1709 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1710 This obviously slows down write operations, but is required if you may have
1711 multiple processes accessing the same DB file (also consider enable I<locking>
1712 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1713 parameter, and defaults to 0 (disabled).
1714
1715 =item * volatile
1716
1717 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1718 STORE() operation.  This is required if an outside force may change the size of
1719 the file between transactions.  Locking also implicitly enables volatile.  This
1720 is useful if you want to use a different locking system or write your own.  Pass
1721 any true value to enable.  This is an optional parameter, and defaults to 0
1722 (disabled).
1723
1724 =item * autobless
1725
1726 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1727 restore them when fetched.  This is an B<experimental> feature, and does have
1728 side-effects.  Basically, when hashes are re-blessed into their original
1729 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1730 able to call any DBM::Deep methods on them.  You have been warned.
1731 This is an optional parameter, and defaults to 0 (disabled).
1732
1733 =item * filter_*
1734
1735 See L<FILTERS> below.
1736
1737 =item * debug
1738
1739 Setting I<debug> mode will make all errors non-fatal, dump them out to
1740 STDERR, and continue on.  This is for debugging purposes only, and probably
1741 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1742
1743 =item * fh
1744
1745 Instead of passing a file path, you can instead pass a handle to an pre-opened
1746 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1747 contains your entire Perl script, as well as the data following the __DATA__
1748 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1749 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1750 in that.
1751
1752 =back
1753
1754 =head1 TIE INTERFACE
1755
1756 With DBM::Deep you can access your databases using Perl's standard hash/array
1757 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1758 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1759 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1760 section above.  This simply tells you how to use DBM::Deep using regular hashes
1761 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1762 work too).  It is entirely up to you how to want to access your databases.
1763
1764 =head2 HASHES
1765
1766 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1767 or even nested hashes (or arrays) using standard Perl syntax:
1768
1769         my $db = DBM::Deep->new( "foo.db" );
1770
1771         $db->{mykey} = "myvalue";
1772         $db->{myhash} = {};
1773         $db->{myhash}->{subkey} = "subvalue";
1774
1775         print $db->{myhash}->{subkey} . "\n";
1776
1777 You can even step through hash keys using the normal Perl C<keys()> function:
1778
1779         foreach my $key (keys %$db) {
1780                 print "$key: " . $db->{$key} . "\n";
1781         }
1782
1783 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1784 pushes them onto an array, all before the loop even begins.  If you have an
1785 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1786 Perl's C<each()> function, which pulls keys/values one at a time, using very
1787 little memory:
1788
1789         while (my ($key, $value) = each %$db) {
1790                 print "$key: $value\n";
1791         }
1792
1793 Please note that when using C<each()>, you should always pass a direct
1794 hash reference, not a lookup.  Meaning, you should B<never> do this:
1795
1796         # NEVER DO THIS
1797         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1798
1799 This causes an infinite loop, because for each iteration, Perl is calling
1800 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1801 it effectively keeps returning the first key over and over again. Instead,
1802 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1803
1804 =head2 ARRAYS
1805
1806 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1807 reference.  This includes inserting, removing and manipulating elements,
1808 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1809 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1810 or simply be a nested array reference inside a hash.  Example:
1811
1812         my $db = DBM::Deep->new(
1813                 file => "foo-array.db",
1814                 type => DBM::Deep->TYPE_ARRAY
1815         );
1816
1817         $db->[0] = "foo";
1818         push @$db, "bar", "baz";
1819         unshift @$db, "bah";
1820
1821         my $last_elem = pop @$db; # baz
1822         my $first_elem = shift @$db; # bah
1823         my $second_elem = $db->[1]; # bar
1824
1825         my $num_elements = scalar @$db;
1826
1827 =head1 OO INTERFACE
1828
1829 In addition to the I<tie()> interface, you can also use a standard OO interface
1830 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1831 array) has its own methods, but both types share the following common methods:
1832 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1833
1834 =over
1835
1836 =item * put()
1837
1838 Stores a new hash key/value pair, or sets an array element value.  Takes two
1839 arguments, the hash key or array index, and the new value.  The value can be
1840 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1841
1842         $db->put("foo", "bar"); # for hashes
1843         $db->put(1, "bar"); # for arrays
1844
1845 =item * get()
1846
1847 Fetches the value of a hash key or array element.  Takes one argument: the hash
1848 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1849 data type stored.
1850
1851         my $value = $db->get("foo"); # for hashes
1852         my $value = $db->get(1); # for arrays
1853
1854 =item * exists()
1855
1856 Checks if a hash key or array index exists.  Takes one argument: the hash key
1857 or array index.  Returns true if it exists, false if not.
1858
1859         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1860         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1861
1862 =item * delete()
1863
1864 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1865 key or array index.  Returns true on success, false if not found.  For arrays,
1866 the remaining elements located after the deleted element are NOT moved over.
1867 The deleted element is essentially just undefined, which is exactly how Perl's
1868 internal arrays work.  Please note that the space occupied by the deleted
1869 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1870 below for details and workarounds.
1871
1872         $db->delete("foo"); # for hashes
1873         $db->delete(1); # for arrays
1874
1875 =item * clear()
1876
1877 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1878 value.  Please note that the space occupied by the deleted keys/values or
1879 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1880 details and workarounds.
1881
1882         $db->clear(); # hashes or arrays
1883
1884 =back
1885
1886 =head2 HASHES
1887
1888 For hashes, DBM::Deep supports all the common methods described above, and the
1889 following additional methods: C<first_key()> and C<next_key()>.
1890
1891 =over
1892
1893 =item * first_key()
1894
1895 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1896 fetched in an undefined order (which appears random).  Takes no arguments,
1897 returns the key as a scalar value.
1898
1899         my $key = $db->first_key();
1900
1901 =item * next_key()
1902
1903 Returns the "next" key in the hash, given the previous one as the sole argument.
1904 Returns undef if there are no more keys to be fetched.
1905
1906         $key = $db->next_key($key);
1907
1908 =back
1909
1910 Here are some examples of using hashes:
1911
1912         my $db = DBM::Deep->new( "foo.db" );
1913
1914         $db->put("foo", "bar");
1915         print "foo: " . $db->get("foo") . "\n";
1916
1917         $db->put("baz", {}); # new child hash ref
1918         $db->get("baz")->put("buz", "biz");
1919         print "buz: " . $db->get("baz")->get("buz") . "\n";
1920
1921         my $key = $db->first_key();
1922         while ($key) {
1923                 print "$key: " . $db->get($key) . "\n";
1924                 $key = $db->next_key($key);
1925         }
1926
1927         if ($db->exists("foo")) { $db->delete("foo"); }
1928
1929 =head2 ARRAYS
1930
1931 For arrays, DBM::Deep supports all the common methods described above, and the
1932 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1933 C<unshift()> and C<splice()>.
1934
1935 =over
1936
1937 =item * length()
1938
1939 Returns the number of elements in the array.  Takes no arguments.
1940
1941         my $len = $db->length();
1942
1943 =item * push()
1944
1945 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1946 refs or array refs.  No return value.
1947
1948         $db->push("foo", "bar", {});
1949
1950 =item * pop()
1951
1952 Fetches the last element in the array, and deletes it.  Takes no arguments.
1953 Returns undef if array is empty.  Returns the element value.
1954
1955         my $elem = $db->pop();
1956
1957 =item * shift()
1958
1959 Fetches the first element in the array, deletes it, then shifts all the
1960 remaining elements over to take up the space.  Returns the element value.  This
1961 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1962 details.
1963
1964         my $elem = $db->shift();
1965
1966 =item * unshift()
1967
1968 Inserts one or more elements onto the beginning of the array, shifting all
1969 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1970 No return value.  This method is not recommended with large arrays -- see
1971 <LARGE ARRAYS> below for details.
1972
1973         $db->unshift("foo", "bar", {});
1974
1975 =item * splice()
1976
1977 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1978 -f splice> for usage -- it is too complicated to document here.  This method is
1979 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1980
1981 =back
1982
1983 Here are some examples of using arrays:
1984
1985         my $db = DBM::Deep->new(
1986                 file => "foo.db",
1987                 type => DBM::Deep->TYPE_ARRAY
1988         );
1989
1990         $db->push("bar", "baz");
1991         $db->unshift("foo");
1992         $db->put(3, "buz");
1993
1994         my $len = $db->length();
1995         print "length: $len\n"; # 4
1996
1997         for (my $k=0; $k<$len; $k++) {
1998                 print "$k: " . $db->get($k) . "\n";
1999         }
2000
2001         $db->splice(1, 2, "biz", "baf");
2002
2003         while (my $elem = shift @$db) {
2004                 print "shifted: $elem\n";
2005         }
2006
2007 =head1 LOCKING
2008
2009 Enable automatic file locking by passing a true value to the C<locking>
2010 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2011
2012         my $db = DBM::Deep->new(
2013                 file => "foo.db",
2014                 locking => 1
2015         );
2016
2017 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2018 mode for writes, and shared mode for reads.  This is required if you have
2019 multiple processes accessing the same database file, to avoid file corruption.
2020 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2021 NFS> below for more.
2022
2023 =head2 EXPLICIT LOCKING
2024
2025 You can explicitly lock a database, so it remains locked for multiple
2026 transactions.  This is done by calling the C<lock()> method, and passing an
2027 optional lock mode argument (defaults to exclusive mode).  This is particularly
2028 useful for things like counters, where the current value needs to be fetched,
2029 then incremented, then stored again.
2030
2031         $db->lock();
2032         my $counter = $db->get("counter");
2033         $counter++;
2034         $db->put("counter", $counter);
2035         $db->unlock();
2036
2037         # or...
2038
2039         $db->lock();
2040         $db->{counter}++;
2041         $db->unlock();
2042
2043 You can pass C<lock()> an optional argument, which specifies which mode to use
2044 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2045 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2046 same as the constants defined in Perl's C<Fcntl> module.
2047
2048         $db->lock( DBM::Deep->LOCK_SH );
2049         # something here
2050         $db->unlock();
2051
2052 If you want to implement your own file locking scheme, be sure to create your
2053 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2054 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2055 below for more.
2056
2057 =head1 IMPORTING/EXPORTING
2058
2059 You can import existing complex structures by calling the C<import()> method,
2060 and export an entire database into an in-memory structure using the C<export()>
2061 method.  Both are examined here.
2062
2063 =head2 IMPORTING
2064
2065 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2066 walking the structure and adding keys/elements to the database as you go,
2067 simply pass a reference to the C<import()> method.  This recursively adds
2068 everything to an existing DBM::Deep object for you.  Here is an example:
2069
2070         my $struct = {
2071                 key1 => "value1",
2072                 key2 => "value2",
2073                 array1 => [ "elem0", "elem1", "elem2" ],
2074                 hash1 => {
2075                         subkey1 => "subvalue1",
2076                         subkey2 => "subvalue2"
2077                 }
2078         };
2079
2080         my $db = DBM::Deep->new( "foo.db" );
2081         $db->import( $struct );
2082
2083         print $db->{key1} . "\n"; # prints "value1"
2084
2085 This recursively imports the entire C<$struct> object into C<$db>, including
2086 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2087 keys are merged with the existing ones, replacing if they already exist.
2088 The C<import()> method can be called on any database level (not just the base
2089 level), and works with both hash and array DB types.
2090
2091
2092
2093 B<Note:> Make sure your existing structure has no circular references in it.
2094 These will cause an infinite loop when importing.
2095
2096 =head2 EXPORTING
2097
2098 Calling the C<export()> method on an existing DBM::Deep object will return
2099 a reference to a new in-memory copy of the database.  The export is done
2100 recursively, so all nested hashes/arrays are all exported to standard Perl
2101 objects.  Here is an example:
2102
2103         my $db = DBM::Deep->new( "foo.db" );
2104
2105         $db->{key1} = "value1";
2106         $db->{key2} = "value2";
2107         $db->{hash1} = {};
2108         $db->{hash1}->{subkey1} = "subvalue1";
2109         $db->{hash1}->{subkey2} = "subvalue2";
2110
2111         my $struct = $db->export();
2112
2113         print $struct->{key1} . "\n"; # prints "value1"
2114
2115 This makes a complete copy of the database in memory, and returns a reference
2116 to it.  The C<export()> method can be called on any database level (not just
2117 the base level), and works with both hash and array DB types.  Be careful of
2118 large databases -- you can store a lot more data in a DBM::Deep object than an
2119 in-memory Perl structure.
2120
2121
2122
2123 B<Note:> Make sure your database has no circular references in it.
2124 These will cause an infinite loop when exporting.
2125
2126 =head1 FILTERS
2127
2128 DBM::Deep has a number of hooks where you can specify your own Perl function
2129 to perform filtering on incoming or outgoing data.  This is a perfect
2130 way to extend the engine, and implement things like real-time compression or
2131 encryption.  Filtering applies to the base DB level, and all child hashes /
2132 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2133 constructed, or by calling the C<set_filter()> method at any time.  There are
2134 four available filter hooks, described below:
2135
2136 =over
2137
2138 =item * filter_store_key
2139
2140 This filter is called whenever a hash key is stored.  It
2141 is passed the incoming key, and expected to return a transformed key.
2142
2143 =item * filter_store_value
2144
2145 This filter is called whenever a hash key or array element is stored.  It
2146 is passed the incoming value, and expected to return a transformed value.
2147
2148 =item * filter_fetch_key
2149
2150 This filter is called whenever a hash key is fetched (i.e. via
2151 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2152 and expected to return the plain key.
2153
2154 =item * filter_fetch_value
2155
2156 This filter is called whenever a hash key or array element is fetched.
2157 It is passed the transformed value, and expected to return the plain value.
2158
2159 =back
2160
2161 Here are the two ways to setup a filter hook:
2162
2163         my $db = DBM::Deep->new(
2164                 file => "foo.db",
2165                 filter_store_value => \&my_filter_store,
2166                 filter_fetch_value => \&my_filter_fetch
2167         );
2168
2169         # or...
2170
2171         $db->set_filter( "filter_store_value", \&my_filter_store );
2172         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2173
2174 Your filter function will be called only when dealing with SCALAR keys or
2175 values.  When nested hashes and arrays are being stored/fetched, filtering
2176 is bypassed.  Filters are called as static functions, passed a single SCALAR
2177 argument, and expected to return a single SCALAR value.  If you want to
2178 remove a filter, set the function reference to C<undef>:
2179
2180         $db->set_filter( "filter_store_value", undef );
2181
2182 =head2 REAL-TIME ENCRYPTION EXAMPLE
2183
2184 Here is a working example that uses the I<Crypt::Blowfish> module to
2185 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2186 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2187 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2188
2189         use DBM::Deep;
2190         use Crypt::Blowfish;
2191         use Crypt::CBC;
2192
2193         my $cipher = Crypt::CBC->new({
2194                 'key'             => 'my secret key',
2195                 'cipher'          => 'Blowfish',
2196                 'iv'              => '$KJh#(}q',
2197                 'regenerate_key'  => 0,
2198                 'padding'         => 'space',
2199                 'prepend_iv'      => 0
2200         });
2201
2202         my $db = DBM::Deep->new(
2203                 file => "foo-encrypt.db",
2204                 filter_store_key => \&my_encrypt,
2205                 filter_store_value => \&my_encrypt,
2206                 filter_fetch_key => \&my_decrypt,
2207                 filter_fetch_value => \&my_decrypt,
2208         );
2209
2210         $db->{key1} = "value1";
2211         $db->{key2} = "value2";
2212         print "key1: " . $db->{key1} . "\n";
2213         print "key2: " . $db->{key2} . "\n";
2214
2215         undef $db;
2216         exit;
2217
2218         sub my_encrypt {
2219                 return $cipher->encrypt( $_[0] );
2220         }
2221         sub my_decrypt {
2222                 return $cipher->decrypt( $_[0] );
2223         }
2224
2225 =head2 REAL-TIME COMPRESSION EXAMPLE
2226
2227 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2228 compression / decompression of keys & values with DBM::Deep Filters.
2229 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2230 more on I<Compress::Zlib>.
2231
2232         use DBM::Deep;
2233         use Compress::Zlib;
2234
2235         my $db = DBM::Deep->new(
2236                 file => "foo-compress.db",
2237                 filter_store_key => \&my_compress,
2238                 filter_store_value => \&my_compress,
2239                 filter_fetch_key => \&my_decompress,
2240                 filter_fetch_value => \&my_decompress,
2241         );
2242
2243         $db->{key1} = "value1";
2244         $db->{key2} = "value2";
2245         print "key1: " . $db->{key1} . "\n";
2246         print "key2: " . $db->{key2} . "\n";
2247
2248         undef $db;
2249         exit;
2250
2251         sub my_compress {
2252                 return Compress::Zlib::memGzip( $_[0] ) ;
2253         }
2254         sub my_decompress {
2255                 return Compress::Zlib::memGunzip( $_[0] ) ;
2256         }
2257
2258 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2259 actually numerical index numbers, and are not filtered.
2260
2261 =head1 ERROR HANDLING
2262
2263 Most DBM::Deep methods return a true value for success, and call die() on
2264 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2265 actual error message is stored in an internal scalar, which can be fetched by
2266 calling the C<error()> method.
2267
2268         my $db = DBM::Deep->new( "foo.db" ); # create hash
2269         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2270
2271         print $db->error(); # prints error message
2272
2273 You can then call C<clear_error()> to clear the current error state.
2274
2275         $db->clear_error();
2276
2277 If you set the C<debug> option to true when creating your DBM::Deep object,
2278 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2279 for debugging purposes.
2280
2281 =head1 LARGEFILE SUPPORT
2282
2283 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2284 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2285 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2286 by calling the static C<set_pack()> method before you do anything else.
2287
2288         DBM::Deep::set_pack(8, 'Q');
2289
2290 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2291 instead of 32-bit longs.  After setting these values your DB files have a
2292 theoretical maximum size of 16 XB (exabytes).
2293
2294
2295
2296 B<Note:> Changing these values will B<NOT> work for existing database files.
2297 Only change this for new files, and make sure it stays set consistently
2298 throughout the file's life.  If you do set these values, you can no longer
2299 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2300 back to 32-bit mode.
2301
2302
2303
2304 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2305 only a 32-bit Perl.  However, I have received user reports that this does
2306 indeed work!
2307
2308 =head1 LOW-LEVEL ACCESS
2309
2310 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2311 you can call the C<fh()> method, which returns the handle:
2312
2313         my $fh = $db->fh();
2314
2315 This method can be called on the root level of the datbase, or any child
2316 hashes or arrays.  All levels share a I<root> structure, which contains things
2317 like the FileHandle, a reference counter, and all your options you specified
2318 when you created the object.  You can get access to this root structure by
2319 calling the C<root()> method.
2320
2321         my $root = $db->root();
2322
2323 This is useful for changing options after the object has already been created,
2324 such as enabling/disabling locking, volatile or debug modes.  You can also
2325 store your own temporary user data in this structure (be wary of name
2326 collision), which is then accessible from any child hash or array.
2327
2328 =head1 CUSTOM DIGEST ALGORITHM
2329
2330 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2331 keys.  However you can override this, and use another algorithm (such as SHA-256)
2332 or even write your own.  But please note that DBM::Deep currently expects zero
2333 collisions, so your algorithm has to be I<perfect>, so to speak.
2334 Collision detection may be introduced in a later version.
2335
2336
2337
2338 You can specify a custom digest algorithm by calling the static C<set_digest()>
2339 function, passing a reference to a subroutine, and the length of the algorithm's
2340 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2341 objects.  Here is a working example that uses a 256-bit hash from the
2342 I<Digest::SHA256> module.  Please see
2343 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2344
2345         use DBM::Deep;
2346         use Digest::SHA256;
2347
2348         my $context = Digest::SHA256::new(256);
2349
2350         DBM::Deep::set_digest( \&my_digest, 32 );
2351
2352         my $db = DBM::Deep->new( "foo-sha.db" );
2353
2354         $db->{key1} = "value1";
2355         $db->{key2} = "value2";
2356         print "key1: " . $db->{key1} . "\n";
2357         print "key2: " . $db->{key2} . "\n";
2358
2359         undef $db;
2360         exit;
2361
2362         sub my_digest {
2363                 return substr( $context->hash($_[0]), 0, 32 );
2364         }
2365
2366 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2367 of bytes you specify in the C<set_digest()> function (in this case 32).
2368
2369 =head1 CIRCULAR REFERENCES
2370
2371 DBM::Deep has B<experimental> support for circular references.  Meaning you
2372 can have a nested hash key or array element that points to a parent object.
2373 This relationship is stored in the DB file, and is preserved between sessions.
2374 Here is an example:
2375
2376         my $db = DBM::Deep->new( "foo.db" );
2377
2378         $db->{foo} = "bar";
2379         $db->{circle} = $db; # ref to self
2380
2381         print $db->{foo} . "\n"; # prints "foo"
2382         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2383
2384 One catch is, passing the object to a function that recursively walks the
2385 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2386 C<export()> methods) will result in an infinite loop.  The other catch is,
2387 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2388 or C<next_key()> methods), you will get the I<target object's key>, not the
2389 ref's key.  This gets even more interesting with the above example, where
2390 the I<circle> key points to the base DB object, which technically doesn't
2391 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2392 special case.
2393
2394 =head1 CAVEATS / ISSUES / BUGS
2395
2396 This section describes all the known issues with DBM::Deep.  It you have found
2397 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2398
2399 =head2 UNUSED SPACE RECOVERY
2400
2401 One major caveat with DBM::Deep is that space occupied by existing keys and
2402 values is not recovered when they are deleted.  Meaning if you keep deleting
2403 and adding new keys, your file will continuously grow.  I am working on this,
2404 but in the meantime you can call the built-in C<optimize()> method from time to
2405 time (perhaps in a crontab or something) to recover all your unused space.
2406
2407         $db->optimize(); # returns true on success
2408
2409 This rebuilds the ENTIRE database into a new file, then moves it on top of
2410 the original.  The new file will have no unused space, thus it will take up as
2411 little disk space as possible.  Please note that this operation can take
2412 a long time for large files, and you need enough disk space to temporarily hold
2413 2 copies of your DB file.  The temporary file is created in the same directory
2414 as the original, named with a ".tmp" extension, and is deleted when the
2415 operation completes.  Oh, and if locking is enabled, the DB is automatically
2416 locked for the entire duration of the copy.
2417
2418
2419
2420 B<WARNING:> Only call optimize() on the top-level node of the database, and
2421 make sure there are no child references lying around.  DBM::Deep keeps a reference
2422 counter, and if it is greater than 1, optimize() will abort and return undef.
2423
2424 =head2 AUTOVIVIFICATION
2425
2426 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2427 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2428 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2429 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2430 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2431 this does not work:
2432
2433         $db->{foo}->{bar} = "hello";
2434
2435 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2436 being an empty hash.  Try this instead, which works fine:
2437
2438         $db->{foo} = { bar => "hello" };
2439
2440 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2441 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2442 Probably a bug in Perl.
2443
2444 =head2 FILE CORRUPTION
2445
2446 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2447 for a 32-bit signature when opened, but other corruption in files can cause
2448 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2449 stuck in an infinite loop depending on the level of corruption.  File write
2450 operations are not checked for failure (for speed), so if you happen to run
2451 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2452 be addressed in a later version of DBM::Deep.
2453
2454 =head2 DB OVER NFS
2455
2456 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2457 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2458 about setting up your NFS server with a locking daemon, then using lockf() to
2459 lock your files, but your milage may vary there as well.  From what I
2460 understand, there is no real way to do it.  However, if you need access to the
2461 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2462 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2463
2464 =head2 COPYING OBJECTS
2465
2466 Beware of copying tied objects in Perl.  Very strange things can happen.
2467 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2468 returns a new, blessed, tied hash or array to the same level in the DB.
2469
2470         my $copy = $db->clone();
2471
2472 =head2 LARGE ARRAYS
2473
2474 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2475 These functions cause every element in the array to move, which can be murder
2476 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2477 a different location.  This may be addressed in a later version.
2478
2479 =head1 PERFORMANCE
2480
2481 This section discusses DBM::Deep's speed and memory usage.
2482
2483 =head2 SPEED
2484
2485 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2486 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2487 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2488 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2489 with huge databases.  Here is some test data:
2490
2491         Adding 1,000,000 keys to new DB file...
2492
2493         At 100 keys, avg. speed is 2,703 keys/sec
2494         At 200 keys, avg. speed is 2,642 keys/sec
2495         At 300 keys, avg. speed is 2,598 keys/sec
2496         At 400 keys, avg. speed is 2,578 keys/sec
2497         At 500 keys, avg. speed is 2,722 keys/sec
2498         At 600 keys, avg. speed is 2,628 keys/sec
2499         At 700 keys, avg. speed is 2,700 keys/sec
2500         At 800 keys, avg. speed is 2,607 keys/sec
2501         At 900 keys, avg. speed is 2,190 keys/sec
2502         At 1,000 keys, avg. speed is 2,570 keys/sec
2503         At 2,000 keys, avg. speed is 2,417 keys/sec
2504         At 3,000 keys, avg. speed is 1,982 keys/sec
2505         At 4,000 keys, avg. speed is 1,568 keys/sec
2506         At 5,000 keys, avg. speed is 1,533 keys/sec
2507         At 6,000 keys, avg. speed is 1,787 keys/sec
2508         At 7,000 keys, avg. speed is 1,977 keys/sec
2509         At 8,000 keys, avg. speed is 2,028 keys/sec
2510         At 9,000 keys, avg. speed is 2,077 keys/sec
2511         At 10,000 keys, avg. speed is 2,031 keys/sec
2512         At 20,000 keys, avg. speed is 1,970 keys/sec
2513         At 30,000 keys, avg. speed is 2,050 keys/sec
2514         At 40,000 keys, avg. speed is 2,073 keys/sec
2515         At 50,000 keys, avg. speed is 1,973 keys/sec
2516         At 60,000 keys, avg. speed is 1,914 keys/sec
2517         At 70,000 keys, avg. speed is 2,091 keys/sec
2518         At 80,000 keys, avg. speed is 2,103 keys/sec
2519         At 90,000 keys, avg. speed is 1,886 keys/sec
2520         At 100,000 keys, avg. speed is 1,970 keys/sec
2521         At 200,000 keys, avg. speed is 2,053 keys/sec
2522         At 300,000 keys, avg. speed is 1,697 keys/sec
2523         At 400,000 keys, avg. speed is 1,838 keys/sec
2524         At 500,000 keys, avg. speed is 1,941 keys/sec
2525         At 600,000 keys, avg. speed is 1,930 keys/sec
2526         At 700,000 keys, avg. speed is 1,735 keys/sec
2527         At 800,000 keys, avg. speed is 1,795 keys/sec
2528         At 900,000 keys, avg. speed is 1,221 keys/sec
2529         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2530
2531 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2532 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2533 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2534 Run time was 12 min 3 sec.
2535
2536 =head2 MEMORY USAGE
2537
2538 One of the great things about DBM::Deep is that it uses very little memory.
2539 Even with huge databases (1,000,000+ keys) you will not see much increased
2540 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2541 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2542 database handle:
2543
2544           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2545         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2546
2547 Basically the process is taking 2,716K of memory.  And here is the same
2548 process after storing and fetching 1,000,000 keys:
2549
2550           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2551         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2552
2553 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2554 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2555
2556 =head1 DB FILE FORMAT
2557
2558 In case you were interested in the underlying DB file format, it is documented
2559 here in this section.  You don't need to know this to use the module, it's just
2560 included for reference.
2561
2562 =head2 SIGNATURE
2563
2564 DBM::Deep files always start with a 32-bit signature to identify the file type.
2565 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2566 checked when the file is opened.
2567
2568 =head2 TAG
2569
2570 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2571 has a standard header containing the type of data, the length of data, and then
2572 the data itself.  The type is a single character (1 byte), the length is a
2573 32-bit unsigned long in network byte order, and the data is, well, the data.
2574 Here is how it unfolds:
2575
2576 =head2 MASTER INDEX
2577
2578 Immediately after the 32-bit file signature is the I<Master Index> record.
2579 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2580 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2581 depending on how the DBM::Deep object was constructed.
2582
2583
2584
2585 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2586 number).  The first 8-bit char of the MD5 signature is the offset into the
2587 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2588 index element is a file offset of the next tag for the key/element in question,
2589 which is usually a I<Bucket List> tag (see below).
2590
2591
2592
2593 The next tag I<could> be another index, depending on how many keys/elements
2594 exist.  See L<RE-INDEXING> below for details.
2595
2596 =head2 BUCKET LIST
2597
2598 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2599 file offsets to where the actual data is stored.  It starts with a standard
2600 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2601 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2602 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2603 When the list fills up, a I<Re-Index> operation is performed (See
2604 L<RE-INDEXING> below).
2605
2606 =head2 BUCKET
2607
2608 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2609 index/value pair (in array mode).  It starts with a standard tag header with
2610 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2611 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2612 header.  The size reported in the tag header is only for the value, but then,
2613 just after the value is another size (32-bit unsigned long) and then the plain
2614 key itself.  Since the value is likely to be fetched more often than the plain
2615 key, I figured it would be I<slightly> faster to store the value first.
2616
2617
2618
2619 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2620 record for the nested structure, where the process begins all over again.
2621
2622 =head2 RE-INDEXING
2623
2624 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2625 exhausted.  Then, when another key/element comes in, the list is converted to a
2626 new index record.  However, this index will look at the next char in the MD5
2627 hash, and arrange new Bucket List pointers accordingly.  This process is called
2628 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2629 17 (16 + new one) keys/elements are removed from the old Bucket List and
2630 inserted into the new index.  Several new Bucket Lists are created in the
2631 process, as a new MD5 char from the key is being examined (it is unlikely that
2632 the keys will all share the same next char of their MD5s).
2633
2634
2635
2636 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2637 when the Bucket Lists will turn into indexes, but the first round tends to
2638 happen right around 4,000 keys.  You will see a I<slight> decrease in
2639 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2640 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2641 right around 900,000 keys.  This process can continue nearly indefinitely --
2642 right up until the point the I<MD5> signatures start colliding with each other,
2643 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2644 getting struck by lightning while you are walking to cash in your tickets.
2645 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2646 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2647 this is 340 unodecillion, but don't quote me).
2648
2649 =head2 STORING
2650
2651 When a new key/element is stored, the key (or index number) is first ran through
2652 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2653 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2654 for the first char of the signature (in this case I<b>).  If it does not exist,
2655 a new I<Bucket List> is created for our key (and the next 15 future keys that
2656 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2657 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2658 this point, unless we are replacing an existing I<Bucket>), where the actual
2659 data will be stored.
2660
2661 =head2 FETCHING
2662
2663 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2664 (or index number), then walking along the indexes.  If there are enough
2665 keys/elements in this DB level, there might be nested indexes, each linked to
2666 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2667 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2668 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2669 plain key are stored.
2670
2671
2672
2673 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2674 methods.  In this process the indexes are walked systematically, and each key
2675 fetched in increasing MD5 order (which is why it appears random).   Once the
2676 I<Bucket> is found, the value is skipped the plain key returned instead.
2677 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2678 alphabetically sorted.  This only happens on an index-level -- as soon as the
2679 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2680 so it's pretty much undefined how the keys will come out -- just like Perl's
2681 built-in hashes.
2682
2683 =head1 CODE COVERAGE
2684
2685 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover>
2686 report on this module's test suite.
2687
2688 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2689 File                           stmt   bran   cond    sub    pod   time  total
2690 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2691 blib/lib/DBM/Deep.pm           93.7   82.5   71.9   96.5   25.9   82.8   87.9
2692 blib/lib/DBM/Deep/Array.pm     98.8   88.0   90.9  100.0    n/a   12.8   96.3
2693 blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    4.4   92.3
2694 Total                          94.8   83.2   76.5   97.6   25.9  100.0   89.7
2695 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2696
2697 =head1 AUTHOR
2698
2699 Joseph Huckaby, L<jhuckaby@cpan.org>
2700
2701 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2702
2703 =head1 SEE ALSO
2704
2705 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2706 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2707
2708 =head1 LICENSE
2709
2710 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2711 This is free software, you may use it and distribute it under the
2712 same terms as Perl itself.
2713
2714 =cut