lib/DBM/Deep/Engine.pm

   1 package DBM::Deep::Engine;
   2
   3 use 5.006_000;
   4
   5 use strict;
   6 use warnings;
   7
   8 our $VERSION = q(1.0010);
   9
  10 # Never import symbols into our namespace. We are a class, not a library.
  11 # -RobK, 2008-05-27
  12 use Scalar::Util ();
  13 use Data::Dumper ();
  14
  15 # File-wide notes:
  16 # * Every method in here assumes that the storage has been appropriately
  17 #   safeguarded. This can be anything from flock() to some sort of manual
  18 #   mutex. But, it's the caller's responsability to make sure that this has
  19 #   been done.
  20
  21 # Setup file and tag signatures.  These should never change.
  22 sub SIG_FILE     () { 'DPDB' }
  23 sub SIG_HEADER   () { 'h'    }
  24 sub SIG_HASH     () { 'H'    }
  25 sub SIG_ARRAY    () { 'A'    }
  26 sub SIG_NULL     () { 'N'    }
  27 sub SIG_DATA     () { 'D'    }
  28 sub SIG_INDEX    () { 'I'    }
  29 sub SIG_BLIST    () { 'B'    }
  30 sub SIG_FREE     () { 'F'    }
  31 sub SIG_SIZE     () {  1     }
  32
  33 my $STALE_SIZE = 2;
  34
  35 # Please refer to the pack() documentation for further information
  36 my %StP = (
  37     1 => 'C', # Unsigned char value (no order needed as it's just one byte)
  38     2 => 'n', # Unsigned short in "network" (big-endian) order
  39     4 => 'N', # Unsigned long in "network" (big-endian) order
  40     8 => 'Q', # Usigned quad (no order specified, presumably machine-dependent)
  41 );
  42
  43 ################################################################################
  44
  45 sub new {
  46     my $class = shift;
  47     my ($args) = @_;
  48
  49     my $self = bless {
  50         byte_size   => 4,
  51
  52         digest      => undef,
  53         hash_size   => 16,  # In bytes
  54         hash_chars  => 256, # Number of chars the algorithm uses per byte
  55         max_buckets => 16,
  56         num_txns    => 1,   # The HEAD
  57         trans_id    => 0,   # Default to the HEAD
  58
  59         data_sector_size => 64, # Size in bytes of each data sector
  60
  61         entries => {}, # This is the list of entries for transactions
  62         storage => undef,
  63     }, $class;
  64
  65     # Never allow byte_size to be set directly.
  66     delete $args->{byte_size};
  67     if ( defined $args->{pack_size} ) {
  68         if ( lc $args->{pack_size} eq 'small' ) {
  69             $args->{byte_size} = 2;
  70         }
  71         elsif ( lc $args->{pack_size} eq 'medium' ) {
  72             $args->{byte_size} = 4;
  73         }
  74         elsif ( lc $args->{pack_size} eq 'large' ) {
  75             $args->{byte_size} = 8;
  76         }
  77         else {
  78             DBM::Deep->_throw_error( "Unknown pack_size value: '$args->{pack_size}'" );
  79         }
  80     }
  81
  82     # Grab the parameters we want to use
  83     foreach my $param ( keys %$self ) {
  84         next unless exists $args->{$param};
  85         $self->{$param} = $args->{$param};
  86     }
  87
  88     my %validations = (
  89         max_buckets      => { floor => 16, ceil => 256 },
  90         num_txns         => { floor => 1,  ceil => 255 },
  91         data_sector_size => { floor => 32, ceil => 256 },
  92     );
  93
  94     while ( my ($attr, $c) = each %validations ) {
  95         if (   !defined $self->{$attr}
  96             || !length $self->{$attr}
  97             || $self->{$attr} =~ /\D/
  98             || $self->{$attr} < $c->{floor}
  99         ) {
 100             $self->{$attr} = '(undef)' if !defined $self->{$attr};
 101             warn "Floor of $attr is $c->{floor}. Setting it to $c->{floor} from '$self->{$attr}'\n";
 102             $self->{$attr} = $c->{floor};
 103         }
 104         elsif ( $self->{$attr} > $c->{ceil} ) {
 105             warn "Ceiling of $attr is $c->{ceil}. Setting it to $c->{ceil} from '$self->{$attr}'\n";
 106             $self->{$attr} = $c->{ceil};
 107         }
 108     }
 109
 110     if ( !$self->{digest} ) {
 111         require Digest::MD5;
 112         $self->{digest} = \&Digest::MD5::md5;
 113     }
 114
 115     return $self;
 116 }
 117
 118 ################################################################################
 119
 120 sub read_value {
 121     my $self = shift;
 122     my ($obj, $key) = @_;
 123
 124     # This will be a Reference sector
 125     my $sector = $self->_load_sector( $obj->_base_offset )
 126         or return;
 127
 128     if ( $sector->staleness != $obj->_staleness ) {
 129         return;
 130     }
 131
 132     my $key_md5 = $self->_apply_digest( $key );
 133
 134     my $value_sector = $sector->get_data_for({
 135         key_md5    => $key_md5,
 136         allow_head => 1,
 137     });
 138
 139     unless ( $value_sector ) {
 140         $value_sector = DBM::Deep::Engine::Sector::Null->new({
 141             engine => $self,
 142             data   => undef,
 143         });
 144
 145         $sector->write_data({
 146             key_md5 => $key_md5,
 147             key     => $key,
 148             value   => $value_sector,
 149         });
 150     }
 151
 152     return $value_sector->data;
 153 }
 154
 155 sub get_classname {
 156     my $self = shift;
 157     my ($obj) = @_;
 158
 159     # This will be a Reference sector
 160     my $sector = $self->_load_sector( $obj->_base_offset )
 161         or DBM::Deep->_throw_error( "How did get_classname fail (no sector for '$obj')?!" );
 162
 163     if ( $sector->staleness != $obj->_staleness ) {
 164         return;
 165     }
 166
 167     return $sector->get_classname;
 168 }
 169
 170 sub make_reference {
 171     my $self = shift;
 172     my ($obj, $old_key, $new_key) = @_;
 173
 174     # This will be a Reference sector
 175     my $sector = $self->_load_sector( $obj->_base_offset )
 176         or DBM::Deep->_throw_error( "How did get_classname fail (no sector for '$obj')?!" );
 177
 178     if ( $sector->staleness != $obj->_staleness ) {
 179         return;
 180     }
 181
 182     my $old_md5 = $self->_apply_digest( $old_key );
 183
 184     my $value_sector = $sector->get_data_for({
 185         key_md5    => $old_md5,
 186         allow_head => 1,
 187     });
 188
 189     unless ( $value_sector ) {
 190         $value_sector = DBM::Deep::Engine::Sector::Null->new({
 191             engine => $self,
 192             data   => undef,
 193         });
 194
 195         $sector->write_data({
 196             key_md5 => $old_md5,
 197             key     => $old_key,
 198             value   => $value_sector,
 199         });
 200     }
 201
 202     if ( $value_sector->isa( 'DBM::Deep::Engine::Sector::Reference' ) ) {
 203         $sector->write_data({
 204             key     => $new_key,
 205             key_md5 => $self->_apply_digest( $new_key ),
 206             value   => $value_sector,
 207         });
 208         $value_sector->increment_refcount;
 209     }
 210     else {
 211         $sector->write_data({
 212             key     => $new_key,
 213             key_md5 => $self->_apply_digest( $new_key ),
 214             value   => $value_sector->clone,
 215         });
 216     }
 217 }
 218
 219 sub key_exists {
 220     my $self = shift;
 221     my ($obj, $key) = @_;
 222
 223     # This will be a Reference sector
 224     my $sector = $self->_load_sector( $obj->_base_offset )
 225         or return '';
 226
 227     if ( $sector->staleness != $obj->_staleness ) {
 228         return '';
 229     }
 230
 231     my $data = $sector->get_data_for({
 232         key_md5    => $self->_apply_digest( $key ),
 233         allow_head => 1,
 234     });
 235
 236     # exists() returns 1 or '' for true/false.
 237     return $data ? 1 : '';
 238 }
 239
 240 sub delete_key {
 241     my $self = shift;
 242     my ($obj, $key) = @_;
 243
 244     my $sector = $self->_load_sector( $obj->_base_offset )
 245         or return;
 246
 247     if ( $sector->staleness != $obj->_staleness ) {
 248         return;
 249     }
 250
 251     return $sector->delete_key({
 252         key_md5    => $self->_apply_digest( $key ),
 253         allow_head => 0,
 254     });
 255 }
 256
 257 sub write_value {
 258     my $self = shift;
 259     my ($obj, $key, $value) = @_;
 260
 261     my $r = Scalar::Util::reftype( $value ) || '';
 262     {
 263         last if $r eq '';
 264         last if $r eq 'HASH';
 265         last if $r eq 'ARRAY';
 266
 267         DBM::Deep->_throw_error(
 268             "Storage of references of type '$r' is not supported."
 269         );
 270     }
 271
 272     # This will be a Reference sector
 273     my $sector = $self->_load_sector( $obj->_base_offset )
 274         or DBM::Deep->_throw_error( "Cannot write to a deleted spot in DBM::Deep." );
 275
 276     if ( $sector->staleness != $obj->_staleness ) {
 277         DBM::Deep->_throw_error( "Cannot write to a deleted spot in DBM::Deep.n" );
 278     }
 279
 280     my ($class, $type);
 281     if ( !defined $value ) {
 282         $class = 'DBM::Deep::Engine::Sector::Null';
 283     }
 284     elsif ( $r eq 'ARRAY' || $r eq 'HASH' ) {
 285
 286         #
 287         # Checking if $value is tied and getting it's underlying variable
 288         #
 289         my $tmpvar;
 290         if ( $r eq 'ARRAY' ) {
 291             $tmpvar = tied @$value;
 292         } elsif ( $r eq 'HASH' ) {
 293             $tmpvar = tied %$value;
 294         }
 295
 296         #
 297         # Checking if underlying variable is a DBM::Deep instance
 298         #
 299         my $is_ref_dbm_deep = eval { local $SIG{'__DIE__'}; $tmpvar->isa( 'DBM::Deep' ); };
 300         if ( $is_ref_dbm_deep ) {
 301             #
 302             # Checking if storage of destination and source variables is the same
 303             #
 304             if ( $tmpvar->_engine->storage == $self->storage ) {
 305                 #
 306                 # If yes - loading source sector and getting its data reference address
 307                 #
 308                 my $value_sector = $self->_load_sector( $tmpvar->_base_offset );
 309                 my $data_addr = Scalar::Util::refaddr( $value_sector->data );
 310                 my $origin_addr;
 311                 #
 312                 # Getting destination reference address for data by key
 313                 #
 314                 if ( Scalar::Util::reftype( $sector->data ) eq 'ARRAY' ) {
 315                     $origin_addr = Scalar::Util::refaddr( ${$sector->data}[$key] );
 316                 } elsif ( Scalar::Util::reftype( $sector->data ) eq 'HASH' ) {
 317                     $origin_addr = Scalar::Util::refaddr( ${$sector->data}{$key} );
 318                 }
 319
 320                 #
 321                 # Do nothing if reference addresses of source and destination data are same
 322                 #
 323                 if (defined $data_addr && defined $origin_addr) {
 324                     return 1 if ($data_addr == $origin_addr);
 325                 }
 326             } else {
 327                 DBM::Deep->_throw_error( "Cannot store values across DBM::Deep files. Please use export() instead." );
 328             }
 329         }
 330
 331         my $is_dbm_deep = eval { local $SIG{'__DIE__'}; $value->isa( 'DBM::Deep' ); };
 332         if ( $is_dbm_deep ) {
 333             if ( $value->_engine->storage == $self->storage ) {
 334                 my $value_sector = $self->_load_sector( $value->_base_offset );
 335                 $sector->write_data({
 336                     key     => $key,
 337                     key_md5 => $self->_apply_digest( $key ),
 338                     value   => $value_sector,
 339                 });
 340                 $value_sector->increment_refcount;
 341                 return 1;
 342             }
 343
 344             DBM::Deep->_throw_error( "Cannot store values across DBM::Deep files. Please use export() instead." );
 345         }
 346         if ( $r eq 'ARRAY' && tied(@$value) ) {
 347             DBM::Deep->_throw_error( "Cannot store something that is tied." );
 348         }
 349         if ( $r eq 'HASH' && tied(%$value) ) {
 350             DBM::Deep->_throw_error( "Cannot store something that is tied." );
 351         }
 352         $class = 'DBM::Deep::Engine::Sector::Reference';
 353         $type = substr( $r, 0, 1 );
 354     }
 355     else {
 356         if ( tied($value) ) {
 357             DBM::Deep->_throw_error( "Cannot store something that is tied." );
 358         }
 359         $class = 'DBM::Deep::Engine::Sector::Scalar';
 360     }
 361
 362     # Create this after loading the reference sector in case something bad happens.
 363     # This way, we won't allocate value sector(s) needlessly.
 364     my $value_sector = $class->new({
 365         engine => $self,
 366         data   => $value,
 367         type   => $type,
 368     });
 369
 370     $sector->write_data({
 371         key     => $key,
 372         key_md5 => $self->_apply_digest( $key ),
 373         value   => $value_sector,
 374     });
 375
 376     # This code is to make sure we write all the values in the $value to the disk
 377     # and to make sure all changes to $value after the assignment are reflected
 378     # on disk. This may be counter-intuitive at first, but it is correct dwimmery.
 379     #   NOTE - simply tying $value won't perform a STORE on each value. Hence, the
 380     # copy to a temp value.
 381     if ( $r eq 'ARRAY' ) {
 382         my @temp = @$value;
 383         tie @$value, 'DBM::Deep', {
 384             base_offset => $value_sector->offset,
 385             staleness   => $value_sector->staleness,
 386             storage     => $self->storage,
 387             engine      => $self,
 388         };
 389         @$value = @temp;
 390         bless $value, 'DBM::Deep::Array' unless Scalar::Util::blessed( $value );
 391     }
 392     elsif ( $r eq 'HASH' ) {
 393         my %temp = %$value;
 394         tie %$value, 'DBM::Deep', {
 395             base_offset => $value_sector->offset,
 396             staleness   => $value_sector->staleness,
 397             storage     => $self->storage,
 398             engine      => $self,
 399         };
 400
 401         %$value = %temp;
 402         bless $value, 'DBM::Deep::Hash' unless Scalar::Util::blessed( $value );
 403     }
 404
 405     return 1;
 406 }
 407
 408 # XXX Add staleness here
 409 sub get_next_key {
 410     my $self = shift;
 411     my ($obj, $prev_key) = @_;
 412
 413     # XXX Need to add logic about resetting the iterator if any key in the reference has changed
 414     unless ( $prev_key ) {
 415         $obj->{iterator} = DBM::Deep::Iterator->new({
 416             base_offset => $obj->_base_offset,
 417             engine      => $self,
 418         });
 419     }
 420
 421     return $obj->{iterator}->get_next_key( $obj );
 422 }
 423
 424 ################################################################################
 425
 426 sub setup_fh {
 427     my $self = shift;
 428     my ($obj) = @_;
 429
 430     # We're opening the file.
 431     unless ( $obj->_base_offset ) {
 432         my $bytes_read = $self->_read_file_header;
 433
 434         # Creating a new file
 435         unless ( $bytes_read ) {
 436             $self->_write_file_header;
 437
 438             # 1) Create Array/Hash entry
 439             my $initial_reference = DBM::Deep::Engine::Sector::Reference->new({
 440                 engine => $self,
 441                 type   => $obj->_type,
 442             });
 443             $obj->{base_offset} = $initial_reference->offset;
 444             $obj->{staleness} = $initial_reference->staleness;
 445
 446             $self->storage->flush;
 447         }
 448         # Reading from an existing file
 449         else {
 450             $obj->{base_offset} = $bytes_read;
 451             my $initial_reference = DBM::Deep::Engine::Sector::Reference->new({
 452                 engine => $self,
 453                 offset => $obj->_base_offset,
 454             });
 455             unless ( $initial_reference ) {
 456                 DBM::Deep->_throw_error("Corrupted file, no master index record");
 457             }
 458
 459             unless ($obj->_type eq $initial_reference->type) {
 460                 DBM::Deep->_throw_error("File type mismatch");
 461             }
 462
 463             $obj->{staleness} = $initial_reference->staleness;
 464         }
 465     }
 466
 467     return 1;
 468 }
 469
 470 sub begin_work {
 471     my $self = shift;
 472     my ($obj) = @_;
 473
 474     if ( $self->trans_id ) {
 475         DBM::Deep->_throw_error( "Cannot begin_work within an active transaction" );
 476     }
 477
 478     my @slots = $self->read_txn_slots;
 479     my $found;
 480     for my $i ( 0 .. $#slots ) {
 481         next if $slots[$i];
 482
 483         $slots[$i] = 1;
 484         $self->set_trans_id( $i + 1 );
 485         $found = 1;
 486         last;
 487     }
 488     unless ( $found ) {
 489         DBM::Deep->_throw_error( "Cannot allocate transaction ID" );
 490     }
 491     $self->write_txn_slots( @slots );
 492
 493     if ( !$self->trans_id ) {
 494         DBM::Deep->_throw_error( "Cannot begin_work - no available transactions" );
 495     }
 496
 497     return;
 498 }
 499
 500 sub rollback {
 501     my $self = shift;
 502     my ($obj) = @_;
 503
 504     if ( !$self->trans_id ) {
 505         DBM::Deep->_throw_error( "Cannot rollback without an active transaction" );
 506     }
 507
 508     # Each entry is the file location for a bucket that has a modification for
 509     # this transaction. The entries need to be expunged.
 510     foreach my $entry (@{ $self->get_entries } ) {
 511         # Remove the entry here
 512         my $read_loc = $entry
 513           + $self->hash_size
 514           + $self->byte_size
 515           + $self->byte_size
 516           + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
 517
 518         my $data_loc = $self->storage->read_at( $read_loc, $self->byte_size );
 519         $data_loc = unpack( $StP{$self->byte_size}, $data_loc );
 520         $self->storage->print_at( $read_loc, pack( $StP{$self->byte_size}, 0 ) );
 521
 522         if ( $data_loc > 1 ) {
 523             $self->_load_sector( $data_loc )->free;
 524         }
 525     }
 526
 527     $self->clear_entries;
 528
 529     my @slots = $self->read_txn_slots;
 530     $slots[$self->trans_id-1] = 0;
 531     $self->write_txn_slots( @slots );
 532     $self->inc_txn_staleness_counter( $self->trans_id );
 533     $self->set_trans_id( 0 );
 534
 535     return 1;
 536 }
 537
 538 sub commit {
 539     my $self = shift;
 540     my ($obj) = @_;
 541
 542     if ( !$self->trans_id ) {
 543         DBM::Deep->_throw_error( "Cannot commit without an active transaction" );
 544     }
 545
 546     foreach my $entry (@{ $self->get_entries } ) {
 547         # Overwrite the entry in head with the entry in trans_id
 548         my $base = $entry
 549           + $self->hash_size
 550           + $self->byte_size;
 551
 552         my $head_loc = $self->storage->read_at( $base, $self->byte_size );
 553         $head_loc = unpack( $StP{$self->byte_size}, $head_loc );
 554
 555         my $spot = $base + $self->byte_size + ($self->trans_id - 1) * ( $self->byte_size + $STALE_SIZE );
 556         my $trans_loc = $self->storage->read_at(
 557             $spot, $self->byte_size,
 558         );
 559
 560         $self->storage->print_at( $base, $trans_loc );
 561         $self->storage->print_at(
 562             $spot,
 563             pack( $StP{$self->byte_size} . ' ' . $StP{$STALE_SIZE}, (0) x 2 ),
 564         );
 565
 566         if ( $head_loc > 1 ) {
 567             $self->_load_sector( $head_loc )->free;
 568         }
 569     }
 570
 571     $self->clear_entries;
 572
 573     my @slots = $self->read_txn_slots;
 574     $slots[$self->trans_id-1] = 0;
 575     $self->write_txn_slots( @slots );
 576     $self->inc_txn_staleness_counter( $self->trans_id );
 577     $self->set_trans_id( 0 );
 578
 579     return 1;
 580 }
 581
 582 sub read_txn_slots {
 583     my $self = shift;
 584     my $bl = $self->txn_bitfield_len;
 585     my $num_bits = $bl * 8;
 586     return split '', unpack( 'b'.$num_bits,
 587         $self->storage->read_at(
 588             $self->trans_loc, $bl,
 589         )
 590     );
 591 }
 592
 593 sub write_txn_slots {
 594     my $self = shift;
 595     my $num_bits = $self->txn_bitfield_len * 8;
 596     $self->storage->print_at( $self->trans_loc,
 597         pack( 'b'.$num_bits, join('', @_) ),
 598     );
 599 }
 600
 601 sub get_running_txn_ids {
 602     my $self = shift;
 603     my @transactions = $self->read_txn_slots;
 604     my @trans_ids = map { $_+1} grep { $transactions[$_] } 0 .. $#transactions;
 605 }
 606
 607 sub get_txn_staleness_counter {
 608     my $self = shift;
 609     my ($trans_id) = @_;
 610
 611     # Hardcode staleness of 0 for the HEAD
 612     return 0 unless $trans_id;
 613
 614     return unpack( $StP{$STALE_SIZE},
 615         $self->storage->read_at(
 616             $self->trans_loc + $self->txn_bitfield_len + $STALE_SIZE * ($trans_id - 1),
 617             $STALE_SIZE,
 618         )
 619     );
 620 }
 621
 622 sub inc_txn_staleness_counter {
 623     my $self = shift;
 624     my ($trans_id) = @_;
 625
 626     # Hardcode staleness of 0 for the HEAD
 627     return 0 unless $trans_id;
 628
 629     $self->storage->print_at(
 630         $self->trans_loc + $self->txn_bitfield_len + $STALE_SIZE * ($trans_id - 1),
 631         pack( $StP{$STALE_SIZE}, $self->get_txn_staleness_counter( $trans_id ) + 1 ),
 632     );
 633 }
 634
 635 sub get_entries {
 636     my $self = shift;
 637     return [ keys %{ $self->{entries}{$self->trans_id} ||= {} } ];
 638 }
 639
 640 sub add_entry {
 641     my $self = shift;
 642     my ($trans_id, $loc) = @_;
 643
 644     $self->{entries}{$trans_id} ||= {};
 645     $self->{entries}{$trans_id}{$loc} = undef;
 646 }
 647
 648 # If the buckets are being relocated because of a reindexing, the entries
 649 # mechanism needs to be made aware of it.
 650 sub reindex_entry {
 651     my $self = shift;
 652     my ($old_loc, $new_loc) = @_;
 653
 654     TRANS:
 655     while ( my ($trans_id, $locs) = each %{ $self->{entries} } ) {
 656         foreach my $orig_loc ( keys %{ $locs } ) {
 657             if ( $orig_loc == $old_loc ) {
 658                 delete $locs->{orig_loc};
 659                 $locs->{$new_loc} = undef;
 660                 next TRANS;
 661             }
 662         }
 663     }
 664 }
 665
 666 sub clear_entries {
 667     my $self = shift;
 668     delete $self->{entries}{$self->trans_id};
 669 }
 670
 671 ################################################################################
 672
 673 {
 674     my $header_fixed = length( SIG_FILE ) + 1 + 4 + 4;
 675     my $this_file_version = 3;
 676
 677     sub _write_file_header {
 678         my $self = shift;
 679
 680         my $nt = $self->num_txns;
 681         my $bl = $self->txn_bitfield_len;
 682
 683         my $header_var = 1 + 1 + 1 + 1 + $bl + $STALE_SIZE * ($nt - 1) + 3 * $self->byte_size;
 684
 685         my $loc = $self->storage->request_space( $header_fixed + $header_var );
 686
 687         $self->storage->print_at( $loc,
 688             SIG_FILE,
 689             SIG_HEADER,
 690             pack('N', $this_file_version), # At this point, we're at 9 bytes
 691             pack('N', $header_var),        # header size
 692             # --- Above is $header_fixed. Below is $header_var
 693             pack('C', $self->byte_size),
 694
 695             # These shenanigans are to allow a 256 within a C
 696             pack('C', $self->max_buckets - 1),
 697             pack('C', $self->data_sector_size - 1),
 698
 699             pack('C', $nt),
 700             pack('C' . $bl, 0 ),                           # Transaction activeness bitfield
 701             pack($StP{$STALE_SIZE}.($nt-1), 0 x ($nt-1) ), # Transaction staleness counters
 702             pack($StP{$self->byte_size}, 0), # Start of free chain (blist size)
 703             pack($StP{$self->byte_size}, 0), # Start of free chain (data size)
 704             pack($StP{$self->byte_size}, 0), # Start of free chain (index size)
 705         );
 706
 707         #XXX Set these less fragilely
 708         $self->set_trans_loc( $header_fixed + 4 );
 709         $self->set_chains_loc( $header_fixed + 4 + $bl + $STALE_SIZE * ($nt-1) );
 710
 711         return;
 712     }
 713
 714     sub _read_file_header {
 715         my $self = shift;
 716
 717         my $buffer = $self->storage->read_at( 0, $header_fixed );
 718         return unless length($buffer);
 719
 720         my ($file_signature, $sig_header, $file_version, $size) = unpack(
 721             'A4 A N N', $buffer
 722         );
 723
 724         unless ( $file_signature eq SIG_FILE ) {
 725             $self->storage->close;
 726             DBM::Deep->_throw_error( "Signature not found -- file is not a Deep DB" );
 727         }
 728
 729         unless ( $sig_header eq SIG_HEADER ) {
 730             $self->storage->close;
 731             DBM::Deep->_throw_error( "Pre-1.00 file version found" );
 732         }
 733
 734         unless ( $file_version == $this_file_version ) {
 735             $self->storage->close;
 736             DBM::Deep->_throw_error(
 737                 "Wrong file version found - " .  $file_version .
 738                 " - expected " . $this_file_version
 739             );
 740         }
 741
 742         my $buffer2 = $self->storage->read_at( undef, $size );
 743         my @values = unpack( 'C C C C', $buffer2 );
 744
 745         if ( @values != 4 || grep { !defined } @values ) {
 746             $self->storage->close;
 747             DBM::Deep->_throw_error("Corrupted file - bad header");
 748         }
 749
 750         #XXX Add warnings if values weren't set right
 751         @{$self}{qw(byte_size max_buckets data_sector_size num_txns)} = @values;
 752
 753         # These shenangians are to allow a 256 within a C
 754         $self->{max_buckets} += 1;
 755         $self->{data_sector_size} += 1;
 756
 757         my $bl = $self->txn_bitfield_len;
 758
 759         my $header_var = scalar(@values) + $bl + $STALE_SIZE * ($self->num_txns - 1) + 3 * $self->byte_size;
 760         unless ( $size == $header_var ) {
 761             $self->storage->close;
 762             DBM::Deep->_throw_error( "Unexpected size found ($size <-> $header_var)." );
 763         }
 764
 765         $self->set_trans_loc( $header_fixed + scalar(@values) );
 766         $self->set_chains_loc( $header_fixed + scalar(@values) + $bl + $STALE_SIZE * ($self->num_txns - 1) );
 767
 768         return length($buffer) + length($buffer2);
 769     }
 770 }
 771
 772 sub _load_sector {
 773     my $self = shift;
 774     my ($offset) = @_;
 775
 776     # Add a catch for offset of 0 or 1
 777     return if !$offset || $offset <= 1;
 778
 779     my $type = $self->storage->read_at( $offset, 1 );
 780     return if $type eq chr(0);
 781
 782     if ( $type eq $self->SIG_ARRAY || $type eq $self->SIG_HASH ) {
 783         return DBM::Deep::Engine::Sector::Reference->new({
 784             engine => $self,
 785             type   => $type,
 786             offset => $offset,
 787         });
 788     }
 789     # XXX Don't we need key_md5 here?
 790     elsif ( $type eq $self->SIG_BLIST ) {
 791         return DBM::Deep::Engine::Sector::BucketList->new({
 792             engine => $self,
 793             type   => $type,
 794             offset => $offset,
 795         });
 796     }
 797     elsif ( $type eq $self->SIG_INDEX ) {
 798         return DBM::Deep::Engine::Sector::Index->new({
 799             engine => $self,
 800             type   => $type,
 801             offset => $offset,
 802         });
 803     }
 804     elsif ( $type eq $self->SIG_NULL ) {
 805         return DBM::Deep::Engine::Sector::Null->new({
 806             engine => $self,
 807             type   => $type,
 808             offset => $offset,
 809         });
 810     }
 811     elsif ( $type eq $self->SIG_DATA ) {
 812         return DBM::Deep::Engine::Sector::Scalar->new({
 813             engine => $self,
 814             type   => $type,
 815             offset => $offset,
 816         });
 817     }
 818     # This was deleted from under us, so just return and let the caller figure it out.
 819     elsif ( $type eq $self->SIG_FREE ) {
 820         return;
 821     }
 822
 823     DBM::Deep->_throw_error( "'$offset': Don't know what to do with type '$type'" );
 824 }
 825
 826 sub _apply_digest {
 827     my $self = shift;
 828     return $self->{digest}->(@_);
 829 }
 830
 831 sub _add_free_blist_sector { shift->_add_free_sector( 0, @_ ) }
 832 sub _add_free_data_sector { shift->_add_free_sector( 1, @_ ) }
 833 sub _add_free_index_sector { shift->_add_free_sector( 2, @_ ) }
 834
 835 sub _add_free_sector {
 836     my $self = shift;
 837     my ($multiple, $offset, $size) = @_;
 838
 839     my $chains_offset = $multiple * $self->byte_size;
 840
 841     my $storage = $self->storage;
 842
 843     # Increment staleness.
 844     # XXX Can this increment+modulo be done by "&= 0x1" ?
 845     my $staleness = unpack( $StP{$STALE_SIZE}, $storage->read_at( $offset + SIG_SIZE, $STALE_SIZE ) );
 846     $staleness = ($staleness + 1 ) % ( 2 ** ( 8 * $STALE_SIZE ) );
 847     $storage->print_at( $offset + SIG_SIZE, pack( $StP{$STALE_SIZE}, $staleness ) );
 848
 849     my $old_head = $storage->read_at( $self->chains_loc + $chains_offset, $self->byte_size );
 850
 851     $storage->print_at( $self->chains_loc + $chains_offset,
 852         pack( $StP{$self->byte_size}, $offset ),
 853     );
 854
 855     # Record the old head in the new sector after the signature and staleness counter
 856     $storage->print_at( $offset + SIG_SIZE + $STALE_SIZE, $old_head );
 857 }
 858
 859 sub _request_blist_sector { shift->_request_sector( 0, @_ ) }
 860 sub _request_data_sector { shift->_request_sector( 1, @_ ) }
 861 sub _request_index_sector { shift->_request_sector( 2, @_ ) }
 862
 863 sub _request_sector {
 864     my $self = shift;
 865     my ($multiple, $size) = @_;
 866
 867     my $chains_offset = $multiple * $self->byte_size;
 868
 869     my $old_head = $self->storage->read_at( $self->chains_loc + $chains_offset, $self->byte_size );
 870     my $loc = unpack( $StP{$self->byte_size}, $old_head );
 871
 872     # We don't have any free sectors of the right size, so allocate a new one.
 873     unless ( $loc ) {
 874         my $offset = $self->storage->request_space( $size );
 875
 876         # Zero out the new sector. This also guarantees correct increases
 877         # in the filesize.
 878         $self->storage->print_at( $offset, chr(0) x $size );
 879
 880         return $offset;
 881     }
 882
 883     # Read the new head after the signature and the staleness counter
 884     my $new_head = $self->storage->read_at( $loc + SIG_SIZE + $STALE_SIZE, $self->byte_size );
 885     $self->storage->print_at( $self->chains_loc + $chains_offset, $new_head );
 886     $self->storage->print_at(
 887         $loc + SIG_SIZE + $STALE_SIZE,
 888         pack( $StP{$self->byte_size}, 0 ),
 889     );
 890
 891     return $loc;
 892 }
 893
 894 ################################################################################
 895
 896 sub storage     { $_[0]{storage} }
 897 sub byte_size   { $_[0]{byte_size} }
 898 sub hash_size   { $_[0]{hash_size} }
 899 sub hash_chars  { $_[0]{hash_chars} }
 900 sub num_txns    { $_[0]{num_txns} }
 901 sub max_buckets { $_[0]{max_buckets} }
 902 sub blank_md5   { chr(0) x $_[0]->hash_size }
 903 sub data_sector_size { $_[0]{data_sector_size} }
 904
 905 # This is a calculated value
 906 sub txn_bitfield_len {
 907     my $self = shift;
 908     unless ( exists $self->{txn_bitfield_len} ) {
 909         my $temp = ($self->num_txns) / 8;
 910         if ( $temp > int( $temp ) ) {
 911             $temp = int( $temp ) + 1;
 912         }
 913         $self->{txn_bitfield_len} = $temp;
 914     }
 915     return $self->{txn_bitfield_len};
 916 }
 917
 918 sub trans_id     { $_[0]{trans_id} }
 919 sub set_trans_id { $_[0]{trans_id} = $_[1] }
 920
 921 sub trans_loc     { $_[0]{trans_loc} }
 922 sub set_trans_loc { $_[0]{trans_loc} = $_[1] }
 923
 924 sub chains_loc     { $_[0]{chains_loc} }
 925 sub set_chains_loc { $_[0]{chains_loc} = $_[1] }
 926
 927 sub cache       { $_[0]{cache} ||= {} }
 928 sub clear_cache { %{$_[0]->cache} = () }
 929
 930 sub _dump_file {
 931     my $self = shift;
 932
 933     # Read the header
 934     my $spot = $self->_read_file_header();
 935
 936     my %types = (
 937         0 => 'B',
 938         1 => 'D',
 939         2 => 'I',
 940     );
 941
 942     my %sizes = (
 943         'D' => $self->data_sector_size,
 944         'B' => DBM::Deep::Engine::Sector::BucketList->new({engine=>$self,offset=>1})->size,
 945         'I' => DBM::Deep::Engine::Sector::Index->new({engine=>$self,offset=>1})->size,
 946     );
 947
 948     my $return = "";
 949
 950     # Header values
 951     $return .= "NumTxns: " . $self->num_txns . $/;
 952
 953     # Read the free sector chains
 954     my %sectors;
 955     foreach my $multiple ( 0 .. 2 ) {
 956         $return .= "Chains($types{$multiple}):";
 957         my $old_loc = $self->chains_loc + $multiple * $self->byte_size;
 958         while ( 1 ) {
 959             my $loc = unpack(
 960                 $StP{$self->byte_size},
 961                 $self->storage->read_at( $old_loc, $self->byte_size ),
 962             );
 963
 964             # We're now out of free sectors of this kind.
 965             unless ( $loc ) {
 966                 last;
 967             }
 968
 969             $sectors{ $types{$multiple} }{ $loc } = undef;
 970             $old_loc = $loc + SIG_SIZE + $STALE_SIZE;
 971             $return .= " $loc";
 972         }
 973         $return .= $/;
 974     }
 975
 976     SECTOR:
 977     while ( $spot < $self->storage->{end} ) {
 978         # Read each sector in order.
 979         my $sector = $self->_load_sector( $spot );
 980         if ( !$sector ) {
 981             # Find it in the free-sectors that were found already
 982             foreach my $type ( keys %sectors ) {
 983                 if ( exists $sectors{$type}{$spot} ) {
 984                     my $size = $sizes{$type};
 985                     $return .= sprintf "%08d: %s %04d\n", $spot, 'F' . $type, $size;
 986                     $spot += $size;
 987                     next SECTOR;
 988                 }
 989             }
 990
 991             die "********\n$return\nDidn't find free sector for $spot in chains\n********\n";
 992         }
 993         else {
 994             $return .= sprintf "%08d: %s  %04d", $spot, $sector->type, $sector->size;
 995             if ( $sector->type eq 'D' ) {
 996                 $return .= ' ' . $sector->data;
 997             }
 998             elsif ( $sector->type eq 'A' || $sector->type eq 'H' ) {
 999                 $return .= ' REF: ' . $sector->get_refcount;
1000             }
1001             elsif ( $sector->type eq 'B' ) {
1002                 foreach my $bucket ( $sector->chopped_up ) {
1003                     $return .= "\n    ";
1004                     $return .= sprintf "%08d", unpack($StP{$self->byte_size},
1005                         substr( $bucket->[-1], $self->hash_size, $self->byte_size),
1006                     );
1007                     my $l = unpack( $StP{$self->byte_size},
1008                         substr( $bucket->[-1],
1009                             $self->hash_size + $self->byte_size,
1010                             $self->byte_size,
1011                         ),
1012                     );
1013                     $return .= sprintf " %08d", $l;
1014                     foreach my $txn ( 0 .. $self->num_txns - 2 ) {
1015                         my $l = unpack( $StP{$self->byte_size},
1016                             substr( $bucket->[-1],
1017                                 $self->hash_size + 2 * $self->byte_size + $txn * ($self->byte_size + $STALE_SIZE),
1018                                 $self->byte_size,
1019                             ),
1020                         );
1021                         $return .= sprintf " %08d", $l;
1022                     }
1023                 }
1024             }
1025             $return .= $/;
1026
1027             $spot += $sector->size;
1028         }
1029     }
1030
1031     return $return;
1032 }
1033
1034 ################################################################################
1035
1036 package DBM::Deep::Iterator;
1037
1038 sub new {
1039     my $class = shift;
1040     my ($args) = @_;
1041
1042     my $self = bless {
1043         breadcrumbs => [],
1044         engine      => $args->{engine},
1045         base_offset => $args->{base_offset},
1046     }, $class;
1047
1048     Scalar::Util::weaken( $self->{engine} );
1049
1050     return $self;
1051 }
1052
1053 sub reset { $_[0]{breadcrumbs} = [] }
1054
1055 sub get_sector_iterator {
1056     my $self = shift;
1057     my ($loc) = @_;
1058
1059     my $sector = $self->{engine}->_load_sector( $loc )
1060         or return;
1061
1062     if ( $sector->isa( 'DBM::Deep::Engine::Sector::Index' ) ) {
1063         return DBM::Deep::Iterator::Index->new({
1064             iterator => $self,
1065             sector   => $sector,
1066         });
1067     }
1068     elsif ( $sector->isa( 'DBM::Deep::Engine::Sector::BucketList' ) ) {
1069         return DBM::Deep::Iterator::BucketList->new({
1070             iterator => $self,
1071             sector   => $sector,
1072         });
1073     }
1074
1075     DBM::Deep->_throw_error( "get_sector_iterator(): Why did $loc make a $sector?" );
1076 }
1077
1078 sub get_next_key {
1079     my $self = shift;
1080     my ($obj) = @_;
1081
1082     my $crumbs = $self->{breadcrumbs};
1083     my $e = $self->{engine};
1084
1085     unless ( @$crumbs ) {
1086         # This will be a Reference sector
1087         my $sector = $e->_load_sector( $self->{base_offset} )
1088             # If no sector is found, thist must have been deleted from under us.
1089             or return;
1090
1091         if ( $sector->staleness != $obj->_staleness ) {
1092             return;
1093         }
1094
1095         my $loc = $sector->get_blist_loc
1096             or return;
1097
1098         push @$crumbs, $self->get_sector_iterator( $loc );
1099     }
1100
1101     FIND_NEXT_KEY: {
1102         # We're at the end.
1103         unless ( @$crumbs ) {
1104             $self->reset;
1105             return;
1106         }
1107
1108         my $iterator = $crumbs->[-1];
1109
1110         # This level is done.
1111         if ( $iterator->at_end ) {
1112             pop @$crumbs;
1113             redo FIND_NEXT_KEY;
1114         }
1115
1116         if ( $iterator->isa( 'DBM::Deep::Iterator::Index' ) ) {
1117             # If we don't have any more, it will be caught at the
1118             # prior check.
1119             if ( my $next = $iterator->get_next_iterator ) {
1120                 push @$crumbs, $next;
1121             }
1122             redo FIND_NEXT_KEY;
1123         }
1124
1125         unless ( $iterator->isa( 'DBM::Deep::Iterator::BucketList' ) ) {
1126             DBM::Deep->_throw_error(
1127                 "Should have a bucketlist iterator here - instead have $iterator"
1128             );
1129         }
1130
1131         # At this point, we have a BucketList iterator
1132         my $key = $iterator->get_next_key;
1133         if ( defined $key ) {
1134             return $key;
1135         }
1136         #XXX else { $iterator->set_to_end() } ?
1137
1138         # We hit the end of the bucketlist iterator, so redo
1139         redo FIND_NEXT_KEY;
1140     }
1141
1142     DBM::Deep->_throw_error( "get_next_key(): How did we get here?" );
1143 }
1144
1145 package DBM::Deep::Iterator::Index;
1146
1147 sub new {
1148     my $self = bless $_[1] => $_[0];
1149     $self->{curr_index} = 0;
1150     return $self;
1151 }
1152
1153 sub at_end {
1154     my $self = shift;
1155     return $self->{curr_index} >= $self->{iterator}{engine}->hash_chars;
1156 }
1157
1158 sub get_next_iterator {
1159     my $self = shift;
1160
1161     my $loc;
1162     while ( !$loc ) {
1163         return if $self->at_end;
1164         $loc = $self->{sector}->get_entry( $self->{curr_index}++ );
1165     }
1166
1167     return $self->{iterator}->get_sector_iterator( $loc );
1168 }
1169
1170 package DBM::Deep::Iterator::BucketList;
1171
1172 sub new {
1173     my $self = bless $_[1] => $_[0];
1174     $self->{curr_index} = 0;
1175     return $self;
1176 }
1177
1178 sub at_end {
1179     my $self = shift;
1180     return $self->{curr_index} >= $self->{iterator}{engine}->max_buckets;
1181 }
1182
1183 sub get_next_key {
1184     my $self = shift;
1185
1186     return if $self->at_end;
1187
1188     my $idx = $self->{curr_index}++;
1189
1190     my $data_loc = $self->{sector}->get_data_location_for({
1191         allow_head => 1,
1192         idx        => $idx,
1193     }) or return;
1194
1195     #XXX Do we want to add corruption checks here?
1196     return $self->{sector}->get_key_for( $idx )->data;
1197 }
1198
1199 package DBM::Deep::Engine::Sector;
1200
1201 sub new {
1202     my $self = bless $_[1], $_[0];
1203     Scalar::Util::weaken( $self->{engine} );
1204     $self->_init;
1205     return $self;
1206 }
1207
1208 #sub _init {}
1209 #sub clone { DBM::Deep->_throw_error( "Must be implemented in the child class" ); }
1210
1211 sub engine { $_[0]{engine} }
1212 sub offset { $_[0]{offset} }
1213 sub type   { $_[0]{type} }
1214
1215 sub base_size {
1216    my $self = shift;
1217    return $self->engine->SIG_SIZE + $STALE_SIZE;
1218 }
1219
1220 sub free {
1221     my $self = shift;
1222
1223     my $e = $self->engine;
1224
1225     $e->storage->print_at( $self->offset, $e->SIG_FREE );
1226     # Skip staleness counter
1227     $e->storage->print_at( $self->offset + $self->base_size,
1228         chr(0) x ($self->size - $self->base_size),
1229     );
1230
1231     my $free_meth = $self->free_meth;
1232     $e->$free_meth( $self->offset, $self->size );
1233
1234     return;
1235 }
1236
1237 package DBM::Deep::Engine::Sector::Data;
1238
1239 our @ISA = qw( DBM::Deep::Engine::Sector );
1240
1241 # This is in bytes
1242 sub size { $_[0]{engine}->data_sector_size }
1243 sub free_meth { return '_add_free_data_sector' }
1244
1245 sub clone {
1246     my $self = shift;
1247     return ref($self)->new({
1248         engine => $self->engine,
1249         type   => $self->type,
1250         data   => $self->data,
1251     });
1252 }
1253
1254 package DBM::Deep::Engine::Sector::Scalar;
1255
1256 our @ISA = qw( DBM::Deep::Engine::Sector::Data );
1257
1258 sub free {
1259     my $self = shift;
1260
1261     my $chain_loc = $self->chain_loc;
1262
1263     $self->SUPER::free();
1264
1265     if ( $chain_loc ) {
1266         $self->engine->_load_sector( $chain_loc )->free;
1267     }
1268
1269     return;
1270 }
1271
1272 sub type { $_[0]{engine}->SIG_DATA }
1273 sub _init {
1274     my $self = shift;
1275
1276     my $engine = $self->engine;
1277
1278     unless ( $self->offset ) {
1279         my $data_section = $self->size - $self->base_size - $engine->byte_size - 1;
1280
1281         $self->{offset} = $engine->_request_data_sector( $self->size );
1282
1283         my $data = delete $self->{data};
1284         my $dlen = length $data;
1285         my $continue = 1;
1286         my $curr_offset = $self->offset;
1287         while ( $continue ) {
1288
1289             my $next_offset = 0;
1290
1291             my ($leftover, $this_len, $chunk);
1292             if ( $dlen > $data_section ) {
1293                 $leftover = 0;
1294                 $this_len = $data_section;
1295                 $chunk = substr( $data, 0, $this_len );
1296
1297                 $dlen -= $data_section;
1298                 $next_offset = $engine->_request_data_sector( $self->size );
1299                 $data = substr( $data, $this_len );
1300             }
1301             else {
1302                 $leftover = $data_section - $dlen;
1303                 $this_len = $dlen;
1304                 $chunk = $data;
1305
1306                 $continue = 0;
1307             }
1308
1309             $engine->storage->print_at( $curr_offset, $self->type ); # Sector type
1310             # Skip staleness
1311             $engine->storage->print_at( $curr_offset + $self->base_size,
1312                 pack( $StP{$engine->byte_size}, $next_offset ),  # Chain loc
1313                 pack( $StP{1}, $this_len ),                      # Data length
1314                 $chunk,                                          # Data to be stored in this sector
1315                 chr(0) x $leftover,                              # Zero-fill the rest
1316             );
1317
1318             $curr_offset = $next_offset;
1319         }
1320
1321         return;
1322     }
1323 }
1324
1325 sub data_length {
1326     my $self = shift;
1327
1328     my $buffer = $self->engine->storage->read_at(
1329         $self->offset + $self->base_size + $self->engine->byte_size, 1
1330     );
1331
1332     return unpack( $StP{1}, $buffer );
1333 }
1334
1335 sub chain_loc {
1336     my $self = shift;
1337     return unpack(
1338         $StP{$self->engine->byte_size},
1339         $self->engine->storage->read_at(
1340             $self->offset + $self->base_size,
1341             $self->engine->byte_size,
1342         ),
1343     );
1344 }
1345
1346 sub data {
1347     my $self = shift;
1348
1349     my $data;
1350     while ( 1 ) {
1351         my $chain_loc = $self->chain_loc;
1352
1353         $data .= $self->engine->storage->read_at(
1354             $self->offset + $self->base_size + $self->engine->byte_size + 1, $self->data_length,
1355         );
1356
1357         last unless $chain_loc;
1358
1359         $self = $self->engine->_load_sector( $chain_loc );
1360     }
1361
1362     return $data;
1363 }
1364
1365 package DBM::Deep::Engine::Sector::Null;
1366
1367 our @ISA = qw( DBM::Deep::Engine::Sector::Data );
1368
1369 sub type { $_[0]{engine}->SIG_NULL }
1370 sub data_length { 0 }
1371 sub data { return }
1372
1373 sub _init {
1374     my $self = shift;
1375
1376     my $engine = $self->engine;
1377
1378     unless ( $self->offset ) {
1379         my $leftover = $self->size - $self->base_size - 1 * $engine->byte_size - 1;
1380
1381         $self->{offset} = $engine->_request_data_sector( $self->size );
1382         $engine->storage->print_at( $self->offset, $self->type ); # Sector type
1383         # Skip staleness counter
1384         $engine->storage->print_at( $self->offset + $self->base_size,
1385             pack( $StP{$engine->byte_size}, 0 ),  # Chain loc
1386             pack( $StP{1}, $self->data_length ),  # Data length
1387             chr(0) x $leftover,                   # Zero-fill the rest
1388         );
1389
1390         return;
1391     }
1392 }
1393
1394 package DBM::Deep::Engine::Sector::Reference;
1395
1396 our @ISA = qw( DBM::Deep::Engine::Sector::Data );
1397
1398 sub _init {
1399     my $self = shift;
1400
1401     my $e = $self->engine;
1402
1403     unless ( $self->offset ) {
1404         my $classname = Scalar::Util::blessed( delete $self->{data} );
1405         my $leftover = $self->size - $self->base_size - 3 * $e->byte_size;
1406
1407         my $class_offset = 0;
1408         if ( defined $classname ) {
1409             my $class_sector = DBM::Deep::Engine::Sector::Scalar->new({
1410                 engine => $e,
1411                 data   => $classname,
1412             });
1413             $class_offset = $class_sector->offset;
1414         }
1415
1416         $self->{offset} = $e->_request_data_sector( $self->size );
1417         $e->storage->print_at( $self->offset, $self->type ); # Sector type
1418         # Skip staleness counter
1419         $e->storage->print_at( $self->offset + $self->base_size,
1420             pack( $StP{$e->byte_size}, 0 ),             # Index/BList loc
1421             pack( $StP{$e->byte_size}, $class_offset ), # Classname loc
1422             pack( $StP{$e->byte_size}, 1 ),             # Initial refcount
1423             chr(0) x $leftover,                         # Zero-fill the rest
1424         );
1425     }
1426     else {
1427         $self->{type} = $e->storage->read_at( $self->offset, 1 );
1428     }
1429
1430     $self->{staleness} = unpack(
1431         $StP{$STALE_SIZE},
1432         $e->storage->read_at( $self->offset + $e->SIG_SIZE, $STALE_SIZE ),
1433     );
1434
1435     return;
1436 }
1437
1438 sub staleness { $_[0]{staleness} }
1439
1440 sub get_data_for {
1441     my $self = shift;
1442     my ($args) = @_;
1443
1444     # Assume that the head is not allowed unless otherwise specified.
1445     $args->{allow_head} = 0 unless exists $args->{allow_head};
1446
1447     # Assume we don't create a new blist location unless otherwise specified.
1448     $args->{create} = 0 unless exists $args->{create};
1449
1450     my $blist = $self->get_bucket_list({
1451         key_md5 => $args->{key_md5},
1452         key => $args->{key},
1453         create  => $args->{create},
1454     });
1455     return unless $blist && $blist->{found};
1456
1457     # At this point, $blist knows where the md5 is. What it -doesn't- know yet
1458     # is whether or not this transaction has this key. That's part of the next
1459     # function call.
1460     my $location = $blist->get_data_location_for({
1461         allow_head => $args->{allow_head},
1462     }) or return;
1463
1464     return $self->engine->_load_sector( $location );
1465 }
1466
1467 sub write_data {
1468     my $self = shift;
1469     my ($args) = @_;
1470
1471     my $blist = $self->get_bucket_list({
1472         key_md5 => $args->{key_md5},
1473         key => $args->{key},
1474         create  => 1,
1475     }) or DBM::Deep->_throw_error( "How did write_data fail (no blist)?!" );
1476
1477     # Handle any transactional bookkeeping.
1478     if ( $self->engine->trans_id ) {
1479         if ( ! $blist->has_md5 ) {
1480             $blist->mark_deleted({
1481                 trans_id => 0,
1482             });
1483         }
1484     }
1485     else {
1486         my @trans_ids = $self->engine->get_running_txn_ids;
1487         if ( $blist->has_md5 ) {
1488             if ( @trans_ids ) {
1489                 my $old_value = $blist->get_data_for;
1490                 foreach my $other_trans_id ( @trans_ids ) {
1491                     next if $blist->get_data_location_for({
1492                         trans_id   => $other_trans_id,
1493                         allow_head => 0,
1494                     });
1495                     $blist->write_md5({
1496                         trans_id => $other_trans_id,
1497                         key      => $args->{key},
1498                         key_md5  => $args->{key_md5},
1499                         value    => $old_value->clone,
1500                     });
1501                 }
1502             }
1503         }
1504         else {
1505             if ( @trans_ids ) {
1506                 foreach my $other_trans_id ( @trans_ids ) {
1507                     #XXX This doesn't seem to possible to ever happen . . .
1508                     next if $blist->get_data_location_for({ trans_id => $other_trans_id, allow_head => 0 });
1509                     $blist->mark_deleted({
1510                         trans_id => $other_trans_id,
1511                     });
1512                 }
1513             }
1514         }
1515     }
1516
1517     #XXX Is this safe to do transactionally?
1518     # Free the place we're about to write to.
1519     if ( $blist->get_data_location_for({ allow_head => 0 }) ) {
1520         $blist->get_data_for({ allow_head => 0 })->free;
1521     }
1522
1523     $blist->write_md5({
1524         key      => $args->{key},
1525         key_md5  => $args->{key_md5},
1526         value    => $args->{value},
1527     });
1528 }
1529
1530 sub delete_key {
1531     my $self = shift;
1532     my ($args) = @_;
1533
1534     # XXX What should happen if this fails?
1535     my $blist = $self->get_bucket_list({
1536         key_md5 => $args->{key_md5},
1537     }) or DBM::Deep->_throw_error( "How did delete_key fail (no blist)?!" );
1538
1539     # Save the location so that we can free the data
1540     my $location = $blist->get_data_location_for({
1541         allow_head => 0,
1542     });
1543     my $old_value = $location && $self->engine->_load_sector( $location );
1544
1545     my @trans_ids = $self->engine->get_running_txn_ids;
1546
1547     # If we're the HEAD and there are running txns, then we need to clone this value to the other
1548     # transactions to preserve Isolation.
1549     if ( $self->engine->trans_id == 0 ) {
1550         if ( @trans_ids ) {
1551             foreach my $other_trans_id ( @trans_ids ) {
1552                 next if $blist->get_data_location_for({ trans_id => $other_trans_id, allow_head => 0 });
1553                 $blist->write_md5({
1554                     trans_id => $other_trans_id,
1555                     key      => $args->{key},
1556                     key_md5  => $args->{key_md5},
1557                     value    => $old_value->clone,
1558                 });
1559             }
1560         }
1561     }
1562
1563     my $data;
1564     if ( @trans_ids ) {
1565         $blist->mark_deleted( $args );
1566
1567         if ( $old_value ) {
1568             $data = $old_value->data;
1569             $old_value->free;
1570         }
1571     }
1572     else {
1573         $data = $blist->delete_md5( $args );
1574     }
1575
1576     return $data;
1577 }
1578
1579 sub get_blist_loc {
1580     my $self = shift;
1581
1582     my $e = $self->engine;
1583     my $blist_loc = $e->storage->read_at( $self->offset + $self->base_size, $e->byte_size );
1584     return unpack( $StP{$e->byte_size}, $blist_loc );
1585 }
1586
1587 sub get_bucket_list {
1588     my $self = shift;
1589     my ($args) = @_;
1590     $args ||= {};
1591
1592     # XXX Add in check here for recycling?
1593
1594     my $engine = $self->engine;
1595
1596     my $blist_loc = $self->get_blist_loc;
1597
1598     # There's no index or blist yet
1599     unless ( $blist_loc ) {
1600         return unless $args->{create};
1601
1602         my $blist = DBM::Deep::Engine::Sector::BucketList->new({
1603             engine  => $engine,
1604             key_md5 => $args->{key_md5},
1605         });
1606
1607         $engine->storage->print_at( $self->offset + $self->base_size,
1608             pack( $StP{$engine->byte_size}, $blist->offset ),
1609         );
1610
1611         return $blist;
1612     }
1613
1614     my $sector = $engine->_load_sector( $blist_loc )
1615         or DBM::Deep->_throw_error( "Cannot read sector at $blist_loc in get_bucket_list()" );
1616     my $i = 0;
1617     my $last_sector = undef;
1618     while ( $sector->isa( 'DBM::Deep::Engine::Sector::Index' ) ) {
1619         $blist_loc = $sector->get_entry( ord( substr( $args->{key_md5}, $i++, 1 ) ) );
1620         $last_sector = $sector;
1621         if ( $blist_loc ) {
1622             $sector = $engine->_load_sector( $blist_loc )
1623                 or DBM::Deep->_throw_error( "Cannot read sector at $blist_loc in get_bucket_list()" );
1624         }
1625         else {
1626             $sector = undef;
1627             last;
1628         }
1629     }
1630
1631     # This means we went through the Index sector(s) and found an empty slot
1632     unless ( $sector ) {
1633         return unless $args->{create};
1634
1635         DBM::Deep->_throw_error( "No last_sector when attempting to build a new entry" )
1636             unless $last_sector;
1637
1638         my $blist = DBM::Deep::Engine::Sector::BucketList->new({
1639             engine  => $engine,
1640             key_md5 => $args->{key_md5},
1641         });
1642
1643         $last_sector->set_entry( ord( substr( $args->{key_md5}, $i - 1, 1 ) ) => $blist->offset );
1644
1645         return $blist;
1646     }
1647
1648     $sector->find_md5( $args->{key_md5} );
1649
1650     # See whether or not we need to reindex the bucketlist
1651     # Yes, the double-braces are there for a reason. if() doesn't create a redo-able block,
1652     # so we have to create a bare block within the if() for redo-purposes. Patch and idea
1653     # submitted by sprout@cpan.org. -RobK, 2008-01-09
1654     if ( !$sector->has_md5 && $args->{create} && $sector->{idx} == -1 ) {{
1655         my $redo;
1656
1657         my $new_index = DBM::Deep::Engine::Sector::Index->new({
1658             engine => $engine,
1659         });
1660
1661         my %blist_cache;
1662         #XXX q.v. the comments for this function.
1663         foreach my $entry ( $sector->chopped_up ) {
1664             my ($spot, $md5) = @{$entry};
1665             my $idx = ord( substr( $md5, $i, 1 ) );
1666
1667             # XXX This is inefficient
1668             my $blist = $blist_cache{$idx}
1669                 ||= DBM::Deep::Engine::Sector::BucketList->new({
1670                     engine => $engine,
1671                 });
1672
1673             $new_index->set_entry( $idx => $blist->offset );
1674
1675             my $new_spot = $blist->write_at_next_open( $md5 );
1676             $engine->reindex_entry( $spot => $new_spot );
1677         }
1678
1679         # Handle the new item separately.
1680         {
1681             my $idx = ord( substr( $args->{key_md5}, $i, 1 ) );
1682
1683             # If all the previous blist's items have been thrown into one
1684             # blist and the new item belongs in there too, we need
1685             # another index.
1686             if ( keys %blist_cache == 1 and each %blist_cache == $idx ) {
1687                 ++$i, ++$redo;
1688             } else {
1689                 my $blist = $blist_cache{$idx}
1690                     ||= DBM::Deep::Engine::Sector::BucketList->new({
1691                         engine => $engine,
1692                     });
1693
1694                 $new_index->set_entry( $idx => $blist->offset );
1695
1696                 #XXX THIS IS HACKY!
1697                 $blist->find_md5( $args->{key_md5} );
1698                 $blist->write_md5({
1699                     key     => $args->{key},
1700                     key_md5 => $args->{key_md5},
1701                     value   => DBM::Deep::Engine::Sector::Null->new({
1702                         engine => $engine,
1703                         data   => undef,
1704                     }),
1705                 });
1706             }
1707 #            my $blist = $blist_cache{$idx}
1708 #                ||= DBM::Deep::Engine::Sector::BucketList->new({
1709 #                    engine => $engine,
1710 #                });
1711 #
1712 #            $new_index->set_entry( $idx => $blist->offset );
1713 #
1714 #            #XXX THIS IS HACKY!
1715 #            $blist->find_md5( $args->{key_md5} );
1716 #            $blist->write_md5({
1717 #                key     => $args->{key},
1718 #                key_md5 => $args->{key_md5},
1719 #                value   => DBM::Deep::Engine::Sector::Null->new({
1720 #                    engine => $engine,
1721 #                    data   => undef,
1722 #                }),
1723 #            });
1724         }
1725
1726         if ( $last_sector ) {
1727             $last_sector->set_entry(
1728                 ord( substr( $args->{key_md5}, $i - 1, 1 ) ),
1729                 $new_index->offset,
1730             );
1731         } else {
1732             $engine->storage->print_at( $self->offset + $self->base_size,
1733                 pack( $StP{$engine->byte_size}, $new_index->offset ),
1734             );
1735         }
1736
1737         $sector->clear;
1738         $sector->free;
1739
1740         if ( $redo ) {
1741             (undef, $sector) = %blist_cache;
1742             $last_sector = $new_index;
1743             redo;
1744         }
1745
1746         $sector = $blist_cache{ ord( substr( $args->{key_md5}, $i, 1 ) ) };
1747         $sector->find_md5( $args->{key_md5} );
1748     }}
1749
1750     return $sector;
1751 }
1752
1753 sub get_class_offset {
1754     my $self = shift;
1755
1756     my $e = $self->engine;
1757     return unpack(
1758         $StP{$e->byte_size},
1759         $e->storage->read_at(
1760             $self->offset + $self->base_size + 1 * $e->byte_size, $e->byte_size,
1761         ),
1762     );
1763 }
1764
1765 sub get_classname {
1766     my $self = shift;
1767
1768     my $class_offset = $self->get_class_offset;
1769
1770     return unless $class_offset;
1771
1772     return $self->engine->_load_sector( $class_offset )->data;
1773 }
1774
1775 sub data {
1776     my $self = shift;
1777
1778     unless ( $self->engine->cache->{ $self->offset } ) {
1779         my $new_obj = DBM::Deep->new({
1780             type        => $self->type,
1781             base_offset => $self->offset,
1782             staleness   => $self->staleness,
1783             storage     => $self->engine->storage,
1784             engine      => $self->engine,
1785         });
1786
1787         if ( $self->engine->storage->{autobless} ) {
1788             my $classname = $self->get_classname;
1789             if ( defined $classname ) {
1790                 bless $new_obj, $classname;
1791             }
1792         }
1793
1794         $self->engine->cache->{$self->offset} = $new_obj;
1795     }
1796     return $self->engine->cache->{$self->offset};
1797 }
1798
1799 sub free {
1800     my $self = shift;
1801
1802     # We're not ready to be removed yet.
1803     if ( $self->decrement_refcount > 0 ) {
1804         return;
1805     }
1806
1807     # Rebless the object into DBM::Deep::Null.
1808     eval { %{ $self->engine->cache->{ $self->offset } } = (); };
1809     eval { @{ $self->engine->cache->{ $self->offset } } = (); };
1810     bless $self->engine->cache->{ $self->offset }, 'DBM::Deep::Null';
1811     delete $self->engine->cache->{ $self->offset };
1812
1813     my $blist_loc = $self->get_blist_loc;
1814     $self->engine->_load_sector( $blist_loc )->free if $blist_loc;
1815
1816     my $class_loc = $self->get_class_offset;
1817     $self->engine->_load_sector( $class_loc )->free if $class_loc;
1818
1819     $self->SUPER::free();
1820 }
1821
1822 sub increment_refcount {
1823     my $self = shift;
1824
1825     my $refcount = $self->get_refcount;
1826
1827     $refcount++;
1828
1829     $self->write_refcount( $refcount );
1830
1831     return $refcount;
1832 }
1833
1834 sub decrement_refcount {
1835     my $self = shift;
1836
1837     my $refcount = $self->get_refcount;
1838
1839     $refcount--;
1840
1841     $self->write_refcount( $refcount );
1842
1843     return $refcount;
1844 }
1845
1846 sub get_refcount {
1847     my $self = shift;
1848
1849     my $e = $self->engine;
1850     return unpack(
1851         $StP{$e->byte_size},
1852         $e->storage->read_at(
1853             $self->offset + $self->base_size + 2 * $e->byte_size, $e->byte_size,
1854         ),
1855     );
1856 }
1857
1858 sub write_refcount {
1859     my $self = shift;
1860     my ($num) = @_;
1861
1862     my $e = $self->engine;
1863     $e->storage->print_at(
1864         $self->offset + $self->base_size + 2 * $e->byte_size,
1865         pack( $StP{$e->byte_size}, $num ),
1866     );
1867 }
1868
1869 package DBM::Deep::Engine::Sector::BucketList;
1870
1871 our @ISA = qw( DBM::Deep::Engine::Sector );
1872
1873 sub _init {
1874     my $self = shift;
1875
1876     my $engine = $self->engine;
1877
1878     unless ( $self->offset ) {
1879         my $leftover = $self->size - $self->base_size;
1880
1881         $self->{offset} = $engine->_request_blist_sector( $self->size );
1882         $engine->storage->print_at( $self->offset, $engine->SIG_BLIST ); # Sector type
1883         # Skip staleness counter
1884         $engine->storage->print_at( $self->offset + $self->base_size,
1885             chr(0) x $leftover, # Zero-fill the data
1886         );
1887     }
1888
1889     if ( $self->{key_md5} ) {
1890         $self->find_md5;
1891     }
1892
1893     return $self;
1894 }
1895
1896 sub clear {
1897     my $self = shift;
1898     $self->engine->storage->print_at( $self->offset + $self->base_size,
1899         chr(0) x ($self->size - $self->base_size), # Zero-fill the data
1900     );
1901 }
1902
1903 sub size {
1904     my $self = shift;
1905     unless ( $self->{size} ) {
1906         my $e = $self->engine;
1907         # Base + numbuckets * bucketsize
1908         $self->{size} = $self->base_size + $e->max_buckets * $self->bucket_size;
1909     }
1910     return $self->{size};
1911 }
1912
1913 sub free_meth { return '_add_free_blist_sector' }
1914
1915 sub free {
1916     my $self = shift;
1917
1918     my $e = $self->engine;
1919     foreach my $bucket ( $self->chopped_up ) {
1920         my $rest = $bucket->[-1];
1921
1922         # Delete the keysector
1923         my $l = unpack( $StP{$e->byte_size}, substr( $rest, $e->hash_size, $e->byte_size ) );
1924         my $s = $e->_load_sector( $l ); $s->free if $s;
1925
1926         # Delete the HEAD sector
1927         $l = unpack( $StP{$e->byte_size},
1928             substr( $rest,
1929                 $e->hash_size + $e->byte_size,
1930                 $e->byte_size,
1931             ),
1932         );
1933         $s = $e->_load_sector( $l ); $s->free if $s;
1934
1935         foreach my $txn ( 0 .. $e->num_txns - 2 ) {
1936             my $l = unpack( $StP{$e->byte_size},
1937                 substr( $rest,
1938                     $e->hash_size + 2 * $e->byte_size + $txn * ($e->byte_size + $STALE_SIZE),
1939                     $e->byte_size,
1940                 ),
1941             );
1942             my $s = $e->_load_sector( $l ); $s->free if $s;
1943         }
1944     }
1945
1946     $self->SUPER::free();
1947 }
1948
1949 sub bucket_size {
1950     my $self = shift;
1951     unless ( $self->{bucket_size} ) {
1952         my $e = $self->engine;
1953         # Key + head (location) + transactions (location + staleness-counter)
1954         my $location_size = $e->byte_size + $e->byte_size + ($e->num_txns - 1) * ($e->byte_size + $STALE_SIZE);
1955         $self->{bucket_size} = $e->hash_size + $location_size;
1956     }
1957     return $self->{bucket_size};
1958 }
1959
1960 # XXX This is such a poor hack. I need to rethink this code.
1961 sub chopped_up {
1962     my $self = shift;
1963
1964     my $e = $self->engine;
1965
1966     my @buckets;
1967     foreach my $idx ( 0 .. $e->max_buckets - 1 ) {
1968         my $spot = $self->offset + $self->base_size + $idx * $self->bucket_size;
1969         my $md5 = $e->storage->read_at( $spot, $e->hash_size );
1970
1971         #XXX If we're chopping, why would we ever have the blank_md5?
1972         last if $md5 eq $e->blank_md5;
1973
1974         my $rest = $e->storage->read_at( undef, $self->bucket_size - $e->hash_size );
1975         push @buckets, [ $spot, $md5 . $rest ];
1976     }
1977
1978     return @buckets;
1979 }
1980
1981 sub write_at_next_open {
1982     my $self = shift;
1983     my ($entry) = @_;
1984
1985     #XXX This is such a hack!
1986     $self->{_next_open} = 0 unless exists $self->{_next_open};
1987
1988     my $spot = $self->offset + $self->base_size + $self->{_next_open}++ * $self->bucket_size;
1989     $self->engine->storage->print_at( $spot, $entry );
1990
1991     return $spot;
1992 }
1993
1994 sub has_md5 {
1995     my $self = shift;
1996     unless ( exists $self->{found} ) {
1997         $self->find_md5;
1998     }
1999     return $self->{found};
2000 }
2001
2002 sub find_md5 {
2003     my $self = shift;
2004
2005     $self->{found} = undef;
2006     $self->{idx}   = -1;
2007
2008     if ( @_ ) {
2009         $self->{key_md5} = shift;
2010     }
2011
2012     # If we don't have an MD5, then what are we supposed to do?
2013     unless ( exists $self->{key_md5} ) {
2014         DBM::Deep->_throw_error( "Cannot find_md5 without a key_md5 set" );
2015     }
2016
2017     my $e = $self->engine;
2018     foreach my $idx ( 0 .. $e->max_buckets - 1 ) {
2019         my $potential = $e->storage->read_at(
2020             $self->offset + $self->base_size + $idx * $self->bucket_size, $e->hash_size,
2021         );
2022
2023         if ( $potential eq $e->blank_md5 ) {
2024             $self->{idx} = $idx;
2025             return;
2026         }
2027
2028         if ( $potential eq $self->{key_md5} ) {
2029             $self->{found} = 1;
2030             $self->{idx} = $idx;
2031             return;
2032         }
2033     }
2034
2035     return;
2036 }
2037
2038 sub write_md5 {
2039     my $self = shift;
2040     my ($args) = @_;
2041
2042     DBM::Deep->_throw_error( "write_md5: no key" ) unless exists $args->{key};
2043     DBM::Deep->_throw_error( "write_md5: no key_md5" ) unless exists $args->{key_md5};
2044     DBM::Deep->_throw_error( "write_md5: no value" ) unless exists $args->{value};
2045
2046     my $engine = $self->engine;
2047
2048     $args->{trans_id} = $engine->trans_id unless exists $args->{trans_id};
2049
2050     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
2051     $engine->add_entry( $args->{trans_id}, $spot );
2052
2053     unless ($self->{found}) {
2054         my $key_sector = DBM::Deep::Engine::Sector::Scalar->new({
2055             engine => $engine,
2056             data   => $args->{key},
2057         });
2058
2059         $engine->storage->print_at( $spot,
2060             $args->{key_md5},
2061             pack( $StP{$engine->byte_size}, $key_sector->offset ),
2062         );
2063     }
2064
2065     my $loc = $spot
2066       + $engine->hash_size
2067       + $engine->byte_size;
2068
2069     if ( $args->{trans_id} ) {
2070         $loc += $engine->byte_size + ($args->{trans_id} - 1) * ( $engine->byte_size + $STALE_SIZE );
2071
2072         $engine->storage->print_at( $loc,
2073             pack( $StP{$engine->byte_size}, $args->{value}->offset ),
2074             pack( $StP{$STALE_SIZE}, $engine->get_txn_staleness_counter( $args->{trans_id} ) ),
2075         );
2076     }
2077     else {
2078         $engine->storage->print_at( $loc,
2079             pack( $StP{$engine->byte_size}, $args->{value}->offset ),
2080         );
2081     }
2082 }
2083
2084 sub mark_deleted {
2085     my $self = shift;
2086     my ($args) = @_;
2087     $args ||= {};
2088
2089     my $engine = $self->engine;
2090
2091     $args->{trans_id} = $engine->trans_id unless exists $args->{trans_id};
2092
2093     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
2094     $engine->add_entry( $args->{trans_id}, $spot );
2095
2096     my $loc = $spot
2097       + $engine->hash_size
2098       + $engine->byte_size;
2099
2100     if ( $args->{trans_id} ) {
2101         $loc += $engine->byte_size + ($args->{trans_id} - 1) * ( $engine->byte_size + $STALE_SIZE );
2102
2103         $engine->storage->print_at( $loc,
2104             pack( $StP{$engine->byte_size}, 1 ), # 1 is the marker for deleted
2105             pack( $StP{$STALE_SIZE}, $engine->get_txn_staleness_counter( $args->{trans_id} ) ),
2106         );
2107     }
2108     else {
2109         $engine->storage->print_at( $loc,
2110             pack( $StP{$engine->byte_size}, 1 ), # 1 is the marker for deleted
2111         );
2112     }
2113
2114 }
2115
2116 sub delete_md5 {
2117     my $self = shift;
2118     my ($args) = @_;
2119
2120     my $engine = $self->engine;
2121     return undef unless $self->{found};
2122
2123     # Save the location so that we can free the data
2124     my $location = $self->get_data_location_for({
2125         allow_head => 0,
2126     });
2127     my $key_sector = $self->get_key_for;
2128
2129     my $spot = $self->offset + $self->base_size + $self->{idx} * $self->bucket_size;
2130     $engine->storage->print_at( $spot,
2131         $engine->storage->read_at(
2132             $spot + $self->bucket_size,
2133             $self->bucket_size * ( $engine->max_buckets - $self->{idx} - 1 ),
2134         ),
2135         chr(0) x $self->bucket_size,
2136     );
2137
2138     $key_sector->free;
2139
2140     my $data_sector = $self->engine->_load_sector( $location );
2141     my $data = $data_sector->data;
2142     $data_sector->free;
2143
2144     return $data;
2145 }
2146
2147 sub get_data_location_for {
2148     my $self = shift;
2149     my ($args) = @_;
2150     $args ||= {};
2151
2152     $args->{allow_head} = 0 unless exists $args->{allow_head};
2153     $args->{trans_id}   = $self->engine->trans_id unless exists $args->{trans_id};
2154     $args->{idx}        = $self->{idx} unless exists $args->{idx};
2155
2156     my $e = $self->engine;
2157
2158     my $spot = $self->offset + $self->base_size
2159       + $args->{idx} * $self->bucket_size
2160       + $e->hash_size
2161       + $e->byte_size;
2162
2163     if ( $args->{trans_id} ) {
2164         $spot += $e->byte_size + ($args->{trans_id} - 1) * ( $e->byte_size + $STALE_SIZE );
2165     }
2166
2167     my $buffer = $e->storage->read_at(
2168         $spot,
2169         $e->byte_size + $STALE_SIZE,
2170     );
2171     my ($loc, $staleness) = unpack( $StP{$e->byte_size} . ' ' . $StP{$STALE_SIZE}, $buffer );
2172
2173     # XXX Merge the two if-clauses below
2174     if ( $args->{trans_id} ) {
2175         # We have found an entry that is old, so get rid of it
2176         if ( $staleness != (my $s = $e->get_txn_staleness_counter( $args->{trans_id} ) ) ) {
2177             $e->storage->print_at(
2178                 $spot,
2179                 pack( $StP{$e->byte_size} . ' ' . $StP{$STALE_SIZE}, (0) x 2 ),
2180             );
2181             $loc = 0;
2182         }
2183     }
2184
2185     # If we're in a transaction and we never wrote to this location, try the
2186     # HEAD instead.
2187     if ( $args->{trans_id} && !$loc && $args->{allow_head} ) {
2188         return $self->get_data_location_for({
2189             trans_id   => 0,
2190             allow_head => 1,
2191             idx        => $args->{idx},
2192         });
2193     }
2194
2195     return $loc <= 1 ? 0 : $loc;
2196 }
2197
2198 sub get_data_for {
2199     my $self = shift;
2200     my ($args) = @_;
2201     $args ||= {};
2202
2203     return unless $self->{found};
2204     my $location = $self->get_data_location_for({
2205         allow_head => $args->{allow_head},
2206     });
2207     return $self->engine->_load_sector( $location );
2208 }
2209
2210 sub get_key_for {
2211     my $self = shift;
2212     my ($idx) = @_;
2213     $idx = $self->{idx} unless defined $idx;
2214
2215     if ( $idx >= $self->engine->max_buckets ) {
2216         DBM::Deep->_throw_error( "get_key_for(): Attempting to retrieve $idx" );
2217     }
2218
2219     my $location = $self->engine->storage->read_at(
2220         $self->offset + $self->base_size + $idx * $self->bucket_size + $self->engine->hash_size,
2221         $self->engine->byte_size,
2222     );
2223     $location = unpack( $StP{$self->engine->byte_size}, $location );
2224     DBM::Deep->_throw_error( "get_key_for: No location?" ) unless $location;
2225
2226     return $self->engine->_load_sector( $location );
2227 }
2228
2229 package DBM::Deep::Engine::Sector::Index;
2230
2231 our @ISA = qw( DBM::Deep::Engine::Sector );
2232
2233 sub _init {
2234     my $self = shift;
2235
2236     my $engine = $self->engine;
2237
2238     unless ( $self->offset ) {
2239         my $leftover = $self->size - $self->base_size;
2240
2241         $self->{offset} = $engine->_request_index_sector( $self->size );
2242         $engine->storage->print_at( $self->offset, $engine->SIG_INDEX ); # Sector type
2243         # Skip staleness counter
2244         $engine->storage->print_at( $self->offset + $self->base_size,
2245             chr(0) x $leftover, # Zero-fill the rest
2246         );
2247     }
2248
2249     return $self;
2250 }
2251
2252 #XXX Change here
2253 sub size {
2254     my $self = shift;
2255     unless ( $self->{size} ) {
2256         my $e = $self->engine;
2257         $self->{size} = $self->base_size + $e->byte_size * $e->hash_chars;
2258     }
2259     return $self->{size};
2260 }
2261
2262 sub free_meth { return '_add_free_index_sector' }
2263
2264 sub free {
2265     my $self = shift;
2266     my $e = $self->engine;
2267
2268     for my $i ( 0 .. $e->hash_chars - 1 ) {
2269         my $l = $self->get_entry( $i ) or next;
2270         $e->_load_sector( $l )->free;
2271     }
2272
2273     $self->SUPER::free();
2274 }
2275
2276 sub _loc_for {
2277     my $self = shift;
2278     my ($idx) = @_;
2279     return $self->offset + $self->base_size + $idx * $self->engine->byte_size;
2280 }
2281
2282 sub get_entry {
2283     my $self = shift;
2284     my ($idx) = @_;
2285
2286     my $e = $self->engine;
2287
2288     DBM::Deep->_throw_error( "get_entry: Out of range ($idx)" )
2289         if $idx < 0 || $idx >= $e->hash_chars;
2290
2291     return unpack(
2292         $StP{$e->byte_size},
2293         $e->storage->read_at( $self->_loc_for( $idx ), $e->byte_size ),
2294     );
2295 }
2296
2297 sub set_entry {
2298     my $self = shift;
2299     my ($idx, $loc) = @_;
2300
2301     my $e = $self->engine;
2302
2303     DBM::Deep->_throw_error( "set_entry: Out of range ($idx)" )
2304         if $idx < 0 || $idx >= $e->hash_chars;
2305
2306     $self->engine->storage->print_at(
2307         $self->_loc_for( $idx ),
2308         pack( $StP{$e->byte_size}, $loc ),
2309     );
2310 }
2311
2312 # This was copied from MARCEL's Class::Null. However, I couldn't use it because
2313 # I need an undef value, not an implementation of the Null Class pattern.
2314 package DBM::Deep::Null;
2315
2316 use overload
2317     'bool'   => sub { undef },
2318     '""'     => sub { undef },
2319     '0+'     => sub { undef },
2320     fallback => 1,
2321     nomethod => 'AUTOLOAD';
2322
2323 sub AUTOLOAD { return; }
2324
2325 1;
2326 __END__