lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw/:flock/;
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37 use vars qw/$VERSION/;
  38
  39 $VERSION = "0.96";
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE  () { 'DPDB' }
  91 sub SIG_HASH  () { 'H' }
  92 sub SIG_ARRAY () { 'A' }
  93 sub SIG_NULL  () { 'N' }
  94 sub SIG_DATA  () { 'D' }
  95 sub SIG_INDEX () { 'I' }
  96 sub SIG_BLIST () { 'B' }
  97 sub SIG_SIZE  () {  1  }
  98
  99 ##
 100 # Setup constants for users to pass to new()
 101 ##
 102 sub TYPE_HASH  () { return SIG_HASH; }
 103 sub TYPE_ARRAY () { return SIG_ARRAY; }
 104
 105 sub new {
 106         ##
 107         # Class constructor method for Perl OO interface.
 108         # Calls tie() and returns blessed reference to tied hash or array,
 109         # providing a hybrid OO/tie interface.
 110         ##
 111         my $class = shift;
 112         my $args;
 113         if (scalar(@_) > 1) { $args = {@_}; }
 114         else { $args = { file => shift }; }
 115
 116         ##
 117         # Check if we want a tied hash or array.
 118         ##
 119         my $self;
 120         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 121         $class = 'DBM::Deep::Array';
 122         require DBM::Deep::Array;
 123                 tie @$self, $class, %$args;
 124         }
 125         else {
 126         $class = 'DBM::Deep::Hash';
 127         require DBM::Deep::Hash;
 128                 tie %$self, $class, %$args;
 129         }
 130
 131         return bless $self, $class;
 132 }
 133
 134 {
 135     my @outer_params = qw( type base_offset );
 136     sub _init {
 137         ##
 138         # Setup $self and bless into this class.
 139         ##
 140         my $class = shift;
 141         my $args = shift;
 142
 143         my $self = {
 144             type => TYPE_HASH,
 145             base_offset => length(SIG_FILE),
 146         };
 147
 148         bless $self, $class;
 149
 150         foreach my $outer_parm ( @outer_params ) {
 151             next unless exists $args->{$outer_parm};
 152             $self->{$outer_parm} = delete $args->{$outer_parm}
 153         }
 154
 155         $self->{root} = exists $args->{root}
 156             ? $args->{root}
 157             : DBM::Deep::_::Root->new( $args );
 158
 159         if (!defined($self->fh)) { $self->_open(); }
 160
 161         return $self;
 162     }
 163 }
 164
 165 sub _get_self {
 166     tied( %{$_[0]} ) || $_[0]
 167 }
 168
 169 sub TIEHASH {
 170     shift;
 171     require DBM::Deep::Hash;
 172     return DBM::Deep::Hash->TIEHASH( @_ );
 173 }
 174
 175 sub TIEARRAY {
 176     shift;
 177     require DBM::Deep::Array;
 178     return DBM::Deep::Array->TIEARRAY( @_ );
 179 }
 180
 181 #XXX Unneeded now ...
 182 #sub DESTROY {
 183 #}
 184
 185 my %translate_mode = (
 186     'r' => '<',
 187     'r+' => '+<',
 188     'w' => '>',
 189     'w+' => '+>',
 190     'a' => '>>',
 191     'a+' => '+>>',
 192 );
 193 sub _open {
 194         ##
 195         # Open a FileHandle to the database, create if nonexistent.
 196         # Make sure file signature matches DeepDB spec.
 197         ##
 198     my $self = _get_self($_[0]);
 199
 200         if (defined($self->fh)) { $self->_close(); }
 201
 202     eval {
 203         my $filename = $self->root->{file};
 204         my $mode = $translate_mode{ $self->root->{mode} };
 205
 206         if (!(-e $filename) && $mode eq '+<') {
 207             open( FH, '>', $filename );
 208             close FH;
 209         }
 210
 211         my $fh;
 212         open( $fh, $mode, $filename )
 213             or $fh = undef;
 214         $self->root->{fh} = $fh;
 215     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 216         if (! defined($self->fh)) {
 217                 return $self->_throw_error("Cannot open file: " . $self->root->{file} . ": $!");
 218         }
 219
 220     my $fh = $self->fh;
 221
 222     #XXX Can we remove this by using the right sysopen() flags?
 223     binmode $fh; # for win32
 224
 225     if ($self->root->{autoflush}) {
 226         my $old = select $fh;
 227         $|=1;
 228         select $old;
 229     }
 230
 231     my $signature;
 232     seek($fh, 0, 0);
 233     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 234
 235     ##
 236     # File is empty -- write signature and master index
 237     ##
 238     if (!$bytes_read) {
 239         seek($fh, 0, 0);
 240         print($fh SIG_FILE);
 241         $self->root->{end} = length(SIG_FILE);
 242         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 243
 244         my $plain_key = "[base]";
 245         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 246         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 247
 248         # Flush the filehandle
 249         my $old_fh = select $fh;
 250         my $old_af = $|;
 251         $| = 1;
 252         $| = $old_af;
 253         select $old_fh;
 254
 255         return 1;
 256     }
 257
 258     ##
 259     # Check signature was valid
 260     ##
 261     unless ($signature eq SIG_FILE) {
 262         $self->_close();
 263         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 264     }
 265
 266     $self->root->{end} = (stat($fh))[7];
 267
 268     ##
 269     # Get our type from master index signature
 270     ##
 271     my $tag = $self->_load_tag($self->base_offset);
 272
 273 #XXX We probably also want to store the hash algorithm name and not assume anything
 274
 275     if (!$tag) {
 276         return $self->_throw_error("Corrupted file, no master index record");
 277     }
 278     if ($self->{type} ne $tag->{signature}) {
 279         return $self->_throw_error("File type mismatch");
 280     }
 281
 282     return 1;
 283 }
 284
 285 sub _close {
 286         ##
 287         # Close database FileHandle
 288         ##
 289     my $self = _get_self($_[0]);
 290     close $self->root->{fh};
 291 }
 292
 293 sub _create_tag {
 294         ##
 295         # Given offset, signature and content, create tag and write to disk
 296         ##
 297         my ($self, $offset, $sig, $content) = @_;
 298         my $size = length($content);
 299
 300     my $fh = $self->fh;
 301
 302         seek($fh, $offset, 0);
 303         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 304
 305         if ($offset == $self->root->{end}) {
 306                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 307         }
 308
 309         return {
 310                 signature => $sig,
 311                 size => $size,
 312                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 313                 content => $content
 314         };
 315 }
 316
 317 sub _load_tag {
 318         ##
 319         # Given offset, load single tag and return signature, size and data
 320         ##
 321         my $self = shift;
 322         my $offset = shift;
 323
 324     my $fh = $self->fh;
 325
 326         seek($fh, $offset, 0);
 327         if (eof $fh) { return undef; }
 328
 329         my $sig;
 330         read( $fh, $sig, SIG_SIZE);
 331
 332         my $size;
 333         read( $fh, $size, $DATA_LENGTH_SIZE);
 334         $size = unpack($DATA_LENGTH_PACK, $size);
 335
 336         my $buffer;
 337         read( $fh, $buffer, $size);
 338
 339         return {
 340                 signature => $sig,
 341                 size => $size,
 342                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 343                 content => $buffer
 344         };
 345 }
 346
 347 sub _index_lookup {
 348         ##
 349         # Given index tag, lookup single entry in index and return .
 350         ##
 351         my $self = shift;
 352         my ($tag, $index) = @_;
 353
 354         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 355         if (!$location) { return; }
 356
 357         return $self->_load_tag( $location );
 358 }
 359
 360 sub _add_bucket {
 361         ##
 362         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 363         # plain (undigested) key and value.
 364         ##
 365         my $self = shift;
 366         my ($tag, $md5, $plain_key, $value) = @_;
 367         my $keys = $tag->{content};
 368         my $location = 0;
 369         my $result = 2;
 370
 371     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 372         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 373
 374     my $fh = $self->fh;
 375
 376         ##
 377         # Iterate through buckets, seeing if this is a new entry or a replace.
 378         ##
 379         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 380                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 381                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 382                 if (!$subloc) {
 383                         ##
 384                         # Found empty bucket (end of list).  Populate and exit loop.
 385                         ##
 386                         $result = 2;
 387
 388             $location = $internal_ref
 389                 ? $value->base_offset
 390                 : $self->root->{end};
 391
 392                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 393                         print($fh $md5 . pack($LONG_PACK, $location) );
 394                         last;
 395                 }
 396                 elsif ($md5 eq $key) {
 397                         ##
 398                         # Found existing bucket with same key.  Replace with new value.
 399                         ##
 400                         $result = 1;
 401
 402                         if ($internal_ref) {
 403                                 $location = $value->base_offset;
 404                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 405                                 print($fh $md5 . pack($LONG_PACK, $location) );
 406                         }
 407                         else {
 408                                 seek($fh, $subloc + SIG_SIZE, 0);
 409                                 my $size;
 410                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 411
 412                                 ##
 413                                 # If value is a hash, array, or raw value with equal or less size, we can
 414                                 # reuse the same content area of the database.  Otherwise, we have to create
 415                                 # a new content area at the EOF.
 416                                 ##
 417                                 my $actual_length;
 418                 my $r = Scalar::Util::reftype( $value ) || '';
 419                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 420                                 else { $actual_length = length($value); }
 421
 422                                 if ($actual_length <= $size) {
 423                                         $location = $subloc;
 424                                 }
 425                                 else {
 426                                         $location = $self->root->{end};
 427                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, 0);
 428                                         print($fh pack($LONG_PACK, $location) );
 429                                 }
 430                         }
 431                         last;
 432                 }
 433         } # i loop
 434
 435         ##
 436         # If this is an internal reference, return now.
 437         # No need to write value or plain key
 438         ##
 439         if ($internal_ref) {
 440         return $result;
 441     }
 442
 443         ##
 444         # If bucket didn't fit into list, split into a new index level
 445         ##
 446         if (!$location) {
 447                 seek($fh, $tag->{ref_loc}, 0);
 448                 print($fh pack($LONG_PACK, $self->root->{end}) );
 449
 450                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 451                 my @offsets = ();
 452
 453                 $keys .= $md5 . pack($LONG_PACK, 0);
 454
 455                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 456                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 457                         if ($key) {
 458                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 459                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 460
 461                                 if ($offsets[$num]) {
 462                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 463                                         seek($fh, $offset, 0);
 464                                         my $subkeys;
 465                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 466
 467                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 468                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 469                                                 if (!$subloc) {
 470                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), 0);
 471                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 472                                                         last;
 473                                                 }
 474                                         } # k loop
 475                                 }
 476                                 else {
 477                                         $offsets[$num] = $self->root->{end};
 478                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), 0);
 479                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 480
 481                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 482
 483                                         seek($fh, $blist_tag->{offset}, 0);
 484                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 485                                 }
 486                         } # key is real
 487                 } # i loop
 488
 489                 $location ||= $self->root->{end};
 490         } # re-index bucket list
 491
 492         ##
 493         # Seek to content area and store signature, value and plaintext key
 494         ##
 495         if ($location) {
 496                 my $content_length;
 497                 seek($fh, $location, 0);
 498
 499                 ##
 500                 # Write signature based on content type, set content length and write actual value.
 501                 ##
 502         my $r = Scalar::Util::reftype($value) || '';
 503                 if ($r eq 'HASH') {
 504                         print($fh TYPE_HASH );
 505                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 506                         $content_length = $INDEX_SIZE;
 507                 }
 508                 elsif ($r eq 'ARRAY') {
 509                         print($fh TYPE_ARRAY );
 510                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 511                         $content_length = $INDEX_SIZE;
 512                 }
 513                 elsif (!defined($value)) {
 514                         print($fh SIG_NULL );
 515                         print($fh pack($DATA_LENGTH_PACK, 0) );
 516                         $content_length = 0;
 517                 }
 518                 else {
 519                         print($fh SIG_DATA );
 520                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 521                         $content_length = length($value);
 522                 }
 523
 524                 ##
 525                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 526                 ##
 527                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 528
 529                 ##
 530                 # If value is blessed, preserve class name
 531                 ##
 532                 if ( $self->root->{autobless} ) {
 533             my $value_class = Scalar::Util::blessed($value);
 534             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 535                 ##
 536                 # Blessed ref -- will restore later
 537                 ##
 538                 print($fh chr(1) );
 539                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 540                 $content_length += 1;
 541                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 542             }
 543             else {
 544                 print($fh chr(0) );
 545                 $content_length += 1;
 546             }
 547         }
 548
 549                 ##
 550                 # If this is a new content area, advance EOF counter
 551                 ##
 552                 if ($location == $self->root->{end}) {
 553                         $self->root->{end} += SIG_SIZE;
 554                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 555                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 556                 }
 557
 558                 ##
 559                 # If content is a hash or array, create new child DeepDB object and
 560                 # pass each key or element to it.
 561                 ##
 562                 if ($r eq 'HASH') {
 563                         my $branch = DBM::Deep->new(
 564                                 type => TYPE_HASH,
 565                                 base_offset => $location,
 566                                 root => $self->root,
 567                         );
 568                         foreach my $key (keys %{$value}) {
 569                 #$branch->{$key} = $value->{$key};
 570                 $branch->STORE( $key, $value->{$key} );
 571                         }
 572                 }
 573                 elsif ($r eq 'ARRAY') {
 574                         my $branch = DBM::Deep->new(
 575                                 type => TYPE_ARRAY,
 576                                 base_offset => $location,
 577                                 root => $self->root,
 578                         );
 579                         my $index = 0;
 580                         foreach my $element (@{$value}) {
 581                 #$branch->[$index] = $element;
 582                 $branch->STORE( $index, $element );
 583                                 $index++;
 584                         }
 585                 }
 586
 587                 return $result;
 588         }
 589
 590         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 591 }
 592
 593 sub _get_bucket_value {
 594         ##
 595         # Fetch single value given tag and MD5 digested key.
 596         ##
 597         my $self = shift;
 598         my ($tag, $md5) = @_;
 599         my $keys = $tag->{content};
 600
 601     my $fh = $self->fh;
 602
 603         ##
 604         # Iterate through buckets, looking for a key match
 605         ##
 606     BUCKET:
 607         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 608                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 609                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 610
 611                 if (!$subloc) {
 612                         ##
 613                         # Hit end of list, no match
 614                         ##
 615                         return;
 616                 }
 617
 618         if ( $md5 ne $key ) {
 619             next BUCKET;
 620         }
 621
 622         ##
 623         # Found match -- seek to offset and read signature
 624         ##
 625         my $signature;
 626         seek($fh, $subloc, 0);
 627         read( $fh, $signature, SIG_SIZE);
 628
 629         ##
 630         # If value is a hash or array, return new DeepDB object with correct offset
 631         ##
 632         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 633             my $obj = DBM::Deep->new(
 634                 type => $signature,
 635                 base_offset => $subloc,
 636                 root => $self->root
 637             );
 638
 639             if ($self->root->{autobless}) {
 640                 ##
 641                 # Skip over value and plain key to see if object needs
 642                 # to be re-blessed
 643                 ##
 644                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, 1);
 645
 646                 my $size;
 647                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 648                 if ($size) { seek($fh, $size, 1); }
 649
 650                 my $bless_bit;
 651                 read( $fh, $bless_bit, 1);
 652                 if (ord($bless_bit)) {
 653                     ##
 654                     # Yes, object needs to be re-blessed
 655                     ##
 656                     my $class_name;
 657                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 658                     if ($size) { read( $fh, $class_name, $size); }
 659                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 660                 }
 661             }
 662
 663             return $obj;
 664         }
 665
 666         ##
 667         # Otherwise return actual value
 668         ##
 669         elsif ($signature eq SIG_DATA) {
 670             my $size;
 671             my $value = '';
 672             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 673             if ($size) { read( $fh, $value, $size); }
 674             return $value;
 675         }
 676
 677         ##
 678         # Key exists, but content is null
 679         ##
 680         else { return; }
 681         } # i loop
 682
 683         return;
 684 }
 685
 686 sub _delete_bucket {
 687         ##
 688         # Delete single key/value pair given tag and MD5 digested key.
 689         ##
 690         my $self = shift;
 691         my ($tag, $md5) = @_;
 692         my $keys = $tag->{content};
 693
 694     my $fh = $self->fh;
 695
 696         ##
 697         # Iterate through buckets, looking for a key match
 698         ##
 699     BUCKET:
 700         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 701                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 702                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 703
 704                 if (!$subloc) {
 705                         ##
 706                         # Hit end of list, no match
 707                         ##
 708                         return;
 709                 }
 710
 711         if ( $md5 ne $key ) {
 712             next BUCKET;
 713         }
 714
 715         ##
 716         # Matched key -- delete bucket and return
 717         ##
 718         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), 0);
 719         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 720         print($fh chr(0) x $BUCKET_SIZE );
 721
 722         return 1;
 723         } # i loop
 724
 725         return;
 726 }
 727
 728 sub _bucket_exists {
 729         ##
 730         # Check existence of single key given tag and MD5 digested key.
 731         ##
 732         my $self = shift;
 733         my ($tag, $md5) = @_;
 734         my $keys = $tag->{content};
 735
 736         ##
 737         # Iterate through buckets, looking for a key match
 738         ##
 739     BUCKET:
 740         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 741                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 742                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 743
 744                 if (!$subloc) {
 745                         ##
 746                         # Hit end of list, no match
 747                         ##
 748                         return;
 749                 }
 750
 751         if ( $md5 ne $key ) {
 752             next BUCKET;
 753         }
 754
 755         ##
 756         # Matched key -- return true
 757         ##
 758         return 1;
 759         } # i loop
 760
 761         return;
 762 }
 763
 764 sub _find_bucket_list {
 765         ##
 766         # Locate offset for bucket list, given digested key
 767         ##
 768         my $self = shift;
 769         my $md5 = shift;
 770
 771         ##
 772         # Locate offset for bucket list using digest index system
 773         ##
 774         my $ch = 0;
 775         my $tag = $self->_load_tag($self->base_offset);
 776         if (!$tag) { return; }
 777
 778         while ($tag->{signature} ne SIG_BLIST) {
 779                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 780                 if (!$tag) { return; }
 781                 $ch++;
 782         }
 783
 784         return $tag;
 785 }
 786
 787 sub _traverse_index {
 788         ##
 789         # Scan index and recursively step into deeper levels, looking for next key.
 790         ##
 791     my ($self, $offset, $ch, $force_return_next) = @_;
 792     $force_return_next = undef unless $force_return_next;
 793
 794         my $tag = $self->_load_tag( $offset );
 795
 796     my $fh = $self->fh;
 797
 798         if ($tag->{signature} ne SIG_BLIST) {
 799                 my $content = $tag->{content};
 800                 my $start;
 801                 if ($self->{return_next}) { $start = 0; }
 802                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 803
 804                 for (my $index = $start; $index < 256; $index++) {
 805                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 806                         if ($subloc) {
 807                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 808                                 if (defined($result)) { return $result; }
 809                         }
 810                 } # index loop
 811
 812                 $self->{return_next} = 1;
 813         } # tag is an index
 814
 815         elsif ($tag->{signature} eq SIG_BLIST) {
 816                 my $keys = $tag->{content};
 817                 if ($force_return_next) { $self->{return_next} = 1; }
 818
 819                 ##
 820                 # Iterate through buckets, looking for a key match
 821                 ##
 822                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 823                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 824                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 825
 826                         if (!$subloc) {
 827                                 ##
 828                                 # End of bucket list -- return to outer loop
 829                                 ##
 830                                 $self->{return_next} = 1;
 831                                 last;
 832                         }
 833                         elsif ($key eq $self->{prev_md5}) {
 834                                 ##
 835                                 # Located previous key -- return next one found
 836                                 ##
 837                                 $self->{return_next} = 1;
 838                                 next;
 839                         }
 840                         elsif ($self->{return_next}) {
 841                                 ##
 842                                 # Seek to bucket location and skip over signature
 843                                 ##
 844                                 seek($fh, $subloc + SIG_SIZE, 0);
 845
 846                                 ##
 847                                 # Skip over value to get to plain key
 848                                 ##
 849                                 my $size;
 850                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 851                                 if ($size) { seek($fh, $size, 1); }
 852
 853                                 ##
 854                                 # Read in plain key and return as scalar
 855                                 ##
 856                                 my $plain_key;
 857                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 858                                 if ($size) { read( $fh, $plain_key, $size); }
 859
 860                                 return $plain_key;
 861                         }
 862                 } # bucket loop
 863
 864                 $self->{return_next} = 1;
 865         } # tag is a bucket list
 866
 867         return;
 868 }
 869
 870 sub _get_next_key {
 871         ##
 872         # Locate next key, given digested previous one
 873         ##
 874     my $self = _get_self($_[0]);
 875
 876         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 877         $self->{return_next} = 0;
 878
 879         ##
 880         # If the previous key was not specifed, start at the top and
 881         # return the first one found.
 882         ##
 883         if (!$self->{prev_md5}) {
 884                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 885                 $self->{return_next} = 1;
 886         }
 887
 888         return $self->_traverse_index( $self->base_offset, 0 );
 889 }
 890
 891 sub lock {
 892         ##
 893         # If db locking is set, flock() the db file.  If called multiple
 894         # times before unlock(), then the same number of unlocks() must
 895         # be called before the lock is released.
 896         ##
 897     my $self = _get_self($_[0]);
 898         my $type = $_[1];
 899     $type = LOCK_EX unless defined $type;
 900
 901         if ($self->root->{locking}) {
 902                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 903                 $self->root->{locked}++;
 904
 905         return 1;
 906         }
 907
 908     return;
 909 }
 910
 911 sub unlock {
 912         ##
 913         # If db locking is set, unlock the db file.  See note in lock()
 914         # regarding calling lock() multiple times.
 915         ##
 916     my $self = _get_self($_[0]);
 917
 918         if ($self->root->{locking} && $self->root->{locked} > 0) {
 919                 $self->root->{locked}--;
 920                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 921
 922         return 1;
 923         }
 924
 925     return;
 926 }
 927
 928 #XXX These uses of ref() need verified
 929 sub _copy_node {
 930         ##
 931         # Copy single level of keys or elements to new DB handle.
 932         # Recurse for nested structures
 933         ##
 934     my $self = _get_self($_[0]);
 935         my $db_temp = $_[1];
 936
 937         if ($self->type eq TYPE_HASH) {
 938                 my $key = $self->first_key();
 939                 while ($key) {
 940                         my $value = $self->get($key);
 941 #XXX This doesn't work with autobless
 942                         if (!ref($value)) { $db_temp->{$key} = $value; }
 943                         else {
 944                                 my $type = $value->type;
 945                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 946                                 else { $db_temp->{$key} = []; }
 947                                 $value->_copy_node( $db_temp->{$key} );
 948                         }
 949                         $key = $self->next_key($key);
 950                 }
 951         }
 952         else {
 953                 my $length = $self->length();
 954                 for (my $index = 0; $index < $length; $index++) {
 955                         my $value = $self->get($index);
 956                         if (!ref($value)) { $db_temp->[$index] = $value; }
 957             #XXX NO tests for this code
 958                         else {
 959                                 my $type = $value->type;
 960                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 961                                 else { $db_temp->[$index] = []; }
 962                                 $value->_copy_node( $db_temp->[$index] );
 963                         }
 964                 }
 965         }
 966 }
 967
 968 sub export {
 969         ##
 970         # Recursively export into standard Perl hashes and arrays.
 971         ##
 972     my $self = _get_self($_[0]);
 973
 974         my $temp;
 975         if ($self->type eq TYPE_HASH) { $temp = {}; }
 976         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 977
 978         $self->lock();
 979         $self->_copy_node( $temp );
 980         $self->unlock();
 981
 982         return $temp;
 983 }
 984
 985 sub import {
 986         ##
 987         # Recursively import Perl hash/array structure
 988         ##
 989     #XXX This use of ref() seems to be ok
 990         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 991
 992     my $self = _get_self($_[0]);
 993         my $struct = $_[1];
 994
 995     #XXX This use of ref() seems to be ok
 996         if (!ref($struct)) {
 997                 ##
 998                 # struct is not a reference, so just import based on our type
 999                 ##
1000                 shift @_;
1001
1002                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1003                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1004         }
1005
1006     my $r = Scalar::Util::reftype($struct) || '';
1007         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1008                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1009         }
1010         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1011                 $self->push( @$struct );
1012         }
1013         else {
1014                 return $self->_throw_error("Cannot import: type mismatch");
1015         }
1016
1017         return 1;
1018 }
1019
1020 sub optimize {
1021         ##
1022         # Rebuild entire database into new file, then move
1023         # it back on top of original.
1024         ##
1025     my $self = _get_self($_[0]);
1026
1027 #XXX Need to create a new test for this
1028 #       if ($self->root->{links} > 1) {
1029 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1030 #       }
1031
1032         my $db_temp = DBM::Deep->new(
1033                 file => $self->root->{file} . '.tmp',
1034                 type => $self->type
1035         );
1036         if (!$db_temp) {
1037                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1038         }
1039
1040         $self->lock();
1041         $self->_copy_node( $db_temp );
1042         undef $db_temp;
1043
1044         ##
1045         # Attempt to copy user, group and permissions over to new file
1046         ##
1047         my @stats = stat($self->fh);
1048         my $perms = $stats[2] & 07777;
1049         my $uid = $stats[4];
1050         my $gid = $stats[5];
1051         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1052         chmod( $perms, $self->root->{file} . '.tmp' );
1053
1054     # q.v. perlport for more information on this variable
1055     if ( $^O eq 'MSWin32' ) {
1056                 ##
1057                 # Potential race condition when optmizing on Win32 with locking.
1058                 # The Windows filesystem requires that the filehandle be closed
1059                 # before it is overwritten with rename().  This could be redone
1060                 # with a soft copy.
1061                 ##
1062                 $self->unlock();
1063                 $self->_close();
1064         }
1065
1066         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1067                 unlink $self->root->{file} . '.tmp';
1068                 $self->unlock();
1069                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1070         }
1071
1072         $self->unlock();
1073         $self->_close();
1074         $self->_open();
1075
1076         return 1;
1077 }
1078
1079 sub clone {
1080         ##
1081         # Make copy of object and return
1082         ##
1083     my $self = _get_self($_[0]);
1084
1085         return DBM::Deep->new(
1086                 type => $self->type,
1087                 base_offset => $self->base_offset,
1088                 root => $self->root
1089         );
1090 }
1091
1092 {
1093     my %is_legal_filter = map {
1094         $_ => ~~1,
1095     } qw(
1096         store_key store_value
1097         fetch_key fetch_value
1098     );
1099
1100     sub set_filter {
1101         ##
1102         # Setup filter function for storing or fetching the key or value
1103         ##
1104         my $self = _get_self($_[0]);
1105         my $type = lc $_[1];
1106         my $func = $_[2] ? $_[2] : undef;
1107
1108         if ( $is_legal_filter{$type} ) {
1109             $self->root->{"filter_$type"} = $func;
1110             return 1;
1111         }
1112
1113         return;
1114     }
1115 }
1116
1117 ##
1118 # Accessor methods
1119 ##
1120
1121 sub root {
1122         ##
1123         # Get access to the root structure
1124         ##
1125     my $self = _get_self($_[0]);
1126         return $self->{root};
1127 }
1128
1129 sub fh {
1130         ##
1131         # Get access to the raw FileHandle
1132         ##
1133     #XXX It will be useful, though, when we split out HASH and ARRAY
1134     my $self = _get_self($_[0]);
1135         return $self->root->{fh};
1136 }
1137
1138 sub type {
1139         ##
1140         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1141         ##
1142     my $self = _get_self($_[0]);
1143         return $self->{type};
1144 }
1145
1146 sub base_offset {
1147         ##
1148         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1149         ##
1150     my $self = _get_self($_[0]);
1151         return $self->{base_offset};
1152 }
1153
1154 sub error {
1155         ##
1156         # Get last error string, or undef if no error
1157         ##
1158         return $_[0]
1159         ? ( _get_self($_[0])->{root}->{error} or undef )
1160         : $@;
1161 }
1162
1163 ##
1164 # Utility methods
1165 ##
1166
1167 sub _throw_error {
1168         ##
1169         # Store error string in self
1170         ##
1171     my $self = _get_self($_[0]);
1172         my $error_text = $_[1];
1173
1174         $self->root->{error} = $error_text;
1175
1176         unless ($self->root->{debug}) {
1177         die "DBM::Deep: $error_text\n";
1178     }
1179
1180     warn "DBM::Deep: $error_text\n";
1181         return;
1182 }
1183
1184 sub clear_error {
1185         ##
1186         # Clear error state
1187         ##
1188     my $self = _get_self($_[0]);
1189
1190         undef $self->root->{error};
1191 }
1192
1193 sub precalc_sizes {
1194         ##
1195         # Precalculate index, bucket and bucket list sizes
1196         ##
1197
1198     #XXX I don't like this ...
1199     set_pack() unless defined $LONG_SIZE;
1200
1201         $INDEX_SIZE = 256 * $LONG_SIZE;
1202         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1203         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1204 }
1205
1206 sub set_pack {
1207         ##
1208         # Set pack/unpack modes (see file header for more)
1209         ##
1210     my ($long_s, $long_p, $data_s, $data_p) = @_;
1211
1212     $LONG_SIZE = $long_s ? $long_s : 4;
1213     $LONG_PACK = $long_p ? $long_p : 'N';
1214
1215     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1216     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1217
1218         precalc_sizes();
1219 }
1220
1221 sub set_digest {
1222         ##
1223         # Set key digest function (default is MD5)
1224         ##
1225     my ($digest_func, $hash_size) = @_;
1226
1227     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1228     $HASH_SIZE = $hash_size ? $hash_size : 16;
1229
1230         precalc_sizes();
1231 }
1232
1233 ##
1234 # tie() methods (hashes and arrays)
1235 ##
1236
1237 sub STORE {
1238         ##
1239         # Store single hash key/value or array element in database.
1240         ##
1241     my $self = _get_self($_[0]);
1242         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1243     #XXX What is ref() checking here?
1244     #YYY User may be storing a hash, in which case we do not want it run
1245     #YYY through the filtering system
1246         my $value = ($self->root->{filter_store_value} && !ref($_[2])) ? $self->root->{filter_store_value}->($_[2]) : $_[2];
1247
1248         my $unpacked_key = $key;
1249         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1250         my $md5 = $DIGEST_FUNC->($key);
1251
1252         ##
1253         # Make sure file is open
1254         ##
1255         if (!defined($self->fh) && !$self->_open()) {
1256                 return;
1257         }
1258         ##
1259
1260     my $fh = $self->fh;
1261
1262         ##
1263         # Request exclusive lock for writing
1264         ##
1265         $self->lock( LOCK_EX );
1266
1267         ##
1268         # If locking is enabled, set 'end' parameter again, in case another
1269         # DB instance appended to our file while we were unlocked.
1270         ##
1271         if ($self->root->{locking} || $self->root->{volatile}) {
1272                 $self->root->{end} = (stat($fh))[7];
1273         }
1274
1275         ##
1276         # Locate offset for bucket list using digest index system
1277         ##
1278         my $tag = $self->_load_tag($self->base_offset);
1279         if (!$tag) {
1280                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1281         }
1282
1283         my $ch = 0;
1284         while ($tag->{signature} ne SIG_BLIST) {
1285                 my $num = ord(substr($md5, $ch, 1));
1286                 my $new_tag = $self->_index_lookup($tag, $num);
1287                 if (!$new_tag) {
1288                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1289                         seek($fh, $ref_loc, 0);
1290                         print($fh pack($LONG_PACK, $self->root->{end}) );
1291
1292                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1293                         $tag->{ref_loc} = $ref_loc;
1294                         $tag->{ch} = $ch;
1295                         last;
1296                 }
1297                 else {
1298                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1299                         $tag = $new_tag;
1300                         $tag->{ref_loc} = $ref_loc;
1301                         $tag->{ch} = $ch;
1302                 }
1303                 $ch++;
1304         }
1305
1306         ##
1307         # Add key/value to bucket list
1308         ##
1309         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1310
1311         ##
1312         # If this object is an array, and bucket was not a replace, and key is numerical,
1313         # and index is equal or greater than current length, advance length variable.
1314         ##
1315         if (($result == 2) && ($self->type eq TYPE_ARRAY) && ($unpacked_key =~ /^\d+$/) && ($unpacked_key >= $self->FETCHSIZE())) {
1316                 $self->STORESIZE( $unpacked_key + 1 );
1317         }
1318
1319         $self->unlock();
1320
1321         return $result;
1322 }
1323
1324 sub FETCH {
1325         ##
1326         # Fetch single value or element given plain key or array index
1327         ##
1328     my $self = _get_self($_[0]);
1329
1330     my $key = $_[1];
1331     if ( $self->type eq TYPE_HASH ) {
1332         if ( my $filter = $self->root->{filter_store_key} ) {
1333             $key = $filter->( $key );
1334         }
1335     }
1336     elsif ( $self->type eq TYPE_ARRAY ) {
1337         if ( $key =~ /^\d+$/ ) {
1338             $key = pack($LONG_PACK, $key);
1339         }
1340     }
1341
1342         my $md5 = $DIGEST_FUNC->($key);
1343
1344         ##
1345         # Make sure file is open
1346         ##
1347         if (!defined($self->fh)) { $self->_open(); }
1348
1349         ##
1350         # Request shared lock for reading
1351         ##
1352         $self->lock( LOCK_SH );
1353
1354         my $tag = $self->_find_bucket_list( $md5 );
1355         if (!$tag) {
1356                 $self->unlock();
1357                 return;
1358         }
1359
1360         ##
1361         # Get value from bucket list
1362         ##
1363         my $result = $self->_get_bucket_value( $tag, $md5 );
1364
1365         $self->unlock();
1366
1367     #XXX What is ref() checking here?
1368         return ($result && !ref($result) && $self->root->{filter_fetch_value}) ? $self->root->{filter_fetch_value}->($result) : $result;
1369 }
1370
1371 sub DELETE {
1372         ##
1373         # Delete single key/value pair or element given plain key or array index
1374         ##
1375     my $self = _get_self($_[0]);
1376         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1377
1378         my $unpacked_key = $key;
1379         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1380         my $md5 = $DIGEST_FUNC->($key);
1381
1382         ##
1383         # Make sure file is open
1384         ##
1385         if (!defined($self->fh)) { $self->_open(); }
1386
1387         ##
1388         # Request exclusive lock for writing
1389         ##
1390         $self->lock( LOCK_EX );
1391
1392         my $tag = $self->_find_bucket_list( $md5 );
1393         if (!$tag) {
1394                 $self->unlock();
1395                 return;
1396         }
1397
1398         ##
1399         # Delete bucket
1400         ##
1401         my $result = $self->_delete_bucket( $tag, $md5 );
1402
1403         ##
1404         # If this object is an array and the key deleted was on the end of the stack,
1405         # decrement the length variable.
1406         ##
1407         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1408                 $self->STORESIZE( $unpacked_key );
1409         }
1410
1411         $self->unlock();
1412
1413         return $result;
1414 }
1415
1416 sub EXISTS {
1417         ##
1418         # Check if a single key or element exists given plain key or array index
1419         ##
1420     my $self = _get_self($_[0]);
1421         my $key = ($self->root->{filter_store_key} && $self->type eq TYPE_HASH) ? $self->root->{filter_store_key}->($_[1]) : $_[1];
1422
1423         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1424         my $md5 = $DIGEST_FUNC->($key);
1425
1426         ##
1427         # Make sure file is open
1428         ##
1429         if (!defined($self->fh)) { $self->_open(); }
1430
1431         ##
1432         # Request shared lock for reading
1433         ##
1434         $self->lock( LOCK_SH );
1435
1436         my $tag = $self->_find_bucket_list( $md5 );
1437
1438         ##
1439         # For some reason, the built-in exists() function returns '' for false
1440         ##
1441         if (!$tag) {
1442                 $self->unlock();
1443                 return '';
1444         }
1445
1446         ##
1447         # Check if bucket exists and return 1 or ''
1448         ##
1449         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1450
1451         $self->unlock();
1452
1453         return $result;
1454 }
1455
1456 sub CLEAR {
1457         ##
1458         # Clear all keys from hash, or all elements from array.
1459         ##
1460     my $self = _get_self($_[0]);
1461
1462         ##
1463         # Make sure file is open
1464         ##
1465         if (!defined($self->fh)) { $self->_open(); }
1466
1467         ##
1468         # Request exclusive lock for writing
1469         ##
1470         $self->lock( LOCK_EX );
1471
1472     my $fh = $self->fh;
1473
1474         seek($fh, $self->base_offset, 0);
1475         if (eof $fh) {
1476                 $self->unlock();
1477                 return;
1478         }
1479
1480         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1481
1482         $self->unlock();
1483
1484         return 1;
1485 }
1486
1487 ##
1488 # Public method aliases
1489 ##
1490 *put = *store = *STORE;
1491 *get = *fetch = *FETCH;
1492 *delete = *DELETE;
1493 *exists = *EXISTS;
1494 *clear = *CLEAR;
1495
1496 package DBM::Deep::_::Root;
1497
1498 sub new {
1499     my $class = shift;
1500     my ($args) = @_;
1501
1502     my $self = bless {
1503         file => undef,
1504         fh => undef,
1505         end => 0,
1506         autoflush => undef,
1507         locking => undef,
1508         volatile => undef,
1509         debug => undef,
1510         mode => 'r+',
1511         filter_store_key => undef,
1512         filter_store_value => undef,
1513         filter_fetch_key => undef,
1514         filter_fetch_value => undef,
1515         autobless => undef,
1516         locked => 0,
1517         %$args,
1518     }, $class;
1519
1520     return $self;
1521 }
1522
1523 sub DESTROY {
1524     my $self = shift;
1525     return unless $self;
1526
1527     close $self->{fh} if $self->{fh};
1528
1529     return;
1530 }
1531
1532 1;
1533
1534 __END__
1535
1536 =head1 NAME
1537
1538 DBM::Deep - A pure perl multi-level hash/array DBM
1539
1540 =head1 SYNOPSIS
1541
1542   use DBM::Deep;
1543   my $db = DBM::Deep->new( "foo.db" );
1544
1545   $db->{key} = 'value'; # tie() style
1546   print $db->{key};
1547
1548   $db->put('key', 'value'); # OO style
1549   print $db->get('key');
1550
1551   # true multi-level support
1552   $db->{my_complex} = [
1553         'hello', { perl => 'rules' },
1554         42, 99 ];
1555
1556 =head1 DESCRIPTION
1557
1558 A unique flat-file database module, written in pure perl.  True
1559 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1560 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1561 handle millions of keys and unlimited hash levels without significant
1562 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1563 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1564 Mac OS X and Windows.
1565
1566 =head1 INSTALLATION
1567
1568 Hopefully you are using CPAN's excellent Perl module, which will download
1569 and install the module for you.  If not, get the tarball, and run these
1570 commands:
1571
1572         tar zxf DBM-Deep-*
1573         cd DBM-Deep-*
1574         perl Makefile.PL
1575         make
1576         make test
1577         make install
1578
1579 =head1 SETUP
1580
1581 Construction can be done OO-style (which is the recommended way), or using
1582 Perl's tie() function.  Both are examined here.
1583
1584 =head2 OO CONSTRUCTION
1585
1586 The recommended way to construct a DBM::Deep object is to use the new()
1587 method, which gets you a blessed, tied hash or array reference.
1588
1589         my $db = DBM::Deep->new( "foo.db" );
1590
1591 This opens a new database handle, mapped to the file "foo.db".  If this
1592 file does not exist, it will automatically be created.  DB files are
1593 opened in "r+" (read/write) mode, and the type of object returned is a
1594 hash, unless otherwise specified (see L<OPTIONS> below).
1595
1596
1597
1598 You can pass a number of options to the constructor to specify things like
1599 locking, autoflush, etc.  This is done by passing an inline hash:
1600
1601         my $db = DBM::Deep->new(
1602                 file => "foo.db",
1603                 locking => 1,
1604                 autoflush => 1
1605         );
1606
1607 Notice that the filename is now specified I<inside> the hash with
1608 the "file" parameter, as opposed to being the sole argument to the
1609 constructor.  This is required if any options are specified.
1610 See L<OPTIONS> below for the complete list.
1611
1612
1613
1614 You can also start with an array instead of a hash.  For this, you must
1615 specify the C<type> parameter:
1616
1617         my $db = DBM::Deep->new(
1618                 file => "foo.db",
1619                 type => DBM::Deep->TYPE_ARRAY
1620         );
1621
1622 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1623 a new DB file.  If you create a DBM::Deep object with an existing file, the
1624 C<type> will be loaded from the file header, and ignored if it is passed
1625 to the constructor.
1626
1627 =head2 TIE CONSTRUCTION
1628
1629 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1630 tie() function.  This is not ideal, because you get only a basic, tied hash
1631 (or array) which is not blessed, so you can't call any functions on it.
1632
1633         my %hash;
1634         tie %hash, "DBM::Deep", "foo.db";
1635
1636         my @array;
1637         tie @array, "DBM::Deep", "bar.db";
1638
1639 As with the OO constructor, you can replace the DB filename parameter with
1640 a hash containing one or more options (see L<OPTIONS> just below for the
1641 complete list).
1642
1643         tie %hash, "DBM::Deep", {
1644                 file => "foo.db",
1645                 locking => 1,
1646                 autoflush => 1
1647         };
1648
1649 =head2 OPTIONS
1650
1651 There are a number of options that can be passed in when constructing your
1652 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1653
1654 =over
1655
1656 =item * file
1657
1658 Filename of the DB file to link the handle to.  You can pass a full absolute
1659 filesystem path, partial path, or a plain filename if the file is in the
1660 current working directory.  This is a required parameter.
1661
1662 =item * mode
1663
1664 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1665 module.  This is an optional parameter, and defaults to "r+" (read/write).
1666 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1667 created if it doesn't exist.
1668
1669 =item * type
1670
1671 This parameter specifies what type of object to create, a hash or array.  Use
1672 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1673 This only takes effect when beginning a new file.  This is an optional
1674 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1675
1676 =item * locking
1677
1678 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1679 function to lock the database in exclusive mode for writes, and shared mode for
1680 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1681 any child hashes or arrays> that use the same DB file.  This is an optional
1682 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1683
1684 =item * autoflush
1685
1686 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1687 This obviously slows down write operations, but is required if you may have
1688 multiple processes accessing the same DB file (also consider enable I<locking>
1689 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1690 parameter, and defaults to 0 (disabled).
1691
1692 =item * volatile
1693
1694 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1695 STORE() operation.  This is required if an outside force may change the size of
1696 the file between transactions.  Locking also implicitly enables volatile.  This
1697 is useful if you want to use a different locking system or write your own.  Pass
1698 any true value to enable.  This is an optional parameter, and defaults to 0
1699 (disabled).
1700
1701 =item * autobless
1702
1703 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1704 restore them when fetched.  This is an B<experimental> feature, and does have
1705 side-effects.  Basically, when hashes are re-blessed into their original
1706 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1707 able to call any DBM::Deep methods on them.  You have been warned.
1708 This is an optional parameter, and defaults to 0 (disabled).
1709
1710 =item * filter_*
1711
1712 See L<FILTERS> below.
1713
1714 =item * debug
1715
1716 Setting I<debug> mode will make all errors non-fatal, dump them out to
1717 STDERR, and continue on.  This is for debugging purposes only, and probably
1718 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1719
1720 =item * fh
1721
1722 Instead of passing a file path, you can instead pass a handle to an pre-opened
1723 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1724 contains your entire Perl script, as well as the data following the __DATA__
1725 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1726 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1727 in that.
1728
1729 =back
1730
1731 =head1 TIE INTERFACE
1732
1733 With DBM::Deep you can access your databases using Perl's standard hash/array
1734 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1735 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1736 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1737 section above.  This simply tells you how to use DBM::Deep using regular hashes
1738 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1739 work too).  It is entirely up to you how to want to access your databases.
1740
1741 =head2 HASHES
1742
1743 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1744 or even nested hashes (or arrays) using standard Perl syntax:
1745
1746         my $db = DBM::Deep->new( "foo.db" );
1747
1748         $db->{mykey} = "myvalue";
1749         $db->{myhash} = {};
1750         $db->{myhash}->{subkey} = "subvalue";
1751
1752         print $db->{myhash}->{subkey} . "\n";
1753
1754 You can even step through hash keys using the normal Perl C<keys()> function:
1755
1756         foreach my $key (keys %$db) {
1757                 print "$key: " . $db->{$key} . "\n";
1758         }
1759
1760 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1761 pushes them onto an array, all before the loop even begins.  If you have an
1762 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1763 Perl's C<each()> function, which pulls keys/values one at a time, using very
1764 little memory:
1765
1766         while (my ($key, $value) = each %$db) {
1767                 print "$key: $value\n";
1768         }
1769
1770 Please note that when using C<each()>, you should always pass a direct
1771 hash reference, not a lookup.  Meaning, you should B<never> do this:
1772
1773         # NEVER DO THIS
1774         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1775
1776 This causes an infinite loop, because for each iteration, Perl is calling
1777 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1778 it effectively keeps returning the first key over and over again. Instead,
1779 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1780
1781 =head2 ARRAYS
1782
1783 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1784 reference.  This includes inserting, removing and manipulating elements,
1785 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1786 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1787 or simply be a nested array reference inside a hash.  Example:
1788
1789         my $db = DBM::Deep->new(
1790                 file => "foo-array.db",
1791                 type => DBM::Deep->TYPE_ARRAY
1792         );
1793
1794         $db->[0] = "foo";
1795         push @$db, "bar", "baz";
1796         unshift @$db, "bah";
1797
1798         my $last_elem = pop @$db; # baz
1799         my $first_elem = shift @$db; # bah
1800         my $second_elem = $db->[1]; # bar
1801
1802         my $num_elements = scalar @$db;
1803
1804 =head1 OO INTERFACE
1805
1806 In addition to the I<tie()> interface, you can also use a standard OO interface
1807 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1808 array) has its own methods, but both types share the following common methods:
1809 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1810
1811 =over
1812
1813 =item * put()
1814
1815 Stores a new hash key/value pair, or sets an array element value.  Takes two
1816 arguments, the hash key or array index, and the new value.  The value can be
1817 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1818
1819         $db->put("foo", "bar"); # for hashes
1820         $db->put(1, "bar"); # for arrays
1821
1822 =item * get()
1823
1824 Fetches the value of a hash key or array element.  Takes one argument: the hash
1825 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1826 data type stored.
1827
1828         my $value = $db->get("foo"); # for hashes
1829         my $value = $db->get(1); # for arrays
1830
1831 =item * exists()
1832
1833 Checks if a hash key or array index exists.  Takes one argument: the hash key
1834 or array index.  Returns true if it exists, false if not.
1835
1836         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1837         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1838
1839 =item * delete()
1840
1841 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1842 key or array index.  Returns true on success, false if not found.  For arrays,
1843 the remaining elements located after the deleted element are NOT moved over.
1844 The deleted element is essentially just undefined, which is exactly how Perl's
1845 internal arrays work.  Please note that the space occupied by the deleted
1846 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1847 below for details and workarounds.
1848
1849         $db->delete("foo"); # for hashes
1850         $db->delete(1); # for arrays
1851
1852 =item * clear()
1853
1854 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1855 value.  Please note that the space occupied by the deleted keys/values or
1856 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1857 details and workarounds.
1858
1859         $db->clear(); # hashes or arrays
1860
1861 =back
1862
1863 =head2 HASHES
1864
1865 For hashes, DBM::Deep supports all the common methods described above, and the
1866 following additional methods: C<first_key()> and C<next_key()>.
1867
1868 =over
1869
1870 =item * first_key()
1871
1872 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1873 fetched in an undefined order (which appears random).  Takes no arguments,
1874 returns the key as a scalar value.
1875
1876         my $key = $db->first_key();
1877
1878 =item * next_key()
1879
1880 Returns the "next" key in the hash, given the previous one as the sole argument.
1881 Returns undef if there are no more keys to be fetched.
1882
1883         $key = $db->next_key($key);
1884
1885 =back
1886
1887 Here are some examples of using hashes:
1888
1889         my $db = DBM::Deep->new( "foo.db" );
1890
1891         $db->put("foo", "bar");
1892         print "foo: " . $db->get("foo") . "\n";
1893
1894         $db->put("baz", {}); # new child hash ref
1895         $db->get("baz")->put("buz", "biz");
1896         print "buz: " . $db->get("baz")->get("buz") . "\n";
1897
1898         my $key = $db->first_key();
1899         while ($key) {
1900                 print "$key: " . $db->get($key) . "\n";
1901                 $key = $db->next_key($key);
1902         }
1903
1904         if ($db->exists("foo")) { $db->delete("foo"); }
1905
1906 =head2 ARRAYS
1907
1908 For arrays, DBM::Deep supports all the common methods described above, and the
1909 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1910 C<unshift()> and C<splice()>.
1911
1912 =over
1913
1914 =item * length()
1915
1916 Returns the number of elements in the array.  Takes no arguments.
1917
1918         my $len = $db->length();
1919
1920 =item * push()
1921
1922 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1923 refs or array refs.  No return value.
1924
1925         $db->push("foo", "bar", {});
1926
1927 =item * pop()
1928
1929 Fetches the last element in the array, and deletes it.  Takes no arguments.
1930 Returns undef if array is empty.  Returns the element value.
1931
1932         my $elem = $db->pop();
1933
1934 =item * shift()
1935
1936 Fetches the first element in the array, deletes it, then shifts all the
1937 remaining elements over to take up the space.  Returns the element value.  This
1938 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1939 details.
1940
1941         my $elem = $db->shift();
1942
1943 =item * unshift()
1944
1945 Inserts one or more elements onto the beginning of the array, shifting all
1946 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1947 No return value.  This method is not recommended with large arrays -- see
1948 <LARGE ARRAYS> below for details.
1949
1950         $db->unshift("foo", "bar", {});
1951
1952 =item * splice()
1953
1954 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1955 -f splice> for usage -- it is too complicated to document here.  This method is
1956 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1957
1958 =back
1959
1960 Here are some examples of using arrays:
1961
1962         my $db = DBM::Deep->new(
1963                 file => "foo.db",
1964                 type => DBM::Deep->TYPE_ARRAY
1965         );
1966
1967         $db->push("bar", "baz");
1968         $db->unshift("foo");
1969         $db->put(3, "buz");
1970
1971         my $len = $db->length();
1972         print "length: $len\n"; # 4
1973
1974         for (my $k=0; $k<$len; $k++) {
1975                 print "$k: " . $db->get($k) . "\n";
1976         }
1977
1978         $db->splice(1, 2, "biz", "baf");
1979
1980         while (my $elem = shift @$db) {
1981                 print "shifted: $elem\n";
1982         }
1983
1984 =head1 LOCKING
1985
1986 Enable automatic file locking by passing a true value to the C<locking>
1987 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1988
1989         my $db = DBM::Deep->new(
1990                 file => "foo.db",
1991                 locking => 1
1992         );
1993
1994 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1995 mode for writes, and shared mode for reads.  This is required if you have
1996 multiple processes accessing the same database file, to avoid file corruption.
1997 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1998 NFS> below for more.
1999
2000 =head2 EXPLICIT LOCKING
2001
2002 You can explicitly lock a database, so it remains locked for multiple
2003 transactions.  This is done by calling the C<lock()> method, and passing an
2004 optional lock mode argument (defaults to exclusive mode).  This is particularly
2005 useful for things like counters, where the current value needs to be fetched,
2006 then incremented, then stored again.
2007
2008         $db->lock();
2009         my $counter = $db->get("counter");
2010         $counter++;
2011         $db->put("counter", $counter);
2012         $db->unlock();
2013
2014         # or...
2015
2016         $db->lock();
2017         $db->{counter}++;
2018         $db->unlock();
2019
2020 You can pass C<lock()> an optional argument, which specifies which mode to use
2021 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2022 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2023 same as the constants defined in Perl's C<Fcntl> module.
2024
2025         $db->lock( DBM::Deep->LOCK_SH );
2026         # something here
2027         $db->unlock();
2028
2029 If you want to implement your own file locking scheme, be sure to create your
2030 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2031 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2032 below for more.
2033
2034 =head1 IMPORTING/EXPORTING
2035
2036 You can import existing complex structures by calling the C<import()> method,
2037 and export an entire database into an in-memory structure using the C<export()>
2038 method.  Both are examined here.
2039
2040 =head2 IMPORTING
2041
2042 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2043 walking the structure and adding keys/elements to the database as you go,
2044 simply pass a reference to the C<import()> method.  This recursively adds
2045 everything to an existing DBM::Deep object for you.  Here is an example:
2046
2047         my $struct = {
2048                 key1 => "value1",
2049                 key2 => "value2",
2050                 array1 => [ "elem0", "elem1", "elem2" ],
2051                 hash1 => {
2052                         subkey1 => "subvalue1",
2053                         subkey2 => "subvalue2"
2054                 }
2055         };
2056
2057         my $db = DBM::Deep->new( "foo.db" );
2058         $db->import( $struct );
2059
2060         print $db->{key1} . "\n"; # prints "value1"
2061
2062 This recursively imports the entire C<$struct> object into C<$db>, including
2063 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2064 keys are merged with the existing ones, replacing if they already exist.
2065 The C<import()> method can be called on any database level (not just the base
2066 level), and works with both hash and array DB types.
2067
2068
2069
2070 B<Note:> Make sure your existing structure has no circular references in it.
2071 These will cause an infinite loop when importing.
2072
2073 =head2 EXPORTING
2074
2075 Calling the C<export()> method on an existing DBM::Deep object will return
2076 a reference to a new in-memory copy of the database.  The export is done
2077 recursively, so all nested hashes/arrays are all exported to standard Perl
2078 objects.  Here is an example:
2079
2080         my $db = DBM::Deep->new( "foo.db" );
2081
2082         $db->{key1} = "value1";
2083         $db->{key2} = "value2";
2084         $db->{hash1} = {};
2085         $db->{hash1}->{subkey1} = "subvalue1";
2086         $db->{hash1}->{subkey2} = "subvalue2";
2087
2088         my $struct = $db->export();
2089
2090         print $struct->{key1} . "\n"; # prints "value1"
2091
2092 This makes a complete copy of the database in memory, and returns a reference
2093 to it.  The C<export()> method can be called on any database level (not just
2094 the base level), and works with both hash and array DB types.  Be careful of
2095 large databases -- you can store a lot more data in a DBM::Deep object than an
2096 in-memory Perl structure.
2097
2098
2099
2100 B<Note:> Make sure your database has no circular references in it.
2101 These will cause an infinite loop when exporting.
2102
2103 =head1 FILTERS
2104
2105 DBM::Deep has a number of hooks where you can specify your own Perl function
2106 to perform filtering on incoming or outgoing data.  This is a perfect
2107 way to extend the engine, and implement things like real-time compression or
2108 encryption.  Filtering applies to the base DB level, and all child hashes /
2109 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2110 constructed, or by calling the C<set_filter()> method at any time.  There are
2111 four available filter hooks, described below:
2112
2113 =over
2114
2115 =item * filter_store_key
2116
2117 This filter is called whenever a hash key is stored.  It
2118 is passed the incoming key, and expected to return a transformed key.
2119
2120 =item * filter_store_value
2121
2122 This filter is called whenever a hash key or array element is stored.  It
2123 is passed the incoming value, and expected to return a transformed value.
2124
2125 =item * filter_fetch_key
2126
2127 This filter is called whenever a hash key is fetched (i.e. via
2128 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2129 and expected to return the plain key.
2130
2131 =item * filter_fetch_value
2132
2133 This filter is called whenever a hash key or array element is fetched.
2134 It is passed the transformed value, and expected to return the plain value.
2135
2136 =back
2137
2138 Here are the two ways to setup a filter hook:
2139
2140         my $db = DBM::Deep->new(
2141                 file => "foo.db",
2142                 filter_store_value => \&my_filter_store,
2143                 filter_fetch_value => \&my_filter_fetch
2144         );
2145
2146         # or...
2147
2148         $db->set_filter( "filter_store_value", \&my_filter_store );
2149         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2150
2151 Your filter function will be called only when dealing with SCALAR keys or
2152 values.  When nested hashes and arrays are being stored/fetched, filtering
2153 is bypassed.  Filters are called as static functions, passed a single SCALAR
2154 argument, and expected to return a single SCALAR value.  If you want to
2155 remove a filter, set the function reference to C<undef>:
2156
2157         $db->set_filter( "filter_store_value", undef );
2158
2159 =head2 REAL-TIME ENCRYPTION EXAMPLE
2160
2161 Here is a working example that uses the I<Crypt::Blowfish> module to
2162 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2163 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2164 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2165
2166         use DBM::Deep;
2167         use Crypt::Blowfish;
2168         use Crypt::CBC;
2169
2170         my $cipher = Crypt::CBC->new({
2171                 'key'             => 'my secret key',
2172                 'cipher'          => 'Blowfish',
2173                 'iv'              => '$KJh#(}q',
2174                 'regenerate_key'  => 0,
2175                 'padding'         => 'space',
2176                 'prepend_iv'      => 0
2177         });
2178
2179         my $db = DBM::Deep->new(
2180                 file => "foo-encrypt.db",
2181                 filter_store_key => \&my_encrypt,
2182                 filter_store_value => \&my_encrypt,
2183                 filter_fetch_key => \&my_decrypt,
2184                 filter_fetch_value => \&my_decrypt,
2185         );
2186
2187         $db->{key1} = "value1";
2188         $db->{key2} = "value2";
2189         print "key1: " . $db->{key1} . "\n";
2190         print "key2: " . $db->{key2} . "\n";
2191
2192         undef $db;
2193         exit;
2194
2195         sub my_encrypt {
2196                 return $cipher->encrypt( $_[0] );
2197         }
2198         sub my_decrypt {
2199                 return $cipher->decrypt( $_[0] );
2200         }
2201
2202 =head2 REAL-TIME COMPRESSION EXAMPLE
2203
2204 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2205 compression / decompression of keys & values with DBM::Deep Filters.
2206 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2207 more on I<Compress::Zlib>.
2208
2209         use DBM::Deep;
2210         use Compress::Zlib;
2211
2212         my $db = DBM::Deep->new(
2213                 file => "foo-compress.db",
2214                 filter_store_key => \&my_compress,
2215                 filter_store_value => \&my_compress,
2216                 filter_fetch_key => \&my_decompress,
2217                 filter_fetch_value => \&my_decompress,
2218         );
2219
2220         $db->{key1} = "value1";
2221         $db->{key2} = "value2";
2222         print "key1: " . $db->{key1} . "\n";
2223         print "key2: " . $db->{key2} . "\n";
2224
2225         undef $db;
2226         exit;
2227
2228         sub my_compress {
2229                 return Compress::Zlib::memGzip( $_[0] ) ;
2230         }
2231         sub my_decompress {
2232                 return Compress::Zlib::memGunzip( $_[0] ) ;
2233         }
2234
2235 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2236 actually numerical index numbers, and are not filtered.
2237
2238 =head1 ERROR HANDLING
2239
2240 Most DBM::Deep methods return a true value for success, and call die() on
2241 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2242 actual error message is stored in an internal scalar, which can be fetched by
2243 calling the C<error()> method.
2244
2245         my $db = DBM::Deep->new( "foo.db" ); # create hash
2246         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2247
2248         print $db->error(); # prints error message
2249
2250 You can then call C<clear_error()> to clear the current error state.
2251
2252         $db->clear_error();
2253
2254 If you set the C<debug> option to true when creating your DBM::Deep object,
2255 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2256 for debugging purposes.
2257
2258 =head1 LARGEFILE SUPPORT
2259
2260 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2261 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2262 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2263 by calling the static C<set_pack()> method before you do anything else.
2264
2265         DBM::Deep::set_pack(8, 'Q');
2266
2267 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2268 instead of 32-bit longs.  After setting these values your DB files have a
2269 theoretical maximum size of 16 XB (exabytes).
2270
2271
2272
2273 B<Note:> Changing these values will B<NOT> work for existing database files.
2274 Only change this for new files, and make sure it stays set consistently
2275 throughout the file's life.  If you do set these values, you can no longer
2276 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2277 back to 32-bit mode.
2278
2279
2280
2281 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2282 only a 32-bit Perl.  However, I have received user reports that this does
2283 indeed work!
2284
2285 =head1 LOW-LEVEL ACCESS
2286
2287 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2288 you can call the C<fh()> method, which returns the handle:
2289
2290         my $fh = $db->fh();
2291
2292 This method can be called on the root level of the datbase, or any child
2293 hashes or arrays.  All levels share a I<root> structure, which contains things
2294 like the FileHandle, a reference counter, and all your options you specified
2295 when you created the object.  You can get access to this root structure by
2296 calling the C<root()> method.
2297
2298         my $root = $db->root();
2299
2300 This is useful for changing options after the object has already been created,
2301 such as enabling/disabling locking, volatile or debug modes.  You can also
2302 store your own temporary user data in this structure (be wary of name
2303 collision), which is then accessible from any child hash or array.
2304
2305 =head1 CUSTOM DIGEST ALGORITHM
2306
2307 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2308 keys.  However you can override this, and use another algorithm (such as SHA-256)
2309 or even write your own.  But please note that DBM::Deep currently expects zero
2310 collisions, so your algorithm has to be I<perfect>, so to speak.
2311 Collision detection may be introduced in a later version.
2312
2313
2314
2315 You can specify a custom digest algorithm by calling the static C<set_digest()>
2316 function, passing a reference to a subroutine, and the length of the algorithm's
2317 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2318 objects.  Here is a working example that uses a 256-bit hash from the
2319 I<Digest::SHA256> module.  Please see
2320 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2321
2322         use DBM::Deep;
2323         use Digest::SHA256;
2324
2325         my $context = Digest::SHA256::new(256);
2326
2327         DBM::Deep::set_digest( \&my_digest, 32 );
2328
2329         my $db = DBM::Deep->new( "foo-sha.db" );
2330
2331         $db->{key1} = "value1";
2332         $db->{key2} = "value2";
2333         print "key1: " . $db->{key1} . "\n";
2334         print "key2: " . $db->{key2} . "\n";
2335
2336         undef $db;
2337         exit;
2338
2339         sub my_digest {
2340                 return substr( $context->hash($_[0]), 0, 32 );
2341         }
2342
2343 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2344 of bytes you specify in the C<set_digest()> function (in this case 32).
2345
2346 =head1 CIRCULAR REFERENCES
2347
2348 DBM::Deep has B<experimental> support for circular references.  Meaning you
2349 can have a nested hash key or array element that points to a parent object.
2350 This relationship is stored in the DB file, and is preserved between sessions.
2351 Here is an example:
2352
2353         my $db = DBM::Deep->new( "foo.db" );
2354
2355         $db->{foo} = "bar";
2356         $db->{circle} = $db; # ref to self
2357
2358         print $db->{foo} . "\n"; # prints "foo"
2359         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2360
2361 One catch is, passing the object to a function that recursively walks the
2362 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2363 C<export()> methods) will result in an infinite loop.  The other catch is,
2364 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2365 or C<next_key()> methods), you will get the I<target object's key>, not the
2366 ref's key.  This gets even more interesting with the above example, where
2367 the I<circle> key points to the base DB object, which technically doesn't
2368 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2369 special case.
2370
2371 =head1 CAVEATS / ISSUES / BUGS
2372
2373 This section describes all the known issues with DBM::Deep.  It you have found
2374 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2375
2376 =head2 UNUSED SPACE RECOVERY
2377
2378 One major caveat with DBM::Deep is that space occupied by existing keys and
2379 values is not recovered when they are deleted.  Meaning if you keep deleting
2380 and adding new keys, your file will continuously grow.  I am working on this,
2381 but in the meantime you can call the built-in C<optimize()> method from time to
2382 time (perhaps in a crontab or something) to recover all your unused space.
2383
2384         $db->optimize(); # returns true on success
2385
2386 This rebuilds the ENTIRE database into a new file, then moves it on top of
2387 the original.  The new file will have no unused space, thus it will take up as
2388 little disk space as possible.  Please note that this operation can take
2389 a long time for large files, and you need enough disk space to temporarily hold
2390 2 copies of your DB file.  The temporary file is created in the same directory
2391 as the original, named with a ".tmp" extension, and is deleted when the
2392 operation completes.  Oh, and if locking is enabled, the DB is automatically
2393 locked for the entire duration of the copy.
2394
2395
2396
2397 B<WARNING:> Only call optimize() on the top-level node of the database, and
2398 make sure there are no child references lying around.  DBM::Deep keeps a reference
2399 counter, and if it is greater than 1, optimize() will abort and return undef.
2400
2401 =head2 AUTOVIVIFICATION
2402
2403 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2404 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2405 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2406 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2407 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2408 this does not work:
2409
2410         $db->{foo}->{bar} = "hello";
2411
2412 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2413 being an empty hash.  Try this instead, which works fine:
2414
2415         $db->{foo} = { bar => "hello" };
2416
2417 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2418 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2419 Probably a bug in Perl.
2420
2421 =head2 FILE CORRUPTION
2422
2423 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2424 for a 32-bit signature when opened, but other corruption in files can cause
2425 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2426 stuck in an infinite loop depending on the level of corruption.  File write
2427 operations are not checked for failure (for speed), so if you happen to run
2428 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2429 be addressed in a later version of DBM::Deep.
2430
2431 =head2 DB OVER NFS
2432
2433 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2434 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2435 about setting up your NFS server with a locking daemon, then using lockf() to
2436 lock your files, but your milage may vary there as well.  From what I
2437 understand, there is no real way to do it.  However, if you need access to the
2438 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2439 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2440
2441 =head2 COPYING OBJECTS
2442
2443 Beware of copying tied objects in Perl.  Very strange things can happen.
2444 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2445 returns a new, blessed, tied hash or array to the same level in the DB.
2446
2447         my $copy = $db->clone();
2448
2449 =head2 LARGE ARRAYS
2450
2451 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2452 These functions cause every element in the array to move, which can be murder
2453 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2454 a different location.  This may be addressed in a later version.
2455
2456 =head1 PERFORMANCE
2457
2458 This section discusses DBM::Deep's speed and memory usage.
2459
2460 =head2 SPEED
2461
2462 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2463 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2464 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2465 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2466 with huge databases.  Here is some test data:
2467
2468         Adding 1,000,000 keys to new DB file...
2469
2470         At 100 keys, avg. speed is 2,703 keys/sec
2471         At 200 keys, avg. speed is 2,642 keys/sec
2472         At 300 keys, avg. speed is 2,598 keys/sec
2473         At 400 keys, avg. speed is 2,578 keys/sec
2474         At 500 keys, avg. speed is 2,722 keys/sec
2475         At 600 keys, avg. speed is 2,628 keys/sec
2476         At 700 keys, avg. speed is 2,700 keys/sec
2477         At 800 keys, avg. speed is 2,607 keys/sec
2478         At 900 keys, avg. speed is 2,190 keys/sec
2479         At 1,000 keys, avg. speed is 2,570 keys/sec
2480         At 2,000 keys, avg. speed is 2,417 keys/sec
2481         At 3,000 keys, avg. speed is 1,982 keys/sec
2482         At 4,000 keys, avg. speed is 1,568 keys/sec
2483         At 5,000 keys, avg. speed is 1,533 keys/sec
2484         At 6,000 keys, avg. speed is 1,787 keys/sec
2485         At 7,000 keys, avg. speed is 1,977 keys/sec
2486         At 8,000 keys, avg. speed is 2,028 keys/sec
2487         At 9,000 keys, avg. speed is 2,077 keys/sec
2488         At 10,000 keys, avg. speed is 2,031 keys/sec
2489         At 20,000 keys, avg. speed is 1,970 keys/sec
2490         At 30,000 keys, avg. speed is 2,050 keys/sec
2491         At 40,000 keys, avg. speed is 2,073 keys/sec
2492         At 50,000 keys, avg. speed is 1,973 keys/sec
2493         At 60,000 keys, avg. speed is 1,914 keys/sec
2494         At 70,000 keys, avg. speed is 2,091 keys/sec
2495         At 80,000 keys, avg. speed is 2,103 keys/sec
2496         At 90,000 keys, avg. speed is 1,886 keys/sec
2497         At 100,000 keys, avg. speed is 1,970 keys/sec
2498         At 200,000 keys, avg. speed is 2,053 keys/sec
2499         At 300,000 keys, avg. speed is 1,697 keys/sec
2500         At 400,000 keys, avg. speed is 1,838 keys/sec
2501         At 500,000 keys, avg. speed is 1,941 keys/sec
2502         At 600,000 keys, avg. speed is 1,930 keys/sec
2503         At 700,000 keys, avg. speed is 1,735 keys/sec
2504         At 800,000 keys, avg. speed is 1,795 keys/sec
2505         At 900,000 keys, avg. speed is 1,221 keys/sec
2506         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2507
2508 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2509 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2510 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2511 Run time was 12 min 3 sec.
2512
2513 =head2 MEMORY USAGE
2514
2515 One of the great things about DBM::Deep is that it uses very little memory.
2516 Even with huge databases (1,000,000+ keys) you will not see much increased
2517 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2518 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2519 database handle:
2520
2521           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2522         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2523
2524 Basically the process is taking 2,716K of memory.  And here is the same
2525 process after storing and fetching 1,000,000 keys:
2526
2527           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2528         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2529
2530 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2531 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2532
2533 =head1 DB FILE FORMAT
2534
2535 In case you were interested in the underlying DB file format, it is documented
2536 here in this section.  You don't need to know this to use the module, it's just
2537 included for reference.
2538
2539 =head2 SIGNATURE
2540
2541 DBM::Deep files always start with a 32-bit signature to identify the file type.
2542 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2543 checked when the file is opened.
2544
2545 =head2 TAG
2546
2547 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2548 has a standard header containing the type of data, the length of data, and then
2549 the data itself.  The type is a single character (1 byte), the length is a
2550 32-bit unsigned long in network byte order, and the data is, well, the data.
2551 Here is how it unfolds:
2552
2553 =head2 MASTER INDEX
2554
2555 Immediately after the 32-bit file signature is the I<Master Index> record.
2556 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2557 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2558 depending on how the DBM::Deep object was constructed.
2559
2560
2561
2562 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2563 number).  The first 8-bit char of the MD5 signature is the offset into the
2564 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2565 index element is a file offset of the next tag for the key/element in question,
2566 which is usually a I<Bucket List> tag (see below).
2567
2568
2569
2570 The next tag I<could> be another index, depending on how many keys/elements
2571 exist.  See L<RE-INDEXING> below for details.
2572
2573 =head2 BUCKET LIST
2574
2575 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2576 file offsets to where the actual data is stored.  It starts with a standard
2577 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2578 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2579 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2580 When the list fills up, a I<Re-Index> operation is performed (See
2581 L<RE-INDEXING> below).
2582
2583 =head2 BUCKET
2584
2585 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2586 index/value pair (in array mode).  It starts with a standard tag header with
2587 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2588 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2589 header.  The size reported in the tag header is only for the value, but then,
2590 just after the value is another size (32-bit unsigned long) and then the plain
2591 key itself.  Since the value is likely to be fetched more often than the plain
2592 key, I figured it would be I<slightly> faster to store the value first.
2593
2594
2595
2596 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2597 record for the nested structure, where the process begins all over again.
2598
2599 =head2 RE-INDEXING
2600
2601 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2602 exhausted.  Then, when another key/element comes in, the list is converted to a
2603 new index record.  However, this index will look at the next char in the MD5
2604 hash, and arrange new Bucket List pointers accordingly.  This process is called
2605 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2606 17 (16 + new one) keys/elements are removed from the old Bucket List and
2607 inserted into the new index.  Several new Bucket Lists are created in the
2608 process, as a new MD5 char from the key is being examined (it is unlikely that
2609 the keys will all share the same next char of their MD5s).
2610
2611
2612
2613 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2614 when the Bucket Lists will turn into indexes, but the first round tends to
2615 happen right around 4,000 keys.  You will see a I<slight> decrease in
2616 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2617 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2618 right around 900,000 keys.  This process can continue nearly indefinitely --
2619 right up until the point the I<MD5> signatures start colliding with each other,
2620 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2621 getting struck by lightning while you are walking to cash in your tickets.
2622 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2623 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2624 this is 340 unodecillion, but don't quote me).
2625
2626 =head2 STORING
2627
2628 When a new key/element is stored, the key (or index number) is first ran through
2629 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2630 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2631 for the first char of the signature (in this case I<b>).  If it does not exist,
2632 a new I<Bucket List> is created for our key (and the next 15 future keys that
2633 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2634 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2635 this point, unless we are replacing an existing I<Bucket>), where the actual
2636 data will be stored.
2637
2638 =head2 FETCHING
2639
2640 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2641 (or index number), then walking along the indexes.  If there are enough
2642 keys/elements in this DB level, there might be nested indexes, each linked to
2643 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2644 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2645 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2646 plain key are stored.
2647
2648
2649
2650 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2651 methods.  In this process the indexes are walked systematically, and each key
2652 fetched in increasing MD5 order (which is why it appears random).   Once the
2653 I<Bucket> is found, the value is skipped the plain key returned instead.
2654 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2655 alphabetically sorted.  This only happens on an index-level -- as soon as the
2656 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2657 so it's pretty much undefined how the keys will come out -- just like Perl's
2658 built-in hashes.
2659
2660 =head1 CODE COVERAGE
2661
2662 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2663 module's test suite.
2664
2665   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2666   File                           stmt   bran   cond    sub    pod   time  total
2667   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2668   blib/lib/DBM/Deep.pm           94.1   82.9   74.5   98.0   10.5   98.1   88.2
2669   blib/lib/DBM/Deep/Array.pm     97.8   83.3   50.0  100.0    n/a    1.6   94.4
2670   blib/lib/DBM/Deep/Hash.pm      93.3   85.7  100.0  100.0    n/a    0.3   92.7
2671   Total                          94.5   83.1   75.5   98.4   10.5  100.0   89.0
2672   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2673
2674 =head1 AUTHOR
2675
2676 Joseph Huckaby, L<jhuckaby@cpan.org>
2677
2678 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2679
2680 =head1 SEE ALSO
2681
2682 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2683 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2684
2685 =head1 LICENSE
2686
2687 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2688 This is free software, you may use it and distribute it under the
2689 same terms as Perl itself.
2690
2691 =cut