lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use FileHandle;
  35 use Fcntl qw/:flock/;
  36 use Digest::MD5 ();
  37 use Scalar::Util ();
  38 use vars qw/$VERSION/;
  39
  40 $VERSION = "0.96";
  41
  42 ##
  43 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  44 #       (Perl must be compiled with largefile support for files > 2 GB)
  45 #
  46 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47 #       (Perl must be compiled with largefile and 64-bit long support)
  48 ##
  49 #my $LONG_SIZE = 4;
  50 #my $LONG_PACK = 'N';
  51
  52 ##
  53 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  54 # Upgrading this is possible (see above) but probably not necessary.  If you need
  55 # more than 4 GB for a single key or value, this module is really not for you :-)
  56 ##
  57 #my $DATA_LENGTH_SIZE = 4;
  58 #my $DATA_LENGTH_PACK = 'N';
  59 my ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  60
  61 ##
  62 # Maximum number of buckets per list before another level of indexing is done.
  63 # Increase this value for slightly greater speed, but larger database files.
  64 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  65 ##
  66 my $MAX_BUCKETS = 16;
  67
  68 ##
  69 # Better not adjust anything below here, unless you're me :-)
  70 ##
  71
  72 ##
  73 # Setup digest function for keys
  74 ##
  75 my ($DIGEST_FUNC, $HASH_SIZE);
  76 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  77
  78 ##
  79 # Precalculate index and bucket sizes based on values above.
  80 ##
  81 #my $HASH_SIZE = 16;
  82 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  83
  84 set_digest();
  85 #set_pack();
  86 #precalc_sizes();
  87
  88 ##
  89 # Setup file and tag signatures.  These should never change.
  90 ##
  91 sub SIG_FILE  () { 'DPDB' }
  92 sub SIG_HASH  () { 'H' }
  93 sub SIG_ARRAY () { 'A' }
  94 sub SIG_NULL  () { 'N' }
  95 sub SIG_DATA  () { 'D' }
  96 sub SIG_INDEX () { 'I' }
  97 sub SIG_BLIST () { 'B' }
  98 sub SIG_SIZE  () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH  () { return SIG_HASH; }
 104 sub TYPE_ARRAY () { return SIG_ARRAY; }
 105
 106 sub new {
 107         ##
 108         # Class constructor method for Perl OO interface.
 109         # Calls tie() and returns blessed reference to tied hash or array,
 110         # providing a hybrid OO/tie interface.
 111         ##
 112         my $class = shift;
 113         my $args;
 114         if (scalar(@_) > 1) { $args = {@_}; }
 115         else { $args = { file => shift }; }
 116
 117         ##
 118         # Check if we want a tied hash or array.
 119         ##
 120         my $self;
 121         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 122                 tie @$self, $class, %$args;
 123         }
 124         else {
 125                 tie %$self, $class, %$args;
 126         }
 127
 128         return bless $self, $class;
 129 }
 130
 131 {
 132     my @outer_params = qw( type base_offset );
 133     sub _init {
 134         ##
 135         # Setup $self and bless into this class.
 136         ##
 137         my $class = shift;
 138         my $args = shift;
 139
 140         my $self = {
 141             type => TYPE_HASH,
 142             base_offset => length(SIG_FILE),
 143             root => {
 144                 file => undef,
 145                 fh => undef,
 146                 end => 0,
 147                 links => 0,
 148                 autoflush => undef,
 149                 locking => undef,
 150                 volatile => undef,
 151                 debug => undef,
 152                 mode => 'r+',
 153                 filter_store_key => undef,
 154                 filter_store_value => undef,
 155                 filter_fetch_key => undef,
 156                 filter_fetch_value => undef,
 157                 autobless => undef,
 158                 locked => 0,
 159                 %$args,
 160             },
 161         };
 162
 163         bless $self, $class;
 164
 165         foreach my $outer_parm ( @outer_params ) {
 166             next unless exists $args->{$outer_parm};
 167             $self->{$outer_parm} = $args->{$outer_parm}
 168         }
 169
 170         if ( exists $args->{root} ) {
 171             $self->{root} = $args->{root};
 172         }
 173         else {
 174             # This is cleanup based on the fact that the $args
 175             # coming in is for both the root and non-root items
 176             delete $self->root->{$_} for @outer_params;
 177         }
 178         $self->root->{links}++;
 179
 180         if (!defined($self->fh)) { $self->_open(); }
 181
 182         return $self;
 183     }
 184 }
 185
 186 sub _get_self { tied( %{$_[0]} ) || $_[0] }
 187
 188 sub TIEHASH {
 189     ##
 190     # Tied hash constructor method, called by Perl's tie() function.
 191     ##
 192     my $class = shift;
 193     my $args;
 194     if (scalar(@_) > 1) { $args = {@_}; }
 195     #XXX This use of ref() is bad and is a bug
 196     elsif (ref($_[0])) { $args = $_[0]; }
 197     else { $args = { file => shift }; }
 198
 199     $args->{type} = TYPE_HASH;
 200
 201     return $class->_init($args);
 202 }
 203
 204 sub TIEARRAY {
 205 ##
 206 # Tied array constructor method, called by Perl's tie() function.
 207 ##
 208     my $class = shift;
 209     my $args;
 210     if (scalar(@_) > 1) { $args = {@_}; }
 211     #XXX This use of ref() is bad and is a bug
 212         elsif (ref($_[0])) { $args = $_[0]; }
 213         else { $args = { file => shift }; }
 214
 215         $args->{type} = TYPE_ARRAY;
 216
 217         return $class->_init($args);
 218 }
 219
 220 sub DESTROY {
 221         ##
 222         # Class deconstructor.  Close file handle if there are no more refs.
 223         ##
 224     my $self = _get_self($_[0]);
 225     return unless $self;
 226
 227         $self->root->{links}--;
 228
 229         if (!$self->root->{links}) {
 230                 $self->_close();
 231         }
 232 }
 233
 234 sub _open {
 235         ##
 236         # Open a FileHandle to the database, create if nonexistent.
 237         # Make sure file signature matches DeepDB spec.
 238         ##
 239     my $self = _get_self($_[0]);
 240
 241         if (defined($self->fh)) { $self->_close(); }
 242
 243 #    eval {
 244         if (!(-e $self->root->{file}) && $self->root->{mode} eq 'r+') {
 245             my $temp = FileHandle->new( $self->root->{file}, 'w' );
 246         }
 247
 248         #XXX Convert to set_fh()
 249         $self->root->{fh} = FileHandle->new( $self->root->{file}, $self->root->{mode} );
 250 #    }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 251         if (! defined($self->fh)) {
 252                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 253         }
 254
 255     binmode $self->fh; # for win32
 256     if ($self->root->{autoflush}) {
 257         $self->fh->autoflush();
 258     }
 259
 260     my $signature;
 261     seek($self->fh, 0, 0);
 262     my $bytes_read = read( $self->fh, $signature, length(SIG_FILE));
 263
 264     ##
 265     # File is empty -- write signature and master index
 266     ##
 267     if (!$bytes_read) {
 268         seek($self->fh, 0, 0);
 269         $self->fh->print(SIG_FILE);
 270         $self->root->{end} = length(SIG_FILE);
 271         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 272
 273         my $plain_key = "[base]";
 274         $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 275         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 276         $self->fh->flush();
 277
 278         return 1;
 279     }
 280
 281     ##
 282     # Check signature was valid
 283     ##
 284     unless ($signature eq SIG_FILE) {
 285         $self->_close();
 286         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 287     }
 288
 289     $self->root->{end} = (stat($self->fh))[7];
 290
 291     ##
 292     # Get our type from master index signature
 293     ##
 294     my $tag = $self->_load_tag($self->base_offset);
 295 #XXX We probably also want to store the hash algorithm name and not assume anything
 296     if (!$tag) {
 297         return $self->_throw_error("Corrupted file, no master index record");
 298     }
 299     if ($self->{type} ne $tag->{signature}) {
 300         return $self->_throw_error("File type mismatch");
 301     }
 302
 303     return 1;
 304 }
 305
 306 sub _close {
 307         ##
 308         # Close database FileHandle
 309         ##
 310     my $self = _get_self($_[0]);
 311         undef $self->root->{fh};
 312 }
 313
 314 sub _create_tag {
 315         ##
 316         # Given offset, signature and content, create tag and write to disk
 317         ##
 318         my ($self, $offset, $sig, $content) = @_;
 319         my $size = length($content);
 320
 321         seek($self->fh, $offset, 0);
 322         $self->fh->print( $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 323
 324         if ($offset == $self->root->{end}) {
 325                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 326         }
 327
 328         return {
 329                 signature => $sig,
 330                 size => $size,
 331                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 332                 content => $content
 333         };
 334 }
 335
 336 sub _load_tag {
 337         ##
 338         # Given offset, load single tag and return signature, size and data
 339         ##
 340         my $self = shift;
 341         my $offset = shift;
 342
 343     my $fh = $self->fh;
 344
 345         seek($fh, $offset, 0);
 346         if (eof $fh) { return undef; }
 347
 348         my $sig;
 349         read( $fh, $sig, SIG_SIZE);
 350
 351         my $size;
 352         read( $fh, $size, $DATA_LENGTH_SIZE);
 353         $size = unpack($DATA_LENGTH_PACK, $size);
 354
 355         my $buffer;
 356         read( $fh, $buffer, $size);
 357
 358         return {
 359                 signature => $sig,
 360                 size => $size,
 361                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 362                 content => $buffer
 363         };
 364 }
 365
 366 sub _index_lookup {
 367         ##
 368         # Given index tag, lookup single entry in index and return .
 369         ##
 370         my $self = shift;
 371         my ($tag, $index) = @_;
 372
 373         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 374         if (!$location) { return; }
 375
 376         return $self->_load_tag( $location );
 377 }
 378
 379 sub _add_bucket {
 380         ##
 381         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 382         # plain (undigested) key and value.
 383         ##
 384         my $self = shift;
 385         my ($tag, $md5, $plain_key, $value) = @_;
 386         my $keys = $tag->{content};
 387         my $location = 0;
 388         my $result = 2;
 389
 390     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 391         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 392
 393         ##
 394         # Iterate through buckets, seeing if this is a new entry or a replace.
 395         ##
 396         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 397                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 398                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 399                 if (!$subloc) {
 400                         ##
 401                         # Found empty bucket (end of list).  Populate and exit loop.
 402                         ##
 403                         $result = 2;
 404
 405             $location = $internal_ref
 406                 ? $value->base_offset
 407                 : $self->root->{end};
 408
 409                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 410                         $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 411                         last;
 412                 }
 413                 elsif ($md5 eq $key) {
 414                         ##
 415                         # Found existing bucket with same key.  Replace with new value.
 416                         ##
 417                         $result = 1;
 418
 419                         if ($internal_ref) {
 420                                 $location = $value->base_offset;
 421                                 seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 422                                 $self->fh->print( $md5 . pack($LONG_PACK, $location) );
 423                         }
 424                         else {
 425                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 426                                 my $size;
 427                                 read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 428
 429                                 ##
 430                                 # If value is a hash, array, or raw value with equal or less size, we can
 431                                 # reuse the same content area of the database.  Otherwise, we have to create
 432                                 # a new content area at the EOF.
 433                                 ##
 434                                 my $actual_length;
 435                 my $r = Scalar::Util::reftype( $value ) || '';
 436                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 437                                 else { $actual_length = length($value); }
 438
 439                                 if ($actual_length <= $size) {
 440                                         $location = $subloc;
 441                                 }
 442                                 else {
 443                                         $location = $self->root->{end};
 444                                         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 445                                         $self->fh->print( pack($LONG_PACK, $location) );
 446                                 }
 447                         }
 448                         last;
 449                 }
 450         } # i loop
 451
 452         ##
 453         # If this is an internal reference, return now.
 454         # No need to write value or plain key
 455         ##
 456         if ($internal_ref) {
 457         return $result;
 458     }
 459
 460         ##
 461         # If bucket didn't fit into list, split into a new index level
 462         ##
 463         if (!$location) {
 464                 seek($self->fh, $tag->{ref_loc}, 0);
 465                 $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 466
 467                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 468                 my @offsets = ();
 469
 470                 $keys .= $md5 . pack($LONG_PACK, 0);
 471
 472                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 473                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 474                         if ($key) {
 475                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 476                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 477
 478                                 if ($offsets[$num]) {
 479                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 480                                         seek($self->fh, $offset, 0);
 481                                         my $subkeys;
 482                                         read( $self->fh, $subkeys, $BUCKET_LIST_SIZE);
 483
 484                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 485                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 486                                                 if (!$subloc) {
 487                                                         seek($self->fh, $offset + ($k * $BUCKET_SIZE), 0);
 488                                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 489                                                         last;
 490                                                 }
 491                                         } # k loop
 492                                 }
 493                                 else {
 494                                         $offsets[$num] = $self->root->{end};
 495                                         seek($self->fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 496                                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
 497
 498                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 499
 500                                         seek($self->fh, $blist_tag->{offset}, 0);
 501                                         $self->fh->print( $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 502                                 }
 503                         } # key is real
 504                 } # i loop
 505
 506                 $location ||= $self->root->{end};
 507         } # re-index bucket list
 508
 509         ##
 510         # Seek to content area and store signature, value and plaintext key
 511         ##
 512         if ($location) {
 513                 my $content_length;
 514                 seek($self->fh, $location, 0);
 515
 516                 ##
 517                 # Write signature based on content type, set content length and write actual value.
 518                 ##
 519         my $r = Scalar::Util::reftype($value) || '';
 520                 if ($r eq 'HASH') {
 521                         $self->fh->print( TYPE_HASH );
 522                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 523                         $content_length = $INDEX_SIZE;
 524                 }
 525                 elsif ($r eq 'ARRAY') {
 526                         $self->fh->print( TYPE_ARRAY );
 527                         $self->fh->print( pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 528                         $content_length = $INDEX_SIZE;
 529                 }
 530                 elsif (!defined($value)) {
 531                         $self->fh->print( SIG_NULL );
 532                         $self->fh->print( pack($DATA_LENGTH_PACK, 0) );
 533                         $content_length = 0;
 534                 }
 535                 else {
 536                         $self->fh->print( SIG_DATA );
 537                         $self->fh->print( pack($DATA_LENGTH_PACK, length($value)) . $value );
 538                         $content_length = length($value);
 539                 }
 540
 541                 ##
 542                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 543                 ##
 544                 $self->fh->print( pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 545
 546                 ##
 547                 # If value is blessed, preserve class name
 548                 ##
 549                 if ( $self->root->{autobless} ) {
 550             my $value_class = Scalar::Util::blessed($value);
 551             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 552                 ##
 553                 # Blessed ref -- will restore later
 554                 ##
 555                 $self->fh->print( chr(1) );
 556                 $self->fh->print( pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 557                 $content_length += 1;
 558                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 559             }
 560             else {
 561                 $self->fh->print( chr(0) );
 562                 $content_length += 1;
 563             }
 564         }
 565
 566                 ##
 567                 # If this is a new content area, advance EOF counter
 568                 ##
 569                 if ($location == $self->root->{end}) {
 570                         $self->root->{end} += SIG_SIZE;
 571                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 572                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 573                 }
 574
 575                 ##
 576                 # If content is a hash or array, create new child DeepDB object and
 577                 # pass each key or element to it.
 578                 ##
 579                 if ($r eq 'HASH') {
 580                         my $branch = DBM::Deep->new(
 581                                 type => TYPE_HASH,
 582                                 base_offset => $location,
 583                                 root => $self->root,
 584                         );
 585                         foreach my $key (keys %{$value}) {
 586                                 $branch->{$key} = $value->{$key};
 587                         }
 588                 }
 589                 elsif ($r eq 'ARRAY') {
 590                         my $branch = DBM::Deep->new(
 591                                 type => TYPE_ARRAY,
 592                                 base_offset => $location,
 593                                 root => $self->root,
 594                         );
 595                         my $index = 0;
 596                         foreach my $element (@{$value}) {
 597                                 $branch->[$index] = $element;
 598                                 $index++;
 599                         }
 600                 }
 601
 602                 return $result;
 603         }
 604
 605         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 606 }
 607
 608 sub _get_bucket_value {
 609         ##
 610         # Fetch single value given tag and MD5 digested key.
 611         ##
 612         my $self = shift;
 613         my ($tag, $md5) = @_;
 614         my $keys = $tag->{content};
 615
 616         ##
 617         # Iterate through buckets, looking for a key match
 618         ##
 619     BUCKET:
 620         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 621                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 622                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 623
 624                 if (!$subloc) {
 625                         ##
 626                         # Hit end of list, no match
 627                         ##
 628                         return;
 629                 }
 630
 631         if ( $md5 ne $key ) {
 632             next BUCKET;
 633         }
 634
 635         ##
 636         # Found match -- seek to offset and read signature
 637         ##
 638         my $signature;
 639         seek($self->fh, $subloc, 0);
 640         read( $self->fh, $signature, SIG_SIZE);
 641
 642         ##
 643         # If value is a hash or array, return new DeepDB object with correct offset
 644         ##
 645         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 646             my $obj = DBM::Deep->new(
 647                 type => $signature,
 648                 base_offset => $subloc,
 649                 root => $self->root
 650             );
 651
 652             if ($self->root->{autobless}) {
 653                 ##
 654                 # Skip over value and plain key to see if object needs
 655                 # to be re-blessed
 656                 ##
 657                 seek($self->fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 658
 659                 my $size;
 660                 read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 661                 if ($size) { seek($self->fh, $size, 1); }
 662
 663                 my $bless_bit;
 664                 read( $self->fh, $bless_bit, 1);
 665                 if (ord($bless_bit)) {
 666                     ##
 667                     # Yes, object needs to be re-blessed
 668                     ##
 669                     my $class_name;
 670                     read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 671                     if ($size) { read( $self->fh, $class_name, $size); }
 672                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 673                 }
 674             }
 675
 676             return $obj;
 677         }
 678
 679         ##
 680         # Otherwise return actual value
 681         ##
 682         elsif ($signature eq SIG_DATA) {
 683             my $size;
 684             my $value = '';
 685             read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 686             if ($size) { read( $self->fh, $value, $size); }
 687             return $value;
 688         }
 689
 690         ##
 691         # Key exists, but content is null
 692         ##
 693         else { return; }
 694         } # i loop
 695
 696         return;
 697 }
 698
 699 sub _delete_bucket {
 700         ##
 701         # Delete single key/value pair given tag and MD5 digested key.
 702         ##
 703         my $self = shift;
 704         my ($tag, $md5) = @_;
 705         my $keys = $tag->{content};
 706
 707         ##
 708         # Iterate through buckets, looking for a key match
 709         ##
 710     BUCKET:
 711         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 712                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 713                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 714
 715                 if (!$subloc) {
 716                         ##
 717                         # Hit end of list, no match
 718                         ##
 719                         return;
 720                 }
 721
 722         if ( $md5 ne $key ) {
 723             next BUCKET;
 724         }
 725
 726         ##
 727         # Matched key -- delete bucket and return
 728         ##
 729         seek($self->fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 730         $self->fh->print( substr($keys, ($i+1) * $BUCKET_SIZE ) );
 731         $self->fh->print( chr(0) x $BUCKET_SIZE );
 732
 733         return 1;
 734         } # i loop
 735
 736         return;
 737 }
 738
 739 sub _bucket_exists {
 740         ##
 741         # Check existence of single key given tag and MD5 digested key.
 742         ##
 743         my $self = shift;
 744         my ($tag, $md5) = @_;
 745         my $keys = $tag->{content};
 746
 747         ##
 748         # Iterate through buckets, looking for a key match
 749         ##
 750     BUCKET:
 751         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 752                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 753                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 754
 755                 if (!$subloc) {
 756                         ##
 757                         # Hit end of list, no match
 758                         ##
 759                         return;
 760                 }
 761
 762         if ( $md5 ne $key ) {
 763             next BUCKET;
 764         }
 765
 766         ##
 767         # Matched key -- return true
 768         ##
 769         return 1;
 770         } # i loop
 771
 772         return;
 773 }
 774
 775 sub _find_bucket_list {
 776         ##
 777         # Locate offset for bucket list, given digested key
 778         ##
 779         my $self = shift;
 780         my $md5 = shift;
 781
 782         ##
 783         # Locate offset for bucket list using digest index system
 784         ##
 785         my $ch = 0;
 786         my $tag = $self->_load_tag($self->base_offset);
 787         if (!$tag) { return; }
 788
 789         while ($tag->{signature} ne SIG_BLIST) {
 790                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 791                 if (!$tag) { return; }
 792                 $ch++;
 793         }
 794
 795         return $tag;
 796 }
 797
 798 sub _traverse_index {
 799         ##
 800         # Scan index and recursively step into deeper levels, looking for next key.
 801         ##
 802     my ($self, $offset, $ch, $force_return_next) = @_;
 803     $force_return_next = undef unless $force_return_next;
 804
 805         my $tag = $self->_load_tag( $offset );
 806
 807         if ($tag->{signature} ne SIG_BLIST) {
 808                 my $content = $tag->{content};
 809                 my $start;
 810                 if ($self->{return_next}) { $start = 0; }
 811                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 812
 813                 for (my $index = $start; $index < 256; $index++) {
 814                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 815                         if ($subloc) {
 816                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 817                                 if (defined($result)) { return $result; }
 818                         }
 819                 } # index loop
 820
 821                 $self->{return_next} = 1;
 822         } # tag is an index
 823
 824         elsif ($tag->{signature} eq SIG_BLIST) {
 825                 my $keys = $tag->{content};
 826                 if ($force_return_next) { $self->{return_next} = 1; }
 827
 828                 ##
 829                 # Iterate through buckets, looking for a key match
 830                 ##
 831                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 832                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 833                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 834
 835                         if (!$subloc) {
 836                                 ##
 837                                 # End of bucket list -- return to outer loop
 838                                 ##
 839                                 $self->{return_next} = 1;
 840                                 last;
 841                         }
 842                         elsif ($key eq $self->{prev_md5}) {
 843                                 ##
 844                                 # Located previous key -- return next one found
 845                                 ##
 846                                 $self->{return_next} = 1;
 847                                 next;
 848                         }
 849                         elsif ($self->{return_next}) {
 850                                 ##
 851                                 # Seek to bucket location and skip over signature
 852                                 ##
 853                                 seek($self->fh, $subloc + SIG_SIZE, 0);
 854
 855                                 ##
 856                                 # Skip over value to get to plain key
 857                                 ##
 858                                 my $size;
 859                                 read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 860                                 if ($size) { seek($self->fh, $size, 1); }
 861
 862                                 ##
 863                                 # Read in plain key and return as scalar
 864                                 ##
 865                                 my $plain_key;
 866                                 read( $self->fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 867                                 if ($size) { read( $self->fh, $plain_key, $size); }
 868
 869                                 return $plain_key;
 870                         }
 871                 } # bucket loop
 872
 873                 $self->{return_next} = 1;
 874         } # tag is a bucket list
 875
 876         return;
 877 }
 878
 879 sub _get_next_key {
 880         ##
 881         # Locate next key, given digested previous one
 882         ##
 883     my $self = _get_self($_[0]);
 884
 885         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 886         $self->{return_next} = 0;
 887
 888         ##
 889         # If the previous key was not specifed, start at the top and
 890         # return the first one found.
 891         ##
 892         if (!$self->{prev_md5}) {
 893                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 894                 $self->{return_next} = 1;
 895         }
 896
 897         return $self->_traverse_index( $self->base_offset, 0 );
 898 }
 899
 900 sub lock {
 901         ##
 902         # If db locking is set, flock() the db file.  If called multiple
 903         # times before unlock(), then the same number of unlocks() must
 904         # be called before the lock is released.
 905         ##
 906     my $self = _get_self($_[0]);
 907         my $type = $_[1];
 908     $type = LOCK_EX unless defined $type;
 909
 910         if ($self->root->{locking}) {
 911                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 912                 $self->root->{locked}++;
 913         }
 914 }
 915
 916 sub unlock {
 917         ##
 918         # If db locking is set, unlock the db file.  See note in lock()
 919         # regarding calling lock() multiple times.
 920         ##
 921     my $self = _get_self($_[0]);
 922
 923         if ($self->root->{locking} && $self->root->{locked} > 0) {
 924                 $self->root->{locked}--;
 925                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 926         }
 927 }
 928
 929 #XXX These uses of ref() need verified
 930 sub _copy_node {
 931         ##
 932         # Copy single level of keys or elements to new DB handle.
 933         # Recurse for nested structures
 934         ##
 935     my $self = _get_self($_[0]);
 936         my $db_temp = $_[1];
 937
 938         if ($self->type eq TYPE_HASH) {
 939                 my $key = $self->first_key();
 940                 while ($key) {
 941                         my $value = $self->get($key);
 942 #XXX This doesn't work with autobless
 943                         if (!ref($value)) { $db_temp->{$key} = $value; }
 944                         else {
 945                                 my $type = $value->type;
 946                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 947                                 else { $db_temp->{$key} = []; }
 948                                 $value->_copy_node( $db_temp->{$key} );
 949                         }
 950                         $key = $self->next_key($key);
 951                 }
 952         }
 953         else {
 954                 my $length = $self->length();
 955                 for (my $index = 0; $index < $length; $index++) {
 956                         my $value = $self->get($index);
 957                         if (!ref($value)) { $db_temp->[$index] = $value; }
 958             #XXX NO tests for this code
 959                         else {
 960                                 my $type = $value->type;
 961                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 962                                 else { $db_temp->[$index] = []; }
 963                                 $value->_copy_node( $db_temp->[$index] );
 964                         }
 965                 }
 966         }
 967 }
 968
 969 sub export {
 970         ##
 971         # Recursively export into standard Perl hashes and arrays.
 972         ##
 973     my $self = _get_self($_[0]);
 974
 975         my $temp;
 976         if ($self->type eq TYPE_HASH) { $temp = {}; }
 977         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 978
 979         $self->lock();
 980         $self->_copy_node( $temp );
 981         $self->unlock();
 982
 983         return $temp;
 984 }
 985
 986 sub import {
 987         ##
 988         # Recursively import Perl hash/array structure
 989         ##
 990     #XXX This use of ref() seems to be ok
 991         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 992
 993     my $self = _get_self($_[0]);
 994         my $struct = $_[1];
 995
 996     #XXX This use of ref() seems to be ok
 997         if (!ref($struct)) {
 998                 ##
 999                 # struct is not a reference, so just import based on our type
1000                 ##
1001                 shift @_;
1002
1003                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1004                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1005         }
1006
1007     my $r = Scalar::Util::reftype($struct) || '';
1008         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1009                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1010         }
1011         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1012                 $self->push( @$struct );
1013         }
1014         else {
1015                 return $self->_throw_error("Cannot import: type mismatch");
1016         }
1017
1018         return 1;
1019 }
1020
1021 sub optimize {
1022         ##
1023         # Rebuild entire database into new file, then move
1024         # it back on top of original.
1025         ##
1026     my $self = _get_self($_[0]);
1027         if ($self->root->{links} > 1) {
1028                 return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1029         }
1030
1031         my $db_temp = DBM::Deep->new(
1032                 file => $self->root->{file} . '.tmp',
1033                 type => $self->type
1034         );
1035         if (!$db_temp) {
1036                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1037         }
1038
1039         $self->lock();
1040         $self->_copy_node( $db_temp );
1041         undef $db_temp;
1042
1043         ##
1044         # Attempt to copy user, group and permissions over to new file
1045         ##
1046         my @stats = stat($self->fh);
1047         my $perms = $stats[2] & 07777;
1048         my $uid = $stats[4];
1049         my $gid = $stats[5];
1050         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1051         chmod( $perms, $self->root->{file} . '.tmp' );
1052
1053     # q.v. perlport for more information on this variable
1054     if ( $^O eq 'MSWin32' ) {
1055                 ##
1056                 # Potential race condition when optmizing on Win32 with locking.
1057                 # The Windows filesystem requires that the filehandle be closed
1058                 # before it is overwritten with rename().  This could be redone
1059                 # with a soft copy.
1060                 ##
1061                 $self->unlock();
1062                 $self->_close();
1063         }
1064
1065         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1066                 unlink $self->root->{file} . '.tmp';
1067                 $self->unlock();
1068                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1069         }
1070
1071         $self->unlock();
1072         $self->_close();
1073         $self->_open();
1074
1075         return 1;
1076 }
1077
1078 sub clone {
1079         ##
1080         # Make copy of object and return
1081         ##
1082     my $self = _get_self($_[0]);
1083
1084         return DBM::Deep->new(
1085                 type => $self->type,
1086                 base_offset => $self->base_offset,
1087                 root => $self->root
1088         );
1089 }
1090
1091 {
1092     my %is_legal_filter = map {
1093         $_ => ~~1,
1094     } qw(
1095         store_key store_value
1096         fetch_key fetch_value
1097     );
1098
1099     sub set_filter {
1100         ##
1101         # Setup filter function for storing or fetching the key or value
1102         ##
1103         my $self = _get_self($_[0]);
1104         my $type = lc $_[1];
1105         my $func = $_[2] ? $_[2] : undef;
1106
1107         if ( $is_legal_filter{$type} ) {
1108             $self->root->{"filter_$type"} = $func;
1109             return 1;
1110         }
1111
1112         return;
1113     }
1114 }
1115
1116 ##
1117 # Accessor methods
1118 ##
1119
1120 sub root {
1121         ##
1122         # Get access to the root structure
1123         ##
1124     my $self = _get_self($_[0]);
1125         return $self->{root};
1126 }
1127
1128 sub fh {
1129         ##
1130         # Get access to the raw FileHandle
1131         ##
1132     #XXX It will be useful, though, when we split out HASH and ARRAY
1133     my $self = _get_self($_[0]);
1134         return $self->root->{fh};
1135 }
1136
1137 sub type {
1138         ##
1139         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1140         ##
1141     my $self = _get_self($_[0]);
1142         return $self->{type};
1143 }
1144
1145 sub base_offset {
1146         ##
1147         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1148         ##
1149     my $self = _get_self($_[0]);
1150         return $self->{base_offset};
1151 }
1152
1153 sub error {
1154         ##
1155         # Get last error string, or undef if no error
1156         ##
1157         return $_[0]
1158         ? ( _get_self($_[0])->{root}->{error} or undef )
1159         : $@;
1160 }
1161
1162 ##
1163 # Utility methods
1164 ##
1165
1166 sub _throw_error {
1167         ##
1168         # Store error string in self
1169         ##
1170     my $self = _get_self($_[0]);
1171         my $error_text = $_[1];
1172
1173         $self->root->{error} = $error_text;
1174
1175         unless ($self->root->{debug}) {
1176         die "DBM::Deep: $error_text\n";
1177     }
1178
1179     warn "DBM::Deep: $error_text\n";
1180         return;
1181 }
1182
1183 sub clear_error {
1184         ##
1185         # Clear error state
1186         ##
1187     my $self = _get_self($_[0]);
1188
1189         undef $self->root->{error};
1190 }
1191
1192 sub precalc_sizes {
1193         ##
1194         # Precalculate index, bucket and bucket list sizes
1195         ##
1196
1197     #XXX I don't like this ...
1198     set_pack() unless defined $LONG_SIZE;
1199
1200         $INDEX_SIZE = 256 * $LONG_SIZE;
1201         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1202         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1203 }
1204
1205 sub set_pack {
1206         ##
1207         # Set pack/unpack modes (see file header for more)
1208         ##
1209     my ($long_s, $long_p, $data_s, $data_p) = @_;
1210
1211     $LONG_SIZE = $long_s ? $long_s : 4;
1212     $LONG_PACK = $long_p ? $long_p : 'N';
1213
1214     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1215     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1216
1217         precalc_sizes();
1218 }
1219
1220 sub set_digest {
1221         ##
1222         # Set key digest function (default is MD5)
1223         ##
1224     my ($digest_func, $hash_size) = @_;
1225
1226     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1227     $HASH_SIZE = $hash_size ? $hash_size : 16;
1228
1229         precalc_sizes();
1230 }
1231
1232 ##
1233 # tie() methods (hashes and arrays)
1234 ##
1235
1236 sub STORE {
1237         ##
1238         # Store single hash key/value or array element in database.
1239         ##
1240     my $self = _get_self($_[0]);
1241         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1242     #XXX What is ref() checking here?
1243     #YYY User may be storing a hash, in which case we do not want it run
1244     #YYY through the filtering system
1245         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1246
1247         my $unpacked_key = $key;
1248         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1249         my $md5 = $DIGEST_FUNC->($key);
1250
1251         ##
1252         # Make sure file is open
1253         ##
1254         if (!defined($self->fh) && !$self->_open()) {
1255                 return;
1256         }
1257
1258         ##
1259         # Request exclusive lock for writing
1260         ##
1261         $self->lock( LOCK_EX );
1262
1263         ##
1264         # If locking is enabled, set 'end' parameter again, in case another
1265         # DB instance appended to our file while we were unlocked.
1266         ##
1267         if ($self->root->{locking} || $self->root->{volatile}) {
1268                 $self->root->{end} = (stat($self->fh))[7];
1269         }
1270
1271         ##
1272         # Locate offset for bucket list using digest index system
1273         ##
1274         my $tag = $self->_load_tag($self->base_offset);
1275         if (!$tag) {
1276                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1277         }
1278
1279         my $ch = 0;
1280         while ($tag->{signature} ne SIG_BLIST) {
1281                 my $num = ord(substr($md5, $ch, 1));
1282                 my $new_tag = $self->_index_lookup($tag, $num);
1283                 if (!$new_tag) {
1284                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1285                         seek($self->fh, $ref_loc, 0);
1286                         $self->fh->print( pack($LONG_PACK, $self->root->{end}) );
1287
1288                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1289                         $tag->{ref_loc} = $ref_loc;
1290                         $tag->{ch} = $ch;
1291                         last;
1292                 }
1293                 else {
1294                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1295                         $tag = $new_tag;
1296                         $tag->{ref_loc} = $ref_loc;
1297                         $tag->{ch} = $ch;
1298                 }
1299                 $ch++;
1300         }
1301
1302         ##
1303         # Add key/value to bucket list
1304         ##
1305         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1306
1307         ##
1308         # If this object is an array, and bucket was not a replace, and key is numerical,
1309         # and index is equal or greater than current length, advance length variable.
1310         ##
1311         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1312                 $self->STORESIZE( $unpacked_key + 1 );
1313         }
1314
1315         $self->unlock();
1316
1317         return $result;
1318 }
1319
1320 sub FETCH {
1321         ##
1322         # Fetch single value or element given plain key or array index
1323         ##
1324     my $self = _get_self($_[0]);
1325
1326     my $key = $_[1];
1327     if ( $self->type eq TYPE_HASH ) {
1328         if ( my $filter = $self->root->{filter_store_key} ) {
1329             $key = $filter->( $key );
1330         }
1331     }
1332     elsif ( $self->type eq TYPE_ARRAY ) {
1333         if ( $key =~ /^\d+$/ ) {
1334             $key = pack($LONG_PACK, $key);
1335         }
1336     }
1337
1338         my $md5 = $DIGEST_FUNC->($key);
1339
1340         ##
1341         # Make sure file is open
1342         ##
1343         if (!defined($self->fh)) { $self->_open(); }
1344
1345         ##
1346         # Request shared lock for reading
1347         ##
1348         $self->lock( LOCK_SH );
1349
1350         my $tag = $self->_find_bucket_list( $md5 );
1351         if (!$tag) {
1352                 $self->unlock();
1353                 return;
1354         }
1355
1356         ##
1357         # Get value from bucket list
1358         ##
1359         my $result = $self->_get_bucket_value( $tag, $md5 );
1360
1361         $self->unlock();
1362
1363     #XXX What is ref() checking here?
1364         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1365 }
1366
1367 sub DELETE {
1368         ##
1369         # Delete single key/value pair or element given plain key or array index
1370         ##
1371     my $self = _get_self($_[0]);
1372         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1373
1374         my $unpacked_key = $key;
1375         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1376         my $md5 = $DIGEST_FUNC->($key);
1377
1378         ##
1379         # Make sure file is open
1380         ##
1381         if (!defined($self->fh)) { $self->_open(); }
1382
1383         ##
1384         # Request exclusive lock for writing
1385         ##
1386         $self->lock( LOCK_EX );
1387
1388         my $tag = $self->_find_bucket_list( $md5 );
1389         if (!$tag) {
1390                 $self->unlock();
1391                 return;
1392         }
1393
1394         ##
1395         # Delete bucket
1396         ##
1397         my $result = $self->_delete_bucket( $tag, $md5 );
1398
1399         ##
1400         # If this object is an array and the key deleted was on the end of the stack,
1401         # decrement the length variable.
1402         ##
1403         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1404                 $self->STORESIZE( $unpacked_key );
1405         }
1406
1407         $self->unlock();
1408
1409         return $result;
1410 }
1411
1412 sub EXISTS {
1413         ##
1414         # Check if a single key or element exists given plain key or array index
1415         ##
1416     my $self = _get_self($_[0]);
1417         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1418
1419         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1420         my $md5 = $DIGEST_FUNC->($key);
1421
1422         ##
1423         # Make sure file is open
1424         ##
1425         if (!defined($self->fh)) { $self->_open(); }
1426
1427         ##
1428         # Request shared lock for reading
1429         ##
1430         $self->lock( LOCK_SH );
1431
1432         my $tag = $self->_find_bucket_list( $md5 );
1433
1434         ##
1435         # For some reason, the built-in exists() function returns '' for false
1436         ##
1437         if (!$tag) {
1438                 $self->unlock();
1439                 return '';
1440         }
1441
1442         ##
1443         # Check if bucket exists and return 1 or ''
1444         ##
1445         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1446
1447         $self->unlock();
1448
1449         return $result;
1450 }
1451
1452 sub CLEAR {
1453         ##
1454         # Clear all keys from hash, or all elements from array.
1455         ##
1456     my $self = _get_self($_[0]);
1457
1458         ##
1459         # Make sure file is open
1460         ##
1461         if (!defined($self->fh)) { $self->_open(); }
1462
1463         ##
1464         # Request exclusive lock for writing
1465         ##
1466         $self->lock( LOCK_EX );
1467
1468     my $fh = $self->fh;
1469
1470         seek($fh, $self->base_offset, 0);
1471         if (eof $fh) {
1472                 $self->unlock();
1473                 return;
1474         }
1475
1476         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1477
1478         $self->unlock();
1479
1480         return 1;
1481 }
1482
1483 sub FIRSTKEY {
1484         ##
1485         # Locate and return first key (in no particular order)
1486         ##
1487     my $self = _get_self($_[0]);
1488         if ($self->type ne TYPE_HASH) {
1489                 return $self->_throw_error("FIRSTKEY method only supported for hashes");
1490         }
1491
1492         ##
1493         # Make sure file is open
1494         ##
1495         if (!defined($self->fh)) { $self->_open(); }
1496
1497         ##
1498         # Request shared lock for reading
1499         ##
1500         $self->lock( LOCK_SH );
1501
1502         my $result = $self->_get_next_key();
1503
1504         $self->unlock();
1505
1506         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1507 }
1508
1509 sub NEXTKEY {
1510         ##
1511         # Return next key (in no particular order), given previous one
1512         ##
1513     my $self = _get_self($_[0]);
1514         if ($self->type ne TYPE_HASH) {
1515                 return $self->_throw_error("NEXTKEY method only supported for hashes");
1516         }
1517         my $prev_key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1518         my $prev_md5 = $DIGEST_FUNC->($prev_key);
1519
1520         ##
1521         # Make sure file is open
1522         ##
1523         if (!defined($self->fh)) { $self->_open(); }
1524
1525         ##
1526         # Request shared lock for reading
1527         ##
1528         $self->lock( LOCK_SH );
1529
1530         my $result = $self->_get_next_key( $prev_md5 );
1531
1532         $self->unlock();
1533
1534         return ($result && $self->root->{filter_fetch_key}) ? $self->root->{filter_fetch_key}->($result) : $result;
1535 }
1536
1537 ##
1538 # The following methods are for arrays only
1539 ##
1540
1541 sub FETCHSIZE {
1542         ##
1543         # Return the length of the array
1544         ##
1545     my $self = _get_self($_[0]);
1546         if ($self->type ne TYPE_ARRAY) {
1547                 return $self->_throw_error("FETCHSIZE method only supported for arrays");
1548         }
1549
1550         my $SAVE_FILTER = $self->root->{filter_fetch_value};
1551         $self->root->{filter_fetch_value} = undef;
1552
1553         my $packed_size = $self->FETCH('length');
1554
1555         $self->root->{filter_fetch_value} = $SAVE_FILTER;
1556
1557         if ($packed_size) { return int(unpack($LONG_PACK, $packed_size)); }
1558         else { return 0; }
1559 }
1560
1561 sub STORESIZE {
1562         ##
1563         # Set the length of the array
1564         ##
1565     my $self = _get_self($_[0]);
1566         if ($self->type ne TYPE_ARRAY) {
1567                 return $self->_throw_error("STORESIZE method only supported for arrays");
1568         }
1569         my $new_length = $_[1];
1570
1571         my $SAVE_FILTER = $self->root->{filter_store_value};
1572         $self->root->{filter_store_value} = undef;
1573
1574         my $result = $self->STORE('length', pack($LONG_PACK, $new_length));
1575
1576         $self->root->{filter_store_value} = $SAVE_FILTER;
1577
1578         return $result;
1579 }
1580
1581 sub POP {
1582         ##
1583         # Remove and return the last element on the array
1584         ##
1585     my $self = _get_self($_[0]);
1586         if ($self->type ne TYPE_ARRAY) {
1587                 return $self->_throw_error("POP method only supported for arrays");
1588         }
1589         my $length = $self->FETCHSIZE();
1590
1591         if ($length) {
1592                 my $content = $self->FETCH( $length - 1 );
1593                 $self->DELETE( $length - 1 );
1594                 return $content;
1595         }
1596         else {
1597                 return;
1598         }
1599 }
1600
1601 sub PUSH {
1602         ##
1603         # Add new element(s) to the end of the array
1604         ##
1605     my $self = _get_self(shift);
1606         if ($self->type ne TYPE_ARRAY) {
1607                 return $self->_throw_error("PUSH method only supported for arrays");
1608         }
1609         my $length = $self->FETCHSIZE();
1610
1611         while (my $content = shift @_) {
1612                 $self->STORE( $length, $content );
1613                 $length++;
1614         }
1615 }
1616
1617 sub SHIFT {
1618         ##
1619         # Remove and return first element on the array.
1620         # Shift over remaining elements to take up space.
1621         ##
1622     my $self = _get_self($_[0]);
1623         if ($self->type ne TYPE_ARRAY) {
1624                 return $self->_throw_error("SHIFT method only supported for arrays");
1625         }
1626         my $length = $self->FETCHSIZE();
1627
1628         if ($length) {
1629                 my $content = $self->FETCH( 0 );
1630
1631                 ##
1632                 # Shift elements over and remove last one.
1633                 ##
1634                 for (my $i = 0; $i < $length - 1; $i++) {
1635                         $self->STORE( $i, $self->FETCH($i + 1) );
1636                 }
1637                 $self->DELETE( $length - 1 );
1638
1639                 return $content;
1640         }
1641         else {
1642                 return;
1643         }
1644 }
1645
1646 sub UNSHIFT {
1647         ##
1648         # Insert new element(s) at beginning of array.
1649         # Shift over other elements to make space.
1650         ##
1651     my $self = _get_self($_[0]);shift @_;
1652         if ($self->type ne TYPE_ARRAY) {
1653                 return $self->_throw_error("UNSHIFT method only supported for arrays");
1654         }
1655         my @new_elements = @_;
1656         my $length = $self->FETCHSIZE();
1657         my $new_size = scalar @new_elements;
1658
1659         if ($length) {
1660                 for (my $i = $length - 1; $i >= 0; $i--) {
1661                         $self->STORE( $i + $new_size, $self->FETCH($i) );
1662                 }
1663         }
1664
1665         for (my $i = 0; $i < $new_size; $i++) {
1666                 $self->STORE( $i, $new_elements[$i] );
1667         }
1668 }
1669
1670 sub SPLICE {
1671         ##
1672         # Splices section of array with optional new section.
1673         # Returns deleted section, or last element deleted in scalar context.
1674         ##
1675     my $self = _get_self($_[0]);shift @_;
1676         if ($self->type ne TYPE_ARRAY) {
1677                 return $self->_throw_error("SPLICE method only supported for arrays");
1678         }
1679         my $length = $self->FETCHSIZE();
1680
1681         ##
1682         # Calculate offset and length of splice
1683         ##
1684         my $offset = shift || 0;
1685         if ($offset < 0) { $offset += $length; }
1686
1687         my $splice_length;
1688         if (scalar @_) { $splice_length = shift; }
1689         else { $splice_length = $length - $offset; }
1690         if ($splice_length < 0) { $splice_length += ($length - $offset); }
1691
1692         ##
1693         # Setup array with new elements, and copy out old elements for return
1694         ##
1695         my @new_elements = @_;
1696         my $new_size = scalar @new_elements;
1697
1698         my @old_elements = ();
1699         for (my $i = $offset; $i < $offset + $splice_length; $i++) {
1700                 push @old_elements, $self->FETCH( $i );
1701         }
1702
1703         ##
1704         # Adjust array length, and shift elements to accomodate new section.
1705         ##
1706     if ( $new_size != $splice_length ) {
1707         if ($new_size > $splice_length) {
1708             for (my $i = $length - 1; $i >= $offset + $splice_length; $i--) {
1709                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1710             }
1711         }
1712         else {
1713             for (my $i = $offset + $splice_length; $i < $length; $i++) {
1714                 $self->STORE( $i + ($new_size - $splice_length), $self->FETCH($i) );
1715             }
1716             for (my $i = 0; $i < $splice_length - $new_size; $i++) {
1717                 $self->DELETE( $length - 1 );
1718                 $length--;
1719             }
1720         }
1721         }
1722
1723         ##
1724         # Insert new elements into array
1725         ##
1726         for (my $i = $offset; $i < $offset + $new_size; $i++) {
1727                 $self->STORE( $i, shift @new_elements );
1728         }
1729
1730         ##
1731         # Return deleted section, or last element in scalar context.
1732         ##
1733         return wantarray ? @old_elements : $old_elements[-1];
1734 }
1735
1736 #XXX We don't need to define it.
1737 #XXX It will be useful, though, when we split out HASH and ARRAY
1738 #sub EXTEND {
1739         ##
1740         # Perl will call EXTEND() when the array is likely to grow.
1741         # We don't care, but include it for compatibility.
1742         ##
1743 #}
1744
1745 ##
1746 # Public method aliases
1747 ##
1748 *put = *store = *STORE;
1749 *get = *fetch = *FETCH;
1750 *delete = *DELETE;
1751 *exists = *EXISTS;
1752 *clear = *CLEAR;
1753 *first_key = *FIRSTKEY;
1754 *next_key = *NEXTKEY;
1755 *length = *FETCHSIZE;
1756 *pop = *POP;
1757 *push = *PUSH;
1758 *shift = *SHIFT;
1759 *unshift = *UNSHIFT;
1760 *splice = *SPLICE;
1761
1762 1;
1763
1764 __END__
1765
1766 =head1 NAME
1767
1768 DBM::Deep - A pure perl multi-level hash/array DBM
1769
1770 =head1 SYNOPSIS
1771
1772   use DBM::Deep;
1773   my $db = DBM::Deep->new( "foo.db" );
1774
1775   $db->{key} = 'value'; # tie() style
1776   print $db->{key};
1777
1778   $db->put('key', 'value'); # OO style
1779   print $db->get('key');
1780
1781   # true multi-level support
1782   $db->{my_complex} = [
1783         'hello', { perl => 'rules' },
1784         42, 99 ];
1785
1786 =head1 DESCRIPTION
1787
1788 A unique flat-file database module, written in pure perl.  True
1789 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1790 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1791 handle millions of keys and unlimited hash levels without significant
1792 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1793 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1794 Mac OS X and Windows.
1795
1796 =head1 INSTALLATION
1797
1798 Hopefully you are using CPAN's excellent Perl module, which will download
1799 and install the module for you.  If not, get the tarball, and run these
1800 commands:
1801
1802         tar zxf DBM-Deep-*
1803         cd DBM-Deep-*
1804         perl Makefile.PL
1805         make
1806         make test
1807         make install
1808
1809 =head1 SETUP
1810
1811 Construction can be done OO-style (which is the recommended way), or using
1812 Perl's tie() function.  Both are examined here.
1813
1814 =head2 OO CONSTRUCTION
1815
1816 The recommended way to construct a DBM::Deep object is to use the new()
1817 method, which gets you a blessed, tied hash or array reference.
1818
1819         my $db = DBM::Deep->new( "foo.db" );
1820
1821 This opens a new database handle, mapped to the file "foo.db".  If this
1822 file does not exist, it will automatically be created.  DB files are
1823 opened in "r+" (read/write) mode, and the type of object returned is a
1824 hash, unless otherwise specified (see L<OPTIONS> below).
1825
1826
1827
1828 You can pass a number of options to the constructor to specify things like
1829 locking, autoflush, etc.  This is done by passing an inline hash:
1830
1831         my $db = DBM::Deep->new(
1832                 file => "foo.db",
1833                 locking => 1,
1834                 autoflush => 1
1835         );
1836
1837 Notice that the filename is now specified I<inside> the hash with
1838 the "file" parameter, as opposed to being the sole argument to the
1839 constructor.  This is required if any options are specified.
1840 See L<OPTIONS> below for the complete list.
1841
1842
1843
1844 You can also start with an array instead of a hash.  For this, you must
1845 specify the C<type> parameter:
1846
1847         my $db = DBM::Deep->new(
1848                 file => "foo.db",
1849                 type => DBM::Deep->TYPE_ARRAY
1850         );
1851
1852 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1853 a new DB file.  If you create a DBM::Deep object with an existing file, the
1854 C<type> will be loaded from the file header, and ignored if it is passed
1855 to the constructor.
1856
1857 =head2 TIE CONSTRUCTION
1858
1859 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1860 tie() function.  This is not ideal, because you get only a basic, tied hash
1861 (or array) which is not blessed, so you can't call any functions on it.
1862
1863         my %hash;
1864         tie %hash, "DBM::Deep", "foo.db";
1865
1866         my @array;
1867         tie @array, "DBM::Deep", "bar.db";
1868
1869 As with the OO constructor, you can replace the DB filename parameter with
1870 a hash containing one or more options (see L<OPTIONS> just below for the
1871 complete list).
1872
1873         tie %hash, "DBM::Deep", {
1874                 file => "foo.db",
1875                 locking => 1,
1876                 autoflush => 1
1877         };
1878
1879 =head2 OPTIONS
1880
1881 There are a number of options that can be passed in when constructing your
1882 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1883
1884 =over
1885
1886 =item * file
1887
1888 Filename of the DB file to link the handle to.  You can pass a full absolute
1889 filesystem path, partial path, or a plain filename if the file is in the
1890 current working directory.  This is a required parameter.
1891
1892 =item * mode
1893
1894 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1895 module.  This is an optional parameter, and defaults to "r+" (read/write).
1896 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1897 created if it doesn't exist.
1898
1899 =item * type
1900
1901 This parameter specifies what type of object to create, a hash or array.  Use
1902 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1903 This only takes effect when beginning a new file.  This is an optional
1904 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1905
1906 =item * locking
1907
1908 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1909 function to lock the database in exclusive mode for writes, and shared mode for
1910 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1911 any child hashes or arrays> that use the same DB file.  This is an optional
1912 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1913
1914 =item * autoflush
1915
1916 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1917 This obviously slows down write operations, but is required if you may have
1918 multiple processes accessing the same DB file (also consider enable I<locking>
1919 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1920 parameter, and defaults to 0 (disabled).
1921
1922 =item * volatile
1923
1924 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1925 STORE() operation.  This is required if an outside force may change the size of
1926 the file between transactions.  Locking also implicitly enables volatile.  This
1927 is useful if you want to use a different locking system or write your own.  Pass
1928 any true value to enable.  This is an optional parameter, and defaults to 0
1929 (disabled).
1930
1931 =item * autobless
1932
1933 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1934 restore them when fetched.  This is an B<experimental> feature, and does have
1935 side-effects.  Basically, when hashes are re-blessed into their original
1936 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1937 able to call any DBM::Deep methods on them.  You have been warned.
1938 This is an optional parameter, and defaults to 0 (disabled).
1939
1940 =item * filter_*
1941
1942 See L<FILTERS> below.
1943
1944 =item * debug
1945
1946 Setting I<debug> mode will make all errors non-fatal, dump them out to
1947 STDERR, and continue on.  This is for debugging purposes only, and probably
1948 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1949
1950 =item * fh
1951
1952 Instead of passing a file path, you can instead pass a handle to an pre-opened
1953 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1954 contains your entire Perl script, as well as the data following the __DATA__
1955 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1956 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1957 in that.
1958
1959 =back
1960
1961 =head1 TIE INTERFACE
1962
1963 With DBM::Deep you can access your databases using Perl's standard hash/array
1964 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1965 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1966 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1967 section above.  This simply tells you how to use DBM::Deep using regular hashes
1968 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1969 work too).  It is entirely up to you how to want to access your databases.
1970
1971 =head2 HASHES
1972
1973 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1974 or even nested hashes (or arrays) using standard Perl syntax:
1975
1976         my $db = DBM::Deep->new( "foo.db" );
1977
1978         $db->{mykey} = "myvalue";
1979         $db->{myhash} = {};
1980         $db->{myhash}->{subkey} = "subvalue";
1981
1982         print $db->{myhash}->{subkey} . "\n";
1983
1984 You can even step through hash keys using the normal Perl C<keys()> function:
1985
1986         foreach my $key (keys %$db) {
1987                 print "$key: " . $db->{$key} . "\n";
1988         }
1989
1990 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1991 pushes them onto an array, all before the loop even begins.  If you have an
1992 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1993 Perl's C<each()> function, which pulls keys/values one at a time, using very
1994 little memory:
1995
1996         while (my ($key, $value) = each %$db) {
1997                 print "$key: $value\n";
1998         }
1999
2000 Please note that when using C<each()>, you should always pass a direct
2001 hash reference, not a lookup.  Meaning, you should B<never> do this:
2002
2003         # NEVER DO THIS
2004         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
2005
2006 This causes an infinite loop, because for each iteration, Perl is calling
2007 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
2008 it effectively keeps returning the first key over and over again. Instead,
2009 assign a temporary variable to C<$db->{foo}>, then pass that to each().
2010
2011 =head2 ARRAYS
2012
2013 As with hashes, you can treat any DBM::Deep object like a normal Perl array
2014 reference.  This includes inserting, removing and manipulating elements,
2015 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
2016 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
2017 or simply be a nested array reference inside a hash.  Example:
2018
2019         my $db = DBM::Deep->new(
2020                 file => "foo-array.db",
2021                 type => DBM::Deep->TYPE_ARRAY
2022         );
2023
2024         $db->[0] = "foo";
2025         push @$db, "bar", "baz";
2026         unshift @$db, "bah";
2027
2028         my $last_elem = pop @$db; # baz
2029         my $first_elem = shift @$db; # bah
2030         my $second_elem = $db->[1]; # bar
2031
2032         my $num_elements = scalar @$db;
2033
2034 =head1 OO INTERFACE
2035
2036 In addition to the I<tie()> interface, you can also use a standard OO interface
2037 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
2038 array) has its own methods, but both types share the following common methods:
2039 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
2040
2041 =over
2042
2043 =item * put()
2044
2045 Stores a new hash key/value pair, or sets an array element value.  Takes two
2046 arguments, the hash key or array index, and the new value.  The value can be
2047 a scalar, hash ref or array ref.  Returns true on success, false on failure.
2048
2049         $db->put("foo", "bar"); # for hashes
2050         $db->put(1, "bar"); # for arrays
2051
2052 =item * get()
2053
2054 Fetches the value of a hash key or array element.  Takes one argument: the hash
2055 key or array index.  Returns a scalar, hash ref or array ref, depending on the
2056 data type stored.
2057
2058         my $value = $db->get("foo"); # for hashes
2059         my $value = $db->get(1); # for arrays
2060
2061 =item * exists()
2062
2063 Checks if a hash key or array index exists.  Takes one argument: the hash key
2064 or array index.  Returns true if it exists, false if not.
2065
2066         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
2067         if ($db->exists(1)) { print "yay!\n"; } # for arrays
2068
2069 =item * delete()
2070
2071 Deletes one hash key/value pair or array element.  Takes one argument: the hash
2072 key or array index.  Returns true on success, false if not found.  For arrays,
2073 the remaining elements located after the deleted element are NOT moved over.
2074 The deleted element is essentially just undefined, which is exactly how Perl's
2075 internal arrays work.  Please note that the space occupied by the deleted
2076 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
2077 below for details and workarounds.
2078
2079         $db->delete("foo"); # for hashes
2080         $db->delete(1); # for arrays
2081
2082 =item * clear()
2083
2084 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
2085 value.  Please note that the space occupied by the deleted keys/values or
2086 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
2087 details and workarounds.
2088
2089         $db->clear(); # hashes or arrays
2090
2091 =back
2092
2093 =head2 HASHES
2094
2095 For hashes, DBM::Deep supports all the common methods described above, and the
2096 following additional methods: C<first_key()> and C<next_key()>.
2097
2098 =over
2099
2100 =item * first_key()
2101
2102 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
2103 fetched in an undefined order (which appears random).  Takes no arguments,
2104 returns the key as a scalar value.
2105
2106         my $key = $db->first_key();
2107
2108 =item * next_key()
2109
2110 Returns the "next" key in the hash, given the previous one as the sole argument.
2111 Returns undef if there are no more keys to be fetched.
2112
2113         $key = $db->next_key($key);
2114
2115 =back
2116
2117 Here are some examples of using hashes:
2118
2119         my $db = DBM::Deep->new( "foo.db" );
2120
2121         $db->put("foo", "bar");
2122         print "foo: " . $db->get("foo") . "\n";
2123
2124         $db->put("baz", {}); # new child hash ref
2125         $db->get("baz")->put("buz", "biz");
2126         print "buz: " . $db->get("baz")->get("buz") . "\n";
2127
2128         my $key = $db->first_key();
2129         while ($key) {
2130                 print "$key: " . $db->get($key) . "\n";
2131                 $key = $db->next_key($key);
2132         }
2133
2134         if ($db->exists("foo")) { $db->delete("foo"); }
2135
2136 =head2 ARRAYS
2137
2138 For arrays, DBM::Deep supports all the common methods described above, and the
2139 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
2140 C<unshift()> and C<splice()>.
2141
2142 =over
2143
2144 =item * length()
2145
2146 Returns the number of elements in the array.  Takes no arguments.
2147
2148         my $len = $db->length();
2149
2150 =item * push()
2151
2152 Adds one or more elements onto the end of the array.  Accepts scalars, hash
2153 refs or array refs.  No return value.
2154
2155         $db->push("foo", "bar", {});
2156
2157 =item * pop()
2158
2159 Fetches the last element in the array, and deletes it.  Takes no arguments.
2160 Returns undef if array is empty.  Returns the element value.
2161
2162         my $elem = $db->pop();
2163
2164 =item * shift()
2165
2166 Fetches the first element in the array, deletes it, then shifts all the
2167 remaining elements over to take up the space.  Returns the element value.  This
2168 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
2169 details.
2170
2171         my $elem = $db->shift();
2172
2173 =item * unshift()
2174
2175 Inserts one or more elements onto the beginning of the array, shifting all
2176 existing elements over to make room.  Accepts scalars, hash refs or array refs.
2177 No return value.  This method is not recommended with large arrays -- see
2178 <LARGE ARRAYS> below for details.
2179
2180         $db->unshift("foo", "bar", {});
2181
2182 =item * splice()
2183
2184 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
2185 -f splice> for usage -- it is too complicated to document here.  This method is
2186 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
2187
2188 =back
2189
2190 Here are some examples of using arrays:
2191
2192         my $db = DBM::Deep->new(
2193                 file => "foo.db",
2194                 type => DBM::Deep->TYPE_ARRAY
2195         );
2196
2197         $db->push("bar", "baz");
2198         $db->unshift("foo");
2199         $db->put(3, "buz");
2200
2201         my $len = $db->length();
2202         print "length: $len\n"; # 4
2203
2204         for (my $k=0; $k<$len; $k++) {
2205                 print "$k: " . $db->get($k) . "\n";
2206         }
2207
2208         $db->splice(1, 2, "biz", "baf");
2209
2210         while (my $elem = shift @$db) {
2211                 print "shifted: $elem\n";
2212         }
2213
2214 =head1 LOCKING
2215
2216 Enable automatic file locking by passing a true value to the C<locking>
2217 parameter when constructing your DBM::Deep object (see L<SETUP> above).
2218
2219         my $db = DBM::Deep->new(
2220                 file => "foo.db",
2221                 locking => 1
2222         );
2223
2224 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
2225 mode for writes, and shared mode for reads.  This is required if you have
2226 multiple processes accessing the same database file, to avoid file corruption.
2227 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
2228 NFS> below for more.
2229
2230 =head2 EXPLICIT LOCKING
2231
2232 You can explicitly lock a database, so it remains locked for multiple
2233 transactions.  This is done by calling the C<lock()> method, and passing an
2234 optional lock mode argument (defaults to exclusive mode).  This is particularly
2235 useful for things like counters, where the current value needs to be fetched,
2236 then incremented, then stored again.
2237
2238         $db->lock();
2239         my $counter = $db->get("counter");
2240         $counter++;
2241         $db->put("counter", $counter);
2242         $db->unlock();
2243
2244         # or...
2245
2246         $db->lock();
2247         $db->{counter}++;
2248         $db->unlock();
2249
2250 You can pass C<lock()> an optional argument, which specifies which mode to use
2251 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2252 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2253 same as the constants defined in Perl's C<Fcntl> module.
2254
2255         $db->lock( DBM::Deep->LOCK_SH );
2256         # something here
2257         $db->unlock();
2258
2259 If you want to implement your own file locking scheme, be sure to create your
2260 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2261 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2262 below for more.
2263
2264 =head1 IMPORTING/EXPORTING
2265
2266 You can import existing complex structures by calling the C<import()> method,
2267 and export an entire database into an in-memory structure using the C<export()>
2268 method.  Both are examined here.
2269
2270 =head2 IMPORTING
2271
2272 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2273 walking the structure and adding keys/elements to the database as you go,
2274 simply pass a reference to the C<import()> method.  This recursively adds
2275 everything to an existing DBM::Deep object for you.  Here is an example:
2276
2277         my $struct = {
2278                 key1 => "value1",
2279                 key2 => "value2",
2280                 array1 => [ "elem0", "elem1", "elem2" ],
2281                 hash1 => {
2282                         subkey1 => "subvalue1",
2283                         subkey2 => "subvalue2"
2284                 }
2285         };
2286
2287         my $db = DBM::Deep->new( "foo.db" );
2288         $db->import( $struct );
2289
2290         print $db->{key1} . "\n"; # prints "value1"
2291
2292 This recursively imports the entire C<$struct> object into C<$db>, including
2293 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2294 keys are merged with the existing ones, replacing if they already exist.
2295 The C<import()> method can be called on any database level (not just the base
2296 level), and works with both hash and array DB types.
2297
2298
2299
2300 B<Note:> Make sure your existing structure has no circular references in it.
2301 These will cause an infinite loop when importing.
2302
2303 =head2 EXPORTING
2304
2305 Calling the C<export()> method on an existing DBM::Deep object will return
2306 a reference to a new in-memory copy of the database.  The export is done
2307 recursively, so all nested hashes/arrays are all exported to standard Perl
2308 objects.  Here is an example:
2309
2310         my $db = DBM::Deep->new( "foo.db" );
2311
2312         $db->{key1} = "value1";
2313         $db->{key2} = "value2";
2314         $db->{hash1} = {};
2315         $db->{hash1}->{subkey1} = "subvalue1";
2316         $db->{hash1}->{subkey2} = "subvalue2";
2317
2318         my $struct = $db->export();
2319
2320         print $struct->{key1} . "\n"; # prints "value1"
2321
2322 This makes a complete copy of the database in memory, and returns a reference
2323 to it.  The C<export()> method can be called on any database level (not just
2324 the base level), and works with both hash and array DB types.  Be careful of
2325 large databases -- you can store a lot more data in a DBM::Deep object than an
2326 in-memory Perl structure.
2327
2328
2329
2330 B<Note:> Make sure your database has no circular references in it.
2331 These will cause an infinite loop when exporting.
2332
2333 =head1 FILTERS
2334
2335 DBM::Deep has a number of hooks where you can specify your own Perl function
2336 to perform filtering on incoming or outgoing data.  This is a perfect
2337 way to extend the engine, and implement things like real-time compression or
2338 encryption.  Filtering applies to the base DB level, and all child hashes /
2339 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2340 constructed, or by calling the C<set_filter()> method at any time.  There are
2341 four available filter hooks, described below:
2342
2343 =over
2344
2345 =item * filter_store_key
2346
2347 This filter is called whenever a hash key is stored.  It
2348 is passed the incoming key, and expected to return a transformed key.
2349
2350 =item * filter_store_value
2351
2352 This filter is called whenever a hash key or array element is stored.  It
2353 is passed the incoming value, and expected to return a transformed value.
2354
2355 =item * filter_fetch_key
2356
2357 This filter is called whenever a hash key is fetched (i.e. via
2358 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2359 and expected to return the plain key.
2360
2361 =item * filter_fetch_value
2362
2363 This filter is called whenever a hash key or array element is fetched.
2364 It is passed the transformed value, and expected to return the plain value.
2365
2366 =back
2367
2368 Here are the two ways to setup a filter hook:
2369
2370         my $db = DBM::Deep->new(
2371                 file => "foo.db",
2372                 filter_store_value => \&my_filter_store,
2373                 filter_fetch_value => \&my_filter_fetch
2374         );
2375
2376         # or...
2377
2378         $db->set_filter( "filter_store_value", \&my_filter_store );
2379         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2380
2381 Your filter function will be called only when dealing with SCALAR keys or
2382 values.  When nested hashes and arrays are being stored/fetched, filtering
2383 is bypassed.  Filters are called as static functions, passed a single SCALAR
2384 argument, and expected to return a single SCALAR value.  If you want to
2385 remove a filter, set the function reference to C<undef>:
2386
2387         $db->set_filter( "filter_store_value", undef );
2388
2389 =head2 REAL-TIME ENCRYPTION EXAMPLE
2390
2391 Here is a working example that uses the I<Crypt::Blowfish> module to
2392 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2393 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2394 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2395
2396         use DBM::Deep;
2397         use Crypt::Blowfish;
2398         use Crypt::CBC;
2399
2400         my $cipher = Crypt::CBC->new({
2401                 'key'             => 'my secret key',
2402                 'cipher'          => 'Blowfish',
2403                 'iv'              => '$KJh#(}q',
2404                 'regenerate_key'  => 0,
2405                 'padding'         => 'space',
2406                 'prepend_iv'      => 0
2407         });
2408
2409         my $db = DBM::Deep->new(
2410                 file => "foo-encrypt.db",
2411                 filter_store_key => \&my_encrypt,
2412                 filter_store_value => \&my_encrypt,
2413                 filter_fetch_key => \&my_decrypt,
2414                 filter_fetch_value => \&my_decrypt,
2415         );
2416
2417         $db->{key1} = "value1";
2418         $db->{key2} = "value2";
2419         print "key1: " . $db->{key1} . "\n";
2420         print "key2: " . $db->{key2} . "\n";
2421
2422         undef $db;
2423         exit;
2424
2425         sub my_encrypt {
2426                 return $cipher->encrypt( $_[0] );
2427         }
2428         sub my_decrypt {
2429                 return $cipher->decrypt( $_[0] );
2430         }
2431
2432 =head2 REAL-TIME COMPRESSION EXAMPLE
2433
2434 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2435 compression / decompression of keys & values with DBM::Deep Filters.
2436 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2437 more on I<Compress::Zlib>.
2438
2439         use DBM::Deep;
2440         use Compress::Zlib;
2441
2442         my $db = DBM::Deep->new(
2443                 file => "foo-compress.db",
2444                 filter_store_key => \&my_compress,
2445                 filter_store_value => \&my_compress,
2446                 filter_fetch_key => \&my_decompress,
2447                 filter_fetch_value => \&my_decompress,
2448         );
2449
2450         $db->{key1} = "value1";
2451         $db->{key2} = "value2";
2452         print "key1: " . $db->{key1} . "\n";
2453         print "key2: " . $db->{key2} . "\n";
2454
2455         undef $db;
2456         exit;
2457
2458         sub my_compress {
2459                 return Compress::Zlib::memGzip( $_[0] ) ;
2460         }
2461         sub my_decompress {
2462                 return Compress::Zlib::memGunzip( $_[0] ) ;
2463         }
2464
2465 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2466 actually numerical index numbers, and are not filtered.
2467
2468 =head1 ERROR HANDLING
2469
2470 Most DBM::Deep methods return a true value for success, and call die() on
2471 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2472 actual error message is stored in an internal scalar, which can be fetched by
2473 calling the C<error()> method.
2474
2475         my $db = DBM::Deep->new( "foo.db" ); # create hash
2476         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2477
2478         print $db->error(); # prints error message
2479
2480 You can then call C<clear_error()> to clear the current error state.
2481
2482         $db->clear_error();
2483
2484 If you set the C<debug> option to true when creating your DBM::Deep object,
2485 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2486 for debugging purposes.
2487
2488 =head1 LARGEFILE SUPPORT
2489
2490 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2491 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2492 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2493 by calling the static C<set_pack()> method before you do anything else.
2494
2495         DBM::Deep::set_pack(8, 'Q');
2496
2497 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2498 instead of 32-bit longs.  After setting these values your DB files have a
2499 theoretical maximum size of 16 XB (exabytes).
2500
2501
2502
2503 B<Note:> Changing these values will B<NOT> work for existing database files.
2504 Only change this for new files, and make sure it stays set consistently
2505 throughout the file's life.  If you do set these values, you can no longer
2506 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2507 back to 32-bit mode.
2508
2509
2510
2511 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2512 only a 32-bit Perl.  However, I have received user reports that this does
2513 indeed work!
2514
2515 =head1 LOW-LEVEL ACCESS
2516
2517 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2518 you can call the C<fh()> method, which returns the handle:
2519
2520         my $fh = $db->fh();
2521
2522 This method can be called on the root level of the datbase, or any child
2523 hashes or arrays.  All levels share a I<root> structure, which contains things
2524 like the FileHandle, a reference counter, and all your options you specified
2525 when you created the object.  You can get access to this root structure by
2526 calling the C<root()> method.
2527
2528         my $root = $db->root();
2529
2530 This is useful for changing options after the object has already been created,
2531 such as enabling/disabling locking, volatile or debug modes.  You can also
2532 store your own temporary user data in this structure (be wary of name
2533 collision), which is then accessible from any child hash or array.
2534
2535 =head1 CUSTOM DIGEST ALGORITHM
2536
2537 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2538 keys.  However you can override this, and use another algorithm (such as SHA-256)
2539 or even write your own.  But please note that DBM::Deep currently expects zero
2540 collisions, so your algorithm has to be I<perfect>, so to speak.
2541 Collision detection may be introduced in a later version.
2542
2543
2544
2545 You can specify a custom digest algorithm by calling the static C<set_digest()>
2546 function, passing a reference to a subroutine, and the length of the algorithm's
2547 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2548 objects.  Here is a working example that uses a 256-bit hash from the
2549 I<Digest::SHA256> module.  Please see
2550 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2551
2552         use DBM::Deep;
2553         use Digest::SHA256;
2554
2555         my $context = Digest::SHA256::new(256);
2556
2557         DBM::Deep::set_digest( \&my_digest, 32 );
2558
2559         my $db = DBM::Deep->new( "foo-sha.db" );
2560
2561         $db->{key1} = "value1";
2562         $db->{key2} = "value2";
2563         print "key1: " . $db->{key1} . "\n";
2564         print "key2: " . $db->{key2} . "\n";
2565
2566         undef $db;
2567         exit;
2568
2569         sub my_digest {
2570                 return substr( $context->hash($_[0]), 0, 32 );
2571         }
2572
2573 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2574 of bytes you specify in the C<set_digest()> function (in this case 32).
2575
2576 =head1 CIRCULAR REFERENCES
2577
2578 DBM::Deep has B<experimental> support for circular references.  Meaning you
2579 can have a nested hash key or array element that points to a parent object.
2580 This relationship is stored in the DB file, and is preserved between sessions.
2581 Here is an example:
2582
2583         my $db = DBM::Deep->new( "foo.db" );
2584
2585         $db->{foo} = "bar";
2586         $db->{circle} = $db; # ref to self
2587
2588         print $db->{foo} . "\n"; # prints "foo"
2589         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2590
2591 One catch is, passing the object to a function that recursively walks the
2592 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2593 C<export()> methods) will result in an infinite loop.  The other catch is,
2594 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2595 or C<next_key()> methods), you will get the I<target object's key>, not the
2596 ref's key.  This gets even more interesting with the above example, where
2597 the I<circle> key points to the base DB object, which technically doesn't
2598 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2599 special case.
2600
2601 =head1 CAVEATS / ISSUES / BUGS
2602
2603 This section describes all the known issues with DBM::Deep.  It you have found
2604 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2605
2606 =head2 UNUSED SPACE RECOVERY
2607
2608 One major caveat with DBM::Deep is that space occupied by existing keys and
2609 values is not recovered when they are deleted.  Meaning if you keep deleting
2610 and adding new keys, your file will continuously grow.  I am working on this,
2611 but in the meantime you can call the built-in C<optimize()> method from time to
2612 time (perhaps in a crontab or something) to recover all your unused space.
2613
2614         $db->optimize(); # returns true on success
2615
2616 This rebuilds the ENTIRE database into a new file, then moves it on top of
2617 the original.  The new file will have no unused space, thus it will take up as
2618 little disk space as possible.  Please note that this operation can take
2619 a long time for large files, and you need enough disk space to temporarily hold
2620 2 copies of your DB file.  The temporary file is created in the same directory
2621 as the original, named with a ".tmp" extension, and is deleted when the
2622 operation completes.  Oh, and if locking is enabled, the DB is automatically
2623 locked for the entire duration of the copy.
2624
2625
2626
2627 B<WARNING:> Only call optimize() on the top-level node of the database, and
2628 make sure there are no child references lying around.  DBM::Deep keeps a reference
2629 counter, and if it is greater than 1, optimize() will abort and return undef.
2630
2631 =head2 AUTOVIVIFICATION
2632
2633 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2634 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2635 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2636 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2637 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2638 this does not work:
2639
2640         $db->{foo}->{bar} = "hello";
2641
2642 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2643 being an empty hash.  Try this instead, which works fine:
2644
2645         $db->{foo} = { bar => "hello" };
2646
2647 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2648 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2649 Probably a bug in Perl.
2650
2651 =head2 FILE CORRUPTION
2652
2653 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2654 for a 32-bit signature when opened, but other corruption in files can cause
2655 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2656 stuck in an infinite loop depending on the level of corruption.  File write
2657 operations are not checked for failure (for speed), so if you happen to run
2658 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2659 be addressed in a later version of DBM::Deep.
2660
2661 =head2 DB OVER NFS
2662
2663 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2664 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2665 about setting up your NFS server with a locking daemon, then using lockf() to
2666 lock your files, but your milage may vary there as well.  From what I
2667 understand, there is no real way to do it.  However, if you need access to the
2668 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2669 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2670
2671 =head2 COPYING OBJECTS
2672
2673 Beware of copying tied objects in Perl.  Very strange things can happen.
2674 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2675 returns a new, blessed, tied hash or array to the same level in the DB.
2676
2677         my $copy = $db->clone();
2678
2679 =head2 LARGE ARRAYS
2680
2681 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2682 These functions cause every element in the array to move, which can be murder
2683 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2684 a different location.  This may be addressed in a later version.
2685
2686 =head1 PERFORMANCE
2687
2688 This section discusses DBM::Deep's speed and memory usage.
2689
2690 =head2 SPEED
2691
2692 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2693 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2694 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2695 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2696 with huge databases.  Here is some test data:
2697
2698         Adding 1,000,000 keys to new DB file...
2699
2700         At 100 keys, avg. speed is 2,703 keys/sec
2701         At 200 keys, avg. speed is 2,642 keys/sec
2702         At 300 keys, avg. speed is 2,598 keys/sec
2703         At 400 keys, avg. speed is 2,578 keys/sec
2704         At 500 keys, avg. speed is 2,722 keys/sec
2705         At 600 keys, avg. speed is 2,628 keys/sec
2706         At 700 keys, avg. speed is 2,700 keys/sec
2707         At 800 keys, avg. speed is 2,607 keys/sec
2708         At 900 keys, avg. speed is 2,190 keys/sec
2709         At 1,000 keys, avg. speed is 2,570 keys/sec
2710         At 2,000 keys, avg. speed is 2,417 keys/sec
2711         At 3,000 keys, avg. speed is 1,982 keys/sec
2712         At 4,000 keys, avg. speed is 1,568 keys/sec
2713         At 5,000 keys, avg. speed is 1,533 keys/sec
2714         At 6,000 keys, avg. speed is 1,787 keys/sec
2715         At 7,000 keys, avg. speed is 1,977 keys/sec
2716         At 8,000 keys, avg. speed is 2,028 keys/sec
2717         At 9,000 keys, avg. speed is 2,077 keys/sec
2718         At 10,000 keys, avg. speed is 2,031 keys/sec
2719         At 20,000 keys, avg. speed is 1,970 keys/sec
2720         At 30,000 keys, avg. speed is 2,050 keys/sec
2721         At 40,000 keys, avg. speed is 2,073 keys/sec
2722         At 50,000 keys, avg. speed is 1,973 keys/sec
2723         At 60,000 keys, avg. speed is 1,914 keys/sec
2724         At 70,000 keys, avg. speed is 2,091 keys/sec
2725         At 80,000 keys, avg. speed is 2,103 keys/sec
2726         At 90,000 keys, avg. speed is 1,886 keys/sec
2727         At 100,000 keys, avg. speed is 1,970 keys/sec
2728         At 200,000 keys, avg. speed is 2,053 keys/sec
2729         At 300,000 keys, avg. speed is 1,697 keys/sec
2730         At 400,000 keys, avg. speed is 1,838 keys/sec
2731         At 500,000 keys, avg. speed is 1,941 keys/sec
2732         At 600,000 keys, avg. speed is 1,930 keys/sec
2733         At 700,000 keys, avg. speed is 1,735 keys/sec
2734         At 800,000 keys, avg. speed is 1,795 keys/sec
2735         At 900,000 keys, avg. speed is 1,221 keys/sec
2736         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2737
2738 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2739 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2740 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2741 Run time was 12 min 3 sec.
2742
2743 =head2 MEMORY USAGE
2744
2745 One of the great things about DBM::Deep is that it uses very little memory.
2746 Even with huge databases (1,000,000+ keys) you will not see much increased
2747 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2748 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2749 database handle:
2750
2751           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2752         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2753
2754 Basically the process is taking 2,716K of memory.  And here is the same
2755 process after storing and fetching 1,000,000 keys:
2756
2757           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2758         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2759
2760 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2761 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2762
2763 =head1 DB FILE FORMAT
2764
2765 In case you were interested in the underlying DB file format, it is documented
2766 here in this section.  You don't need to know this to use the module, it's just
2767 included for reference.
2768
2769 =head2 SIGNATURE
2770
2771 DBM::Deep files always start with a 32-bit signature to identify the file type.
2772 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2773 checked when the file is opened.
2774
2775 =head2 TAG
2776
2777 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2778 has a standard header containing the type of data, the length of data, and then
2779 the data itself.  The type is a single character (1 byte), the length is a
2780 32-bit unsigned long in network byte order, and the data is, well, the data.
2781 Here is how it unfolds:
2782
2783 =head2 MASTER INDEX
2784
2785 Immediately after the 32-bit file signature is the I<Master Index> record.
2786 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2787 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2788 depending on how the DBM::Deep object was constructed.
2789
2790
2791
2792 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2793 number).  The first 8-bit char of the MD5 signature is the offset into the
2794 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2795 index element is a file offset of the next tag for the key/element in question,
2796 which is usually a I<Bucket List> tag (see below).
2797
2798
2799
2800 The next tag I<could> be another index, depending on how many keys/elements
2801 exist.  See L<RE-INDEXING> below for details.
2802
2803 =head2 BUCKET LIST
2804
2805 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2806 file offsets to where the actual data is stored.  It starts with a standard
2807 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2808 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2809 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2810 When the list fills up, a I<Re-Index> operation is performed (See
2811 L<RE-INDEXING> below).
2812
2813 =head2 BUCKET
2814
2815 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2816 index/value pair (in array mode).  It starts with a standard tag header with
2817 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2818 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2819 header.  The size reported in the tag header is only for the value, but then,
2820 just after the value is another size (32-bit unsigned long) and then the plain
2821 key itself.  Since the value is likely to be fetched more often than the plain
2822 key, I figured it would be I<slightly> faster to store the value first.
2823
2824
2825
2826 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2827 record for the nested structure, where the process begins all over again.
2828
2829 =head2 RE-INDEXING
2830
2831 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2832 exhausted.  Then, when another key/element comes in, the list is converted to a
2833 new index record.  However, this index will look at the next char in the MD5
2834 hash, and arrange new Bucket List pointers accordingly.  This process is called
2835 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2836 17 (16 + new one) keys/elements are removed from the old Bucket List and
2837 inserted into the new index.  Several new Bucket Lists are created in the
2838 process, as a new MD5 char from the key is being examined (it is unlikely that
2839 the keys will all share the same next char of their MD5s).
2840
2841
2842
2843 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2844 when the Bucket Lists will turn into indexes, but the first round tends to
2845 happen right around 4,000 keys.  You will see a I<slight> decrease in
2846 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2847 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2848 right around 900,000 keys.  This process can continue nearly indefinitely --
2849 right up until the point the I<MD5> signatures start colliding with each other,
2850 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2851 getting struck by lightning while you are walking to cash in your tickets.
2852 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2853 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2854 this is 340 unodecillion, but don't quote me).
2855
2856 =head2 STORING
2857
2858 When a new key/element is stored, the key (or index number) is first ran through
2859 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2860 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2861 for the first char of the signature (in this case I<b>).  If it does not exist,
2862 a new I<Bucket List> is created for our key (and the next 15 future keys that
2863 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2864 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2865 this point, unless we are replacing an existing I<Bucket>), where the actual
2866 data will be stored.
2867
2868 =head2 FETCHING
2869
2870 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2871 (or index number), then walking along the indexes.  If there are enough
2872 keys/elements in this DB level, there might be nested indexes, each linked to
2873 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2874 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2875 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2876 plain key are stored.
2877
2878
2879
2880 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2881 methods.  In this process the indexes are walked systematically, and each key
2882 fetched in increasing MD5 order (which is why it appears random).   Once the
2883 I<Bucket> is found, the value is skipped the plain key returned instead.
2884 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2885 alphabetically sorted.  This only happens on an index-level -- as soon as the
2886 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2887 so it's pretty much undefined how the keys will come out -- just like Perl's
2888 built-in hashes.
2889
2890 =head1 CODE COVERAGE
2891
2892 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2893 module's test suite.
2894
2895   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2896   File                           stmt   bran   cond    sub    pod   time  total
2897   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2898   blib/lib/DBM/Deep.pm           94.9   84.5   77.8  100.0   11.1  100.0   89.7
2899   Total                          94.9   84.5   77.8  100.0   11.1  100.0   89.7
2900   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2901
2902 =head1 AUTHOR
2903
2904 Joseph Huckaby, L<jhuckaby@cpan.org>
2905
2906 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2907
2908 =head1 SEE ALSO
2909
2910 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2911 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2912
2913 =head1 LICENSE
2914
2915 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2916 This is free software, you may use it and distribute it under the
2917 same terms as Perl itself.
2918
2919 =cut