lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use FileHandle;
  35 use Fcntl qw/:flock/;
  36 use Digest::MD5 ();
  37 use Scalar::Util ();
  38 use vars qw/$VERSION/;
  39
  40 $VERSION = "0.96";
  41
  42 ##
  43 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  44 #       (Perl must be compiled with largefile support for files > 2 GB)
  45 #
  46 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47 #       (Perl must be compiled with largefile and 64-bit long support)
  48 ##
  49 #my $LONG_SIZE = 4;
  50 #my $LONG_PACK = 'N';
  51
  52 ##
  53 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  54 # Upgrading this is possible (see above) but probably not necessary.  If you need
  55 # more than 4 GB for a single key or value, this module is really not for you :-)
  56 ##
  57 #my $DATA_LENGTH_SIZE = 4;
  58 #my $DATA_LENGTH_PACK = 'N';
  59 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  60
  61 ##
  62 # Maximum number of buckets per list before another level of indexing is done.
  63 # Increase this value for slightly greater speed, but larger database files.
  64 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  65 ##
  66 my $MAX_BUCKETS = 16;
  67
  68 ##
  69 # Better not adjust anything below here, unless you're me :-)
  70 ##
  71
  72 ##
  73 # Setup digest function for keys
  74 ##
  75 my ($DIGEST_FUNC, $HASH_SIZE);
  76 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  77
  78 ##
  79 # Precalculate index and bucket sizes based on values above.
  80 ##
  81 #my $HASH_SIZE = 16;
  82 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  83
  84 set_digest();
  85 #set_pack();
  86 #precalc_sizes();
  87
  88 ##
  89 # Setup file and tag signatures.  These should never change.
  90 ##
  91 sub SIG_FILE  () { 'DPDB' }
  92 sub SIG_HASH  () { 'H' }
  93 sub SIG_ARRAY () { 'A' }
  94 sub SIG_NULL  () { 'N' }
  95 sub SIG_DATA  () { 'D' }
  96 sub SIG_INDEX () { 'I' }
  97 sub SIG_BLIST () { 'B' }
  98 sub SIG_SIZE  () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH  () { return SIG_HASH; }
 104 sub TYPE_ARRAY () { return SIG_ARRAY; }
 105
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116
 117         ##
 118         # Check if we want a tied hash or array.
 119         ##
 120         my $self;
 121         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 122                 tie @$self, $class, %$args;
 123         }
 124         else {
 125                 tie %$self, $class, %$args;
 126         }
 127
 128         return bless $self, $class;
 129 }
 130
 131 {
 132     my @outer_params = qw( type base_offset );
 133     sub _init {
 134         ##
 135         # Setup $self and bless into this class.
 136         ##
 137         my $class = shift;
 138         my $args = shift;
 139
 140         my $self = {
 141             type => TYPE_HASH,
 142             base_offset => length(SIG_FILE),
 143             root => {
 144                 file => undef,
 145                 fh => undef,
 146                 end => 0,
 147                 links => 0,
 148                 autoflush => undef,
 149                 locking => undef,
 150                 volatile => undef,
 151                 debug => undef,
 152                 mode => 'r+',
 153                 filter_store_key => undef,
 154                 filter_store_value => undef,
 155                 filter_fetch_key => undef,
 156                 filter_fetch_value => undef,
 157                 autobless => undef,
 158                 locked => 0,
 159                 %$args,
 160             },
 161         };
 162
 163         bless $self, $class;
 164
 165         foreach my $outer_parm ( @outer_params ) {
 166             next unless exists $args->{$outer_parm};
 167             $self->{$outer_parm} = $args->{$outer_parm}
 168         }
 169
 170         if ( exists $args->{root} ) {
 171             $self->{root} = $args->{root};
 172         }
 173         else {
 174             # This is cleanup based on the fact that the $args
 175             # coming in is for both the root and non-root items
 176             delete $self->root->{$_} for @outer_params;
 177         }
 178         $self->root->{links}++;
 179
 180         if (!defined($self->fh)) { $self->_open(); }
 181
 182         return $self;
 183     }
 184 }
 185
 186 sub _get_self { tied( %{$_[0]} ) || $_[0] }
 187
 188 sub TIEHASH {
 189     ##
 190     # Tied hash constructor method, called by Perl's tie() function.
 191     ##
 192     my $class = shift;
 193     my $args;
 194     if (scalar(@_) > 1) { $args = {@_}; }
 195     #XXX This use of ref() is bad and is a bug
 196     elsif (ref($_[0])) { $args = $_[0]; }
 197     else { $args = { file => shift }; }
 198
 199     $args->{type} = TYPE_HASH;
 200
 201     return $class->_init($args);
 202 }
 203
 204 sub TIEARRAY {
 205 ##
 206 # Tied array constructor method, called by Perl's tie() function.
 207 ##
 208     my $class = shift;
 209     my $args;
 210     if (scalar(@_) > 1) { $args = {@_}; }
 211     #XXX This use of ref() is bad and is a bug
 212         elsif (ref($_[0])) { $args = $_[0]; }
 213         else { $args = { file => shift }; }
 214
 215         $args->{type} = TYPE_ARRAY;
 216
 217         return $class->_init($args);
 218 }
 219
 220 sub DESTROY {
 221         ##
 222         # Class deconstructor.  Close file handle if there are no more refs.
 223         ##
 224     my $self = _get_self($_[0]);
 225     return unless $self;
 226
 227         $self->root->{links}--;
 228
 229         if (!$self->root->{links}) {
 230                 $self->_close();
 231         }
 232 }
 233
 234 sub _open {
 235         ##
 236         # Open a FileHandle to the database, create if nonexistent.
 237         # Make sure file signature matches DeepDB spec.
 238         ##
 239     my $self = _get_self($_[0]);
 240
 241         if (defined($self->fh)) { $self->_close(); }
 242
 243 #    eval {
 244         if (!(-e $self->root->{file}) && $self->root->{mode} eq 'r+') {
 245             my $temp = FileHandle->new( $self->root->{file}, 'w' );
 246         }
 247
 248         #XXX Convert to set_fh()
 249         $self->root->{fh} = FileHandle->new( $self->root->{file}, $self->root->{mode} );
 250 #    }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 251         if (! defined($self->fh)) {
 252                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 253         }
 254
 255     my $fh = $self->fh;
 256     binmode $fh; # for win32
 257     if ($self->root->{autoflush}) {
 258         my $old = select( $fh );
 259         $|++;
 260         select $old;
 261 #        $self->fh->autoflush();
 262     }
 263
 264     my $signature;
 265     seek($fh, 0, 0);
 266     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 267
 268     ##
 269     # File is empty -- write signature and master index
 270     ##
 271     if (!$bytes_read) {
 272         seek($fh, 0, 0);
 273         $fh->print(SIG_FILE);
 274         $self->root->{end} = length(SIG_FILE);
 275         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 276
 277         my $plain_key = "[base]";
 278         $fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 279         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 280         $fh->flush();
 281
 282         return 1;
 283     }
 284
 285     ##
 286     # Check signature was valid
 287     ##
 288     unless ($signature eq SIG_FILE) {
 289         $self->_close();
 290         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 291     }
 292
 293     $self->root->{end} = (stat($fh))[7];
 294
 295     ##
 296     # Get our type from master index signature
 297     ##
 298     my $tag = $self->_load_tag($self->base_offset);
 299 #XXX We probably also want to store the hash algorithm name and not assume anything
 300     if (!$tag) {
 301         return $self->_throw_error("Corrupted file, no master index record");
 302     }
 303     if ($self->{type} ne $tag->{signature}) {
 304         return $self->_throw_error("File type mismatch");
 305     }
 306
 307     return 1;
 308 }
 309
 310 sub _close {
 311         ##
 312         # Close database FileHandle
 313         ##
 314     my $self = _get_self($_[0]);
 315         undef $self->root->{fh};
 316 }
 317
 318 sub _create_tag {
 319         ##
 320         # Given offset, signature and content, create tag and write to disk
 321         ##
 322         my ($self, $offset, $sig, $content) = @_;
 323         my $size = length($content);
 324
 325     my $fh = $self->fh;
 326
 327         seek($fh, $offset, 0);
 328         $fh->print( $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 329
 330         if ($offset == $self->root->{end}) {
 331                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 332         }
 333
 334         return {
 335                 signature => $sig,
 336                 size => $size,
 337                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 338                 content => $content
 339         };
 340 }
 341
 342 sub _load_tag {
 343         ##
 344         # Given offset, load single tag and return signature, size and data
 345         ##
 346         my $self = shift;
 347         my $offset = shift;
 348
 349     my $fh = $self->fh;
 350
 351         seek($fh, $offset, 0);
 352         if (eof $fh) { return undef; }
 353
 354         my $sig;
 355         read( $fh, $sig, SIG_SIZE);
 356
 357         my $size;
 358         read( $fh, $size, $DATA_LENGTH_SIZE);
 359         $size = unpack($DATA_LENGTH_PACK, $size);
 360
 361         my $buffer;
 362         read( $fh, $buffer, $size);
 363
 364         return {
 365                 signature => $sig,
 366                 size => $size,
 367                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 368                 content => $buffer
 369         };
 370 }
 371
 372 sub _index_lookup {
 373         ##
 374         # Given index tag, lookup single entry in index and return .
 375         ##
 376         my $self = shift;
 377         my ($tag, $index) = @_;
 378
 379         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 380         if (!$location) { return; }
 381
 382         return $self->_load_tag( $location );
 383 }
 384
 385 sub _add_bucket {
 386         ##
 387         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 388         # plain (undigested) key and value.
 389         ##
 390         my $self = shift;
 391         my ($tag, $md5, $plain_key, $value) = @_;
 392         my $keys = $tag->{content};
 393         my $location = 0;
 394         my $result = 2;
 395
 396     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 397         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 398
 399     my $fh = $self->fh;
 400
 401         ##
 402         # Iterate through buckets, seeing if this is a new entry or a replace.
 403         ##
 404         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 405                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 406                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 407                 if (!$subloc) {
 408                         ##
 409                         # Found empty bucket (end of list).  Populate and exit loop.
 410                         ##
 411                         $result = 2;
 412
 413             $location = $internal_ref
 414                 ? $value->base_offset
 415                 : $self->root->{end};
 416
 417                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 418                         $fh->print( $md5 . pack($LONG_PACK, $location) );
 419                         last;
 420                 }
 421                 elsif ($md5 eq $key) {
 422                         ##
 423                         # Found existing bucket with same key.  Replace with new value.
 424                         ##
 425                         $result = 1;
 426
 427                         if ($internal_ref) {
 428                                 $location = $value->base_offset;
 429                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 430                                 $fh->print( $md5 . pack($LONG_PACK, $location) );
 431                         }
 432                         else {
 433                                 seek($fh, $subloc + SIG_SIZE, 0);
 434                                 my $size;
 435                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 436
 437                                 ##
 438                                 # If value is a hash, array, or raw value with equal or less size, we can
 439                                 # reuse the same content area of the database.  Otherwise, we have to create
 440                                 # a new content area at the EOF.
 441                                 ##
 442                                 my $actual_length;
 443                 my $r = Scalar::Util::reftype( $value ) || '';
 444                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 445                                 else { $actual_length = length($value); }
 446
 447                                 if ($actual_length <= $size) {
 448                                         $location = $subloc;
 449                                 }
 450                                 else {
 451                                         $location = $self->root->{end};
 452                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 453                                         $fh->print( pack($LONG_PACK, $location) );
 454                                 }
 455                         }
 456                         last;
 457                 }
 458         } # i loop
 459
 460         ##
 461         # If this is an internal reference, return now.
 462         # No need to write value or plain key
 463         ##
 464         if ($internal_ref) {
 465         return $result;
 466     }
 467
 468         ##
 469         # If bucket didn't fit into list, split into a new index level
 470         ##
 471         if (!$location) {
 472                 seek($fh, $tag->{ref_loc}, 0);
 473                 $fh->print( pack($LONG_PACK, $self->root->{end}) );
 474
 475                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 476                 my @offsets = ();
 477
 478                 $keys .= $md5 . pack($LONG_PACK, 0);
 479
 480                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 481                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 482                         if ($key) {
 483                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 484                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 485
 486                                 if ($offsets[$num]) {
 487                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 488                                         seek($fh, $offset, 0);
 489                                         my $subkeys;
 490                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 491
 492                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 493                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 494                                                 if (!$subloc) {
 495                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), 0);
 496                                                         $fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 497                                                         last;
 498                                                 }
 499                                         } # k loop
 500                                 }
 501                                 else {
 502                                         $offsets[$num] = $self->root->{end};
 503                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 504                                         $fh->print( pack($LONG_PACK, $self->root->{end}) );
 505
 506                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 507
 508                                         seek($fh, $blist_tag->{offset}, 0);
 509                                         $fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 510                                 }
 511                         } # key is real
 512                 } # i loop
 513
 514                 $location ||= $self->root->{end};
 515         } # re-index bucket list
 516
 517         ##
 518         # Seek to content area and store signature, value and plaintext key
 519         ##
 520         if ($location) {
 521                 my $content_length;
 522                 seek($fh, $location, 0);
 523
 524                 ##
 525                 # Write signature based on content type, set content length and write actual value.
 526                 ##
 527         my $r = Scalar::Util::reftype($value) || '';
 528                 if ($r eq 'HASH') {
 529                         $fh->print( TYPE_HASH );
 530                         $fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 531                         $content_length = $INDEX_SIZE;
 532                 }
 533                 elsif ($r eq 'ARRAY') {
 534                         $fh->print( TYPE_ARRAY );
 535                         $fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 536                         $content_length = $INDEX_SIZE;
 537                 }
 538                 elsif (!defined($value)) {
 539                         $fh->print( SIG_NULL );
 540                         $fh->print( pack($DATA_LENGTH_PACK, 0) );
 541                         $content_length = 0;
 542                 }
 543                 else {
 544                         $fh->print( SIG_DATA );
 545                         $fh->print( pack($DATA_LENGTH_PACK, length($value)) . $value );
 546                         $content_length = length($value);
 547                 }
 548
 549                 ##
 550                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 551                 ##
 552                 $fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 553
 554                 ##
 555                 # If value is blessed, preserve class name
 556                 ##
 557                 if ( $self->root->{autobless} ) {
 558             my $value_class = Scalar::Util::blessed($value);
 559             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 560                 ##
 561                 # Blessed ref -- will restore later
 562                 ##
 563                 $fh->print( chr(1) );
 564                 $fh->print( pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 565                 $content_length += 1;
 566                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 567             }
 568             else {
 569                 $fh->print( chr(0) );
 570                 $content_length += 1;
 571             }
 572         }
 573
 574                 ##
 575                 # If this is a new content area, advance EOF counter
 576                 ##
 577                 if ($location == $self->root->{end}) {
 578                         $self->root->{end} += SIG_SIZE;
 579                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 580                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 581                 }
 582
 583                 ##
 584                 # If content is a hash or array, create new child DeepDB object and
 585                 # pass each key or element to it.
 586                 ##
 587                 if ($r eq 'HASH') {
 588                         my $branch = DBM::Deep->new(
 589                                 type => TYPE_HASH,
 590                                 base_offset => $location,
 591                                 root => $self->root,
 592                         );
 593                         foreach my $key (keys %{$value}) {
 594                                 $branch->{$key} = $value->{$key};
 595                         }
 596                 }
 597                 elsif ($r eq 'ARRAY') {
 598                         my $branch = DBM::Deep->new(
 599                                 type => TYPE_ARRAY,
 600                                 base_offset => $location,
 601                                 root => $self->root,
 602                         );
 603                         my $index = 0;
 604                         foreach my $element (@{$value}) {
 605                                 $branch->[$index] = $element;
 606                                 $index++;
 607                         }
 608                 }
 609
 610                 return $result;
 611         }
 612
 613         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 614 }
 615
 616 sub _get_bucket_value {
 617         ##
 618         # Fetch single value given tag and MD5 digested key.
 619         ##
 620         my $self = shift;
 621         my ($tag, $md5) = @_;
 622         my $keys = $tag->{content};
 623
 624     my $fh = $self->fh;
 625
 626         ##
 627         # Iterate through buckets, looking for a key match
 628         ##
 629     BUCKET:
 630         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 631                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 632                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 633
 634                 if (!$subloc) {
 635                         ##
 636                         # Hit end of list, no match
 637                         ##
 638                         return;
 639                 }
 640
 641         if ( $md5 ne $key ) {
 642             next BUCKET;
 643         }
 644
 645         ##
 646         # Found match -- seek to offset and read signature
 647         ##
 648         my $signature;
 649         seek($fh, $subloc, 0);
 650         read( $fh, $signature, SIG_SIZE);
 651
 652         ##
 653         # If value is a hash or array, return new DeepDB object with correct offset
 654         ##
 655         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 656             my $obj = DBM::Deep->new(
 657                 type => $signature,
 658                 base_offset => $subloc,
 659                 root => $self->root
 660             );
 661
 662             if ($self->root->{autobless}) {
 663                 ##
 664                 # Skip over value and plain key to see if object needs
 665                 # to be re-blessed
 666                 ##
 667                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 668
 669                 my $size;
 670                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 671                 if ($size) { seek($fh, $size, 1); }
 672
 673                 my $bless_bit;
 674                 read( $fh, $bless_bit, 1);
 675                 if (ord($bless_bit)) {
 676                     ##
 677                     # Yes, object needs to be re-blessed
 678                     ##
 679                     my $class_name;
 680                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 681                     if ($size) { read( $fh, $class_name, $size); }
 682                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 683                 }
 684             }
 685
 686             return $obj;
 687         }
 688
 689         ##
 690         # Otherwise return actual value
 691         ##
 692         elsif ($signature eq SIG_DATA) {
 693             my $size;
 694             my $value = '';
 695             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 696             if ($size) { read( $fh, $value, $size); }
 697             return $value;
 698         }
 699
 700         ##
 701         # Key exists, but content is null
 702         ##
 703         else { return; }
 704         } # i loop
 705
 706         return;
 707 }
 708
 709 sub _delete_bucket {
 710         ##
 711         # Delete single key/value pair given tag and MD5 digested key.
 712         ##
 713         my $self = shift;
 714         my ($tag, $md5) = @_;
 715         my $keys = $tag->{content};
 716
 717     my $fh = $self->fh;
 718
 719         ##
 720         # Iterate through buckets, looking for a key match
 721         ##
 722     BUCKET:
 723         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 724                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 725                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 726
 727                 if (!$subloc) {
 728                         ##
 729                         # Hit end of list, no match
 730                         ##
 731                         return;
 732                 }
 733
 734         if ( $md5 ne $key ) {
 735             next BUCKET;
 736         }
 737
 738         ##
 739         # Matched key -- delete bucket and return
 740         ##
 741         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 742         $fh->print( substr($keys, ($i+1) * $BUCKET_SIZE ) );
 743         $fh->print( chr(0) x $BUCKET_SIZE );
 744
 745         return 1;
 746         } # i loop
 747
 748         return;
 749 }
 750
 751 sub _bucket_exists {
 752         ##
 753         # Check existence of single key given tag and MD5 digested key.
 754         ##
 755         my $self = shift;
 756         my ($tag, $md5) = @_;
 757         my $keys = $tag->{content};
 758
 759         ##
 760         # Iterate through buckets, looking for a key match
 761         ##
 762     BUCKET:
 763         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 764                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 765                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 766
 767                 if (!$subloc) {
 768                         ##
 769                         # Hit end of list, no match
 770                         ##
 771                         return;
 772                 }
 773
 774         if ( $md5 ne $key ) {
 775             next BUCKET;
 776         }
 777
 778         ##
 779         # Matched key -- return true
 780         ##
 781         return 1;
 782         } # i loop
 783
 784         return;
 785 }
 786
 787 sub _find_bucket_list {
 788         ##
 789         # Locate offset for bucket list, given digested key
 790         ##
 791         my $self = shift;
 792         my $md5 = shift;
 793
 794         ##
 795         # Locate offset for bucket list using digest index system
 796         ##
 797         my $ch = 0;
 798         my $tag = $self->_load_tag($self->base_offset);
 799         if (!$tag) { return; }
 800
 801         while ($tag->{signature} ne SIG_BLIST) {
 802                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 803                 if (!$tag) { return; }
 804                 $ch++;
 805         }
 806
 807         return $tag;
 808 }
 809
 810 sub _traverse_index {
 811         ##
 812         # Scan index and recursively step into deeper levels, looking for next key.
 813         ##
 814     my ($self, $offset, $ch, $force_return_next) = @_;
 815     $force_return_next = undef unless $force_return_next;
 816
 817         my $tag = $self->_load_tag( $offset );
 818
 819     my $fh = $self->fh;
 820
 821         if ($tag->{signature} ne SIG_BLIST) {
 822                 my $content = $tag->{content};
 823                 my $start;
 824                 if ($self->{return_next}) { $start = 0; }
 825                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 826
 827                 for (my $index = $start; $index < 256; $index++) {
 828                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 829                         if ($subloc) {
 830                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 831                                 if (defined($result)) { return $result; }
 832                         }
 833                 } # index loop
 834
 835                 $self->{return_next} = 1;
 836         } # tag is an index
 837
 838         elsif ($tag->{signature} eq SIG_BLIST) {
 839                 my $keys = $tag->{content};
 840                 if ($force_return_next) { $self->{return_next} = 1; }
 841
 842                 ##
 843                 # Iterate through buckets, looking for a key match
 844                 ##
 845                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 846                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 847                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 848
 849                         if (!$subloc) {
 850                                 ##
 851                                 # End of bucket list -- return to outer loop
 852                                 ##
 853                                 $self->{return_next} = 1;
 854                                 last;
 855                         }
 856                         elsif ($key eq $self->{prev_md5}) {
 857                                 ##
 858                                 # Located previous key -- return next one found
 859                                 ##
 860                                 $self->{return_next} = 1;
 861                                 next;
 862                         }
 863                         elsif ($self->{return_next}) {
 864                                 ##
 865                                 # Seek to bucket location and skip over signature
 866                                 ##
 867                                 seek($fh, $subloc + SIG_SIZE, 0);
 868
 869                                 ##
 870                                 # Skip over value to get to plain key
 871                                 ##
 872                                 my $size;
 873                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 874                                 if ($size) { seek($fh, $size, 1); }
 875
 876                                 ##
 877                                 # Read in plain key and return as scalar
 878                                 ##
 879                                 my $plain_key;
 880                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 881                                 if ($size) { read( $fh, $plain_key, $size); }
 882
 883                                 return $plain_key;
 884                         }
 885                 } # bucket loop
 886
 887                 $self->{return_next} = 1;
 888         } # tag is a bucket list
 889
 890         return;
 891 }
 892
 893 sub _get_next_key {
 894         ##
 895         # Locate next key, given digested previous one
 896         ##
 897     my $self = _get_self($_[0]);
 898
 899         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 900         $self->{return_next} = 0;
 901
 902         ##
 903         # If the previous key was not specifed, start at the top and
 904         # return the first one found.
 905         ##
 906         if (!$self->{prev_md5}) {
 907                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 908                 $self->{return_next} = 1;
 909         }
 910
 911         return $self->_traverse_index( $self->base_offset, 0 );
 912 }
 913
 914 sub lock {
 915         ##
 916         # If db locking is set, flock() the db file.  If called multiple
 917         # times before unlock(), then the same number of unlocks() must
 918         # be called before the lock is released.
 919         ##
 920     my $self = _get_self($_[0]);
 921         my $type = $_[1];
 922     $type = LOCK_EX unless defined $type;
 923
 924         if ($self->root->{locking}) {
 925                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 926                 $self->root->{locked}++;
 927         }
 928 }
 929
 930 sub unlock {
 931         ##
 932         # If db locking is set, unlock the db file.  See note in lock()
 933         # regarding calling lock() multiple times.
 934         ##
 935     my $self = _get_self($_[0]);
 936
 937         if ($self->root->{locking} && $self->root->{locked} > 0) {
 938                 $self->root->{locked}--;
 939                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 940         }
 941 }
 942
 943 #XXX These uses of ref() need verified
 944 sub _copy_node {
 945         ##
 946         # Copy single level of keys or elements to new DB handle.
 947         # Recurse for nested structures
 948         ##
 949     my $self = _get_self($_[0]);
 950         my $db_temp = $_[1];
 951
 952         if ($self->type eq TYPE_HASH) {
 953                 my $key = $self->first_key();
 954                 while ($key) {
 955                         my $value = $self->get($key);
 956 #XXX This doesn't work with autobless
 957                         if (!ref($value)) { $db_temp->{$key} = $value; }
 958                         else {
 959                                 my $type = $value->type;
 960                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 961                                 else { $db_temp->{$key} = []; }
 962                                 $value->_copy_node( $db_temp->{$key} );
 963                         }
 964                         $key = $self->next_key($key);
 965                 }
 966         }
 967         else {
 968                 my $length = $self->length();
 969                 for (my $index = 0; $index < $length; $index++) {
 970                         my $value = $self->get($index);
 971                         if (!ref($value)) { $db_temp->[$index] = $value; }
 972             #XXX NO tests for this code
 973                         else {
 974                                 my $type = $value->type;
 975                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 976                                 else { $db_temp->[$index] = []; }
 977                                 $value->_copy_node( $db_temp->[$index] );
 978                         }
 979                 }
 980         }
 981 }
 982
 983 sub export {
 984         ##
 985         # Recursively export into standard Perl hashes and arrays.
 986         ##
 987     my $self = _get_self($_[0]);
 988
 989         my $temp;
 990         if ($self->type eq TYPE_HASH) { $temp = {}; }
 991         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 992
 993         $self->lock();
 994         $self->_copy_node( $temp );
 995         $self->unlock();
 996
 997         return $temp;
 998 }
 999
1000 sub import {
1001         ##
1002         # Recursively import Perl hash/array structure
1003         ##
1004     #XXX This use of ref() seems to be ok
1005         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1006
1007     my $self = _get_self($_[0]);
1008         my $struct = $_[1];
1009
1010     #XXX This use of ref() seems to be ok
1011         if (!ref($struct)) {
1012                 ##
1013                 # struct is not a reference, so just import based on our type
1014                 ##
1015                 shift @_;
1016
1017                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1018                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1019         }
1020
1021     my $r = Scalar::Util::reftype($struct) || '';
1022         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1023                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1024         }
1025         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1026                 $self->push( @$struct );
1027         }
1028         else {
1029                 return $self->_throw_error("Cannot import: type mismatch");
1030         }
1031
1032         return 1;
1033 }
1034
1035 sub optimize {
1036         ##
1037         # Rebuild entire database into new file, then move
1038         # it back on top of original.
1039         ##
1040     my $self = _get_self($_[0]);
1041         if ($self->root->{links} > 1) {
1042                 return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1043         }
1044
1045         my $db_temp = DBM::Deep->new(
1046                 file => $self->root->{file} . '.tmp',
1047                 type => $self->type
1048         );
1049         if (!$db_temp) {
1050                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1051         }
1052
1053         $self->lock();
1054         $self->_copy_node( $db_temp );
1055         undef $db_temp;
1056
1057         ##
1058         # Attempt to copy user, group and permissions over to new file
1059         ##
1060         my @stats = stat($self->fh);
1061         my $perms = $stats[2] & 07777;
1062         my $uid = $stats[4];
1063         my $gid = $stats[5];
1064         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1065         chmod( $perms, $self->root->{file} . '.tmp' );
1066
1067     # q.v. perlport for more information on this variable
1068     if ( $^O eq 'MSWin32' ) {
1069                 ##
1070                 # Potential race condition when optmizing on Win32 with locking.
1071                 # The Windows filesystem requires that the filehandle be closed
1072                 # before it is overwritten with rename().  This could be redone
1073                 # with a soft copy.
1074                 ##
1075                 $self->unlock();
1076                 $self->_close();
1077         }
1078
1079         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1080                 unlink $self->root->{file} . '.tmp';
1081                 $self->unlock();
1082                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1083         }
1084
1085         $self->unlock();
1086         $self->_close();
1087         $self->_open();
1088
1089         return 1;
1090 }
1091
1092 sub clone {
1093         ##
1094         # Make copy of object and return
1095         ##
1096     my $self = _get_self($_[0]);
1097
1098         return DBM::Deep->new(
1099                 type => $self->type,
1100                 base_offset => $self->base_offset,
1101                 root => $self->root
1102         );
1103 }
1104
1105 {
1106     my %is_legal_filter = map {
1107         $_ => ~~1,
1108     } qw(
1109         store_key store_value
1110         fetch_key fetch_value
1111     );
1112
1113     sub set_filter {
1114         ##
1115         # Setup filter function for storing or fetching the key or value
1116         ##
1117         my $self = _get_self($_[0]);
1118         my $type = lc $_[1];
1119         my $func = $_[2] ? $_[2] : undef;
1120
1121         if ( $is_legal_filter{$type} ) {
1122             $self->root->{"filter_$type"} = $func;
1123             return 1;
1124         }
1125
1126         return;
1127     }
1128 }
1129
1130 ##
1131 # Accessor methods
1132 ##
1133
1134 sub root {
1135         ##
1136         # Get access to the root structure
1137         ##
1138     my $self = _get_self($_[0]);
1139         return $self->{root};
1140 }
1141
1142 sub fh {
1143         ##
1144         # Get access to the raw FileHandle
1145         ##
1146     #XXX It will be useful, though, when we split out HASH and ARRAY
1147     my $self = _get_self($_[0]);
1148         return $self->root->{fh};
1149 }
1150
1151 sub type {
1152         ##
1153         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1154         ##
1155     my $self = _get_self($_[0]);
1156         return $self->{type};
1157 }
1158
1159 sub base_offset {
1160         ##
1161         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1162         ##
1163     my $self = _get_self($_[0]);
1164         return $self->{base_offset};
1165 }
1166
1167 sub error {
1168         ##
1169         # Get last error string, or undef if no error
1170         ##
1171         return $_[0]
1172         ? ( _get_self($_[0])->{root}->{error} or undef )
1173         : $@;
1174 }
1175
1176 ##
1177 # Utility methods
1178 ##
1179
1180 sub _throw_error {
1181         ##
1182         # Store error string in self
1183         ##
1184     my $self = _get_self($_[0]);
1185         my $error_text = $_[1];
1186
1187         $self->root->{error} = $error_text;
1188
1189         unless ($self->root->{debug}) {
1190         die "DBM::Deep: $error_text\n";
1191     }
1192
1193     warn "DBM::Deep: $error_text\n";
1194         return;
1195 }
1196
1197 sub clear_error {
1198         ##
1199         # Clear error state
1200         ##
1201     my $self = _get_self($_[0]);
1202
1203         undef $self->root->{error};
1204 }
1205
1206 sub precalc_sizes {
1207         ##
1208         # Precalculate index, bucket and bucket list sizes
1209         ##
1210
1211     #XXX I don't like this ...
1212     set_pack() unless defined $LONG_SIZE;
1213
1214         $INDEX_SIZE = 256 * $LONG_SIZE;
1215         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1216         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1217 }
1218
1219 sub set_pack {
1220         ##
1221         # Set pack/unpack modes (see file header for more)
1222         ##
1223     my ($long_s, $long_p, $data_s, $data_p) = @_;
1224
1225     $LONG_SIZE = $long_s ? $long_s : 4;
1226     $LONG_PACK = $long_p ? $long_p : 'N';
1227
1228     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1229     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1230
1231         precalc_sizes();
1232 }
1233
1234 sub set_digest {
1235         ##
1236         # Set key digest function (default is MD5)
1237         ##
1238     my ($digest_func, $hash_size) = @_;
1239
1240     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1241     $HASH_SIZE = $hash_size ? $hash_size : 16;
1242
1243         precalc_sizes();
1244 }
1245
1246 ##
1247 # tie() methods (hashes and arrays)
1248 ##
1249
1250 sub STORE {
1251         ##
1252         # Store single hash key/value or array element in database.
1253         ##
1254     my $self = _get_self($_[0]);
1255         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1256     #XXX What is ref() checking here?
1257     #YYY User may be storing a hash, in which case we do not want it run
1258     #YYY through the filtering system
1259         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1260
1261         my $unpacked_key = $key;
1262         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1263         my $md5 = $DIGEST_FUNC->($key);
1264
1265         ##
1266         # Make sure file is open
1267         ##
1268         if (!defined($self->fh) && !$self->_open()) {
1269                 return;
1270         }
1271
1272     my $fh = $self->fh;
1273
1274         ##
1275         # Request exclusive lock for writing
1276         ##
1277         $self->lock( LOCK_EX );
1278
1279         ##
1280         # If locking is enabled, set 'end' parameter again, in case another
1281         # DB instance appended to our file while we were unlocked.
1282         ##
1283         if ($self->root->{locking} || $self->root->{volatile}) {
1284                 $self->root->{end} = (stat($fh))[7];
1285         }
1286
1287         ##
1288         # Locate offset for bucket list using digest index system
1289         ##
1290         my $tag = $self->_load_tag($self->base_offset);
1291         if (!$tag) {
1292                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1293         }
1294
1295         my $ch = 0;
1296         while ($tag->{signature} ne SIG_BLIST) {
1297                 my $num = ord(substr($md5, $ch, 1));
1298                 my $new_tag = $self->_index_lookup($tag, $num);
1299                 if (!$new_tag) {
1300                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1301                         seek($fh, $ref_loc, 0);
1302                         $fh->print( pack($LONG_PACK, $self->root->{end}) );
1303
1304                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1305                         $tag->{ref_loc} = $ref_loc;
1306                         $tag->{ch} = $ch;
1307                         last;
1308                 }
1309                 else {
1310                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1311                         $tag = $new_tag;
1312                         $tag->{ref_loc} = $ref_loc;
1313                         $tag->{ch} = $ch;
1314                 }
1315                 $ch++;
1316         }
1317
1318         ##
1319         # Add key/value to bucket list
1320         ##
1321         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1322
1323         ##
1324         # If this object is an array, and bucket was not a replace, and key is numerical,
1325         # and index is equal or greater than current length, advance length variable.
1326         ##
1327         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1328                 $self->STORESIZE( $unpacked_key + 1 );
1329         }
1330
1331         $self->unlock();
1332
1333         return $result;
1334 }
1335
1336 sub FETCH {
1337         ##
1338         # Fetch single value or element given plain key or array index
1339         ##
1340     my $self = _get_self($_[0]);
1341
1342     my $key = $_[1];
1343     if ( $self->type eq TYPE_HASH ) {
1344         if ( my $filter = $self->root->{filter_store_key} ) {
1345             $key = $filter->( $key );
1346         }
1347     }
1348     elsif ( $self->type eq TYPE_ARRAY ) {
1349         if ( $key =~ /^\d+$/ ) {
1350             $key = pack($LONG_PACK, $key);
1351         }
1352     }
1353
1354         my $md5 = $DIGEST_FUNC->($key);
1355
1356         ##
1357         # Make sure file is open
1358         ##
1359         if (!defined($self->fh)) { $self->_open(); }
1360
1361         ##
1362         # Request shared lock for reading
1363         ##
1364         $self->lock( LOCK_SH );
1365
1366         my $tag = $self->_find_bucket_list( $md5 );
1367         if (!$tag) {
1368                 $self->unlock();
1369                 return;
1370         }
1371
1372         ##
1373         # Get value from bucket list
1374         ##
1375         my $result = $self->_get_bucket_value( $tag, $md5 );
1376
1377         $self->unlock();
1378
1379     #XXX What is ref() checking here?
1380         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1381 }
1382
1383 sub DELETE {
1384         ##
1385         # Delete single key/value pair or element given plain key or array index
1386         ##
1387     my $self = _get_self($_[0]);
1388         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1389
1390         my $unpacked_key = $key;
1391         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1392         my $md5 = $DIGEST_FUNC->($key);
1393
1394         ##
1395         # Make sure file is open
1396         ##
1397         if (!defined($self->fh)) { $self->_open(); }
1398
1399         ##
1400         # Request exclusive lock for writing
1401         ##
1402         $self->lock( LOCK_EX );
1403
1404         my $tag = $self->_find_bucket_list( $md5 );
1405         if (!$tag) {
1406                 $self->unlock();
1407                 return;
1408         }
1409
1410         ##
1411         # Delete bucket
1412         ##
1413         my $result = $self->_delete_bucket( $tag, $md5 );
1414
1415         ##
1416         # If this object is an array and the key deleted was on the end of the stack,
1417         # decrement the length variable.
1418         ##
1419         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1420                 $self->STORESIZE( $unpacked_key );
1421         }
1422
1423         $self->unlock();
1424
1425         return $result;
1426 }
1427
1428 sub EXISTS {
1429         ##
1430         # Check if a single key or element exists given plain key or array index
1431         ##
1432     my $self = _get_self($_[0]);
1433         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1434
1435         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1436         my $md5 = $DIGEST_FUNC->($key);
1437
1438         ##
1439         # Make sure file is open
1440         ##
1441         if (!defined($self->fh)) { $self->_open(); }
1442
1443         ##
1444         # Request shared lock for reading
1445         ##
1446         $self->lock( LOCK_SH );
1447
1448         my $tag = $self->_find_bucket_list( $md5 );
1449
1450         ##
1451         # For some reason, the built-in exists() function returns '' for false
1452         ##
1453         if (!$tag) {
1454                 $self->unlock();
1455                 return '';
1456         }
1457
1458         ##
1459         # Check if bucket exists and return 1 or ''
1460         ##
1461         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1462
1463         $self->unlock();
1464
1465         return $result;
1466 }
1467
1468 sub CLEAR {
1469         ##
1470         # Clear all keys from hash, or all elements from array.
1471         ##
1472     my $self = _get_self($_[0]);
1473
1474         ##
1475         # Make sure file is open
1476         ##
1477         if (!defined($self->fh)) { $self->_open(); }
1478
1479         ##
1480         # Request exclusive lock for writing
1481         ##
1482         $self->lock( LOCK_EX );
1483
1484     my $fh = $self->fh;
1485
1486         seek($fh, $self->base_offset, 0);
1487         if (eof $fh) {
1488                 $self->unlock();
1489                 return;
1490         }
1491
1492         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1493
1494         $self->unlock();
1495
1496         return 1;
1497 }
1498
1499 sub FIRSTKEY {
1500         ##
1501         # Locate and return first key (in no particular order)
1502         ##
1503     my $self = _get_self($_[0]);
1504         if ($self->type ne TYPE_HASH) {
1505                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1506         }
1507
1508         ##
1509         # Make sure file is open
1510         ##
1511         if (!defined($self->fh)) { $self->_open(); }
1512
1513         ##
1514         # Request shared lock for reading
1515         ##
1516         $self->lock( LOCK_SH );
1517
1518         my $result = $self->_get_next_key();
1519
1520         $self->unlock();
1521
1522         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1523 }
1524
1525 sub NEXTKEY {
1526         ##
1527         # Return next key (in no particular order), given previous one
1528         ##
1529     my $self = _get_self($_[0]);
1530         if ($self->type ne TYPE_HASH) {
1531                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1532         }
1533         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1534         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1535
1536         ##
1537         # Make sure file is open
1538         ##
1539         if (!defined($self->fh)) { $self->_open(); }
1540
1541         ##
1542         # Request shared lock for reading
1543         ##
1544         $self->lock( LOCK_SH );
1545
1546         my $result = $self->_get_next_key( $prev_md5 );
1547
1548         $self->unlock();
1549
1550         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1551 }
1552
1553 ##
1554 # The following methods are for arrays only
1555 ##
1556
1557 sub FETCHSIZE {
1558         ##
1559         # Return the length of the array
1560         ##
1561     my $self = _get_self($_[0]);
1562         if ($self->type ne TYPE_ARRAY) {
1563                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1564         }
1565
1566         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1567         $self->root->{filter_fetch_value} = undef;
1568
1569         my $packed_size = $self->FETCH('length');
1570
1571         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1572
1573         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1574         else { return 0; }
1575 }
1576
1577 sub STORESIZE {
1578         ##
1579         # Set the length of the array
1580         ##
1581     my $self = _get_self($_[0]);
1582         if ($self->type ne TYPE_ARRAY) {
1583                 return $self->_throw_error("STORESIZE method only supported for arrays");
1584         }
1585         my $new_length = $_[1];
1586
1587         my $SAVE_FILTER = $self->root->{filter_store_value};
1588         $self->root->{filter_store_value} = undef;
1589
1590         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1591
1592         $self->root->{filter_store_value} = $SAVE_FILTER;
1593
1594         return $result;
1595 }
1596
1597 sub POP {
1598         ##
1599         # Remove and return the last element on the array
1600         ##
1601     my $self = _get_self($_[0]);
1602         if ($self->type ne TYPE_ARRAY) {
1603                 return $self->_throw_error("POP method only supported for arrays");
1604         }
1605         my $length = $self->FETCHSIZE();
1606
1607         if ($length) {
1608                 my $content = $self->FETCH( $length - 1 );
1609                 $self->DELETE( $length - 1 );
1610                 return $content;
1611         }
1612         else {
1613                 return;
1614         }
1615 }
1616
1617 sub PUSH {
1618         ##
1619         # Add new element(s) to the end of the array
1620         ##
1621     my $self = _get_self(shift);
1622         if ($self->type ne TYPE_ARRAY) {
1623                 return $self->_throw_error("PUSH method only supported for arrays");
1624         }
1625         my $length = $self->FETCHSIZE();
1626
1627         while (my $content = shift @_) {
1628                 $self->STORE( $length, $content );
1629                 $length++;
1630         }
1631 }
1632
1633 sub SHIFT {
1634         ##
1635         # Remove and return first element on the array.
1636         # Shift over remaining elements to take up space.
1637         ##
1638     my $self = _get_self($_[0]);
1639         if ($self->type ne TYPE_ARRAY) {
1640                 return $self->_throw_error("SHIFT method only supported for arrays");
1641         }
1642         my $length = $self->FETCHSIZE();
1643
1644         if ($length) {
1645                 my $content = $self->FETCH( 0 );
1646
1647                 ##
1648                 # Shift elements over and remove last one.
1649                 ##
1650                 for (my $i = 0; $i < $length - 1; $i++) {
1651                         $self->STORE( $i, $self->FETCH($i + 1) );
1652                 }
1653                 $self->DELETE( $length - 1 );
1654
1655                 return $content;
1656         }
1657         else {
1658                 return;
1659         }
1660 }
1661
1662 sub UNSHIFT {
1663         ##
1664         # Insert new element(s) at beginning of array.
1665         # Shift over other elements to make space.
1666         ##
1667     my $self = _get_self($_[0]);shift @_;
1668         if ($self->type ne TYPE_ARRAY) {
1669                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1670         }
1671         my @new_elements = @_;
1672         my $length = $self->FETCHSIZE();
1673         my $new_size = scalar @new_elements;
1674
1675         if ($length) {
1676                 for (my $i = $length - 1; $i >= 0; $i--) {
1677                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1678                 }
1679         }
1680
1681         for (my $i = 0; $i < $new_size; $i++) {
1682                 $self->STORE( $i, $new_elements[$i] );
1683         }
1684 }
1685
1686 sub SPLICE {
1687         ##
1688         # Splices section of array with optional new section.
1689         # Returns deleted section, or last element deleted in scalar context.
1690         ##
1691     my $self = _get_self($_[0]);shift @_;
1692         if ($self->type ne TYPE_ARRAY) {
1693                 return $self->_throw_error("SPLICE method only supported for arrays");
1694         }
1695         my $length = $self->FETCHSIZE();
1696
1697         ##
1698         # Calculate offset and length of splice
1699         ##
1700         my $offset = shift || 0;
1701         if ($offset < 0) { $offset += $length; }
1702
1703         my $splice_length;
1704         if (scalar @_) { $splice_length = shift; }
1705         else { $splice_length = $length - $offset; }
1706         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1707
1708         ##
1709         # Setup array with new elements, and copy out old elements for return
1710         ##
1711         my @new_elements = @_;
1712         my $new_size = scalar @new_elements;
1713
1714         my @old_elements = ();
1715         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1716                 push @old_elements, $self->FETCH( $i );
1717         }
1718
1719         ##
1720         # Adjust array length, and shift elements to accomodate new section.
1721         ##
1722     if ( $new_size != $splice_length ) {
1723         if ($new_size > $splice_length) {
1724             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1725                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1726             }
1727         }
1728         else {
1729             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1730                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1731             }
1732             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1733                 $self->DELETE( $length - 1 );
1734                 $length--;
1735             }
1736         }
1737         }
1738
1739         ##
1740         # Insert new elements into array
1741         ##
1742         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1743                 $self->STORE( $i, shift @new_elements );
1744         }
1745
1746         ##
1747         # Return deleted section, or last element in scalar context.
1748         ##
1749         return wantarray ? @old_elements : $old_elements[-1];
1750 }
1751
1752 #XXX We don't need to define it.
1753 #XXX It will be useful, though, when we split out HASH and ARRAY
1754 #sub EXTEND {
1755         ##
1756         # Perl will call EXTEND() when the array is likely to grow.
1757         # We don't care, but include it for compatibility.
1758         ##
1759 #}
1760
1761 ##
1762 # Public method aliases
1763 ##
1764 *put = *store = *STORE;
1765 *get = *fetch = *FETCH;
1766 *delete = *DELETE;
1767 *exists = *EXISTS;
1768 *clear = *CLEAR;
1769 *first_key = *FIRSTKEY;
1770 *next_key = *NEXTKEY;
1771 *length = *FETCHSIZE;
1772 *pop = *POP;
1773 *push = *PUSH;
1774 *shift = *SHIFT;
1775 *unshift = *UNSHIFT;
1776 *splice = *SPLICE;
1777
1778 1;
1779
1780 __END__
1781
1782 =head1 NAME
1783
1784 DBM::Deep - A pure perl multi-level hash/array DBM
1785
1786 =head1 SYNOPSIS
1787
1788   use DBM::Deep;
1789   my $db = DBM::Deep->new( "foo.db" );
1790
1791   $db->{key} = 'value'; # tie() style
1792   print $db->{key};
1793
1794   $db->put('key', 'value'); # OO style
1795   print $db->get('key');
1796
1797   # true multi-level support
1798   $db->{my_complex} = [
1799         'hello', { perl => 'rules' },
1800         42, 99 ];
1801
1802 =head1 DESCRIPTION
1803
1804 A unique flat-file database module, written in pure perl.  True
1805 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1806 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1807 handle millions of keys and unlimited hash levels without significant
1808 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1809 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1810 Mac OS X and Windows.
1811
1812 =head1 INSTALLATION
1813
1814 Hopefully you are using CPAN's excellent Perl module, which will download
1815 and install the module for you.  If not, get the tarball, and run these
1816 commands:
1817
1818         tar zxf DBM-Deep-*
1819         cd DBM-Deep-*
1820         perl Makefile.PL
1821         make
1822         make test
1823         make install
1824
1825 =head1 SETUP
1826
1827 Construction can be done OO-style (which is the recommended way), or using
1828 Perl's tie() function.  Both are examined here.
1829
1830 =head2 OO CONSTRUCTION
1831
1832 The recommended way to construct a DBM::Deep object is to use the new()
1833 method, which gets you a blessed, tied hash or array reference.
1834
1835         my $db = DBM::Deep->new( "foo.db" );
1836
1837 This opens a new database handle, mapped to the file "foo.db".  If this
1838 file does not exist, it will automatically be created.  DB files are
1839 opened in "r+" (read/write) mode, and the type of object returned is a
1840 hash, unless otherwise specified (see L<OPTIONS> below).
1841
1842
1843
1844 You can pass a number of options to the constructor to specify things like
1845 locking, autoflush, etc.  This is done by passing an inline hash:
1846
1847         my $db = DBM::Deep->new(
1848                 file => "foo.db",
1849                 locking => 1,
1850                 autoflush => 1
1851         );
1852
1853 Notice that the filename is now specified I<inside> the hash with
1854 the "file" parameter, as opposed to being the sole argument to the
1855 constructor.  This is required if any options are specified.
1856 See L<OPTIONS> below for the complete list.
1857
1858
1859
1860 You can also start with an array instead of a hash.  For this, you must
1861 specify the C<type> parameter:
1862
1863         my $db = DBM::Deep->new(
1864                 file => "foo.db",
1865                 type => DBM::Deep->TYPE_ARRAY
1866         );
1867
1868 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1869 a new DB file.  If you create a DBM::Deep object with an existing file, the
1870 C<type> will be loaded from the file header, and ignored if it is passed
1871 to the constructor.
1872
1873 =head2 TIE CONSTRUCTION
1874
1875 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1876 tie() function.  This is not ideal, because you get only a basic, tied hash
1877 (or array) which is not blessed, so you can't call any functions on it.
1878
1879         my %hash;
1880         tie %hash, "DBM::Deep", "foo.db";
1881
1882         my @array;
1883         tie @array, "DBM::Deep", "bar.db";
1884
1885 As with the OO constructor, you can replace the DB filename parameter with
1886 a hash containing one or more options (see L<OPTIONS> just below for the
1887 complete list).
1888
1889         tie %hash, "DBM::Deep", {
1890                 file => "foo.db",
1891                 locking => 1,
1892                 autoflush => 1
1893         };
1894
1895 =head2 OPTIONS
1896
1897 There are a number of options that can be passed in when constructing your
1898 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1899
1900 =over
1901
1902 =item * file
1903
1904 Filename of the DB file to link the handle to.  You can pass a full absolute
1905 filesystem path, partial path, or a plain filename if the file is in the
1906 current working directory.  This is a required parameter.
1907
1908 =item * mode
1909
1910 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1911 module.  This is an optional parameter, and defaults to "r+" (read/write).
1912 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1913 created if it doesn't exist.
1914
1915 =item * type
1916
1917 This parameter specifies what type of object to create, a hash or array.  Use
1918 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1919 This only takes effect when beginning a new file.  This is an optional
1920 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1921
1922 =item * locking
1923
1924 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1925 function to lock the database in exclusive mode for writes, and shared mode for
1926 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1927 any child hashes or arrays> that use the same DB file.  This is an optional
1928 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1929
1930 =item * autoflush
1931
1932 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1933 This obviously slows down write operations, but is required if you may have
1934 multiple processes accessing the same DB file (also consider enable I<locking>
1935 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1936 parameter, and defaults to 0 (disabled).
1937
1938 =item * volatile
1939
1940 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1941 STORE() operation.  This is required if an outside force may change the size of
1942 the file between transactions.  Locking also implicitly enables volatile.  This
1943 is useful if you want to use a different locking system or write your own.  Pass
1944 any true value to enable.  This is an optional parameter, and defaults to 0
1945 (disabled).
1946
1947 =item * autobless
1948
1949 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1950 restore them when fetched.  This is an B<experimental> feature, and does have
1951 side-effects.  Basically, when hashes are re-blessed into their original
1952 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1953 able to call any DBM::Deep methods on them.  You have been warned.
1954 This is an optional parameter, and defaults to 0 (disabled).
1955
1956 =item * filter_*
1957
1958 See L<FILTERS> below.
1959
1960 =item * debug
1961
1962 Setting I<debug> mode will make all errors non-fatal, dump them out to
1963 STDERR, and continue on.  This is for debugging purposes only, and probably
1964 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1965
1966 =item * fh
1967
1968 Instead of passing a file path, you can instead pass a handle to an pre-opened
1969 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1970 contains your entire Perl script, as well as the data following the __DATA__
1971 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1972 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1973 in that.
1974
1975 =back
1976
1977 =head1 TIE INTERFACE
1978
1979 With DBM::Deep you can access your databases using Perl's standard hash/array
1980 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1981 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1982 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1983 section above.  This simply tells you how to use DBM::Deep using regular hashes
1984 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1985 work too).  It is entirely up to you how to want to access your databases.
1986
1987 =head2 HASHES
1988
1989 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1990 or even nested hashes (or arrays) using standard Perl syntax:
1991
1992         my $db = DBM::Deep->new( "foo.db" );
1993
1994         $db->{mykey} = "myvalue";
1995         $db->{myhash} = {};
1996         $db->{myhash}->{subkey} = "subvalue";
1997
1998         print $db->{myhash}->{subkey} . "\n";
1999
2000 You can even step through hash keys using the normal Perl C<keys()> function:
2001
2002         foreach my $key (keys %$db) {
2003                 print "$key: " . $db->{$key} . "\n";
2004         }
2005
2006 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
2007 pushes them onto an array, all before the loop even begins.  If you have an
2008 extra large hash, this may exhaust Perl's memory.  Instead, consider using
2009 Perl's C<each()> function, which pulls keys/values one at a time, using very
2010 little memory:
2011
2012         while (my ($key, $value) = each %$db) {
2013                 print "$key: $value\n";
2014         }
2015
2016 Please note that when using C<each()>, you should always pass a direct
2017 hash reference, not a lookup.  Meaning, you should B<never> do this:
2018
2019         # NEVER DO THIS
2020         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
2021
2022 This causes an infinite loop, because for each iteration, Perl is calling
2023 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
2024 it effectively keeps returning the first key over and over again. Instead,
2025 assign a temporary variable to C<$db->{foo}>, then pass that to each().
2026
2027 =head2 ARRAYS
2028
2029 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2030 reference.  This includes inserting, removing and manipulating elements,
2031 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2032 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2033 or simply be a nested array reference inside a hash.  Example:
2034
2035         my $db = DBM::Deep->new(
2036                 file => "foo-array.db",
2037                 type => DBM::Deep->TYPE_ARRAY
2038         );
2039
2040         $db->[0] = "foo";
2041         push @$db, "bar", "baz";
2042         unshift @$db, "bah";
2043
2044         my $last_elem = pop @$db; # baz
2045         my $first_elem = shift @$db; # bah
2046         my $second_elem = $db->[1]; # bar
2047
2048         my $num_elements = scalar @$db;
2049
2050 =head1 OO INTERFACE
2051
2052 In addition to the I<tie()> interface, you can also use a standard OO interface
2053 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2054 array) has its own methods, but both types share the following common methods:
2055 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2056
2057 =over
2058
2059 =item * put()
2060
2061 Stores a new hash key/value pair, or sets an array element value.  Takes two
2062 arguments, the hash key or array index, and the new value.  The value can be
2063 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2064
2065         $db->put("foo", "bar"); # for hashes
2066         $db->put(1, "bar"); # for arrays
2067
2068 =item * get()
2069
2070 Fetches the value of a hash key or array element.  Takes one argument: the hash
2071 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2072 data type stored.
2073
2074         my $value = $db->get("foo"); # for hashes
2075         my $value = $db->get(1); # for arrays
2076
2077 =item * exists()
2078
2079 Checks if a hash key or array index exists.  Takes one argument: the hash key
2080 or array index.  Returns true if it exists, false if not.
2081
2082         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2083         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2084
2085 =item * delete()
2086
2087 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2088 key or array index.  Returns true on success, false if not found.  For arrays,
2089 the remaining elements located after the deleted element are NOT moved over.
2090 The deleted element is essentially just undefined, which is exactly how Perl's
2091 internal arrays work.  Please note that the space occupied by the deleted
2092 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2093 below for details and workarounds.
2094
2095         $db->delete("foo"); # for hashes
2096         $db->delete(1); # for arrays
2097
2098 =item * clear()
2099
2100 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2101 value.  Please note that the space occupied by the deleted keys/values or
2102 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2103 details and workarounds.
2104
2105         $db->clear(); # hashes or arrays
2106
2107 =back
2108
2109 =head2 HASHES
2110
2111 For hashes, DBM::Deep supports all the common methods described above, and the
2112 following additional methods: C<first_key()> and C<next_key()>.
2113
2114 =over
2115
2116 =item * first_key()
2117
2118 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2119 fetched in an undefined order (which appears random).  Takes no arguments,
2120 returns the key as a scalar value.
2121
2122         my $key = $db->first_key();
2123
2124 =item * next_key()
2125
2126 Returns the "next" key in the hash, given the previous one as the sole argument.
2127 Returns undef if there are no more keys to be fetched.
2128
2129         $key = $db->next_key($key);
2130
2131 =back
2132
2133 Here are some examples of using hashes:
2134
2135         my $db = DBM::Deep->new( "foo.db" );
2136
2137         $db->put("foo", "bar");
2138         print "foo: " . $db->get("foo") . "\n";
2139
2140         $db->put("baz", {}); # new child hash ref
2141         $db->get("baz")->put("buz", "biz");
2142         print "buz: " . $db->get("baz")->get("buz") . "\n";
2143
2144         my $key = $db->first_key();
2145         while ($key) {
2146                 print "$key: " . $db->get($key) . "\n";
2147                 $key = $db->next_key($key);
2148         }
2149
2150         if ($db->exists("foo")) { $db->delete("foo"); }
2151
2152 =head2 ARRAYS
2153
2154 For arrays, DBM::Deep supports all the common methods described above, and the
2155 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2156 C<unshift()> and C<splice()>.
2157
2158 =over
2159
2160 =item * length()
2161
2162 Returns the number of elements in the array.  Takes no arguments.
2163
2164         my $len = $db->length();
2165
2166 =item * push()
2167
2168 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2169 refs or array refs.  No return value.
2170
2171         $db->push("foo", "bar", {});
2172
2173 =item * pop()
2174
2175 Fetches the last element in the array, and deletes it.  Takes no arguments.
2176 Returns undef if array is empty.  Returns the element value.
2177
2178         my $elem = $db->pop();
2179
2180 =item * shift()
2181
2182 Fetches the first element in the array, deletes it, then shifts all the
2183 remaining elements over to take up the space.  Returns the element value.  This
2184 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2185 details.
2186
2187         my $elem = $db->shift();
2188
2189 =item * unshift()
2190
2191 Inserts one or more elements onto the beginning of the array, shifting all
2192 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2193 No return value.  This method is not recommended with large arrays -- see
2194 <LARGE ARRAYS> below for details.
2195
2196         $db->unshift("foo", "bar", {});
2197
2198 =item * splice()
2199
2200 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2201 -f splice> for usage -- it is too complicated to document here.  This method is
2202 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2203
2204 =back
2205
2206 Here are some examples of using arrays:
2207
2208         my $db = DBM::Deep->new(
2209                 file => "foo.db",
2210                 type => DBM::Deep->TYPE_ARRAY
2211         );
2212
2213         $db->push("bar", "baz");
2214         $db->unshift("foo");
2215         $db->put(3, "buz");
2216
2217         my $len = $db->length();
2218         print "length: $len\n"; # 4
2219
2220         for (my $k=0; $k<$len; $k++) {
2221                 print "$k: " . $db->get($k) . "\n";
2222         }
2223
2224         $db->splice(1, 2, "biz", "baf");
2225
2226         while (my $elem = shift @$db) {
2227                 print "shifted: $elem\n";
2228         }
2229
2230 =head1 LOCKING
2231
2232 Enable automatic file locking by passing a true value to the C<locking>
2233 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2234
2235         my $db = DBM::Deep->new(
2236                 file => "foo.db",
2237                 locking => 1
2238         );
2239
2240 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2241 mode for writes, and shared mode for reads.  This is required if you have
2242 multiple processes accessing the same database file, to avoid file corruption.
2243 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2244 NFS> below for more.
2245
2246 =head2 EXPLICIT LOCKING
2247
2248 You can explicitly lock a database, so it remains locked for multiple
2249 transactions.  This is done by calling the C<lock()> method, and passing an
2250 optional lock mode argument (defaults to exclusive mode).  This is particularly
2251 useful for things like counters, where the current value needs to be fetched,
2252 then incremented, then stored again.
2253
2254         $db->lock();
2255         my $counter = $db->get("counter");
2256         $counter++;
2257         $db->put("counter", $counter);
2258         $db->unlock();
2259
2260         # or...
2261
2262         $db->lock();
2263         $db->{counter}++;
2264         $db->unlock();
2265
2266 You can pass C<lock()> an optional argument, which specifies which mode to use
2267 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2268 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2269 same as the constants defined in Perl's C<Fcntl> module.
2270
2271         $db->lock( DBM::Deep->LOCK_SH );
2272         # something here
2273         $db->unlock();
2274
2275 If you want to implement your own file locking scheme, be sure to create your
2276 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2277 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2278 below for more.
2279
2280 =head1 IMPORTING/EXPORTING
2281
2282 You can import existing complex structures by calling the C<import()> method,
2283 and export an entire database into an in-memory structure using the C<export()>
2284 method.  Both are examined here.
2285
2286 =head2 IMPORTING
2287
2288 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2289 walking the structure and adding keys/elements to the database as you go,
2290 simply pass a reference to the C<import()> method.  This recursively adds
2291 everything to an existing DBM::Deep object for you.  Here is an example:
2292
2293         my $struct = {
2294                 key1 => "value1",
2295                 key2 => "value2",
2296                 array1 => [ "elem0", "elem1", "elem2" ],
2297                 hash1 => {
2298                         subkey1 => "subvalue1",
2299                         subkey2 => "subvalue2"
2300                 }
2301         };
2302
2303         my $db = DBM::Deep->new( "foo.db" );
2304         $db->import( $struct );
2305
2306         print $db->{key1} . "\n"; # prints "value1"
2307
2308 This recursively imports the entire C<$struct> object into C<$db>, including
2309 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2310 keys are merged with the existing ones, replacing if they already exist.
2311 The C<import()> method can be called on any database level (not just the base
2312 level), and works with both hash and array DB types.
2313
2314
2315
2316 B<Note:> Make sure your existing structure has no circular references in it.
2317 These will cause an infinite loop when importing.
2318
2319 =head2 EXPORTING
2320
2321 Calling the C<export()> method on an existing DBM::Deep object will return
2322 a reference to a new in-memory copy of the database.  The export is done
2323 recursively, so all nested hashes/arrays are all exported to standard Perl
2324 objects.  Here is an example:
2325
2326         my $db = DBM::Deep->new( "foo.db" );
2327
2328         $db->{key1} = "value1";
2329         $db->{key2} = "value2";
2330         $db->{hash1} = {};
2331         $db->{hash1}->{subkey1} = "subvalue1";
2332         $db->{hash1}->{subkey2} = "subvalue2";
2333
2334         my $struct = $db->export();
2335
2336         print $struct->{key1} . "\n"; # prints "value1"
2337
2338 This makes a complete copy of the database in memory, and returns a reference
2339 to it.  The C<export()> method can be called on any database level (not just
2340 the base level), and works with both hash and array DB types.  Be careful of
2341 large databases -- you can store a lot more data in a DBM::Deep object than an
2342 in-memory Perl structure.
2343
2344
2345
2346 B<Note:> Make sure your database has no circular references in it.
2347 These will cause an infinite loop when exporting.
2348
2349 =head1 FILTERS
2350
2351 DBM::Deep has a number of hooks where you can specify your own Perl function
2352 to perform filtering on incoming or outgoing data.  This is a perfect
2353 way to extend the engine, and implement things like real-time compression or
2354 encryption.  Filtering applies to the base DB level, and all child hashes /
2355 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2356 constructed, or by calling the C<set_filter()> method at any time.  There are
2357 four available filter hooks, described below:
2358
2359 =over
2360
2361 =item * filter_store_key
2362
2363 This filter is called whenever a hash key is stored.  It
2364 is passed the incoming key, and expected to return a transformed key.
2365
2366 =item * filter_store_value
2367
2368 This filter is called whenever a hash key or array element is stored.  It
2369 is passed the incoming value, and expected to return a transformed value.
2370
2371 =item * filter_fetch_key
2372
2373 This filter is called whenever a hash key is fetched (i.e. via
2374 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2375 and expected to return the plain key.
2376
2377 =item * filter_fetch_value
2378
2379 This filter is called whenever a hash key or array element is fetched.
2380 It is passed the transformed value, and expected to return the plain value.
2381
2382 =back
2383
2384 Here are the two ways to setup a filter hook:
2385
2386         my $db = DBM::Deep->new(
2387                 file => "foo.db",
2388                 filter_store_value => \&my_filter_store,
2389                 filter_fetch_value => \&my_filter_fetch
2390         );
2391
2392         # or...
2393
2394         $db->set_filter( "filter_store_value", \&my_filter_store );
2395         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2396
2397 Your filter function will be called only when dealing with SCALAR keys or
2398 values.  When nested hashes and arrays are being stored/fetched, filtering
2399 is bypassed.  Filters are called as static functions, passed a single SCALAR
2400 argument, and expected to return a single SCALAR value.  If you want to
2401 remove a filter, set the function reference to C<undef>:
2402
2403         $db->set_filter( "filter_store_value", undef );
2404
2405 =head2 REAL-TIME ENCRYPTION EXAMPLE
2406
2407 Here is a working example that uses the I<Crypt::Blowfish> module to
2408 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2409 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2410 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2411
2412         use DBM::Deep;
2413         use Crypt::Blowfish;
2414         use Crypt::CBC;
2415
2416         my $cipher = Crypt::CBC->new({
2417                 'key'             => 'my secret key',
2418                 'cipher'          => 'Blowfish',
2419                 'iv'              => '$KJh#(}q',
2420                 'regenerate_key'  => 0,
2421                 'padding'         => 'space',
2422                 'prepend_iv'      => 0
2423         });
2424
2425         my $db = DBM::Deep->new(
2426                 file => "foo-encrypt.db",
2427                 filter_store_key => \&my_encrypt,
2428                 filter_store_value => \&my_encrypt,
2429                 filter_fetch_key => \&my_decrypt,
2430                 filter_fetch_value => \&my_decrypt,
2431         );
2432
2433         $db->{key1} = "value1";
2434         $db->{key2} = "value2";
2435         print "key1: " . $db->{key1} . "\n";
2436         print "key2: " . $db->{key2} . "\n";
2437
2438         undef $db;
2439         exit;
2440
2441         sub my_encrypt {
2442                 return $cipher->encrypt( $_[0] );
2443         }
2444         sub my_decrypt {
2445                 return $cipher->decrypt( $_[0] );
2446         }
2447
2448 =head2 REAL-TIME COMPRESSION EXAMPLE
2449
2450 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2451 compression / decompression of keys & values with DBM::Deep Filters.
2452 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2453 more on I<Compress::Zlib>.
2454
2455         use DBM::Deep;
2456         use Compress::Zlib;
2457
2458         my $db = DBM::Deep->new(
2459                 file => "foo-compress.db",
2460                 filter_store_key => \&my_compress,
2461                 filter_store_value => \&my_compress,
2462                 filter_fetch_key => \&my_decompress,
2463                 filter_fetch_value => \&my_decompress,
2464         );
2465
2466         $db->{key1} = "value1";
2467         $db->{key2} = "value2";
2468         print "key1: " . $db->{key1} . "\n";
2469         print "key2: " . $db->{key2} . "\n";
2470
2471         undef $db;
2472         exit;
2473
2474         sub my_compress {
2475                 return Compress::Zlib::memGzip( $_[0] ) ;
2476         }
2477         sub my_decompress {
2478                 return Compress::Zlib::memGunzip( $_[0] ) ;
2479         }
2480
2481 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2482 actually numerical index numbers, and are not filtered.
2483
2484 =head1 ERROR HANDLING
2485
2486 Most DBM::Deep methods return a true value for success, and call die() on
2487 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2488 actual error message is stored in an internal scalar, which can be fetched by
2489 calling the C<error()> method.
2490
2491         my $db = DBM::Deep->new( "foo.db" ); # create hash
2492         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2493
2494         print $db->error(); # prints error message
2495
2496 You can then call C<clear_error()> to clear the current error state.
2497
2498         $db->clear_error();
2499
2500 If you set the C<debug> option to true when creating your DBM::Deep object,
2501 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2502 for debugging purposes.
2503
2504 =head1 LARGEFILE SUPPORT
2505
2506 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2507 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2508 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2509 by calling the static C<set_pack()> method before you do anything else.
2510
2511         DBM::Deep::set_pack(8, 'Q');
2512
2513 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2514 instead of 32-bit longs.  After setting these values your DB files have a
2515 theoretical maximum size of 16 XB (exabytes).
2516
2517
2518
2519 B<Note:> Changing these values will B<NOT> work for existing database files.
2520 Only change this for new files, and make sure it stays set consistently
2521 throughout the file's life.  If you do set these values, you can no longer
2522 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2523 back to 32-bit mode.
2524
2525
2526
2527 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2528 only a 32-bit Perl.  However, I have received user reports that this does
2529 indeed work!
2530
2531 =head1 LOW-LEVEL ACCESS
2532
2533 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2534 you can call the C<fh()> method, which returns the handle:
2535
2536         my $fh = $db->fh();
2537
2538 This method can be called on the root level of the datbase, or any child
2539 hashes or arrays.  All levels share a I<root> structure, which contains things
2540 like the FileHandle, a reference counter, and all your options you specified
2541 when you created the object.  You can get access to this root structure by
2542 calling the C<root()> method.
2543
2544         my $root = $db->root();
2545
2546 This is useful for changing options after the object has already been created,
2547 such as enabling/disabling locking, volatile or debug modes.  You can also
2548 store your own temporary user data in this structure (be wary of name
2549 collision), which is then accessible from any child hash or array.
2550
2551 =head1 CUSTOM DIGEST ALGORITHM
2552
2553 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2554 keys.  However you can override this, and use another algorithm (such as SHA-256)
2555 or even write your own.  But please note that DBM::Deep currently expects zero
2556 collisions, so your algorithm has to be I<perfect>, so to speak.
2557 Collision detection may be introduced in a later version.
2558
2559
2560
2561 You can specify a custom digest algorithm by calling the static C<set_digest()>
2562 function, passing a reference to a subroutine, and the length of the algorithm's
2563 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2564 objects.  Here is a working example that uses a 256-bit hash from the
2565 I<Digest::SHA256> module.  Please see
2566 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2567
2568         use DBM::Deep;
2569         use Digest::SHA256;
2570
2571         my $context = Digest::SHA256::new(256);
2572
2573         DBM::Deep::set_digest( \&my_digest, 32 );
2574
2575         my $db = DBM::Deep->new( "foo-sha.db" );
2576
2577         $db->{key1} = "value1";
2578         $db->{key2} = "value2";
2579         print "key1: " . $db->{key1} . "\n";
2580         print "key2: " . $db->{key2} . "\n";
2581
2582         undef $db;
2583         exit;
2584
2585         sub my_digest {
2586                 return substr( $context->hash($_[0]), 0, 32 );
2587         }
2588
2589 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2590 of bytes you specify in the C<set_digest()> function (in this case 32).
2591
2592 =head1 CIRCULAR REFERENCES
2593
2594 DBM::Deep has B<experimental> support for circular references.  Meaning you
2595 can have a nested hash key or array element that points to a parent object.
2596 This relationship is stored in the DB file, and is preserved between sessions.
2597 Here is an example:
2598
2599         my $db = DBM::Deep->new( "foo.db" );
2600
2601         $db->{foo} = "bar";
2602         $db->{circle} = $db; # ref to self
2603
2604         print $db->{foo} . "\n"; # prints "foo"
2605         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2606
2607 One catch is, passing the object to a function that recursively walks the
2608 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2609 C<export()> methods) will result in an infinite loop.  The other catch is,
2610 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2611 or C<next_key()> methods), you will get the I<target object's key>, not the
2612 ref's key.  This gets even more interesting with the above example, where
2613 the I<circle> key points to the base DB object, which technically doesn't
2614 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2615 special case.
2616
2617 =head1 CAVEATS / ISSUES / BUGS
2618
2619 This section describes all the known issues with DBM::Deep.  It you have found
2620 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2621
2622 =head2 UNUSED SPACE RECOVERY
2623
2624 One major caveat with DBM::Deep is that space occupied by existing keys and
2625 values is not recovered when they are deleted.  Meaning if you keep deleting
2626 and adding new keys, your file will continuously grow.  I am working on this,
2627 but in the meantime you can call the built-in C<optimize()> method from time to
2628 time (perhaps in a crontab or something) to recover all your unused space.
2629
2630         $db->optimize(); # returns true on success
2631
2632 This rebuilds the ENTIRE database into a new file, then moves it on top of
2633 the original.  The new file will have no unused space, thus it will take up as
2634 little disk space as possible.  Please note that this operation can take
2635 a long time for large files, and you need enough disk space to temporarily hold
2636 2 copies of your DB file.  The temporary file is created in the same directory
2637 as the original, named with a ".tmp" extension, and is deleted when the
2638 operation completes.  Oh, and if locking is enabled, the DB is automatically
2639 locked for the entire duration of the copy.
2640
2641
2642
2643 B<WARNING:> Only call optimize() on the top-level node of the database, and
2644 make sure there are no child references lying around.  DBM::Deep keeps a reference
2645 counter, and if it is greater than 1, optimize() will abort and return undef.
2646
2647 =head2 AUTOVIVIFICATION
2648
2649 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2650 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2651 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2652 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2653 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2654 this does not work:
2655
2656         $db->{foo}->{bar} = "hello";
2657
2658 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2659 being an empty hash.  Try this instead, which works fine:
2660
2661         $db->{foo} = { bar => "hello" };
2662
2663 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2664 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2665 Probably a bug in Perl.
2666
2667 =head2 FILE CORRUPTION
2668
2669 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2670 for a 32-bit signature when opened, but other corruption in files can cause
2671 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2672 stuck in an infinite loop depending on the level of corruption.  File write
2673 operations are not checked for failure (for speed), so if you happen to run
2674 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2675 be addressed in a later version of DBM::Deep.
2676
2677 =head2 DB OVER NFS
2678
2679 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2680 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2681 about setting up your NFS server with a locking daemon, then using lockf() to
2682 lock your files, but your milage may vary there as well.  From what I
2683 understand, there is no real way to do it.  However, if you need access to the
2684 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2685 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2686
2687 =head2 COPYING OBJECTS
2688
2689 Beware of copying tied objects in Perl.  Very strange things can happen.
2690 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2691 returns a new, blessed, tied hash or array to the same level in the DB.
2692
2693         my $copy = $db->clone();
2694
2695 =head2 LARGE ARRAYS
2696
2697 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2698 These functions cause every element in the array to move, which can be murder
2699 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2700 a different location.  This may be addressed in a later version.
2701
2702 =head1 PERFORMANCE
2703
2704 This section discusses DBM::Deep's speed and memory usage.
2705
2706 =head2 SPEED
2707
2708 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2709 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2710 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2711 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2712 with huge databases.  Here is some test data:
2713
2714         Adding 1,000,000 keys to new DB file...
2715
2716         At 100 keys, avg. speed is 2,703 keys/sec
2717         At 200 keys, avg. speed is 2,642 keys/sec
2718         At 300 keys, avg. speed is 2,598 keys/sec
2719         At 400 keys, avg. speed is 2,578 keys/sec
2720         At 500 keys, avg. speed is 2,722 keys/sec
2721         At 600 keys, avg. speed is 2,628 keys/sec
2722         At 700 keys, avg. speed is 2,700 keys/sec
2723         At 800 keys, avg. speed is 2,607 keys/sec
2724         At 900 keys, avg. speed is 2,190 keys/sec
2725         At 1,000 keys, avg. speed is 2,570 keys/sec
2726         At 2,000 keys, avg. speed is 2,417 keys/sec
2727         At 3,000 keys, avg. speed is 1,982 keys/sec
2728         At 4,000 keys, avg. speed is 1,568 keys/sec
2729         At 5,000 keys, avg. speed is 1,533 keys/sec
2730         At 6,000 keys, avg. speed is 1,787 keys/sec
2731         At 7,000 keys, avg. speed is 1,977 keys/sec
2732         At 8,000 keys, avg. speed is 2,028 keys/sec
2733         At 9,000 keys, avg. speed is 2,077 keys/sec
2734         At 10,000 keys, avg. speed is 2,031 keys/sec
2735         At 20,000 keys, avg. speed is 1,970 keys/sec
2736         At 30,000 keys, avg. speed is 2,050 keys/sec
2737         At 40,000 keys, avg. speed is 2,073 keys/sec
2738         At 50,000 keys, avg. speed is 1,973 keys/sec
2739         At 60,000 keys, avg. speed is 1,914 keys/sec
2740         At 70,000 keys, avg. speed is 2,091 keys/sec
2741         At 80,000 keys, avg. speed is 2,103 keys/sec
2742         At 90,000 keys, avg. speed is 1,886 keys/sec
2743         At 100,000 keys, avg. speed is 1,970 keys/sec
2744         At 200,000 keys, avg. speed is 2,053 keys/sec
2745         At 300,000 keys, avg. speed is 1,697 keys/sec
2746         At 400,000 keys, avg. speed is 1,838 keys/sec
2747         At 500,000 keys, avg. speed is 1,941 keys/sec
2748         At 600,000 keys, avg. speed is 1,930 keys/sec
2749         At 700,000 keys, avg. speed is 1,735 keys/sec
2750         At 800,000 keys, avg. speed is 1,795 keys/sec
2751         At 900,000 keys, avg. speed is 1,221 keys/sec
2752         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2753
2754 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2755 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2756 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2757 Run time was 12 min 3 sec.
2758
2759 =head2 MEMORY USAGE
2760
2761 One of the great things about DBM::Deep is that it uses very little memory.
2762 Even with huge databases (1,000,000+ keys) you will not see much increased
2763 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2764 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2765 database handle:
2766
2767           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2768         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2769
2770 Basically the process is taking 2,716K of memory.  And here is the same
2771 process after storing and fetching 1,000,000 keys:
2772
2773           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2774         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2775
2776 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2777 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2778
2779 =head1 DB FILE FORMAT
2780
2781 In case you were interested in the underlying DB file format, it is documented
2782 here in this section.  You don't need to know this to use the module, it's just
2783 included for reference.
2784
2785 =head2 SIGNATURE
2786
2787 DBM::Deep files always start with a 32-bit signature to identify the file type.
2788 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2789 checked when the file is opened.
2790
2791 =head2 TAG
2792
2793 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2794 has a standard header containing the type of data, the length of data, and then
2795 the data itself.  The type is a single character (1 byte), the length is a
2796 32-bit unsigned long in network byte order, and the data is, well, the data.
2797 Here is how it unfolds:
2798
2799 =head2 MASTER INDEX
2800
2801 Immediately after the 32-bit file signature is the I<Master Index> record.
2802 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2803 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2804 depending on how the DBM::Deep object was constructed.
2805
2806
2807
2808 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2809 number).  The first 8-bit char of the MD5 signature is the offset into the
2810 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2811 index element is a file offset of the next tag for the key/element in question,
2812 which is usually a I<Bucket List> tag (see below).
2813
2814
2815
2816 The next tag I<could> be another index, depending on how many keys/elements
2817 exist.  See L<RE-INDEXING> below for details.
2818
2819 =head2 BUCKET LIST
2820
2821 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2822 file offsets to where the actual data is stored.  It starts with a standard
2823 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2824 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2825 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2826 When the list fills up, a I<Re-Index> operation is performed (See
2827 L<RE-INDEXING> below).
2828
2829 =head2 BUCKET
2830
2831 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2832 index/value pair (in array mode).  It starts with a standard tag header with
2833 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2834 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2835 header.  The size reported in the tag header is only for the value, but then,
2836 just after the value is another size (32-bit unsigned long) and then the plain
2837 key itself.  Since the value is likely to be fetched more often than the plain
2838 key, I figured it would be I<slightly> faster to store the value first.
2839
2840
2841
2842 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2843 record for the nested structure, where the process begins all over again.
2844
2845 =head2 RE-INDEXING
2846
2847 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2848 exhausted.  Then, when another key/element comes in, the list is converted to a
2849 new index record.  However, this index will look at the next char in the MD5
2850 hash, and arrange new Bucket List pointers accordingly.  This process is called
2851 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2852 17 (16 + new one) keys/elements are removed from the old Bucket List and
2853 inserted into the new index.  Several new Bucket Lists are created in the
2854 process, as a new MD5 char from the key is being examined (it is unlikely that
2855 the keys will all share the same next char of their MD5s).
2856
2857
2858
2859 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2860 when the Bucket Lists will turn into indexes, but the first round tends to
2861 happen right around 4,000 keys.  You will see a I<slight> decrease in
2862 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2863 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2864 right around 900,000 keys.  This process can continue nearly indefinitely --
2865 right up until the point the I<MD5> signatures start colliding with each other,
2866 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2867 getting struck by lightning while you are walking to cash in your tickets.
2868 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2869 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2870 this is 340 unodecillion, but don't quote me).
2871
2872 =head2 STORING
2873
2874 When a new key/element is stored, the key (or index number) is first ran through
2875 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2876 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2877 for the first char of the signature (in this case I<b>).  If it does not exist,
2878 a new I<Bucket List> is created for our key (and the next 15 future keys that
2879 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2880 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2881 this point, unless we are replacing an existing I<Bucket>), where the actual
2882 data will be stored.
2883
2884 =head2 FETCHING
2885
2886 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2887 (or index number), then walking along the indexes.  If there are enough
2888 keys/elements in this DB level, there might be nested indexes, each linked to
2889 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2890 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2891 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2892 plain key are stored.
2893
2894
2895
2896 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2897 methods.  In this process the indexes are walked systematically, and each key
2898 fetched in increasing MD5 order (which is why it appears random).   Once the
2899 I<Bucket> is found, the value is skipped the plain key returned instead.
2900 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2901 alphabetically sorted.  This only happens on an index-level -- as soon as the
2902 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2903 so it's pretty much undefined how the keys will come out -- just like Perl's
2904 built-in hashes.
2905
2906 =head1 CODE COVERAGE
2907
2908 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2909 module's test suite.
2910
2911   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2912   File                           stmt   bran   cond    sub    pod   time  total
2913   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2914   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2915   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2916   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2917
2918 =head1 AUTHOR
2919
2920 Joseph Huckaby, L<jhuckaby@cpan.org>
2921
2922 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2923
2924 =head1 SEE ALSO
2925
2926 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2927 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2928
2929 =head1 LICENSE
2930
2931 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2932 This is free software, you may use it and distribute it under the
2933 same terms as Perl itself.
2934
2935 =cut