lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub _get_args {
 108     my $proto = shift;
 109
 110     my $args;
 111     if (scalar(@_) > 1) {
 112         if ( @_ % 2 ) {
 113             $proto->_throw_error( "Odd number of parameters to " . (caller(1))[2] );
 114         }
 115         $args = {@_};
 116     }
 117         elsif ( my $type = Scalar::Util::reftype($_[0]) ) {
 118         if ( $type ne 'HASH' ) {
 119             $proto->_throw_error( "Not a hashref in args to " . (caller(1))[2] );
 120         }
 121         $args = $_[0];
 122     }
 123         else {
 124         $args = { file => shift };
 125     }
 126
 127     return $args;
 128 }
 129
 130 sub new {
 131         ##
 132         # Class constructor method for Perl OO interface.
 133         # Calls tie() and returns blessed reference to tied hash or array,
 134         # providing a hybrid OO/tie interface.
 135         ##
 136         my $class = shift;
 137         my $args = $class->_get_args( @_ );
 138
 139         ##
 140         # Check if we want a tied hash or array.
 141         ##
 142         my $self;
 143         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 144         $class = 'DBM::Deep::Array';
 145         require DBM::Deep::Array;
 146                 tie @$self, $class, %$args;
 147         }
 148         else {
 149         $class = 'DBM::Deep::Hash';
 150         require DBM::Deep::Hash;
 151                 tie %$self, $class, %$args;
 152         }
 153
 154         return bless $self, $class;
 155 }
 156
 157 sub _init {
 158     ##
 159     # Setup $self and bless into this class.
 160     ##
 161     my $class = shift;
 162     my $args = shift;
 163
 164     # These are the defaults to be optionally overridden below
 165     my $self = bless {
 166         type => TYPE_HASH,
 167         base_offset => length(SIG_FILE),
 168     }, $class;
 169
 170     foreach my $param ( keys %$self ) {
 171         next unless exists $args->{$param};
 172         $self->{$param} = delete $args->{$param}
 173     }
 174
 175     $self->{root} = exists $args->{root}
 176         ? $args->{root}
 177         : DBM::Deep::_::Root->new( $args );
 178
 179     if (!defined($self->fh)) { $self->_open(); }
 180
 181     return $self;
 182 }
 183
 184 sub TIEHASH {
 185     shift;
 186     require DBM::Deep::Hash;
 187     return DBM::Deep::Hash->TIEHASH( @_ );
 188 }
 189
 190 sub TIEARRAY {
 191     shift;
 192     require DBM::Deep::Array;
 193     return DBM::Deep::Array->TIEARRAY( @_ );
 194 }
 195
 196 #XXX Unneeded now ...
 197 #sub DESTROY {
 198 #}
 199
 200 sub _open {
 201         ##
 202         # Open a FileHandle to the database, create if nonexistent.
 203         # Make sure file signature matches DeepDB spec.
 204         ##
 205     my $self = $_[0]->_get_self;
 206
 207         if (defined($self->fh)) { $self->_close(); }
 208
 209     eval {
 210         # Theoretically, adding O_BINARY should remove the need for the binmode
 211         # Of course, testing it is going to be ... interesting.
 212         my $flags = O_RDWR | O_CREAT | O_BINARY;
 213
 214         #XXX Can the mode be anything but r+, w+, or a+??
 215         #XXX ie, it has to be in read-write mode
 216         #XXX So, should we verify that the mode is legitimate?
 217
 218         #XXX Maybe the mode thingy should just go away. There's no good
 219         #XXX reason for it ...
 220         if ( $self->root->{mode} eq 'w+' ) {
 221             $flags |= O_TRUNC;
 222         }
 223
 224         my $fh;
 225         sysopen( $fh, $self->root->{file}, $flags )
 226             or $fh = undef;
 227         $self->root->{fh} = $fh;
 228     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 229         if (! defined($self->fh)) {
 230                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 231         }
 232
 233     my $fh = $self->fh;
 234
 235     #XXX Can we remove this by using the right sysopen() flags?
 236     # Maybe ... q.v. above
 237     binmode $fh; # for win32
 238
 239     if ($self->root->{autoflush}) {
 240         my $old = select $fh;
 241         $|=1;
 242         select $old;
 243     }
 244
 245     # Set the
 246     seek($fh, 0, SEEK_SET);
 247
 248     my $signature;
 249     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 250
 251     ##
 252     # File is empty -- write signature and master index
 253     ##
 254     if (!$bytes_read) {
 255         seek($fh, 0, SEEK_SET);
 256         print($fh SIG_FILE);
 257         $self->root->{end} = length(SIG_FILE);
 258         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 259
 260         my $plain_key = "[base]";
 261         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 262         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 263
 264         # Flush the filehandle
 265         my $old_fh = select $fh;
 266         my $old_af = $|;
 267         $| = 1;
 268         $| = $old_af;
 269         select $old_fh;
 270
 271         return 1;
 272     }
 273
 274     ##
 275     # Check signature was valid
 276     ##
 277     unless ($signature eq SIG_FILE) {
 278         $self->_close();
 279         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 280     }
 281
 282     $self->root->{end} = (stat($fh))[7];
 283
 284     ##
 285     # Get our type from master index signature
 286     ##
 287     my $tag = $self->_load_tag($self->base_offset);
 288
 289 #XXX We probably also want to store the hash algorithm name and not assume anything
 290 #XXX The cool thing would be to allow a different hashing algorithm at every level
 291
 292     if (!$tag) {
 293         return $self->_throw_error("Corrupted file, no master index record");
 294     }
 295     if ($self->{type} ne $tag->{signature}) {
 296         return $self->_throw_error("File type mismatch");
 297     }
 298
 299     return 1;
 300 }
 301
 302 sub _close {
 303         ##
 304         # Close database FileHandle
 305         ##
 306     my $self = $_[0]->_get_self;
 307     close $self->root->{fh};
 308     $self->root->{fh} = undef;
 309 }
 310
 311 sub _create_tag {
 312         ##
 313         # Given offset, signature and content, create tag and write to disk
 314         ##
 315         my ($self, $offset, $sig, $content) = @_;
 316         my $size = length($content);
 317
 318     my $fh = $self->fh;
 319
 320         seek($fh, $offset, SEEK_SET);
 321         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 322
 323         if ($offset == $self->root->{end}) {
 324                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 325         }
 326
 327         return {
 328                 signature => $sig,
 329                 size => $size,
 330                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 331                 content => $content
 332         };
 333 }
 334
 335 sub _load_tag {
 336         ##
 337         # Given offset, load single tag and return signature, size and data
 338         ##
 339         my $self = shift;
 340         my $offset = shift;
 341
 342     my $fh = $self->fh;
 343
 344         seek($fh, $offset, SEEK_SET);
 345         if (eof $fh) { return undef; }
 346
 347         my $sig;
 348         read( $fh, $sig, SIG_SIZE);
 349
 350         my $size;
 351         read( $fh, $size, $DATA_LENGTH_SIZE);
 352         $size = unpack($DATA_LENGTH_PACK, $size);
 353
 354         my $buffer;
 355         read( $fh, $buffer, $size);
 356
 357         return {
 358                 signature => $sig,
 359                 size => $size,
 360                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 361                 content => $buffer
 362         };
 363 }
 364
 365 sub _index_lookup {
 366         ##
 367         # Given index tag, lookup single entry in index and return .
 368         ##
 369         my $self = shift;
 370         my ($tag, $index) = @_;
 371
 372         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 373         if (!$location) { return; }
 374
 375         return $self->_load_tag( $location );
 376 }
 377
 378 sub _add_bucket {
 379         ##
 380         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 381         # plain (undigested) key and value.
 382         ##
 383         my $self = shift;
 384         my ($tag, $md5, $plain_key, $value) = @_;
 385         my $keys = $tag->{content};
 386         my $location = 0;
 387         my $result = 2;
 388
 389     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 390         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 391
 392     my $fh = $self->fh;
 393
 394         ##
 395         # Iterate through buckets, seeing if this is a new entry or a replace.
 396         ##
 397         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 398                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 399                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 400                 if (!$subloc) {
 401                         ##
 402                         # Found empty bucket (end of list).  Populate and exit loop.
 403                         ##
 404                         $result = 2;
 405
 406             $location = $internal_ref
 407                 ? $value->base_offset
 408                 : $self->root->{end};
 409
 410                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 411                         print($fh $md5 . pack($LONG_PACK, $location) );
 412                         last;
 413                 }
 414                 elsif ($md5 eq $key) {
 415                         ##
 416                         # Found existing bucket with same key.  Replace with new value.
 417                         ##
 418                         $result = 1;
 419
 420                         if ($internal_ref) {
 421                                 $location = $value->base_offset;
 422                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 423                                 print($fh $md5 . pack($LONG_PACK, $location) );
 424                         }
 425                         else {
 426                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 427                                 my $size;
 428                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 429
 430                                 ##
 431                                 # If value is a hash, array, or raw value with equal or less size, we can
 432                                 # reuse the same content area of the database.  Otherwise, we have to create
 433                                 # a new content area at the EOF.
 434                                 ##
 435                                 my $actual_length;
 436                 my $r = Scalar::Util::reftype( $value ) || '';
 437                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 438                                 else { $actual_length = length($value); }
 439
 440                                 if ($actual_length <= $size) {
 441                                         $location = $subloc;
 442                                 }
 443                                 else {
 444                                         $location = $self->root->{end};
 445                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 446                                         print($fh pack($LONG_PACK, $location) );
 447                                 }
 448                         }
 449                         last;
 450                 }
 451         } # i loop
 452
 453         ##
 454         # If this is an internal reference, return now.
 455         # No need to write value or plain key
 456         ##
 457         if ($internal_ref) {
 458         return $result;
 459     }
 460
 461         ##
 462         # If bucket didn't fit into list, split into a new index level
 463         ##
 464         if (!$location) {
 465                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 466                 print($fh pack($LONG_PACK, $self->root->{end}) );
 467
 468                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 469                 my @offsets = ();
 470
 471                 $keys .= $md5 . pack($LONG_PACK, 0);
 472
 473                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 474                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 475                         if ($key) {
 476                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 477                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 478
 479                                 if ($offsets[$num]) {
 480                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 481                                         seek($fh, $offset, SEEK_SET);
 482                                         my $subkeys;
 483                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 484
 485                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 486                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 487                                                 if (!$subloc) {
 488                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 489                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 490                                                         last;
 491                                                 }
 492                                         } # k loop
 493                                 }
 494                                 else {
 495                                         $offsets[$num] = $self->root->{end};
 496                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 497                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 498
 499                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 500
 501                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 502                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 503                                 }
 504                         } # key is real
 505                 } # i loop
 506
 507                 $location ||= $self->root->{end};
 508         } # re-index bucket list
 509
 510         ##
 511         # Seek to content area and store signature, value and plaintext key
 512         ##
 513         if ($location) {
 514                 my $content_length;
 515                 seek($fh, $location, SEEK_SET);
 516
 517                 ##
 518                 # Write signature based on content type, set content length and write actual value.
 519                 ##
 520         my $r = Scalar::Util::reftype($value) || '';
 521                 if ($r eq 'HASH') {
 522                         print($fh TYPE_HASH );
 523                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 524                         $content_length = $INDEX_SIZE;
 525                 }
 526                 elsif ($r eq 'ARRAY') {
 527                         print($fh TYPE_ARRAY );
 528                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 529                         $content_length = $INDEX_SIZE;
 530                 }
 531                 elsif (!defined($value)) {
 532                         print($fh SIG_NULL );
 533                         print($fh pack($DATA_LENGTH_PACK, 0) );
 534                         $content_length = 0;
 535                 }
 536                 else {
 537                         print($fh SIG_DATA );
 538                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 539                         $content_length = length($value);
 540                 }
 541
 542                 ##
 543                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 544                 ##
 545                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 546
 547                 ##
 548                 # If value is blessed, preserve class name
 549                 ##
 550                 if ( $self->root->{autobless} ) {
 551             my $value_class = Scalar::Util::blessed($value);
 552             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 553                 ##
 554                 # Blessed ref -- will restore later
 555                 ##
 556                 print($fh chr(1) );
 557                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 558                 $content_length += 1;
 559                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 560             }
 561             else {
 562                 print($fh chr(0) );
 563                 $content_length += 1;
 564             }
 565         }
 566
 567                 ##
 568                 # If this is a new content area, advance EOF counter
 569                 ##
 570                 if ($location == $self->root->{end}) {
 571                         $self->root->{end} += SIG_SIZE;
 572                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 573                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 574                 }
 575
 576                 ##
 577                 # If content is a hash or array, create new child DeepDB object and
 578                 # pass each key or element to it.
 579                 ##
 580                 if ($r eq 'HASH') {
 581                         my $branch = DBM::Deep->new(
 582                                 type => TYPE_HASH,
 583                                 base_offset => $location,
 584                                 root => $self->root,
 585                         );
 586                         foreach my $key (keys %{$value}) {
 587                 #$branch->{$key} = $value->{$key};
 588                 $branch->STORE( $key, $value->{$key} );
 589                         }
 590                 }
 591                 elsif ($r eq 'ARRAY') {
 592                         my $branch = DBM::Deep->new(
 593                                 type => TYPE_ARRAY,
 594                                 base_offset => $location,
 595                                 root => $self->root,
 596                         );
 597                         my $index = 0;
 598                         foreach my $element (@{$value}) {
 599                 #$branch->[$index] = $element;
 600                 $branch->STORE( $index, $element );
 601                                 $index++;
 602                         }
 603                 }
 604
 605                 return $result;
 606         }
 607
 608         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 609 }
 610
 611 sub _get_bucket_value {
 612         ##
 613         # Fetch single value given tag and MD5 digested key.
 614         ##
 615         my $self = shift;
 616         my ($tag, $md5) = @_;
 617         my $keys = $tag->{content};
 618
 619     my $fh = $self->fh;
 620
 621         ##
 622         # Iterate through buckets, looking for a key match
 623         ##
 624     BUCKET:
 625         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 626                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 627                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 628
 629                 if (!$subloc) {
 630                         ##
 631                         # Hit end of list, no match
 632                         ##
 633                         return;
 634                 }
 635
 636         if ( $md5 ne $key ) {
 637             next BUCKET;
 638         }
 639
 640         ##
 641         # Found match -- seek to offset and read signature
 642         ##
 643         my $signature;
 644         seek($fh, $subloc, SEEK_SET);
 645         read( $fh, $signature, SIG_SIZE);
 646
 647         ##
 648         # If value is a hash or array, return new DeepDB object with correct offset
 649         ##
 650         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 651             my $obj = DBM::Deep->new(
 652                 type => $signature,
 653                 base_offset => $subloc,
 654                 root => $self->root
 655             );
 656
 657             if ($self->root->{autobless}) {
 658                 ##
 659                 # Skip over value and plain key to see if object needs
 660                 # to be re-blessed
 661                 ##
 662                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 663
 664                 my $size;
 665                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 666                 if ($size) { seek($fh, $size, SEEK_CUR); }
 667
 668                 my $bless_bit;
 669                 read( $fh, $bless_bit, 1);
 670                 if (ord($bless_bit)) {
 671                     ##
 672                     # Yes, object needs to be re-blessed
 673                     ##
 674                     my $class_name;
 675                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 676                     if ($size) { read( $fh, $class_name, $size); }
 677                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 678                 }
 679             }
 680
 681             return $obj;
 682         }
 683
 684         ##
 685         # Otherwise return actual value
 686         ##
 687         elsif ($signature eq SIG_DATA) {
 688             my $size;
 689             my $value = '';
 690             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 691             if ($size) { read( $fh, $value, $size); }
 692             return $value;
 693         }
 694
 695         ##
 696         # Key exists, but content is null
 697         ##
 698         else { return; }
 699         } # i loop
 700
 701         return;
 702 }
 703
 704 sub _delete_bucket {
 705         ##
 706         # Delete single key/value pair given tag and MD5 digested key.
 707         ##
 708         my $self = shift;
 709         my ($tag, $md5) = @_;
 710         my $keys = $tag->{content};
 711
 712     my $fh = $self->fh;
 713
 714         ##
 715         # Iterate through buckets, looking for a key match
 716         ##
 717     BUCKET:
 718         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 719                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 720                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 721
 722                 if (!$subloc) {
 723                         ##
 724                         # Hit end of list, no match
 725                         ##
 726                         return;
 727                 }
 728
 729         if ( $md5 ne $key ) {
 730             next BUCKET;
 731         }
 732
 733         ##
 734         # Matched key -- delete bucket and return
 735         ##
 736         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 737         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 738         print($fh chr(0) x $BUCKET_SIZE );
 739
 740         return 1;
 741         } # i loop
 742
 743         return;
 744 }
 745
 746 sub _bucket_exists {
 747         ##
 748         # Check existence of single key given tag and MD5 digested key.
 749         ##
 750         my $self = shift;
 751         my ($tag, $md5) = @_;
 752         my $keys = $tag->{content};
 753
 754         ##
 755         # Iterate through buckets, looking for a key match
 756         ##
 757     BUCKET:
 758         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 759                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 760                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 761
 762                 if (!$subloc) {
 763                         ##
 764                         # Hit end of list, no match
 765                         ##
 766                         return;
 767                 }
 768
 769         if ( $md5 ne $key ) {
 770             next BUCKET;
 771         }
 772
 773         ##
 774         # Matched key -- return true
 775         ##
 776         return 1;
 777         } # i loop
 778
 779         return;
 780 }
 781
 782 sub _find_bucket_list {
 783         ##
 784         # Locate offset for bucket list, given digested key
 785         ##
 786         my $self = shift;
 787         my $md5 = shift;
 788
 789         ##
 790         # Locate offset for bucket list using digest index system
 791         ##
 792         my $ch = 0;
 793         my $tag = $self->_load_tag($self->base_offset);
 794         if (!$tag) { return; }
 795
 796         while ($tag->{signature} ne SIG_BLIST) {
 797                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 798                 if (!$tag) { return; }
 799                 $ch++;
 800         }
 801
 802         return $tag;
 803 }
 804
 805 sub _traverse_index {
 806         ##
 807         # Scan index and recursively step into deeper levels, looking for next key.
 808         ##
 809     my ($self, $offset, $ch, $force_return_next) = @_;
 810     $force_return_next = undef unless $force_return_next;
 811
 812         my $tag = $self->_load_tag( $offset );
 813
 814     my $fh = $self->fh;
 815
 816         if ($tag->{signature} ne SIG_BLIST) {
 817                 my $content = $tag->{content};
 818                 my $start;
 819                 if ($self->{return_next}) { $start = 0; }
 820                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 821
 822                 for (my $index = $start; $index < 256; $index++) {
 823                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 824                         if ($subloc) {
 825                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 826                                 if (defined($result)) { return $result; }
 827                         }
 828                 } # index loop
 829
 830                 $self->{return_next} = 1;
 831         } # tag is an index
 832
 833         elsif ($tag->{signature} eq SIG_BLIST) {
 834                 my $keys = $tag->{content};
 835                 if ($force_return_next) { $self->{return_next} = 1; }
 836
 837                 ##
 838                 # Iterate through buckets, looking for a key match
 839                 ##
 840                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 841                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 842                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 843
 844                         if (!$subloc) {
 845                                 ##
 846                                 # End of bucket list -- return to outer loop
 847                                 ##
 848                                 $self->{return_next} = 1;
 849                                 last;
 850                         }
 851                         elsif ($key eq $self->{prev_md5}) {
 852                                 ##
 853                                 # Located previous key -- return next one found
 854                                 ##
 855                                 $self->{return_next} = 1;
 856                                 next;
 857                         }
 858                         elsif ($self->{return_next}) {
 859                                 ##
 860                                 # Seek to bucket location and skip over signature
 861                                 ##
 862                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 863
 864                                 ##
 865                                 # Skip over value to get to plain key
 866                                 ##
 867                                 my $size;
 868                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 869                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 870
 871                                 ##
 872                                 # Read in plain key and return as scalar
 873                                 ##
 874                                 my $plain_key;
 875                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 876                                 if ($size) { read( $fh, $plain_key, $size); }
 877
 878                                 return $plain_key;
 879                         }
 880                 } # bucket loop
 881
 882                 $self->{return_next} = 1;
 883         } # tag is a bucket list
 884
 885         return;
 886 }
 887
 888 sub _get_next_key {
 889         ##
 890         # Locate next key, given digested previous one
 891         ##
 892     my $self = $_[0]->_get_self;
 893
 894         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 895         $self->{return_next} = 0;
 896
 897         ##
 898         # If the previous key was not specifed, start at the top and
 899         # return the first one found.
 900         ##
 901         if (!$self->{prev_md5}) {
 902                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 903                 $self->{return_next} = 1;
 904         }
 905
 906         return $self->_traverse_index( $self->base_offset, 0 );
 907 }
 908
 909 sub lock {
 910         ##
 911         # If db locking is set, flock() the db file.  If called multiple
 912         # times before unlock(), then the same number of unlocks() must
 913         # be called before the lock is released.
 914         ##
 915     my $self = $_[0]->_get_self;
 916         my $type = $_[1];
 917     $type = LOCK_EX unless defined $type;
 918
 919         if (!defined($self->fh)) { return; }
 920
 921         if ($self->root->{locking}) {
 922                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 923                 $self->root->{locked}++;
 924
 925         return 1;
 926         }
 927
 928     return;
 929 }
 930
 931 sub unlock {
 932         ##
 933         # If db locking is set, unlock the db file.  See note in lock()
 934         # regarding calling lock() multiple times.
 935         ##
 936     my $self = $_[0]->_get_self;
 937
 938         if (!defined($self->fh)) { return; }
 939
 940         if ($self->root->{locking} && $self->root->{locked} > 0) {
 941                 $self->root->{locked}--;
 942                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 943
 944         return 1;
 945         }
 946
 947     return;
 948 }
 949
 950 #XXX These uses of ref() need verified
 951 sub _copy_node {
 952         ##
 953         # Copy single level of keys or elements to new DB handle.
 954         # Recurse for nested structures
 955         ##
 956     my $self = $_[0]->_get_self;
 957         my $db_temp = $_[1];
 958
 959         if ($self->type eq TYPE_HASH) {
 960                 my $key = $self->first_key();
 961                 while ($key) {
 962                         my $value = $self->get($key);
 963 #XXX This doesn't work with autobless
 964                         if (!ref($value)) { $db_temp->{$key} = $value; }
 965                         else {
 966                                 my $type = $value->type;
 967                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 968                                 else { $db_temp->{$key} = []; }
 969                                 $value->_copy_node( $db_temp->{$key} );
 970                         }
 971                         $key = $self->next_key($key);
 972                 }
 973         }
 974         else {
 975                 my $length = $self->length();
 976                 for (my $index = 0; $index < $length; $index++) {
 977                         my $value = $self->get($index);
 978                         if (!ref($value)) { $db_temp->[$index] = $value; }
 979             #XXX NO tests for this code
 980                         else {
 981                                 my $type = $value->type;
 982                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 983                                 else { $db_temp->[$index] = []; }
 984                                 $value->_copy_node( $db_temp->[$index] );
 985                         }
 986                 }
 987         }
 988 }
 989
 990 sub export {
 991         ##
 992         # Recursively export into standard Perl hashes and arrays.
 993         ##
 994     my $self = $_[0]->_get_self;
 995
 996         my $temp;
 997         if ($self->type eq TYPE_HASH) { $temp = {}; }
 998         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 999
1000         $self->lock();
1001         $self->_copy_node( $temp );
1002         $self->unlock();
1003
1004         return $temp;
1005 }
1006
1007 sub import {
1008         ##
1009         # Recursively import Perl hash/array structure
1010         ##
1011     #XXX This use of ref() seems to be ok
1012         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
1013
1014     my $self = $_[0]->_get_self;
1015         my $struct = $_[1];
1016
1017     #XXX This use of ref() seems to be ok
1018         if (!ref($struct)) {
1019                 ##
1020                 # struct is not a reference, so just import based on our type
1021                 ##
1022                 shift @_;
1023
1024                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1025                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1026         }
1027
1028     my $r = Scalar::Util::reftype($struct) || '';
1029         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1030                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1031         }
1032         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1033                 $self->push( @$struct );
1034         }
1035         else {
1036                 return $self->_throw_error("Cannot import: type mismatch");
1037         }
1038
1039         return 1;
1040 }
1041
1042 sub optimize {
1043         ##
1044         # Rebuild entire database into new file, then move
1045         # it back on top of original.
1046         ##
1047     my $self = $_[0]->_get_self;
1048
1049 #XXX Need to create a new test for this
1050 #       if ($self->root->{links} > 1) {
1051 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1052 #       }
1053
1054         my $db_temp = DBM::Deep->new(
1055                 file => $self->root->{file} . '.tmp',
1056                 type => $self->type
1057         );
1058         if (!$db_temp) {
1059                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1060         }
1061
1062         $self->lock();
1063         $self->_copy_node( $db_temp );
1064         undef $db_temp;
1065
1066         ##
1067         # Attempt to copy user, group and permissions over to new file
1068         ##
1069         my @stats = stat($self->fh);
1070         my $perms = $stats[2] & 07777;
1071         my $uid = $stats[4];
1072         my $gid = $stats[5];
1073         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1074         chmod( $perms, $self->root->{file} . '.tmp' );
1075
1076     # q.v. perlport for more information on this variable
1077     if ( $^O eq 'MSWin32' ) {
1078                 ##
1079                 # Potential race condition when optmizing on Win32 with locking.
1080                 # The Windows filesystem requires that the filehandle be closed
1081                 # before it is overwritten with rename().  This could be redone
1082                 # with a soft copy.
1083                 ##
1084                 $self->unlock();
1085                 $self->_close();
1086         }
1087
1088         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1089                 unlink $self->root->{file} . '.tmp';
1090                 $self->unlock();
1091                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1092         }
1093
1094         $self->unlock();
1095         $self->_close();
1096         $self->_open();
1097
1098         return 1;
1099 }
1100
1101 sub clone {
1102         ##
1103         # Make copy of object and return
1104         ##
1105     my $self = $_[0]->_get_self;
1106
1107         return DBM::Deep->new(
1108                 type => $self->type,
1109                 base_offset => $self->base_offset,
1110                 root => $self->root
1111         );
1112 }
1113
1114 {
1115     my %is_legal_filter = map {
1116         $_ => ~~1,
1117     } qw(
1118         store_key store_value
1119         fetch_key fetch_value
1120     );
1121
1122     sub set_filter {
1123         ##
1124         # Setup filter function for storing or fetching the key or value
1125         ##
1126         my $self = $_[0]->_get_self;
1127         my $type = lc $_[1];
1128         my $func = $_[2] ? $_[2] : undef;
1129
1130         if ( $is_legal_filter{$type} ) {
1131             $self->root->{"filter_$type"} = $func;
1132             return 1;
1133         }
1134
1135         return;
1136     }
1137 }
1138
1139 ##
1140 # Accessor methods
1141 ##
1142
1143 sub root {
1144         ##
1145         # Get access to the root structure
1146         ##
1147     my $self = $_[0]->_get_self;
1148         return $self->{root};
1149 }
1150
1151 sub fh {
1152         ##
1153         # Get access to the raw FileHandle
1154         ##
1155     #XXX It will be useful, though, when we split out HASH and ARRAY
1156     my $self = $_[0]->_get_self;
1157         return $self->root->{fh};
1158 }
1159
1160 sub type {
1161         ##
1162         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1163         ##
1164     my $self = $_[0]->_get_self;
1165         return $self->{type};
1166 }
1167
1168 sub base_offset {
1169         ##
1170         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1171         ##
1172     my $self = $_[0]->_get_self;
1173         return $self->{base_offset};
1174 }
1175
1176 sub error {
1177         ##
1178         # Get last error string, or undef if no error
1179         ##
1180         return $_[0]
1181         #? ( _get_self($_[0])->{root}->{error} or undef )
1182         ? ( $_[0]->_get_self->{root}->{error} or undef )
1183         : $@;
1184 }
1185
1186 ##
1187 # Utility methods
1188 ##
1189
1190 sub _throw_error {
1191         ##
1192         # Store error string in self
1193         ##
1194     my $self = $_[0]->_get_self;
1195         my $error_text = $_[1];
1196
1197     if ( Scalar::Util::blessed $self ) {
1198         $self->root->{error} = $error_text;
1199
1200         unless ($self->root->{debug}) {
1201             die "DBM::Deep: $error_text\n";
1202         }
1203
1204         warn "DBM::Deep: $error_text\n";
1205         return;
1206     }
1207     else {
1208         die "DBM::Deep: $error_text\n";
1209     }
1210 }
1211
1212 sub clear_error {
1213         ##
1214         # Clear error state
1215         ##
1216     my $self = $_[0]->_get_self;
1217
1218         undef $self->root->{error};
1219 }
1220
1221 sub precalc_sizes {
1222         ##
1223         # Precalculate index, bucket and bucket list sizes
1224         ##
1225
1226     #XXX I don't like this ...
1227     set_pack() unless defined $LONG_SIZE;
1228
1229         $INDEX_SIZE = 256 * $LONG_SIZE;
1230         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1231         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1232 }
1233
1234 sub set_pack {
1235         ##
1236         # Set pack/unpack modes (see file header for more)
1237         ##
1238     my ($long_s, $long_p, $data_s, $data_p) = @_;
1239
1240     $LONG_SIZE = $long_s ? $long_s : 4;
1241     $LONG_PACK = $long_p ? $long_p : 'N';
1242
1243     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1244     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1245
1246         precalc_sizes();
1247 }
1248
1249 sub set_digest {
1250         ##
1251         # Set key digest function (default is MD5)
1252         ##
1253     my ($digest_func, $hash_size) = @_;
1254
1255     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1256     $HASH_SIZE = $hash_size ? $hash_size : 16;
1257
1258         precalc_sizes();
1259 }
1260
1261 ##
1262 # tie() methods (hashes and arrays)
1263 ##
1264
1265 sub STORE {
1266         ##
1267         # Store single hash key/value or array element in database.
1268         ##
1269     my $self = $_[0]->_get_self;
1270         my $key = $_[1];
1271
1272     #XXX What is ref() checking here?
1273     #YYY User may be storing a hash, in which case we do not want it run
1274     #YYY through the filtering system
1275         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1276         ? $self->root->{filter_store_value}->($_[2])
1277         : $_[2];
1278
1279         my $md5 = $DIGEST_FUNC->($key);
1280
1281         ##
1282         # Make sure file is open
1283         ##
1284         if (!defined($self->fh) && !$self->_open()) {
1285                 return;
1286         }
1287         ##
1288
1289     my $fh = $self->fh;
1290
1291         ##
1292         # Request exclusive lock for writing
1293         ##
1294         $self->lock( LOCK_EX );
1295
1296         ##
1297         # If locking is enabled, set 'end' parameter again, in case another
1298         # DB instance appended to our file while we were unlocked.
1299         ##
1300         if ($self->root->{locking} || $self->root->{volatile}) {
1301                 $self->root->{end} = (stat($fh))[7];
1302         }
1303
1304         ##
1305         # Locate offset for bucket list using digest index system
1306         ##
1307         my $tag = $self->_load_tag($self->base_offset);
1308         if (!$tag) {
1309                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1310         }
1311
1312         my $ch = 0;
1313         while ($tag->{signature} ne SIG_BLIST) {
1314                 my $num = ord(substr($md5, $ch, 1));
1315                 my $new_tag = $self->_index_lookup($tag, $num);
1316                 if (!$new_tag) {
1317                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1318                         seek($fh, $ref_loc, SEEK_SET);
1319                         print($fh pack($LONG_PACK, $self->root->{end}) );
1320
1321                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1322                         $tag->{ref_loc} = $ref_loc;
1323                         $tag->{ch} = $ch;
1324                         last;
1325                 }
1326                 else {
1327                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1328                         $tag = $new_tag;
1329                         $tag->{ref_loc} = $ref_loc;
1330                         $tag->{ch} = $ch;
1331                 }
1332                 $ch++;
1333         }
1334
1335         ##
1336         # Add key/value to bucket list
1337         ##
1338         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1339
1340         $self->unlock();
1341
1342         return $result;
1343 }
1344
1345 sub FETCH {
1346         ##
1347         # Fetch single value or element given plain key or array index
1348         ##
1349     my $self = shift->_get_self;
1350     my $key = shift;
1351
1352         ##
1353         # Make sure file is open
1354         ##
1355         if (!defined($self->fh)) { $self->_open(); }
1356
1357         my $md5 = $DIGEST_FUNC->($key);
1358
1359         ##
1360         # Request shared lock for reading
1361         ##
1362         $self->lock( LOCK_SH );
1363
1364         my $tag = $self->_find_bucket_list( $md5 );
1365         if (!$tag) {
1366                 $self->unlock();
1367                 return;
1368         }
1369
1370         ##
1371         # Get value from bucket list
1372         ##
1373         my $result = $self->_get_bucket_value( $tag, $md5 );
1374
1375         $self->unlock();
1376
1377     #XXX What is ref() checking here?
1378         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1379         ? $self->root->{filter_fetch_value}->($result)
1380         : $result;
1381 }
1382
1383 sub DELETE {
1384         ##
1385         # Delete single key/value pair or element given plain key or array index
1386         ##
1387     my $self = $_[0]->_get_self;
1388         my $key = $_[1];
1389
1390         my $unpacked_key = $key;
1391         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1392         my $md5 = $DIGEST_FUNC->($key);
1393
1394         ##
1395         # Make sure file is open
1396         ##
1397         if (!defined($self->fh)) { $self->_open(); }
1398
1399         ##
1400         # Request exclusive lock for writing
1401         ##
1402         $self->lock( LOCK_EX );
1403
1404         my $tag = $self->_find_bucket_list( $md5 );
1405         if (!$tag) {
1406                 $self->unlock();
1407                 return;
1408         }
1409
1410         ##
1411         # Delete bucket
1412         ##
1413     my $value = $self->_get_bucket_value( $tag, $md5 );
1414         if ($value && !ref($value) && $self->root->{filter_fetch_value}) {
1415         $value = $self->root->{filter_fetch_value}->($value);
1416     }
1417
1418         my $result = $self->_delete_bucket( $tag, $md5 );
1419
1420         ##
1421         # If this object is an array and the key deleted was on the end of the stack,
1422         # decrement the length variable.
1423         ##
1424         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1425                 $self->STORESIZE( $unpacked_key );
1426         }
1427
1428         $self->unlock();
1429
1430         return $value;
1431 }
1432
1433 sub EXISTS {
1434         ##
1435         # Check if a single key or element exists given plain key or array index
1436         ##
1437     my $self = $_[0]->_get_self;
1438         my $key = $_[1];
1439
1440         my $md5 = $DIGEST_FUNC->($key);
1441
1442         ##
1443         # Make sure file is open
1444         ##
1445         if (!defined($self->fh)) { $self->_open(); }
1446
1447         ##
1448         # Request shared lock for reading
1449         ##
1450         $self->lock( LOCK_SH );
1451
1452         my $tag = $self->_find_bucket_list( $md5 );
1453
1454         ##
1455         # For some reason, the built-in exists() function returns '' for false
1456         ##
1457         if (!$tag) {
1458                 $self->unlock();
1459                 return '';
1460         }
1461
1462         ##
1463         # Check if bucket exists and return 1 or ''
1464         ##
1465         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1466
1467         $self->unlock();
1468
1469         return $result;
1470 }
1471
1472 sub CLEAR {
1473         ##
1474         # Clear all keys from hash, or all elements from array.
1475         ##
1476     my $self = $_[0]->_get_self;
1477
1478         ##
1479         # Make sure file is open
1480         ##
1481         if (!defined($self->fh)) { $self->_open(); }
1482
1483         ##
1484         # Request exclusive lock for writing
1485         ##
1486         $self->lock( LOCK_EX );
1487
1488     my $fh = $self->fh;
1489
1490         seek($fh, $self->base_offset, SEEK_SET);
1491         if (eof $fh) {
1492                 $self->unlock();
1493                 return;
1494         }
1495
1496         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1497
1498         $self->unlock();
1499
1500         return 1;
1501 }
1502
1503 ##
1504 # Public method aliases
1505 ##
1506 sub put { (shift)->STORE( @_ ) }
1507 sub store { (shift)->STORE( @_ ) }
1508 sub get { (shift)->FETCH( @_ ) }
1509 sub fetch { (shift)->FETCH( @_ ) }
1510 sub delete { (shift)->DELETE( @_ ) }
1511 sub exists { (shift)->EXISTS( @_ ) }
1512 sub clear { (shift)->CLEAR( @_ ) }
1513
1514 package DBM::Deep::_::Root;
1515
1516 sub new {
1517     my $class = shift;
1518     my ($args) = @_;
1519
1520     my $self = bless {
1521         file => undef,
1522         fh => undef,
1523         end => 0,
1524         autoflush => undef,
1525         locking => undef,
1526         volatile => undef,
1527         debug => undef,
1528         mode => 'r+',
1529         filter_store_key => undef,
1530         filter_store_value => undef,
1531         filter_fetch_key => undef,
1532         filter_fetch_value => undef,
1533         autobless => undef,
1534         locked => 0,
1535         %$args,
1536     }, $class;
1537
1538     return $self;
1539 }
1540
1541 sub DESTROY {
1542     my $self = shift;
1543     return unless $self;
1544
1545     close $self->{fh} if $self->{fh};
1546
1547     return;
1548 }
1549
1550 1;
1551
1552 __END__
1553
1554 =head1 NAME
1555
1556 DBM::Deep - A pure perl multi-level hash/array DBM
1557
1558 =head1 SYNOPSIS
1559
1560   use DBM::Deep;
1561   my $db = DBM::Deep->new( "foo.db" );
1562
1563   $db->{key} = 'value'; # tie() style
1564   print $db->{key};
1565
1566   $db->put('key', 'value'); # OO style
1567   print $db->get('key');
1568
1569   # true multi-level support
1570   $db->{my_complex} = [
1571         'hello', { perl => 'rules' },
1572         42, 99 ];
1573
1574 =head1 DESCRIPTION
1575
1576 A unique flat-file database module, written in pure perl.  True
1577 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1578 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1579 handle millions of keys and unlimited hash levels without significant
1580 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1581 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1582 Mac OS X and Windows.
1583
1584 =head1 INSTALLATION
1585
1586 Hopefully you are using CPAN's excellent Perl module, which will download
1587 and install the module for you.  If not, get the tarball, and run these
1588 commands:
1589
1590         tar zxf DBM-Deep-*
1591         cd DBM-Deep-*
1592         perl Makefile.PL
1593         make
1594         make test
1595         make install
1596
1597 =head1 SETUP
1598
1599 Construction can be done OO-style (which is the recommended way), or using
1600 Perl's tie() function.  Both are examined here.
1601
1602 =head2 OO CONSTRUCTION
1603
1604 The recommended way to construct a DBM::Deep object is to use the new()
1605 method, which gets you a blessed, tied hash or array reference.
1606
1607         my $db = DBM::Deep->new( "foo.db" );
1608
1609 This opens a new database handle, mapped to the file "foo.db".  If this
1610 file does not exist, it will automatically be created.  DB files are
1611 opened in "r+" (read/write) mode, and the type of object returned is a
1612 hash, unless otherwise specified (see L<OPTIONS> below).
1613
1614
1615
1616 You can pass a number of options to the constructor to specify things like
1617 locking, autoflush, etc.  This is done by passing an inline hash:
1618
1619         my $db = DBM::Deep->new(
1620                 file => "foo.db",
1621                 locking => 1,
1622                 autoflush => 1
1623         );
1624
1625 Notice that the filename is now specified I<inside> the hash with
1626 the "file" parameter, as opposed to being the sole argument to the
1627 constructor.  This is required if any options are specified.
1628 See L<OPTIONS> below for the complete list.
1629
1630
1631
1632 You can also start with an array instead of a hash.  For this, you must
1633 specify the C<type> parameter:
1634
1635         my $db = DBM::Deep->new(
1636                 file => "foo.db",
1637                 type => DBM::Deep->TYPE_ARRAY
1638         );
1639
1640 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1641 a new DB file.  If you create a DBM::Deep object with an existing file, the
1642 C<type> will be loaded from the file header, and ignored if it is passed
1643 to the constructor.
1644
1645 =head2 TIE CONSTRUCTION
1646
1647 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1648 tie() function.  This is not ideal, because you get only a basic, tied hash
1649 (or array) which is not blessed, so you can't call any functions on it.
1650
1651         my %hash;
1652         tie %hash, "DBM::Deep", "foo.db";
1653
1654         my @array;
1655         tie @array, "DBM::Deep", "bar.db";
1656
1657 As with the OO constructor, you can replace the DB filename parameter with
1658 a hash containing one or more options (see L<OPTIONS> just below for the
1659 complete list).
1660
1661         tie %hash, "DBM::Deep", {
1662                 file => "foo.db",
1663                 locking => 1,
1664                 autoflush => 1
1665         };
1666
1667 =head2 OPTIONS
1668
1669 There are a number of options that can be passed in when constructing your
1670 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1671
1672 =over
1673
1674 =item * file
1675
1676 Filename of the DB file to link the handle to.  You can pass a full absolute
1677 filesystem path, partial path, or a plain filename if the file is in the
1678 current working directory.  This is a required parameter.
1679
1680 =item * mode
1681
1682 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1683 module.  This is an optional parameter, and defaults to "r+" (read/write).
1684 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1685 created if it doesn't exist.
1686
1687 =item * type
1688
1689 This parameter specifies what type of object to create, a hash or array.  Use
1690 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1691 This only takes effect when beginning a new file.  This is an optional
1692 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1693
1694 =item * locking
1695
1696 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1697 function to lock the database in exclusive mode for writes, and shared mode for
1698 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1699 any child hashes or arrays> that use the same DB file.  This is an optional
1700 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1701
1702 =item * autoflush
1703
1704 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1705 This obviously slows down write operations, but is required if you may have
1706 multiple processes accessing the same DB file (also consider enable I<locking>
1707 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1708 parameter, and defaults to 0 (disabled).
1709
1710 =item * volatile
1711
1712 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1713 STORE() operation.  This is required if an outside force may change the size of
1714 the file between transactions.  Locking also implicitly enables volatile.  This
1715 is useful if you want to use a different locking system or write your own.  Pass
1716 any true value to enable.  This is an optional parameter, and defaults to 0
1717 (disabled).
1718
1719 =item * autobless
1720
1721 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1722 restore them when fetched.  This is an B<experimental> feature, and does have
1723 side-effects.  Basically, when hashes are re-blessed into their original
1724 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1725 able to call any DBM::Deep methods on them.  You have been warned.
1726 This is an optional parameter, and defaults to 0 (disabled).
1727
1728 =item * filter_*
1729
1730 See L<FILTERS> below.
1731
1732 =item * debug
1733
1734 Setting I<debug> mode will make all errors non-fatal, dump them out to
1735 STDERR, and continue on.  This is for debugging purposes only, and probably
1736 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1737
1738 =item * fh
1739
1740 Instead of passing a file path, you can instead pass a handle to an pre-opened
1741 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1742 contains your entire Perl script, as well as the data following the __DATA__
1743 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1744 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1745 in that.
1746
1747 =back
1748
1749 =head1 TIE INTERFACE
1750
1751 With DBM::Deep you can access your databases using Perl's standard hash/array
1752 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1753 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1754 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1755 section above.  This simply tells you how to use DBM::Deep using regular hashes
1756 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1757 work too).  It is entirely up to you how to want to access your databases.
1758
1759 =head2 HASHES
1760
1761 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1762 or even nested hashes (or arrays) using standard Perl syntax:
1763
1764         my $db = DBM::Deep->new( "foo.db" );
1765
1766         $db->{mykey} = "myvalue";
1767         $db->{myhash} = {};
1768         $db->{myhash}->{subkey} = "subvalue";
1769
1770         print $db->{myhash}->{subkey} . "\n";
1771
1772 You can even step through hash keys using the normal Perl C<keys()> function:
1773
1774         foreach my $key (keys %$db) {
1775                 print "$key: " . $db->{$key} . "\n";
1776         }
1777
1778 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1779 pushes them onto an array, all before the loop even begins.  If you have an
1780 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1781 Perl's C<each()> function, which pulls keys/values one at a time, using very
1782 little memory:
1783
1784         while (my ($key, $value) = each %$db) {
1785                 print "$key: $value\n";
1786         }
1787
1788 Please note that when using C<each()>, you should always pass a direct
1789 hash reference, not a lookup.  Meaning, you should B<never> do this:
1790
1791         # NEVER DO THIS
1792         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1793
1794 This causes an infinite loop, because for each iteration, Perl is calling
1795 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1796 it effectively keeps returning the first key over and over again. Instead,
1797 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1798
1799 =head2 ARRAYS
1800
1801 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1802 reference.  This includes inserting, removing and manipulating elements,
1803 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1804 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1805 or simply be a nested array reference inside a hash.  Example:
1806
1807         my $db = DBM::Deep->new(
1808                 file => "foo-array.db",
1809                 type => DBM::Deep->TYPE_ARRAY
1810         );
1811
1812         $db->[0] = "foo";
1813         push @$db, "bar", "baz";
1814         unshift @$db, "bah";
1815
1816         my $last_elem = pop @$db; # baz
1817         my $first_elem = shift @$db; # bah
1818         my $second_elem = $db->[1]; # bar
1819
1820         my $num_elements = scalar @$db;
1821
1822 =head1 OO INTERFACE
1823
1824 In addition to the I<tie()> interface, you can also use a standard OO interface
1825 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1826 array) has its own methods, but both types share the following common methods:
1827 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1828
1829 =over
1830
1831 =item * put()
1832
1833 Stores a new hash key/value pair, or sets an array element value.  Takes two
1834 arguments, the hash key or array index, and the new value.  The value can be
1835 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1836
1837         $db->put("foo", "bar"); # for hashes
1838         $db->put(1, "bar"); # for arrays
1839
1840 =item * get()
1841
1842 Fetches the value of a hash key or array element.  Takes one argument: the hash
1843 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1844 data type stored.
1845
1846         my $value = $db->get("foo"); # for hashes
1847         my $value = $db->get(1); # for arrays
1848
1849 =item * exists()
1850
1851 Checks if a hash key or array index exists.  Takes one argument: the hash key
1852 or array index.  Returns true if it exists, false if not.
1853
1854         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1855         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1856
1857 =item * delete()
1858
1859 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1860 key or array index.  Returns true on success, false if not found.  For arrays,
1861 the remaining elements located after the deleted element are NOT moved over.
1862 The deleted element is essentially just undefined, which is exactly how Perl's
1863 internal arrays work.  Please note that the space occupied by the deleted
1864 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1865 below for details and workarounds.
1866
1867         $db->delete("foo"); # for hashes
1868         $db->delete(1); # for arrays
1869
1870 =item * clear()
1871
1872 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1873 value.  Please note that the space occupied by the deleted keys/values or
1874 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1875 details and workarounds.
1876
1877         $db->clear(); # hashes or arrays
1878
1879 =back
1880
1881 =head2 HASHES
1882
1883 For hashes, DBM::Deep supports all the common methods described above, and the
1884 following additional methods: C<first_key()> and C<next_key()>.
1885
1886 =over
1887
1888 =item * first_key()
1889
1890 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1891 fetched in an undefined order (which appears random).  Takes no arguments,
1892 returns the key as a scalar value.
1893
1894         my $key = $db->first_key();
1895
1896 =item * next_key()
1897
1898 Returns the "next" key in the hash, given the previous one as the sole argument.
1899 Returns undef if there are no more keys to be fetched.
1900
1901         $key = $db->next_key($key);
1902
1903 =back
1904
1905 Here are some examples of using hashes:
1906
1907         my $db = DBM::Deep->new( "foo.db" );
1908
1909         $db->put("foo", "bar");
1910         print "foo: " . $db->get("foo") . "\n";
1911
1912         $db->put("baz", {}); # new child hash ref
1913         $db->get("baz")->put("buz", "biz");
1914         print "buz: " . $db->get("baz")->get("buz") . "\n";
1915
1916         my $key = $db->first_key();
1917         while ($key) {
1918                 print "$key: " . $db->get($key) . "\n";
1919                 $key = $db->next_key($key);
1920         }
1921
1922         if ($db->exists("foo")) { $db->delete("foo"); }
1923
1924 =head2 ARRAYS
1925
1926 For arrays, DBM::Deep supports all the common methods described above, and the
1927 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1928 C<unshift()> and C<splice()>.
1929
1930 =over
1931
1932 =item * length()
1933
1934 Returns the number of elements in the array.  Takes no arguments.
1935
1936         my $len = $db->length();
1937
1938 =item * push()
1939
1940 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1941 refs or array refs.  No return value.
1942
1943         $db->push("foo", "bar", {});
1944
1945 =item * pop()
1946
1947 Fetches the last element in the array, and deletes it.  Takes no arguments.
1948 Returns undef if array is empty.  Returns the element value.
1949
1950         my $elem = $db->pop();
1951
1952 =item * shift()
1953
1954 Fetches the first element in the array, deletes it, then shifts all the
1955 remaining elements over to take up the space.  Returns the element value.  This
1956 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1957 details.
1958
1959         my $elem = $db->shift();
1960
1961 =item * unshift()
1962
1963 Inserts one or more elements onto the beginning of the array, shifting all
1964 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1965 No return value.  This method is not recommended with large arrays -- see
1966 <LARGE ARRAYS> below for details.
1967
1968         $db->unshift("foo", "bar", {});
1969
1970 =item * splice()
1971
1972 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1973 -f splice> for usage -- it is too complicated to document here.  This method is
1974 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1975
1976 =back
1977
1978 Here are some examples of using arrays:
1979
1980         my $db = DBM::Deep->new(
1981                 file => "foo.db",
1982                 type => DBM::Deep->TYPE_ARRAY
1983         );
1984
1985         $db->push("bar", "baz");
1986         $db->unshift("foo");
1987         $db->put(3, "buz");
1988
1989         my $len = $db->length();
1990         print "length: $len\n"; # 4
1991
1992         for (my $k=0; $k<$len; $k++) {
1993                 print "$k: " . $db->get($k) . "\n";
1994         }
1995
1996         $db->splice(1, 2, "biz", "baf");
1997
1998         while (my $elem = shift @$db) {
1999                 print "shifted: $elem\n";
2000         }
2001
2002 =head1 LOCKING
2003
2004 Enable automatic file locking by passing a true value to the C<locking>
2005 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2006
2007         my $db = DBM::Deep->new(
2008                 file => "foo.db",
2009                 locking => 1
2010         );
2011
2012 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2013 mode for writes, and shared mode for reads.  This is required if you have
2014 multiple processes accessing the same database file, to avoid file corruption.
2015 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2016 NFS> below for more.
2017
2018 =head2 EXPLICIT LOCKING
2019
2020 You can explicitly lock a database, so it remains locked for multiple
2021 transactions.  This is done by calling the C<lock()> method, and passing an
2022 optional lock mode argument (defaults to exclusive mode).  This is particularly
2023 useful for things like counters, where the current value needs to be fetched,
2024 then incremented, then stored again.
2025
2026         $db->lock();
2027         my $counter = $db->get("counter");
2028         $counter++;
2029         $db->put("counter", $counter);
2030         $db->unlock();
2031
2032         # or...
2033
2034         $db->lock();
2035         $db->{counter}++;
2036         $db->unlock();
2037
2038 You can pass C<lock()> an optional argument, which specifies which mode to use
2039 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2040 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2041 same as the constants defined in Perl's C<Fcntl> module.
2042
2043         $db->lock( DBM::Deep->LOCK_SH );
2044         # something here
2045         $db->unlock();
2046
2047 If you want to implement your own file locking scheme, be sure to create your
2048 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2049 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2050 below for more.
2051
2052 =head1 IMPORTING/EXPORTING
2053
2054 You can import existing complex structures by calling the C<import()> method,
2055 and export an entire database into an in-memory structure using the C<export()>
2056 method.  Both are examined here.
2057
2058 =head2 IMPORTING
2059
2060 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2061 walking the structure and adding keys/elements to the database as you go,
2062 simply pass a reference to the C<import()> method.  This recursively adds
2063 everything to an existing DBM::Deep object for you.  Here is an example:
2064
2065         my $struct = {
2066                 key1 => "value1",
2067                 key2 => "value2",
2068                 array1 => [ "elem0", "elem1", "elem2" ],
2069                 hash1 => {
2070                         subkey1 => "subvalue1",
2071                         subkey2 => "subvalue2"
2072                 }
2073         };
2074
2075         my $db = DBM::Deep->new( "foo.db" );
2076         $db->import( $struct );
2077
2078         print $db->{key1} . "\n"; # prints "value1"
2079
2080 This recursively imports the entire C<$struct> object into C<$db>, including
2081 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2082 keys are merged with the existing ones, replacing if they already exist.
2083 The C<import()> method can be called on any database level (not just the base
2084 level), and works with both hash and array DB types.
2085
2086
2087
2088 B<Note:> Make sure your existing structure has no circular references in it.
2089 These will cause an infinite loop when importing.
2090
2091 =head2 EXPORTING
2092
2093 Calling the C<export()> method on an existing DBM::Deep object will return
2094 a reference to a new in-memory copy of the database.  The export is done
2095 recursively, so all nested hashes/arrays are all exported to standard Perl
2096 objects.  Here is an example:
2097
2098         my $db = DBM::Deep->new( "foo.db" );
2099
2100         $db->{key1} = "value1";
2101         $db->{key2} = "value2";
2102         $db->{hash1} = {};
2103         $db->{hash1}->{subkey1} = "subvalue1";
2104         $db->{hash1}->{subkey2} = "subvalue2";
2105
2106         my $struct = $db->export();
2107
2108         print $struct->{key1} . "\n"; # prints "value1"
2109
2110 This makes a complete copy of the database in memory, and returns a reference
2111 to it.  The C<export()> method can be called on any database level (not just
2112 the base level), and works with both hash and array DB types.  Be careful of
2113 large databases -- you can store a lot more data in a DBM::Deep object than an
2114 in-memory Perl structure.
2115
2116
2117
2118 B<Note:> Make sure your database has no circular references in it.
2119 These will cause an infinite loop when exporting.
2120
2121 =head1 FILTERS
2122
2123 DBM::Deep has a number of hooks where you can specify your own Perl function
2124 to perform filtering on incoming or outgoing data.  This is a perfect
2125 way to extend the engine, and implement things like real-time compression or
2126 encryption.  Filtering applies to the base DB level, and all child hashes /
2127 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2128 constructed, or by calling the C<set_filter()> method at any time.  There are
2129 four available filter hooks, described below:
2130
2131 =over
2132
2133 =item * filter_store_key
2134
2135 This filter is called whenever a hash key is stored.  It
2136 is passed the incoming key, and expected to return a transformed key.
2137
2138 =item * filter_store_value
2139
2140 This filter is called whenever a hash key or array element is stored.  It
2141 is passed the incoming value, and expected to return a transformed value.
2142
2143 =item * filter_fetch_key
2144
2145 This filter is called whenever a hash key is fetched (i.e. via
2146 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2147 and expected to return the plain key.
2148
2149 =item * filter_fetch_value
2150
2151 This filter is called whenever a hash key or array element is fetched.
2152 It is passed the transformed value, and expected to return the plain value.
2153
2154 =back
2155
2156 Here are the two ways to setup a filter hook:
2157
2158         my $db = DBM::Deep->new(
2159                 file => "foo.db",
2160                 filter_store_value => \&my_filter_store,
2161                 filter_fetch_value => \&my_filter_fetch
2162         );
2163
2164         # or...
2165
2166         $db->set_filter( "filter_store_value", \&my_filter_store );
2167         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2168
2169 Your filter function will be called only when dealing with SCALAR keys or
2170 values.  When nested hashes and arrays are being stored/fetched, filtering
2171 is bypassed.  Filters are called as static functions, passed a single SCALAR
2172 argument, and expected to return a single SCALAR value.  If you want to
2173 remove a filter, set the function reference to C<undef>:
2174
2175         $db->set_filter( "filter_store_value", undef );
2176
2177 =head2 REAL-TIME ENCRYPTION EXAMPLE
2178
2179 Here is a working example that uses the I<Crypt::Blowfish> module to
2180 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2181 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2182 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2183
2184         use DBM::Deep;
2185         use Crypt::Blowfish;
2186         use Crypt::CBC;
2187
2188         my $cipher = Crypt::CBC->new({
2189                 'key'             => 'my secret key',
2190                 'cipher'          => 'Blowfish',
2191                 'iv'              => '$KJh#(}q',
2192                 'regenerate_key'  => 0,
2193                 'padding'         => 'space',
2194                 'prepend_iv'      => 0
2195         });
2196
2197         my $db = DBM::Deep->new(
2198                 file => "foo-encrypt.db",
2199                 filter_store_key => \&my_encrypt,
2200                 filter_store_value => \&my_encrypt,
2201                 filter_fetch_key => \&my_decrypt,
2202                 filter_fetch_value => \&my_decrypt,
2203         );
2204
2205         $db->{key1} = "value1";
2206         $db->{key2} = "value2";
2207         print "key1: " . $db->{key1} . "\n";
2208         print "key2: " . $db->{key2} . "\n";
2209
2210         undef $db;
2211         exit;
2212
2213         sub my_encrypt {
2214                 return $cipher->encrypt( $_[0] );
2215         }
2216         sub my_decrypt {
2217                 return $cipher->decrypt( $_[0] );
2218         }
2219
2220 =head2 REAL-TIME COMPRESSION EXAMPLE
2221
2222 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2223 compression / decompression of keys & values with DBM::Deep Filters.
2224 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2225 more on I<Compress::Zlib>.
2226
2227         use DBM::Deep;
2228         use Compress::Zlib;
2229
2230         my $db = DBM::Deep->new(
2231                 file => "foo-compress.db",
2232                 filter_store_key => \&my_compress,
2233                 filter_store_value => \&my_compress,
2234                 filter_fetch_key => \&my_decompress,
2235                 filter_fetch_value => \&my_decompress,
2236         );
2237
2238         $db->{key1} = "value1";
2239         $db->{key2} = "value2";
2240         print "key1: " . $db->{key1} . "\n";
2241         print "key2: " . $db->{key2} . "\n";
2242
2243         undef $db;
2244         exit;
2245
2246         sub my_compress {
2247                 return Compress::Zlib::memGzip( $_[0] ) ;
2248         }
2249         sub my_decompress {
2250                 return Compress::Zlib::memGunzip( $_[0] ) ;
2251         }
2252
2253 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2254 actually numerical index numbers, and are not filtered.
2255
2256 =head1 ERROR HANDLING
2257
2258 Most DBM::Deep methods return a true value for success, and call die() on
2259 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2260 actual error message is stored in an internal scalar, which can be fetched by
2261 calling the C<error()> method.
2262
2263         my $db = DBM::Deep->new( "foo.db" ); # create hash
2264         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2265
2266         print $db->error(); # prints error message
2267
2268 You can then call C<clear_error()> to clear the current error state.
2269
2270         $db->clear_error();
2271
2272 If you set the C<debug> option to true when creating your DBM::Deep object,
2273 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2274 for debugging purposes.
2275
2276 =head1 LARGEFILE SUPPORT
2277
2278 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2279 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2280 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2281 by calling the static C<set_pack()> method before you do anything else.
2282
2283         DBM::Deep::set_pack(8, 'Q');
2284
2285 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2286 instead of 32-bit longs.  After setting these values your DB files have a
2287 theoretical maximum size of 16 XB (exabytes).
2288
2289
2290
2291 B<Note:> Changing these values will B<NOT> work for existing database files.
2292 Only change this for new files, and make sure it stays set consistently
2293 throughout the file's life.  If you do set these values, you can no longer
2294 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2295 back to 32-bit mode.
2296
2297
2298
2299 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2300 only a 32-bit Perl.  However, I have received user reports that this does
2301 indeed work!
2302
2303 =head1 LOW-LEVEL ACCESS
2304
2305 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2306 you can call the C<fh()> method, which returns the handle:
2307
2308         my $fh = $db->fh();
2309
2310 This method can be called on the root level of the datbase, or any child
2311 hashes or arrays.  All levels share a I<root> structure, which contains things
2312 like the FileHandle, a reference counter, and all your options you specified
2313 when you created the object.  You can get access to this root structure by
2314 calling the C<root()> method.
2315
2316         my $root = $db->root();
2317
2318 This is useful for changing options after the object has already been created,
2319 such as enabling/disabling locking, volatile or debug modes.  You can also
2320 store your own temporary user data in this structure (be wary of name
2321 collision), which is then accessible from any child hash or array.
2322
2323 =head1 CUSTOM DIGEST ALGORITHM
2324
2325 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2326 keys.  However you can override this, and use another algorithm (such as SHA-256)
2327 or even write your own.  But please note that DBM::Deep currently expects zero
2328 collisions, so your algorithm has to be I<perfect>, so to speak.
2329 Collision detection may be introduced in a later version.
2330
2331
2332
2333 You can specify a custom digest algorithm by calling the static C<set_digest()>
2334 function, passing a reference to a subroutine, and the length of the algorithm's
2335 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2336 objects.  Here is a working example that uses a 256-bit hash from the
2337 I<Digest::SHA256> module.  Please see
2338 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2339
2340         use DBM::Deep;
2341         use Digest::SHA256;
2342
2343         my $context = Digest::SHA256::new(256);
2344
2345         DBM::Deep::set_digest( \&my_digest, 32 );
2346
2347         my $db = DBM::Deep->new( "foo-sha.db" );
2348
2349         $db->{key1} = "value1";
2350         $db->{key2} = "value2";
2351         print "key1: " . $db->{key1} . "\n";
2352         print "key2: " . $db->{key2} . "\n";
2353
2354         undef $db;
2355         exit;
2356
2357         sub my_digest {
2358                 return substr( $context->hash($_[0]), 0, 32 );
2359         }
2360
2361 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2362 of bytes you specify in the C<set_digest()> function (in this case 32).
2363
2364 =head1 CIRCULAR REFERENCES
2365
2366 DBM::Deep has B<experimental> support for circular references.  Meaning you
2367 can have a nested hash key or array element that points to a parent object.
2368 This relationship is stored in the DB file, and is preserved between sessions.
2369 Here is an example:
2370
2371         my $db = DBM::Deep->new( "foo.db" );
2372
2373         $db->{foo} = "bar";
2374         $db->{circle} = $db; # ref to self
2375
2376         print $db->{foo} . "\n"; # prints "foo"
2377         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2378
2379 One catch is, passing the object to a function that recursively walks the
2380 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2381 C<export()> methods) will result in an infinite loop.  The other catch is,
2382 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2383 or C<next_key()> methods), you will get the I<target object's key>, not the
2384 ref's key.  This gets even more interesting with the above example, where
2385 the I<circle> key points to the base DB object, which technically doesn't
2386 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2387 special case.
2388
2389 =head1 CAVEATS / ISSUES / BUGS
2390
2391 This section describes all the known issues with DBM::Deep.  It you have found
2392 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2393
2394 =head2 UNUSED SPACE RECOVERY
2395
2396 One major caveat with DBM::Deep is that space occupied by existing keys and
2397 values is not recovered when they are deleted.  Meaning if you keep deleting
2398 and adding new keys, your file will continuously grow.  I am working on this,
2399 but in the meantime you can call the built-in C<optimize()> method from time to
2400 time (perhaps in a crontab or something) to recover all your unused space.
2401
2402         $db->optimize(); # returns true on success
2403
2404 This rebuilds the ENTIRE database into a new file, then moves it on top of
2405 the original.  The new file will have no unused space, thus it will take up as
2406 little disk space as possible.  Please note that this operation can take
2407 a long time for large files, and you need enough disk space to temporarily hold
2408 2 copies of your DB file.  The temporary file is created in the same directory
2409 as the original, named with a ".tmp" extension, and is deleted when the
2410 operation completes.  Oh, and if locking is enabled, the DB is automatically
2411 locked for the entire duration of the copy.
2412
2413
2414
2415 B<WARNING:> Only call optimize() on the top-level node of the database, and
2416 make sure there are no child references lying around.  DBM::Deep keeps a reference
2417 counter, and if it is greater than 1, optimize() will abort and return undef.
2418
2419 =head2 AUTOVIVIFICATION
2420
2421 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2422 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2423 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2424 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2425 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2426 this does not work:
2427
2428         $db->{foo}->{bar} = "hello";
2429
2430 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2431 being an empty hash.  Try this instead, which works fine:
2432
2433         $db->{foo} = { bar => "hello" };
2434
2435 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2436 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2437 Probably a bug in Perl.
2438
2439 =head2 FILE CORRUPTION
2440
2441 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2442 for a 32-bit signature when opened, but other corruption in files can cause
2443 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2444 stuck in an infinite loop depending on the level of corruption.  File write
2445 operations are not checked for failure (for speed), so if you happen to run
2446 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2447 be addressed in a later version of DBM::Deep.
2448
2449 =head2 DB OVER NFS
2450
2451 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2452 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2453 about setting up your NFS server with a locking daemon, then using lockf() to
2454 lock your files, but your milage may vary there as well.  From what I
2455 understand, there is no real way to do it.  However, if you need access to the
2456 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2457 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2458
2459 =head2 COPYING OBJECTS
2460
2461 Beware of copying tied objects in Perl.  Very strange things can happen.
2462 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2463 returns a new, blessed, tied hash or array to the same level in the DB.
2464
2465         my $copy = $db->clone();
2466
2467 =head2 LARGE ARRAYS
2468
2469 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2470 These functions cause every element in the array to move, which can be murder
2471 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2472 a different location.  This may be addressed in a later version.
2473
2474 =head1 PERFORMANCE
2475
2476 This section discusses DBM::Deep's speed and memory usage.
2477
2478 =head2 SPEED
2479
2480 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2481 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2482 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2483 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2484 with huge databases.  Here is some test data:
2485
2486         Adding 1,000,000 keys to new DB file...
2487
2488         At 100 keys, avg. speed is 2,703 keys/sec
2489         At 200 keys, avg. speed is 2,642 keys/sec
2490         At 300 keys, avg. speed is 2,598 keys/sec
2491         At 400 keys, avg. speed is 2,578 keys/sec
2492         At 500 keys, avg. speed is 2,722 keys/sec
2493         At 600 keys, avg. speed is 2,628 keys/sec
2494         At 700 keys, avg. speed is 2,700 keys/sec
2495         At 800 keys, avg. speed is 2,607 keys/sec
2496         At 900 keys, avg. speed is 2,190 keys/sec
2497         At 1,000 keys, avg. speed is 2,570 keys/sec
2498         At 2,000 keys, avg. speed is 2,417 keys/sec
2499         At 3,000 keys, avg. speed is 1,982 keys/sec
2500         At 4,000 keys, avg. speed is 1,568 keys/sec
2501         At 5,000 keys, avg. speed is 1,533 keys/sec
2502         At 6,000 keys, avg. speed is 1,787 keys/sec
2503         At 7,000 keys, avg. speed is 1,977 keys/sec
2504         At 8,000 keys, avg. speed is 2,028 keys/sec
2505         At 9,000 keys, avg. speed is 2,077 keys/sec
2506         At 10,000 keys, avg. speed is 2,031 keys/sec
2507         At 20,000 keys, avg. speed is 1,970 keys/sec
2508         At 30,000 keys, avg. speed is 2,050 keys/sec
2509         At 40,000 keys, avg. speed is 2,073 keys/sec
2510         At 50,000 keys, avg. speed is 1,973 keys/sec
2511         At 60,000 keys, avg. speed is 1,914 keys/sec
2512         At 70,000 keys, avg. speed is 2,091 keys/sec
2513         At 80,000 keys, avg. speed is 2,103 keys/sec
2514         At 90,000 keys, avg. speed is 1,886 keys/sec
2515         At 100,000 keys, avg. speed is 1,970 keys/sec
2516         At 200,000 keys, avg. speed is 2,053 keys/sec
2517         At 300,000 keys, avg. speed is 1,697 keys/sec
2518         At 400,000 keys, avg. speed is 1,838 keys/sec
2519         At 500,000 keys, avg. speed is 1,941 keys/sec
2520         At 600,000 keys, avg. speed is 1,930 keys/sec
2521         At 700,000 keys, avg. speed is 1,735 keys/sec
2522         At 800,000 keys, avg. speed is 1,795 keys/sec
2523         At 900,000 keys, avg. speed is 1,221 keys/sec
2524         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2525
2526 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2527 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2528 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2529 Run time was 12 min 3 sec.
2530
2531 =head2 MEMORY USAGE
2532
2533 One of the great things about DBM::Deep is that it uses very little memory.
2534 Even with huge databases (1,000,000+ keys) you will not see much increased
2535 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2536 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2537 database handle:
2538
2539           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2540         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2541
2542 Basically the process is taking 2,716K of memory.  And here is the same
2543 process after storing and fetching 1,000,000 keys:
2544
2545           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2546         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2547
2548 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2549 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2550
2551 =head1 DB FILE FORMAT
2552
2553 In case you were interested in the underlying DB file format, it is documented
2554 here in this section.  You don't need to know this to use the module, it's just
2555 included for reference.
2556
2557 =head2 SIGNATURE
2558
2559 DBM::Deep files always start with a 32-bit signature to identify the file type.
2560 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2561 checked when the file is opened.
2562
2563 =head2 TAG
2564
2565 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2566 has a standard header containing the type of data, the length of data, and then
2567 the data itself.  The type is a single character (1 byte), the length is a
2568 32-bit unsigned long in network byte order, and the data is, well, the data.
2569 Here is how it unfolds:
2570
2571 =head2 MASTER INDEX
2572
2573 Immediately after the 32-bit file signature is the I<Master Index> record.
2574 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2575 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2576 depending on how the DBM::Deep object was constructed.
2577
2578
2579
2580 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2581 number).  The first 8-bit char of the MD5 signature is the offset into the
2582 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2583 index element is a file offset of the next tag for the key/element in question,
2584 which is usually a I<Bucket List> tag (see below).
2585
2586
2587
2588 The next tag I<could> be another index, depending on how many keys/elements
2589 exist.  See L<RE-INDEXING> below for details.
2590
2591 =head2 BUCKET LIST
2592
2593 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2594 file offsets to where the actual data is stored.  It starts with a standard
2595 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2596 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2597 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2598 When the list fills up, a I<Re-Index> operation is performed (See
2599 L<RE-INDEXING> below).
2600
2601 =head2 BUCKET
2602
2603 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2604 index/value pair (in array mode).  It starts with a standard tag header with
2605 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2606 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2607 header.  The size reported in the tag header is only for the value, but then,
2608 just after the value is another size (32-bit unsigned long) and then the plain
2609 key itself.  Since the value is likely to be fetched more often than the plain
2610 key, I figured it would be I<slightly> faster to store the value first.
2611
2612
2613
2614 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2615 record for the nested structure, where the process begins all over again.
2616
2617 =head2 RE-INDEXING
2618
2619 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2620 exhausted.  Then, when another key/element comes in, the list is converted to a
2621 new index record.  However, this index will look at the next char in the MD5
2622 hash, and arrange new Bucket List pointers accordingly.  This process is called
2623 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2624 17 (16 + new one) keys/elements are removed from the old Bucket List and
2625 inserted into the new index.  Several new Bucket Lists are created in the
2626 process, as a new MD5 char from the key is being examined (it is unlikely that
2627 the keys will all share the same next char of their MD5s).
2628
2629
2630
2631 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2632 when the Bucket Lists will turn into indexes, but the first round tends to
2633 happen right around 4,000 keys.  You will see a I<slight> decrease in
2634 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2635 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2636 right around 900,000 keys.  This process can continue nearly indefinitely --
2637 right up until the point the I<MD5> signatures start colliding with each other,
2638 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2639 getting struck by lightning while you are walking to cash in your tickets.
2640 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2641 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2642 this is 340 unodecillion, but don't quote me).
2643
2644 =head2 STORING
2645
2646 When a new key/element is stored, the key (or index number) is first ran through
2647 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2648 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2649 for the first char of the signature (in this case I<b>).  If it does not exist,
2650 a new I<Bucket List> is created for our key (and the next 15 future keys that
2651 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2652 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2653 this point, unless we are replacing an existing I<Bucket>), where the actual
2654 data will be stored.
2655
2656 =head2 FETCHING
2657
2658 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2659 (or index number), then walking along the indexes.  If there are enough
2660 keys/elements in this DB level, there might be nested indexes, each linked to
2661 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2662 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2663 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2664 plain key are stored.
2665
2666
2667
2668 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2669 methods.  In this process the indexes are walked systematically, and each key
2670 fetched in increasing MD5 order (which is why it appears random).   Once the
2671 I<Bucket> is found, the value is skipped the plain key returned instead.
2672 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2673 alphabetically sorted.  This only happens on an index-level -- as soon as the
2674 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2675 so it's pretty much undefined how the keys will come out -- just like Perl's
2676 built-in hashes.
2677
2678 =head1 CODE COVERAGE
2679
2680 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2681 module's test suite.
2682
2683   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2684   File                           stmt   bran   cond    sub    pod   time  total
2685   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2686   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2687   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2688   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2689   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2690   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2691
2692 =head1 AUTHOR
2693
2694 Joseph Huckaby, L<jhuckaby@cpan.org>
2695
2696 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2697
2698 =head1 SEE ALSO
2699
2700 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2701 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2702
2703 =head1 LICENSE
2704
2705 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2706 This is free software, you may use it and distribute it under the
2707 same terms as Perl itself.
2708
2709 =cut