lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.97);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a fh to the database, create if nonexistent.
 203         # Make sure file signature matches DBM::Deep spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         my $fh;
 215         sysopen( $fh, $self->root->{file}, $flags )
 216             or $fh = undef;
 217         $self->root->{fh} = $fh;
 218     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 219         if (! defined($self->fh)) {
 220                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 221         }
 222
 223     my $fh = $self->fh;
 224
 225     #XXX Can we remove this by using the right sysopen() flags?
 226     # Maybe ... q.v. above
 227     binmode $fh; # for win32
 228
 229     if ($self->root->{autoflush}) {
 230         my $old = select $fh;
 231         $|=1;
 232         select $old;
 233     }
 234
 235     # Set the
 236     seek($fh, 0, SEEK_SET);
 237
 238     my $signature;
 239     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 240
 241     ##
 242     # File is empty -- write signature and master index
 243     ##
 244     if (!$bytes_read) {
 245         seek($fh, 0, SEEK_SET);
 246         print($fh SIG_FILE);
 247         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 248
 249         my $plain_key = "[base]";
 250         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 251
 252         # Flush the filehandle
 253         my $old_fh = select $fh;
 254         my $old_af = $|;
 255         $| = 1;
 256         $| = $old_af;
 257         select $old_fh;
 258
 259         my @stats = stat($fh);
 260         $self->root->{inode} = $stats[1];
 261         $self->root->{end} = $stats[7];
 262
 263         return 1;
 264     }
 265
 266     ##
 267     # Check signature was valid
 268     ##
 269     unless ($signature eq SIG_FILE) {
 270         $self->_close();
 271         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 272     }
 273
 274         my @stats = stat($fh);
 275         $self->root->{inode} = $stats[1];
 276     $self->root->{end} = $stats[7];
 277
 278     ##
 279     # Get our type from master index signature
 280     ##
 281     my $tag = $self->_load_tag($self->base_offset);
 282
 283 #XXX We probably also want to store the hash algorithm name and not assume anything
 284 #XXX The cool thing would be to allow a different hashing algorithm at every level
 285
 286     if (!$tag) {
 287         return $self->_throw_error("Corrupted file, no master index record");
 288     }
 289     if ($self->{type} ne $tag->{signature}) {
 290         return $self->_throw_error("File type mismatch");
 291     }
 292
 293     return 1;
 294 }
 295
 296 sub _close {
 297         ##
 298         # Close database fh
 299         ##
 300     my $self = $_[0]->_get_self;
 301     close $self->root->{fh} if $self->root->{fh};
 302     $self->root->{fh} = undef;
 303 }
 304
 305 sub _create_tag {
 306         ##
 307         # Given offset, signature and content, create tag and write to disk
 308         ##
 309         my ($self, $offset, $sig, $content) = @_;
 310         my $size = length($content);
 311
 312     my $fh = $self->fh;
 313
 314         seek($fh, $offset, SEEK_SET);
 315         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 316
 317         if ($offset == $self->root->{end}) {
 318                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 319         }
 320
 321         return {
 322                 signature => $sig,
 323                 size => $size,
 324                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 325                 content => $content
 326         };
 327 }
 328
 329 sub _load_tag {
 330         ##
 331         # Given offset, load single tag and return signature, size and data
 332         ##
 333         my $self = shift;
 334         my $offset = shift;
 335
 336     my $fh = $self->fh;
 337
 338         seek($fh, $offset, SEEK_SET);
 339         if (eof $fh) { return undef; }
 340
 341         my $sig;
 342         read( $fh, $sig, SIG_SIZE);
 343
 344         my $size;
 345         read( $fh, $size, $DATA_LENGTH_SIZE);
 346         $size = unpack($DATA_LENGTH_PACK, $size);
 347
 348         my $buffer;
 349         read( $fh, $buffer, $size);
 350
 351         return {
 352                 signature => $sig,
 353                 size => $size,
 354                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 355                 content => $buffer
 356         };
 357 }
 358
 359 sub _index_lookup {
 360         ##
 361         # Given index tag, lookup single entry in index and return .
 362         ##
 363         my $self = shift;
 364         my ($tag, $index) = @_;
 365
 366         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 367         if (!$location) { return; }
 368
 369         return $self->_load_tag( $location );
 370 }
 371
 372 sub _add_bucket {
 373         ##
 374         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 375         # plain (undigested) key and value.
 376         ##
 377         my $self = shift;
 378         my ($tag, $md5, $plain_key, $value) = @_;
 379         my $keys = $tag->{content};
 380         my $location = 0;
 381         my $result = 2;
 382
 383         # added ref() check first to avoid eval and runtime exception for every
 384         # scalar value being stored.  performance tweak.
 385     my $is_dbm_deep = ref($value) && eval { $value->isa( 'DBM::Deep' ) };
 386
 387         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 388
 389     my $fh = $self->fh;
 390
 391         ##
 392         # Iterate through buckets, seeing if this is a new entry or a replace.
 393         ##
 394         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 395                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 396                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 397                 if (!$subloc) {
 398                         ##
 399                         # Found empty bucket (end of list).  Populate and exit loop.
 400                         ##
 401                         $result = 2;
 402
 403             $location = $internal_ref
 404                 ? $value->base_offset
 405                 : $self->root->{end};
 406
 407                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 408                         print($fh $md5 . pack($LONG_PACK, $location) );
 409                         last;
 410                 }
 411                 elsif ($md5 eq $key) {
 412                         ##
 413                         # Found existing bucket with same key.  Replace with new value.
 414                         ##
 415                         $result = 1;
 416
 417                         if ($internal_ref) {
 418                                 $location = $value->base_offset;
 419                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 420                                 print($fh $md5 . pack($LONG_PACK, $location) );
 421                         }
 422                         else {
 423                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 424                                 my $size;
 425                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 426
 427                                 ##
 428                                 # If value is a hash, array, or raw value with equal or less size, we can
 429                                 # reuse the same content area of the database.  Otherwise, we have to create
 430                                 # a new content area at the EOF.
 431                                 ##
 432                                 my $actual_length;
 433                 my $r = Scalar::Util::reftype( $value ) || '';
 434                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 435                         $actual_length = $INDEX_SIZE;
 436
 437                         # if autobless is enabled, must also take into consideration
 438                         # the class name, as it is stored along with key/value.
 439                         if ( $self->root->{autobless} ) {
 440                                                 my $value_class = Scalar::Util::blessed($value);
 441                                                 if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 442                                                         $actual_length += length($value_class);
 443                                                 }
 444                                         } # autobless
 445                 }
 446                                 else { $actual_length = length($value); }
 447
 448                                 if ($actual_length <= $size) {
 449                                         $location = $subloc;
 450                                 }
 451                                 else {
 452                                         $location = $self->root->{end};
 453                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 454                                         print($fh pack($LONG_PACK, $location) );
 455                                 }
 456                         }
 457                         last;
 458                 }
 459         } # i loop
 460
 461         ##
 462         # If this is an internal reference, return now.
 463         # No need to write value or plain key
 464         ##
 465         if ($internal_ref) {
 466         return $result;
 467     }
 468
 469         ##
 470         # If bucket didn't fit into list, split into a new index level
 471         ##
 472         if (!$location) {
 473                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 474                 print($fh pack($LONG_PACK, $self->root->{end}) );
 475
 476                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 477                 my @offsets = ();
 478
 479                 $keys .= $md5 . pack($LONG_PACK, 0);
 480
 481                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 482                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 483                         if ($key) {
 484                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 485                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 486
 487                                 if ($offsets[$num]) {
 488                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 489                                         seek($fh, $offset, SEEK_SET);
 490                                         my $subkeys;
 491                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 492
 493                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 494                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 495                                                 if (!$subloc) {
 496                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 497                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 498                                                         last;
 499                                                 }
 500                                         } # k loop
 501                                 }
 502                                 else {
 503                                         $offsets[$num] = $self->root->{end};
 504                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 505                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 506
 507                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 508
 509                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 510                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 511                                 }
 512                         } # key is real
 513                 } # i loop
 514
 515                 $location ||= $self->root->{end};
 516         } # re-index bucket list
 517
 518         ##
 519         # Seek to content area and store signature, value and plaintext key
 520         ##
 521         if ($location) {
 522                 my $content_length;
 523                 seek($fh, $location, SEEK_SET);
 524
 525                 ##
 526                 # Write signature based on content type, set content length and write actual value.
 527                 ##
 528         my $r = Scalar::Util::reftype($value) || '';
 529                 if ($r eq 'HASH') {
 530                         print($fh TYPE_HASH );
 531                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 532                         $content_length = $INDEX_SIZE;
 533                 }
 534                 elsif ($r eq 'ARRAY') {
 535                         print($fh TYPE_ARRAY );
 536                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 537                         $content_length = $INDEX_SIZE;
 538                 }
 539                 elsif (!defined($value)) {
 540                         print($fh SIG_NULL );
 541                         print($fh pack($DATA_LENGTH_PACK, 0) );
 542                         $content_length = 0;
 543                 }
 544                 else {
 545                         print($fh SIG_DATA );
 546                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 547                         $content_length = length($value);
 548                 }
 549
 550                 ##
 551                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 552                 ##
 553                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 554
 555                 ##
 556                 # If value is blessed, preserve class name
 557                 ##
 558                 if ( $self->root->{autobless} ) {
 559             my $value_class = Scalar::Util::blessed($value);
 560             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 561                 ##
 562                 # Blessed ref -- will restore later
 563                 ##
 564                 print($fh chr(1) );
 565                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 566                 $content_length += 1;
 567                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 568             }
 569             else {
 570                 print($fh chr(0) );
 571                 $content_length += 1;
 572             }
 573         }
 574
 575                 ##
 576                 # If this is a new content area, advance EOF counter
 577                 ##
 578                 if ($location == $self->root->{end}) {
 579                         $self->root->{end} += SIG_SIZE;
 580                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 581                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 582                 }
 583
 584                 ##
 585                 # If content is a hash or array, create new child DBM::Deep object and
 586                 # pass each key or element to it.
 587                 ##
 588                 if ($r eq 'HASH') {
 589                         my $branch = DBM::Deep->new(
 590                                 type => TYPE_HASH,
 591                                 base_offset => $location,
 592                                 root => $self->root,
 593                         );
 594                         foreach my $key (keys %{$value}) {
 595                 $branch->STORE( $key, $value->{$key} );
 596                         }
 597                 }
 598                 elsif ($r eq 'ARRAY') {
 599                         my $branch = DBM::Deep->new(
 600                                 type => TYPE_ARRAY,
 601                                 base_offset => $location,
 602                                 root => $self->root,
 603                         );
 604                         my $index = 0;
 605                         foreach my $element (@{$value}) {
 606                 $branch->STORE( $index, $element );
 607                                 $index++;
 608                         }
 609                 }
 610
 611                 return $result;
 612         }
 613
 614         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 615 }
 616
 617 sub _get_bucket_value {
 618         ##
 619         # Fetch single value given tag and MD5 digested key.
 620         ##
 621         my $self = shift;
 622         my ($tag, $md5) = @_;
 623         my $keys = $tag->{content};
 624
 625     my $fh = $self->fh;
 626
 627         ##
 628         # Iterate through buckets, looking for a key match
 629         ##
 630     BUCKET:
 631         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 632                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 633                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 634
 635                 if (!$subloc) {
 636                         ##
 637                         # Hit end of list, no match
 638                         ##
 639                         return;
 640                 }
 641
 642         if ( $md5 ne $key ) {
 643             next BUCKET;
 644         }
 645
 646         ##
 647         # Found match -- seek to offset and read signature
 648         ##
 649         my $signature;
 650         seek($fh, $subloc, SEEK_SET);
 651         read( $fh, $signature, SIG_SIZE);
 652
 653         ##
 654         # If value is a hash or array, return new DBM::Deep object with correct offset
 655         ##
 656         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 657             my $obj = DBM::Deep->new(
 658                 type => $signature,
 659                 base_offset => $subloc,
 660                 root => $self->root
 661             );
 662
 663             if ($self->root->{autobless}) {
 664                 ##
 665                 # Skip over value and plain key to see if object needs
 666                 # to be re-blessed
 667                 ##
 668                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 669
 670                 my $size;
 671                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 672                 if ($size) { seek($fh, $size, SEEK_CUR); }
 673
 674                 my $bless_bit;
 675                 read( $fh, $bless_bit, 1);
 676                 if (ord($bless_bit)) {
 677                     ##
 678                     # Yes, object needs to be re-blessed
 679                     ##
 680                     my $class_name;
 681                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 682                     if ($size) { read( $fh, $class_name, $size); }
 683                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 684                 }
 685             }
 686
 687             return $obj;
 688         }
 689
 690         ##
 691         # Otherwise return actual value
 692         ##
 693         elsif ($signature eq SIG_DATA) {
 694             my $size;
 695             my $value = '';
 696             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 697             if ($size) { read( $fh, $value, $size); }
 698             return $value;
 699         }
 700
 701         ##
 702         # Key exists, but content is null
 703         ##
 704         else { return; }
 705         } # i loop
 706
 707         return;
 708 }
 709
 710 sub _delete_bucket {
 711         ##
 712         # Delete single key/value pair given tag and MD5 digested key.
 713         ##
 714         my $self = shift;
 715         my ($tag, $md5) = @_;
 716         my $keys = $tag->{content};
 717
 718     my $fh = $self->fh;
 719
 720         ##
 721         # Iterate through buckets, looking for a key match
 722         ##
 723     BUCKET:
 724         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 725                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 726                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 727
 728                 if (!$subloc) {
 729                         ##
 730                         # Hit end of list, no match
 731                         ##
 732                         return;
 733                 }
 734
 735         if ( $md5 ne $key ) {
 736             next BUCKET;
 737         }
 738
 739         ##
 740         # Matched key -- delete bucket and return
 741         ##
 742         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 743         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 744         print($fh chr(0) x $BUCKET_SIZE );
 745
 746         return 1;
 747         } # i loop
 748
 749         return;
 750 }
 751
 752 sub _bucket_exists {
 753         ##
 754         # Check existence of single key given tag and MD5 digested key.
 755         ##
 756         my $self = shift;
 757         my ($tag, $md5) = @_;
 758         my $keys = $tag->{content};
 759
 760         ##
 761         # Iterate through buckets, looking for a key match
 762         ##
 763     BUCKET:
 764         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 765                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 766                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 767
 768                 if (!$subloc) {
 769                         ##
 770                         # Hit end of list, no match
 771                         ##
 772                         return;
 773                 }
 774
 775         if ( $md5 ne $key ) {
 776             next BUCKET;
 777         }
 778
 779         ##
 780         # Matched key -- return true
 781         ##
 782         return 1;
 783         } # i loop
 784
 785         return;
 786 }
 787
 788 sub _find_bucket_list {
 789         ##
 790         # Locate offset for bucket list, given digested key
 791         ##
 792         my $self = shift;
 793         my $md5 = shift;
 794
 795         ##
 796         # Locate offset for bucket list using digest index system
 797         ##
 798         my $ch = 0;
 799         my $tag = $self->_load_tag($self->base_offset);
 800         if (!$tag) { return; }
 801
 802         while ($tag->{signature} ne SIG_BLIST) {
 803                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 804                 if (!$tag) { return; }
 805                 $ch++;
 806         }
 807
 808         return $tag;
 809 }
 810
 811 sub _traverse_index {
 812         ##
 813         # Scan index and recursively step into deeper levels, looking for next key.
 814         ##
 815     my ($self, $offset, $ch, $force_return_next) = @_;
 816     $force_return_next = undef unless $force_return_next;
 817
 818         my $tag = $self->_load_tag( $offset );
 819
 820     my $fh = $self->fh;
 821
 822         if ($tag->{signature} ne SIG_BLIST) {
 823                 my $content = $tag->{content};
 824                 my $start;
 825                 if ($self->{return_next}) { $start = 0; }
 826                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 827
 828                 for (my $index = $start; $index < 256; $index++) {
 829                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 830                         if ($subloc) {
 831                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 832                                 if (defined($result)) { return $result; }
 833                         }
 834                 } # index loop
 835
 836                 $self->{return_next} = 1;
 837         } # tag is an index
 838
 839         elsif ($tag->{signature} eq SIG_BLIST) {
 840                 my $keys = $tag->{content};
 841                 if ($force_return_next) { $self->{return_next} = 1; }
 842
 843                 ##
 844                 # Iterate through buckets, looking for a key match
 845                 ##
 846                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 847                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 848                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 849
 850                         if (!$subloc) {
 851                                 ##
 852                                 # End of bucket list -- return to outer loop
 853                                 ##
 854                                 $self->{return_next} = 1;
 855                                 last;
 856                         }
 857                         elsif ($key eq $self->{prev_md5}) {
 858                                 ##
 859                                 # Located previous key -- return next one found
 860                                 ##
 861                                 $self->{return_next} = 1;
 862                                 next;
 863                         }
 864                         elsif ($self->{return_next}) {
 865                                 ##
 866                                 # Seek to bucket location and skip over signature
 867                                 ##
 868                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 869
 870                                 ##
 871                                 # Skip over value to get to plain key
 872                                 ##
 873                                 my $size;
 874                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 875                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 876
 877                                 ##
 878                                 # Read in plain key and return as scalar
 879                                 ##
 880                                 my $plain_key;
 881                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 882                                 if ($size) { read( $fh, $plain_key, $size); }
 883
 884                                 return $plain_key;
 885                         }
 886                 } # bucket loop
 887
 888                 $self->{return_next} = 1;
 889         } # tag is a bucket list
 890
 891         return;
 892 }
 893
 894 sub _get_next_key {
 895         ##
 896         # Locate next key, given digested previous one
 897         ##
 898     my $self = $_[0]->_get_self;
 899
 900         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 901         $self->{return_next} = 0;
 902
 903         ##
 904         # If the previous key was not specifed, start at the top and
 905         # return the first one found.
 906         ##
 907         if (!$self->{prev_md5}) {
 908                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 909                 $self->{return_next} = 1;
 910         }
 911
 912         return $self->_traverse_index( $self->base_offset, 0 );
 913 }
 914
 915 sub lock {
 916         ##
 917         # If db locking is set, flock() the db file.  If called multiple
 918         # times before unlock(), then the same number of unlocks() must
 919         # be called before the lock is released.
 920         ##
 921     my $self = $_[0]->_get_self;
 922         my $type = $_[1];
 923     $type = LOCK_EX unless defined $type;
 924
 925         if (!defined($self->fh)) { return; }
 926
 927         if ($self->root->{locking}) {
 928                 if (!$self->root->{locked}) {
 929                         flock($self->fh, $type);
 930
 931                         # double-check file inode, in case another process
 932                         # has optimize()d our file while we were waiting.
 933                         if ((stat($self->root->{file}))[1] != $self->root->{inode}) {
 934                                 $self->_open(); # re-open
 935                                 flock($self->fh, $type); # re-lock
 936                         }
 937                 }
 938                 $self->root->{locked}++;
 939
 940         return 1;
 941         }
 942
 943     return;
 944 }
 945
 946 sub unlock {
 947         ##
 948         # If db locking is set, unlock the db file.  See note in lock()
 949         # regarding calling lock() multiple times.
 950         ##
 951     my $self = $_[0]->_get_self;
 952
 953         if (!defined($self->fh)) { return; }
 954
 955         if ($self->root->{locking} && $self->root->{locked} > 0) {
 956                 $self->root->{locked}--;
 957                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 958
 959         return 1;
 960         }
 961
 962     return;
 963 }
 964
 965 #XXX These uses of ref() need verified
 966 sub _copy_node {
 967         ##
 968         # Copy single level of keys or elements to new DB handle.
 969         # Recurse for nested structures
 970         ##
 971     my $self = $_[0]->_get_self;
 972         my $db_temp = $_[1];
 973
 974         if ($self->type eq TYPE_HASH) {
 975                 my $key = $self->first_key();
 976                 while ($key) {
 977                         my $value = $self->get($key);
 978 #XXX This doesn't work with autobless
 979                         if (!ref($value)) { $db_temp->{$key} = $value; }
 980                         else {
 981                                 my $type = $value->type;
 982                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 983                                 else { $db_temp->{$key} = []; }
 984                                 $value->_copy_node( $db_temp->{$key} );
 985                         }
 986                         $key = $self->next_key($key);
 987                 }
 988         }
 989         else {
 990                 my $length = $self->length();
 991                 for (my $index = 0; $index < $length; $index++) {
 992                         my $value = $self->get($index);
 993                         if (!ref($value)) { $db_temp->[$index] = $value; }
 994             #XXX NO tests for this code
 995                         else {
 996                                 my $type = $value->type;
 997                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 998                                 else { $db_temp->[$index] = []; }
 999                                 $value->_copy_node( $db_temp->[$index] );
1000                         }
1001                 }
1002         }
1003 }
1004
1005 sub export {
1006         ##
1007         # Recursively export into standard Perl hashes and arrays.
1008         ##
1009     my $self = $_[0]->_get_self;
1010
1011         my $temp;
1012         if ($self->type eq TYPE_HASH) { $temp = {}; }
1013         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
1014
1015         $self->lock();
1016         $self->_copy_node( $temp );
1017         $self->unlock();
1018
1019         return $temp;
1020 }
1021
1022 sub import {
1023         ##
1024         # Recursively import Perl hash/array structure
1025         ##
1026     #XXX This use of ref() seems to be ok
1027         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1028
1029     my $self = $_[0]->_get_self;
1030         my $struct = $_[1];
1031
1032     #XXX This use of ref() seems to be ok
1033         if (!ref($struct)) {
1034                 ##
1035                 # struct is not a reference, so just import based on our type
1036                 ##
1037                 shift @_;
1038
1039                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1040                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1041         }
1042
1043     my $r = Scalar::Util::reftype($struct) || '';
1044         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1045                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1046         }
1047         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1048                 $self->push( @$struct );
1049         }
1050         else {
1051                 return $self->_throw_error("Cannot import: type mismatch");
1052         }
1053
1054         return 1;
1055 }
1056
1057 sub optimize {
1058         ##
1059         # Rebuild entire database into new file, then move
1060         # it back on top of original.
1061         ##
1062     my $self = $_[0]->_get_self;
1063
1064 #XXX Need to create a new test for this
1065 #       if ($self->root->{links} > 1) {
1066 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1067 #       }
1068
1069         my $db_temp = DBM::Deep->new(
1070                 file => $self->root->{file} . '.tmp',
1071                 type => $self->type
1072         );
1073         if (!$db_temp) {
1074                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1075         }
1076
1077         $self->lock();
1078         $self->_copy_node( $db_temp );
1079         undef $db_temp;
1080
1081         ##
1082         # Attempt to copy user, group and permissions over to new file
1083         ##
1084         my @stats = stat($self->fh);
1085         my $perms = $stats[2] & 07777;
1086         my $uid = $stats[4];
1087         my $gid = $stats[5];
1088         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1089         chmod( $perms, $self->root->{file} . '.tmp' );
1090
1091     # q.v. perlport for more information on this variable
1092     if ( $^O eq 'MSWin32' || $^O eq 'cygwin' ) {
1093                 ##
1094                 # Potential race condition when optmizing on Win32 with locking.
1095                 # The Windows filesystem requires that the filehandle be closed
1096                 # before it is overwritten with rename().  This could be redone
1097                 # with a soft copy.
1098                 ##
1099                 $self->unlock();
1100                 $self->_close();
1101         }
1102
1103         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1104                 unlink $self->root->{file} . '.tmp';
1105                 $self->unlock();
1106                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1107         }
1108
1109         $self->unlock();
1110         $self->_close();
1111         $self->_open();
1112
1113         return 1;
1114 }
1115
1116 sub clone {
1117         ##
1118         # Make copy of object and return
1119         ##
1120     my $self = $_[0]->_get_self;
1121
1122         return DBM::Deep->new(
1123                 type => $self->type,
1124                 base_offset => $self->base_offset,
1125                 root => $self->root
1126         );
1127 }
1128
1129 {
1130     my %is_legal_filter = map {
1131         $_ => ~~1,
1132     } qw(
1133         store_key store_value
1134         fetch_key fetch_value
1135     );
1136
1137     sub set_filter {
1138         ##
1139         # Setup filter function for storing or fetching the key or value
1140         ##
1141         my $self = $_[0]->_get_self;
1142         my $type = lc $_[1];
1143         my $func = $_[2] ? $_[2] : undef;
1144
1145         if ( $is_legal_filter{$type} ) {
1146             $self->root->{"filter_$type"} = $func;
1147             return 1;
1148         }
1149
1150         return;
1151     }
1152 }
1153
1154 ##
1155 # Accessor methods
1156 ##
1157
1158 sub root {
1159         ##
1160         # Get access to the root structure
1161         ##
1162     my $self = $_[0]->_get_self;
1163         return $self->{root};
1164 }
1165
1166 sub fh {
1167         ##
1168         # Get access to the raw fh
1169         ##
1170     #XXX It will be useful, though, when we split out HASH and ARRAY
1171     my $self = $_[0]->_get_self;
1172         return $self->root->{fh};
1173 }
1174
1175 sub type {
1176         ##
1177         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1178         ##
1179     my $self = $_[0]->_get_self;
1180         return $self->{type};
1181 }
1182
1183 sub base_offset {
1184         ##
1185         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1186         ##
1187     my $self = $_[0]->_get_self;
1188         return $self->{base_offset};
1189 }
1190
1191 sub error {
1192         ##
1193         # Get last error string, or undef if no error
1194         ##
1195         return $_[0]
1196         #? ( _get_self($_[0])->{root}->{error} or undef )
1197         ? ( $_[0]->_get_self->{root}->{error} or undef )
1198         : $@;
1199 }
1200
1201 ##
1202 # Utility methods
1203 ##
1204
1205 sub _throw_error {
1206         ##
1207         # Store error string in self
1208         ##
1209     my $self = $_[0]->_get_self;
1210         my $error_text = $_[1];
1211
1212     if ( Scalar::Util::blessed $self ) {
1213         $self->root->{error} = $error_text;
1214
1215         unless ($self->root->{debug}) {
1216             die "DBM::Deep: $error_text\n";
1217         }
1218
1219         warn "DBM::Deep: $error_text\n";
1220         return;
1221     }
1222     else {
1223         die "DBM::Deep: $error_text\n";
1224     }
1225 }
1226
1227 sub clear_error {
1228         ##
1229         # Clear error state
1230         ##
1231     my $self = $_[0]->_get_self;
1232
1233         undef $self->root->{error};
1234 }
1235
1236 sub precalc_sizes {
1237         ##
1238         # Precalculate index, bucket and bucket list sizes
1239         ##
1240
1241     #XXX I don't like this ...
1242     set_pack() unless defined $LONG_SIZE;
1243
1244         $INDEX_SIZE = 256 * $LONG_SIZE;
1245         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1246         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1247 }
1248
1249 sub set_pack {
1250         ##
1251         # Set pack/unpack modes (see file header for more)
1252         ##
1253     my ($long_s, $long_p, $data_s, $data_p) = @_;
1254
1255     $LONG_SIZE = $long_s ? $long_s : 4;
1256     $LONG_PACK = $long_p ? $long_p : 'N';
1257
1258     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1259     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1260
1261         precalc_sizes();
1262 }
1263
1264 sub set_digest {
1265         ##
1266         # Set key digest function (default is MD5)
1267         ##
1268     my ($digest_func, $hash_size) = @_;
1269
1270     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1271     $HASH_SIZE = $hash_size ? $hash_size : 16;
1272
1273         precalc_sizes();
1274 }
1275
1276 ##
1277 # tie() methods (hashes and arrays)
1278 ##
1279
1280 sub STORE {
1281         ##
1282         # Store single hash key/value or array element in database.
1283         ##
1284     my $self = $_[0]->_get_self;
1285         my $key = $_[1];
1286
1287     # User may be storing a hash, in which case we do not want it run
1288     # through the filtering system
1289         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1290         ? $self->root->{filter_store_value}->($_[2])
1291         : $_[2];
1292
1293         my $md5 = $DIGEST_FUNC->($key);
1294
1295         ##
1296         # Make sure file is open
1297         ##
1298         if (!defined($self->fh) && !$self->_open()) {
1299                 return;
1300         }
1301         ##
1302
1303         ##
1304         # Request exclusive lock for writing
1305         ##
1306         $self->lock( LOCK_EX );
1307
1308         my $fh = $self->fh;
1309
1310         ##
1311         # If locking is enabled, set 'end' parameter again, in case another
1312         # DB instance appended to our file while we were unlocked.
1313         ##
1314         if ($self->root->{locking} || $self->root->{volatile}) {
1315                 $self->root->{end} = (stat($fh))[7];
1316         }
1317
1318         ##
1319         # Locate offset for bucket list using digest index system
1320         ##
1321         my $tag = $self->_load_tag($self->base_offset);
1322         if (!$tag) {
1323                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1324         }
1325
1326         my $ch = 0;
1327         while ($tag->{signature} ne SIG_BLIST) {
1328                 my $num = ord(substr($md5, $ch, 1));
1329                 my $new_tag = $self->_index_lookup($tag, $num);
1330                 if (!$new_tag) {
1331                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1332                         seek($fh, $ref_loc, SEEK_SET);
1333                         print($fh pack($LONG_PACK, $self->root->{end}) );
1334
1335                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1336                         $tag->{ref_loc} = $ref_loc;
1337                         $tag->{ch} = $ch;
1338                         last;
1339                 }
1340                 else {
1341                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1342                         $tag = $new_tag;
1343                         $tag->{ref_loc} = $ref_loc;
1344                         $tag->{ch} = $ch;
1345                 }
1346                 $ch++;
1347         }
1348
1349         ##
1350         # Add key/value to bucket list
1351         ##
1352         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1353
1354         $self->unlock();
1355
1356         return $result;
1357 }
1358
1359 sub FETCH {
1360         ##
1361         # Fetch single value or element given plain key or array index
1362         ##
1363     my $self = shift->_get_self;
1364     my $key = shift;
1365
1366         ##
1367         # Make sure file is open
1368         ##
1369         if (!defined($self->fh)) { $self->_open(); }
1370
1371         my $md5 = $DIGEST_FUNC->($key);
1372
1373         ##
1374         # Request shared lock for reading
1375         ##
1376         $self->lock( LOCK_SH );
1377
1378         my $tag = $self->_find_bucket_list( $md5 );
1379         if (!$tag) {
1380                 $self->unlock();
1381                 return;
1382         }
1383
1384         ##
1385         # Get value from bucket list
1386         ##
1387         my $result = $self->_get_bucket_value( $tag, $md5 );
1388
1389         $self->unlock();
1390
1391     #XXX What is ref() checking here?
1392     #YYY Filters only apply on scalar values, so the ref check is making
1393     #YYY sure the fetched bucket is a scalar, not a child hash or array.
1394         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1395         ? $self->root->{filter_fetch_value}->($result)
1396         : $result;
1397 }
1398
1399 sub DELETE {
1400         ##
1401         # Delete single key/value pair or element given plain key or array index
1402         ##
1403     my $self = $_[0]->_get_self;
1404         my $key = $_[1];
1405
1406         my $md5 = $DIGEST_FUNC->($key);
1407
1408         ##
1409         # Make sure file is open
1410         ##
1411         if (!defined($self->fh)) { $self->_open(); }
1412
1413         ##
1414         # Request exclusive lock for writing
1415         ##
1416         $self->lock( LOCK_EX );
1417
1418         my $tag = $self->_find_bucket_list( $md5 );
1419         if (!$tag) {
1420                 $self->unlock();
1421                 return;
1422         }
1423
1424         ##
1425         # Delete bucket
1426         ##
1427     my $value = $self->_get_bucket_value( $tag, $md5 );
1428         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1429         $value = $self->root->{filter_fetch_value}->($value);
1430     }
1431
1432         my $result = $self->_delete_bucket( $tag, $md5 );
1433
1434         ##
1435         # If this object is an array and the key deleted was on the end of the stack,
1436         # decrement the length variable.
1437         ##
1438
1439         $self->unlock();
1440
1441         return $value;
1442 }
1443
1444 sub EXISTS {
1445         ##
1446         # Check if a single key or element exists given plain key or array index
1447         ##
1448     my $self = $_[0]->_get_self;
1449         my $key = $_[1];
1450
1451         my $md5 = $DIGEST_FUNC->($key);
1452
1453         ##
1454         # Make sure file is open
1455         ##
1456         if (!defined($self->fh)) { $self->_open(); }
1457
1458         ##
1459         # Request shared lock for reading
1460         ##
1461         $self->lock( LOCK_SH );
1462
1463         my $tag = $self->_find_bucket_list( $md5 );
1464
1465         ##
1466         # For some reason, the built-in exists() function returns '' for false
1467         ##
1468         if (!$tag) {
1469                 $self->unlock();
1470                 return '';
1471         }
1472
1473         ##
1474         # Check if bucket exists and return 1 or ''
1475         ##
1476         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1477
1478         $self->unlock();
1479
1480         return $result;
1481 }
1482
1483 sub CLEAR {
1484         ##
1485         # Clear all keys from hash, or all elements from array.
1486         ##
1487     my $self = $_[0]->_get_self;
1488
1489         ##
1490         # Make sure file is open
1491         ##
1492         if (!defined($self->fh)) { $self->_open(); }
1493
1494         ##
1495         # Request exclusive lock for writing
1496         ##
1497         $self->lock( LOCK_EX );
1498
1499     my $fh = $self->fh;
1500
1501         seek($fh, $self->base_offset, SEEK_SET);
1502         if (eof $fh) {
1503                 $self->unlock();
1504                 return;
1505         }
1506
1507         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1508
1509         $self->unlock();
1510
1511         return 1;
1512 }
1513
1514 ##
1515 # Public method aliases
1516 ##
1517 sub put { (shift)->STORE( @_ ) }
1518 sub store { (shift)->STORE( @_ ) }
1519 sub get { (shift)->FETCH( @_ ) }
1520 sub fetch { (shift)->FETCH( @_ ) }
1521 sub delete { (shift)->DELETE( @_ ) }
1522 sub exists { (shift)->EXISTS( @_ ) }
1523 sub clear { (shift)->CLEAR( @_ ) }
1524
1525 package DBM::Deep::_::Root;
1526
1527 sub new {
1528     my $class = shift;
1529     my ($args) = @_;
1530
1531     my $self = bless {
1532         file => undef,
1533         fh => undef,
1534         end => 0,
1535         autoflush => undef,
1536         locking => undef,
1537         volatile => undef,
1538         debug => undef,
1539         filter_store_key => undef,
1540         filter_store_value => undef,
1541         filter_fetch_key => undef,
1542         filter_fetch_value => undef,
1543         autobless => undef,
1544         locked => 0,
1545         %$args,
1546     }, $class;
1547
1548     return $self;
1549 }
1550
1551 sub DESTROY {
1552     my $self = shift;
1553     return unless $self;
1554
1555     close $self->{fh} if $self->{fh};
1556
1557     return;
1558 }
1559
1560 1;
1561
1562 __END__
1563
1564 =head1 NAME
1565
1566 DBM::Deep - A pure perl multi-level hash/array DBM
1567
1568 =head1 SYNOPSIS
1569
1570   use DBM::Deep;
1571   my $db = DBM::Deep->new( "foo.db" );
1572
1573   $db->{key} = 'value'; # tie() style
1574   print $db->{key};
1575
1576   $db->put('key' => 'value'); # OO style
1577   print $db->get('key');
1578
1579   # true multi-level support
1580   $db->{my_complex} = [
1581         'hello', { perl => 'rules' },
1582         42, 99,
1583   ];
1584
1585 =head1 DESCRIPTION
1586
1587 A unique flat-file database module, written in pure perl.  True
1588 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1589 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1590 handle millions of keys and unlimited hash levels without significant
1591 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1592 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1593 Mac OS X and Windows.
1594
1595 =head1 INSTALLATION
1596
1597 Hopefully you are using Perl's excellent CPAN module, which will download
1598 and install the module for you.  If not, get the tarball, and run these
1599 commands:
1600
1601         tar zxf DBM-Deep-*
1602         cd DBM-Deep-*
1603         perl Makefile.PL
1604         make
1605         make test
1606         make install
1607
1608 =head1 SETUP
1609
1610 Construction can be done OO-style (which is the recommended way), or using
1611 Perl's tie() function.  Both are examined here.
1612
1613 =head2 OO CONSTRUCTION
1614
1615 The recommended way to construct a DBM::Deep object is to use the new()
1616 method, which gets you a blessed, tied hash or array reference.
1617
1618         my $db = DBM::Deep->new( "foo.db" );
1619
1620 This opens a new database handle, mapped to the file "foo.db".  If this
1621 file does not exist, it will automatically be created.  DB files are
1622 opened in "r+" (read/write) mode, and the type of object returned is a
1623 hash, unless otherwise specified (see L<OPTIONS> below).
1624
1625 You can pass a number of options to the constructor to specify things like
1626 locking, autoflush, etc.  This is done by passing an inline hash:
1627
1628         my $db = DBM::Deep->new(
1629                 file => "foo.db",
1630                 locking => 1,
1631                 autoflush => 1
1632         );
1633
1634 Notice that the filename is now specified I<inside> the hash with
1635 the "file" parameter, as opposed to being the sole argument to the
1636 constructor.  This is required if any options are specified.
1637 See L<OPTIONS> below for the complete list.
1638
1639
1640
1641 You can also start with an array instead of a hash.  For this, you must
1642 specify the C<type> parameter:
1643
1644         my $db = DBM::Deep->new(
1645                 file => "foo.db",
1646                 type => DBM::Deep->TYPE_ARRAY
1647         );
1648
1649 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1650 a new DB file.  If you create a DBM::Deep object with an existing file, the
1651 C<type> will be loaded from the file header, and an error will be thrown if
1652 the wrong type is passed in.
1653
1654 =head2 TIE CONSTRUCTION
1655
1656 Alternately, you can create a DBM::Deep handle by using Perl's built-in
1657 tie() function.  The object returned from tie() can be used to call methods,
1658 such as lock() and unlock(), but cannot be used to assign to the DBM::Deep
1659 file (as expected with most tie'd objects).
1660
1661         my %hash;
1662         my $db = tie %hash, "DBM::Deep", "foo.db";
1663
1664         my @array;
1665         my $db = tie @array, "DBM::Deep", "bar.db";
1666
1667 As with the OO constructor, you can replace the DB filename parameter with
1668 a hash containing one or more options (see L<OPTIONS> just below for the
1669 complete list).
1670
1671         tie %hash, "DBM::Deep", {
1672                 file => "foo.db",
1673                 locking => 1,
1674                 autoflush => 1
1675         };
1676
1677 =head2 OPTIONS
1678
1679 There are a number of options that can be passed in when constructing your
1680 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1681
1682 =over
1683
1684 =item * file
1685
1686 Filename of the DB file to link the handle to.  You can pass a full absolute
1687 filesystem path, partial path, or a plain filename if the file is in the
1688 current working directory.  This is a required parameter.
1689
1690 =item * type
1691
1692 This parameter specifies what type of object to create, a hash or array.  Use
1693 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1694 This only takes effect when beginning a new file.  This is an optional
1695 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1696
1697 =item * locking
1698
1699 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1700 function to lock the database in exclusive mode for writes, and shared mode for
1701 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1702 any child hashes or arrays> that use the same DB file.  This is an optional
1703 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1704
1705 =item * autoflush
1706
1707 Specifies whether autoflush is to be enabled on the underlying filehandle.
1708 This obviously slows down write operations, but is required if you may have
1709 multiple processes accessing the same DB file (also consider enable I<locking>
1710 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1711 parameter, and defaults to 0 (disabled).
1712
1713 =item * volatile
1714
1715 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1716 STORE() operation.  This is required if an outside force may change the size of
1717 the file between transactions.  Locking also implicitly enables volatile.  This
1718 is useful if you want to use a different locking system or write your own.  Pass
1719 any true value to enable.  This is an optional parameter, and defaults to 0
1720 (disabled).
1721
1722 =item * autobless
1723
1724 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1725 restore them when fetched.  This is an B<experimental> feature, and does have
1726 side-effects.  Basically, when hashes are re-blessed into their original
1727 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1728 able to call any DBM::Deep methods on them.  You have been warned.
1729 This is an optional parameter, and defaults to 0 (disabled).
1730
1731 =item * filter_*
1732
1733 See L<FILTERS> below.
1734
1735 =item * debug
1736
1737 Setting I<debug> mode will make all errors non-fatal, dump them out to
1738 STDERR, and continue on.  This is for debugging purposes only, and probably
1739 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1740
1741 =item * fh
1742
1743 Instead of passing a file path, you can instead pass a handle to an pre-opened
1744 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1745 contains your entire Perl script, as well as the data following the __DATA__
1746 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1747 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1748 in that.  Also please note optimize() will NOT work when passing in only a
1749 handle.  Pass in a real filename in order to use optimize().
1750
1751 =back
1752
1753 =head1 TIE INTERFACE
1754
1755 With DBM::Deep you can access your databases using Perl's standard hash/array
1756 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can
1757 treat them as such.  DBM::Deep will intercept all reads/writes and direct them
1758 to the right place -- the DB file.  This has nothing to do with the
1759 L<TIE CONSTRUCTION> section above.  This simply tells you how to use DBM::Deep
1760 using regular hashes and arrays, rather than calling functions like C<get()>
1761 and C<put()> (although those work too).  It is entirely up to you how to want
1762 to access your databases.
1763
1764 =head2 HASHES
1765
1766 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1767 or even nested hashes (or arrays) using standard Perl syntax:
1768
1769         my $db = DBM::Deep->new( "foo.db" );
1770
1771         $db->{mykey} = "myvalue";
1772         $db->{myhash} = {};
1773         $db->{myhash}->{subkey} = "subvalue";
1774
1775         print $db->{myhash}->{subkey} . "\n";
1776
1777 You can even step through hash keys using the normal Perl C<keys()> function:
1778
1779         foreach my $key (keys %$db) {
1780                 print "$key: " . $db->{$key} . "\n";
1781         }
1782
1783 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1784 pushes them onto an array, all before the loop even begins.  If you have an
1785 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1786 Perl's C<each()> function, which pulls keys/values one at a time, using very
1787 little memory:
1788
1789         while (my ($key, $value) = each %$db) {
1790                 print "$key: $value\n";
1791         }
1792
1793 Please note that when using C<each()>, you should always pass a direct
1794 hash reference, not a lookup.  Meaning, you should B<never> do this:
1795
1796         # NEVER DO THIS
1797         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1798
1799 This causes an infinite loop, because for each iteration, Perl is calling
1800 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1801 it effectively keeps returning the first key over and over again. Instead,
1802 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1803
1804 =head2 ARRAYS
1805
1806 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1807 reference.  This includes inserting, removing and manipulating elements,
1808 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1809 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1810 or simply be a nested array reference inside a hash.  Example:
1811
1812         my $db = DBM::Deep->new(
1813                 file => "foo-array.db",
1814                 type => DBM::Deep->TYPE_ARRAY
1815         );
1816
1817         $db->[0] = "foo";
1818         push @$db, "bar", "baz";
1819         unshift @$db, "bah";
1820
1821         my $last_elem = pop @$db; # baz
1822         my $first_elem = shift @$db; # bah
1823         my $second_elem = $db->[1]; # bar
1824
1825         my $num_elements = scalar @$db;
1826
1827 =head1 OO INTERFACE
1828
1829 In addition to the I<tie()> interface, you can also use a standard OO interface
1830 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1831 array) has its own methods, but both types share the following common methods:
1832 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1833
1834 =over
1835
1836 =item * put() / store()
1837
1838 Stores a new hash key/value pair, or sets an array element value.  Takes two
1839 arguments, the hash key or array index, and the new value.  The value can be
1840 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1841
1842         $db->put("foo", "bar"); # for hashes
1843         $db->put(1, "bar"); # for arrays
1844
1845 =item * get() / fetch()
1846
1847 Fetches the value of a hash key or array element.  Takes one argument: the hash
1848 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1849 data type stored.
1850
1851         my $value = $db->get("foo"); # for hashes
1852         my $value = $db->get(1); # for arrays
1853
1854 =item * exists()
1855
1856 Checks if a hash key or array index exists.  Takes one argument: the hash key
1857 or array index.  Returns true if it exists, false if not.
1858
1859         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1860         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1861
1862 =item * delete()
1863
1864 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1865 key or array index.  Returns true on success, false if not found.  For arrays,
1866 the remaining elements located after the deleted element are NOT moved over.
1867 The deleted element is essentially just undefined, which is exactly how Perl's
1868 internal arrays work.  Please note that the space occupied by the deleted
1869 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1870 below for details and workarounds.
1871
1872         $db->delete("foo"); # for hashes
1873         $db->delete(1); # for arrays
1874
1875 =item * clear()
1876
1877 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1878 value.  Please note that the space occupied by the deleted keys/values or
1879 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1880 details and workarounds.
1881
1882         $db->clear(); # hashes or arrays
1883
1884 =back
1885
1886 =head2 HASHES
1887
1888 For hashes, DBM::Deep supports all the common methods described above, and the
1889 following additional methods: C<first_key()> and C<next_key()>.
1890
1891 =over
1892
1893 =item * first_key()
1894
1895 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1896 fetched in an undefined order (which appears random).  Takes no arguments,
1897 returns the key as a scalar value.
1898
1899         my $key = $db->first_key();
1900
1901 =item * next_key()
1902
1903 Returns the "next" key in the hash, given the previous one as the sole argument.
1904 Returns undef if there are no more keys to be fetched.
1905
1906         $key = $db->next_key($key);
1907
1908 =back
1909
1910 Here are some examples of using hashes:
1911
1912         my $db = DBM::Deep->new( "foo.db" );
1913
1914         $db->put("foo", "bar");
1915         print "foo: " . $db->get("foo") . "\n";
1916
1917         $db->put("baz", {}); # new child hash ref
1918         $db->get("baz")->put("buz", "biz");
1919         print "buz: " . $db->get("baz")->get("buz") . "\n";
1920
1921         my $key = $db->first_key();
1922         while ($key) {
1923                 print "$key: " . $db->get($key) . "\n";
1924                 $key = $db->next_key($key);
1925         }
1926
1927         if ($db->exists("foo")) { $db->delete("foo"); }
1928
1929 =head2 ARRAYS
1930
1931 For arrays, DBM::Deep supports all the common methods described above, and the
1932 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1933 C<unshift()> and C<splice()>.
1934
1935 =over
1936
1937 =item * length()
1938
1939 Returns the number of elements in the array.  Takes no arguments.
1940
1941         my $len = $db->length();
1942
1943 =item * push()
1944
1945 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1946 refs or array refs.  No return value.
1947
1948         $db->push("foo", "bar", {});
1949
1950 =item * pop()
1951
1952 Fetches the last element in the array, and deletes it.  Takes no arguments.
1953 Returns undef if array is empty.  Returns the element value.
1954
1955         my $elem = $db->pop();
1956
1957 =item * shift()
1958
1959 Fetches the first element in the array, deletes it, then shifts all the
1960 remaining elements over to take up the space.  Returns the element value.  This
1961 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1962 details.
1963
1964         my $elem = $db->shift();
1965
1966 =item * unshift()
1967
1968 Inserts one or more elements onto the beginning of the array, shifting all
1969 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1970 No return value.  This method is not recommended with large arrays -- see
1971 <LARGE ARRAYS> below for details.
1972
1973         $db->unshift("foo", "bar", {});
1974
1975 =item * splice()
1976
1977 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1978 -f splice> for usage -- it is too complicated to document here.  This method is
1979 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1980
1981 =back
1982
1983 Here are some examples of using arrays:
1984
1985         my $db = DBM::Deep->new(
1986                 file => "foo.db",
1987                 type => DBM::Deep->TYPE_ARRAY
1988         );
1989
1990         $db->push("bar", "baz");
1991         $db->unshift("foo");
1992         $db->put(3, "buz");
1993
1994         my $len = $db->length();
1995         print "length: $len\n"; # 4
1996
1997         for (my $k=0; $k<$len; $k++) {
1998                 print "$k: " . $db->get($k) . "\n";
1999         }
2000
2001         $db->splice(1, 2, "biz", "baf");
2002
2003         while (my $elem = shift @$db) {
2004                 print "shifted: $elem\n";
2005         }
2006
2007 =head1 LOCKING
2008
2009 Enable automatic file locking by passing a true value to the C<locking>
2010 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2011
2012         my $db = DBM::Deep->new(
2013                 file => "foo.db",
2014                 locking => 1
2015         );
2016
2017 This causes DBM::Deep to C<flock()> the underlying filehandle with exclusive
2018 mode for writes, and shared mode for reads.  This is required if you have
2019 multiple processes accessing the same database file, to avoid file corruption.
2020 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2021 NFS> below for more.
2022
2023 =head2 EXPLICIT LOCKING
2024
2025 You can explicitly lock a database, so it remains locked for multiple
2026 transactions.  This is done by calling the C<lock()> method, and passing an
2027 optional lock mode argument (defaults to exclusive mode).  This is particularly
2028 useful for things like counters, where the current value needs to be fetched,
2029 then incremented, then stored again.
2030
2031         $db->lock();
2032         my $counter = $db->get("counter");
2033         $counter++;
2034         $db->put("counter", $counter);
2035         $db->unlock();
2036
2037         # or...
2038
2039         $db->lock();
2040         $db->{counter}++;
2041         $db->unlock();
2042
2043 You can pass C<lock()> an optional argument, which specifies which mode to use
2044 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2045 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2046 same as the constants defined in Perl's C<Fcntl> module.
2047
2048         $db->lock( DBM::Deep->LOCK_SH );
2049         # something here
2050         $db->unlock();
2051
2052 If you want to implement your own file locking scheme, be sure to create your
2053 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2054 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2055 below for more.
2056
2057 =head1 IMPORTING/EXPORTING
2058
2059 You can import existing complex structures by calling the C<import()> method,
2060 and export an entire database into an in-memory structure using the C<export()>
2061 method.  Both are examined here.
2062
2063 =head2 IMPORTING
2064
2065 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2066 walking the structure and adding keys/elements to the database as you go,
2067 simply pass a reference to the C<import()> method.  This recursively adds
2068 everything to an existing DBM::Deep object for you.  Here is an example:
2069
2070         my $struct = {
2071                 key1 => "value1",
2072                 key2 => "value2",
2073                 array1 => [ "elem0", "elem1", "elem2" ],
2074                 hash1 => {
2075                         subkey1 => "subvalue1",
2076                         subkey2 => "subvalue2"
2077                 }
2078         };
2079
2080         my $db = DBM::Deep->new( "foo.db" );
2081         $db->import( $struct );
2082
2083         print $db->{key1} . "\n"; # prints "value1"
2084
2085 This recursively imports the entire C<$struct> object into C<$db>, including
2086 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2087 keys are merged with the existing ones, replacing if they already exist.
2088 The C<import()> method can be called on any database level (not just the base
2089 level), and works with both hash and array DB types.
2090
2091 B<Note:> Make sure your existing structure has no circular references in it.
2092 These will cause an infinite loop when importing.
2093
2094 =head2 EXPORTING
2095
2096 Calling the C<export()> method on an existing DBM::Deep object will return
2097 a reference to a new in-memory copy of the database.  The export is done
2098 recursively, so all nested hashes/arrays are all exported to standard Perl
2099 objects.  Here is an example:
2100
2101         my $db = DBM::Deep->new( "foo.db" );
2102
2103         $db->{key1} = "value1";
2104         $db->{key2} = "value2";
2105         $db->{hash1} = {};
2106         $db->{hash1}->{subkey1} = "subvalue1";
2107         $db->{hash1}->{subkey2} = "subvalue2";
2108
2109         my $struct = $db->export();
2110
2111         print $struct->{key1} . "\n"; # prints "value1"
2112
2113 This makes a complete copy of the database in memory, and returns a reference
2114 to it.  The C<export()> method can be called on any database level (not just
2115 the base level), and works with both hash and array DB types.  Be careful of
2116 large databases -- you can store a lot more data in a DBM::Deep object than an
2117 in-memory Perl structure.
2118
2119 B<Note:> Make sure your database has no circular references in it.
2120 These will cause an infinite loop when exporting.
2121
2122 =head1 FILTERS
2123
2124 DBM::Deep has a number of hooks where you can specify your own Perl function
2125 to perform filtering on incoming or outgoing data.  This is a perfect
2126 way to extend the engine, and implement things like real-time compression or
2127 encryption.  Filtering applies to the base DB level, and all child hashes /
2128 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2129 constructed, or by calling the C<set_filter()> method at any time.  There are
2130 four available filter hooks, described below:
2131
2132 =over
2133
2134 =item * filter_store_key
2135
2136 This filter is called whenever a hash key is stored.  It
2137 is passed the incoming key, and expected to return a transformed key.
2138
2139 =item * filter_store_value
2140
2141 This filter is called whenever a hash key or array element is stored.  It
2142 is passed the incoming value, and expected to return a transformed value.
2143
2144 =item * filter_fetch_key
2145
2146 This filter is called whenever a hash key is fetched (i.e. via
2147 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2148 and expected to return the plain key.
2149
2150 =item * filter_fetch_value
2151
2152 This filter is called whenever a hash key or array element is fetched.
2153 It is passed the transformed value, and expected to return the plain value.
2154
2155 =back
2156
2157 Here are the two ways to setup a filter hook:
2158
2159         my $db = DBM::Deep->new(
2160                 file => "foo.db",
2161                 filter_store_value => \&my_filter_store,
2162                 filter_fetch_value => \&my_filter_fetch
2163         );
2164
2165         # or...
2166
2167         $db->set_filter( "filter_store_value", \&my_filter_store );
2168         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2169
2170 Your filter function will be called only when dealing with SCALAR keys or
2171 values.  When nested hashes and arrays are being stored/fetched, filtering
2172 is bypassed.  Filters are called as static functions, passed a single SCALAR
2173 argument, and expected to return a single SCALAR value.  If you want to
2174 remove a filter, set the function reference to C<undef>:
2175
2176         $db->set_filter( "filter_store_value", undef );
2177
2178 =head2 REAL-TIME ENCRYPTION EXAMPLE
2179
2180 Here is a working example that uses the I<Crypt::Blowfish> module to
2181 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2182 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2183 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2184
2185         use DBM::Deep;
2186         use Crypt::Blowfish;
2187         use Crypt::CBC;
2188
2189         my $cipher = Crypt::CBC->new({
2190                 'key'             => 'my secret key',
2191                 'cipher'          => 'Blowfish',
2192                 'iv'              => '$KJh#(}q',
2193                 'regenerate_key'  => 0,
2194                 'padding'         => 'space',
2195                 'prepend_iv'      => 0
2196         });
2197
2198         my $db = DBM::Deep->new(
2199                 file => "foo-encrypt.db",
2200                 filter_store_key => \&my_encrypt,
2201                 filter_store_value => \&my_encrypt,
2202                 filter_fetch_key => \&my_decrypt,
2203                 filter_fetch_value => \&my_decrypt,
2204         );
2205
2206         $db->{key1} = "value1";
2207         $db->{key2} = "value2";
2208         print "key1: " . $db->{key1} . "\n";
2209         print "key2: " . $db->{key2} . "\n";
2210
2211         undef $db;
2212         exit;
2213
2214         sub my_encrypt {
2215                 return $cipher->encrypt( $_[0] );
2216         }
2217         sub my_decrypt {
2218                 return $cipher->decrypt( $_[0] );
2219         }
2220
2221 =head2 REAL-TIME COMPRESSION EXAMPLE
2222
2223 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2224 compression / decompression of keys & values with DBM::Deep Filters.
2225 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2226 more on I<Compress::Zlib>.
2227
2228         use DBM::Deep;
2229         use Compress::Zlib;
2230
2231         my $db = DBM::Deep->new(
2232                 file => "foo-compress.db",
2233                 filter_store_key => \&my_compress,
2234                 filter_store_value => \&my_compress,
2235                 filter_fetch_key => \&my_decompress,
2236                 filter_fetch_value => \&my_decompress,
2237         );
2238
2239         $db->{key1} = "value1";
2240         $db->{key2} = "value2";
2241         print "key1: " . $db->{key1} . "\n";
2242         print "key2: " . $db->{key2} . "\n";
2243
2244         undef $db;
2245         exit;
2246
2247         sub my_compress {
2248                 return Compress::Zlib::memGzip( $_[0] ) ;
2249         }
2250         sub my_decompress {
2251                 return Compress::Zlib::memGunzip( $_[0] ) ;
2252         }
2253
2254 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2255 actually numerical index numbers, and are not filtered.
2256
2257 =head1 ERROR HANDLING
2258
2259 Most DBM::Deep methods return a true value for success, and call die() on
2260 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2261 actual error message is stored in an internal scalar, which can be fetched by
2262 calling the C<error()> method.
2263
2264         my $db = DBM::Deep->new( "foo.db" ); # create hash
2265         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2266
2267     print $@;           # prints error message
2268         print $db->error(); # prints error message
2269
2270 You can then call C<clear_error()> to clear the current error state.
2271
2272         $db->clear_error();
2273
2274 If you set the C<debug> option to true when creating your DBM::Deep object,
2275 all errors are considered NON-FATAL, and dumped to STDERR.  This should only
2276 be used for debugging purposes and not production work. DBM::Deep expects errors
2277 to be thrown, not propagated back up the stack.
2278
2279 =head1 LARGEFILE SUPPORT
2280
2281 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2282 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2283 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2284 by calling the static C<set_pack()> method before you do anything else.
2285
2286         DBM::Deep::set_pack(8, 'Q');
2287
2288 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2289 instead of 32-bit longs.  After setting these values your DB files have a
2290 theoretical maximum size of 16 XB (exabytes).
2291
2292 B<Note:> Changing these values will B<NOT> work for existing database files.
2293 Only change this for new files, and make sure it stays set consistently
2294 throughout the file's life.  If you do set these values, you can no longer
2295 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2296 back to 32-bit mode.
2297
2298 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2299 only a 32-bit Perl.  However, I have received user reports that this does
2300 indeed work!
2301
2302 =head1 LOW-LEVEL ACCESS
2303
2304 If you require low-level access to the underlying filehandle that DBM::Deep uses,
2305 you can call the C<fh()> method, which returns the handle:
2306
2307         my $fh = $db->fh();
2308
2309 This method can be called on the root level of the datbase, or any child
2310 hashes or arrays.  All levels share a I<root> structure, which contains things
2311 like the filehandle, a reference counter, and all the options specified
2312 when you created the object.  You can get access to this root structure by
2313 calling the C<root()> method.
2314
2315         my $root = $db->root();
2316
2317 This is useful for changing options after the object has already been created,
2318 such as enabling/disabling locking, volatile or debug modes.  You can also
2319 store your own temporary user data in this structure (be wary of name
2320 collision), which is then accessible from any child hash or array.
2321
2322 =head1 CUSTOM DIGEST ALGORITHM
2323
2324 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2325 keys.  However you can override this, and use another algorithm (such as SHA-256)
2326 or even write your own.  But please note that DBM::Deep currently expects zero
2327 collisions, so your algorithm has to be I<perfect>, so to speak.
2328 Collision detection may be introduced in a later version.
2329
2330
2331
2332 You can specify a custom digest algorithm by calling the static C<set_digest()>
2333 function, passing a reference to a subroutine, and the length of the algorithm's
2334 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2335 objects.  Here is a working example that uses a 256-bit hash from the
2336 I<Digest::SHA256> module.  Please see
2337 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2338
2339         use DBM::Deep;
2340         use Digest::SHA256;
2341
2342         my $context = Digest::SHA256::new(256);
2343
2344         DBM::Deep::set_digest( \&my_digest, 32 );
2345
2346         my $db = DBM::Deep->new( "foo-sha.db" );
2347
2348         $db->{key1} = "value1";
2349         $db->{key2} = "value2";
2350         print "key1: " . $db->{key1} . "\n";
2351         print "key2: " . $db->{key2} . "\n";
2352
2353         undef $db;
2354         exit;
2355
2356         sub my_digest {
2357                 return substr( $context->hash($_[0]), 0, 32 );
2358         }
2359
2360 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2361 of bytes you specify in the C<set_digest()> function (in this case 32).
2362
2363 =head1 CIRCULAR REFERENCES
2364
2365 DBM::Deep has B<experimental> support for circular references.  Meaning you
2366 can have a nested hash key or array element that points to a parent object.
2367 This relationship is stored in the DB file, and is preserved between sessions.
2368 Here is an example:
2369
2370         my $db = DBM::Deep->new( "foo.db" );
2371
2372         $db->{foo} = "bar";
2373         $db->{circle} = $db; # ref to self
2374
2375         print $db->{foo} . "\n"; # prints "foo"
2376         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2377
2378 One catch is, passing the object to a function that recursively walks the
2379 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2380 C<export()> methods) will result in an infinite loop.  The other catch is,
2381 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2382 or C<next_key()> methods), you will get the I<target object's key>, not the
2383 ref's key.  This gets even more interesting with the above example, where
2384 the I<circle> key points to the base DB object, which technically doesn't
2385 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2386 special case.
2387
2388 =head1 CAVEATS / ISSUES / BUGS
2389
2390 This section describes all the known issues with DBM::Deep.  It you have found
2391 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2392
2393 =head2 UNUSED SPACE RECOVERY
2394
2395 One major caveat with DBM::Deep is that space occupied by existing keys and
2396 values is not recovered when they are deleted.  Meaning if you keep deleting
2397 and adding new keys, your file will continuously grow.  I am working on this,
2398 but in the meantime you can call the built-in C<optimize()> method from time to
2399 time (perhaps in a crontab or something) to recover all your unused space.
2400
2401         $db->optimize(); # returns true on success
2402
2403 This rebuilds the ENTIRE database into a new file, then moves it on top of
2404 the original.  The new file will have no unused space, thus it will take up as
2405 little disk space as possible.  Please note that this operation can take
2406 a long time for large files, and you need enough disk space to temporarily hold
2407 2 copies of your DB file.  The temporary file is created in the same directory
2408 as the original, named with a ".tmp" extension, and is deleted when the
2409 operation completes.  Oh, and if locking is enabled, the DB is automatically
2410 locked for the entire duration of the copy.
2411
2412 B<WARNING:> Only call optimize() on the top-level node of the database, and
2413 make sure there are no child references lying around.  DBM::Deep keeps a reference
2414 counter, and if it is greater than 1, optimize() will abort and return undef.
2415
2416 =head2 AUTOVIVIFICATION
2417
2418 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2419 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2420 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2421 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2422 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2423 this does not work:
2424
2425         $db->{foo}->{bar} = "hello";
2426
2427 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2428 being an empty hash.  Try this instead, which works fine:
2429
2430         $db->{foo} = { bar => "hello" };
2431
2432 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2433 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2434 Probably a bug in Perl.
2435
2436 =head2 FILE CORRUPTION
2437
2438 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2439 for a 32-bit signature when opened, but other corruption in files can cause
2440 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2441 stuck in an infinite loop depending on the level of corruption.  File write
2442 operations are not checked for failure (for speed), so if you happen to run
2443 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2444 be addressed in a later version of DBM::Deep.
2445
2446 =head2 DB OVER NFS
2447
2448 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2449 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2450 about setting up your NFS server with a locking daemon, then using lockf() to
2451 lock your files, but your mileage may vary there as well.  From what I
2452 understand, there is no real way to do it.  However, if you need access to the
2453 underlying filehandle in DBM::Deep for using some other kind of locking scheme like
2454 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2455
2456 =head2 COPYING OBJECTS
2457
2458 Beware of copying tied objects in Perl.  Very strange things can happen.
2459 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2460 returns a new, blessed, tied hash or array to the same level in the DB.
2461
2462         my $copy = $db->clone();
2463
2464 B<Note>: Since clone() here is cloning the object, not the database location, any
2465 modifications to either $db or $copy will be visible in both.
2466
2467 =head2 LARGE ARRAYS
2468
2469 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2470 These functions cause every element in the array to move, which can be murder
2471 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2472 a different location.  This will be addressed in the forthcoming version 1.00.
2473
2474 =head1 PERFORMANCE
2475
2476 This section discusses DBM::Deep's speed and memory usage.
2477
2478 =head2 SPEED
2479
2480 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2481 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2482 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2483 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2484 with huge databases.  Here is some test data:
2485
2486         Adding 1,000,000 keys to new DB file...
2487
2488         At 100 keys, avg. speed is 2,703 keys/sec
2489         At 200 keys, avg. speed is 2,642 keys/sec
2490         At 300 keys, avg. speed is 2,598 keys/sec
2491         At 400 keys, avg. speed is 2,578 keys/sec
2492         At 500 keys, avg. speed is 2,722 keys/sec
2493         At 600 keys, avg. speed is 2,628 keys/sec
2494         At 700 keys, avg. speed is 2,700 keys/sec
2495         At 800 keys, avg. speed is 2,607 keys/sec
2496         At 900 keys, avg. speed is 2,190 keys/sec
2497         At 1,000 keys, avg. speed is 2,570 keys/sec
2498         At 2,000 keys, avg. speed is 2,417 keys/sec
2499         At 3,000 keys, avg. speed is 1,982 keys/sec
2500         At 4,000 keys, avg. speed is 1,568 keys/sec
2501         At 5,000 keys, avg. speed is 1,533 keys/sec
2502         At 6,000 keys, avg. speed is 1,787 keys/sec
2503         At 7,000 keys, avg. speed is 1,977 keys/sec
2504         At 8,000 keys, avg. speed is 2,028 keys/sec
2505         At 9,000 keys, avg. speed is 2,077 keys/sec
2506         At 10,000 keys, avg. speed is 2,031 keys/sec
2507         At 20,000 keys, avg. speed is 1,970 keys/sec
2508         At 30,000 keys, avg. speed is 2,050 keys/sec
2509         At 40,000 keys, avg. speed is 2,073 keys/sec
2510         At 50,000 keys, avg. speed is 1,973 keys/sec
2511         At 60,000 keys, avg. speed is 1,914 keys/sec
2512         At 70,000 keys, avg. speed is 2,091 keys/sec
2513         At 80,000 keys, avg. speed is 2,103 keys/sec
2514         At 90,000 keys, avg. speed is 1,886 keys/sec
2515         At 100,000 keys, avg. speed is 1,970 keys/sec
2516         At 200,000 keys, avg. speed is 2,053 keys/sec
2517         At 300,000 keys, avg. speed is 1,697 keys/sec
2518         At 400,000 keys, avg. speed is 1,838 keys/sec
2519         At 500,000 keys, avg. speed is 1,941 keys/sec
2520         At 600,000 keys, avg. speed is 1,930 keys/sec
2521         At 700,000 keys, avg. speed is 1,735 keys/sec
2522         At 800,000 keys, avg. speed is 1,795 keys/sec
2523         At 900,000 keys, avg. speed is 1,221 keys/sec
2524         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2525
2526 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2527 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2528 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2529 Run time was 12 min 3 sec.
2530
2531 =head2 MEMORY USAGE
2532
2533 One of the great things about DBM::Deep is that it uses very little memory.
2534 Even with huge databases (1,000,000+ keys) you will not see much increased
2535 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2536 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2537 database handle:
2538
2539           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2540         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2541
2542 Basically the process is taking 2,716K of memory.  And here is the same
2543 process after storing and fetching 1,000,000 keys:
2544
2545           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2546         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2547
2548 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2549 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2550
2551 =head1 DB FILE FORMAT
2552
2553 In case you were interested in the underlying DB file format, it is documented
2554 here in this section.  You don't need to know this to use the module, it's just
2555 included for reference.
2556
2557 =head2 SIGNATURE
2558
2559 DBM::Deep files always start with a 32-bit signature to identify the file type.
2560 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2561 checked for when the file is opened and an error will be thrown if it's not found.
2562
2563 =head2 TAG
2564
2565 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2566 has a standard header containing the type of data, the length of data, and then
2567 the data itself.  The type is a single character (1 byte), the length is a
2568 32-bit unsigned long in network byte order, and the data is, well, the data.
2569 Here is how it unfolds:
2570
2571 =head2 MASTER INDEX
2572
2573 Immediately after the 32-bit file signature is the I<Master Index> record.
2574 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2575 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2576 depending on how the DBM::Deep object was constructed.
2577
2578 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2579 number).  The first 8-bit char of the MD5 signature is the offset into the
2580 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2581 index element is a file offset of the next tag for the key/element in question,
2582 which is usually a I<Bucket List> tag (see below).
2583
2584 The next tag I<could> be another index, depending on how many keys/elements
2585 exist.  See L<RE-INDEXING> below for details.
2586
2587 =head2 BUCKET LIST
2588
2589 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2590 file offsets to where the actual data is stored.  It starts with a standard
2591 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2592 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2593 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2594 When the list fills up, a I<Re-Index> operation is performed (See
2595 L<RE-INDEXING> below).
2596
2597 =head2 BUCKET
2598
2599 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2600 index/value pair (in array mode).  It starts with a standard tag header with
2601 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2602 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2603 header.  The size reported in the tag header is only for the value, but then,
2604 just after the value is another size (32-bit unsigned long) and then the plain
2605 key itself.  Since the value is likely to be fetched more often than the plain
2606 key, I figured it would be I<slightly> faster to store the value first.
2607
2608 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2609 record for the nested structure, where the process begins all over again.
2610
2611 =head2 RE-INDEXING
2612
2613 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2614 exhausted.  Then, when another key/element comes in, the list is converted to a
2615 new index record.  However, this index will look at the next char in the MD5
2616 hash, and arrange new Bucket List pointers accordingly.  This process is called
2617 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2618 17 (16 + new one) keys/elements are removed from the old Bucket List and
2619 inserted into the new index.  Several new Bucket Lists are created in the
2620 process, as a new MD5 char from the key is being examined (it is unlikely that
2621 the keys will all share the same next char of their MD5s).
2622
2623 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2624 when the Bucket Lists will turn into indexes, but the first round tends to
2625 happen right around 4,000 keys.  You will see a I<slight> decrease in
2626 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2627 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2628 right around 900,000 keys.  This process can continue nearly indefinitely --
2629 right up until the point the I<MD5> signatures start colliding with each other,
2630 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2631 getting struck by lightning while you are walking to cash in your tickets.
2632 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2633 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2634 this is 340 unodecillion, but don't quote me).
2635
2636 =head2 STORING
2637
2638 When a new key/element is stored, the key (or index number) is first run through
2639 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2640 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2641 for the first char of the signature (in this case I<b>).  If it does not exist,
2642 a new I<Bucket List> is created for our key (and the next 15 future keys that
2643 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2644 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2645 this point, unless we are replacing an existing I<Bucket>), where the actual
2646 data will be stored.
2647
2648 =head2 FETCHING
2649
2650 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2651 (or index number), then walking along the indexes.  If there are enough
2652 keys/elements in this DB level, there might be nested indexes, each linked to
2653 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2654 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2655 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2656 plain key are stored.
2657
2658 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2659 methods.  In this process the indexes are walked systematically, and each key
2660 fetched in increasing MD5 order (which is why it appears random).   Once the
2661 I<Bucket> is found, the value is skipped the plain key returned instead.
2662 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2663 alphabetically sorted.  This only happens on an index-level -- as soon as the
2664 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2665 so it's pretty much undefined how the keys will come out -- just like Perl's
2666 built-in hashes.
2667
2668 =head1 CODE COVERAGE
2669
2670 We use B<Devel::Cover> to test the code coverage of my tests, below is the
2671 B<Devel::Cover> report on this module's test suite.
2672
2673 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2674 File                           stmt   bran   cond    sub    pod   time  total
2675 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2676 blib/lib/DBM/Deep.pm           93.7   82.5   71.9   96.5   25.9   82.8   87.9
2677 blib/lib/DBM/Deep/Array.pm     98.8   88.0   90.9  100.0    n/a   12.8   96.3
2678 blib/lib/DBM/Deep/Hash.pm      95.2   80.0  100.0  100.0    n/a    4.4   92.3
2679 Total                          94.8   83.2   76.5   97.6   25.9  100.0   89.7
2680 ---------------------------- ------ ------ ------ ------ ------ ------ ------
2681
2682 =head1 AUTHORS
2683
2684 Joseph Huckaby, L<jhuckaby@cpan.org>
2685 Rob Kinyon, L<rkinyon@cpan.org>
2686
2687 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2688
2689 =head1 SEE ALSO
2690
2691 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2692 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2693
2694 =head1 LICENSE
2695
2696 Copyright (c) 2002-2006 Joseph Huckaby.  All Rights Reserved.
2697 This is free software, you may use it and distribute it under the
2698 same terms as Perl itself.
2699
2700 =cut