lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 ##
   8 # Setup file and tag signatures.  These should never change.
   9 ##
  10 sub SIG_FILE     () { 'DPDB' }
  11 sub SIG_INTERNAL () { 'i'    }
  12 sub SIG_HASH     () { 'H'    }
  13 sub SIG_ARRAY    () { 'A'    }
  14 sub SIG_NULL     () { 'N'    }
  15 sub SIG_DATA     () { 'D'    }
  16 sub SIG_INDEX    () { 'I'    }
  17 sub SIG_BLIST    () { 'B'    }
  18 sub SIG_FREE     () { 'F'    }
  19 sub SIG_SIZE     () {  1     }
  20
  21 sub precalc_sizes {
  22     ##
  23     # Precalculate index, bucket and bucket list sizes
  24     ##
  25     my $self = shift;
  26
  27     $self->{index_size}       = (2**8) * $self->{long_size};
  28     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size} * 2;
  29     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  30
  31     return 1;
  32 }
  33
  34 sub set_pack {
  35     ##
  36     # Set pack/unpack modes (see file header for more)
  37     ##
  38     my $self = shift;
  39     my ($long_s, $long_p, $data_s, $data_p) = @_;
  40
  41     ##
  42     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
  43     # GB per file.
  44     #    (Perl must be compiled with largefile support for files > 2 GB)
  45     #
  46     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  47     #    (Perl must be compiled with largefile and 64-bit long support)
  48     ##
  49     $self->{long_size} = $long_s ? $long_s : 4;
  50     $self->{long_pack} = $long_p ? $long_p : 'N';
  51
  52     ##
  53     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
  54     # key/value. Upgrading this is possible (see above) but probably not
  55     # necessary. If you need more than 4 GB for a single key or value, this
  56     # module is really not for you :-)
  57     ##
  58     $self->{data_size} = $data_s ? $data_s : 4;
  59     $self->{data_pack} = $data_p ? $data_p : 'N';
  60
  61     return $self->precalc_sizes();
  62 }
  63
  64 sub set_digest {
  65     ##
  66     # Set key digest function (default is MD5)
  67     ##
  68     my $self = shift;
  69     my ($digest_func, $hash_size) = @_;
  70
  71     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  72     $self->{hash_size} = $hash_size ? $hash_size : 16;
  73
  74     return $self->precalc_sizes();
  75 }
  76
  77 sub new {
  78     my $class = shift;
  79     my ($args) = @_;
  80
  81     my $self = bless {
  82         long_size   => 4,
  83         long_pack   => 'N',
  84         data_size   => 4,
  85         data_pack   => 'N',
  86
  87         digest      => \&Digest::MD5::md5,
  88         hash_size   => 16,
  89
  90         ##
  91         # Maximum number of buckets per list before another level of indexing is
  92         # done.
  93         # Increase this value for slightly greater speed, but larger database
  94         # files. DO NOT decrease this value below 16, due to risk of recursive
  95         # reindex overrun.
  96         ##
  97         max_buckets => 16,
  98     }, $class;
  99
 100     $self->precalc_sizes;
 101
 102     return $self;
 103 }
 104
 105 sub setup_fh {
 106     my $self = shift;
 107     my ($obj) = @_;
 108
 109     $self->open( $obj ) if !defined $obj->_fh;
 110
 111     my $fh = $obj->_fh;
 112     flock $fh, LOCK_EX;
 113
 114     unless ( $obj->{base_offset} ) {
 115         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 116         my $signature;
 117         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 118
 119         ##
 120         # File is empty -- write signature and master index
 121         ##
 122         if (!$bytes_read) {
 123             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
 124             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
 125             print( $fh SIG_FILE);
 126
 127             $obj->{base_offset} = $self->_request_space(
 128                 $obj, $self->tag_size( $self->{index_size} ),
 129             );
 130
 131             $self->write_tag(
 132                 $obj, $obj->_base_offset, $obj->_type,
 133                 chr(0)x$self->{index_size},
 134             );
 135
 136             # Flush the filehandle
 137             my $old_fh = select $fh;
 138             my $old_af = $|; $| = 1; $| = $old_af;
 139             select $old_fh;
 140         }
 141         else {
 142             $obj->{base_offset} = $bytes_read;
 143
 144             ##
 145             # Check signature was valid
 146             ##
 147             unless ($signature eq SIG_FILE) {
 148                 $self->close_fh( $obj );
 149                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
 150             }
 151
 152             ##
 153             # Get our type from master index signature
 154             ##
 155             my $tag = $self->load_tag($obj, $obj->_base_offset)
 156             or $obj->_throw_error("Corrupted file, no master index record");
 157
 158             unless ($obj->{type} eq $tag->{signature}) {
 159                 $obj->_throw_error("File type mismatch");
 160             }
 161         }
 162     }
 163
 164     #XXX We have to make sure we don't mess up when autoflush isn't turned on
 165     unless ( $obj->_root->{inode} ) {
 166         my @stats = stat($obj->_fh);
 167         $obj->_root->{inode} = $stats[1];
 168         $obj->_root->{end} = $stats[7];
 169     }
 170
 171     flock $fh, LOCK_UN;
 172
 173     return 1;
 174 }
 175
 176 sub open {
 177     ##
 178     # Open a fh to the database, create if nonexistent.
 179     # Make sure file signature matches DBM::Deep spec.
 180     ##
 181     my $self = shift;
 182     my ($obj) = @_;
 183
 184     # Theoretically, adding O_BINARY should remove the need for the binmode
 185     # Of course, testing it is going to be ... interesting.
 186     my $flags = O_RDWR | O_CREAT | O_BINARY;
 187
 188     my $fh;
 189     my $filename = $obj->_root->{file};
 190     sysopen( $fh, $filename, $flags )
 191         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
 192     $obj->_root->{fh} = $fh;
 193
 194     #XXX Can we remove this by using the right sysopen() flags?
 195     # Maybe ... q.v. above
 196     binmode $fh; # for win32
 197
 198     if ($obj->_root->{autoflush}) {
 199         my $old = select $fh;
 200         $|=1;
 201         select $old;
 202     }
 203
 204     return 1;
 205 }
 206
 207 sub close_fh {
 208     my $self = shift;
 209     my ($obj) = @_;
 210
 211     if ( my $fh = $obj->_root->{fh} ) {
 212         close $fh;
 213     }
 214     $obj->_root->{fh} = undef;
 215
 216     return 1;
 217 }
 218
 219 sub tag_size {
 220     my $self = shift;
 221     my ($size) = @_;
 222     return SIG_SIZE + $self->{data_size} + $size;
 223 }
 224
 225 sub write_tag {
 226     ##
 227     # Given offset, signature and content, create tag and write to disk
 228     ##
 229     my $self = shift;
 230     my ($obj, $offset, $sig, $content) = @_;
 231     my $size = length( $content );
 232
 233     my $fh = $obj->_fh;
 234
 235     if ( defined $offset ) {
 236         seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 237     }
 238
 239     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 240
 241     return unless defined $offset;
 242
 243     return {
 244         signature => $sig,
 245         size => $size,
 246         offset => $offset + SIG_SIZE + $self->{data_size},
 247         content => $content
 248     };
 249 }
 250
 251 sub load_tag {
 252     ##
 253     # Given offset, load single tag and return signature, size and data
 254     ##
 255     my $self = shift;
 256     my ($obj, $offset) = @_;
 257
 258 #    print join(':',map{$_||''}caller(1)), $/;
 259
 260     my $fh = $obj->_fh;
 261
 262     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 263
 264     #XXX I'm not sure this check will work if autoflush isn't enabled ...
 265     return if eof $fh;
 266
 267     my $b;
 268     read( $fh, $b, SIG_SIZE + $self->{data_size} );
 269     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 270
 271     my $buffer;
 272     read( $fh, $buffer, $size);
 273
 274     return {
 275         signature => $sig,
 276         size => $size,
 277         offset => $offset + SIG_SIZE + $self->{data_size},
 278         content => $buffer
 279     };
 280 }
 281
 282 sub _length_needed {
 283     my $self = shift;
 284     my ($obj, $value, $key) = @_;
 285
 286     my $is_dbm_deep = eval {
 287         local $SIG{'__DIE__'};
 288         $value->isa( 'DBM::Deep' );
 289     };
 290
 291     my $len = SIG_SIZE + $self->{data_size}
 292             + $self->{data_size} + length( $key );
 293
 294     if ( $is_dbm_deep && $value->_root eq $obj->_root ) {
 295         return $len + $self->{long_size};
 296     }
 297
 298     my $r = Scalar::Util::reftype( $value ) || '';
 299     if ( $obj->_root->{autobless} ) {
 300         # This is for the bit saying whether or not this thing is blessed.
 301         $len += 1;
 302     }
 303
 304     unless ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 305         if ( defined $value ) {
 306             $len += length( $value );
 307         }
 308         return $len;
 309     }
 310
 311     $len += $self->{index_size};
 312
 313     # if autobless is enabled, must also take into consideration
 314     # the class name as it is stored after the key.
 315     if ( $obj->_root->{autobless} ) {
 316         my $value_class = Scalar::Util::blessed($value);
 317         if ( defined $value_class && !$is_dbm_deep ) {
 318             $len += $self->{data_size} + length($value_class);
 319         }
 320     }
 321
 322     return $len;
 323 }
 324
 325 sub add_bucket {
 326     ##
 327     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 328     # plain (undigested) key and value.
 329     ##
 330     my $self = shift;
 331     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 332
 333     # This verifies that only supported values will be stored.
 334     {
 335         my $r = Scalar::Util::reftype( $value );
 336         last if !defined $r;
 337
 338         last if $r eq 'HASH';
 339         last if $r eq 'ARRAY';
 340
 341         $obj->_throw_error(
 342             "Storage of variables of type '$r' is not supported."
 343         );
 344     }
 345
 346     my $location = 0;
 347     my $result = 2;
 348
 349     my $root = $obj->_root;
 350     my $fh   = $obj->_fh;
 351
 352     my $actual_length = $self->_length_needed( $obj, $value, $plain_key );
 353
 354     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 355
 356 #    $self->_release_space( $obj, $size, $subloc );
 357     # Updating a known md5
 358 #XXX This needs updating to use _release_space
 359     if ( $subloc ) {
 360         $result = 1;
 361
 362         if ($actual_length <= $size) {
 363             $location = $subloc;
 364         }
 365         else {
 366             $location = $self->_request_space( $obj, $actual_length );
 367             seek(
 368                 $fh,
 369                 $tag->{offset} + $offset
 370               + $self->{hash_size} + $root->{file_offset},
 371                 SEEK_SET,
 372             );
 373             print( $fh pack($self->{long_pack}, $location ) );
 374             print( $fh pack($self->{long_pack}, $actual_length ) );
 375         }
 376     }
 377     # Adding a new md5
 378     elsif ( defined $offset ) {
 379         $location = $self->_request_space( $obj, $actual_length );
 380
 381         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
 382         print( $fh $md5 . pack($self->{long_pack}, $location ) );
 383         print( $fh pack($self->{long_pack}, $actual_length ) );
 384     }
 385     # If bucket didn't fit into list, split into a new index level
 386     # split_index() will do the _request_space() call
 387     else {
 388         $location = $self->split_index( $obj, $md5, $tag );
 389     }
 390
 391     $self->write_value( $obj, $location, $plain_key, $value );
 392
 393     return $result;
 394 }
 395
 396 sub write_value {
 397     my $self = shift;
 398     my ($obj, $location, $key, $value) = @_;
 399
 400     my $fh = $obj->_fh;
 401     my $root = $obj->_root;
 402
 403     my $is_dbm_deep = eval {
 404         local $SIG{'__DIE__'};
 405         $value->isa( 'DBM::Deep' );
 406     };
 407
 408     my $is_internal_ref = $is_dbm_deep && ($value->_root eq $root);
 409
 410     seek($fh, $location + $root->{file_offset}, SEEK_SET);
 411
 412     ##
 413     # Write signature based on content type, set content length and write
 414     # actual value.
 415     ##
 416     my $r = Scalar::Util::reftype($value) || '';
 417     if ( $is_internal_ref ) {
 418         $self->write_tag( $obj, undef, SIG_INTERNAL,pack($self->{long_pack}, $value->_base_offset) );
 419     }
 420     elsif ($r eq 'HASH') {
 421         if ( !$is_dbm_deep && tied %{$value} ) {
 422             $obj->_throw_error( "Cannot store something that is tied" );
 423         }
 424         $self->write_tag( $obj, undef, SIG_HASH, chr(0)x$self->{index_size} );
 425     }
 426     elsif ($r eq 'ARRAY') {
 427         if ( !$is_dbm_deep && tied @{$value} ) {
 428             $obj->_throw_error( "Cannot store something that is tied" );
 429         }
 430         $self->write_tag( $obj, undef, SIG_ARRAY, chr(0)x$self->{index_size} );
 431     }
 432     elsif (!defined($value)) {
 433         $self->write_tag( $obj, undef, SIG_NULL, '' );
 434     }
 435     else {
 436         $self->write_tag( $obj, undef, SIG_DATA, $value );
 437     }
 438
 439     ##
 440     # Plain key is stored AFTER value, as keys are typically fetched less often.
 441     ##
 442     print( $fh pack($self->{data_pack}, length($key)) . $key );
 443
 444     # Internal references don't care about autobless
 445     return 1 if $is_internal_ref;
 446
 447     ##
 448     # If value is blessed, preserve class name
 449     ##
 450     if ( $root->{autobless} ) {
 451         my $value_class = Scalar::Util::blessed($value);
 452         if ( defined $value_class && !$is_dbm_deep ) {
 453             print( $fh chr(1) );
 454             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 455         }
 456         else {
 457             print( $fh chr(0) );
 458         }
 459     }
 460
 461     ##
 462     # If content is a hash or array, create new child DBM::Deep object and
 463     # pass each key or element to it.
 464     ##
 465     if ( !$is_internal_ref ) {
 466         if ($r eq 'HASH') {
 467             my %x = %$value;
 468             tie %$value, 'DBM::Deep', {
 469                 base_offset => $location,
 470                 root => $root,
 471             };
 472             %$value = %x;
 473         }
 474         elsif ($r eq 'ARRAY') {
 475             my @x = @$value;
 476             tie @$value, 'DBM::Deep', {
 477                 base_offset => $location,
 478                 root => $root,
 479             };
 480             @$value = @x;
 481         }
 482     }
 483
 484     return 1;
 485 }
 486
 487 sub split_index {
 488     my $self = shift;
 489     my ($obj, $md5, $tag) = @_;
 490
 491     my $fh = $obj->_fh;
 492     my $root = $obj->_root;
 493
 494     my $loc = $self->_request_space(
 495         $obj, $self->tag_size( $self->{index_size} ),
 496     );
 497
 498     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 499     print( $fh pack($self->{long_pack}, $loc) );
 500
 501     my $index_tag = $self->write_tag(
 502         $obj, $loc, SIG_INDEX,
 503         chr(0)x$self->{index_size},
 504     );
 505
 506     my $newtag_loc = $self->_request_space(
 507         $obj, $self->tag_size( $self->{bucket_list_size} ),
 508     );
 509
 510     my $keys = $tag->{content}
 511              . $md5 . pack($self->{long_pack}, $newtag_loc)
 512                     . pack($self->{long_pack}, 0);
 513
 514     my @newloc = ();
 515     BUCKET:
 516     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
 517         my ($key, $old_subloc, $size) = $self->_get_key_subloc( $keys, $i );
 518
 519         die "[INTERNAL ERROR]: No key in split_index()\n" unless $key;
 520         die "[INTERNAL ERROR]: No subloc in split_index()\n" unless $old_subloc;
 521
 522         my $num = ord(substr($key, $tag->{ch} + 1, 1));
 523
 524         if ($newloc[$num]) {
 525             seek($fh, $newloc[$num] + $root->{file_offset}, SEEK_SET);
 526             my $subkeys;
 527             read( $fh, $subkeys, $self->{bucket_list_size});
 528
 529             # This is looking for the first empty spot
 530             my ($subloc, $offset, $size) = $self->_find_in_buckets(
 531                 { content => $subkeys }, '',
 532             );
 533
 534             seek($fh, $newloc[$num] + $offset + $root->{file_offset}, SEEK_SET);
 535             print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 536
 537             next;
 538         }
 539
 540         seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 541
 542         my $loc = $self->_request_space(
 543             $obj, $self->tag_size( $self->{bucket_list_size} ),
 544         );
 545
 546         print( $fh pack($self->{long_pack}, $loc) );
 547
 548         my $blist_tag = $self->write_tag(
 549             $obj, $loc, SIG_BLIST,
 550             chr(0)x$self->{bucket_list_size},
 551         );
 552
 553         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 554         print( $fh $key . pack($self->{long_pack}, $old_subloc) );
 555
 556         $newloc[$num] = $blist_tag->{offset};
 557     }
 558
 559     $self->_release_space(
 560         $obj, $self->tag_size( $self->{bucket_list_size} ),
 561         $tag->{offset} - SIG_SIZE - $self->{data_size},
 562     );
 563
 564     return $newtag_loc;
 565 }
 566
 567 sub read_from_loc {
 568     my $self = shift;
 569     my ($obj, $subloc) = @_;
 570
 571     my $fh = $obj->_fh;
 572
 573     ##
 574     # Found match -- seek to offset and read signature
 575     ##
 576     my $signature;
 577     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 578     read( $fh, $signature, SIG_SIZE);
 579
 580     ##
 581     # If value is a hash or array, return new DBM::Deep object with correct offset
 582     ##
 583     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
 584         my $new_obj = DBM::Deep->new({
 585             type => $signature,
 586             base_offset => $subloc,
 587             root => $obj->_root,
 588         });
 589
 590         if ($new_obj->_root->{autobless}) {
 591             ##
 592             # Skip over value and plain key to see if object needs
 593             # to be re-blessed
 594             ##
 595             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 596
 597             my $size;
 598             read( $fh, $size, $self->{data_size});
 599             $size = unpack($self->{data_pack}, $size);
 600             if ($size) { seek($fh, $size, SEEK_CUR); }
 601
 602             my $bless_bit;
 603             read( $fh, $bless_bit, 1);
 604             if (ord($bless_bit)) {
 605                 ##
 606                 # Yes, object needs to be re-blessed
 607                 ##
 608                 my $class_name;
 609                 read( $fh, $size, $self->{data_size});
 610                 $size = unpack($self->{data_pack}, $size);
 611                 if ($size) { read( $fh, $class_name, $size); }
 612                 if ($class_name) { $new_obj = bless( $new_obj, $class_name ); }
 613             }
 614         }
 615
 616         return $new_obj;
 617     }
 618     elsif ( $signature eq SIG_INTERNAL ) {
 619         my $size;
 620         read( $fh, $size, $self->{data_size});
 621         $size = unpack($self->{data_pack}, $size);
 622
 623         if ( $size ) {
 624             my $new_loc;
 625             read( $fh, $new_loc, $size );
 626             $new_loc = unpack( $self->{long_pack}, $new_loc );
 627
 628             return $self->read_from_loc( $obj, $new_loc );
 629         }
 630         else {
 631             return;
 632         }
 633     }
 634     ##
 635     # Otherwise return actual value
 636     ##
 637     elsif ($signature eq SIG_DATA) {
 638         my $size;
 639         read( $fh, $size, $self->{data_size});
 640         $size = unpack($self->{data_pack}, $size);
 641
 642         my $value = '';
 643         if ($size) { read( $fh, $value, $size); }
 644         return $value;
 645     }
 646
 647     ##
 648     # Key exists, but content is null
 649     ##
 650     return;
 651 }
 652
 653 sub get_bucket_value {
 654     ##
 655     # Fetch single value given tag and MD5 digested key.
 656     ##
 657     my $self = shift;
 658     my ($obj, $tag, $md5) = @_;
 659
 660     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 661     if ( $subloc ) {
 662         return $self->read_from_loc( $obj, $subloc );
 663     }
 664     return;
 665 }
 666
 667 sub delete_bucket {
 668     ##
 669     # Delete single key/value pair given tag and MD5 digested key.
 670     ##
 671     my $self = shift;
 672     my ($obj, $tag, $md5) = @_;
 673
 674     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 675 #XXX This needs _release_space()
 676     if ( $subloc ) {
 677         my $fh = $obj->_fh;
 678         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
 679         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
 680         print( $fh chr(0) x $self->{bucket_size} );
 681
 682         return 1;
 683     }
 684     return;
 685 }
 686
 687 sub bucket_exists {
 688     ##
 689     # Check existence of single key given tag and MD5 digested key.
 690     ##
 691     my $self = shift;
 692     my ($obj, $tag, $md5) = @_;
 693
 694     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 695     return $subloc && 1;
 696 }
 697
 698 sub find_bucket_list {
 699     ##
 700     # Locate offset for bucket list, given digested key
 701     ##
 702     my $self = shift;
 703     my ($obj, $md5, $args) = @_;
 704     $args = {} unless $args;
 705
 706     ##
 707     # Locate offset for bucket list using digest index system
 708     ##
 709     my $tag = $self->load_tag($obj, $obj->_base_offset)
 710         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 711
 712     my $ch = 0;
 713     while ($tag->{signature} ne SIG_BLIST) {
 714         my $num = ord substr($md5, $ch, 1);
 715
 716         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 717         $tag = $self->index_lookup( $obj, $tag, $num );
 718
 719         if (!$tag) {
 720             return if !$args->{create};
 721
 722             my $loc = $self->_request_space(
 723                 $obj, $self->tag_size( $self->{bucket_list_size} ),
 724             );
 725
 726             my $fh = $obj->_fh;
 727             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 728             print( $fh pack($self->{long_pack}, $loc) );
 729
 730             $tag = $self->write_tag(
 731                 $obj, $loc, SIG_BLIST,
 732                 chr(0)x$self->{bucket_list_size},
 733             );
 734
 735             $tag->{ref_loc} = $ref_loc;
 736             $tag->{ch} = $ch;
 737
 738             last;
 739         }
 740
 741         $tag->{ch} = $ch++;
 742         $tag->{ref_loc} = $ref_loc;
 743     }
 744
 745     return $tag;
 746 }
 747
 748 sub index_lookup {
 749     ##
 750     # Given index tag, lookup single entry in index and return .
 751     ##
 752     my $self = shift;
 753     my ($obj, $tag, $index) = @_;
 754
 755     my $location = unpack(
 756         $self->{long_pack},
 757         substr(
 758             $tag->{content},
 759             $index * $self->{long_size},
 760             $self->{long_size},
 761         ),
 762     );
 763
 764     if (!$location) { return; }
 765
 766     return $self->load_tag( $obj, $location );
 767 }
 768
 769 sub traverse_index {
 770     ##
 771     # Scan index and recursively step into deeper levels, looking for next key.
 772     ##
 773     my $self = shift;
 774     my ($obj, $offset, $ch, $force_return_next) = @_;
 775
 776     my $tag = $self->load_tag($obj, $offset );
 777
 778     my $fh = $obj->_fh;
 779
 780     if ($tag->{signature} ne SIG_BLIST) {
 781         my $content = $tag->{content};
 782         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
 783
 784         for (my $idx = $start; $idx < (2**8); $idx++) {
 785             my $subloc = unpack(
 786                 $self->{long_pack},
 787                 substr(
 788                     $content,
 789                     $idx * $self->{long_size},
 790                     $self->{long_size},
 791                 ),
 792             );
 793
 794             if ($subloc) {
 795                 my $result = $self->traverse_index(
 796                     $obj, $subloc, $ch + 1, $force_return_next,
 797                 );
 798
 799                 if (defined($result)) { return $result; }
 800             }
 801         } # index loop
 802
 803         $obj->{return_next} = 1;
 804     } # tag is an index
 805
 806     else {
 807         my $keys = $tag->{content};
 808         if ($force_return_next) { $obj->{return_next} = 1; }
 809
 810         ##
 811         # Iterate through buckets, looking for a key match
 812         ##
 813         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 814             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
 815
 816             # End of bucket list -- return to outer loop
 817             if (!$subloc) {
 818                 $obj->{return_next} = 1;
 819                 last;
 820             }
 821             # Located previous key -- return next one found
 822             elsif ($key eq $obj->{prev_md5}) {
 823                 $obj->{return_next} = 1;
 824                 next;
 825             }
 826             # Seek to bucket location and skip over signature
 827             elsif ($obj->{return_next}) {
 828                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 829
 830                 # Skip over value to get to plain key
 831                 my $sig;
 832                 read( $fh, $sig, SIG_SIZE );
 833
 834                 my $size;
 835                 read( $fh, $size, $self->{data_size});
 836                 $size = unpack($self->{data_pack}, $size);
 837                 if ($size) { seek($fh, $size, SEEK_CUR); }
 838
 839                 # Read in plain key and return as scalar
 840                 my $plain_key;
 841                 read( $fh, $size, $self->{data_size});
 842                 $size = unpack($self->{data_pack}, $size);
 843                 if ($size) { read( $fh, $plain_key, $size); }
 844
 845                 return $plain_key;
 846             }
 847         }
 848
 849         $obj->{return_next} = 1;
 850     } # tag is a bucket list
 851
 852     return;
 853 }
 854
 855 sub get_next_key {
 856     ##
 857     # Locate next key, given digested previous one
 858     ##
 859     my $self = shift;
 860     my ($obj) = @_;
 861
 862     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 863     $obj->{return_next} = 0;
 864
 865     ##
 866     # If the previous key was not specifed, start at the top and
 867     # return the first one found.
 868     ##
 869     if (!$obj->{prev_md5}) {
 870         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 871         $obj->{return_next} = 1;
 872     }
 873
 874     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 875 }
 876
 877 # Utilities
 878
 879 sub _get_key_subloc {
 880     my $self = shift;
 881     my ($keys, $idx) = @_;
 882
 883     my ($key, $subloc, $size) = unpack(
 884         "a$self->{hash_size} $self->{long_pack} $self->{long_pack}",
 885         substr(
 886             $keys,
 887             ($idx * $self->{bucket_size}),
 888             $self->{bucket_size},
 889         ),
 890     );
 891
 892     return ($key, $subloc, $size);
 893 }
 894
 895 sub _find_in_buckets {
 896     my $self = shift;
 897     my ($tag, $md5) = @_;
 898
 899     BUCKET:
 900     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
 901         my ($key, $subloc, $size) = $self->_get_key_subloc(
 902             $tag->{content}, $i,
 903         );
 904
 905         return ($subloc, $i * $self->{bucket_size}, $size) unless $subloc;
 906
 907         next BUCKET if $key ne $md5;
 908
 909         return ($subloc, $i * $self->{bucket_size}, $size);
 910     }
 911
 912     return;
 913 }
 914
 915 #sub _print_at {
 916 #    my $self = shift;
 917 #    my ($obj, $spot, $data) = @_;
 918 #
 919 #    my $fh = $obj->_fh;
 920 #    seek( $fh, $spot, SEEK_SET );
 921 #    print( $fh $data );
 922 #
 923 #    return;
 924 #}
 925
 926 sub _request_space {
 927     my $self = shift;
 928     my ($obj, $size) = @_;
 929
 930     my $loc = $obj->_root->{end};
 931     $obj->_root->{end} += $size;
 932
 933     return $loc;
 934 }
 935
 936 sub _release_space {
 937     my $self = shift;
 938     my ($obj, $size, $loc) = @_;
 939
 940     my $next_loc = 0;
 941
 942     my $fh = $obj->_fh;
 943     seek( $fh, $loc + $obj->_root->{file_offset}, SEEK_SET );
 944     print( $fh SIG_FREE
 945         . pack($self->{long_pack}, $size )
 946         . pack($self->{long_pack}, $next_loc )
 947     );
 948
 949     return;
 950 }
 951
 952 1;
 953 __END__
 954
 955 # This will be added in later, after more refactoring is done. This is an early
 956 # attempt at refactoring on the physical level instead of the virtual level.
 957 sub _read_at {
 958     my $self = shift;
 959     my ($obj, $spot, $amount, $unpack) = @_;
 960
 961     my $fh = $obj->_fh;
 962     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
 963
 964     my $buffer;
 965     my $bytes_read = read( $fh, $buffer, $amount );
 966
 967     if ( $unpack ) {
 968         $buffer = unpack( $unpack, $buffer );
 969     }
 970
 971     if ( wantarray ) {
 972         return ($buffer, $bytes_read);
 973     }
 974     else {
 975         return $buffer;
 976     }
 977 }