Cleaning up split_index()
[dbsrgits/DBM-Deep.git] / lib / DBM / Deep / Engine.pm
1 package DBM::Deep::Engine;
2
3 use strict;
4
5 use Fcntl qw( :DEFAULT :flock :seek );
6
7 ##
8 # Setup file and tag signatures.  These should never change.
9 ##
10 sub SIG_FILE     () { 'DPDB' }
11 sub SIG_INTERNAL () { 'i'    }
12 sub SIG_HASH     () { 'H'    }
13 sub SIG_ARRAY    () { 'A'    }
14 sub SIG_NULL     () { 'N'    }
15 sub SIG_DATA     () { 'D'    }
16 sub SIG_INDEX    () { 'I'    }
17 sub SIG_BLIST    () { 'B'    }
18 sub SIG_FREE     () { 'F'    }
19 sub SIG_SIZE     () {  1     }
20
21 sub precalc_sizes {
22     ##
23     # Precalculate index, bucket and bucket list sizes
24     ##
25     my $self = shift;
26
27     $self->{index_size}       = (2**8) * $self->{long_size};
28     $self->{bucket_size}      = $self->{hash_size} + $self->{long_size} * 2;
29     $self->{bucket_list_size} = $self->{max_buckets} * $self->{bucket_size};
30
31     return 1;
32 }
33
34 sub set_pack {
35     ##
36     # Set pack/unpack modes (see file header for more)
37     ##
38     my $self = shift;
39     my ($long_s, $long_p, $data_s, $data_p) = @_;
40
41     ##
42     # Set to 4 and 'N' for 32-bit offset tags (default).  Theoretical limit of 4
43     # GB per file.
44     #    (Perl must be compiled with largefile support for files > 2 GB)
45     #
46     # Set to 8 and 'Q' for 64-bit offsets.  Theoretical limit of 16 XB per file.
47     #    (Perl must be compiled with largefile and 64-bit long support)
48     ##
49     $self->{long_size} = $long_s ? $long_s : 4;
50     $self->{long_pack} = $long_p ? $long_p : 'N';
51
52     ##
53     # Set to 4 and 'N' for 32-bit data length prefixes.  Limit of 4 GB for each
54     # key/value. Upgrading this is possible (see above) but probably not
55     # necessary. If you need more than 4 GB for a single key or value, this
56     # module is really not for you :-)
57     ##
58     $self->{data_size} = $data_s ? $data_s : 4;
59     $self->{data_pack} = $data_p ? $data_p : 'N';
60
61     return $self->precalc_sizes();
62 }
63
64 sub set_digest {
65     ##
66     # Set key digest function (default is MD5)
67     ##
68     my $self = shift;
69     my ($digest_func, $hash_size) = @_;
70
71     $self->{digest} = $digest_func ? $digest_func : \&Digest::MD5::md5;
72     $self->{hash_size} = $hash_size ? $hash_size : 16;
73
74     return $self->precalc_sizes();
75 }
76
77 sub new {
78     my $class = shift;
79     my ($args) = @_;
80
81     my $self = bless {
82         long_size   => 4,
83         long_pack   => 'N',
84         data_size   => 4,
85         data_pack   => 'N',
86
87         digest      => \&Digest::MD5::md5,
88         hash_size   => 16,
89
90         ##
91         # Maximum number of buckets per list before another level of indexing is
92         # done.
93         # Increase this value for slightly greater speed, but larger database
94         # files. DO NOT decrease this value below 16, due to risk of recursive
95         # reindex overrun.
96         ##
97         max_buckets => 16,
98     }, $class;
99
100     $self->precalc_sizes;
101
102     return $self;
103 }
104
105 sub setup_fh {
106     my $self = shift;
107     my ($obj) = @_;
108
109     $self->open( $obj ) if !defined $obj->_fh;
110
111     my $fh = $obj->_fh;
112     flock $fh, LOCK_EX;
113
114     unless ( $obj->{base_offset} ) {
115         seek($fh, 0 + $obj->_root->{file_offset}, SEEK_SET);
116         my $signature;
117         my $bytes_read = read( $fh, $signature, length(SIG_FILE));
118
119         ##
120         # File is empty -- write signature and master index
121         ##
122         if (!$bytes_read) {
123             my $loc = $self->_request_space( $obj, length( SIG_FILE ) );
124             seek($fh, $loc + $obj->_root->{file_offset}, SEEK_SET);
125             print( $fh SIG_FILE);
126
127             $obj->{base_offset} = $self->_request_space(
128                 $obj, $self->tag_size( $self->{index_size} ),
129             );
130
131             $self->write_tag(
132                 $obj, $obj->_base_offset, $obj->_type,
133                 chr(0)x$self->{index_size},
134             );
135
136             # Flush the filehandle
137             my $old_fh = select $fh;
138             my $old_af = $|; $| = 1; $| = $old_af;
139             select $old_fh;
140         }
141         else {
142             $obj->{base_offset} = $bytes_read;
143
144             ##
145             # Check signature was valid
146             ##
147             unless ($signature eq SIG_FILE) {
148                 $self->close_fh( $obj );
149                 $obj->_throw_error("Signature not found -- file is not a Deep DB");
150             }
151
152             ##
153             # Get our type from master index signature
154             ##
155             my $tag = $self->load_tag($obj, $obj->_base_offset)
156             or $obj->_throw_error("Corrupted file, no master index record");
157
158             unless ($obj->{type} eq $tag->{signature}) {
159                 $obj->_throw_error("File type mismatch");
160             }
161         }
162     }
163
164     #XXX We have to make sure we don't mess up when autoflush isn't turned on
165     unless ( $obj->_root->{inode} ) {
166         my @stats = stat($obj->_fh);
167         $obj->_root->{inode} = $stats[1];
168         $obj->_root->{end} = $stats[7];
169     }
170
171     flock $fh, LOCK_UN;
172
173     return 1;
174 }
175
176 sub open {
177     ##
178     # Open a fh to the database, create if nonexistent.
179     # Make sure file signature matches DBM::Deep spec.
180     ##
181     my $self = shift;
182     my ($obj) = @_;
183
184     # Theoretically, adding O_BINARY should remove the need for the binmode
185     # Of course, testing it is going to be ... interesting.
186     my $flags = O_RDWR | O_CREAT | O_BINARY;
187
188     my $fh;
189     my $filename = $obj->_root->{file};
190     sysopen( $fh, $filename, $flags )
191         or $obj->_throw_error("Cannot sysopen file '$filename': $!");
192     $obj->_root->{fh} = $fh;
193
194     #XXX Can we remove this by using the right sysopen() flags?
195     # Maybe ... q.v. above
196     binmode $fh; # for win32
197
198     if ($obj->_root->{autoflush}) {
199         my $old = select $fh;
200         $|=1;
201         select $old;
202     }
203
204     return 1;
205 }
206
207 sub close_fh {
208     my $self = shift;
209     my ($obj) = @_;
210
211     if ( my $fh = $obj->_root->{fh} ) {
212         close $fh;
213     }
214     $obj->_root->{fh} = undef;
215
216     return 1;
217 }
218
219 sub tag_size {
220     my $self = shift;
221     my ($size) = @_;
222     return SIG_SIZE + $self->{data_size} + $size;
223 }
224
225 sub write_tag {
226     ##
227     # Given offset, signature and content, create tag and write to disk
228     ##
229     my $self = shift;
230     my ($obj, $offset, $sig, $content) = @_;
231     my $size = length( $content );
232
233     my $fh = $obj->_fh;
234
235     if ( defined $offset ) {
236         seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
237     }
238
239     print( $fh $sig . pack($self->{data_pack}, $size) . $content );
240
241     return unless defined $offset;
242
243     return {
244         signature => $sig,
245         size => $size,
246         offset => $offset + SIG_SIZE + $self->{data_size},
247         content => $content
248     };
249 }
250
251 sub load_tag {
252     ##
253     # Given offset, load single tag and return signature, size and data
254     ##
255     my $self = shift;
256     my ($obj, $offset) = @_;
257
258 #    print join(':',map{$_||''}caller(1)), $/;
259
260     my $fh = $obj->_fh;
261
262     seek($fh, $offset + $obj->_root->{file_offset}, SEEK_SET);
263
264     #XXX I'm not sure this check will work if autoflush isn't enabled ...
265     return if eof $fh;
266
267     my $b;
268     read( $fh, $b, SIG_SIZE + $self->{data_size} );
269     my ($sig, $size) = unpack( "A $self->{data_pack}", $b );
270
271     my $buffer;
272     read( $fh, $buffer, $size);
273
274     return {
275         signature => $sig,
276         size => $size,
277         offset => $offset + SIG_SIZE + $self->{data_size},
278         content => $buffer
279     };
280 }
281
282 sub _length_needed {
283     my $self = shift;
284     my ($obj, $value, $key) = @_;
285
286     my $is_dbm_deep = eval {
287         local $SIG{'__DIE__'};
288         $value->isa( 'DBM::Deep' );
289     };
290
291     my $len = SIG_SIZE + $self->{data_size}
292             + $self->{data_size} + length( $key );
293
294     if ( $is_dbm_deep && $value->_root eq $obj->_root ) {
295         return $len + $self->{long_size};
296     }
297
298     my $r = Scalar::Util::reftype( $value ) || '';
299     if ( $obj->_root->{autobless} ) {
300         # This is for the bit saying whether or not this thing is blessed.
301         $len += 1;
302     }
303
304     unless ( $r eq 'HASH' || $r eq 'ARRAY' ) {
305         if ( defined $value ) {
306             $len += length( $value );
307         }
308         return $len;
309     }
310
311     $len += $self->{index_size};
312
313     # if autobless is enabled, must also take into consideration
314     # the class name as it is stored after the key.
315     if ( $obj->_root->{autobless} ) {
316         my $value_class = Scalar::Util::blessed($value);
317         if ( defined $value_class && !$is_dbm_deep ) {
318             $len += $self->{data_size} + length($value_class);
319         }
320     }
321
322     return $len;
323 }
324
325 sub add_bucket {
326     ##
327     # Adds one key/value pair to bucket list, given offset, MD5 digest of key,
328     # plain (undigested) key and value.
329     ##
330     my $self = shift;
331     my ($obj, $tag, $md5, $plain_key, $value) = @_;
332
333     # This verifies that only supported values will be stored.
334     {
335         my $r = Scalar::Util::reftype( $value );
336         last if !defined $r;
337
338         last if $r eq 'HASH';
339         last if $r eq 'ARRAY';
340
341         $obj->_throw_error(
342             "Storage of variables of type '$r' is not supported."
343         );
344     }
345
346     my $location = 0;
347     my $result = 2;
348
349     my $root = $obj->_root;
350     my $fh   = $obj->_fh;
351
352     my $actual_length = $self->_length_needed( $obj, $value, $plain_key );
353
354     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
355
356     # Updating a known md5
357     if ( $subloc ) {
358         $result = 1;
359
360         if ($actual_length <= $size) {
361             $location = $subloc;
362         }
363         else {
364             $location = $self->_request_space( $obj, $actual_length );
365             seek(
366                 $fh,
367                 $tag->{offset} + $offset
368               + $self->{hash_size} + $root->{file_offset},
369                 SEEK_SET,
370             );
371             print( $fh pack($self->{long_pack}, $location ) );
372             print( $fh pack($self->{long_pack}, $actual_length ) );
373         }
374     }
375     # Adding a new md5
376     elsif ( defined $offset ) {
377         $location = $self->_request_space( $obj, $actual_length );
378
379         seek( $fh, $tag->{offset} + $offset + $root->{file_offset}, SEEK_SET );
380         print( $fh $md5 . pack($self->{long_pack}, $location ) );
381         print( $fh pack($self->{long_pack}, $actual_length ) );
382     }
383     # If bucket didn't fit into list, split into a new index level
384     else {
385 #XXX This is going to be a problem.
386        $self->split_index( $obj, $md5, $tag );
387
388         $location = $self->_request_space( $obj, $actual_length );
389     }
390
391     $self->write_value( $obj, $location, $plain_key, $value );
392
393     return $result;
394 }
395
396 sub write_value {
397     my $self = shift;
398     my ($obj, $location, $key, $value) = @_;
399
400     my $fh = $obj->_fh;
401     my $root = $obj->_root;
402
403     my $is_dbm_deep = eval {
404         local $SIG{'__DIE__'};
405         $value->isa( 'DBM::Deep' );
406     };
407
408     my $internal_ref = $is_dbm_deep && ($value->_root eq $root);
409
410     seek($fh, $location + $root->{file_offset}, SEEK_SET);
411
412     ##
413     # Write signature based on content type, set content length and write
414     # actual value.
415     ##
416     my $r = Scalar::Util::reftype($value) || '';
417     if ( $internal_ref ) {
418         $self->write_tag( $obj, undef, SIG_INTERNAL,pack($self->{long_pack}, $value->_base_offset) );
419     }
420     elsif ($r eq 'HASH') {
421         $self->write_tag( $obj, undef, SIG_HASH, chr(0)x$self->{index_size} );
422     }
423     elsif ($r eq 'ARRAY') {
424         $self->write_tag( $obj, undef, SIG_ARRAY, chr(0)x$self->{index_size} );
425     }
426     elsif (!defined($value)) {
427         $self->write_tag( $obj, undef, SIG_NULL, '' );
428     }
429     else {
430         $self->write_tag( $obj, undef, SIG_DATA, $value );
431     }
432
433     ##
434     # Plain key is stored AFTER value, as keys are typically fetched less often.
435     ##
436     print( $fh pack($self->{data_pack}, length($key)) . $key );
437
438     # Internal references don't care about autobless
439     return 1 if $internal_ref;
440
441     ##
442     # If value is blessed, preserve class name
443     ##
444     if ( $root->{autobless} ) {
445         my $value_class = Scalar::Util::blessed($value);
446         if ( defined $value_class && !$is_dbm_deep ) {
447             print( $fh chr(1) );
448             print( $fh pack($self->{data_pack}, length($value_class)) . $value_class );
449         }
450         else {
451             print( $fh chr(0) );
452         }
453     }
454
455     ##
456     # If content is a hash or array, create new child DBM::Deep object and
457     # pass each key or element to it.
458     ##
459     if ( !$internal_ref ) {
460         if ($r eq 'HASH') {
461             my $branch = DBM::Deep->new(
462                 type => DBM::Deep->TYPE_HASH,
463                 base_offset => $location,
464                 root => $root,
465             );
466             foreach my $key (keys %{$value}) {
467                 $branch->STORE( $key, $value->{$key} );
468             }
469         }
470         elsif ($r eq 'ARRAY') {
471             my $branch = DBM::Deep->new(
472                 type => DBM::Deep->TYPE_ARRAY,
473                 base_offset => $location,
474                 root => $root,
475             );
476             my $index = 0;
477             foreach my $element (@{$value}) {
478                 $branch->STORE( $index, $element );
479                 $index++;
480             }
481         }
482     }
483
484     return 1;
485 }
486
487 sub split_index {
488     my $self = shift;
489     my ($obj, $md5, $tag) = @_;
490
491     my $fh = $obj->_fh;
492     my $root = $obj->_root;
493
494     my $loc = $self->_request_space(
495         $obj, $self->tag_size( $self->{index_size} ),
496     );
497
498     seek($fh, $tag->{ref_loc} + $root->{file_offset}, SEEK_SET);
499     print( $fh pack($self->{long_pack}, $loc) );
500
501     my $index_tag = $self->write_tag(
502         $obj, $loc, SIG_INDEX,
503         chr(0)x$self->{index_size},
504     );
505
506     my @offsets = ();
507
508     my $keys = $tag->{content}
509              . $md5 . (pack($self->{long_pack}, 0) x 2);
510
511     BUCKET:
512     for (my $i = 0; $i <= $self->{max_buckets}; $i++) {
513         my ($key, $old_subloc, $size) = $self->_get_key_subloc( $keys, $i );
514
515         next BUCKET unless $key;
516
517         my $num = ord(substr($key, $tag->{ch} + 1, 1));
518
519         if ($offsets[$num]) {
520             seek($fh, $offsets[$num] + $root->{file_offset}, SEEK_SET);
521             my $subkeys;
522             read( $fh, $subkeys, $self->{bucket_list_size});
523
524             my ($subloc, $offset, $size) = $self->_find_in_buckets(
525                 { content => $subkeys }, ''
526             );
527
528             seek($fh, $offsets[$num] + $offset + $root->{file_offset}, SEEK_SET);
529             print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
530
531             next;
532         }
533
534         seek($fh, $index_tag->{offset} + ($num * $self->{long_size}) + $root->{file_offset}, SEEK_SET);
535
536         my $loc = $self->_request_space(
537             $obj, $self->tag_size( $self->{bucket_list_size} ),
538         );
539
540         print( $fh pack($self->{long_pack}, $loc) );
541
542         my $blist_tag = $self->write_tag(
543             $obj, $loc, SIG_BLIST,
544             chr(0)x$self->{bucket_list_size},
545         );
546
547         seek($fh, $blist_tag->{offset} + $root->{file_offset}, SEEK_SET);
548         print( $fh $key . pack($self->{long_pack}, $old_subloc || $root->{end}) );
549
550         $offsets[$num] = $blist_tag->{offset};
551     }
552
553     $self->_release_space(
554         $obj, $self->tag_size( $self->{index_size} ),
555         $tag->{offset} - SIG_SIZE - $self->{data_size},
556     );
557
558     return;
559 }
560
561 sub read_from_loc {
562     my $self = shift;
563     my ($obj, $subloc) = @_;
564
565     my $fh = $obj->_fh;
566
567     ##
568     # Found match -- seek to offset and read signature
569     ##
570     my $signature;
571     seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
572     read( $fh, $signature, SIG_SIZE);
573
574     ##
575     # If value is a hash or array, return new DBM::Deep object with correct offset
576     ##
577     if (($signature eq SIG_HASH) || ($signature eq SIG_ARRAY)) {
578         my $obj = DBM::Deep->new(
579             type => $signature,
580             base_offset => $subloc,
581             root => $obj->_root,
582         );
583
584         if ($obj->_root->{autobless}) {
585             ##
586             # Skip over value and plain key to see if object needs
587             # to be re-blessed
588             ##
589             seek($fh, $self->{data_size} + $self->{index_size}, SEEK_CUR);
590
591             my $size;
592             read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
593             if ($size) { seek($fh, $size, SEEK_CUR); }
594
595             my $bless_bit;
596             read( $fh, $bless_bit, 1);
597             if (ord($bless_bit)) {
598                 ##
599                 # Yes, object needs to be re-blessed
600                 ##
601                 my $class_name;
602                 read( $fh, $size, $self->{data_size}); $size = unpack($self->{data_pack}, $size);
603                 if ($size) { read( $fh, $class_name, $size); }
604                 if ($class_name) { $obj = bless( $obj, $class_name ); }
605             }
606         }
607
608         return $obj;
609     }
610     elsif ( $signature eq SIG_INTERNAL ) {
611         my $size;
612         read( $fh, $size, $self->{data_size});
613         $size = unpack($self->{data_pack}, $size);
614
615         if ( $size ) {
616             my $new_loc;
617             read( $fh, $new_loc, $size );
618             $new_loc = unpack( $self->{long_pack}, $new_loc );
619
620             return $self->read_from_loc( $obj, $new_loc );
621         }
622         else {
623             return;
624         }
625     }
626     ##
627     # Otherwise return actual value
628     ##
629     elsif ($signature eq SIG_DATA) {
630         my $size;
631         read( $fh, $size, $self->{data_size});
632         $size = unpack($self->{data_pack}, $size);
633
634         my $value = '';
635         if ($size) { read( $fh, $value, $size); }
636         return $value;
637     }
638
639     ##
640     # Key exists, but content is null
641     ##
642     return;
643 }
644
645 sub get_bucket_value {
646     ##
647     # Fetch single value given tag and MD5 digested key.
648     ##
649     my $self = shift;
650     my ($obj, $tag, $md5) = @_;
651
652     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
653     if ( $subloc ) {
654         return $self->read_from_loc( $obj, $subloc );
655     }
656     return;
657 }
658
659 sub delete_bucket {
660     ##
661     # Delete single key/value pair given tag and MD5 digested key.
662     ##
663     my $self = shift;
664     my ($obj, $tag, $md5) = @_;
665
666     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
667     if ( $subloc ) {
668         my $fh = $obj->_fh;
669         seek($fh, $tag->{offset} + $offset + $obj->_root->{file_offset}, SEEK_SET);
670         print( $fh substr($tag->{content}, $offset + $self->{bucket_size} ) );
671         print( $fh chr(0) x $self->{bucket_size} );
672
673         return 1;
674     }
675     return;
676 }
677
678 sub bucket_exists {
679     ##
680     # Check existence of single key given tag and MD5 digested key.
681     ##
682     my $self = shift;
683     my ($obj, $tag, $md5) = @_;
684
685     my ($subloc, $offset, $size) = $self->_find_in_buckets( $tag, $md5 );
686     return $subloc && 1;
687 }
688
689 sub find_bucket_list {
690     ##
691     # Locate offset for bucket list, given digested key
692     ##
693     my $self = shift;
694     my ($obj, $md5, $args) = @_;
695     $args = {} unless $args;
696
697     ##
698     # Locate offset for bucket list using digest index system
699     ##
700     my $tag = $self->load_tag($obj, $obj->_base_offset)
701         or $obj->_throw_error( "INTERNAL ERROR - Cannot find tag" );
702
703     my $ch = 0;
704     while ($tag->{signature} ne SIG_BLIST) {
705         my $num = ord substr($md5, $ch, 1);
706
707         my $ref_loc = $tag->{offset} + ($num * $self->{long_size});
708         $tag = $self->index_lookup( $obj, $tag, $num );
709
710         if (!$tag) {
711             return if !$args->{create};
712
713             my $loc = $self->_request_space(
714                 $obj, $self->tag_size( $self->{bucket_list_size} ),
715             );
716
717             my $fh = $obj->_fh;
718             seek($fh, $ref_loc + $obj->_root->{file_offset}, SEEK_SET);
719             print( $fh pack($self->{long_pack}, $loc) );
720
721             $tag = $self->write_tag(
722                 $obj, $loc, SIG_BLIST,
723                 chr(0)x$self->{bucket_list_size},
724             );
725
726             $tag->{ref_loc} = $ref_loc;
727             $tag->{ch} = $ch;
728
729             last;
730         }
731
732         $tag->{ch} = $ch++;
733         $tag->{ref_loc} = $ref_loc;
734     }
735
736     return $tag;
737 }
738
739 sub index_lookup {
740     ##
741     # Given index tag, lookup single entry in index and return .
742     ##
743     my $self = shift;
744     my ($obj, $tag, $index) = @_;
745
746     my $location = unpack(
747         $self->{long_pack},
748         substr(
749             $tag->{content},
750             $index * $self->{long_size},
751             $self->{long_size},
752         ),
753     );
754
755     if (!$location) { return; }
756
757     return $self->load_tag( $obj, $location );
758 }
759
760 sub traverse_index {
761     ##
762     # Scan index and recursively step into deeper levels, looking for next key.
763     ##
764     my $self = shift;
765     my ($obj, $offset, $ch, $force_return_next) = @_;
766
767     my $tag = $self->load_tag($obj, $offset );
768
769     my $fh = $obj->_fh;
770
771     if ($tag->{signature} ne SIG_BLIST) {
772         my $content = $tag->{content};
773         my $start = $obj->{return_next} ? 0 : ord(substr($obj->{prev_md5}, $ch, 1));
774
775         for (my $idx = $start; $idx < (2**8); $idx++) {
776             my $subloc = unpack(
777                 $self->{long_pack},
778                 substr(
779                     $content,
780                     $idx * $self->{long_size},
781                     $self->{long_size},
782                 ),
783             );
784
785             if ($subloc) {
786                 my $result = $self->traverse_index(
787                     $obj, $subloc, $ch + 1, $force_return_next,
788                 );
789
790                 if (defined($result)) { return $result; }
791             }
792         } # index loop
793
794         $obj->{return_next} = 1;
795     } # tag is an index
796
797     else {
798         my $keys = $tag->{content};
799         if ($force_return_next) { $obj->{return_next} = 1; }
800
801         ##
802         # Iterate through buckets, looking for a key match
803         ##
804         for (my $i = 0; $i < $self->{max_buckets}; $i++) {
805             my ($key, $subloc) = $self->_get_key_subloc( $keys, $i );
806
807             # End of bucket list -- return to outer loop
808             if (!$subloc) {
809                 $obj->{return_next} = 1;
810                 last;
811             }
812             # Located previous key -- return next one found
813             elsif ($key eq $obj->{prev_md5}) {
814                 $obj->{return_next} = 1;
815                 next;
816             }
817             # Seek to bucket location and skip over signature
818             elsif ($obj->{return_next}) {
819                 seek($fh, $subloc + $obj->_root->{file_offset}, SEEK_SET);
820
821                 # Skip over value to get to plain key
822                 my $sig;
823                 read( $fh, $sig, SIG_SIZE );
824
825                 my $size;
826                 read( $fh, $size, $self->{data_size});
827                 $size = unpack($self->{data_pack}, $size);
828                 if ($size) { seek($fh, $size, SEEK_CUR); }
829
830                 # Read in plain key and return as scalar
831                 my $plain_key;
832                 read( $fh, $size, $self->{data_size});
833                 $size = unpack($self->{data_pack}, $size);
834                 if ($size) { read( $fh, $plain_key, $size); }
835
836                 return $plain_key;
837             }
838         }
839
840         $obj->{return_next} = 1;
841     } # tag is a bucket list
842
843     return;
844 }
845
846 sub get_next_key {
847     ##
848     # Locate next key, given digested previous one
849     ##
850     my $self = shift;
851     my ($obj) = @_;
852
853     $obj->{prev_md5} = $_[1] ? $_[1] : undef;
854     $obj->{return_next} = 0;
855
856     ##
857     # If the previous key was not specifed, start at the top and
858     # return the first one found.
859     ##
860     if (!$obj->{prev_md5}) {
861         $obj->{prev_md5} = chr(0) x $self->{hash_size};
862         $obj->{return_next} = 1;
863     }
864
865     return $self->traverse_index( $obj, $obj->_base_offset, 0 );
866 }
867
868 # Utilities
869
870 sub _get_key_subloc {
871     my $self = shift;
872     my ($keys, $idx) = @_;
873
874     my ($key, $subloc, $size) = unpack(
875         "a$self->{hash_size} $self->{long_pack} $self->{long_pack}",
876         substr(
877             $keys,
878             ($idx * $self->{bucket_size}),
879             $self->{bucket_size},
880         ),
881     );
882
883     return ($key, $subloc, $size);
884 }
885
886 sub _find_in_buckets {
887     my $self = shift;
888     my ($tag, $md5) = @_;
889
890     BUCKET:
891     for ( my $i = 0; $i < $self->{max_buckets}; $i++ ) {
892         my ($key, $subloc, $size) = $self->_get_key_subloc(
893             $tag->{content}, $i,
894         );
895
896         return ($subloc, $i * $self->{bucket_size}, $size) unless $subloc;
897
898         next BUCKET if $key ne $md5;
899
900         return ($subloc, $i * $self->{bucket_size}, $size);
901     }
902
903     return;
904 }
905
906 #sub _print_at {
907 #    my $self = shift;
908 #    my ($obj, $spot, $data) = @_;
909 #
910 #    my $fh = $obj->_fh;
911 #    seek( $fh, $spot, SEEK_SET );
912 #    print( $fh $data );
913 #
914 #    return;
915 #}
916
917 sub _request_space {
918     my $self = shift;
919     my ($obj, $size) = @_;
920
921     my $loc = $obj->_root->{end};
922     $obj->_root->{end} += $size;
923
924     return $loc;
925 }
926
927 sub _release_space {
928     my $self = shift;
929     my ($obj, $size, $loc) = @_;
930
931     my $next_loc = 0;
932
933     my $fh = $obj->_fh;
934     seek( $fh, $loc + $obj->_root->{file_offset}, SEEK_SET );
935     print( $fh SIG_FREE
936         . pack($self->{long_pack}, $size )
937         . pack($self->{long_pack}, $next_loc )
938     );
939
940     return;
941 }
942
943 1;
944 __END__
945
946 # This will be added in later, after more refactoring is done. This is an early
947 # attempt at refactoring on the physical level instead of the virtual level.
948 sub _read_at {
949     my $self = shift;
950     my ($obj, $spot, $amount, $unpack) = @_;
951
952     my $fh = $obj->_fh;
953     seek( $fh, $spot + $obj->_root->{file_offset}, SEEK_SET );
954
955     my $buffer;
956     my $bytes_read = read( $fh, $buffer, $amount );
957
958     if ( $unpack ) {
959         $buffer = unpack( $unpack, $buffer );
960     }
961
962     if ( wantarray ) {
963         return ($buffer, $bytes_read);
964     }
965     else {
966         return $buffer;
967     }
968 }