lib/DBM/Deep/Hash.pm

   1 package DBM::Deep::Hash;
   2
   3 use 5.6.0;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = q(0.99_01);
   9
  10 use base 'DBM::Deep';
  11
  12 sub _get_self {
  13     eval { local $SIG{'__DIE__'}; tied( %{$_[0]} ) } || $_[0]
  14 }
  15
  16 sub _repr { shift;return { @_ } }
  17
  18 sub _import {
  19     my $self = shift;
  20     my ($struct) = @_;
  21
  22     eval {
  23         local $SIG{'__DIE__'};
  24         foreach my $key (keys %$struct) {
  25             $self->put($key, $struct->{$key});
  26         }
  27     }; if ($@) {
  28         $self->_throw_error("Cannot import: type mismatch");
  29     }
  30
  31     return 1;
  32 }
  33
  34 sub TIEHASH {
  35     ##
  36     # Tied hash constructor method, called by Perl's tie() function.
  37     ##
  38     my $class = shift;
  39     my $args = $class->_get_args( @_ );
  40
  41     $args->{type} = $class->TYPE_HASH;
  42
  43     return $class->_init($args);
  44 }
  45
  46 sub FETCH {
  47     my $self = shift->_get_self;
  48     my $key = ($self->_fileobj->{filter_store_key})
  49         ? $self->_fileobj->{filter_store_key}->($_[0])
  50         : $_[0];
  51
  52     return $self->SUPER::FETCH( $key, $_[0] );
  53 }
  54
  55 sub STORE {
  56     my $self = shift->_get_self;
  57         my $key = ($self->_fileobj->{filter_store_key})
  58         ? $self->_fileobj->{filter_store_key}->($_[0])
  59         : $_[0];
  60     my $value = $_[1];
  61
  62     return $self->SUPER::STORE( $key, $value, $_[0] );
  63 }
  64
  65 sub EXISTS {
  66     my $self = shift->_get_self;
  67         my $key = ($self->_fileobj->{filter_store_key})
  68         ? $self->_fileobj->{filter_store_key}->($_[0])
  69         : $_[0];
  70
  71     return $self->SUPER::EXISTS( $key );
  72 }
  73
  74 sub DELETE {
  75     my $self = shift->_get_self;
  76         my $key = ($self->_fileobj->{filter_store_key})
  77         ? $self->_fileobj->{filter_store_key}->($_[0])
  78         : $_[0];
  79
  80     return $self->SUPER::DELETE( $key, $_[0] );
  81 }
  82
  83 sub FIRSTKEY {
  84         ##
  85         # Locate and return first key (in no particular order)
  86         ##
  87     my $self = shift->_get_self;
  88
  89         ##
  90         # Request shared lock for reading
  91         ##
  92         $self->lock( $self->LOCK_SH );
  93
  94         my $result = $self->_engine->get_next_key($self);
  95
  96         $self->unlock();
  97
  98         return ($result && $self->_fileobj->{filter_fetch_key})
  99         ? $self->_fileobj->{filter_fetch_key}->($result)
 100         : $result;
 101 }
 102
 103 sub NEXTKEY {
 104         ##
 105         # Return next key (in no particular order), given previous one
 106         ##
 107     my $self = shift->_get_self;
 108
 109         my $prev_key = ($self->_fileobj->{filter_store_key})
 110         ? $self->_fileobj->{filter_store_key}->($_[0])
 111         : $_[0];
 112
 113         my $prev_md5 = $self->_engine->{digest}->($prev_key);
 114
 115         ##
 116         # Request shared lock for reading
 117         ##
 118         $self->lock( $self->LOCK_SH );
 119
 120         my $result = $self->_engine->get_next_key( $self, $prev_md5 );
 121
 122         $self->unlock();
 123
 124         return ($result && $self->_fileobj->{filter_fetch_key})
 125         ? $self->_fileobj->{filter_fetch_key}->($result)
 126         : $result;
 127 }
 128
 129 ##
 130 # Public method aliases
 131 ##
 132 sub first_key { (shift)->FIRSTKEY(@_) }
 133 sub next_key { (shift)->NEXTKEY(@_) }
 134
 135 sub _copy_node {
 136     my $self = shift;
 137     my ($db_temp) = @_;
 138
 139     my $key = $self->first_key();
 140     while ($key) {
 141         my $value = $self->get($key);
 142         $self->_copy_value( \$db_temp->{$key}, $value );
 143         $key = $self->next_key($key);
 144     }
 145
 146     return 1;
 147 }
 148
 149 1;
 150 __END__