lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 ##
   8 # Setup file and tag signatures.  These should never change.
   9 ##
  10 sub SIG_FILE     () { 'DPDB' }
  11 sub SIG_INTERNAL () { 'i'    }
  12 sub SIG_HASH     () { 'H'    }
  13 sub SIG_ARRAY    () { 'A'    }
  14 sub SIG_NULL     () { 'N'    }
  15 sub SIG_DATA     () { 'D'    }
  16 sub SIG_INDEX    () { 'I'    }
  17 sub SIG_BLIST    () { 'B'    }
  18 sub SIG_SIZE     () {  1     }
  19
  20 sub precalc_sizes {
  21     ##
  22     # Precalculate index, bucket and bucket list sizes
  23     ##
  24     my $self = shift;
  25
  26     $self->{index_size}       = (2**8) * $self->{long_size};
  27     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size};
  28     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  29
  30     return 1;
  31 }
  32
  33 sub set_pack {
  34     ##
  35     # Set pack/unpack modes (see file header for more)
  36     ##
  37     my $self = shift;
  38     my ($long_s, $long_p, $data_s, $data_p) = @_;
  39
  40     ##
  41     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
  42     # GB per file.
  43     #    (Perl must be compiled with largefile support for files > 2 GB)
  44     #
  45     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46     #    (Perl must be compiled with largefile and 64-bit long support)
  47     ##
  48     $self->{long_size} = $long_s ? $long_s : 4;
  49     $self->{long_pack} = $long_p ? $long_p : 'N';
  50
  51     ##
  52     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
  53     # key/value. Upgrading this is possible (see above) but probably not
  54     # necessary. If you need more than 4 GB for a single key or value, this
  55     # module is really not for you :-)
  56     ##
  57     $self->{data_size} = $data_s ? $data_s : 4;
  58     $self->{data_pack} = $data_p ? $data_p : 'N';
  59
  60     return $self->precalc_sizes();
  61 }
  62
  63 sub set_digest {
  64     ##
  65     # Set key digest function (default is MD5)
  66     ##
  67     my $self = shift;
  68     my ($digest_func, $hash_size) = @_;
  69
  70     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  71     $self->{hash_size} = $hash_size ? $hash_size : 16;
  72
  73     return $self->precalc_sizes();
  74 }
  75
  76 sub new {
  77     my $class = shift;
  78     my ($args) = @_;
  79
  80     my $self = bless {
  81         long_size   => 4,
  82         long_pack   => 'N',
  83         data_size   => 4,
  84         data_pack   => 'N',
  85
  86         digest      => \&Digest::MD5::md5,
  87         hash_size   => 16,
  88
  89         ##
  90         # Maximum number of buckets per list before another level of indexing is
  91         # done.
  92         # Increase this value for slightly greater speed, but larger database
  93         # files. DO NOT decrease this value below 16, due to risk of recursive
  94         # reindex overrun.
  95         ##
  96         max_buckets => 16,
  97     }, $class;
  98
  99     $self->precalc_sizes;
 100
 101     return $self;
 102 }
 103
 104 sub setup_fh {
 105     my $self = shift;
 106     my ($obj) = @_;
 107
 108     $self->open( $obj ) if !defined $obj->_fh;
 109
 110     my $fh = $obj->_fh;
 111     flock $fh, LOCK_EX;
 112
 113     unless ( $obj->{base_offset} ) {
 114         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 115         my $signature;
 116         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 117
 118         ##
 119         # File is empty -- write signature and master index
 120         ##
 121         if (!$bytes_read) {
 122             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
 123             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
 124             print( $fh SIG_FILE);
 125
 126             $obj->{base_offset} = $self->_request_space(
 127                 $obj, $self->{index_size},
 128             );
 129
 130             $self->create_tag(
 131                 $obj, $obj->_base_offset, $obj->_type,
 132                 chr(0) x $self->{index_size},
 133             );
 134
 135             # Flush the filehandle
 136             my $old_fh = select $fh;
 137             my $old_af = $|; $| = 1; $| = $old_af;
 138             select $old_fh;
 139         }
 140         else {
 141             $obj->{base_offset} = $bytes_read;
 142
 143             ##
 144             # Check signature was valid
 145             ##
 146             unless ($signature eq SIG_FILE) {
 147                 $self->close_fh( $obj );
 148                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
 149             }
 150
 151             ##
 152             # Get our type from master index signature
 153             ##
 154             my $tag = $self->load_tag($obj, $obj->_base_offset)
 155             or $obj->_throw_error("Corrupted file, no master index record");
 156
 157             unless ($obj->{type} eq $tag->{signature}) {
 158                 $obj->_throw_error("File type mismatch");
 159             }
 160         }
 161     }
 162
 163     #XXX We have to make sure we don't mess up when autoflush isn't turned on
 164     unless ( $obj->_root->{inode} ) {
 165         my @stats = stat($obj->_fh);
 166         $obj->_root->{inode} = $stats[1];
 167         $obj->_root->{end} = $stats[7];
 168     }
 169
 170     flock $fh, LOCK_UN;
 171
 172     return 1;
 173 }
 174
 175 sub open {
 176     ##
 177     # Open a fh to the database, create if nonexistent.
 178     # Make sure file signature matches DBM::Deep spec.
 179     ##
 180     my $self = shift;
 181     my ($obj) = @_;
 182
 183     # Theoretically, adding O_BINARY should remove the need for the binmode
 184     # Of course, testing it is going to be ... interesting.
 185     my $flags = O_RDWR | O_CREAT | O_BINARY;
 186
 187     my $fh;
 188     my $filename = $obj->_root->{file};
 189     sysopen( $fh, $filename, $flags )
 190         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
 191     $obj->_root->{fh} = $fh;
 192
 193     #XXX Can we remove this by using the right sysopen() flags?
 194     # Maybe ... q.v. above
 195     binmode $fh; # for win32
 196
 197     if ($obj->_root->{autoflush}) {
 198         my $old = select $fh;
 199         $|=1;
 200         select $old;
 201     }
 202
 203     return 1;
 204 }
 205
 206 sub close_fh {
 207     my $self = shift;
 208     my ($obj) = @_;
 209
 210     if ( my $fh = $obj->_root->{fh} ) {
 211         close $fh;
 212     }
 213     $obj->_root->{fh} = undef;
 214
 215     return 1;
 216 }
 217
 218 sub create_tag {
 219     ##
 220     # Given offset, signature and content, create tag and write to disk
 221     ##
 222     my $self = shift;
 223     my ($obj, $offset, $sig, $content) = @_;
 224     my $size = length($content);
 225
 226     my $fh = $obj->_fh;
 227
 228     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 229     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 230
 231     if ($offset == $obj->_root->{end}) {
 232         $obj->_root->{end} += SIG_SIZE + $self->{data_size} + $size;
 233     }
 234
 235     return {
 236         signature => $sig,
 237         size => $size,
 238         offset => $offset + SIG_SIZE + $self->{data_size},
 239         content => $content
 240     };
 241 }
 242
 243 sub load_tag {
 244     ##
 245     # Given offset, load single tag and return signature, size and data
 246     ##
 247     my $self = shift;
 248     my ($obj, $offset) = @_;
 249
 250 #    print join(':',map{$_||''}caller(1)), $/;
 251
 252     my $fh = $obj->_fh;
 253
 254     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 255
 256     #XXX I'm not sure this check will work if autoflush isn't enabled ...
 257     return if eof $fh;
 258
 259     my $b;
 260     read( $fh, $b, SIG_SIZE + $self->{data_size} );
 261     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 262
 263     my $buffer;
 264     read( $fh, $buffer, $size);
 265
 266     return {
 267         signature => $sig,
 268         size => $size,
 269         offset => $offset + SIG_SIZE + $self->{data_size},
 270         content => $buffer
 271     };
 272 }
 273
 274 sub add_bucket {
 275     ##
 276     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 277     # plain (undigested) key and value.
 278     ##
 279     my $self = shift;
 280     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 281
 282     # This verifies that only supported values will be stored.
 283     {
 284         my $r = Scalar::Util::reftype( $value );
 285         last if !defined $r;
 286
 287         last if $r eq 'HASH';
 288         last if $r eq 'ARRAY';
 289
 290         $obj->_throw_error(
 291             "Storage of variables of type '$r' is not supported."
 292         );
 293     }
 294
 295     my $location = 0;
 296     my $result = 2;
 297
 298     my $root = $obj->_root;
 299
 300     my $is_dbm_deep = eval {
 301         local $SIG{'__DIE__'};
 302         $value->isa( 'DBM::Deep' );
 303     };
 304
 305     my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 306
 307     my $fh = $obj->_fh;
 308
 309     my ($subloc, $offset) = $self->_find_in_buckets( $tag, $md5 );
 310
 311     # Updating a known md5
 312     if ( $subloc ) {
 313         $result = 1;
 314
 315         ##
 316         # If value is a hash, array, or raw value with equal or less size, we
 317         # can reuse the same content area of the database.  Otherwise, we have
 318         # to create a new content area at the EOF.
 319         ##
 320         my $actual_length;
 321         if ( $internal_ref ) {
 322             $actual_length = $self->{long_size};
 323         }
 324         else {
 325             my $r = Scalar::Util::reftype( $value ) || '';
 326             if ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 327                 $actual_length = $self->{index_size};
 328
 329                 # if autobless is enabled, must also take into consideration
 330                 # the class name, as it is stored along with key/value.
 331                 if ( $root->{autobless} ) {
 332                     my $value_class = Scalar::Util::blessed($value);
 333                     if ( defined $value_class && !$value->isa('DBM::Deep') ) {
 334                         $actual_length += length($value_class);
 335                     }
 336                 }
 337             }
 338             else { $actual_length = length($value); }
 339         }
 340
 341         seek($fh, $subloc + SIG_SIZE + $root->{file_offset}, SEEK_SET);
 342         my $size;
 343         read( $fh, $size, $self->{data_size});
 344         $size = unpack($self->{data_pack}, $size);
 345
 346         if ($actual_length <= $size) {
 347             $location = $subloc;
 348         }
 349         else {
 350             $location = $root->{end};
 351             seek(
 352                 $fh,
 353                 $tag->{offset} + $offset + $self->{hash_size} + $root->{file_offset},
 354                 SEEK_SET,
 355             );
 356             print( $fh pack($self->{long_pack}, $location) );
 357         }
 358     }
 359     # Adding a new md5
 360     elsif ( defined $offset ) {
 361         $location = $root->{end};
 362
 363         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
 364         print( $fh $md5 . pack($self->{long_pack}, $location) );
 365     }
 366     # If bucket didn't fit into list, split into a new index level
 367     else {
 368         $self->split_index( $obj, $md5, $tag );
 369
 370         $location = $root->{end};
 371     }
 372
 373     $self->write_value( $obj, $location, $plain_key, $value );
 374
 375     return $result;
 376 }
 377
 378 sub write_value {
 379     my $self = shift;
 380     my ($obj, $location, $key, $value) = @_;
 381
 382     my $fh = $obj->_fh;
 383     my $root = $obj->_root;
 384
 385     my $is_dbm_deep = eval {
 386         local $SIG{'__DIE__'};
 387         $value->isa( 'DBM::Deep' );
 388     };
 389
 390     my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 391
 392     seek($fh, $location + $root->{file_offset}, SEEK_SET);
 393
 394     ##
 395     # Write signature based on content type, set content length and write
 396     # actual value.
 397     ##
 398     my $r = Scalar::Util::reftype($value) || '';
 399     my $content_length;
 400     if ( $internal_ref ) {
 401         print( $fh SIG_INTERNAL );
 402         print( $fh pack($self->{data_pack}, $self->{long_size}) );
 403         print( $fh pack($self->{long_pack}, $value->_base_offset) );
 404         $content_length = $self->{long_size};
 405     }
 406     else {
 407         if ($r eq 'HASH') {
 408             print( $fh SIG_HASH );
 409             print( $fh pack($self->{data_pack}, $self->{index_size}) . chr(0) x $self->{index_size} );
 410             $content_length = $self->{index_size};
 411         }
 412         elsif ($r eq 'ARRAY') {
 413             print( $fh SIG_ARRAY );
 414             print( $fh pack($self->{data_pack}, $self->{index_size}) . chr(0) x $self->{index_size} );
 415             $content_length = $self->{index_size};
 416         }
 417         elsif (!defined($value)) {
 418             print( $fh SIG_NULL );
 419             print( $fh pack($self->{data_pack}, 0) );
 420             $content_length = 0;
 421         }
 422         else {
 423             print( $fh SIG_DATA );
 424             print( $fh pack($self->{data_pack}, length($value)) . $value );
 425             $content_length = length($value);
 426         }
 427     }
 428
 429     ##
 430     # Plain key is stored AFTER value, as keys are typically fetched less often.
 431     ##
 432     print( $fh pack($self->{data_pack}, length($key)) . $key );
 433
 434     ##
 435     # If value is blessed, preserve class name
 436     ##
 437     if ( $root->{autobless} ) {
 438         my $value_class = Scalar::Util::blessed($value);
 439         if ( defined $value_class && !$value->isa( 'DBM::Deep' ) ) {
 440             ##
 441             # Blessed ref -- will restore later
 442             ##
 443             print( $fh chr(1) );
 444             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 445             $content_length += 1;
 446             $content_length += $self->{data_size} + length($value_class);
 447         }
 448         else {
 449             print( $fh chr(0) );
 450             $content_length += 1;
 451         }
 452     }
 453
 454     ##
 455     # If this is a new content area, advance EOF counter
 456     ##
 457     if ($location == $root->{end}) {
 458         $root->{end} += SIG_SIZE;
 459         $root->{end} += $self->{data_size} + $content_length;
 460         $root->{end} += $self->{data_size} + length($key);
 461     }
 462
 463     ##
 464     # If content is a hash or array, create new child DBM::Deep object and
 465     # pass each key or element to it.
 466     ##
 467     if ( ! $internal_ref ) {
 468         if ($r eq 'HASH') {
 469             my $branch = DBM::Deep->new(
 470                 type => DBM::Deep->TYPE_HASH,
 471                 base_offset => $location,
 472                 root => $root,
 473             );
 474             foreach my $key (keys %{$value}) {
 475                 $branch->STORE( $key, $value->{$key} );
 476             }
 477         }
 478         elsif ($r eq 'ARRAY') {
 479             my $branch = DBM::Deep->new(
 480                 type => DBM::Deep->TYPE_ARRAY,
 481                 base_offset => $location,
 482                 root => $root,
 483             );
 484             my $index = 0;
 485             foreach my $element (@{$value}) {
 486                 $branch->STORE( $index, $element );
 487                 $index++;
 488             }
 489         }
 490     }
 491
 492     return 1;
 493 }
 494
 495 sub split_index {
 496     my $self = shift;
 497     my ($obj, $md5, $tag) = @_;
 498
 499     my $fh = $obj->_fh;
 500     my $root = $obj->_root;
 501     my $keys = $tag->{content};
 502
 503     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 504     print( $fh pack($self->{long_pack}, $root->{end}) );
 505
 506     my $index_tag = $self->create_tag(
 507         $obj,
 508         $root->{end},
 509         SIG_INDEX,
 510         chr(0) x $self->{index_size},
 511     );
 512
 513     my @offsets = ();
 514
 515     $keys .= $md5 . pack($self->{long_pack}, 0);
 516
 517     BUCKET:
 518     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
 519         my ($key, $old_subloc) = $self->_get_key_subloc( $keys, $i );
 520
 521         next BUCKET unless $key;
 522
 523         my $num = ord(substr($key, $tag->{ch} + 1, 1));
 524
 525         if ($offsets[$num]) {
 526             my $offset = $offsets[$num] + SIG_SIZE + $self->{data_size};
 527             seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 528             my $subkeys;
 529             read( $fh, $subkeys, $self->{bucket_list_size});
 530
 531             for (my $k=0; $k<$self->{max_buckets}; $k++) {
 532                 my ($temp, $subloc) = $self->_get_key_subloc( $subkeys, $k );
 533
 534                 if (!$subloc) {
 535                     seek($fh, $offset + ($k * $self->{bucket_size}) + $root->{file_offset}, SEEK_SET);
 536                     print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 537                     last;
 538                 }
 539             } # k loop
 540         }
 541         else {
 542             $offsets[$num] = $root->{end};
 543             seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 544             print( $fh pack($self->{long_pack}, $root->{end}) );
 545
 546             my $blist_tag = $self->create_tag($obj, $root->{end}, SIG_BLIST, chr(0) x $self->{bucket_list_size});
 547
 548             seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 549             print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 550         }
 551     } # i loop
 552
 553     return;
 554 }
 555
 556 sub read_from_loc {
 557     my $self = shift;
 558     my ($obj, $subloc) = @_;
 559
 560     my $fh = $obj->_fh;
 561
 562     ##
 563     # Found match -- seek to offset and read signature
 564     ##
 565     my $signature;
 566     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 567     read( $fh, $signature, SIG_SIZE);
 568
 569     ##
 570     # If value is a hash or array, return new DBM::Deep object with correct offset
 571     ##
 572     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
 573         my $obj = DBM::Deep->new(
 574             type => $signature,
 575             base_offset => $subloc,
 576             root => $obj->_root,
 577         );
 578
 579         if ($obj->_root->{autobless}) {
 580             ##
 581             # Skip over value and plain key to see if object needs
 582             # to be re-blessed
 583             ##
 584             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 585
 586             my $size;
 587             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 588             if ($size) { seek($fh, $size, SEEK_CUR); }
 589
 590             my $bless_bit;
 591             read( $fh, $bless_bit, 1);
 592             if (ord($bless_bit)) {
 593                 ##
 594                 # Yes, object needs to be re-blessed
 595                 ##
 596                 my $class_name;
 597                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 598                 if ($size) { read( $fh, $class_name, $size); }
 599                 if ($class_name) { $obj = bless( $obj, $class_name ); }
 600             }
 601         }
 602
 603         return $obj;
 604     }
 605     elsif ( $signature eq SIG_INTERNAL ) {
 606         my $size;
 607         read( $fh, $size, $self->{data_size});
 608         $size = unpack($self->{data_pack}, $size);
 609
 610         if ( $size ) {
 611             my $new_loc;
 612             read( $fh, $new_loc, $size );
 613             $new_loc = unpack( $self->{long_pack}, $new_loc );
 614
 615             return $self->read_from_loc( $obj, $new_loc );
 616         }
 617         else {
 618             return;
 619         }
 620     }
 621     ##
 622     # Otherwise return actual value
 623     ##
 624     elsif ($signature eq SIG_DATA) {
 625         my $size;
 626         read( $fh, $size, $self->{data_size});
 627         $size = unpack($self->{data_pack}, $size);
 628
 629         my $value = '';
 630         if ($size) { read( $fh, $value, $size); }
 631         return $value;
 632     }
 633
 634     ##
 635     # Key exists, but content is null
 636     ##
 637     return;
 638 }
 639
 640 sub get_bucket_value {
 641     ##
 642     # Fetch single value given tag and MD5 digested key.
 643     ##
 644     my $self = shift;
 645     my ($obj, $tag, $md5) = @_;
 646
 647     my ($subloc, $offset) = $self->_find_in_buckets( $tag, $md5 );
 648     if ( $subloc ) {
 649         return $self->read_from_loc( $obj, $subloc );
 650     }
 651     return;
 652 }
 653
 654 sub delete_bucket {
 655     ##
 656     # Delete single key/value pair given tag and MD5 digested key.
 657     ##
 658     my $self = shift;
 659     my ($obj, $tag, $md5) = @_;
 660
 661     my ($subloc, $offset) = $self->_find_in_buckets( $tag, $md5 );
 662     if ( $subloc ) {
 663         my $fh = $obj->_fh;
 664         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
 665         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
 666         print( $fh chr(0) x $self->{bucket_size} );
 667
 668         return 1;
 669     }
 670     return;
 671 }
 672
 673 sub bucket_exists {
 674     ##
 675     # Check existence of single key given tag and MD5 digested key.
 676     ##
 677     my $self = shift;
 678     my ($obj, $tag, $md5) = @_;
 679
 680     my ($subloc, $offset) = $self->_find_in_buckets( $tag, $md5 );
 681     return $subloc && 1;
 682 }
 683
 684 sub find_bucket_list {
 685     ##
 686     # Locate offset for bucket list, given digested key
 687     ##
 688     my $self = shift;
 689     my ($obj, $md5, $args) = @_;
 690     $args = {} unless $args;
 691
 692     ##
 693     # Locate offset for bucket list using digest index system
 694     ##
 695     my $tag = $self->load_tag($obj, $obj->_base_offset)
 696         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 697
 698     my $ch = 0;
 699     while ($tag->{signature} ne SIG_BLIST) {
 700         my $num = ord substr($md5, $ch, 1);
 701
 702         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 703         $tag = $self->index_lookup( $obj, $tag, $num );
 704
 705         if (!$tag) {
 706             return if ! $args->{create};
 707
 708             my $fh = $obj->_fh;
 709             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 710             print( $fh pack($self->{long_pack}, $obj->_root->{end}) );
 711
 712             $tag = $self->create_tag(
 713                 $obj, $obj->_root->{end},
 714                 SIG_BLIST,
 715                 chr(0) x $self->{bucket_list_size},
 716             );
 717
 718             $tag->{ref_loc} = $ref_loc;
 719             $tag->{ch} = $ch;
 720
 721             last;
 722         }
 723
 724         $tag->{ch} = $ch;
 725         $tag->{ref_loc} = $ref_loc;
 726
 727         $ch++;
 728     }
 729
 730     return $tag;
 731 }
 732
 733 sub index_lookup {
 734     ##
 735     # Given index tag, lookup single entry in index and return .
 736     ##
 737     my $self = shift;
 738     my ($obj, $tag, $index) = @_;
 739
 740     my $location = unpack(
 741         $self->{long_pack},
 742         substr(
 743             $tag->{content},
 744             $index * $self->{long_size},
 745             $self->{long_size},
 746         ),
 747     );
 748
 749     if (!$location) { return; }
 750
 751     return $self->load_tag( $obj, $location );
 752 }
 753
 754 sub traverse_index {
 755     ##
 756     # Scan index and recursively step into deeper levels, looking for next key.
 757     ##
 758     my $self = shift;
 759     my ($obj, $offset, $ch, $force_return_next) = @_;
 760
 761     my $tag = $self->load_tag($obj, $offset );
 762
 763     my $fh = $obj->_fh;
 764
 765     if ($tag->{signature} ne SIG_BLIST) {
 766         my $content = $tag->{content};
 767         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
 768
 769         for (my $idx = $start; $idx < (2**8); $idx++) {
 770             my $subloc = unpack(
 771                 $self->{long_pack},
 772                 substr(
 773                     $content,
 774                     $idx * $self->{long_size},
 775                     $self->{long_size},
 776                 ),
 777             );
 778
 779             if ($subloc) {
 780                 my $result = $self->traverse_index(
 781                     $obj, $subloc, $ch + 1, $force_return_next,
 782                 );
 783
 784                 if (defined($result)) { return $result; }
 785             }
 786         } # index loop
 787
 788         $obj->{return_next} = 1;
 789     } # tag is an index
 790
 791     else {
 792         my $keys = $tag->{content};
 793         if ($force_return_next) { $obj->{return_next} = 1; }
 794
 795         ##
 796         # Iterate through buckets, looking for a key match
 797         ##
 798         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 799             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
 800
 801             # End of bucket list -- return to outer loop
 802             if (!$subloc) {
 803                 $obj->{return_next} = 1;
 804                 last;
 805             }
 806             # Located previous key -- return next one found
 807             elsif ($key eq $obj->{prev_md5}) {
 808                 $obj->{return_next} = 1;
 809                 next;
 810             }
 811             # Seek to bucket location and skip over signature
 812             elsif ($obj->{return_next}) {
 813                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 814
 815                 # Skip over value to get to plain key
 816                 my $sig;
 817                 read( $fh, $sig, SIG_SIZE );
 818
 819                 my $size;
 820                 read( $fh, $size, $self->{data_size});
 821                 $size = unpack($self->{data_pack}, $size);
 822                 if ($size) { seek($fh, $size, SEEK_CUR); }
 823
 824                 # Read in plain key and return as scalar
 825                 my $plain_key;
 826                 read( $fh, $size, $self->{data_size});
 827                 $size = unpack($self->{data_pack}, $size);
 828                 if ($size) { read( $fh, $plain_key, $size); }
 829
 830                 return $plain_key;
 831             }
 832         }
 833
 834         $obj->{return_next} = 1;
 835     } # tag is a bucket list
 836
 837     return;
 838 }
 839
 840 sub get_next_key {
 841     ##
 842     # Locate next key, given digested previous one
 843     ##
 844     my $self = shift;
 845     my ($obj) = @_;
 846
 847     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 848     $obj->{return_next} = 0;
 849
 850     ##
 851     # If the previous key was not specifed, start at the top and
 852     # return the first one found.
 853     ##
 854     if (!$obj->{prev_md5}) {
 855         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 856         $obj->{return_next} = 1;
 857     }
 858
 859     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 860 }
 861
 862 # Utilities
 863
 864 sub _get_key_subloc {
 865     my $self = shift;
 866     my ($keys, $idx) = @_;
 867
 868     my ($key, $subloc) = unpack(
 869         "a$self->{hash_size} $self->{long_pack}",
 870         substr(
 871             $keys,
 872             ($idx * $self->{bucket_size}),
 873             $self->{bucket_size},
 874         ),
 875     );
 876
 877     return ($key, $subloc);
 878 }
 879
 880 sub _find_in_buckets {
 881     my $self = shift;
 882     my ($tag, $md5) = @_;
 883
 884     BUCKET:
 885     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
 886         my ($key, $subloc) = $self->_get_key_subloc( $tag->{content}, $i );
 887
 888         return ($subloc, $i * $self->{bucket_size}) unless $subloc;
 889
 890         next BUCKET if $key ne $md5;
 891
 892         return ($subloc, $i * $self->{bucket_size});
 893     }
 894
 895     return;
 896 }
 897
 898 sub _request_space {
 899     my $self = shift;
 900     my ($obj, $size) = @_;
 901
 902     my $loc = $obj->_root->{end};
 903     $obj->_root->{end} += $size;
 904
 905     return $loc;
 906 }
 907
 908 sub _release_space {
 909     my $self = shift;
 910     my ($obj, $size, $loc) = @_;
 911
 912     return;
 913 }
 914
 915 1;
 916 __END__
 917
 918 # This will be added in later, after more refactoring is done. This is an early
 919 # attempt at refactoring on the physical level instead of the virtual level.
 920 sub _read_at {
 921     my $self = shift;
 922     my ($obj, $spot, $amount, $unpack) = @_;
 923
 924     my $fh = $obj->_fh;
 925     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
 926
 927     my $buffer;
 928     my $bytes_read = read( $fh, $buffer, $amount );
 929
 930     if ( $unpack ) {
 931         $buffer = unpack( $unpack, $buffer );
 932     }
 933
 934     if ( wantarray ) {
 935         return ($buffer, $bytes_read);
 936     }
 937     else {
 938         return $buffer;
 939     }
 940 }