lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 ##
   8 # Setup file and tag signatures.  These should never change.
   9 ##
  10 sub SIG_FILE     () { 'DPDB' }
  11 sub SIG_INTERNAL () { 'i'    }
  12 sub SIG_HASH     () { 'H'    }
  13 sub SIG_ARRAY    () { 'A'    }
  14 sub SIG_NULL     () { 'N'    }
  15 sub SIG_DATA     () { 'D'    }
  16 sub SIG_INDEX    () { 'I'    }
  17 sub SIG_BLIST    () { 'B'    }
  18 sub SIG_FREE     () { 'F'    }
  19 sub SIG_SIZE     () {  1     }
  20
  21 sub precalc_sizes {
  22     ##
  23     # Precalculate index, bucket and bucket list sizes
  24     ##
  25     my $self = shift;
  26
  27     $self->{index_size}       = (2**8) * $self->{long_size};
  28     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size} * 2;
  29     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  30
  31     return 1;
  32 }
  33
  34 sub set_pack {
  35     ##
  36     # Set pack/unpack modes (see file header for more)
  37     ##
  38     my $self = shift;
  39     my ($long_s, $long_p, $data_s, $data_p) = @_;
  40
  41     ##
  42     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
  43     # GB per file.
  44     #    (Perl must be compiled with largefile support for files > 2 GB)
  45     #
  46     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47     #    (Perl must be compiled with largefile and 64-bit long support)
  48     ##
  49     $self->{long_size} = $long_s ? $long_s : 4;
  50     $self->{long_pack} = $long_p ? $long_p : 'N';
  51
  52     ##
  53     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
  54     # key/value. Upgrading this is possible (see above) but probably not
  55     # necessary. If you need more than 4 GB for a single key or value, this
  56     # module is really not for you :-)
  57     ##
  58     $self->{data_size} = $data_s ? $data_s : 4;
  59     $self->{data_pack} = $data_p ? $data_p : 'N';
  60
  61     return $self->precalc_sizes();
  62 }
  63
  64 sub set_digest {
  65     ##
  66     # Set key digest function (default is MD5)
  67     ##
  68     my $self = shift;
  69     my ($digest_func, $hash_size) = @_;
  70
  71     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  72     $self->{hash_size} = $hash_size ? $hash_size : 16;
  73
  74     return $self->precalc_sizes();
  75 }
  76
  77 sub new {
  78     my $class = shift;
  79     my ($args) = @_;
  80
  81     my $self = bless {
  82         long_size   => 4,
  83         long_pack   => 'N',
  84         data_size   => 4,
  85         data_pack   => 'N',
  86
  87         digest      => \&Digest::MD5::md5,
  88         hash_size   => 16,
  89
  90         ##
  91         # Maximum number of buckets per list before another level of indexing is
  92         # done.
  93         # Increase this value for slightly greater speed, but larger database
  94         # files. DO NOT decrease this value below 16, due to risk of recursive
  95         # reindex overrun.
  96         ##
  97         max_buckets => 16,
  98     }, $class;
  99
 100     $self->precalc_sizes;
 101
 102     return $self;
 103 }
 104
 105 sub setup_fh {
 106     my $self = shift;
 107     my ($obj) = @_;
 108
 109     $self->open( $obj ) if !defined $obj->_fh;
 110
 111     my $fh = $obj->_fh;
 112     flock $fh, LOCK_EX;
 113
 114     unless ( $obj->{base_offset} ) {
 115         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 116         my $signature;
 117         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 118
 119         ##
 120         # File is empty -- write signature and master index
 121         ##
 122         if (!$bytes_read) {
 123             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
 124             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
 125             print( $fh SIG_FILE);
 126
 127             $obj->{base_offset} = $self->_request_space(
 128                 $obj, $self->tag_size( $self->{index_size} ),
 129             );
 130
 131             $self->write_tag(
 132                 $obj, $obj->_base_offset, $obj->_type,
 133                 chr(0)x$self->{index_size},
 134             );
 135
 136             # Flush the filehandle
 137             my $old_fh = select $fh;
 138             my $old_af = $|; $| = 1; $| = $old_af;
 139             select $old_fh;
 140         }
 141         else {
 142             $obj->{base_offset} = $bytes_read;
 143
 144             ##
 145             # Check signature was valid
 146             ##
 147             unless ($signature eq SIG_FILE) {
 148                 $self->close_fh( $obj );
 149                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
 150             }
 151
 152             ##
 153             # Get our type from master index signature
 154             ##
 155             my $tag = $self->load_tag($obj, $obj->_base_offset)
 156             or $obj->_throw_error("Corrupted file, no master index record");
 157
 158             unless ($obj->{type} eq $tag->{signature}) {
 159                 $obj->_throw_error("File type mismatch");
 160             }
 161         }
 162     }
 163
 164     #XXX We have to make sure we don't mess up when autoflush isn't turned on
 165     unless ( $obj->_root->{inode} ) {
 166         my @stats = stat($obj->_fh);
 167         $obj->_root->{inode} = $stats[1];
 168         $obj->_root->{end} = $stats[7];
 169     }
 170
 171     flock $fh, LOCK_UN;
 172
 173     return 1;
 174 }
 175
 176 sub open {
 177     ##
 178     # Open a fh to the database, create if nonexistent.
 179     # Make sure file signature matches DBM::Deep spec.
 180     ##
 181     my $self = shift;
 182     my ($obj) = @_;
 183
 184     # Theoretically, adding O_BINARY should remove the need for the binmode
 185     # Of course, testing it is going to be ... interesting.
 186     my $flags = O_RDWR | O_CREAT | O_BINARY;
 187
 188     my $fh;
 189     my $filename = $obj->_root->{file};
 190     sysopen( $fh, $filename, $flags )
 191         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
 192     $obj->_root->{fh} = $fh;
 193
 194     #XXX Can we remove this by using the right sysopen() flags?
 195     # Maybe ... q.v. above
 196     binmode $fh; # for win32
 197
 198     if ($obj->_root->{autoflush}) {
 199         my $old = select $fh;
 200         $|=1;
 201         select $old;
 202     }
 203
 204     return 1;
 205 }
 206
 207 sub close_fh {
 208     my $self = shift;
 209     my ($obj) = @_;
 210
 211     if ( my $fh = $obj->_root->{fh} ) {
 212         close $fh;
 213     }
 214     $obj->_root->{fh} = undef;
 215
 216     return 1;
 217 }
 218
 219 sub tag_size {
 220     my $self = shift;
 221     my ($size) = @_;
 222     return SIG_SIZE + $self->{data_size} + $size;
 223 }
 224
 225 sub write_tag {
 226     ##
 227     # Given offset, signature and content, create tag and write to disk
 228     ##
 229     my $self = shift;
 230     my ($obj, $offset, $sig, $content) = @_;
 231     my $size = length( $content );
 232
 233     my $fh = $obj->_fh;
 234
 235     if ( defined $offset ) {
 236         seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 237     }
 238
 239     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 240
 241     return unless defined $offset;
 242
 243     return {
 244         signature => $sig,
 245         size => $size,
 246         offset => $offset + SIG_SIZE + $self->{data_size},
 247         content => $content
 248     };
 249 }
 250
 251 sub load_tag {
 252     ##
 253     # Given offset, load single tag and return signature, size and data
 254     ##
 255     my $self = shift;
 256     my ($obj, $offset) = @_;
 257
 258 #    print join(':',map{$_||''}caller(1)), $/;
 259
 260     my $fh = $obj->_fh;
 261
 262     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 263
 264     #XXX I'm not sure this check will work if autoflush isn't enabled ...
 265     return if eof $fh;
 266
 267     my $b;
 268     read( $fh, $b, SIG_SIZE + $self->{data_size} );
 269     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 270
 271     my $buffer;
 272     read( $fh, $buffer, $size);
 273
 274     return {
 275         signature => $sig,
 276         size => $size,
 277         offset => $offset + SIG_SIZE + $self->{data_size},
 278         content => $buffer
 279     };
 280 }
 281
 282 sub _length_needed {
 283     my $self = shift;
 284     my ($obj, $value, $key) = @_;
 285
 286     my $is_dbm_deep = eval {
 287         local $SIG{'__DIE__'};
 288         $value->isa( 'DBM::Deep' );
 289     };
 290
 291     my $len = SIG_SIZE + $self->{data_size}
 292             + $self->{data_size} + length( $key );
 293
 294     if ( $is_dbm_deep && $value->_root eq $obj->_root ) {
 295         return $len + $self->{long_size};
 296     }
 297
 298     my $r = Scalar::Util::reftype( $value ) || '';
 299     if ( $obj->_root->{autobless} ) {
 300         # This is for the bit saying whether or not this thing is blessed.
 301         $len += 1;
 302     }
 303
 304     unless ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 305         if ( defined $value ) {
 306             $len += length( $value );
 307         }
 308         return $len;
 309     }
 310
 311     $len += $self->{index_size};
 312
 313     # if autobless is enabled, must also take into consideration
 314     # the class name as it is stored after the key.
 315     if ( $obj->_root->{autobless} ) {
 316         my $value_class = Scalar::Util::blessed($value);
 317         if ( defined $value_class && !$is_dbm_deep ) {
 318             $len += $self->{data_size} + length($value_class);
 319         }
 320     }
 321
 322     return $len;
 323 }
 324
 325 sub add_bucket {
 326     ##
 327     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 328     # plain (undigested) key and value.
 329     ##
 330     my $self = shift;
 331     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 332
 333     # This verifies that only supported values will be stored.
 334     {
 335         my $r = Scalar::Util::reftype( $value );
 336         last if !defined $r;
 337
 338         last if $r eq 'HASH';
 339         last if $r eq 'ARRAY';
 340
 341         $obj->_throw_error(
 342             "Storage of variables of type '$r' is not supported."
 343         );
 344     }
 345
 346     my $location = 0;
 347     my $result = 2;
 348
 349     my $root = $obj->_root;
 350     my $fh   = $obj->_fh;
 351
 352     my $actual_length = $self->_length_needed( $obj, $value, $plain_key );
 353
 354     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 355
 356 #    $self->_release_space( $obj, $size, $subloc );
 357     # Updating a known md5
 358 #XXX This needs updating to use _release_space
 359     if ( $subloc ) {
 360         $result = 1;
 361
 362         if ($actual_length <= $size) {
 363             $location = $subloc;
 364         }
 365         else {
 366             $location = $self->_request_space( $obj, $actual_length );
 367             seek(
 368                 $fh,
 369                 $tag->{offset} + $offset
 370               + $self->{hash_size} + $root->{file_offset},
 371                 SEEK_SET,
 372             );
 373             print( $fh pack($self->{long_pack}, $location ) );
 374             print( $fh pack($self->{long_pack}, $actual_length ) );
 375         }
 376     }
 377     # Adding a new md5
 378     elsif ( defined $offset ) {
 379         $location = $self->_request_space( $obj, $actual_length );
 380
 381         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
 382         print( $fh $md5 . pack($self->{long_pack}, $location ) );
 383         print( $fh pack($self->{long_pack}, $actual_length ) );
 384     }
 385     # If bucket didn't fit into list, split into a new index level
 386     # split_index() will do the _request_space() call
 387     else {
 388         $location = $self->split_index( $obj, $md5, $tag );
 389     }
 390
 391     $self->write_value( $obj, $location, $plain_key, $value );
 392
 393     return $result;
 394 }
 395
 396 sub write_value {
 397     my $self = shift;
 398     my ($obj, $location, $key, $value) = @_;
 399
 400     my $fh = $obj->_fh;
 401     my $root = $obj->_root;
 402
 403     my $is_dbm_deep = eval {
 404         local $SIG{'__DIE__'};
 405         $value->isa( 'DBM::Deep' );
 406     };
 407
 408     my $is_internal_ref = $is_dbm_deep && ($value->_root eq $root);
 409
 410     seek($fh, $location + $root->{file_offset}, SEEK_SET);
 411
 412     ##
 413     # Write signature based on content type, set content length and write
 414     # actual value.
 415     ##
 416     my $r = Scalar::Util::reftype($value) || '';
 417     if ( $is_internal_ref ) {
 418         $self->write_tag( $obj, undef, SIG_INTERNAL,pack($self->{long_pack}, $value->_base_offset) );
 419     }
 420     elsif ($r eq 'HASH') {
 421         $self->write_tag( $obj, undef, SIG_HASH, chr(0)x$self->{index_size} );
 422     }
 423     elsif ($r eq 'ARRAY') {
 424         $self->write_tag( $obj, undef, SIG_ARRAY, chr(0)x$self->{index_size} );
 425     }
 426     elsif (!defined($value)) {
 427         $self->write_tag( $obj, undef, SIG_NULL, '' );
 428     }
 429     else {
 430         $self->write_tag( $obj, undef, SIG_DATA, $value );
 431     }
 432
 433     ##
 434     # Plain key is stored AFTER value, as keys are typically fetched less often.
 435     ##
 436     print( $fh pack($self->{data_pack}, length($key)) . $key );
 437
 438     # Internal references don't care about autobless
 439     return 1 if $is_internal_ref;
 440
 441     ##
 442     # If value is blessed, preserve class name
 443     ##
 444     if ( $root->{autobless} ) {
 445         my $value_class = Scalar::Util::blessed($value);
 446         if ( defined $value_class && !$is_dbm_deep ) {
 447             print( $fh chr(1) );
 448             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 449         }
 450         else {
 451             print( $fh chr(0) );
 452         }
 453     }
 454
 455     ##
 456     # If content is a hash or array, create new child DBM::Deep object and
 457     # pass each key or element to it.
 458     ##
 459     if ( !$is_internal_ref ) {
 460         if ($r eq 'HASH') {
 461             my $branch = DBM::Deep->new(
 462                 type => DBM::Deep->TYPE_HASH,
 463                 base_offset => $location,
 464                 root => $root,
 465             );
 466             foreach my $key (keys %{$value}) {
 467                 $branch->STORE( $key, $value->{$key} );
 468             }
 469         }
 470         elsif ($r eq 'ARRAY') {
 471             my $branch = DBM::Deep->new(
 472                 type => DBM::Deep->TYPE_ARRAY,
 473                 base_offset => $location,
 474                 root => $root,
 475             );
 476             my $index = 0;
 477             foreach my $element (@{$value}) {
 478                 $branch->STORE( $index, $element );
 479                 $index++;
 480             }
 481         }
 482     }
 483
 484     return 1;
 485 }
 486
 487 sub split_index {
 488     my $self = shift;
 489     my ($obj, $md5, $tag) = @_;
 490
 491     my $fh = $obj->_fh;
 492     my $root = $obj->_root;
 493
 494     my $loc = $self->_request_space(
 495         $obj, $self->tag_size( $self->{index_size} ),
 496     );
 497
 498     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 499     print( $fh pack($self->{long_pack}, $loc) );
 500
 501     my $index_tag = $self->write_tag(
 502         $obj, $loc, SIG_INDEX,
 503         chr(0)x$self->{index_size},
 504     );
 505
 506     my $newtag_loc = $self->_request_space(
 507         $obj, $self->tag_size( $self->{bucket_list_size} ),
 508     );
 509
 510     my $keys = $tag->{content}
 511              . $md5 . pack($self->{long_pack}, $newtag_loc)
 512                     . pack($self->{long_pack}, 0);
 513
 514     my @newloc = ();
 515     BUCKET:
 516     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
 517         my ($key, $old_subloc, $size) = $self->_get_key_subloc( $keys, $i );
 518
 519         die "[INTERNAL ERROR]: No key in split_index()\n" unless $key;
 520         die "[INTERNAL ERROR]: No subloc in split_index()\n" unless $old_subloc;
 521
 522         my $num = ord(substr($key, $tag->{ch} + 1, 1));
 523
 524         if ($newloc[$num]) {
 525             seek($fh, $newloc[$num] + $root->{file_offset}, SEEK_SET);
 526             my $subkeys;
 527             read( $fh, $subkeys, $self->{bucket_list_size});
 528
 529             # This is looking for the first empty spot
 530             my ($subloc, $offset, $size) = $self->_find_in_buckets(
 531                 { content => $subkeys }, '',
 532             );
 533
 534             seek($fh, $newloc[$num] + $offset + $root->{file_offset}, SEEK_SET);
 535             print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 536
 537             next;
 538         }
 539
 540         seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 541
 542         my $loc = $self->_request_space(
 543             $obj, $self->tag_size( $self->{bucket_list_size} ),
 544         );
 545
 546         print( $fh pack($self->{long_pack}, $loc) );
 547
 548         my $blist_tag = $self->write_tag(
 549             $obj, $loc, SIG_BLIST,
 550             chr(0)x$self->{bucket_list_size},
 551         );
 552
 553         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 554         print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 555
 556         $newloc[$num] = $blist_tag->{offset};
 557     }
 558
 559     $self->_release_space(
 560         $obj, $self->tag_size( $self->{bucket_list_size} ),
 561         $tag->{offset} - SIG_SIZE - $self->{data_size},
 562     );
 563
 564     return $newtag_loc;
 565 }
 566
 567 sub read_from_loc {
 568     my $self = shift;
 569     my ($obj, $subloc) = @_;
 570
 571     my $fh = $obj->_fh;
 572
 573     ##
 574     # Found match -- seek to offset and read signature
 575     ##
 576     my $signature;
 577     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 578     read( $fh, $signature, SIG_SIZE);
 579
 580     ##
 581     # If value is a hash or array, return new DBM::Deep object with correct offset
 582     ##
 583     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
 584         my $obj = DBM::Deep->new(
 585             type => $signature,
 586             base_offset => $subloc,
 587             root => $obj->_root,
 588         );
 589
 590         if ($obj->_root->{autobless}) {
 591             ##
 592             # Skip over value and plain key to see if object needs
 593             # to be re-blessed
 594             ##
 595             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 596
 597             my $size;
 598             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 599             if ($size) { seek($fh, $size, SEEK_CUR); }
 600
 601             my $bless_bit;
 602             read( $fh, $bless_bit, 1);
 603             if (ord($bless_bit)) {
 604                 ##
 605                 # Yes, object needs to be re-blessed
 606                 ##
 607                 my $class_name;
 608                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 609                 if ($size) { read( $fh, $class_name, $size); }
 610                 if ($class_name) { $obj = bless( $obj, $class_name ); }
 611             }
 612         }
 613
 614         return $obj;
 615     }
 616     elsif ( $signature eq SIG_INTERNAL ) {
 617         my $size;
 618         read( $fh, $size, $self->{data_size});
 619         $size = unpack($self->{data_pack}, $size);
 620
 621         if ( $size ) {
 622             my $new_loc;
 623             read( $fh, $new_loc, $size );
 624             $new_loc = unpack( $self->{long_pack}, $new_loc );
 625
 626             return $self->read_from_loc( $obj, $new_loc );
 627         }
 628         else {
 629             return;
 630         }
 631     }
 632     ##
 633     # Otherwise return actual value
 634     ##
 635     elsif ($signature eq SIG_DATA) {
 636         my $size;
 637         read( $fh, $size, $self->{data_size});
 638         $size = unpack($self->{data_pack}, $size);
 639
 640         my $value = '';
 641         if ($size) { read( $fh, $value, $size); }
 642         return $value;
 643     }
 644
 645     ##
 646     # Key exists, but content is null
 647     ##
 648     return;
 649 }
 650
 651 sub get_bucket_value {
 652     ##
 653     # Fetch single value given tag and MD5 digested key.
 654     ##
 655     my $self = shift;
 656     my ($obj, $tag, $md5) = @_;
 657
 658     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 659     if ( $subloc ) {
 660         return $self->read_from_loc( $obj, $subloc );
 661     }
 662     return;
 663 }
 664
 665 sub delete_bucket {
 666     ##
 667     # Delete single key/value pair given tag and MD5 digested key.
 668     ##
 669     my $self = shift;
 670     my ($obj, $tag, $md5) = @_;
 671
 672     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 673 #XXX This needs _release_space()
 674     if ( $subloc ) {
 675         my $fh = $obj->_fh;
 676         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
 677         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
 678         print( $fh chr(0) x $self->{bucket_size} );
 679
 680         return 1;
 681     }
 682     return;
 683 }
 684
 685 sub bucket_exists {
 686     ##
 687     # Check existence of single key given tag and MD5 digested key.
 688     ##
 689     my $self = shift;
 690     my ($obj, $tag, $md5) = @_;
 691
 692     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 693     return $subloc && 1;
 694 }
 695
 696 sub find_bucket_list {
 697     ##
 698     # Locate offset for bucket list, given digested key
 699     ##
 700     my $self = shift;
 701     my ($obj, $md5, $args) = @_;
 702     $args = {} unless $args;
 703
 704     ##
 705     # Locate offset for bucket list using digest index system
 706     ##
 707     my $tag = $self->load_tag($obj, $obj->_base_offset)
 708         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 709
 710     my $ch = 0;
 711     while ($tag->{signature} ne SIG_BLIST) {
 712         my $num = ord substr($md5, $ch, 1);
 713
 714         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 715         $tag = $self->index_lookup( $obj, $tag, $num );
 716
 717         if (!$tag) {
 718             return if !$args->{create};
 719
 720             my $loc = $self->_request_space(
 721                 $obj, $self->tag_size( $self->{bucket_list_size} ),
 722             );
 723
 724             my $fh = $obj->_fh;
 725             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 726             print( $fh pack($self->{long_pack}, $loc) );
 727
 728             $tag = $self->write_tag(
 729                 $obj, $loc, SIG_BLIST,
 730                 chr(0)x$self->{bucket_list_size},
 731             );
 732
 733             $tag->{ref_loc} = $ref_loc;
 734             $tag->{ch} = $ch;
 735
 736             last;
 737         }
 738
 739         $tag->{ch} = $ch++;
 740         $tag->{ref_loc} = $ref_loc;
 741     }
 742
 743     return $tag;
 744 }
 745
 746 sub index_lookup {
 747     ##
 748     # Given index tag, lookup single entry in index and return .
 749     ##
 750     my $self = shift;
 751     my ($obj, $tag, $index) = @_;
 752
 753     my $location = unpack(
 754         $self->{long_pack},
 755         substr(
 756             $tag->{content},
 757             $index * $self->{long_size},
 758             $self->{long_size},
 759         ),
 760     );
 761
 762     if (!$location) { return; }
 763
 764     return $self->load_tag( $obj, $location );
 765 }
 766
 767 sub traverse_index {
 768     ##
 769     # Scan index and recursively step into deeper levels, looking for next key.
 770     ##
 771     my $self = shift;
 772     my ($obj, $offset, $ch, $force_return_next) = @_;
 773
 774     my $tag = $self->load_tag($obj, $offset );
 775
 776     my $fh = $obj->_fh;
 777
 778     if ($tag->{signature} ne SIG_BLIST) {
 779         my $content = $tag->{content};
 780         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
 781
 782         for (my $idx = $start; $idx < (2**8); $idx++) {
 783             my $subloc = unpack(
 784                 $self->{long_pack},
 785                 substr(
 786                     $content,
 787                     $idx * $self->{long_size},
 788                     $self->{long_size},
 789                 ),
 790             );
 791
 792             if ($subloc) {
 793                 my $result = $self->traverse_index(
 794                     $obj, $subloc, $ch + 1, $force_return_next,
 795                 );
 796
 797                 if (defined($result)) { return $result; }
 798             }
 799         } # index loop
 800
 801         $obj->{return_next} = 1;
 802     } # tag is an index
 803
 804     else {
 805         my $keys = $tag->{content};
 806         if ($force_return_next) { $obj->{return_next} = 1; }
 807
 808         ##
 809         # Iterate through buckets, looking for a key match
 810         ##
 811         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 812             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
 813
 814             # End of bucket list -- return to outer loop
 815             if (!$subloc) {
 816                 $obj->{return_next} = 1;
 817                 last;
 818             }
 819             # Located previous key -- return next one found
 820             elsif ($key eq $obj->{prev_md5}) {
 821                 $obj->{return_next} = 1;
 822                 next;
 823             }
 824             # Seek to bucket location and skip over signature
 825             elsif ($obj->{return_next}) {
 826                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 827
 828                 # Skip over value to get to plain key
 829                 my $sig;
 830                 read( $fh, $sig, SIG_SIZE );
 831
 832                 my $size;
 833                 read( $fh, $size, $self->{data_size});
 834                 $size = unpack($self->{data_pack}, $size);
 835                 if ($size) { seek($fh, $size, SEEK_CUR); }
 836
 837                 # Read in plain key and return as scalar
 838                 my $plain_key;
 839                 read( $fh, $size, $self->{data_size});
 840                 $size = unpack($self->{data_pack}, $size);
 841                 if ($size) { read( $fh, $plain_key, $size); }
 842
 843                 return $plain_key;
 844             }
 845         }
 846
 847         $obj->{return_next} = 1;
 848     } # tag is a bucket list
 849
 850     return;
 851 }
 852
 853 sub get_next_key {
 854     ##
 855     # Locate next key, given digested previous one
 856     ##
 857     my $self = shift;
 858     my ($obj) = @_;
 859
 860     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 861     $obj->{return_next} = 0;
 862
 863     ##
 864     # If the previous key was not specifed, start at the top and
 865     # return the first one found.
 866     ##
 867     if (!$obj->{prev_md5}) {
 868         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 869         $obj->{return_next} = 1;
 870     }
 871
 872     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 873 }
 874
 875 # Utilities
 876
 877 sub _get_key_subloc {
 878     my $self = shift;
 879     my ($keys, $idx) = @_;
 880
 881     my ($key, $subloc, $size) = unpack(
 882         "a$self->{hash_size} $self->{long_pack} $self->{long_pack}",
 883         substr(
 884             $keys,
 885             ($idx * $self->{bucket_size}),
 886             $self->{bucket_size},
 887         ),
 888     );
 889
 890     return ($key, $subloc, $size);
 891 }
 892
 893 sub _find_in_buckets {
 894     my $self = shift;
 895     my ($tag, $md5) = @_;
 896
 897     BUCKET:
 898     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
 899         my ($key, $subloc, $size) = $self->_get_key_subloc(
 900             $tag->{content}, $i,
 901         );
 902
 903         return ($subloc, $i * $self->{bucket_size}, $size) unless $subloc;
 904
 905         next BUCKET if $key ne $md5;
 906
 907         return ($subloc, $i * $self->{bucket_size}, $size);
 908     }
 909
 910     return;
 911 }
 912
 913 #sub _print_at {
 914 #    my $self = shift;
 915 #    my ($obj, $spot, $data) = @_;
 916 #
 917 #    my $fh = $obj->_fh;
 918 #    seek( $fh, $spot, SEEK_SET );
 919 #    print( $fh $data );
 920 #
 921 #    return;
 922 #}
 923
 924 sub _request_space {
 925     my $self = shift;
 926     my ($obj, $size) = @_;
 927
 928     my $loc = $obj->_root->{end};
 929     $obj->_root->{end} += $size;
 930
 931     return $loc;
 932 }
 933
 934 sub _release_space {
 935     my $self = shift;
 936     my ($obj, $size, $loc) = @_;
 937
 938     my $next_loc = 0;
 939
 940     my $fh = $obj->_fh;
 941     seek( $fh, $loc + $obj->_root->{file_offset}, SEEK_SET );
 942     print( $fh SIG_FREE
 943         . pack($self->{long_pack}, $size )
 944         . pack($self->{long_pack}, $next_loc )
 945     );
 946
 947     return;
 948 }
 949
 950 1;
 951 __END__
 952
 953 # This will be added in later, after more refactoring is done. This is an early
 954 # attempt at refactoring on the physical level instead of the virtual level.
 955 sub _read_at {
 956     my $self = shift;
 957     my ($obj, $spot, $amount, $unpack) = @_;
 958
 959     my $fh = $obj->_fh;
 960     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
 961
 962     my $buffer;
 963     my $bytes_read = read( $fh, $buffer, $amount );
 964
 965     if ( $unpack ) {
 966         $buffer = unpack( $unpack, $buffer );
 967     }
 968
 969     if ( wantarray ) {
 970         return ($buffer, $bytes_read);
 971     }
 972     else {
 973         return $buffer;
 974     }
 975 }