lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use strict;
   4
   5 use Fcntl qw( :DEFAULT :flock :seek );
   6
   7 ##
   8 # Setup file and tag signatures.  These should never change.
   9 ##
  10 sub SIG_FILE     () { 'DPDB' }
  11 sub SIG_INTERNAL () { 'i'    }
  12 sub SIG_HASH     () { 'H'    }
  13 sub SIG_ARRAY    () { 'A'    }
  14 sub SIG_NULL     () { 'N'    }
  15 sub SIG_DATA     () { 'D'    }
  16 sub SIG_INDEX    () { 'I'    }
  17 sub SIG_BLIST    () { 'B'    }
  18 sub SIG_SIZE     () {  1     }
  19
  20 sub precalc_sizes {
  21     ##
  22     # Precalculate index, bucket and bucket list sizes
  23     ##
  24     my $self = shift;
  25
  26     $self->{index_size}       = (2**8) * $self->{long_size};
  27     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size} * 2;
  28     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
  29
  30     return 1;
  31 }
  32
  33 sub set_pack {
  34     ##
  35     # Set pack/unpack modes (see file header for more)
  36     ##
  37     my $self = shift;
  38     my ($long_s, $long_p, $data_s, $data_p) = @_;
  39
  40     ##
  41     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
  42     # GB per file.
  43     #    (Perl must be compiled with largefile support for files > 2 GB)
  44     #
  45     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
  46     #    (Perl must be compiled with largefile and 64-bit long support)
  47     ##
  48     $self->{long_size} = $long_s ? $long_s : 4;
  49     $self->{long_pack} = $long_p ? $long_p : 'N';
  50
  51     ##
  52     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
  53     # key/value. Upgrading this is possible (see above) but probably not
  54     # necessary. If you need more than 4 GB for a single key or value, this
  55     # module is really not for you :-)
  56     ##
  57     $self->{data_size} = $data_s ? $data_s : 4;
  58     $self->{data_pack} = $data_p ? $data_p : 'N';
  59
  60     return $self->precalc_sizes();
  61 }
  62
  63 sub set_digest {
  64     ##
  65     # Set key digest function (default is MD5)
  66     ##
  67     my $self = shift;
  68     my ($digest_func, $hash_size) = @_;
  69
  70     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
  71     $self->{hash_size} = $hash_size ? $hash_size : 16;
  72
  73     return $self->precalc_sizes();
  74 }
  75
  76 sub new {
  77     my $class = shift;
  78     my ($args) = @_;
  79
  80     my $self = bless {
  81         long_size   => 4,
  82         long_pack   => 'N',
  83         data_size   => 4,
  84         data_pack   => 'N',
  85
  86         digest      => \&Digest::MD5::md5,
  87         hash_size   => 16,
  88
  89         ##
  90         # Maximum number of buckets per list before another level of indexing is
  91         # done.
  92         # Increase this value for slightly greater speed, but larger database
  93         # files. DO NOT decrease this value below 16, due to risk of recursive
  94         # reindex overrun.
  95         ##
  96         max_buckets => 16,
  97     }, $class;
  98
  99     $self->precalc_sizes;
 100
 101     return $self;
 102 }
 103
 104 sub setup_fh {
 105     my $self = shift;
 106     my ($obj) = @_;
 107
 108     $self->open( $obj ) if !defined $obj->_fh;
 109
 110     my $fh = $obj->_fh;
 111     flock $fh, LOCK_EX;
 112
 113     unless ( $obj->{base_offset} ) {
 114         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
 115         my $signature;
 116         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
 117
 118         ##
 119         # File is empty -- write signature and master index
 120         ##
 121         if (!$bytes_read) {
 122             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
 123             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
 124             print( $fh SIG_FILE);
 125
 126             $obj->{base_offset} = $self->_request_space(
 127                 $obj, $self->tag_size( $self->{index_size} ),
 128             );
 129
 130             $self->write_tag(
 131                 $obj, $obj->_base_offset, $obj->_type,
 132                 chr(0)x$self->{index_size},
 133             );
 134
 135             # Flush the filehandle
 136             my $old_fh = select $fh;
 137             my $old_af = $|; $| = 1; $| = $old_af;
 138             select $old_fh;
 139         }
 140         else {
 141             $obj->{base_offset} = $bytes_read;
 142
 143             ##
 144             # Check signature was valid
 145             ##
 146             unless ($signature eq SIG_FILE) {
 147                 $self->close_fh( $obj );
 148                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
 149             }
 150
 151             ##
 152             # Get our type from master index signature
 153             ##
 154             my $tag = $self->load_tag($obj, $obj->_base_offset)
 155             or $obj->_throw_error("Corrupted file, no master index record");
 156
 157             unless ($obj->{type} eq $tag->{signature}) {
 158                 $obj->_throw_error("File type mismatch");
 159             }
 160         }
 161     }
 162
 163     #XXX We have to make sure we don't mess up when autoflush isn't turned on
 164     unless ( $obj->_root->{inode} ) {
 165         my @stats = stat($obj->_fh);
 166         $obj->_root->{inode} = $stats[1];
 167         $obj->_root->{end} = $stats[7];
 168     }
 169
 170     flock $fh, LOCK_UN;
 171
 172     return 1;
 173 }
 174
 175 sub open {
 176     ##
 177     # Open a fh to the database, create if nonexistent.
 178     # Make sure file signature matches DBM::Deep spec.
 179     ##
 180     my $self = shift;
 181     my ($obj) = @_;
 182
 183     # Theoretically, adding O_BINARY should remove the need for the binmode
 184     # Of course, testing it is going to be ... interesting.
 185     my $flags = O_RDWR | O_CREAT | O_BINARY;
 186
 187     my $fh;
 188     my $filename = $obj->_root->{file};
 189     sysopen( $fh, $filename, $flags )
 190         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
 191     $obj->_root->{fh} = $fh;
 192
 193     #XXX Can we remove this by using the right sysopen() flags?
 194     # Maybe ... q.v. above
 195     binmode $fh; # for win32
 196
 197     if ($obj->_root->{autoflush}) {
 198         my $old = select $fh;
 199         $|=1;
 200         select $old;
 201     }
 202
 203     return 1;
 204 }
 205
 206 sub close_fh {
 207     my $self = shift;
 208     my ($obj) = @_;
 209
 210     if ( my $fh = $obj->_root->{fh} ) {
 211         close $fh;
 212     }
 213     $obj->_root->{fh} = undef;
 214
 215     return 1;
 216 }
 217
 218 sub tag_size {
 219     my $self = shift;
 220     my ($size) = @_;
 221     return SIG_SIZE + $self->{data_size} + $size;
 222 }
 223
 224 sub write_tag {
 225     ##
 226     # Given offset, signature and content, create tag and write to disk
 227     ##
 228     my $self = shift;
 229     my ($obj, $offset, $sig, $content) = @_;
 230     my $size = length( $content );
 231
 232     my $fh = $obj->_fh;
 233
 234     if ( defined $offset ) {
 235         seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 236     }
 237
 238     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
 239
 240     return unless defined $offset;
 241
 242     return {
 243         signature => $sig,
 244         size => $size,
 245         offset => $offset + SIG_SIZE + $self->{data_size},
 246         content => $content
 247     };
 248 }
 249
 250 sub load_tag {
 251     ##
 252     # Given offset, load single tag and return signature, size and data
 253     ##
 254     my $self = shift;
 255     my ($obj, $offset) = @_;
 256
 257 #    print join(':',map{$_||''}caller(1)), $/;
 258
 259     my $fh = $obj->_fh;
 260
 261     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
 262
 263     #XXX I'm not sure this check will work if autoflush isn't enabled ...
 264     return if eof $fh;
 265
 266     my $b;
 267     read( $fh, $b, SIG_SIZE + $self->{data_size} );
 268     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
 269
 270     my $buffer;
 271     read( $fh, $buffer, $size);
 272
 273     return {
 274         signature => $sig,
 275         size => $size,
 276         offset => $offset + SIG_SIZE + $self->{data_size},
 277         content => $buffer
 278     };
 279 }
 280
 281 sub _length_needed {
 282     my $self = shift;
 283     my ($obj, $value, $key) = @_;
 284
 285     my $is_dbm_deep = eval {
 286         local $SIG{'__DIE__'};
 287         $value->isa( 'DBM::Deep' );
 288     };
 289
 290     my $len = SIG_SIZE + $self->{data_size}
 291             + $self->{data_size} + length( $key );
 292
 293     if ( $is_dbm_deep && $value->_root eq $obj->_root ) {
 294         return $len + $self->{long_size};
 295     }
 296
 297     my $r = Scalar::Util::reftype( $value ) || '';
 298     if ( $obj->_root->{autobless} ) {
 299         # This is for the bit saying whether or not this thing is blessed.
 300         $len += 1;
 301     }
 302
 303     unless ( $r eq 'HASH' || $r eq 'ARRAY' ) {
 304         if ( defined $value ) {
 305             $len += length( $value );
 306         }
 307         return $len;
 308     }
 309
 310     $len += $self->{index_size};
 311
 312     # if autobless is enabled, must also take into consideration
 313     # the class name as it is stored after the key.
 314     if ( $obj->_root->{autobless} ) {
 315         my $value_class = Scalar::Util::blessed($value);
 316         if ( defined $value_class && !$is_dbm_deep ) {
 317             $len += $self->{data_size} + length($value_class);
 318         }
 319     }
 320
 321     return $len;
 322 }
 323
 324 sub add_bucket {
 325     ##
 326     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
 327     # plain (undigested) key and value.
 328     ##
 329     my $self = shift;
 330     my ($obj, $tag, $md5, $plain_key, $value) = @_;
 331
 332     # This verifies that only supported values will be stored.
 333     {
 334         my $r = Scalar::Util::reftype( $value );
 335         last if !defined $r;
 336
 337         last if $r eq 'HASH';
 338         last if $r eq 'ARRAY';
 339
 340         $obj->_throw_error(
 341             "Storage of variables of type '$r' is not supported."
 342         );
 343     }
 344
 345     my $location = 0;
 346     my $result = 2;
 347
 348     my $root = $obj->_root;
 349     my $fh   = $obj->_fh;
 350
 351     my $actual_length = $self->_length_needed( $obj, $value, $plain_key );
 352
 353     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 354
 355     # Updating a known md5
 356     if ( $subloc ) {
 357         $result = 1;
 358
 359         if ($actual_length <= $size) {
 360             $location = $subloc;
 361         }
 362         else {
 363             $location = $self->_request_space( $obj, $actual_length );
 364             seek(
 365                 $fh,
 366                 $tag->{offset} + $offset
 367               + $self->{hash_size} + $root->{file_offset},
 368                 SEEK_SET,
 369             );
 370             print( $fh pack($self->{long_pack}, $location ) );
 371             print( $fh pack($self->{long_pack}, $actual_length ) );
 372         }
 373     }
 374     # Adding a new md5
 375     elsif ( defined $offset ) {
 376         $location = $self->_request_space( $obj, $actual_length );
 377
 378         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
 379         print( $fh $md5 . pack($self->{long_pack}, $location ) );
 380         print( $fh pack($self->{long_pack}, $actual_length ) );
 381     }
 382     # If bucket didn't fit into list, split into a new index level
 383     else {
 384 #XXX This is going to be a problem.
 385         $self->split_index( $obj, $md5, $tag );
 386
 387         $location = $self->_request_space( $obj, $actual_length );
 388     }
 389
 390     $self->write_value( $obj, $location, $plain_key, $value );
 391
 392     return $result;
 393 }
 394
 395 sub write_value {
 396     my $self = shift;
 397     my ($obj, $location, $key, $value) = @_;
 398
 399     my $fh = $obj->_fh;
 400     my $root = $obj->_root;
 401
 402     my $is_dbm_deep = eval {
 403         local $SIG{'__DIE__'};
 404         $value->isa( 'DBM::Deep' );
 405     };
 406
 407     my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
 408
 409     seek($fh, $location + $root->{file_offset}, SEEK_SET);
 410
 411     ##
 412     # Write signature based on content type, set content length and write
 413     # actual value.
 414     ##
 415     my $r = Scalar::Util::reftype($value) || '';
 416     if ( $internal_ref ) {
 417         $self->write_tag( $obj, undef, SIG_INTERNAL,pack($self->{long_pack}, $value->_base_offset) );
 418     }
 419     elsif ($r eq 'HASH') {
 420         $self->write_tag( $obj, undef, SIG_HASH, chr(0)x$self->{index_size} );
 421     }
 422     elsif ($r eq 'ARRAY') {
 423         $self->write_tag( $obj, undef, SIG_ARRAY, chr(0)x$self->{index_size} );
 424     }
 425     elsif (!defined($value)) {
 426         $self->write_tag( $obj, undef, SIG_NULL, '' );
 427     }
 428     else {
 429         $self->write_tag( $obj, undef, SIG_DATA, $value );
 430     }
 431
 432     ##
 433     # Plain key is stored AFTER value, as keys are typically fetched less often.
 434     ##
 435     print( $fh pack($self->{data_pack}, length($key)) . $key );
 436
 437     # Internal references don't care about autobless
 438     return 1 if $internal_ref;
 439
 440     ##
 441     # If value is blessed, preserve class name
 442     ##
 443     if ( $root->{autobless} ) {
 444         my $value_class = Scalar::Util::blessed($value);
 445         if ( defined $value_class && !$is_dbm_deep ) {
 446             print( $fh chr(1) );
 447             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
 448         }
 449         else {
 450             print( $fh chr(0) );
 451         }
 452     }
 453
 454     ##
 455     # If content is a hash or array, create new child DBM::Deep object and
 456     # pass each key or element to it.
 457     ##
 458     if ( !$internal_ref ) {
 459         if ($r eq 'HASH') {
 460             my $branch = DBM::Deep->new(
 461                 type => DBM::Deep->TYPE_HASH,
 462                 base_offset => $location,
 463                 root => $root,
 464             );
 465             foreach my $key (keys %{$value}) {
 466                 $branch->STORE( $key, $value->{$key} );
 467             }
 468         }
 469         elsif ($r eq 'ARRAY') {
 470             my $branch = DBM::Deep->new(
 471                 type => DBM::Deep->TYPE_ARRAY,
 472                 base_offset => $location,
 473                 root => $root,
 474             );
 475             my $index = 0;
 476             foreach my $element (@{$value}) {
 477                 $branch->STORE( $index, $element );
 478                 $index++;
 479             }
 480         }
 481     }
 482
 483     return 1;
 484 }
 485
 486 sub split_index {
 487     my $self = shift;
 488     my ($obj, $md5, $tag) = @_;
 489
 490     my $fh = $obj->_fh;
 491     my $root = $obj->_root;
 492     my $keys = $tag->{content};
 493
 494     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
 495
 496     my $loc = $self->_request_space(
 497         $obj, $self->tag_size( $self->{index_size} ),
 498     );
 499
 500     print( $fh pack($self->{long_pack}, $loc) );
 501
 502     my $index_tag = $self->write_tag(
 503         $obj, $loc, SIG_INDEX,
 504         chr(0)x$self->{index_size},
 505     );
 506
 507     my @offsets = ();
 508
 509     $keys .= $md5 . (pack($self->{long_pack}, 0) x 2);
 510
 511     BUCKET:
 512     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
 513         my ($key, $old_subloc, $size) = $self->_get_key_subloc( $keys, $i );
 514
 515         next BUCKET unless $key;
 516
 517         my $num = ord(substr($key, $tag->{ch} + 1, 1));
 518
 519         if ($offsets[$num]) {
 520             my $offset = $offsets[$num] + SIG_SIZE + $self->{data_size};
 521             seek($fh, $offset + $root->{file_offset}, SEEK_SET);
 522             my $subkeys;
 523             read( $fh, $subkeys, $self->{bucket_list_size});
 524
 525             for (my $k=0; $k<$self->{max_buckets}; $k++) {
 526                 my ($temp, $subloc) = $self->_get_key_subloc( $subkeys, $k );
 527
 528                 if (!$subloc) {
 529                     seek($fh, $offset + ($k * $self->{bucket_size}) + $root->{file_offset}, SEEK_SET);
 530                     print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 531                     last;
 532                 }
 533             } # k loop
 534         }
 535         else {
 536             $offsets[$num] = $root->{end};
 537             seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
 538
 539             my $loc = $self->_request_space(
 540                 $obj, $self->tag_size( $self->{bucket_list_size} ),
 541             );
 542
 543             print( $fh pack($self->{long_pack}, $loc) );
 544
 545             my $blist_tag = $self->write_tag(
 546                 $obj, $loc, SIG_BLIST,
 547                 chr(0)x$self->{bucket_list_size},
 548             );
 549
 550             seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
 551             print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
 552         }
 553     } # i loop
 554
 555     return;
 556 }
 557
 558 sub read_from_loc {
 559     my $self = shift;
 560     my ($obj, $subloc) = @_;
 561
 562     my $fh = $obj->_fh;
 563
 564     ##
 565     # Found match -- seek to offset and read signature
 566     ##
 567     my $signature;
 568     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 569     read( $fh, $signature, SIG_SIZE);
 570
 571     ##
 572     # If value is a hash or array, return new DBM::Deep object with correct offset
 573     ##
 574     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
 575         my $obj = DBM::Deep->new(
 576             type => $signature,
 577             base_offset => $subloc,
 578             root => $obj->_root,
 579         );
 580
 581         if ($obj->_root->{autobless}) {
 582             ##
 583             # Skip over value and plain key to see if object needs
 584             # to be re-blessed
 585             ##
 586             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
 587
 588             my $size;
 589             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 590             if ($size) { seek($fh, $size, SEEK_CUR); }
 591
 592             my $bless_bit;
 593             read( $fh, $bless_bit, 1);
 594             if (ord($bless_bit)) {
 595                 ##
 596                 # Yes, object needs to be re-blessed
 597                 ##
 598                 my $class_name;
 599                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
 600                 if ($size) { read( $fh, $class_name, $size); }
 601                 if ($class_name) { $obj = bless( $obj, $class_name ); }
 602             }
 603         }
 604
 605         return $obj;
 606     }
 607     elsif ( $signature eq SIG_INTERNAL ) {
 608         my $size;
 609         read( $fh, $size, $self->{data_size});
 610         $size = unpack($self->{data_pack}, $size);
 611
 612         if ( $size ) {
 613             my $new_loc;
 614             read( $fh, $new_loc, $size );
 615             $new_loc = unpack( $self->{long_pack}, $new_loc );
 616
 617             return $self->read_from_loc( $obj, $new_loc );
 618         }
 619         else {
 620             return;
 621         }
 622     }
 623     ##
 624     # Otherwise return actual value
 625     ##
 626     elsif ($signature eq SIG_DATA) {
 627         my $size;
 628         read( $fh, $size, $self->{data_size});
 629         $size = unpack($self->{data_pack}, $size);
 630
 631         my $value = '';
 632         if ($size) { read( $fh, $value, $size); }
 633         return $value;
 634     }
 635
 636     ##
 637     # Key exists, but content is null
 638     ##
 639     return;
 640 }
 641
 642 sub get_bucket_value {
 643     ##
 644     # Fetch single value given tag and MD5 digested key.
 645     ##
 646     my $self = shift;
 647     my ($obj, $tag, $md5) = @_;
 648
 649     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 650     if ( $subloc ) {
 651         return $self->read_from_loc( $obj, $subloc );
 652     }
 653     return;
 654 }
 655
 656 sub delete_bucket {
 657     ##
 658     # Delete single key/value pair given tag and MD5 digested key.
 659     ##
 660     my $self = shift;
 661     my ($obj, $tag, $md5) = @_;
 662
 663     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 664     if ( $subloc ) {
 665         my $fh = $obj->_fh;
 666         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
 667         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
 668         print( $fh chr(0) x $self->{bucket_size} );
 669
 670         return 1;
 671     }
 672     return;
 673 }
 674
 675 sub bucket_exists {
 676     ##
 677     # Check existence of single key given tag and MD5 digested key.
 678     ##
 679     my $self = shift;
 680     my ($obj, $tag, $md5) = @_;
 681
 682     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
 683     return $subloc && 1;
 684 }
 685
 686 sub find_bucket_list {
 687     ##
 688     # Locate offset for bucket list, given digested key
 689     ##
 690     my $self = shift;
 691     my ($obj, $md5, $args) = @_;
 692     $args = {} unless $args;
 693
 694     ##
 695     # Locate offset for bucket list using digest index system
 696     ##
 697     my $tag = $self->load_tag($obj, $obj->_base_offset)
 698         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
 699
 700     my $ch = 0;
 701     while ($tag->{signature} ne SIG_BLIST) {
 702         my $num = ord substr($md5, $ch, 1);
 703
 704         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
 705         $tag = $self->index_lookup( $obj, $tag, $num );
 706
 707         if (!$tag) {
 708             return if !$args->{create};
 709
 710             my $fh = $obj->_fh;
 711             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
 712
 713             my $loc = $self->_request_space(
 714                 $obj, $self->tag_size( $self->{bucket_list_size} ),
 715             );
 716
 717             print( $fh pack($self->{long_pack}, $loc) );
 718
 719             $tag = $self->write_tag(
 720                 $obj, $loc, SIG_BLIST,
 721                 chr(0)x$self->{bucket_list_size},
 722             );
 723
 724             $tag->{ref_loc} = $ref_loc;
 725             $tag->{ch} = $ch;
 726
 727             last;
 728         }
 729
 730         $tag->{ch} = $ch++;
 731         $tag->{ref_loc} = $ref_loc;
 732     }
 733
 734     return $tag;
 735 }
 736
 737 sub index_lookup {
 738     ##
 739     # Given index tag, lookup single entry in index and return .
 740     ##
 741     my $self = shift;
 742     my ($obj, $tag, $index) = @_;
 743
 744     my $location = unpack(
 745         $self->{long_pack},
 746         substr(
 747             $tag->{content},
 748             $index * $self->{long_size},
 749             $self->{long_size},
 750         ),
 751     );
 752
 753     if (!$location) { return; }
 754
 755     return $self->load_tag( $obj, $location );
 756 }
 757
 758 sub traverse_index {
 759     ##
 760     # Scan index and recursively step into deeper levels, looking for next key.
 761     ##
 762     my $self = shift;
 763     my ($obj, $offset, $ch, $force_return_next) = @_;
 764
 765     my $tag = $self->load_tag($obj, $offset );
 766
 767     my $fh = $obj->_fh;
 768
 769     if ($tag->{signature} ne SIG_BLIST) {
 770         my $content = $tag->{content};
 771         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
 772
 773         for (my $idx = $start; $idx < (2**8); $idx++) {
 774             my $subloc = unpack(
 775                 $self->{long_pack},
 776                 substr(
 777                     $content,
 778                     $idx * $self->{long_size},
 779                     $self->{long_size},
 780                 ),
 781             );
 782
 783             if ($subloc) {
 784                 my $result = $self->traverse_index(
 785                     $obj, $subloc, $ch + 1, $force_return_next,
 786                 );
 787
 788                 if (defined($result)) { return $result; }
 789             }
 790         } # index loop
 791
 792         $obj->{return_next} = 1;
 793     } # tag is an index
 794
 795     else {
 796         my $keys = $tag->{content};
 797         if ($force_return_next) { $obj->{return_next} = 1; }
 798
 799         ##
 800         # Iterate through buckets, looking for a key match
 801         ##
 802         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
 803             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
 804
 805             # End of bucket list -- return to outer loop
 806             if (!$subloc) {
 807                 $obj->{return_next} = 1;
 808                 last;
 809             }
 810             # Located previous key -- return next one found
 811             elsif ($key eq $obj->{prev_md5}) {
 812                 $obj->{return_next} = 1;
 813                 next;
 814             }
 815             # Seek to bucket location and skip over signature
 816             elsif ($obj->{return_next}) {
 817                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
 818
 819                 # Skip over value to get to plain key
 820                 my $sig;
 821                 read( $fh, $sig, SIG_SIZE );
 822
 823                 my $size;
 824                 read( $fh, $size, $self->{data_size});
 825                 $size = unpack($self->{data_pack}, $size);
 826                 if ($size) { seek($fh, $size, SEEK_CUR); }
 827
 828                 # Read in plain key and return as scalar
 829                 my $plain_key;
 830                 read( $fh, $size, $self->{data_size});
 831                 $size = unpack($self->{data_pack}, $size);
 832                 if ($size) { read( $fh, $plain_key, $size); }
 833
 834                 return $plain_key;
 835             }
 836         }
 837
 838         $obj->{return_next} = 1;
 839     } # tag is a bucket list
 840
 841     return;
 842 }
 843
 844 sub get_next_key {
 845     ##
 846     # Locate next key, given digested previous one
 847     ##
 848     my $self = shift;
 849     my ($obj) = @_;
 850
 851     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
 852     $obj->{return_next} = 0;
 853
 854     ##
 855     # If the previous key was not specifed, start at the top and
 856     # return the first one found.
 857     ##
 858     if (!$obj->{prev_md5}) {
 859         $obj->{prev_md5} = chr(0) x $self->{hash_size};
 860         $obj->{return_next} = 1;
 861     }
 862
 863     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
 864 }
 865
 866 # Utilities
 867
 868 sub _get_key_subloc {
 869     my $self = shift;
 870     my ($keys, $idx) = @_;
 871
 872     my ($key, $subloc, $size) = unpack(
 873         "a$self->{hash_size} $self->{long_pack} $self->{long_pack}",
 874         substr(
 875             $keys,
 876             ($idx * $self->{bucket_size}),
 877             $self->{bucket_size},
 878         ),
 879     );
 880
 881     return ($key, $subloc, $size);
 882 }
 883
 884 sub _find_in_buckets {
 885     my $self = shift;
 886     my ($tag, $md5) = @_;
 887
 888     BUCKET:
 889     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
 890         my ($key, $subloc, $size) = $self->_get_key_subloc(
 891             $tag->{content}, $i,
 892         );
 893
 894         return ($subloc, $i * $self->{bucket_size}, $size) unless $subloc;
 895
 896         next BUCKET if $key ne $md5;
 897
 898         return ($subloc, $i * $self->{bucket_size}, $size);
 899     }
 900
 901     return;
 902 }
 903
 904 sub _request_space {
 905     my $self = shift;
 906     my ($obj, $size) = @_;
 907
 908     my $loc = $obj->_root->{end};
 909     $obj->_root->{end} += $size;
 910
 911     return $loc;
 912 }
 913
 914 sub _release_space {
 915     my $self = shift;
 916     my ($obj, $size, $loc) = @_;
 917
 918     return;
 919 }
 920
 921 1;
 922 __END__
 923
 924 # This will be added in later, after more refactoring is done. This is an early
 925 # attempt at refactoring on the physical level instead of the virtual level.
 926 sub _read_at {
 927     my $self = shift;
 928     my ($obj, $spot, $amount, $unpack) = @_;
 929
 930     my $fh = $obj->_fh;
 931     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
 932
 933     my $buffer;
 934     my $bytes_read = read( $fh, $buffer, $amount );
 935
 936     if ( $unpack ) {
 937         $buffer = unpack( $unpack, $buffer );
 938     }
 939
 940     if ( wantarray ) {
 941         return ($buffer, $bytes_read);
 942     }
 943     else {
 944         return $buffer;
 945     }
 946 }