lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.98);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     # locking implicitly enables autoflush
 176     if ($args->{locking}) { $args->{autoflush} = 1; }
 177
 178     $self->{root} = exists $args->{root}
 179         ? $args->{root}
 180         : DBM::Deep::_::Root->new( $args );
 181
 182     if (!defined($self->fh)) { $self->_open(); }
 183
 184     return $self;
 185 }
 186
 187 sub TIEHASH {
 188     shift;
 189     require DBM::Deep::Hash;
 190     return DBM::Deep::Hash->TIEHASH( @_ );
 191 }
 192
 193 sub TIEARRAY {
 194     shift;
 195     require DBM::Deep::Array;
 196     return DBM::Deep::Array->TIEARRAY( @_ );
 197 }
 198
 199 #XXX Unneeded now ...
 200 #sub DESTROY {
 201 #}
 202
 203 sub _open {
 204         ##
 205         # Open a fh to the database, create if nonexistent.
 206         # Make sure file signature matches DBM::Deep spec.
 207         ##
 208     my $self = $_[0]->_get_self;
 209
 210         if (defined($self->fh)) { $self->_close(); }
 211
 212     eval {
 213         # Theoretically, adding O_BINARY should remove the need for the binmode
 214         # Of course, testing it is going to be ... interesting.
 215         my $flags = O_RDWR | O_CREAT | O_BINARY;
 216
 217         my $fh;
 218         sysopen( $fh, $self->root->{file}, $flags )
 219             or $fh = undef;
 220         $self->root->{fh} = $fh;
 221     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 222         if (! defined($self->fh)) {
 223                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 224         }
 225
 226     my $fh = $self->fh;
 227
 228     #XXX Can we remove this by using the right sysopen() flags?
 229     # Maybe ... q.v. above
 230     binmode $fh; # for win32
 231
 232     if ($self->root->{autoflush}) {
 233         my $old = select $fh;
 234         $|=1;
 235         select $old;
 236     }
 237
 238     # Set the
 239     seek($fh, 0, SEEK_SET);
 240
 241     my $signature;
 242     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 243
 244     ##
 245     # File is empty -- write signature and master index
 246     ##
 247     if (!$bytes_read) {
 248         seek($fh, 0, SEEK_SET);
 249         print($fh SIG_FILE);
 250         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 251
 252         my $plain_key = "[base]";
 253         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 254
 255         # Flush the filehandle
 256         my $old_fh = select $fh;
 257         my $old_af = $|;
 258         $| = 1;
 259         $| = $old_af;
 260         select $old_fh;
 261
 262         my @stats = stat($fh);
 263         $self->root->{inode} = $stats[1];
 264         $self->root->{end} = $stats[7];
 265
 266         return 1;
 267     }
 268
 269     ##
 270     # Check signature was valid
 271     ##
 272     unless ($signature eq SIG_FILE) {
 273         $self->_close();
 274         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 275     }
 276
 277         my @stats = stat($fh);
 278         $self->root->{inode} = $stats[1];
 279     $self->root->{end} = $stats[7];
 280
 281     ##
 282     # Get our type from master index signature
 283     ##
 284     my $tag = $self->_load_tag($self->base_offset);
 285
 286 #XXX We probably also want to store the hash algorithm name and not assume anything
 287 #XXX The cool thing would be to allow a different hashing algorithm at every level
 288
 289     if (!$tag) {
 290         return $self->_throw_error("Corrupted file, no master index record");
 291     }
 292     if ($self->{type} ne $tag->{signature}) {
 293         return $self->_throw_error("File type mismatch");
 294     }
 295
 296     return 1;
 297 }
 298
 299 sub _close {
 300         ##
 301         # Close database fh
 302         ##
 303     my $self = $_[0]->_get_self;
 304     close $self->root->{fh} if $self->root->{fh};
 305     $self->root->{fh} = undef;
 306 }
 307
 308 sub _create_tag {
 309         ##
 310         # Given offset, signature and content, create tag and write to disk
 311         ##
 312         my ($self, $offset, $sig, $content) = @_;
 313         my $size = length($content);
 314
 315     my $fh = $self->fh;
 316
 317         seek($fh, $offset, SEEK_SET);
 318         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 319
 320         if ($offset == $self->root->{end}) {
 321                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 322         }
 323
 324         return {
 325                 signature => $sig,
 326                 size => $size,
 327                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 328                 content => $content
 329         };
 330 }
 331
 332 sub _load_tag {
 333         ##
 334         # Given offset, load single tag and return signature, size and data
 335         ##
 336         my $self = shift;
 337         my $offset = shift;
 338
 339     my $fh = $self->fh;
 340
 341         seek($fh, $offset, SEEK_SET);
 342         if (eof $fh) { return undef; }
 343
 344         my $sig;
 345         read( $fh, $sig, SIG_SIZE);
 346
 347         my $size;
 348         read( $fh, $size, $DATA_LENGTH_SIZE);
 349         $size = unpack($DATA_LENGTH_PACK, $size);
 350
 351         my $buffer;
 352         read( $fh, $buffer, $size);
 353
 354         return {
 355                 signature => $sig,
 356                 size => $size,
 357                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 358                 content => $buffer
 359         };
 360 }
 361
 362 sub _index_lookup {
 363         ##
 364         # Given index tag, lookup single entry in index and return .
 365         ##
 366         my $self = shift;
 367         my ($tag, $index) = @_;
 368
 369         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 370         if (!$location) { return; }
 371
 372         return $self->_load_tag( $location );
 373 }
 374
 375 sub _add_bucket {
 376         ##
 377         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 378         # plain (undigested) key and value.
 379         ##
 380         my $self = shift;
 381         my ($tag, $md5, $plain_key, $value) = @_;
 382         my $keys = $tag->{content};
 383         my $location = 0;
 384         my $result = 2;
 385
 386         # added ref() check first to avoid eval and runtime exception for every
 387         # scalar value being stored.  performance tweak.
 388     my $is_dbm_deep = ref($value) && eval { $value->isa( 'DBM::Deep' ) };
 389
 390         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 391
 392     my $fh = $self->fh;
 393
 394         ##
 395         # Iterate through buckets, seeing if this is a new entry or a replace.
 396         ##
 397         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 398                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 399                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 400                 if (!$subloc) {
 401                         ##
 402                         # Found empty bucket (end of list).  Populate and exit loop.
 403                         ##
 404                         $result = 2;
 405
 406             $location = $internal_ref
 407                 ? $value->base_offset
 408                 : $self->root->{end};
 409
 410                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 411                         print($fh $md5 . pack($LONG_PACK, $location) );
 412                         last;
 413                 }
 414                 elsif ($md5 eq $key) {
 415                         ##
 416                         # Found existing bucket with same key.  Replace with new value.
 417                         ##
 418                         $result = 1;
 419
 420                         if ($internal_ref) {
 421                                 $location = $value->base_offset;
 422                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 423                                 print($fh $md5 . pack($LONG_PACK, $location) );
 424                         }
 425                         else {
 426                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 427                                 my $size;
 428                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 429
 430                                 ##
 431                                 # If value is a hash, array, or raw value with equal or less size, we can
 432                                 # reuse the same content area of the database.  Otherwise, we have to create
 433                                 # a new content area at the EOF.
 434                                 ##
 435                                 my $actual_length;
 436                 my $r = Scalar::Util::reftype( $value ) || '';
 437                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 438                         $actual_length = $INDEX_SIZE;
 439
 440                         # if autobless is enabled, must also take into consideration
 441                         # the class name, as it is stored along with key/value.
 442                         if ( $self->root->{autobless} ) {
 443                                                 my $value_class = Scalar::Util::blessed($value);
 444                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 445                                                         $actual_length += length($value_class);
 446                                                 }
 447                                         } # autobless
 448                 }
 449                                 else { $actual_length = length($value); }
 450
 451                                 if ($actual_length <= $size) {
 452                                         $location = $subloc;
 453                                 }
 454                                 else {
 455                                         $location = $self->root->{end};
 456                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 457                                         print($fh pack($LONG_PACK, $location) );
 458                                 }
 459                         }
 460                         last;
 461                 }
 462         } # i loop
 463
 464         ##
 465         # If this is an internal reference, return now.
 466         # No need to write value or plain key
 467         ##
 468         if ($internal_ref) {
 469         return $result;
 470     }
 471
 472         ##
 473         # If bucket didn't fit into list, split into a new index level
 474         ##
 475         if (!$location) {
 476                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 477                 print($fh pack($LONG_PACK, $self->root->{end}) );
 478
 479                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 480                 my @offsets = ();
 481
 482                 $keys .= $md5 . pack($LONG_PACK, 0);
 483
 484                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 485                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 486                         if ($key) {
 487                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 488                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 489
 490                                 if ($offsets[$num]) {
 491                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 492                                         seek($fh, $offset, SEEK_SET);
 493                                         my $subkeys;
 494                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 495
 496                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 497                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 498                                                 if (!$subloc) {
 499                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 500                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 501                                                         last;
 502                                                 }
 503                                         } # k loop
 504                                 }
 505                                 else {
 506                                         $offsets[$num] = $self->root->{end};
 507                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 508                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 509
 510                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 511
 512                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 513                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 514                                 }
 515                         } # key is real
 516                 } # i loop
 517
 518                 $location ||= $self->root->{end};
 519         } # re-index bucket list
 520
 521         ##
 522         # Seek to content area and store signature, value and plaintext key
 523         ##
 524         if ($location) {
 525                 my $content_length;
 526                 seek($fh, $location, SEEK_SET);
 527
 528                 ##
 529                 # Write signature based on content type, set content length and write actual value.
 530                 ##
 531         my $r = Scalar::Util::reftype($value) || '';
 532                 if ($r eq 'HASH') {
 533                         print($fh TYPE_HASH );
 534                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 535                         $content_length = $INDEX_SIZE;
 536                 }
 537                 elsif ($r eq 'ARRAY') {
 538                         print($fh TYPE_ARRAY );
 539                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 540                         $content_length = $INDEX_SIZE;
 541                 }
 542                 elsif (!defined($value)) {
 543                         print($fh SIG_NULL );
 544                         print($fh pack($DATA_LENGTH_PACK, 0) );
 545                         $content_length = 0;
 546                 }
 547                 else {
 548                         print($fh SIG_DATA );
 549                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 550                         $content_length = length($value);
 551                 }
 552
 553                 ##
 554                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 555                 ##
 556                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 557
 558                 ##
 559                 # If value is blessed, preserve class name
 560                 ##
 561                 if ( $self->root->{autobless} ) {
 562             my $value_class = Scalar::Util::blessed($value);
 563             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 564                 ##
 565                 # Blessed ref -- will restore later
 566                 ##
 567                 print($fh chr(1) );
 568                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 569                 $content_length += 1;
 570                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 571             }
 572             else {
 573                 print($fh chr(0) );
 574                 $content_length += 1;
 575             }
 576         }
 577
 578                 ##
 579                 # If this is a new content area, advance EOF counter
 580                 ##
 581                 if ($location == $self->root->{end}) {
 582                         $self->root->{end} += SIG_SIZE;
 583                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 584                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 585                 }
 586
 587                 ##
 588                 # If content is a hash or array, create new child DBM::Deep object and
 589                 # pass each key or element to it.
 590                 ##
 591                 if ($r eq 'HASH') {
 592                         my $branch = DBM::Deep->new(
 593                                 type => TYPE_HASH,
 594                                 base_offset => $location,
 595                                 root => $self->root,
 596                         );
 597                         foreach my $key (keys %{$value}) {
 598                 $branch->STORE( $key, $value->{$key} );
 599                         }
 600                 }
 601                 elsif ($r eq 'ARRAY') {
 602                         my $branch = DBM::Deep->new(
 603                                 type => TYPE_ARRAY,
 604                                 base_offset => $location,
 605                                 root => $self->root,
 606                         );
 607                         my $index = 0;
 608                         foreach my $element (@{$value}) {
 609                 $branch->STORE( $index, $element );
 610                                 $index++;
 611                         }
 612                 }
 613
 614                 return $result;
 615         }
 616
 617         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 618 }
 619
 620 sub _get_bucket_value {
 621         ##
 622         # Fetch single value given tag and MD5 digested key.
 623         ##
 624         my $self = shift;
 625         my ($tag, $md5) = @_;
 626         my $keys = $tag->{content};
 627
 628     my $fh = $self->fh;
 629
 630         ##
 631         # Iterate through buckets, looking for a key match
 632         ##
 633     BUCKET:
 634         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 635                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 636                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 637
 638                 if (!$subloc) {
 639                         ##
 640                         # Hit end of list, no match
 641                         ##
 642                         return;
 643                 }
 644
 645         if ( $md5 ne $key ) {
 646             next BUCKET;
 647         }
 648
 649         ##
 650         # Found match -- seek to offset and read signature
 651         ##
 652         my $signature;
 653         seek($fh, $subloc, SEEK_SET);
 654         read( $fh, $signature, SIG_SIZE);
 655
 656         ##
 657         # If value is a hash or array, return new DBM::Deep object with correct offset
 658         ##
 659         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 660             my $obj = DBM::Deep->new(
 661                 type => $signature,
 662                 base_offset => $subloc,
 663                 root => $self->root
 664             );
 665
 666             if ($self->root->{autobless}) {
 667                 ##
 668                 # Skip over value and plain key to see if object needs
 669                 # to be re-blessed
 670                 ##
 671                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 672
 673                 my $size;
 674                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 675                 if ($size) { seek($fh, $size, SEEK_CUR); }
 676
 677                 my $bless_bit;
 678                 read( $fh, $bless_bit, 1);
 679                 if (ord($bless_bit)) {
 680                     ##
 681                     # Yes, object needs to be re-blessed
 682                     ##
 683                     my $class_name;
 684                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 685                     if ($size) { read( $fh, $class_name, $size); }
 686                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 687                 }
 688             }
 689
 690             return $obj;
 691         }
 692
 693         ##
 694         # Otherwise return actual value
 695         ##
 696         elsif ($signature eq SIG_DATA) {
 697             my $size;
 698             my $value = '';
 699             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 700             if ($size) { read( $fh, $value, $size); }
 701             return $value;
 702         }
 703
 704         ##
 705         # Key exists, but content is null
 706         ##
 707         else { return; }
 708         } # i loop
 709
 710         return;
 711 }
 712
 713 sub _delete_bucket {
 714         ##
 715         # Delete single key/value pair given tag and MD5 digested key.
 716         ##
 717         my $self = shift;
 718         my ($tag, $md5) = @_;
 719         my $keys = $tag->{content};
 720
 721     my $fh = $self->fh;
 722
 723         ##
 724         # Iterate through buckets, looking for a key match
 725         ##
 726     BUCKET:
 727         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 728                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 729                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 730
 731                 if (!$subloc) {
 732                         ##
 733                         # Hit end of list, no match
 734                         ##
 735                         return;
 736                 }
 737
 738         if ( $md5 ne $key ) {
 739             next BUCKET;
 740         }
 741
 742         ##
 743         # Matched key -- delete bucket and return
 744         ##
 745         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 746         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 747         print($fh chr(0) x $BUCKET_SIZE );
 748
 749         return 1;
 750         } # i loop
 751
 752         return;
 753 }
 754
 755 sub _bucket_exists {
 756         ##
 757         # Check existence of single key given tag and MD5 digested key.
 758         ##
 759         my $self = shift;
 760         my ($tag, $md5) = @_;
 761         my $keys = $tag->{content};
 762
 763         ##
 764         # Iterate through buckets, looking for a key match
 765         ##
 766     BUCKET:
 767         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 768                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 769                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 770
 771                 if (!$subloc) {
 772                         ##
 773                         # Hit end of list, no match
 774                         ##
 775                         return;
 776                 }
 777
 778         if ( $md5 ne $key ) {
 779             next BUCKET;
 780         }
 781
 782         ##
 783         # Matched key -- return true
 784         ##
 785         return 1;
 786         } # i loop
 787
 788         return;
 789 }
 790
 791 sub _find_bucket_list {
 792         ##
 793         # Locate offset for bucket list, given digested key
 794         ##
 795         my $self = shift;
 796         my $md5 = shift;
 797
 798         ##
 799         # Locate offset for bucket list using digest index system
 800         ##
 801         my $ch = 0;
 802         my $tag = $self->_load_tag($self->base_offset);
 803         if (!$tag) { return; }
 804
 805         while ($tag->{signature} ne SIG_BLIST) {
 806                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 807                 if (!$tag) { return; }
 808                 $ch++;
 809         }
 810
 811         return $tag;
 812 }
 813
 814 sub _traverse_index {
 815         ##
 816         # Scan index and recursively step into deeper levels, looking for next key.
 817         ##
 818     my ($self, $offset, $ch, $force_return_next) = @_;
 819     $force_return_next = undef unless $force_return_next;
 820
 821         my $tag = $self->_load_tag( $offset );
 822
 823     my $fh = $self->fh;
 824
 825         if ($tag->{signature} ne SIG_BLIST) {
 826                 my $content = $tag->{content};
 827                 my $start;
 828                 if ($self->{return_next}) { $start = 0; }
 829                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 830
 831                 for (my $index = $start; $index < 256; $index++) {
 832                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 833                         if ($subloc) {
 834                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 835                                 if (defined($result)) { return $result; }
 836                         }
 837                 } # index loop
 838
 839                 $self->{return_next} = 1;
 840         } # tag is an index
 841
 842         elsif ($tag->{signature} eq SIG_BLIST) {
 843                 my $keys = $tag->{content};
 844                 if ($force_return_next) { $self->{return_next} = 1; }
 845
 846                 ##
 847                 # Iterate through buckets, looking for a key match
 848                 ##
 849                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 850                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 851                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 852
 853                         if (!$subloc) {
 854                                 ##
 855                                 # End of bucket list -- return to outer loop
 856                                 ##
 857                                 $self->{return_next} = 1;
 858                                 last;
 859                         }
 860                         elsif ($key eq $self->{prev_md5}) {
 861                                 ##
 862                                 # Located previous key -- return next one found
 863                                 ##
 864                                 $self->{return_next} = 1;
 865                                 next;
 866                         }
 867                         elsif ($self->{return_next}) {
 868                                 ##
 869                                 # Seek to bucket location and skip over signature
 870                                 ##
 871                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 872
 873                                 ##
 874                                 # Skip over value to get to plain key
 875                                 ##
 876                                 my $size;
 877                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 878                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 879
 880                                 ##
 881                                 # Read in plain key and return as scalar
 882                                 ##
 883                                 my $plain_key;
 884                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 885                                 if ($size) { read( $fh, $plain_key, $size); }
 886
 887                                 return $plain_key;
 888                         }
 889                 } # bucket loop
 890
 891                 $self->{return_next} = 1;
 892         } # tag is a bucket list
 893
 894         return;
 895 }
 896
 897 sub _get_next_key {
 898         ##
 899         # Locate next key, given digested previous one
 900         ##
 901     my $self = $_[0]->_get_self;
 902
 903         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 904         $self->{return_next} = 0;
 905
 906         ##
 907         # If the previous key was not specifed, start at the top and
 908         # return the first one found.
 909         ##
 910         if (!$self->{prev_md5}) {
 911                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 912                 $self->{return_next} = 1;
 913         }
 914
 915         return $self->_traverse_index( $self->base_offset, 0 );
 916 }
 917
 918 sub lock {
 919         ##
 920         # If db locking is set, flock() the db file.  If called multiple
 921         # times before unlock(), then the same number of unlocks() must
 922         # be called before the lock is released.
 923         ##
 924     my $self = $_[0]->_get_self;
 925         my $type = $_[1];
 926     $type = LOCK_EX unless defined $type;
 927
 928         if (!defined($self->fh)) { return; }
 929
 930         if ($self->root->{locking}) {
 931                 if (!$self->root->{locked}) {
 932                         flock($self->fh, $type);
 933
 934                         # refresh end counter in case file has changed size
 935                         my @stats = stat($self->root->{file});
 936                         $self->root->{end} = $stats[7];
 937
 938                         # double-check file inode, in case another process
 939                         # has optimize()d our file while we were waiting.
 940                         if ($stats[1] != $self->root->{inode}) {
 941                                 $self->_open(); # re-open
 942                                 flock($self->fh, $type); # re-lock
 943                                 $self->root->{end} = (stat($self->fh))[7]; # re-end
 944                         }
 945                 }
 946                 $self->root->{locked}++;
 947
 948         return 1;
 949         }
 950
 951     return;
 952 }
 953
 954 sub unlock {
 955         ##
 956         # If db locking is set, unlock the db file.  See note in lock()
 957         # regarding calling lock() multiple times.
 958         ##
 959     my $self = $_[0]->_get_self;
 960
 961         if (!defined($self->fh)) { return; }
 962
 963         if ($self->root->{locking} && $self->root->{locked} > 0) {
 964                 $self->root->{locked}--;
 965                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 966
 967         return 1;
 968         }
 969
 970     return;
 971 }
 972
 973 #XXX These uses of ref() need verified
 974 sub _copy_node {
 975         ##
 976         # Copy single level of keys or elements to new DB handle.
 977         # Recurse for nested structures
 978         ##
 979     my $self = $_[0]->_get_self;
 980         my $db_temp = $_[1];
 981
 982         if ($self->type eq TYPE_HASH) {
 983                 my $key = $self->first_key();
 984                 while ($key) {
 985                         my $value = $self->get($key);
 986 #XXX This doesn't work with autobless
 987                         if (!ref($value)) { $db_temp->{$key} = $value; }
 988                         else {
 989                                 my $type = $value->type;
 990                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 991                                 else { $db_temp->{$key} = []; }
 992                                 $value->_copy_node( $db_temp->{$key} );
 993                         }
 994                         $key = $self->next_key($key);
 995                 }
 996         }
 997         else {
 998                 my $length = $self->length();
 999                 for (my $index = 0; $index < $length; $index++) {
1000                         my $value = $self->get($index);
1001                         if (!ref($value)) { $db_temp->[$index] = $value; }
1002             #XXX NO tests for this code
1003                         else {
1004                                 my $type = $value->type;
1005                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
1006                                 else { $db_temp->[$index] = []; }
1007                                 $value->_copy_node( $db_temp->[$index] );
1008                         }
1009                 }
1010         }
1011 }
1012
1013 sub export {
1014         ##
1015         # Recursively export into standard Perl hashes and arrays.
1016         ##
1017     my $self = $_[0]->_get_self;
1018
1019         my $temp;
1020         if ($self->type eq TYPE_HASH) { $temp = {}; }
1021         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1022
1023         $self->lock();
1024         $self->_copy_node( $temp );
1025         $self->unlock();
1026
1027         return $temp;
1028 }
1029
1030 sub import {
1031         ##
1032         # Recursively import Perl hash/array structure
1033         ##
1034     #XXX This use of ref() seems to be ok
1035         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1036
1037     my $self = $_[0]->_get_self;
1038         my $struct = $_[1];
1039
1040     #XXX This use of ref() seems to be ok
1041         if (!ref($struct)) {
1042                 ##
1043                 # struct is not a reference, so just import based on our type
1044                 ##
1045                 shift @_;
1046
1047                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1048                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1049         }
1050
1051     my $r = Scalar::Util::reftype($struct) || '';
1052         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1053                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1054         }
1055         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1056                 $self->push( @$struct );
1057         }
1058         else {
1059                 return $self->_throw_error("Cannot import: type mismatch");
1060         }
1061
1062         return 1;
1063 }
1064
1065 sub optimize {
1066         ##
1067         # Rebuild entire database into new file, then move
1068         # it back on top of original.
1069         ##
1070     my $self = $_[0]->_get_self;
1071
1072 #XXX Need to create a new test for this
1073 #       if ($self->root->{links} > 1) {
1074 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1075 #       }
1076
1077         my $db_temp = DBM::Deep->new(
1078                 file => $self->root->{file} . '.tmp',
1079                 type => $self->type
1080         );
1081         if (!$db_temp) {
1082                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1083         }
1084
1085         $self->lock();
1086         $self->_copy_node( $db_temp );
1087         undef $db_temp;
1088
1089         ##
1090         # Attempt to copy user, group and permissions over to new file
1091         ##
1092         my @stats = stat($self->fh);
1093         my $perms = $stats[2] & 07777;
1094         my $uid = $stats[4];
1095         my $gid = $stats[5];
1096         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1097         chmod( $perms, $self->root->{file} . '.tmp' );
1098
1099     # q.v. perlport for more information on this variable
1100     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1101                 ##
1102                 # Potential race condition when optmizing on Win32 with locking.
1103                 # The Windows filesystem requires that the filehandle be closed
1104                 # before it is overwritten with rename().  This could be redone
1105                 # with a soft copy.
1106                 ##
1107                 $self->unlock();
1108                 $self->_close();
1109         }
1110
1111         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1112                 unlink $self->root->{file} . '.tmp';
1113                 $self->unlock();
1114                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1115         }
1116
1117         $self->unlock();
1118         $self->_close();
1119         $self->_open();
1120
1121         return 1;
1122 }
1123
1124 sub clone {
1125         ##
1126         # Make copy of object and return
1127         ##
1128     my $self = $_[0]->_get_self;
1129
1130         return DBM::Deep->new(
1131                 type => $self->type,
1132                 base_offset => $self->base_offset,
1133                 root => $self->root
1134         );
1135 }
1136
1137 {
1138     my %is_legal_filter = map {
1139         $_ => ~~1,
1140     } qw(
1141         store_key store_value
1142         fetch_key fetch_value
1143     );
1144
1145     sub set_filter {
1146         ##
1147         # Setup filter function for storing or fetching the key or value
1148         ##
1149         my $self = $_[0]->_get_self;
1150         my $type = lc $_[1];
1151         my $func = $_[2] ? $_[2] : undef;
1152
1153         if ( $is_legal_filter{$type} ) {
1154             $self->root->{"filter_$type"} = $func;
1155             return 1;
1156         }
1157
1158         return;
1159     }
1160 }
1161
1162 ##
1163 # Accessor methods
1164 ##
1165
1166 sub root {
1167         ##
1168         # Get access to the root structure
1169         ##
1170     my $self = $_[0]->_get_self;
1171         return $self->{root};
1172 }
1173
1174 sub fh {
1175         ##
1176         # Get access to the raw fh
1177         ##
1178     #XXX It will be useful, though, when we split out HASH and ARRAY
1179     my $self = $_[0]->_get_self;
1180         return $self->root->{fh};
1181 }
1182
1183 sub type {
1184         ##
1185         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1186         ##
1187     my $self = $_[0]->_get_self;
1188         return $self->{type};
1189 }
1190
1191 sub base_offset {
1192         ##
1193         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1194         ##
1195     my $self = $_[0]->_get_self;
1196         return $self->{base_offset};
1197 }
1198
1199 sub error {
1200         ##
1201         # Get last error string, or undef if no error
1202         ##
1203         return $_[0]
1204         #? ( _get_self($_[0])->{root}->{error} or undef )
1205         ? ( $_[0]->_get_self->{root}->{error} or undef )
1206         : $@;
1207 }
1208
1209 ##
1210 # Utility methods
1211 ##
1212
1213 sub _throw_error {
1214         ##
1215         # Store error string in self
1216         ##
1217     my $self = $_[0]->_get_self;
1218         my $error_text = $_[1];
1219
1220     if ( Scalar::Util::blessed $self ) {
1221         $self->root->{error} = $error_text;
1222
1223         unless ($self->root->{debug}) {
1224             die "DBM::Deep: $error_text\n";
1225         }
1226
1227         warn "DBM::Deep: $error_text\n";
1228         return;
1229     }
1230     else {
1231         die "DBM::Deep: $error_text\n";
1232     }
1233 }
1234
1235 sub clear_error {
1236         ##
1237         # Clear error state
1238         ##
1239     my $self = $_[0]->_get_self;
1240
1241         undef $self->root->{error};
1242 }
1243
1244 sub precalc_sizes {
1245         ##
1246         # Precalculate index, bucket and bucket list sizes
1247         ##
1248
1249     #XXX I don't like this ...
1250     set_pack() unless defined $LONG_SIZE;
1251
1252         $INDEX_SIZE = 256 * $LONG_SIZE;
1253         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1254         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1255 }
1256
1257 sub set_pack {
1258         ##
1259         # Set pack/unpack modes (see file header for more)
1260         ##
1261     my ($long_s, $long_p, $data_s, $data_p) = @_;
1262
1263     $LONG_SIZE = $long_s ? $long_s : 4;
1264     $LONG_PACK = $long_p ? $long_p : 'N';
1265
1266     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1267     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1268
1269         precalc_sizes();
1270 }
1271
1272 sub set_digest {
1273         ##
1274         # Set key digest function (default is MD5)
1275         ##
1276     my ($digest_func, $hash_size) = @_;
1277
1278     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1279     $HASH_SIZE = $hash_size ? $hash_size : 16;
1280
1281         precalc_sizes();
1282 }
1283
1284 ##
1285 # tie() methods (hashes and arrays)
1286 ##
1287
1288 sub STORE {
1289         ##
1290         # Store single hash key/value or array element in database.
1291         ##
1292     my $self = $_[0]->_get_self;
1293         my $key = $_[1];
1294
1295     # User may be storing a hash, in which case we do not want it run
1296     # through the filtering system
1297         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1298         ? $self->root->{filter_store_value}->($_[2])
1299         : $_[2];
1300
1301         my $md5 = $DIGEST_FUNC->($key);
1302
1303         ##
1304         # Make sure file is open
1305         ##
1306         if (!defined($self->fh) && !$self->_open()) {
1307                 return;
1308         }
1309         ##
1310
1311         ##
1312         # Request exclusive lock for writing
1313         ##
1314         $self->lock( LOCK_EX );
1315
1316         my $fh = $self->fh;
1317
1318         ##
1319         # Locate offset for bucket list using digest index system
1320         ##
1321         my $tag = $self->_load_tag($self->base_offset);
1322         if (!$tag) {
1323                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1324         }
1325
1326         my $ch = 0;
1327         while ($tag->{signature} ne SIG_BLIST) {
1328                 my $num = ord(substr($md5, $ch, 1));
1329                 my $new_tag = $self->_index_lookup($tag, $num);
1330                 if (!$new_tag) {
1331                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1332                         seek($fh, $ref_loc, SEEK_SET);
1333                         print($fh pack($LONG_PACK, $self->root->{end}) );
1334
1335                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1336                         $tag->{ref_loc} = $ref_loc;
1337                         $tag->{ch} = $ch;
1338                         last;
1339                 }
1340                 else {
1341                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1342                         $tag = $new_tag;
1343                         $tag->{ref_loc} = $ref_loc;
1344                         $tag->{ch} = $ch;
1345                 }
1346                 $ch++;
1347         }
1348
1349         ##
1350         # Add key/value to bucket list
1351         ##
1352         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1353
1354         $self->unlock();
1355
1356         return $result;
1357 }
1358
1359 sub FETCH {
1360         ##
1361         # Fetch single value or element given plain key or array index
1362         ##
1363     my $self = shift->_get_self;
1364     my $key = shift;
1365
1366         ##
1367         # Make sure file is open
1368         ##
1369         if (!defined($self->fh)) { $self->_open(); }
1370
1371         my $md5 = $DIGEST_FUNC->($key);
1372
1373         ##
1374         # Request shared lock for reading
1375         ##
1376         $self->lock( LOCK_SH );
1377
1378         my $tag = $self->_find_bucket_list( $md5 );
1379         if (!$tag) {
1380                 $self->unlock();
1381                 return;
1382         }
1383
1384         ##
1385         # Get value from bucket list
1386         ##
1387         my $result = $self->_get_bucket_value( $tag, $md5 );
1388
1389         $self->unlock();
1390
1391     #XXX What is ref() checking here?
1392     #YYY Filters only apply on scalar values, so the ref check is making
1393     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1394         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1395         ? $self->root->{filter_fetch_value}->($result)
1396         : $result;
1397 }
1398
1399 sub DELETE {
1400         ##
1401         # Delete single key/value pair or element given plain key or array index
1402         ##
1403     my $self = $_[0]->_get_self;
1404         my $key = $_[1];
1405
1406         my $md5 = $DIGEST_FUNC->($key);
1407
1408         ##
1409         # Make sure file is open
1410         ##
1411         if (!defined($self->fh)) { $self->_open(); }
1412
1413         ##
1414         # Request exclusive lock for writing
1415         ##
1416         $self->lock( LOCK_EX );
1417
1418         my $tag = $self->_find_bucket_list( $md5 );
1419         if (!$tag) {
1420                 $self->unlock();
1421                 return;
1422         }
1423
1424         ##
1425         # Delete bucket
1426         ##
1427     my $value = $self->_get_bucket_value( $tag, $md5 );
1428         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1429         $value = $self->root->{filter_fetch_value}->($value);
1430     }
1431
1432         my $result = $self->_delete_bucket( $tag, $md5 );
1433
1434         ##
1435         # If this object is an array and the key deleted was on the end of the stack,
1436         # decrement the length variable.
1437         ##
1438
1439         $self->unlock();
1440
1441         return $value;
1442 }
1443
1444 sub EXISTS {
1445         ##
1446         # Check if a single key or element exists given plain key or array index
1447         ##
1448     my $self = $_[0]->_get_self;
1449         my $key = $_[1];
1450
1451         my $md5 = $DIGEST_FUNC->($key);
1452
1453         ##
1454         # Make sure file is open
1455         ##
1456         if (!defined($self->fh)) { $self->_open(); }
1457
1458         ##
1459         # Request shared lock for reading
1460         ##
1461         $self->lock( LOCK_SH );
1462
1463         my $tag = $self->_find_bucket_list( $md5 );
1464
1465         ##
1466         # For some reason, the built-in exists() function returns '' for false
1467         ##
1468         if (!$tag) {
1469                 $self->unlock();
1470                 return '';
1471         }
1472
1473         ##
1474         # Check if bucket exists and return 1 or ''
1475         ##
1476         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1477
1478         $self->unlock();
1479
1480         return $result;
1481 }
1482
1483 sub CLEAR {
1484         ##
1485         # Clear all keys from hash, or all elements from array.
1486         ##
1487     my $self = $_[0]->_get_self;
1488
1489         ##
1490         # Make sure file is open
1491         ##
1492         if (!defined($self->fh)) { $self->_open(); }
1493
1494         ##
1495         # Request exclusive lock for writing
1496         ##
1497         $self->lock( LOCK_EX );
1498
1499     my $fh = $self->fh;
1500
1501         seek($fh, $self->base_offset, SEEK_SET);
1502         if (eof $fh) {
1503                 $self->unlock();
1504                 return;
1505         }
1506
1507         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1508
1509         $self->unlock();
1510
1511         return 1;
1512 }
1513
1514 ##
1515 # Public method aliases
1516 ##
1517 sub put { (shift)->STORE( @_ ) }
1518 sub store { (shift)->STORE( @_ ) }
1519 sub get { (shift)->FETCH( @_ ) }
1520 sub fetch { (shift)->FETCH( @_ ) }
1521 sub delete { (shift)->DELETE( @_ ) }
1522 sub exists { (shift)->EXISTS( @_ ) }
1523 sub clear { (shift)->CLEAR( @_ ) }
1524
1525 package DBM::Deep::_::Root;
1526
1527 sub new {
1528     my $class = shift;
1529     my ($args) = @_;
1530
1531     my $self = bless {
1532         file => undef,
1533         fh => undef,
1534         end => 0,
1535         autoflush => undef,
1536         locking => undef,
1537         debug => undef,
1538         filter_store_key => undef,
1539         filter_store_value => undef,
1540         filter_fetch_key => undef,
1541         filter_fetch_value => undef,
1542         autobless => undef,
1543         locked => 0,
1544         %$args,
1545     }, $class;
1546
1547     return $self;
1548 }
1549
1550 sub DESTROY {
1551     my $self = shift;
1552     return unless $self;
1553
1554     close $self->{fh} if $self->{fh};
1555
1556     return;
1557 }
1558
1559 1;
1560
1561 __END__
1562
1563 =head1 NAME
1564
1565 DBM::Deep - A pure perl multi-level hash/array DBM
1566
1567 =head1 SYNOPSIS
1568
1569   use DBM::Deep;
1570   my $db = DBM::Deep->new( "foo.db" );
1571
1572   $db->{key} = 'value'; # tie() style
1573   print $db->{key};
1574
1575   $db->put('key' => 'value'); # OO style
1576   print $db->get('key');
1577
1578   # true multi-level support
1579   $db->{my_complex} = [
1580         'hello', { perl => 'rules' },
1581         42, 99,
1582   ];
1583
1584 =head1 DESCRIPTION
1585
1586 A unique flat-file database module, written in pure perl.  True
1587 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1588 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1589 handle millions of keys and unlimited hash levels without significant
1590 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1591 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1592 Mac OS X and Windows.
1593
1594 =head1 INSTALLATION
1595
1596 Hopefully you are using Perl's excellent CPAN module, which will download
1597 and install the module for you.  If not, get the tarball, and run these
1598 commands:
1599
1600         tar zxf DBM-Deep-*
1601         cd DBM-Deep-*
1602         perl Makefile.PL
1603         make
1604         make test
1605         make install
1606
1607 =head1 SETUP
1608
1609 Construction can be done OO-style (which is the recommended way), or using
1610 Perl's tie() function.  Both are examined here.
1611
1612 =head2 OO CONSTRUCTION
1613
1614 The recommended way to construct a DBM::Deep object is to use the new()
1615 method, which gets you a blessed, tied hash or array reference.
1616
1617         my $db = DBM::Deep->new( "foo.db" );
1618
1619 This opens a new database handle, mapped to the file "foo.db".  If this
1620 file does not exist, it will automatically be created.  DB files are
1621 opened in "r+" (read/write) mode, and the type of object returned is a
1622 hash, unless otherwise specified (see L<OPTIONS> below).
1623
1624 You can pass a number of options to the constructor to specify things like
1625 locking, autoflush, etc.  This is done by passing an inline hash:
1626
1627         my $db = DBM::Deep->new(
1628                 file => "foo.db",
1629                 locking => 1,
1630                 autoflush => 1
1631         );
1632
1633 Notice that the filename is now specified I<inside> the hash with
1634 the "file" parameter, as opposed to being the sole argument to the
1635 constructor.  This is required if any options are specified.
1636 See L<OPTIONS> below for the complete list.
1637
1638
1639
1640 You can also start with an array instead of a hash.  For this, you must
1641 specify the C<type> parameter:
1642
1643         my $db = DBM::Deep->new(
1644                 file => "foo.db",
1645                 type => DBM::Deep->TYPE_ARRAY
1646         );
1647
1648 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1649 a new DB file.  If you create a DBM::Deep object with an existing file, the
1650 C<type> will be loaded from the file header, and an error will be thrown if
1651 the wrong type is passed in.
1652
1653 =head2 TIE CONSTRUCTION
1654
1655 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1656 tie() function.  The object returned from tie() can be used to call methods,
1657 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1658 file (as expected with most tie'd objects).
1659
1660         my %hash;
1661         my $db = tie %hash, "DBM::Deep", "foo.db";
1662
1663         my @array;
1664         my $db = tie @array, "DBM::Deep", "bar.db";
1665
1666 As with the OO constructor, you can replace the DB filename parameter with
1667 a hash containing one or more options (see L<OPTIONS> just below for the
1668 complete list).
1669
1670         tie %hash, "DBM::Deep", {
1671                 file => "foo.db",
1672                 locking => 1,
1673                 autoflush => 1
1674         };
1675
1676 =head2 OPTIONS
1677
1678 There are a number of options that can be passed in when constructing your
1679 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1680
1681 =over
1682
1683 =item * file
1684
1685 Filename of the DB file to link the handle to.  You can pass a full absolute
1686 filesystem path, partial path, or a plain filename if the file is in the
1687 current working directory.  This is a required parameter.
1688
1689 =item * type
1690
1691 This parameter specifies what type of object to create, a hash or array.  Use
1692 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1693 This only takes effect when beginning a new file.  This is an optional
1694 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1695
1696 =item * locking
1697
1698 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1699 function to lock the database in exclusive mode for writes, and shared mode for
1700 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1701 any child hashes or arrays> that use the same DB file.  This is an optional
1702 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1703
1704 =item * autoflush
1705
1706 Specifies whether autoflush is to be enabled on the underlying filehandle.
1707 This obviously slows down write operations, but is required if you may have
1708 multiple processes accessing the same DB file (also consider enable I<locking>).
1709 Pass any true value to enable.  This is an optional parameter, and defaults to 0
1710 (disabled).
1711
1712 =item * autobless
1713
1714 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1715 restore them when fetched.  This is an B<experimental> feature, and does have
1716 side-effects.  Basically, when hashes are re-blessed into their original
1717 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1718 able to call any DBM::Deep methods on them.  You have been warned.
1719 This is an optional parameter, and defaults to 0 (disabled).
1720
1721 =item * filter_*
1722
1723 See L<FILTERS> below.
1724
1725 =item * debug
1726
1727 Setting I<debug> mode will make all errors non-fatal, dump them out to
1728 STDERR, and continue on.  This is for debugging purposes only, and probably
1729 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1730
1731 =item * fh
1732
1733 Instead of passing a file path, you can instead pass a handle to an pre-opened
1734 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1735 contains your entire Perl script, as well as the data following the __DATA__
1736 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1737 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1738 in that.  Also please note optimize() will NOT work when passing in only a
1739 handle.  Pass in a real filename in order to use optimize().
1740
1741 =back
1742
1743 =head1 TIE INTERFACE
1744
1745 With DBM::Deep you can access your databases using Perl's standard hash/array
1746 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1747 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1748 to the right place -- the DB file.  This has nothing to do with the
1749 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1750 using regular hashes and arrays, rather than calling functions like C<get()>
1751 and C<put()> (although those work too).  It is entirely up to you how to want
1752 to access your databases.
1753
1754 =head2 HASHES
1755
1756 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1757 or even nested hashes (or arrays) using standard Perl syntax:
1758
1759         my $db = DBM::Deep->new( "foo.db" );
1760
1761         $db->{mykey} = "myvalue";
1762         $db->{myhash} = {};
1763         $db->{myhash}->{subkey} = "subvalue";
1764
1765         print $db->{myhash}->{subkey} . "\n";
1766
1767 You can even step through hash keys using the normal Perl C<keys()> function:
1768
1769         foreach my $key (keys %$db) {
1770                 print "$key: " . $db->{$key} . "\n";
1771         }
1772
1773 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1774 pushes them onto an array, all before the loop even begins.  If you have an
1775 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1776 Perl's C<each()> function, which pulls keys/values one at a time, using very
1777 little memory:
1778
1779         while (my ($key, $value) = each %$db) {
1780                 print "$key: $value\n";
1781         }
1782
1783 Please note that when using C<each()>, you should always pass a direct
1784 hash reference, not a lookup.  Meaning, you should B<never> do this:
1785
1786         # NEVER DO THIS
1787         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1788
1789 This causes an infinite loop, because for each iteration, Perl is calling
1790 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1791 it effectively keeps returning the first key over and over again. Instead,
1792 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1793
1794 =head2 ARRAYS
1795
1796 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1797 reference.  This includes inserting, removing and manipulating elements,
1798 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1799 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1800 or simply be a nested array reference inside a hash.  Example:
1801
1802         my $db = DBM::Deep->new(
1803                 file => "foo-array.db",
1804                 type => DBM::Deep->TYPE_ARRAY
1805         );
1806
1807         $db->[0] = "foo";
1808         push @$db, "bar", "baz";
1809         unshift @$db, "bah";
1810
1811         my $last_elem = pop @$db; # baz
1812         my $first_elem = shift @$db; # bah
1813         my $second_elem = $db->[1]; # bar
1814
1815         my $num_elements = scalar @$db;
1816
1817 =head1 OO INTERFACE
1818
1819 In addition to the I<tie()> interface, you can also use a standard OO interface
1820 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1821 array) has its own methods, but both types share the following common methods:
1822 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1823
1824 =over
1825
1826 =item * put() / store()
1827
1828 Stores a new hash key/value pair, or sets an array element value.  Takes two
1829 arguments, the hash key or array index, and the new value.  The value can be
1830 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1831
1832         $db->put("foo", "bar"); # for hashes
1833         $db->put(1, "bar"); # for arrays
1834
1835 =item * get() / fetch()
1836
1837 Fetches the value of a hash key or array element.  Takes one argument: the hash
1838 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1839 data type stored.
1840
1841         my $value = $db->get("foo"); # for hashes
1842         my $value = $db->get(1); # for arrays
1843
1844 =item * exists()
1845
1846 Checks if a hash key or array index exists.  Takes one argument: the hash key
1847 or array index.  Returns true if it exists, false if not.
1848
1849         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1850         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1851
1852 =item * delete()
1853
1854 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1855 key or array index.  Returns true on success, false if not found.  For arrays,
1856 the remaining elements located after the deleted element are NOT moved over.
1857 The deleted element is essentially just undefined, which is exactly how Perl's
1858 internal arrays work.  Please note that the space occupied by the deleted
1859 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1860 below for details and workarounds.
1861
1862         $db->delete("foo"); # for hashes
1863         $db->delete(1); # for arrays
1864
1865 =item * clear()
1866
1867 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1868 value.  Please note that the space occupied by the deleted keys/values or
1869 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1870 details and workarounds.
1871
1872         $db->clear(); # hashes or arrays
1873
1874 =back
1875
1876 =head2 HASHES
1877
1878 For hashes, DBM::Deep supports all the common methods described above, and the
1879 following additional methods: C<first_key()> and C<next_key()>.
1880
1881 =over
1882
1883 =item * first_key()
1884
1885 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1886 fetched in an undefined order (which appears random).  Takes no arguments,
1887 returns the key as a scalar value.
1888
1889         my $key = $db->first_key();
1890
1891 =item * next_key()
1892
1893 Returns the "next" key in the hash, given the previous one as the sole argument.
1894 Returns undef if there are no more keys to be fetched.
1895
1896         $key = $db->next_key($key);
1897
1898 =back
1899
1900 Here are some examples of using hashes:
1901
1902         my $db = DBM::Deep->new( "foo.db" );
1903
1904         $db->put("foo", "bar");
1905         print "foo: " . $db->get("foo") . "\n";
1906
1907         $db->put("baz", {}); # new child hash ref
1908         $db->get("baz")->put("buz", "biz");
1909         print "buz: " . $db->get("baz")->get("buz") . "\n";
1910
1911         my $key = $db->first_key();
1912         while ($key) {
1913                 print "$key: " . $db->get($key) . "\n";
1914                 $key = $db->next_key($key);
1915         }
1916
1917         if ($db->exists("foo")) { $db->delete("foo"); }
1918
1919 =head2 ARRAYS
1920
1921 For arrays, DBM::Deep supports all the common methods described above, and the
1922 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1923 C<unshift()> and C<splice()>.
1924
1925 =over
1926
1927 =item * length()
1928
1929 Returns the number of elements in the array.  Takes no arguments.
1930
1931         my $len = $db->length();
1932
1933 =item * push()
1934
1935 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1936 refs or array refs.  No return value.
1937
1938         $db->push("foo", "bar", {});
1939
1940 =item * pop()
1941
1942 Fetches the last element in the array, and deletes it.  Takes no arguments.
1943 Returns undef if array is empty.  Returns the element value.
1944
1945         my $elem = $db->pop();
1946
1947 =item * shift()
1948
1949 Fetches the first element in the array, deletes it, then shifts all the
1950 remaining elements over to take up the space.  Returns the element value.  This
1951 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1952 details.
1953
1954         my $elem = $db->shift();
1955
1956 =item * unshift()
1957
1958 Inserts one or more elements onto the beginning of the array, shifting all
1959 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1960 No return value.  This method is not recommended with large arrays -- see
1961 <LARGE ARRAYS> below for details.
1962
1963         $db->unshift("foo", "bar", {});
1964
1965 =item * splice()
1966
1967 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1968 -f splice> for usage -- it is too complicated to document here.  This method is
1969 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1970
1971 =back
1972
1973 Here are some examples of using arrays:
1974
1975         my $db = DBM::Deep->new(
1976                 file => "foo.db",
1977                 type => DBM::Deep->TYPE_ARRAY
1978         );
1979
1980         $db->push("bar", "baz");
1981         $db->unshift("foo");
1982         $db->put(3, "buz");
1983
1984         my $len = $db->length();
1985         print "length: $len\n"; # 4
1986
1987         for (my $k=0; $k<$len; $k++) {
1988                 print "$k: " . $db->get($k) . "\n";
1989         }
1990
1991         $db->splice(1, 2, "biz", "baf");
1992
1993         while (my $elem = shift @$db) {
1994                 print "shifted: $elem\n";
1995         }
1996
1997 =head1 LOCKING
1998
1999 Enable automatic file locking by passing a true value to the C<locking>
2000 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2001
2002         my $db = DBM::Deep->new(
2003                 file => "foo.db",
2004                 locking => 1
2005         );
2006
2007 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2008 mode for writes, and shared mode for reads.  This is required if you have
2009 multiple processes accessing the same database file, to avoid file corruption.
2010 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2011 NFS> below for more.
2012
2013 =head2 EXPLICIT LOCKING
2014
2015 You can explicitly lock a database, so it remains locked for multiple
2016 transactions.  This is done by calling the C<lock()> method, and passing an
2017 optional lock mode argument (defaults to exclusive mode).  This is particularly
2018 useful for things like counters, where the current value needs to be fetched,
2019 then incremented, then stored again.
2020
2021         $db->lock();
2022         my $counter = $db->get("counter");
2023         $counter++;
2024         $db->put("counter", $counter);
2025         $db->unlock();
2026
2027         # or...
2028
2029         $db->lock();
2030         $db->{counter}++;
2031         $db->unlock();
2032
2033 You can pass C<lock()> an optional argument, which specifies which mode to use
2034 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2035 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2036 same as the constants defined in Perl's C<Fcntl> module.
2037
2038         $db->lock( DBM::Deep->LOCK_SH );
2039         # something here
2040         $db->unlock();
2041
2042 =head1 IMPORTING/EXPORTING
2043
2044 You can import existing complex structures by calling the C<import()> method,
2045 and export an entire database into an in-memory structure using the C<export()>
2046 method.  Both are examined here.
2047
2048 =head2 IMPORTING
2049
2050 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2051 walking the structure and adding keys/elements to the database as you go,
2052 simply pass a reference to the C<import()> method.  This recursively adds
2053 everything to an existing DBM::Deep object for you.  Here is an example:
2054
2055         my $struct = {
2056                 key1 => "value1",
2057                 key2 => "value2",
2058                 array1 => [ "elem0", "elem1", "elem2" ],
2059                 hash1 => {
2060                         subkey1 => "subvalue1",
2061                         subkey2 => "subvalue2"
2062                 }
2063         };
2064
2065         my $db = DBM::Deep->new( "foo.db" );
2066         $db->import( $struct );
2067
2068         print $db->{key1} . "\n"; # prints "value1"
2069
2070 This recursively imports the entire C<$struct> object into C<$db>, including
2071 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2072 keys are merged with the existing ones, replacing if they already exist.
2073 The C<import()> method can be called on any database level (not just the base
2074 level), and works with both hash and array DB types.
2075
2076 B<Note:> Make sure your existing structure has no circular references in it.
2077 These will cause an infinite loop when importing.
2078
2079 =head2 EXPORTING
2080
2081 Calling the C<export()> method on an existing DBM::Deep object will return
2082 a reference to a new in-memory copy of the database.  The export is done
2083 recursively, so all nested hashes/arrays are all exported to standard Perl
2084 objects.  Here is an example:
2085
2086         my $db = DBM::Deep->new( "foo.db" );
2087
2088         $db->{key1} = "value1";
2089         $db->{key2} = "value2";
2090         $db->{hash1} = {};
2091         $db->{hash1}->{subkey1} = "subvalue1";
2092         $db->{hash1}->{subkey2} = "subvalue2";
2093
2094         my $struct = $db->export();
2095
2096         print $struct->{key1} . "\n"; # prints "value1"
2097
2098 This makes a complete copy of the database in memory, and returns a reference
2099 to it.  The C<export()> method can be called on any database level (not just
2100 the base level), and works with both hash and array DB types.  Be careful of
2101 large databases -- you can store a lot more data in a DBM::Deep object than an
2102 in-memory Perl structure.
2103
2104 B<Note:> Make sure your database has no circular references in it.
2105 These will cause an infinite loop when exporting.
2106
2107 =head1 FILTERS
2108
2109 DBM::Deep has a number of hooks where you can specify your own Perl function
2110 to perform filtering on incoming or outgoing data.  This is a perfect
2111 way to extend the engine, and implement things like real-time compression or
2112 encryption.  Filtering applies to the base DB level, and all child hashes /
2113 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2114 constructed, or by calling the C<set_filter()> method at any time.  There are
2115 four available filter hooks, described below:
2116
2117 =over
2118
2119 =item * filter_store_key
2120
2121 This filter is called whenever a hash key is stored.  It
2122 is passed the incoming key, and expected to return a transformed key.
2123
2124 =item * filter_store_value
2125
2126 This filter is called whenever a hash key or array element is stored.  It
2127 is passed the incoming value, and expected to return a transformed value.
2128
2129 =item * filter_fetch_key
2130
2131 This filter is called whenever a hash key is fetched (i.e. via
2132 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2133 and expected to return the plain key.
2134
2135 =item * filter_fetch_value
2136
2137 This filter is called whenever a hash key or array element is fetched.
2138 It is passed the transformed value, and expected to return the plain value.
2139
2140 =back
2141
2142 Here are the two ways to setup a filter hook:
2143
2144         my $db = DBM::Deep->new(
2145                 file => "foo.db",
2146                 filter_store_value => \&my_filter_store,
2147                 filter_fetch_value => \&my_filter_fetch
2148         );
2149
2150         # or...
2151
2152         $db->set_filter( "filter_store_value", \&my_filter_store );
2153         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2154
2155 Your filter function will be called only when dealing with SCALAR keys or
2156 values.  When nested hashes and arrays are being stored/fetched, filtering
2157 is bypassed.  Filters are called as static functions, passed a single SCALAR
2158 argument, and expected to return a single SCALAR value.  If you want to
2159 remove a filter, set the function reference to C<undef>:
2160
2161         $db->set_filter( "filter_store_value", undef );
2162
2163 =head2 REAL-TIME ENCRYPTION EXAMPLE
2164
2165 Here is a working example that uses the I<Crypt::Blowfish> module to
2166 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2167 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2168 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2169
2170         use DBM::Deep;
2171         use Crypt::Blowfish;
2172         use Crypt::CBC;
2173
2174         my $cipher = Crypt::CBC->new({
2175                 'key'             => 'my secret key',
2176                 'cipher'          => 'Blowfish',
2177                 'iv'              => '$KJh#(}q',
2178                 'regenerate_key'  => 0,
2179                 'padding'         => 'space',
2180                 'prepend_iv'      => 0
2181         });
2182
2183         my $db = DBM::Deep->new(
2184                 file => "foo-encrypt.db",
2185                 filter_store_key => \&my_encrypt,
2186                 filter_store_value => \&my_encrypt,
2187                 filter_fetch_key => \&my_decrypt,
2188                 filter_fetch_value => \&my_decrypt,
2189         );
2190
2191         $db->{key1} = "value1";
2192         $db->{key2} = "value2";
2193         print "key1: " . $db->{key1} . "\n";
2194         print "key2: " . $db->{key2} . "\n";
2195
2196         undef $db;
2197         exit;
2198
2199         sub my_encrypt {
2200                 return $cipher->encrypt( $_[0] );
2201         }
2202         sub my_decrypt {
2203                 return $cipher->decrypt( $_[0] );
2204         }
2205
2206 =head2 REAL-TIME COMPRESSION EXAMPLE
2207
2208 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2209 compression / decompression of keys & values with DBM::Deep Filters.
2210 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2211 more on I<Compress::Zlib>.
2212
2213         use DBM::Deep;
2214         use Compress::Zlib;
2215
2216         my $db = DBM::Deep->new(
2217                 file => "foo-compress.db",
2218                 filter_store_key => \&my_compress,
2219                 filter_store_value => \&my_compress,
2220                 filter_fetch_key => \&my_decompress,
2221                 filter_fetch_value => \&my_decompress,
2222         );
2223
2224         $db->{key1} = "value1";
2225         $db->{key2} = "value2";
2226         print "key1: " . $db->{key1} . "\n";
2227         print "key2: " . $db->{key2} . "\n";
2228
2229         undef $db;
2230         exit;
2231
2232         sub my_compress {
2233                 return Compress::Zlib::memGzip( $_[0] ) ;
2234         }
2235         sub my_decompress {
2236                 return Compress::Zlib::memGunzip( $_[0] ) ;
2237         }
2238
2239 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2240 actually numerical index numbers, and are not filtered.
2241
2242 =head1 ERROR HANDLING
2243
2244 Most DBM::Deep methods return a true value for success, and call die() on
2245 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2246 actual error message is stored in an internal scalar, which can be fetched by
2247 calling the C<error()> method.
2248
2249         my $db = DBM::Deep->new( "foo.db" ); # create hash
2250         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2251
2252     print $@;           # prints error message
2253         print $db->error(); # prints error message
2254
2255 You can then call C<clear_error()> to clear the current error state.
2256
2257         $db->clear_error();
2258
2259 If you set the C<debug> option to true when creating your DBM::Deep object,
2260 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2261 be used for debugging purposes and not production work. DBM::Deep expects errors
2262 to be thrown, not propagated back up the stack.
2263
2264 =head1 LARGEFILE SUPPORT
2265
2266 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2267 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2268 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2269 by calling the static C<set_pack()> method before you do anything else.
2270
2271         DBM::Deep::set_pack(8, 'Q');
2272
2273 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2274 instead of 32-bit longs.  After setting these values your DB files have a
2275 theoretical maximum size of 16 XB (exabytes).
2276
2277 B<Note:> Changing these values will B<NOT> work for existing database files.
2278 Only change this for new files, and make sure it stays set consistently
2279 throughout the file's life.  If you do set these values, you can no longer
2280 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2281 back to 32-bit mode.
2282
2283 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2284 only a 32-bit Perl.  However, I have received user reports that this does
2285 indeed work!
2286
2287 =head1 LOW-LEVEL ACCESS
2288
2289 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2290 you can call the C<fh()> method, which returns the handle:
2291
2292         my $fh = $db->fh();
2293
2294 This method can be called on the root level of the datbase, or any child
2295 hashes or arrays.  All levels share a I<root> structure, which contains things
2296 like the filehandle, a reference counter, and all the options specified
2297 when you created the object.  You can get access to this root structure by
2298 calling the C<root()> method.
2299
2300         my $root = $db->root();
2301
2302 This is useful for changing options after the object has already been created,
2303 such as enabling/disabling locking, or debug modes.  You can also
2304 store your own temporary user data in this structure (be wary of name
2305 collision), which is then accessible from any child hash or array.
2306
2307 =head1 CUSTOM DIGEST ALGORITHM
2308
2309 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2310 keys.  However you can override this, and use another algorithm (such as SHA-256)
2311 or even write your own.  But please note that DBM::Deep currently expects zero
2312 collisions, so your algorithm has to be I<perfect>, so to speak.
2313 Collision detection may be introduced in a later version.
2314
2315
2316
2317 You can specify a custom digest algorithm by calling the static C<set_digest()>
2318 function, passing a reference to a subroutine, and the length of the algorithm's
2319 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2320 objects.  Here is a working example that uses a 256-bit hash from the
2321 I<Digest::SHA256> module.  Please see
2322 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2323
2324         use DBM::Deep;
2325         use Digest::SHA256;
2326
2327         my $context = Digest::SHA256::new(256);
2328
2329         DBM::Deep::set_digest( \&my_digest, 32 );
2330
2331         my $db = DBM::Deep->new( "foo-sha.db" );
2332
2333         $db->{key1} = "value1";
2334         $db->{key2} = "value2";
2335         print "key1: " . $db->{key1} . "\n";
2336         print "key2: " . $db->{key2} . "\n";
2337
2338         undef $db;
2339         exit;
2340
2341         sub my_digest {
2342                 return substr( $context->hash($_[0]), 0, 32 );
2343         }
2344
2345 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2346 of bytes you specify in the C<set_digest()> function (in this case 32).
2347
2348 =head1 CIRCULAR REFERENCES
2349
2350 DBM::Deep has B<experimental> support for circular references.  Meaning you
2351 can have a nested hash key or array element that points to a parent object.
2352 This relationship is stored in the DB file, and is preserved between sessions.
2353 Here is an example:
2354
2355         my $db = DBM::Deep->new( "foo.db" );
2356
2357         $db->{foo} = "bar";
2358         $db->{circle} = $db; # ref to self
2359
2360         print $db->{foo} . "\n"; # prints "foo"
2361         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2362
2363 One catch is, passing the object to a function that recursively walks the
2364 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2365 C<export()> methods) will result in an infinite loop.  The other catch is,
2366 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2367 or C<next_key()> methods), you will get the I<target object's key>, not the
2368 ref's key.  This gets even more interesting with the above example, where
2369 the I<circle> key points to the base DB object, which technically doesn't
2370 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2371 special case.
2372
2373 =head1 CAVEATS / ISSUES / BUGS
2374
2375 This section describes all the known issues with DBM::Deep.  It you have found
2376 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2377
2378 =head2 UNUSED SPACE RECOVERY
2379
2380 One major caveat with DBM::Deep is that space occupied by existing keys and
2381 values is not recovered when they are deleted.  Meaning if you keep deleting
2382 and adding new keys, your file will continuously grow.  I am working on this,
2383 but in the meantime you can call the built-in C<optimize()> method from time to
2384 time (perhaps in a crontab or something) to recover all your unused space.
2385
2386         $db->optimize(); # returns true on success
2387
2388 This rebuilds the ENTIRE database into a new file, then moves it on top of
2389 the original.  The new file will have no unused space, thus it will take up as
2390 little disk space as possible.  Please note that this operation can take
2391 a long time for large files, and you need enough disk space to temporarily hold
2392 2 copies of your DB file.  The temporary file is created in the same directory
2393 as the original, named with a ".tmp" extension, and is deleted when the
2394 operation completes.  Oh, and if locking is enabled, the DB is automatically
2395 locked for the entire duration of the copy.
2396
2397 B<WARNING:> Only call optimize() on the top-level node of the database, and
2398 make sure there are no child references lying around.  DBM::Deep keeps a reference
2399 counter, and if it is greater than 1, optimize() will abort and return undef.
2400
2401 =head2 AUTOVIVIFICATION
2402
2403 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2404 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2405 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2406 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2407 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2408 this does not work:
2409
2410         $db->{foo}->{bar} = "hello";
2411
2412 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2413 being an empty hash.  Try this instead, which works fine:
2414
2415         $db->{foo} = { bar => "hello" };
2416
2417 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2418 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2419 Probably a bug in Perl.
2420
2421 =head2 FILE CORRUPTION
2422
2423 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2424 for a 32-bit signature when opened, but other corruption in files can cause
2425 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2426 stuck in an infinite loop depending on the level of corruption.  File write
2427 operations are not checked for failure (for speed), so if you happen to run
2428 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2429 be addressed in a later version of DBM::Deep.
2430
2431 =head2 DB OVER NFS
2432
2433 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2434 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2435 about setting up your NFS server with a locking daemon, then using lockf() to
2436 lock your files, but your mileage may vary there as well.  From what I
2437 understand, there is no real way to do it.  However, if you need access to the
2438 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2439 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2440
2441 =head2 COPYING OBJECTS
2442
2443 Beware of copying tied objects in Perl.  Very strange things can happen.
2444 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2445 returns a new, blessed, tied hash or array to the same level in the DB.
2446
2447         my $copy = $db->clone();
2448
2449 B<Note>: Since clone() here is cloning the object, not the database location, any
2450 modifications to either $db or $copy will be visible in both.
2451
2452 =head2 LARGE ARRAYS
2453
2454 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2455 These functions cause every element in the array to move, which can be murder
2456 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2457 a different location.  This will be addressed in the forthcoming version 1.00.
2458
2459 =head1 PERFORMANCE
2460
2461 This section discusses DBM::Deep's speed and memory usage.
2462
2463 =head2 SPEED
2464
2465 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2466 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2467 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2468 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2469 with huge databases.  Here is some test data:
2470
2471         Adding 1,000,000 keys to new DB file...
2472
2473         At 100 keys, avg. speed is 2,703 keys/sec
2474         At 200 keys, avg. speed is 2,642 keys/sec
2475         At 300 keys, avg. speed is 2,598 keys/sec
2476         At 400 keys, avg. speed is 2,578 keys/sec
2477         At 500 keys, avg. speed is 2,722 keys/sec
2478         At 600 keys, avg. speed is 2,628 keys/sec
2479         At 700 keys, avg. speed is 2,700 keys/sec
2480         At 800 keys, avg. speed is 2,607 keys/sec
2481         At 900 keys, avg. speed is 2,190 keys/sec
2482         At 1,000 keys, avg. speed is 2,570 keys/sec
2483         At 2,000 keys, avg. speed is 2,417 keys/sec
2484         At 3,000 keys, avg. speed is 1,982 keys/sec
2485         At 4,000 keys, avg. speed is 1,568 keys/sec
2486         At 5,000 keys, avg. speed is 1,533 keys/sec
2487         At 6,000 keys, avg. speed is 1,787 keys/sec
2488         At 7,000 keys, avg. speed is 1,977 keys/sec
2489         At 8,000 keys, avg. speed is 2,028 keys/sec
2490         At 9,000 keys, avg. speed is 2,077 keys/sec
2491         At 10,000 keys, avg. speed is 2,031 keys/sec
2492         At 20,000 keys, avg. speed is 1,970 keys/sec
2493         At 30,000 keys, avg. speed is 2,050 keys/sec
2494         At 40,000 keys, avg. speed is 2,073 keys/sec
2495         At 50,000 keys, avg. speed is 1,973 keys/sec
2496         At 60,000 keys, avg. speed is 1,914 keys/sec
2497         At 70,000 keys, avg. speed is 2,091 keys/sec
2498         At 80,000 keys, avg. speed is 2,103 keys/sec
2499         At 90,000 keys, avg. speed is 1,886 keys/sec
2500         At 100,000 keys, avg. speed is 1,970 keys/sec
2501         At 200,000 keys, avg. speed is 2,053 keys/sec
2502         At 300,000 keys, avg. speed is 1,697 keys/sec
2503         At 400,000 keys, avg. speed is 1,838 keys/sec
2504         At 500,000 keys, avg. speed is 1,941 keys/sec
2505         At 600,000 keys, avg. speed is 1,930 keys/sec
2506         At 700,000 keys, avg. speed is 1,735 keys/sec
2507         At 800,000 keys, avg. speed is 1,795 keys/sec
2508         At 900,000 keys, avg. speed is 1,221 keys/sec
2509         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2510
2511 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2512 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2513 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2514 Run time was 12 min 3 sec.
2515
2516 =head2 MEMORY USAGE
2517
2518 One of the great things about DBM::Deep is that it uses very little memory.
2519 Even with huge databases (1,000,000+ keys) you will not see much increased
2520 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2521 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2522 database handle:
2523
2524           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2525         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2526
2527 Basically the process is taking 2,716K of memory.  And here is the same
2528 process after storing and fetching 1,000,000 keys:
2529
2530           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2531         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2532
2533 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2534 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2535
2536 =head1 DB FILE FORMAT
2537
2538 In case you were interested in the underlying DB file format, it is documented
2539 here in this section.  You don't need to know this to use the module, it's just
2540 included for reference.
2541
2542 =head2 SIGNATURE
2543
2544 DBM::Deep files always start with a 32-bit signature to identify the file type.
2545 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2546 checked for when the file is opened and an error will be thrown if it's not found.
2547
2548 =head2 TAG
2549
2550 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2551 has a standard header containing the type of data, the length of data, and then
2552 the data itself.  The type is a single character (1 byte), the length is a
2553 32-bit unsigned long in network byte order, and the data is, well, the data.
2554 Here is how it unfolds:
2555
2556 =head2 MASTER INDEX
2557
2558 Immediately after the 32-bit file signature is the I<Master Index> record.
2559 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2560 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2561 depending on how the DBM::Deep object was constructed.
2562
2563 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2564 number).  The first 8-bit char of the MD5 signature is the offset into the
2565 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2566 index element is a file offset of the next tag for the key/element in question,
2567 which is usually a I<Bucket List> tag (see below).
2568
2569 The next tag I<could> be another index, depending on how many keys/elements
2570 exist.  See L<RE-INDEXING> below for details.
2571
2572 =head2 BUCKET LIST
2573
2574 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2575 file offsets to where the actual data is stored.  It starts with a standard
2576 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2577 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2578 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2579 When the list fills up, a I<Re-Index> operation is performed (See
2580 L<RE-INDEXING> below).
2581
2582 =head2 BUCKET
2583
2584 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2585 index/value pair (in array mode).  It starts with a standard tag header with
2586 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2587 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2588 header.  The size reported in the tag header is only for the value, but then,
2589 just after the value is another size (32-bit unsigned long) and then the plain
2590 key itself.  Since the value is likely to be fetched more often than the plain
2591 key, I figured it would be I<slightly> faster to store the value first.
2592
2593 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2594 record for the nested structure, where the process begins all over again.
2595
2596 =head2 RE-INDEXING
2597
2598 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2599 exhausted.  Then, when another key/element comes in, the list is converted to a
2600 new index record.  However, this index will look at the next char in the MD5
2601 hash, and arrange new Bucket List pointers accordingly.  This process is called
2602 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2603 17 (16 + new one) keys/elements are removed from the old Bucket List and
2604 inserted into the new index.  Several new Bucket Lists are created in the
2605 process, as a new MD5 char from the key is being examined (it is unlikely that
2606 the keys will all share the same next char of their MD5s).
2607
2608 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2609 when the Bucket Lists will turn into indexes, but the first round tends to
2610 happen right around 4,000 keys.  You will see a I<slight> decrease in
2611 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2612 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2613 right around 900,000 keys.  This process can continue nearly indefinitely --
2614 right up until the point the I<MD5> signatures start colliding with each other,
2615 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2616 getting struck by lightning while you are walking to cash in your tickets.
2617 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2618 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2619 this is 340 unodecillion, but don't quote me).
2620
2621 =head2 STORING
2622
2623 When a new key/element is stored, the key (or index number) is first run through
2624 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2625 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2626 for the first char of the signature (in this case I<b0>).  If it does not exist,
2627 a new I<Bucket List> is created for our key (and the next 15 future keys that
2628 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2629 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2630 this point, unless we are replacing an existing I<Bucket>), where the actual
2631 data will be stored.
2632
2633 =head2 FETCHING
2634
2635 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2636 (or index number), then walking along the indexes.  If there are enough
2637 keys/elements in this DB level, there might be nested indexes, each linked to
2638 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2639 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2640 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2641 plain key are stored.
2642
2643 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2644 methods.  In this process the indexes are walked systematically, and each key
2645 fetched in increasing MD5 order (which is why it appears random).   Once the
2646 I<Bucket> is found, the value is skipped the plain key returned instead.
2647 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2648 alphabetically sorted.  This only happens on an index-level -- as soon as the
2649 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2650 so it's pretty much undefined how the keys will come out -- just like Perl's
2651 built-in hashes.
2652
2653 =head1 CODE COVERAGE
2654
2655 We use B<Devel::Cover> to test the code coverage of our tests, below is the
2656 B<Devel::Cover> report on this module's test suite.
2657
2658   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2659   File                           stmt   bran   cond    sub    pod   time  total
2660   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2661   blib/lib/DBM/Deep.pm           93.9   82.5   70.0   96.5   33.3   84.3   88.1
2662   blib/lib/DBM/Deep/Array.pm     98.8   88.9   87.5  100.0    n/a    9.0   96.4
2663   blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    6.7   92.3
2664   Total                          95.0   83.4   73.8   97.6   33.3  100.0   89.9
2665   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2666
2667 =head1 MORE INFORMATION
2668
2669 Check out the DBM::Deep Google Group at L<http://groups.google.com/group/DBM-Deep>
2670 or send email to L<DBM-Deep@googlegroups.com>.
2671
2672 =head1 AUTHORS
2673
2674 Joseph Huckaby, L<jhuckaby@cpan.org>
2675
2676 Rob Kinyon, L<rkinyon@cpan.org>
2677
2678 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2679
2680 =head1 SEE ALSO
2681
2682 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2683 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2684
2685 =head1 LICENSE
2686
2687 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2688 This is free software, you may use it and distribute it under the
2689 same terms as Perl itself.
2690
2691 =cut