lib/DBM/Deep.pm

   1 package DBM::Deep;
   2
   3 ##
   4 # DBM::Deep
   5 #
   6 # Description:
   7 #       Multi-level database module for storing hash trees, arrays and simple
   8 #       key/value pairs into FTP-able, cross-platform binary database files.
   9 #
  10 #       Type `perldoc DBM::Deep` for complete documentation.
  11 #
  12 # Usage Examples:
  13 #       my %db;
  14 #       tie %db, 'DBM::Deep', 'my_database.db'; # standard tie() method
  15 #
  16 #       my $db = new DBM::Deep( 'my_database.db' ); # preferred OO method
  17 #
  18 #       $db->{my_scalar} = 'hello world';
  19 #       $db->{my_hash} = { larry => 'genius', hashes => 'fast' };
  20 #       $db->{my_array} = [ 1, 2, 3, time() ];
  21 #       $db->{my_complex} = [ 'hello', { perl => 'rules' }, 42, 99 ];
  22 #       push @{$db->{my_array}}, 'another value';
  23 #       my @key_list = keys %{$db->{my_hash}};
  24 #       print "This module " . $db->{my_complex}->[1]->{perl} . "!\n";
  25 #
  26 # Copyright:
  27 #       (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
  28 #       This program is free software; you can redistribute it and/or
  29 #       modify it under the same terms as Perl itself.
  30 ##
  31
  32 use strict;
  33
  34 use Fcntl qw( :DEFAULT :flock :seek );
  35 use Digest::MD5 ();
  36 use Scalar::Util ();
  37
  38 use vars qw( $VERSION );
  39 $VERSION = q(0.96);
  40
  41 ##
  42 # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4 GB per file.
  43 #       (Perl must be compiled with largefile support for files > 2 GB)
  44 #
  45 # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46 #       (Perl must be compiled with largefile and 64-bit long support)
  47 ##
  48 #my $LONG_SIZE = 4;
  49 #my $LONG_PACK = 'N';
  50
  51 ##
  52 # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each key/value.
  53 # Upgrading this is possible (see above) but probably not necessary.  If you need
  54 # more than 4 GB for a single key or value, this module is really not for you :-)
  55 ##
  56 #my $DATA_LENGTH_SIZE = 4;
  57 #my $DATA_LENGTH_PACK = 'N';
  58 our ($LONG_SIZE, $LONG_PACK, $DATA_LENGTH_SIZE, $DATA_LENGTH_PACK);
  59
  60 ##
  61 # Maximum number of buckets per list before another level of indexing is done.
  62 # Increase this value for slightly greater speed, but larger database files.
  63 # DO NOT decrease this value below 16, due to risk of recursive reindex overrun.
  64 ##
  65 my $MAX_BUCKETS = 16;
  66
  67 ##
  68 # Better not adjust anything below here, unless you're me :-)
  69 ##
  70
  71 ##
  72 # Setup digest function for keys
  73 ##
  74 our ($DIGEST_FUNC, $HASH_SIZE);
  75 #my $DIGEST_FUNC = \&Digest::MD5::md5;
  76
  77 ##
  78 # Precalculate index and bucket sizes based on values above.
  79 ##
  80 #my $HASH_SIZE = 16;
  81 my ($INDEX_SIZE, $BUCKET_SIZE, $BUCKET_LIST_SIZE);
  82
  83 set_digest();
  84 #set_pack();
  85 #precalc_sizes();
  86
  87 ##
  88 # Setup file and tag signatures.  These should never change.
  89 ##
  90 sub SIG_FILE   () { 'DPDB' }
  91 sub SIG_HASH   () { 'H' }
  92 sub SIG_ARRAY  () { 'A' }
  93 sub SIG_SCALAR () { 'S' }
  94 sub SIG_NULL   () { 'N' }
  95 sub SIG_DATA   () { 'D' }
  96 sub SIG_INDEX  () { 'I' }
  97 sub SIG_BLIST  () { 'B' }
  98 sub SIG_SIZE   () {  1  }
  99
 100 ##
 101 # Setup constants for users to pass to new()
 102 ##
 103 sub TYPE_HASH   () { return SIG_HASH; }
 104 sub TYPE_ARRAY  () { return SIG_ARRAY; }
 105 sub TYPE_SCALAR () { return SIG_SCALAR; }
 106
 107 sub new {
 108         ##
 109         # Class constructor method for Perl OO interface.
 110         # Calls tie() and returns blessed reference to tied hash or array,
 111         # providing a hybrid OO/tie interface.
 112         ##
 113         my $class = shift;
 114         my $args;
 115         if (scalar(@_) > 1) { $args = {@_}; }
 116         else { $args = { file => shift }; }
 117
 118         ##
 119         # Check if we want a tied hash or array.
 120         ##
 121         my $self;
 122         if (defined($args->{type}) && $args->{type} eq TYPE_ARRAY) {
 123         $class = 'DBM::Deep::Array';
 124         require DBM::Deep::Array;
 125                 tie @$self, $class, %$args;
 126         }
 127         else {
 128         $class = 'DBM::Deep::Hash';
 129         require DBM::Deep::Hash;
 130                 tie %$self, $class, %$args;
 131         }
 132
 133         return bless $self, $class;
 134 }
 135
 136 sub _init {
 137     ##
 138     # Setup $self and bless into this class.
 139     ##
 140     my $class = shift;
 141     my $args = shift;
 142
 143     # These are the defaults to be optionally overridden below
 144     my $self = bless {
 145         type => TYPE_HASH,
 146         base_offset => length(SIG_FILE),
 147     }, $class;
 148
 149     foreach my $param ( keys %$self ) {
 150         next unless exists $args->{$param};
 151         $self->{$param} = delete $args->{$param}
 152     }
 153
 154     $self->{root} = exists $args->{root}
 155         ? $args->{root}
 156         : DBM::Deep::_::Root->new( $args );
 157
 158     if (!defined($self->fh)) { $self->_open(); }
 159
 160     return $self;
 161 }
 162
 163 sub TIEHASH {
 164     shift;
 165     require DBM::Deep::Hash;
 166     return DBM::Deep::Hash->TIEHASH( @_ );
 167 }
 168
 169 sub TIEARRAY {
 170     shift;
 171     require DBM::Deep::Array;
 172     return DBM::Deep::Array->TIEARRAY( @_ );
 173 }
 174
 175 #XXX Unneeded now ...
 176 #sub DESTROY {
 177 #}
 178
 179 sub _open {
 180         ##
 181         # Open a FileHandle to the database, create if nonexistent.
 182         # Make sure file signature matches DeepDB spec.
 183         ##
 184     my $self = $_[0]->_get_self;
 185
 186         if (defined($self->fh)) { $self->_close(); }
 187
 188     eval {
 189         # Theoretically, adding O_BINARY should remove the need for the binmode
 190         # Of course, testing it is going to be ... interesting.
 191         my $flags = O_RDWR | O_CREAT | O_BINARY;
 192
 193         #XXX Can the mode be anything but r+, w+, or a+??
 194         #XXX ie, it has to be in read-write mode
 195         #XXX So, should we verify that the mode is legitimate?
 196
 197         #XXX Maybe the mode thingy should just go away. There's no good
 198         #XXX reason for it ...
 199         if ( $self->root->{mode} eq 'w+' ) {
 200             $flags |= O_TRUNC;
 201         }
 202
 203         my $fh;
 204         sysopen( $fh, $self->root->{file}, $flags )
 205             or $fh = undef;
 206         $self->root->{fh} = $fh;
 207     }; if ($@ ) { $self->_throw_error( "Received error: $@\n" ); }
 208         if (! defined($self->fh)) {
 209                 return $self->_throw_error("Cannot sysopen file: " . $self->root->{file} . ": $!");
 210         }
 211
 212     my $fh = $self->fh;
 213
 214     #XXX Can we remove this by using the right sysopen() flags?
 215     # Maybe ... q.v. above
 216     binmode $fh; # for win32
 217
 218     if ($self->root->{autoflush}) {
 219         my $old = select $fh;
 220         $|=1;
 221         select $old;
 222     }
 223
 224     # Set the
 225     seek($fh, 0, SEEK_SET);
 226
 227     my $signature;
 228     my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 229
 230     ##
 231     # File is empty -- write signature and master index
 232     ##
 233     if (!$bytes_read) {
 234         seek($fh, 0, SEEK_SET);
 235         print($fh SIG_FILE);
 236         $self->root->{end} = length(SIG_FILE);
 237         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
 238
 239         my $plain_key = "[base]";
 240         print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 241         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 242
 243         # Flush the filehandle
 244         my $old_fh = select $fh;
 245         my $old_af = $|;
 246         $| = 1;
 247         $| = $old_af;
 248         select $old_fh;
 249
 250         return 1;
 251     }
 252
 253     ##
 254     # Check signature was valid
 255     ##
 256     unless ($signature eq SIG_FILE) {
 257         $self->_close();
 258         return $self->_throw_error("Signature not found -- file is not a Deep DB");
 259     }
 260
 261     $self->root->{end} = (stat($fh))[7];
 262
 263     ##
 264     # Get our type from master index signature
 265     ##
 266     my $tag = $self->_load_tag($self->base_offset);
 267
 268 #XXX We probably also want to store the hash algorithm name and not assume anything
 269 #XXX The cool thing would be to allow a different hashing algorithm at every level
 270
 271     if (!$tag) {
 272         return $self->_throw_error("Corrupted file, no master index record");
 273     }
 274     if ($self->{type} ne $tag->{signature}) {
 275         return $self->_throw_error("File type mismatch");
 276     }
 277
 278     return 1;
 279 }
 280
 281 sub _close {
 282         ##
 283         # Close database FileHandle
 284         ##
 285     my $self = $_[0]->_get_self;
 286     close $self->root->{fh};
 287     $self->root->{fh} = undef;
 288 }
 289
 290 sub _create_tag {
 291         ##
 292         # Given offset, signature and content, create tag and write to disk
 293         ##
 294         my ($self, $offset, $sig, $content) = @_;
 295         my $size = length($content);
 296
 297     my $fh = $self->fh;
 298
 299         seek($fh, $offset, SEEK_SET);
 300         print($fh $sig . pack($DATA_LENGTH_PACK, $size) . $content );
 301
 302         if ($offset == $self->root->{end}) {
 303                 $self->root->{end} += SIG_SIZE + $DATA_LENGTH_SIZE + $size;
 304         }
 305
 306         return {
 307                 signature => $sig,
 308                 size => $size,
 309                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 310                 content => $content
 311         };
 312 }
 313
 314 sub _load_tag {
 315         ##
 316         # Given offset, load single tag and return signature, size and data
 317         ##
 318         my $self = shift;
 319         my $offset = shift;
 320
 321     my $fh = $self->fh;
 322
 323         seek($fh, $offset, SEEK_SET);
 324         if (eof $fh) { return undef; }
 325
 326         my $sig;
 327         read( $fh, $sig, SIG_SIZE);
 328
 329         my $size;
 330         read( $fh, $size, $DATA_LENGTH_SIZE);
 331         $size = unpack($DATA_LENGTH_PACK, $size);
 332
 333         my $buffer;
 334         read( $fh, $buffer, $size);
 335
 336         return {
 337                 signature => $sig,
 338                 size => $size,
 339                 offset => $offset + SIG_SIZE + $DATA_LENGTH_SIZE,
 340                 content => $buffer
 341         };
 342 }
 343
 344 sub _index_lookup {
 345         ##
 346         # Given index tag, lookup single entry in index and return .
 347         ##
 348         my $self = shift;
 349         my ($tag, $index) = @_;
 350
 351         my $location = unpack($LONG_PACK, substr($tag->{content}, $index * $LONG_SIZE, $LONG_SIZE) );
 352         if (!$location) { return; }
 353
 354         return $self->_load_tag( $location );
 355 }
 356
 357 sub _add_bucket {
 358         ##
 359         # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 360         # plain (undigested) key and value.
 361         ##
 362         my $self = shift;
 363         my ($tag, $md5, $plain_key, $value) = @_;
 364         my $keys = $tag->{content};
 365         my $location = 0;
 366         my $result = 2;
 367
 368     my $is_dbm_deep = eval { $value->isa( 'DBM::Deep' ) };
 369         my $internal_ref = $is_dbm_deep && ($value->root eq $self->root);
 370
 371     my $fh = $self->fh;
 372
 373         ##
 374         # Iterate through buckets, seeing if this is a new entry or a replace.
 375         ##
 376         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 377                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 378                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 379                 if (!$subloc) {
 380                         ##
 381                         # Found empty bucket (end of list).  Populate and exit loop.
 382                         ##
 383                         $result = 2;
 384
 385             $location = $internal_ref
 386                 ? $value->base_offset
 387                 : $self->root->{end};
 388
 389                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 390                         print($fh $md5 . pack($LONG_PACK, $location) );
 391                         last;
 392                 }
 393                 elsif ($md5 eq $key) {
 394                         ##
 395                         # Found existing bucket with same key.  Replace with new value.
 396                         ##
 397                         $result = 1;
 398
 399                         if ($internal_ref) {
 400                                 $location = $value->base_offset;
 401                                 seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 402                                 print($fh $md5 . pack($LONG_PACK, $location) );
 403                         }
 404                         else {
 405                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 406                                 my $size;
 407                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 408
 409                                 ##
 410                                 # If value is a hash, array, or raw value with equal or less size, we can
 411                                 # reuse the same content area of the database.  Otherwise, we have to create
 412                                 # a new content area at the EOF.
 413                                 ##
 414                                 my $actual_length;
 415                 my $r = Scalar::Util::reftype( $value ) || '';
 416                 if ( $r eq 'HASH' || $r eq 'ARRAY' ) { $actual_length = $INDEX_SIZE; }
 417                                 else { $actual_length = length($value); }
 418
 419                                 if ($actual_length <= $size) {
 420                                         $location = $subloc;
 421                                 }
 422                                 else {
 423                                         $location = $self->root->{end};
 424                                         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE) + $HASH_SIZE, SEEK_SET);
 425                                         print($fh pack($LONG_PACK, $location) );
 426                                 }
 427                         }
 428                         last;
 429                 }
 430         } # i loop
 431
 432         ##
 433         # If this is an internal reference, return now.
 434         # No need to write value or plain key
 435         ##
 436         if ($internal_ref) {
 437         return $result;
 438     }
 439
 440         ##
 441         # If bucket didn't fit into list, split into a new index level
 442         ##
 443         if (!$location) {
 444                 seek($fh, $tag->{ref_loc}, SEEK_SET);
 445                 print($fh pack($LONG_PACK, $self->root->{end}) );
 446
 447                 my $index_tag = $self->_create_tag($self->root->{end}, SIG_INDEX, chr(0) x $INDEX_SIZE);
 448                 my @offsets = ();
 449
 450                 $keys .= $md5 . pack($LONG_PACK, 0);
 451
 452                 for (my $i=0; $i<=$MAX_BUCKETS; $i++) {
 453                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 454                         if ($key) {
 455                                 my $old_subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 456                                 my $num = ord(substr($key, $tag->{ch} + 1, 1));
 457
 458                                 if ($offsets[$num]) {
 459                                         my $offset = $offsets[$num] + SIG_SIZE + $DATA_LENGTH_SIZE;
 460                                         seek($fh, $offset, SEEK_SET);
 461                                         my $subkeys;
 462                                         read( $fh, $subkeys, $BUCKET_LIST_SIZE);
 463
 464                                         for (my $k=0; $k<$MAX_BUCKETS; $k++) {
 465                                                 my $subloc = unpack($LONG_PACK, substr($subkeys, ($k * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 466                                                 if (!$subloc) {
 467                                                         seek($fh, $offset + ($k * $BUCKET_SIZE), SEEK_SET);
 468                                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 469                                                         last;
 470                                                 }
 471                                         } # k loop
 472                                 }
 473                                 else {
 474                                         $offsets[$num] = $self->root->{end};
 475                                         seek($fh, $index_tag->{offset} + ($num * $LONG_SIZE), SEEK_SET);
 476                                         print($fh pack($LONG_PACK, $self->root->{end}) );
 477
 478                                         my $blist_tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
 479
 480                                         seek($fh, $blist_tag->{offset}, SEEK_SET);
 481                                         print($fh $key . pack($LONG_PACK, $old_subloc || $self->root->{end}) );
 482                                 }
 483                         } # key is real
 484                 } # i loop
 485
 486                 $location ||= $self->root->{end};
 487         } # re-index bucket list
 488
 489         ##
 490         # Seek to content area and store signature, value and plaintext key
 491         ##
 492         if ($location) {
 493                 my $content_length;
 494                 seek($fh, $location, SEEK_SET);
 495
 496                 ##
 497                 # Write signature based on content type, set content length and write actual value.
 498                 ##
 499         my $r = Scalar::Util::reftype($value) || '';
 500                 if ($r eq 'HASH') {
 501                         print($fh TYPE_HASH );
 502                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 503                         $content_length = $INDEX_SIZE;
 504                 }
 505                 elsif ($r eq 'ARRAY') {
 506                         print($fh TYPE_ARRAY );
 507                         print($fh pack($DATA_LENGTH_PACK, $INDEX_SIZE) . chr(0) x $INDEX_SIZE );
 508                         $content_length = $INDEX_SIZE;
 509                 }
 510                 elsif (!defined($value)) {
 511                         print($fh SIG_NULL );
 512                         print($fh pack($DATA_LENGTH_PACK, 0) );
 513                         $content_length = 0;
 514                 }
 515                 else {
 516                         print($fh SIG_DATA );
 517                         print($fh pack($DATA_LENGTH_PACK, length($value)) . $value );
 518                         $content_length = length($value);
 519                 }
 520
 521                 ##
 522                 # Plain key is stored AFTER value, as keys are typically fetched less often.
 523                 ##
 524                 print($fh pack($DATA_LENGTH_PACK, length($plain_key)) . $plain_key );
 525
 526                 ##
 527                 # If value is blessed, preserve class name
 528                 ##
 529                 if ( $self->root->{autobless} ) {
 530             my $value_class = Scalar::Util::blessed($value);
 531             if ( defined $value_class && $value_class ne 'DBM::Deep' ) {
 532                 ##
 533                 # Blessed ref -- will restore later
 534                 ##
 535                 print($fh chr(1) );
 536                 print($fh pack($DATA_LENGTH_PACK, length($value_class)) . $value_class );
 537                 $content_length += 1;
 538                 $content_length += $DATA_LENGTH_SIZE + length($value_class);
 539             }
 540             else {
 541                 print($fh chr(0) );
 542                 $content_length += 1;
 543             }
 544         }
 545
 546                 ##
 547                 # If this is a new content area, advance EOF counter
 548                 ##
 549                 if ($location == $self->root->{end}) {
 550                         $self->root->{end} += SIG_SIZE;
 551                         $self->root->{end} += $DATA_LENGTH_SIZE + $content_length;
 552                         $self->root->{end} += $DATA_LENGTH_SIZE + length($plain_key);
 553                 }
 554
 555                 ##
 556                 # If content is a hash or array, create new child DeepDB object and
 557                 # pass each key or element to it.
 558                 ##
 559                 if ($r eq 'HASH') {
 560                         my $branch = DBM::Deep->new(
 561                                 type => TYPE_HASH,
 562                                 base_offset => $location,
 563                                 root => $self->root,
 564                         );
 565                         foreach my $key (keys %{$value}) {
 566                 #$branch->{$key} = $value->{$key};
 567                 $branch->STORE( $key, $value->{$key} );
 568                         }
 569                 }
 570                 elsif ($r eq 'ARRAY') {
 571                         my $branch = DBM::Deep->new(
 572                                 type => TYPE_ARRAY,
 573                                 base_offset => $location,
 574                                 root => $self->root,
 575                         );
 576                         my $index = 0;
 577                         foreach my $element (@{$value}) {
 578                 #$branch->[$index] = $element;
 579                 $branch->STORE( $index, $element );
 580                                 $index++;
 581                         }
 582                 }
 583
 584                 return $result;
 585         }
 586
 587         return $self->_throw_error("Fatal error: indexing failed -- possibly due to corruption in file");
 588 }
 589
 590 sub _get_bucket_value {
 591         ##
 592         # Fetch single value given tag and MD5 digested key.
 593         ##
 594         my $self = shift;
 595         my ($tag, $md5) = @_;
 596         my $keys = $tag->{content};
 597
 598     my $fh = $self->fh;
 599
 600         ##
 601         # Iterate through buckets, looking for a key match
 602         ##
 603     BUCKET:
 604         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 605                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 606                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 607
 608                 if (!$subloc) {
 609                         ##
 610                         # Hit end of list, no match
 611                         ##
 612                         return;
 613                 }
 614
 615         if ( $md5 ne $key ) {
 616             next BUCKET;
 617         }
 618
 619         ##
 620         # Found match -- seek to offset and read signature
 621         ##
 622         my $signature;
 623         seek($fh, $subloc, SEEK_SET);
 624         read( $fh, $signature, SIG_SIZE);
 625
 626         ##
 627         # If value is a hash or array, return new DeepDB object with correct offset
 628         ##
 629         if (($signature eq TYPE_HASH) || ($signature eq TYPE_ARRAY)) {
 630             my $obj = DBM::Deep->new(
 631                 type => $signature,
 632                 base_offset => $subloc,
 633                 root => $self->root
 634             );
 635
 636             if ($self->root->{autobless}) {
 637                 ##
 638                 # Skip over value and plain key to see if object needs
 639                 # to be re-blessed
 640                 ##
 641                 seek($fh, $DATA_LENGTH_SIZE + $INDEX_SIZE, SEEK_CUR);
 642
 643                 my $size;
 644                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 645                 if ($size) { seek($fh, $size, SEEK_CUR); }
 646
 647                 my $bless_bit;
 648                 read( $fh, $bless_bit, 1);
 649                 if (ord($bless_bit)) {
 650                     ##
 651                     # Yes, object needs to be re-blessed
 652                     ##
 653                     my $class_name;
 654                     read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 655                     if ($size) { read( $fh, $class_name, $size); }
 656                     if ($class_name) { $obj = bless( $obj, $class_name ); }
 657                 }
 658             }
 659
 660             return $obj;
 661         }
 662
 663         ##
 664         # Otherwise return actual value
 665         ##
 666         elsif ($signature eq SIG_DATA) {
 667             my $size;
 668             my $value = '';
 669             read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 670             if ($size) { read( $fh, $value, $size); }
 671             return $value;
 672         }
 673
 674         ##
 675         # Key exists, but content is null
 676         ##
 677         else { return; }
 678         } # i loop
 679
 680         return;
 681 }
 682
 683 sub _delete_bucket {
 684         ##
 685         # Delete single key/value pair given tag and MD5 digested key.
 686         ##
 687         my $self = shift;
 688         my ($tag, $md5) = @_;
 689         my $keys = $tag->{content};
 690
 691     my $fh = $self->fh;
 692
 693         ##
 694         # Iterate through buckets, looking for a key match
 695         ##
 696     BUCKET:
 697         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 698                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 699                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 700
 701                 if (!$subloc) {
 702                         ##
 703                         # Hit end of list, no match
 704                         ##
 705                         return;
 706                 }
 707
 708         if ( $md5 ne $key ) {
 709             next BUCKET;
 710         }
 711
 712         ##
 713         # Matched key -- delete bucket and return
 714         ##
 715         seek($fh, $tag->{offset} + ($i * $BUCKET_SIZE), SEEK_SET);
 716         print($fh substr($keys, ($i+1) * $BUCKET_SIZE ) );
 717         print($fh chr(0) x $BUCKET_SIZE );
 718
 719         return 1;
 720         } # i loop
 721
 722         return;
 723 }
 724
 725 sub _bucket_exists {
 726         ##
 727         # Check existence of single key given tag and MD5 digested key.
 728         ##
 729         my $self = shift;
 730         my ($tag, $md5) = @_;
 731         my $keys = $tag->{content};
 732
 733         ##
 734         # Iterate through buckets, looking for a key match
 735         ##
 736     BUCKET:
 737         for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 738                 my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 739                 my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 740
 741                 if (!$subloc) {
 742                         ##
 743                         # Hit end of list, no match
 744                         ##
 745                         return;
 746                 }
 747
 748         if ( $md5 ne $key ) {
 749             next BUCKET;
 750         }
 751
 752         ##
 753         # Matched key -- return true
 754         ##
 755         return 1;
 756         } # i loop
 757
 758         return;
 759 }
 760
 761 sub _find_bucket_list {
 762         ##
 763         # Locate offset for bucket list, given digested key
 764         ##
 765         my $self = shift;
 766         my $md5 = shift;
 767
 768         ##
 769         # Locate offset for bucket list using digest index system
 770         ##
 771         my $ch = 0;
 772         my $tag = $self->_load_tag($self->base_offset);
 773         if (!$tag) { return; }
 774
 775         while ($tag->{signature} ne SIG_BLIST) {
 776                 $tag = $self->_index_lookup($tag, ord(substr($md5, $ch, 1)));
 777                 if (!$tag) { return; }
 778                 $ch++;
 779         }
 780
 781         return $tag;
 782 }
 783
 784 sub _traverse_index {
 785         ##
 786         # Scan index and recursively step into deeper levels, looking for next key.
 787         ##
 788     my ($self, $offset, $ch, $force_return_next) = @_;
 789     $force_return_next = undef unless $force_return_next;
 790
 791         my $tag = $self->_load_tag( $offset );
 792
 793     my $fh = $self->fh;
 794
 795         if ($tag->{signature} ne SIG_BLIST) {
 796                 my $content = $tag->{content};
 797                 my $start;
 798                 if ($self->{return_next}) { $start = 0; }
 799                 else { $start = ord(substr($self->{prev_md5}, $ch, 1)); }
 800
 801                 for (my $index = $start; $index < 256; $index++) {
 802                         my $subloc = unpack($LONG_PACK, substr($content, $index * $LONG_SIZE, $LONG_SIZE) );
 803                         if ($subloc) {
 804                                 my $result = $self->_traverse_index( $subloc, $ch + 1, $force_return_next );
 805                                 if (defined($result)) { return $result; }
 806                         }
 807                 } # index loop
 808
 809                 $self->{return_next} = 1;
 810         } # tag is an index
 811
 812         elsif ($tag->{signature} eq SIG_BLIST) {
 813                 my $keys = $tag->{content};
 814                 if ($force_return_next) { $self->{return_next} = 1; }
 815
 816                 ##
 817                 # Iterate through buckets, looking for a key match
 818                 ##
 819                 for (my $i=0; $i<$MAX_BUCKETS; $i++) {
 820                         my $key = substr($keys, $i * $BUCKET_SIZE, $HASH_SIZE);
 821                         my $subloc = unpack($LONG_PACK, substr($keys, ($i * $BUCKET_SIZE) + $HASH_SIZE, $LONG_SIZE));
 822
 823                         if (!$subloc) {
 824                                 ##
 825                                 # End of bucket list -- return to outer loop
 826                                 ##
 827                                 $self->{return_next} = 1;
 828                                 last;
 829                         }
 830                         elsif ($key eq $self->{prev_md5}) {
 831                                 ##
 832                                 # Located previous key -- return next one found
 833                                 ##
 834                                 $self->{return_next} = 1;
 835                                 next;
 836                         }
 837                         elsif ($self->{return_next}) {
 838                                 ##
 839                                 # Seek to bucket location and skip over signature
 840                                 ##
 841                                 seek($fh, $subloc + SIG_SIZE, SEEK_SET);
 842
 843                                 ##
 844                                 # Skip over value to get to plain key
 845                                 ##
 846                                 my $size;
 847                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 848                                 if ($size) { seek($fh, $size, SEEK_CUR); }
 849
 850                                 ##
 851                                 # Read in plain key and return as scalar
 852                                 ##
 853                                 my $plain_key;
 854                                 read( $fh, $size, $DATA_LENGTH_SIZE); $size = unpack($DATA_LENGTH_PACK, $size);
 855                                 if ($size) { read( $fh, $plain_key, $size); }
 856
 857                                 return $plain_key;
 858                         }
 859                 } # bucket loop
 860
 861                 $self->{return_next} = 1;
 862         } # tag is a bucket list
 863
 864         return;
 865 }
 866
 867 sub _get_next_key {
 868         ##
 869         # Locate next key, given digested previous one
 870         ##
 871     my $self = $_[0]->_get_self;
 872
 873         $self->{prev_md5} = $_[1] ? $_[1] : undef;
 874         $self->{return_next} = 0;
 875
 876         ##
 877         # If the previous key was not specifed, start at the top and
 878         # return the first one found.
 879         ##
 880         if (!$self->{prev_md5}) {
 881                 $self->{prev_md5} = chr(0) x $HASH_SIZE;
 882                 $self->{return_next} = 1;
 883         }
 884
 885         return $self->_traverse_index( $self->base_offset, 0 );
 886 }
 887
 888 sub lock {
 889         ##
 890         # If db locking is set, flock() the db file.  If called multiple
 891         # times before unlock(), then the same number of unlocks() must
 892         # be called before the lock is released.
 893         ##
 894     my $self = $_[0]->_get_self;
 895         my $type = $_[1];
 896     $type = LOCK_EX unless defined $type;
 897
 898         if (!defined($self->fh)) { return; }
 899
 900         if ($self->root->{locking}) {
 901                 if (!$self->root->{locked}) { flock($self->fh, $type); }
 902                 $self->root->{locked}++;
 903
 904         return 1;
 905         }
 906
 907     return;
 908 }
 909
 910 sub unlock {
 911         ##
 912         # If db locking is set, unlock the db file.  See note in lock()
 913         # regarding calling lock() multiple times.
 914         ##
 915     my $self = $_[0]->_get_self;
 916
 917         if (!defined($self->fh)) { return; }
 918
 919         if ($self->root->{locking} && $self->root->{locked} > 0) {
 920                 $self->root->{locked}--;
 921                 if (!$self->root->{locked}) { flock($self->fh, LOCK_UN); }
 922
 923         return 1;
 924         }
 925
 926     return;
 927 }
 928
 929 #XXX These uses of ref() need verified
 930 sub _copy_node {
 931         ##
 932         # Copy single level of keys or elements to new DB handle.
 933         # Recurse for nested structures
 934         ##
 935     my $self = $_[0]->_get_self;
 936         my $db_temp = $_[1];
 937
 938         if ($self->type eq TYPE_HASH) {
 939                 my $key = $self->first_key();
 940                 while ($key) {
 941                         my $value = $self->get($key);
 942 #XXX This doesn't work with autobless
 943                         if (!ref($value)) { $db_temp->{$key} = $value; }
 944                         else {
 945                                 my $type = $value->type;
 946                                 if ($type eq TYPE_HASH) { $db_temp->{$key} = {}; }
 947                                 else { $db_temp->{$key} = []; }
 948                                 $value->_copy_node( $db_temp->{$key} );
 949                         }
 950                         $key = $self->next_key($key);
 951                 }
 952         }
 953         else {
 954                 my $length = $self->length();
 955                 for (my $index = 0; $index < $length; $index++) {
 956                         my $value = $self->get($index);
 957                         if (!ref($value)) { $db_temp->[$index] = $value; }
 958             #XXX NO tests for this code
 959                         else {
 960                                 my $type = $value->type;
 961                                 if ($type eq TYPE_HASH) { $db_temp->[$index] = {}; }
 962                                 else { $db_temp->[$index] = []; }
 963                                 $value->_copy_node( $db_temp->[$index] );
 964                         }
 965                 }
 966         }
 967 }
 968
 969 sub export {
 970         ##
 971         # Recursively export into standard Perl hashes and arrays.
 972         ##
 973     my $self = $_[0]->_get_self;
 974
 975         my $temp;
 976         if ($self->type eq TYPE_HASH) { $temp = {}; }
 977         elsif ($self->type eq TYPE_ARRAY) { $temp = []; }
 978
 979         $self->lock();
 980         $self->_copy_node( $temp );
 981         $self->unlock();
 982
 983         return $temp;
 984 }
 985
 986 sub import {
 987         ##
 988         # Recursively import Perl hash/array structure
 989         ##
 990     #XXX This use of ref() seems to be ok
 991         if (!ref($_[0])) { return; } # Perl calls import() on use -- ignore
 992
 993     my $self = $_[0]->_get_self;
 994         my $struct = $_[1];
 995
 996     #XXX This use of ref() seems to be ok
 997         if (!ref($struct)) {
 998                 ##
 999                 # struct is not a reference, so just import based on our type
1000                 ##
1001                 shift @_;
1002
1003                 if ($self->type eq TYPE_HASH) { $struct = {@_}; }
1004                 elsif ($self->type eq TYPE_ARRAY) { $struct = [@_]; }
1005         }
1006
1007     my $r = Scalar::Util::reftype($struct) || '';
1008         if ($r eq "HASH" && $self->type eq TYPE_HASH) {
1009                 foreach my $key (keys %$struct) { $self->put($key, $struct->{$key}); }
1010         }
1011         elsif ($r eq "ARRAY" && $self->type eq TYPE_ARRAY) {
1012                 $self->push( @$struct );
1013         }
1014         else {
1015                 return $self->_throw_error("Cannot import: type mismatch");
1016         }
1017
1018         return 1;
1019 }
1020
1021 sub optimize {
1022         ##
1023         # Rebuild entire database into new file, then move
1024         # it back on top of original.
1025         ##
1026     my $self = $_[0]->_get_self;
1027
1028 #XXX Need to create a new test for this
1029 #       if ($self->root->{links} > 1) {
1030 #               return $self->_throw_error("Cannot optimize: reference count is greater than 1");
1031 #       }
1032
1033         my $db_temp = DBM::Deep->new(
1034                 file => $self->root->{file} . '.tmp',
1035                 type => $self->type
1036         );
1037         if (!$db_temp) {
1038                 return $self->_throw_error("Cannot optimize: failed to open temp file: $!");
1039         }
1040
1041         $self->lock();
1042         $self->_copy_node( $db_temp );
1043         undef $db_temp;
1044
1045         ##
1046         # Attempt to copy user, group and permissions over to new file
1047         ##
1048         my @stats = stat($self->fh);
1049         my $perms = $stats[2] & 07777;
1050         my $uid = $stats[4];
1051         my $gid = $stats[5];
1052         chown( $uid, $gid, $self->root->{file} . '.tmp' );
1053         chmod( $perms, $self->root->{file} . '.tmp' );
1054
1055     # q.v. perlport for more information on this variable
1056     if ( $^O eq 'MSWin32' ) {
1057                 ##
1058                 # Potential race condition when optmizing on Win32 with locking.
1059                 # The Windows filesystem requires that the filehandle be closed
1060                 # before it is overwritten with rename().  This could be redone
1061                 # with a soft copy.
1062                 ##
1063                 $self->unlock();
1064                 $self->_close();
1065         }
1066
1067         if (!rename $self->root->{file} . '.tmp', $self->root->{file}) {
1068                 unlink $self->root->{file} . '.tmp';
1069                 $self->unlock();
1070                 return $self->_throw_error("Optimize failed: Cannot copy temp file over original: $!");
1071         }
1072
1073         $self->unlock();
1074         $self->_close();
1075         $self->_open();
1076
1077         return 1;
1078 }
1079
1080 sub clone {
1081         ##
1082         # Make copy of object and return
1083         ##
1084     my $self = $_[0]->_get_self;
1085
1086         return DBM::Deep->new(
1087                 type => $self->type,
1088                 base_offset => $self->base_offset,
1089                 root => $self->root
1090         );
1091 }
1092
1093 {
1094     my %is_legal_filter = map {
1095         $_ => ~~1,
1096     } qw(
1097         store_key store_value
1098         fetch_key fetch_value
1099     );
1100
1101     sub set_filter {
1102         ##
1103         # Setup filter function for storing or fetching the key or value
1104         ##
1105         my $self = $_[0]->_get_self;
1106         my $type = lc $_[1];
1107         my $func = $_[2] ? $_[2] : undef;
1108
1109         if ( $is_legal_filter{$type} ) {
1110             $self->root->{"filter_$type"} = $func;
1111             return 1;
1112         }
1113
1114         return;
1115     }
1116 }
1117
1118 ##
1119 # Accessor methods
1120 ##
1121
1122 sub root {
1123         ##
1124         # Get access to the root structure
1125         ##
1126     my $self = $_[0]->_get_self;
1127         return $self->{root};
1128 }
1129
1130 sub fh {
1131         ##
1132         # Get access to the raw FileHandle
1133         ##
1134     #XXX It will be useful, though, when we split out HASH and ARRAY
1135     my $self = $_[0]->_get_self;
1136         return $self->root->{fh};
1137 }
1138
1139 sub type {
1140         ##
1141         # Get type of current node (TYPE_HASH or TYPE_ARRAY)
1142         ##
1143     my $self = $_[0]->_get_self;
1144         return $self->{type};
1145 }
1146
1147 sub base_offset {
1148         ##
1149         # Get base_offset of current node (TYPE_HASH or TYPE_ARRAY)
1150         ##
1151     my $self = $_[0]->_get_self;
1152         return $self->{base_offset};
1153 }
1154
1155 sub error {
1156         ##
1157         # Get last error string, or undef if no error
1158         ##
1159         return $_[0]
1160         #? ( _get_self($_[0])->{root}->{error} or undef )
1161         ? ( $_[0]->_get_self->{root}->{error} or undef )
1162         : $@;
1163 }
1164
1165 ##
1166 # Utility methods
1167 ##
1168
1169 sub _throw_error {
1170         ##
1171         # Store error string in self
1172         ##
1173     my $self = $_[0]->_get_self;
1174         my $error_text = $_[1];
1175
1176     if ( Scalar::Util::blessed $self ) {
1177         $self->root->{error} = $error_text;
1178
1179         unless ($self->root->{debug}) {
1180             die "DBM::Deep: $error_text\n";
1181         }
1182
1183         warn "DBM::Deep: $error_text\n";
1184         return;
1185     }
1186     else {
1187         die "DBM::Deep: $error_text\n";
1188     }
1189 }
1190
1191 sub clear_error {
1192         ##
1193         # Clear error state
1194         ##
1195     my $self = $_[0]->_get_self;
1196
1197         undef $self->root->{error};
1198 }
1199
1200 sub precalc_sizes {
1201         ##
1202         # Precalculate index, bucket and bucket list sizes
1203         ##
1204
1205     #XXX I don't like this ...
1206     set_pack() unless defined $LONG_SIZE;
1207
1208         $INDEX_SIZE = 256 * $LONG_SIZE;
1209         $BUCKET_SIZE = $HASH_SIZE + $LONG_SIZE;
1210         $BUCKET_LIST_SIZE = $MAX_BUCKETS * $BUCKET_SIZE;
1211 }
1212
1213 sub set_pack {
1214         ##
1215         # Set pack/unpack modes (see file header for more)
1216         ##
1217     my ($long_s, $long_p, $data_s, $data_p) = @_;
1218
1219     $LONG_SIZE = $long_s ? $long_s : 4;
1220     $LONG_PACK = $long_p ? $long_p : 'N';
1221
1222     $DATA_LENGTH_SIZE = $data_s ? $data_s : 4;
1223     $DATA_LENGTH_PACK = $data_p ? $data_p : 'N';
1224
1225         precalc_sizes();
1226 }
1227
1228 sub set_digest {
1229         ##
1230         # Set key digest function (default is MD5)
1231         ##
1232     my ($digest_func, $hash_size) = @_;
1233
1234     $DIGEST_FUNC = $digest_func ? $digest_func : \&Digest::MD5::md5;
1235     $HASH_SIZE = $hash_size ? $hash_size : 16;
1236
1237         precalc_sizes();
1238 }
1239
1240 ##
1241 # tie() methods (hashes and arrays)
1242 ##
1243
1244 sub STORE {
1245         ##
1246         # Store single hash key/value or array element in database.
1247         ##
1248     my $self = $_[0]->_get_self;
1249         my $key = $_[1];
1250
1251     #XXX What is ref() checking here?
1252     #YYY User may be storing a hash, in which case we do not want it run
1253     #YYY through the filtering system
1254         my $value = ($self->root->{filter_store_value} && !ref($_[2]))
1255         ? $self->root->{filter_store_value}->($_[2])
1256         : $_[2];
1257
1258         my $md5 = $DIGEST_FUNC->($key);
1259
1260         ##
1261         # Make sure file is open
1262         ##
1263         if (!defined($self->fh) && !$self->_open()) {
1264                 return;
1265         }
1266         ##
1267
1268     my $fh = $self->fh;
1269
1270         ##
1271         # Request exclusive lock for writing
1272         ##
1273         $self->lock( LOCK_EX );
1274
1275         ##
1276         # If locking is enabled, set 'end' parameter again, in case another
1277         # DB instance appended to our file while we were unlocked.
1278         ##
1279         if ($self->root->{locking} || $self->root->{volatile}) {
1280                 $self->root->{end} = (stat($fh))[7];
1281         }
1282
1283         ##
1284         # Locate offset for bucket list using digest index system
1285         ##
1286         my $tag = $self->_load_tag($self->base_offset);
1287         if (!$tag) {
1288                 $tag = $self->_create_tag($self->base_offset, SIG_INDEX, chr(0) x $INDEX_SIZE);
1289         }
1290
1291         my $ch = 0;
1292         while ($tag->{signature} ne SIG_BLIST) {
1293                 my $num = ord(substr($md5, $ch, 1));
1294                 my $new_tag = $self->_index_lookup($tag, $num);
1295                 if (!$new_tag) {
1296                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1297                         seek($fh, $ref_loc, SEEK_SET);
1298                         print($fh pack($LONG_PACK, $self->root->{end}) );
1299
1300                         $tag = $self->_create_tag($self->root->{end}, SIG_BLIST, chr(0) x $BUCKET_LIST_SIZE);
1301                         $tag->{ref_loc} = $ref_loc;
1302                         $tag->{ch} = $ch;
1303                         last;
1304                 }
1305                 else {
1306                         my $ref_loc = $tag->{offset} + ($num * $LONG_SIZE);
1307                         $tag = $new_tag;
1308                         $tag->{ref_loc} = $ref_loc;
1309                         $tag->{ch} = $ch;
1310                 }
1311                 $ch++;
1312         }
1313
1314         ##
1315         # Add key/value to bucket list
1316         ##
1317         my $result = $self->_add_bucket( $tag, $md5, $key, $value );
1318
1319         $self->unlock();
1320
1321         return $result;
1322 }
1323
1324 sub FETCH {
1325         ##
1326         # Fetch single value or element given plain key or array index
1327         ##
1328     my $self = shift->_get_self;
1329     my $key = shift;
1330
1331         ##
1332         # Make sure file is open
1333         ##
1334         if (!defined($self->fh)) { $self->_open(); }
1335
1336         my $md5 = $DIGEST_FUNC->($key);
1337
1338         ##
1339         # Request shared lock for reading
1340         ##
1341         $self->lock( LOCK_SH );
1342
1343         my $tag = $self->_find_bucket_list( $md5 );
1344         if (!$tag) {
1345                 $self->unlock();
1346                 return;
1347         }
1348
1349         ##
1350         # Get value from bucket list
1351         ##
1352         my $result = $self->_get_bucket_value( $tag, $md5 );
1353
1354         $self->unlock();
1355
1356     #XXX What is ref() checking here?
1357         return ($result && !ref($result) && $self->root->{filter_fetch_value})
1358         ? $self->root->{filter_fetch_value}->($result)
1359         : $result;
1360 }
1361
1362 sub DELETE {
1363         ##
1364         # Delete single key/value pair or element given plain key or array index
1365         ##
1366     my $self = $_[0]->_get_self;
1367         my $key = $_[1];
1368
1369         my $unpacked_key = $key;
1370         if (($self->type eq TYPE_ARRAY) && ($key =~ /^\d+$/)) { $key = pack($LONG_PACK, $key); }
1371         my $md5 = $DIGEST_FUNC->($key);
1372
1373         ##
1374         # Make sure file is open
1375         ##
1376         if (!defined($self->fh)) { $self->_open(); }
1377
1378         ##
1379         # Request exclusive lock for writing
1380         ##
1381         $self->lock( LOCK_EX );
1382
1383         my $tag = $self->_find_bucket_list( $md5 );
1384         if (!$tag) {
1385                 $self->unlock();
1386                 return;
1387         }
1388
1389         ##
1390         # Delete bucket
1391         ##
1392     my $value = $self->FETCH( $unpacked_key );
1393         my $result = $self->_delete_bucket( $tag, $md5 );
1394
1395         ##
1396         # If this object is an array and the key deleted was on the end of the stack,
1397         # decrement the length variable.
1398         ##
1399         if ($result && ($self->type eq TYPE_ARRAY) && ($unpacked_key == $self->FETCHSIZE() - 1)) {
1400                 $self->STORESIZE( $unpacked_key );
1401         }
1402
1403         $self->unlock();
1404
1405         return $value;
1406 }
1407
1408 sub EXISTS {
1409         ##
1410         # Check if a single key or element exists given plain key or array index
1411         ##
1412     my $self = $_[0]->_get_self;
1413         my $key = $_[1];
1414
1415         my $md5 = $DIGEST_FUNC->($key);
1416
1417         ##
1418         # Make sure file is open
1419         ##
1420         if (!defined($self->fh)) { $self->_open(); }
1421
1422         ##
1423         # Request shared lock for reading
1424         ##
1425         $self->lock( LOCK_SH );
1426
1427         my $tag = $self->_find_bucket_list( $md5 );
1428
1429         ##
1430         # For some reason, the built-in exists() function returns '' for false
1431         ##
1432         if (!$tag) {
1433                 $self->unlock();
1434                 return '';
1435         }
1436
1437         ##
1438         # Check if bucket exists and return 1 or ''
1439         ##
1440         my $result = $self->_bucket_exists( $tag, $md5 ) || '';
1441
1442         $self->unlock();
1443
1444         return $result;
1445 }
1446
1447 sub CLEAR {
1448         ##
1449         # Clear all keys from hash, or all elements from array.
1450         ##
1451     my $self = $_[0]->_get_self;
1452
1453         ##
1454         # Make sure file is open
1455         ##
1456         if (!defined($self->fh)) { $self->_open(); }
1457
1458         ##
1459         # Request exclusive lock for writing
1460         ##
1461         $self->lock( LOCK_EX );
1462
1463     my $fh = $self->fh;
1464
1465         seek($fh, $self->base_offset, SEEK_SET);
1466         if (eof $fh) {
1467                 $self->unlock();
1468                 return;
1469         }
1470
1471         $self->_create_tag($self->base_offset, $self->type, chr(0) x $INDEX_SIZE);
1472
1473         $self->unlock();
1474
1475         return 1;
1476 }
1477
1478 ##
1479 # Public method aliases
1480 ##
1481 sub put { (shift)->STORE( @_ ) }
1482 sub store { (shift)->STORE( @_ ) }
1483 sub get { (shift)->FETCH( @_ ) }
1484 sub fetch { (shift)->FETCH( @_ ) }
1485 sub delete { (shift)->DELETE( @_ ) }
1486 sub exists { (shift)->EXISTS( @_ ) }
1487 sub clear { (shift)->CLEAR( @_ ) }
1488
1489 package DBM::Deep::_::Root;
1490
1491 sub new {
1492     my $class = shift;
1493     my ($args) = @_;
1494
1495     my $self = bless {
1496         file => undef,
1497         fh => undef,
1498         end => 0,
1499         autoflush => undef,
1500         locking => undef,
1501         volatile => undef,
1502         debug => undef,
1503         mode => 'r+',
1504         filter_store_key => undef,
1505         filter_store_value => undef,
1506         filter_fetch_key => undef,
1507         filter_fetch_value => undef,
1508         autobless => undef,
1509         locked => 0,
1510         %$args,
1511     }, $class;
1512
1513     return $self;
1514 }
1515
1516 sub DESTROY {
1517     my $self = shift;
1518     return unless $self;
1519
1520     close $self->{fh} if $self->{fh};
1521
1522     return;
1523 }
1524
1525 1;
1526
1527 __END__
1528
1529 =head1 NAME
1530
1531 DBM::Deep - A pure perl multi-level hash/array DBM
1532
1533 =head1 SYNOPSIS
1534
1535   use DBM::Deep;
1536   my $db = DBM::Deep->new( "foo.db" );
1537
1538   $db->{key} = 'value'; # tie() style
1539   print $db->{key};
1540
1541   $db->put('key', 'value'); # OO style
1542   print $db->get('key');
1543
1544   # true multi-level support
1545   $db->{my_complex} = [
1546         'hello', { perl => 'rules' },
1547         42, 99 ];
1548
1549 =head1 DESCRIPTION
1550
1551 A unique flat-file database module, written in pure perl.  True
1552 multi-level hash/array support (unlike MLDBM, which is faked), hybrid
1553 OO / tie() interface, cross-platform FTPable files, and quite fast.  Can
1554 handle millions of keys and unlimited hash levels without significant
1555 slow-down.  Written from the ground-up in pure perl -- this is NOT a
1556 wrapper around a C-based DBM.  Out-of-the-box compatibility with Unix,
1557 Mac OS X and Windows.
1558
1559 =head1 INSTALLATION
1560
1561 Hopefully you are using CPAN's excellent Perl module, which will download
1562 and install the module for you.  If not, get the tarball, and run these
1563 commands:
1564
1565         tar zxf DBM-Deep-*
1566         cd DBM-Deep-*
1567         perl Makefile.PL
1568         make
1569         make test
1570         make install
1571
1572 =head1 SETUP
1573
1574 Construction can be done OO-style (which is the recommended way), or using
1575 Perl's tie() function.  Both are examined here.
1576
1577 =head2 OO CONSTRUCTION
1578
1579 The recommended way to construct a DBM::Deep object is to use the new()
1580 method, which gets you a blessed, tied hash or array reference.
1581
1582         my $db = DBM::Deep->new( "foo.db" );
1583
1584 This opens a new database handle, mapped to the file "foo.db".  If this
1585 file does not exist, it will automatically be created.  DB files are
1586 opened in "r+" (read/write) mode, and the type of object returned is a
1587 hash, unless otherwise specified (see L<OPTIONS> below).
1588
1589
1590
1591 You can pass a number of options to the constructor to specify things like
1592 locking, autoflush, etc.  This is done by passing an inline hash:
1593
1594         my $db = DBM::Deep->new(
1595                 file => "foo.db",
1596                 locking => 1,
1597                 autoflush => 1
1598         );
1599
1600 Notice that the filename is now specified I<inside> the hash with
1601 the "file" parameter, as opposed to being the sole argument to the
1602 constructor.  This is required if any options are specified.
1603 See L<OPTIONS> below for the complete list.
1604
1605
1606
1607 You can also start with an array instead of a hash.  For this, you must
1608 specify the C<type> parameter:
1609
1610         my $db = DBM::Deep->new(
1611                 file => "foo.db",
1612                 type => DBM::Deep->TYPE_ARRAY
1613         );
1614
1615 B<Note:> Specifing the C<type> parameter only takes effect when beginning
1616 a new DB file.  If you create a DBM::Deep object with an existing file, the
1617 C<type> will be loaded from the file header, and ignored if it is passed
1618 to the constructor.
1619
1620 =head2 TIE CONSTRUCTION
1621
1622 Alternatively, you can create a DBM::Deep handle by using Perl's built-in
1623 tie() function.  This is not ideal, because you get only a basic, tied hash
1624 (or array) which is not blessed, so you can't call any functions on it.
1625
1626         my %hash;
1627         tie %hash, "DBM::Deep", "foo.db";
1628
1629         my @array;
1630         tie @array, "DBM::Deep", "bar.db";
1631
1632 As with the OO constructor, you can replace the DB filename parameter with
1633 a hash containing one or more options (see L<OPTIONS> just below for the
1634 complete list).
1635
1636         tie %hash, "DBM::Deep", {
1637                 file => "foo.db",
1638                 locking => 1,
1639                 autoflush => 1
1640         };
1641
1642 =head2 OPTIONS
1643
1644 There are a number of options that can be passed in when constructing your
1645 DBM::Deep objects.  These apply to both the OO- and tie- based approaches.
1646
1647 =over
1648
1649 =item * file
1650
1651 Filename of the DB file to link the handle to.  You can pass a full absolute
1652 filesystem path, partial path, or a plain filename if the file is in the
1653 current working directory.  This is a required parameter.
1654
1655 =item * mode
1656
1657 File open mode (read-only, read-write, etc.) string passed to Perl's FileHandle
1658 module.  This is an optional parameter, and defaults to "r+" (read/write).
1659 B<Note:> If the default (r+) mode is selected, the file will also be auto-
1660 created if it doesn't exist.
1661
1662 =item * type
1663
1664 This parameter specifies what type of object to create, a hash or array.  Use
1665 one of these two constants: C<DBM::Deep-E<gt>TYPE_HASH> or C<DBM::Deep-E<gt>TYPE_ARRAY>.
1666 This only takes effect when beginning a new file.  This is an optional
1667 parameter, and defaults to C<DBM::Deep-E<gt>TYPE_HASH>.
1668
1669 =item * locking
1670
1671 Specifies whether locking is to be enabled.  DBM::Deep uses Perl's Fnctl flock()
1672 function to lock the database in exclusive mode for writes, and shared mode for
1673 reads.  Pass any true value to enable.  This affects the base DB handle I<and
1674 any child hashes or arrays> that use the same DB file.  This is an optional
1675 parameter, and defaults to 0 (disabled).  See L<LOCKING> below for more.
1676
1677 =item * autoflush
1678
1679 Specifies whether autoflush is to be enabled on the underlying FileHandle.
1680 This obviously slows down write operations, but is required if you may have
1681 multiple processes accessing the same DB file (also consider enable I<locking>
1682 or at least I<volatile>).  Pass any true value to enable.  This is an optional
1683 parameter, and defaults to 0 (disabled).
1684
1685 =item * volatile
1686
1687 If I<volatile> mode is enabled, DBM::Deep will stat() the DB file before each
1688 STORE() operation.  This is required if an outside force may change the size of
1689 the file between transactions.  Locking also implicitly enables volatile.  This
1690 is useful if you want to use a different locking system or write your own.  Pass
1691 any true value to enable.  This is an optional parameter, and defaults to 0
1692 (disabled).
1693
1694 =item * autobless
1695
1696 If I<autobless> mode is enabled, DBM::Deep will preserve blessed hashes, and
1697 restore them when fetched.  This is an B<experimental> feature, and does have
1698 side-effects.  Basically, when hashes are re-blessed into their original
1699 classes, they are no longer blessed into the DBM::Deep class!  So you won't be
1700 able to call any DBM::Deep methods on them.  You have been warned.
1701 This is an optional parameter, and defaults to 0 (disabled).
1702
1703 =item * filter_*
1704
1705 See L<FILTERS> below.
1706
1707 =item * debug
1708
1709 Setting I<debug> mode will make all errors non-fatal, dump them out to
1710 STDERR, and continue on.  This is for debugging purposes only, and probably
1711 not what you want.  This is an optional parameter, and defaults to 0 (disabled).
1712
1713 =item * fh
1714
1715 Instead of passing a file path, you can instead pass a handle to an pre-opened
1716 filehandle.  Note: Beware of using the magick *DATA handle, as this actually
1717 contains your entire Perl script, as well as the data following the __DATA__
1718 marker.  This will not work, because DBM::Deep uses absolute seek()s into the
1719 file.  Instead, consider reading *DATA into an IO::Scalar handle, then passing
1720 in that.
1721
1722 =back
1723
1724 =head1 TIE INTERFACE
1725
1726 With DBM::Deep you can access your databases using Perl's standard hash/array
1727 syntax.  Because all DBM::Deep objects are I<tied> to hashes or arrays, you can treat
1728 them as such.  DBM::Deep will intercept all reads/writes and direct them to the right
1729 place -- the DB file.  This has nothing to do with the L<TIE CONSTRUCTION>
1730 section above.  This simply tells you how to use DBM::Deep using regular hashes
1731 and arrays, rather than calling functions like C<get()> and C<put()> (although those
1732 work too).  It is entirely up to you how to want to access your databases.
1733
1734 =head2 HASHES
1735
1736 You can treat any DBM::Deep object like a normal Perl hash reference.  Add keys,
1737 or even nested hashes (or arrays) using standard Perl syntax:
1738
1739         my $db = DBM::Deep->new( "foo.db" );
1740
1741         $db->{mykey} = "myvalue";
1742         $db->{myhash} = {};
1743         $db->{myhash}->{subkey} = "subvalue";
1744
1745         print $db->{myhash}->{subkey} . "\n";
1746
1747 You can even step through hash keys using the normal Perl C<keys()> function:
1748
1749         foreach my $key (keys %$db) {
1750                 print "$key: " . $db->{$key} . "\n";
1751         }
1752
1753 Remember that Perl's C<keys()> function extracts I<every> key from the hash and
1754 pushes them onto an array, all before the loop even begins.  If you have an
1755 extra large hash, this may exhaust Perl's memory.  Instead, consider using
1756 Perl's C<each()> function, which pulls keys/values one at a time, using very
1757 little memory:
1758
1759         while (my ($key, $value) = each %$db) {
1760                 print "$key: $value\n";
1761         }
1762
1763 Please note that when using C<each()>, you should always pass a direct
1764 hash reference, not a lookup.  Meaning, you should B<never> do this:
1765
1766         # NEVER DO THIS
1767         while (my ($key, $value) = each %{$db->{foo}}) { # BAD
1768
1769 This causes an infinite loop, because for each iteration, Perl is calling
1770 FETCH() on the $db handle, resulting in a "new" hash for foo every time, so
1771 it effectively keeps returning the first key over and over again. Instead,
1772 assign a temporary variable to C<$db->{foo}>, then pass that to each().
1773
1774 =head2 ARRAYS
1775
1776 As with hashes, you can treat any DBM::Deep object like a normal Perl array
1777 reference.  This includes inserting, removing and manipulating elements,
1778 and the C<push()>, C<pop()>, C<shift()>, C<unshift()> and C<splice()> functions.
1779 The object must have first been created using type C<DBM::Deep-E<gt>TYPE_ARRAY>,
1780 or simply be a nested array reference inside a hash.  Example:
1781
1782         my $db = DBM::Deep->new(
1783                 file => "foo-array.db",
1784                 type => DBM::Deep->TYPE_ARRAY
1785         );
1786
1787         $db->[0] = "foo";
1788         push @$db, "bar", "baz";
1789         unshift @$db, "bah";
1790
1791         my $last_elem = pop @$db; # baz
1792         my $first_elem = shift @$db; # bah
1793         my $second_elem = $db->[1]; # bar
1794
1795         my $num_elements = scalar @$db;
1796
1797 =head1 OO INTERFACE
1798
1799 In addition to the I<tie()> interface, you can also use a standard OO interface
1800 to manipulate all aspects of DBM::Deep databases.  Each type of object (hash or
1801 array) has its own methods, but both types share the following common methods:
1802 C<put()>, C<get()>, C<exists()>, C<delete()> and C<clear()>.
1803
1804 =over
1805
1806 =item * put()
1807
1808 Stores a new hash key/value pair, or sets an array element value.  Takes two
1809 arguments, the hash key or array index, and the new value.  The value can be
1810 a scalar, hash ref or array ref.  Returns true on success, false on failure.
1811
1812         $db->put("foo", "bar"); # for hashes
1813         $db->put(1, "bar"); # for arrays
1814
1815 =item * get()
1816
1817 Fetches the value of a hash key or array element.  Takes one argument: the hash
1818 key or array index.  Returns a scalar, hash ref or array ref, depending on the
1819 data type stored.
1820
1821         my $value = $db->get("foo"); # for hashes
1822         my $value = $db->get(1); # for arrays
1823
1824 =item * exists()
1825
1826 Checks if a hash key or array index exists.  Takes one argument: the hash key
1827 or array index.  Returns true if it exists, false if not.
1828
1829         if ($db->exists("foo")) { print "yay!\n"; } # for hashes
1830         if ($db->exists(1)) { print "yay!\n"; } # for arrays
1831
1832 =item * delete()
1833
1834 Deletes one hash key/value pair or array element.  Takes one argument: the hash
1835 key or array index.  Returns true on success, false if not found.  For arrays,
1836 the remaining elements located after the deleted element are NOT moved over.
1837 The deleted element is essentially just undefined, which is exactly how Perl's
1838 internal arrays work.  Please note that the space occupied by the deleted
1839 key/value or element is B<not> reused again -- see L<UNUSED SPACE RECOVERY>
1840 below for details and workarounds.
1841
1842         $db->delete("foo"); # for hashes
1843         $db->delete(1); # for arrays
1844
1845 =item * clear()
1846
1847 Deletes B<all> hash keys or array elements.  Takes no arguments.  No return
1848 value.  Please note that the space occupied by the deleted keys/values or
1849 elements is B<not> reused again -- see L<UNUSED SPACE RECOVERY> below for
1850 details and workarounds.
1851
1852         $db->clear(); # hashes or arrays
1853
1854 =back
1855
1856 =head2 HASHES
1857
1858 For hashes, DBM::Deep supports all the common methods described above, and the
1859 following additional methods: C<first_key()> and C<next_key()>.
1860
1861 =over
1862
1863 =item * first_key()
1864
1865 Returns the "first" key in the hash.  As with built-in Perl hashes, keys are
1866 fetched in an undefined order (which appears random).  Takes no arguments,
1867 returns the key as a scalar value.
1868
1869         my $key = $db->first_key();
1870
1871 =item * next_key()
1872
1873 Returns the "next" key in the hash, given the previous one as the sole argument.
1874 Returns undef if there are no more keys to be fetched.
1875
1876         $key = $db->next_key($key);
1877
1878 =back
1879
1880 Here are some examples of using hashes:
1881
1882         my $db = DBM::Deep->new( "foo.db" );
1883
1884         $db->put("foo", "bar");
1885         print "foo: " . $db->get("foo") . "\n";
1886
1887         $db->put("baz", {}); # new child hash ref
1888         $db->get("baz")->put("buz", "biz");
1889         print "buz: " . $db->get("baz")->get("buz") . "\n";
1890
1891         my $key = $db->first_key();
1892         while ($key) {
1893                 print "$key: " . $db->get($key) . "\n";
1894                 $key = $db->next_key($key);
1895         }
1896
1897         if ($db->exists("foo")) { $db->delete("foo"); }
1898
1899 =head2 ARRAYS
1900
1901 For arrays, DBM::Deep supports all the common methods described above, and the
1902 following additional methods: C<length()>, C<push()>, C<pop()>, C<shift()>,
1903 C<unshift()> and C<splice()>.
1904
1905 =over
1906
1907 =item * length()
1908
1909 Returns the number of elements in the array.  Takes no arguments.
1910
1911         my $len = $db->length();
1912
1913 =item * push()
1914
1915 Adds one or more elements onto the end of the array.  Accepts scalars, hash
1916 refs or array refs.  No return value.
1917
1918         $db->push("foo", "bar", {});
1919
1920 =item * pop()
1921
1922 Fetches the last element in the array, and deletes it.  Takes no arguments.
1923 Returns undef if array is empty.  Returns the element value.
1924
1925         my $elem = $db->pop();
1926
1927 =item * shift()
1928
1929 Fetches the first element in the array, deletes it, then shifts all the
1930 remaining elements over to take up the space.  Returns the element value.  This
1931 method is not recommended with large arrays -- see L<LARGE ARRAYS> below for
1932 details.
1933
1934         my $elem = $db->shift();
1935
1936 =item * unshift()
1937
1938 Inserts one or more elements onto the beginning of the array, shifting all
1939 existing elements over to make room.  Accepts scalars, hash refs or array refs.
1940 No return value.  This method is not recommended with large arrays -- see
1941 <LARGE ARRAYS> below for details.
1942
1943         $db->unshift("foo", "bar", {});
1944
1945 =item * splice()
1946
1947 Performs exactly like Perl's built-in function of the same name.  See L<perldoc
1948 -f splice> for usage -- it is too complicated to document here.  This method is
1949 not recommended with large arrays -- see L<LARGE ARRAYS> below for details.
1950
1951 =back
1952
1953 Here are some examples of using arrays:
1954
1955         my $db = DBM::Deep->new(
1956                 file => "foo.db",
1957                 type => DBM::Deep->TYPE_ARRAY
1958         );
1959
1960         $db->push("bar", "baz");
1961         $db->unshift("foo");
1962         $db->put(3, "buz");
1963
1964         my $len = $db->length();
1965         print "length: $len\n"; # 4
1966
1967         for (my $k=0; $k<$len; $k++) {
1968                 print "$k: " . $db->get($k) . "\n";
1969         }
1970
1971         $db->splice(1, 2, "biz", "baf");
1972
1973         while (my $elem = shift @$db) {
1974                 print "shifted: $elem\n";
1975         }
1976
1977 =head1 LOCKING
1978
1979 Enable automatic file locking by passing a true value to the C<locking>
1980 parameter when constructing your DBM::Deep object (see L<SETUP> above).
1981
1982         my $db = DBM::Deep->new(
1983                 file => "foo.db",
1984                 locking => 1
1985         );
1986
1987 This causes DBM::Deep to C<flock()> the underlying FileHandle object with exclusive
1988 mode for writes, and shared mode for reads.  This is required if you have
1989 multiple processes accessing the same database file, to avoid file corruption.
1990 Please note that C<flock()> does NOT work for files over NFS.  See L<DB OVER
1991 NFS> below for more.
1992
1993 =head2 EXPLICIT LOCKING
1994
1995 You can explicitly lock a database, so it remains locked for multiple
1996 transactions.  This is done by calling the C<lock()> method, and passing an
1997 optional lock mode argument (defaults to exclusive mode).  This is particularly
1998 useful for things like counters, where the current value needs to be fetched,
1999 then incremented, then stored again.
2000
2001         $db->lock();
2002         my $counter = $db->get("counter");
2003         $counter++;
2004         $db->put("counter", $counter);
2005         $db->unlock();
2006
2007         # or...
2008
2009         $db->lock();
2010         $db->{counter}++;
2011         $db->unlock();
2012
2013 You can pass C<lock()> an optional argument, which specifies which mode to use
2014 (exclusive or shared).  Use one of these two constants: C<DBM::Deep-E<gt>LOCK_EX>
2015 or C<DBM::Deep-E<gt>LOCK_SH>.  These are passed directly to C<flock()>, and are the
2016 same as the constants defined in Perl's C<Fcntl> module.
2017
2018         $db->lock( DBM::Deep->LOCK_SH );
2019         # something here
2020         $db->unlock();
2021
2022 If you want to implement your own file locking scheme, be sure to create your
2023 DBM::Deep objects setting the C<volatile> option to true.  This hints to DBM::Deep
2024 that the DB file may change between transactions.  See L<LOW-LEVEL ACCESS>
2025 below for more.
2026
2027 =head1 IMPORTING/EXPORTING
2028
2029 You can import existing complex structures by calling the C<import()> method,
2030 and export an entire database into an in-memory structure using the C<export()>
2031 method.  Both are examined here.
2032
2033 =head2 IMPORTING
2034
2035 Say you have an existing hash with nested hashes/arrays inside it.  Instead of
2036 walking the structure and adding keys/elements to the database as you go,
2037 simply pass a reference to the C<import()> method.  This recursively adds
2038 everything to an existing DBM::Deep object for you.  Here is an example:
2039
2040         my $struct = {
2041                 key1 => "value1",
2042                 key2 => "value2",
2043                 array1 => [ "elem0", "elem1", "elem2" ],
2044                 hash1 => {
2045                         subkey1 => "subvalue1",
2046                         subkey2 => "subvalue2"
2047                 }
2048         };
2049
2050         my $db = DBM::Deep->new( "foo.db" );
2051         $db->import( $struct );
2052
2053         print $db->{key1} . "\n"; # prints "value1"
2054
2055 This recursively imports the entire C<$struct> object into C<$db>, including
2056 all nested hashes and arrays.  If the DBM::Deep object contains exsiting data,
2057 keys are merged with the existing ones, replacing if they already exist.
2058 The C<import()> method can be called on any database level (not just the base
2059 level), and works with both hash and array DB types.
2060
2061
2062
2063 B<Note:> Make sure your existing structure has no circular references in it.
2064 These will cause an infinite loop when importing.
2065
2066 =head2 EXPORTING
2067
2068 Calling the C<export()> method on an existing DBM::Deep object will return
2069 a reference to a new in-memory copy of the database.  The export is done
2070 recursively, so all nested hashes/arrays are all exported to standard Perl
2071 objects.  Here is an example:
2072
2073         my $db = DBM::Deep->new( "foo.db" );
2074
2075         $db->{key1} = "value1";
2076         $db->{key2} = "value2";
2077         $db->{hash1} = {};
2078         $db->{hash1}->{subkey1} = "subvalue1";
2079         $db->{hash1}->{subkey2} = "subvalue2";
2080
2081         my $struct = $db->export();
2082
2083         print $struct->{key1} . "\n"; # prints "value1"
2084
2085 This makes a complete copy of the database in memory, and returns a reference
2086 to it.  The C<export()> method can be called on any database level (not just
2087 the base level), and works with both hash and array DB types.  Be careful of
2088 large databases -- you can store a lot more data in a DBM::Deep object than an
2089 in-memory Perl structure.
2090
2091
2092
2093 B<Note:> Make sure your database has no circular references in it.
2094 These will cause an infinite loop when exporting.
2095
2096 =head1 FILTERS
2097
2098 DBM::Deep has a number of hooks where you can specify your own Perl function
2099 to perform filtering on incoming or outgoing data.  This is a perfect
2100 way to extend the engine, and implement things like real-time compression or
2101 encryption.  Filtering applies to the base DB level, and all child hashes /
2102 arrays.  Filter hooks can be specified when your DBM::Deep object is first
2103 constructed, or by calling the C<set_filter()> method at any time.  There are
2104 four available filter hooks, described below:
2105
2106 =over
2107
2108 =item * filter_store_key
2109
2110 This filter is called whenever a hash key is stored.  It
2111 is passed the incoming key, and expected to return a transformed key.
2112
2113 =item * filter_store_value
2114
2115 This filter is called whenever a hash key or array element is stored.  It
2116 is passed the incoming value, and expected to return a transformed value.
2117
2118 =item * filter_fetch_key
2119
2120 This filter is called whenever a hash key is fetched (i.e. via
2121 C<first_key()> or C<next_key()>).  It is passed the transformed key,
2122 and expected to return the plain key.
2123
2124 =item * filter_fetch_value
2125
2126 This filter is called whenever a hash key or array element is fetched.
2127 It is passed the transformed value, and expected to return the plain value.
2128
2129 =back
2130
2131 Here are the two ways to setup a filter hook:
2132
2133         my $db = DBM::Deep->new(
2134                 file => "foo.db",
2135                 filter_store_value => \&my_filter_store,
2136                 filter_fetch_value => \&my_filter_fetch
2137         );
2138
2139         # or...
2140
2141         $db->set_filter( "filter_store_value", \&my_filter_store );
2142         $db->set_filter( "filter_fetch_value", \&my_filter_fetch );
2143
2144 Your filter function will be called only when dealing with SCALAR keys or
2145 values.  When nested hashes and arrays are being stored/fetched, filtering
2146 is bypassed.  Filters are called as static functions, passed a single SCALAR
2147 argument, and expected to return a single SCALAR value.  If you want to
2148 remove a filter, set the function reference to C<undef>:
2149
2150         $db->set_filter( "filter_store_value", undef );
2151
2152 =head2 REAL-TIME ENCRYPTION EXAMPLE
2153
2154 Here is a working example that uses the I<Crypt::Blowfish> module to
2155 do real-time encryption / decryption of keys & values with DBM::Deep Filters.
2156 Please visit L<http://search.cpan.org/search?module=Crypt::Blowfish> for more
2157 on I<Crypt::Blowfish>.  You'll also need the I<Crypt::CBC> module.
2158
2159         use DBM::Deep;
2160         use Crypt::Blowfish;
2161         use Crypt::CBC;
2162
2163         my $cipher = Crypt::CBC->new({
2164                 'key'             => 'my secret key',
2165                 'cipher'          => 'Blowfish',
2166                 'iv'              => '$KJh#(}q',
2167                 'regenerate_key'  => 0,
2168                 'padding'         => 'space',
2169                 'prepend_iv'      => 0
2170         });
2171
2172         my $db = DBM::Deep->new(
2173                 file => "foo-encrypt.db",
2174                 filter_store_key => \&my_encrypt,
2175                 filter_store_value => \&my_encrypt,
2176                 filter_fetch_key => \&my_decrypt,
2177                 filter_fetch_value => \&my_decrypt,
2178         );
2179
2180         $db->{key1} = "value1";
2181         $db->{key2} = "value2";
2182         print "key1: " . $db->{key1} . "\n";
2183         print "key2: " . $db->{key2} . "\n";
2184
2185         undef $db;
2186         exit;
2187
2188         sub my_encrypt {
2189                 return $cipher->encrypt( $_[0] );
2190         }
2191         sub my_decrypt {
2192                 return $cipher->decrypt( $_[0] );
2193         }
2194
2195 =head2 REAL-TIME COMPRESSION EXAMPLE
2196
2197 Here is a working example that uses the I<Compress::Zlib> module to do real-time
2198 compression / decompression of keys & values with DBM::Deep Filters.
2199 Please visit L<http://search.cpan.org/search?module=Compress::Zlib> for
2200 more on I<Compress::Zlib>.
2201
2202         use DBM::Deep;
2203         use Compress::Zlib;
2204
2205         my $db = DBM::Deep->new(
2206                 file => "foo-compress.db",
2207                 filter_store_key => \&my_compress,
2208                 filter_store_value => \&my_compress,
2209                 filter_fetch_key => \&my_decompress,
2210                 filter_fetch_value => \&my_decompress,
2211         );
2212
2213         $db->{key1} = "value1";
2214         $db->{key2} = "value2";
2215         print "key1: " . $db->{key1} . "\n";
2216         print "key2: " . $db->{key2} . "\n";
2217
2218         undef $db;
2219         exit;
2220
2221         sub my_compress {
2222                 return Compress::Zlib::memGzip( $_[0] ) ;
2223         }
2224         sub my_decompress {
2225                 return Compress::Zlib::memGunzip( $_[0] ) ;
2226         }
2227
2228 B<Note:> Filtering of keys only applies to hashes.  Array "keys" are
2229 actually numerical index numbers, and are not filtered.
2230
2231 =head1 ERROR HANDLING
2232
2233 Most DBM::Deep methods return a true value for success, and call die() on
2234 failure.  You can wrap calls in an eval block to catch the die.  Also, the
2235 actual error message is stored in an internal scalar, which can be fetched by
2236 calling the C<error()> method.
2237
2238         my $db = DBM::Deep->new( "foo.db" ); # create hash
2239         eval { $db->push("foo"); }; # ILLEGAL -- push is array-only call
2240
2241         print $db->error(); # prints error message
2242
2243 You can then call C<clear_error()> to clear the current error state.
2244
2245         $db->clear_error();
2246
2247 If you set the C<debug> option to true when creating your DBM::Deep object,
2248 all errors are considered NON-FATAL, and dumped to STDERR.  This is only
2249 for debugging purposes.
2250
2251 =head1 LARGEFILE SUPPORT
2252
2253 If you have a 64-bit system, and your Perl is compiled with both LARGEFILE
2254 and 64-bit support, you I<may> be able to create databases larger than 2 GB.
2255 DBM::Deep by default uses 32-bit file offset tags, but these can be changed
2256 by calling the static C<set_pack()> method before you do anything else.
2257
2258         DBM::Deep::set_pack(8, 'Q');
2259
2260 This tells DBM::Deep to pack all file offsets with 8-byte (64-bit) quad words
2261 instead of 32-bit longs.  After setting these values your DB files have a
2262 theoretical maximum size of 16 XB (exabytes).
2263
2264
2265
2266 B<Note:> Changing these values will B<NOT> work for existing database files.
2267 Only change this for new files, and make sure it stays set consistently
2268 throughout the file's life.  If you do set these values, you can no longer
2269 access 32-bit DB files.  You can, however, call C<set_pack(4, 'N')> to change
2270 back to 32-bit mode.
2271
2272
2273
2274 B<Note:> I have not personally tested files > 2 GB -- all my systems have
2275 only a 32-bit Perl.  However, I have received user reports that this does
2276 indeed work!
2277
2278 =head1 LOW-LEVEL ACCESS
2279
2280 If you require low-level access to the underlying FileHandle that DBM::Deep uses,
2281 you can call the C<fh()> method, which returns the handle:
2282
2283         my $fh = $db->fh();
2284
2285 This method can be called on the root level of the datbase, or any child
2286 hashes or arrays.  All levels share a I<root> structure, which contains things
2287 like the FileHandle, a reference counter, and all your options you specified
2288 when you created the object.  You can get access to this root structure by
2289 calling the C<root()> method.
2290
2291         my $root = $db->root();
2292
2293 This is useful for changing options after the object has already been created,
2294 such as enabling/disabling locking, volatile or debug modes.  You can also
2295 store your own temporary user data in this structure (be wary of name
2296 collision), which is then accessible from any child hash or array.
2297
2298 =head1 CUSTOM DIGEST ALGORITHM
2299
2300 DBM::Deep by default uses the I<Message Digest 5> (MD5) algorithm for hashing
2301 keys.  However you can override this, and use another algorithm (such as SHA-256)
2302 or even write your own.  But please note that DBM::Deep currently expects zero
2303 collisions, so your algorithm has to be I<perfect>, so to speak.
2304 Collision detection may be introduced in a later version.
2305
2306
2307
2308 You can specify a custom digest algorithm by calling the static C<set_digest()>
2309 function, passing a reference to a subroutine, and the length of the algorithm's
2310 hashes (in bytes).  This is a global static function, which affects ALL DBM::Deep
2311 objects.  Here is a working example that uses a 256-bit hash from the
2312 I<Digest::SHA256> module.  Please see
2313 L<http://search.cpan.org/search?module=Digest::SHA256> for more.
2314
2315         use DBM::Deep;
2316         use Digest::SHA256;
2317
2318         my $context = Digest::SHA256::new(256);
2319
2320         DBM::Deep::set_digest( \&my_digest, 32 );
2321
2322         my $db = DBM::Deep->new( "foo-sha.db" );
2323
2324         $db->{key1} = "value1";
2325         $db->{key2} = "value2";
2326         print "key1: " . $db->{key1} . "\n";
2327         print "key2: " . $db->{key2} . "\n";
2328
2329         undef $db;
2330         exit;
2331
2332         sub my_digest {
2333                 return substr( $context->hash($_[0]), 0, 32 );
2334         }
2335
2336 B<Note:> Your returned digest strings must be B<EXACTLY> the number
2337 of bytes you specify in the C<set_digest()> function (in this case 32).
2338
2339 =head1 CIRCULAR REFERENCES
2340
2341 DBM::Deep has B<experimental> support for circular references.  Meaning you
2342 can have a nested hash key or array element that points to a parent object.
2343 This relationship is stored in the DB file, and is preserved between sessions.
2344 Here is an example:
2345
2346         my $db = DBM::Deep->new( "foo.db" );
2347
2348         $db->{foo} = "bar";
2349         $db->{circle} = $db; # ref to self
2350
2351         print $db->{foo} . "\n"; # prints "foo"
2352         print $db->{circle}->{foo} . "\n"; # prints "foo" again
2353
2354 One catch is, passing the object to a function that recursively walks the
2355 object tree (such as I<Data::Dumper> or even the built-in C<optimize()> or
2356 C<export()> methods) will result in an infinite loop.  The other catch is,
2357 if you fetch the I<key> of a circular reference (i.e. using the C<first_key()>
2358 or C<next_key()> methods), you will get the I<target object's key>, not the
2359 ref's key.  This gets even more interesting with the above example, where
2360 the I<circle> key points to the base DB object, which technically doesn't
2361 have a key.  So I made DBM::Deep return "[base]" as the key name in that
2362 special case.
2363
2364 =head1 CAVEATS / ISSUES / BUGS
2365
2366 This section describes all the known issues with DBM::Deep.  It you have found
2367 something that is not listed here, please send e-mail to L<jhuckaby@cpan.org>.
2368
2369 =head2 UNUSED SPACE RECOVERY
2370
2371 One major caveat with DBM::Deep is that space occupied by existing keys and
2372 values is not recovered when they are deleted.  Meaning if you keep deleting
2373 and adding new keys, your file will continuously grow.  I am working on this,
2374 but in the meantime you can call the built-in C<optimize()> method from time to
2375 time (perhaps in a crontab or something) to recover all your unused space.
2376
2377         $db->optimize(); # returns true on success
2378
2379 This rebuilds the ENTIRE database into a new file, then moves it on top of
2380 the original.  The new file will have no unused space, thus it will take up as
2381 little disk space as possible.  Please note that this operation can take
2382 a long time for large files, and you need enough disk space to temporarily hold
2383 2 copies of your DB file.  The temporary file is created in the same directory
2384 as the original, named with a ".tmp" extension, and is deleted when the
2385 operation completes.  Oh, and if locking is enabled, the DB is automatically
2386 locked for the entire duration of the copy.
2387
2388
2389
2390 B<WARNING:> Only call optimize() on the top-level node of the database, and
2391 make sure there are no child references lying around.  DBM::Deep keeps a reference
2392 counter, and if it is greater than 1, optimize() will abort and return undef.
2393
2394 =head2 AUTOVIVIFICATION
2395
2396 Unfortunately, autovivification doesn't work with tied hashes.  This appears to
2397 be a bug in Perl's tie() system, as I<Jakob Schmidt> encountered the very same
2398 issue with his I<DWH_FIle> module (see L<http://search.cpan.org/search?module=DWH_File>),
2399 and it is also mentioned in the BUGS section for the I<MLDBM> module <see
2400 L<http://search.cpan.org/search?module=MLDBM>).  Basically, on a new db file,
2401 this does not work:
2402
2403         $db->{foo}->{bar} = "hello";
2404
2405 Since "foo" doesn't exist, you cannot add "bar" to it.  You end up with "foo"
2406 being an empty hash.  Try this instead, which works fine:
2407
2408         $db->{foo} = { bar => "hello" };
2409
2410 As of Perl 5.8.7, this bug still exists.  I have walked very carefully through
2411 the execution path, and Perl indeed passes an empty hash to the STORE() method.
2412 Probably a bug in Perl.
2413
2414 =head2 FILE CORRUPTION
2415
2416 The current level of error handling in DBM::Deep is minimal.  Files I<are> checked
2417 for a 32-bit signature when opened, but other corruption in files can cause
2418 segmentation faults.  DBM::Deep may try to seek() past the end of a file, or get
2419 stuck in an infinite loop depending on the level of corruption.  File write
2420 operations are not checked for failure (for speed), so if you happen to run
2421 out of disk space, DBM::Deep will probably fail in a bad way.  These things will
2422 be addressed in a later version of DBM::Deep.
2423
2424 =head2 DB OVER NFS
2425
2426 Beware of using DB files over NFS.  DBM::Deep uses flock(), which works well on local
2427 filesystems, but will NOT protect you from file corruption over NFS.  I've heard
2428 about setting up your NFS server with a locking daemon, then using lockf() to
2429 lock your files, but your milage may vary there as well.  From what I
2430 understand, there is no real way to do it.  However, if you need access to the
2431 underlying FileHandle in DBM::Deep for using some other kind of locking scheme like
2432 lockf(), see the L<LOW-LEVEL ACCESS> section above.
2433
2434 =head2 COPYING OBJECTS
2435
2436 Beware of copying tied objects in Perl.  Very strange things can happen.
2437 Instead, use DBM::Deep's C<clone()> method which safely copies the object and
2438 returns a new, blessed, tied hash or array to the same level in the DB.
2439
2440         my $copy = $db->clone();
2441
2442 =head2 LARGE ARRAYS
2443
2444 Beware of using C<shift()>, C<unshift()> or C<splice()> with large arrays.
2445 These functions cause every element in the array to move, which can be murder
2446 on DBM::Deep, as every element has to be fetched from disk, then stored again in
2447 a different location.  This may be addressed in a later version.
2448
2449 =head1 PERFORMANCE
2450
2451 This section discusses DBM::Deep's speed and memory usage.
2452
2453 =head2 SPEED
2454
2455 Obviously, DBM::Deep isn't going to be as fast as some C-based DBMs, such as
2456 the almighty I<BerkeleyDB>.  But it makes up for it in features like true
2457 multi-level hash/array support, and cross-platform FTPable files.  Even so,
2458 DBM::Deep is still pretty fast, and the speed stays fairly consistent, even
2459 with huge databases.  Here is some test data:
2460
2461         Adding 1,000,000 keys to new DB file...
2462
2463         At 100 keys, avg. speed is 2,703 keys/sec
2464         At 200 keys, avg. speed is 2,642 keys/sec
2465         At 300 keys, avg. speed is 2,598 keys/sec
2466         At 400 keys, avg. speed is 2,578 keys/sec
2467         At 500 keys, avg. speed is 2,722 keys/sec
2468         At 600 keys, avg. speed is 2,628 keys/sec
2469         At 700 keys, avg. speed is 2,700 keys/sec
2470         At 800 keys, avg. speed is 2,607 keys/sec
2471         At 900 keys, avg. speed is 2,190 keys/sec
2472         At 1,000 keys, avg. speed is 2,570 keys/sec
2473         At 2,000 keys, avg. speed is 2,417 keys/sec
2474         At 3,000 keys, avg. speed is 1,982 keys/sec
2475         At 4,000 keys, avg. speed is 1,568 keys/sec
2476         At 5,000 keys, avg. speed is 1,533 keys/sec
2477         At 6,000 keys, avg. speed is 1,787 keys/sec
2478         At 7,000 keys, avg. speed is 1,977 keys/sec
2479         At 8,000 keys, avg. speed is 2,028 keys/sec
2480         At 9,000 keys, avg. speed is 2,077 keys/sec
2481         At 10,000 keys, avg. speed is 2,031 keys/sec
2482         At 20,000 keys, avg. speed is 1,970 keys/sec
2483         At 30,000 keys, avg. speed is 2,050 keys/sec
2484         At 40,000 keys, avg. speed is 2,073 keys/sec
2485         At 50,000 keys, avg. speed is 1,973 keys/sec
2486         At 60,000 keys, avg. speed is 1,914 keys/sec
2487         At 70,000 keys, avg. speed is 2,091 keys/sec
2488         At 80,000 keys, avg. speed is 2,103 keys/sec
2489         At 90,000 keys, avg. speed is 1,886 keys/sec
2490         At 100,000 keys, avg. speed is 1,970 keys/sec
2491         At 200,000 keys, avg. speed is 2,053 keys/sec
2492         At 300,000 keys, avg. speed is 1,697 keys/sec
2493         At 400,000 keys, avg. speed is 1,838 keys/sec
2494         At 500,000 keys, avg. speed is 1,941 keys/sec
2495         At 600,000 keys, avg. speed is 1,930 keys/sec
2496         At 700,000 keys, avg. speed is 1,735 keys/sec
2497         At 800,000 keys, avg. speed is 1,795 keys/sec
2498         At 900,000 keys, avg. speed is 1,221 keys/sec
2499         At 1,000,000 keys, avg. speed is 1,077 keys/sec
2500
2501 This test was performed on a PowerMac G4 1gHz running Mac OS X 10.3.2 & Perl
2502 5.8.1, with an 80GB Ultra ATA/100 HD spinning at 7200RPM.  The hash keys and
2503 values were between 6 - 12 chars in length.  The DB file ended up at 210MB.
2504 Run time was 12 min 3 sec.
2505
2506 =head2 MEMORY USAGE
2507
2508 One of the great things about DBM::Deep is that it uses very little memory.
2509 Even with huge databases (1,000,000+ keys) you will not see much increased
2510 memory on your process.  DBM::Deep relies solely on the filesystem for storing
2511 and fetching data.  Here is output from I</usr/bin/top> before even opening a
2512 database handle:
2513
2514           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2515         22831 root      11   0  2716 2716  1296 R     0.0  0.2   0:07 perl
2516
2517 Basically the process is taking 2,716K of memory.  And here is the same
2518 process after storing and fetching 1,000,000 keys:
2519
2520           PID USER     PRI  NI  SIZE  RSS SHARE STAT %CPU %MEM   TIME COMMAND
2521         22831 root      14   0  2772 2772  1328 R     0.0  0.2  13:32 perl
2522
2523 Notice the memory usage increased by only 56K.  Test was performed on a 700mHz
2524 x86 box running Linux RedHat 7.2 & Perl 5.6.1.
2525
2526 =head1 DB FILE FORMAT
2527
2528 In case you were interested in the underlying DB file format, it is documented
2529 here in this section.  You don't need to know this to use the module, it's just
2530 included for reference.
2531
2532 =head2 SIGNATURE
2533
2534 DBM::Deep files always start with a 32-bit signature to identify the file type.
2535 This is at offset 0.  The signature is "DPDB" in network byte order.  This is
2536 checked when the file is opened.
2537
2538 =head2 TAG
2539
2540 The DBM::Deep file is in a I<tagged format>, meaning each section of the file
2541 has a standard header containing the type of data, the length of data, and then
2542 the data itself.  The type is a single character (1 byte), the length is a
2543 32-bit unsigned long in network byte order, and the data is, well, the data.
2544 Here is how it unfolds:
2545
2546 =head2 MASTER INDEX
2547
2548 Immediately after the 32-bit file signature is the I<Master Index> record.
2549 This is a standard tag header followed by 1024 bytes (in 32-bit mode) or 2048
2550 bytes (in 64-bit mode) of data.  The type is I<H> for hash or I<A> for array,
2551 depending on how the DBM::Deep object was constructed.
2552
2553
2554
2555 The index works by looking at a I<MD5 Hash> of the hash key (or array index
2556 number).  The first 8-bit char of the MD5 signature is the offset into the
2557 index, multipled by 4 in 32-bit mode, or 8 in 64-bit mode.  The value of the
2558 index element is a file offset of the next tag for the key/element in question,
2559 which is usually a I<Bucket List> tag (see below).
2560
2561
2562
2563 The next tag I<could> be another index, depending on how many keys/elements
2564 exist.  See L<RE-INDEXING> below for details.
2565
2566 =head2 BUCKET LIST
2567
2568 A I<Bucket List> is a collection of 16 MD5 hashes for keys/elements, plus
2569 file offsets to where the actual data is stored.  It starts with a standard
2570 tag header, with type I<B>, and a data size of 320 bytes in 32-bit mode, or
2571 384 bytes in 64-bit mode.  Each MD5 hash is stored in full (16 bytes), plus
2572 the 32-bit or 64-bit file offset for the I<Bucket> containing the actual data.
2573 When the list fills up, a I<Re-Index> operation is performed (See
2574 L<RE-INDEXING> below).
2575
2576 =head2 BUCKET
2577
2578 A I<Bucket> is a tag containing a key/value pair (in hash mode), or a
2579 index/value pair (in array mode).  It starts with a standard tag header with
2580 type I<D> for scalar data (string, binary, etc.), or it could be a nested
2581 hash (type I<H>) or array (type I<A>).  The value comes just after the tag
2582 header.  The size reported in the tag header is only for the value, but then,
2583 just after the value is another size (32-bit unsigned long) and then the plain
2584 key itself.  Since the value is likely to be fetched more often than the plain
2585 key, I figured it would be I<slightly> faster to store the value first.
2586
2587
2588
2589 If the type is I<H> (hash) or I<A> (array), the value is another I<Master Index>
2590 record for the nested structure, where the process begins all over again.
2591
2592 =head2 RE-INDEXING
2593
2594 After a I<Bucket List> grows to 16 records, its allocated space in the file is
2595 exhausted.  Then, when another key/element comes in, the list is converted to a
2596 new index record.  However, this index will look at the next char in the MD5
2597 hash, and arrange new Bucket List pointers accordingly.  This process is called
2598 I<Re-Indexing>.  Basically, a new index tag is created at the file EOF, and all
2599 17 (16 + new one) keys/elements are removed from the old Bucket List and
2600 inserted into the new index.  Several new Bucket Lists are created in the
2601 process, as a new MD5 char from the key is being examined (it is unlikely that
2602 the keys will all share the same next char of their MD5s).
2603
2604
2605
2606 Because of the way the I<MD5> algorithm works, it is impossible to tell exactly
2607 when the Bucket Lists will turn into indexes, but the first round tends to
2608 happen right around 4,000 keys.  You will see a I<slight> decrease in
2609 performance here, but it picks back up pretty quick (see L<SPEED> above).  Then
2610 it takes B<a lot> more keys to exhaust the next level of Bucket Lists.  It's
2611 right around 900,000 keys.  This process can continue nearly indefinitely --
2612 right up until the point the I<MD5> signatures start colliding with each other,
2613 and this is B<EXTREMELY> rare -- like winning the lottery 5 times in a row AND
2614 getting struck by lightning while you are walking to cash in your tickets.
2615 Theoretically, since I<MD5> hashes are 128-bit values, you I<could> have up to
2616 340,282,366,921,000,000,000,000,000,000,000,000,000 keys/elements (I believe
2617 this is 340 unodecillion, but don't quote me).
2618
2619 =head2 STORING
2620
2621 When a new key/element is stored, the key (or index number) is first ran through
2622 I<Digest::MD5> to get a 128-bit signature (example, in hex:
2623 b05783b0773d894396d475ced9d2f4f6).  Then, the I<Master Index> record is checked
2624 for the first char of the signature (in this case I<b>).  If it does not exist,
2625 a new I<Bucket List> is created for our key (and the next 15 future keys that
2626 happen to also have I<b> as their first MD5 char).  The entire MD5 is written
2627 to the I<Bucket List> along with the offset of the new I<Bucket> record (EOF at
2628 this point, unless we are replacing an existing I<Bucket>), where the actual
2629 data will be stored.
2630
2631 =head2 FETCHING
2632
2633 Fetching an existing key/element involves getting a I<Digest::MD5> of the key
2634 (or index number), then walking along the indexes.  If there are enough
2635 keys/elements in this DB level, there might be nested indexes, each linked to
2636 a particular char of the MD5.  Finally, a I<Bucket List> is pointed to, which
2637 contains up to 16 full MD5 hashes.  Each is checked for equality to the key in
2638 question.  If we found a match, the I<Bucket> tag is loaded, where the value and
2639 plain key are stored.
2640
2641
2642
2643 Fetching the plain key occurs when calling the I<first_key()> and I<next_key()>
2644 methods.  In this process the indexes are walked systematically, and each key
2645 fetched in increasing MD5 order (which is why it appears random).   Once the
2646 I<Bucket> is found, the value is skipped the plain key returned instead.
2647 B<Note:> Do not count on keys being fetched as if the MD5 hashes were
2648 alphabetically sorted.  This only happens on an index-level -- as soon as the
2649 I<Bucket Lists> are hit, the keys will come out in the order they went in --
2650 so it's pretty much undefined how the keys will come out -- just like Perl's
2651 built-in hashes.
2652
2653 =head1 CODE COVERAGE
2654
2655 I use B<Devel::Cover> to test the code coverage of my tests, below is the B<Devel::Cover> report on this
2656 module's test suite.
2657
2658   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2659   File                           stmt   bran   cond    sub    pod   time  total
2660   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2661   blib/lib/DBM/Deep.pm           93.9   82.4   74.7   97.9   10.5   85.7   88.0
2662   blib/lib/DBM/Deep/Array.pm     97.8   84.6   50.0  100.0    n/a    9.0   94.6
2663   blib/lib/DBM/Deep/Hash.pm      93.9   87.5  100.0  100.0    n/a    5.3   93.4
2664   Total                          94.4   82.9   75.8   98.5   10.5  100.0   89.0
2665   ---------------------------- ------ ------ ------ ------ ------ ------ ------
2666
2667 =head1 AUTHOR
2668
2669 Joseph Huckaby, L<jhuckaby@cpan.org>
2670
2671 Special thanks to Adam Sah and Rich Gaushell!  You know why :-)
2672
2673 =head1 SEE ALSO
2674
2675 perltie(1), Tie::Hash(3), Digest::MD5(3), Fcntl(3), flock(2), lockf(3), nfs(5),
2676 Digest::SHA256(3), Crypt::Blowfish(3), Compress::Zlib(3)
2677
2678 =head1 LICENSE
2679
2680 Copyright (c) 2002-2005 Joseph Huckaby.  All Rights Reserved.
2681 This is free software, you may use it and distribute it under the
2682 same terms as Perl itself.
2683
2684 =cut